code.delx.au - gnu-emacs/blob - lisp/dirtrack.el

   1 ;;; dirtrack.el --- Directory Tracking by watching the prompt
   2
   3 ;; Copyright (C) 1996, 2002, 2003, 2004, 2005,
   4 ;;   2006 Free Software Foundation, Inc.
   5
   6 ;; Author: Peter Breton <pbreton@cs.umb.edu>
   7 ;; Created: Sun Nov 17 1996
   8 ;; Keywords: processes
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  25 ;; Boston, MA 02110-1301, USA.
  26
  27 ;;; Commentary:
  28
  29 ;; Shell directory tracking by watching the prompt.
  30 ;;
  31 ;; This is yet another attempt at a directory-tracking package for
  32 ;; Emacs shell-mode. However, this package makes one strong assumption:
  33 ;; that you can customize your shell's prompt to contain the
  34 ;; current working directory. Most shells do support this, including
  35 ;; almost every type of Bourne and C shell on Unix, the native shells on
  36 ;; Windows95 (COMMAND.COM) and Windows NT (CMD.EXE), and most 3rd party
  37 ;; Windows shells. If you cannot do this, or do not wish to, this package
  38 ;; will be useless to you.
  39 ;;
  40 ;; Installation:
  41 ;;
  42 ;; 1) Set your shell's prompt to contain the current working directory.
  43 ;; You may need to consult your shell's documentation to find out how to
  44 ;; do this.
  45 ;;
  46 ;; Note that directory tracking is done by matching regular expressions,
  47 ;; therefore it is *VERY IMPORTANT* for your prompt to be easily
  48 ;; distinguishable from other output. If your prompt regexp is too general,
  49 ;; you will see error messages from the dirtrack filter as it attempts to cd
  50 ;; to non-existent directories.
  51 ;;
  52 ;; 2) Set the variable `dirtrack-list' to an appropriate value. This
  53 ;; should be a list of two elements: the first is a regular expression
  54 ;; which matches your prompt up to and including the pathname part.
  55 ;; The second is a number which tells which regular expression group to
  56 ;; match to extract only the pathname. If you use a multi-line prompt,
  57 ;; add 't' as a third element. Note that some of the functions in
  58 ;; 'comint.el' assume a single-line prompt (eg, comint-bol).
  59 ;;
  60 ;; Determining this information may take some experimentation. Setting
  61 ;; the variable `dirtrack-debug' may help; it causes the directory-tracking
  62 ;; filter to log messages to the buffer `dirtrack-debug-buffer'. You can easily
  63 ;; toggle this setting with the `dirtrack-debug-toggle' function.
  64 ;;
  65 ;; 3) Add a hook to shell-mode to enable the directory tracking:
  66 ;;
  67 ;; (add-hook 'shell-mode-hook
  68 ;;   (function (lambda ()
  69 ;;            (setq comint-preoutput-filter-functions
  70 ;;                  (append (list 'dirtrack)
  71 ;;                          comint-preoutput-filter-functions)))))
  72 ;;
  73 ;; You may wish to turn ordinary shell tracking off by calling
  74 ;; `shell-dirtrack-toggle' or setting `shell-dirtrackp'.
  75 ;;
  76 ;; Examples:
  77 ;;
  78 ;; 1) On Windows NT, my prompt is set to emacs$S$P$G.
  79 ;; 'dirtrack-list' is set to (list "^emacs \\([a-zA-Z]:.*\\)>" 1)
  80 ;;
  81 ;; 2) On Solaris running bash, my prompt is set like this:
  82 ;;    PS1="\w\012emacs@\h(\!) [\t]% "
  83 ;;    'dirtrack-list' is set to (list "^\\([/~].*\\)\nemacs@[^%]+% *" 1 t)
  84 ;;
  85 ;; I'd appreciate other examples from people who use this package.
  86 ;;
  87 ;; Here's one from Stephen Eglen:
  88 ;;
  89 ;;   Running under tcsh:
  90 ;;   (setq-default dirtrack-list '("^%E \\([^ ]+\\)" 1))
  91 ;;
  92 ;;   It might be worth mentioning in your file that emacs sources start up
  93 ;;   files of the form: ~/.emacs_<SHELL> where <SHELL> is the name of the
  94 ;;   shell.  So for example, I have the following in ~/.emacs_tcsh:
  95 ;;
  96 ;;   set prompt = "%%E %~ %h% "
  97 ;;
  98 ;;   This produces a prompt of the form:
  99 ;;   %E /var/spool 10%
 100 ;;
 101 ;;   This saves me from having to use the %E prefix in other non-emacs
 102 ;;   shells.
 103 ;;
 104 ;; A final note:
 105 ;;
 106 ;;   I run LOTS of shell buffers through Emacs, sometimes as different users
 107 ;;   (eg, when logged in as myself, I'll run a root shell in the same Emacs).
 108 ;;   If you do this, and the shell prompt contains a ~, Emacs will interpret
 109 ;;   this relative to the user which owns the Emacs process, not the user
 110 ;;   who owns the shell buffer. This may cause dirtrack to behave strangely
 111 ;;   (typically it reports that it is unable to cd to a directory
 112 ;;   with a ~ in it).
 113 ;;
 114 ;;   The same behavior can occur if you use dirtrack with remote filesystems
 115 ;;   (using telnet, rlogin, etc) as Emacs will be checking the local
 116 ;;   filesystem, not the remote one. This problem is not specific to dirtrack,
 117 ;;   but also affects file completion, etc.
 118
 119 ;;; Code:
 120
 121 (eval-when-compile
 122   (require 'comint)
 123   (require 'shell))
 124
 125 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 126 ;; Customization Variables
 127 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 128
 129 (defgroup dirtrack nil
 130   "Directory tracking by watching the prompt."
 131   :prefix "dirtrack-"
 132   :group 'shell)
 133
 134 (defcustom dirtrack-list (list "^emacs \\([a-zA-Z]:.*\\)>" 1)
 135   "*List for directory tracking.
 136 First item is a regexp that describes where to find the path in a prompt.
 137 Second is a number, the regexp group to match.  Optional third item is
 138 whether the prompt is multi-line.  If nil or omitted, prompt is assumed to
 139 be on a single line."
 140   :group 'dirtrack
 141   :type  '(sexp (regexp  :tag "Prompt Expression")
 142                 (integer :tag "Regexp Group")
 143                 (boolean :tag "Multiline Prompt")
 144                 )
 145   )
 146
 147 (make-variable-buffer-local 'dirtrack-list)
 148
 149 (defcustom dirtrack-debug nil
 150   "*If non-nil, the function `dirtrack' will report debugging info."
 151   :group 'dirtrack
 152   :type  'boolean
 153   )
 154
 155 (defcustom dirtrack-debug-buffer "*Directory Tracking Log*"
 156   "Buffer to write directory tracking debug information."
 157   :group 'dirtrack
 158   :type  'string
 159   )
 160
 161 (defcustom dirtrackp t
 162   "*If non-nil, directory tracking via `dirtrack' is enabled."
 163   :group 'dirtrack
 164   :type  'boolean
 165   )
 166
 167 (make-variable-buffer-local 'dirtrackp)
 168
 169 (defcustom dirtrack-directory-function
 170   (if (memq system-type (list 'ms-dos 'windows-nt 'cygwin))
 171       'dirtrack-windows-directory-function
 172     'dirtrack-default-directory-function)
 173   "*Function to apply to the prompt directory for comparison purposes."
 174   :group 'dirtrack
 175   :type  'function
 176   )
 177
 178 (defcustom dirtrack-canonicalize-function
 179   (if (memq system-type (list 'ms-dos 'windows-nt 'cygwin))
 180       'downcase 'identity)
 181   "*Function to apply to the default directory for comparison purposes."
 182   :group 'dirtrack
 183   :type  'function
 184   )
 185
 186 (defcustom dirtrack-directory-change-hook nil
 187   "Hook that is called when a directory change is made."
 188   :group 'dirtrack
 189   :type 'hook
 190   )
 191
 192
 193 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 194 ;; Functions
 195 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 196
 197 (defun dirtrack-default-directory-function (dir)
 198   "Return a canonical directory for comparison purposes.
 199 Such a directory ends with a forward slash."
 200   (let ((directory dir))
 201     (if (not (char-equal ?/ (string-to-char (substring directory -1))))
 202         (concat directory "/")
 203       directory)))
 204
 205 (defun dirtrack-windows-directory-function (dir)
 206   "Return a canonical directory for comparison purposes.
 207 Such a directory is all lowercase, has forward-slashes as delimiters,
 208 and ends with a forward slash."
 209   (let ((directory dir))
 210     (setq directory (downcase (dirtrack-replace-slash directory t)))
 211     (if (not (char-equal ?/ (string-to-char (substring directory -1))))
 212         (concat directory "/")
 213       directory)))
 214
 215 (defun dirtrack-cygwin-directory-function (dir)
 216   "Return a canonical directory taken from a Cygwin path for comparison purposes."
 217   (if (string-match "/cygdrive/\\([A-Z]\\)\\(.*\\)" dir)
 218       (concat (match-string 1 dir) ":" (match-string 2 dir))
 219     dir))
 220
 221 (defconst dirtrack-forward-slash  (regexp-quote "/"))
 222 (defconst dirtrack-backward-slash (regexp-quote "\\"))
 223
 224 (defun dirtrack-replace-slash (string &optional opposite)
 225   "Replace forward slashes with backwards ones.
 226 If additional argument is non-nil, replace backwards slashes with
 227 forward ones."
 228   (let ((orig     (if opposite
 229                       dirtrack-backward-slash
 230                     dirtrack-forward-slash))
 231         (replace  (if opposite
 232                       dirtrack-forward-slash
 233                     dirtrack-backward-slash))
 234         (newstring string)
 235         )
 236     (while (string-match orig newstring)
 237       (setq newstring (replace-match replace nil t newstring)))
 238   newstring))
 239
 240 ;; Copied from shell.el
 241 (defun dirtrack-toggle ()
 242   "Enable or disable Dirtrack directory tracking in a shell buffer."
 243   (interactive)
 244   (setq dirtrackp (not dirtrackp))
 245   (message "Directory tracking %s" (if dirtrackp "ON" "OFF")))
 246
 247 (defun dirtrack-debug-toggle ()
 248   "Enable or disable Dirtrack debugging."
 249   (interactive)
 250   (setq dirtrack-debug (not dirtrack-debug))
 251   (message "Directory debugging %s" (if dirtrack-debug "ON" "OFF"))
 252   (and dirtrack-debug
 253        (display-buffer (get-buffer-create dirtrack-debug-buffer))))
 254
 255 (defun dirtrack-debug-message (string)
 256   (let ((buf (current-buffer))
 257         (debug-buf (get-buffer-create dirtrack-debug-buffer))
 258         )
 259     (set-buffer debug-buf)
 260     (goto-char (point-max))
 261     (insert (concat string "\n"))
 262     (set-buffer buf)
 263   ))
 264
 265 ;;;###autoload
 266 (defun dirtrack (input)
 267   "Determine the current directory by scanning the process output for a prompt.
 268 The prompt to look for is the first item in `dirtrack-list'.
 269
 270 You can toggle directory tracking by using the function `dirtrack-toggle'.
 271
 272 If directory tracking does not seem to be working, you can use the
 273 function `dirtrack-debug-toggle' to turn on debugging output.
 274
 275 You can enable directory tracking by adding this function to
 276 `comint-output-filter-functions'.
 277 "
 278   (if (null dirtrackp)
 279       nil
 280     (let (prompt-path
 281           matched
 282           (current-dir default-directory)
 283           (dirtrack-regexp    (nth 0 dirtrack-list))
 284           (match-num          (nth 1 dirtrack-list))
 285           (multi-line         (nth 2 dirtrack-list))
 286           )
 287       ;; No output?
 288       (if (eq (point) (point-min))
 289           nil
 290         (save-excursion
 291           (setq matched (string-match dirtrack-regexp input)))
 292           ;; No match
 293           (if (null matched)
 294               (and dirtrack-debug
 295                    (dirtrack-debug-message
 296                     (format
 297                      "Input `%s' failed to match regexp: %s"
 298                     input dirtrack-regexp)))
 299             (setq prompt-path
 300                   (substring input
 301                    (match-beginning match-num) (match-end match-num)))
 302             ;; Empty string
 303             (if (not (> (length prompt-path) 0))
 304                 (and dirtrack-debug
 305                      (dirtrack-debug-message "Match is empty string"))
 306               ;; Transform prompts into canonical forms
 307               (setq prompt-path (funcall dirtrack-directory-function
 308                                          prompt-path))
 309               (setq current-dir (funcall dirtrack-canonicalize-function
 310                                          current-dir))
 311               (and dirtrack-debug
 312                    (dirtrack-debug-message
 313                     (format
 314                      "Prompt is %s\nCurrent directory is %s"
 315                      prompt-path current-dir)))
 316               ;; Compare them
 317               (if (or (string= current-dir prompt-path)
 318                       (string= current-dir
 319                                (abbreviate-file-name prompt-path)))
 320                   (and dirtrack-debug
 321                        (dirtrack-debug-message
 322                         (format "Not changing directory")))
 323                 ;; It's possible that Emacs will think the directory
 324                 ;; won't exist (eg, rlogin buffers)
 325                 (if (file-accessible-directory-p prompt-path)
 326                     ;; Change directory
 327                     (and (shell-process-cd prompt-path)
 328                          (run-hooks 'dirtrack-directory-change-hook)
 329                          dirtrack-debug
 330                          (dirtrack-debug-message
 331                           (format "Changing directory to %s" prompt-path)))
 332                   (error "Directory %s does not exist" prompt-path)))
 333               )))))
 334   input)
 335
 336 (provide 'dirtrack)
 337
 338 ;;; arch-tag: 168de071-be88-4937-aff6-2aba9f328d5a
 339 ;;; dirtrack.el ends here