code.delx.au - gnu-emacs/blob - lisp/international/utf7.el

   1 ;;; utf7.el --- UTF-7 encoding/decoding for Emacs   -*-coding: utf-8;-*-
   2
   3 ;; Copyright (C) 1999-2016 Free Software Foundation, Inc.
   4
   5 ;; Author: Jon K Hellan <hellan@acm.org>
   6 ;; Maintainer: bugs@gnus.org
   7 ;; Keywords: mail
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; UTF-7 - A Mail-Safe Transformation Format of Unicode - RFC 2152
  27 ;; This is a transformation format of Unicode that contains only 7-bit
  28 ;; ASCII octets and is intended to be readable by humans in the limiting
  29 ;; case that the document consists of characters from the US-ASCII
  30 ;; repertoire.
  31 ;; In short, runs of characters outside US-ASCII are encoded as base64
  32 ;; inside delimiters.
  33 ;; A variation of UTF-7 is specified in IMAP 4rev1 (RFC 2060) as the way
  34 ;; to represent characters outside US-ASCII in mailbox names in IMAP.
  35 ;; This library supports both variants, but the IMAP variation was the
  36 ;; reason I wrote it.
  37 ;; The routines convert UTF-7 -> UTF-16 (16 bit encoding of Unicode)
  38 ;; -> current character set, and vice versa.
  39 ;; However, until Emacs supports Unicode, the only Emacs character set
  40 ;; supported here is ISO-8859.1, which can trivially be converted to/from
  41 ;; Unicode.
  42 ;; When decoding results in a character outside the Emacs character set,
  43 ;; an error is thrown.  It is up to the application to recover.
  44
  45 ;; UTF-7 should be done by providing a coding system.  Mule-UCS does
  46 ;; already, but I don't know if it does the IMAP version and it's not
  47 ;; clear whether that should really be a coding system.  The UTF-16
  48 ;; part of the conversion can be done with coding systems available
  49 ;; with Mule-UCS or some versions of Emacs.  Unfortunately these were
  50 ;; done wrongly (regarding handling of byte-order marks and how the
  51 ;; variants were named), so we don't have a consistent name for the
  52 ;; necessary coding system.  The code below doesn't seem to DTRT
  53 ;; generally.  E.g.:
  54 ;;
  55 ;; (utf7-encode "a+£")
  56 ;;   => "a+ACsAow-"
  57 ;;
  58 ;; $ echo "a+£"|iconv -f utf-8 -t utf-7
  59 ;; a+-+AKM
  60 ;;
  61 ;;  -- fx
  62
  63
  64 ;;; Code:
  65
  66 (require 'base64)
  67 (eval-when-compile (require 'cl))
  68 (require 'mm-util)
  69
  70 (defconst utf7-direct-encoding-chars " -%'-*,-[]-}"
  71   "Character ranges which do not need escaping in UTF-7.")
  72
  73 (defconst utf7-imap-direct-encoding-chars
  74   (concat utf7-direct-encoding-chars "+\\~")
  75   "Character ranges which do not need escaping in the IMAP variant of UTF-7.")
  76
  77 (defconst utf7-utf-16-coding-system
  78   (cond ((mm-coding-system-p 'utf-16-be-no-signature) ; Mule-UCS
  79          'utf-16-be-no-signature)
  80         ((and (mm-coding-system-p 'utf-16-be) ; Emacs
  81               ;; Avoid versions with BOM.
  82               (= 2 (length (encode-coding-string "a" 'utf-16-be))))
  83          'utf-16-be)
  84         ((mm-coding-system-p 'utf-16-be-nosig) ; ?
  85          'utf-16-be-nosig))
  86   "Coding system which encodes big endian UTF-16 without a BOM signature.")
  87
  88 (defsubst utf7-imap-get-pad-length (len modulus)
  89   "Return required length of padding for IMAP modified base64 fragment."
  90   (mod (- len) modulus))
  91
  92 (defun utf7-encode-internal (&optional for-imap)
  93   "Encode text in (temporary) buffer as UTF-7.
  94 Use IMAP modification if FOR-IMAP is non-nil."
  95   (let ((start (point-min))
  96         (end (point-max)))
  97     (narrow-to-region start end)
  98     (goto-char start)
  99     (let* ((esc-char (if for-imap ?& ?+))
 100            (direct-encoding-chars
 101             (if for-imap utf7-imap-direct-encoding-chars
 102               utf7-direct-encoding-chars))
 103            (not-direct-encoding-chars (concat "^" direct-encoding-chars)))
 104       (while (not (eobp))
 105         (skip-chars-forward direct-encoding-chars)
 106         (unless (eobp)
 107           (insert esc-char)
 108           (let ((p (point))
 109                 (fc (following-char))
 110                 (run-length
 111                  (skip-chars-forward not-direct-encoding-chars)))
 112             (if (and (= fc esc-char)
 113                      (= run-length 1))  ; Lone esc-char?
 114                 (delete-char -1)        ; Now there's one too many
 115               (utf7-fragment-encode p (point) for-imap))
 116             (insert "-")))))))
 117
 118 (defun utf7-fragment-encode (start end &optional for-imap)
 119   "Encode text from START to END in buffer as UTF-7 escape fragment.
 120 Use IMAP modification if FOR-IMAP is non-nil."
 121   (save-restriction
 122     (let* ((buf (current-buffer))
 123            (base (with-temp-buffer
 124                    (set-buffer-multibyte nil)
 125                    (insert-buffer-substring buf start end)
 126                    (funcall (utf7-get-u16char-converter 'to-utf-16))
 127                    (base64-encode-region (point-min) (point-max))
 128                    (buffer-string))))
 129       (narrow-to-region start end)
 130       (delete-region (point-min) (point-max))
 131       (insert base))
 132     (goto-char (point-min))
 133     (let ((pm (point-max)))
 134       (when for-imap
 135         (while (search-forward "/" nil t)
 136           (replace-match ",")))
 137       (skip-chars-forward "^= \t\n" pm)
 138       (delete-region (point) pm))))
 139
 140 (defun utf7-decode-internal (&optional for-imap)
 141   "Decode UTF-7 text in (temporary) buffer.
 142 Use IMAP modification if FOR-IMAP is non-nil."
 143   (let ((start (point-min))
 144         (end (point-max)))
 145     (goto-char start)
 146     (let* ((esc-pattern (concat "^" (char-to-string (if for-imap ?& ?+))))
 147            (base64-chars (concat "A-Za-z0-9+"
 148                                  (char-to-string (if for-imap ?, ?/)))))
 149       (while (not (eobp))
 150         (skip-chars-forward esc-pattern)
 151         (unless (eobp)
 152           (forward-char)
 153           (let ((p (point))
 154                 (run-length (skip-chars-forward base64-chars)))
 155             (when (and (not (eobp)) (= (following-char) ?-))
 156               (delete-char 1))
 157             (unless (= run-length 0)    ; Encoded lone esc-char?
 158               (save-excursion
 159                 (utf7-fragment-decode p (point) for-imap)
 160                 (goto-char p)
 161                 (delete-char -1)))))))))
 162
 163 (defun utf7-fragment-decode (start end &optional for-imap)
 164   "Decode base64 encoded fragment from START to END of UTF-7 text in buffer.
 165 Use IMAP modification if FOR-IMAP is non-nil."
 166   (save-restriction
 167     (narrow-to-region start end)
 168     (when for-imap
 169       (goto-char start)
 170       (while (search-forward "," nil 'move-to-end) (replace-match "/")))
 171     (let ((pl (utf7-imap-get-pad-length (- end start) 4)))
 172       (insert (make-string pl ?=))
 173       (base64-decode-region start (+ end pl)))
 174     (funcall (utf7-get-u16char-converter 'from-utf-16))))
 175
 176 (defun utf7-get-u16char-converter (which-way)
 177   "Return a function to convert between UTF-16 and current character set."
 178   (if utf7-utf-16-coding-system
 179       (if (eq which-way 'to-utf-16)
 180           (lambda ()
 181             (encode-coding-region (point-min) (point-max)
 182                                   utf7-utf-16-coding-system))
 183         (lambda ()
 184           (decode-coding-region (point-min) (point-max)
 185                                 utf7-utf-16-coding-system)))
 186     ;; Add test to check if we are really Latin-1.
 187     (if (eq which-way 'to-utf-16)
 188         'utf7-latin1-u16-char-converter
 189       'utf7-u16-latin1-char-converter)))
 190
 191 (defun utf7-latin1-u16-char-converter ()
 192   "Convert latin 1 (ISO-8859.1) characters to 16 bit Unicode.
 193 Characters are converted to raw byte pairs in narrowed buffer."
 194   (encode-coding-region (point-min) (point-max) 'iso-8859-1)
 195   (goto-char (point-min))
 196   (while (not (eobp))
 197     (insert 0)
 198     (forward-char)))
 199
 200 (defun utf7-u16-latin1-char-converter ()
 201   "Convert 16 bit Unicode characters to latin 1 (ISO-8859.1).
 202 Characters are in raw byte pairs in narrowed buffer."
 203   (goto-char (point-min))
 204   (while (not (eobp))
 205     (if (= 0 (following-char))
 206         (delete-char 1)
 207         (error "Unable to convert from Unicode"))
 208     (forward-char))
 209   (decode-coding-region (point-min) (point-max) 'iso-8859-1)
 210   (mm-enable-multibyte))
 211
 212 ;;;###autoload
 213 (defun utf7-encode (string &optional for-imap)
 214   "Encode UTF-7 STRING.  Use IMAP modification if FOR-IMAP is non-nil."
 215   (if (and (coding-system-p 'utf-7) (coding-system-p 'utf-7-imap))
 216       ;; Emacs 23 with proper support for IMAP
 217       (encode-coding-string string (if for-imap 'utf-7-imap 'utf-7))
 218     (mm-with-multibyte-buffer
 219      (insert string)
 220      (utf7-encode-internal for-imap)
 221      (buffer-string))))
 222
 223 (defun utf7-decode (string &optional for-imap)
 224   "Decode UTF-7 STRING.  Use IMAP modification if FOR-IMAP is non-nil."
 225   (if (and (coding-system-p 'utf-7) (coding-system-p 'utf-7-imap))
 226       ;; Emacs 23 with proper support for IMAP
 227       (decode-coding-string string (if for-imap 'utf-7-imap 'utf-7))
 228     (mm-with-unibyte-buffer
 229      (insert string)
 230      (utf7-decode-internal for-imap)
 231      (mm-enable-multibyte)
 232      (buffer-string))))
 233
 234 (provide 'utf7)
 235
 236 ;;; utf7.el ends here