code.delx.au - gnu-emacs/blob - configure.in

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl
   6 dnl  Copyright (C) 1994, 1995, 1996, 1999, 2000, 2001, 2002, 2003,
   7 dnl    2004, 2005, 2006, 2007, 2008  Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation, either version 3 of the License, or
  14 dnl  (at your option) any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 AC_PREREQ(2.61)dnl
  25 AC_INIT(emacs, 23.0.60)
  26 AC_CONFIG_HEADER(src/config.h:src/config.in)
  27 AC_CONFIG_SRCDIR(src/lisp.h)
  28
  29 dnl Support for --program-prefix, --program-suffix and
  30 dnl --program-transform-name options
  31 AC_ARG_PROGRAM
  32
  33 lispdir='${datadir}/emacs/${version}/lisp'
  34 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  35 '${datadir}/emacs/site-lisp'
  36 lisppath='${locallisppath}:${lispdir}:${datadir}/emacs/${version}/leim'
  37 etcdir='${datadir}/emacs/${version}/etc'
  38 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  39 docdir='${datadir}/emacs/${version}/etc'
  40 gamedir='${localstatedir}/games/emacs'
  41
  42 gameuser=games
  43
  44 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
  45 dnl Create a new --with option that defaults to being disabled.
  46 dnl NAME is the base name of the option.  The shell variable with_NAME
  47 dnl   will be set to either the user's value (if the option is
  48 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
  49 dnl   option is not specified).  Note that the shell variable name is
  50 dnl   constructed as autoconf does, by replacing non-alphanumeric
  51 dnl   characters with "_".
  52 dnl HELP-STRING is the help text for the option.
  53 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
  54   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
  55     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
  56 ])dnl
  57
  58 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
  59 dnl Create a new --with option that defaults to being enabled.  NAME
  60 dnl   is the base name of the option.  The shell variable with_NAME
  61 dnl   will be set either to 'no' (for a plain --without-NAME) or to
  62 dnl   'yes' (if the option is not specified).  Note that the shell
  63 dnl   variable name is constructed as autoconf does, by replacing
  64 dnl   non-alphanumeric characters with "_".
  65 dnl HELP-STRING is the help text for the option.
  66 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
  67   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
  68    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=yes])dnl
  69 ])dnl
  70
  71 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
  72 if test "$with_pop" = yes; then
  73    AC_DEFINE(MAIL_USE_POP)
  74 fi
  75 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
  76
  77 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
  78 if test "$with_kerberos" = yes; then
  79    AC_DEFINE(KERBEROS)
  80 fi
  81 AH_TEMPLATE(KERBEROS,
  82             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
  83
  84 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
  85 if test "${with_kerberos5}" = yes; then
  86   if test "${with_kerberos}" != yes; then
  87     with_kerberos=yes
  88     AC_DEFINE(KERBEROS)
  89   fi
  90   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
  91 fi
  92
  93 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
  94 if test "$with_hesiod" = yes; then
  95   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
  96 fi
  97
  98 OPTION_DEFAULT_ON([sound],[don't compile with sound support])
  99
 100 OPTION_DEFAULT_ON([sync-input],[Process async input synchronously])
 101 if test "$with_sync_input" = yes; then
 102    AC_DEFINE(SYNC_INPUT, 1, [Process async input synchronously.])
 103 fi
 104
 105 dnl FIXME currently it is not the last.
 106 dnl This should be the last --with option, because --with-x is
 107 dnl added later on when we find the path of X, and it's best to
 108 dnl keep them together visually.
 109 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 110  [use an X toolkit (KIT one of: yes, lucid, athena, motif, gtk, no)])],
 111 [         case "${withval}" in
 112             y | ye | yes )      val=gtk ;;
 113             n | no )            val=no  ;;
 114             l | lu | luc | luci | lucid )       val=lucid ;;
 115             a | at | ath | athe | athen | athena )      val=athena ;;
 116             m | mo | mot | moti | motif )       val=motif ;;
 117             g | gt | gtk  )     val=gtk ;;
 118             * )
 119 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 120 this option's value should be `yes', `no', `lucid', `athena', `motif' or `gtk'.
 121 `yes' and `gtk' are synonyms. `athena' and `lucid' are synonyms.])
 122             ;;
 123           esac
 124           with_x_toolkit=$val
 125 ])
 126
 127 dnl _ON results in a '--without' option in the --help output, so
 128 dnl the help text should refer to "don't compile", etc.
 129 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 130 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 131 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 132 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 133 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 134 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 135
 136 OPTION_DEFAULT_ON([freetype],[don't use Freetype for local font support])
 137 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 138 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 139 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 140
 141 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 142 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 143 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 144 OPTION_DEFAULT_OFF([carbon],[use Carbon GUI on Mac OS X.  This is unsupported!])
 145
 146 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 147 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 148
 149 ## For the times when you want to build Emacs but don't have
 150 ## a suitable makeinfo, and can live without the manuals.
 151 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 152 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 153
 154 dnl Can remove these in Emacs 24.
 155 AC_ARG_WITH([gtk],,
 156   AC_MSG_ERROR([--with-gtk has been removed.  Use --with-x-toolkit to
 157 specify a toolkit.]),,)
 158
 159 AC_ARG_WITH([gcc],,
 160   AC_MSG_ERROR([--with-gcc has been removed.  Set the `CC' environment
 161   variable to specify a compiler.]),,)
 162
 163 AC_ARG_WITH([pkg-config-prog],dnl
 164 [AS_HELP_STRING([--with-pkg-config-prog=PATH],
 165                   [Path to pkg-config for finding GTK and librsvg])])
 166 if test "X${with_pkg_config_prog}" != X; then
 167    if test "${with_pkg_config_prog}" != yes; then
 168       PKG_CONFIG="${with_pkg_config_prog}"
 169    fi
 170 fi
 171
 172 AC_ARG_ENABLE(carbon-app,
 173 [AS_HELP_STRING([--enable-carbon-app@<:@=DIR@:>@],
 174                 [specify install directory for Emacs.app on Mac OS X
 175                  [DIR=/Application]])],
 176 [ carbon_appdir_x=${enableval}])
 177
 178 AC_ARG_ENABLE(asserts,
 179 [AS_HELP_STRING([--enable-asserts], [compile code with asserts enabled])],
 180       USE_XASSERTS=$enableval,
 181       USE_XASSERTS=no)
 182
 183 AC_ARG_ENABLE(maintainer-mode,
 184 [AS_HELP_STRING([--enable-maintainer-mode],
 185                 [enable make rules and dependencies not useful (and sometimes
 186                  confusing) to the casual installer])],
 187       USE_MAINTAINER_MODE=$enableval,
 188       USE_MAINTAINER_MODE=no)
 189 if test $USE_MAINTAINER_MODE = yes; then
 190   MAINT=
 191 else
 192   MAINT=#
 193 fi
 194 AC_SUBST(MAINT)
 195
 196 AC_ARG_ENABLE(locallisppath,
 197 [AS_HELP_STRING([--enable-locallisppath=PATH],
 198                 [directories Emacs should search for lisp files specific
 199                  to this site])],
 200 if test "${enableval}" = "no"; then
 201   locallisppath=
 202 elif test "${enableval}" != "yes"; then
 203   locallisppath=${enableval}
 204 fi)
 205
 206 #### Make srcdir absolute, if it isn't already.  It's important to
 207 #### avoid running the path through pwd unnecessarily, since pwd can
 208 #### give you automounter prefixes, which can go away.  We do all this
 209 #### so Emacs can find its files when run uninstalled.
 210 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 211 unset CDPATH
 212 case "${srcdir}" in
 213   /* ) ;;
 214   . )
 215     ## We may be able to use the $PWD environment variable to make this
 216     ## absolute.  But sometimes PWD is inaccurate.
 217     ## Note: we used to use ${PWD} at the end instead of `pwd`,
 218     ## but that tested only for a well-formed and valid PWD,
 219     ## it did not object when PWD was well-formed and valid but just wrong.
 220     if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`"  ;
 221     then
 222       srcdir="$PWD"
 223     else
 224       srcdir="`(cd ${srcdir}; pwd)`"
 225     fi
 226   ;;
 227   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
 228 esac
 229
 230 #### Check if the source directory already has a configured system in it.
 231 if test `pwd` != `(cd ${srcdir} && pwd)` \
 232    && test -f "${srcdir}/src/config.h" ; then
 233   AC_MSG_WARN([[The directory tree `${srcdir}' is being used
 234    as a build directory right now; it has been configured in its own
 235    right.  To configure in another directory as well, you MUST
 236    use GNU make.  If you do not have GNU make, then you must
 237    now do `make distclean' in ${srcdir},
 238    and then run $0 again.]])
 239 fi
 240
 241 #### Given the configuration name, set machfile and opsysfile to the
 242 #### names of the m/*.h and s/*.h files we should use.
 243
 244 ### Canonicalize the configuration name.
 245
 246 AC_CANONICAL_HOST
 247 canonical=$host
 248 configuration=${host_alias-${build_alias-$host}}
 249
 250 dnl This used to use changequote, but, apart from `changequote is evil'
 251 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 252 dnl the great gob of text.  Thus it's not processed for possible expansion.
 253 dnl Just make sure the brackets remain balanced.
 254 dnl
 255 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 256 dnl indicated by comments.
 257 dnl quotation begins
 258 [
 259
 260 ### If you add support for a new configuration, add code to this
 261 ### switch statement to recognize your configuration name and select
 262 ### the appropriate operating system and machine description files.
 263
 264 ### You would hope that you could choose an m/*.h file pretty much
 265 ### based on the machine portion of the configuration name, and an s-
 266 ### file based on the operating system portion.  However, it turns out
 267 ### that each m/*.h file is pretty manufacturer-specific - for
 268 ### example hp9000s300.h is a 68000 machine;
 269 ### mips.h, pmax.h are all MIPS
 270 ### machines.  So we basically have to have a special case for each
 271 ### configuration name.
 272 ###
 273 ### As far as handling version numbers on operating systems is
 274 ### concerned, make sure things will fail in a fixable way.  If
 275 ### /etc/MACHINES doesn't say anything about version numbers, be
 276 ### prepared to handle anything reasonably.  If version numbers
 277 ### matter, be sure /etc/MACHINES says something about it.
 278 ###
 279 ### Eric Raymond says we should accept strings like "sysvr4" to mean
 280 ### "System V Release 4"; he writes, "The old convention encouraged
 281 ### confusion between `system' and `release' levels'."
 282
 283 machine='' opsys='' unported=no
 284 case "${canonical}" in
 285
 286   ## FreeBSD ports
 287   *-*-freebsd* )
 288     opsys=freebsd
 289     case "${canonical}" in
 290       alpha*-*-freebsd*)        machine=alpha ;;
 291       arm*-*-freebsd*)          machine=arm ;;
 292       ia64-*-freebsd*)          machine=ia64 ;;
 293       sparc64-*-freebsd*)       machine=sparc ;;
 294       powerpc-*-freebsd*)       machine=macppc ;;
 295       i[3456]86-*-freebsd*)     machine=intel386 ;;
 296       amd64-*-freebsd*|x86_64-*-freebsd*) machine=amdx86-64 ;;
 297     esac
 298   ;;
 299
 300   ## FreeBSD kernel + glibc based userland
 301   *-*-kfreebsd*gnu* )
 302     opsys=gnu-kfreebsd
 303     case "${canonical}" in
 304       alpha*-*-kfreebsd*)       machine=alpha ;;
 305       ia64-*-kfreebsd*)         machine=ia64 ;;
 306       sparc64-*-kfreebsd*)      machine=sparc ;;
 307       powerpc-*-kfreebsd*)      machine=macppc ;;
 308       i[3456]86-*-kfreebsd*)    machine=intel386 ;;
 309       amd64-*-kfreebsd*|x86_64-*-kfreebsd*) machine=amdx86-64 ;;
 310     esac
 311   ;;
 312
 313   ## NetBSD ports
 314   *-*-netbsd* )
 315     opsys=netbsd
 316     if test -f /usr/lib/crti.o; then]
 317 dnl The close and open brackets here are because this section is quoted --
 318 dnl see the `changequote' comment above.
 319       AC_DEFINE(HAVE_CRTIN, [], [Define to 1 if you have /usr/lib/crti.o.])
 320 [   fi
 321
 322     case "${canonical}" in
 323       alpha*-*-netbsd*) machine=alpha ;;
 324       i[3456]86-*-netbsd*) machine=intel386 ;;
 325       m68k-*-netbsd*)
 326                         # This is somewhat bogus.
 327                         machine=hp9000s300 ;;
 328       mips-*-netbsd*)   machine=pmax ;;
 329       mipsel-*-netbsd*) machine=pmax ;;
 330       mipseb-*-netbsd*) machine=pmax ;;
 331       powerpc-*-netbsd*) machine=macppc ;;
 332       sparc*-*-netbsd*) machine=sparc ;;
 333       vax-*-netbsd*)    machine=vax ;;
 334       arm-*-netbsd*)    machine=arm ;;
 335       x86_64-*-netbsd*) machine=amdx86-64 ;;
 336       hppa-*-netbsd*)   machine=hp800 ;;
 337     esac
 338   ;;
 339
 340   ## OpenBSD ports
 341   *-*-openbsd* )
 342     opsys=openbsd
 343     case "${canonical}" in
 344       alpha*-*-openbsd*)        machine=alpha ;;
 345       arm-*-openbsd*)          machine=arm ;;
 346       hppa-*-openbsd*)         machine=hp9000s300 ;;
 347       i386-*-openbsd*)         machine=intel386 ;;
 348       m68k-*-openbsd*)         machine=hp9000s300 ;;
 349       powerpc-*-openbsd*)      machine=macppc ;;
 350       sparc*-*-openbsd*)       machine=sparc ;;
 351       vax-*-openbsd*)          machine=vax ;;
 352       x86_64-*-openbsd*)       machine=amdx86-64 ;;
 353     esac
 354   ;;
 355
 356   ## LynxOS ports
 357   *-*-lynxos* )
 358     opsys=lynxos
 359     case "${canonical}" in
 360       i[3456]86-*-lynxos*) machine=intel386 ;;
 361       powerpc-*-lynxos*) machine=powerpc ;;
 362     esac
 363   ;;
 364
 365   ## BSDI ports
 366   *-*-bsdi* )
 367     opsys=bsdi
 368     case "${canonical}" in
 369       i[345]86-*-bsdi*) machine=intel386 ;;
 370       sparc-*-bsdi*)  machine=sparc ;;
 371       powerpc-*-bsdi*)  machine=macppc ;;
 372     esac
 373     case "${canonical}" in
 374       *-*-bsd386* | *-*-bsdi1* )        opsys=bsd386 ;;
 375       *-*-bsdi2.0* )            opsys=bsdos2 ;;
 376       *-*-bsdi2* )              opsys=bsdos2-1 ;;
 377       *-*-bsdi3* )              opsys=bsdos3 ;;
 378       *-*-bsdi[45]* )           opsys=bsdos4 ;;
 379     esac
 380   ;;
 381
 382   alpha*-*-linux-gnu* )
 383     machine=alpha opsys=gnu-linux
 384   ;;
 385
 386   arm*-*-linux-gnu* )
 387     machine=arm opsys=gnu-linux
 388   ;;
 389
 390   ## Apple Darwin / Mac OS X
 391   *-apple-darwin* )
 392     case "${canonical}" in
 393       i[3456]86-* )  machine=intel386 ;;
 394       powerpc-* )    machine=powermac ;;
 395       * )            unported=yes ;;
 396     esac
 397     opsys=darwin
 398     # Define CPP as follows to make autoconf work correctly.
 399     CPP="${CC-cc} -E -no-cpp-precomp"
 400     # Use fink packages if available.
 401     if test -d /sw/include && test -d /sw/lib; then
 402       GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 403       CPP="${CPP} ${GCC_TEST_OPTIONS}"
 404       NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 405     fi
 406   ;;
 407
 408   ## Cubix QBx/386
 409   i[3456]86-cubix-sysv* )
 410     machine=intel386 opsys=usg5-3
 411   ;;
 412
 413   mips-dec-ultrix[0-3].* | mips-dec-ultrix4.0* | mips-dec-bsd4.2* )
 414     machine=pmax opsys=bsd4-2
 415   ;;
 416   mips-dec-ultrix4.[12]* | mips-dec-bsd* )
 417     machine=pmax opsys=bsd4-3
 418   ;;
 419   mips-dec-ultrix* )
 420     machine=pmax opsys=ultrix4-3
 421   ;;
 422   ## HP 9000 series 200 or 300
 423   m68*-hp-bsd* )
 424     machine=hp9000s300 opsys=bsd4-3
 425   ;;
 426   ## HP/UX 7, 8, 9, and 10 are supported on these machines.
 427   m68*-hp-hpux* )
 428     case "`uname -r`" in
 429       ## Someone's system reports A.B8.05 for this.
 430       ## I wonder what other possibilities there are.
 431       *.B8.* ) machine=hp9000s300 opsys=hpux8 ;;
 432       *.08.* ) machine=hp9000s300 opsys=hpux8 ;;
 433       *.09.* ) machine=hp9000s300 opsys=hpux9 ;;
 434       *.1[0-9].* ) machine=hp9000s300 opsys=hpux9shr ;;
 435       *) machine=hp9000s300 opsys=hpux ;;
 436     esac
 437   ;;
 438
 439   ## HP 9000 series 700 and 800, running HP/UX
 440   hppa*-hp-hpux7* )
 441     machine=hp800 opsys=hpux
 442   ;;
 443   hppa*-hp-hpux8* )
 444     machine=hp800 opsys=hpux8
 445   ;;
 446   hppa*-hp-hpux9shr* )
 447     machine=hp800 opsys=hpux9shr
 448   ;;
 449   hppa*-hp-hpux9* )
 450     machine=hp800 opsys=hpux9
 451   ;;
 452   hppa*-hp-hpux10.2* )
 453     machine=hp800 opsys=hpux10-20
 454   ;;
 455   hppa*-hp-hpux10* )
 456     machine=hp800 opsys=hpux10
 457   ;;
 458   hppa*-hp-hpux1[1-9]* )
 459     machine=hp800 opsys=hpux11
 460     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 461   ;;
 462
 463   hppa*-*-linux-gnu* )
 464     machine=hp800 opsys=gnu-linux
 465   ;;
 466
 467   ## HP 9000 series 700 and 800, running HP/UX
 468   hppa*-hp-hpux* )
 469     ## Cross-compilation?  Nah!
 470     case "`uname -r`" in
 471       ## Someone's system reports A.B8.05 for this.
 472       ## I wonder what other possibilities there are.
 473       *.B8.* ) machine=hp800 opsys=hpux8 ;;
 474       *.08.* ) machine=hp800 opsys=hpux8 ;;
 475       *.09.* ) machine=hp800 opsys=hpux9 ;;
 476       *) machine=hp800 opsys=hpux10 ;;
 477     esac
 478   ;;
 479   hppa*-*-nextstep* )
 480     machine=hp800 opsys=nextstep
 481   ;;
 482
 483   ## IBM machines
 484   i370-ibm-aix*)
 485     machine=ibm370aix opsys=usg5-3
 486   ;;
 487   s390-*-linux-gnu* )
 488     machine=ibms390 opsys=gnu-linux
 489   ;;
 490   s390x-*-linux-gnu* )
 491     machine=ibms390x opsys=gnu-linux
 492   ;;
 493   rs6000-ibm-aix3.1* | powerpc-ibm-aix3.1*  )
 494     machine=ibmrs6000 opsys=aix3-1
 495   ;;
 496   rs6000-ibm-aix3.2.5 | powerpc-ibm-aix3.2.5 )
 497     machine=ibmrs6000 opsys=aix3-2-5
 498   ;;
 499   rs6000-ibm-aix4.1* | powerpc-ibm-aix4.1*  )
 500     machine=ibmrs6000 opsys=aix4-1
 501   ;;
 502   rs6000-ibm-aix4.2* | powerpc-ibm-aix4.2*  )
 503     machine=ibmrs6000 opsys=aix4-2
 504   ;;
 505   rs6000-ibm-aix4.3* | powerpc-ibm-aix4.3*  )
 506     machine=ibmrs6000 opsys=aix4-2
 507   ;;
 508   rs6000-ibm-aix5* | powerpc-ibm-aix5*  )
 509     machine=ibmrs6000 opsys=aix4-2
 510   ;;
 511   rs6000-ibm-aix5* | powerpc-ibm-aix6*  )
 512     machine=ibmrs6000 opsys=aix4-2
 513   ;;
 514   rs6000-ibm-aix4.0* | powerpc-ibm-aix4.0*  )
 515     machine=ibmrs6000 opsys=aix4
 516   ;;
 517   rs6000-ibm-aix4* | powerpc-ibm-aix4*  )
 518     machine=ibmrs6000 opsys=aix4-1
 519   ;;
 520   rs6000-ibm-aix* | powerpc-ibm-aix* )
 521     machine=ibmrs6000 opsys=aix3-2
 522   ;;
 523
 524   ## Prime EXL
 525   i[3456]86-prime-sysv* )
 526     machine=i386 opsys=usg5-3
 527   ;;
 528
 529   ## ncr machine running svr4.3.
 530   i[3456]86-ncr-sysv4.3 )
 531     machine=ncr386 opsys=usg5-4-3
 532   ;;
 533
 534   ## Unspecified sysv on an ncr machine defaults to svr4.2.
 535   ## (Plain usg5-4 doesn't turn on POSIX signals, which we need.)
 536   i[3456]86-ncr-sysv* )
 537     machine=ncr386 opsys=usg5-4-2
 538   ;;
 539
 540   ## Macintosh PowerPC
 541   powerpc*-*-linux-gnu* )
 542     machine=macppc opsys=gnu-linux
 543   ;;
 544
 545   ## Workstations sold by MIPS
 546   ## This is not necessarily all workstations using the MIPS processor -
 547   ## Irises are produced by SGI, and DECstations by DEC.
 548
 549   mips-mips-bsd* )
 550     machine=mips opsys=bsd4-3
 551   ;;
 552   mips-mips-* )
 553     machine=mips opsys=usg5-2-2
 554   ;;
 555
 556   ## NeXT
 557   m68*-next-* | m68k-*-nextstep* )
 558     machine=m68k opsys=nextstep
 559   ;;
 560
 561   ## NEC EWS4800
 562   mips-nec-sysv4*)
 563   machine=ews4800 opsys=ux4800
 564   ;;
 565
 566   ## Siemens Nixdorf
 567   mips-siemens-sysv* | mips-sni-sysv*)
 568     machine=mips-siemens opsys=usg5-4
 569     NON_GNU_CC=/usr/ccs/bin/cc
 570     NON_GNU_CPP=/usr/ccs/lib/cpp
 571   ;;
 572
 573   ## Silicon Graphics machines
 574   ## Iris 4D
 575   mips-sgi-irix6.5 )
 576     machine=iris4d opsys=irix6-5
 577     # Without defining _LANGUAGE_C, things get masked out in the headers
 578     # so that, for instance, grepping for `free' in stdlib.h fails and
 579     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 580     NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
 581     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 582   ;;
 583
 584   ## Suns
 585   sparc-*-linux-gnu* | sparc64-*-linux-gnu* )
 586     machine=sparc opsys=gnu-linux
 587   ;;
 588
 589   *-auspex-sunos* | *-sun-sunos* | *-sun-bsd* | *-sun-solaris* \
 590     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* | powerpc*-*-solaris2* \
 591     | rs6000-*-solaris2*)
 592     case "${canonical}" in
 593       i[3456]86-*-* )     machine=intel386 ;;
 594       amd64-*-*|x86_64-*-*)     machine=amdx86-64 ;;
 595       powerpcle* )      machine=powerpcle ;;
 596       powerpc* | rs6000* )  machine=ibmrs6000 ;;
 597       sparc* )          machine=sparc ;;
 598       * )               unported=yes ;;
 599     esac
 600     case "${canonical}" in
 601       *-sunos5.3* | *-solaris2.3* )
 602                 opsys=sol2-3
 603                 NON_GNU_CPP=/usr/ccs/lib/cpp
 604                 ;;
 605       *-sunos5.4* | *-solaris2.4* )
 606                 opsys=sol2-4
 607                 NON_GNU_CPP=/usr/ccs/lib/cpp
 608                 RANLIB="ar -ts"
 609                 ;;
 610       *-sunos5.5* | *-solaris2.5* )
 611                 opsys=sol2-5
 612                 NON_GNU_CPP=/usr/ccs/lib/cpp
 613                 RANLIB="ar -ts"
 614                 ;;
 615       *-sunos5.6* | *-solaris2.6* )
 616                 opsys=sol2-6
 617                 NON_GNU_CPP=/usr/ccs/lib/cpp
 618                 RANLIB="ar -ts"
 619                 ;;
 620       *-sunos5* | *-solaris* )
 621                 opsys=sol2-6
 622                 emacs_check_sunpro_c=yes
 623                 NON_GNU_CPP=/usr/ccs/lib/cpp
 624                 ;;
 625       *                   ) opsys=bsd4-2   ;;
 626     esac
 627     ## Watch out for a compiler that we know will not work.
 628     case "${canonical}" in
 629      *-solaris* | *-sunos5* )
 630                 if [ "x$CC" = x/usr/ucb/cc ]; then
 631                   ## /usr/ucb/cc doesn't work;
 632                   ## we should find some other compiler that does work.
 633                   unset CC
 634                 fi
 635                 ;;
 636       *) ;;
 637     esac
 638   ;;
 639   sparc-*-nextstep* )
 640     machine=sparc opsys=nextstep
 641   ;;
 642
 643   ## Tandem Integrity S2
 644   mips-tandem-sysv* )
 645     machine=tandem-s2 opsys=usg5-3
 646   ;;
 647
 648   ## Vaxen.
 649   vax-dec-* )
 650     machine=vax
 651     case "${canonical}" in
 652       *-bsd4.1* )                                       opsys=bsd4-1 ;;
 653       *-bsd4.2* | *-ultrix[0-3].* | *-ultrix4.0* )      opsys=bsd4-2 ;;
 654       *-bsd4.3* | *-ultrix* )                           opsys=bsd4-3 ;;
 655       *-sysv[01]* | *-sysvr[01]* )                      opsys=usg5-0 ;;
 656       *-sysv2* | *-sysvr2* )                            opsys=usg5-2 ;;
 657       *-vms* )                                          opsys=vms ;;
 658       * )                                               unported=yes
 659     esac
 660   ;;
 661
 662   ## IA-64
 663   ia64*-*-linux* )
 664     machine=ia64 opsys=gnu-linux
 665   ;;
 666
 667   ## Intel 386 machines where we don't care about the manufacturer
 668   i[3456]86-*-* )
 669     machine=intel386
 670     case "${canonical}" in
 671       *-cygwin )                opsys=cygwin ;;
 672       *-darwin* )               opsys=darwin
 673                                 CPP="${CC-cc} -E -no-cpp-precomp"
 674                                 ;;
 675       *-linux-gnu* )            opsys=gnu-linux ;;
 676       *-sysv4.2uw* )            opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 677       *-sysv5uw* )              opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 678       *-sysv5OpenUNIX* )        opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 679       *-386bsd* )               opsys=386bsd ;;
 680       *-nextstep* )             opsys=nextstep ;;
 681       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 682     esac
 683   ;;
 684
 685   ## m68k Linux-based GNU system
 686   m68k-*-linux-gnu* )
 687     machine=m68k opsys=gnu-linux
 688   ;;
 689
 690   ## Mips Linux-based GNU system
 691   mips-*-linux-gnu* | mipsel-*-linux-gnu* )
 692     machine=mips opsys=gnu-linux
 693   ;;
 694
 695   ## UXP/DS
 696   sparc-fujitsu-sysv4* )
 697     machine=sparc opsys=uxpds
 698     NON_GNU_CPP=/usr/ccs/lib/cpp
 699     RANLIB="ar -ts"
 700   ;;
 701
 702   ## AMD x86-64 Linux-based GNU system
 703   x86_64-*-linux-gnu* )
 704     machine=amdx86-64 opsys=gnu-linux
 705   ;;
 706
 707   ## Tensilica Xtensa Linux-based GNU system
 708   xtensa*-*-linux-gnu* )
 709     machine=xtensa opsys=gnu-linux
 710     ;;
 711
 712   * )
 713     unported=yes
 714   ;;
 715 esac
 716
 717 ### If the code above didn't choose an operating system, just choose
 718 ### an operating system based on the configuration name.  You really
 719 ### only want to use this when you have no idea what the right
 720 ### operating system is; if you know what operating systems a machine
 721 ### runs, it's cleaner to make it explicit in the case statement
 722 ### above.
 723 if test x"${opsys}" = x; then
 724   case "${canonical}" in
 725     *-gnu* )                            opsys=gnu ;;
 726     *-bsd4.[01] )                       opsys=bsd4-1 ;;
 727     *-bsd4.2 )                          opsys=bsd4-2 ;;
 728     *-bsd4.3 )                          opsys=bsd4-3 ;;
 729     *-sysv0 | *-sysvr0 )                opsys=usg5-0 ;;
 730     *-sysv2 | *-sysvr2 )                opsys=usg5-2 ;;
 731     *-sysv2.2 | *-sysvr2.2 )            opsys=usg5-2-2 ;;
 732     *-sysv3* | *-sysvr3* )              opsys=usg5-3 ;;
 733     *-sysv4.2uw* )                      opsys=unixware ;;
 734     *-sysv5uw* )                        opsys=unixware ;;
 735     *-sysv5OpenUNIX* )                  opsys=unixware ;;
 736     *-sysv4.1* | *-sysvr4.1* )
 737         NON_GNU_CPP=/usr/lib/cpp
 738         opsys=usg5-4 ;;
 739     *-sysv4.[2-9]* | *-sysvr4.[2-9]* )
 740         if [ x$NON_GNU_CPP = x ]; then
 741           if [ -f /usr/ccs/lib/cpp ]; then
 742             NON_GNU_CPP=/usr/ccs/lib/cpp
 743           else
 744             NON_GNU_CPP=/lib/cpp
 745           fi
 746         fi
 747         opsys=usg5-4-2 ;;
 748     *-sysv4* | *-sysvr4* )              opsys=usg5-4 ;;
 749     * )
 750       unported=yes
 751     ;;
 752   esac
 753 fi
 754
 755 ### Tests for sytems that we beleive are obsolete and should be desupported.
 756
 757 case "${machine}" in
 758      pmax | hp9000s300 | ibm370aix | ncr386 | ews4800 | mips-siemens | powerpcle | tandem-s2 )
 759           echo "The system that you are configuring on: ${canonical} is considered to be obsolete"
 760           echo "and it is planned to be desupported in the next version of Emacs"
 761           echo "Please email emacs-devel@gnu.org as soon as possible if this system is still in use."
 762           echo "The code is still functional, but you need to edit the 'configure' script and remove the"
 763           echo "exit 33 line.  After that you can run configure again and 'complete' the build."
 764           exit 33
 765           ;;
 766 esac
 767
 768 case "${opsys}" in
 769      bsd386 | bsdos2-1 |  bsdos2 | bsdos3 | bsdos4 | bsd4-1 | bsd4-2 | bsd4-3 | usg5-0 | usg5-2-2 | usg5-2 | usg5-3 | ultrix4-3 | 386bsd | hpux | hpux8 | hpux9 | hpux9shr | hpux10 | aix3-1 | aix3-2-5 | aix3-2 | aix4-1 | nextstep | ux4800 | uxpds | uxpv )
 770           echo "The system that you are configuring on: ${canonical} is considered to be obsolete"
 771           echo "and it is planned to be desupported in the next version of Emacs"
 772           echo "Please email emacs-devel@gnu.org as soon as possible if this system is still in use."
 773           echo "The code is still functional, but you need to edit the 'configure' script and remove the"
 774           echo "'exit 44' line.  After that you can run 'configure' again and complete the build."
 775           exit 44
 776           ;;
 777 esac
 778
 779 ]
 780 dnl quotation ends
 781
 782 if test $unported = yes; then
 783   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
 784 Check `etc/MACHINES' for recognized configuration names.])
 785 fi
 786
 787 machfile="m/${machine}.h"
 788 opsysfile="s/${opsys}.h"
 789
 790
 791 #### Choose a compiler.
 792 test -n "$CC" && cc_specified=yes
 793
 794 # Save the value of CFLAGS that the user specified.
 795 SPECIFIED_CFLAGS="$CFLAGS"
 796
 797 dnl Sets GCC=yes if using gcc.
 798 AC_PROG_CC
 799
 800 # On Suns, sometimes $CPP names a directory.
 801 if test -n "$CPP" && test -d "$CPP"; then
 802   CPP=
 803 fi
 804
 805 ## If not using gcc, and on Solaris, and no CPP specified, see if
 806 ## using a Sun compiler, which needs -Xs to prevent whitespace.
 807 if test x"$GCC" != xyes && test x"$emacs_check_sunpro_c" = xyes && \
 808  test x"$CPP" = x; then
 809   AC_MSG_CHECKING([whether we are using a Sun C compiler])
 810   AC_CACHE_VAL(emacs_cv_sunpro_c,
 811   [AC_TRY_LINK([],
 812 [#ifndef __SUNPRO_C
 813 fail;
 814 #endif
 815 ], emacs_cv_sunpro_c=yes, emacs_cv_sunpro_c=no)])
 816   AC_MSG_RESULT($emacs_cv_sunpro_c)
 817
 818   if test x"$emacs_cv_sunpro_c" = xyes; then
 819     NON_GNU_CPP="$CC -E -Xs"
 820   fi
 821 fi
 822
 823 #### Some systems specify a CPP to use unless we are using GCC.
 824 #### Now that we know whether we are using GCC, we can decide whether
 825 #### to use that one.
 826 if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x
 827 then
 828   CPP="$NON_GNU_CPP"
 829 fi
 830
 831 #### Some systems specify a CC to use unless we are using GCC.
 832 #### Now that we know whether we are using GCC, we can decide whether
 833 #### to use that one.
 834 if test "x$NON_GNU_CC" != x && test x$GCC != xyes &&
 835   test x$cc_specified != xyes
 836 then
 837   CC="$NON_GNU_CC"
 838 fi
 839
 840 if test x$GCC = xyes && test "x$GCC_TEST_OPTIONS" != x
 841 then
 842   CC="$CC $GCC_TEST_OPTIONS"
 843 fi
 844
 845 if test x$GCC = x && test "x$NON_GCC_TEST_OPTIONS" != x
 846 then
 847   CC="$CC $NON_GCC_TEST_OPTIONS"
 848 fi
 849
 850 dnl checks for Unix variants
 851 AC_USE_SYSTEM_EXTENSIONS
 852
 853 ### Use -Wno-pointer-sign if the compiler supports it
 854 AC_MSG_CHECKING([whether gcc understands -Wno-pointer-sign])
 855 SAVE_CFLAGS="$CFLAGS"
 856 CFLAGS="$CFLAGS -Wno-pointer-sign"
 857 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 858 if test $has_option = yes; then
 859    C_WARNINGS_SWITCH="-Wno-pointer-sign $C_WARNINGS_SWITCH"
 860 fi
 861 AC_MSG_RESULT($has_option)
 862 CFLAGS="$SAVE_CFLAGS"
 863 unset has_option
 864 unset SAVE_CFLAGS
 865
 866 #### Some other nice autoconf tests.
 867
 868 dnl checks for programs
 869 AC_PROG_LN_S
 870 AC_PROG_CPP
 871 AC_PROG_INSTALL
 872 if test "x$RANLIB" = x; then
 873   AC_PROG_RANLIB
 874 fi
 875 AC_PATH_PROG(INSTALL_INFO, install-info)
 876 AC_PATH_PROG(INSTALL_INFO, install-info,, /usr/sbin)
 877 AC_PATH_PROG(INSTALL_INFO, install-info,:, /sbin)
 878 dnl Don't use GZIP, which is used by gzip for additional parameters.
 879 AC_PATH_PROG(GZIP_PROG, gzip)
 880
 881
 882 ## Need makeinfo >= 4.6 (?) to build the manuals.
 883 AC_PATH_PROG(MAKEINFO, makeinfo, no)
 884 dnl By this stage, configure has already checked for egrep and set EGREP,
 885 dnl or exited with an error if no egrep was found.
 886 if test "$MAKEINFO" != "no" && \
 887   test x"`$MAKEINFO --version 2> /dev/null | $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[6-9]]|4\.[[1-5]][[0-9]]+)'`" = x; then
 888    MAKEINFO=no
 889 fi
 890
 891 ## Makeinfo is unusual.  For a released Emacs, the manuals are
 892 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
 893 ## therefore in the category of "special tools" not normally required, which
 894 ## configure does not have to check for (eg autoconf itself).
 895 ## In a CVS checkout on the other hand, the manuals are not included.
 896 ## So makeinfo is a requirement to build from CVS, and configure
 897 ## should test for it as it does for any other build requirement.
 898 ## We use the presence of $srcdir/info/emacs to distinguish a release,
 899 ## with pre-built manuals, from a CVS checkout.
 900 if test "$MAKEINFO" = "no"; then
 901   if test "x${with_makeinfo}" = "xno"; then
 902     MAKEINFO=off
 903   elif ! test -e $srcdir/info/emacs; then
 904     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.6, and your
 905 source tree does not seem to have pre-built manuals in the `info' directory.
 906 Either install a suitable version of makeinfo, or re-run configure
 907 with the `--without-makeinfo' option to build without the manuals.] )
 908   fi
 909 fi
 910
 911 dnl Add our options to ac_link now, after it is set up.
 912
 913 if test x$GCC = xyes && test "x$GCC_LINK_TEST_OPTIONS" != x
 914 then
 915   ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
 916 fi
 917
 918 if test x$GCC = x && test "x$NON_GCC_LINK_TEST_OPTIONS" != x
 919 then
 920   ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
 921 fi
 922
 923 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
 924 dnl If we can link with the flag, it shouldn't do any harm anyhow.
 925 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
 926 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
 927 dnl if not built to support GNU ld.
 928
 929 late_LDFLAGS=$LDFLAGS
 930 if test "$GCC" = yes; then
 931   LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
 932 else
 933   LDFLAGS="$LDFLAGS -znocombreloc"
 934 fi
 935
 936 AC_MSG_CHECKING([for -znocombreloc])
 937 AC_LINK_IFELSE([main(){return 0;}],
 938   [AC_MSG_RESULT(yes)],
 939   LDFLAGS=$late_LDFLAGS
 940   [AC_MSG_RESULT(no)])
 941
 942 #### Extract some information from the operating system and machine files.
 943
 944 AC_CHECKING([the machine- and system-dependent files to find out
 945  - which libraries the lib-src programs will want, and
 946  - whether the GNU malloc routines are usable])
 947
 948 ### First figure out CFLAGS (which we use for running the compiler here)
 949 ### and REAL_CFLAGS (which we use for real compilation).
 950 ### The two are the same except on a few systems, where they are made
 951 ### different to work around various lossages.  For example,
 952 ### GCC 2.5 on GNU/Linux needs them to be different because it treats -g
 953 ### as implying static linking.
 954
 955 ### If the CFLAGS env var is specified, we use that value
 956 ### instead of the default.
 957
 958 ### It's not important that this name contain the PID; you can't run
 959 ### two configures in the same directory and have anything work
 960 ### anyway.
 961 tempcname="conftest.c"
 962
 963 echo '
 964 #include "'${srcdir}'/src/'${opsysfile}'"
 965 #include "'${srcdir}'/src/'${machfile}'"
 966 #ifndef LIBS_MACHINE
 967 #define LIBS_MACHINE
 968 #endif
 969 #ifndef LIBS_SYSTEM
 970 #define LIBS_SYSTEM
 971 #endif
 972 #ifndef C_SWITCH_SYSTEM
 973 #define C_SWITCH_SYSTEM
 974 #endif
 975 #ifndef C_SWITCH_MACHINE
 976 #define C_SWITCH_MACHINE
 977 #endif
 978 configure___ libsrc_libs=LIBS_MACHINE LIBS_SYSTEM
 979 configure___ c_switch_system=C_SWITCH_SYSTEM
 980 configure___ c_switch_machine=C_SWITCH_MACHINE
 981
 982 #ifndef LIB_X11_LIB
 983 #define LIB_X11_LIB -lX11
 984 #endif
 985
 986 #ifndef LIBX11_SYSTEM
 987 #define LIBX11_SYSTEM
 988 #endif
 989 configure___ LIBX=LIB_X11_LIB LIBX11_SYSTEM
 990
 991 #ifdef UNEXEC
 992 configure___ unexec=UNEXEC
 993 #else
 994 configure___ unexec=unexec.o
 995 #endif
 996
 997 #ifdef SYSTEM_MALLOC
 998 configure___ system_malloc=yes
 999 #else
1000 configure___ system_malloc=no
1001 #endif
1002
1003 #ifdef USE_MMAP_FOR_BUFFERS
1004 configure___ use_mmap_for_buffers=yes
1005 #else
1006 configure___ use_mmap_for_buffers=no
1007 #endif
1008
1009 #ifndef C_DEBUG_SWITCH
1010 #define C_DEBUG_SWITCH -g
1011 #endif
1012
1013 #ifndef C_OPTIMIZE_SWITCH
1014 #ifdef __GNUC__
1015 #define C_OPTIMIZE_SWITCH -O2
1016 #else
1017 #define C_OPTIMIZE_SWITCH -O
1018 #endif
1019 #endif
1020
1021 #ifndef C_WARNINGS_SWITCH
1022 #define C_WARNINGS_SWITCH ${C_WARNINGS_SWITCH}
1023 #endif
1024
1025 #ifndef LD_SWITCH_MACHINE
1026 #define LD_SWITCH_MACHINE
1027 #endif
1028
1029 #ifndef LD_SWITCH_SYSTEM
1030 #define LD_SWITCH_SYSTEM
1031 #endif
1032
1033 #ifndef LD_SWITCH_X_SITE_AUX
1034 #define LD_SWITCH_X_SITE_AUX
1035 #endif
1036
1037 configure___ ld_switch_system=LD_SWITCH_SYSTEM
1038 configure___ ld_switch_machine=LD_SWITCH_MACHINE
1039
1040 #ifdef THIS_IS_CONFIGURE
1041
1042 /* Get the CFLAGS for tests in configure.  */
1043 #ifdef __GNUC__
1044 configure___ CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH '${SPECIFIED_CFLAGS}'
1045 #else
1046 configure___ CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
1047 #endif
1048
1049 #else /* not THIS_IS_CONFIGURE */
1050
1051 /* Get the CFLAGS for real compilation.  */
1052 #ifdef __GNUC__
1053 configure___ REAL_CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH C_WARNINGS_SWITCH '${SPECIFIED_CFLAGS}'
1054 #else
1055 configure___ REAL_CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
1056 #endif
1057
1058 #endif /* not THIS_IS_CONFIGURE */
1059 ' > ${tempcname}
1060
1061 # The value of CPP is a quoted variable reference, so we need to do this
1062 # to get its actual value...
1063 CPP=`eval "echo $CPP"`
1064 [eval `${CPP} -Isrc ${tempcname} \
1065        | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
1066 if test "x$SPECIFIED_CFLAGS" = x; then
1067   eval `${CPP} -Isrc -DTHIS_IS_CONFIGURE ${tempcname} \
1068          | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
1069 else
1070   REAL_CFLAGS="$CFLAGS"
1071 fi]
1072 rm ${tempcname}
1073
1074 ac_link="$ac_link $ld_switch_machine $ld_switch_system"
1075
1076 ### Make sure subsequent tests use flags consistent with the build flags.
1077
1078 if test x"${OVERRIDE_CPPFLAGS}" != x; then
1079   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
1080 else
1081   CPPFLAGS="$c_switch_system $c_switch_machine $CPPFLAGS"
1082 fi
1083
1084 dnl For AC_FUNC_GETLOADAVG, at least:
1085 AC_CONFIG_LIBOBJ_DIR(src)
1086
1087 dnl Do this early because it can frob feature test macros for Unix-98 &c.
1088 AC_SYS_LARGEFILE
1089
1090
1091 ### The standard library on x86-64 and s390x GNU/Linux distributions can
1092 ### be located in either /usr/lib64 or /usr/lib.
1093 case "${canonical}" in
1094   x86_64-*-linux-gnu* | s390x-*-linux-gnu* )
1095     if test -d /usr/lib64; then
1096       AC_DEFINE(HAVE_LIB64_DIR, 1,
1097         [Define to 1 if the directory /usr/lib64 exists.])
1098 fi
1099 esac
1100
1101 dnl This function defintion taken from Gnome 2.0
1102 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1103 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1104 dnl also defines GSTUFF_PKG_ERRORS on error
1105 AC_DEFUN([PKG_CHECK_MODULES], [
1106   succeeded=no
1107
1108   AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1109
1110   if test "$PKG_CONFIG" = "no" ; then
1111      ifelse([$4], , [AC_MSG_ERROR([
1112       *** The pkg-config script could not be found. Make sure it is in your path, or give the full path to pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
1113   else
1114      PKG_CONFIG_MIN_VERSION=0.9.0
1115      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1116         AC_MSG_CHECKING(for $2)
1117
1118         if $PKG_CONFIG --exists "$2" 2>&AS_MESSAGE_LOG_FD; then
1119             AC_MSG_RESULT(yes)
1120             succeeded=yes
1121
1122             AC_MSG_CHECKING($1_CFLAGS)
1123             $1_CFLAGS=`$PKG_CONFIG --cflags "$2"|sed -e 's,///*,/,g'`
1124             AC_MSG_RESULT($$1_CFLAGS)
1125
1126             AC_MSG_CHECKING($1_LIBS)
1127             $1_LIBS=`$PKG_CONFIG --libs "$2"|sed -e 's,///*,/,g'`
1128             AC_MSG_RESULT($$1_LIBS)
1129         else
1130             AC_MSG_RESULT(no)
1131             $1_CFLAGS=""
1132             $1_LIBS=""
1133             ## If we have a custom action on failure, don't print errors, but
1134             ## do set a variable so people can do so.
1135             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
1136             ifelse([$4], ,echo $$1_PKG_ERRORS,)
1137         fi
1138
1139         AC_SUBST($1_CFLAGS)
1140         AC_SUBST($1_LIBS)
1141      else
1142         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1143         echo "*** See http://www.freedesktop.org/software/pkgconfig"
1144      fi
1145   fi
1146
1147   if test $succeeded = yes; then
1148      ifelse([$3], , :, [$3])
1149   else
1150      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
1151   fi
1152 ])
1153
1154
1155 if test "${with_sound}" != "no"; then
1156   # Sound support for GNU/Linux and the free BSDs.
1157   AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h)
1158   # Emulation library used on NetBSD.
1159   AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1160   AC_SUBST(LIBSOUND)
1161
1162   ALSA_REQUIRED=1.0.0
1163   ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1164   PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
1165   if test $HAVE_ALSA = yes; then
1166     SAVE_CFLAGS="$CFLAGS"
1167     SAVE_LDFLAGS="$LDFLAGS"
1168     CFLAGS="$ALSA_CFLAGS $CFLAGS"
1169     LDFLAGS="$ALSA_LIBS $LDFLAGS"
1170     AC_TRY_COMPILE([#include <asoundlib.h>], [snd_lib_error_set_handler (0);],
1171                     emacs_alsa_normal=yes,
1172                     emacs_alsa_normal=no)
1173     if test "$emacs_alsa_normal" != yes; then
1174       AC_TRY_COMPILE([#include <alsa/asoundlib.h>],
1175                      [snd_lib_error_set_handler (0);],
1176                      emacs_alsa_subdir=yes,
1177                      emacs_alsa_subdir=no)
1178       if test "$emacs_alsa_subdir" != yes; then
1179         AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1180       fi
1181       ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1182     fi
1183
1184     CFLAGS="$SAVE_CFLAGS"
1185     LDFLAGS="$SAVE_LDFLAGS"
1186     LIBSOUND="$LIBSOUND $ALSA_LIBS"
1187     CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1188     AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1189   fi
1190   AC_SUBST(CFLAGS_SOUND)
1191 fi
1192
1193 dnl checks for header files
1194 AC_CHECK_HEADERS(sys/select.h sys/timeb.h sys/time.h unistd.h utime.h \
1195   linux/version.h sys/systeminfo.h termios.h limits.h string.h stdlib.h \
1196   termcap.h stdio_ext.h fcntl.h strings.h coff.h pty.h sys/mman.h \
1197   sys/param.h sys/vlimit.h sys/resource.h locale.h sys/_mbstate_t.h \
1198   sys/utsname.h pwd.h)
1199
1200 AC_MSG_CHECKING(if personality LINUX32 can be set)
1201 AC_TRY_COMPILE([#include <sys/personality.h>], [personality (PER_LINUX32)],
1202                emacs_cv_personality_linux32=yes,
1203                emacs_cv_personality_linux32=no)
1204 AC_MSG_RESULT($emacs_cv_personality_linux32)
1205
1206 if test $emacs_cv_personality_linux32 = yes; then
1207   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1208             [Define to 1 if personality LINUX32 can be set.])
1209 fi
1210
1211 dnl On Solaris 8 there's a compilation warning for term.h because
1212 dnl it doesn't define `bool'.
1213 AC_CHECK_HEADERS(term.h, , , -)
1214 AC_HEADER_STDC
1215 AC_HEADER_TIME
1216 AC_CHECK_DECLS([sys_siglist])
1217 if test $ac_cv_have_decl_sys_siglist != yes; then
1218   # For Tru64, at least:
1219   AC_CHECK_DECLS([__sys_siglist])
1220   if test $ac_cv_have_decl___sys_siglist = yes; then
1221     AC_DEFINE(sys_siglist, __sys_siglist,
1222               [Define to any substitute for sys_siglist.])
1223   fi
1224 fi
1225 AC_HEADER_SYS_WAIT
1226
1227 dnl Some systems have utime.h but don't declare the struct anyplace.
1228 AC_CACHE_CHECK(for struct utimbuf, emacs_cv_struct_utimbuf,
1229 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1230 #include <sys/time.h>
1231 #include <time.h>
1232 #else
1233 #ifdef HAVE_SYS_TIME_H
1234 #include <sys/time.h>
1235 #else
1236 #include <time.h>
1237 #endif
1238 #endif
1239 #ifdef HAVE_UTIME_H
1240 #include <utime.h>
1241 #endif], [static struct utimbuf x; x.actime = x.modtime;],
1242   emacs_cv_struct_utimbuf=yes, emacs_cv_struct_utimbuf=no))
1243 if test $emacs_cv_struct_utimbuf = yes; then
1244   AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if `struct utimbuf' is declared by <utime.h>.])
1245 fi
1246
1247 dnl checks for typedefs
1248 AC_TYPE_SIGNAL
1249
1250 dnl Check for speed_t typedef.
1251 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1252   [AC_TRY_COMPILE([#include <termios.h>], [speed_t x = 1;],
1253     emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1254 if test $emacs_cv_speed_t = yes; then
1255   AC_DEFINE(HAVE_SPEED_T, 1,
1256            [Define to 1 if `speed_t' is declared by <termios.h>.])
1257 fi
1258
1259 AC_CACHE_CHECK(for struct timeval, emacs_cv_struct_timeval,
1260 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1261 #include <sys/time.h>
1262 #include <time.h>
1263 #else
1264 #ifdef HAVE_SYS_TIME_H
1265 #include <sys/time.h>
1266 #else
1267 #include <time.h>
1268 #endif
1269 #endif], [static struct timeval x; x.tv_sec = x.tv_usec;],
1270   emacs_cv_struct_timeval=yes, emacs_cv_struct_timeval=no))
1271 HAVE_TIMEVAL=$emacs_cv_struct_timeval
1272 if test $emacs_cv_struct_timeval = yes; then
1273   AC_DEFINE(HAVE_TIMEVAL, 1, [Define to 1 if `struct timeval' is declared by <sys/time.h>.])
1274 fi
1275
1276 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1277 AC_TRY_COMPILE([#include <math.h>],
1278 [static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;],
1279   emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1280 HAVE_EXCEPTION=$emacs_cv_struct_exception
1281 if test $emacs_cv_struct_exception != yes; then
1282   AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1283 fi
1284
1285 AC_CHECK_HEADERS(sys/socket.h)
1286 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1287 #if HAVE_SYS_SOCKET_H
1288 #include <sys/socket.h>
1289 #endif])
1290
1291 dnl checks for structure members
1292 AC_STRUCT_TM
1293 AC_STRUCT_TIMEZONE
1294 AC_CHECK_MEMBER(struct tm.tm_gmtoff,
1295                 [AC_DEFINE(HAVE_TM_GMTOFF, 1,
1296                            [Define to 1 if `tm_gmtoff' is member of `struct tm'.])],,
1297                 [#include <time.h>])
1298 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1299                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1300                   struct ifreq.ifr_addr], , ,
1301                  [AC_INCLUDES_DEFAULT
1302 #if HAVE_SYS_SOCKET_H
1303 #include <sys/socket.h>
1304 #endif
1305 #if HAVE_NET_IF_H
1306 #include <net/if.h>
1307 #endif])
1308
1309 dnl checks for compiler characteristics
1310
1311 dnl Testing __STDC__ to determine prototype support isn't good enough.
1312 dnl DEC C, for instance, doesn't define it with default options, and
1313 dnl is used on 64-bit systems (OSF Alphas).  Similarly for volatile
1314 dnl and void *.
1315 AC_C_PROTOTYPES
1316 AC_C_VOLATILE
1317 AC_C_CONST
1318 dnl This isn't useful because we can't turn on use of `inline' unless
1319 dnl the compiler groks `extern inline'.
1320 dnl AC_C_INLINE
1321 AC_CACHE_CHECK([for void * support], emacs_cv_void_star,
1322   [AC_TRY_COMPILE(, [void * foo;],
1323                    emacs_cv_void_star=yes, emacs_cv_void_star=no)])
1324 if test $emacs_cv_void_star = yes; then
1325   AC_DEFINE(POINTER_TYPE, void)
1326 else
1327   AC_DEFINE(POINTER_TYPE, char)
1328 fi
1329 AH_TEMPLATE(POINTER_TYPE,
1330             [Define as `void' if your compiler accepts `void *'; otherwise
1331              define as `char'.])dnl
1332
1333
1334
1335 dnl This could be used for targets which can have both byte sexes.
1336 dnl We could presumably replace the hardwired WORDS_BIG_ENDIAN generally.
1337 dnl AC_C_BIGENDIAN
1338
1339 dnl check for Make feature
1340 AC_PROG_MAKE_SET
1341
1342 dnl checks for operating system services
1343 AC_SYS_LONG_FILE_NAMES
1344
1345 #### Choose a window system.
1346
1347 AC_PATH_X
1348 if test "$no_x" = yes; then
1349   window_system=none
1350 else
1351   window_system=x11
1352 fi
1353
1354 ## Workaround for bug in autoconf <= 2.62.
1355 ## http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01551.html
1356 ## No need to do anything special for these standard directories.
1357 ## This is an experiment, take it out if it causes problems.
1358 if test -n "${x_libraries}" && test x"${x_libraries}" != xNONE; then
1359
1360    x_libraries=`echo :${x_libraries}: | sed -e 's|:/usr/lib64:|:|g' -e 's|:/lib64:|:|g' -e 's|^:||' -e 's|:$||'`
1361
1362 fi
1363
1364 if test "${x_libraries}" != NONE; then
1365   if test -n "${x_libraries}"; then
1366     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1367     LD_SWITCH_X_SITE_AUX=-R`echo ${x_libraries} | sed -e "s/:/ -R/g"`
1368   fi
1369   x_default_search_path=""
1370   x_search_path=${x_libraries}
1371   if test -z "${x_search_path}"; then
1372     x_search_path=/usr/lib
1373   fi
1374   for x_library in `echo ${x_search_path}: | \
1375                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1376     x_search_path="\
1377 ${x_library}/X11/%L/%T/%N%C%S:\
1378 ${x_library}/X11/%l/%T/%N%C%S:\
1379 ${x_library}/X11/%T/%N%C%S:\
1380 ${x_library}/X11/%L/%T/%N%S:\
1381 ${x_library}/X11/%l/%T/%N%S:\
1382 ${x_library}/X11/%T/%N%S"
1383     if test x"${x_default_search_path}" = x; then
1384       x_default_search_path=${x_search_path}
1385     else
1386       x_default_search_path="${x_search_path}:${x_default_search_path}"
1387     fi
1388   done
1389 fi
1390 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1391   C_SWITCH_X_SITE=-I`echo ${x_includes} | sed -e "s/:/ -I/g"`
1392 fi
1393
1394 if test x"${x_includes}" = x; then
1395   bitmapdir=/usr/include/X11/bitmaps
1396 else
1397   # accumulate include directories that have X11 bitmap subdirectories
1398   bmd_acc="dummyval"
1399   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1400     if test -d "${bmd}/X11/bitmaps"; then
1401       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1402     fi
1403     if test -d "${bmd}/bitmaps"; then
1404       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1405     fi
1406   done
1407   if test ${bmd_acc} != "dummyval"; then
1408     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1409   fi
1410 fi
1411
1412 HAVE_CARBON=no
1413 if test "${with_carbon}" != no; then
1414   AC_CHECK_HEADER(Carbon/Carbon.h, HAVE_CARBON=yes)
1415 fi
1416 if test "${window_system}" = x11 && test "${HAVE_CARBON}" = yes; then
1417   if test "${with_carbon+set}" != set \
1418      && test "${carbon_appdir_x+set}" != set; then
1419     for var in with_x with_x_toolkit with_xim \
1420                with_xpm with_jpeg with_tiff with_gif with_png; do
1421       if eval test \"\${$var+set}\" = set; then
1422         HAVE_CARBON=no
1423         break
1424       fi
1425     done
1426   fi
1427 fi
1428 if test "${HAVE_CARBON}" = yes; then
1429   window_system=mac
1430 fi
1431
1432 case "${window_system}" in
1433   x11 )
1434     HAVE_X_WINDOWS=yes
1435     HAVE_X11=yes
1436     case "${with_x_toolkit}" in
1437       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1438       motif ) USE_X_TOOLKIT=MOTIF ;;
1439       gtk ) with_gtk=yes
1440 dnl Dont set this for GTK.  A lot of tests below assumes Xt when
1441 dnl USE_X_TOOLKIT is set.
1442             USE_X_TOOLKIT=none ;;
1443       no ) USE_X_TOOLKIT=none ;;
1444 dnl If user did not say whether to use a toolkit, make this decision later:
1445 dnl use the toolkit if we have gtk, or X11R5 or newer.
1446       * ) USE_X_TOOLKIT=maybe ;;
1447     esac
1448   ;;
1449   mac | none )
1450     HAVE_X_WINDOWS=no
1451     HAVE_X11=no
1452     USE_X_TOOLKIT=none
1453   ;;
1454 esac
1455
1456 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1457    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1458    if test "$HAVE_XSERVER" = true ||
1459       test -n "$DISPLAY" ||
1460       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1461         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1462 were found.  You should install the relevant development files for X
1463 and for the toolkit you want, such as Gtk+, Lesstif or Motif.  Also make
1464 sure you have development files for image handling, i.e.
1465 tiff, gif, jpeg, png and xpm.
1466 If you are sure you want Emacs compiled without X window support, pass
1467   --without-x
1468 to configure.])
1469    fi
1470 fi
1471
1472 ### If we're using X11, we should use the X menu package.
1473 HAVE_MENUS=no
1474 case ${HAVE_X11} in
1475   yes ) HAVE_MENUS=yes ;;
1476 esac
1477
1478 ### Compute the unexec source name from the object name.
1479 UNEXEC_SRC="`echo ${unexec} | sed 's/\.o/.c/'`"
1480
1481 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1482 # Assume not, until told otherwise.
1483 GNU_MALLOC=yes
1484 doug_lea_malloc=yes
1485 AC_CHECK_FUNC(malloc_get_state, ,doug_lea_malloc=no)
1486 AC_CHECK_FUNC(malloc_set_state, ,doug_lea_malloc=no)
1487 AC_CACHE_CHECK(whether __after_morecore_hook exists,
1488                emacs_cv_var___after_morecore_hook,
1489 [AC_TRY_LINK([extern void (* __after_morecore_hook)();],[__after_morecore_hook = 0],
1490   emacs_cv_var___after_morecore_hook=yes,
1491   emacs_cv_var___after_morecore_hook=no)])
1492 if test $emacs_cv_var___after_morecore_hook = no; then
1493   doug_lea_malloc=no
1494 fi
1495 if test "${system_malloc}" = "yes"; then
1496   GNU_MALLOC=no
1497   GNU_MALLOC_reason="
1498     (The GNU allocators don't work with this system configuration.)"
1499 fi
1500 if test "$doug_lea_malloc" = "yes" ; then
1501   if test "$GNU_MALLOC" = yes ; then
1502     GNU_MALLOC_reason="
1503       (Using Doug Lea's new malloc from the GNU C Library.)"
1504   fi
1505   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1506             [Define to 1 if you are using the GNU C Library.])
1507 fi
1508
1509 if test x"${REL_ALLOC}" = x; then
1510   REL_ALLOC=${GNU_MALLOC}
1511 fi
1512
1513 dnl For now, need to use an explicit `#define USE_MMAP_FOR_BUFFERS 1'
1514 dnl the system configuration file (s/*.h) to turn the use of mmap
1515 dnl in the relocating allocator on.
1516
1517 AC_FUNC_MMAP
1518 if test $use_mmap_for_buffers = yes; then
1519   REL_ALLOC=no
1520 fi
1521
1522 LIBS="$libsrc_libs $LIBS"
1523
1524 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1525 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1526 AC_CHECK_LIB(dnet, dnet_ntoa)
1527 dnl This causes -lresolv to get used in subsequent tests,
1528 dnl which causes failures on some systems such as HPUX 9.
1529 dnl AC_CHECK_LIB(resolv, gethostbyname)
1530
1531 dnl FIXME replace main with a function we actually want from this library.
1532 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1533
1534 AC_CHECK_LIB(pthreads, cma_open)
1535
1536 dnl Check for need for bigtoc support on IBM AIX
1537
1538 case ${host_os} in
1539 aix*)
1540   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1541     case $GCC in
1542     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1543     *) gdb_cv_bigtoc=-bbigtoc ;;
1544     esac
1545
1546     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1547     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1548   ])
1549   ;;
1550 esac
1551
1552 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1553 # used for the tests that follow.  We set them back to REAL_CFLAGS and
1554 # REAL_CPPFLAGS later on.
1555
1556 REAL_CPPFLAGS="$CPPFLAGS"
1557
1558 if test "${HAVE_X11}" = "yes"; then
1559   DEFS="$C_SWITCH_X_SITE $DEFS"
1560   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1561   LIBS="$LIBX $LIBS"
1562   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1563   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1564
1565   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1566   # This is handled by LD_SWITCH_X_SITE_AUX during the real build,
1567   # but it's more convenient here to set LD_RUN_PATH
1568   # since this also works on hosts that don't understand LD_SWITCH_X_SITE_AUX.
1569   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1570     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1571     export LD_RUN_PATH
1572   fi
1573
1574   if test "${opsys}" = "gnu-linux"; then
1575     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1576     AC_TRY_LINK([],
1577      [XOpenDisplay ("foo");],
1578      [xlinux_first_failure=no],
1579      [xlinux_first_failure=yes])
1580     if test "${xlinux_first_failure}" = "yes"; then
1581       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1582       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1583       OLD_CPPFLAGS="$CPPFLAGS"
1584       OLD_LIBS="$LIBS"
1585       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1586       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1587       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1588       LIBS="$LIBS -b i486-linuxaout"
1589       AC_TRY_LINK([],
1590        [XOpenDisplay ("foo");],
1591        [xlinux_second_failure=no],
1592        [xlinux_second_failure=yes])
1593       if test "${xlinux_second_failure}" = "yes"; then
1594         # If we get the same failure with -b, there is no use adding -b.
1595         # So take it out.  This plays safe.
1596         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1597         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1598         CPPFLAGS="$OLD_CPPFLAGS"
1599         LIBS="$OLD_LIBS"
1600         AC_MSG_RESULT(no)
1601       else
1602         AC_MSG_RESULT(yes)
1603       fi
1604     else
1605       AC_MSG_RESULT(no)
1606     fi
1607   fi
1608
1609   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1610   # header files included from there.
1611   AC_MSG_CHECKING(for Xkb)
1612   AC_TRY_LINK([#include <X11/Xlib.h>
1613 #include <X11/XKBlib.h>],
1614         [XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);],
1615         emacs_xkb=yes, emacs_xkb=no)
1616   AC_MSG_RESULT($emacs_xkb)
1617   if test $emacs_xkb = yes; then
1618     AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1619   fi
1620
1621   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1622 XScreenNumberOfScreen XSetWMProtocols)
1623 fi
1624
1625 if test "${window_system}" = "x11"; then
1626   AC_MSG_CHECKING(X11 version 6)
1627   AC_CACHE_VAL(emacs_cv_x11_version_6,
1628   [AC_TRY_LINK([#include <X11/Xlib.h>],
1629 [#if XlibSpecificationRelease < 6
1630 fail;
1631 #endif
1632 ], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1633   if test $emacs_cv_x11_version_6 = yes; then
1634     AC_MSG_RESULT(6 or newer)
1635     AC_DEFINE(HAVE_X11R6, 1,
1636               [Define to 1 if you have the X11R6 or newer version of Xlib.])
1637   else
1638     AC_MSG_RESULT(before 6)
1639   fi
1640 fi
1641
1642
1643 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
1644 HAVE_RSVG=no
1645 if test "${HAVE_X11}" = "yes" || test "${HAVE_CARBON}" = "yes"; then
1646   if test "${with_rsvg}" != "no"; then
1647     RSVG_REQUIRED=2.0.0
1648     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
1649
1650     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, :, :)
1651     AC_SUBST(RSVG_CFLAGS)
1652     AC_SUBST(RSVG_LIBS)
1653
1654     if test ".${RSVG_CFLAGS}" != "."; then
1655       HAVE_RSVG=yes
1656       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
1657       CFLAGS="$CFLAGS $RSVG_CFLAGS"
1658       LIBS="$RSVG_LIBS $LIBS"
1659     fi
1660   fi
1661 fi
1662
1663
1664 HAVE_GTK=no
1665 if test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
1666   GLIB_REQUIRED=2.6
1667   GTK_REQUIRED=2.6
1668   GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1669
1670   dnl Checks for libraries.
1671   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1672   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1673      AC_MSG_ERROR($GTK_PKG_ERRORS)
1674   fi
1675 fi
1676
1677
1678 if test x"$pkg_check_gtk" = xyes; then
1679
1680   AC_SUBST(GTK_CFLAGS)
1681   AC_SUBST(GTK_LIBS)
1682   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
1683   CFLAGS="$CFLAGS $GTK_CFLAGS"
1684   LIBS="$GTK_LIBS $LIBS"
1685   dnl Try to compile a simple GTK program.
1686   GTK_COMPILES=no
1687   AC_CHECK_FUNCS(gtk_main, GTK_COMPILES=yes)
1688   if test "${GTK_COMPILES}" != "yes"; then
1689     if test "$USE_X_TOOLKIT" != "maybe"; then
1690       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
1691     fi
1692   else
1693     HAVE_GTK=yes
1694     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
1695     USE_X_TOOLKIT=none
1696     if $PKG_CONFIG --atleast-version=2.10 gtk+-2.0; then
1697       :
1698     else
1699       AC_MSG_WARN([[Your version of Gtk+ will have problems with
1700        closing open displays.  This is no problem if you just use
1701        one display, but if you use more than one and close one of them
1702        Emacs may crash.]])
1703       sleep 3
1704     fi
1705   fi
1706
1707 fi
1708
1709
1710 if test "${HAVE_GTK}" = "yes"; then
1711
1712   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
1713   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
1714   if test "$with_toolkit_scroll_bars" != no; then
1715     with_toolkit_scroll_bars=yes
1716   fi
1717
1718   dnl  Check if we can use multiple displays with this GTK version.
1719   dnl  If gdk_display_open exists, assume all others are there also.
1720   HAVE_GTK_MULTIDISPLAY=no
1721   AC_CHECK_FUNCS(gdk_display_open, HAVE_GTK_MULTIDISPLAY=yes)
1722   if test "${HAVE_GTK_MULTIDISPLAY}" = "yes"; then
1723     AC_DEFINE(HAVE_GTK_MULTIDISPLAY, 1,
1724               [Define to 1 if GTK can handle more than one display.])
1725   fi
1726
1727   dnl  Check if we have the old file selection dialog.
1728   dnl  If gdk_display_open exists, assume all others are there also.
1729   HAVE_GTK_FILE_SELECTION=no
1730   AC_CHECK_FUNCS(gtk_file_selection_new, HAVE_GTK_FILE_SELECTION=yes)
1731
1732   dnl  Check if we have the new file chooser dialog
1733   dnl  If gdk_display_open exists, assume all others are there also.
1734   HAVE_GTK_FILE_CHOOSER=no
1735   AC_CHECK_FUNCS(gtk_file_chooser_dialog_new, HAVE_GTK_FILE_CHOOSER=yes)
1736
1737   if test "$HAVE_GTK_FILE_SELECTION" = yes \
1738      && test "$HAVE_GTK_FILE_CHOOSER" = yes;  then
1739     AC_DEFINE(HAVE_GTK_FILE_BOTH, 1,
1740               [Define to 1 if GTK has both file selection and chooser dialog.])
1741   fi
1742
1743   dnl Check if pthreads are available.  Emacs only needs this when using
1744   dnl gtk_file_chooser under Gnome.
1745   if test "$HAVE_GTK_FILE_CHOOSER" = yes; then
1746     HAVE_GTK_AND_PTHREAD=no
1747     AC_CHECK_HEADERS(pthread.h)
1748     if test "$ac_cv_header_pthread_h"; then
1749       AC_CHECK_LIB(pthread, pthread_self, HAVE_GTK_AND_PTHREAD=yes)
1750     fi
1751     if test "$HAVE_GTK_AND_PTHREAD" = yes; then
1752       case "${canonical}" in
1753         *-hpux*) ;;
1754         *) GTK_LIBS="$GTK_LIBS -lpthread" ;;
1755       esac
1756       AC_DEFINE(HAVE_GTK_AND_PTHREAD, 1,
1757                [Define to 1 if you have GTK and pthread (-lpthread).])
1758     fi
1759   fi
1760 fi
1761
1762 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
1763 dnl other platforms.  Support for higher D-Bus versions than 1.0 is
1764 dnl also not configured.
1765 HAVE_DBUS=no
1766 if test "${with_dbus}" = "yes"; then
1767    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
1768    if test "$HAVE_DBUS" = yes; then
1769       AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
1770    fi
1771 fi
1772
1773 dnl Do not put whitespace before the #include statements below.
1774 dnl Older compilers (eg sunos4 cc) choke on it.
1775 HAVE_XAW3D=no
1776 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
1777   if test "$with_xaw3d" != no; then
1778     AC_MSG_CHECKING(for xaw3d)
1779     AC_CACHE_VAL(emacs_cv_xaw3d,
1780     [AC_TRY_LINK([
1781 #include <X11/Intrinsic.h>
1782 #include <X11/Xaw3d/Simple.h>],
1783       [],
1784       emacs_cv_xaw3d=yes,
1785       emacs_cv_xaw3d=no)])
1786   else
1787     emacs_cv_xaw3d=no
1788   fi
1789   if test $emacs_cv_xaw3d = yes; then
1790     AC_MSG_RESULT([yes; using Lucid toolkit])
1791     USE_X_TOOLKIT=LUCID
1792     HAVE_XAW3D=yes
1793     AC_DEFINE(HAVE_XAW3D, 1,
1794               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
1795   else
1796     AC_MSG_RESULT(no)
1797     AC_MSG_CHECKING(for libXaw)
1798     AC_CACHE_VAL(emacs_cv_xaw,
1799     [AC_TRY_LINK([
1800 #include <X11/Intrinsic.h>
1801 #include <X11/Xaw/Simple.h>],
1802       [],
1803       emacs_cv_xaw=yes,
1804       emacs_cv_xaw=no)])
1805     if test $emacs_cv_xaw = yes; then
1806       AC_MSG_RESULT([yes; using Lucid toolkit])
1807       USE_X_TOOLKIT=LUCID
1808     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
1809       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
1810     else
1811       AC_MSG_RESULT([no; do not use toolkit by default])
1812       USE_X_TOOLKIT=none
1813     fi
1814   fi
1815 fi
1816
1817 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
1818
1819 if test "${USE_X_TOOLKIT}" != "none"; then
1820   AC_MSG_CHECKING(X11 toolkit version)
1821   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
1822   [AC_TRY_LINK([#include <X11/Intrinsic.h>],
1823 [#if XtSpecificationRelease < 6
1824 fail;
1825 #endif
1826 ], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
1827   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
1828   if test $emacs_cv_x11_toolkit_version_6 = yes; then
1829     AC_MSG_RESULT(6 or newer)
1830     AC_DEFINE(HAVE_X11XTR6, 1,
1831               [Define to 1 if you have the X11R6 or newer version of Xt.])
1832   else
1833     AC_MSG_RESULT(before 6)
1834   fi
1835
1836 dnl If using toolkit, check whether libXmu.a exists.
1837 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
1838   OLDLIBS="$LIBS"
1839   if test x$HAVE_X11XTR6 = xyes; then
1840     LIBS="-lXt -lSM -lICE $LIBS"
1841   else
1842     LIBS="-lXt $LIBS"
1843   fi
1844   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
1845   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
1846 fi
1847
1848 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
1849 if test "${HAVE_X11}" = "yes"; then
1850   if test "${USE_X_TOOLKIT}" != "none"; then
1851     AC_CHECK_LIB(Xext, XShapeQueryExtension)
1852   fi
1853 fi
1854
1855 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
1856   AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
1857   [AC_TRY_COMPILE([#include <Xm/Xm.h>],
1858     [#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
1859 int x = 5;
1860 #else
1861 Motif version prior to 2.1.
1862 #endif],
1863     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
1864   HAVE_MOTIF_2_1=$emacs_cv_motif_version_2_1
1865   if test $emacs_cv_motif_version_2_1 = yes; then
1866     HAVE_LIBXP=no
1867     AC_DEFINE(HAVE_MOTIF_2_1, 1,
1868               [Define to 1 if you have Motif 2.1 or newer.])
1869     AC_CHECK_LIB(Xp, XpCreateContext, HAVE_LIBXP=yes)
1870     if test ${HAVE_LIBXP} = yes; then
1871       AC_DEFINE(HAVE_LIBXP, 1,
1872                 [Define to 1 if you have the Xp library (-lXp).])
1873     fi
1874   else
1875     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
1876     # We put this in CFLAGS temporarily to precede other -I options
1877     # that might be in CFLAGS temporarily.
1878     # We put this in CPPFLAGS where it precedes the other -I options.
1879     OLD_CPPFLAGS=$CPPFLAGS
1880     OLD_CFLAGS=$CFLAGS
1881     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
1882     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
1883     [AC_TRY_COMPILE([#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>],
1884       [int x = 5;],
1885       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
1886     if test $emacs_cv_lesstif = yes; then
1887       # Make sure this -I option remains in CPPFLAGS after it is set
1888       # back to REAL_CPPFLAGS.
1889       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
1890       # have those other -I options anyway.  Ultimately, having this
1891       # directory ultimately in CPPFLAGS will be enough.
1892       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
1893       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
1894     else
1895       CFLAGS=$OLD_CFLAGS
1896       CPPFLAGS=$OLD_CPPFLAGS
1897     fi
1898   fi
1899 fi
1900
1901 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
1902 dnl using Motif or Xaw3d is available, and unless
1903 dnl --with-toolkit-scroll-bars=no was specified.
1904
1905 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
1906             [Define to 1 if we should use toolkit scroll bars.])dnl
1907 USE_TOOLKIT_SCROLL_BARS=no
1908 if test "${with_toolkit_scroll_bars}" != "no"; then
1909   if test "${USE_X_TOOLKIT}" != "none"; then
1910     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
1911       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1912       HAVE_XAW3D=no
1913       USE_TOOLKIT_SCROLL_BARS=yes
1914     elif test "${HAVE_XAW3D}" = "yes"; then
1915       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1916       USE_TOOLKIT_SCROLL_BARS=yes
1917     fi
1918   elif test "${HAVE_GTK}" = "yes"; then
1919     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1920     USE_TOOLKIT_SCROLL_BARS=yes
1921   elif test "${HAVE_CARBON}" = "yes"; then
1922     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1923     USE_TOOLKIT_SCROLL_BARS=yes
1924   fi
1925 fi
1926
1927 dnl See if XIM is available.
1928 AC_TRY_COMPILE([
1929           #include <X11/Xlib.h>
1930           #include <X11/Xresource.h>],
1931          [XIMProc  callback;],
1932          [HAVE_XIM=yes
1933          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
1934          HAVE_XIM=no)
1935
1936 dnl `--with-xim' now controls only the initial value of use_xim at run time.
1937
1938 if test "${with_xim}" != "no"; then
1939   AC_DEFINE(USE_XIM, 1,
1940             [Define to 1 if we should use XIM, if it is available.])
1941 fi
1942
1943
1944 if test "${HAVE_XIM}" != "no"; then
1945   late_CFLAGS=$CFLAGS
1946   if test "$GCC" = yes; then
1947     CFLAGS="$CFLAGS --pedantic-errors"
1948   fi
1949   AC_TRY_COMPILE([
1950 #include <X11/Xlib.h>
1951 #include <X11/Xresource.h>],
1952 [Display *display;
1953 XrmDatabase db;
1954 char *res_name;
1955 char *res_class;
1956 XIMProc  callback;
1957 XPointer *client_data;
1958 #ifndef __GNUC__
1959 /* If we're not using GCC, it's probably not XFree86, and this is
1960    probably right, but we can't use something like --pedantic-errors.  */
1961 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
1962                                            char*, XIMProc, XPointer*);
1963 #endif
1964 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
1965    client_data);],
1966     [emacs_cv_arg6_star=yes])
1967   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
1968          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
1969 either XPointer or XPointer*.])dnl
1970   if test "$emacs_cv_arg6_star" = yes; then
1971     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
1972   else
1973     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
1974   fi
1975   CFLAGS=$late_CFLAGS
1976 fi
1977
1978 ### Start of font-backend section.
1979
1980 ## Use -lXft if available, unless `--with-freetype=no' nor `--with-xft=no'.
1981 HAVE_XFT=maybe
1982 if test "x${with_freetype}" = "xno"; then
1983   with_xft="no";
1984 fi
1985 if test "x${with_xft}" != "xno"; then
1986
1987   PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
1988   if test "$HAVE_XFT" != no; then
1989     OLD_CPPFLAGS="$CPPFLAGS"
1990     OLD_CFLAGS="$CFLAGS"
1991     OLD_LIBS="$LIBS"
1992     CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
1993     CFLAGS="$CFLAGS $XFT_CFLAGS"
1994     LIBS="$XFT_LIBS $LIBS"
1995     AC_CHECK_HEADER(X11/Xft/Xft.h,
1996       AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS))
1997
1998     if test "${HAVE_XFT}" = "yes"; then
1999       AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
2000         AC_SUBST(XFT_LIBS)
2001       C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
2002     else
2003       CPPFLAGS="$OLD_CPPFLAGS"
2004       CFLAGS="$OLD_CFLAGS"
2005       LIBS="$OLD_LIBS"
2006     fi                        # "${HAVE_XFT}" = "yes"
2007   fi                          # "$HAVE_XFT" != no
2008 fi                            # "x${with_xft}" != "xno"
2009
2010 dnl For the "Does Emacs use" message at the end.
2011 if test "$HAVE_XFT" != "yes"; then
2012    HAVE_XFT=no
2013 fi
2014
2015
2016 HAVE_FREETYPE=no
2017 ### Use -lfreetype if available, unless `--with-freetype=no'.
2018 if test "${HAVE_XFT}" = "yes"; then
2019   dnl As we use Xft, we anyway use freetype.
2020   dnl In this case, there's no need of additional CFLAGS and LIBS.
2021   HAVE_FREETYPE=yes
2022 elif test "x${with_freetype}" != "xno"; then
2023
2024   PKG_CHECK_MODULES(FREETYPE, freetype2, HAVE_FREETYPE=yes, HAVE_FREETYPE=no)
2025   if test "${HAVE_FREETYPE}" = "yes"; then
2026     PKG_CHECK_MODULES(FONTCONFIG, fontconfig, HAVE_FC=yes, HAVE_FC=no)
2027     if test "${HAVE_FC}" = "no"; then
2028       dnl Without fontconfig, we can't use freetype at the moment.
2029       HAVE_FREETYPE=no
2030     fi
2031   fi
2032 fi
2033
2034 HAVE_LIBOTF=no
2035 if test "${HAVE_FREETYPE}" = "yes"; then
2036   AC_DEFINE(HAVE_FREETYPE, 1,
2037             [Define to 1 if using the freetype and fontconfig libraries.])
2038   if test "${with_libotf}" != "no"; then
2039     PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
2040                       HAVE_LIBOTF=no)
2041     if test "$HAVE_LIBOTF" = "yes"; then
2042       AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
2043     fi
2044   fi
2045 dnl FIXME should there be an error if HAVE_FREETYPE != yes?
2046 dnl Does the new font backend require it, or can it work without it?
2047 fi
2048
2049 HAVE_M17N_FLT=no
2050 if test "${with_m17n_flt}" != "no"; then
2051   PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no)
2052   if test "$HAVE_M17N_FLT" = "yes"; then
2053     AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
2054   fi
2055 fi
2056
2057 AC_SUBST(FREETYPE_CFLAGS)
2058 AC_SUBST(FREETYPE_LIBS)
2059 AC_SUBST(FONTCONFIG_CFLAGS)
2060 AC_SUBST(FONTCONFIG_LIBS)
2061 AC_SUBST(LIBOTF_CFLAGS)
2062 AC_SUBST(LIBOTF_LIBS)
2063 AC_SUBST(M17N_FLT_CFLAGS)
2064 AC_SUBST(M17N_FLT_LIBS)
2065
2066 ### End of font-backend section.
2067
2068 ### Use -lXpm if available, unless `--with-xpm=no'.
2069 HAVE_XPM=no
2070 if test "${HAVE_X11}" = "yes"; then
2071   if test "${with_xpm}" != "no"; then
2072     AC_CHECK_HEADER(X11/xpm.h,
2073       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
2074     if test "${HAVE_XPM}" = "yes"; then
2075       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2076       AC_EGREP_CPP(no_return_alloc_pixels,
2077       [#include "X11/xpm.h"
2078 #ifndef XpmReturnAllocPixels
2079 no_return_alloc_pixels
2080 #endif
2081       ], HAVE_XPM=no, HAVE_XPM=yes)
2082
2083       if test "${HAVE_XPM}" = "yes"; then
2084         AC_MSG_RESULT(yes)
2085       else
2086         AC_MSG_RESULT(no)
2087       fi
2088     fi
2089   fi
2090
2091   if test "${HAVE_XPM}" = "yes"; then
2092     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm libary (-lXpm).])
2093   fi
2094 fi
2095
2096 ### Use -ljpeg if available, unless `--with-jpeg=no'.
2097 HAVE_JPEG=no
2098 if test "${HAVE_X11}" = "yes"; then
2099   if test "${with_jpeg}" != "no"; then
2100     dnl Checking for jpeglib.h can lose because of a redefinition of
2101     dnl  HAVE_STDLIB_H.
2102     AC_CHECK_HEADER(jerror.h,
2103       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
2104   fi
2105
2106   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
2107   if test "${HAVE_JPEG}" = "yes"; then
2108     AC_DEFINE(HAVE_JPEG)
2109     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
2110         [#include <jpeglib.h>
2111          version=JPEG_LIB_VERSION
2112 ],
2113         [AC_DEFINE(HAVE_JPEG)],
2114         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
2115         HAVE_JPEG=no])
2116   fi
2117 fi
2118
2119 ### Use -lpng if available, unless `--with-png=no'.
2120 HAVE_PNG=no
2121 if test "${HAVE_X11}" = "yes"; then
2122   if test "${with_png}" != "no"; then
2123     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
2124     # in /usr/include/libpng.
2125     AC_CHECK_HEADERS(png.h libpng/png.h)
2126     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
2127       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
2128     fi
2129   fi
2130
2131   if test "${HAVE_PNG}" = "yes"; then
2132     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2133   fi
2134 fi
2135
2136 ### Use -ltiff if available, unless `--with-tiff=no'.
2137 HAVE_TIFF=no
2138 if test "${HAVE_X11}" = "yes"; then
2139   if test "${with_tiff}" != "no"; then
2140     AC_CHECK_HEADER(tiffio.h,
2141       [tifflibs="-lz -lm"
2142       # At least one tiff package requires the jpeg library.
2143       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
2144       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
2145   fi
2146
2147   if test "${HAVE_TIFF}" = "yes"; then
2148     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2149   fi
2150 fi
2151
2152 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
2153 HAVE_GIF=no
2154 if test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no"; then
2155   AC_CHECK_HEADER(gif_lib.h,
2156 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2157 # Earlier versions can crash Emacs.
2158     [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, try_libungif=yes)])
2159
2160   if test "$HAVE_GIF" = yes; then
2161       ac_gif_lib_name="-lgif"
2162   fi
2163
2164 # If gif_lib.h but no libgif, try libungif.
2165   if test x"$try_libungif" = xyes; then
2166     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes)
2167
2168     if test "$HAVE_GIF" = yes; then
2169       AC_DEFINE(LIBGIF, -lungif, [Compiler option to link with the gif library (if not -lgif).])
2170       ac_gif_lib_name="-lungif"
2171     fi
2172   fi
2173
2174   if test "${HAVE_GIF}" = "yes"; then
2175     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif library (default -lgif; otherwise specify with LIBGIF).])
2176   fi
2177 fi
2178
2179 dnl Check for required libraries.
2180 if test "${HAVE_X11}" = "yes"; then
2181   MISSING=""
2182   WITH_NO=""
2183   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
2184     MISSING="libXpm" && WITH_NO="--with-xpm=no"
2185   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
2186     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
2187   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
2188     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
2189   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
2190     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
2191   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
2192     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
2193
2194   if test "X${MISSING}" != X; then
2195     AC_MSG_ERROR([The following required libraries were not found:
2196     $MISSING
2197 Maybe some development libraries/packages are missing?
2198 If you don't want to link with them give
2199     $WITH_NO
2200 as options to configure])
2201   fi
2202 fi
2203
2204 ### Use -lgpm if available, unless `--with-gpm=no'.
2205 HAVE_GPM=no
2206 if test "${with_gpm}" != "no"; then
2207   AC_CHECK_HEADER(gpm.h,
2208     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
2209 fi
2210
2211 if test "${HAVE_GPM}" = "yes"; then
2212   AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
2213 fi
2214
2215 dnl Check for malloc/malloc.h on darwin
2216 AC_CHECK_HEADER(malloc/malloc.h, [AC_DEFINE(HAVE_MALLOC_MALLOC_H, 1, [Define to 1 if you have the <malloc/malloc.h> header file.])])
2217
2218 ### Use Mac OS X Carbon API to implement GUI.
2219 if test "${HAVE_CARBON}" = "yes"; then
2220   AC_DEFINE(HAVE_CARBON, 1, [Define to 1 if you are using the Carbon API on Mac OS X.])
2221   AC_CHECK_HEADERS(AvailabilityMacros.h)
2222   ## Specify the install directory
2223   carbon_appdir=
2224   if test "${carbon_appdir_x}" != ""; then
2225     case ${carbon_appdir_x} in
2226       y | ye | yes)  carbon_appdir=/Applications ;;
2227       * ) carbon_appdir=${carbon_appdir_x} ;;
2228     esac
2229   fi
2230   # We also have mouse menus.
2231   HAVE_MENUS=yes
2232 fi
2233
2234 ### Use session management (-lSM -lICE) if available
2235 HAVE_X_SM=no
2236 if test "${HAVE_X11}" = "yes"; then
2237   AC_CHECK_HEADER(X11/SM/SMlib.h,
2238     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
2239
2240   if test "${HAVE_X_SM}" = "yes"; then
2241     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2242     case "$LIBS" in
2243       *-lSM*) ;;
2244       *)      LIBS="-lSM -lICE $LIBS" ;;
2245     esac
2246   fi
2247 fi
2248
2249 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2250 AC_CACHE_CHECK(whether netdb declares h_errno,
2251                emacs_cv_netdb_declares_h_errno,
2252 [AC_TRY_LINK([#include <netdb.h>],
2253   [return h_errno;],
2254   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2255 if test $emacs_cv_netdb_declares_h_errno = yes; then
2256   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2257 fi
2258
2259 AC_FUNC_ALLOCA
2260
2261 dnl src/alloca.c has been removed.  Could also check if $ALLOCA is set?
2262 dnl FIXME is there an autoconf test that does the right thing, without
2263 dnl needing to call A_M_E afterwards?
2264 if test x"$ac_cv_func_alloca_works" != xyes; then
2265    AC_MSG_ERROR( [a system implementation of alloca is required] )
2266 fi
2267
2268 # fmod, logb, and frexp are found in -lm on most systems.
2269 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2270 AC_CHECK_LIB(m, sqrt)
2271
2272 # Check for mail-locking functions in a "mail" library.  Probably this should
2273 # have the same check as for liblockfile below.
2274 AC_CHECK_LIB(mail, maillock)
2275 dnl Debian, at least:
2276 AC_CHECK_LIB(lockfile, maillock)
2277 # If we have the shared liblockfile, assume we must use it for mail
2278 # locking (e.g. Debian).  If we couldn't link against liblockfile
2279 # (no liblockfile.a installed), ensure that we don't need to.
2280 if test "$ac_cv_lib_lockfile_maillock" = no; then
2281   dnl This works for files generally, not just executables.
2282   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
2283   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2284                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2285   if test $ac_cv_prog_liblockfile = yes; then
2286     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2287 This probably means that movemail could lose mail.
2288 There may be a `development' package to install containing liblockfile.])
2289   else :
2290   fi
2291 fi
2292 AC_CHECK_FUNCS(touchlock)
2293 AC_CHECK_HEADERS(maillock.h)
2294
2295 AC_CHECK_FUNCS(gethostname getdomainname dup2 \
2296 rename closedir mkdir rmdir sysinfo getrusage get_current_dir_name \
2297 random lrand48 bcopy bcmp logb frexp fmod rint cbrt ftime setsid \
2298 strerror fpathconf select mktime euidaccess getpagesize tzset setlocale \
2299 utimes setrlimit setpgid getcwd getwd shutdown getaddrinfo \
2300 __fpending mblen mbrlen mbsinit strsignal setitimer ualarm index rindex \
2301 sendto recvfrom getsockopt setsockopt getsockname getpeername \
2302 gai_strerror mkstemp getline getdelim mremap memmove fsync sync bzero \
2303 memset memcmp difftime memcpy mempcpy mblen mbrlen posix_memalign)
2304
2305 AC_CHECK_HEADERS(sys/un.h)
2306
2307 AC_FUNC_MKTIME
2308 if test "$ac_cv_func_working_mktime" = no; then
2309   AC_DEFINE(BROKEN_MKTIME, 1, [Define to 1 if the mktime function is broken.])
2310 fi
2311
2312 AC_FUNC_GETLOADAVG
2313
2314 AC_FUNC_FSEEKO
2315
2316 # Configure getopt.
2317 m4_include([m4/getopt.m4])
2318 gl_GETOPT_IFELSE([
2319   gl_GETOPT_SUBSTITUTE_HEADER
2320   gl_PREREQ_GETOPT
2321   GETOPTOBJS='getopt.o getopt1.o'
2322 ])
2323 AC_SUBST(GETOPTOBJS)
2324
2325 AC_FUNC_GETPGRP
2326
2327 AC_FUNC_STRFTIME
2328
2329 # UNIX98 PTYs.
2330 AC_CHECK_FUNCS(grantpt)
2331
2332 # PTY-related GNU extensions.
2333 AC_CHECK_FUNCS(getpt)
2334
2335 # Check this now, so that we will NOT find the above functions in ncurses.
2336 # That is because we have not set up to link ncurses in lib-src.
2337 # It's better to believe a function is not available
2338 # than to expect to find it in ncurses.
2339 AC_CHECK_LIB(ncurses, tparm)
2340
2341 # Do we have res_init, for detecting changes in /etc/resolv.conf?
2342
2343 resolv=no
2344 AC_TRY_LINK([#include <netinet/in.h>
2345 #include <arpa/nameser.h>
2346 #include <resolv.h>],
2347     [return res_init();],
2348     have_res_init=yes, have_res_init=no)
2349 if test "$have_res_init" = no; then
2350   OLIBS="$LIBS"
2351   LIBS="$LIBS -lresolv"
2352   AC_MSG_CHECKING(for res_init with -lresolv)
2353   AC_TRY_LINK([#include <netinet/in.h>
2354 #include <arpa/nameser.h>
2355 #include <resolv.h>],
2356     [return res_init();],
2357     have_res_init=yes, have_res_init=no)
2358   AC_MSG_RESULT($have_res_init)
2359   if test "$have_res_init" = yes ; then
2360     resolv=yes
2361   fi
2362   LIBS="$OLIBS"
2363 fi
2364
2365 if test "$have_res_init" = yes; then
2366   AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
2367 fi
2368
2369 # Do we need the Hesiod library to provide the support routines?
2370 if test "$with_hesiod" = yes ; then
2371   # Don't set $LIBS here -- see comments above.
2372   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
2373      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
2374                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
2375   if test "$resolv" = yes ; then
2376     RESOLVLIB=-lresolv
2377   else
2378     RESOLVLIB=
2379   fi
2380   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2381         [AC_DEFINE(HAVE_LIBHESIOD, 1,
2382                   [Define to 1 if you have the hesiod library (-lhesiod).])],
2383         :, $RESOLVLIB)])
2384 fi
2385
2386 # Do we need libresolv (due to res_init or Hesiod)?
2387 if test "$resolv" = yes ; then
2388   AC_DEFINE(HAVE_LIBRESOLV, 1,
2389             [Define to 1 if you have the resolv library (-lresolv).])
2390 fi
2391
2392 # These tell us which Kerberos-related libraries to use.
2393 if test "${with_kerberos+set}" = set; then
2394   AC_CHECK_LIB(com_err, com_err)
2395   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt)
2396   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt)
2397   AC_CHECK_LIB(krb5, krb5_init_context)
2398   if test "${with_kerberos5+set}" != set; then
2399     AC_CHECK_LIB(des425, des_cbc_encrypt,,
2400                  [AC_CHECK_LIB(des, des_cbc_encrypt)])
2401     AC_CHECK_LIB(krb4, krb_get_cred,,
2402                  [AC_CHECK_LIB(krb, krb_get_cred)])
2403   fi
2404
2405   if test "${with_kerberos5+set}" = set; then
2406     AC_CHECK_HEADERS(krb5.h)
2407   else
2408     AC_CHECK_HEADERS(des.h,,
2409                      [AC_CHECK_HEADERS(kerberosIV/des.h,,
2410                                        [AC_CHECK_HEADERS(kerberos/des.h)])])
2411     AC_CHECK_HEADERS(krb.h,,
2412                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
2413                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
2414   fi
2415   AC_CHECK_HEADERS(com_err.h)
2416 fi
2417
2418 # Solaris requires -lintl if you want strerror (which calls dgettext)
2419 # to return localized messages.
2420 AC_CHECK_LIB(intl, dgettext)
2421
2422 AC_MSG_CHECKING(whether localtime caches TZ)
2423 AC_CACHE_VAL(emacs_cv_localtime_cache,
2424 [if test x$ac_cv_func_tzset = xyes; then
2425 AC_TRY_RUN([#include <time.h>
2426 extern char **environ;
2427 unset_TZ ()
2428 {
2429   char **from, **to;
2430   for (to = from = environ; (*to = *from); from++)
2431     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
2432       to++;
2433 }
2434 char TZ_GMT0[] = "TZ=GMT0";
2435 char TZ_PST8[] = "TZ=PST8";
2436 main()
2437 {
2438   time_t now = time ((time_t *) 0);
2439   int hour_GMT0, hour_unset;
2440   if (putenv (TZ_GMT0) != 0)
2441     exit (1);
2442   hour_GMT0 = localtime (&now)->tm_hour;
2443   unset_TZ ();
2444   hour_unset = localtime (&now)->tm_hour;
2445   if (putenv (TZ_PST8) != 0)
2446     exit (1);
2447   if (localtime (&now)->tm_hour == hour_GMT0)
2448     exit (1);
2449   unset_TZ ();
2450   if (localtime (&now)->tm_hour != hour_unset)
2451     exit (1);
2452   exit (0);
2453 }], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
2454 [# If we have tzset, assume the worst when cross-compiling.
2455 emacs_cv_localtime_cache=yes])
2456 else
2457         # If we lack tzset, report that localtime does not cache TZ,
2458         # since we can't invalidate the cache if we don't have tzset.
2459         emacs_cv_localtime_cache=no
2460 fi])dnl
2461 AC_MSG_RESULT($emacs_cv_localtime_cache)
2462 if test $emacs_cv_localtime_cache = yes; then
2463   AC_DEFINE(LOCALTIME_CACHE, 1,
2464             [Define to 1 if localtime caches TZ.])
2465 fi
2466
2467 if test "x$HAVE_TIMEVAL" = xyes; then
2468   AC_CHECK_FUNCS(gettimeofday)
2469   if test $ac_cv_func_gettimeofday = yes; then
2470     AC_CACHE_CHECK(whether gettimeofday can accept two arguments,
2471                    emacs_cv_gettimeofday_two_arguments,
2472     [AC_TRY_COMPILE([
2473 #ifdef TIME_WITH_SYS_TIME
2474 #include <sys/time.h>
2475 #include <time.h>
2476 #else
2477 #ifdef HAVE_SYS_TIME_H
2478 #include <sys/time.h>
2479 #else
2480 #include <time.h>
2481 #endif
2482 #endif],
2483       [struct timeval time;
2484        gettimeofday (&time, 0);],
2485       emacs_cv_gettimeofday_two_arguments=yes,
2486       emacs_cv_gettimeofday_two_arguments=no)])
2487     if test $emacs_cv_gettimeofday_two_arguments = no; then
2488       AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT, 1,
2489                 [Define to 1 if gettimeofday accepts only one argument.])
2490     fi
2491   fi
2492 fi
2493
2494 ok_so_far=yes
2495 AC_CHECK_FUNC(socket, , ok_so_far=no)
2496 if test $ok_so_far = yes; then
2497   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
2498 fi
2499 if test $ok_so_far = yes; then
2500   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
2501 fi
2502 if test $ok_so_far = yes; then
2503 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
2504   AC_DEFINE(HAVE_INET_SOCKETS, 1,
2505             [Define to 1 if you have inet sockets.])
2506 fi
2507
2508 AC_CHECK_HEADERS(sys/ioctl.h)
2509
2510 if test -f /usr/lpp/X11/bin/smt.exp; then
2511   AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
2512             [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
2513 fi
2514
2515 AC_MSG_CHECKING(whether system supports dynamic ptys)
2516 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
2517   AC_MSG_RESULT(yes)
2518   AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
2519 else
2520   AC_MSG_RESULT(no)
2521 fi
2522
2523 AC_FUNC_FORK
2524
2525 dnl Adapted from Haible's version.
2526 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
2527   [AC_TRY_LINK([#include <langinfo.h>],
2528     [char* cs = nl_langinfo(CODESET);],
2529     emacs_cv_langinfo_codeset=yes,
2530     emacs_cv_langinfo_codeset=no)
2531   ])
2532 if test $emacs_cv_langinfo_codeset = yes; then
2533   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
2534     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
2535 fi
2536
2537 AC_CHECK_TYPES(size_t)
2538
2539 AC_TYPE_MBSTATE_T
2540
2541 dnl Restrict could probably be used effectively other than in regex.c.
2542 AC_CACHE_CHECK([for C restrict keyword], emacs_cv_c_restrict,
2543   [AC_TRY_COMPILE([void fred (int *restrict x);], [],
2544                   emacs_cv_c_restrict=yes,
2545                   [AC_TRY_COMPILE([void fred (int *__restrict x);], [],
2546                                   emacs_cv_c_restrict=__restrict,
2547                                   emacs_cv_c_restrict=no)])])
2548 case "$emacs_cv_c_restrict" in
2549   yes) emacs_restrict=restrict;;
2550   no) emacs_restrict="";;
2551   *) emacs_restrict="$emacs_cv_c_restrict";;
2552 esac
2553 if test "$emacs_restrict" != __restrict; then
2554   AC_DEFINE_UNQUOTED(__restrict, $emacs_restrict,
2555     [Define to compiler's equivalent of C99 restrict keyword.
2556      Don't define if equivalent is `__restrict'.])
2557 fi
2558
2559 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
2560   [AC_TRY_COMPILE([void fred (int x[__restrict]);], [],
2561                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
2562 if test "$emacs_cv_c_restrict_arr" = yes; then
2563   AC_DEFINE(__restrict_arr, __restrict,
2564     [Define to compiler's equivalent of C99 restrict keyword in array
2565      declarations.  Define as empty for no equivalent.])
2566 fi
2567
2568 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
2569 dnl how the tty code is related to POSIX and/or other versions of termios.
2570 dnl The following looks like a useful start.
2571 dnl
2572 dnl AC_SYS_POSIX_TERMIOS
2573 dnl if test $ac_cv_sys_posix_termios = yes; then
2574 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
2575 dnl                                and macros for terminal control.])
2576 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
2577 dnl fi
2578
2579 dnl Fixme: Use AC_FUNC_MEMCMP since memcmp is used.  (Needs libobj replacement.)
2580
2581 # Set up the CFLAGS for real compilation, so we can substitute it.
2582 CFLAGS="$REAL_CFLAGS"
2583 CPPFLAGS="$REAL_CPPFLAGS"
2584
2585 #### Find out which version of Emacs this is.
2586 [version=`grep 'defconst[        ]*emacs-version' ${srcdir}/lisp/version.el \
2587          | sed -e 's/^[^"]*"\([^"]*\)".*$/\1/'`]
2588 if test x"${version}" = x; then
2589   AC_MSG_ERROR([can't find current emacs version in `${srcdir}/lisp/version.el'.])
2590 fi
2591
2592 ### Specify what sort of things we'll be editing into Makefile and config.h.
2593 ### Use configuration here uncanonicalized to avoid exceeding size limits.
2594 AC_SUBST(version)
2595 AC_SUBST(configuration)
2596 AC_SUBST(canonical)
2597 AC_SUBST(srcdir)
2598 AC_SUBST(prefix)
2599 AC_SUBST(exec_prefix)
2600 AC_SUBST(bindir)
2601 AC_SUBST(datadir)
2602 AC_SUBST(sharedstatedir)
2603 AC_SUBST(libexecdir)
2604 AC_SUBST(mandir)
2605 AC_SUBST(infodir)
2606 AC_SUBST(lispdir)
2607 AC_SUBST(locallisppath)
2608 AC_SUBST(lisppath)
2609 AC_SUBST(x_default_search_path)
2610 AC_SUBST(etcdir)
2611 AC_SUBST(archlibdir)
2612 AC_SUBST(docdir)
2613 AC_SUBST(bitmapdir)
2614 AC_SUBST(gamedir)
2615 AC_SUBST(gameuser)
2616 AC_SUBST(c_switch_system)
2617 AC_SUBST(c_switch_machine)
2618 AC_SUBST(LD_SWITCH_X_SITE)
2619 AC_SUBST(LD_SWITCH_X_SITE_AUX)
2620 AC_SUBST(C_SWITCH_X_SITE)
2621 AC_SUBST(CFLAGS)
2622 AC_SUBST(X_TOOLKIT_TYPE)
2623 AC_SUBST(machfile)
2624 AC_SUBST(opsysfile)
2625 AC_SUBST(GETLOADAVG_LIBS)
2626 AC_SUBST(carbon_appdir)
2627
2628 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
2629                    [Define to the canonical Emacs configuration name.])
2630 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
2631                    [Define to the options passed to configure.])
2632 AC_DEFINE_UNQUOTED(config_machfile,  "${machfile}",
2633                    [Define to the used machine dependent file.])
2634 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}",
2635                    [Define to the used os dependent file.])
2636 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE, ${LD_SWITCH_X_SITE},
2637 [Define LD_SWITCH_X_SITE to contain any special flags your loader
2638  may need to deal with X Windows.  For instance, if you've defined
2639  HAVE_X_WINDOWS above and your X libraries aren't in a place that
2640  your loader can find on its own, you might want to add "-L/..." or
2641  something similar.])
2642 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE_AUX, ${LD_SWITCH_X_SITE_AUX},
2643                    [Define LD_SWITCH_X_SITE_AUX with an -R option
2644                     in case it's needed (for Solaris, for example).])
2645 AC_DEFINE_UNQUOTED(C_SWITCH_X_SITE,  ${C_SWITCH_X_SITE},
2646 [Define C_SWITCH_X_SITE to contain any special flags your compiler
2647  may need to deal with X Windows.  For instance, if you've defined
2648  HAVE_X_WINDOWS above and your X include files aren't in a place
2649  that your compiler can find on its own, you might want to add
2650  "-I/..." or something similar.])
2651 AC_DEFINE_UNQUOTED(UNEXEC_SRC,       ${UNEXEC_SRC},
2652                    [Define to the unexec source file name.])
2653
2654 if test "${HAVE_X_WINDOWS}" = "yes" ; then
2655   AC_DEFINE(HAVE_X_WINDOWS, 1,
2656             [Define to 1 if you want to use the X window system.])
2657 fi
2658 if test "${USE_X_TOOLKIT}" != "none" ; then
2659   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
2660   if test "${USE_X_TOOLKIT}" == "LUCID"; then
2661     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
2662   elif test "${USE_X_TOOLKIT}" == "MOTIF"; then
2663     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
2664   fi
2665 fi
2666 if test "${HAVE_X11}" = "yes" ; then
2667   AC_DEFINE(HAVE_X11, 1,
2668             [Define to 1 if you want to use version 11 of X windows.
2669              Otherwise, Emacs expects to use version 10.])
2670 fi
2671 if test "${HAVE_MENUS}" = "yes" ; then
2672   AC_DEFINE(HAVE_MENUS, 1,
2673             [Define to 1 if you have mouse menus.
2674              (This is automatic if you use X, but the option to specify it remains.)
2675              It is also defined with other window systems that support xmenu.c.])
2676 fi
2677 if test "${GNU_MALLOC}" = "yes" ; then
2678   AC_DEFINE(GNU_MALLOC, 1,
2679             [Define to 1 if you want to use the GNU memory allocator.])
2680 fi
2681 if test "${REL_ALLOC}" = "yes" ; then
2682   AC_DEFINE(REL_ALLOC, 1,
2683             [Define REL_ALLOC if you want to use the relocating allocator for
2684              buffer space.])
2685 fi
2686
2687
2688 AH_TOP([/* GNU Emacs site configuration template file.
2689    Copyright (C) 1988, 1993, 1994, 1999, 2000, 2001, 2002, 2004, 2005,
2690      2006, 2007, 2008  Free Software Foundation, Inc.
2691
2692 This file is part of GNU Emacs.
2693
2694 GNU Emacs is free software: you can redistribute it and/or modify
2695 it under the terms of the GNU General Public License as published by
2696 the Free Software Foundation, either version 3 of the License, or
2697 (at your option) any later version.
2698
2699 GNU Emacs is distributed in the hope that it will be useful,
2700 but WITHOUT ANY WARRANTY; without even the implied warranty of
2701 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
2702 GNU General Public License for more details.
2703
2704 You should have received a copy of the GNU General Public License
2705 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
2706
2707
2708 /* No code in Emacs #includes config.h twice, but some bits of code
2709    intended to work with other packages as well (like gmalloc.c)
2710    think they can include it as many times as they like.  */
2711 #ifndef EMACS_CONFIG_H
2712 #define EMACS_CONFIG_H
2713 ])dnl
2714
2715 AH_BOTTOM([
2716 /* If we're using any sort of window system, define some consequences.  */
2717 #ifdef HAVE_X_WINDOWS
2718 #define HAVE_WINDOW_SYSTEM
2719 #define MULTI_KBOARD
2720 #define HAVE_MOUSE
2721 #endif
2722
2723 /* Multi-tty support relies on MULTI_KBOARD.  It seems safe to turn it
2724    on unconditionally. */
2725 #ifndef MULTI_KBOARD
2726 #define MULTI_KBOARD
2727 #endif
2728
2729 /* If we're using the Carbon API on Mac OS X, define a few more
2730    variables as well.  */
2731 #ifdef HAVE_CARBON
2732 #define HAVE_WINDOW_SYSTEM
2733 #define HAVE_MOUSE
2734 #endif
2735
2736 /* Define USER_FULL_NAME to return a string
2737    that is the user's full name.
2738    It can assume that the variable `pw'
2739    points to the password file entry for this user.
2740
2741    At some sites, the pw_gecos field contains
2742    the user's full name.  If neither this nor any other
2743    field contains the right thing, use pw_name,
2744    giving the user's login name, since that is better than nothing.  */
2745 #define USER_FULL_NAME pw->pw_gecos
2746
2747 /* Define AMPERSAND_FULL_NAME if you use the convention
2748    that & in the full name stands for the login id.  */
2749 /* Turned on June 1996 supposing nobody will mind it.  */
2750 #define AMPERSAND_FULL_NAME
2751
2752 /* We have blockinput.h.  */
2753 #define DO_BLOCK_INPUT
2754
2755 /* Define HAVE_SOUND if we have sound support.  We know it works
2756    and compiles only on the specified platforms.   For others,
2757    it probably doesn't make sense to try.  */
2758
2759 #if defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
2760 #ifdef HAVE_MACHINE_SOUNDCARD_H
2761 #define HAVE_SOUND 1
2762 #endif
2763 #ifdef HAVE_SYS_SOUNDCARD_H
2764 #define HAVE_SOUND 1
2765 #endif
2766 #ifdef HAVE_SOUNDCARD_H
2767 #define HAVE_SOUND 1
2768 #endif
2769 #ifdef HAVE_ALSA
2770 #define HAVE_SOUND 1
2771 #endif
2772 #endif /* __FreeBSD__ || __NetBSD__ || __linux__  */
2773
2774 /* If using GNU, then support inline function declarations. */
2775 /* Don't try to switch on inline handling as detected by AC_C_INLINE
2776    generally, because even if non-gcc compilers accept `inline', they
2777    may reject `extern inline'.  */
2778 #if defined (__GNUC__) && defined (OPTIMIZE)
2779 #define INLINE __inline__
2780 #else
2781 #define INLINE
2782 #endif
2783
2784 /* Include the os and machine dependent files.  */
2785 #include config_opsysfile
2786 #include config_machfile
2787
2788 /* If no remapping takes place, static variables cannot be dumped as
2789    pure, so don't worry about the `static' keyword. */
2790 #ifdef NO_REMAP
2791 #undef static
2792 #endif
2793
2794 /* Define `subprocesses' should be defined if you want to
2795    have code for asynchronous subprocesses
2796    (as used in M-x compile and M-x shell).
2797    These do not work for some USG systems yet;
2798    for the ones where they work, the s/SYSTEM.h file defines this flag.  */
2799
2800 #ifndef VMS
2801 #ifndef USG
2802 /* #define subprocesses */
2803 #endif
2804 #endif
2805
2806 /* SIGTYPE is the macro we actually use.  */
2807 #ifndef SIGTYPE
2808 #define SIGTYPE RETSIGTYPE
2809 #endif
2810
2811 #ifdef emacs /* Don't do this for lib-src.  */
2812 /* Tell regex.c to use a type compatible with Emacs.  */
2813 #define RE_TRANSLATE_TYPE Lisp_Object
2814 #define RE_TRANSLATE(TBL, C) CHAR_TABLE_TRANSLATE (TBL, C)
2815 #ifdef make_number
2816 /* If make_number is a macro, use it.  */
2817 #define RE_TRANSLATE_P(TBL) (!EQ (TBL, make_number (0)))
2818 #else
2819 /* If make_number is a function, avoid it.  */
2820 #define RE_TRANSLATE_P(TBL) (!(INTEGERP (TBL) && XINT (TBL) == 0))
2821 #endif
2822 #endif
2823
2824 /* Avoid link-time collision with system mktime if we will use our own.  */
2825 #if ! HAVE_MKTIME || BROKEN_MKTIME
2826 #define mktime emacs_mktime
2827 #endif
2828
2829 #define my_strftime nstrftime   /* for strftime.c */
2830
2831 /* The rest of the code currently tests the CPP symbol BSTRING.
2832    Override any claims made by the system-description files.
2833    Note that on some SCO version it is possible to have bcopy and not bcmp.  */
2834 #undef BSTRING
2835 #if defined (HAVE_BCOPY) && defined (HAVE_BCMP)
2836 #define BSTRING
2837 #endif
2838
2839 /* Some of the files of Emacs which are intended for use with other
2840    programs assume that if you have a config.h file, you must declare
2841    the type of getenv.
2842
2843    This declaration shouldn't appear when alloca.s or Makefile.in
2844    includes config.h.  */
2845 #ifndef NOT_C_CODE
2846 extern char *getenv ();
2847 #endif
2848
2849 /* These default definitions are good for almost all machines.
2850    The exceptions override them in m/MACHINE.h.  */
2851
2852 #ifndef BITS_PER_CHAR
2853 #define BITS_PER_CHAR 8
2854 #endif
2855
2856 #ifndef BITS_PER_SHORT
2857 #define BITS_PER_SHORT 16
2858 #endif
2859
2860 /* Note that lisp.h uses this in a preprocessor conditional, so it
2861    would not work to use sizeof.  That being so, we do all of them
2862    without sizeof, for uniformity's sake.  */
2863 #ifndef BITS_PER_INT
2864 #define BITS_PER_INT 32
2865 #endif
2866
2867 #ifndef BITS_PER_LONG
2868 #ifdef _LP64
2869 #define BITS_PER_LONG 64
2870 #else
2871 #define BITS_PER_LONG 32
2872 #endif
2873 #endif
2874
2875 /* Define if the compiler supports function prototypes.  It may do so
2876    but not define __STDC__ (e.g. DEC C by default) or may define it as
2877    zero.  */
2878 #undef PROTOTYPES
2879 /* For mktime.c:  */
2880 #ifndef __P
2881 # if defined PROTOTYPES
2882 #  define __P(args) args
2883 # else
2884 #  define __P(args) ()
2885 # endif  /* GCC.  */
2886 #endif /* __P */
2887
2888 /* Don't include "string.h" or <stdlib.h> in non-C code.  */
2889 #ifndef NOT_C_CODE
2890 #ifdef HAVE_STRING_H
2891 #include "string.h"
2892 #endif
2893 #ifdef HAVE_STRINGS_H
2894 #include "strings.h"  /* May be needed for bcopy & al. */
2895 #endif
2896 #ifdef HAVE_STDLIB_H
2897 #include <stdlib.h>
2898 #endif
2899 #ifndef __GNUC__
2900 # ifdef HAVE_ALLOCA_H
2901 #  include <alloca.h>
2902 # else /* AIX files deal with #pragma.  */
2903 #  ifndef alloca /* predefined by HP cc +Olibcalls */
2904 char *alloca ();
2905 #  endif
2906 # endif /* HAVE_ALLOCA_H */
2907 #endif /* __GNUC__ */
2908 #ifndef HAVE_SIZE_T
2909 typedef unsigned size_t;
2910 #endif
2911 #endif /* NOT_C_CODE */
2912
2913 /* Define HAVE_X_I18N if we have usable i18n support.  */
2914
2915 #ifdef HAVE_X11R6
2916 #define HAVE_X_I18N
2917 #elif !defined X11R5_INHIBIT_I18N
2918 #define HAVE_X_I18N
2919 #endif
2920
2921 /* Define HAVE_X11R6_XIM if we have usable X11R6-style XIM support.  */
2922
2923 #if defined HAVE_X11R6 && !defined INHIBIT_X11R6_XIM
2924 #define HAVE_X11R6_XIM
2925 #endif
2926
2927 /* Should we enable expensive run-time checking of data types?  */
2928 #undef ENABLE_CHECKING
2929
2930 #if defined __GNUC__ && (__GNUC__ > 2 \
2931                          || (__GNUC__ == 2 && __GNUC_MINOR__ >= 5))
2932 #define NO_RETURN       __attribute__ ((__noreturn__))
2933 #else
2934 #define NO_RETURN       /* nothing */
2935 #endif
2936
2937 /* These won't be used automatically yet.  We also need to know, at least,
2938    that the stack is continuous.  */
2939 #ifdef __GNUC__
2940 #  ifndef GC_SETJMP_WORKS
2941   /* GC_SETJMP_WORKS is nearly always appropriate for GCC --
2942      see NON_SAVING_SETJMP in the target descriptions.  */
2943   /* Exceptions (see NON_SAVING_SETJMP in target description) are
2944      SCO5 non-ELF (but Emacs specifies ELF) and SVR3 on x86.
2945      Fixme: Deal with SVR3.  */
2946 #    define GC_SETJMP_WORKS 1
2947 #  endif
2948 #  ifndef GC_LISP_OBJECT_ALIGNMENT
2949 #    define GC_LISP_OBJECT_ALIGNMENT (__alignof__ (Lisp_Object))
2950 #  endif
2951 #endif
2952
2953 #ifndef HAVE_BCOPY
2954 #define bcopy(a,b,s) memcpy (b,a,s)
2955 #endif
2956 #ifndef HAVE_BZERO
2957 #define bzero(a,s) memset (a,0,s)
2958 #endif
2959 #ifndef HAVE_BCMP
2960 #define BCMP memcmp
2961 #endif
2962
2963 #endif /* EMACS_CONFIG_H */
2964
2965 /*
2966 Local Variables:
2967 mode: c
2968 End:
2969 */
2970 ])dnl
2971
2972 #### Report on what we decided to do.
2973 #### Report GTK as a toolkit, even if it doesn't use Xt.
2974 #### It makes printing result more understandable as using GTK sets
2975 #### toolkit_scroll_bars to yes by default.
2976 if test "${HAVE_GTK}" = "yes"; then
2977   USE_X_TOOLKIT=GTK
2978 fi
2979
2980 echo "
2981 Configured for \`${canonical}'.
2982
2983   Where should the build process find the source code?    ${srcdir}
2984   What operating system and machine description files should Emacs use?
2985         \`${opsysfile}' and \`${machfile}'
2986   What compiler should emacs be built with?               ${CC} ${CFLAGS}
2987   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
2988   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
2989   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
2990   What window system should Emacs use?                    ${window_system}
2991   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
2992
2993 if test -n "${x_includes}"; then
2994 echo "  Where do we find X Windows header files?                ${x_includes}"
2995 else
2996 echo "  Where do we find X Windows header files?                Standard dirs"
2997 fi
2998 if test -n "${x_libraries}"; then
2999 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
3000 else
3001 echo "  Where do we find X Windows libraries?                   Standard dirs"
3002 fi
3003
3004 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
3005 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
3006 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
3007 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
3008 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $ac_gif_lib_name"
3009 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
3010 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
3011 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
3012 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
3013
3014 if test "${USE_FONT_BACKEND}" = "yes"; then
3015   echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
3016   echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
3017   echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
3018   echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
3019 fi
3020 echo "  Does Emacs use X toolkit scroll bars?                   ${USE_TOOLKIT_SCROLL_BARS}"
3021 echo
3022
3023 if test $USE_XASSERTS = yes; then
3024    echo "  Compiling with asserts turned on."
3025    CPPFLAGS="$CPPFLAGS -DXASSERTS=1"
3026 fi
3027
3028 echo
3029
3030 if test "$USE_X_TOOLKIT" = GTK; then
3031   case "$canonical" in
3032   *cygwin*)
3033     echo "There are known problems with Emacs and Gtk+ on cygwin, so you
3034   will probably get a crash on startup.  If this happens, please use another
3035   toolkit for Emacs.  See etc/PROBLEMS for more information."
3036   ;;
3037   esac
3038 fi
3039
3040
3041 if test "$HAVE_CARBON" = "yes"; then
3042    echo
3043    echo "Warning: The Mac Carbon port is currently unsupported and has
3044 known problems.  It is not recommended for use by non-developers.
3045 Read the emacs-devel archives for more information."
3046    echo
3047 fi
3048
3049 if test "$HAVE_DBUS" = yes && test "${opsys}" != "gnu-linux"; then
3050   echo "D-Bus integration has been tested for GNU/Linux only."
3051   echo
3052 fi
3053
3054
3055 # Remove any trailing slashes in these variables.
3056 [test "${prefix}" != NONE &&
3057   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
3058 test "${exec_prefix}" != NONE &&
3059   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
3060
3061 ## Check if the C preprocessor will convert `..' to `. .'.  If so, set
3062 ## CPP_NEED_TRADITIONAL to `yes' so that the code to generate Makefile
3063 ## from Makefile.c can correctly provide the arg `-traditional' to the
3064 ## C preprocessor.
3065
3066 AC_EGREP_CPP(yes..yes,
3067         [yes..yes],
3068         CPP_NEED_TRADITIONAL=no,
3069         CPP_NEED_TRADITIONAL=yes)
3070
3071 AC_OUTPUT(Makefile lib-src/Makefile.c:lib-src/Makefile.in oldXMenu/Makefile \
3072         doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
3073         doc/lispref/Makefile src/Makefile.c:src/Makefile.in \
3074         lwlib/Makefile lisp/Makefile leim/Makefile, [
3075
3076 ### Make the necessary directories, if they don't exist.
3077 for dir in etc lisp ; do
3078   test -d ${dir} || mkdir ${dir}
3079 done
3080
3081 # Build src/Makefile from ${srcdir}/src/Makefile.c
3082 # and lib-src/Makefile from ${srcdir}/lib-src/Makefile.c
3083 # This must be done after src/config.h is built, since we rely on that file.
3084
3085 # Now get this: Some word that is part of the ${srcdir} directory name
3086 # or the ${configuration} value might, just might, happen to be an
3087 # identifier like `sun4' or `i386' or something, and be predefined by
3088 # the C preprocessor to some helpful value like 1, or maybe the empty
3089 # string.  Needless to say consequent macro substitutions are less
3090 # than conducive to the makefile finding the correct directory.
3091 [undefs="`echo $top_srcdir $configuration $canonical |
3092 sed -e 's/[^a-zA-Z0-9_]/ /g' -e 's/^/ /' -e 's/  *$//' \
3093     -e 's/  */ -U/g' -e 's/-U[0-9][^ ]*//g' \
3094 `"]
3095
3096 echo creating src/epaths.h
3097 ${MAKE-make} epaths-force
3098
3099 # As of 2000-11-19, newest development versions of GNU cpp preprocess
3100 # `..' to `. .'  unless invoked with -traditional
3101
3102 if test "x$GCC" = xyes && test "x$CPP_NEED_TRADITIONAL" = xyes; then
3103   CPPFLAGS="$CPPFLAGS -traditional"
3104 fi
3105
3106 echo creating lib-src/Makefile
3107 ( cd lib-src
3108   rm -f junk.c junk1.c junk2.c
3109   sed -e '/start of cpp stuff/q' \
3110       < Makefile.c > junk1.c
3111   sed -e '1,/start of cpp stuff/d'\
3112       -e 's,/\*\*/#\(.*\)$,/* \1 */,' \
3113       < Makefile.c > junk.c
3114   $CPP $undefs -I. -I$srcdir/src $CPPFLAGS junk.c | \
3115       sed -e 's/^ /     /' -e '/^#/d' -e '/^[   \f]*$/d' > junk2.c
3116   cat junk1.c junk2.c > Makefile.new
3117   rm -f junk.c junk1.c junk2.c
3118   chmod 444 Makefile.new
3119   mv -f Makefile.new Makefile
3120 )
3121
3122 echo creating src/Makefile
3123 ( cd src
3124   rm -f junk.c junk1.c junk2.c
3125   sed -e '/start of cpp stuff/q' \
3126       < Makefile.c > junk1.c
3127   sed -e '1,/start of cpp stuff/d'\
3128       -e 's,/\*\*/#\(.*\)$,/* \1 */,' \
3129       < Makefile.c > junk.c
3130   $CPP $undefs -I. -I$srcdir/src $CPPFLAGS junk.c | \
3131       sed -e 's/^ /     /' -e '/^#/d' -e '/^[   \f]*$/d' > junk2.c
3132   cat junk1.c junk2.c > Makefile.new
3133   rm -f junk.c junk1.c junk2.c
3134   chmod 444 Makefile.new
3135   mv -f Makefile.new Makefile
3136 )
3137
3138 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
3139   echo creating src/.gdbinit
3140   echo source $srcdir/src/.gdbinit > src/.gdbinit
3141 fi
3142
3143 # This is how we know whether to re-run configure in certain cases.
3144 touch src/config.stamp
3145
3146 ], [GCC="$GCC" NON_GNU_CPP="$NON_GNU_CPP" CPP="$CPP" CPP_NEED_TRADITIONAL="$CPP_NEED_TRADITIONAL" CPPFLAGS="$CPPFLAGS"])
3147
3148 m4_if(dnl       Do not change this comment
3149    arch-tag: 156a4dd5-bddc-4d18-96ac-f37742cf6a5e
3150 )dnl