code.delx.au - gnu-emacs/blob - lisp/emacs-lisp/find-func.el

   1 ;;; find-func.el --- find the definition of the Emacs Lisp function near point  -*- lexical-binding:t -*-
   2
   3 ;; Copyright (C) 1997, 1999, 2001-2016 Free Software Foundation, Inc.
   4
   5 ;; Author: Jens Petersen <petersen@kurims.kyoto-u.ac.jp>
   6 ;; Maintainer: petersen@kurims.kyoto-u.ac.jp
   7 ;; Keywords: emacs-lisp, functions, variables
   8 ;; Created: 97/07/25
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26 ;;
  27 ;; The funniest thing about this is that I can't imagine why a package
  28 ;; so obviously useful as this hasn't been written before!!
  29 ;; ;;; find-func
  30 ;; (find-function-setup-keys)
  31 ;;
  32 ;; or just:
  33 ;;
  34 ;; (load "find-func")
  35 ;;
  36 ;; if you don't like the given keybindings and away you go!  It does
  37 ;; pretty much what you would expect, putting the cursor at the
  38 ;; definition of the function or variable at point.
  39 ;;
  40 ;; The code started out from `describe-function', `describe-key'
  41 ;; ("help.el") and `fff-find-loaded-emacs-lisp-function' (Noah Friedman's
  42 ;; "fff.el").
  43
  44 ;;; Code:
  45
  46 ;;; User variables:
  47
  48 (defgroup find-function nil
  49   "Finds the definition of the Emacs Lisp symbol near point."
  50 ;;   :prefix "find-function"
  51   :group 'lisp)
  52
  53 (defconst find-function-space-re "\\(?:\\s-\\|\n\\|;.*\n\\)+")
  54
  55 (defcustom find-function-regexp
  56   ;; Match things like (defun foo ...), (defmacro foo ...),
  57   ;; (define-skeleton foo ...), (define-generic-mode 'foo ...),
  58   ;;  (define-derived-mode foo ...), (define-minor-mode foo)
  59   (concat
  60    "^\\s-*(\\(def\\(ine-skeleton\\|ine-generic-mode\\|ine-derived-mode\\|\
  61 ine\\(?:-global\\)?-minor-mode\\|ine-compilation-mode\\|un-cvs-mode\\|\
  62 foo\\|\\(?:[^icfgv]\\|g[^r]\\)\\(\\w\\|\\s_\\)+\\*?\\)\\|easy-mmode-define-[a-z-]+\\|easy-menu-define\\|\
  63 menu-bar-make-toggle\\)"
  64    find-function-space-re
  65    "\\('\\|(quote \\)?%s\\(\\s-\\|$\\|[()]\\)")
  66   "The regexp used by `find-function' to search for a function definition.
  67 Note it must contain a `%s' at the place where `format'
  68 should insert the function name.  The default value avoids `defconst',
  69 `defgroup', `defvar', `defface'.
  70
  71 Please send improvements and fixes to the maintainer."
  72   :type 'regexp
  73   :group 'find-function
  74   :version "21.1")
  75
  76 (defcustom find-variable-regexp
  77   (concat
  78    "^\\s-*(\\(def[^fumag]\\(\\w\\|\\s_\\)+\\*?\\|\
  79 easy-mmode-def\\(map\\|syntax\\)\\|easy-menu-define\\)"
  80    find-function-space-re
  81    "%s\\(\\s-\\|$\\)")
  82   "The regexp used by `find-variable' to search for a variable definition.
  83 Note it must contain a `%s' at the place where `format'
  84 should insert the variable name.  The default value
  85 avoids `defun', `defmacro', `defalias', `defadvice', `defgroup', `defface'.
  86
  87 Please send improvements and fixes to the maintainer."
  88   :type 'regexp
  89   :group 'find-function
  90   :version "21.1")
  91
  92 (defcustom find-face-regexp
  93   (concat"^\\s-*(defface" find-function-space-re "%s\\(\\s-\\|$\\)")
  94   "The regexp used by `find-face' to search for a face definition.
  95 Note it must contain a `%s' at the place where `format'
  96 should insert the face name.
  97
  98 Please send improvements and fixes to the maintainer."
  99   :type 'regexp
 100   :group 'find-function
 101   :version "22.1")
 102
 103 (defcustom find-feature-regexp
 104   (concat ";;; Code:")
 105   "The regexp used by `xref-find-definitions' when searching for a feature definition.
 106 Note it must contain a `%s' at the place where `format'
 107 should insert the feature name."
 108   ;; We search for ";;; Code" rather than (feature '%s) because the
 109   ;; former is near the start of the code, and the latter is very
 110   ;; uninteresting. If the regexp is not found, just goes to
 111   ;; (point-min), which is acceptable in this case.
 112   :type 'regexp
 113   :group 'xref
 114   :version "25.0")
 115
 116 (defcustom find-alias-regexp
 117   "(defalias +'%s"
 118   "The regexp used by `xref-find-definitions' to search for an alias definition.
 119 Note it must contain a `%s' at the place where `format'
 120 should insert the feature name."
 121   :type 'regexp
 122   :group 'xref
 123   :version "25.0")
 124
 125 (defvar find-function-regexp-alist
 126   '((nil . find-function-regexp)
 127     (defvar . find-variable-regexp)
 128     (defface . find-face-regexp)
 129     (feature . find-feature-regexp)
 130     (defalias . find-alias-regexp))
 131   "Alist mapping definition types into regexp variables.
 132 Each regexp variable's value should actually be a format string
 133 to be used to substitute the desired symbol name into the regexp.
 134 Instead of regexp variable, types can be mapped to functions as well,
 135 in which case the function is called with one argument (the object
 136 we're looking for) and it should search for it.")
 137 (put 'find-function-regexp-alist 'risky-local-variable t)
 138
 139 (defcustom find-function-source-path nil
 140   "The default list of directories where `find-function' searches.
 141
 142 If this variable is nil then `find-function' searches `load-path' by
 143 default."
 144   :type '(repeat directory)
 145   :group 'find-function)
 146
 147 (defcustom find-function-recenter-line 1
 148   "The window line-number from which to start displaying a symbol definition.
 149 A value of nil implies center the beginning of the definition.
 150 See `find-function' and `find-variable'."
 151   :type '(choice (const :tag "Center" nil)
 152                  integer)
 153   :group 'find-function
 154   :version "20.3")
 155
 156 (defcustom find-function-after-hook nil
 157   "Hook run after finding symbol definition.
 158
 159 See the functions `find-function' and `find-variable'."
 160   :type 'hook
 161   :group 'find-function
 162   :version "20.3")
 163
 164 ;;; Functions:
 165
 166 (defun find-library-suffixes ()
 167   (let ((suffixes nil))
 168     (dolist (suffix (get-load-suffixes) (nreverse suffixes))
 169       (unless (string-match "elc" suffix) (push suffix suffixes)))))
 170
 171 (defun find-library--load-name (library)
 172   (let ((name library))
 173     (dolist (dir load-path)
 174       (let ((rel (file-relative-name library dir)))
 175         (if (and (not (string-match "\\`\\.\\./" rel))
 176                  (< (length rel) (length name)))
 177             (setq name rel))))
 178     (unless (equal name library) name)))
 179
 180 (defun find-library-name (library)
 181   "Return the absolute file name of the Emacs Lisp source of LIBRARY.
 182 LIBRARY should be a string (the name of the library)."
 183   ;; If the library is byte-compiled, try to find a source library by
 184   ;; the same name.
 185   (if (string-match "\\.el\\(c\\(\\..*\\)?\\)\\'" library)
 186       (setq library (replace-match "" t t library)))
 187   (or
 188    (locate-file library
 189                 (or find-function-source-path load-path)
 190                 (find-library-suffixes))
 191    (locate-file library
 192                 (or find-function-source-path load-path)
 193                 load-file-rep-suffixes)
 194    (when (file-name-absolute-p library)
 195      (let ((rel (find-library--load-name library)))
 196        (when rel
 197          (or
 198           (locate-file rel
 199                        (or find-function-source-path load-path)
 200                        (find-library-suffixes))
 201           (locate-file rel
 202                        (or find-function-source-path load-path)
 203                        load-file-rep-suffixes)))))
 204    (error "Can't find library %s" library)))
 205
 206 (defvar find-function-C-source-directory
 207   (let ((dir (expand-file-name "src" source-directory)))
 208     (if (file-accessible-directory-p dir) dir))
 209   "Directory where the C source files of Emacs can be found.
 210 If nil, do not try to find the source code of functions and variables
 211 defined in C.")
 212
 213 (declare-function ad-get-advice-info "advice" (function))
 214
 215 (defun find-function-advised-original (func)
 216   "Return the original function definition of an advised function FUNC.
 217 If FUNC is not a symbol, return it.  Else, if it's not advised,
 218 return the symbol's function definition."
 219   (or (and (symbolp func)
 220            (featurep 'nadvice)
 221            (let ((ofunc (advice--symbol-function func)))
 222              (if (advice--p ofunc)
 223                  (advice--cd*r ofunc)
 224                ofunc)))
 225       func))
 226
 227 (defun find-function-C-source (fun-or-var file type)
 228   "Find the source location where FUN-OR-VAR is defined in FILE.
 229 TYPE should be nil to find a function, or `defvar' to find a variable."
 230   (let ((dir (or find-function-C-source-directory
 231                  (read-directory-name "Emacs C source dir: " nil nil t))))
 232     (setq file (expand-file-name file dir))
 233     (if (file-readable-p file)
 234         (if (null find-function-C-source-directory)
 235             (setq find-function-C-source-directory dir))
 236       (error "The C source file %s is not available"
 237              (file-name-nondirectory file))))
 238   (unless type
 239     ;; Either or both an alias and its target might be advised.
 240     (setq fun-or-var (find-function-advised-original
 241                       (indirect-function
 242                        (find-function-advised-original fun-or-var)))))
 243   (with-current-buffer (find-file-noselect file)
 244     (goto-char (point-min))
 245     (unless (re-search-forward
 246              (if type
 247                  (concat "DEFVAR[A-Z_]*[ \t\n]*([ \t\n]*\""
 248                          (regexp-quote (symbol-name fun-or-var))
 249                          "\"")
 250                (concat "DEFUN[ \t\n]*([ \t\n]*\""
 251                        (regexp-quote (subr-name (advice--cd*r fun-or-var)))
 252                        "\""))
 253              nil t)
 254       (error "Can't find source for %s" fun-or-var))
 255     (cons (current-buffer) (match-beginning 0))))
 256
 257 ;;;###autoload
 258 (defun find-library (library)
 259   "Find the Emacs Lisp source of LIBRARY.
 260 LIBRARY should be a string (the name of the library)."
 261   (interactive
 262    (let* ((dirs (or find-function-source-path load-path))
 263           (suffixes (find-library-suffixes))
 264           (table (apply-partially 'locate-file-completion-table
 265                                   dirs suffixes))
 266           (def (if (eq (function-called-at-point) 'require)
 267                    ;; `function-called-at-point' may return 'require
 268                    ;; with `point' anywhere on this line.  So wrap the
 269                    ;; `save-excursion' below in a `condition-case' to
 270                    ;; avoid reporting a scan-error here.
 271                    (condition-case nil
 272                        (save-excursion
 273                          (backward-up-list)
 274                          (forward-char)
 275                          (forward-sexp 2)
 276                          (thing-at-point 'symbol))
 277                      (error nil))
 278                  (thing-at-point 'symbol))))
 279      (when (and def (not (test-completion def table)))
 280        (setq def nil))
 281      (list
 282       (completing-read (if def (format "Library name (default %s): " def)
 283                          "Library name: ")
 284                        table nil nil nil nil def))))
 285   (let ((buf (find-file-noselect (find-library-name library))))
 286     (condition-case nil (switch-to-buffer buf) (error (pop-to-buffer buf)))))
 287
 288 ;;;###autoload
 289 (defun find-function-search-for-symbol (symbol type library)
 290   "Search for SYMBOL's definition of type TYPE in LIBRARY.
 291 Visit the library in a buffer, and return a cons cell (BUFFER . POSITION),
 292 or just (BUFFER . nil) if the definition can't be found in the file.
 293
 294 If TYPE is nil, look for a function definition.
 295 Otherwise, TYPE specifies the kind of definition,
 296 and it is interpreted via `find-function-regexp-alist'.
 297 The search is done in the source for library LIBRARY."
 298   (if (null library)
 299       (error "Don't know where `%s' is defined" symbol))
 300   ;; Some functions are defined as part of the construct
 301   ;; that defines something else.
 302   (while (and (symbolp symbol) (get symbol 'definition-name))
 303     (setq symbol (get symbol 'definition-name)))
 304   (if (string-match "\\`src/\\(.*\\.\\(c\\|m\\)\\)\\'" library)
 305       (find-function-C-source symbol (match-string 1 library) type)
 306     (when (string-match "\\.el\\(c\\)\\'" library)
 307       (setq library (substring library 0 (match-beginning 1))))
 308     ;; Strip extension from .emacs.el to make sure symbol is searched in
 309     ;; .emacs too.
 310     (when (string-match "\\.emacs\\(.el\\)" library)
 311       (setq library (substring library 0 (match-beginning 1))))
 312     (let* ((filename (find-library-name library))
 313            (regexp-symbol (cdr (assq type find-function-regexp-alist))))
 314       (with-current-buffer (find-file-noselect filename)
 315         (let ((regexp (if (functionp regexp-symbol) regexp-symbol
 316                         (format (symbol-value regexp-symbol)
 317                                 ;; Entry for ` (backquote) macro in loaddefs.el,
 318                                 ;; (defalias (quote \`)..., has a \ but
 319                                 ;; (symbol-name symbol) doesn't.  Add an
 320                                 ;; optional \ to catch this.
 321                                 (concat "\\\\?"
 322                                         (regexp-quote (symbol-name symbol))))))
 323               (case-fold-search))
 324           (with-syntax-table emacs-lisp-mode-syntax-table
 325             (goto-char (point-min))
 326             (if (if (functionp regexp)
 327                     (funcall regexp symbol)
 328                   (or (re-search-forward regexp nil t)
 329                       ;; `regexp' matches definitions using known forms like
 330                       ;; `defun', or `defvar'.  But some functions/variables
 331                       ;; are defined using special macros (or functions), so
 332                       ;; if `regexp' can't find the definition, we look for
 333                       ;; something of the form "(SOMETHING <symbol> ...)".
 334                       ;; This fails to distinguish function definitions from
 335                       ;; variable declarations (or even uses thereof), but is
 336                       ;; a good pragmatic fallback.
 337                       (re-search-forward
 338                        (concat "^([^ ]+" find-function-space-re "['(]?"
 339                                (regexp-quote (symbol-name symbol))
 340                                "\\_>")
 341                        nil t)))
 342                 (progn
 343                   (beginning-of-line)
 344                   (cons (current-buffer) (point)))
 345               (cons (current-buffer) nil))))))))
 346
 347 (defun find-function-library (function &optional lisp-only verbose)
 348   "Return the pair (ORIG-FUNCTION . LIBRARY) for FUNCTION.
 349
 350 ORIG-FUNCTION is the original name, after removing all advice and
 351 resolving aliases.  LIBRARY is an absolute file name, a relative
 352 file name inside the C sources directory, or a name of an
 353 autoloaded feature.
 354
 355 If ORIG-FUNCTION is a built-in function and LISP-ONLY is non-nil,
 356 signal an error.
 357
 358 If VERBOSE is non-nil, and FUNCTION is an alias, display a
 359 message about the whole chain of aliases."
 360   (let ((def (if (symbolp function)
 361                  (find-function-advised-original function)))
 362         aliases)
 363     ;; FIXME for completeness, it might be nice to print something like:
 364     ;; foo (which is advised), which is an alias for bar (which is advised).
 365     (while (and def (symbolp def))
 366       (or (eq def function)
 367           (not verbose)
 368           (setq aliases (if aliases
 369                             (concat aliases
 370                                     (format-message
 371                                      ", which is an alias for `%s'"
 372                                      (symbol-name def)))
 373                           (format-message "`%s' is an alias for `%s'"
 374                                           function (symbol-name def)))))
 375       (setq function (find-function-advised-original function)
 376             def (find-function-advised-original function)))
 377     (if aliases
 378         (message "%s" aliases))
 379     (cons function
 380           (cond
 381            ((autoloadp def) (nth 1 def))
 382            ((subrp def)
 383             (if lisp-only
 384                 (error "%s is a built-in function" function))
 385             (help-C-file-name def 'subr))
 386            ((symbol-file function 'defun))))))
 387
 388 ;;;###autoload
 389 (defun find-function-noselect (function &optional lisp-only)
 390   "Return a pair (BUFFER . POINT) pointing to the definition of FUNCTION.
 391
 392 Finds the source file containing the definition of FUNCTION
 393 in a buffer and the point of the definition.  The buffer is
 394 not selected.  If the function definition can't be found in
 395 the buffer, returns (BUFFER).
 396
 397 If FUNCTION is a built-in function, this function normally
 398 attempts to find it in the Emacs C sources; however, if LISP-ONLY
 399 is non-nil, signal an error instead.
 400
 401 If the file where FUNCTION is defined is not known, then it is
 402 searched for in `find-function-source-path' if non-nil, otherwise
 403 in `load-path'."
 404   (if (not function)
 405     (error "You didn't specify a function"))
 406   (let ((func-lib (find-function-library function lisp-only t)))
 407     (find-function-search-for-symbol (car func-lib) nil (cdr func-lib))))
 408
 409 (defun find-function-read (&optional type)
 410   "Read and return an interned symbol, defaulting to the one near point.
 411
 412 If TYPE is nil, insist on a symbol with a function definition.
 413 Otherwise TYPE should be `defvar' or `defface'.
 414 If TYPE is nil, defaults using `function-called-at-point',
 415 otherwise uses `variable-at-point'."
 416   (let* ((symb1 (cond ((null type) (function-called-at-point))
 417                       ((eq type 'defvar) (variable-at-point))
 418                       (t (variable-at-point t))))
 419          (symb  (unless (eq symb1 0) symb1))
 420          (predicate (cdr (assq type '((nil . fboundp)
 421                                       (defvar . boundp)
 422                                       (defface . facep)))))
 423          (prompt-type (cdr (assq type '((nil . "function")
 424                                         (defvar . "variable")
 425                                         (defface . "face")))))
 426          (prompt (concat "Find " prompt-type
 427                          (and symb (format " (default %s)" symb))
 428                          ": "))
 429          (enable-recursive-minibuffers t))
 430     (list (intern (completing-read
 431                    prompt obarray predicate
 432                    t nil nil (and symb (symbol-name symb)))))))
 433
 434 (defun find-function-do-it (symbol type switch-fn)
 435   "Find Emacs Lisp SYMBOL in a buffer and display it.
 436 TYPE is nil to search for a function definition,
 437 or else `defvar' or `defface'.
 438
 439 The variable `find-function-recenter-line' controls how
 440 to recenter the display.  SWITCH-FN is the function to call
 441 to display and select the buffer.
 442 See also `find-function-after-hook'.
 443
 444 Set mark before moving, if the buffer already existed."
 445   (let* ((orig-point (point))
 446         (orig-buffers (buffer-list))
 447         (buffer-point (save-excursion
 448                         (find-definition-noselect symbol type)))
 449         (new-buf (car buffer-point))
 450         (new-point (cdr buffer-point)))
 451     (when buffer-point
 452       (when (memq new-buf orig-buffers)
 453         (push-mark orig-point))
 454       (funcall switch-fn new-buf)
 455       (when new-point (goto-char new-point))
 456       (recenter find-function-recenter-line)
 457       (run-hooks 'find-function-after-hook))))
 458
 459 ;;;###autoload
 460 (defun find-function (function)
 461   "Find the definition of the FUNCTION near point.
 462
 463 Finds the source file containing the definition of the function
 464 near point (selected by `function-called-at-point') in a buffer and
 465 places point before the definition.
 466 Set mark before moving, if the buffer already existed.
 467
 468 The library where FUNCTION is defined is searched for in
 469 `find-function-source-path', if non-nil, otherwise in `load-path'.
 470 See also `find-function-recenter-line' and `find-function-after-hook'."
 471   (interactive (find-function-read))
 472   (find-function-do-it function nil 'switch-to-buffer))
 473
 474 ;;;###autoload
 475 (defun find-function-other-window (function)
 476   "Find, in another window, the definition of FUNCTION near point.
 477
 478 See `find-function' for more details."
 479   (interactive (find-function-read))
 480   (find-function-do-it function nil 'switch-to-buffer-other-window))
 481
 482 ;;;###autoload
 483 (defun find-function-other-frame (function)
 484   "Find, in another frame, the definition of FUNCTION near point.
 485
 486 See `find-function' for more details."
 487   (interactive (find-function-read))
 488   (find-function-do-it function nil 'switch-to-buffer-other-frame))
 489
 490 ;;;###autoload
 491 (defun find-variable-noselect (variable &optional file)
 492   "Return a pair `(BUFFER . POINT)' pointing to the definition of VARIABLE.
 493
 494 Finds the library containing the definition of VARIABLE in a buffer and
 495 the point of the definition.  The buffer is not selected.
 496 If the variable's definition can't be found in the buffer, return (BUFFER).
 497
 498 The library where VARIABLE is defined is searched for in FILE or
 499 `find-function-source-path', if non-nil, otherwise in `load-path'."
 500   (if (not variable)
 501       (error "You didn't specify a variable")
 502     (let ((library (or file
 503                        (symbol-file variable 'defvar)
 504                        (help-C-file-name variable 'var))))
 505       (find-function-search-for-symbol variable 'defvar library))))
 506
 507 ;;;###autoload
 508 (defun find-variable (variable)
 509   "Find the definition of the VARIABLE at or before point.
 510
 511 Finds the library containing the definition of the variable
 512 near point (selected by `variable-at-point') in a buffer and
 513 places point before the definition.
 514
 515 Set mark before moving, if the buffer already existed.
 516
 517 The library where VARIABLE is defined is searched for in
 518 `find-function-source-path', if non-nil, otherwise in `load-path'.
 519 See also `find-function-recenter-line' and `find-function-after-hook'."
 520   (interactive (find-function-read 'defvar))
 521   (find-function-do-it variable 'defvar 'switch-to-buffer))
 522
 523 ;;;###autoload
 524 (defun find-variable-other-window (variable)
 525   "Find, in another window, the definition of VARIABLE near point.
 526
 527 See `find-variable' for more details."
 528   (interactive (find-function-read 'defvar))
 529   (find-function-do-it variable 'defvar 'switch-to-buffer-other-window))
 530
 531 ;;;###autoload
 532 (defun find-variable-other-frame (variable)
 533   "Find, in another frame, the definition of VARIABLE near point.
 534
 535 See `find-variable' for more details."
 536   (interactive (find-function-read 'defvar))
 537   (find-function-do-it variable 'defvar 'switch-to-buffer-other-frame))
 538
 539 ;;;###autoload
 540 (defun find-definition-noselect (symbol type &optional file)
 541   "Return a pair `(BUFFER . POINT)' pointing to the definition of SYMBOL.
 542 If the definition can't be found in the buffer, return (BUFFER).
 543 TYPE says what type of definition: nil for a function, `defvar' for a
 544 variable, `defface' for a face.  This function does not switch to the
 545 buffer nor display it.
 546
 547 The library where SYMBOL is defined is searched for in FILE or
 548 `find-function-source-path', if non-nil, otherwise in `load-path'."
 549   (cond
 550    ((not symbol)
 551     (error "You didn't specify a symbol"))
 552    ((null type)
 553     (find-function-noselect symbol))
 554    ((eq type 'defvar)
 555     (find-variable-noselect symbol file))
 556    (t
 557     (let ((library (or file (symbol-file symbol type))))
 558       (find-function-search-for-symbol symbol type library)))))
 559
 560 ;; For symmetry, this should be called find-face; but some programs
 561 ;; assume that, if that name is defined, it means something else.
 562 ;;;###autoload
 563 (defun find-face-definition (face)
 564   "Find the definition of FACE.  FACE defaults to the name near point.
 565
 566 Finds the Emacs Lisp library containing the definition of the face
 567 near point (selected by `variable-at-point') in a buffer and
 568 places point before the definition.
 569
 570 Set mark before moving, if the buffer already existed.
 571
 572 The library where FACE is defined is searched for in
 573 `find-function-source-path', if non-nil, otherwise in `load-path'.
 574 See also `find-function-recenter-line' and `find-function-after-hook'."
 575   (interactive (find-function-read 'defface))
 576   (find-function-do-it face 'defface 'switch-to-buffer))
 577
 578 (defun find-function-on-key-do-it (key find-fn)
 579   "Find the function that KEY invokes.  KEY is a string.
 580 Set mark before moving, if the buffer already existed.
 581
 582 FIND-FN is the function to call to navigate to the function."
 583   (let (defn)
 584     (save-excursion
 585       (let* ((event (and (eventp key) (aref key 0))) ; Null event OK below.
 586              (start (event-start event))
 587              (modifiers (event-modifiers event))
 588              (window (and (or (memq 'click modifiers) (memq 'down modifiers)
 589                               (memq 'drag modifiers))
 590                           (posn-window start))))
 591         ;; For a mouse button event, go to the button it applies to
 592         ;; to get the right key bindings.  And go to the right place
 593         ;; in case the keymap depends on where you clicked.
 594         (when (windowp window)
 595           (set-buffer (window-buffer window))
 596           (goto-char (posn-point start)))
 597         (setq defn (key-binding key))))
 598     (let ((key-desc (key-description key)))
 599       (if (or (null defn) (integerp defn))
 600           (message "%s is unbound" key-desc)
 601         (if (consp defn)
 602             (message "%s runs %s" key-desc (prin1-to-string defn))
 603           (funcall find-fn defn))))))
 604
 605 ;;;###autoload
 606 (defun find-function-on-key (key)
 607   "Find the function that KEY invokes.  KEY is a string.
 608 Set mark before moving, if the buffer already existed."
 609   (interactive "kFind function on key: ")
 610   (find-function-on-key-do-it key #'find-function))
 611
 612 ;;;###autoload
 613 (defun find-function-on-key-other-window (key)
 614   "Find, in the other window, the function that KEY invokes.
 615 See `find-function-on-key'."
 616   (interactive "kFind function on key: ")
 617   (find-function-on-key-do-it key #'find-function-other-window))
 618
 619 ;;;###autoload
 620 (defun find-function-on-key-other-frame (key)
 621   "Find, in the other frame, the function that KEY invokes.
 622 See `find-function-on-key'."
 623   (interactive "kFind function on key: ")
 624   (find-function-on-key-do-it key #'find-function-other-frame))
 625
 626 ;;;###autoload
 627 (defun find-function-at-point ()
 628   "Find directly the function at point in the other window."
 629   (interactive)
 630   (let ((symb (function-called-at-point)))
 631     (when symb
 632       (find-function-other-window symb))))
 633
 634 ;;;###autoload
 635 (defun find-variable-at-point ()
 636   "Find directly the variable at point in the other window."
 637   (interactive)
 638   (let ((symb (variable-at-point)))
 639     (when (and symb (not (equal symb 0)))
 640       (find-variable-other-window symb))))
 641
 642 ;;;###autoload
 643 (defun find-function-setup-keys ()
 644   "Define some key bindings for the find-function family of functions."
 645   (define-key ctl-x-map "F" 'find-function)
 646   (define-key ctl-x-4-map "F" 'find-function-other-window)
 647   (define-key ctl-x-5-map "F" 'find-function-other-frame)
 648   (define-key ctl-x-map "K" 'find-function-on-key)
 649   (define-key ctl-x-4-map "K" 'find-function-on-key-other-window)
 650   (define-key ctl-x-5-map "K" 'find-function-on-key-other-frame)
 651   (define-key ctl-x-map "V" 'find-variable)
 652   (define-key ctl-x-4-map "V" 'find-variable-other-window)
 653   (define-key ctl-x-5-map "V" 'find-variable-other-frame))
 654
 655 (provide 'find-func)
 656
 657 ;;; find-func.el ends here