code.delx.au - gnu-emacs/blob - configure.in

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl
   6 dnl  Copyright (C) 1994, 1995, 1996, 1999, 2000, 2001, 2002, 2003,
   7 dnl    2004, 2005, 2006, 2007, 2008  Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation, either version 3 of the License, or
  14 dnl  (at your option) any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 AC_PREREQ(2.61)dnl
  25 AC_INIT(emacs, 23.0.60)
  26 AC_CONFIG_HEADER(src/config.h:src/config.in)
  27 AC_CONFIG_SRCDIR(src/lisp.h)
  28
  29 dnl Support for --program-prefix, --program-suffix and
  30 dnl --program-transform-name options
  31 AC_ARG_PROGRAM
  32
  33 lispdir='${datadir}/emacs/${version}/lisp'
  34 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  35 '${datadir}/emacs/site-lisp'
  36 lisppath='${locallisppath}:${lispdir}:${datadir}/emacs/${version}/leim'
  37 etcdir='${datadir}/emacs/${version}/etc'
  38 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  39 docdir='${datadir}/emacs/${version}/etc'
  40 gamedir='${localstatedir}/games/emacs'
  41
  42 gameuser=games
  43
  44 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
  45 dnl Create a new --with option that defaults to being disabled.
  46 dnl NAME is the base name of the option.  The shell variable with_NAME
  47 dnl   will be set to either the user's value (if the option is
  48 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
  49 dnl   option is not specified).  Note that the shell variable name is
  50 dnl   constructed as autoconf does, by replacing non-alphanumeric
  51 dnl   characters with "_".
  52 dnl HELP-STRING is the help text for the option.
  53 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
  54   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
  55     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
  56 ])dnl
  57
  58 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
  59 dnl Create a new --with option that defaults to being enabled.  NAME
  60 dnl   is the base name of the option.  The shell variable with_NAME
  61 dnl   will be set either to 'no' (for a plain --without-NAME) or to
  62 dnl   'yes' (if the option is not specified).  Note that the shell
  63 dnl   variable name is constructed as autoconf does, by replacing
  64 dnl   non-alphanumeric characters with "_".
  65 dnl HELP-STRING is the help text for the option.
  66 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
  67   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
  68    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=yes])dnl
  69 ])dnl
  70
  71 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
  72 if test "$with_pop" = yes; then
  73    AC_DEFINE(MAIL_USE_POP)
  74 fi
  75 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
  76
  77 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
  78 if test "$with_kerberos" = yes; then
  79    AC_DEFINE(KERBEROS)
  80 fi
  81 AH_TEMPLATE(KERBEROS,
  82             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
  83
  84 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
  85 if test "${with_kerberos5}" = yes; then
  86   if test "${with_kerberos}" != yes; then
  87     with_kerberos=yes
  88     AC_DEFINE(KERBEROS)
  89   fi
  90   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
  91 fi
  92
  93 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
  94 if test "$with_hesiod" = yes; then
  95   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
  96 fi
  97
  98 OPTION_DEFAULT_ON([sound],[don't compile with sound support])
  99
 100 OPTION_DEFAULT_ON([sync-input],[Process async input synchronously])
 101 if test "$with_sync_input" = yes; then
 102    AC_DEFINE(SYNC_INPUT, 1, [Process async input synchronously.])
 103 fi
 104
 105 dnl FIXME currently it is not the last.
 106 dnl This should be the last --with option, because --with-x is
 107 dnl added later on when we find the path of X, and it's best to
 108 dnl keep them together visually.
 109 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 110  [use an X toolkit (KIT one of: yes, lucid, athena, motif, gtk, no)])],
 111 [         case "${withval}" in
 112             y | ye | yes )      val=gtk ;;
 113             n | no )            val=no  ;;
 114             l | lu | luc | luci | lucid )       val=lucid ;;
 115             a | at | ath | athe | athen | athena )      val=athena ;;
 116             m | mo | mot | moti | motif )       val=motif ;;
 117             g | gt | gtk  )     val=gtk ;;
 118             * )
 119 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 120 this option's value should be `yes', `no', `lucid', `athena', `motif' or `gtk'.
 121 `yes' and `gtk' are synonyms. `athena' and `lucid' are synonyms.])
 122             ;;
 123           esac
 124           with_x_toolkit=$val
 125 ])
 126
 127 dnl _ON results in a '--without' option in the --help output, so
 128 dnl the help text should refer to "don't compile", etc.
 129 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 130 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 131 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 132 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 133 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 134 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 135
 136 OPTION_DEFAULT_ON([freetype],[don't use Freetype for local font support])
 137 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 138 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 139 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 140
 141 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 142 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 143 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 144 OPTION_DEFAULT_OFF([carbon],[use Carbon GUI on Mac OS X.  This is unsupported!])
 145
 146 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 147 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 148
 149 ## For the times when you want to build Emacs but don't have
 150 ## a suitable makeinfo, and can live without the manuals.
 151 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 152 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 153
 154 dnl Can remove these in Emacs 24.
 155 AC_ARG_WITH([gtk],,
 156   AC_MSG_ERROR([--with-gtk has been removed.  Use --with-x-toolkit to
 157 specify a toolkit.]),,)
 158
 159 AC_ARG_WITH([gcc],,
 160   AC_MSG_ERROR([--with-gcc has been removed.  Set the `CC' environment
 161   variable to specify a compiler.]),,)
 162
 163 AC_ARG_WITH([pkg-config-prog],dnl
 164 [AS_HELP_STRING([--with-pkg-config-prog=PATH],
 165                   [Path to pkg-config for finding GTK and librsvg])])
 166 if test "X${with_pkg_config_prog}" != X; then
 167    if test "${with_pkg_config_prog}" != yes; then
 168       PKG_CONFIG="${with_pkg_config_prog}"
 169    fi
 170 fi
 171
 172 AC_ARG_ENABLE(carbon-app,
 173 [AS_HELP_STRING([--enable-carbon-app@<:@=DIR@:>@],
 174                 [specify install directory for Emacs.app on Mac OS X
 175                  [DIR=/Application]])],
 176 [ carbon_appdir_x=${enableval}])
 177
 178 ## Enabled by default.
 179 AC_ARG_ENABLE(font-backend,
 180 [AS_HELP_STRING([--disable-font-backend],[don't compile font-backend support])],
 181       USE_FONT_BACKEND=$enableval,
 182       USE_FONT_BACKEND=yes)
 183
 184 AC_ARG_ENABLE(asserts,
 185 [AS_HELP_STRING([--enable-asserts], [compile code with asserts enabled])],
 186       USE_XASSERTS=$enableval,
 187       USE_XASSERTS=no)
 188
 189 AC_ARG_ENABLE(maintainer-mode,
 190 [AS_HELP_STRING([--enable-maintainer-mode],
 191                 [enable make rules and dependencies not useful (and sometimes
 192                  confusing) to the casual installer])],
 193       USE_MAINTAINER_MODE=$enableval,
 194       USE_MAINTAINER_MODE=no)
 195 if test $USE_MAINTAINER_MODE = yes; then
 196   MAINT=
 197 else
 198   MAINT=#
 199 fi
 200 AC_SUBST(MAINT)
 201
 202 AC_ARG_ENABLE(locallisppath,
 203 [AS_HELP_STRING([--enable-locallisppath=PATH],
 204                 [directories Emacs should search for lisp files specific
 205                  to this site])],
 206 if test "${enableval}" = "no"; then
 207   locallisppath=
 208 elif test "${enableval}" != "yes"; then
 209   locallisppath=${enableval}
 210 fi)
 211
 212 #### Make srcdir absolute, if it isn't already.  It's important to
 213 #### avoid running the path through pwd unnecessarily, since pwd can
 214 #### give you automounter prefixes, which can go away.  We do all this
 215 #### so Emacs can find its files when run uninstalled.
 216 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 217 unset CDPATH
 218 case "${srcdir}" in
 219   /* ) ;;
 220   . )
 221     ## We may be able to use the $PWD environment variable to make this
 222     ## absolute.  But sometimes PWD is inaccurate.
 223     ## Note: we used to use ${PWD} at the end instead of `pwd`,
 224     ## but that tested only for a well-formed and valid PWD,
 225     ## it did not object when PWD was well-formed and valid but just wrong.
 226     if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`"  ;
 227     then
 228       srcdir="$PWD"
 229     else
 230       srcdir="`(cd ${srcdir}; pwd)`"
 231     fi
 232   ;;
 233   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
 234 esac
 235
 236 #### Check if the source directory already has a configured system in it.
 237 if test `pwd` != `(cd ${srcdir} && pwd)` \
 238    && test -f "${srcdir}/src/config.h" ; then
 239   AC_MSG_WARN([[The directory tree `${srcdir}' is being used
 240    as a build directory right now; it has been configured in its own
 241    right.  To configure in another directory as well, you MUST
 242    use GNU make.  If you do not have GNU make, then you must
 243    now do `make distclean' in ${srcdir},
 244    and then run $0 again.]])
 245 fi
 246
 247 #### Given the configuration name, set machfile and opsysfile to the
 248 #### names of the m/*.h and s/*.h files we should use.
 249
 250 ### Canonicalize the configuration name.
 251
 252 AC_CANONICAL_HOST
 253 canonical=$host
 254 configuration=${host_alias-${build_alias-$host}}
 255
 256 dnl This used to use changequote, but, apart from `changequote is evil'
 257 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 258 dnl the great gob of text.  Thus it's not processed for possible expansion.
 259 dnl Just make sure the brackets remain balanced.
 260 dnl
 261 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 262 dnl indicated by comments.
 263 dnl quotation begins
 264 [
 265
 266 ### If you add support for a new configuration, add code to this
 267 ### switch statement to recognize your configuration name and select
 268 ### the appropriate operating system and machine description files.
 269
 270 ### You would hope that you could choose an m/*.h file pretty much
 271 ### based on the machine portion of the configuration name, and an s-
 272 ### file based on the operating system portion.  However, it turns out
 273 ### that each m/*.h file is pretty manufacturer-specific - for
 274 ### example hp9000s300.h is a 68000 machine;
 275 ### mips.h, pmax.h are all MIPS
 276 ### machines.  So we basically have to have a special case for each
 277 ### configuration name.
 278 ###
 279 ### As far as handling version numbers on operating systems is
 280 ### concerned, make sure things will fail in a fixable way.  If
 281 ### /etc/MACHINES doesn't say anything about version numbers, be
 282 ### prepared to handle anything reasonably.  If version numbers
 283 ### matter, be sure /etc/MACHINES says something about it.
 284 ###
 285 ### Eric Raymond says we should accept strings like "sysvr4" to mean
 286 ### "System V Release 4"; he writes, "The old convention encouraged
 287 ### confusion between `system' and `release' levels'."
 288
 289 machine='' opsys='' unported=no
 290 case "${canonical}" in
 291
 292   ## FreeBSD ports
 293   *-*-freebsd* )
 294     opsys=freebsd
 295     case "${canonical}" in
 296       alpha*-*-freebsd*)        machine=alpha ;;
 297       arm*-*-freebsd*)          machine=arm ;;
 298       ia64-*-freebsd*)          machine=ia64 ;;
 299       sparc64-*-freebsd*)       machine=sparc ;;
 300       powerpc-*-freebsd*)       machine=macppc ;;
 301       i[3456]86-*-freebsd*)     machine=intel386 ;;
 302       amd64-*-freebsd*|x86_64-*-freebsd*) machine=amdx86-64 ;;
 303     esac
 304   ;;
 305
 306   ## FreeBSD kernel + glibc based userland
 307   *-*-kfreebsd*gnu* )
 308     opsys=gnu-kfreebsd
 309     case "${canonical}" in
 310       alpha*-*-kfreebsd*)       machine=alpha ;;
 311       ia64-*-kfreebsd*)         machine=ia64 ;;
 312       sparc64-*-kfreebsd*)      machine=sparc ;;
 313       powerpc-*-kfreebsd*)      machine=macppc ;;
 314       i[3456]86-*-kfreebsd*)    machine=intel386 ;;
 315       amd64-*-kfreebsd*|x86_64-*-kfreebsd*) machine=amdx86-64 ;;
 316     esac
 317   ;;
 318
 319   ## NetBSD ports
 320   *-*-netbsd* )
 321     opsys=netbsd
 322     if test -f /usr/lib/crti.o; then]
 323 dnl The close and open brackets here are because this section is quoted --
 324 dnl see the `changequote' comment above.
 325       AC_DEFINE(HAVE_CRTIN, [], [Define to 1 if you have /usr/lib/crti.o.])
 326 [   fi
 327
 328     case "${canonical}" in
 329       alpha*-*-netbsd*) machine=alpha ;;
 330       i[3456]86-*-netbsd*) machine=intel386 ;;
 331       m68k-*-netbsd*)
 332                         # This is somewhat bogus.
 333                         machine=hp9000s300 ;;
 334       mips-*-netbsd*)   machine=pmax ;;
 335       mipsel-*-netbsd*) machine=pmax ;;
 336       mipseb-*-netbsd*) machine=pmax ;;
 337       powerpc-*-netbsd*) machine=macppc ;;
 338       sparc*-*-netbsd*) machine=sparc ;;
 339       vax-*-netbsd*)    machine=vax ;;
 340       arm-*-netbsd*)    machine=arm ;;
 341       x86_64-*-netbsd*) machine=amdx86-64 ;;
 342       hppa-*-netbsd*)   machine=hp800 ;;
 343     esac
 344   ;;
 345
 346   ## OpenBSD ports
 347   *-*-openbsd* )
 348     opsys=openbsd
 349     case "${canonical}" in
 350       alpha*-*-openbsd*)        machine=alpha ;;
 351       arm-*-openbsd*)          machine=arm ;;
 352       hppa-*-openbsd*)         machine=hp9000s300 ;;
 353       i386-*-openbsd*)         machine=intel386 ;;
 354       m68k-*-openbsd*)         machine=hp9000s300 ;;
 355       powerpc-*-openbsd*)      machine=macppc ;;
 356       sparc*-*-openbsd*)       machine=sparc ;;
 357       vax-*-openbsd*)          machine=vax ;;
 358       x86_64-*-openbsd*)       machine=amdx86-64 ;;
 359     esac
 360   ;;
 361
 362   ## LynxOS ports
 363   *-*-lynxos* )
 364     opsys=lynxos
 365     case "${canonical}" in
 366       i[3456]86-*-lynxos*) machine=intel386 ;;
 367       powerpc-*-lynxos*) machine=powerpc ;;
 368     esac
 369   ;;
 370
 371   ## BSDI ports
 372   *-*-bsdi* )
 373     opsys=bsdi
 374     case "${canonical}" in
 375       i[345]86-*-bsdi*) machine=intel386 ;;
 376       sparc-*-bsdi*)  machine=sparc ;;
 377       powerpc-*-bsdi*)  machine=macppc ;;
 378     esac
 379     case "${canonical}" in
 380       *-*-bsd386* | *-*-bsdi1* )        opsys=bsd386 ;;
 381       *-*-bsdi2.0* )            opsys=bsdos2 ;;
 382       *-*-bsdi2* )              opsys=bsdos2-1 ;;
 383       *-*-bsdi3* )              opsys=bsdos3 ;;
 384       *-*-bsdi[45]* )           opsys=bsdos4 ;;
 385     esac
 386   ;;
 387
 388   alpha*-*-linux-gnu* )
 389     machine=alpha opsys=gnu-linux
 390   ;;
 391
 392   arm*-*-linux-gnu* )
 393     machine=arm opsys=gnu-linux
 394   ;;
 395
 396   ## Apple Darwin / Mac OS X
 397   *-apple-darwin* )
 398     case "${canonical}" in
 399       i[3456]86-* )  machine=intel386 ;;
 400       powerpc-* )    machine=powermac ;;
 401       * )            unported=yes ;;
 402     esac
 403     opsys=darwin
 404     # Define CPP as follows to make autoconf work correctly.
 405     CPP="${CC-cc} -E -no-cpp-precomp"
 406     # Use fink packages if available.
 407     if test -d /sw/include && test -d /sw/lib; then
 408       GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 409       CPP="${CPP} ${GCC_TEST_OPTIONS}"
 410       NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 411     fi
 412   ;;
 413
 414   ## Cubix QBx/386
 415   i[3456]86-cubix-sysv* )
 416     machine=intel386 opsys=usg5-3
 417   ;;
 418
 419   mips-dec-ultrix[0-3].* | mips-dec-ultrix4.0* | mips-dec-bsd4.2* )
 420     machine=pmax opsys=bsd4-2
 421   ;;
 422   mips-dec-ultrix4.[12]* | mips-dec-bsd* )
 423     machine=pmax opsys=bsd4-3
 424   ;;
 425   mips-dec-ultrix* )
 426     machine=pmax opsys=ultrix4-3
 427   ;;
 428   ## HP 9000 series 200 or 300
 429   m68*-hp-bsd* )
 430     machine=hp9000s300 opsys=bsd4-3
 431   ;;
 432   ## HP/UX 7, 8, 9, and 10 are supported on these machines.
 433   m68*-hp-hpux* )
 434     case "`uname -r`" in
 435       ## Someone's system reports A.B8.05 for this.
 436       ## I wonder what other possibilities there are.
 437       *.B8.* ) machine=hp9000s300 opsys=hpux8 ;;
 438       *.08.* ) machine=hp9000s300 opsys=hpux8 ;;
 439       *.09.* ) machine=hp9000s300 opsys=hpux9 ;;
 440       *.1[0-9].* ) machine=hp9000s300 opsys=hpux9shr ;;
 441       *) machine=hp9000s300 opsys=hpux ;;
 442     esac
 443   ;;
 444
 445   ## HP 9000 series 700 and 800, running HP/UX
 446   hppa*-hp-hpux7* )
 447     machine=hp800 opsys=hpux
 448   ;;
 449   hppa*-hp-hpux8* )
 450     machine=hp800 opsys=hpux8
 451   ;;
 452   hppa*-hp-hpux9shr* )
 453     machine=hp800 opsys=hpux9shr
 454   ;;
 455   hppa*-hp-hpux9* )
 456     machine=hp800 opsys=hpux9
 457   ;;
 458   hppa*-hp-hpux10.2* )
 459     machine=hp800 opsys=hpux10-20
 460   ;;
 461   hppa*-hp-hpux10* )
 462     machine=hp800 opsys=hpux10
 463   ;;
 464   hppa*-hp-hpux1[1-9]* )
 465     machine=hp800 opsys=hpux11
 466     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 467   ;;
 468
 469   hppa*-*-linux-gnu* )
 470     machine=hp800 opsys=gnu-linux
 471   ;;
 472
 473   ## HP 9000 series 700 and 800, running HP/UX
 474   hppa*-hp-hpux* )
 475     ## Cross-compilation?  Nah!
 476     case "`uname -r`" in
 477       ## Someone's system reports A.B8.05 for this.
 478       ## I wonder what other possibilities there are.
 479       *.B8.* ) machine=hp800 opsys=hpux8 ;;
 480       *.08.* ) machine=hp800 opsys=hpux8 ;;
 481       *.09.* ) machine=hp800 opsys=hpux9 ;;
 482       *) machine=hp800 opsys=hpux10 ;;
 483     esac
 484   ;;
 485   hppa*-*-nextstep* )
 486     machine=hp800 opsys=nextstep
 487   ;;
 488
 489   ## IBM machines
 490   i370-ibm-aix*)
 491     machine=ibm370aix opsys=usg5-3
 492   ;;
 493   s390-*-linux-gnu* )
 494     machine=ibms390 opsys=gnu-linux
 495   ;;
 496   s390x-*-linux-gnu* )
 497     machine=ibms390x opsys=gnu-linux
 498   ;;
 499   rs6000-ibm-aix3.1* | powerpc-ibm-aix3.1*  )
 500     machine=ibmrs6000 opsys=aix3-1
 501   ;;
 502   rs6000-ibm-aix3.2.5 | powerpc-ibm-aix3.2.5 )
 503     machine=ibmrs6000 opsys=aix3-2-5
 504   ;;
 505   rs6000-ibm-aix4.1* | powerpc-ibm-aix4.1*  )
 506     machine=ibmrs6000 opsys=aix4-1
 507   ;;
 508   rs6000-ibm-aix4.2* | powerpc-ibm-aix4.2*  )
 509     machine=ibmrs6000 opsys=aix4-2
 510   ;;
 511   rs6000-ibm-aix4.3* | powerpc-ibm-aix4.3*  )
 512     machine=ibmrs6000 opsys=aix4-2
 513   ;;
 514   rs6000-ibm-aix5* | powerpc-ibm-aix5*  )
 515     machine=ibmrs6000 opsys=aix4-2
 516   ;;
 517   rs6000-ibm-aix5* | powerpc-ibm-aix6*  )
 518     machine=ibmrs6000 opsys=aix4-2
 519   ;;
 520   rs6000-ibm-aix4.0* | powerpc-ibm-aix4.0*  )
 521     machine=ibmrs6000 opsys=aix4
 522   ;;
 523   rs6000-ibm-aix4* | powerpc-ibm-aix4*  )
 524     machine=ibmrs6000 opsys=aix4-1
 525   ;;
 526   rs6000-ibm-aix* | powerpc-ibm-aix* )
 527     machine=ibmrs6000 opsys=aix3-2
 528   ;;
 529
 530   ## Prime EXL
 531   i[3456]86-prime-sysv* )
 532     machine=i386 opsys=usg5-3
 533   ;;
 534
 535   ## ncr machine running svr4.3.
 536   i[3456]86-ncr-sysv4.3 )
 537     machine=ncr386 opsys=usg5-4-3
 538   ;;
 539
 540   ## Unspecified sysv on an ncr machine defaults to svr4.2.
 541   ## (Plain usg5-4 doesn't turn on POSIX signals, which we need.)
 542   i[3456]86-ncr-sysv* )
 543     machine=ncr386 opsys=usg5-4-2
 544   ;;
 545
 546   ## Macintosh PowerPC
 547   powerpc*-*-linux-gnu* )
 548     machine=macppc opsys=gnu-linux
 549   ;;
 550
 551   ## Workstations sold by MIPS
 552   ## This is not necessarily all workstations using the MIPS processor -
 553   ## Irises are produced by SGI, and DECstations by DEC.
 554
 555   mips-mips-bsd* )
 556     machine=mips opsys=bsd4-3
 557   ;;
 558   mips-mips-* )
 559     machine=mips opsys=usg5-2-2
 560   ;;
 561
 562   ## NeXT
 563   m68*-next-* | m68k-*-nextstep* )
 564     machine=m68k opsys=nextstep
 565   ;;
 566
 567   ## NEC EWS4800
 568   mips-nec-sysv4*)
 569   machine=ews4800 opsys=ux4800
 570   ;;
 571
 572   ## Siemens Nixdorf
 573   mips-siemens-sysv* | mips-sni-sysv*)
 574     machine=mips-siemens opsys=usg5-4
 575     NON_GNU_CC=/usr/ccs/bin/cc
 576     NON_GNU_CPP=/usr/ccs/lib/cpp
 577   ;;
 578
 579   ## Silicon Graphics machines
 580   ## Iris 4D
 581   mips-sgi-irix6.5 )
 582     machine=iris4d opsys=irix6-5
 583     # Without defining _LANGUAGE_C, things get masked out in the headers
 584     # so that, for instance, grepping for `free' in stdlib.h fails and
 585     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 586     NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
 587     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 588   ;;
 589
 590   ## Suns
 591   sparc-*-linux-gnu* | sparc64-*-linux-gnu* )
 592     machine=sparc opsys=gnu-linux
 593   ;;
 594
 595   *-auspex-sunos* | *-sun-sunos* | *-sun-bsd* | *-sun-solaris* \
 596     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* | powerpc*-*-solaris2* \
 597     | rs6000-*-solaris2*)
 598     case "${canonical}" in
 599       i[3456]86-*-* )     machine=intel386 ;;
 600       amd64-*-*|x86_64-*-*)     machine=amdx86-64 ;;
 601       powerpcle* )      machine=powerpcle ;;
 602       powerpc* | rs6000* )  machine=ibmrs6000 ;;
 603       sparc* )          machine=sparc ;;
 604       * )               unported=yes ;;
 605     esac
 606     case "${canonical}" in
 607       *-sunos5.3* | *-solaris2.3* )
 608                 opsys=sol2-3
 609                 NON_GNU_CPP=/usr/ccs/lib/cpp
 610                 ;;
 611       *-sunos5.4* | *-solaris2.4* )
 612                 opsys=sol2-4
 613                 NON_GNU_CPP=/usr/ccs/lib/cpp
 614                 RANLIB="ar -ts"
 615                 ;;
 616       *-sunos5.5* | *-solaris2.5* )
 617                 opsys=sol2-5
 618                 NON_GNU_CPP=/usr/ccs/lib/cpp
 619                 RANLIB="ar -ts"
 620                 ;;
 621       *-sunos5.6* | *-solaris2.6* )
 622                 opsys=sol2-6
 623                 NON_GNU_CPP=/usr/ccs/lib/cpp
 624                 RANLIB="ar -ts"
 625                 ;;
 626       *-sunos5* | *-solaris* )
 627                 opsys=sol2-6
 628                 emacs_check_sunpro_c=yes
 629                 NON_GNU_CPP=/usr/ccs/lib/cpp
 630                 ;;
 631       *                   ) opsys=bsd4-2   ;;
 632     esac
 633     ## Watch out for a compiler that we know will not work.
 634     case "${canonical}" in
 635      *-solaris* | *-sunos5* )
 636                 if [ "x$CC" = x/usr/ucb/cc ]; then
 637                   ## /usr/ucb/cc doesn't work;
 638                   ## we should find some other compiler that does work.
 639                   unset CC
 640                 fi
 641                 ;;
 642       *) ;;
 643     esac
 644   ;;
 645   sparc-*-nextstep* )
 646     machine=sparc opsys=nextstep
 647   ;;
 648
 649   ## Tandem Integrity S2
 650   mips-tandem-sysv* )
 651     machine=tandem-s2 opsys=usg5-3
 652   ;;
 653
 654   ## Vaxen.
 655   vax-dec-* )
 656     machine=vax
 657     case "${canonical}" in
 658       *-bsd4.1* )                                       opsys=bsd4-1 ;;
 659       *-bsd4.2* | *-ultrix[0-3].* | *-ultrix4.0* )      opsys=bsd4-2 ;;
 660       *-bsd4.3* | *-ultrix* )                           opsys=bsd4-3 ;;
 661       *-sysv[01]* | *-sysvr[01]* )                      opsys=usg5-0 ;;
 662       *-sysv2* | *-sysvr2* )                            opsys=usg5-2 ;;
 663       *-vms* )                                          opsys=vms ;;
 664       * )                                               unported=yes
 665     esac
 666   ;;
 667
 668   ## IA-64
 669   ia64*-*-linux* )
 670     machine=ia64 opsys=gnu-linux
 671   ;;
 672
 673   ## Intel 386 machines where we don't care about the manufacturer
 674   i[3456]86-*-* )
 675     machine=intel386
 676     case "${canonical}" in
 677       *-cygwin )                opsys=cygwin ;;
 678       *-darwin* )               opsys=darwin
 679                                 CPP="${CC-cc} -E -no-cpp-precomp"
 680                                 ;;
 681       *-linux-gnu* )            opsys=gnu-linux ;;
 682       *-sysv4.2uw* )            opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 683       *-sysv5uw* )              opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 684       *-sysv5OpenUNIX* )        opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 685       *-386bsd* )               opsys=386bsd ;;
 686       *-nextstep* )             opsys=nextstep ;;
 687       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 688     esac
 689   ;;
 690
 691   ## m68k Linux-based GNU system
 692   m68k-*-linux-gnu* )
 693     machine=m68k opsys=gnu-linux
 694   ;;
 695
 696   ## Mips Linux-based GNU system
 697   mips-*-linux-gnu* | mipsel-*-linux-gnu* )
 698     machine=mips opsys=gnu-linux
 699   ;;
 700
 701   ## UXP/DS
 702   sparc-fujitsu-sysv4* )
 703     machine=sparc opsys=uxpds
 704     NON_GNU_CPP=/usr/ccs/lib/cpp
 705     RANLIB="ar -ts"
 706   ;;
 707
 708   ## AMD x86-64 Linux-based GNU system
 709   x86_64-*-linux-gnu* )
 710     machine=amdx86-64 opsys=gnu-linux
 711   ;;
 712
 713   ## Tensilica Xtensa Linux-based GNU system
 714   xtensa*-*-linux-gnu* )
 715     machine=xtensa opsys=gnu-linux
 716     ;;
 717
 718   * )
 719     unported=yes
 720   ;;
 721 esac
 722
 723 ### If the code above didn't choose an operating system, just choose
 724 ### an operating system based on the configuration name.  You really
 725 ### only want to use this when you have no idea what the right
 726 ### operating system is; if you know what operating systems a machine
 727 ### runs, it's cleaner to make it explicit in the case statement
 728 ### above.
 729 if test x"${opsys}" = x; then
 730   case "${canonical}" in
 731     *-gnu* )                            opsys=gnu ;;
 732     *-bsd4.[01] )                       opsys=bsd4-1 ;;
 733     *-bsd4.2 )                          opsys=bsd4-2 ;;
 734     *-bsd4.3 )                          opsys=bsd4-3 ;;
 735     *-sysv0 | *-sysvr0 )                opsys=usg5-0 ;;
 736     *-sysv2 | *-sysvr2 )                opsys=usg5-2 ;;
 737     *-sysv2.2 | *-sysvr2.2 )            opsys=usg5-2-2 ;;
 738     *-sysv3* | *-sysvr3* )              opsys=usg5-3 ;;
 739     *-sysv4.2uw* )                      opsys=unixware ;;
 740     *-sysv5uw* )                        opsys=unixware ;;
 741     *-sysv5OpenUNIX* )                  opsys=unixware ;;
 742     *-sysv4.1* | *-sysvr4.1* )
 743         NON_GNU_CPP=/usr/lib/cpp
 744         opsys=usg5-4 ;;
 745     *-sysv4.[2-9]* | *-sysvr4.[2-9]* )
 746         if [ x$NON_GNU_CPP = x ]; then
 747           if [ -f /usr/ccs/lib/cpp ]; then
 748             NON_GNU_CPP=/usr/ccs/lib/cpp
 749           else
 750             NON_GNU_CPP=/lib/cpp
 751           fi
 752         fi
 753         opsys=usg5-4-2 ;;
 754     *-sysv4* | *-sysvr4* )              opsys=usg5-4 ;;
 755     * )
 756       unported=yes
 757     ;;
 758   esac
 759 fi
 760
 761 ### Tests for sytems that we beleive are obsolete and should be desupported.
 762
 763 case "${machine}" in
 764      pmax | hp9000s300 | ibm370aix | ncr386 | ews4800 | mips-siemens | powerpcle | tandem-s2 )
 765           echo "The system that you are configuring on: ${canonical} is considered to be obsolete"
 766           echo "and it is planned to be desupported in the next version of Emacs"
 767           echo "Please email emacs-devel@gnu.org as soon as possible if this system is still in use."
 768           echo "The code is still functional, but you need to edit the 'configure' script and remove the"
 769           echo "exit 33 line.  After that you can run configure again and 'complete' the build."
 770           exit 33
 771           ;;
 772 esac
 773
 774 case "${opsys}" in
 775      bsd386 | bsdos2-1 |  bsdos2 | bsdos3 | bsdos4 | bsd4-1 | bsd4-2 | bsd4-3 | usg5-0 | usg5-2-2 | usg5-2 | usg5-3 | ultrix4-3 | 386bsd | hpux | hpux8 | hpux9 | hpux9shr | hpux10 | aix3-1 | aix3-2-5 | aix3-2 | aix4-1 | nextstep | ux4800 | uxpds | uxpv )
 776           echo "The system that you are configuring on: ${canonical} is considered to be obsolete"
 777           echo "and it is planned to be desupported in the next version of Emacs"
 778           echo "Please email emacs-devel@gnu.org as soon as possible if this system is still in use."
 779           echo "The code is still functional, but you need to edit the 'configure' script and remove the"
 780           echo "'exit 44' line.  After that you can run 'configure' again and complete the build."
 781           exit 44
 782           ;;
 783 esac
 784
 785 ]
 786 dnl quotation ends
 787
 788 if test $unported = yes; then
 789   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
 790 Check `etc/MACHINES' for recognized configuration names.])
 791 fi
 792
 793 machfile="m/${machine}.h"
 794 opsysfile="s/${opsys}.h"
 795
 796
 797 #### Choose a compiler.
 798 test -n "$CC" && cc_specified=yes
 799
 800 # Save the value of CFLAGS that the user specified.
 801 SPECIFIED_CFLAGS="$CFLAGS"
 802
 803 dnl Sets GCC=yes if using gcc.
 804 AC_PROG_CC
 805
 806 # On Suns, sometimes $CPP names a directory.
 807 if test -n "$CPP" && test -d "$CPP"; then
 808   CPP=
 809 fi
 810
 811 ## If not using gcc, and on Solaris, and no CPP specified, see if
 812 ## using a Sun compiler, which needs -Xs to prevent whitespace.
 813 if test x"$GCC" != xyes && test x"$emacs_check_sunpro_c" = xyes && \
 814  test x"$CPP" = x; then
 815   AC_MSG_CHECKING([whether we are using a Sun C compiler])
 816   AC_CACHE_VAL(emacs_cv_sunpro_c,
 817   [AC_TRY_LINK([],
 818 [#ifndef __SUNPRO_C
 819 fail;
 820 #endif
 821 ], emacs_cv_sunpro_c=yes, emacs_cv_sunpro_c=no)])
 822   AC_MSG_RESULT($emacs_cv_sunpro_c)
 823
 824   if test x"$emacs_cv_sunpro_c" = xyes; then
 825     NON_GNU_CPP="$CC -E -Xs"
 826   fi
 827 fi
 828
 829 #### Some systems specify a CPP to use unless we are using GCC.
 830 #### Now that we know whether we are using GCC, we can decide whether
 831 #### to use that one.
 832 if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x
 833 then
 834   CPP="$NON_GNU_CPP"
 835 fi
 836
 837 #### Some systems specify a CC to use unless we are using GCC.
 838 #### Now that we know whether we are using GCC, we can decide whether
 839 #### to use that one.
 840 if test "x$NON_GNU_CC" != x && test x$GCC != xyes &&
 841   test x$cc_specified != xyes
 842 then
 843   CC="$NON_GNU_CC"
 844 fi
 845
 846 if test x$GCC = xyes && test "x$GCC_TEST_OPTIONS" != x
 847 then
 848   CC="$CC $GCC_TEST_OPTIONS"
 849 fi
 850
 851 if test x$GCC = x && test "x$NON_GCC_TEST_OPTIONS" != x
 852 then
 853   CC="$CC $NON_GCC_TEST_OPTIONS"
 854 fi
 855
 856 dnl checks for Unix variants
 857 AC_USE_SYSTEM_EXTENSIONS
 858
 859 ### Use -Wno-pointer-sign if the compiler supports it
 860 AC_MSG_CHECKING([whether gcc understands -Wno-pointer-sign])
 861 SAVE_CFLAGS="$CFLAGS"
 862 CFLAGS="$CFLAGS -Wno-pointer-sign"
 863 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 864 if test $has_option = yes; then
 865    C_WARNINGS_SWITCH="-Wno-pointer-sign $C_WARNINGS_SWITCH"
 866 fi
 867 AC_MSG_RESULT($has_option)
 868 CFLAGS="$SAVE_CFLAGS"
 869 unset has_option
 870 unset SAVE_CFLAGS
 871
 872 #### Some other nice autoconf tests.
 873
 874 dnl checks for programs
 875 AC_PROG_LN_S
 876 AC_PROG_CPP
 877 AC_PROG_INSTALL
 878 if test "x$RANLIB" = x; then
 879   AC_PROG_RANLIB
 880 fi
 881 AC_PATH_PROG(INSTALL_INFO, install-info)
 882 AC_PATH_PROG(INSTALL_INFO, install-info,, /usr/sbin)
 883 AC_PATH_PROG(INSTALL_INFO, install-info,:, /sbin)
 884 dnl Don't use GZIP, which is used by gzip for additional parameters.
 885 AC_PATH_PROG(GZIP_PROG, gzip)
 886
 887
 888 ## Need makeinfo >= 4.6 (?) to build the manuals.
 889 AC_PATH_PROG(MAKEINFO, makeinfo, no)
 890 dnl By this stage, configure has already checked for egrep and set EGREP,
 891 dnl or exited with an error if no egrep was found.
 892 if test "$MAKEINFO" != "no" && \
 893   test x"`$MAKEINFO --version 2> /dev/null | $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[6-9]]|4\.[[1-5]][[0-9]]+)'`" = x; then
 894    MAKEINFO=no
 895 fi
 896
 897 ## Makeinfo is unusual.  For a released Emacs, the manuals are
 898 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
 899 ## therefore in the category of "special tools" not normally required, which
 900 ## configure does not have to check for (eg autoconf itself).
 901 ## In a CVS checkout on the other hand, the manuals are not included.
 902 ## So makeinfo is a requirement to build from CVS, and configure
 903 ## should test for it as it does for any other build requirement.
 904 ## We use the presence of $srcdir/info/emacs to distinguish a release,
 905 ## with pre-built manuals, from a CVS checkout.
 906 if test "$MAKEINFO" = "no"; then
 907   if test "x${with_makeinfo}" = "xno"; then
 908     MAKEINFO=off
 909   elif ! test -e $srcdir/info/emacs; then
 910     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.6, and your
 911 source tree does not seem to have pre-built manuals in the `info' directory.
 912 Either install a suitable version of makeinfo, or re-run configure
 913 with the `--without-makeinfo' option to build without the manuals.] )
 914   fi
 915 fi
 916
 917 dnl Add our options to ac_link now, after it is set up.
 918
 919 if test x$GCC = xyes && test "x$GCC_LINK_TEST_OPTIONS" != x
 920 then
 921   ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
 922 fi
 923
 924 if test x$GCC = x && test "x$NON_GCC_LINK_TEST_OPTIONS" != x
 925 then
 926   ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
 927 fi
 928
 929 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
 930 dnl If we can link with the flag, it shouldn't do any harm anyhow.
 931 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
 932 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
 933 dnl if not built to support GNU ld.
 934
 935 late_LDFLAGS=$LDFLAGS
 936 if test "$GCC" = yes; then
 937   LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
 938 else
 939   LDFLAGS="$LDFLAGS -znocombreloc"
 940 fi
 941
 942 AC_MSG_CHECKING([for -znocombreloc])
 943 AC_LINK_IFELSE([main(){return 0;}],
 944   [AC_MSG_RESULT(yes)],
 945   LDFLAGS=$late_LDFLAGS
 946   [AC_MSG_RESULT(no)])
 947
 948 #### Extract some information from the operating system and machine files.
 949
 950 AC_CHECKING([the machine- and system-dependent files to find out
 951  - which libraries the lib-src programs will want, and
 952  - whether the GNU malloc routines are usable])
 953
 954 ### First figure out CFLAGS (which we use for running the compiler here)
 955 ### and REAL_CFLAGS (which we use for real compilation).
 956 ### The two are the same except on a few systems, where they are made
 957 ### different to work around various lossages.  For example,
 958 ### GCC 2.5 on GNU/Linux needs them to be different because it treats -g
 959 ### as implying static linking.
 960
 961 ### If the CFLAGS env var is specified, we use that value
 962 ### instead of the default.
 963
 964 ### It's not important that this name contain the PID; you can't run
 965 ### two configures in the same directory and have anything work
 966 ### anyway.
 967 tempcname="conftest.c"
 968
 969 echo '
 970 #include "'${srcdir}'/src/'${opsysfile}'"
 971 #include "'${srcdir}'/src/'${machfile}'"
 972 #ifndef LIBS_MACHINE
 973 #define LIBS_MACHINE
 974 #endif
 975 #ifndef LIBS_SYSTEM
 976 #define LIBS_SYSTEM
 977 #endif
 978 #ifndef C_SWITCH_SYSTEM
 979 #define C_SWITCH_SYSTEM
 980 #endif
 981 #ifndef C_SWITCH_MACHINE
 982 #define C_SWITCH_MACHINE
 983 #endif
 984 configure___ libsrc_libs=LIBS_MACHINE LIBS_SYSTEM
 985 configure___ c_switch_system=C_SWITCH_SYSTEM
 986 configure___ c_switch_machine=C_SWITCH_MACHINE
 987
 988 #ifndef LIB_X11_LIB
 989 #define LIB_X11_LIB -lX11
 990 #endif
 991
 992 #ifndef LIBX11_SYSTEM
 993 #define LIBX11_SYSTEM
 994 #endif
 995 configure___ LIBX=LIB_X11_LIB LIBX11_SYSTEM
 996
 997 #ifdef UNEXEC
 998 configure___ unexec=UNEXEC
 999 #else
1000 configure___ unexec=unexec.o
1001 #endif
1002
1003 #ifdef SYSTEM_MALLOC
1004 configure___ system_malloc=yes
1005 #else
1006 configure___ system_malloc=no
1007 #endif
1008
1009 #ifdef USE_MMAP_FOR_BUFFERS
1010 configure___ use_mmap_for_buffers=yes
1011 #else
1012 configure___ use_mmap_for_buffers=no
1013 #endif
1014
1015 #ifndef C_DEBUG_SWITCH
1016 #define C_DEBUG_SWITCH -g
1017 #endif
1018
1019 #ifndef C_OPTIMIZE_SWITCH
1020 #ifdef __GNUC__
1021 #define C_OPTIMIZE_SWITCH -O2
1022 #else
1023 #define C_OPTIMIZE_SWITCH -O
1024 #endif
1025 #endif
1026
1027 #ifndef C_WARNINGS_SWITCH
1028 #define C_WARNINGS_SWITCH ${C_WARNINGS_SWITCH}
1029 #endif
1030
1031 #ifndef LD_SWITCH_MACHINE
1032 #define LD_SWITCH_MACHINE
1033 #endif
1034
1035 #ifndef LD_SWITCH_SYSTEM
1036 #define LD_SWITCH_SYSTEM
1037 #endif
1038
1039 #ifndef LD_SWITCH_X_SITE_AUX
1040 #define LD_SWITCH_X_SITE_AUX
1041 #endif
1042
1043 configure___ ld_switch_system=LD_SWITCH_SYSTEM
1044 configure___ ld_switch_machine=LD_SWITCH_MACHINE
1045
1046 #ifdef THIS_IS_CONFIGURE
1047
1048 /* Get the CFLAGS for tests in configure.  */
1049 #ifdef __GNUC__
1050 configure___ CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH '${SPECIFIED_CFLAGS}'
1051 #else
1052 configure___ CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
1053 #endif
1054
1055 #else /* not THIS_IS_CONFIGURE */
1056
1057 /* Get the CFLAGS for real compilation.  */
1058 #ifdef __GNUC__
1059 configure___ REAL_CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH C_WARNINGS_SWITCH '${SPECIFIED_CFLAGS}'
1060 #else
1061 configure___ REAL_CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
1062 #endif
1063
1064 #endif /* not THIS_IS_CONFIGURE */
1065 ' > ${tempcname}
1066
1067 # The value of CPP is a quoted variable reference, so we need to do this
1068 # to get its actual value...
1069 CPP=`eval "echo $CPP"`
1070 [eval `${CPP} -Isrc ${tempcname} \
1071        | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
1072 if test "x$SPECIFIED_CFLAGS" = x; then
1073   eval `${CPP} -Isrc -DTHIS_IS_CONFIGURE ${tempcname} \
1074          | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
1075 else
1076   REAL_CFLAGS="$CFLAGS"
1077 fi]
1078 rm ${tempcname}
1079
1080 ac_link="$ac_link $ld_switch_machine $ld_switch_system"
1081
1082 ### Make sure subsequent tests use flags consistent with the build flags.
1083
1084 if test x"${OVERRIDE_CPPFLAGS}" != x; then
1085   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
1086 else
1087   CPPFLAGS="$c_switch_system $c_switch_machine $CPPFLAGS"
1088 fi
1089
1090 dnl For AC_FUNC_GETLOADAVG, at least:
1091 AC_CONFIG_LIBOBJ_DIR(src)
1092
1093 dnl Do this early because it can frob feature test macros for Unix-98 &c.
1094 AC_SYS_LARGEFILE
1095
1096
1097 ### The standard library on x86-64 and s390x GNU/Linux distributions can
1098 ### be located in either /usr/lib64 or /usr/lib.
1099 case "${canonical}" in
1100   x86_64-*-linux-gnu* | s390x-*-linux-gnu* )
1101     if test -d /usr/lib64; then
1102       AC_DEFINE(HAVE_LIB64_DIR, 1,
1103         [Define to 1 if the directory /usr/lib64 exists.])
1104 fi
1105 esac
1106
1107 dnl This function defintion taken from Gnome 2.0
1108 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1109 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1110 dnl also defines GSTUFF_PKG_ERRORS on error
1111 AC_DEFUN([PKG_CHECK_MODULES], [
1112   succeeded=no
1113
1114   AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1115
1116   if test "$PKG_CONFIG" = "no" ; then
1117      ifelse([$4], , [AC_MSG_ERROR([
1118       *** The pkg-config script could not be found. Make sure it is in your path, or give the full path to pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
1119   else
1120      PKG_CONFIG_MIN_VERSION=0.9.0
1121      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1122         AC_MSG_CHECKING(for $2)
1123
1124         if $PKG_CONFIG --exists "$2" 2>&AS_MESSAGE_LOG_FD; then
1125             AC_MSG_RESULT(yes)
1126             succeeded=yes
1127
1128             AC_MSG_CHECKING($1_CFLAGS)
1129             $1_CFLAGS=`$PKG_CONFIG --cflags "$2"|sed -e 's,///*,/,g'`
1130             AC_MSG_RESULT($$1_CFLAGS)
1131
1132             AC_MSG_CHECKING($1_LIBS)
1133             $1_LIBS=`$PKG_CONFIG --libs "$2"|sed -e 's,///*,/,g'`
1134             AC_MSG_RESULT($$1_LIBS)
1135         else
1136             AC_MSG_RESULT(no)
1137             $1_CFLAGS=""
1138             $1_LIBS=""
1139             ## If we have a custom action on failure, don't print errors, but
1140             ## do set a variable so people can do so.
1141             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
1142             ifelse([$4], ,echo $$1_PKG_ERRORS,)
1143         fi
1144
1145         AC_SUBST($1_CFLAGS)
1146         AC_SUBST($1_LIBS)
1147      else
1148         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1149         echo "*** See http://www.freedesktop.org/software/pkgconfig"
1150      fi
1151   fi
1152
1153   if test $succeeded = yes; then
1154      ifelse([$3], , :, [$3])
1155   else
1156      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
1157   fi
1158 ])
1159
1160
1161 if test "${with_sound}" != "no"; then
1162   # Sound support for GNU/Linux and the free BSDs.
1163   AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h)
1164   # Emulation library used on NetBSD.
1165   AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1166   AC_SUBST(LIBSOUND)
1167
1168   ALSA_REQUIRED=1.0.0
1169   ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1170   PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
1171   if test $HAVE_ALSA = yes; then
1172     SAVE_CFLAGS="$CFLAGS"
1173     SAVE_LDFLAGS="$LDFLAGS"
1174     CFLAGS="$ALSA_CFLAGS $CFLAGS"
1175     LDFLAGS="$ALSA_LIBS $LDFLAGS"
1176     AC_TRY_COMPILE([#include <asoundlib.h>], [snd_lib_error_set_handler (0);],
1177                     emacs_alsa_normal=yes,
1178                     emacs_alsa_normal=no)
1179     if test "$emacs_alsa_normal" != yes; then
1180       AC_TRY_COMPILE([#include <alsa/asoundlib.h>],
1181                      [snd_lib_error_set_handler (0);],
1182                      emacs_alsa_subdir=yes,
1183                      emacs_alsa_subdir=no)
1184       if test "$emacs_alsa_subdir" != yes; then
1185         AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1186       fi
1187       ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1188     fi
1189
1190     CFLAGS="$SAVE_CFLAGS"
1191     LDFLAGS="$SAVE_LDFLAGS"
1192     LIBSOUND="$LIBSOUND $ALSA_LIBS"
1193     CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1194     AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1195   fi
1196   AC_SUBST(CFLAGS_SOUND)
1197 fi
1198
1199 dnl checks for header files
1200 AC_CHECK_HEADERS(sys/select.h sys/timeb.h sys/time.h unistd.h utime.h \
1201   linux/version.h sys/systeminfo.h termios.h limits.h string.h stdlib.h \
1202   termcap.h stdio_ext.h fcntl.h strings.h coff.h pty.h sys/mman.h \
1203   sys/param.h sys/vlimit.h sys/resource.h locale.h sys/_mbstate_t.h \
1204   sys/utsname.h pwd.h)
1205
1206 AC_MSG_CHECKING(if personality LINUX32 can be set)
1207 AC_TRY_COMPILE([#include <sys/personality.h>], [personality (PER_LINUX32)],
1208                emacs_cv_personality_linux32=yes,
1209                emacs_cv_personality_linux32=no)
1210 AC_MSG_RESULT($emacs_cv_personality_linux32)
1211
1212 if test $emacs_cv_personality_linux32 = yes; then
1213   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1214             [Define to 1 if personality LINUX32 can be set.])
1215 fi
1216
1217 dnl On Solaris 8 there's a compilation warning for term.h because
1218 dnl it doesn't define `bool'.
1219 AC_CHECK_HEADERS(term.h, , , -)
1220 AC_HEADER_STDC
1221 AC_HEADER_TIME
1222 AC_CHECK_DECLS([sys_siglist])
1223 if test $ac_cv_have_decl_sys_siglist != yes; then
1224   # For Tru64, at least:
1225   AC_CHECK_DECLS([__sys_siglist])
1226   if test $ac_cv_have_decl___sys_siglist = yes; then
1227     AC_DEFINE(sys_siglist, __sys_siglist,
1228               [Define to any substitute for sys_siglist.])
1229   fi
1230 fi
1231 AC_HEADER_SYS_WAIT
1232
1233 dnl Some systems have utime.h but don't declare the struct anyplace.
1234 AC_CACHE_CHECK(for struct utimbuf, emacs_cv_struct_utimbuf,
1235 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1236 #include <sys/time.h>
1237 #include <time.h>
1238 #else
1239 #ifdef HAVE_SYS_TIME_H
1240 #include <sys/time.h>
1241 #else
1242 #include <time.h>
1243 #endif
1244 #endif
1245 #ifdef HAVE_UTIME_H
1246 #include <utime.h>
1247 #endif], [static struct utimbuf x; x.actime = x.modtime;],
1248   emacs_cv_struct_utimbuf=yes, emacs_cv_struct_utimbuf=no))
1249 if test $emacs_cv_struct_utimbuf = yes; then
1250   AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if `struct utimbuf' is declared by <utime.h>.])
1251 fi
1252
1253 dnl checks for typedefs
1254 AC_TYPE_SIGNAL
1255
1256 dnl Check for speed_t typedef.
1257 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1258   [AC_TRY_COMPILE([#include <termios.h>], [speed_t x = 1;],
1259     emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1260 if test $emacs_cv_speed_t = yes; then
1261   AC_DEFINE(HAVE_SPEED_T, 1,
1262            [Define to 1 if `speed_t' is declared by <termios.h>.])
1263 fi
1264
1265 AC_CACHE_CHECK(for struct timeval, emacs_cv_struct_timeval,
1266 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1267 #include <sys/time.h>
1268 #include <time.h>
1269 #else
1270 #ifdef HAVE_SYS_TIME_H
1271 #include <sys/time.h>
1272 #else
1273 #include <time.h>
1274 #endif
1275 #endif], [static struct timeval x; x.tv_sec = x.tv_usec;],
1276   emacs_cv_struct_timeval=yes, emacs_cv_struct_timeval=no))
1277 HAVE_TIMEVAL=$emacs_cv_struct_timeval
1278 if test $emacs_cv_struct_timeval = yes; then
1279   AC_DEFINE(HAVE_TIMEVAL, 1, [Define to 1 if `struct timeval' is declared by <sys/time.h>.])
1280 fi
1281
1282 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1283 AC_TRY_COMPILE([#include <math.h>],
1284 [static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;],
1285   emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1286 HAVE_EXCEPTION=$emacs_cv_struct_exception
1287 if test $emacs_cv_struct_exception != yes; then
1288   AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1289 fi
1290
1291 AC_CHECK_HEADERS(sys/socket.h)
1292 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1293 #if HAVE_SYS_SOCKET_H
1294 #include <sys/socket.h>
1295 #endif])
1296
1297 dnl checks for structure members
1298 AC_STRUCT_TM
1299 AC_STRUCT_TIMEZONE
1300 AC_CHECK_MEMBER(struct tm.tm_gmtoff,
1301                 [AC_DEFINE(HAVE_TM_GMTOFF, 1,
1302                            [Define to 1 if `tm_gmtoff' is member of `struct tm'.])],,
1303                 [#include <time.h>])
1304 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1305                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1306                   struct ifreq.ifr_addr], , ,
1307                  [AC_INCLUDES_DEFAULT
1308 #if HAVE_SYS_SOCKET_H
1309 #include <sys/socket.h>
1310 #endif
1311 #if HAVE_NET_IF_H
1312 #include <net/if.h>
1313 #endif])
1314
1315 dnl checks for compiler characteristics
1316
1317 dnl Testing __STDC__ to determine prototype support isn't good enough.
1318 dnl DEC C, for instance, doesn't define it with default options, and
1319 dnl is used on 64-bit systems (OSF Alphas).  Similarly for volatile
1320 dnl and void *.
1321 AC_C_PROTOTYPES
1322 AC_C_VOLATILE
1323 AC_C_CONST
1324 dnl This isn't useful because we can't turn on use of `inline' unless
1325 dnl the compiler groks `extern inline'.
1326 dnl AC_C_INLINE
1327 AC_CACHE_CHECK([for void * support], emacs_cv_void_star,
1328   [AC_TRY_COMPILE(, [void * foo;],
1329                    emacs_cv_void_star=yes, emacs_cv_void_star=no)])
1330 if test $emacs_cv_void_star = yes; then
1331   AC_DEFINE(POINTER_TYPE, void)
1332 else
1333   AC_DEFINE(POINTER_TYPE, char)
1334 fi
1335 AH_TEMPLATE(POINTER_TYPE,
1336             [Define as `void' if your compiler accepts `void *'; otherwise
1337              define as `char'.])dnl
1338
1339
1340
1341 dnl This could be used for targets which can have both byte sexes.
1342 dnl We could presumably replace the hardwired WORDS_BIG_ENDIAN generally.
1343 dnl AC_C_BIGENDIAN
1344
1345 dnl check for Make feature
1346 AC_PROG_MAKE_SET
1347
1348 dnl checks for operating system services
1349 AC_SYS_LONG_FILE_NAMES
1350
1351 #### Choose a window system.
1352
1353 AC_PATH_X
1354 if test "$no_x" = yes; then
1355   window_system=none
1356 else
1357   window_system=x11
1358 fi
1359
1360 ## Workaround for bug in autoconf <= 2.62.
1361 ## http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01551.html
1362 ## No need to do anything special for these standard directories.
1363 ## This is an experiment, take it out if it causes problems.
1364 if test -n "${x_libraries}" && test x"${x_libraries}" != xNONE; then
1365
1366    x_libraries=`echo :${x_libraries}: | sed -e 's|:/usr/lib64:|:|g' -e 's|:/lib64:|:|g' -e 's|^:||' -e 's|:$||'`
1367
1368 fi
1369
1370 if test "${x_libraries}" != NONE; then
1371   if test -n "${x_libraries}"; then
1372     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1373     LD_SWITCH_X_SITE_AUX=-R`echo ${x_libraries} | sed -e "s/:/ -R/g"`
1374   fi
1375   x_default_search_path=""
1376   x_search_path=${x_libraries}
1377   if test -z "${x_search_path}"; then
1378     x_search_path=/usr/lib
1379   fi
1380   for x_library in `echo ${x_search_path}: | \
1381                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1382     x_search_path="\
1383 ${x_library}/X11/%L/%T/%N%C%S:\
1384 ${x_library}/X11/%l/%T/%N%C%S:\
1385 ${x_library}/X11/%T/%N%C%S:\
1386 ${x_library}/X11/%L/%T/%N%S:\
1387 ${x_library}/X11/%l/%T/%N%S:\
1388 ${x_library}/X11/%T/%N%S"
1389     if test x"${x_default_search_path}" = x; then
1390       x_default_search_path=${x_search_path}
1391     else
1392       x_default_search_path="${x_search_path}:${x_default_search_path}"
1393     fi
1394   done
1395 fi
1396 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1397   C_SWITCH_X_SITE=-I`echo ${x_includes} | sed -e "s/:/ -I/g"`
1398 fi
1399
1400 if test x"${x_includes}" = x; then
1401   bitmapdir=/usr/include/X11/bitmaps
1402 else
1403   # accumulate include directories that have X11 bitmap subdirectories
1404   bmd_acc="dummyval"
1405   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1406     if test -d "${bmd}/X11/bitmaps"; then
1407       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1408     fi
1409     if test -d "${bmd}/bitmaps"; then
1410       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1411     fi
1412   done
1413   if test ${bmd_acc} != "dummyval"; then
1414     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1415   fi
1416 fi
1417
1418 HAVE_CARBON=no
1419 if test "${with_carbon}" != no; then
1420   AC_CHECK_HEADER(Carbon/Carbon.h, HAVE_CARBON=yes)
1421 fi
1422 if test "${window_system}" = x11 && test "${HAVE_CARBON}" = yes; then
1423   if test "${with_carbon+set}" != set \
1424      && test "${carbon_appdir_x+set}" != set; then
1425     for var in with_x with_x_toolkit with_xim \
1426                with_xpm with_jpeg with_tiff with_gif with_png; do
1427       if eval test \"\${$var+set}\" = set; then
1428         HAVE_CARBON=no
1429         break
1430       fi
1431     done
1432   fi
1433 fi
1434 if test "${HAVE_CARBON}" = yes; then
1435   window_system=mac
1436 fi
1437
1438 case "${window_system}" in
1439   x11 )
1440     HAVE_X_WINDOWS=yes
1441     HAVE_X11=yes
1442     case "${with_x_toolkit}" in
1443       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1444       motif ) USE_X_TOOLKIT=MOTIF ;;
1445       gtk ) with_gtk=yes
1446 dnl Dont set this for GTK.  A lot of tests below assumes Xt when
1447 dnl USE_X_TOOLKIT is set.
1448             USE_X_TOOLKIT=none ;;
1449       no ) USE_X_TOOLKIT=none ;;
1450 dnl If user did not say whether to use a toolkit, make this decision later:
1451 dnl use the toolkit if we have gtk, or X11R5 or newer.
1452       * ) USE_X_TOOLKIT=maybe ;;
1453     esac
1454   ;;
1455   mac | none )
1456     HAVE_X_WINDOWS=no
1457     HAVE_X11=no
1458     USE_X_TOOLKIT=none
1459   ;;
1460 esac
1461
1462 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1463    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1464    if test "$HAVE_XSERVER" = true ||
1465       test -n "$DISPLAY" ||
1466       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1467         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1468 were found.  You should install the relevant development files for X
1469 and for the toolkit you want, such as Gtk+, Lesstif or Motif.  Also make
1470 sure you have development files for image handling, i.e.
1471 tiff, gif, jpeg, png and xpm.
1472 If you are sure you want Emacs compiled without X window support, pass
1473   --without-x
1474 to configure.])
1475    fi
1476 fi
1477
1478 ### If we're using X11, we should use the X menu package.
1479 HAVE_MENUS=no
1480 case ${HAVE_X11} in
1481   yes ) HAVE_MENUS=yes ;;
1482 esac
1483
1484 ### Compute the unexec source name from the object name.
1485 UNEXEC_SRC="`echo ${unexec} | sed 's/\.o/.c/'`"
1486
1487 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1488 # Assume not, until told otherwise.
1489 GNU_MALLOC=yes
1490 doug_lea_malloc=yes
1491 AC_CHECK_FUNC(malloc_get_state, ,doug_lea_malloc=no)
1492 AC_CHECK_FUNC(malloc_set_state, ,doug_lea_malloc=no)
1493 AC_CACHE_CHECK(whether __after_morecore_hook exists,
1494                emacs_cv_var___after_morecore_hook,
1495 [AC_TRY_LINK([extern void (* __after_morecore_hook)();],[__after_morecore_hook = 0],
1496   emacs_cv_var___after_morecore_hook=yes,
1497   emacs_cv_var___after_morecore_hook=no)])
1498 if test $emacs_cv_var___after_morecore_hook = no; then
1499   doug_lea_malloc=no
1500 fi
1501 if test "${system_malloc}" = "yes"; then
1502   GNU_MALLOC=no
1503   GNU_MALLOC_reason="
1504     (The GNU allocators don't work with this system configuration.)"
1505 fi
1506 if test "$doug_lea_malloc" = "yes" ; then
1507   if test "$GNU_MALLOC" = yes ; then
1508     GNU_MALLOC_reason="
1509       (Using Doug Lea's new malloc from the GNU C Library.)"
1510   fi
1511   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1512             [Define to 1 if you are using the GNU C Library.])
1513 fi
1514
1515 if test x"${REL_ALLOC}" = x; then
1516   REL_ALLOC=${GNU_MALLOC}
1517 fi
1518
1519 dnl For now, need to use an explicit `#define USE_MMAP_FOR_BUFFERS 1'
1520 dnl the system configuration file (s/*.h) to turn the use of mmap
1521 dnl in the relocating allocator on.
1522
1523 AC_FUNC_MMAP
1524 if test $use_mmap_for_buffers = yes; then
1525   REL_ALLOC=no
1526 fi
1527
1528 LIBS="$libsrc_libs $LIBS"
1529
1530 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1531 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1532 AC_CHECK_LIB(dnet, dnet_ntoa)
1533 dnl This causes -lresolv to get used in subsequent tests,
1534 dnl which causes failures on some systems such as HPUX 9.
1535 dnl AC_CHECK_LIB(resolv, gethostbyname)
1536
1537 dnl FIXME replace main with a function we actually want from this library.
1538 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1539
1540 AC_CHECK_LIB(pthreads, cma_open)
1541
1542 dnl Check for need for bigtoc support on IBM AIX
1543
1544 case ${host_os} in
1545 aix*)
1546   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1547     case $GCC in
1548     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1549     *) gdb_cv_bigtoc=-bbigtoc ;;
1550     esac
1551
1552     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1553     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1554   ])
1555   ;;
1556 esac
1557
1558 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1559 # used for the tests that follow.  We set them back to REAL_CFLAGS and
1560 # REAL_CPPFLAGS later on.
1561
1562 REAL_CPPFLAGS="$CPPFLAGS"
1563
1564 if test "${HAVE_X11}" = "yes"; then
1565   DEFS="$C_SWITCH_X_SITE $DEFS"
1566   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1567   LIBS="$LIBX $LIBS"
1568   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1569   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1570
1571   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1572   # This is handled by LD_SWITCH_X_SITE_AUX during the real build,
1573   # but it's more convenient here to set LD_RUN_PATH
1574   # since this also works on hosts that don't understand LD_SWITCH_X_SITE_AUX.
1575   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1576     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1577     export LD_RUN_PATH
1578   fi
1579
1580   if test "${opsys}" = "gnu-linux"; then
1581     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1582     AC_TRY_LINK([],
1583      [XOpenDisplay ("foo");],
1584      [xlinux_first_failure=no],
1585      [xlinux_first_failure=yes])
1586     if test "${xlinux_first_failure}" = "yes"; then
1587       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1588       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1589       OLD_CPPFLAGS="$CPPFLAGS"
1590       OLD_LIBS="$LIBS"
1591       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1592       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1593       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1594       LIBS="$LIBS -b i486-linuxaout"
1595       AC_TRY_LINK([],
1596        [XOpenDisplay ("foo");],
1597        [xlinux_second_failure=no],
1598        [xlinux_second_failure=yes])
1599       if test "${xlinux_second_failure}" = "yes"; then
1600         # If we get the same failure with -b, there is no use adding -b.
1601         # So take it out.  This plays safe.
1602         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1603         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1604         CPPFLAGS="$OLD_CPPFLAGS"
1605         LIBS="$OLD_LIBS"
1606         AC_MSG_RESULT(no)
1607       else
1608         AC_MSG_RESULT(yes)
1609       fi
1610     else
1611       AC_MSG_RESULT(no)
1612     fi
1613   fi
1614
1615   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1616   # header files included from there.
1617   AC_MSG_CHECKING(for Xkb)
1618   AC_TRY_LINK([#include <X11/Xlib.h>
1619 #include <X11/XKBlib.h>],
1620         [XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);],
1621         emacs_xkb=yes, emacs_xkb=no)
1622   AC_MSG_RESULT($emacs_xkb)
1623   if test $emacs_xkb = yes; then
1624     AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1625   fi
1626
1627   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1628 XScreenNumberOfScreen XSetWMProtocols)
1629 fi
1630
1631 if test "${window_system}" = "x11"; then
1632   AC_MSG_CHECKING(X11 version 6)
1633   AC_CACHE_VAL(emacs_cv_x11_version_6,
1634   [AC_TRY_LINK([#include <X11/Xlib.h>],
1635 [#if XlibSpecificationRelease < 6
1636 fail;
1637 #endif
1638 ], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1639   if test $emacs_cv_x11_version_6 = yes; then
1640     AC_MSG_RESULT(6 or newer)
1641     AC_DEFINE(HAVE_X11R6, 1,
1642               [Define to 1 if you have the X11R6 or newer version of Xlib.])
1643   else
1644     AC_MSG_RESULT(before 6)
1645   fi
1646 fi
1647
1648
1649 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
1650 HAVE_RSVG=no
1651 if test "${HAVE_X11}" = "yes" || test "${HAVE_CARBON}" = "yes"; then
1652   if test "${with_rsvg}" != "no"; then
1653     RSVG_REQUIRED=2.0.0
1654     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
1655
1656     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, :, :)
1657     AC_SUBST(RSVG_CFLAGS)
1658     AC_SUBST(RSVG_LIBS)
1659
1660     if test ".${RSVG_CFLAGS}" != "."; then
1661       HAVE_RSVG=yes
1662       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
1663       CFLAGS="$CFLAGS $RSVG_CFLAGS"
1664       LIBS="$RSVG_LIBS $LIBS"
1665     fi
1666   fi
1667 fi
1668
1669
1670 HAVE_GTK=no
1671 if test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
1672   GLIB_REQUIRED=2.6
1673   GTK_REQUIRED=2.6
1674   GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1675
1676   dnl Checks for libraries.
1677   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1678   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1679      AC_MSG_ERROR($GTK_PKG_ERRORS)
1680   fi
1681 fi
1682
1683
1684 if test x"$pkg_check_gtk" = xyes; then
1685
1686   AC_SUBST(GTK_CFLAGS)
1687   AC_SUBST(GTK_LIBS)
1688   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
1689   CFLAGS="$CFLAGS $GTK_CFLAGS"
1690   LIBS="$GTK_LIBS $LIBS"
1691   dnl Try to compile a simple GTK program.
1692   GTK_COMPILES=no
1693   AC_CHECK_FUNCS(gtk_main, GTK_COMPILES=yes)
1694   if test "${GTK_COMPILES}" != "yes"; then
1695     if test "$USE_X_TOOLKIT" != "maybe"; then
1696       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
1697     fi
1698   else
1699     HAVE_GTK=yes
1700     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
1701     USE_X_TOOLKIT=none
1702     if $PKG_CONFIG --atleast-version=2.10 gtk+-2.0; then
1703       :
1704     else
1705       AC_MSG_WARN([[Your version of Gtk+ will have problems with
1706        closing open displays.  This is no problem if you just use
1707        one display, but if you use more than one and close one of them
1708        Emacs may crash.]])
1709       sleep 3
1710     fi
1711   fi
1712
1713 fi
1714
1715
1716 if test "${HAVE_GTK}" = "yes"; then
1717
1718   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
1719   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
1720   if test "$with_toolkit_scroll_bars" != no; then
1721     with_toolkit_scroll_bars=yes
1722   fi
1723
1724   dnl  Check if we can use multiple displays with this GTK version.
1725   dnl  If gdk_display_open exists, assume all others are there also.
1726   HAVE_GTK_MULTIDISPLAY=no
1727   AC_CHECK_FUNCS(gdk_display_open, HAVE_GTK_MULTIDISPLAY=yes)
1728   if test "${HAVE_GTK_MULTIDISPLAY}" = "yes"; then
1729     AC_DEFINE(HAVE_GTK_MULTIDISPLAY, 1,
1730               [Define to 1 if GTK can handle more than one display.])
1731   fi
1732
1733   dnl  Check if we have the old file selection dialog.
1734   dnl  If gdk_display_open exists, assume all others are there also.
1735   HAVE_GTK_FILE_SELECTION=no
1736   AC_CHECK_FUNCS(gtk_file_selection_new, HAVE_GTK_FILE_SELECTION=yes)
1737
1738   dnl  Check if we have the new file chooser dialog
1739   dnl  If gdk_display_open exists, assume all others are there also.
1740   HAVE_GTK_FILE_CHOOSER=no
1741   AC_CHECK_FUNCS(gtk_file_chooser_dialog_new, HAVE_GTK_FILE_CHOOSER=yes)
1742
1743   if test "$HAVE_GTK_FILE_SELECTION" = yes \
1744      && test "$HAVE_GTK_FILE_CHOOSER" = yes;  then
1745     AC_DEFINE(HAVE_GTK_FILE_BOTH, 1,
1746               [Define to 1 if GTK has both file selection and chooser dialog.])
1747   fi
1748
1749   dnl Check if pthreads are available.  Emacs only needs this when using
1750   dnl gtk_file_chooser under Gnome.
1751   if test "$HAVE_GTK_FILE_CHOOSER" = yes; then
1752     HAVE_GTK_AND_PTHREAD=no
1753     AC_CHECK_HEADERS(pthread.h)
1754     if test "$ac_cv_header_pthread_h"; then
1755       AC_CHECK_LIB(pthread, pthread_self, HAVE_GTK_AND_PTHREAD=yes)
1756     fi
1757     if test "$HAVE_GTK_AND_PTHREAD" = yes; then
1758       case "${canonical}" in
1759         *-hpux*) ;;
1760         *) GTK_LIBS="$GTK_LIBS -lpthread" ;;
1761       esac
1762       AC_DEFINE(HAVE_GTK_AND_PTHREAD, 1,
1763                [Define to 1 if you have GTK and pthread (-lpthread).])
1764     fi
1765   fi
1766 fi
1767
1768 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
1769 dnl other platforms.  Support for higher D-Bus versions than 1.0 is
1770 dnl also not configured.
1771 HAVE_DBUS=no
1772 if test "${with_dbus}" = "yes"; then
1773    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
1774    if test "$HAVE_DBUS" = yes; then
1775       AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
1776    fi
1777 fi
1778
1779 dnl Do not put whitespace before the #include statements below.
1780 dnl Older compilers (eg sunos4 cc) choke on it.
1781 HAVE_XAW3D=no
1782 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
1783   if test "$with_xaw3d" != no; then
1784     AC_MSG_CHECKING(for xaw3d)
1785     AC_CACHE_VAL(emacs_cv_xaw3d,
1786     [AC_TRY_LINK([
1787 #include <X11/Intrinsic.h>
1788 #include <X11/Xaw3d/Simple.h>],
1789       [],
1790       emacs_cv_xaw3d=yes,
1791       emacs_cv_xaw3d=no)])
1792   else
1793     emacs_cv_xaw3d=no
1794   fi
1795   if test $emacs_cv_xaw3d = yes; then
1796     AC_MSG_RESULT([yes; using Lucid toolkit])
1797     USE_X_TOOLKIT=LUCID
1798     HAVE_XAW3D=yes
1799     AC_DEFINE(HAVE_XAW3D, 1,
1800               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
1801   else
1802     AC_MSG_RESULT(no)
1803     AC_MSG_CHECKING(for libXaw)
1804     AC_CACHE_VAL(emacs_cv_xaw,
1805     [AC_TRY_LINK([
1806 #include <X11/Intrinsic.h>
1807 #include <X11/Xaw/Simple.h>],
1808       [],
1809       emacs_cv_xaw=yes,
1810       emacs_cv_xaw=no)])
1811     if test $emacs_cv_xaw = yes; then
1812       AC_MSG_RESULT([yes; using Lucid toolkit])
1813       USE_X_TOOLKIT=LUCID
1814     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
1815       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
1816     else
1817       AC_MSG_RESULT([no; do not use toolkit by default])
1818       USE_X_TOOLKIT=none
1819     fi
1820   fi
1821 fi
1822
1823 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
1824
1825 if test "${USE_X_TOOLKIT}" != "none"; then
1826   AC_MSG_CHECKING(X11 toolkit version)
1827   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
1828   [AC_TRY_LINK([#include <X11/Intrinsic.h>],
1829 [#if XtSpecificationRelease < 6
1830 fail;
1831 #endif
1832 ], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
1833   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
1834   if test $emacs_cv_x11_toolkit_version_6 = yes; then
1835     AC_MSG_RESULT(6 or newer)
1836     AC_DEFINE(HAVE_X11XTR6, 1,
1837               [Define to 1 if you have the X11R6 or newer version of Xt.])
1838   else
1839     AC_MSG_RESULT(before 6)
1840   fi
1841
1842 dnl If using toolkit, check whether libXmu.a exists.
1843 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
1844   OLDLIBS="$LIBS"
1845   if test x$HAVE_X11XTR6 = xyes; then
1846     LIBS="-lXt -lSM -lICE $LIBS"
1847   else
1848     LIBS="-lXt $LIBS"
1849   fi
1850   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
1851   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
1852 fi
1853
1854 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
1855 if test "${HAVE_X11}" = "yes"; then
1856   if test "${USE_X_TOOLKIT}" != "none"; then
1857     AC_CHECK_LIB(Xext, XShapeQueryExtension)
1858   fi
1859 fi
1860
1861 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
1862   AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
1863   [AC_TRY_COMPILE([#include <Xm/Xm.h>],
1864     [#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
1865 int x = 5;
1866 #else
1867 Motif version prior to 2.1.
1868 #endif],
1869     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
1870   HAVE_MOTIF_2_1=$emacs_cv_motif_version_2_1
1871   if test $emacs_cv_motif_version_2_1 = yes; then
1872     HAVE_LIBXP=no
1873     AC_DEFINE(HAVE_MOTIF_2_1, 1,
1874               [Define to 1 if you have Motif 2.1 or newer.])
1875     AC_CHECK_LIB(Xp, XpCreateContext, HAVE_LIBXP=yes)
1876     if test ${HAVE_LIBXP} = yes; then
1877       AC_DEFINE(HAVE_LIBXP, 1,
1878                 [Define to 1 if you have the Xp library (-lXp).])
1879     fi
1880   else
1881     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
1882     # We put this in CFLAGS temporarily to precede other -I options
1883     # that might be in CFLAGS temporarily.
1884     # We put this in CPPFLAGS where it precedes the other -I options.
1885     OLD_CPPFLAGS=$CPPFLAGS
1886     OLD_CFLAGS=$CFLAGS
1887     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
1888     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
1889     [AC_TRY_COMPILE([#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>],
1890       [int x = 5;],
1891       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
1892     if test $emacs_cv_lesstif = yes; then
1893       # Make sure this -I option remains in CPPFLAGS after it is set
1894       # back to REAL_CPPFLAGS.
1895       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
1896       # have those other -I options anyway.  Ultimately, having this
1897       # directory ultimately in CPPFLAGS will be enough.
1898       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
1899       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
1900     else
1901       CFLAGS=$OLD_CFLAGS
1902       CPPFLAGS=$OLD_CPPFLAGS
1903     fi
1904   fi
1905 fi
1906
1907 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
1908 dnl using Motif or Xaw3d is available, and unless
1909 dnl --with-toolkit-scroll-bars=no was specified.
1910
1911 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
1912             [Define to 1 if we should use toolkit scroll bars.])dnl
1913 USE_TOOLKIT_SCROLL_BARS=no
1914 if test "${with_toolkit_scroll_bars}" != "no"; then
1915   if test "${USE_X_TOOLKIT}" != "none"; then
1916     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
1917       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1918       HAVE_XAW3D=no
1919       USE_TOOLKIT_SCROLL_BARS=yes
1920     elif test "${HAVE_XAW3D}" = "yes"; then
1921       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1922       USE_TOOLKIT_SCROLL_BARS=yes
1923     fi
1924   elif test "${HAVE_GTK}" = "yes"; then
1925     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1926     USE_TOOLKIT_SCROLL_BARS=yes
1927   elif test "${HAVE_CARBON}" = "yes"; then
1928     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1929     USE_TOOLKIT_SCROLL_BARS=yes
1930   fi
1931 fi
1932
1933 dnl See if XIM is available.
1934 AC_TRY_COMPILE([
1935           #include <X11/Xlib.h>
1936           #include <X11/Xresource.h>],
1937          [XIMProc  callback;],
1938          [HAVE_XIM=yes
1939          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
1940          HAVE_XIM=no)
1941
1942 dnl `--with-xim' now controls only the initial value of use_xim at run time.
1943
1944 if test "${with_xim}" != "no"; then
1945   AC_DEFINE(USE_XIM, 1,
1946             [Define to 1 if we should use XIM, if it is available.])
1947 fi
1948
1949
1950 if test "${HAVE_XIM}" != "no"; then
1951   late_CFLAGS=$CFLAGS
1952   if test "$GCC" = yes; then
1953     CFLAGS="$CFLAGS --pedantic-errors"
1954   fi
1955   AC_TRY_COMPILE([
1956 #include <X11/Xlib.h>
1957 #include <X11/Xresource.h>],
1958 [Display *display;
1959 XrmDatabase db;
1960 char *res_name;
1961 char *res_class;
1962 XIMProc  callback;
1963 XPointer *client_data;
1964 #ifndef __GNUC__
1965 /* If we're not using GCC, it's probably not XFree86, and this is
1966    probably right, but we can't use something like --pedantic-errors.  */
1967 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
1968                                            char*, XIMProc, XPointer*);
1969 #endif
1970 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
1971    client_data);],
1972     [emacs_cv_arg6_star=yes])
1973   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
1974          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
1975 either XPointer or XPointer*.])dnl
1976   if test "$emacs_cv_arg6_star" = yes; then
1977     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
1978   else
1979     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
1980   fi
1981   CFLAGS=$late_CFLAGS
1982 fi
1983
1984 ### Start of font-backend section.
1985 if test "${HAVE_X11}" != "yes"; then
1986   USE_FONT_BACKEND=no
1987 fi
1988
1989 if test "${USE_FONT_BACKEND}" = "yes"; then
1990   AC_DEFINE(USE_FONT_BACKEND, 1, [Define to 1 if we should use font-backend.])
1991
1992   ## Use -lXft if available, unless `--with-freetype=no' nor `--with-xft=no'.
1993   HAVE_XFT=maybe
1994   if test "x${with_freetype}" = "xno"; then
1995     with_xft="no";
1996   fi
1997   if test "x${with_xft}" != "xno"; then
1998
1999     PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
2000     if test "$HAVE_XFT" != no; then
2001       OLD_CPPFLAGS="$CPPFLAGS"
2002       OLD_CFLAGS="$CFLAGS"
2003       OLD_LIBS="$LIBS"
2004       CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
2005       CFLAGS="$CFLAGS $XFT_CFLAGS"
2006       LIBS="$XFT_LIBS $LIBS"
2007       AC_CHECK_HEADER(X11/Xft/Xft.h,
2008         AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS))
2009
2010       if test "${HAVE_XFT}" = "yes"; then
2011         AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
2012         AC_SUBST(XFT_LIBS)
2013         C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
2014       else
2015         CPPFLAGS="$OLD_CPPFLAGS"
2016         CFLAGS="$OLD_CFLAGS"
2017         LIBS="$OLD_LIBS"
2018       fi                        # "${HAVE_XFT}" = "yes"
2019     fi                          # "$HAVE_XFT" != no
2020   fi                            # "x${with_xft}" != "xno"
2021
2022   dnl For the "Does Emacs use" message at the end.
2023   if test "$HAVE_XFT" != "yes"; then
2024      HAVE_XFT=no
2025   fi
2026
2027
2028   HAVE_FREETYPE=no
2029   ### Use -lfreetype if available, unless `--with-freetype=no'.
2030   if test "${HAVE_XFT}" = "yes"; then
2031     dnl As we use Xft, we anyway use freetype.
2032     dnl In this case, there's no need of additional CFLAGS and LIBS.
2033     HAVE_FREETYPE=yes
2034   elif test "x${with_freetype}" != "xno"; then
2035
2036     PKG_CHECK_MODULES(FREETYPE, freetype2, HAVE_FREETYPE=yes, HAVE_FREETYPE=no)
2037     if test "${HAVE_FREETYPE}" = "yes"; then
2038       PKG_CHECK_MODULES(FONTCONFIG, fontconfig, HAVE_FC=yes, HAVE_FC=no)
2039       if test "${HAVE_FC}" = "no"; then
2040         dnl Without fontconfig, we can't use freetype at the moment.
2041         HAVE_FREETYPE=no
2042       fi
2043     fi
2044   fi
2045
2046   HAVE_LIBOTF=no
2047   if test "${HAVE_FREETYPE}" = "yes"; then
2048     AC_DEFINE(HAVE_FREETYPE, 1,
2049               [Define to 1 if using the freetype and fontconfig libraries.])
2050     if test "${with_libotf}" != "no"; then
2051       PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
2052                         HAVE_LIBOTF=no)
2053       if test "$HAVE_LIBOTF" = "yes"; then
2054         AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
2055       fi
2056     fi
2057 dnl FIXME should there be an error if HAVE_FREETYPE != yes?
2058 dnl Does the new font backend require it, or can it work without it?
2059   fi
2060
2061   HAVE_M17N_FLT=no
2062   if test "${with_m17n_flt}" != "no"; then
2063     PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no)
2064     if test "$HAVE_M17N_FLT" = "yes"; then
2065       AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
2066     fi
2067   fi
2068
2069   AC_SUBST(FREETYPE_CFLAGS)
2070   AC_SUBST(FREETYPE_LIBS)
2071   AC_SUBST(FONTCONFIG_CFLAGS)
2072   AC_SUBST(FONTCONFIG_LIBS)
2073   AC_SUBST(LIBOTF_CFLAGS)
2074   AC_SUBST(LIBOTF_LIBS)
2075   AC_SUBST(M17N_FLT_CFLAGS)
2076   AC_SUBST(M17N_FLT_LIBS)
2077
2078 fi                              # "${USE_FONT_BACKEND}" = "yes"
2079 ### End of font-backend section.
2080
2081 ### Use -lXpm if available, unless `--with-xpm=no'.
2082 HAVE_XPM=no
2083 if test "${HAVE_X11}" = "yes"; then
2084   if test "${with_xpm}" != "no"; then
2085     AC_CHECK_HEADER(X11/xpm.h,
2086       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
2087     if test "${HAVE_XPM}" = "yes"; then
2088       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2089       AC_EGREP_CPP(no_return_alloc_pixels,
2090       [#include "X11/xpm.h"
2091 #ifndef XpmReturnAllocPixels
2092 no_return_alloc_pixels
2093 #endif
2094       ], HAVE_XPM=no, HAVE_XPM=yes)
2095
2096       if test "${HAVE_XPM}" = "yes"; then
2097         AC_MSG_RESULT(yes)
2098       else
2099         AC_MSG_RESULT(no)
2100       fi
2101     fi
2102   fi
2103
2104   if test "${HAVE_XPM}" = "yes"; then
2105     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm libary (-lXpm).])
2106   fi
2107 fi
2108
2109 ### Use -ljpeg if available, unless `--with-jpeg=no'.
2110 HAVE_JPEG=no
2111 if test "${HAVE_X11}" = "yes"; then
2112   if test "${with_jpeg}" != "no"; then
2113     dnl Checking for jpeglib.h can lose because of a redefinition of
2114     dnl  HAVE_STDLIB_H.
2115     AC_CHECK_HEADER(jerror.h,
2116       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
2117   fi
2118
2119   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
2120   if test "${HAVE_JPEG}" = "yes"; then
2121     AC_DEFINE(HAVE_JPEG)
2122     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
2123         [#include <jpeglib.h>
2124          version=JPEG_LIB_VERSION
2125 ],
2126         [AC_DEFINE(HAVE_JPEG)],
2127         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
2128         HAVE_JPEG=no])
2129   fi
2130 fi
2131
2132 ### Use -lpng if available, unless `--with-png=no'.
2133 HAVE_PNG=no
2134 if test "${HAVE_X11}" = "yes"; then
2135   if test "${with_png}" != "no"; then
2136     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
2137     # in /usr/include/libpng.
2138     AC_CHECK_HEADERS(png.h libpng/png.h)
2139     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
2140       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
2141     fi
2142   fi
2143
2144   if test "${HAVE_PNG}" = "yes"; then
2145     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2146   fi
2147 fi
2148
2149 ### Use -ltiff if available, unless `--with-tiff=no'.
2150 HAVE_TIFF=no
2151 if test "${HAVE_X11}" = "yes"; then
2152   if test "${with_tiff}" != "no"; then
2153     AC_CHECK_HEADER(tiffio.h,
2154       [tifflibs="-lz -lm"
2155       # At least one tiff package requires the jpeg library.
2156       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
2157       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
2158   fi
2159
2160   if test "${HAVE_TIFF}" = "yes"; then
2161     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2162   fi
2163 fi
2164
2165 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
2166 HAVE_GIF=no
2167 if test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no"; then
2168   AC_CHECK_HEADER(gif_lib.h,
2169 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2170 # Earlier versions can crash Emacs.
2171     [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, try_libungif=yes)])
2172
2173   if test "$HAVE_GIF" = yes; then
2174       ac_gif_lib_name="-lgif"
2175   fi
2176
2177 # If gif_lib.h but no libgif, try libungif.
2178   if test x"$try_libungif" = xyes; then
2179     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes)
2180
2181     if test "$HAVE_GIF" = yes; then
2182       AC_DEFINE(LIBGIF, -lungif, [Compiler option to link with the gif library (if not -lgif).])
2183       ac_gif_lib_name="-lungif"
2184     fi
2185   fi
2186
2187   if test "${HAVE_GIF}" = "yes"; then
2188     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif library (default -lgif; otherwise specify with LIBGIF).])
2189   fi
2190 fi
2191
2192 dnl Check for required libraries.
2193 if test "${HAVE_X11}" = "yes"; then
2194   MISSING=""
2195   WITH_NO=""
2196   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
2197     MISSING="libXpm" && WITH_NO="--with-xpm=no"
2198   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
2199     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
2200   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
2201     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
2202   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
2203     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
2204   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
2205     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
2206
2207   if test "X${MISSING}" != X; then
2208     AC_MSG_ERROR([The following required libraries were not found:
2209     $MISSING
2210 Maybe some development libraries/packages are missing?
2211 If you don't want to link with them give
2212     $WITH_NO
2213 as options to configure])
2214   fi
2215 fi
2216
2217 ### Use -lgpm if available, unless `--with-gpm=no'.
2218 HAVE_GPM=no
2219 if test "${with_gpm}" != "no"; then
2220   AC_CHECK_HEADER(gpm.h,
2221     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
2222 fi
2223
2224 if test "${HAVE_GPM}" = "yes"; then
2225   AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
2226 fi
2227
2228 dnl Check for malloc/malloc.h on darwin
2229 AC_CHECK_HEADER(malloc/malloc.h, [AC_DEFINE(HAVE_MALLOC_MALLOC_H, 1, [Define to 1 if you have the <malloc/malloc.h> header file.])])
2230
2231 ### Use Mac OS X Carbon API to implement GUI.
2232 if test "${HAVE_CARBON}" = "yes"; then
2233   AC_DEFINE(HAVE_CARBON, 1, [Define to 1 if you are using the Carbon API on Mac OS X.])
2234   AC_CHECK_HEADERS(AvailabilityMacros.h)
2235   ## Specify the install directory
2236   carbon_appdir=
2237   if test "${carbon_appdir_x}" != ""; then
2238     case ${carbon_appdir_x} in
2239       y | ye | yes)  carbon_appdir=/Applications ;;
2240       * ) carbon_appdir=${carbon_appdir_x} ;;
2241     esac
2242   fi
2243   # We also have mouse menus.
2244   HAVE_MENUS=yes
2245 fi
2246
2247 ### Use session management (-lSM -lICE) if available
2248 HAVE_X_SM=no
2249 if test "${HAVE_X11}" = "yes"; then
2250   AC_CHECK_HEADER(X11/SM/SMlib.h,
2251     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
2252
2253   if test "${HAVE_X_SM}" = "yes"; then
2254     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2255     case "$LIBS" in
2256       *-lSM*) ;;
2257       *)      LIBS="-lSM -lICE $LIBS" ;;
2258     esac
2259   fi
2260 fi
2261
2262 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2263 AC_CACHE_CHECK(whether netdb declares h_errno,
2264                emacs_cv_netdb_declares_h_errno,
2265 [AC_TRY_LINK([#include <netdb.h>],
2266   [return h_errno;],
2267   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2268 if test $emacs_cv_netdb_declares_h_errno = yes; then
2269   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2270 fi
2271
2272 AC_FUNC_ALLOCA
2273
2274 dnl src/alloca.c has been removed.  Could also check if $ALLOCA is set?
2275 dnl FIXME is there an autoconf test that does the right thing, without
2276 dnl needing to call A_M_E afterwards?
2277 if test x"$ac_cv_func_alloca_works" != xyes; then
2278    AC_MSG_ERROR( [a system implementation of alloca is required] )
2279 fi
2280
2281 # fmod, logb, and frexp are found in -lm on most systems.
2282 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2283 AC_CHECK_LIB(m, sqrt)
2284
2285 # Check for mail-locking functions in a "mail" library.  Probably this should
2286 # have the same check as for liblockfile below.
2287 AC_CHECK_LIB(mail, maillock)
2288 dnl Debian, at least:
2289 AC_CHECK_LIB(lockfile, maillock)
2290 # If we have the shared liblockfile, assume we must use it for mail
2291 # locking (e.g. Debian).  If we couldn't link against liblockfile
2292 # (no liblockfile.a installed), ensure that we don't need to.
2293 if test "$ac_cv_lib_lockfile_maillock" = no; then
2294   dnl This works for files generally, not just executables.
2295   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
2296   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2297                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2298   if test $ac_cv_prog_liblockfile = yes; then
2299     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2300 This probably means that movemail could lose mail.
2301 There may be a `development' package to install containing liblockfile.])
2302   else :
2303   fi
2304 fi
2305 AC_CHECK_FUNCS(touchlock)
2306 AC_CHECK_HEADERS(maillock.h)
2307
2308 AC_CHECK_FUNCS(gethostname getdomainname dup2 \
2309 rename closedir mkdir rmdir sysinfo getrusage get_current_dir_name \
2310 random lrand48 bcopy bcmp logb frexp fmod rint cbrt ftime setsid \
2311 strerror fpathconf select mktime euidaccess getpagesize tzset setlocale \
2312 utimes setrlimit setpgid getcwd getwd shutdown getaddrinfo \
2313 __fpending mblen mbrlen mbsinit strsignal setitimer ualarm index rindex \
2314 sendto recvfrom getsockopt setsockopt getsockname getpeername \
2315 gai_strerror mkstemp getline getdelim mremap memmove fsync sync bzero \
2316 memset memcmp difftime memcpy mempcpy mblen mbrlen posix_memalign)
2317
2318 AC_CHECK_HEADERS(sys/un.h)
2319
2320 AC_FUNC_MKTIME
2321 if test "$ac_cv_func_working_mktime" = no; then
2322   AC_DEFINE(BROKEN_MKTIME, 1, [Define to 1 if the mktime function is broken.])
2323 fi
2324
2325 AC_FUNC_GETLOADAVG
2326
2327 AC_FUNC_FSEEKO
2328
2329 # Configure getopt.
2330 m4_include([m4/getopt.m4])
2331 gl_GETOPT_IFELSE([
2332   gl_GETOPT_SUBSTITUTE_HEADER
2333   gl_PREREQ_GETOPT
2334   GETOPTOBJS='getopt.o getopt1.o'
2335 ])
2336 AC_SUBST(GETOPTOBJS)
2337
2338 AC_FUNC_GETPGRP
2339
2340 AC_FUNC_STRFTIME
2341
2342 # UNIX98 PTYs.
2343 AC_CHECK_FUNCS(grantpt)
2344
2345 # PTY-related GNU extensions.
2346 AC_CHECK_FUNCS(getpt)
2347
2348 # Check this now, so that we will NOT find the above functions in ncurses.
2349 # That is because we have not set up to link ncurses in lib-src.
2350 # It's better to believe a function is not available
2351 # than to expect to find it in ncurses.
2352 AC_CHECK_LIB(ncurses, tparm)
2353
2354 # Do we have res_init, for detecting changes in /etc/resolv.conf?
2355
2356 resolv=no
2357 AC_TRY_LINK([#include <netinet/in.h>
2358 #include <arpa/nameser.h>
2359 #include <resolv.h>],
2360     [return res_init();],
2361     have_res_init=yes, have_res_init=no)
2362 if test "$have_res_init" = no; then
2363   OLIBS="$LIBS"
2364   LIBS="$LIBS -lresolv"
2365   AC_MSG_CHECKING(for res_init with -lresolv)
2366   AC_TRY_LINK([#include <netinet/in.h>
2367 #include <arpa/nameser.h>
2368 #include <resolv.h>],
2369     [return res_init();],
2370     have_res_init=yes, have_res_init=no)
2371   AC_MSG_RESULT($have_res_init)
2372   if test "$have_res_init" = yes ; then
2373     resolv=yes
2374   fi
2375   LIBS="$OLIBS"
2376 fi
2377
2378 if test "$have_res_init" = yes; then
2379   AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
2380 fi
2381
2382 # Do we need the Hesiod library to provide the support routines?
2383 if test "$with_hesiod" = yes ; then
2384   # Don't set $LIBS here -- see comments above.
2385   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
2386      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
2387                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
2388   if test "$resolv" = yes ; then
2389     RESOLVLIB=-lresolv
2390   else
2391     RESOLVLIB=
2392   fi
2393   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2394         [AC_DEFINE(HAVE_LIBHESIOD, 1,
2395                   [Define to 1 if you have the hesiod library (-lhesiod).])],
2396         :, $RESOLVLIB)])
2397 fi
2398
2399 # Do we need libresolv (due to res_init or Hesiod)?
2400 if test "$resolv" = yes ; then
2401   AC_DEFINE(HAVE_LIBRESOLV, 1,
2402             [Define to 1 if you have the resolv library (-lresolv).])
2403 fi
2404
2405 # These tell us which Kerberos-related libraries to use.
2406 if test "${with_kerberos+set}" = set; then
2407   AC_CHECK_LIB(com_err, com_err)
2408   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt)
2409   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt)
2410   AC_CHECK_LIB(krb5, krb5_init_context)
2411   if test "${with_kerberos5+set}" != set; then
2412     AC_CHECK_LIB(des425, des_cbc_encrypt,,
2413                  [AC_CHECK_LIB(des, des_cbc_encrypt)])
2414     AC_CHECK_LIB(krb4, krb_get_cred,,
2415                  [AC_CHECK_LIB(krb, krb_get_cred)])
2416   fi
2417
2418   if test "${with_kerberos5+set}" = set; then
2419     AC_CHECK_HEADERS(krb5.h)
2420   else
2421     AC_CHECK_HEADERS(des.h,,
2422                      [AC_CHECK_HEADERS(kerberosIV/des.h,,
2423                                        [AC_CHECK_HEADERS(kerberos/des.h)])])
2424     AC_CHECK_HEADERS(krb.h,,
2425                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
2426                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
2427   fi
2428   AC_CHECK_HEADERS(com_err.h)
2429 fi
2430
2431 # Solaris requires -lintl if you want strerror (which calls dgettext)
2432 # to return localized messages.
2433 AC_CHECK_LIB(intl, dgettext)
2434
2435 AC_MSG_CHECKING(whether localtime caches TZ)
2436 AC_CACHE_VAL(emacs_cv_localtime_cache,
2437 [if test x$ac_cv_func_tzset = xyes; then
2438 AC_TRY_RUN([#include <time.h>
2439 extern char **environ;
2440 unset_TZ ()
2441 {
2442   char **from, **to;
2443   for (to = from = environ; (*to = *from); from++)
2444     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
2445       to++;
2446 }
2447 char TZ_GMT0[] = "TZ=GMT0";
2448 char TZ_PST8[] = "TZ=PST8";
2449 main()
2450 {
2451   time_t now = time ((time_t *) 0);
2452   int hour_GMT0, hour_unset;
2453   if (putenv (TZ_GMT0) != 0)
2454     exit (1);
2455   hour_GMT0 = localtime (&now)->tm_hour;
2456   unset_TZ ();
2457   hour_unset = localtime (&now)->tm_hour;
2458   if (putenv (TZ_PST8) != 0)
2459     exit (1);
2460   if (localtime (&now)->tm_hour == hour_GMT0)
2461     exit (1);
2462   unset_TZ ();
2463   if (localtime (&now)->tm_hour != hour_unset)
2464     exit (1);
2465   exit (0);
2466 }], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
2467 [# If we have tzset, assume the worst when cross-compiling.
2468 emacs_cv_localtime_cache=yes])
2469 else
2470         # If we lack tzset, report that localtime does not cache TZ,
2471         # since we can't invalidate the cache if we don't have tzset.
2472         emacs_cv_localtime_cache=no
2473 fi])dnl
2474 AC_MSG_RESULT($emacs_cv_localtime_cache)
2475 if test $emacs_cv_localtime_cache = yes; then
2476   AC_DEFINE(LOCALTIME_CACHE, 1,
2477             [Define to 1 if localtime caches TZ.])
2478 fi
2479
2480 if test "x$HAVE_TIMEVAL" = xyes; then
2481   AC_CHECK_FUNCS(gettimeofday)
2482   if test $ac_cv_func_gettimeofday = yes; then
2483     AC_CACHE_CHECK(whether gettimeofday can accept two arguments,
2484                    emacs_cv_gettimeofday_two_arguments,
2485     [AC_TRY_COMPILE([
2486 #ifdef TIME_WITH_SYS_TIME
2487 #include <sys/time.h>
2488 #include <time.h>
2489 #else
2490 #ifdef HAVE_SYS_TIME_H
2491 #include <sys/time.h>
2492 #else
2493 #include <time.h>
2494 #endif
2495 #endif],
2496       [struct timeval time;
2497        gettimeofday (&time, 0);],
2498       emacs_cv_gettimeofday_two_arguments=yes,
2499       emacs_cv_gettimeofday_two_arguments=no)])
2500     if test $emacs_cv_gettimeofday_two_arguments = no; then
2501       AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT, 1,
2502                 [Define to 1 if gettimeofday accepts only one argument.])
2503     fi
2504   fi
2505 fi
2506
2507 ok_so_far=yes
2508 AC_CHECK_FUNC(socket, , ok_so_far=no)
2509 if test $ok_so_far = yes; then
2510   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
2511 fi
2512 if test $ok_so_far = yes; then
2513   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
2514 fi
2515 if test $ok_so_far = yes; then
2516 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
2517   AC_DEFINE(HAVE_INET_SOCKETS, 1,
2518             [Define to 1 if you have inet sockets.])
2519 fi
2520
2521 AC_CHECK_HEADERS(sys/ioctl.h)
2522
2523 if test -f /usr/lpp/X11/bin/smt.exp; then
2524   AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
2525             [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
2526 fi
2527
2528 AC_MSG_CHECKING(whether system supports dynamic ptys)
2529 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
2530   AC_MSG_RESULT(yes)
2531   AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
2532 else
2533   AC_MSG_RESULT(no)
2534 fi
2535
2536 AC_FUNC_FORK
2537
2538 dnl Adapted from Haible's version.
2539 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
2540   [AC_TRY_LINK([#include <langinfo.h>],
2541     [char* cs = nl_langinfo(CODESET);],
2542     emacs_cv_langinfo_codeset=yes,
2543     emacs_cv_langinfo_codeset=no)
2544   ])
2545 if test $emacs_cv_langinfo_codeset = yes; then
2546   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
2547     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
2548 fi
2549
2550 AC_CHECK_TYPES(size_t)
2551
2552 AC_TYPE_MBSTATE_T
2553
2554 dnl Restrict could probably be used effectively other than in regex.c.
2555 AC_CACHE_CHECK([for C restrict keyword], emacs_cv_c_restrict,
2556   [AC_TRY_COMPILE([void fred (int *restrict x);], [],
2557                   emacs_cv_c_restrict=yes,
2558                   [AC_TRY_COMPILE([void fred (int *__restrict x);], [],
2559                                   emacs_cv_c_restrict=__restrict,
2560                                   emacs_cv_c_restrict=no)])])
2561 case "$emacs_cv_c_restrict" in
2562   yes) emacs_restrict=restrict;;
2563   no) emacs_restrict="";;
2564   *) emacs_restrict="$emacs_cv_c_restrict";;
2565 esac
2566 if test "$emacs_restrict" != __restrict; then
2567   AC_DEFINE_UNQUOTED(__restrict, $emacs_restrict,
2568     [Define to compiler's equivalent of C99 restrict keyword.
2569      Don't define if equivalent is `__restrict'.])
2570 fi
2571
2572 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
2573   [AC_TRY_COMPILE([void fred (int x[__restrict]);], [],
2574                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
2575 if test "$emacs_cv_c_restrict_arr" = yes; then
2576   AC_DEFINE(__restrict_arr, __restrict,
2577     [Define to compiler's equivalent of C99 restrict keyword in array
2578      declarations.  Define as empty for no equivalent.])
2579 fi
2580
2581 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
2582 dnl how the tty code is related to POSIX and/or other versions of termios.
2583 dnl The following looks like a useful start.
2584 dnl
2585 dnl AC_SYS_POSIX_TERMIOS
2586 dnl if test $ac_cv_sys_posix_termios = yes; then
2587 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
2588 dnl                                and macros for terminal control.])
2589 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
2590 dnl fi
2591
2592 dnl Fixme: Use AC_FUNC_MEMCMP since memcmp is used.  (Needs libobj replacement.)
2593
2594 # Set up the CFLAGS for real compilation, so we can substitute it.
2595 CFLAGS="$REAL_CFLAGS"
2596 CPPFLAGS="$REAL_CPPFLAGS"
2597
2598 #### Find out which version of Emacs this is.
2599 [version=`grep 'defconst[        ]*emacs-version' ${srcdir}/lisp/version.el \
2600          | sed -e 's/^[^"]*"\([^"]*\)".*$/\1/'`]
2601 if test x"${version}" = x; then
2602   AC_MSG_ERROR([can't find current emacs version in `${srcdir}/lisp/version.el'.])
2603 fi
2604
2605 ### Specify what sort of things we'll be editing into Makefile and config.h.
2606 ### Use configuration here uncanonicalized to avoid exceeding size limits.
2607 AC_SUBST(version)
2608 AC_SUBST(configuration)
2609 AC_SUBST(canonical)
2610 AC_SUBST(srcdir)
2611 AC_SUBST(prefix)
2612 AC_SUBST(exec_prefix)
2613 AC_SUBST(bindir)
2614 AC_SUBST(datadir)
2615 AC_SUBST(sharedstatedir)
2616 AC_SUBST(libexecdir)
2617 AC_SUBST(mandir)
2618 AC_SUBST(infodir)
2619 AC_SUBST(lispdir)
2620 AC_SUBST(locallisppath)
2621 AC_SUBST(lisppath)
2622 AC_SUBST(x_default_search_path)
2623 AC_SUBST(etcdir)
2624 AC_SUBST(archlibdir)
2625 AC_SUBST(docdir)
2626 AC_SUBST(bitmapdir)
2627 AC_SUBST(gamedir)
2628 AC_SUBST(gameuser)
2629 AC_SUBST(c_switch_system)
2630 AC_SUBST(c_switch_machine)
2631 AC_SUBST(LD_SWITCH_X_SITE)
2632 AC_SUBST(LD_SWITCH_X_SITE_AUX)
2633 AC_SUBST(C_SWITCH_X_SITE)
2634 AC_SUBST(CFLAGS)
2635 AC_SUBST(X_TOOLKIT_TYPE)
2636 AC_SUBST(machfile)
2637 AC_SUBST(opsysfile)
2638 AC_SUBST(GETLOADAVG_LIBS)
2639 AC_SUBST(carbon_appdir)
2640
2641 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
2642                    [Define to the canonical Emacs configuration name.])
2643 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
2644                    [Define to the options passed to configure.])
2645 AC_DEFINE_UNQUOTED(config_machfile,  "${machfile}",
2646                    [Define to the used machine dependent file.])
2647 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}",
2648                    [Define to the used os dependent file.])
2649 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE, ${LD_SWITCH_X_SITE},
2650 [Define LD_SWITCH_X_SITE to contain any special flags your loader
2651  may need to deal with X Windows.  For instance, if you've defined
2652  HAVE_X_WINDOWS above and your X libraries aren't in a place that
2653  your loader can find on its own, you might want to add "-L/..." or
2654  something similar.])
2655 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE_AUX, ${LD_SWITCH_X_SITE_AUX},
2656                    [Define LD_SWITCH_X_SITE_AUX with an -R option
2657                     in case it's needed (for Solaris, for example).])
2658 AC_DEFINE_UNQUOTED(C_SWITCH_X_SITE,  ${C_SWITCH_X_SITE},
2659 [Define C_SWITCH_X_SITE to contain any special flags your compiler
2660  may need to deal with X Windows.  For instance, if you've defined
2661  HAVE_X_WINDOWS above and your X include files aren't in a place
2662  that your compiler can find on its own, you might want to add
2663  "-I/..." or something similar.])
2664 AC_DEFINE_UNQUOTED(UNEXEC_SRC,       ${UNEXEC_SRC},
2665                    [Define to the unexec source file name.])
2666
2667 if test "${HAVE_X_WINDOWS}" = "yes" ; then
2668   AC_DEFINE(HAVE_X_WINDOWS, 1,
2669             [Define to 1 if you want to use the X window system.])
2670 fi
2671 if test "${USE_X_TOOLKIT}" != "none" ; then
2672   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
2673   if test "${USE_X_TOOLKIT}" == "LUCID"; then
2674     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
2675   elif test "${USE_X_TOOLKIT}" == "MOTIF"; then
2676     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
2677   fi
2678 fi
2679 if test "${HAVE_X11}" = "yes" ; then
2680   AC_DEFINE(HAVE_X11, 1,
2681             [Define to 1 if you want to use version 11 of X windows.
2682              Otherwise, Emacs expects to use version 10.])
2683 fi
2684 if test "${HAVE_MENUS}" = "yes" ; then
2685   AC_DEFINE(HAVE_MENUS, 1,
2686             [Define to 1 if you have mouse menus.
2687              (This is automatic if you use X, but the option to specify it remains.)
2688              It is also defined with other window systems that support xmenu.c.])
2689 fi
2690 if test "${GNU_MALLOC}" = "yes" ; then
2691   AC_DEFINE(GNU_MALLOC, 1,
2692             [Define to 1 if you want to use the GNU memory allocator.])
2693 fi
2694 if test "${REL_ALLOC}" = "yes" ; then
2695   AC_DEFINE(REL_ALLOC, 1,
2696             [Define REL_ALLOC if you want to use the relocating allocator for
2697              buffer space.])
2698 fi
2699
2700
2701 AH_TOP([/* GNU Emacs site configuration template file.
2702    Copyright (C) 1988, 1993, 1994, 1999, 2000, 2001, 2002, 2004, 2005,
2703      2006, 2007, 2008  Free Software Foundation, Inc.
2704
2705 This file is part of GNU Emacs.
2706
2707 GNU Emacs is free software: you can redistribute it and/or modify
2708 it under the terms of the GNU General Public License as published by
2709 the Free Software Foundation, either version 3 of the License, or
2710 (at your option) any later version.
2711
2712 GNU Emacs is distributed in the hope that it will be useful,
2713 but WITHOUT ANY WARRANTY; without even the implied warranty of
2714 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
2715 GNU General Public License for more details.
2716
2717 You should have received a copy of the GNU General Public License
2718 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
2719
2720
2721 /* No code in Emacs #includes config.h twice, but some bits of code
2722    intended to work with other packages as well (like gmalloc.c)
2723    think they can include it as many times as they like.  */
2724 #ifndef EMACS_CONFIG_H
2725 #define EMACS_CONFIG_H
2726 ])dnl
2727
2728 AH_BOTTOM([
2729 /* If we're using any sort of window system, define some consequences.  */
2730 #ifdef HAVE_X_WINDOWS
2731 #define HAVE_WINDOW_SYSTEM
2732 #define MULTI_KBOARD
2733 #define HAVE_MOUSE
2734 #endif
2735
2736 /* Multi-tty support relies on MULTI_KBOARD.  It seems safe to turn it
2737    on unconditionally. */
2738 #ifndef MULTI_KBOARD
2739 #define MULTI_KBOARD
2740 #endif
2741
2742 /* If we're using the Carbon API on Mac OS X, define a few more
2743    variables as well.  */
2744 #ifdef HAVE_CARBON
2745 #define HAVE_WINDOW_SYSTEM
2746 #define HAVE_MOUSE
2747 #endif
2748
2749 /* Define USER_FULL_NAME to return a string
2750    that is the user's full name.
2751    It can assume that the variable `pw'
2752    points to the password file entry for this user.
2753
2754    At some sites, the pw_gecos field contains
2755    the user's full name.  If neither this nor any other
2756    field contains the right thing, use pw_name,
2757    giving the user's login name, since that is better than nothing.  */
2758 #define USER_FULL_NAME pw->pw_gecos
2759
2760 /* Define AMPERSAND_FULL_NAME if you use the convention
2761    that & in the full name stands for the login id.  */
2762 /* Turned on June 1996 supposing nobody will mind it.  */
2763 #define AMPERSAND_FULL_NAME
2764
2765 /* We have blockinput.h.  */
2766 #define DO_BLOCK_INPUT
2767
2768 /* Define HAVE_SOUND if we have sound support.  We know it works
2769    and compiles only on the specified platforms.   For others,
2770    it probably doesn't make sense to try.  */
2771
2772 #if defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
2773 #ifdef HAVE_MACHINE_SOUNDCARD_H
2774 #define HAVE_SOUND 1
2775 #endif
2776 #ifdef HAVE_SYS_SOUNDCARD_H
2777 #define HAVE_SOUND 1
2778 #endif
2779 #ifdef HAVE_SOUNDCARD_H
2780 #define HAVE_SOUND 1
2781 #endif
2782 #ifdef HAVE_ALSA
2783 #define HAVE_SOUND 1
2784 #endif
2785 #endif /* __FreeBSD__ || __NetBSD__ || __linux__  */
2786
2787 /* If using GNU, then support inline function declarations. */
2788 /* Don't try to switch on inline handling as detected by AC_C_INLINE
2789    generally, because even if non-gcc compilers accept `inline', they
2790    may reject `extern inline'.  */
2791 #if defined (__GNUC__) && defined (OPTIMIZE)
2792 #define INLINE __inline__
2793 #else
2794 #define INLINE
2795 #endif
2796
2797 /* Include the os and machine dependent files.  */
2798 #include config_opsysfile
2799 #include config_machfile
2800
2801 /* If no remapping takes place, static variables cannot be dumped as
2802    pure, so don't worry about the `static' keyword. */
2803 #ifdef NO_REMAP
2804 #undef static
2805 #endif
2806
2807 /* Define `subprocesses' should be defined if you want to
2808    have code for asynchronous subprocesses
2809    (as used in M-x compile and M-x shell).
2810    These do not work for some USG systems yet;
2811    for the ones where they work, the s/SYSTEM.h file defines this flag.  */
2812
2813 #ifndef VMS
2814 #ifndef USG
2815 /* #define subprocesses */
2816 #endif
2817 #endif
2818
2819 /* SIGTYPE is the macro we actually use.  */
2820 #ifndef SIGTYPE
2821 #define SIGTYPE RETSIGTYPE
2822 #endif
2823
2824 #ifdef emacs /* Don't do this for lib-src.  */
2825 /* Tell regex.c to use a type compatible with Emacs.  */
2826 #define RE_TRANSLATE_TYPE Lisp_Object
2827 #define RE_TRANSLATE(TBL, C) CHAR_TABLE_TRANSLATE (TBL, C)
2828 #ifdef make_number
2829 /* If make_number is a macro, use it.  */
2830 #define RE_TRANSLATE_P(TBL) (!EQ (TBL, make_number (0)))
2831 #else
2832 /* If make_number is a function, avoid it.  */
2833 #define RE_TRANSLATE_P(TBL) (!(INTEGERP (TBL) && XINT (TBL) == 0))
2834 #endif
2835 #endif
2836
2837 /* Avoid link-time collision with system mktime if we will use our own.  */
2838 #if ! HAVE_MKTIME || BROKEN_MKTIME
2839 #define mktime emacs_mktime
2840 #endif
2841
2842 #define my_strftime nstrftime   /* for strftime.c */
2843
2844 /* The rest of the code currently tests the CPP symbol BSTRING.
2845    Override any claims made by the system-description files.
2846    Note that on some SCO version it is possible to have bcopy and not bcmp.  */
2847 #undef BSTRING
2848 #if defined (HAVE_BCOPY) && defined (HAVE_BCMP)
2849 #define BSTRING
2850 #endif
2851
2852 /* Some of the files of Emacs which are intended for use with other
2853    programs assume that if you have a config.h file, you must declare
2854    the type of getenv.
2855
2856    This declaration shouldn't appear when alloca.s or Makefile.in
2857    includes config.h.  */
2858 #ifndef NOT_C_CODE
2859 extern char *getenv ();
2860 #endif
2861
2862 /* These default definitions are good for almost all machines.
2863    The exceptions override them in m/MACHINE.h.  */
2864
2865 #ifndef BITS_PER_CHAR
2866 #define BITS_PER_CHAR 8
2867 #endif
2868
2869 #ifndef BITS_PER_SHORT
2870 #define BITS_PER_SHORT 16
2871 #endif
2872
2873 /* Note that lisp.h uses this in a preprocessor conditional, so it
2874    would not work to use sizeof.  That being so, we do all of them
2875    without sizeof, for uniformity's sake.  */
2876 #ifndef BITS_PER_INT
2877 #define BITS_PER_INT 32
2878 #endif
2879
2880 #ifndef BITS_PER_LONG
2881 #ifdef _LP64
2882 #define BITS_PER_LONG 64
2883 #else
2884 #define BITS_PER_LONG 32
2885 #endif
2886 #endif
2887
2888 /* Define if the compiler supports function prototypes.  It may do so
2889    but not define __STDC__ (e.g. DEC C by default) or may define it as
2890    zero.  */
2891 #undef PROTOTYPES
2892 /* For mktime.c:  */
2893 #ifndef __P
2894 # if defined PROTOTYPES
2895 #  define __P(args) args
2896 # else
2897 #  define __P(args) ()
2898 # endif  /* GCC.  */
2899 #endif /* __P */
2900
2901 /* Don't include "string.h" or <stdlib.h> in non-C code.  */
2902 #ifndef NOT_C_CODE
2903 #ifdef HAVE_STRING_H
2904 #include "string.h"
2905 #endif
2906 #ifdef HAVE_STRINGS_H
2907 #include "strings.h"  /* May be needed for bcopy & al. */
2908 #endif
2909 #ifdef HAVE_STDLIB_H
2910 #include <stdlib.h>
2911 #endif
2912 #ifndef __GNUC__
2913 # ifdef HAVE_ALLOCA_H
2914 #  include <alloca.h>
2915 # else /* AIX files deal with #pragma.  */
2916 #  ifndef alloca /* predefined by HP cc +Olibcalls */
2917 char *alloca ();
2918 #  endif
2919 # endif /* HAVE_ALLOCA_H */
2920 #endif /* __GNUC__ */
2921 #ifndef HAVE_SIZE_T
2922 typedef unsigned size_t;
2923 #endif
2924 #endif /* NOT_C_CODE */
2925
2926 /* Define HAVE_X_I18N if we have usable i18n support.  */
2927
2928 #ifdef HAVE_X11R6
2929 #define HAVE_X_I18N
2930 #elif !defined X11R5_INHIBIT_I18N
2931 #define HAVE_X_I18N
2932 #endif
2933
2934 /* Define HAVE_X11R6_XIM if we have usable X11R6-style XIM support.  */
2935
2936 #if defined HAVE_X11R6 && !defined INHIBIT_X11R6_XIM
2937 #define HAVE_X11R6_XIM
2938 #endif
2939
2940 /* Should we enable expensive run-time checking of data types?  */
2941 #undef ENABLE_CHECKING
2942
2943 #if defined __GNUC__ && (__GNUC__ > 2 \
2944                          || (__GNUC__ == 2 && __GNUC_MINOR__ >= 5))
2945 #define NO_RETURN       __attribute__ ((__noreturn__))
2946 #else
2947 #define NO_RETURN       /* nothing */
2948 #endif
2949
2950 /* These won't be used automatically yet.  We also need to know, at least,
2951    that the stack is continuous.  */
2952 #ifdef __GNUC__
2953 #  ifndef GC_SETJMP_WORKS
2954   /* GC_SETJMP_WORKS is nearly always appropriate for GCC --
2955      see NON_SAVING_SETJMP in the target descriptions.  */
2956   /* Exceptions (see NON_SAVING_SETJMP in target description) are
2957      SCO5 non-ELF (but Emacs specifies ELF) and SVR3 on x86.
2958      Fixme: Deal with SVR3.  */
2959 #    define GC_SETJMP_WORKS 1
2960 #  endif
2961 #  ifndef GC_LISP_OBJECT_ALIGNMENT
2962 #    define GC_LISP_OBJECT_ALIGNMENT (__alignof__ (Lisp_Object))
2963 #  endif
2964 #endif
2965
2966 #ifndef HAVE_BCOPY
2967 #define bcopy(a,b,s) memcpy (b,a,s)
2968 #endif
2969 #ifndef HAVE_BZERO
2970 #define bzero(a,s) memset (a,0,s)
2971 #endif
2972 #ifndef HAVE_BCMP
2973 #define BCMP memcmp
2974 #endif
2975
2976 #endif /* EMACS_CONFIG_H */
2977
2978 /*
2979 Local Variables:
2980 mode: c
2981 End:
2982 */
2983 ])dnl
2984
2985 #### Report on what we decided to do.
2986 #### Report GTK as a toolkit, even if it doesn't use Xt.
2987 #### It makes printing result more understandable as using GTK sets
2988 #### toolkit_scroll_bars to yes by default.
2989 if test "${HAVE_GTK}" = "yes"; then
2990   USE_X_TOOLKIT=GTK
2991 fi
2992
2993 echo "
2994 Configured for \`${canonical}'.
2995
2996   Where should the build process find the source code?    ${srcdir}
2997   What operating system and machine description files should Emacs use?
2998         \`${opsysfile}' and \`${machfile}'
2999   What compiler should emacs be built with?               ${CC} ${CFLAGS}
3000   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
3001   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
3002   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
3003   What window system should Emacs use?                    ${window_system}
3004   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
3005
3006 if test -n "${x_includes}"; then
3007 echo "  Where do we find X Windows header files?                ${x_includes}"
3008 else
3009 echo "  Where do we find X Windows header files?                Standard dirs"
3010 fi
3011 if test -n "${x_libraries}"; then
3012 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
3013 else
3014 echo "  Where do we find X Windows libraries?                   Standard dirs"
3015 fi
3016
3017 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
3018 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
3019 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
3020 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
3021 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $ac_gif_lib_name"
3022 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
3023 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
3024 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
3025 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
3026 echo "  Does Emacs use a font backend?                          ${USE_FONT_BACKEND}"
3027
3028 if test "${USE_FONT_BACKEND}" = "yes"; then
3029   echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
3030   echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
3031   echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
3032   echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
3033 fi
3034 echo "  Does Emacs use X toolkit scroll bars?                   ${USE_TOOLKIT_SCROLL_BARS}"
3035 echo
3036
3037 if test $USE_XASSERTS = yes; then
3038    echo "  Compiling with asserts turned on."
3039    CPPFLAGS="$CPPFLAGS -DXASSERTS=1"
3040 fi
3041
3042 echo
3043
3044 if test "$USE_X_TOOLKIT" = GTK; then
3045   case "$canonical" in
3046   *cygwin*)
3047     echo "There are known problems with Emacs and Gtk+ on cygwin, so you
3048   will probably get a crash on startup.  If this happens, please use another
3049   toolkit for Emacs.  See etc/PROBLEMS for more information."
3050   ;;
3051   esac
3052 fi
3053
3054
3055 if test "$HAVE_CARBON" = "yes"; then
3056    echo
3057    echo "Warning: The Mac Carbon port is currently unsupported and has
3058 known problems.  It is not recommended for use by non-developers.
3059 Read the emacs-devel archives for more information."
3060    echo
3061 fi
3062
3063 if test "$HAVE_DBUS" = yes && test "${opsys}" != "gnu-linux"; then
3064   echo "D-Bus integration has been tested for GNU/Linux only."
3065   echo
3066 fi
3067
3068
3069 # Remove any trailing slashes in these variables.
3070 [test "${prefix}" != NONE &&
3071   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
3072 test "${exec_prefix}" != NONE &&
3073   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
3074
3075 ## Check if the C preprocessor will convert `..' to `. .'.  If so, set
3076 ## CPP_NEED_TRADITIONAL to `yes' so that the code to generate Makefile
3077 ## from Makefile.c can correctly provide the arg `-traditional' to the
3078 ## C preprocessor.
3079
3080 AC_EGREP_CPP(yes..yes,
3081         [yes..yes],
3082         CPP_NEED_TRADITIONAL=no,
3083         CPP_NEED_TRADITIONAL=yes)
3084
3085 AC_OUTPUT(Makefile lib-src/Makefile.c:lib-src/Makefile.in oldXMenu/Makefile \
3086         doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
3087         doc/lispref/Makefile src/Makefile.c:src/Makefile.in \
3088         lwlib/Makefile lisp/Makefile leim/Makefile, [
3089
3090 ### Make the necessary directories, if they don't exist.
3091 for dir in etc lisp ; do
3092   test -d ${dir} || mkdir ${dir}
3093 done
3094
3095 # Build src/Makefile from ${srcdir}/src/Makefile.c
3096 # and lib-src/Makefile from ${srcdir}/lib-src/Makefile.c
3097 # This must be done after src/config.h is built, since we rely on that file.
3098
3099 # Now get this: Some word that is part of the ${srcdir} directory name
3100 # or the ${configuration} value might, just might, happen to be an
3101 # identifier like `sun4' or `i386' or something, and be predefined by
3102 # the C preprocessor to some helpful value like 1, or maybe the empty
3103 # string.  Needless to say consequent macro substitutions are less
3104 # than conducive to the makefile finding the correct directory.
3105 [undefs="`echo $top_srcdir $configuration $canonical |
3106 sed -e 's/[^a-zA-Z0-9_]/ /g' -e 's/^/ /' -e 's/  *$//' \
3107     -e 's/  */ -U/g' -e 's/-U[0-9][^ ]*//g' \
3108 `"]
3109
3110 echo creating src/epaths.h
3111 ${MAKE-make} epaths-force
3112
3113 # As of 2000-11-19, newest development versions of GNU cpp preprocess
3114 # `..' to `. .'  unless invoked with -traditional
3115
3116 if test "x$GCC" = xyes && test "x$CPP_NEED_TRADITIONAL" = xyes; then
3117   CPPFLAGS="$CPPFLAGS -traditional"
3118 fi
3119
3120 echo creating lib-src/Makefile
3121 ( cd lib-src
3122   rm -f junk.c junk1.c junk2.c
3123   sed -e '/start of cpp stuff/q' \
3124       < Makefile.c > junk1.c
3125   sed -e '1,/start of cpp stuff/d'\
3126       -e 's,/\*\*/#\(.*\)$,/* \1 */,' \
3127       < Makefile.c > junk.c
3128   $CPP $undefs -I. -I$srcdir/src $CPPFLAGS junk.c | \
3129       sed -e 's/^ /     /' -e '/^#/d' -e '/^[   \f]*$/d' > junk2.c
3130   cat junk1.c junk2.c > Makefile.new
3131   rm -f junk.c junk1.c junk2.c
3132   chmod 444 Makefile.new
3133   mv -f Makefile.new Makefile
3134 )
3135
3136 echo creating src/Makefile
3137 ( cd src
3138   rm -f junk.c junk1.c junk2.c
3139   sed -e '/start of cpp stuff/q' \
3140       < Makefile.c > junk1.c
3141   sed -e '1,/start of cpp stuff/d'\
3142       -e 's,/\*\*/#\(.*\)$,/* \1 */,' \
3143       < Makefile.c > junk.c
3144   $CPP $undefs -I. -I$srcdir/src $CPPFLAGS junk.c | \
3145       sed -e 's/^ /     /' -e '/^#/d' -e '/^[   \f]*$/d' > junk2.c
3146   cat junk1.c junk2.c > Makefile.new
3147   rm -f junk.c junk1.c junk2.c
3148   chmod 444 Makefile.new
3149   mv -f Makefile.new Makefile
3150 )
3151
3152 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
3153   echo creating src/.gdbinit
3154   echo source $srcdir/src/.gdbinit > src/.gdbinit
3155 fi
3156
3157 # This is how we know whether to re-run configure in certain cases.
3158 touch src/config.stamp
3159
3160 ], [GCC="$GCC" NON_GNU_CPP="$NON_GNU_CPP" CPP="$CPP" CPP_NEED_TRADITIONAL="$CPP_NEED_TRADITIONAL" CPPFLAGS="$CPPFLAGS"])
3161
3162 m4_if(dnl       Do not change this comment
3163    arch-tag: 156a4dd5-bddc-4d18-96ac-f37742cf6a5e
3164 )dnl