code.delx.au - gnu-emacs/blob - lisp/rect.el

   1 ;;; rect.el --- rectangle functions for GNU Emacs  -*- lexical-binding:t -*-
   2
   3 ;; Copyright (C) 1985, 1999-2016 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: Didier Verna <didier@xemacs.org>
   6 ;; Keywords: internal
   7 ;; Package: emacs
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; This package provides the operations on rectangles that are documented
  27 ;; in the Emacs manual.
  28
  29 ;; ### NOTE: this file was almost completely rewritten by Didier Verna
  30 ;; <didier@xemacs.org> in July 1999.
  31
  32 ;;; Code:
  33
  34 (eval-when-compile (require 'cl-lib))
  35
  36 (defgroup rectangle nil
  37   "Operations on rectangles."
  38   :version "25.1"
  39   :group 'editing)
  40
  41 ;; FIXME: this function should be replaced by `apply-on-rectangle'
  42 (defun operate-on-rectangle (function start end coerce-tabs)
  43   "Call FUNCTION for each line of rectangle with corners at START, END.
  44 If COERCE-TABS is non-nil, convert multi-column characters
  45 that span the starting or ending columns on any line
  46 to multiple spaces before calling FUNCTION.
  47 FUNCTION is called with three arguments:
  48  position of start of segment of this line within the rectangle,
  49  number of columns that belong to rectangle but are before that position,
  50  number of columns that belong to rectangle but are after point.
  51 Point is at the end of the segment of this line within the rectangle."
  52   (apply-on-rectangle
  53    (lambda (startcol endcol)
  54      (let (startpos begextra endextra)
  55        (move-to-column startcol coerce-tabs)
  56        (setq begextra (- (current-column) startcol))
  57        (setq startpos (point))
  58        (move-to-column endcol coerce-tabs)
  59        ;; If we overshot, move back one character
  60        ;; so that endextra will be positive.
  61        (if (and (not coerce-tabs) (> (current-column) endcol))
  62            (backward-char 1))
  63        (setq endextra (- endcol (current-column)))
  64        (if (< begextra 0)
  65            (setq endextra (+ endextra begextra)
  66                  begextra 0))
  67        (funcall function startpos begextra endextra)))
  68    start end))
  69
  70 ;;; Crutches to let rectangle's corners be where point can't be
  71 ;; (e.g. in the middle of a TAB, or past the EOL).
  72
  73 (defvar-local rectangle--mark-crutches nil
  74   "(POS . COL) to override the column to use for the mark.")
  75
  76 (defun rectangle--pos-cols (start end &optional window)
  77   ;; At this stage, we don't know which of start/end is point/mark :-(
  78   ;; And in case start=end, it might still be that point and mark have
  79   ;; different crutches!
  80   (let ((cw (window-parameter window 'rectangle--point-crutches)))
  81     (cond
  82      ((eq start (car cw))
  83       (let ((sc (cdr cw))
  84             (ec (if (eq end (car rectangle--mark-crutches))
  85                     (cdr rectangle--mark-crutches)
  86                   (if rectangle--mark-crutches
  87                       (setq rectangle--mark-crutches nil))
  88                   (goto-char end) (current-column))))
  89         (if (eq start end) (cons (min sc ec) (max sc ec)) (cons sc ec))))
  90      ((eq end (car cw))
  91       (if (eq start (car rectangle--mark-crutches))
  92           (cons (cdr rectangle--mark-crutches) (cdr cw))
  93         (if rectangle--mark-crutches (setq rectangle--mark-crutches nil))
  94         (cons (progn (goto-char start) (current-column)) (cdr cw))))
  95      ((progn
  96         (if cw (setf (window-parameter nil 'rectangle--point-crutches) nil))
  97         (eq start (car rectangle--mark-crutches)))
  98       (let ((sc (cdr rectangle--mark-crutches))
  99             (ec (progn (goto-char end) (current-column))))
 100         (if (eq start end) (cons (min sc ec) (max sc ec)) (cons sc ec))))
 101      ((eq end (car rectangle--mark-crutches))
 102       (cons (progn (goto-char start) (current-column))
 103             (cdr rectangle--mark-crutches)))
 104      (t
 105       (if rectangle--mark-crutches (setq rectangle--mark-crutches nil))
 106       (cons (progn (goto-char start) (current-column))
 107             (progn (goto-char end) (current-column)))))))
 108
 109 (defun rectangle--col-pos (col kind)
 110   (let ((c (move-to-column col)))
 111     (if (= c col)
 112         (if (eq kind 'point)
 113             (if (window-parameter nil 'rectangle--point-crutches)
 114                 (setf (window-parameter nil 'rectangle--point-crutches) nil))
 115           (if rectangle--mark-crutches (setq rectangle--mark-crutches nil)))
 116       ;; If move-to-column overshot, move back one char so we're
 117       ;; at the position where rectangle--highlight-for-redisplay
 118       ;; will add the overlay (so that the cursor can be drawn at the
 119       ;; right place).
 120       (when (> c col) (forward-char -1))
 121       (setf (if (eq kind 'point)
 122                 (window-parameter nil 'rectangle--point-crutches)
 123               rectangle--mark-crutches)
 124             (cons (point) col)))))
 125
 126 (defun rectangle--point-col (pos)
 127   (let ((pc (window-parameter nil 'rectangle--point-crutches)))
 128     (if (eq pos (car pc)) (cdr pc)
 129       (goto-char pos)
 130       (current-column))))
 131
 132 (defun rectangle--crutches ()
 133   (cons rectangle--mark-crutches
 134         (window-parameter nil 'rectangle--point-crutches)))
 135 (defun rectangle--reset-crutches ()
 136   (kill-local-variable 'rectangle--mark-crutches)
 137   (if (window-parameter nil 'rectangle--point-crutches)
 138       (setf (window-parameter nil 'rectangle--point-crutches) nil)))
 139
 140 ;;; Rectangle operations.
 141
 142 (defun apply-on-rectangle (function start end &rest args)
 143   "Call FUNCTION for each line of rectangle with corners at START, END.
 144 FUNCTION is called with two arguments: the start and end columns of the
 145 rectangle, plus ARGS extra arguments.  Point is at the beginning of line when
 146 the function is called.
 147 The final point after the last operation will be returned."
 148   (save-excursion
 149     (let* ((cols (rectangle--pos-cols start end))
 150            (startcol (car cols))
 151            (endcol (cdr cols))
 152            (startpt (progn (goto-char start) (line-beginning-position)))
 153            (endpt (progn (goto-char end)
 154                          (copy-marker (line-end-position))))
 155            final-point)
 156       ;; Ensure the start column is the left one.
 157       (if (< endcol startcol)
 158           (let ((col startcol))
 159             (setq startcol endcol endcol col)))
 160       ;; Start looping over lines.
 161       (goto-char startpt)
 162       (while
 163           (progn
 164             (apply function startcol endcol args)
 165             (setq final-point (point))
 166             (and (zerop (forward-line 1)) (bolp)
 167                  (<= (point) endpt))))
 168       final-point)))
 169
 170 (defun delete-rectangle-line (startcol endcol fill)
 171   (when (= (move-to-column startcol (if fill t 'coerce)) startcol)
 172     (delete-region (point)
 173                    (progn (move-to-column endcol 'coerce)
 174                           (point)))))
 175
 176 (defun delete-extract-rectangle-line (startcol endcol lines fill)
 177   (let ((pt (point-at-eol)))
 178     (if (< (move-to-column startcol (if fill t 'coerce)) startcol)
 179         (setcdr lines (cons (spaces-string (- endcol startcol))
 180                             (cdr lines)))
 181       ;; else
 182       (setq pt (point))
 183       (move-to-column endcol t)
 184       (setcdr lines (cons (filter-buffer-substring pt (point) t) (cdr lines))))
 185     ))
 186
 187 ;; This is actually the only function that needs to do complicated
 188 ;; stuff like what's happening in `operate-on-rectangle', because the
 189 ;; buffer might be read-only.
 190 (defun extract-rectangle-line (startcol endcol lines)
 191   (let (start end begextra endextra line)
 192     (move-to-column startcol)
 193     (setq start (point)
 194           begextra (- (current-column) startcol))
 195     (move-to-column endcol)
 196     (setq end (point)
 197           endextra (- endcol (current-column)))
 198     (setq line (buffer-substring start (point)))
 199     (if (< begextra 0)
 200         (setq endextra (+ endextra begextra)
 201               begextra 0))
 202     (if (< endextra 0)
 203         (setq endextra 0))
 204     (goto-char start)
 205     (while (search-forward "\t" end t)
 206       (let ((width (- (current-column)
 207                       (save-excursion (forward-char -1)
 208                                       (current-column)))))
 209         (setq line (concat (substring line 0 (- (point) end 1))
 210                            (spaces-string width)
 211                            (substring line (+ (length line)
 212                                               (- (point) end)))))))
 213     (if (or (> begextra 0) (> endextra 0))
 214         (setq line (concat (spaces-string begextra)
 215                            line
 216                            (spaces-string endextra))))
 217     (setcdr lines (cons line (cdr lines)))))
 218
 219 (defconst spaces-strings
 220   '["" " " "  " "   " "    " "     " "      " "       " "        "])
 221
 222 (defun spaces-string (n)
 223   "Return a string with N spaces."
 224   (if (<= n 8) (aref spaces-strings n)
 225     (make-string n ?\s)))
 226
 227 ;;;###autoload
 228 (defun delete-rectangle (start end &optional fill)
 229   "Delete (don't save) text in the region-rectangle.
 230 The same range of columns is deleted in each line starting with the
 231 line where the region begins and ending with the line where the region
 232 ends.
 233
 234 When called from a program the rectangle's corners are START and END.
 235 With a prefix (or a FILL) argument, also fill lines where nothing has
 236 to be deleted."
 237   (interactive "*r\nP")
 238   (apply-on-rectangle 'delete-rectangle-line start end fill))
 239
 240 ;;;###autoload
 241 (defun delete-extract-rectangle (start end &optional fill)
 242   "Delete the contents of the rectangle with corners at START and END.
 243 Return it as a list of strings, one for each line of the rectangle.
 244
 245 When called from a program the rectangle's corners are START and END.
 246 With an optional FILL argument, also fill lines where nothing has to be
 247 deleted."
 248   (let ((lines (list nil)))
 249     (apply-on-rectangle 'delete-extract-rectangle-line start end lines fill)
 250     (nreverse (cdr lines))))
 251
 252 ;;;###autoload
 253 (defun extract-rectangle (start end)
 254   "Return the contents of the rectangle with corners at START and END.
 255 Return it as a list of strings, one for each line of the rectangle."
 256   (let ((lines (list nil)))
 257     (apply-on-rectangle 'extract-rectangle-line start end lines)
 258     (nreverse (cdr lines))))
 259
 260 (defun extract-rectangle-bounds (start end)
 261   "Return the bounds of the rectangle with corners at START and END.
 262 Return it as a list of (START . END) positions, one for each line of
 263 the rectangle."
 264   (let (bounds)
 265     (apply-on-rectangle
 266      (lambda (startcol endcol)
 267        (move-to-column startcol)
 268        (push (cons (prog1 (point) (move-to-column endcol)) (point))
 269              bounds))
 270      start end)
 271     (nreverse bounds)))
 272
 273 (defvar killed-rectangle nil
 274   "Rectangle for `yank-rectangle' to insert.")
 275
 276 ;;;###autoload
 277 (defun kill-rectangle (start end &optional fill)
 278   "Delete the region-rectangle and save it as the last killed one.
 279
 280 When called from a program the rectangle's corners are START and END.
 281 You might prefer to use `delete-extract-rectangle' from a program.
 282
 283 With a prefix (or a FILL) argument, also fill lines where nothing has to be
 284 deleted.
 285
 286 If the buffer is read-only, Emacs will beep and refrain from deleting
 287 the rectangle, but put it in the kill ring anyway.  This means that
 288 you can use this command to copy text from a read-only buffer.
 289 \(If the variable `kill-read-only-ok' is non-nil, then this won't
 290 even beep.)"
 291   (interactive "r\nP")
 292   (condition-case nil
 293       (setq killed-rectangle (delete-extract-rectangle start end fill))
 294     ((buffer-read-only text-read-only)
 295      (setq deactivate-mark t)
 296      (setq killed-rectangle (extract-rectangle start end))
 297      (if kill-read-only-ok
 298          (progn (message "Read only text copied to kill ring") nil)
 299        (barf-if-buffer-read-only)
 300        (signal 'text-read-only (list (current-buffer)))))))
 301
 302 ;;;###autoload
 303 (defun copy-rectangle-as-kill (start end)
 304   "Copy the region-rectangle and save it as the last killed one."
 305   (interactive "r")
 306   (setq killed-rectangle (extract-rectangle start end))
 307   (setq deactivate-mark t)
 308   (if (called-interactively-p 'interactive)
 309       (indicate-copied-region (length (car killed-rectangle)))))
 310
 311 ;;;###autoload
 312 (defun yank-rectangle ()
 313   "Yank the last killed rectangle with upper left corner at point."
 314   (interactive "*")
 315   (insert-rectangle killed-rectangle))
 316
 317 ;;;###autoload
 318 (defun insert-rectangle (rectangle)
 319   "Insert text of RECTANGLE with upper left corner at point.
 320 RECTANGLE's first line is inserted at point, its second
 321 line is inserted at a point vertically under point, etc.
 322 RECTANGLE should be a list of strings.
 323 After this command, the mark is at the upper left corner
 324 and point is at the lower right corner."
 325   (let ((lines rectangle)
 326         (insertcolumn (current-column))
 327         (first t))
 328     (push-mark)
 329     (while lines
 330       (or first
 331           (progn
 332            (forward-line 1)
 333            (or (bolp) (insert ?\n))
 334            (move-to-column insertcolumn t)))
 335       (setq first nil)
 336       (insert-for-yank (car lines))
 337       (setq lines (cdr lines)))))
 338
 339 ;;;###autoload
 340 (defun open-rectangle (start end &optional fill)
 341   "Blank out the region-rectangle, shifting text right.
 342
 343 The text previously in the region is not overwritten by the blanks,
 344 but instead winds up to the right of the rectangle.
 345
 346 When called from a program the rectangle's corners are START and END.
 347 With a prefix (or a FILL) argument, fill with blanks even if there is
 348 no text on the right side of the rectangle."
 349   (interactive "*r\nP")
 350   (apply-on-rectangle 'open-rectangle-line start end fill)
 351   (goto-char start))
 352
 353 (defun open-rectangle-line (startcol endcol fill)
 354   (when (= (move-to-column startcol (if fill t 'coerce)) startcol)
 355     (unless (and (not fill)
 356                  (= (point) (point-at-eol)))
 357       (indent-to endcol))))
 358
 359 (defun delete-whitespace-rectangle-line (startcol _endcol fill)
 360   (when (= (move-to-column startcol (if fill t 'coerce)) startcol)
 361     (unless (= (point) (point-at-eol))
 362       (delete-region (point) (progn (skip-syntax-forward " " (point-at-eol))
 363                                     (point))))))
 364
 365 ;;;###autoload
 366 (defalias 'close-rectangle 'delete-whitespace-rectangle) ;; Old name
 367
 368 ;;;###autoload
 369 (defun delete-whitespace-rectangle (start end &optional fill)
 370   "Delete all whitespace following a specified column in each line.
 371 The left edge of the rectangle specifies the position in each line
 372 at which whitespace deletion should begin.  On each line in the
 373 rectangle, all continuous whitespace starting at that column is deleted.
 374
 375 When called from a program the rectangle's corners are START and END.
 376 With a prefix (or a FILL) argument, also fill too short lines."
 377   (interactive "*r\nP")
 378   (apply-on-rectangle 'delete-whitespace-rectangle-line start end fill))
 379
 380 (defvar string-rectangle-history nil)
 381 (defun string-rectangle-line (startcol endcol string delete)
 382   (move-to-column startcol t)
 383   (if delete
 384       (delete-rectangle-line startcol endcol nil))
 385   (insert string))
 386
 387 (defvar-local rectangle--string-preview-state nil)
 388 (defvar-local rectangle--string-preview-window nil)
 389
 390 (defun rectangle--string-flush-preview ()
 391   (mapc #'delete-overlay (nthcdr 3 rectangle--string-preview-state))
 392   (setf (nthcdr 3 rectangle--string-preview-state) nil))
 393
 394 (defun rectangle--string-erase-preview ()
 395   (with-selected-window rectangle--string-preview-window
 396     (rectangle--string-flush-preview)))
 397
 398 (defun rectangle--space-to (col)
 399   (propertize " " 'display `(space :align-to ,col)))
 400
 401 (defface rectangle-preview-face '((t :inherit region))
 402   "The face to use for the `string-rectangle' preview.")
 403
 404 (defcustom rectangle-preview t
 405   "If non-nil, `string-rectangle' will show an-the-fly preview."
 406   :type 'boolean)
 407
 408 (defun rectangle--string-preview ()
 409   (let ((str (minibuffer-contents)))
 410     (when (equal str "")
 411       (setq str (or (car-safe minibuffer-default)
 412                     (if (stringp minibuffer-default) minibuffer-default))))
 413     (when str (setq str (propertize str 'face 'region)))
 414     (with-selected-window rectangle--string-preview-window
 415       (unless (or (null rectangle--string-preview-state)
 416                   (equal str (car rectangle--string-preview-state)))
 417         (rectangle--string-flush-preview)
 418         (apply-on-rectangle
 419          (lambda (startcol endcol)
 420            (let* ((sc (move-to-column startcol))
 421                   (start (if (<= sc startcol) (point)
 422                            (forward-char -1)
 423                            (setq sc (current-column))
 424                            (point)))
 425                   (ec (move-to-column endcol))
 426                   (end (point))
 427                   (ol (make-overlay start end)))
 428              (push ol (nthcdr 3 rectangle--string-preview-state))
 429              ;; FIXME: The extra spacing doesn't interact correctly with
 430              ;; the extra spacing added by the rectangular-region-highlight.
 431              (when (< sc startcol)
 432                (overlay-put ol 'before-string (rectangle--space-to startcol)))
 433              (let ((as (when (< endcol ec)
 434                          ;; (rectangle--space-to ec)
 435                          (spaces-string (- ec endcol))
 436                          )))
 437                (if (= start end)
 438                    (overlay-put ol 'after-string (if as (concat str as) str))
 439                  (overlay-put ol 'display str)
 440                  (if as (overlay-put ol 'after-string as))))))
 441          (nth 1 rectangle--string-preview-state)
 442          (nth 2 rectangle--string-preview-state))))))
 443
 444 ;; FIXME: Should this be turned into inhibit-region-highlight and made to apply
 445 ;; to non-rectangular regions as well?
 446 (defvar rectangle--inhibit-region-highlight nil)
 447
 448 ;;;###autoload
 449 (defun string-rectangle (start end string)
 450   "Replace rectangle contents with STRING on each line.
 451 The length of STRING need not be the same as the rectangle width.
 452
 453 Called from a program, takes three args; START, END and STRING."
 454   (interactive
 455    (progn
 456      (make-local-variable 'rectangle--string-preview-state)
 457      (make-local-variable 'rectangle--inhibit-region-highlight)
 458      (let* ((buf (current-buffer))
 459             (win (if (eq (window-buffer) buf) (selected-window)))
 460             (start (region-beginning))
 461             (end (region-end))
 462             (rectangle--string-preview-state `(nil ,start ,end))
 463             ;; Rectangle-region-highlighting doesn't work well in the presence
 464             ;; of the preview overlays.  We could work harder to try and make
 465             ;; it work better, but it's easier to just disable it temporarily.
 466             (rectangle--inhibit-region-highlight t))
 467        (barf-if-buffer-read-only)
 468        (list start end
 469              (minibuffer-with-setup-hook
 470                  (lambda ()
 471                    (setq rectangle--string-preview-window win)
 472                    (add-hook 'minibuffer-exit-hook
 473                              #'rectangle--string-erase-preview nil t)
 474                    (add-hook 'post-command-hook
 475                              #'rectangle--string-preview nil t))
 476            (read-string (format "String rectangle (default %s): "
 477                                 (or (car string-rectangle-history) ""))
 478                         nil 'string-rectangle-history
 479                             (car string-rectangle-history)))))))
 480   (goto-char
 481    (apply-on-rectangle 'string-rectangle-line start end string t)))
 482
 483 ;;;###autoload
 484 (defalias 'replace-rectangle 'string-rectangle)
 485
 486 ;;;###autoload
 487 (defun string-insert-rectangle (start end string)
 488   "Insert STRING on each line of region-rectangle, shifting text right.
 489
 490 When called from a program, the rectangle's corners are START and END.
 491 The left edge of the rectangle specifies the column for insertion.
 492 This command does not delete or overwrite any existing text."
 493   (interactive
 494    (progn (barf-if-buffer-read-only)
 495           (list
 496            (region-beginning)
 497            (region-end)
 498            (read-string (format "String insert rectangle (default %s): "
 499                                 (or (car string-rectangle-history) ""))
 500                         nil 'string-rectangle-history
 501                         (car string-rectangle-history)))))
 502   (apply-on-rectangle 'string-rectangle-line start end string nil))
 503
 504 ;;;###autoload
 505 (defun clear-rectangle (start end &optional fill)
 506   "Blank out the region-rectangle.
 507 The text previously in the region is overwritten with blanks.
 508
 509 When called from a program the rectangle's corners are START and END.
 510 With a prefix (or a FILL) argument, also fill with blanks the parts of the
 511 rectangle which were empty."
 512   (interactive "*r\nP")
 513   (apply-on-rectangle 'clear-rectangle-line start end fill))
 514
 515 (defun clear-rectangle-line (startcol endcol fill)
 516   (let ((pt (point-at-eol)))
 517     (when (= (move-to-column startcol (if fill t 'coerce)) startcol)
 518       (if (and (not fill)
 519                (<= (save-excursion (goto-char pt) (current-column)) endcol))
 520           (delete-region (point) pt)
 521         ;; else
 522         (setq pt (point))
 523         (move-to-column endcol t)
 524         (setq endcol (current-column))
 525         (delete-region pt (point))
 526         (indent-to endcol)))))
 527
 528 ;; Line numbers for `rectangle-number-line-callback'.
 529 (defvar rectangle-number-line-counter)
 530
 531 (defun rectangle-number-line-callback (start _end format-string)
 532   (move-to-column start t)
 533   (insert (format format-string rectangle-number-line-counter))
 534   (setq rectangle-number-line-counter
 535         (1+ rectangle-number-line-counter)))
 536
 537 (defun rectangle--default-line-number-format (start end start-at)
 538   (concat "%"
 539           (int-to-string (length (int-to-string (+ (count-lines start end)
 540                                                    start-at))))
 541           "d "))
 542
 543 ;;;###autoload
 544 (defun rectangle-number-lines (start end start-at &optional format)
 545   "Insert numbers in front of the region-rectangle.
 546
 547 START-AT, if non-nil, should be a number from which to begin
 548 counting.  FORMAT, if non-nil, should be a format string to pass
 549 to `format' along with the line count.  When called interactively
 550 with a prefix argument, prompt for START-AT and FORMAT."
 551   (interactive
 552    (if current-prefix-arg
 553        (let* ((start (region-beginning))
 554               (end   (region-end))
 555               (start-at (read-number "Number to count from: " 1)))
 556          (list start end start-at
 557                (read-string "Format string: "
 558                             (rectangle--default-line-number-format
 559                              start end start-at))))
 560      (list (region-beginning) (region-end) 1 nil)))
 561   (unless format
 562     (setq format (rectangle--default-line-number-format start end start-at)))
 563   (let ((rectangle-number-line-counter start-at))
 564     (apply-on-rectangle 'rectangle-number-line-callback
 565                         start end format)))
 566
 567 ;;; New rectangle integration with kill-ring.
 568
 569 ;; FIXME: known problems with the new rectangle support:
 570 ;; - lots of commands handle the region without paying attention to its
 571 ;;   rectangular shape.
 572
 573 (add-function :around redisplay-highlight-region-function
 574               #'rectangle--highlight-for-redisplay)
 575 (add-function :around redisplay-unhighlight-region-function
 576               #'rectangle--unhighlight-for-redisplay)
 577 (add-function :around region-extract-function
 578               #'rectangle--extract-region)
 579 (add-function :around region-insert-function
 580               #'rectangle--insert-region)
 581
 582 (defvar rectangle-mark-mode-map
 583   (let ((map (make-sparse-keymap)))
 584     (define-key map [?\C-o] 'open-rectangle)
 585     (define-key map [?\C-t] 'string-rectangle)
 586     (define-key map [remap exchange-point-and-mark]
 587       'rectangle-exchange-point-and-mark)
 588     (dolist (cmd '(right-char left-char forward-char backward-char
 589                    next-line previous-line))
 590       (define-key map (vector 'remap cmd)
 591         (intern (format "rectangle-%s" cmd))))
 592     map)
 593   "Keymap used while marking a rectangular region.")
 594
 595 ;;;###autoload
 596 (define-minor-mode rectangle-mark-mode
 597   "Toggle the region as rectangular.
 598 Activates the region if needed.  Only lasts until the region is deactivated."
 599   nil nil nil
 600   (rectangle--reset-crutches)
 601   (when rectangle-mark-mode
 602     (add-hook 'deactivate-mark-hook
 603               (lambda () (rectangle-mark-mode -1)))
 604     (unless (region-active-p)
 605       (push-mark (point) t t)
 606       (message "Mark set (rectangle mode)"))))
 607
 608 (defun rectangle-exchange-point-and-mark (&optional arg)
 609   "Like `exchange-point-and-mark' but cycles through the rectangle's corners."
 610   (interactive "P")
 611   (if arg
 612       (progn
 613         (setq this-command 'exchange-point-and-mark)
 614         (exchange-point-and-mark arg))
 615     (let* ((p (point))
 616            (repeat (eq this-command last-command))
 617            (m (mark))
 618            (p<m (< p m))
 619            (cols (if p<m (rectangle--pos-cols p m) (rectangle--pos-cols m p)))
 620            (cp (if p<m (car cols) (cdr cols)))
 621            (cm (if p<m (cdr cols) (car cols))))
 622       (if repeat (setq this-command 'exchange-point-and-mark))
 623       (rectangle--reset-crutches)
 624       (goto-char p)
 625       (rectangle--col-pos (if repeat cm cp) 'mark)
 626       (set-mark (point))
 627       (goto-char m)
 628       (rectangle--col-pos (if repeat cp cm) 'point))))
 629
 630 (defun rectangle--*-char (cmd n &optional other-cmd)
 631   ;; Part of the complexity here is that I'm trying to avoid making assumptions
 632   ;; about the L2R/R2L direction of text around point, but this is largely
 633   ;; useless since the rectangles implemented in this file are "logical
 634   ;; rectangles" and not "visual rectangles", so in the presence of
 635   ;; bidirectional text things won't work well anyway.
 636   (if (< n 0) (rectangle--*-char other-cmd (- n))
 637     (let ((col (rectangle--point-col (point))))
 638       (while (> n 0)
 639         (let* ((bol (line-beginning-position))
 640                (eol (line-end-position))
 641                (curcol (current-column))
 642                (nextcol
 643                 (condition-case nil
 644                     (save-excursion
 645                       (funcall cmd 1)
 646                       (cond
 647                        ((> bol (point)) (- curcol 1))
 648                        ((< eol (point)) (+ col (1+ n)))
 649                        (t (current-column))))
 650                   (end-of-buffer (+ col (1+ n)))
 651                   (beginning-of-buffer (- curcol 1))))
 652                (diff (abs (- nextcol col))))
 653           (cond
 654            ((and (< nextcol curcol) (< curcol col))
 655             (let ((curdiff (- col curcol)))
 656               (if (<= curdiff n)
 657                 (progn (cl-decf n curdiff) (setq col curcol))
 658                 (setq col (- col n) n 0))))
 659            ((< nextcol 0) (ding) (setq n 0 col 0)) ;Bumping into BOL!
 660            ((= nextcol curcol) (funcall cmd 1))
 661            (t ;; (> nextcol curcol)
 662             (if (<= diff n)
 663                 (progn (cl-decf n diff) (setq col nextcol))
 664               (setq col (if (< col nextcol) (+ col n) (- col n)) n 0))))))
 665       ;; FIXME: This rectangle--col-pos's move-to-column is wasted!
 666       (rectangle--col-pos col 'point))))
 667
 668 (defun rectangle-right-char (&optional n)
 669   "Like `right-char' but steps into wide chars and moves past EOL."
 670   (interactive "p") (rectangle--*-char #'right-char n #'left-char))
 671 (defun rectangle-left-char (&optional n)
 672   "Like `left-char' but steps into wide chars and moves past EOL."
 673   (interactive "p") (rectangle--*-char #'left-char n #'right-char))
 674
 675 (defun rectangle-forward-char (&optional n)
 676   "Like `forward-char' but steps into wide chars and moves past EOL."
 677   (interactive "p") (rectangle--*-char #'forward-char n #'backward-char))
 678 (defun rectangle-backward-char (&optional n)
 679   "Like `backward-char' but steps into wide chars and moves past EOL."
 680   (interactive "p") (rectangle--*-char #'backward-char n #'forward-char))
 681
 682 (defun rectangle-next-line (&optional n)
 683   "Like `next-line' but steps into wide chars and moves past EOL.
 684 Ignores `line-move-visual'."
 685   (interactive "p")
 686   (let ((col (rectangle--point-col (point))))
 687     (forward-line n)
 688     (rectangle--col-pos col 'point)))
 689 (defun rectangle-previous-line (&optional n)
 690   "Like `previous-line' but steps into wide chars and moves past EOL.
 691 Ignores `line-move-visual'."
 692   (interactive "p")
 693   (let ((col (rectangle--point-col (point))))
 694     (forward-line (- n))
 695     (rectangle--col-pos col 'point)))
 696
 697
 698 (defun rectangle--extract-region (orig &optional delete)
 699   (cond
 700    ((not rectangle-mark-mode)
 701     (funcall orig delete))
 702    ((eq delete 'bounds)
 703     (extract-rectangle-bounds (region-beginning) (region-end)))
 704    (t
 705     (let* ((strs (funcall (if delete
 706                               #'delete-extract-rectangle
 707                             #'extract-rectangle)
 708                           (region-beginning) (region-end)))
 709            (str (mapconcat #'identity strs "\n")))
 710       (when (eq last-command 'kill-region)
 711         ;; Try to prevent kill-region from appending this to some
 712         ;; earlier element.
 713         (setq last-command 'kill-region-dont-append))
 714       (when strs
 715         (put-text-property 0 (length str) 'yank-handler
 716                            `(rectangle--insert-for-yank ,strs t)
 717                            str)
 718         str)))))
 719
 720 (defun rectangle--insert-region (orig strings)
 721   (cond
 722    ((not rectangle-mark-mode)
 723     (funcall orig strings))
 724    (t
 725     (funcall #'insert-rectangle strings))))
 726
 727 (defun rectangle--insert-for-yank (strs)
 728   (push (point) buffer-undo-list)
 729   (let ((undo-at-start buffer-undo-list))
 730     (insert-rectangle strs)
 731     (setq yank-undo-function
 732           (lambda (_start _end)
 733             (undo-start)
 734             (setcar undo-at-start nil)  ;Turn it into a boundary.
 735             (while (not (eq pending-undo-list (cdr undo-at-start)))
 736               (undo-more 1))))))
 737
 738 (defun rectangle--place-cursor (leftcol left str)
 739   (let ((pc (window-parameter nil 'rectangle--point-crutches)))
 740     (if (and (eq left (car pc)) (eq leftcol (cdr pc)))
 741         (put-text-property 0 1 'cursor 1 str))))
 742
 743 (defun rectangle--highlight-for-redisplay (orig start end window rol)
 744   (cond
 745    ((not rectangle-mark-mode)
 746     (funcall orig start end window rol))
 747    (rectangle--inhibit-region-highlight
 748     (funcall redisplay-unhighlight-region-function rol)
 749     nil)
 750    ((and (eq 'rectangle (car-safe rol))
 751          (eq (nth 1 rol) (buffer-chars-modified-tick))
 752          (eq start (nth 2 rol))
 753          (eq end (nth 3 rol))
 754          (equal (rectangle--crutches) (nth 4 rol)))
 755     rol)
 756    (t
 757     (save-excursion
 758       (let* ((nrol nil)
 759              (old (if (eq 'rectangle (car-safe rol))
 760                       (nthcdr 5 rol)
 761                     (funcall redisplay-unhighlight-region-function rol)
 762                     nil)))
 763         (cl-assert (eq (window-buffer window) (current-buffer)))
 764         ;; `rectangle--pos-cols' looks up the `selected-window's parameter!
 765         (with-selected-window window
 766           (apply-on-rectangle
 767            (lambda (leftcol rightcol)
 768              (let* ((mleft (move-to-column leftcol))
 769                     (left (point))
 770                     ;; BEWARE: In the presence of other overlays with
 771                     ;; before/after/display-strings, this happens to move to
 772                     ;; the column "as if the overlays were not applied", which
 773                     ;; is sometimes what we want, tho it can be
 774                     ;; considered a bug in move-to-column (it should arguably
 775                     ;; pay attention to the before/after-string/display
 776                     ;; properties when computing the column).
 777                     (mright (move-to-column rightcol))
 778                     (right (point))
 779                     (ol
 780                      (if (not old)
 781                          (let ((ol (make-overlay left right)))
 782                            (overlay-put ol 'window window)
 783                            (overlay-put ol 'face 'region)
 784                            ol)
 785                        (let ((ol (pop old)))
 786                          (move-overlay ol left right (current-buffer))
 787                          ol))))
 788                ;; `move-to-column' may stop before the column (if bumping into
 789                ;; EOL) or overshoot it a little, when column is in the middle
 790                ;; of a char.
 791                (cond
 792                 ((< mleft leftcol)      ;`leftcol' is past EOL.
 793                  (overlay-put ol 'before-string (rectangle--space-to leftcol))
 794                  (setq mright (max mright leftcol)))
 795                 ((and (> mleft leftcol) ;`leftcol' is in the middle of a char.
 796                       (eq (char-before left) ?\t))
 797                  (setq left (1- left))
 798                  (move-overlay ol left right)
 799                  (goto-char left)
 800                  (overlay-put ol 'before-string (rectangle--space-to leftcol)))
 801                 ((overlay-get ol 'before-string)
 802                  (overlay-put ol 'before-string nil)))
 803                (cond
 804                 ;; While doing rectangle--string-preview, the two sets of
 805                 ;; overlays steps on the other's toes.  I fixed some of the
 806                 ;; problems, but others remain.  The main one is the two
 807                 ;; (rectangle--space-to rightcol) below which try to virtually
 808                 ;; insert missing text, but during "preview", the text is not
 809                 ;; missing (it's provided by preview's own overlay).
 810                 (rectangle--string-preview-state
 811                  (if (overlay-get ol 'after-string)
 812                      (overlay-put ol 'after-string nil)))
 813                 ((< mright rightcol)    ;`rightcol' is past EOL.
 814                  (let ((str (rectangle--space-to rightcol)))
 815                    (put-text-property 0 (length str) 'face 'region str)
 816                    ;; If cursor happens to be here, draw it at the right place.
 817                    (rectangle--place-cursor leftcol left str)
 818                    (overlay-put ol 'after-string str)))
 819                 ((and (> mright rightcol) ;`rightcol's in the middle of a char.
 820                       (eq (char-before right) ?\t))
 821                  (setq right (1- right))
 822                  (move-overlay ol left right)
 823                  (if (= rightcol leftcol)
 824                      (overlay-put ol 'after-string nil)
 825                    (goto-char right)
 826                    (let ((str (rectangle--space-to rightcol)))
 827                      (put-text-property 0 (length str) 'face 'region str)
 828                      (when (= left right)
 829                        (rectangle--place-cursor leftcol left str))
 830                      (overlay-put ol 'after-string str))))
 831                 ((overlay-get ol 'after-string)
 832                  (overlay-put ol 'after-string nil)))
 833                (when (and (= leftcol rightcol) (display-graphic-p))
 834                  ;; Make zero-width rectangles visible!
 835                  (overlay-put ol 'after-string
 836                               (concat (propertize " "
 837                                                   'face '(region (:height 0.2)))
 838                                       (overlay-get ol 'after-string))))
 839                (push ol nrol)))
 840            start end))
 841         (mapc #'delete-overlay old)
 842         `(rectangle ,(buffer-chars-modified-tick)
 843                     ,start ,end ,(rectangle--crutches)
 844                     ,@nrol))))))
 845
 846 (defun rectangle--unhighlight-for-redisplay (orig rol)
 847   (if (not (eq 'rectangle (car-safe rol)))
 848       (funcall orig rol)
 849     (mapc #'delete-overlay (nthcdr 5 rol))
 850     (setcar (cdr rol) nil)))
 851
 852 (provide 'rect)
 853
 854 ;;; rect.el ends here