code.delx.au - gnu-emacs/blob - lisp/compare-w.el

   1 ;;; compare-w.el --- compare text between windows for Emacs
   2
   3 ;; Copyright (C) 1986, 1989, 1993, 1997, 2002, 2003, 2004,
   4 ;;   2005, 2006 Free Software Foundation, Inc.
   5
   6 ;; Maintainer: FSF
   7 ;; Keywords: convenience files
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 ;; Boston, MA 02110-1301, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; This package provides one entry point, compare-windows.  It compares
  29 ;; text starting from point in two adjacent windows, advancing point
  30 ;; until it finds a difference.  Option variables permit you to ignore
  31 ;; whitespace differences, or case differences, or both.
  32
  33 ;;; Code:
  34
  35 (defgroup compare-w nil
  36   "Compare text between windows."
  37   :prefix "compare-"
  38   :group 'tools)
  39
  40 (defcustom compare-windows-whitespace "\\(\\s-\\|\n\\)+"
  41   "*Regexp or function that defines whitespace sequences for `compare-windows'.
  42 That command optionally ignores changes in whitespace.
  43
  44 The value of `compare-windows-whitespace' is normally a regexp, but it
  45 can also be a function.  The function's job is to categorize any
  46 whitespace around (including before) point; it should also advance
  47 past any whitespace.  The function is called in each window, with
  48 point at the current scanning point.  It gets one argument, the point
  49 where \\[compare-windows] was originally called; it should not look at
  50 any text before that point.
  51
  52 If the function returns the same value for both windows, then the
  53 whitespace is considered to match, and is skipped."
  54   :type '(choice regexp function)
  55   :group 'compare-w)
  56
  57 (defcustom compare-ignore-whitespace nil
  58   "*Non-nil means `compare-windows' ignores whitespace."
  59   :type 'boolean
  60   :group 'compare-w
  61   :version "22.1")
  62
  63 (defcustom compare-ignore-case nil
  64   "*Non-nil means `compare-windows' ignores case differences."
  65   :type 'boolean
  66   :group 'compare-w)
  67
  68 (defcustom compare-windows-sync 'compare-windows-sync-default-function
  69   "*Function or regexp that is used to synchronize points in two
  70 windows if before calling `compare-windows' points are located
  71 on mismatched positions.
  72
  73 The value of `compare-windows-sync' can be a function.  The
  74 function's job is to advance points in both windows to the next
  75 matching text.  If the value of `compare-windows-sync' is a
  76 regexp, then points in both windows are advanced to the next
  77 occurrence of this regexp.
  78
  79 The current default value is the general function
  80 `compare-windows-sync-default-function' that is able to
  81 synchronize points by using quadratic algorithm to find the first
  82 matching 32-character string in two windows.
  83
  84 The other useful values of this variable could be such functions
  85 as `forward-word', `forward-sentence', `forward-paragraph', or a
  86 regexp containing some field separator or a newline, depending on
  87 the nature of the difference units separator.  The variable can
  88 be made buffer-local.
  89
  90 If the value of this variable is `nil', then function `ding' is
  91 called to beep or flash the screen when points are mismatched."
  92   :type '(choice regexp function)
  93   :group 'compare-w
  94   :version "22.1")
  95
  96 (defcustom compare-windows-sync-string-size 32
  97   "*Size of string from one window that is searched in second window.
  98
  99 Small number makes difference regions more fine-grained, but it
 100 may fail by finding the wrong match.  The bigger number makes
 101 difference regions more coarse-grained.
 102
 103 The default value 32 is good for the most cases."
 104   :type 'integer
 105   :group 'compare-w
 106   :version "22.1")
 107
 108 (defcustom compare-windows-recenter nil
 109   "*List of two values, each of which is used as argument of
 110 function `recenter' called in each of two windows to place
 111 matching points side-by-side.
 112
 113 The value `(-1 0)' is useful if windows are split vertically,
 114 and the value `((4) (4))' for horizontally split windows."
 115   :type '(list sexp sexp)
 116   :group 'compare-w
 117   :version "22.1")
 118
 119 (defcustom compare-windows-highlight t
 120   "*Non-nil means compare-windows highlights the differences.
 121 The value t removes highlighting immediately after invoking a command
 122 other than `compare-windows'.
 123 The value `persistent' leaves all highlighted differences.  You can clear
 124 out all highlighting later with the command `compare-windows-dehighlight'."
 125   :type '(choice (const :tag "No highlighting" nil)
 126                  (const :tag "Persistent highlighting" persistent)
 127                  (other :tag "Highlight until next command" t))
 128   :group 'compare-w
 129   :version "22.1")
 130
 131 (defface compare-windows
 132   '((t :inherit lazy-highlight))
 133   "Face for highlighting of compare-windows difference regions."
 134   :group 'compare-w
 135   :version "22.1")
 136
 137 (defvar compare-windows-overlay1 nil)
 138 (defvar compare-windows-overlay2 nil)
 139 (defvar compare-windows-overlays1 nil)
 140 (defvar compare-windows-overlays2 nil)
 141 (defvar compare-windows-sync-point nil)
 142
 143 ;;;###autoload
 144 (defun compare-windows (ignore-whitespace)
 145   "Compare text in current window with text in next window.
 146 Compares the text starting at point in each window,
 147 moving over text in each one as far as they match.
 148
 149 This command pushes the mark in each window
 150 at the prior location of point in that window.
 151 If both windows display the same buffer,
 152 the mark is pushed twice in that buffer:
 153 first in the other window, then in the selected window.
 154
 155 A prefix arg means reverse the value of variable
 156 `compare-ignore-whitespace'.  If `compare-ignore-whitespace' is
 157 nil, then a prefix arg means ignore changes in whitespace.  If
 158 `compare-ignore-whitespace' is non-nil, then a prefix arg means
 159 don't ignore changes in whitespace.  The variable
 160 `compare-windows-whitespace' controls how whitespace is skipped.
 161 If `compare-ignore-case' is non-nil, changes in case are also
 162 ignored.
 163
 164 If `compare-windows-sync' is non-nil, then successive calls of
 165 this command work in interlaced mode:
 166 on first call it advances points to the next difference,
 167 on second call it synchronizes points by skipping the difference,
 168 on third call it again advances points to the next difference and so on."
 169   (interactive "P")
 170   (let* (p1 p2 maxp1 maxp2 b1 b2 w2
 171             (progress 1)
 172             (opoint1 (point))
 173             opoint2
 174             (skip-func (if (if ignore-whitespace ; XOR
 175                                (not compare-ignore-whitespace)
 176                              compare-ignore-whitespace)
 177                            (if (stringp compare-windows-whitespace)
 178                                'compare-windows-skip-whitespace
 179                              compare-windows-whitespace)))
 180             (sync-func (if (stringp compare-windows-sync)
 181                            'compare-windows-sync-regexp
 182                          compare-windows-sync)))
 183     (setq p1 (point) b1 (current-buffer))
 184     (setq w2 (next-window (selected-window)))
 185     (if (eq w2 (selected-window))
 186         (setq w2 (next-window (selected-window) nil 'visible)))
 187     (if (eq w2 (selected-window))
 188         (error "No other window"))
 189     (setq p2 (window-point w2)
 190           b2 (window-buffer w2))
 191     (setq opoint2 p2)
 192     (setq maxp1 (point-max))
 193     (save-excursion
 194       (set-buffer b2)
 195       (push-mark p2 t)
 196       (setq maxp2 (point-max)))
 197     (push-mark)
 198
 199     (while (> progress 0)
 200       ;; If both windows have whitespace next to point,
 201       ;; optionally skip over it.
 202       (and skip-func
 203            (save-excursion
 204              (let (p1a p2a w1 w2 result1 result2)
 205                (setq result1 (funcall skip-func opoint1))
 206                (setq p1a (point))
 207                (set-buffer b2)
 208                (goto-char p2)
 209                (setq result2 (funcall skip-func opoint2))
 210                (setq p2a (point))
 211                (if (or (stringp compare-windows-whitespace)
 212                        (and result1 result2 (eq result1 result2)))
 213                    (setq p1 p1a
 214                          p2 p2a)))))
 215
 216       (let ((size (min (- maxp1 p1) (- maxp2 p2)))
 217             (case-fold-search compare-ignore-case))
 218         (setq progress (compare-buffer-substrings b2 p2 (+ size p2)
 219                                                   b1 p1 (+ size p1)))
 220         (setq progress (if (zerop progress) size (1- (abs progress))))
 221         (setq p1 (+ p1 progress) p2 (+ p2 progress)))
 222       ;; Advance point now rather than later, in case we're interrupted.
 223       (goto-char p1)
 224       (set-window-point w2 p2)
 225       (when compare-windows-recenter
 226         (recenter (car compare-windows-recenter))
 227         (with-selected-window w2 (recenter (cadr compare-windows-recenter)))))
 228
 229     (if (= (point) opoint1)
 230         (if (not sync-func)
 231             (ding)
 232           ;; If points are not advanced (i.e. already on mismatch position),
 233           ;; then synchronize points between both windows
 234           (save-excursion
 235             (setq compare-windows-sync-point nil)
 236             (funcall sync-func)
 237             (setq p1 (point))
 238             (set-buffer b2)
 239             (goto-char p2)
 240             (funcall sync-func)
 241             (setq p2 (point)))
 242           (goto-char p1)
 243           (set-window-point w2 p2)
 244           (when compare-windows-recenter
 245             (recenter (car compare-windows-recenter))
 246             (with-selected-window w2 (recenter (cadr compare-windows-recenter))))
 247           ;; If points are still not synchronized, then ding
 248           (when (and (= p1 opoint1) (= p2 opoint2))
 249             ;; Display error message when current points in two windows
 250             ;; are unmatched and next matching points can't be found.
 251             (compare-windows-dehighlight)
 252             (ding)
 253             (message "No more matching points"))))))
 254
 255 ;; Move forward over whatever might be called whitespace.
 256 ;; compare-windows-whitespace is a regexp that matches whitespace.
 257 ;; Match it at various starting points before the original point
 258 ;; and find the latest point at which a match ends.
 259 ;; Don't try starting points before START, though.
 260 ;; Value is non-nil if whitespace is found.
 261 ;; If there is whitespace before point, but none after,
 262 ;; then return t, but don't advance point.
 263 (defun compare-windows-skip-whitespace (start)
 264   (let ((end (point))
 265         (beg (point))
 266         (opoint (point)))
 267     (while (or (and (looking-at compare-windows-whitespace)
 268                     (<= end (match-end 0))
 269                     ;; This match goes past END, so advance END.
 270                     (progn (setq end (match-end 0))
 271                            (> (point) start)))
 272                (and (/= (point) start)
 273                     ;; Consider at least the char before point,
 274                     ;; unless it is also before START.
 275                     (= (point) opoint)))
 276       ;; keep going back until whitespace
 277       ;; doesn't extend to or past end
 278       (forward-char -1))
 279     (setq beg (point))
 280     (goto-char end)
 281     (or (/= beg opoint)
 282         (/= end opoint))))
 283
 284 ;; Move forward to the next synchronization regexp.
 285 (defun compare-windows-sync-regexp ()
 286   (if (stringp compare-windows-sync)
 287       (re-search-forward compare-windows-sync nil t)))
 288
 289 ;; Function works in two passes: one call on each window.
 290 ;; On the first call both matching points are computed,
 291 ;; and one of them is stored in compare-windows-sync-point
 292 ;; to be used when this function is called on second window.
 293 (defun compare-windows-sync-default-function ()
 294   (if (not compare-windows-sync-point)
 295       (let* ((w1 (selected-window))
 296              (w2 (next-window w1))
 297              (b2 (window-buffer w2))
 298              (point-max2 (with-current-buffer b2 (point-max)))
 299              (op2 (window-point w2))
 300              (op1 (point))
 301              (region-size compare-windows-sync-string-size)
 302              (string-size compare-windows-sync-string-size)
 303              in-bounds-p s1 p2 p12s p12)
 304         (while (and
 305                 ;; until matching points are found
 306                 (not p12s)
 307                 ;; until size exceeds the maximum points of both buffers
 308                 ;; (bounds below take care to not overdo in each of them)
 309                 (or (setq in-bounds-p (< region-size (max (- (point-max) op1)
 310                                                           (- point-max2 op2))))
 311                     ;; until string size becomes smaller than 4
 312                     (> string-size 4)))
 313           (if in-bounds-p
 314               ;; make the next search in the double-sized region;
 315               ;; on first iteration it is 2*compare-windows-sync-string-size,
 316               ;; on last iterations it exceeds both buffers maximum points
 317               (setq region-size (* region-size 2))
 318             ;; if region size exceeds the maximum points of both buffers,
 319             ;; then start to halve the string size until 4;
 320             ;; this helps to find differences near the end of buffers
 321             (setq string-size (/ string-size 2)))
 322           (let ((p1 op1)
 323                 (bound1 (- (min (+ op1 region-size) (point-max)) string-size))
 324                 (bound2 (min (+ op2 region-size) point-max2)))
 325             (while (< p1 bound1)
 326               (setq s1 (buffer-substring-no-properties p1 (+ p1 string-size)))
 327               (setq p2 (with-current-buffer b2
 328                          (goto-char op2)
 329                          (let ((case-fold-search compare-ignore-case))
 330                            (search-forward s1 bound2 t))))
 331               (when p2
 332                 (setq p2 (- p2 string-size))
 333                 (setq p12s (cons (list (+ p1 p2) p1 p2) p12s)))
 334               (setq p1 (1+ p1)))))
 335         (when p12s
 336           ;; use closest matching points (i.e. points with minimal sum)
 337           (setq p12 (cdr (assq (apply 'min (mapcar 'car p12s)) p12s)))
 338           (goto-char (car p12))
 339           (compare-windows-highlight op1 (car p12) (current-buffer) w1
 340                                      op2 (cadr p12) b2 w2))
 341         (setq compare-windows-sync-point (or (cadr p12) t)))
 342     ;; else set point in the second window to the pre-calculated value
 343     (if (numberp compare-windows-sync-point)
 344         (goto-char compare-windows-sync-point))
 345     (setq compare-windows-sync-point nil)))
 346
 347 ;; Highlight differences
 348 (defun compare-windows-highlight (beg1 end1 b1 w1 beg2 end2 b2 w2)
 349   (when compare-windows-highlight
 350     (if compare-windows-overlay1
 351         (move-overlay compare-windows-overlay1 beg1 end1 b1)
 352       (setq compare-windows-overlay1 (make-overlay beg1 end1 b1))
 353       (overlay-put compare-windows-overlay1 'face 'compare-windows)
 354       (overlay-put compare-windows-overlay1 'priority 1000))
 355     (overlay-put compare-windows-overlay1 'window w1)
 356     (if compare-windows-overlay2
 357         (move-overlay compare-windows-overlay2 beg2 end2 b2)
 358       (setq compare-windows-overlay2 (make-overlay beg2 end2 b2))
 359       (overlay-put compare-windows-overlay2 'face 'compare-windows)
 360       (overlay-put compare-windows-overlay2 'priority 1000))
 361     (overlay-put compare-windows-overlay2 'window w2)
 362     (if (not (eq compare-windows-highlight 'persistent))
 363         ;; Remove highlighting before next command is executed
 364         (add-hook 'pre-command-hook 'compare-windows-dehighlight)
 365       (when compare-windows-overlay1
 366         (push (copy-overlay compare-windows-overlay1) compare-windows-overlays1)
 367         (delete-overlay compare-windows-overlay1))
 368       (when compare-windows-overlay2
 369         (push (copy-overlay compare-windows-overlay2) compare-windows-overlays2)
 370         (delete-overlay compare-windows-overlay2)))))
 371
 372 (defun compare-windows-dehighlight ()
 373   "Remove highlighting created by `compare-windows-highlight'."
 374   (interactive)
 375   (remove-hook 'pre-command-hook 'compare-windows-dehighlight)
 376   (mapc 'delete-overlay compare-windows-overlays1)
 377   (mapc 'delete-overlay compare-windows-overlays2)
 378   (and compare-windows-overlay1 (delete-overlay compare-windows-overlay1))
 379   (and compare-windows-overlay2 (delete-overlay compare-windows-overlay2)))
 380
 381 (provide 'compare-w)
 382
 383 ;;; arch-tag: 4177aab1-48e6-4a98-b7a1-000ee285de46
 384 ;;; compare-w.el ends here