code.delx.au - gnu-emacs/blob - lisp/iimage.el

   1 ;;; iimage.el --- Inline image minor mode.
   2
   3 ;; Copyright (C) 2004, 2005, 2006, 2007, 2008, 2009, 2010 Free Software Foundation, Inc.
   4
   5 ;; Author: KOSEKI Yoshinori <kose@meadowy.org>
   6 ;; Maintainer: KOSEKI Yoshinori <kose@meadowy.org>
   7 ;; Keywords: multimedia
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; Iimage is a minor mode that displays images, when image-filename
  27 ;; exists in the buffer.
  28 ;; http://www.netlaputa.ne.jp/~kose/Emacs/iimage.html
  29 ;;
  30 ;; Add to your `~/.emacs':
  31 ;; (autoload 'iimage-mode "iimage" "Support Inline image minor mode." t)
  32 ;; (autoload 'turn-on-iimage-mode "iimage" "Turn on Inline image minor mode." t)
  33 ;;
  34 ;; ** Display images in *Info* buffer.
  35 ;;
  36 ;; (add-hook 'info-mode-hook 'turn-on-iimage-mode)
  37 ;;
  38 ;; .texinfo:   @file{file://foo.png}
  39 ;; .info:      `file://foo.png'
  40 ;;
  41 ;; ** Display images in Wiki buffer.
  42 ;;
  43 ;; (add-hook 'wiki-mode-hook 'turn-on-iimage-mode)
  44 ;;
  45 ;; wiki-file:   [[foo.png]]
  46
  47 ;;; Code:
  48
  49 (eval-when-compile
  50   (require 'image-file))
  51
  52 (defgroup iimage nil
  53   "Support for inline images."
  54   :version "22.1"
  55   :group 'image)
  56
  57 (defconst iimage-version "1.1")
  58
  59 (defvar iimage-mode-map
  60   (let ((map (make-sparse-keymap)))
  61     (define-key map "\C-l" 'iimage-recenter)
  62     map))
  63
  64 (defun iimage-recenter (&optional arg)
  65   "Re-draw images and recenter."
  66   (interactive "P")
  67   (iimage-mode-buffer nil)
  68   (iimage-mode-buffer t)
  69   (recenter arg))
  70
  71 (defvar iimage-mode-image-filename-regex
  72   (concat "[-+./_0-9a-zA-Z]+\\."
  73           (regexp-opt (nconc (mapcar #'upcase
  74                                      image-file-name-extensions)
  75                              image-file-name-extensions)
  76                       t)))
  77
  78 (defvar iimage-mode-image-regex-alist
  79   `((,(concat "\\(`?file://\\|\\[\\[\\|<\\|`\\)?"
  80               "\\(" iimage-mode-image-filename-regex "\\)"
  81               "\\(\\]\\]\\|>\\|'\\)?") . 2))
  82   "*Alist of filename REGEXP vs NUM.
  83 Each element looks like (REGEXP . NUM).
  84 NUM specifies which parenthesized expression in the regexp.
  85
  86 Examples of image filename regexps:
  87     file://foo.png
  88     `file://foo.png'
  89     \\[\\[foo.gif]]
  90     <foo.png>
  91      foo.JPG")
  92
  93 (defvar iimage-mode-image-search-path nil
  94   "*List of directories to search for image files for `iimage-mode'.")
  95
  96 ;;;###autoload
  97 (define-obsolete-function-alias 'turn-on-iimage-mode 'iimage-mode "24.1")
  98
  99 (defun turn-off-iimage-mode ()
 100   "Unconditionally turn off iimage mode."
 101   (interactive)
 102   (iimage-mode 0))
 103
 104 (defun iimage-modification-hook (beg end)
 105   "Remove display property if a display region is modified."
 106   ;;(debug-print "ii1 begin %d, end %d\n" beg end)
 107   (let ((inhibit-modification-hooks t)
 108         (beg (previous-single-property-change end 'display
 109                                               nil (line-beginning-position)))
 110         (end (next-single-property-change     beg 'display
 111                                               nil (line-end-position))))
 112     (when (and beg end (plist-get (text-properties-at beg) 'display))
 113       ;;(debug-print "ii2 begin %d, end %d\n" beg end)
 114       (remove-text-properties beg end
 115                               '(display nil modification-hooks nil)))))
 116
 117 (defun iimage-mode-buffer (arg)
 118   "Display images if ARG is non-nil, undisplay them otherwise."
 119   (let ((image-path (cons default-directory iimage-mode-image-search-path))
 120         file)
 121     (with-silent-modifications
 122       (save-excursion
 123         (goto-char (point-min))
 124         (dolist (pair iimage-mode-image-regex-alist)
 125           (while (re-search-forward (car pair) nil t)
 126             (when (and (setq file (match-string (cdr pair)))
 127                        (setq file (locate-file file image-path)))
 128               ;; FIXME: we don't mark our images, so we can't reliably
 129               ;; remove them either (we may leave some of ours, and we
 130               ;; may remove other packages's display properties).
 131               (if arg
 132                   (add-text-properties (match-beginning 0) (match-end 0)
 133                                        `(display ,(create-image file)
 134                                          modification-hooks
 135                                          (iimage-modification-hook)))
 136                 (remove-text-properties (match-beginning 0) (match-end 0)
 137                                         '(display modification-hooks))))))))))
 138
 139 ;;;###autoload
 140 (define-minor-mode iimage-mode
 141   "Toggle inline image minor mode."
 142   :group 'iimage :lighter " iImg" :keymap iimage-mode-map
 143   (iimage-mode-buffer iimage-mode))
 144
 145 (provide 'iimage)
 146
 147 ;; arch-tag: f6f8e29a-08f6-4a12-9496-51e67441ce65
 148 ;;; iimage.el ends here