code.delx.au - gnu-emacs/blob - lisp/progmodes/compile.el

   1 ;;; compile.el --- run compiler as inferior of Emacs, parse error messages
   2
   3 ;; Copyright (C) 1985, 1986, 1987, 1993, 1994, 1995, 1996, 1997, 1998, 1999,
   4 ;;   2001, 2003, 2004, 2005  Free Software Foundation, Inc.
   5
   6 ;; Authors: Roland McGrath <roland@gnu.org>,
   7 ;;          Daniel Pfeiffer <occitan@esperanto.org>
   8 ;; Maintainer: FSF
   9 ;; Keywords: tools, processes
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software; you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation; either version 2, or (at your option)
  16 ;; any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  25 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  26 ;; Boston, MA 02111-1307, USA.
  27
  28 ;;; Commentary:
  29
  30 ;; This package provides the compile facilities documented in the Emacs user's
  31 ;; manual.
  32
  33 ;; This mode uses some complex data-structures:
  34
  35 ;;   LOC (or location) is a list of (COLUMN LINE FILE-STRUCTURE)
  36
  37 ;; COLUMN and LINE are numbers parsed from an error message.  COLUMN and maybe
  38 ;; LINE will be nil for a message that doesn't contain them.  Then the
  39 ;; location refers to a indented beginning of line or beginning of file.
  40 ;; Once any location in some file has been jumped to, the list is extended to
  41 ;; (COLUMN LINE FILE-STRUCTURE MARKER . VISITED) for all LOCs pertaining to
  42 ;; that file.
  43 ;; MARKER initially points to LINE and COLUMN in a buffer visiting that file.
  44 ;; Being a marker it sticks to some text, when the buffer grows or shrinks
  45 ;; before that point.  VISITED is t if we have jumped there, else nil.
  46
  47 ;;   FILE-STRUCTURE is a list of
  48 ;;   ((FILENAME . DIRECTORY) FORMATS (LINE LOC ...) ...)
  49
  50 ;; FILENAME is a string parsed from an error message.  DIRECTORY is a string
  51 ;; obtained by following directory change messages.  DIRECTORY will be nil for
  52 ;; an absolute filename.  FORMATS is a list of formats to apply to FILENAME if
  53 ;; a file of that name can't be found.
  54 ;; The rest of the list is an alist of elements with LINE as key.  The keys
  55 ;; are either nil or line numbers.  If present, nil comes first, followed by
  56 ;; the numbers in decreasing order.  The LOCs for each line are again an alist
  57 ;; ordered the same way.  Note that the whole file structure is referenced in
  58 ;; every LOC.
  59
  60 ;;   MESSAGE is a list of (LOC TYPE END-LOC)
  61
  62 ;; TYPE is 0 for info or 1 for warning if the message matcher identified it as
  63 ;; such, 2 otherwise (for a real error).  END-LOC is a LOC pointing to the
  64 ;; other end, if the parsed message contained a range.  If the end of the
  65 ;; range didn't specify a COLUMN, it defaults to -1, meaning end of line.
  66 ;; These are the value of the `message' text-properties in the compilation
  67 ;; buffer.
  68
  69 ;;; Code:
  70
  71 (eval-when-compile (require 'cl))
  72
  73 (defgroup compilation nil
  74   "Run compiler as inferior of Emacs, parse error messages."
  75   :group 'tools
  76   :group 'processes)
  77
  78
  79 ;;;###autoload
  80 (defcustom compilation-mode-hook nil
  81   "*List of hook functions run by `compilation-mode' (see `run-hooks')."
  82   :type 'hook
  83   :group 'compilation)
  84
  85 ;;;###autoload
  86 (defcustom compilation-window-height nil
  87   "*Number of lines in a compilation window.  If nil, use Emacs default."
  88   :type '(choice (const :tag "Default" nil)
  89                  integer)
  90   :group 'compilation)
  91
  92 (defvar compilation-first-column 1
  93   "*This is how compilers number the first column, usually 1 or 0.")
  94
  95 (defvar compilation-parse-errors-filename-function nil
  96   "Function to call to post-process filenames while parsing error messages.
  97 It takes one arg FILENAME which is the name of a file as found
  98 in the compilation output, and should return a transformed file name.")
  99
 100 ;;;###autoload
 101 (defvar compilation-process-setup-function nil
 102   "*Function to call to customize the compilation process.
 103 This function is called immediately before the compilation process is
 104 started.  It can be used to set any variables or functions that are used
 105 while processing the output of the compilation process.  The function
 106 is called with variables `compilation-buffer' and `compilation-window'
 107 bound to the compilation buffer and window, respectively.")
 108
 109 ;;;###autoload
 110 (defvar compilation-buffer-name-function nil
 111   "Function to compute the name of a compilation buffer.
 112 The function receives one argument, the name of the major mode of the
 113 compilation buffer.  It should return a string.
 114 nil means compute the name with `(concat \"*\" (downcase major-mode) \"*\")'.")
 115
 116 ;;;###autoload
 117 (defvar compilation-finish-function nil
 118   "Function to call when a compilation process finishes.
 119 It is called with two arguments: the compilation buffer, and a string
 120 describing how the process finished.")
 121
 122 ;;;###autoload
 123 (defvar compilation-finish-functions nil
 124   "Functions to call when a compilation process finishes.
 125 Each function is called with two arguments: the compilation buffer,
 126 and a string describing how the process finished.")
 127
 128 (defvar compilation-in-progress nil
 129   "List of compilation processes now running.")
 130 (or (assq 'compilation-in-progress minor-mode-alist)
 131     (setq minor-mode-alist (cons '(compilation-in-progress " Compiling")
 132                                  minor-mode-alist)))
 133
 134 (defvar compilation-error "error"
 135   "Stem of message to print when no matches are found.")
 136
 137 (defvar compilation-arguments nil
 138   "Arguments that were given to `compilation-start'.")
 139
 140 (defvar compilation-num-errors-found)
 141
 142 (defconst compilation-error-regexp-alist-alist
 143   '((absoft
 144      "^\\(?:[Ee]rror on \\|[Ww]arning on\\( \\)\\)?[Ll]ine[ \t]+\\([0-9]+\\)[ \t]+\
 145 of[ \t]+\"?\\([a-zA-Z]?:?[^\":\n]+\\)\"?:" 3 2 nil (1))
 146
 147     (ada
 148      "\\(warning: .*\\)? at \\([^ \n]+\\):\\([0-9]+\\)$" 2 3 nil (1))
 149
 150     (aix
 151      " in line \\([0-9]+\\) of file \\([^ \n]+[^. \n]\\)\\.? " 2 1)
 152
 153     (ant
 154      "^[ \t]*\\[[^] \n]+\\][ \t]*\\([^: \n]+\\):\\([0-9]+\\):\\(?:\\([0-9]+\\):[0-9]+:[0-9]+:\\)?\
 155 \\( warning\\)?" 1 2 3 (4))
 156
 157     (bash
 158      "^\\([^: \n\t]+\\): line \\([0-9]+\\):" 1 2)
 159
 160     (borland
 161      "^\\(?:Error\\|Warnin\\(g\\)\\) \\(?:[FEW][0-9]+ \\)?\
 162 \\([a-zA-Z]?:?[^:( \t\n]+\\)\
 163  \\([0-9]+\\)\\(?:[) \t]\\|:[^0-9\n]\\)" 2 3 nil (1))
 164
 165     (caml
 166      "^ *File \\(\"?\\)\\([^,\" \n\t<>]+\\)\\1, lines? \\([0-9]+\\)-?\\([0-9]+\\)?\\(?:$\\|,\
 167 \\(?: characters? \\([0-9]+\\)-?\\([0-9]+\\)?:\\)?\\([ \n]Warning:\\)?\\)"
 168      2 (3 . 4) (5 . 6) (7))
 169
 170     (comma
 171      "^\"\\([^,\" \n\t]+\\)\", line \\([0-9]+\\)\
 172 \\(?:[(. pos]+\\([0-9]+\\))?\\)?[:.,; (-]\\( warning:\\|[-0-9 ]*(W)\\)?" 1 2 3 (4))
 173
 174     (edg-1
 175      "^\\([^ \n]+\\)(\\([0-9]+\\)): \\(?:error\\|warnin\\(g\\)\\|remar\\(k\\)\\)"
 176      1 2 nil (3 . 4))
 177     (edg-2
 178      "at line \\([0-9]+\\) of \"\\([^ \n]+\\)\"$"
 179      2 1 nil 0)
 180
 181     (epc
 182      "^Error [0-9]+ at (\\([0-9]+\\):\\([^)\n]+\\))" 2 1)
 183
 184     (ftnchek
 185      "\\(^Warning .*\\)? line[ \n]\\([0-9]+\\)[ \n]\\(?:col \\([0-9]+\\)[ \n]\\)?file \\([^ :;\n]+\\)"
 186      4 2 3 (1))
 187
 188     (iar
 189      "^\"\\(.*\\)\",\\([0-9]+\\)\\s-+\\(?:Error\\|Warnin\\(g\\)\\)\\[[0-9]+\\]:"
 190      1 2 nil (3))
 191
 192     (ibm
 193      "^\\([^( \n\t]+\\)(\\([0-9]+\\):\\([0-9]+\\)) :\
 194  \\(?:warnin\\(g\\)\\|informationa\\(l\\)\\)?" 1 2 3 (4 . 5))
 195
 196     ;; fixme: should be `mips'
 197     (irix
 198      "^[-[:alnum:]_/ ]+: \\(?:\\(?:[sS]evere\\|[eE]rror\\|[wW]arnin\\(g\\)\\|[iI]nf\\(o\\)\\)[0-9 ]*: \\)?\
 199 \\([^,\" \n\t]+\\)\\(?:, line\\|:\\) \\([0-9]+\\):" 3 4 nil (1 . 2))
 200
 201     (java
 202      "^\\(?:[ \t]+at \\|==[0-9]+== +\\(?:at\\|b\\(y\\)\\)\\).+(\\([^()\n]+\\):\\([0-9]+\\))$" 2 3 nil (1))
 203
 204     (jikes-file
 205      "^\\(?:Found\\|Issued\\) .* compiling \"\\(.+\\)\":$" 1 nil nil 0)
 206     (jikes-line
 207      "^ *\\([0-9]+\\)\\.[ \t]+.*\n +\\(<-*>\n\\*\\*\\* \\(?:Error\\|Warnin\\(g\\)\\)\\)"
 208      nil 1 nil 2 0
 209      (2 (compilation-face '(3))))
 210
 211     (gcc-include
 212      "^\\(?:In file included\\|                \\) from \
 213 \\(.+\\):\\([0-9]+\\)\\(?:\\(:\\)\\|\\(,\\)\\)?" 1 2 nil (3 . 4))
 214
 215     (gnu
 216      "^\\(?:[[:alpha:]][-[:alnum:].]+: ?\\)?\
 217 \\([/.]*[a-zA-Z]:?[^ \t\n:]*\\|{standard input}\\): ?\
 218 \\([0-9]+\\)\\([.:]?\\)\\([0-9]+\\)?\
 219 \\(?:-\\(?:\\([0-9]+\\)\\3\\)?\\.?\\([0-9]+\\)?\\)?:\
 220 \\(?: *\\(\\(?:Future\\|Runtime\\)?[Ww]arning\\|W:\\)\\|\
 221  *\\([Ii]nfo\\(?:\\>\\|rmationa?l?\\)\\|I:\\)\\)?"
 222      1 (2 . 5) (4 . 6) (7 . 8))
 223
 224     (lcc
 225      "^\\(?:E\\|\\(W\\)\\), \\([^(\n]+\\)(\\([0-9]+\\),[ \t]*\\([0-9]+\\)"
 226      2 3 4 (1))
 227
 228     (makepp
 229      "^makepp: \\(?:\\(?:warning\\(:\\).*?\\|\\(Scanning\\|[LR]e?l?oading makefile\\) \\|.*?\\)\
 230 `\\(\\(\\S +?\\)\\(?::\\([0-9]+\\)\\)?\\)'\\)"
 231      4 5 nil (1 . 2) 3
 232      ("`\\(\\(\\S +?\\)\\(?::\\([0-9]+\\)\\)?\\)'" nil nil
 233       (2 compilation-info-face)
 234       (3 compilation-line-face nil t)
 235       (1 (compilation-error-properties 2 3 nil nil nil 0 nil)
 236          append)))
 237
 238     ;; Should be lint-1, lint-2 (SysV lint)
 239     (mips-1
 240      " (\\([0-9]+\\)) in \\([^ \n]+\\)" 2 1)
 241     (mips-2
 242      " in \\([^()\n ]+\\)(\\([0-9]+\\))$" 1 2)
 243
 244     (msft
 245      "^\\(\\(?:[a-zA-Z]:\\)?[^:(\t\n]+\\)(\\([0-9]+\\)) \
 246 : \\(?:error\\|warnin\\(g\\)\\) C[0-9]+:" 1 2 nil (3))
 247
 248     (oracle
 249      "^\\(?:Semantic error\\|Error\\|PCC-[0-9]+:\\).* line \\([0-9]+\\)\
 250 \\(?:\\(?:,\\| at\\)? column \\([0-9]+\\)\\)?\
 251 \\(?:,\\| in\\| of\\)? file \\(.*?\\):?$"
 252      3 1 2)
 253
 254     (perl
 255      " at \\([^ \n]+\\) line \\([0-9]+\\)\\(?:[,.]\\|$\\)" 1 2)
 256
 257     (rxp
 258      "^\\(?:Error\\|Warnin\\(g\\)\\):.*\n.* line \\([0-9]+\\) char\
 259  \\([0-9]+\\) of file://\\(.+\\)"
 260      4 2 3 (1))
 261
 262     (sparc-pascal-file
 263      "^\\w\\w\\w \\w\\w\\w +[0-3]?[0-9] +[0-2][0-9]:[0-5][0-9]:[0-5][0-9]\
 264  [12][09][0-9][0-9] +\\(.*\\):$"
 265      1 nil nil 0)
 266     (sparc-pascal-line
 267      "^\\(\\(?:E\\|\\(w\\)\\) +[0-9]+\\) line \\([0-9]+\\) -  "
 268      nil 3 nil (2) nil (1 (compilation-face '(2))))
 269     (sparc-pascal-example
 270      "^ +\\([0-9]+\\) +.*\n\\(\\(?:e\\|\\(w\\)\\) [0-9]+\\)-+"
 271      nil 1 nil (3) nil (2 (compilation-face '(3))))
 272
 273     (sun
 274      ": \\(?:ERROR\\|WARNIN\\(G\\)\\|REMAR\\(K\\)\\) \\(?:[[:alnum:] ]+, \\)?\
 275 File = \\(.+\\), Line = \\([0-9]+\\)\\(?:, Column = \\([0-9]+\\)\\)?"
 276      3 4 5 (1 . 2))
 277
 278     (sun-ada
 279      "^\\([^, \n\t]+\\), line \\([0-9]+\\), char \\([0-9]+\\)[:., \(-]" 1 2 3)
 280
 281     (4bsd
 282      "\\(?:^\\|::  \\|\\S ( \\)\\(/[^ \n\t()]+\\)(\\([0-9]+\\))\
 283 \\(?:: \\(warning:\\)?\\|$\\| ),\\)" 1 2 nil (3))
 284
 285     (gcov-file
 286      "^ +-:    \\(0\\):Source:\\(.+\\)$" 2 1 nil 0)
 287     (gcov-bb-file
 288      "^ +-:    \\(0\\):Object:\\(?:.+\\)$" nil 1 nil 0)
 289     (gcov-never-called-line
 290      "^ +\\(#####\\): +\\([0-9]+\\):.+$" nil 2 nil 2 nil
 291      (1 compilation-error-face))
 292     (gcov-called-line
 293      "^ +[-0-9]+: +\\([1-9]\\|[0-9]\\{2,\\}\\):.*$" nil 1 nil 0)
 294 )
 295   "Alist of values for `compilation-error-regexp-alist'.")
 296
 297 (defcustom compilation-error-regexp-alist
 298   (mapcar 'car compilation-error-regexp-alist-alist)
 299   "Alist that specifies how to match errors in compiler output.
 300 Note that on Unix everything is a valid filename, so these
 301 matchers must make some common sense assumptions, which catch
 302 normal cases.  A shorter list will be lighter on resource usage.
 303
 304 Instead of an alist element, you can use a symbol, which is
 305 looked up in `compilation-error-regexp-alist-alist'.  You can see
 306 the predefined symbols and their effects in the file
 307 `etc/compilation.txt' (linked below if you are customizing this).
 308
 309 Each elt has the form (REGEXP FILE [LINE COLUMN TYPE HYPERLINK
 310 HIGHLIGHT...]).  If REGEXP matches, the FILE'th subexpression
 311 gives the file name, and the LINE'th subexpression gives the line
 312 number.  The COLUMN'th subexpression gives the column number on
 313 that line.
 314
 315 If FILE, LINE or COLUMN are nil or that index didn't match, that
 316 information is not present on the matched line.  In that case the
 317 file name is assumed to be the same as the previous one in the
 318 buffer, line number defaults to 1 and column defaults to
 319 beginning of line's indentation.
 320
 321 FILE can also have the form (FILE FORMAT...), where the FORMATs
 322 \(e.g. \"%s.c\") will be applied in turn to the recognized file
 323 name, until a file of that name is found.  Or FILE can also be a
 324 function to return the filename.
 325
 326 LINE can also be of the form (LINE . END-LINE) meaning a range
 327 of lines.  COLUMN can also be of the form (COLUMN . END-COLUMN)
 328 meaning a range of columns starting on LINE and ending on
 329 END-LINE, if that matched.
 330
 331 TYPE is 2 or nil for a real error or 1 for warning or 0 for info.
 332 TYPE can also be of the form (WARNING . INFO).  In that case this
 333 will be equivalent to 1 if the WARNING'th subexpression matched
 334 or else equivalent to 0 if the INFO'th subexpression matched.
 335 See `compilation-error-face', `compilation-warning-face',
 336 `compilation-info-face' and `compilation-skip-threshold'.
 337
 338 What matched the HYPERLINK'th subexpression has `mouse-face' and
 339 `compilation-message-face' applied.  If this is nil, the text
 340 matched by the whole REGEXP becomes the hyperlink.
 341
 342 Additional HIGHLIGHTs as described under `font-lock-keywords' can
 343 be added."
 344   :type `(set :menu-tag "Pick"
 345               ,@(mapcar (lambda (elt)
 346                           (list 'const (car elt)))
 347                         compilation-error-regexp-alist-alist))
 348   :link `(file-link :tag "example file"
 349                     ,(expand-file-name "compilation.txt" data-directory))
 350   :group 'compilation)
 351
 352 (defvar compilation-directory nil
 353   "Directory to restore to when doing `recompile'.")
 354
 355 (defvar compilation-directory-matcher
 356   '("\\(?:Entering\\|Leavin\\(g\\)\\) directory `\\(.+\\)'$" (2 . 1))
 357   "A list for tracking when directories are entered or left.
 358 Nil means not to track directories, e.g. if all file names are absolute.  The
 359 first element is the REGEXP matching these messages.  It can match any number
 360 of variants, e.g. different languages.  The remaining elements are all of the
 361 form (DIR .  LEAVE).  If for any one of these the DIR'th subexpression
 362 matches, that is a directory name.  If LEAVE is nil or the corresponding
 363 LEAVE'th subexpression doesn't match, this message is about going into another
 364 directory.  If it does match anything, this message is about going back to the
 365 directory we were in before the last entering message.  If you change this,
 366 you may also want to change `compilation-page-delimiter'.")
 367
 368 (defvar compilation-page-delimiter
 369   "^\\(?:\f\\|.*\\(?:Entering\\|Leaving\\) directory `.+'\n\\)+"
 370   "Value of `page-delimiter' in Compilation mode.")
 371
 372 (defvar compilation-mode-font-lock-keywords
 373    '(;; configure output lines.
 374      ("^[Cc]hecking \\(?:[Ff]or \\|[Ii]f \\|[Ww]hether \\(?:to \\)?\\)?\\(.+\\)\\.\\.\\. *\\(?:(cached) *\\)?\\(\\(yes\\(?: .+\\)?\\)\\|no\\|\\(.*\\)\\)$"
 375       (1 font-lock-variable-name-face)
 376       (2 (compilation-face '(4 . 3))))
 377      ;; Command output lines.  Recognize `make[n]:' lines too.
 378      ("^\\([[:alnum:]_/.+-]+\\)\\(\\[\\([0-9]+\\)\\]\\)?[ \t]*:"
 379       (1 font-lock-function-name-face) (3 compilation-line-face nil t))
 380      (" --?o\\(?:utfile\\|utput\\)?[= ]?\\(\\S +\\)" . 1)
 381      ("^Compilation finished" . compilation-info-face)
 382      ("^Compilation exited abnormally" . compilation-error-face))
 383    "Additional things to highlight in Compilation mode.
 384 This gets tacked on the end of the generated expressions.")
 385
 386 (defvar compilation-highlight-regexp t
 387   "Regexp matching part of visited source lines to highlight temporarily.
 388 Highlight entire line if t; don't highlight source lines if nil.")
 389
 390 (defvar compilation-highlight-overlay nil
 391   "Overlay used to temporarily highlight compilation matches.")
 392
 393 (defcustom compilation-error-screen-columns t
 394   "*If non-nil, column numbers in error messages are screen columns.
 395 Otherwise they are interpreted as character positions, with
 396 each character occupying one column.
 397 The default is to use screen columns, which requires that the compilation
 398 program and Emacs agree about the display width of the characters,
 399 especially the TAB character."
 400   :type 'boolean
 401   :group 'compilation
 402   :version "20.4")
 403
 404 (defcustom compilation-read-command t
 405   "*Non-nil means \\[compile] reads the compilation command to use.
 406 Otherwise, \\[compile] just uses the value of `compile-command'."
 407   :type 'boolean
 408   :group 'compilation)
 409
 410 ;;;###autoload
 411 (defcustom compilation-ask-about-save t
 412   "*Non-nil means \\[compile] asks which buffers to save before compiling.
 413 Otherwise, it saves all modified buffers without asking."
 414   :type 'boolean
 415   :group 'compilation)
 416
 417 ;;;###autoload
 418 (defcustom compilation-search-path '(nil)
 419   "*List of directories to search for source files named in error messages.
 420 Elements should be directory names, not file names of directories.
 421 nil as an element means to try the default directory."
 422   :type '(repeat (choice (const :tag "Default" nil)
 423                          (string :tag "Directory")))
 424   :group 'compilation)
 425
 426 (defcustom compile-command "make -k "
 427   "*Last shell command used to do a compilation; default for next compilation.
 428
 429 Sometimes it is useful for files to supply local values for this variable.
 430 You might also use mode hooks to specify it in certain modes, like this:
 431
 432     (add-hook 'c-mode-hook
 433        (lambda ()
 434          (unless (or (file-exists-p \"makefile\")
 435                      (file-exists-p \"Makefile\"))
 436            (set (make-local-variable 'compile-command)
 437                 (concat \"make -k \"
 438                         (file-name-sans-extension buffer-file-name))))))"
 439   :type 'string
 440   :group 'compilation)
 441
 442 ;; A weak per-compilation-buffer hash indexed by (FILENAME . DIRECTORY).  Each
 443 ;; value is a FILE-STRUCTURE as described above, with the car eq to the hash
 444 ;; key.  This holds the tree seen from root, for storing new nodes.
 445 (defvar compilation-locs ())
 446
 447 (defvar compilation-debug nil
 448   "*Set this to t before creating a *compilation* buffer.
 449 Then every error line will have a debug text property with the matcher that
 450 fit this line and the match data.  Use `describe-text-properties'.")
 451
 452 (defvar compilation-exit-message-function nil "\
 453 If non-nil, called when a compilation process dies to return a status message.
 454 This should be a function of three arguments: process status, exit status,
 455 and exit message; it returns a cons (MESSAGE . MODELINE) of the strings to
 456 write into the compilation buffer, and to put in its mode line.")
 457
 458 (defvar compilation-environment nil
 459   "*List of environment variables for compilation to inherit.
 460 Each element should be a string of the form ENVVARNAME=VALUE.
 461 This list is temporarily prepended to `process-environment' prior to
 462 starting the compilation process.")
 463
 464 ;; History of compile commands.
 465 (defvar compile-history nil)
 466
 467 (defface compilation-warning-face
 468   '((((class color) (min-colors 16)) (:foreground "Orange" :weight bold))
 469     (((class color)) (:foreground "cyan" :weight bold))
 470     (t (:weight bold)))
 471   "Face used to highlight compiler warnings."
 472   :group 'font-lock-highlighting-faces
 473   :version "22.1")
 474
 475 (defface compilation-info-face
 476   '((((class color) (min-colors 16) (background light))
 477      (:foreground "Green3" :weight bold))
 478     (((class color) (min-colors 88) (background dark))
 479      (:foreground "Green1" :weight bold))
 480     (((class color) (min-colors 16) (background dark))
 481      (:foreground "Green" :weight bold))
 482     (((class color)) (:foreground "green" :weight bold))
 483     (t (:weight bold)))
 484   "Face used to highlight compiler warnings."
 485   :group 'font-lock-highlighting-faces
 486   :version "22.1")
 487
 488 (defvar compilation-message-face nil
 489   "Face name to use for whole messages.
 490 Faces `compilation-error-face', `compilation-warning-face',
 491 `compilation-info-face', `compilation-line-face' and
 492 `compilation-column-face' get prepended to this, when applicable.")
 493
 494 (defvar compilation-error-face 'font-lock-warning-face
 495   "Face name to use for file name in error messages.")
 496
 497 (defvar compilation-warning-face 'compilation-warning-face
 498   "Face name to use for file name in warning messages.")
 499
 500 (defvar compilation-info-face 'compilation-info-face
 501   "Face name to use for file name in informational messages.")
 502
 503 (defvar compilation-line-face 'font-lock-variable-name-face
 504   "Face name to use for line number in message.")
 505
 506 (defvar compilation-column-face 'font-lock-type-face
 507   "Face name to use for column number in message.")
 508
 509 ;; same faces as dired uses
 510 (defvar compilation-enter-directory-face 'font-lock-function-name-face
 511   "Face name to use for column number in message.")
 512
 513 (defvar compilation-leave-directory-face 'font-lock-type-face
 514   "Face name to use for column number in message.")
 515
 516
 517
 518 ;; Used for compatibility with the old compile.el.
 519 (defvaralias 'compilation-last-buffer 'next-error-last-buffer)
 520 (defvar compilation-parsing-end (make-marker))
 521 (defvar compilation-parse-errors-function nil)
 522 (defvar compilation-error-list nil)
 523 (defvar compilation-old-error-list nil)
 524
 525 (defun compilation-face (type)
 526   (or (and (car type) (match-end (car type)) compilation-warning-face)
 527       (and (cdr type) (match-end (cdr type)) compilation-info-face)
 528       compilation-error-face))
 529
 530 ;; Internal function for calculating the text properties of a directory
 531 ;; change message.  The directory property is important, because it is
 532 ;; the stack of nested enter-messages.  Relative filenames on the following
 533 ;; lines are relative to the top of the stack.
 534 (defun compilation-directory-properties (idx leave)
 535   (if leave (setq leave (match-end leave)))
 536   ;; find previous stack, and push onto it, or if `leave' pop it
 537   (let ((dir (previous-single-property-change (point) 'directory)))
 538     (setq dir (if dir (or (get-text-property (1- dir) 'directory)
 539                           (get-text-property dir 'directory))))
 540     `(face ,(if leave
 541                 compilation-leave-directory-face
 542               compilation-enter-directory-face)
 543       directory ,(if leave
 544                      (or (cdr dir)
 545                          '(nil))        ; nil only isn't a property-change
 546                    (cons (match-string-no-properties idx) dir))
 547       mouse-face highlight
 548       keymap compilation-button-map
 549       help-echo "mouse-2: visit current directory")))
 550
 551 ;; Data type `reverse-ordered-alist' retriever.  This function retrieves the
 552 ;; KEY element from the ALIST, creating it in the right position if not already
 553 ;; present. ALIST structure is
 554 ;; '(ANCHOR (KEY1 ...) (KEY2 ...)... (KEYn ALIST ...))
 555 ;; ANCHOR is ignored, but necessary so that elements can be inserted.  KEY1
 556 ;; may be nil.  The other KEYs are ordered backwards so that growing line
 557 ;; numbers can be inserted in front and searching can abort after half the
 558 ;; list on average.
 559 (eval-when-compile                  ;Don't keep it at runtime if not needed.
 560 (defmacro compilation-assq (key alist)
 561   `(let* ((l1 ,alist)
 562           (l2 (cdr l1)))
 563      (car (if (if (null ,key)
 564                   (if l2 (null (caar l2)))
 565                 (while (if l2 (if (caar l2) (< ,key (caar l2)) t))
 566                   (setq l1 l2
 567                         l2 (cdr l1)))
 568                 (if l2 (eq ,key (caar l2))))
 569               l2
 570             (setcdr l1 (cons (list ,key) l2)))))))
 571
 572
 573 ;; This function is the central driver, called when font-locking to gather
 574 ;; all information needed to later jump to corresponding source code.
 575 ;; Return a property list with all meta information on this error location.
 576 (defun compilation-error-properties (file line end-line col end-col type fmt)
 577   (unless (< (next-single-property-change (match-beginning 0) 'directory nil (point))
 578              (point))
 579     (if file
 580         (if (functionp file)
 581             (setq file (funcall file))
 582           (let (dir)
 583             (setq file (match-string-no-properties file))
 584             (unless (file-name-absolute-p file)
 585               (setq dir (previous-single-property-change (point) 'directory)
 586                     dir (if dir (or (get-text-property (1- dir) 'directory)
 587                                     (get-text-property dir 'directory)))))
 588             (setq file (cons file (car dir)))))
 589       ;; This message didn't mention one, get it from previous
 590       (setq file (previous-single-property-change (point) 'message)
 591             file (or (if file
 592                          (car (nth 2 (car (or (get-text-property (1- file) 'message)
 593                                          (get-text-property file 'message))))))
 594                      '("*unknown*"))))
 595     ;; All of these fields are optional, get them only if we have an index, and
 596     ;; it matched some part of the message.
 597     (and line
 598          (setq line (match-string-no-properties line))
 599          (setq line (string-to-number line)))
 600     (and end-line
 601          (setq end-line (match-string-no-properties end-line))
 602          (setq end-line (string-to-number end-line)))
 603     (if col
 604         (if (functionp col)
 605             (setq col (funcall col))
 606           (and
 607            (setq col (match-string-no-properties col))
 608            (setq col (- (string-to-number col) compilation-first-column)))))
 609     (if (and end-col (functionp end-col))
 610         (setq end-col (funcall end-col))
 611       (if (and end-col (setq end-col (match-string-no-properties end-col)))
 612           (setq end-col (- (string-to-number end-col) compilation-first-column -1))
 613         (if end-line (setq end-col -1))))
 614     (if (consp type)                    ; not a static type, check what it is.
 615         (setq type (or (and (car type) (match-end (car type)) 1)
 616                        (and (cdr type) (match-end (cdr type)) 0)
 617                        2)))
 618     (compilation-internal-error-properties file line end-line col end-col type fmt)))
 619
 620 (defun compilation-move-to-column (col screen)
 621   "Go to column COL on the current line.
 622 If SCREEN is non-nil, columns are screen columns, otherwise, they are
 623 just char-counts."
 624   (if screen
 625       (move-to-column col)
 626     (goto-char (min (+ (line-beginning-position) col) (line-end-position)))))
 627
 628 (defun compilation-internal-error-properties (file line end-line col end-col type fmt)
 629   "Get the meta-info that will be added as text-properties.
 630 LINE, END-LINE, COL, END-COL are integers or nil.
 631 TYPE can be 0, 1, or 2.
 632 FILE should be (ABSOLUTE-FILENAME) or (RELATIVE-FILENAME . DIRNAME) or nil."
 633   (unless file (setq file '("*unknown*")))
 634   (setq file (compilation-get-file-structure file fmt))
 635   ;; Get first already existing marker (if any has one, all have one).
 636   ;; Do this first, as the compilation-assq`s may create new nodes.
 637   (let* ((marker-line (car (cddr file)))        ; a line structure
 638          (marker (nth 3 (cadr marker-line)))    ; its marker
 639          (compilation-error-screen-columns compilation-error-screen-columns)
 640          end-marker loc end-loc)
 641     (if (not (and marker (marker-buffer marker)))
 642         (setq marker)                   ; no valid marker for this file
 643       (setq loc (or line 1))            ; normalize no linenumber to line 1
 644       (catch 'marker                    ; find nearest loc, at least one exists
 645         (dolist (x (nthcdr 3 file))     ; loop over remaining lines
 646           (if (> (car x) loc)           ; still bigger
 647               (setq marker-line x)
 648             (if (> (- (or (car marker-line) 1) loc)
 649                    (- loc (car x)))     ; current line is nearer
 650                 (setq marker-line x))
 651             (throw 'marker t))))
 652       (setq marker (nth 3 (cadr marker-line))
 653             marker-line (or (car marker-line) 1))
 654       (with-current-buffer (marker-buffer marker)
 655         (save-restriction
 656           (widen)
 657           (goto-char (marker-position marker))
 658           (when (or end-col end-line)
 659             (beginning-of-line (- (or end-line line) marker-line -1))
 660             (if (or (null end-col) (< end-col 0))
 661                 (end-of-line)
 662               (compilation-move-to-column
 663                end-col compilation-error-screen-columns))
 664             (setq end-marker (list (point-marker))))
 665           (beginning-of-line (if end-line
 666                                  (- line end-line -1)
 667                                (- loc marker-line -1)))
 668           (if col
 669               (compilation-move-to-column
 670                col compilation-error-screen-columns)
 671             (forward-to-indentation 0))
 672           (setq marker (list (point-marker))))))
 673
 674     (setq loc (compilation-assq line (cdr file)))
 675     (if end-line
 676         (setq end-loc (compilation-assq end-line (cdr file))
 677               end-loc (compilation-assq end-col end-loc))
 678       (if end-col                       ; use same line element
 679           (setq end-loc (compilation-assq end-col loc))))
 680     (setq loc (compilation-assq col loc))
 681     ;; If they are new, make the loc(s) reference the file they point to.
 682     (or (cdr loc) (setcdr loc `(,line ,file ,@marker)))
 683     (if end-loc
 684         (or (cdr end-loc) (setcdr end-loc `(,(or end-line line) ,file ,@end-marker))))
 685
 686     ;; Must start with face
 687     `(face ,compilation-message-face
 688            message (,loc ,type ,end-loc)
 689            ,@(if compilation-debug
 690                  `(debug (,(assoc (with-no-warnings matcher) font-lock-keywords)
 691                           ,@(match-data))))
 692            help-echo ,(if col
 693                           "mouse-2: visit this file, line and column"
 694                         (if line
 695                             "mouse-2: visit this file and line"
 696                           "mouse-2: visit this file"))
 697            keymap compilation-button-map
 698            mouse-face highlight)))
 699
 700 (defun compilation-mode-font-lock-keywords ()
 701   "Return expressions to highlight in Compilation mode."
 702   (if compilation-parse-errors-function
 703       ;; An old package!  Try the compatibility code.
 704       '((compilation-compat-parse-errors))
 705     (append
 706      ;; make directory tracking
 707      (if compilation-directory-matcher
 708          `((,(car compilation-directory-matcher)
 709             ,@(mapcar (lambda (elt)
 710                         `(,(car elt)
 711                           (compilation-directory-properties
 712                            ,(car elt) ,(cdr elt))
 713                           t))
 714                       (cdr compilation-directory-matcher)))))
 715
 716      ;; Compiler warning/error lines.
 717      (mapcar
 718       (lambda (item)
 719         (if (symbolp item)
 720             (setq item (cdr (assq item
 721                                   compilation-error-regexp-alist-alist))))
 722         (let ((file (nth 1 item))
 723               (line (nth 2 item))
 724               (col (nth 3 item))
 725               (type (nth 4 item))
 726               end-line end-col fmt)
 727           (if (consp file)      (setq fmt (cdr file)      file (car file)))
 728           (if (consp line)      (setq end-line (cdr line) line (car line)))
 729           (if (consp col)       (setq end-col (cdr col)   col (car col)))
 730
 731           (if (functionp line)
 732               ;; The old compile.el had here an undocumented hook that
 733               ;; allowed `line' to be a function that computed the actual
 734               ;; error location.  Let's do our best.
 735               `(,(car item)
 736                 (0 (compilation-compat-error-properties
 737                     (funcall ',line (cons (match-string ,file)
 738                                           (cons default-directory
 739                                                 ',(nthcdr 4 item)))
 740                              ,(if col `(match-string ,col)))))
 741                 (,file compilation-error-face t))
 742
 743             (unless (or (null (nth 5 item)) (integerp (nth 5 item)))
 744               (error "HYPERLINK should be an integer: %s" (nth 5 item)))
 745
 746             `(,(nth 0 item)
 747
 748               ,@(when (integerp file)
 749                   `((,file ,(if (consp type)
 750                                 `(compilation-face ',type)
 751                               (aref [compilation-info-face
 752                                      compilation-warning-face
 753                                      compilation-error-face]
 754                                     (or type 2))))))
 755
 756               ,@(when line
 757                   `((,line compilation-line-face nil t)))
 758               ,@(when end-line
 759                   `((,end-line compilation-line-face nil t)))
 760
 761               ,@(when (integerp col)
 762                   `((,col compilation-column-face nil t)))
 763               ,@(when (integerp end-col)
 764                   `((,end-col compilation-column-face nil t)))
 765
 766               ,@(nthcdr 6 item)
 767               (,(or (nth 5 item) 0)
 768                (compilation-error-properties ',file ,line ,end-line
 769                                              ,col ,end-col ',(or type 2)
 770                                              ',fmt)
 771                append)))))              ; for compilation-message-face
 772       compilation-error-regexp-alist)
 773
 774      compilation-mode-font-lock-keywords)))
 775
 776 \f
 777 ;;;###autoload
 778 (defun compile (command &optional comint)
 779   "Compile the program including the current buffer.  Default: run `make'.
 780 Runs COMMAND, a shell command, in a separate process asynchronously
 781 with output going to the buffer `*compilation*'.
 782
 783 If optional second arg COMINT is t the buffer will be in Comint mode with
 784 `compilation-shell-minor-mode'.
 785
 786 You can then use the command \\[next-error] to find the next error message
 787 and move to the source code that caused it.
 788
 789 Interactively, prompts for the command if `compilation-read-command' is
 790 non-nil; otherwise uses `compile-command'.  With prefix arg, always prompts.
 791 Additionally, with universal prefix arg, compilation buffer will be in
 792 comint mode, i.e. interactive.
 793
 794 To run more than one compilation at once, start one and rename
 795 the \`*compilation*' buffer to some other name with
 796 \\[rename-buffer].  Then start the next one.  On most systems,
 797 termination of the main compilation process kills its
 798 subprocesses.
 799
 800 The name used for the buffer is actually whatever is returned by
 801 the function in `compilation-buffer-name-function', so you can set that
 802 to a function that generates a unique name."
 803   (interactive
 804    (list
 805     (let ((command (eval compile-command)))
 806       (if (or compilation-read-command current-prefix-arg)
 807           (read-from-minibuffer "Compile command: "
 808                                 command nil nil
 809                                 (if (equal (car compile-history) command)
 810                                     '(compile-history . 1)
 811                                   'compile-history))
 812         command))
 813     (consp current-prefix-arg)))
 814   (unless (equal command (eval compile-command))
 815     (setq compile-command command))
 816   (save-some-buffers (not compilation-ask-about-save) nil)
 817   (setq compilation-directory default-directory)
 818   (compilation-start command comint))
 819
 820 ;; run compile with the default command line
 821 (defun recompile ()
 822   "Re-compile the program including the current buffer.
 823 If this is run in a Compilation mode buffer, re-use the arguments from the
 824 original use.  Otherwise, recompile using `compile-command'."
 825   (interactive)
 826   (save-some-buffers (not compilation-ask-about-save) nil)
 827   (let ((default-directory
 828           (or (and (not (eq major-mode (nth 1 compilation-arguments)))
 829                    compilation-directory)
 830               default-directory)))
 831     (apply 'compilation-start (or compilation-arguments
 832                                   `(,(eval compile-command))))))
 833
 834 (defcustom compilation-scroll-output nil
 835   "*Non-nil to scroll the *compilation* buffer window as output appears.
 836
 837 Setting it causes the Compilation mode commands to put point at the
 838 end of their output window so that the end of the output is always
 839 visible rather than the beginning."
 840   :type 'boolean
 841   :version "20.3"
 842   :group 'compilation)
 843
 844
 845 (defun compilation-buffer-name (mode-name name-function)
 846   "Return the name of a compilation buffer to use.
 847 If NAME-FUNCTION is non-nil, call it with one argument MODE-NAME
 848 to determine the buffer name.
 849 Likewise if `compilation-buffer-name-function' is non-nil.
 850 If current buffer is in Compilation mode for the same mode name
 851 return the name of the current buffer, so that it gets reused.
 852 Otherwise, construct a buffer name from MODE-NAME."
 853   (cond (name-function
 854          (funcall name-function mode-name))
 855         (compilation-buffer-name-function
 856          (funcall compilation-buffer-name-function mode-name))
 857         ((eq major-mode (nth 1 compilation-arguments))
 858          (buffer-name))
 859         (t
 860          (concat "*" (downcase mode-name) "*"))))
 861
 862 ;; This is a rough emulation of the old hack, until the transition to new
 863 ;; compile is complete.
 864 (defun compile-internal (command error-message
 865                                  &optional name-of-mode parser
 866                                  error-regexp-alist name-function
 867                                  enter-regexp-alist leave-regexp-alist
 868                                  file-regexp-alist nomessage-regexp-alist
 869                                  no-async highlight-regexp local-map)
 870   (if parser
 871       (error "Compile now works very differently, see `compilation-error-regexp-alist'"))
 872   (let ((compilation-error-regexp-alist
 873          (append file-regexp-alist (or error-regexp-alist
 874                                        compilation-error-regexp-alist)))
 875         (compilation-error (replace-regexp-in-string "^No more \\(.+\\)s\\.?"
 876                                                      "\\1" error-message)))
 877     (compilation-start command nil name-function highlight-regexp)))
 878 (make-obsolete 'compile-internal 'compilation-start)
 879
 880 (defun compilation-start (command &optional mode name-function highlight-regexp)
 881   "Run compilation command COMMAND (low level interface).
 882 If COMMAND starts with a cd command, that becomes the `default-directory'.
 883 The rest of the arguments are optional; for them, nil means use the default.
 884
 885 MODE is the major mode to set in the compilation buffer.  Mode
 886 may also be t meaning use `compilation-shell-minor-mode' under `comint-mode'.
 887 NAME-FUNCTION is a function called to name the buffer.
 888
 889 If HIGHLIGHT-REGEXP is non-nil, `next-error' will temporarily highlight
 890 the matching section of the visited source line; the default is to use the
 891 global value of `compilation-highlight-regexp'.
 892
 893 Returns the compilation buffer created."
 894   (or mode (setq mode 'compilation-mode))
 895   (let* ((name-of-mode
 896           (if (eq mode t)
 897               (prog1 "compilation" (require 'comint))
 898             (replace-regexp-in-string "-mode$" "" (symbol-name mode))))
 899          (thisdir default-directory)
 900          outwin outbuf)
 901     (with-current-buffer
 902         (setq outbuf
 903               (get-buffer-create
 904                (compilation-buffer-name name-of-mode name-function)))
 905       (let ((comp-proc (get-buffer-process (current-buffer))))
 906         (if comp-proc
 907             (if (or (not (eq (process-status comp-proc) 'run))
 908                     (yes-or-no-p
 909                      (format "A %s process is running; kill it? "
 910                              name-of-mode)))
 911                 (condition-case ()
 912                     (progn
 913                       (interrupt-process comp-proc)
 914                       (sit-for 1)
 915                       (delete-process comp-proc))
 916                   (error nil))
 917               (error "Cannot have two processes in `%s' at once"
 918                      (buffer-name)))))
 919       (buffer-disable-undo (current-buffer))
 920       ;; first transfer directory from where M-x compile was called
 921       (setq default-directory thisdir)
 922       ;; Make compilation buffer read-only.  The filter can still write it.
 923       ;; Clear out the compilation buffer.
 924       (let ((inhibit-read-only t)
 925             (default-directory thisdir))
 926         ;; Then evaluate a cd command if any, but don't perform it yet, else start-command
 927         ;; would do it again through the shell: (cd "..") AND sh -c "cd ..; make"
 928         (cd (if (string-match "^\\s *cd\\(?:\\s +\\(\\S +?\\)\\)?\\s *[;&\n]" command)
 929                 (if (match-end 1)
 930                     (substitute-env-vars (match-string 1 command))
 931                   "~")
 932               default-directory))
 933         (erase-buffer)
 934         ;; output a mode setter, for saving and later reloading this buffer
 935         (insert "-*- mode: " name-of-mode
 936                 "; default-directory: " (prin1-to-string default-directory)
 937                 " -*-\n" command "\n")
 938         (setq thisdir default-directory))
 939       (set-buffer-modified-p nil))
 940     ;; If we're already in the compilation buffer, go to the end
 941     ;; of the buffer, so point will track the compilation output.
 942     (if (eq outbuf (current-buffer))
 943         (goto-char (point-max)))
 944     ;; Pop up the compilation buffer.
 945     (setq outwin (display-buffer outbuf nil t))
 946     (with-current-buffer outbuf
 947       (let ((process-environment
 948              (append
 949               compilation-environment
 950               (if (if (boundp 'system-uses-terminfo) ; `if' for compiler warning
 951                       system-uses-terminfo)
 952                   (list "TERM=dumb" "TERMCAP="
 953                         (format "COLUMNS=%d" (window-width)))
 954                 (list "TERM=emacs"
 955                       (format "TERMCAP=emacs:co#%d:tc=unknown:"
 956                               (window-width))))
 957               ;; Set the EMACS variable, but
 958               ;; don't override users' setting of $EMACS.
 959               (unless (getenv "EMACS") '("EMACS=t"))
 960               (copy-sequence process-environment))))
 961         (if (not (eq mode t))
 962             (funcall mode)
 963           (setq buffer-read-only nil)
 964           (with-no-warnings (comint-mode))
 965           (compilation-shell-minor-mode))
 966         (if highlight-regexp
 967             (set (make-local-variable 'compilation-highlight-regexp)
 968                  highlight-regexp))
 969         (set (make-local-variable 'compilation-arguments)
 970              (list command mode name-function highlight-regexp))
 971         (set (make-local-variable 'revert-buffer-function)
 972              'compilation-revert-buffer)
 973         (set-window-start outwin (point-min))
 974         (or (eq outwin (selected-window))
 975             (set-window-point outwin (if compilation-scroll-output
 976                                          (point)
 977                                        (point-min))))
 978         ;; The setup function is called before compilation-set-window-height
 979         ;; so it can set the compilation-window-height buffer locally.
 980         (if compilation-process-setup-function
 981             (funcall compilation-process-setup-function))
 982         (compilation-set-window-height outwin)
 983         ;; Start the compilation.
 984         (if (fboundp 'start-process)
 985             (let ((proc (if (eq mode t)
 986                             (get-buffer-process
 987                              (with-no-warnings
 988                               (comint-exec outbuf (downcase mode-name)
 989                                            shell-file-name nil `("-c" ,command))))
 990                           (start-process-shell-command (downcase mode-name)
 991                                                        outbuf command))))
 992               ;; Make the buffer's mode line show process state.
 993               (setq mode-line-process '(":%s"))
 994               (set-process-sentinel proc 'compilation-sentinel)
 995               (set-process-filter proc 'compilation-filter)
 996               (set-marker (process-mark proc) (point) outbuf)
 997               (setq compilation-in-progress
 998                     (cons proc compilation-in-progress)))
 999           ;; No asynchronous processes available.
1000           (message "Executing `%s'..." command)
1001           ;; Fake modeline display as if `start-process' were run.
1002           (setq mode-line-process ":run")
1003           (force-mode-line-update)
1004           (sit-for 0)                   ; Force redisplay
1005           (let* ((buffer-read-only nil) ; call-process needs to modify outbuf
1006                  (status (call-process shell-file-name nil outbuf nil "-c"
1007                                        command)))
1008             (cond ((numberp status)
1009                    (compilation-handle-exit 'exit status
1010                                             (if (zerop status)
1011                                                 "finished\n"
1012                                               (format "\
1013 exited abnormally with code %d\n"
1014                                                       status))))
1015                   ((stringp status)
1016                    (compilation-handle-exit 'signal status
1017                                             (concat status "\n")))
1018                   (t
1019                    (compilation-handle-exit 'bizarre status status))))
1020           ;; Without async subprocesses, the buffer is not yet
1021           ;; fontified, so fontify it now.
1022           (let ((font-lock-verbose nil)) ; shut up font-lock messages
1023             (font-lock-fontify-buffer))
1024           (set-buffer-modified-p nil)
1025           (message "Executing `%s'...done" command)))
1026       ;; Now finally cd to where the shell started make/grep/...
1027       (setq default-directory thisdir))
1028     (if (buffer-local-value 'compilation-scroll-output outbuf)
1029         (save-selected-window
1030           (select-window outwin)
1031           (goto-char (point-max))))
1032     ;; Make it so the next C-x ` will use this buffer.
1033     (setq next-error-last-buffer outbuf)))
1034
1035 (defun compilation-set-window-height (window)
1036   "Set the height of WINDOW according to `compilation-window-height'."
1037   (let ((height (buffer-local-value 'compilation-window-height (window-buffer window))))
1038     (and height
1039          (= (window-width window) (frame-width (window-frame window)))
1040          ;; If window is alone in its frame, aside from a minibuffer,
1041          ;; don't change its height.
1042          (not (eq window (frame-root-window (window-frame window))))
1043          ;; Stef said that doing the saves in this order is safer:
1044          (save-excursion
1045            (save-selected-window
1046              (select-window window)
1047              (enlarge-window (- height (window-height))))))))
1048
1049 (defvar compilation-menu-map
1050   (let ((map (make-sparse-keymap "Errors")))
1051     (define-key map [stop-subjob]
1052       '("Stop Compilation" . kill-compilation))
1053     (define-key map [compilation-mode-separator2]
1054       '("----" . nil))
1055     (define-key map [compilation-first-error]
1056       '("First Error" . first-error))
1057     (define-key map [compilation-previous-error]
1058       '("Previous Error" . previous-error))
1059     (define-key map [compilation-next-error]
1060       '("Next Error" . next-error))
1061     map))
1062
1063 (defvar compilation-minor-mode-map
1064   (let ((map (make-sparse-keymap)))
1065     (define-key map [mouse-2] 'compile-goto-error)
1066     (define-key map [follow-link] 'mouse-face)
1067     (define-key map "\C-c\C-c" 'compile-goto-error)
1068     (define-key map "\C-m" 'compile-goto-error)
1069     (define-key map "\C-c\C-k" 'kill-compilation)
1070     (define-key map "\M-n" 'compilation-next-error)
1071     (define-key map "\M-p" 'compilation-previous-error)
1072     (define-key map "\M-{" 'compilation-previous-file)
1073     (define-key map "\M-}" 'compilation-next-file)
1074     ;; Set up the menu-bar
1075     (define-key map [menu-bar compilation]
1076       (cons "Errors" compilation-menu-map))
1077     map)
1078   "Keymap for `compilation-minor-mode'.")
1079
1080 (defvar compilation-shell-minor-mode-map
1081   (let ((map (make-sparse-keymap)))
1082     (define-key map "\M-\C-m" 'compile-goto-error)
1083     (define-key map "\M-\C-n" 'compilation-next-error)
1084     (define-key map "\M-\C-p" 'compilation-previous-error)
1085     (define-key map "\M-{" 'compilation-previous-file)
1086     (define-key map "\M-}" 'compilation-next-file)
1087     ;; Set up the menu-bar
1088     (define-key map [menu-bar compilation]
1089       (cons "Errors" compilation-menu-map))
1090     map)
1091   "Keymap for `compilation-shell-minor-mode'.")
1092
1093 (defvar compilation-button-map
1094   (let ((map (make-sparse-keymap)))
1095     (define-key map [mouse-2] 'compile-goto-error)
1096     (define-key map [follow-link] 'mouse-face)
1097     (define-key map "\C-m" 'compile-goto-error)
1098     map)
1099   "Keymap for compilation-message buttons.")
1100 (fset 'compilation-button-map compilation-button-map)
1101
1102 (defvar compilation-mode-map
1103   (let ((map (make-sparse-keymap)))
1104     ;; Don't inherit from compilation-minor-mode-map,
1105     ;; because that introduces a menu bar item we don't want.
1106     ;; That confuses C-down-mouse-3.
1107     (define-key map [mouse-2] 'compile-goto-error)
1108     (define-key map [follow-link] 'mouse-face)
1109     (define-key map "\C-c\C-c" 'compile-goto-error)
1110     (define-key map "\C-m" 'compile-goto-error)
1111     (define-key map "\C-c\C-k" 'kill-compilation)
1112     (define-key map "\M-n" 'compilation-next-error)
1113     (define-key map "\M-p" 'compilation-previous-error)
1114     (define-key map "\M-{" 'compilation-previous-file)
1115     (define-key map "\M-}" 'compilation-next-file)
1116
1117     (define-key map " " 'scroll-up)
1118     (define-key map "\^?" 'scroll-down)
1119     (define-key map "\C-c\C-f" 'next-error-follow-minor-mode)
1120
1121     ;; Set up the menu-bar
1122     (let ((submap (make-sparse-keymap "Compile")))
1123       (define-key map [menu-bar compilation]
1124         (cons "Compile" submap))
1125       (set-keymap-parent submap compilation-menu-map))
1126     (define-key map [menu-bar compilation compilation-separator2]
1127       '("----" . nil))
1128     (define-key map [menu-bar compilation compilation-grep]
1129       '("Search Files (grep)" . grep))
1130     (define-key map [menu-bar compilation compilation-recompile]
1131       '("Recompile" . recompile))
1132     (define-key map [menu-bar compilation compilation-compile]
1133       '("Compile..." . compile))
1134     map)
1135   "Keymap for compilation log buffers.
1136 `compilation-minor-mode-map' is a parent of this.")
1137
1138 (put 'compilation-mode 'mode-class 'special)
1139
1140 (defvar compilation-skip-to-next-location t
1141   "*If non-nil, skip multiple error messages for the same source location.")
1142
1143 (defcustom compilation-skip-threshold 1
1144   "*Compilation motion commands skip less important messages.
1145 The value can be either 2 -- skip anything less than error, 1 --
1146 skip anything less than warning or 0 -- don't skip any messages.
1147 Note that all messages not positively identified as warning or
1148 info, are considered errors."
1149   :type '(choice (const :tag "Warnings and info" 2)
1150                  (const :tag "Info" 1)
1151                  (const :tag "None" 0))
1152   :group 'compilation
1153   :version "22.1")
1154
1155 (defcustom compilation-skip-visited nil
1156   "*Compilation motion commands skip visited messages if this is t.
1157 Visited messages are ones for which the file, line and column have been jumped
1158 to from the current content in the current compilation buffer, even if it was
1159 from a different message."
1160   :type 'boolean
1161   :group 'compilation
1162   :version "22.1")
1163
1164 ;;;###autoload
1165 (defun compilation-mode (&optional name-of-mode)
1166   "Major mode for compilation log buffers.
1167 \\<compilation-mode-map>To visit the source for a line-numbered error,
1168 move point to the error message line and type \\[compile-goto-error].
1169 To kill the compilation, type \\[kill-compilation].
1170
1171 Runs `compilation-mode-hook' with `run-hooks' (which see).
1172
1173 \\{compilation-mode-map}"
1174   (interactive)
1175   (kill-all-local-variables)
1176   (use-local-map compilation-mode-map)
1177   (setq major-mode 'compilation-mode
1178         mode-name (or name-of-mode "Compilation"))
1179   (set (make-local-variable 'page-delimiter)
1180        compilation-page-delimiter)
1181   (compilation-setup)
1182   (setq buffer-read-only t)
1183   (run-mode-hooks 'compilation-mode-hook))
1184
1185 (defmacro define-compilation-mode (mode name doc &rest body)
1186   "This is like `define-derived-mode' without the PARENT argument.
1187 The parent is always `compilation-mode' and the customizable `compilation-...'
1188 variables are also set from the name of the mode you have chosen, by replacing
1189 the fist word, e.g `compilation-scroll-output' from `grep-scroll-output' if that
1190 variable exists."
1191   (let ((mode-name (replace-regexp-in-string "-mode\\'" "" (symbol-name mode))))
1192     `(define-derived-mode ,mode compilation-mode ,name
1193        ,doc
1194        ,@(mapcar (lambda (v)
1195                    (setq v (cons v
1196                                  (intern-soft (replace-regexp-in-string
1197                                                "^compilation" mode-name
1198                                                (symbol-name v)))))
1199                    (and (cdr v)
1200                         (or (boundp (cdr v))
1201                             (if (boundp 'byte-compile-bound-variables)
1202                                 (memq (cdr v) byte-compile-bound-variables)))
1203                         `(set (make-local-variable ',(car v)) ,(cdr v))))
1204                  '(compilation-buffer-name-function
1205                    compilation-directory-matcher
1206                    compilation-error
1207                    compilation-error-regexp-alist
1208                    compilation-error-regexp-alist-alist
1209                    compilation-error-screen-columns
1210                    compilation-finish-function
1211                    compilation-finish-functions
1212                    compilation-first-column
1213                    compilation-mode-font-lock-keywords
1214                    compilation-page-delimiter
1215                    compilation-parse-errors-filename-function
1216                    compilation-process-setup-function
1217                    compilation-scroll-output
1218                    compilation-search-path
1219                    compilation-skip-threshold
1220                    compilation-window-height))
1221        ,@body)))
1222
1223 (defun compilation-revert-buffer (ignore-auto noconfirm)
1224   (if buffer-file-name
1225       (let (revert-buffer-function)
1226         (revert-buffer ignore-auto noconfirm))
1227     (if (or noconfirm (yes-or-no-p (format "Restart compilation? ")))
1228         (apply 'compilation-start compilation-arguments))))
1229
1230 (defvar compilation-current-error nil
1231   "Marker to the location from where the next error will be found.
1232 The global commands next/previous/first-error/goto-error use this.")
1233
1234 (defvar compilation-messages-start nil
1235   "Buffer position of the beginning of the compilation messages.
1236 If nil, use the beginning of buffer.")
1237
1238 ;; A function name can't be a hook, must be something with a value.
1239 (defconst compilation-turn-on-font-lock 'turn-on-font-lock)
1240
1241 (defun compilation-setup (&optional minor)
1242   "Prepare the buffer for the compilation parsing commands to work.
1243 Optional argument MINOR indicates this is called from
1244 `compilation-minor-mode'."
1245   (make-local-variable 'compilation-current-error)
1246   (make-local-variable 'compilation-messages-start)
1247   (make-local-variable 'compilation-error-screen-columns)
1248   (make-local-variable 'overlay-arrow-position)
1249   (set (make-local-variable 'overlay-arrow-string) "=>")
1250   (setq next-error-overlay-arrow-position nil)
1251   (add-hook 'kill-buffer-hook
1252             (lambda () (setq next-error-overlay-arrow-position nil)) nil t)
1253   ;; Note that compilation-next-error-function is for interfacing
1254   ;; with the next-error function in simple.el, and it's only
1255   ;; coincidentally named similarly to compilation-next-error.
1256   (setq next-error-function 'compilation-next-error-function)
1257   (set (make-local-variable 'font-lock-extra-managed-props)
1258        '(directory message help-echo mouse-face debug))
1259   (set (make-local-variable 'compilation-locs)
1260        (make-hash-table :test 'equal :weakness 'value))
1261   ;; lazy-lock would never find the message unless it's scrolled to.
1262   ;; jit-lock might fontify some things too late.
1263   (set (make-local-variable 'font-lock-support-mode) nil)
1264   (set (make-local-variable 'font-lock-maximum-size) nil)
1265   (let ((fld font-lock-defaults))
1266     (if (and minor fld)
1267         (font-lock-add-keywords nil (compilation-mode-font-lock-keywords))
1268       (setq font-lock-defaults '(compilation-mode-font-lock-keywords t)))
1269     (if minor
1270         (if font-lock-mode
1271             (if fld
1272                 (font-lock-fontify-buffer)
1273               (font-lock-change-mode)
1274               (turn-on-font-lock))
1275           (turn-on-font-lock))
1276       ;; maybe defer font-lock till after derived mode is set up
1277       (run-mode-hooks 'compilation-turn-on-font-lock))))
1278
1279 ;;;###autoload
1280 (define-minor-mode compilation-shell-minor-mode
1281   "Toggle compilation shell minor mode.
1282 With arg, turn compilation mode on if and only if arg is positive.
1283 In this minor mode, all the error-parsing commands of the
1284 Compilation major mode are available but bound to keys that don't
1285 collide with Shell mode.  See `compilation-mode'.
1286 Turning the mode on runs the normal hook `compilation-shell-minor-mode-hook'."
1287   nil " Shell-Compile"
1288   :group 'compilation
1289   (if compilation-shell-minor-mode
1290       (compilation-setup t)
1291     (font-lock-remove-keywords nil (compilation-mode-font-lock-keywords))
1292     (font-lock-fontify-buffer)))
1293
1294 ;;;###autoload
1295 (define-minor-mode compilation-minor-mode
1296   "Toggle compilation minor mode.
1297 With arg, turn compilation mode on if and only if arg is positive.
1298 In this minor mode, all the error-parsing commands of the
1299 Compilation major mode are available.  See `compilation-mode'.
1300 Turning the mode on runs the normal hook `compilation-minor-mode-hook'."
1301   nil " Compilation"
1302   :group 'compilation
1303   (if compilation-minor-mode
1304       (compilation-setup t)
1305     (font-lock-remove-keywords nil (compilation-mode-font-lock-keywords))
1306     (font-lock-fontify-buffer)))
1307
1308 (defun compilation-handle-exit (process-status exit-status msg)
1309   "Write MSG in the current buffer and hack its mode-line-process."
1310   (let ((inhibit-read-only t)
1311         (status (if compilation-exit-message-function
1312                     (funcall compilation-exit-message-function
1313                              process-status exit-status msg)
1314                   (cons msg exit-status)))
1315         (omax (point-max))
1316         (opoint (point)))
1317     ;; Record where we put the message, so we can ignore it later on.
1318     (goto-char omax)
1319     (insert ?\n mode-name " " (car status))
1320     (if (and (numberp compilation-window-height)
1321              (zerop compilation-window-height))
1322         (message "%s" (cdr status)))
1323     (if (bolp)
1324         (forward-char -1))
1325     (insert " at " (substring (current-time-string) 0 19))
1326     (goto-char (point-max))
1327     ;; Prevent that message from being recognized as a compilation error.
1328     (add-text-properties omax (point)
1329                          (append '(compilation-handle-exit t) nil))
1330     (setq mode-line-process (format ":%s [%s]" process-status (cdr status)))
1331     ;; Force mode line redisplay soon.
1332     (force-mode-line-update)
1333     (if (and opoint (< opoint omax))
1334         (goto-char opoint))
1335     (if compilation-finish-function
1336         (funcall compilation-finish-function (current-buffer) msg))
1337     (let ((functions compilation-finish-functions))
1338       (while functions
1339         (funcall (car functions) (current-buffer) msg)
1340         (setq functions (cdr functions))))))
1341
1342 ;; Called when compilation process changes state.
1343 (defun compilation-sentinel (proc msg)
1344   "Sentinel for compilation buffers."
1345   (if (memq (process-status proc) '(exit signal))
1346       (let ((buffer (process-buffer proc)))
1347         (if (null (buffer-name buffer))
1348             ;; buffer killed
1349             (set-process-buffer proc nil)
1350           (with-current-buffer buffer
1351             ;; Write something in the compilation buffer
1352             ;; and hack its mode line.
1353             (compilation-handle-exit (process-status proc)
1354                                      (process-exit-status proc)
1355                                      msg)
1356             ;; Since the buffer and mode line will show that the
1357             ;; process is dead, we can delete it now.  Otherwise it
1358             ;; will stay around until M-x list-processes.
1359             (delete-process proc)))
1360         (setq compilation-in-progress (delq proc compilation-in-progress)))))
1361
1362 (defun compilation-filter (proc string)
1363   "Process filter for compilation buffers.
1364 Just inserts the text, but uses `insert-before-markers'."
1365   (if (buffer-name (process-buffer proc))
1366       (with-current-buffer (process-buffer proc)
1367         (let ((inhibit-read-only t))
1368           (save-excursion
1369             (goto-char (process-mark proc))
1370             (insert-before-markers string)
1371             (run-hooks 'compilation-filter-hook))))))
1372
1373 ;;; test if a buffer is a compilation buffer, assuming we're in the buffer
1374 (defsubst compilation-buffer-internal-p ()
1375   "Test if inside a compilation buffer."
1376   (local-variable-p 'compilation-locs))
1377
1378 ;;; test if a buffer is a compilation buffer, using compilation-buffer-internal-p
1379 (defsubst compilation-buffer-p (buffer)
1380   "Test if BUFFER is a compilation buffer."
1381   (with-current-buffer buffer
1382     (compilation-buffer-internal-p)))
1383
1384 (defmacro compilation-loop (< property-change 1+ error)
1385   `(while (,< n 0)
1386       (or (setq pt (,property-change pt 'message))
1387           (error ,error compilation-error))
1388       ;; prop 'message usually has 2 changes, on and off, so re-search if off
1389       (or (setq msg (get-text-property pt 'message))
1390           (if (setq pt (,property-change pt 'message))
1391               (setq msg (get-text-property pt 'message)))
1392           (error ,error compilation-error))
1393       (or (< (cadr msg) compilation-skip-threshold)
1394           (if different-file
1395               (eq (prog1 last (setq last (nth 2 (car msg))))
1396                   last))
1397           (if compilation-skip-visited
1398               (nthcdr 4 (car msg)))
1399           (if compilation-skip-to-next-location
1400               (eq (car msg) loc))
1401           ;; count this message only if none of the above are true
1402           (setq n (,1+ n)))))
1403
1404 (defun compilation-next-error (n &optional different-file pt)
1405   "Move point to the next error in the compilation buffer.
1406 Prefix arg N says how many error messages to move forwards (or
1407 backwards, if negative).
1408 Does NOT find the source line like \\[next-error]."
1409   (interactive "p")
1410   (or (compilation-buffer-p (current-buffer))
1411       (error "Not in a compilation buffer"))
1412   (or pt (setq pt (point)))
1413   (let* ((msg (get-text-property pt 'message))
1414          (loc (car msg))
1415          last)
1416     (if (zerop n)
1417         (unless (or msg                 ; find message near here
1418                     (setq msg (get-text-property (max (1- pt) (point-min))
1419                                                  'message)))
1420           (setq pt (previous-single-property-change pt 'message nil
1421                                                     (line-beginning-position)))
1422           (unless (setq msg (get-text-property (max (1- pt) (point-min)) 'message))
1423             (setq pt (next-single-property-change pt 'message nil
1424                                                   (line-end-position)))
1425             (or (setq msg (get-text-property pt 'message))
1426                 (setq pt (point)))))
1427       (setq last (nth 2 (car msg)))
1428       (if (>= n 0)
1429           (compilation-loop > next-single-property-change 1-
1430                             (if (get-buffer-process (current-buffer))
1431                                 "No more %ss yet"
1432                               "Moved past last %s"))
1433         ;; Don't move "back" to message at or before point.
1434         ;; Pass an explicit (point-min) to make sure pt is non-nil.
1435         (setq pt (previous-single-property-change pt 'message nil (point-min)))
1436         (compilation-loop < previous-single-property-change 1+
1437                           "Moved back before first %s")))
1438     (goto-char pt)
1439     (or msg
1440         (error "No %s here" compilation-error))))
1441
1442 (defun compilation-previous-error (n)
1443   "Move point to the previous error in the compilation buffer.
1444 Prefix arg N says how many error messages to move backwards (or
1445 forwards, if negative).
1446 Does NOT find the source line like \\[previous-error]."
1447   (interactive "p")
1448   (compilation-next-error (- n)))
1449
1450 (defun compilation-next-file (n)
1451   "Move point to the next error for a different file than the current one.
1452 Prefix arg N says how many files to move forwards (or backwards, if negative)."
1453   (interactive "p")
1454   (compilation-next-error n t))
1455
1456 (defun compilation-previous-file (n)
1457   "Move point to the previous error for a different file than the current one.
1458 Prefix arg N says how many files to move backwards (or forwards, if negative)."
1459   (interactive "p")
1460   (compilation-next-file (- n)))
1461
1462 (defun kill-compilation ()
1463   "Kill the process made by the \\[compile] or \\[grep] commands."
1464   (interactive)
1465   (let ((buffer (compilation-find-buffer)))
1466     (if (get-buffer-process buffer)
1467         (interrupt-process (get-buffer-process buffer))
1468       (error "The compilation process is not running"))))
1469
1470 (defalias 'compile-mouse-goto-error 'compile-goto-error)
1471
1472 (defun compile-goto-error (&optional event)
1473   "Visit the source for the error message at point.
1474 Use this command in a compilation log buffer.  Sets the mark at point there."
1475   (interactive (list last-input-event))
1476   (if event (posn-set-point (event-end event)))
1477   (or (compilation-buffer-p (current-buffer))
1478       (error "Not in a compilation buffer"))
1479   (if (get-text-property (point) 'directory)
1480       (dired-other-window (car (get-text-property (point) 'directory)))
1481     (push-mark)
1482     (setq compilation-current-error (point))
1483     (next-error 0)))
1484
1485 ;; Return a compilation buffer.
1486 ;; If the current buffer is a compilation buffer, return it.
1487 ;; Otherwise, look for a compilation buffer and signal an error
1488 ;; if there are none.
1489 (defun compilation-find-buffer (&optional avoid-current)
1490   (next-error-find-buffer avoid-current 'compilation-buffer-internal-p))
1491
1492 ;;;###autoload
1493 (defun compilation-next-error-function (n &optional reset)
1494   (interactive "p")
1495   (set-buffer (compilation-find-buffer))
1496   (when reset
1497     (setq compilation-current-error nil))
1498   (let* ((columns compilation-error-screen-columns) ; buffer's local value
1499          (last 1)
1500          (loc (compilation-next-error (or n 1) nil
1501                                       (or compilation-current-error
1502                                           compilation-messages-start
1503                                           (point-min))))
1504          (end-loc (nth 2 loc))
1505          (marker (point-marker)))
1506     (setq compilation-current-error (point-marker)
1507           overlay-arrow-position
1508             (if (bolp)
1509                 compilation-current-error
1510               (copy-marker (line-beginning-position)))
1511           loc (car loc))
1512     ;; If loc contains no marker, no error in that file has been visited.  If
1513     ;; the marker is invalid the buffer has been killed.  So, recalculate all
1514     ;; markers for that file.
1515     (unless (and (nth 3 loc) (marker-buffer (nth 3 loc)))
1516       (with-current-buffer (compilation-find-file marker (caar (nth 2 loc))
1517                                                   (or (cdar (nth 2 loc))
1518                                                       default-directory))
1519         (save-restriction
1520           (widen)
1521           (goto-char (point-min))
1522           ;; Treat file's found lines in forward order, 1 by 1.
1523           (dolist (line (reverse (cddr (nth 2 loc))))
1524             (when (car line)            ; else this is a filename w/o a line#
1525               (beginning-of-line (- (car line) last -1))
1526               (setq last (car line)))
1527             ;; Treat line's found columns and store/update a marker for each.
1528             (dolist (col (cdr line))
1529               (if (car col)
1530                   (if (eq (car col) -1) ; special case for range end
1531                       (end-of-line)
1532                     (compilation-move-to-column (car col) columns))
1533                 (beginning-of-line)
1534                 (skip-chars-forward " \t"))
1535               (if (nth 3 col)
1536                   (set-marker (nth 3 col) (point))
1537                 (setcdr (nthcdr 2 col) `(,(point-marker)))))))))
1538     (compilation-goto-locus marker (nth 3 loc) (nth 3 end-loc))
1539     (setcdr (nthcdr 3 loc) t)))         ; Set this one as visited.
1540
1541 (defvar compilation-gcpro nil
1542   "Internal variable used to keep some values from being GC'd.")
1543 (make-variable-buffer-local 'compilation-gcpro)
1544
1545 (defun compilation-fake-loc (marker file &optional line col)
1546   "Preassociate MARKER with FILE.
1547 FILE should be ABSOLUTE-FILENAME or (RELATIVE-FILENAME . DIRNAME).
1548 This is useful when you compile temporary files, but want
1549 automatic translation of the messages to the real buffer from
1550 which the temporary file came.  This only works if done before a
1551 message about FILE appears!
1552
1553 Optional args LINE and COL default to 1 and beginning of
1554 indentation respectively.  The marker is expected to reflect
1555 this.  In the simplest case the marker points to the first line
1556 of the region that was saved to the temp file.
1557
1558 If you concatenate several regions into the temp file (e.g. a
1559 header with variable assignments and a code region), you must
1560 call this several times, once each for the last line of one
1561 region and the first line of the next region."
1562   (or (consp file) (setq file (list file)))
1563   (setq file (compilation-get-file-structure file))
1564   ;; Between the current call to compilation-fake-loc and the first occurrence
1565   ;; of an error message referring to `file', the data is only kept is the
1566   ;; weak hash-table compilation-locs, so we need to prevent this entry
1567   ;; in compilation-locs from being GC'd away.  --Stef
1568   (push file compilation-gcpro)
1569   (let ((loc (compilation-assq (or line 1) (cdr file))))
1570     (setq loc (compilation-assq col loc))
1571     (if (cdr loc)
1572         (setcdr (cddr loc) (list marker))
1573       (setcdr loc (list line file marker)))
1574     loc))
1575
1576 (defcustom compilation-context-lines 0
1577   "*Display this many lines of leading context before message.
1578 If nil, don't scroll the compilation output window."
1579   :type '(choice integer (const :tag "No window scrolling" nil))
1580   :group 'compilation
1581   :version "22.1")
1582
1583 (defsubst compilation-set-window (w mk)
1584   "Align the compilation output window W with marker MK near top."
1585   (if (integerp compilation-context-lines)
1586       (set-window-start w (save-excursion
1587                             (goto-char mk)
1588                             (beginning-of-line (- 1 compilation-context-lines))
1589                             (point))))
1590   (set-window-point w mk))
1591
1592 (defun compilation-goto-locus (msg mk end-mk)
1593   "Jump to an error corresponding to MSG at MK.
1594 All arguments are markers.  If END-MK is non-nil, mark is set there
1595 and overlay is highlighted between MK and END-MK."
1596   (if (eq (window-buffer (selected-window))
1597           (marker-buffer msg))
1598       ;; If the compilation buffer window is selected,
1599       ;; keep the compilation buffer in this window;
1600       ;; display the source in another window.
1601       (let ((pop-up-windows t))
1602         (pop-to-buffer (marker-buffer mk)))
1603     (if (window-dedicated-p (selected-window))
1604         (pop-to-buffer (marker-buffer mk))
1605       (switch-to-buffer (marker-buffer mk))))
1606   ;; If narrowing gets in the way of going to the right place, widen.
1607   (unless (eq (goto-char mk) (point))
1608     (widen)
1609     (goto-char mk))
1610   (if end-mk
1611       (push-mark end-mk t)
1612     (if mark-active (setq mark-active)))
1613   ;; If hideshow got in the way of
1614   ;; seeing the right place, open permanently.
1615   (dolist (ov (overlays-at (point)))
1616     (when (eq 'hs (overlay-get ov 'invisible))
1617       (delete-overlay ov)
1618       (goto-char mk)))
1619
1620   ;; Show compilation buffer in other window, scrolled to this error.
1621   (let* ((pop-up-windows t)
1622          ;; Use an existing window if it is in a visible frame.
1623          (w (or (get-buffer-window (marker-buffer msg) 'visible)
1624                 ;; Pop up a window.
1625                 (display-buffer (marker-buffer msg))))
1626          (highlight-regexp (with-current-buffer (marker-buffer msg)
1627                              ;; also do this while we change buffer
1628                              (compilation-set-window w msg)
1629                              compilation-highlight-regexp)))
1630     (compilation-set-window-height w)
1631
1632     (when highlight-regexp
1633       (if (timerp next-error-highlight-timer)
1634           (cancel-timer next-error-highlight-timer))
1635       (unless compilation-highlight-overlay
1636         (setq compilation-highlight-overlay
1637               (make-overlay (point-min) (point-min)))
1638         (overlay-put compilation-highlight-overlay 'face 'next-error))
1639       (with-current-buffer (marker-buffer mk)
1640         (save-excursion
1641           (if end-mk (goto-char end-mk) (end-of-line))
1642           (let ((end (point)))
1643             (if mk (goto-char mk) (beginning-of-line))
1644             (if (and (stringp highlight-regexp)
1645                      (re-search-forward highlight-regexp end t))
1646                 (progn
1647                   (goto-char (match-beginning 0))
1648                   (move-overlay compilation-highlight-overlay
1649                                 (match-beginning 0) (match-end 0)
1650                                 (current-buffer)))
1651               (move-overlay compilation-highlight-overlay
1652                             (point) end (current-buffer)))
1653             (if (numberp next-error-highlight)
1654                 (setq next-error-highlight-timer
1655                       (run-at-time next-error-highlight nil 'delete-overlay
1656                                    compilation-highlight-overlay)))
1657             (if (not (or (eq next-error-highlight t)
1658                          (numberp next-error-highlight)))
1659                 (delete-overlay compilation-highlight-overlay))))))
1660     (when (and (eq next-error-highlight 'fringe-arrow))
1661       (setq next-error-overlay-arrow-position
1662             (copy-marker (line-beginning-position))))))
1663
1664 \f
1665 (defun compilation-find-file (marker filename dir &rest formats)
1666   "Find a buffer for file FILENAME.
1667 Search the directories in `compilation-search-path'.
1668 A nil in `compilation-search-path' means to try the
1669 current directory, which is passed in DIR.
1670 If FILENAME is not found at all, ask the user where to find it.
1671 Pop up the buffer containing MARKER and scroll to MARKER if we ask the user."
1672   (or formats (setq formats '("%s")))
1673   (save-excursion
1674     (let ((dirs compilation-search-path)
1675           buffer thisdir fmts name)
1676       (if (file-name-absolute-p filename)
1677           ;; The file name is absolute.  Use its explicit directory as
1678           ;; the first in the search path, and strip it from FILENAME.
1679           (setq filename (abbreviate-file-name (expand-file-name filename))
1680                 dirs (cons (file-name-directory filename) dirs)
1681                 filename (file-name-nondirectory filename)))
1682       ;; Now search the path.
1683       (while (and dirs (null buffer))
1684         (setq thisdir (or (car dirs) dir)
1685               fmts formats)
1686         ;; For each directory, try each format string.
1687         (while (and fmts (null buffer))
1688           (setq name (expand-file-name (format (car fmts) filename) thisdir)
1689                 buffer (and (file-exists-p name)
1690                             (find-file-noselect name))
1691                 fmts (cdr fmts)))
1692         (setq dirs (cdr dirs)))
1693       (or buffer
1694           ;; The file doesn't exist.  Ask the user where to find it.
1695           (let ((pop-up-windows t))
1696             (compilation-set-window (display-buffer (marker-buffer marker))
1697                                     marker)
1698             (let ((name (expand-file-name
1699                          (read-file-name
1700                           (format "Find this error in: (default %s) "
1701                                   filename)
1702                           dir filename t))))
1703               (if (file-directory-p name)
1704                   (setq name (expand-file-name filename name)))
1705               (setq buffer (and (file-exists-p name)
1706                                 (find-file name))))))
1707       ;; Make intangible overlays tangible.
1708       (mapcar (function (lambda (ov)
1709                           (when (overlay-get ov 'intangible)
1710                             (overlay-put ov 'intangible nil))))
1711               (overlays-in (point-min) (point-max)))
1712       buffer)))
1713
1714 (defun compilation-get-file-structure (file &optional fmt)
1715   "Retrieve FILE's file-structure or create a new one.
1716 FILE should be (ABSOLUTE-FILENAME) or (RELATIVE-FILENAME . DIRNAME)."
1717
1718   (or (gethash file compilation-locs)
1719       ;; File was not previously encountered, at least not in the form passed.
1720       ;; Let's normalize it and look again.
1721       (let ((filename (car file))
1722             (default-directory (if (cdr file)
1723                                    (file-truename (cdr file))
1724                                  default-directory)))
1725
1726         ;; Check for a comint-file-name-prefix and prepend it if appropriate.
1727         ;; (This is very useful for compilation-minor-mode in an rlogin-mode
1728         ;; buffer.)
1729         (if (boundp 'comint-file-name-prefix)
1730             (if (file-name-absolute-p filename)
1731                 (setq filename
1732                       (concat (with-no-warnings comint-file-name-prefix) filename))
1733               (setq default-directory
1734                     (file-truename
1735                      (concat (with-no-warnings comint-file-name-prefix) default-directory)))))
1736
1737         ;; If compilation-parse-errors-filename-function is
1738         ;; defined, use it to process the filename.
1739         (when compilation-parse-errors-filename-function
1740           (setq filename
1741                 (funcall compilation-parse-errors-filename-function
1742                          filename)))
1743
1744         ;; Some compilers (e.g. Sun's java compiler, reportedly) produce bogus
1745         ;; file names like "./bar//foo.c" for file "bar/foo.c";
1746         ;; expand-file-name will collapse these into "/foo.c" and fail to find
1747         ;; the appropriate file.  So we look for doubled slashes in the file
1748         ;; name and fix them.
1749         (setq filename (command-line-normalize-file-name filename))
1750
1751         ;; Now eliminate any "..", because find-file would get them wrong.
1752         ;; Make relative and absolute filenames, with or without links, the
1753         ;; same.
1754         (setq filename
1755               (list (abbreviate-file-name
1756                      (file-truename (if (cdr file)
1757                                         (expand-file-name filename)
1758                                       filename)))))
1759
1760         ;; Store it for the possibly unnormalized name
1761         (puthash file
1762                  ;; Retrieve or create file-structure for normalized name
1763                  (or (gethash filename compilation-locs)
1764                      (puthash filename (list filename fmt) compilation-locs))
1765                  compilation-locs))))
1766
1767 (add-to-list 'debug-ignored-errors "^No more [-a-z ]+s yet$")
1768
1769 ;;; Compatibility with the old compile.el.
1770
1771 (defun compile-buffer-substring (n) (if n (match-string n)))
1772
1773 (defun compilation-compat-error-properties (err)
1774   "Map old-style error ERR to new-style message."
1775   ;; Old-style structure is (MARKER (FILE DIR) LINE COL) or
1776   ;; (MARKER . MARKER).
1777   (let ((dst (cdr err)))
1778     (if (markerp dst)
1779         ;; Must start with a face, for font-lock.
1780         `(face nil
1781           message ,(list (list nil nil nil dst) 2)
1782           help-echo "mouse-2: visit the source location"
1783           keymap compilation-button-map
1784           mouse-face highlight)
1785       ;; Too difficult to do it by hand: dispatch to the normal code.
1786       (let* ((file (pop dst))
1787              (line (pop dst))
1788              (col (pop dst))
1789              (filename (pop file))
1790              (dirname (pop file))
1791              (fmt (pop file)))
1792         (compilation-internal-error-properties
1793          (cons filename dirname) line nil col nil 2 fmt)))))
1794
1795 (defun compilation-compat-parse-errors (limit)
1796   (when compilation-parse-errors-function
1797     ;; FIXME: We should remove the rest of the compilation keywords
1798     ;; but we can't do that from here because font-lock is using
1799     ;; the value right now.  --stef
1800     (save-excursion
1801       (setq compilation-error-list nil)
1802       ;; Reset compilation-parsing-end each time because font-lock
1803       ;; might force us the re-parse many times (typically because
1804       ;; some code adds some text-property to the output that we
1805       ;; already parsed).  You might say "why reparse", well:
1806       ;; because font-lock has just removed the `message' property so
1807       ;; have to do it all over again.
1808       (if compilation-parsing-end
1809           (set-marker compilation-parsing-end (point))
1810         (setq compilation-parsing-end (point-marker)))
1811       (condition-case nil
1812           ;; Ignore any error: we're calling this function earlier than
1813           ;; in the old compile.el so things might not all be setup yet.
1814           (funcall compilation-parse-errors-function limit nil)
1815         (error nil))
1816       (dolist (err (if (listp compilation-error-list) compilation-error-list))
1817         (let* ((src (car err))
1818                (dst (cdr err))
1819                (loc (cond ((markerp dst) (list nil nil nil dst))
1820                           ((consp dst)
1821                            (list (nth 2 dst) (nth 1 dst)
1822                                  (cons (cdar dst) (caar dst)))))))
1823           (when loc
1824             (goto-char src)
1825             ;; (put-text-property src (line-end-position) 'font-lock-face 'font-lock-warning-face)
1826             (put-text-property src (line-end-position)
1827                                'message (list loc 2)))))))
1828   (goto-char limit)
1829   nil)
1830
1831 ;; Beware: this is not only compatiblity code.  New code stil uses it.  --Stef
1832 (defun compilation-forget-errors ()
1833   ;; In case we hit the same file/line specs, we want to recompute a new
1834   ;; marker for them, so flush our cache.
1835   (setq compilation-locs (make-hash-table :test 'equal :weakness 'value))
1836   (setq compilation-gcpro nil)
1837   ;; FIXME: the old code reset the directory-stack, so maybe we should
1838   ;; put a `directory change' marker of some sort, but where?  -stef
1839   ;;
1840   ;; FIXME: The old code moved compilation-current-error (which was
1841   ;; virtually represented by a mix of compilation-parsing-end and
1842   ;; compilation-error-list) to point-min, but that was only meaningful for
1843   ;; the internal uses of compilation-forget-errors: all calls from external
1844   ;; packages seem to be followed by a move of compilation-parsing-end to
1845   ;; something equivalent to point-max.  So we speculatively move
1846   ;; compilation-current-error to point-max (since the external package
1847   ;; won't know that it should do it).  --stef
1848   (setq compilation-current-error nil)
1849   (let* ((proc (get-buffer-process (current-buffer)))
1850          (mark (if proc (process-mark proc)))
1851          (pos (or mark (point-max))))
1852     (setq compilation-messages-start
1853           ;; In the future, ignore the text already present in the buffer.
1854           ;; Since many process filter functions insert before markers,
1855           ;; we need to put ours just before the insertion point rather
1856           ;; than at the insertion point.  If that's not possible, then
1857           ;; don't use a marker.  --Stef
1858           (if (> pos (point-min)) (copy-marker (1- pos)) pos))))
1859
1860 ;;;###autoload
1861 (add-to-list 'auto-mode-alist '("\\.gcov\\'" . compilation-mode))
1862
1863 (provide 'compile)
1864
1865 ;; arch-tag: 12465727-7382-4f72-b234-79855a00dd8c
1866 ;;; compile.el ends here