code.delx.au - gnu-emacs/blob - lisp/eshell/em-dirs.el

   1 ;;; em-dirs.el --- directory navigation commands  -*- lexical-binding:t -*-
   2
   3 ;; Copyright (C) 1999-2016 Free Software Foundation, Inc.
   4
   5 ;; Author: John Wiegley <johnw@gnu.org>
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software: you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation, either version 3 of the License, or
  12 ;; (at your option) any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  21
  22 ;;; Commentary:
  23
  24 ;; The only special feature that Eshell offers in the last-dir-ring.
  25 ;; To view the ring, enter:
  26 ;;
  27 ;;   cd =
  28 ;;
  29 ;; Changing to an index within the ring is done using:
  30 ;;
  31 ;;   cd -      ; same as cd -0
  32 ;;   cd -4
  33 ;;
  34 ;; Or, it is possible to change the first member in the ring which
  35 ;; matches a regexp:
  36 ;;
  37 ;;   cd =bcc   ; change to the last directory visited containing "bcc"
  38 ;;
  39 ;; This ring is maintained automatically, and is persisted across
  40 ;; Eshell sessions.  It is a separate mechanism from `pushd' and
  41 ;; `popd', and the two may be used at the same time.
  42
  43 ;;; Code:
  44
  45 (require 'eshell)
  46 (require 'ring)
  47 (require 'esh-opt)
  48
  49 ;;;###autoload
  50 (progn
  51 (defgroup eshell-dirs nil
  52   "Directory navigation involves changing directories, examining the
  53 current directory, maintaining a directory stack, and also keeping
  54 track of a history of the last directory locations the user was in.
  55 Emacs does provide standard Lisp definitions of `pwd' and `cd', but
  56 they lack somewhat in feel from the typical shell equivalents."
  57   :tag "Directory navigation"
  58   :group 'eshell-module))
  59
  60 ;;; User Variables:
  61
  62 (defcustom eshell-dirs-load-hook nil
  63   "A hook that gets run when `eshell-dirs' is loaded."
  64   :version "24.1"                       ; removed eshell-dirs-initialize
  65   :type 'hook
  66   :group 'eshell-dirs)
  67
  68 (defcustom eshell-pwd-convert-function (if (eshell-under-windows-p)
  69                                            'expand-file-name
  70                                          'identity)
  71   "The function used to normalize the value of Eshell's `pwd'.
  72 The value returned by `pwd' is also used when recording the
  73 last-visited directory in the last-dir-ring, so it will affect the
  74 form of the list used by `cd ='."
  75   :type '(radio (function-item file-truename)
  76                 (function-item expand-file-name)
  77                 (function-item identity)
  78                 (function :tag "Other"))
  79   :group 'eshell-dirs)
  80
  81 (defcustom eshell-ask-to-save-last-dir 'always
  82   "Determine if the last-dir-ring should be automatically saved.
  83 The last-dir-ring is always preserved when exiting an Eshell buffer.
  84 However, when Emacs is being shut down, this variable determines
  85 whether to prompt the user, or just save the ring.
  86 If set to nil, it means never ask whether to save the last-dir-ring.
  87 If set to t, always ask if any Eshell buffers are open at exit time.
  88 If set to `always', the list-dir-ring will always be saved, silently."
  89   :type '(choice (const :tag "Never" nil)
  90                  (const :tag "Ask" t)
  91                  (const :tag "Always save" always))
  92   :group 'eshell-dirs)
  93
  94 (defcustom eshell-cd-shows-directory nil
  95   "If non-nil, using `cd' will report the directory it changes to."
  96   :type 'boolean
  97   :group 'eshell-dirs)
  98
  99 (defcustom eshell-cd-on-directory t
 100   "If non-nil, do a cd if a directory is in command position."
 101   :type 'boolean
 102   :group 'eshell-dirs)
 103
 104 (defcustom eshell-directory-change-hook nil
 105   "A hook to run when the current directory changes."
 106   :type 'hook
 107   :group 'eshell-dirs)
 108
 109 (defcustom eshell-list-files-after-cd nil
 110   "If non-nil, call \"ls\" with any remaining args after doing a cd.
 111 This is provided for convenience, since the same effect is easily
 112 achieved by adding a function to `eshell-directory-change-hook' that
 113 calls \"ls\" and references `eshell-last-arguments'."
 114   :type 'boolean
 115   :group 'eshell-dirs)
 116
 117 (defcustom eshell-pushd-tohome nil
 118   "If non-nil, make pushd with no arg behave as `pushd ~' (like `cd').
 119 This mirrors the optional behavior of tcsh."
 120   :type 'boolean
 121   :group 'eshell-dirs)
 122
 123 (defcustom eshell-pushd-dextract nil
 124   "If non-nil, make \"pushd +n\" pop the nth dir to the stack top.
 125 This mirrors the optional behavior of tcsh."
 126   :type 'boolean
 127   :group 'eshell-dirs)
 128
 129 (defcustom eshell-pushd-dunique nil
 130   "If non-nil, make pushd only add unique directories to the stack.
 131 This mirrors the optional behavior of tcsh."
 132   :type 'boolean
 133   :group 'eshell-dirs)
 134
 135 (defcustom eshell-dirtrack-verbose t
 136   "If non-nil, show the directory stack following directory change.
 137 This is effective only if directory tracking is enabled."
 138   :type 'boolean
 139   :group 'eshell-dirs)
 140
 141 (defcustom eshell-last-dir-ring-file-name
 142   (expand-file-name "lastdir" eshell-directory-name)
 143   "If non-nil, name of the file to read/write the last-dir-ring.
 144 See also `eshell-read-last-dir-ring' and `eshell-write-last-dir-ring'.
 145 If it is nil, the last-dir-ring will not be written to disk."
 146   :type 'file
 147   :group 'eshell-dirs)
 148
 149 (defcustom eshell-last-dir-ring-size 32
 150   "If non-nil, the size of the directory history ring.
 151 This ring is added to every time `cd' or `pushd' is used.  It simply
 152 stores the most recent directory locations Eshell has been in.  To
 153 return to the most recent entry, use `cd -' (equivalent to `cd -0').
 154 To return to an older entry, use `cd -N', where N is an integer less
 155 than `eshell-last-dir-ring-size'.  To return to the last directory
 156 matching a particular regexp, use `cd =REGEXP'.  To display the
 157 directory history list, use `cd ='.
 158
 159 This mechanism is very similar to that provided by `pushd', except
 160 it's far more automatic.  `pushd' allows the user to decide which
 161 directories gets pushed, and its size is unlimited.
 162
 163 `eshell-last-dir-ring' is meant for users who don't use `pushd'
 164 explicitly very much, but every once in a while would like to return to
 165 a previously visited directory without having to type in the whole
 166 thing again."
 167   :type 'integer
 168   :group 'eshell-dirs)
 169
 170 (defcustom eshell-last-dir-unique t
 171   "If non-nil, `eshell-last-dir-ring' contains only unique entries."
 172   :type 'boolean
 173   :group 'eshell-dirs)
 174
 175 ;;; Internal Variables:
 176
 177 (defvar eshell-dirstack nil
 178   "List of directories saved by pushd in the Eshell buffer.
 179 Thus, this does not include the current directory.")
 180
 181 (defvar eshell-last-dir-ring nil
 182   "The last directory that Eshell was in.")
 183
 184 ;;; Functions:
 185
 186 (defun eshell-dirs-initialize ()
 187   "Initialize the builtin functions for Eshell."
 188   (make-local-variable 'eshell-variable-aliases-list)
 189   (setq eshell-variable-aliases-list
 190         (append
 191          eshell-variable-aliases-list
 192          '(("-" (lambda (indices)
 193                   (if (not indices)
 194                       (unless (ring-empty-p eshell-last-dir-ring)
 195                         (expand-file-name
 196                          (ring-ref eshell-last-dir-ring 0)))
 197                     (expand-file-name
 198                      (eshell-apply-indices eshell-last-dir-ring indices)))))
 199            ("+" "PWD")
 200            ("PWD" (lambda (indices)
 201                     (expand-file-name (eshell/pwd))) t)
 202            ("OLDPWD" (lambda (indices)
 203                        (unless (ring-empty-p eshell-last-dir-ring)
 204                          (expand-file-name
 205                           (ring-ref eshell-last-dir-ring 0)))) t))))
 206
 207   (when eshell-cd-on-directory
 208     (make-local-variable 'eshell-interpreter-alist)
 209     (setq eshell-interpreter-alist
 210           (cons (cons #'(lambda (file args)
 211                           (eshell-lone-directory-p file))
 212                       'eshell-dirs-substitute-cd)
 213                 eshell-interpreter-alist)))
 214
 215   (add-hook 'eshell-parse-argument-hook
 216             'eshell-parse-user-reference nil t)
 217   (if (eshell-under-windows-p)
 218       (add-hook 'eshell-parse-argument-hook
 219                 'eshell-parse-drive-letter nil t))
 220
 221   (when (eshell-using-module 'eshell-cmpl)
 222     (add-hook 'pcomplete-try-first-hook
 223               'eshell-complete-user-reference nil t))
 224
 225   (make-local-variable 'eshell-dirstack)
 226   (make-local-variable 'eshell-last-dir-ring)
 227
 228   (if eshell-last-dir-ring-file-name
 229       (eshell-read-last-dir-ring))
 230   (unless eshell-last-dir-ring
 231     (setq eshell-last-dir-ring (make-ring eshell-last-dir-ring-size)))
 232
 233   (add-hook 'eshell-exit-hook 'eshell-write-last-dir-ring nil t)
 234
 235   (add-hook 'kill-emacs-hook 'eshell-save-some-last-dir))
 236
 237 (defun eshell-save-some-last-dir ()
 238   "Save the list-dir-ring for any open Eshell buffers."
 239   (dolist (buf (buffer-list))
 240     (if (buffer-live-p buf)
 241         (with-current-buffer buf
 242           (if (and eshell-mode
 243                    eshell-ask-to-save-last-dir
 244                    (or (eq eshell-ask-to-save-last-dir 'always)
 245                        (y-or-n-p
 246                         (format-message
 247                          "Save last dir ring for Eshell buffer `%s'? "
 248                          (buffer-name buf)))))
 249               (eshell-write-last-dir-ring))))))
 250
 251 (defun eshell-lone-directory-p (file)
 252   "Test whether FILE is just a directory name, and not a command name."
 253   (and (file-directory-p file)
 254        (or (file-name-directory file)
 255            (not (eshell-search-path file)))))
 256
 257 (defun eshell-dirs-substitute-cd (&rest args)
 258   "Substitute the given command for a call to `cd' on that name."
 259   (if (> (length args) 1)
 260       (error "%s: command not found" (car args))
 261     (throw 'eshell-replace-command
 262            (eshell-parse-command "cd" (eshell-flatten-list args)))))
 263
 264 (defun eshell-parse-user-reference ()
 265   "An argument beginning with ~ is a filename to be expanded."
 266   (when (and (not eshell-current-argument)
 267              (eq (char-after) ?~))
 268     (add-to-list 'eshell-current-modifiers 'expand-file-name)
 269     (forward-char)
 270     (char-to-string (char-before))))
 271
 272 (defun eshell-parse-drive-letter ()
 273   "An argument beginning with X:[^/] is a drive letter reference."
 274   (when (and (not eshell-current-argument)
 275              (looking-at "\\([A-Za-z]:\\)\\([^/\\\\]\\|\\'\\)"))
 276     (goto-char (match-end 1))
 277     (let* ((letter (match-string 1))
 278            (regexp (concat "\\`" letter))
 279            (path (eshell-find-previous-directory regexp)))
 280       (concat (or path letter) "/"))))
 281
 282 (defvar pcomplete-stub)
 283 (defvar pcomplete-last-completion-raw)
 284 (declare-function pcomplete-actual-arg "pcomplete")
 285 (declare-function pcomplete-uniqify-list "pcomplete")
 286
 287 (defun eshell-complete-user-reference ()
 288   "If there is a user reference, complete it."
 289   (let ((arg (pcomplete-actual-arg)))
 290     (when (string-match "\\`~[a-z]*\\'" arg)
 291       (setq pcomplete-stub (substring arg 1)
 292             pcomplete-last-completion-raw t)
 293       (throw 'pcomplete-completions
 294              (progn
 295                (eshell-read-user-names)
 296                (pcomplete-uniqify-list
 297                 (mapcar
 298                  (function
 299                   (lambda (user)
 300                     (file-name-as-directory (cdr user))))
 301                  eshell-user-names)))))))
 302
 303 (defun eshell/pwd (&rest args)
 304   "Change output from `pwd' to be cleaner."
 305   (let* ((path default-directory)
 306          (len (length path)))
 307     (if (and (> len 1)
 308              (eq (aref path (1- len)) ?/)
 309              (not (and (eshell-under-windows-p)
 310                        (string-match "\\`[A-Za-z]:[\\\\/]\\'" path))))
 311         (setq path (substring path 0 (1- (length path)))))
 312     (if eshell-pwd-convert-function
 313         (funcall eshell-pwd-convert-function path)
 314       path)))
 315
 316 (defun eshell-expand-multiple-dots (path)
 317   "Convert `...' to `../..', `....' to `../../..', etc..
 318
 319 With the following piece of advice, you can make this functionality
 320 available in most of Emacs, with the exception of filename completion
 321 in the minibuffer:
 322
 323   (defadvice expand-file-name
 324     (before translate-multiple-dots
 325             (filename &optional directory) activate)
 326     (setq filename (eshell-expand-multiple-dots filename)))"
 327   (while (string-match "\\(?:^\\|/\\)\\.\\.\\(\\.+\\)\\(?:$\\|/\\)" path)
 328     (let* ((extra-dots (match-string 1 path))
 329            (len (length extra-dots))
 330            replace-text)
 331       (while (> len 0)
 332         (setq replace-text (concat replace-text "/..")
 333               len (1- len)))
 334       (setq path
 335             (replace-match replace-text t t path 1))))
 336   path)
 337
 338 (defun eshell-find-previous-directory (regexp)
 339   "Find the most recent last-dir matching REGEXP."
 340   (let ((index 0)
 341         (len (ring-length eshell-last-dir-ring))
 342         oldpath)
 343     (if (> (length regexp) 0)
 344         (while (< index len)
 345           (setq oldpath (ring-ref eshell-last-dir-ring index))
 346           (if (string-match regexp oldpath)
 347               (setq index len)
 348             (setq oldpath nil
 349                   index (1+ index)))))
 350     oldpath))
 351
 352 (defun eshell/cd (&rest args)           ; all but first ignored
 353   "Alias to extend the behavior of `cd'."
 354   (setq args (eshell-flatten-list args))
 355   (let ((path (car args))
 356         (subpath (car (cdr args)))
 357         (case-fold-search (eshell-under-windows-p))
 358         handled)
 359     (if (numberp path)
 360         (setq path (number-to-string path)))
 361     (if (numberp subpath)
 362         (setq subpath (number-to-string subpath)))
 363     (cond
 364      (subpath
 365       (let ((curdir (eshell/pwd)))
 366         (if (string-match path curdir)
 367             (setq path (replace-match subpath nil nil curdir))
 368           (error "Path substring `%s' not found" path))))
 369      ((and path (string-match "^-\\([0-9]*\\)$" path))
 370       (let ((index (match-string 1 path)))
 371         (setq path
 372               (ring-remove eshell-last-dir-ring
 373                            (if index
 374                                (string-to-number index)
 375                              0)))))
 376      ((and path (string-match "^=\\(.*\\)$" path))
 377       (let ((oldpath (eshell-find-previous-directory
 378                       (match-string 1 path))))
 379         (if oldpath
 380             (setq path oldpath)
 381           (let ((len (ring-length eshell-last-dir-ring))
 382                 (index 0))
 383             (if (= len 0)
 384                 (error "Directory ring empty"))
 385             (eshell-init-print-buffer)
 386             (while (< index len)
 387               (eshell-buffered-print
 388                (concat (number-to-string index) ": "
 389                        (ring-ref eshell-last-dir-ring index) "\n"))
 390               (setq index (1+ index)))
 391             (eshell-flush)
 392             (setq handled t)))))
 393      (path
 394       (setq path (eshell-expand-multiple-dots path))))
 395     (unless handled
 396       (let ((curdir (eshell/pwd))
 397             (newdir (or path "~")))
 398         (unless (equal curdir newdir)
 399           (eshell-add-to-dir-ring curdir))
 400         (let ((result (cd newdir)))
 401           (and eshell-cd-shows-directory
 402                (eshell-printn result)))
 403         (run-hooks 'eshell-directory-change-hook)
 404         (if eshell-list-files-after-cd
 405             ;; Let-bind eshell-last-command around this?
 406             (eshell-plain-command "ls" (cdr args)))
 407         nil))))
 408
 409 (put 'eshell/cd 'eshell-no-numeric-conversions t)
 410
 411 (defun eshell-add-to-dir-ring (path)
 412   "Add PATH to the last-dir-ring, if applicable."
 413   (unless (and (not (ring-empty-p eshell-last-dir-ring))
 414                (equal path (ring-ref eshell-last-dir-ring 0)))
 415     (if eshell-last-dir-unique
 416         (let ((index 0)
 417               (len (ring-length eshell-last-dir-ring)))
 418           (while (< index len)
 419             (if (equal (ring-ref eshell-last-dir-ring index) path)
 420                 (ring-remove eshell-last-dir-ring index)
 421               (setq index (1+ index))))))
 422     (ring-insert eshell-last-dir-ring path)))
 423
 424 ;;; pushd [+n | dir]
 425 (defun eshell/pushd (&rest args)        ; all but first ignored
 426   "Implementation of pushd in Lisp."
 427   (let ((path (car args)))
 428     (cond
 429      ((null path)
 430       ;; no arg -- swap pwd and car of stack unless eshell-pushd-tohome
 431       (cond (eshell-pushd-tohome
 432              (eshell/pushd "~"))
 433             (eshell-dirstack
 434              (let ((old (eshell/pwd)))
 435                (eshell/cd (car eshell-dirstack))
 436                (setq eshell-dirstack (cons old (cdr eshell-dirstack)))
 437                (eshell/dirs t)))
 438             (t
 439              (error "pushd: No other directory"))))
 440      ((string-match "^\\+\\([0-9]\\)" path)
 441       ;; pushd +n
 442       (setq path (string-to-number (match-string 1 path)))
 443       (cond ((> path (length eshell-dirstack))
 444              (error "Directory stack not that deep"))
 445             ((= path 0)
 446              (error "Couldn't cd"))
 447             (eshell-pushd-dextract
 448              (let ((dir (nth (1- path) eshell-dirstack)))
 449                (eshell/popd path)
 450                (eshell/pushd (eshell/pwd))
 451                (eshell/cd dir)
 452                (eshell/dirs t)))
 453             (t
 454              (let* ((ds (cons (eshell/pwd) eshell-dirstack))
 455                     (dslen (length ds))
 456                     (front (nthcdr path ds))
 457                     (back (nreverse (nthcdr (- dslen path) (reverse ds))))
 458                     (new-ds (append front back)))
 459                (eshell/cd (car new-ds))
 460                (setq eshell-dirstack (cdr new-ds))
 461                (eshell/dirs t)))))
 462      (t
 463       ;; pushd <dir>
 464       (let ((old-wd (eshell/pwd)))
 465         (eshell/cd path)
 466         (if (or (null eshell-pushd-dunique)
 467                 (not (member old-wd eshell-dirstack)))
 468             (setq eshell-dirstack (cons old-wd eshell-dirstack)))
 469         (eshell/dirs t)))))
 470   nil)
 471
 472 (put 'eshell/pushd 'eshell-no-numeric-conversions t)
 473
 474 ;;; popd [+n]
 475 (defun eshell/popd (&rest args)
 476   "Implementation of popd in Lisp."
 477   (let ((ref (or (car args) "+0")))
 478     (unless (and (stringp ref)
 479                  (string-match "\\`\\([+-][0-9]+\\)\\'" ref))
 480       (error "popd: bad arg `%s'" ref))
 481     (setq ref (string-to-number (match-string 1 ref)))
 482     (cond ((= ref 0)
 483            (unless eshell-dirstack
 484              (error "popd: Directory stack empty"))
 485            (eshell/cd (car eshell-dirstack))
 486            (setq eshell-dirstack (cdr eshell-dirstack))
 487            (eshell/dirs t))
 488           ((<= (abs ref) (length eshell-dirstack))
 489            (let* ((ds (cons nil eshell-dirstack))
 490                   (cell (nthcdr (if (> ref 0)
 491                                     (1- ref)
 492                                   (+ (length eshell-dirstack) ref)) ds))
 493                   (dir (cadr cell)))
 494              (eshell/cd dir)
 495              (setcdr cell (cdr (cdr cell)))
 496              (setq eshell-dirstack (cdr ds))
 497              (eshell/dirs t)))
 498           (t
 499            (error "Couldn't popd"))))
 500   nil)
 501
 502 (put 'eshell/popd 'eshell-no-numeric-conversions t)
 503
 504 (defun eshell/dirs (&optional if-verbose)
 505   "Implementation of dirs in Lisp."
 506   (when (or (not if-verbose) eshell-dirtrack-verbose)
 507     (let* ((msg "")
 508            (ds (cons (eshell/pwd) eshell-dirstack))
 509            (home (expand-file-name "~/"))
 510            (homelen (length home)))
 511       (while ds
 512         (let ((dir (car ds)))
 513           (and (>= (length dir) homelen)
 514                (string= home (substring dir 0 homelen))
 515                (setq dir (concat "~/" (substring dir homelen))))
 516           (setq msg (concat msg (directory-file-name dir) " "))
 517           (setq ds (cdr ds))))
 518       msg)))
 519
 520 (defun eshell-read-last-dir-ring ()
 521   "Set the buffer's `eshell-last-dir-ring' from a history file."
 522   (let ((file eshell-last-dir-ring-file-name))
 523     (cond
 524      ((or (null file)
 525           (equal file "")
 526           (not (file-readable-p file)))
 527       nil)
 528      (t
 529       (let* ((count 0)
 530              (size eshell-last-dir-ring-size)
 531              (ring (make-ring size)))
 532         (with-temp-buffer
 533           (insert-file-contents file)
 534           ;; Save restriction in case file is already visited...
 535           ;; Watch for those date stamps in history files!
 536           (goto-char (point-max))
 537           (while (and (< count size)
 538                       (re-search-backward "^\\([^\n].*\\)$" nil t))
 539             (ring-insert-at-beginning ring (match-string 1))
 540             (setq count (1+ count)))
 541           ;; never allow the top element to equal the current
 542           ;; directory
 543           (while (and (not (ring-empty-p ring))
 544                       (equal (ring-ref ring 0) (eshell/pwd)))
 545             (ring-remove ring 0)))
 546         (setq eshell-last-dir-ring ring))))))
 547
 548 (defun eshell-write-last-dir-ring ()
 549   "Write the buffer's `eshell-last-dir-ring' to a history file."
 550   (let ((file eshell-last-dir-ring-file-name))
 551     (cond
 552      ((or (null file)
 553           (equal file "")
 554           (null eshell-last-dir-ring)
 555           (ring-empty-p eshell-last-dir-ring))
 556       nil)
 557      ((not (file-writable-p file))
 558       (message "Cannot write last-dir-ring file %s" file))
 559      (t
 560       (let* ((ring eshell-last-dir-ring)
 561              (index (ring-length ring)))
 562         (with-temp-buffer
 563           (while (> index 0)
 564             (setq index (1- index))
 565             (insert (ring-ref ring index) ?\n))
 566           (insert (eshell/pwd) ?\n)
 567           (eshell-with-private-file-modes
 568            (write-region (point-min) (point-max) file nil
 569                          'no-message))))))))
 570
 571 (provide 'em-dirs)
 572
 573 ;; Local Variables:
 574 ;; generated-autoload-file: "esh-groups.el"
 575 ;; End:
 576
 577 ;;; em-dirs.el ends here