code.delx.au - gnu-emacs/blob - lisp/cedet/semantic/util.el

   1 ;;; semantic/util.el --- Utilities for use with semantic tag tables
   2
   3 ;;; Copyright (C) 1999, 2000, 2001, 2002, 2003, 2004, 2005, 2007,
   4 ;;; 2008, 2009 Free Software Foundation, Inc.
   5
   6 ;; Author: Eric M. Ludlam <zappo@gnu.org>
   7 ;; Keywords: syntax
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25 ;;
  26 ;; Semantic utility API for use with semantic tag tables.
  27 ;;
  28
  29 (require 'semantic)
  30
  31 (eval-when-compile
  32   (require 'semantic/db-find)
  33   ;; For semantic-find-tags-by-class, semantic--find-tags-by-function,
  34   ;; and semantic-brute-find-tag-standard:
  35   (require 'semantic/find))
  36
  37 (declare-function data-debug-insert-stuff-list "data-debug")
  38 (declare-function data-debug-insert-thing "data-debug")
  39 (declare-function semantic-ctxt-current-symbol-and-bounds "semantic/ctxt")
  40
  41 ;;; Code:
  42
  43 (defvar semantic-type-relation-separator-character '(".")
  44   "Character strings used to separate a parent/child relationship.
  45 This list of strings are used for displaying or finding separators
  46 in variable field dereferencing.  The first character will be used for
  47 display.  In C, a type field is separated like this: \"type.field\"
  48 thus, the character is a \".\".  In C, and additional value of \"->\"
  49 would be in the list, so that \"type->field\" could be found.")
  50 (make-variable-buffer-local 'semantic-type-relation-separator-character)
  51
  52 (defvar semantic-equivalent-major-modes nil
  53   "List of major modes which are considered equivalent.
  54 Equivalent modes share a parser, and a set of override methods.
  55 A value of nil means that the current major mode is the only one.")
  56 (make-variable-buffer-local 'semantic-equivalent-major-modes)
  57
  58 ;; These semanticdb calls will throw warnings in the byte compiler.
  59 ;; Doing the right thing to make them available at compile time
  60 ;; really messes up the compilation sequence.
  61 (defun semantic-file-tag-table (file)
  62   "Return a tag table for FILE.
  63 If it is loaded, return the stream after making sure it's ok.
  64 If FILE is not loaded, check to see if `semanticdb' feature exists,
  65    and use it to get tags from files not in memory.
  66 If FILE is not loaded, and semanticdb is not available, find the file
  67    and parse it."
  68   (save-match-data
  69     (if (find-buffer-visiting file)
  70         (with-current-buffer (find-buffer-visiting file)
  71           (semantic-fetch-tags))
  72       ;; File not loaded
  73       (if (and (require 'semantic/db-mode)
  74                (semanticdb-minor-mode-p))
  75           ;; semanticdb is around, use it.
  76           (semanticdb-file-stream file)
  77         ;; Get the stream ourselves.
  78         (with-current-buffer (find-file-noselect file)
  79           (semantic-fetch-tags))))))
  80
  81 (semantic-alias-obsolete 'semantic-file-token-stream
  82                          'semantic-file-tag-table "23.2")
  83
  84 (defun semantic-something-to-tag-table (something)
  85   "Convert SOMETHING into a semantic tag table.
  86 Something can be a tag with a valid BUFFER property, a tag table, a
  87 buffer, or a filename.  If SOMETHING is nil return nil."
  88   (cond
  89    ;; A list of tags
  90    ((and (listp something)
  91          (semantic-tag-p (car something)))
  92     something)
  93    ;; A buffer
  94    ((bufferp something)
  95     (with-current-buffer something
  96       (semantic-fetch-tags)))
  97    ;; A Tag: Get that tag's buffer
  98    ((and (semantic-tag-with-position-p something)
  99          (semantic-tag-in-buffer-p something))
 100     (with-current-buffer (semantic-tag-buffer something)
 101       (semantic-fetch-tags)))
 102    ;; Tag with a file name in it
 103    ((and (semantic-tag-p something)
 104          (semantic-tag-file-name something)
 105          (file-exists-p (semantic-tag-file-name something)))
 106     (semantic-file-tag-table
 107      (semantic-tag-file-name something)))
 108    ;; A file name
 109    ((and (stringp something)
 110          (file-exists-p something))
 111     (semantic-file-tag-table something))
 112    ;; A Semanticdb table
 113    ((and (featurep 'semantic/db)
 114          (semanticdb-minor-mode-p)
 115          (semanticdb-abstract-table-child-p something))
 116     (semanticdb-refresh-table something)
 117     (semanticdb-get-tags something))
 118    ;; Semanticdb find-results
 119    ((and (featurep 'semantic/db)
 120          (semanticdb-minor-mode-p)
 121          (require 'semantic/db-find)
 122          (semanticdb-find-results-p something))
 123     (semanticdb-strip-find-results something))
 124    ;; NOTE: This commented out since if a search result returns
 125    ;;       empty, that empty would turn into everything on the next search.
 126    ;; Use the current buffer for nil
 127 ;;   ((null something)
 128 ;;    (semantic-fetch-tags))
 129    ;; don't know what it is
 130    (t nil)))
 131
 132 (semantic-alias-obsolete 'semantic-something-to-stream
 133                          'semantic-something-to-tag-table "23.2")
 134
 135 ;;; Recursive searching through dependency trees
 136 ;;
 137 ;; This will depend on the general searching APIS defined above.
 138 ;; but will add full recursion through the dependencies list per
 139 ;; stream.
 140 (defun semantic-recursive-find-nonterminal-by-name (name buffer)
 141   "Recursively find the first occurrence of NAME.
 142 Start search with BUFFER.  Recurse through all dependencies till found.
 143 The return item is of the form (BUFFER TOKEN) where BUFFER is the buffer
 144 in which TOKEN (the token found to match NAME) was found.
 145
 146 THIS ISN'T USED IN SEMANTIC.  DELETE ME SOON."
 147   (with-current-buffer buffer
 148     (let* ((stream (semantic-fetch-tags))
 149            (includelist (or (semantic-find-tags-by-class 'include stream)
 150                             "empty.silly.thing"))
 151            (found (semantic-find-first-tag-by-name name stream))
 152            (unfound nil))
 153       (while (and (not found) includelist)
 154         (let ((fn (semantic-dependency-tag-file (car includelist))))
 155           (if (and fn (not (member fn unfound)))
 156               (with-current-buffer (save-match-data
 157                                      (find-file-noselect fn))
 158                 (message "Scanning %s" (buffer-file-name))
 159                 (setq stream (semantic-fetch-tags))
 160                 (setq found (semantic-find-first-tag-by-name name stream))
 161                 (if found
 162                     (setq found (cons (current-buffer) (list found)))
 163                   (setq includelist
 164                         (append includelist
 165                                 (semantic-find-tags-by-class
 166                                  'include stream))))
 167                 (setq unfound (cons fn unfound)))))
 168         (setq includelist (cdr includelist)))
 169       found)))
 170 (make-obsolete 'semantic-recursive-find-nonterminal-by-name
 171                "Do not use this function." "23.2")
 172
 173 ;;; Completion APIs
 174 ;;
 175 ;; These functions provide minibuffer reading/completion for lists of
 176 ;; nonterminals.
 177 (defvar semantic-read-symbol-history nil
 178   "History for a symbol read.")
 179
 180 (defun semantic-read-symbol (prompt &optional default stream filter)
 181   "Read a symbol name from the user for the current buffer.
 182 PROMPT is the prompt to use.
 183 Optional arguments:
 184 DEFAULT is the default choice.  If no default is given, one is read
 185 from under point.
 186 STREAM is the list of tokens to complete from.
 187 FILTER is provides a filter on the types of things to complete.
 188 FILTER must be a function to call on each element."
 189   (if (not default) (setq default (thing-at-point 'symbol)))
 190   (if (not stream) (setq stream (semantic-fetch-tags)))
 191   (setq stream
 192         (if filter
 193             (semantic--find-tags-by-function filter stream)
 194           (semantic-brute-find-tag-standard stream)))
 195   (if (and default (string-match ":" prompt))
 196       (setq prompt
 197             (concat (substring prompt 0 (match-end 0))
 198                     " (default: " default ") ")))
 199   (completing-read prompt stream nil t ""
 200                    'semantic-read-symbol-history
 201                    default))
 202
 203 (defun semantic-read-variable (prompt &optional default stream)
 204   "Read a variable name from the user for the current buffer.
 205 PROMPT is the prompt to use.
 206 Optional arguments:
 207 DEFAULT is the default choice.  If no default is given, one is read
 208 from under point.
 209 STREAM is the list of tokens to complete from."
 210   (semantic-read-symbol
 211    prompt default
 212    (or (semantic-find-tags-by-class
 213         'variable (or stream (current-buffer)))
 214        (error "No local variables"))))
 215
 216 (defun semantic-read-function (prompt &optional default stream)
 217   "Read a function name from the user for the current buffer.
 218 PROMPT is the prompt to use.
 219 Optional arguments:
 220 DEFAULT is the default choice.  If no default is given, one is read
 221 from under point.
 222 STREAM is the list of tags to complete from."
 223   (semantic-read-symbol
 224    prompt default
 225    (or (semantic-find-tags-by-class
 226         'function (or stream (current-buffer)))
 227        (error "No local functions"))))
 228
 229 (defun semantic-read-type (prompt &optional default stream)
 230   "Read a type name from the user for the current buffer.
 231 PROMPT is the prompt to use.
 232 Optional arguments:
 233 DEFAULT is the default choice.  If no default is given, one is read
 234 from under point.
 235 STREAM is the list of tags to complete from."
 236   (semantic-read-symbol
 237    prompt default
 238    (or (semantic-find-tags-by-class
 239         'type (or stream (current-buffer)))
 240        (error "No local types"))))
 241
 242 \f
 243 ;;; Interactive Functions for
 244 ;;
 245 (defun semantic-describe-tag (&optional tag)
 246   "Describe TAG in the minibuffer.
 247 If TAG is nil, describe the tag under the cursor."
 248   (interactive)
 249   (if (not tag) (setq tag (semantic-current-tag)))
 250   (semantic-fetch-tags)
 251   (if tag (message (semantic-format-tag-summarize tag))))
 252
 253 \f
 254 ;;; Putting keys on tags.
 255 ;;
 256 (defun semantic-add-label (label value &optional tag)
 257   "Add a LABEL with VALUE on TAG.
 258 If TAG is not specified, use the tag at point."
 259   (interactive "sLabel: \nXValue (eval): ")
 260   (if (not tag)
 261       (progn
 262         (semantic-fetch-tags)
 263         (setq tag (semantic-current-tag))))
 264   (semantic--tag-put-property tag (intern label) value)
 265   (message "Added label %s with value %S" label value))
 266
 267 (defun semantic-show-label (label &optional tag)
 268   "Show the value of LABEL on TAG.
 269 If TAG is not specified, use the tag at point."
 270   (interactive "sLabel: ")
 271   (if (not tag)
 272       (progn
 273         (semantic-fetch-tags)
 274         (setq tag (semantic-current-tag))))
 275   (message "%s: %S" label (semantic--tag-get-property tag (intern label))))
 276
 277 \f
 278 ;;; Hacks
 279 ;;
 280 ;; Some hacks to help me test these functions
 281 (defun semantic-describe-buffer-var-helper (varsym buffer)
 282   "Display to standard out the value of VARSYM in BUFFER."
 283   (require 'data-debug)
 284   (let ((value (with-current-buffer buffer
 285                  (symbol-value varsym))))
 286     (cond
 287      ((and (consp value)
 288            (< (length value) 10))
 289       ;; Draw the list of things in the list.
 290       (princ (format "  %s:  #<list of %d items>\n"
 291                      varsym (length value)))
 292       (data-debug-insert-stuff-list
 293        value "    " )
 294       )
 295      (t
 296       ;; Else do a one-liner.
 297       (data-debug-insert-thing
 298        value " " (concat " " (symbol-name varsym) ": "))
 299       ))))
 300
 301 (defun semantic-describe-buffer ()
 302   "Describe the semantic environment for the current buffer."
 303   (interactive)
 304   (let ((buff (current-buffer))
 305         )
 306
 307     (with-output-to-temp-buffer (help-buffer)
 308       (help-setup-xref (list #'semantic-describe-buffer) (interactive-p))
 309       (with-current-buffer standard-output
 310         (princ "Semantic Configuration in ")
 311         (princ (buffer-name buff))
 312         (princ "\n\n")
 313
 314         (princ "Buffer specific configuration items:\n")
 315         (let ((vars '(major-mode
 316                       semantic-case-fold
 317                       semantic-expand-nonterminal
 318                       semantic-parser-name
 319                       semantic-parse-tree-state
 320                       semantic-lex-analyzer
 321                       semantic-lex-reset-hooks
 322                       )))
 323           (dolist (V vars)
 324             (semantic-describe-buffer-var-helper V buff)))
 325
 326         (princ "\nGeneral configuration items:\n")
 327         (let ((vars '(semantic-inhibit-functions
 328                       semantic-init-hook
 329                       semantic-init-db-hook
 330                       semantic-unmatched-syntax-hook
 331                       semantic--before-fetch-tags-hook
 332                       semantic-after-toplevel-bovinate-hook
 333                       semantic-after-toplevel-cache-change-hook
 334                       semantic-before-toplevel-cache-flush-hook
 335                       semantic-dump-parse
 336
 337                       )))
 338           (dolist (V vars)
 339             (semantic-describe-buffer-var-helper V buff)))
 340
 341         (princ "\n\n")
 342         (mode-local-describe-bindings-2 buff)
 343         )))
 344   )
 345
 346 (defun semantic-current-tag-interactive (p)
 347   "Display the current token.
 348 Argument P is the point to search from in the current buffer."
 349   (interactive "d")
 350   (require 'semantic/find)
 351   (let ((tok (semantic-brute-find-innermost-tag-by-position
 352               p (current-buffer))))
 353     (message (mapconcat 'semantic-abbreviate-nonterminal tok ","))
 354     (car tok))
 355   )
 356
 357 (defun semantic-hack-search ()
 358   "Display info about something under the cursor using generic methods."
 359   (interactive)
 360   (require 'semantic/find)
 361   (let ((strm (cdr (semantic-fetch-tags)))
 362         (res nil))
 363     (setq res (semantic-brute-find-tag-by-position (point) strm))
 364     (if res
 365         (progn
 366           (pop-to-buffer "*SEMANTIC HACK RESULTS*")
 367           (require 'pp)
 368           (erase-buffer)
 369           (insert (pp-to-string res) "\n")
 370           (goto-char (point-min))
 371           (shrink-window-if-larger-than-buffer))
 372       (message "nil"))))
 373
 374 (defun semantic-assert-valid-token (tok)
 375   "Assert that TOK is a valid token."
 376   (if (semantic-tag-p tok)
 377       (if (semantic-tag-with-position-p tok)
 378           (let ((o  (semantic-tag-overlay tok)))
 379             (if (and (semantic-overlay-p o)
 380                      (not (semantic-overlay-live-p o)))
 381                 (let ((debug-on-error t))
 382                   (error "Tag %s is invalid!" (semantic-tag-name tok)))
 383               ;; else, tag is OK.
 384               ))
 385         ;; Positionless tags are also ok.
 386         )
 387     (let ((debug-on-error t))
 388       (error "Not a semantic tag: %S" tok))))
 389
 390 (defun semantic-sanity-check (&optional cache over notfirst)
 391   "Perform a sanity check on the current buffer.
 392 The buffer's set of overlays, and those overlays found via the cache
 393 are verified against each other.
 394 CACHE, and OVER are the semantic cache, and the overlay list.
 395 NOTFIRST indicates that this was not the first call in the recursive use."
 396   (interactive)
 397   (if (and (not cache) (not over) (not notfirst))
 398       (setq cache semantic--buffer-cache
 399             over (semantic-overlays-in (point-min) (point-max))))
 400   (while cache
 401     (let ((chil (semantic-tag-components-with-overlays (car cache))))
 402       (if (not (memq (semantic-tag-overlay (car cache)) over))
 403           (message "Tag %s not in buffer overlay list."
 404                    (semantic-format-tag-concise-prototype (car cache))))
 405       (setq over (delq (semantic-tag-overlay (car cache)) over))
 406       (setq over (semantic-sanity-check chil over t))
 407       (setq cache (cdr cache))))
 408   (if (not notfirst)
 409       ;; Strip out all overlays which aren't semantic overlays
 410       (let ((o nil))
 411         (while over
 412           (when (and (semantic-overlay-get (car over) 'semantic)
 413                      (not (eq (semantic-overlay-get (car over) 'semantic)
 414                               'unmatched)))
 415             (setq o (cons (car over) o)))
 416           (setq over (cdr over)))
 417         (message "Remaining overlays: %S" o)))
 418   over)
 419
 420 ;;; Interactive commands (from Senator).
 421
 422 ;; The Senator library from upstream CEDET is not included in the
 423 ;; built-in version of Emacs.  The plan is to fold it into the
 424 ;; different parts of CEDET and Emacs, so that it works
 425 ;; "transparently".  Here are some interactive commands based on
 426 ;; Senator.
 427
 428 ;; Symbol completion
 429
 430 (defun semantic-find-tag-for-completion (prefix)
 431   "Find all tags with name starting with PREFIX.
 432 This uses `semanticdb' when available."
 433   (let (result ctxt)
 434     ;; Try the Semantic analyzer
 435     (condition-case nil
 436         (and (featurep 'semantic/analyze)
 437              (setq ctxt (semantic-analyze-current-context))
 438              (setq result (semantic-analyze-possible-completions ctxt)))
 439       (error nil))
 440     (or result
 441         ;; If the analyzer fails, then go into boring completion.
 442         (if (and (featurep 'semantic/db)
 443                  (semanticdb-minor-mode-p)
 444                  (require 'semantic/db-find))
 445             (semanticdb-fast-strip-find-results
 446              (semanticdb-deep-find-tags-for-completion prefix))
 447           (semantic-deep-find-tags-for-completion prefix (current-buffer))))))
 448
 449 (defun semantic-complete-symbol (&optional predicate)
 450   "Complete the symbol under point, using Semantic facilities.
 451 When called from a program, optional arg PREDICATE is a predicate
 452 determining which symbols are considered."
 453   (interactive)
 454   (require 'semantic/ctxt)
 455   (let* ((start (car (nth 2 (semantic-ctxt-current-symbol-and-bounds
 456                              (point)))))
 457          (pattern (regexp-quote (buffer-substring start (point))))
 458          collection completion)
 459     (when start
 460       (if (and semantic--completion-cache
 461                (eq (nth 0 semantic--completion-cache) (current-buffer))
 462                (=  (nth 1 semantic--completion-cache) start)
 463                (save-excursion
 464                  (goto-char start)
 465                  (looking-at (nth 3 semantic--completion-cache))))
 466           ;; Use cached value.
 467           (setq collection (nthcdr 4 semantic--completion-cache))
 468         ;; Perform new query.
 469         (setq collection (semantic-find-tag-for-completion pattern))
 470         (setq semantic--completion-cache
 471               (append (list (current-buffer) start 0 pattern)
 472                       collection))))
 473     (if (null collection)
 474         (let ((str (if pattern (format " for \"%s\"" pattern) "")))
 475           (if (window-minibuffer-p (selected-window))
 476               (minibuffer-message (format " [No completions%s]" str))
 477             (message "Can't find completion%s" str)))
 478       (setq completion (try-completion pattern collection predicate))
 479       (if (string= pattern completion)
 480           (let ((list (all-completions pattern collection predicate)))
 481             (setq list (sort list 'string<))
 482             (if (> (length list) 1)
 483                 (with-output-to-temp-buffer "*Completions*"
 484                   (display-completion-list list pattern))
 485               ;; Bury any out-of-date completions buffer.
 486               (let ((win (get-buffer-window "*Completions*" 0)))
 487                 (if win (with-selected-window win (bury-buffer))))))
 488         ;; Exact match
 489         (delete-region start (point))
 490         (insert completion)
 491         ;; Bury any out-of-date completions buffer.
 492         (let ((win (get-buffer-window "*Completions*" 0)))
 493           (if win (with-selected-window win (bury-buffer))))))))
 494
 495 (provide 'semantic/util)
 496
 497 ;;; Minor modes
 498 ;;
 499 (require 'semantic/util-modes)
 500
 501 ;; arch-tag: eaa7808d-83b9-43fe-adf0-4fb742dcb956
 502 ;;; semantic/util.el ends here