code.delx.au - gnu-emacs/blob - lisp/avoid.el

   1 ;;; avoid.el --- make mouse pointer stay out of the way of editing
   2
   3 ;; Copyright (C) 1993, 1994, 2000, 2002, 2003, 2004,
   4 ;;   2005, 2006 Free Software Foundation, Inc.
   5
   6 ;; Author: Boris Goldowsky <boris@gnu.org>
   7 ;; Keywords: mouse
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 ;; Boston, MA 02110-1301, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; For those who are annoyed by the mouse pointer obscuring text,
  29 ;; this mode moves the mouse pointer - either just a little out of
  30 ;; the way, or all the way to the corner of the frame.
  31 ;; To use, load or evaluate this file and type M-x mouse-avoidance-mode .
  32 ;; To set up permanently, put the following in your .emacs:
  33 ;;
  34 ;; (if (display-mouse-p) (mouse-avoidance-mode 'animate))
  35 ;;
  36 ;; Other legitimate alternatives include
  37 ;; `banish', `exile', `jump', `cat-and-mouse', and `proteus'.
  38 ;; They do somewhat different things.
  39 ;; See the documentation for function `mouse-avoidance-mode' for
  40 ;; details of the different modes.
  41 ;;
  42 ;; For added silliness, make the animatee animate...
  43 ;; put something similar to the following into your .emacs:
  44 ;;
  45 ;; (if (eq window-system 'x)
  46 ;;     (mouse-avoidance-set-pointer-shape
  47 ;;           (eval (nth (random 4)
  48 ;;                      '(x-pointer-man x-pointer-spider
  49 ;;                        x-pointer-gobbler x-pointer-gumby)))))
  50 ;;
  51 ;; For completely random pointer shape, replace the setq above with:
  52 ;; (setq x-pointer-shape (mouse-avoidance-random-shape))
  53 ;;
  54 ;; Bugs / Warnings / To-Do:
  55 ;;
  56 ;; - Using this code does slow Emacs down.  "banish" mode shouldn't
  57 ;;   be too bad, and on my workstation even "animate" is reasonable.
  58 ;;
  59 ;; - It ought to find out where any overlapping frames are and avoid them,
  60 ;;   rather than always raising the frame.
  61
  62 ;; Credits:
  63 ;; This code was helped by all those who contributed suggestions,
  64 ;;   fixes, and additions
  65 ;; Joe Harrington (and his advisor), for the original inspiration.
  66 ;; Ken Manheimer, for dreaming up the Protean mode.
  67 ;; Richard Stallman, for the awful cat-and-mouse pun, among other things.
  68 ;; Mike Williams, Denis Howe, Bill Benedetto, Chris Moore, Don Morris,
  69 ;; Simon Marshall, and M.S. Ashton, for their feedback.
  70
  71 ;;; Code:
  72
  73 (provide 'avoid)
  74
  75 (defgroup avoid nil
  76   "Make mouse pointer stay out of the way of editing."
  77   :prefix "mouse-avoidance-"
  78   :group 'mouse)
  79
  80 ;;;###autoload
  81 (defcustom mouse-avoidance-mode nil
  82   "Activate mouse avoidance mode.
  83 See function `mouse-avoidance-mode' for possible values.
  84 Setting this variable directly does not take effect;
  85 use either \\[customize] or the function `mouse-avoidance-mode'."
  86   :set (lambda (symbol value)
  87          ;; 'none below prevents toggling when value is nil.
  88          (mouse-avoidance-mode (or value 'none)))
  89   :initialize 'custom-initialize-default
  90   :type '(choice (const :tag "none" nil) (const banish) (const jump)
  91                  (const animate) (const exile) (const proteus)
  92                  )
  93   :group 'avoid
  94   :require 'avoid
  95   :version "20.3")
  96
  97
  98 (defcustom mouse-avoidance-nudge-dist 15
  99   "*Average distance that mouse will be moved when approached by cursor.
 100 Only applies in Mouse-Avoidance mode `jump' and its derivatives.
 101 For best results make this larger than `mouse-avoidance-threshold'."
 102   :type 'integer
 103   :group 'avoid)
 104
 105 (defcustom mouse-avoidance-nudge-var 10
 106   "*Variability of `mouse-avoidance-nudge-dist' (which see)."
 107   :type 'integer
 108   :group 'avoid)
 109
 110 (defcustom mouse-avoidance-animation-delay .01
 111   "Delay between animation steps, in seconds."
 112   :type 'number
 113   :group 'avoid)
 114
 115 (defcustom mouse-avoidance-threshold 5
 116   "*Mouse-pointer's flight distance.
 117 If the cursor gets closer than this, the mouse pointer will move away.
 118 Only applies in mouse-avoidance-modes `animate' and `jump'."
 119   :type 'integer
 120   :group 'avoid)
 121
 122 ;; Internal variables
 123 (defvar mouse-avoidance-state nil)
 124 (defvar mouse-avoidance-pointer-shapes nil)
 125 (defvar mouse-avoidance-n-pointer-shapes 0)
 126 (defvar mouse-avoidance-old-pointer-shape nil)
 127
 128 ;; This timer is used to run something when Emacs is idle.
 129 (defvar mouse-avoidance-timer nil)
 130
 131 ;;; Functions:
 132
 133 (defsubst mouse-avoidance-set-pointer-shape (shape)
 134   "Set the shape of the mouse pointer to SHAPE."
 135   (when (boundp 'x-pointer-shape)
 136     (setq x-pointer-shape shape)
 137     (set-mouse-color nil)))
 138
 139 (defun mouse-avoidance-point-position ()
 140   "Return the position of point as (FRAME X . Y).
 141 Analogous to `mouse-position'."
 142   (let* ((w (selected-window))
 143          (edges (window-inside-edges w))
 144          (list
 145           (compute-motion (max (window-start w) (point-min))   ; start pos
 146                           ;; window-start can be < point-min if the
 147                           ;; latter has changed since the last redisplay
 148                           '(0 . 0)                             ; start XY
 149                           (point)                              ; stop pos
 150                           nil                                  ; stop XY: none
 151                           nil                                  ; width
 152                           (cons (window-hscroll w) 0)          ; 0 may not be right?
 153                           (selected-window))))
 154     ;; compute-motion returns (pos HPOS VPOS prevhpos contin)
 155     ;; we want:               (frame hpos . vpos)
 156     (cons (selected-frame)
 157           (cons (+ (car edges)       (car (cdr list)))
 158                 (+ (car (cdr edges)) (car (cdr (cdr list))))))))
 159
 160 ;(defun mouse-avoidance-point-position-test ()
 161 ;  (interactive)
 162 ;  (message (format "point=%s mouse=%s"
 163 ;                  (cdr (mouse-avoidance-point-position))
 164 ;                  (cdr (mouse-position)))))
 165
 166 (defun mouse-avoidance-set-mouse-position (pos)
 167   ;; Carefully set mouse position to given position (X . Y)
 168   ;; Ideally, should check if X,Y is in the current frame, and if not,
 169   ;; leave the mouse where it was.  However, this is currently
 170   ;; difficult to do, so we just raise the frame to avoid frame switches.
 171   ;; Returns t if it moved the mouse.
 172   (let ((f (selected-frame)))
 173     (raise-frame f)
 174     (set-mouse-position f (car pos) (cdr pos))
 175     t))
 176
 177 (defun mouse-avoidance-too-close-p (mouse)
 178   "Return t if mouse pointer and point cursor are too close.
 179 MOUSE is the current mouse position as returned by `mouse-position'.
 180 Acceptable distance is defined by `mouse-avoidance-threshold'."
 181   (let* ((frame (car mouse))
 182          (mouse-y (cdr (cdr mouse)))
 183          (tool-bar-lines (frame-parameter nil 'tool-bar-lines)))
 184     (or tool-bar-lines
 185         (setq tool-bar-lines 0))
 186     (if (and mouse-y (< mouse-y tool-bar-lines))
 187         nil
 188       (let ((point (mouse-avoidance-point-position))
 189             (mouse-x (car (cdr mouse))))
 190         (and (eq frame (car point))
 191              (not (null mouse-x))
 192              (< (abs (- mouse-x (car (cdr point))))
 193                 mouse-avoidance-threshold)
 194              (< (abs (- mouse-y (cdr (cdr point))))
 195                 mouse-avoidance-threshold))))))
 196
 197 (defun mouse-avoidance-banish-destination ()
 198   "The position to which Mouse-Avoidance mode `banish' moves the mouse.
 199 You can redefine this if you want the mouse banished to a different corner."
 200   (let* ((pos (window-edges)))
 201     (cons (- (nth 2 pos) 2)
 202           (nth 1 pos))))
 203
 204 (defun mouse-avoidance-banish-mouse ()
 205   ;; Put the mouse pointer in the upper-right corner of the current frame.
 206   (mouse-avoidance-set-mouse-position (mouse-avoidance-banish-destination)))
 207
 208 (defsubst mouse-avoidance-delta (cur delta dist var min max)
 209   ;; Decide how far to move in either dimension.
 210   ;; Args are the CURRENT location, the desired DELTA for
 211   ;; warp-conservation, the DISTANCE we like to move, the VARIABILITY
 212   ;; in distance allowed, and the MIN and MAX possible window positions.
 213   ;; Returns something as close to DELTA as possible within the constraints.
 214   (let ((L1 (max (- min cur) (+ (- dist) (- var))))
 215         (R1                  (+ (- dist)    var ))
 216         (L2                  (+    dist  (- var)))
 217         (R2 (min (- max cur) (+    dist     var))))
 218     (if (< R1 (- min cur)) (setq L1 nil R1 nil))
 219     (if (> L2 (- max cur)) (setq L2 nil R2 nil))
 220     (cond ((and L1 (< delta L1)) L1)
 221           ((and R1 (< delta R1)) delta)
 222           ((and R1 (< delta 0)) R1)
 223           ((and L2 (< delta L2)) L2)
 224           ((and R2 (< delta R2)) delta)
 225           (R2)
 226           ((or R1 L2))
 227           (t 0))))
 228
 229 (defun mouse-avoidance-nudge-mouse ()
 230   ;; Push the mouse a little way away, possibly animating the move.
 231   ;; For these modes, state keeps track of the total offset that we've
 232   ;; accumulated, and tries to keep it close to zero.
 233   (let* ((cur (mouse-position))
 234          (cur-frame (car cur))
 235          (cur-pos (cdr cur))
 236          (pos (window-edges))
 237          (wleft (pop pos))
 238          (wtop (pop pos))
 239          (wright (pop pos))
 240          (wbot (pop pos))
 241          (deltax (mouse-avoidance-delta
 242                   (car cur-pos) (- (random mouse-avoidance-nudge-var)
 243                                    (car mouse-avoidance-state))
 244                   mouse-avoidance-nudge-dist mouse-avoidance-nudge-var
 245                   wleft (1- wright)))
 246          (deltay (mouse-avoidance-delta
 247                   (cdr cur-pos) (- (random mouse-avoidance-nudge-var)
 248                                    (cdr mouse-avoidance-state))
 249                   mouse-avoidance-nudge-dist mouse-avoidance-nudge-var
 250                   wtop (1- wbot))))
 251     (setq mouse-avoidance-state
 252           (cons (+ (car mouse-avoidance-state) deltax)
 253                 (+ (cdr mouse-avoidance-state) deltay)))
 254     (if (or (eq mouse-avoidance-mode 'animate)
 255             (eq mouse-avoidance-mode 'proteus))
 256         (let ((i 0.0))
 257           (while (<= i 1)
 258             (mouse-avoidance-set-mouse-position
 259              (cons (+ (car cur-pos) (round (* i deltax)))
 260                    (+ (cdr cur-pos) (round (* i deltay)))))
 261             (setq i (+ i (max .1 (/ 1.0 mouse-avoidance-nudge-dist))))
 262             (if (eq mouse-avoidance-mode 'proteus)
 263                 (mouse-avoidance-set-pointer-shape
 264                  (mouse-avoidance-random-shape)))
 265             (sit-for mouse-avoidance-animation-delay)))
 266       (mouse-avoidance-set-mouse-position (cons (+ (car (cdr cur)) deltax)
 267                                                 (+ (cdr (cdr cur)) deltay))))))
 268
 269 (defun mouse-avoidance-random-shape ()
 270   "Return a random cursor shape.
 271 This assumes that any variable whose name begins with x-pointer- and
 272 has an integer value is a valid cursor shape.  You might want to
 273 redefine this function to suit your own tastes."
 274   (if (null mouse-avoidance-pointer-shapes)
 275       (progn
 276         (setq mouse-avoidance-pointer-shapes
 277               (mapcar (lambda (x) (symbol-value (intern x)))
 278                       (all-completions "x-pointer-" obarray
 279                                        (lambda (x)
 280                                           (and (boundp x)
 281                                                (integerp (symbol-value x)))))))
 282         (setq mouse-avoidance-n-pointer-shapes
 283               (length mouse-avoidance-pointer-shapes))))
 284   (nth (random mouse-avoidance-n-pointer-shapes)
 285        mouse-avoidance-pointer-shapes))
 286
 287 (defun mouse-avoidance-ignore-p ()
 288   (let ((mp (mouse-position)))
 289     (or executing-kbd-macro            ; don't check inside macro
 290         (null (cadr mp))               ; don't move unless in an Emacs frame
 291         (not (eq (car mp) (selected-frame)))
 292         ;; Don't do anything if last event was a mouse event.
 293         ;; FIXME: this code fails in the case where the mouse was moved
 294         ;; since the last key-press but without generating any event.
 295         (and (consp last-input-event)
 296              (symbolp (car last-input-event))
 297              (let ((modifiers (event-modifiers (car last-input-event))))
 298                (or (memq (car last-input-event)
 299                          '(mouse-movement scroll-bar-movement
 300                            select-window switch-frame))
 301                    (memq 'click modifiers)
 302                    (memq 'double modifiers)
 303                    (memq 'triple modifiers)
 304                    (memq 'drag modifiers)
 305                    (memq 'down modifiers)))))))
 306
 307 (defun mouse-avoidance-banish-hook ()
 308   (if (not (mouse-avoidance-ignore-p))
 309       (mouse-avoidance-banish-mouse)))
 310
 311 (defun mouse-avoidance-exile-hook ()
 312   ;; For exile mode, the state is nil when the mouse is in its normal
 313   ;; position, and set to the old mouse-position when the mouse is in exile.
 314   (if (not (mouse-avoidance-ignore-p))
 315       (let ((mp (mouse-position)))
 316         (cond ((and (not mouse-avoidance-state)
 317                     (mouse-avoidance-too-close-p mp))
 318                (setq mouse-avoidance-state mp)
 319                (mouse-avoidance-banish-mouse))
 320               ((and mouse-avoidance-state
 321                     (not (mouse-avoidance-too-close-p mouse-avoidance-state)))
 322                (if (and (eq (car mp) (selected-frame))
 323                         (equal (cdr mp) (mouse-avoidance-banish-destination)))
 324                    (mouse-avoidance-set-mouse-position
 325                     ;; move back only if user has not moved mouse
 326                     (cdr mouse-avoidance-state)))
 327                ;; but clear state anyway, to be ready for another move
 328                (setq mouse-avoidance-state nil))))))
 329
 330 (defun mouse-avoidance-fancy-hook ()
 331   ;; Used for the "fancy" modes, ie jump et al.
 332   (if (and (not (mouse-avoidance-ignore-p))
 333            (mouse-avoidance-too-close-p (mouse-position)))
 334       (let ((old-pos (mouse-position)))
 335         (mouse-avoidance-nudge-mouse)
 336         (if (not (eq (selected-frame) (car old-pos)))
 337             ;; This should never happen.
 338             (apply 'set-mouse-position old-pos)))))
 339
 340 ;;;###autoload
 341 (defun mouse-avoidance-mode (&optional mode)
 342   "Set cursor avoidance mode to MODE.
 343 MODE should be one of the symbols `banish', `exile', `jump', `animate',
 344 `cat-and-mouse', `proteus', or `none'.
 345
 346 If MODE is nil, toggle mouse avoidance between `none' and `banish'
 347 modes.  Positive numbers and symbols other than the above are treated
 348 as equivalent to `banish'; negative numbers and `-' are equivalent to `none'.
 349
 350 Effects of the different modes:
 351  * banish: Move the mouse to the upper-right corner on any keypress.
 352  * exile: Move the mouse to the corner only if the cursor gets too close,
 353      and allow it to return once the cursor is out of the way.
 354  * jump: If the cursor gets too close to the mouse, displace the mouse
 355      a random distance & direction.
 356  * animate: As `jump', but shows steps along the way for illusion of motion.
 357  * cat-and-mouse: Same as `animate'.
 358  * proteus: As `animate', but changes the shape of the mouse pointer too.
 359
 360 Whenever the mouse is moved, the frame is also raised.
 361
 362 \(see `mouse-avoidance-threshold' for definition of \"too close\",
 363 and `mouse-avoidance-nudge-dist' and `mouse-avoidance-nudge-var' for
 364 definition of \"random distance\".)"
 365   (interactive
 366    (list (intern (completing-read
 367                   "Select cursor avoidance technique (SPACE for list): "
 368                   '(("banish") ("exile") ("jump") ("animate")
 369                     ("cat-and-mouse") ("proteus") ("none"))
 370                   nil t))))
 371   (if (eq mode 'cat-and-mouse)
 372       (setq mode 'animate))
 373   (if mouse-avoidance-timer
 374       (cancel-timer mouse-avoidance-timer))
 375   (setq mouse-avoidance-timer nil)
 376
 377   ;; Restore pointer shape if necessary
 378   (if (eq mouse-avoidance-mode 'proteus)
 379       (mouse-avoidance-set-pointer-shape mouse-avoidance-old-pointer-shape))
 380
 381   ;; Do additional setup depending on version of mode requested
 382   (cond ((eq mode 'none)
 383          (setq mouse-avoidance-mode nil))
 384         ((or (eq mode 'jump)
 385              (eq mode 'animate)
 386              (eq mode 'proteus))
 387          (setq mouse-avoidance-timer
 388                (run-with-idle-timer 0.1 t 'mouse-avoidance-fancy-hook))
 389          (setq mouse-avoidance-mode mode
 390                mouse-avoidance-state (cons 0 0)
 391                mouse-avoidance-old-pointer-shape
 392                (and (boundp 'x-pointer-shape) x-pointer-shape)))
 393         ((eq mode 'exile)
 394          (setq mouse-avoidance-timer
 395                (run-with-idle-timer 0.1 t 'mouse-avoidance-exile-hook))
 396          (setq mouse-avoidance-mode mode
 397                mouse-avoidance-state nil))
 398         ((or (eq mode 'banish)
 399              (eq mode t)
 400              (and (null mode) (null mouse-avoidance-mode))
 401              (and mode (> (prefix-numeric-value mode) 0)))
 402          (setq mouse-avoidance-timer
 403                (run-with-idle-timer 0.1 t 'mouse-avoidance-banish-hook))
 404          (setq mouse-avoidance-mode 'banish))
 405         (t (setq mouse-avoidance-mode nil)))
 406   (force-mode-line-update))
 407
 408 ;; Most people who use avoid mode leave it on all the time, so it's not
 409 ;; very informative to announce it in the mode line.
 410 ;;(or (assq 'mouse-avoidance-mode minor-mode-alist)
 411 ;;    (setq minor-mode-alist (cons '(mouse-avoidance-mode " Avoid")
 412 ;;                               minor-mode-alist)))
 413
 414 ;; Needed for custom.
 415 (if mouse-avoidance-mode
 416     (mouse-avoidance-mode mouse-avoidance-mode))
 417
 418 ;; arch-tag: 64ad4ef8-a870-4183-8d96-3aa93b7a6800
 419 ;;; avoid.el ends here