code.delx.au - gnu-emacs/blob - lisp/cedet/cedet-global.el

   1 ;;; cedet-global.el --- GNU Global support for CEDET.
   2
   3 ;; Copyright (C) 2008-2016 Free Software Foundation, Inc.
   4
   5 ;; Author: Eric M. Ludlam <eric@siege-engine.com>
   6 ;; Package: cedet
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24 ;;
  25 ;; Basic support for calling GNU Global, and testing version numbers.
  26
  27 (declare-function inversion-check-version "inversion")
  28
  29 (defvar cedet-global-min-version "5.0"
  30   "Minimum version of GNU Global required.")
  31
  32 (defcustom cedet-global-command "global"
  33   "Command name for the GNU Global executable."
  34   :type 'string
  35   :group 'cedet)
  36
  37 (defcustom cedet-global-gtags-command "gtags"
  38   "Command name for the GNU Global gtags executable.
  39 GTAGS is used to create the tags table queried by the `global' command."
  40   :type 'string
  41   :group 'cedet)
  42
  43 ;;; Code:
  44 (defun cedet-gnu-global-search (searchtext texttype type scope)
  45   "Perform a search with GNU Global, return the created buffer.
  46 SEARCHTEXT is text to find.
  47 TEXTTYPE is the type of text, such as 'regexp, 'string, 'tagname,
  48 'tagregexp, or 'tagcompletions.
  49 TYPE is the type of search, meaning that SEARCHTEXT is compared to
  50 filename, tagname (tags table), references (uses of a tag) , or
  51 symbol (uses of something not in the tag table.)
  52 SCOPE is the scope of the search, such as 'project or 'subdirs."
  53   (let ((flgs (cond ((eq type 'file)
  54                      "-a")
  55                     (t "-xa")))
  56         (scopeflgs (cond
  57                     ((eq scope 'project)
  58                      ""
  59                      )
  60                     ((eq scope 'target)
  61                      "l")))
  62         (stflag (cond ((or (eq texttype 'tagname)
  63                            (eq texttype 'tagregexp))
  64                        "")
  65                       ((eq texttype 'tagcompletions)
  66                        "c")
  67                       ((eq texttype 'regexp)
  68                        "g")
  69                       (t "r"))))
  70     (cedet-gnu-global-call (list (concat flgs scopeflgs stflag)
  71                                  searchtext))))
  72
  73 (defun cedet-gnu-global-call (flags)
  74   "Call GNU Global with the list of FLAGS."
  75   (let ((b (get-buffer-create "*CEDET Global*"))
  76         (cd default-directory))
  77     (with-current-buffer b
  78       (setq default-directory cd)
  79       (erase-buffer))
  80     (apply 'call-process cedet-global-command
  81            nil b nil
  82            flags)
  83     b))
  84
  85 (defun cedet-gnu-global-gtags-call (flags)
  86   "Create GNU Global TAGS using gtags with FLAGS."
  87   (let ((b (get-buffer-create "*CEDET Global gtags*"))
  88         (cd default-directory)
  89         )
  90     (with-current-buffer b
  91       (setq default-directory cd)
  92       (erase-buffer))
  93     (apply 'call-process cedet-global-gtags-command
  94            nil b nil
  95            flags)
  96
  97     ;; Check for warnings.
  98     (with-current-buffer b
  99       (goto-char (point-min))
 100       (when (re-search-forward "Error\\|Warning\\|invalid" nil t)
 101         (error "Output:\n%S" (buffer-string))))
 102
 103     b))
 104
 105 (defun cedet-gnu-global-expand-filename (filename)
 106   "Expand the FILENAME with GNU Global.
 107 Return a list of absolute filenames or nil if none found.
 108 Signal an error if Gnu global not available."
 109   (interactive "sFile: ")
 110   (let ((ans (with-current-buffer (cedet-gnu-global-call (list "-Pa" filename))
 111                (goto-char (point-min))
 112                (if (looking-at "global: ")
 113                    (error "GNU Global not available")
 114                  (split-string (buffer-string) "\n" t)))))
 115     (when (called-interactively-p 'interactive)
 116       (if ans
 117           (if (= (length ans) 1)
 118               (message "%s" (car ans))
 119             (message "%s + %d others" (car ans)
 120                      (length (cdr ans))))
 121         (error "No file found")))
 122     ans))
 123
 124 (defun cedet-gnu-global-show-root ()
 125   "Show the root of a GNU Global area under the current buffer."
 126   (interactive)
 127   (message "%s" (cedet-gnu-global-root)))
 128
 129 (defun cedet-gnu-global-root (&optional dir)
 130   "Return the root of any GNU Global scanned project.
 131 If a default starting DIR is not specified, the current buffer's
 132 `default-directory' is used."
 133   (let ((default-directory (or dir default-directory)))
 134     (with-current-buffer (cedet-gnu-global-call (list "-pq"))
 135       (goto-char (point-min))
 136       (when (not (eobp))
 137         (file-name-as-directory
 138          (buffer-substring (point) (point-at-eol)))))))
 139
 140 (defun cedet-gnu-global-version-check (&optional noerror)
 141   "Check the version of the installed GNU Global command.
 142 If optional programmatic argument NOERROR is non-nil,
 143 then instead of throwing an error if Global isn't available,
 144 return nil."
 145   (interactive)
 146   (require 'inversion)
 147   (let ((b (condition-case nil
 148                (cedet-gnu-global-call (list "--version"))
 149              (error nil)))
 150         (rev nil))
 151     (if (not b)
 152         (progn
 153           (when (called-interactively-p 'interactive)
 154             (message "GNU Global not found."))
 155           nil)
 156       (with-current-buffer b
 157         (goto-char (point-min))
 158         (re-search-forward "(?GNU GLOBAL)? \\([0-9.]+\\)" nil t)
 159         (setq rev (match-string 1))
 160         (if (inversion-check-version rev nil cedet-global-min-version)
 161             (if noerror
 162                 nil
 163               (error "Version of GNU Global is %s.  Need at least %s"
 164                      rev cedet-global-min-version))
 165           ;; Else, return TRUE, as in good enough.
 166           (when (called-interactively-p 'interactive)
 167             (message "GNU Global %s  - Good enough for CEDET." rev))
 168           t)))))
 169
 170 (defun cedet-gnu-global-scan-hits (buffer)
 171   "Scan all the hits from the GNU Global output BUFFER."
 172   (let ((hits nil)
 173         (r1 "^\\([^ ]+\\) +\\([0-9]+\\) \\([^ ]+\\) "))
 174     (with-current-buffer buffer
 175       (goto-char (point-min))
 176       (while (re-search-forward r1 nil t)
 177         (setq hits (cons (cons (string-to-number (match-string 2))
 178                                (match-string 3))
 179                          hits)))
 180       ;; Return the results
 181       (nreverse hits))))
 182
 183 (defun cedet-gnu-global-create/update-database (&optional dir)
 184   "Create a GNU Global database in DIR.
 185 If a database already exists, then just update it."
 186   (interactive "DDirectory: ")
 187   (let ((root (cedet-gnu-global-root dir)))
 188     (if root (setq dir root))
 189     (let ((default-directory dir))
 190       (if root
 191           ;; Incremental update. This can be either "gtags -i" or
 192           ;; "global -u"; the gtags manpage says it's better to use
 193           ;; "global -u".
 194           (cedet-gnu-global-call (list "-u"))
 195         (cedet-gnu-global-gtags-call nil)
 196         )
 197       )))
 198
 199 (provide 'cedet-global)
 200
 201 ;;; cedet-global.el ends here