code.delx.au - gnu-emacs/blob - lisp/buff-menu.el

   1 ;;; buff-menu.el --- Interface for viewing and manipulating buffers
   2
   3 ;; Copyright (C) 1985-1987, 1993-1995, 2000-2012
   4 ;;   Free Software Foundation, Inc.
   5
   6 ;; Maintainer: FSF
   7 ;; Keywords: convenience
   8 ;; Package: emacs
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; The Buffer Menu is used to view, edit, delete, or change attributes
  28 ;; of buffers.  The entry points are C-x C-b (`list-buffers') and
  29 ;; M-x buffer-menu.
  30
  31 ;;; Code:
  32
  33 (require 'tabulated-list)
  34
  35 (defgroup Buffer-menu nil
  36   "Show a menu of all buffers in a buffer."
  37   :group 'tools
  38   :group 'convenience)
  39
  40 (defcustom Buffer-menu-use-header-line t
  41   "If non-nil, use the header line to display Buffer Menu column titles."
  42   :type 'boolean
  43   :group 'Buffer-menu)
  44
  45 (defface buffer-menu-buffer
  46   '((t (:weight bold)))
  47   "Face for buffer names in the Buffer Menu."
  48   :group 'Buffer-menu)
  49 (put 'Buffer-menu-buffer 'face-alias 'buffer-menu-buffer)
  50
  51 (defcustom Buffer-menu-buffer+size-width nil
  52   "Combined width of buffer name and size columns in Buffer Menu.
  53 If nil, use `Buffer-menu-name-width' and `Buffer-menu-size-width'."
  54   :type 'number
  55   :group 'Buffer-menu
  56   :version "24.2")
  57
  58 (make-obsolete-variable 'Buffer-menu-buffer+size-width
  59                         "`Buffer-menu-name-width' and `Buffer-menu-size-width'"
  60                         "24.2")
  61
  62 (defcustom Buffer-menu-name-width 19
  63   "Width of buffer size column in the Buffer Menu."
  64   :type 'number
  65   :group 'Buffer-menu
  66   :version "24.2")
  67
  68 (defcustom Buffer-menu-size-width 7
  69   "Width of buffer name column in the Buffer Menu."
  70   :type 'number
  71   :group 'Buffer-menu
  72   :version "24.2")
  73
  74 (defcustom Buffer-menu-mode-width 16
  75   "Width of mode name column in the Buffer Menu."
  76   :type 'number
  77   :group 'Buffer-menu)
  78
  79 (defcustom Buffer-menu-use-frame-buffer-list t
  80   "If non-nil, the Buffer Menu uses the selected frame's buffer list.
  81 Buffers that were never selected in that frame are listed at the end.
  82 If the value is nil, the Buffer Menu uses the global buffer list.
  83 This variable matters if the Buffer Menu is sorted by visited order,
  84 as it is by default."
  85   :type 'boolean
  86   :group 'Buffer-menu
  87   :version "22.1")
  88
  89 (defvar Buffer-menu-files-only nil
  90   "Non-nil if the current Buffer Menu lists only file buffers.
  91 This is set by the prefix argument to `buffer-menu' and related
  92 commands.")
  93 (make-variable-buffer-local 'Buffer-menu-files-only)
  94
  95 (defvar Info-current-file) ; from info.el
  96 (defvar Info-current-node) ; from info.el
  97
  98 (defvar Buffer-menu-mode-map
  99   (let ((map (make-sparse-keymap))
 100         (menu-map (make-sparse-keymap)))
 101     (set-keymap-parent map tabulated-list-mode-map)
 102     (define-key map "v" 'Buffer-menu-select)
 103     (define-key map "2" 'Buffer-menu-2-window)
 104     (define-key map "1" 'Buffer-menu-1-window)
 105     (define-key map "f" 'Buffer-menu-this-window)
 106     (define-key map "e" 'Buffer-menu-this-window)
 107     (define-key map "\C-m" 'Buffer-menu-this-window)
 108     (define-key map "o" 'Buffer-menu-other-window)
 109     (define-key map "\C-o" 'Buffer-menu-switch-other-window)
 110     (define-key map "s" 'Buffer-menu-save)
 111     (define-key map "d" 'Buffer-menu-delete)
 112     (define-key map "k" 'Buffer-menu-delete)
 113     (define-key map "\C-k" 'Buffer-menu-delete)
 114     (define-key map "\C-d" 'Buffer-menu-delete-backwards)
 115     (define-key map "x" 'Buffer-menu-execute)
 116     (define-key map " " 'next-line)
 117     (define-key map "\177" 'Buffer-menu-backup-unmark)
 118     (define-key map "~" 'Buffer-menu-not-modified)
 119     (define-key map "u" 'Buffer-menu-unmark)
 120     (define-key map "m" 'Buffer-menu-mark)
 121     (define-key map "t" 'Buffer-menu-visit-tags-table)
 122     (define-key map "%" 'Buffer-menu-toggle-read-only)
 123     (define-key map "b" 'Buffer-menu-bury)
 124     (define-key map "V" 'Buffer-menu-view)
 125     (define-key map "T" 'Buffer-menu-toggle-files-only)
 126     (define-key map (kbd "M-s a C-s")   'Buffer-menu-isearch-buffers)
 127     (define-key map (kbd "M-s a M-C-s") 'Buffer-menu-isearch-buffers-regexp)
 128
 129     (define-key map [menu-bar Buffer-menu-mode] (cons (purecopy "Buffer-Menu") menu-map))
 130     (define-key menu-map [quit]
 131       `(menu-item ,(purecopy "Quit") quit-window
 132                  :help ,(purecopy "Remove the buffer menu from the display")))
 133     (define-key menu-map [rev]
 134       `(menu-item ,(purecopy "Refresh") revert-buffer
 135                  :help ,(purecopy "Refresh the *Buffer List* buffer contents")))
 136     (define-key menu-map [s0] menu-bar-separator)
 137     (define-key menu-map [tf]
 138       `(menu-item ,(purecopy "Show Only File Buffers") Buffer-menu-toggle-files-only
 139                   :button (:toggle . Buffer-menu-files-only)
 140                   :help ,(purecopy "Toggle whether the current buffer-menu displays only file buffers")))
 141     (define-key menu-map [s1] menu-bar-separator)
 142     ;; FIXME: The "Select" entries could use better names...
 143     (define-key menu-map [sel]
 144       `(menu-item ,(purecopy "Select Marked") Buffer-menu-select
 145                  :help ,(purecopy "Select this line's buffer; also display buffers marked with `>'")))
 146     (define-key menu-map [bm2]
 147       `(menu-item ,(purecopy "Select Two") Buffer-menu-2-window
 148                  :help ,(purecopy "Select this line's buffer, with previous buffer in second window")))
 149     (define-key menu-map [bm1]
 150       `(menu-item ,(purecopy "Select Current") Buffer-menu-1-window
 151                  :help ,(purecopy "Select this line's buffer, alone, in full frame")))
 152     (define-key menu-map [ow]
 153       `(menu-item ,(purecopy "Select in Other Window") Buffer-menu-other-window
 154                  :help ,(purecopy "Select this line's buffer in other window, leaving buffer menu visible")))
 155     (define-key menu-map [tw]
 156       `(menu-item ,(purecopy "Select in Current Window") Buffer-menu-this-window
 157                  :help ,(purecopy "Select this line's buffer in this window")))
 158     (define-key menu-map [s2] menu-bar-separator)
 159     (define-key menu-map [is]
 160       `(menu-item ,(purecopy "Regexp Isearch Marked Buffers...") Buffer-menu-isearch-buffers-regexp
 161                  :help ,(purecopy "Search for a regexp through all marked buffers using Isearch")))
 162     (define-key menu-map [ir]
 163       `(menu-item ,(purecopy "Isearch Marked Buffers...") Buffer-menu-isearch-buffers
 164                  :help ,(purecopy "Search for a string through all marked buffers using Isearch")))
 165     (define-key menu-map [s3] menu-bar-separator)
 166     (define-key menu-map [by]
 167       `(menu-item ,(purecopy "Bury") Buffer-menu-bury
 168                  :help ,(purecopy "Bury the buffer listed on this line")))
 169     (define-key menu-map [vt]
 170       `(menu-item ,(purecopy "Set Unmodified") Buffer-menu-not-modified
 171                  :help ,(purecopy "Mark buffer on this line as unmodified (no changes to save)")))
 172     (define-key menu-map [ex]
 173       `(menu-item ,(purecopy "Execute") Buffer-menu-execute
 174                  :help ,(purecopy "Save and/or delete buffers marked with s or k commands")))
 175     (define-key menu-map [s4] menu-bar-separator)
 176     (define-key menu-map [delb]
 177       `(menu-item ,(purecopy "Mark for Delete and Move Backwards") Buffer-menu-delete-backwards
 178                  :help ,(purecopy "Mark buffer on this line to be deleted by x command and move up one line")))
 179     (define-key menu-map [del]
 180       `(menu-item ,(purecopy "Mark for Delete") Buffer-menu-delete
 181                  :help ,(purecopy "Mark buffer on this line to be deleted by x command")))
 182
 183     (define-key menu-map [sv]
 184       `(menu-item ,(purecopy "Mark for Save") Buffer-menu-save
 185                  :help ,(purecopy "Mark buffer on this line to be saved by x command")))
 186     (define-key menu-map [umk]
 187       `(menu-item ,(purecopy "Unmark") Buffer-menu-unmark
 188                  :help ,(purecopy "Cancel all requested operations on buffer on this line and move down")))
 189     (define-key menu-map [mk]
 190       `(menu-item ,(purecopy "Mark") Buffer-menu-mark
 191                  :help ,(purecopy "Mark buffer on this line for being displayed by v command")))
 192     map)
 193   "Local keymap for `Buffer-menu-mode' buffers.")
 194
 195 (define-derived-mode Buffer-menu-mode tabulated-list-mode "Buffer Menu"
 196   "Major mode for Buffer Menu buffers.
 197 The Buffer Menu is invoked by the commands \\[list-buffers], \\[buffer-menu], and
 198 \\[buffer-menu-other-window].  See `buffer-menu' for details."
 199   (set (make-local-variable 'buffer-stale-function)
 200        (lambda (&optional _noconfirm) 'fast))
 201   (add-hook 'tabulated-list-revert-hook 'list-buffers--refresh nil t))
 202
 203 (define-obsolete-variable-alias 'buffer-menu-mode-hook
 204   'Buffer-menu-mode-hook "23.1")
 205
 206 (defun buffer-menu (&optional arg)
 207   "Switch to the Buffer Menu.
 208 By default, all buffers are listed except those whose names start
 209 with a space (which are for internal use).  With prefix argument
 210 ARG, show only buffers that are visiting files.
 211
 212 The first column (denoted \"C\") shows \".\" for the buffer from
 213 which you came.  It shows \">\" for buffers you mark to be
 214 displayed, and \"D\" for those you mark for deletion.
 215
 216 The \"R\" column has a \"%\" if the buffer is read-only.
 217 The \"M\" column has a \"*\" if it is modified, or \"S\" if you
 218 have marked it for saving.
 219
 220 After this come the buffer name, its size in characters, its
 221 major mode, and the visited file name (if any).
 222
 223
 224 In the Buffer Menu, the following commands are defined:
 225 \\<Buffer-menu-mode-map>
 226 \\[quit-window]    Remove the Buffer Menu from the display.
 227 \\[Buffer-menu-this-window]  Select current line's buffer in place of the buffer menu.
 228 \\[Buffer-menu-other-window]    Select that buffer in another window,
 229      so the Buffer Menu remains visible in its window.
 230 \\[Buffer-menu-view]    Select current line's buffer, in View mode.
 231 \\[Buffer-menu-view-other-window]  Select that buffer in
 232      another window, in view-mode.
 233 \\[Buffer-menu-switch-other-window]  Make another window display that buffer.
 234 \\[Buffer-menu-mark]    Mark current line's buffer to be displayed.
 235 \\[Buffer-menu-select]    Select current line's buffer.
 236      Also show buffers marked with m, in other windows.
 237 \\[Buffer-menu-1-window]    Select that buffer in full-frame window.
 238 \\[Buffer-menu-2-window]    Select that buffer in one window, together with the
 239      buffer selected before this one in another window.
 240 \\[Buffer-menu-isearch-buffers]  Incremental search in the marked buffers.
 241 \\[Buffer-menu-isearch-buffers-regexp]  Isearch for regexp in the marked buffers.
 242 \\[Buffer-menu-visit-tags-table]    visit-tags-table this buffer.
 243 \\[Buffer-menu-not-modified]    Clear modified-flag on that buffer.
 244 \\[Buffer-menu-save]    Mark that buffer to be saved, and move down.
 245 \\[Buffer-menu-delete]  Mark that buffer to be deleted, and move down.
 246 \\[Buffer-menu-delete-backwards]  Mark that buffer to be deleted, and move up.
 247 \\[Buffer-menu-execute]    Delete or save marked buffers.
 248 \\[Buffer-menu-unmark]    Remove all marks from current line.
 249      With prefix argument, also move up one line.
 250 \\[Buffer-menu-backup-unmark]  Back up a line and remove marks.
 251 \\[Buffer-menu-toggle-read-only]    Toggle read-only status of buffer on this line.
 252 \\[revert-buffer]    Update the list of buffers.
 253 \\[Buffer-menu-toggle-files-only]    Toggle whether the menu displays only file buffers.
 254 \\[Buffer-menu-bury]    Bury the buffer listed on this line."
 255   (interactive "P")
 256   (switch-to-buffer (list-buffers-noselect arg))
 257   (message
 258    "Commands: d, s, x, u; f, o, 1, 2, m, v; ~, %%; q to quit; ? for help."))
 259
 260 (defun buffer-menu-other-window (&optional arg)
 261   "Display the Buffer Menu in another window.
 262 See `buffer-menu' for a description of the Buffer Menu.
 263
 264 By default, all buffers are listed except those whose names start
 265 with a space (which are for internal use).  With prefix argument
 266 ARG, show only buffers that are visiting files."
 267   (interactive "P")
 268   (switch-to-buffer-other-window (list-buffers-noselect arg))
 269   (message
 270    "Commands: d, s, x, u; f, o, 1, 2, m, v; ~, %%; q to quit; ? for help."))
 271
 272 (defun list-buffers (&optional arg)
 273   "Display a list of existing buffers.
 274 The list is displayed in a buffer named \"*Buffer List*\".
 275 See `buffer-menu' for details about the Buffer Menu buffer.
 276
 277 By default, all buffers are listed except those whose names start
 278 with a space (which are for internal use).  With prefix argument
 279 ARG, show only buffers that are visiting files."
 280   (interactive "P")
 281   (display-buffer (list-buffers-noselect arg)))
 282
 283 (defun Buffer-menu-toggle-files-only (arg)
 284   "Toggle whether the current buffer-menu displays only file buffers.
 285 With a positive ARG, display only file buffers.  With zero or
 286 negative ARG, display other buffers as well."
 287   (interactive "P")
 288   (setq Buffer-menu-files-only
 289         (cond ((not arg) (not Buffer-menu-files-only))
 290               ((> (prefix-numeric-value arg) 0) t)))
 291   (message (if Buffer-menu-files-only
 292                "Showing only file-visiting buffers."
 293              "Showing all non-internal buffers."))
 294   (revert-buffer))
 295
 296 (defalias 'Buffer-menu-sort 'tabulated-list-sort)
 297 \f
 298
 299 (defun Buffer-menu-buffer (&optional error-if-non-existent-p)
 300   "Return the buffer described by the current Buffer Menu line.
 301 If there is no buffer here, return nil if ERROR-IF-NON-EXISTENT-P
 302 is nil or omitted, and signal an error otherwise."
 303   (let ((buffer (tabulated-list-get-id)))
 304     (cond ((null buffer)
 305            (if error-if-non-existent-p
 306                (error "No buffer on this line")))
 307           ((not (buffer-live-p buffer))
 308            (if error-if-non-existent-p
 309                (error "This buffer has been killed")))
 310           (t buffer))))
 311
 312 (defun Buffer-menu-no-header ()
 313   (beginning-of-line)
 314   (if (or Buffer-menu-use-header-line
 315           (not (eq (char-after) ?C)))
 316       t
 317     (ding)
 318     (forward-line 1)
 319     nil))
 320
 321 (defun Buffer-menu-beginning ()
 322   (goto-char (point-min))
 323   (unless Buffer-menu-use-header-line
 324     (forward-line)))
 325
 326 \f
 327 ;;; Commands for modifying Buffer Menu entries.
 328
 329 (defun Buffer-menu-mark ()
 330   "Mark the Buffer menu entry at point for later display.
 331 It will be displayed by the \\<Buffer-menu-mode-map>\\[Buffer-menu-select] command."
 332   (interactive)
 333   (tabulated-list-set-col 0 ">" t)
 334   (forward-line))
 335
 336 (defun Buffer-menu-unmark (&optional backup)
 337   "Cancel all requested operations on buffer on this line and move down.
 338 Optional prefix arg means move up."
 339   (interactive "P")
 340   (tabulated-list-set-col 0 " " t)
 341   (forward-line (if backup -1 1)))
 342
 343 (defun Buffer-menu-backup-unmark ()
 344   "Move up and cancel all requested operations on buffer on line above."
 345   (interactive)
 346   (forward-line -1)
 347   (tabulated-list-set-col 0 " " t))
 348
 349 (defun Buffer-menu-delete (&optional arg)
 350   "Mark the buffer on this Buffer Menu buffer line for deletion.
 351 A subsequent \\<Buffer-menu-mode-map>`\\[Buffer-menu-execute]' command
 352 will delete it.
 353
 354 If prefix argument ARG is non-nil, it specifies the number of
 355 buffers to delete; a negative ARG means to delete backwards."
 356   (interactive "p")
 357   (if (or (null arg) (= arg 0))
 358       (setq arg 1))
 359   (while (> arg 0)
 360     (when (Buffer-menu-buffer)
 361       (tabulated-list-set-col 0 "D" t))
 362     (forward-line 1)
 363     (setq arg (1- arg)))
 364   (while (< arg 0)
 365     (when (Buffer-menu-buffer)
 366       (tabulated-list-set-col 0 "D" t))
 367     (forward-line -1)
 368     (setq arg (1+ arg))))
 369
 370 (defun Buffer-menu-delete-backwards (&optional arg)
 371   "Mark the buffer on this Buffer Menu line for deletion, and move up.
 372 Prefix ARG means move that many lines."
 373   (interactive "p")
 374   (Buffer-menu-delete (- (or arg 1))))
 375
 376 (defun Buffer-menu-save ()
 377   "Mark the buffer on this Buffer Menu line for saving.
 378 A subsequent \\<Buffer-menu-mode-map>`\\[Buffer-menu-execute]' command
 379 will save it."
 380   (interactive)
 381   (when (Buffer-menu-buffer)
 382     (tabulated-list-set-col 2 "S" t)
 383     (forward-line 1)))
 384
 385 (defun Buffer-menu-not-modified (&optional arg)
 386   "Mark the buffer on this line as unmodified (no changes to save).
 387 If ARG is non-nil (interactively, with a prefix argument), mark
 388 it as modified."
 389   (interactive "P")
 390   (with-current-buffer (Buffer-menu-buffer t)
 391     (set-buffer-modified-p arg))
 392   (tabulated-list-set-col 2 (if arg "*" " ") t))
 393
 394 (defun Buffer-menu-execute ()
 395   "Save and/or delete marked buffers in the Buffer Menu.
 396 Buffers marked with \\<Buffer-menu-mode-map>`\\[Buffer-menu-save]' are saved.
 397 Buffers marked with \\<Buffer-menu-mode-map>`\\[Buffer-menu-delete]' are deleted."
 398   (interactive)
 399   (save-excursion
 400     (Buffer-menu-beginning)
 401     (while (not (eobp))
 402       (let ((buffer (tabulated-list-get-id))
 403             (entry  (tabulated-list-get-entry)))
 404         (cond ((null entry)
 405                (forward-line 1))
 406               ((not (buffer-live-p buffer))
 407                (tabulated-list-delete-entry))
 408               (t
 409                (let ((delete (eq (char-after) ?D)))
 410                  (when (equal (aref entry 2) "S")
 411                    (condition-case nil
 412                        (progn
 413                          (with-current-buffer buffer
 414                            (save-buffer))
 415                          (tabulated-list-set-col 2 " " t))
 416                      (error (warn "Error saving %s" buffer))))
 417                  (if delete
 418                      (unless (eq buffer (current-buffer))
 419                        (kill-buffer buffer)
 420                        (tabulated-list-delete-entry))
 421                    (forward-line 1)))))))))
 422
 423 (defun Buffer-menu-select ()
 424   "Select this line's buffer; also, display buffers marked with `>'.
 425 You can mark buffers with the \\<Buffer-menu-mode-map>`\\[Buffer-menu-mark]' command.
 426 This command deletes and replaces all the previously existing windows
 427 in the selected frame."
 428   (interactive)
 429   (let* ((this-buffer (Buffer-menu-buffer t))
 430          (menu-buffer (current-buffer))
 431          (others (delq this-buffer (Buffer-menu-marked-buffers t)))
 432          (height (/ (1- (frame-height)) (1+ (length others)))))
 433     (delete-other-windows)
 434     (switch-to-buffer this-buffer)
 435     (unless (eq menu-buffer this-buffer)
 436       (bury-buffer menu-buffer))
 437     (dolist (buffer others)
 438       (split-window nil height)
 439       (other-window 1)
 440       (switch-to-buffer buffer))
 441     ;; Back to the beginning!
 442     (other-window 1)))
 443
 444 (defun Buffer-menu-marked-buffers (&optional unmark)
 445   "Return the list of buffers marked with `Buffer-menu-mark'.
 446 If UNMARK is non-nil, unmark them."
 447   (let (buffers)
 448     (Buffer-menu-beginning)
 449     (while (re-search-forward "^>" nil t)
 450       (let ((buffer (Buffer-menu-buffer)))
 451         (if (and buffer unmark)
 452             (tabulated-list-set-col 0 " " t))
 453         (if (buffer-live-p buffer)
 454             (push buffer buffers))))
 455     (nreverse buffers)))
 456
 457 (defun Buffer-menu-isearch-buffers ()
 458   "Search for a string through all marked buffers using Isearch."
 459   (interactive)
 460   (multi-isearch-buffers (Buffer-menu-marked-buffers)))
 461
 462 (defun Buffer-menu-isearch-buffers-regexp ()
 463   "Search for a regexp through all marked buffers using Isearch."
 464   (interactive)
 465   (multi-isearch-buffers-regexp (Buffer-menu-marked-buffers)))
 466
 467 \f
 468 (defun Buffer-menu-visit-tags-table ()
 469   "Visit the tags table in the buffer on this line.  See `visit-tags-table'."
 470   (interactive)
 471   (let ((file (buffer-file-name (Buffer-menu-buffer t))))
 472     (if file
 473         (visit-tags-table file)
 474       (error "Specified buffer has no file"))))
 475
 476 (defun Buffer-menu-1-window ()
 477   "Select this line's buffer, alone, in full frame."
 478   (interactive)
 479   (switch-to-buffer (Buffer-menu-buffer t))
 480   (bury-buffer (other-buffer))
 481   (delete-other-windows))
 482
 483 (defun Buffer-menu-this-window ()
 484   "Select this line's buffer in this window."
 485   (interactive)
 486   (switch-to-buffer (Buffer-menu-buffer t)))
 487
 488 (defun Buffer-menu-other-window ()
 489   "Select this line's buffer in other window, leaving buffer menu visible."
 490   (interactive)
 491   (switch-to-buffer-other-window (Buffer-menu-buffer t)))
 492
 493 (defun Buffer-menu-switch-other-window ()
 494   "Make the other window select this line's buffer.
 495 The current window remains selected."
 496   (interactive)
 497   (display-buffer (Buffer-menu-buffer t) t))
 498
 499 (defun Buffer-menu-2-window ()
 500   "Select this line's buffer, with previous buffer in second window."
 501   (interactive)
 502   (let ((buff (Buffer-menu-buffer t))
 503         (menu (current-buffer)))
 504     (delete-other-windows)
 505     (switch-to-buffer (other-buffer))
 506     (switch-to-buffer-other-window buff)
 507     (bury-buffer menu)))
 508
 509 (defun Buffer-menu-toggle-read-only ()
 510   "Toggle read-only status of buffer on this line."
 511   (interactive)
 512   (let (read-only)
 513     (with-current-buffer (Buffer-menu-buffer t)
 514       (with-no-warnings (toggle-read-only))
 515       (setq read-only buffer-read-only))
 516     (tabulated-list-set-col 1 (if read-only "%" " ") t)))
 517
 518 (defun Buffer-menu-bury ()
 519   "Bury the buffer listed on this line."
 520   (interactive)
 521   (let ((buffer (tabulated-list-get-id)))
 522     (cond ((null buffer))
 523           ((buffer-live-p buffer)
 524            (bury-buffer buffer)
 525            (save-excursion
 526              (let ((elt (tabulated-list-delete-entry)))
 527                (goto-char (point-max))
 528                (apply 'tabulated-list-print-entry elt)))
 529            (message "Buffer buried."))
 530           (t
 531            (tabulated-list-delete-entry)
 532            (message "Buffer is dead; removing from list.")))))
 533
 534 (defun Buffer-menu-view ()
 535   "View this line's buffer in View mode."
 536   (interactive)
 537   (view-buffer (Buffer-menu-buffer t)))
 538
 539 (defun Buffer-menu-view-other-window ()
 540   "View this line's buffer in View mode in another window."
 541   (interactive)
 542   (view-buffer-other-window (Buffer-menu-buffer t)))
 543 \f
 544 ;;; Functions for populating the Buffer Menu.
 545
 546 (defun list-buffers-noselect (&optional files-only buffer-list)
 547   "Create and return a Buffer Menu buffer.
 548 This is called by `buffer-menu' and others as a subroutine.
 549
 550 If FILES-ONLY is non-nil, show only file-visiting buffers.
 551 If BUFFER-LIST is non-nil, it should be a list of buffers; it
 552 means list those buffers and no others."
 553   (let ((old-buffer (current-buffer))
 554         (buffer (get-buffer-create "*Buffer List*")))
 555     (with-current-buffer buffer
 556       (Buffer-menu-mode)
 557       (setq Buffer-menu-files-only (and files-only (>= files-only 0)))
 558       (list-buffers--refresh buffer-list old-buffer)
 559       (tabulated-list-print))
 560     buffer))
 561
 562 (defun list-buffers--refresh (&optional buffer-list old-buffer)
 563   ;; Set up `tabulated-list-format'.
 564   (let ((name-width Buffer-menu-name-width)
 565         (size-width Buffer-menu-size-width))
 566     ;; Handle obsolete variable:
 567     (if Buffer-menu-buffer+size-width
 568         (setq name-width (- Buffer-menu-buffer+size-width size-width)))
 569     (setq tabulated-list-format
 570           (vector '("C" 1 t :pad-right 0)
 571                   '("R" 1 t :pad-right 0)
 572                   '("M" 1 t)
 573                   `("Buffer" ,name-width t)
 574                   `("Size" ,size-width tabulated-list-entry-size->)
 575                   `("Mode" ,Buffer-menu-mode-width t)
 576                   '("File" 1 t))))
 577   (setq tabulated-list-use-header-line Buffer-menu-use-header-line)
 578   ;; Collect info for each buffer we're interested in.
 579   (let ((buffer-menu-buffer (current-buffer))
 580         (show-non-file (not Buffer-menu-files-only))
 581         entries)
 582     (dolist (buffer (or buffer-list
 583                         (buffer-list (if Buffer-menu-use-frame-buffer-list
 584                                          (selected-frame)))))
 585       (with-current-buffer buffer
 586         (let* ((name (buffer-name))
 587                (file buffer-file-name))
 588           (when (and (buffer-live-p buffer)
 589                      (or buffer-list
 590                          (and (not (string= (substring name 0 1) " "))
 591                               (not (eq buffer buffer-menu-buffer))
 592                               (or file show-non-file))))
 593             (push (list buffer
 594                         (vector (if (eq buffer old-buffer) "." " ")
 595                                 (if buffer-read-only "%" " ")
 596                                 (if (buffer-modified-p) "*" " ")
 597                                 (Buffer-menu--pretty-name name)
 598                                 (number-to-string (buffer-size))
 599                                 (concat (format-mode-line mode-name nil nil buffer)
 600                                         (if mode-line-process
 601                                             (format-mode-line mode-line-process
 602                                                               nil nil buffer)))
 603                                 (Buffer-menu--pretty-file-name file)))
 604                   entries)))))
 605     (setq tabulated-list-entries (nreverse entries)))
 606   (tabulated-list-init-header))
 607
 608 (defun tabulated-list-entry-size-> (entry1 entry2)
 609   (> (string-to-number (aref (cadr entry1) 4))
 610      (string-to-number (aref (cadr entry2) 4))))
 611
 612 (defun Buffer-menu--pretty-name (name)
 613   (propertize name 'font-lock-face 'buffer-menu-buffer))
 614
 615 (defun Buffer-menu--pretty-file-name (file)
 616   (cond (file
 617          (abbreviate-file-name file))
 618         ((and (boundp 'list-buffers-directory)
 619               list-buffers-directory)
 620          list-buffers-directory)
 621         ((eq major-mode 'Info-mode)
 622          (Buffer-menu-info-node-description Info-current-file))
 623         (t "")))
 624
 625 (defun Buffer-menu-info-node-description (file)
 626   (cond
 627    ((equal file "dir") "*Info Directory*")
 628    ((eq file 'apropos) "*Info Apropos*")
 629    ((eq file 'history) "*Info History*")
 630    ((eq file 'toc)     "*Info TOC*")
 631    ((not (stringp file)) "") ; Avoid errors
 632    (t
 633     (concat "(" (file-name-nondirectory file) ") " Info-current-node))))
 634
 635 ;;; buff-menu.el ends here