code.delx.au - gnu-emacs/blob - lisp/dired.el

   1 ;;; dired.el --- directory-browsing commands -*- lexical-binding: t -*-
   2
   3 ;; Copyright (C) 1985-1986, 1992-1997, 2000-2016 Free Software
   4 ;; Foundation, Inc.
   5
   6 ;; Author: Sebastian Kremer <sk@thp.uni-koeln.de>
   7 ;; Maintainer: emacs-devel@gnu.org
   8 ;; Keywords: files
   9 ;; Package: emacs
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software: you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation, either version 3 of the License, or
  16 ;; (at your option) any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  25
  26 ;;; Commentary:
  27
  28 ;; This is a major mode for directory browsing and editing.
  29 ;; It is documented in the Emacs manual.
  30
  31 ;; Rewritten in 1990/1991 to add tree features, file marking and
  32 ;; sorting by Sebastian Kremer <sk@thp.uni-koeln.de>.
  33 ;; Finished up by rms in 1992.
  34
  35 ;;; Code:
  36
  37 (declare-function dired-buffer-more-recently-used-p
  38                   "dired-x" (buffer1 buffer2))
  39
  40 ;;; Customizable variables
  41
  42 (defgroup dired nil
  43   "Directory editing."
  44   :link '(custom-manual "(emacs)Dired")
  45   :group 'files)
  46
  47 (defgroup dired-mark nil
  48   "Handling marks in Dired."
  49   :prefix "dired-"
  50   :group 'dired)
  51
  52
  53 ;;;###autoload
  54 (defcustom dired-listing-switches (purecopy "-al")
  55   "Switches passed to `ls' for Dired.  MUST contain the `l' option.
  56 May contain all other options that don't contradict `-l';
  57 may contain even `F', `b', `i' and `s'.  See also the variable
  58 `dired-ls-F-marks-symlinks' concerning the `F' switch.
  59 On systems such as MS-DOS and MS-Windows, which use `ls' emulation in Lisp,
  60 some of the `ls' switches are not supported; see the doc string of
  61 `insert-directory' in `ls-lisp.el' for more details."
  62   :type 'string
  63   :group 'dired)
  64
  65 (defcustom dired-subdir-switches nil
  66   "If non-nil, switches passed to `ls' for inserting subdirectories.
  67 If nil, `dired-listing-switches' is used."
  68    :group 'dired
  69    :type '(choice (const :tag "Use dired-listing-switches" nil)
  70                   (string :tag "Switches")))
  71
  72 (defcustom dired-chown-program
  73   (purecopy (cond ((executable-find "chown") "chown")
  74                   ((file-executable-p "/usr/sbin/chown") "/usr/sbin/chown")
  75                   ((file-executable-p "/etc/chown") "/etc/chown")
  76                   (t "chown")))
  77   "Name of chown command (usually `chown')."
  78   :group 'dired
  79   :type 'file)
  80
  81 (defcustom dired-use-ls-dired 'unspecified
  82   "Non-nil means Dired should pass the \"--dired\" option to \"ls\".
  83 The special value of `unspecified' means to check explicitly, and
  84 save the result in this variable.  This is performed the first
  85 time `dired-insert-directory' is called.
  86
  87 Note that if you set this option to nil, either through choice or
  88 because your \"ls\" program does not support \"--dired\", Dired
  89 will fail to parse some \"unusual\" file names, e.g. those with leading
  90 spaces.  You might want to install ls from GNU Coreutils, which does
  91 support this option.  Alternatively, you might want to use Emacs's
  92 own emulation of \"ls\", by using:
  93   (setq ls-lisp-use-insert-directory-program nil)
  94   (require \\='ls-lisp)
  95 This is used by default on MS Windows, which does not have an \"ls\" program.
  96 Note that `ls-lisp' does not support as many options as GNU ls, though.
  97 For more details, see Info node `(emacs)ls in Lisp'."
  98   :group 'dired
  99   :type '(choice (const :tag "Check for --dired support" unspecified)
 100                  (const :tag "Do not use --dired" nil)
 101                  (other :tag "Use --dired" t)))
 102
 103 (defcustom dired-chmod-program "chmod"
 104   "Name of chmod command (usually `chmod')."
 105   :group 'dired
 106   :type 'file)
 107
 108 (defcustom dired-touch-program "touch"
 109   "Name of touch command (usually `touch')."
 110    :group 'dired
 111    :type 'file)
 112
 113 (defcustom dired-ls-F-marks-symlinks nil
 114   "Informs Dired about how `ls -lF' marks symbolic links.
 115 Set this to t if `ls' (or whatever program is specified by
 116 `insert-directory-program') with `-lF' marks the symbolic link
 117 itself with a trailing @ (usually the case under Ultrix).
 118
 119 Example: if `ln -s foo bar; ls -F bar' gives `bar -> foo', set it to
 120 nil (the default), if it gives `bar@ -> foo', set it to t.
 121
 122 Dired checks if there is really a @ appended.  Thus, if you have a
 123 marking `ls' program on one host and a non-marking on another host, and
 124 don't care about symbolic links which really end in a @, you can
 125 always set this variable to t."
 126   :type 'boolean
 127   :group 'dired-mark)
 128
 129 (defcustom dired-trivial-filenames (purecopy "^\\.\\.?$\\|^#")
 130   "Regexp of files to skip when finding first file of a directory.
 131 A value of nil means move to the subdir line.
 132 A value of t means move to first file."
 133   :type '(choice (const :tag "Move to subdir" nil)
 134                  (const :tag "Move to first" t)
 135                  regexp)
 136   :group 'dired)
 137
 138 (defcustom dired-keep-marker-rename t
 139   ;; Use t as default so that moved files "take their markers with them".
 140   "Controls marking of renamed files.
 141 If t, files keep their previous marks when they are renamed.
 142 If a character, renamed files (whether previously marked or not)
 143 are afterward marked with that character.
 144 This option affects only files renamed by `dired-do-rename' and
 145 `dired-do-rename-regexp'.  See `wdired-keep-marker-rename'
 146 if you want to do the same for files renamed in WDired mode."
 147   :type '(choice (const :tag "Keep" t)
 148                  (character :tag "Mark" :value ?R))
 149   :group 'dired-mark)
 150
 151 (defcustom dired-keep-marker-copy ?C
 152   "Controls marking of copied files.
 153 If t, copied files are marked if and as the corresponding original files were.
 154 If a character, copied files are unconditionally marked with that character."
 155   :type '(choice (const :tag "Keep" t)
 156                  (character :tag "Mark"))
 157   :group 'dired-mark)
 158
 159 (defcustom dired-keep-marker-hardlink ?H
 160   "Controls marking of newly made hard links.
 161 If t, they are marked if and as the files linked to were marked.
 162 If a character, new links are unconditionally marked with that character."
 163   :type '(choice (const :tag "Keep" t)
 164                  (character :tag "Mark"))
 165   :group 'dired-mark)
 166
 167 (defcustom dired-keep-marker-symlink ?Y
 168   "Controls marking of newly made symbolic links.
 169 If t, they are marked if and as the files linked to were marked.
 170 If a character, new links are unconditionally marked with that character."
 171   :type '(choice (const :tag "Keep" t)
 172                  (character :tag "Mark"))
 173   :group 'dired-mark)
 174
 175 (defcustom dired-dwim-target nil
 176   "If non-nil, Dired tries to guess a default target directory.
 177 This means: if there is a Dired buffer displayed in the next
 178 window, use its current directory, instead of this Dired buffer's
 179 current directory.
 180
 181 The target is used in the prompt for file copy, rename etc."
 182   :type 'boolean
 183   :group 'dired)
 184
 185 (defcustom dired-copy-preserve-time t
 186   "If non-nil, Dired preserves the last-modified time in a file copy.
 187 \(This works on only some systems.)"
 188   :type 'boolean
 189   :group 'dired)
 190
 191 ; These variables were deleted and the replacements are on files.el.
 192 ; We leave aliases behind for back-compatibility.
 193 (defvaralias 'dired-free-space-program 'directory-free-space-program)
 194 (defvaralias 'dired-free-space-args 'directory-free-space-args)
 195
 196 ;;; Hook variables
 197
 198 (defcustom dired-load-hook nil
 199   "Run after loading Dired.
 200 You can customize key bindings or load extensions with this."
 201   :group 'dired
 202   :type 'hook)
 203
 204 (defcustom dired-mode-hook nil
 205   "Run at the very end of `dired-mode'."
 206   :group 'dired
 207   :type 'hook)
 208
 209 (defcustom dired-before-readin-hook nil
 210   "This hook is run before a Dired buffer is read in (created or reverted)."
 211   :group 'dired
 212   :type 'hook)
 213
 214 (defcustom dired-after-readin-hook nil
 215   "Hook run after each time a file or directory is read by Dired.
 216 After each listing of a file or directory, this hook is run
 217 with the buffer narrowed to the listing."
 218   :group 'dired
 219   :type 'hook)
 220 ;; Note this can't simply be run inside function `dired-ls' as the hook
 221 ;; functions probably depend on the dired-subdir-alist to be OK.
 222
 223 (defcustom dired-initial-position-hook nil
 224   "This hook is used to position the point.
 225 It is run by the function `dired-initial-position'."
 226   :group 'dired
 227   :type 'hook
 228   :version "24.4")
 229
 230 (defcustom dired-dnd-protocol-alist
 231   '(("^file:///" . dired-dnd-handle-local-file)
 232     ("^file://"  . dired-dnd-handle-file)
 233     ("^file:"    . dired-dnd-handle-local-file))
 234   "The functions to call when a drop in `dired-mode' is made.
 235 See `dnd-protocol-alist' for more information.  When nil, behave
 236 as in other buffers.  Changing this option is effective only for
 237 new Dired buffers."
 238   :type '(choice (repeat (cons (regexp) (function)))
 239                  (const :tag "Behave as in other buffers" nil))
 240   :version "22.1"
 241   :group 'dired)
 242
 243 (defcustom dired-hide-details-hide-symlink-targets t
 244   "Non-nil means `dired-hide-details-mode' hides symbolic link targets."
 245   :type 'boolean
 246   :version "24.4"
 247   :group 'dired)
 248
 249 (defcustom dired-hide-details-hide-information-lines t
 250   "Non-nil means `dired-hide-details-mode' hides all but header and file lines."
 251   :type 'boolean
 252   :version "24.4"
 253   :group 'dired)
 254
 255 ;; Internal variables
 256
 257 (defvar dired-marker-char ?*            ; the answer is 42
 258   ;; so that you can write things like
 259   ;; (let ((dired-marker-char ?X))
 260   ;;    ;; great code using X markers ...
 261   ;;    )
 262   ;; For example, commands operating on two sets of files, A and B.
 263   ;; Or marking files with digits 0-9.  This could implicate
 264   ;; concentric sets or an order for the marked files.
 265   ;; The code depends on dynamic scoping on the marker char.
 266   "In Dired, the current mark character.
 267 This is what the do-commands look for, and what the mark-commands store.")
 268
 269 (defvar dired-del-marker ?D
 270   "Character used to flag files for deletion.")
 271
 272 (defvar dired-shrink-to-fit t
 273 ;; I see no reason ever to make this nil -- rms.
 274 ;;  (> baud-rate search-slow-speed)
 275   "Non-nil means Dired shrinks the display buffer to fit the marked files.")
 276 (make-obsolete-variable 'dired-shrink-to-fit
 277                         "use the Customization interface to add a new rule
 278 to `display-buffer-alist' where condition regexp is \"^ \\*Marked Files\\*$\",
 279 action argument symbol is `window-height' and its value is nil." "24.3")
 280
 281 (defvar dired-file-version-alist)
 282
 283 ;;;###autoload
 284 (defvar dired-directory nil
 285   "The directory name or wildcard spec that this Dired directory lists.
 286 Local to each Dired buffer.  May be a list, in which case the car is the
 287 directory name and the cdr is the list of files to mention.
 288 The directory name must be absolute, but need not be fully expanded.")
 289
 290 ;; Beware of "-l;reboot" etc.  See bug#3230.
 291 (defun dired-safe-switches-p (switches)
 292   "Return non-nil if string SWITCHES does not look risky for Dired."
 293   (or (not switches)
 294       (and (stringp switches)
 295            (< (length switches) 100)    ; arbitrary
 296            (string-match-p "\\` *-[- [:alnum:]]+\\'" switches))))
 297
 298 (defvar dired-actual-switches nil
 299   "The value of `dired-listing-switches' used to make this buffer's text.")
 300
 301 (put 'dired-actual-switches 'safe-local-variable 'dired-safe-switches-p)
 302
 303 (defvar dired-re-inode-size "[0-9 \t]*"
 304   "Regexp for optional initial inode and file size as made by `ls -i -s'.")
 305
 306 ;; These regexps must be tested at beginning-of-line, but are also
 307 ;; used to search for next matches, so neither omitting "^" nor
 308 ;; replacing "^" by "\n" (to make it slightly faster) will work.
 309
 310 (defvar dired-re-mark "^[^ \n]")
 311 ;; "Regexp matching a marked line.
 312 ;; Important: the match ends just after the marker."
 313 (defvar dired-re-maybe-mark "^. ")
 314 ;; The [^:] part after "d" and "l" is to avoid confusion with the
 315 ;; DOS/Windows-style drive letters in directory names, like in "d:/foo".
 316 (defvar dired-re-dir (concat dired-re-maybe-mark dired-re-inode-size "d[^:]"))
 317 (defvar dired-re-sym (concat dired-re-maybe-mark dired-re-inode-size "l[^:]"))
 318 (defvar dired-re-exe;; match ls permission string of an executable file
 319   (mapconcat (function
 320               (lambda (x)
 321                 (concat dired-re-maybe-mark dired-re-inode-size x)))
 322              '("-[-r][-w][xs][-r][-w].[-r][-w]."
 323                "-[-r][-w].[-r][-w][xs][-r][-w]."
 324                "-[-r][-w].[-r][-w].[-r][-w][xst]")
 325              "\\|"))
 326 (defvar dired-re-perms "[-bcdlps][-r][-w].[-r][-w].[-r][-w].")
 327 (defvar dired-re-dot "^.* \\.\\.?/?$")
 328
 329 ;; The subdirectory names in the next two lists are expanded.
 330 (defvar dired-subdir-alist nil
 331   "Association list of subdirectories and their buffer positions.
 332 Each subdirectory has an element: (DIRNAME . STARTMARKER).
 333 The order of elements is the reverse of the order in the buffer.
 334 In simple cases, this list contains one element.")
 335
 336 (defvar-local dired-switches-alist nil
 337   "Keeps track of which switches to use for inserted subdirectories.
 338 This is an alist of the form (SUBDIR . SWITCHES).")
 339
 340 (defvaralias 'dired-move-to-filename-regexp
 341   'directory-listing-before-filename-regexp)
 342
 343 (defvar dired-subdir-regexp "^. \\([^\n\r]+\\)\\(:\\)[\n\r]"
 344   "Regexp matching a maybe hidden subdirectory line in `ls -lR' output.
 345 Subexpression 1 is the subdirectory proper, no trailing colon.
 346 The match starts at the beginning of the line and ends after the end
 347 of the line (\\n or \\r).
 348 Subexpression 2 must end right before the \\n or \\r.")
 349
 350 (defgroup dired-faces nil
 351   "Faces used by Dired."
 352   :group 'dired
 353   :group 'faces)
 354
 355 (defface dired-header
 356   '((t (:inherit font-lock-type-face)))
 357   "Face used for directory headers."
 358   :group 'dired-faces
 359   :version "22.1")
 360 (defvar dired-header-face 'dired-header
 361   "Face name used for directory headers.")
 362
 363 (defface dired-mark
 364   '((t (:inherit font-lock-constant-face)))
 365   "Face used for Dired marks."
 366   :group 'dired-faces
 367   :version "22.1")
 368 (defvar dired-mark-face 'dired-mark
 369   "Face name used for Dired marks.")
 370
 371 (defface dired-marked
 372   '((t (:inherit warning)))
 373   "Face used for marked files."
 374   :group 'dired-faces
 375   :version "22.1")
 376 (defvar dired-marked-face 'dired-marked
 377   "Face name used for marked files.")
 378
 379 (defface dired-flagged
 380   '((t (:inherit error)))
 381   "Face used for files flagged for deletion."
 382   :group 'dired-faces
 383   :version "22.1")
 384 (defvar dired-flagged-face 'dired-flagged
 385   "Face name used for files flagged for deletion.")
 386
 387 (defface dired-warning
 388   ;; Inherit from font-lock-warning-face since with min-colors 8
 389   ;; font-lock-comment-face is not colored any more.
 390   '((t (:inherit font-lock-warning-face)))
 391   "Face used to highlight a part of a buffer that needs user attention."
 392   :group 'dired-faces
 393   :version "22.1")
 394 (defvar dired-warning-face 'dired-warning
 395   "Face name used for a part of a buffer that needs user attention.")
 396
 397 (defface dired-perm-write
 398   '((((type w32 pc)) :inherit default)  ;; These default to rw-rw-rw.
 399     ;; Inherit from font-lock-comment-delimiter-face since with min-colors 8
 400     ;; font-lock-comment-face is not colored any more.
 401     (t (:inherit font-lock-comment-delimiter-face)))
 402   "Face used to highlight permissions of group- and world-writable files."
 403   :group 'dired-faces
 404   :version "22.2")
 405 (defvar dired-perm-write-face 'dired-perm-write
 406   "Face name used for permissions of group- and world-writable files.")
 407
 408 (defface dired-directory
 409   '((t (:inherit font-lock-function-name-face)))
 410   "Face used for subdirectories."
 411   :group 'dired-faces
 412   :version "22.1")
 413 (defvar dired-directory-face 'dired-directory
 414   "Face name used for subdirectories.")
 415
 416 (defface dired-symlink
 417   '((t (:inherit font-lock-keyword-face)))
 418   "Face used for symbolic links."
 419   :group 'dired-faces
 420   :version "22.1")
 421 (defvar dired-symlink-face 'dired-symlink
 422   "Face name used for symbolic links.")
 423
 424 (defface dired-ignored
 425   '((t (:inherit shadow)))
 426   "Face used for files suffixed with `completion-ignored-extensions'."
 427   :group 'dired-faces
 428   :version "22.1")
 429 (defvar dired-ignored-face 'dired-ignored
 430   "Face name used for files suffixed with `completion-ignored-extensions'.")
 431
 432 (defvar dired-font-lock-keywords
 433   (list
 434    ;;
 435    ;; Dired marks.
 436    (list dired-re-mark '(0 dired-mark-face))
 437    ;;
 438    ;; We make heavy use of MATCH-ANCHORED, since the regexps don't identify the
 439    ;; file name itself.  We search for Dired defined regexps, and then use the
 440    ;; Dired defined function `dired-move-to-filename' before searching for the
 441    ;; simple regexp ".+".  It is that regexp which matches the file name.
 442    ;;
 443    ;; Marked files.
 444    (list (concat "^[" (char-to-string dired-marker-char) "]")
 445          '(".+" (dired-move-to-filename) nil (0 dired-marked-face)))
 446    ;;
 447    ;; Flagged files.
 448    (list (concat "^[" (char-to-string dired-del-marker) "]")
 449          '(".+" (dired-move-to-filename) nil (0 dired-flagged-face)))
 450    ;; People who are paranoid about security would consider this more
 451    ;; important than other things such as whether it is a directory.
 452    ;; But we don't want to encourage paranoia, so our default
 453    ;; should be what's most useful for non-paranoids. -- rms.
 454 ;;;   ;;
 455 ;;;   ;; Files that are group or world writable.
 456 ;;;   (list (concat dired-re-maybe-mark dired-re-inode-size
 457 ;;;              "\\([-d]\\(....w....\\|.......w.\\)\\)")
 458 ;;;      '(1 dired-warning-face)
 459 ;;;      '(".+" (dired-move-to-filename) nil (0 dired-warning-face)))
 460    ;; However, we don't need to highlight the file name, only the
 461    ;; permissions, to win generally.  -- fx.
 462    ;; Fixme: we could also put text properties on the permission
 463    ;; fields with keymaps to frob the permissions, somewhat a la XEmacs.
 464    (list (concat dired-re-maybe-mark dired-re-inode-size
 465                  "[-d]....\\(w\\)....") ; group writable
 466          '(1 dired-perm-write-face))
 467    (list (concat dired-re-maybe-mark dired-re-inode-size
 468                  "[-d].......\\(w\\).") ; world writable
 469          '(1 dired-perm-write-face))
 470    ;;
 471    ;; Subdirectories.
 472    (list dired-re-dir
 473          '(".+" (dired-move-to-filename) nil (0 dired-directory-face)))
 474    ;;
 475    ;; Symbolic links.
 476    (list dired-re-sym
 477          '(".+" (dired-move-to-filename) nil (0 dired-symlink-face)))
 478    ;;
 479    ;; Files suffixed with `completion-ignored-extensions'.
 480    '(eval .
 481      ;; It is quicker to first find just an extension, then go back to the
 482      ;; start of that file name.  So we do this complex MATCH-ANCHORED form.
 483      (list (concat "\\(" (regexp-opt completion-ignored-extensions) "\\|#\\)$")
 484            '(".+" (dired-move-to-filename) nil (0 dired-ignored-face))))
 485    ;;
 486    ;; Files suffixed with `completion-ignored-extensions'
 487    ;; plus a character put in by -F.
 488    '(eval .
 489      (list (concat "\\(" (regexp-opt completion-ignored-extensions)
 490                    "\\|#\\)[*=|]$")
 491            '(".+" (progn
 492                     (end-of-line)
 493                     ;; If the last character is not part of the filename,
 494                     ;; move back to the start of the filename
 495                     ;; so it can be fontified.
 496                     ;; Otherwise, leave point at the end of the line;
 497                     ;; that way, nothing is fontified.
 498                     (unless (get-text-property (1- (point)) 'mouse-face)
 499                       (dired-move-to-filename)))
 500              nil (0 dired-ignored-face))))
 501    ;;
 502    ;; Explicitly put the default face on file names ending in a colon to
 503    ;; avoid fontifying them as directory header.
 504    (list (concat dired-re-maybe-mark dired-re-inode-size dired-re-perms ".*:$")
 505          '(".+" (dired-move-to-filename) nil (0 'default)))
 506    ;;
 507    ;; Directory headers.
 508    (list dired-subdir-regexp '(1 dired-header-face))
 509 )
 510   "Additional expressions to highlight in Dired mode.")
 511
 512 (defvar dnd-protocol-alist)
 513 \f
 514 ;;; Macros must be defined before they are used, for the byte compiler.
 515
 516 (defmacro dired-mark-if (predicate msg)
 517   "Mark all files for which PREDICATE evals to non-nil.
 518 PREDICATE is evaluated on each line, with point at beginning of line.
 519 MSG is a noun phrase for the type of files being marked.
 520 It should end with a noun that can be pluralized by adding `s'.
 521 Return value is the number of files marked, or nil if none were marked."
 522   `(let ((inhibit-read-only t) count)
 523     (save-excursion
 524       (setq count 0)
 525       (when ,msg
 526         (message "%s %ss%s..."
 527                  (cond ((eq dired-marker-char ?\040) "Unmarking")
 528                        ((eq dired-del-marker dired-marker-char)
 529                         "Flagging")
 530                        (t "Marking"))
 531                  ,msg
 532                  (if (eq dired-del-marker dired-marker-char)
 533                      " for deletion"
 534                    "")))
 535       (goto-char (point-min))
 536       (while (not (eobp))
 537         (if ,predicate
 538             (progn
 539               (delete-char 1)
 540               (insert dired-marker-char)
 541               (setq count (1+ count))))
 542         (forward-line 1))
 543       (if ,msg (message "%s %s%s %s%s."
 544                         count
 545                         ,msg
 546                         (dired-plural-s count)
 547                         (if (eq dired-marker-char ?\040) "un" "")
 548                         (if (eq dired-marker-char dired-del-marker)
 549                             "flagged" "marked"))))
 550     (and (> count 0) count)))
 551
 552 (defmacro dired-map-over-marks (body arg &optional show-progress
 553                                      distinguish-one-marked)
 554   "Eval BODY with point on each marked line.  Return a list of BODY's results.
 555 If no marked file could be found, execute BODY on the current
 556 line.  ARG, if non-nil, specifies the files to use instead of the
 557 marked files.
 558
 559 If ARG is an integer, use the next ARG (or previous -ARG, if
 560 ARG<0) files.  In that case, point is dragged along.  This is so
 561 that commands on the next ARG (instead of the marked) files can
 562 be chained easily.
 563 For any other non-nil value of ARG, use the current file.
 564
 565 If optional third arg SHOW-PROGRESS evaluates to non-nil,
 566 redisplay the dired buffer after each file is processed.
 567
 568 No guarantee is made about the position on the marked line.
 569 BODY must ensure this itself if it depends on this.
 570
 571 Search starts at the beginning of the buffer, thus the car of the
 572 list corresponds to the line nearest to the buffer's bottom.
 573 This is also true for (positive and negative) integer values of
 574 ARG.
 575
 576 BODY should not be too long as it is expanded four times.
 577
 578 If DISTINGUISH-ONE-MARKED is non-nil, then if we find just one
 579 marked file, return (t FILENAME) instead of (FILENAME)."
 580   ;;
 581   ;;Warning: BODY must not add new lines before point - this may cause an
 582   ;;endless loop.
 583   ;;This warning should not apply any longer, sk  2-Sep-1991 14:10.
 584   `(prog1
 585        (let ((inhibit-read-only t) case-fold-search found results)
 586          (if ,arg
 587              (if (integerp ,arg)
 588                  (progn ;; no save-excursion, want to move point.
 589                    (dired-repeat-over-lines
 590                     ,arg
 591                     (function (lambda ()
 592                                 (if ,show-progress (sit-for 0))
 593                                 (setq results (cons ,body results)))))
 594                    (if (< ,arg 0)
 595                        (nreverse results)
 596                      results))
 597                ;; non-nil, non-integer ARG means use current file:
 598                (list ,body))
 599            (let ((regexp (dired-marker-regexp)) next-position)
 600              (save-excursion
 601                (goto-char (point-min))
 602                ;; remember position of next marked file before BODY
 603                ;; can insert lines before the just found file,
 604                ;; confusing us by finding the same marked file again
 605                ;; and again and...
 606                (setq next-position (and (re-search-forward regexp nil t)
 607                                         (point-marker))
 608                      found (not (null next-position)))
 609                (while next-position
 610                  (goto-char next-position)
 611                  (if ,show-progress (sit-for 0))
 612                  (setq results (cons ,body results))
 613                  ;; move after last match
 614                  (goto-char next-position)
 615                  (forward-line 1)
 616                  (set-marker next-position nil)
 617                  (setq next-position (and (re-search-forward regexp nil t)
 618                                           (point-marker)))))
 619              (if (and ,distinguish-one-marked (= (length results) 1))
 620                  (setq results (cons t results)))
 621              (if found
 622                  results
 623                (list ,body)))))
 624      ;; save-excursion loses, again
 625      (dired-move-to-filename)))
 626
 627 (defun dired-get-marked-files (&optional localp arg filter distinguish-one-marked)
 628   "Return the marked files' names as list of strings.
 629 The list is in the same order as the buffer, that is, the car is the
 630   first marked file.
 631 Values returned are normally absolute file names.
 632 Optional arg LOCALP as in `dired-get-filename'.
 633 Optional second argument ARG, if non-nil, specifies files near
 634  point instead of marked files.  It usually comes from the prefix
 635  argument.
 636   If ARG is an integer, use the next ARG files.
 637   If ARG is any other non-nil value, return the current file name.
 638   If no files are marked, and ARG is nil, also return the current file name.
 639 Optional third argument FILTER, if non-nil, is a function to select
 640   some of the files--those for which (funcall FILTER FILENAME) is non-nil.
 641
 642 If DISTINGUISH-ONE-MARKED is non-nil, then if we find just one marked file,
 643 return (t FILENAME) instead of (FILENAME).
 644 Don't use that together with FILTER."
 645   (let ((all-of-them
 646          (save-excursion
 647            (delq nil (dired-map-over-marks
 648                       (dired-get-filename localp 'no-error-if-not-filep)
 649                       arg nil distinguish-one-marked))))
 650         result)
 651     (when (equal all-of-them '(t))
 652       (setq all-of-them nil))
 653     (if (not filter)
 654         (if (and distinguish-one-marked (eq (car all-of-them) t))
 655             all-of-them
 656           (nreverse all-of-them))
 657       (dolist (file all-of-them)
 658         (if (funcall filter file)
 659             (push file result)))
 660       result)))
 661 \f
 662 ;; The dired command
 663
 664 (defun dired-read-dir-and-switches (str)
 665   ;; For use in interactive.
 666   (reverse (list
 667             (if current-prefix-arg
 668                 (read-string "Dired listing switches: "
 669                              dired-listing-switches))
 670             ;; If a dialog is used, call `read-directory-name' so the
 671             ;; dialog code knows we want directories.  Some dialogs
 672             ;; can only select directories or files when popped up,
 673             ;; not both.  If no dialog is used, call `read-file-name'
 674             ;; because the user may want completion of file names for
 675             ;; use in a wildcard pattern.
 676             (if (next-read-file-uses-dialog-p)
 677                 (read-directory-name (format "Dired %s(directory): " str)
 678                                      nil default-directory nil)
 679               (read-file-name (format "Dired %s(directory): " str)
 680                               nil default-directory nil)))))
 681
 682 ;; We want to switch to a more sophisticated version of
 683 ;; dired-read-dir-and-switches like the following, if there is a way
 684 ;; to make it more intuitive.  See bug#1285.
 685
 686 ;; (defun dired-read-dir-and-switches (str)
 687 ;;   ;; For use in interactive.
 688 ;;   (reverse
 689 ;;    (list
 690 ;;     (if current-prefix-arg
 691 ;;         (read-string "Dired listing switches: "
 692 ;;                      dired-listing-switches))
 693 ;;     ;; If a dialog is about to be used, call read-directory-name so
 694 ;;     ;; the dialog code knows we want directories.  Some dialogs can
 695 ;;     ;; only select directories or files when popped up, not both.
 696 ;;     (if (next-read-file-uses-dialog-p)
 697 ;;         (read-directory-name (format "Dired %s(directory): " str)
 698 ;;                              nil default-directory nil)
 699 ;;       (let ((cie ()))
 700 ;;         (dolist (ext completion-ignored-extensions)
 701 ;;           (if (eq ?/ (aref ext (1- (length ext)))) (push ext cie)))
 702 ;;         (setq cie (concat (regexp-opt cie "\\(?:") "\\'"))
 703 ;;         (let* ((default (and buffer-file-name
 704 ;;                              (abbreviate-file-name buffer-file-name)))
 705 ;;                (cie cie)
 706 ;;                (completion-table
 707 ;;                 ;; We need a mix of read-file-name and
 708 ;;                 ;; read-directory-name so that completion to directories
 709 ;;                 ;; is preferred, but if the user wants to enter a global
 710 ;;                 ;; pattern, he can still use completion on filenames to
 711 ;;                 ;; help him write the pattern.
 712 ;;                 ;; Essentially, we want to use
 713 ;;                 ;; (completion-table-with-predicate
 714 ;;                 ;;  'read-file-name-internal 'file-directory-p nil)
 715 ;;                 ;; but that doesn't work because read-file-name-internal
 716 ;;                 ;; does not obey its `predicate' argument.
 717 ;;                 (completion-table-in-turn
 718 ;;                  (lambda (str pred action)
 719 ;;                    (let ((read-file-name-predicate
 720 ;;                           (lambda (f)
 721 ;;                             (and (not (member f '("./" "../")))
 722 ;;                                  ;; Hack! Faster than file-directory-p!
 723 ;;                                  (eq (aref f (1- (length f))) ?/)
 724 ;;                                  (not (string-match cie f))))))
 725 ;;                      (complete-with-action
 726 ;;                       action 'read-file-name-internal str nil)))
 727 ;;                  'read-file-name-internal)))
 728 ;;           (minibuffer-with-setup-hook
 729 ;;               (lambda ()
 730 ;;                 (setq minibuffer-default default)
 731 ;;                 (setq minibuffer-completion-table completion-table))
 732 ;;             (read-file-name (format "Dired %s(directory): " str)
 733 ;;                             nil default-directory nil))))))))
 734
 735 (defun dired-file-name-at-point ()
 736   "Try to get a file name at point in the current dired buffer.
 737 This hook is intended to be put in `file-name-at-point-functions'.
 738 Note that it returns an abbreviated name that can't be used
 739 as an argument to `dired-goto-file'."
 740   (let ((filename (dired-get-filename nil t)))
 741     (when filename
 742       (if (file-directory-p filename)
 743           (file-name-as-directory (abbreviate-file-name filename))
 744         (abbreviate-file-name filename)))))
 745
 746 ;;;###autoload (define-key ctl-x-map "d" 'dired)
 747 ;;;###autoload
 748 (defun dired (dirname &optional switches)
 749   "\"Edit\" directory DIRNAME--delete, rename, print, etc. some files in it.
 750 Optional second argument SWITCHES specifies the `ls' options used.
 751 \(Interactively, use a prefix argument to be able to specify SWITCHES.)
 752
 753 If DIRNAME is a string, Dired displays a list of files in DIRNAME (which
 754 may also have shell wildcards appended to select certain files).
 755
 756 If DIRNAME is a cons, its first element is taken as the directory name
 757 and the rest as an explicit list of files to make directory entries for.
 758 In this case, SWITCHES are applied to each of the files separately, and
 759 therefore switches that control the order of the files in the produced
 760 listing have no effect.
 761
 762 \\<dired-mode-map>\
 763 You can flag files for deletion with \\[dired-flag-file-deletion] and then
 764 delete them by typing \\[dired-do-flagged-delete].
 765 Type \\[describe-mode] after entering Dired for more info.
 766
 767 If DIRNAME is already in a Dired buffer, that buffer is used without refresh."
 768   ;; Cannot use (interactive "D") because of wildcards.
 769   (interactive (dired-read-dir-and-switches ""))
 770   (switch-to-buffer (dired-noselect dirname switches)))
 771
 772 ;;;###autoload (define-key ctl-x-4-map "d" 'dired-other-window)
 773 ;;;###autoload
 774 (defun dired-other-window (dirname &optional switches)
 775   "\"Edit\" directory DIRNAME.  Like `dired' but selects in another window."
 776   (interactive (dired-read-dir-and-switches "in other window "))
 777   (switch-to-buffer-other-window (dired-noselect dirname switches)))
 778
 779 ;;;###autoload (define-key ctl-x-5-map "d" 'dired-other-frame)
 780 ;;;###autoload
 781 (defun dired-other-frame (dirname &optional switches)
 782   "\"Edit\" directory DIRNAME.  Like `dired' but makes a new frame."
 783   (interactive (dired-read-dir-and-switches "in other frame "))
 784   (switch-to-buffer-other-frame (dired-noselect dirname switches)))
 785
 786 ;;;###autoload
 787 (defun dired-noselect (dir-or-list &optional switches)
 788   "Like `dired' but returns the Dired buffer as value, does not select it."
 789   (or dir-or-list (setq dir-or-list default-directory))
 790   ;; This loses the distinction between "/foo/*/" and "/foo/*" that
 791   ;; some shells make:
 792   (let (dirname initially-was-dirname)
 793     (if (consp dir-or-list)
 794         (setq dirname (car dir-or-list))
 795       (setq dirname dir-or-list))
 796     (setq initially-was-dirname
 797           (string= (file-name-as-directory dirname) dirname))
 798     (setq dirname (abbreviate-file-name
 799                    (expand-file-name (directory-file-name dirname))))
 800     (if find-file-visit-truename
 801         (setq dirname (file-truename dirname)))
 802     ;; If the argument was syntactically  a directory name not a file name,
 803     ;; or if it happens to name a file that is a directory,
 804     ;; convert it syntactically to a directory name.
 805     ;; The reason for checking initially-was-dirname
 806     ;; and not just file-directory-p
 807     ;; is that file-directory-p is slow over ftp.
 808     (if (or initially-was-dirname (file-directory-p dirname))
 809         (setq dirname  (file-name-as-directory dirname)))
 810     (if (consp dir-or-list)
 811         (setq dir-or-list (cons dirname (cdr dir-or-list)))
 812       (setq dir-or-list dirname))
 813     (dired-internal-noselect dir-or-list switches)))
 814
 815 ;; The following is an internal dired function.  It returns non-nil if
 816 ;; the directory visited by the current dired buffer has changed on
 817 ;; disk.  DIRNAME should be the directory name of that directory.
 818 (defun dired-directory-changed-p (dirname)
 819   (not (let ((attributes (file-attributes dirname))
 820              (modtime (visited-file-modtime)))
 821          (or (eq modtime 0)
 822              (not (eq (car attributes) t))
 823              (equal (nth 5 attributes) modtime)))))
 824
 825 (defun dired-buffer-stale-p (&optional noconfirm)
 826   "Return non-nil if current Dired buffer needs updating.
 827 If NOCONFIRM is non-nil, then this function always returns nil
 828 for a remote directory.  This feature is used by Auto Revert mode."
 829   (let ((dirname
 830          (if (consp dired-directory) (car dired-directory) dired-directory)))
 831     (and (stringp dirname)
 832          (not (when noconfirm (file-remote-p dirname)))
 833          (file-readable-p dirname)
 834          ;; Do not auto-revert when the dired buffer can be currently
 835          ;; written by the user as in `wdired-mode'.
 836          buffer-read-only
 837          (dired-directory-changed-p dirname))))
 838
 839 (defcustom dired-auto-revert-buffer nil
 840   "Automatically revert Dired buffer on revisiting.
 841 If t, revisiting an existing Dired buffer automatically reverts it.
 842 If its value is a function, call this function with the directory
 843 name as single argument and revert the buffer if it returns non-nil.
 844 Otherwise, a message offering to revert the changed dired buffer
 845 is displayed.
 846 Note that this is not the same as `auto-revert-mode' that
 847 periodically reverts at specified time intervals."
 848   :type '(choice
 849           (const :tag "Don't revert" nil)
 850           (const :tag "Always revert visited Dired buffer" t)
 851           (const :tag "Revert changed Dired buffer" dired-directory-changed-p)
 852           (function :tag "Predicate function"))
 853   :group 'dired
 854   :version "23.2")
 855
 856 (defun dired-internal-noselect (dir-or-list &optional switches mode)
 857   ;; If there is an existing dired buffer for DIRNAME, just leave
 858   ;; buffer as it is (don't even call dired-revert).
 859   ;; This saves time especially for deep trees or with ange-ftp.
 860   ;; The user can type `g' easily, and it is more consistent with find-file.
 861   ;; But if SWITCHES are given they are probably different from the
 862   ;; buffer's old value, so call dired-sort-other, which does
 863   ;; revert the buffer.
 864   ;; A pity we can't possibly do "Directory has changed - refresh? "
 865   ;; like find-file does.
 866   ;; Optional argument MODE is passed to dired-find-buffer-nocreate,
 867   ;; see there.
 868   (let* ((old-buf (current-buffer))
 869          (dirname (if (consp dir-or-list) (car dir-or-list) dir-or-list))
 870          ;; Look for an existing buffer.
 871          (buffer (dired-find-buffer-nocreate dirname mode))
 872          ;; Note that buffer already is in dired-mode, if found.
 873          (new-buffer-p (null buffer)))
 874     (or buffer
 875         (setq buffer (create-file-buffer (directory-file-name dirname))))
 876     (set-buffer buffer)
 877     (if (not new-buffer-p)              ; existing buffer ...
 878         (cond (switches                 ; ... but new switches
 879                ;; file list may have changed
 880                (setq dired-directory dir-or-list)
 881                ;; this calls dired-revert
 882                (dired-sort-other switches))
 883               ;; Always revert regardless of whether it has changed or not.
 884               ((eq dired-auto-revert-buffer t)
 885                (revert-buffer))
 886               ;; Revert when predicate function returns non-nil.
 887               ((functionp dired-auto-revert-buffer)
 888                (when (funcall dired-auto-revert-buffer dirname)
 889                  (revert-buffer)
 890                  (message "Changed directory automatically updated")))
 891               ;; If directory has changed on disk, offer to revert.
 892               ((when (dired-directory-changed-p dirname)
 893                  (message "%s"
 894                           (substitute-command-keys
 895                            "Directory has changed on disk; type \\[revert-buffer] to update Dired")))))
 896       ;; Else a new buffer
 897       (setq default-directory
 898             ;; We can do this unconditionally
 899             ;; because dired-noselect ensures that the name
 900             ;; is passed in directory name syntax
 901             ;; if it was the name of a directory at all.
 902             (file-name-directory dirname))
 903       (or switches (setq switches dired-listing-switches))
 904       (if mode (funcall mode)
 905         (dired-mode dir-or-list switches))
 906       ;; default-directory and dired-actual-switches are set now
 907       ;; (buffer-local), so we can call dired-readin:
 908       (let ((failed t))
 909         (unwind-protect
 910             (progn (dired-readin)
 911                    (setq failed nil))
 912           ;; dired-readin can fail if parent directories are inaccessible.
 913           ;; Don't leave an empty buffer around in that case.
 914           (if failed (kill-buffer buffer))))
 915       (goto-char (point-min))
 916       (dired-initial-position dirname))
 917     (set-buffer old-buf)
 918     buffer))
 919
 920 (defvar dired-buffers nil
 921   ;; Enlarged by dired-advertise
 922   ;; Queried by function dired-buffers-for-dir. When this detects a
 923   ;; killed buffer, it is removed from this list.
 924   "Alist of expanded directories and their associated Dired buffers.")
 925
 926 (defvar dired-find-subdir)
 927
 928 ;; FIXME add a doc-string, and document dired-x extensions.
 929 (defun dired-find-buffer-nocreate (dirname &optional mode)
 930   ;; This differs from dired-buffers-for-dir in that it does not consider
 931   ;; subdirs of default-directory and searches for the first match only.
 932   ;; Also, the major mode must be MODE.
 933   (if (and (featurep 'dired-x)
 934            dired-find-subdir
 935            ;; Don't try to find a wildcard as a subdirectory.
 936            (string-equal dirname (file-name-directory dirname)))
 937       (let* ((cur-buf (current-buffer))
 938              (buffers (nreverse
 939                        (dired-buffers-for-dir (expand-file-name dirname))))
 940              (cur-buf-matches (and (memq cur-buf buffers)
 941                                    ;; Wildcards must match, too:
 942                                    (equal dired-directory dirname))))
 943         ;; We don't want to switch to the same buffer---
 944         (setq buffers (delq cur-buf buffers))
 945         (or (car (sort buffers #'dired-buffer-more-recently-used-p))
 946             ;; ---unless it's the only possibility:
 947             (and cur-buf-matches cur-buf)))
 948     ;; No dired-x, or dired-find-subdir nil.
 949     (setq dirname (expand-file-name dirname))
 950     (let (found (blist dired-buffers))    ; was (buffer-list)
 951       (or mode (setq mode 'dired-mode))
 952       (while blist
 953         (if (null (buffer-name (cdr (car blist))))
 954             (setq blist (cdr blist))
 955           (with-current-buffer (cdr (car blist))
 956             (if (and (eq major-mode mode)
 957                      dired-directory  ;; nil during find-alternate-file
 958                      (equal dirname
 959                             (expand-file-name
 960                              (if (consp dired-directory)
 961                                  (car dired-directory)
 962                                dired-directory))))
 963                 (setq found (cdr (car blist))
 964                       blist nil)
 965               (setq blist (cdr blist))))))
 966       found)))
 967
 968 \f
 969 ;; Read in a new dired buffer
 970
 971 (defun dired-readin ()
 972   "Read in a new Dired buffer.
 973 Differs from `dired-insert-subdir' in that it accepts
 974 wildcards, erases the buffer, and builds the subdir-alist anew
 975 \(including making it buffer-local and clearing it first)."
 976
 977   ;; default-directory and dired-actual-switches must be buffer-local
 978   ;; and initialized by now.
 979   (let (dirname
 980         ;; This makes readin much much faster.
 981         ;; In particular, it prevents the font lock hook from running
 982         ;; until the directory is all read in.
 983         (inhibit-modification-hooks t))
 984     (if (consp dired-directory)
 985         (setq dirname (car dired-directory))
 986       (setq dirname dired-directory))
 987     (setq dirname (expand-file-name dirname))
 988     (save-excursion
 989       ;; This hook which may want to modify dired-actual-switches
 990       ;; based on dired-directory, e.g. with ange-ftp to a SysV host
 991       ;; where ls won't understand -Al switches.
 992       (run-hooks 'dired-before-readin-hook)
 993       (if (consp buffer-undo-list)
 994           (setq buffer-undo-list nil))
 995       (setq-local file-name-coding-system
 996                   (or coding-system-for-read file-name-coding-system))
 997       (let ((inhibit-read-only t)
 998             ;; Don't make undo entries for readin.
 999             (buffer-undo-list t))
1000         (widen)
1001         (erase-buffer)
1002         (dired-readin-insert))
1003       (goto-char (point-min))
1004       ;; Must first make alist buffer local and set it to nil because
1005       ;; dired-build-subdir-alist will call dired-clear-alist first
1006       (setq-local dired-subdir-alist nil)
1007       (dired-build-subdir-alist)
1008       (let ((attributes (file-attributes dirname)))
1009         (if (eq (car attributes) t)
1010             (set-visited-file-modtime (nth 5 attributes))))
1011       (set-buffer-modified-p nil)
1012       ;; No need to narrow since the whole buffer contains just
1013       ;; dired-readin's output, nothing else.  The hook can
1014       ;; successfully use dired functions (e.g. dired-get-filename)
1015       ;; as the subdir-alist has been built in dired-readin.
1016       (run-hooks 'dired-after-readin-hook))))
1017
1018 ;; Subroutines of dired-readin
1019
1020 (defun dired-readin-insert ()
1021   ;; Insert listing for the specified dir (and maybe file list)
1022   ;; already in dired-directory, assuming a clean buffer.
1023   (let (dir file-list)
1024     (if (consp dired-directory)
1025         (setq dir (car dired-directory)
1026               file-list (cdr dired-directory))
1027       (setq dir dired-directory
1028             file-list nil))
1029     (setq dir (expand-file-name dir))
1030     (if (and (equal "" (file-name-nondirectory dir))
1031              (not file-list))
1032         ;; If we are reading a whole single directory...
1033         (dired-insert-directory dir dired-actual-switches nil nil t)
1034       (if (not (file-readable-p
1035                 (directory-file-name (file-name-directory dir))))
1036           (error "Directory %s inaccessible or nonexistent" dir)
1037         ;; Else treat it as a wildcard spec
1038         ;; unless we have an explicit list of files.
1039         (dired-insert-directory dir dired-actual-switches
1040                                 file-list (not file-list) t)))))
1041
1042 (defun dired-align-file (beg end)
1043   "Align the fields of a file to the ones of surrounding lines.
1044 BEG..END is the line where the file info is located."
1045   ;; Some versions of ls try to adjust the size of each field so as to just
1046   ;; hold the largest element ("largest" in the current invocation, of
1047   ;; course).  So when a single line is output, the size of each field is
1048   ;; just big enough for that one output.  Thus when dired refreshes one
1049   ;; line, the alignment if this line w.r.t the rest is messed up because
1050   ;; the fields of that one line will generally be smaller.
1051   ;;
1052   ;; To work around this problem, we here add spaces to try and
1053   ;; re-align the fields as needed.  Since this is purely aesthetic,
1054   ;; it is of utmost importance that it doesn't mess up anything like
1055   ;; `dired-move-to-filename'.  To this end, we limit ourselves to
1056   ;; adding spaces only, and to only add them at places where there
1057   ;; was already at least one space.  This way, as long as
1058   ;; `directory-listing-before-filename-regexp' always matches spaces
1059   ;; with "*" or "+", we know we haven't made anything worse.  There
1060   ;; is one spot where the exact number of spaces is important, which
1061   ;; is just before the actual filename, so we refrain from adding
1062   ;; spaces there (and within the filename as well, of course).
1063   (save-excursion
1064     (let (file file-col other other-col)
1065       ;; Check that there is indeed a file, and that there is another adjacent
1066       ;; file with which to align, and that additional spaces are needed to
1067       ;; align the filenames.
1068       (when (and (setq file (progn (goto-char beg)
1069                                    (dired-move-to-filename nil end)))
1070                  (setq file-col (current-column))
1071                  (setq other
1072                        (or (and (goto-char beg)
1073                                 (zerop (forward-line -1))
1074                                 (dired-move-to-filename))
1075                            (and (goto-char beg)
1076                                 (zerop (forward-line 1))
1077                                 (dired-move-to-filename))))
1078                  (setq other-col (current-column))
1079                  (/= file other)
1080                  ;; Make sure there is some work left to do.
1081                  (> other-col file-col))
1082         ;; If we've only looked at the line above, check to see if the line
1083         ;; below exists as well and if so, align with the shorter one.
1084         (when (and (< other file)
1085                    (goto-char beg)
1086                    (zerop (forward-line 1))
1087                    (dired-move-to-filename))
1088           (let ((alt-col (current-column)))
1089             (when (< alt-col other-col)
1090               (setq other-col alt-col)
1091               (setq other (point)))))
1092         ;; Keep positions uptodate when we insert stuff.
1093         (if (> other file) (setq other (copy-marker other)))
1094         (setq file (copy-marker file))
1095         ;; Main loop.
1096         (goto-char beg)
1097         (skip-chars-forward " ")        ;Skip to the first field.
1098         (while (and (> other-col file-col)
1099                     ;; Don't touch anything just before (and after) the
1100                     ;; beginning of the filename.
1101                     (> file (point)))
1102           ;; We're now just in front of a field, with a space behind us.
1103           (let* ((curcol (current-column))
1104                  ;; Nums are right-aligned.
1105                  (num-align (looking-at-p "[0-9]"))
1106                  ;; Let's look at the other line, in the same column: we
1107                  ;; should be either near the end of the previous field, or
1108                  ;; in the space between that field and the next.
1109                  ;; [ Of course, it's also possible that we're already within
1110                  ;; the next field or even past it, but that's unlikely since
1111                  ;; other-col > file-col. ]
1112                  ;; Let's find the distance to the alignment-point (either
1113                  ;; the beginning or the end of the next field, depending on
1114                  ;; whether this field is left or right aligned).
1115                  (align-pt-offset
1116                   (save-excursion
1117                     (goto-char other)
1118                     (move-to-column curcol)
1119                     (when (looking-at
1120                            (concat
1121                             (if (eq (char-before) ?\s) " *" "[^ ]* *")
1122                             (if num-align "[0-9][^ ]*")))
1123                       (- (match-end 0) (match-beginning 0)))))
1124                  ;; Now, the number of spaces to insert is align-pt-offset
1125                  ;; minus the distance to the equivalent point on the
1126                  ;; current line.
1127                  (spaces
1128                   (if (not num-align)
1129                       align-pt-offset
1130                     (and align-pt-offset
1131                          (save-excursion
1132                            (skip-chars-forward "^ ")
1133                            (- align-pt-offset (- (current-column) curcol)))))))
1134             (when (and spaces (> spaces 0))
1135               (setq file-col (+ spaces file-col))
1136               (if (> file-col other-col)
1137                   (setq spaces (- spaces (- file-col other-col))))
1138               (insert-char ?\s spaces)
1139               ;; Let's just make really sure we did not mess up.
1140               (unless (save-excursion
1141                         (eq (dired-move-to-filename) (marker-position file)))
1142                 ;; Damn!  We messed up: let's revert the change.
1143                 (delete-char (- spaces)))))
1144           ;; Now skip to next field.
1145           (skip-chars-forward "^ ") (skip-chars-forward " "))
1146         (set-marker file nil)))))
1147
1148
1149 (defvar ls-lisp-use-insert-directory-program)
1150
1151 (defun dired-check-switches (switches short &optional long)
1152   "Return non-nil if the string SWITCHES matches LONG or SHORT format."
1153   (let (case-fold-search)
1154     (and (stringp switches)
1155          (string-match-p (concat "\\(\\`\\| \\)-[[:alnum:]]*" short
1156                                  (if long (concat "\\|--" long "\\>") ""))
1157                          switches))))
1158
1159 (defun dired-switches-escape-p (switches)
1160   "Return non-nil if the string SWITCHES contains -b or --escape."
1161   ;; Do not match things like "--block-size" that happen to contain "b".
1162   (dired-check-switches switches "b" "escape"))
1163
1164 (defun dired-switches-recursive-p (switches)
1165   "Return non-nil if the string SWITCHES contains -R or --recursive."
1166   (dired-check-switches switches "R" "recursive"))
1167
1168 (defun dired-insert-directory (dir switches &optional file-list wildcard hdr)
1169   "Insert a directory listing of DIR, Dired style.
1170 Use SWITCHES to make the listings.
1171 If FILE-LIST is non-nil, list only those files.
1172 Otherwise, if WILDCARD is non-nil, expand wildcards;
1173  in that case, DIR should be a file name that uses wildcards.
1174 In other cases, DIR should be a directory name or a directory filename.
1175 If HDR is non-nil, insert a header line with the directory name."
1176   (let ((opoint (point))
1177         (process-environment (copy-sequence process-environment))
1178         end)
1179     (if (and
1180          ;; Don't try to invoke `ls' if we are on DOS/Windows where
1181          ;; ls-lisp emulation is used, except if they want to use `ls'
1182          ;; as indicated by `ls-lisp-use-insert-directory-program'.
1183          (not (and (featurep 'ls-lisp)
1184                    (null ls-lisp-use-insert-directory-program)))
1185          (or (if (eq dired-use-ls-dired 'unspecified)
1186                  ;; Check whether "ls --dired" gives exit code 0, and
1187                  ;; save the answer in `dired-use-ls-dired'.
1188                  (or (setq dired-use-ls-dired
1189                            (eq 0 (call-process insert-directory-program
1190                                              nil nil nil "--dired")))
1191                      (progn
1192                        (message "ls does not support --dired; \
1193 see `dired-use-ls-dired' for more details.")
1194                        nil))
1195                dired-use-ls-dired)
1196              (file-remote-p dir)))
1197         (setq switches (concat "--dired " switches)))
1198     ;; We used to specify the C locale here, to force English month names;
1199     ;; but this should not be necessary any more,
1200     ;; with the new value of `directory-listing-before-filename-regexp'.
1201     (if file-list
1202         (dolist (f file-list)
1203           (let ((beg (point)))
1204             (insert-directory f switches nil nil)
1205             ;; Re-align fields, if necessary.
1206             (dired-align-file beg (point))))
1207       (insert-directory dir switches wildcard (not wildcard)))
1208     ;; Quote certain characters, unless ls quoted them for us.
1209     (if (not (dired-switches-escape-p dired-actual-switches))
1210         (save-excursion
1211           (setq end (point-marker))
1212           (goto-char opoint)
1213           (while (search-forward "\\" end t)
1214             (replace-match (apply #'propertize
1215                                   "\\\\"
1216                                   (text-properties-at (match-beginning 0)))
1217                            nil t))
1218           (goto-char opoint)
1219           (while (search-forward "\^m" end t)
1220             (replace-match (apply #'propertize
1221                                   "\\015"
1222                                   (text-properties-at (match-beginning 0)))
1223                            nil t))
1224           (set-marker end nil))
1225       ;; Replace any newlines in DIR with literal "\n"s, for the sake
1226       ;; of the header line.  To disambiguate a literal "\n" in the
1227       ;; actual dirname, we also replace "\" with "\\".
1228       ;; Personally, I think this should always be done, irrespective
1229       ;; of the value of dired-actual-switches, because:
1230       ;;  i) Dired simply does not work with an unescaped newline in
1231       ;;  the directory name used in the header (bug=10469#28), and
1232       ;;  ii) "\" is always replaced with "\\" in the listing, so doing
1233       ;;  it in the header as well makes things consistent.
1234       ;; But at present it is only done if "-b" is in ls-switches,
1235       ;; because newlines in dirnames are uncommon, and people may
1236       ;; have gotten used to seeing unescaped "\" in the headers.
1237       ;; Note: adjust dired-build-subdir-alist if you change this.
1238       (setq dir (replace-regexp-in-string "\\\\" "\\\\" dir nil t)
1239             dir (replace-regexp-in-string "\n" "\\n" dir nil t)))
1240     ;; If we used --dired and it worked, the lines are already indented.
1241     ;; Otherwise, indent them.
1242     (unless (save-excursion
1243               (goto-char opoint)
1244               (looking-at-p "  "))
1245       (let ((indent-tabs-mode nil))
1246         (indent-rigidly opoint (point) 2)))
1247     ;; Insert text at the beginning to standardize things.
1248     (let ((content-point opoint))
1249       (save-excursion
1250         (goto-char opoint)
1251         (when (and (or hdr wildcard)
1252                    (not (and (looking-at "^  \\(.*\\):$")
1253                              (file-name-absolute-p (match-string 1)))))
1254           ;; Note that dired-build-subdir-alist will replace the name
1255           ;; by its expansion, so it does not matter whether what we insert
1256           ;; here is fully expanded, but it should be absolute.
1257           (insert "  " (directory-file-name (file-name-directory dir)) ":\n")
1258           (setq content-point (point)))
1259         (when wildcard
1260           ;; Insert "wildcard" line where "total" line would be for a full dir.
1261           (insert "  wildcard " (file-name-nondirectory dir) "\n")))
1262       (dired-insert-set-properties content-point (point)))))
1263
1264 (defun dired-insert-set-properties (beg end)
1265   "Add various text properties to the lines in the region."
1266   (save-excursion
1267     (goto-char beg)
1268     (while (< (point) end)
1269       (ignore-errors
1270         (if (not (dired-move-to-filename))
1271             (unless (or (looking-at-p "^$")
1272                         (looking-at-p dired-subdir-regexp))
1273               (put-text-property (line-beginning-position)
1274                                  (1+ (line-end-position))
1275                                  'invisible 'dired-hide-details-information))
1276           (put-text-property (+ (line-beginning-position) 1) (1- (point))
1277                              'invisible 'dired-hide-details-detail)
1278           (add-text-properties
1279            (point)
1280            (progn
1281              (dired-move-to-end-of-filename)
1282              (point))
1283            '(mouse-face
1284              highlight
1285              dired-filename t
1286              help-echo "mouse-2: visit this file in other window"))
1287           (when (< (+ (point) 4) (line-end-position))
1288             (put-text-property (+ (point) 4) (line-end-position)
1289                                'invisible 'dired-hide-details-link))))
1290       (forward-line 1))))
1291 \f
1292 ;; Reverting a dired buffer
1293
1294 (defun dired-revert (&optional _arg _noconfirm)
1295   "Reread the Dired buffer.
1296 Must also be called after `dired-actual-switches' have changed.
1297 Should not fail even on completely garbaged buffers.
1298 Preserves old cursor, marks/flags, hidden-p.
1299
1300 Dired sets `revert-buffer-function' to this function.  The args
1301 ARG and NOCONFIRM, passed from `revert-buffer', are ignored."
1302   (widen)                               ; just in case user narrowed
1303   (let ((modflag (buffer-modified-p))
1304         (positions (dired-save-positions))
1305         (mark-alist nil)                ; save marked files
1306         (hidden-subdirs (dired-remember-hidden))
1307         (old-subdir-alist (cdr (reverse dired-subdir-alist))) ; except pwd
1308         (case-fold-search nil)          ; we check for upper case ls flags
1309         (inhibit-read-only t))
1310     (goto-char (point-min))
1311     (setq mark-alist;; only after dired-remember-hidden since this unhides:
1312           (dired-remember-marks (point-min) (point-max)))
1313     ;; treat top level dir extra (it may contain wildcards)
1314     (if (not (consp dired-directory))
1315         (dired-uncache dired-directory)
1316       (dired-uncache (car dired-directory))
1317       (dolist (dir (cdr dired-directory))
1318         (if (file-name-absolute-p dir)
1319             (dired-uncache dir))))
1320     ;; Run dired-after-readin-hook just once, below.
1321     (let ((dired-after-readin-hook nil))
1322       (dired-readin)
1323       (dired-insert-old-subdirs old-subdir-alist))
1324     (dired-mark-remembered mark-alist)  ; mark files that were marked
1325     ;; ... run the hook for the whole buffer, and only after markers
1326     ;; have been reinserted (else omitting in dired-x would omit marked files)
1327     (run-hooks 'dired-after-readin-hook)        ; no need to narrow
1328     (dired-restore-positions positions)
1329     (save-excursion                     ; hide subdirs that were hidden
1330       (dolist (dir hidden-subdirs)
1331         (if (dired-goto-subdir dir)
1332             (dired-hide-subdir 1))))
1333     (unless modflag (restore-buffer-modified-p nil)))
1334   ;; outside of the let scope
1335 ;;;  Might as well not override the user if the user changed this.
1336 ;;;  (setq buffer-read-only t)
1337   )
1338
1339 ;; Subroutines of dired-revert
1340 ;; Some of these are also used when inserting subdirs.
1341
1342 (defun dired-save-positions ()
1343   "Return current positions in the buffer and all windows with this directory.
1344 The positions have the form (BUFFER-POSITION WINDOW-POSITIONS).
1345
1346 BUFFER-POSITION is the point position in the current Dired buffer.
1347 It has the form (BUFFER DIRED-FILENAME BUFFER-POINT).
1348
1349 WINDOW-POSITIONS are current positions in all windows displaying
1350 this dired buffer.  The window positions have the form (WINDOW
1351 DIRED-FILENAME WINDOW-POINT)."
1352   (list
1353    (list (current-buffer) (dired-get-filename nil t) (point))
1354    (mapcar (lambda (w)
1355              (list w
1356                    (with-selected-window w
1357                      (dired-get-filename nil t))
1358                    (window-point w)))
1359            (get-buffer-window-list nil 0 t))))
1360
1361 (defun dired-restore-positions (positions)
1362   "Restore POSITIONS saved with `dired-save-positions'."
1363   (let* ((buf-file-pos (nth 0 positions))
1364          (buffer (nth 0 buf-file-pos)))
1365     (unless (and (nth 1 buf-file-pos)
1366                  (dired-goto-file (nth 1 buf-file-pos)))
1367       (goto-char (nth 2 buf-file-pos))
1368       (dired-move-to-filename))
1369     (dolist (win-file-pos (nth 1 positions))
1370       ;; Ensure that window still displays the original buffer.
1371       (when (eq (window-buffer (nth 0 win-file-pos)) buffer)
1372         (with-selected-window (nth 0 win-file-pos)
1373           (unless (and (nth 1 win-file-pos)
1374                        (dired-goto-file (nth 1 win-file-pos)))
1375             (goto-char (nth 2 win-file-pos))
1376             (dired-move-to-filename)))))))
1377
1378 (defun dired-remember-marks (beg end)
1379   "Return alist of files and their marks, from BEG to END."
1380   (if selective-display                 ; must unhide to make this work.
1381       (let ((inhibit-read-only t))
1382         (subst-char-in-region beg end ?\r ?\n)))
1383   (let (fil chr alist)
1384     (save-excursion
1385       (goto-char beg)
1386       (while (re-search-forward dired-re-mark end t)
1387         (if (setq fil (dired-get-filename nil t))
1388             (setq chr (preceding-char)
1389                   alist (cons (cons fil chr) alist)))))
1390     alist))
1391
1392 (defun dired-mark-remembered (alist)
1393   "Mark all files remembered in ALIST.
1394 Each element of ALIST looks like (FILE . MARKERCHAR)."
1395   (let (elt fil chr)
1396     (save-excursion
1397       (while alist
1398         (setq elt (car alist)
1399               alist (cdr alist)
1400               fil (car elt)
1401               chr (cdr elt))
1402         (when (dired-goto-file fil)
1403           (beginning-of-line)
1404           (delete-char 1)
1405           (insert chr))))))
1406
1407 (defun dired-remember-hidden ()
1408   "Return a list of names of subdirs currently hidden."
1409   (let ((l dired-subdir-alist) dir pos result)
1410     (while l
1411       (setq dir (car (car l))
1412             pos (cdr (car l))
1413             l (cdr l))
1414       (goto-char pos)
1415       (skip-chars-forward "^\r\n")
1416       (if (eq (following-char) ?\r)
1417           (setq result (cons dir result))))
1418     result))
1419
1420 (defun dired-insert-old-subdirs (old-subdir-alist)
1421   "Try to insert all subdirs that were displayed before.
1422 Do so according to the former subdir alist OLD-SUBDIR-ALIST."
1423   (or (dired-switches-recursive-p dired-actual-switches)
1424       (let (elt dir)
1425         (while old-subdir-alist
1426           (setq elt (car old-subdir-alist)
1427                 old-subdir-alist (cdr old-subdir-alist)
1428                 dir (car elt))
1429           (ignore-errors
1430             (dired-uncache dir)
1431             (dired-insert-subdir dir))))))
1432
1433 (defun dired-uncache (dir)
1434   "Remove directory DIR from any directory cache."
1435   (let ((handler (find-file-name-handler dir 'dired-uncache)))
1436     (if handler
1437         (funcall handler 'dired-uncache dir))))
1438 \f
1439 ;; dired mode key bindings and initialization
1440
1441 (defvar dired-mode-map
1442   ;; This looks ugly when substitute-command-keys uses C-d instead d:
1443   ;;  (define-key dired-mode-map "\C-d" 'dired-flag-file-deletion)
1444   (let ((map (make-keymap)))
1445     (set-keymap-parent map special-mode-map)
1446     (define-key map [mouse-2] 'dired-mouse-find-file-other-window)
1447     (define-key map [follow-link] 'mouse-face)
1448     ;; Commands to mark or flag certain categories of files
1449     (define-key map "#" 'dired-flag-auto-save-files)
1450     (define-key map "." 'dired-clean-directory)
1451     (define-key map "~" 'dired-flag-backup-files)
1452     ;; Upper case keys (except !) for operating on the marked files
1453     (define-key map "A" 'dired-do-find-regexp)
1454     (define-key map "C" 'dired-do-copy)
1455     (define-key map "B" 'dired-do-byte-compile)
1456     (define-key map "D" 'dired-do-delete)
1457     (define-key map "G" 'dired-do-chgrp)
1458     (define-key map "H" 'dired-do-hardlink)
1459     (define-key map "L" 'dired-do-load)
1460     (define-key map "M" 'dired-do-chmod)
1461     (define-key map "O" 'dired-do-chown)
1462     (define-key map "P" 'dired-do-print)
1463     (define-key map "Q" 'dired-do-find-regexp-and-replace)
1464     (define-key map "R" 'dired-do-rename)
1465     (define-key map "S" 'dired-do-symlink)
1466     (define-key map "T" 'dired-do-touch)
1467     (define-key map "X" 'dired-do-shell-command)
1468     (define-key map "Z" 'dired-do-compress)
1469     (define-key map "c" 'dired-do-compress-to)
1470     (define-key map "!" 'dired-do-shell-command)
1471     (define-key map "&" 'dired-do-async-shell-command)
1472     ;; Comparison commands
1473     (define-key map "=" 'dired-diff)
1474     ;; Tree Dired commands
1475     (define-key map "\M-\C-?" 'dired-unmark-all-files)
1476     (define-key map "\M-\C-d" 'dired-tree-down)
1477     (define-key map "\M-\C-u" 'dired-tree-up)
1478     (define-key map "\M-\C-n" 'dired-next-subdir)
1479     (define-key map "\M-\C-p" 'dired-prev-subdir)
1480     ;; move to marked files
1481     (define-key map "\M-{" 'dired-prev-marked-file)
1482     (define-key map "\M-}" 'dired-next-marked-file)
1483     ;; Make all regexp commands share a `%' prefix:
1484     ;; We used to get to the submap via a symbol dired-regexp-prefix,
1485     ;; but that seems to serve little purpose, and copy-keymap
1486     ;; does a better job without it.
1487     (define-key map "%" nil)
1488     (define-key map "%u" 'dired-upcase)
1489     (define-key map "%l" 'dired-downcase)
1490     (define-key map "%d" 'dired-flag-files-regexp)
1491     (define-key map "%g" 'dired-mark-files-containing-regexp)
1492     (define-key map "%m" 'dired-mark-files-regexp)
1493     (define-key map "%r" 'dired-do-rename-regexp)
1494     (define-key map "%C" 'dired-do-copy-regexp)
1495     (define-key map "%H" 'dired-do-hardlink-regexp)
1496     (define-key map "%R" 'dired-do-rename-regexp)
1497     (define-key map "%S" 'dired-do-symlink-regexp)
1498     (define-key map "%&" 'dired-flag-garbage-files)
1499     ;; Commands for marking and unmarking.
1500     (define-key map "*" nil)
1501     (define-key map "**" 'dired-mark-executables)
1502     (define-key map "*/" 'dired-mark-directories)
1503     (define-key map "*@" 'dired-mark-symlinks)
1504     (define-key map "*%" 'dired-mark-files-regexp)
1505     (define-key map "*c" 'dired-change-marks)
1506     (define-key map "*s" 'dired-mark-subdir-files)
1507     (define-key map "*m" 'dired-mark)
1508     (define-key map "*u" 'dired-unmark)
1509     (define-key map "*?" 'dired-unmark-all-files)
1510     (define-key map "*!" 'dired-unmark-all-marks)
1511     (define-key map "U" 'dired-unmark-all-marks)
1512     (define-key map "*\177" 'dired-unmark-backward)
1513     (define-key map "*\C-n" 'dired-next-marked-file)
1514     (define-key map "*\C-p" 'dired-prev-marked-file)
1515     (define-key map "*t" 'dired-toggle-marks)
1516     ;; Lower keys for commands not operating on all the marked files
1517     (define-key map "a" 'dired-find-alternate-file)
1518     (define-key map "d" 'dired-flag-file-deletion)
1519     (define-key map "e" 'dired-find-file)
1520     (define-key map "f" 'dired-find-file)
1521     (define-key map "\C-m" 'dired-find-file)
1522     (put 'dired-find-file :advertised-binding "\C-m")
1523     (define-key map "g" 'revert-buffer)
1524     (define-key map "i" 'dired-maybe-insert-subdir)
1525     (define-key map "j" 'dired-goto-file)
1526     (define-key map "k" 'dired-do-kill-lines)
1527     (define-key map "l" 'dired-do-redisplay)
1528     (define-key map "m" 'dired-mark)
1529     (define-key map "n" 'dired-next-line)
1530     (define-key map "o" 'dired-find-file-other-window)
1531     (define-key map "\C-o" 'dired-display-file)
1532     (define-key map "p" 'dired-previous-line)
1533     (define-key map "s" 'dired-sort-toggle-or-edit)
1534     (define-key map "t" 'dired-toggle-marks)
1535     (define-key map "u" 'dired-unmark)
1536     (define-key map "v" 'dired-view-file)
1537     (define-key map "w" 'dired-copy-filename-as-kill)
1538     (define-key map "x" 'dired-do-flagged-delete)
1539     (define-key map "y" 'dired-show-file-type)
1540     (define-key map "+" 'dired-create-directory)
1541     ;; moving
1542     (define-key map "<" 'dired-prev-dirline)
1543     (define-key map ">" 'dired-next-dirline)
1544     (define-key map "^" 'dired-up-directory)
1545     (define-key map " " 'dired-next-line)
1546     (define-key map [?\S-\ ] 'dired-previous-line)
1547     (define-key map [remap next-line] 'dired-next-line)
1548     (define-key map [remap previous-line] 'dired-previous-line)
1549     ;; hiding
1550     (define-key map "$" 'dired-hide-subdir)
1551     (define-key map "\M-$" 'dired-hide-all)
1552     (define-key map "(" 'dired-hide-details-mode)
1553     ;; isearch
1554     (define-key map (kbd "M-s a C-s")   'dired-do-isearch)
1555     (define-key map (kbd "M-s a M-C-s") 'dired-do-isearch-regexp)
1556     (define-key map (kbd "M-s f C-s")   'dired-isearch-filenames)
1557     (define-key map (kbd "M-s f M-C-s") 'dired-isearch-filenames-regexp)
1558     ;; misc
1559     (define-key map [remap read-only-mode] 'dired-toggle-read-only)
1560     ;; `toggle-read-only' is an obsolete alias for `read-only-mode'
1561     (define-key map [remap toggle-read-only] 'dired-toggle-read-only)
1562     (define-key map "?" 'dired-summary)
1563     (define-key map "\177" 'dired-unmark-backward)
1564     (define-key map [remap undo] 'dired-undo)
1565     (define-key map [remap advertised-undo] 'dired-undo)
1566     ;; thumbnail manipulation (image-dired)
1567     (define-key map "\C-td" 'image-dired-display-thumbs)
1568     (define-key map "\C-tt" 'image-dired-tag-files)
1569     (define-key map "\C-tr" 'image-dired-delete-tag)
1570     (define-key map "\C-tj" 'image-dired-jump-thumbnail-buffer)
1571     (define-key map "\C-ti" 'image-dired-dired-display-image)
1572     (define-key map "\C-tx" 'image-dired-dired-display-external)
1573     (define-key map "\C-ta" 'image-dired-display-thumbs-append)
1574     (define-key map "\C-t." 'image-dired-display-thumb)
1575     (define-key map "\C-tc" 'image-dired-dired-comment-files)
1576     (define-key map "\C-tf" 'image-dired-mark-tagged-files)
1577     (define-key map "\C-t\C-t" 'image-dired-dired-toggle-marked-thumbs)
1578     (define-key map "\C-te" 'image-dired-dired-edit-comment-and-tags)
1579     ;; encryption and decryption (epa-dired)
1580     (define-key map ":d" 'epa-dired-do-decrypt)
1581     (define-key map ":v" 'epa-dired-do-verify)
1582     (define-key map ":s" 'epa-dired-do-sign)
1583     (define-key map ":e" 'epa-dired-do-encrypt)
1584
1585     ;; Make menu bar items.
1586
1587     ;; No need to fo this, now that top-level items are fewer.
1588     ;;;;
1589     ;; Get rid of the Edit menu bar item to save space.
1590     ;(define-key map [menu-bar edit] 'undefined)
1591
1592     (define-key map [menu-bar subdir]
1593       (cons "Subdir" (make-sparse-keymap "Subdir")))
1594
1595     (define-key map [menu-bar subdir hide-all]
1596       '(menu-item "Hide All" dired-hide-all
1597                   :help "Hide all subdirectories, leave only header lines"))
1598     (define-key map [menu-bar subdir hide-subdir]
1599       '(menu-item "Hide/UnHide Subdir" dired-hide-subdir
1600                   :help "Hide or unhide current directory listing"))
1601     (define-key map [menu-bar subdir tree-down]
1602       '(menu-item "Tree Down" dired-tree-down
1603                   :help "Go to first subdirectory header down the tree"))
1604     (define-key map [menu-bar subdir tree-up]
1605       '(menu-item "Tree Up" dired-tree-up
1606                   :help "Go to first subdirectory header up the tree"))
1607     (define-key map [menu-bar subdir up]
1608       '(menu-item "Up Directory" dired-up-directory
1609                   :help "Edit the parent directory"))
1610     (define-key map [menu-bar subdir prev-subdir]
1611       '(menu-item "Prev Subdir" dired-prev-subdir
1612                   :help "Go to previous subdirectory header line"))
1613     (define-key map [menu-bar subdir next-subdir]
1614       '(menu-item "Next Subdir" dired-next-subdir
1615                   :help "Go to next subdirectory header line"))
1616     (define-key map [menu-bar subdir prev-dirline]
1617       '(menu-item "Prev Dirline" dired-prev-dirline
1618                   :help "Move to next directory-file line"))
1619     (define-key map [menu-bar subdir next-dirline]
1620       '(menu-item "Next Dirline" dired-next-dirline
1621                   :help "Move to previous directory-file line"))
1622     (define-key map [menu-bar subdir insert]
1623       '(menu-item "Insert This Subdir" dired-maybe-insert-subdir
1624                   :help "Insert contents of subdirectory"
1625                   :enable (let ((f (dired-get-filename nil t)))
1626                             (and f (file-directory-p f)))))
1627     (define-key map [menu-bar immediate]
1628       (cons "Immediate" (make-sparse-keymap "Immediate")))
1629
1630     (define-key map
1631       [menu-bar immediate image-dired-dired-display-external]
1632       '(menu-item "Display Image Externally" image-dired-dired-display-external
1633                   :help "Display image in external viewer"))
1634     (define-key map
1635       [menu-bar immediate image-dired-dired-display-image]
1636       '(menu-item "Display Image" image-dired-dired-display-image
1637                   :help "Display sized image in a separate window"))
1638     (define-key map
1639       [menu-bar immediate image-dired-dired-toggle-marked-thumbs]
1640       '(menu-item "Toggle Image Thumbnails in This Buffer" image-dired-dired-toggle-marked-thumbs
1641                   :help "Add or remove image thumbnails in front of marked file names"))
1642
1643     (define-key map [menu-bar immediate hide-details]
1644       '(menu-item "Hide Details" dired-hide-details-mode
1645                   :help "Hide details in buffer"
1646                   :button (:toggle . dired-hide-details-mode)))
1647     (define-key map [menu-bar immediate revert-buffer]
1648       '(menu-item "Refresh" revert-buffer
1649                   :help "Update contents of shown directories"))
1650
1651     (define-key map [menu-bar immediate dashes]
1652       '("--"))
1653
1654     (define-key map [menu-bar immediate isearch-filenames-regexp]
1655       '(menu-item "Isearch Regexp in File Names..." dired-isearch-filenames-regexp
1656                   :help "Incrementally search for regexp in file names only"))
1657     (define-key map [menu-bar immediate isearch-filenames]
1658       '(menu-item "Isearch in File Names..." dired-isearch-filenames
1659                   :help "Incrementally search for string in file names only."))
1660     (define-key map [menu-bar immediate compare-directories]
1661       '(menu-item "Compare Directories..." dired-compare-directories
1662                   :help "Mark files with different attributes in two Dired buffers"))
1663     (define-key map [menu-bar immediate backup-diff]
1664       '(menu-item "Compare with Backup" dired-backup-diff
1665                   :help "Diff file at cursor with its latest backup"))
1666     (define-key map [menu-bar immediate diff]
1667       '(menu-item "Diff..." dired-diff
1668                   :help "Compare file at cursor with another file"))
1669     (define-key map [menu-bar immediate view]
1670       '(menu-item "View This File" dired-view-file
1671                   :help "Examine file at cursor in read-only mode"))
1672     (define-key map [menu-bar immediate display]
1673       '(menu-item "Display in Other Window" dired-display-file
1674                   :help "Display file at cursor in other window"))
1675     (define-key map [menu-bar immediate find-file-other-window]
1676       '(menu-item "Find in Other Window" dired-find-file-other-window
1677                   :help "Edit file at cursor in other window"))
1678     (define-key map [menu-bar immediate find-file]
1679       '(menu-item "Find This File" dired-find-file
1680                   :help "Edit file at cursor"))
1681     (define-key map [menu-bar immediate create-directory]
1682       '(menu-item "Create Directory..." dired-create-directory
1683                   :help "Create a directory"))
1684     (define-key map [menu-bar immediate wdired-mode]
1685       '(menu-item "Edit File Names" wdired-change-to-wdired-mode
1686                   :help "Put a Dired buffer in a mode in which filenames are editable"
1687                   :keys "C-x C-q"
1688                   :filter (lambda (x) (if (eq major-mode 'dired-mode) x))))
1689
1690     (define-key map [menu-bar regexp]
1691       (cons "Regexp" (make-sparse-keymap "Regexp")))
1692
1693     (define-key map
1694       [menu-bar regexp image-dired-mark-tagged-files]
1695       '(menu-item "Mark From Image Tag..." image-dired-mark-tagged-files
1696                   :help "Mark files whose image tags matches regexp"))
1697
1698     (define-key map [menu-bar regexp dashes-1]
1699       '("--"))
1700
1701     (define-key map [menu-bar regexp downcase]
1702       '(menu-item "Downcase" dired-downcase
1703                   ;; When running on plain MS-DOS, there's only one
1704                   ;; letter-case for file names.
1705                   :enable (or (not (fboundp 'msdos-long-file-names))
1706                               (msdos-long-file-names))
1707                   :help "Rename marked files to lower-case name"))
1708     (define-key map [menu-bar regexp upcase]
1709       '(menu-item "Upcase" dired-upcase
1710                   :enable (or (not (fboundp 'msdos-long-file-names))
1711                               (msdos-long-file-names))
1712                   :help "Rename marked files to upper-case name"))
1713     (define-key map [menu-bar regexp hardlink]
1714       '(menu-item "Hardlink..." dired-do-hardlink-regexp
1715                   :help "Make hard links for files matching regexp"))
1716     (define-key map [menu-bar regexp symlink]
1717       '(menu-item "Symlink..." dired-do-symlink-regexp
1718                   :visible (fboundp 'make-symbolic-link)
1719                   :help "Make symbolic links for files matching regexp"))
1720     (define-key map [menu-bar regexp rename]
1721       '(menu-item "Rename..." dired-do-rename-regexp
1722                   :help "Rename marked files matching regexp"))
1723     (define-key map [menu-bar regexp copy]
1724       '(menu-item "Copy..." dired-do-copy-regexp
1725                   :help "Copy marked files matching regexp"))
1726     (define-key map [menu-bar regexp flag]
1727       '(menu-item "Flag..." dired-flag-files-regexp
1728                   :help "Flag files matching regexp for deletion"))
1729     (define-key map [menu-bar regexp mark]
1730       '(menu-item "Mark..." dired-mark-files-regexp
1731                   :help "Mark files matching regexp for future operations"))
1732     (define-key map [menu-bar regexp mark-cont]
1733       '(menu-item "Mark Containing..." dired-mark-files-containing-regexp
1734                   :help "Mark files whose contents matches regexp"))
1735
1736     (define-key map [menu-bar mark]
1737       (cons "Mark" (make-sparse-keymap "Mark")))
1738
1739     (define-key map [menu-bar mark prev]
1740       '(menu-item "Previous Marked" dired-prev-marked-file
1741                   :help "Move to previous marked file"))
1742     (define-key map [menu-bar mark next]
1743       '(menu-item "Next Marked" dired-next-marked-file
1744                   :help "Move to next marked file"))
1745     (define-key map [menu-bar mark marks]
1746       '(menu-item "Change Marks..." dired-change-marks
1747                   :help "Replace marker with another character"))
1748     (define-key map [menu-bar mark unmark-all]
1749       '(menu-item "Unmark All" dired-unmark-all-marks))
1750     (define-key map [menu-bar mark symlinks]
1751       '(menu-item "Mark Symlinks" dired-mark-symlinks
1752                   :visible (fboundp 'make-symbolic-link)
1753                   :help "Mark all symbolic links"))
1754     (define-key map [menu-bar mark directories]
1755       '(menu-item "Mark Directories" dired-mark-directories
1756                   :help "Mark all directories except `.' and `..'"))
1757     (define-key map [menu-bar mark directory]
1758       '(menu-item "Mark Old Backups" dired-clean-directory
1759                   :help "Flag old numbered backups for deletion"))
1760     (define-key map [menu-bar mark executables]
1761       '(menu-item "Mark Executables" dired-mark-executables
1762                   :help "Mark all executable files"))
1763     (define-key map [menu-bar mark garbage-files]
1764       '(menu-item "Flag Garbage Files" dired-flag-garbage-files
1765                   :help "Flag unneeded files for deletion"))
1766     (define-key map [menu-bar mark backup-files]
1767       '(menu-item "Flag Backup Files" dired-flag-backup-files
1768                   :help "Flag all backup files for deletion"))
1769     (define-key map [menu-bar mark auto-save-files]
1770       '(menu-item "Flag Auto-save Files" dired-flag-auto-save-files
1771                   :help "Flag auto-save files for deletion"))
1772     (define-key map [menu-bar mark deletion]
1773       '(menu-item "Flag" dired-flag-file-deletion
1774                   :help "Flag current line's file for deletion"))
1775     (define-key map [menu-bar mark unmark]
1776       '(menu-item "Unmark" dired-unmark
1777                   :help "Unmark or unflag current line's file"))
1778     (define-key map [menu-bar mark mark]
1779       '(menu-item "Mark" dired-mark
1780                   :help "Mark current line's file for future operations"))
1781     (define-key map [menu-bar mark toggle-marks]
1782       '(menu-item "Toggle Marks" dired-toggle-marks
1783                   :help "Mark unmarked files, unmark marked ones"))
1784
1785     (define-key map [menu-bar operate]
1786       (cons "Operate" (make-sparse-keymap "Operate")))
1787
1788     (define-key map
1789       [menu-bar operate image-dired-delete-tag]
1790       '(menu-item "Delete Image Tag..." image-dired-delete-tag
1791                   :help "Delete image tag from current or marked files"))
1792     (define-key map
1793       [menu-bar operate image-dired-tag-files]
1794       '(menu-item "Add Image Tags..." image-dired-tag-files
1795                   :help "Add image tags to current or marked files"))
1796     (define-key map
1797       [menu-bar operate image-dired-dired-comment-files]
1798       '(menu-item "Add Image Comment..." image-dired-dired-comment-files
1799                   :help "Add image comment to current or marked files"))
1800     (define-key map
1801       [menu-bar operate image-dired-display-thumbs]
1802       '(menu-item "Display Image Thumbnails" image-dired-display-thumbs
1803                   :help "Display image thumbnails for current or marked image files"))
1804
1805     (define-key map [menu-bar operate dashes-4]
1806       '("--"))
1807
1808     (define-key map
1809       [menu-bar operate epa-dired-do-decrypt]
1810       '(menu-item "Decrypt..." epa-dired-do-decrypt
1811                   :help "Decrypt current or marked files"))
1812
1813     (define-key map
1814       [menu-bar operate epa-dired-do-verify]
1815       '(menu-item "Verify" epa-dired-do-verify
1816                   :help "Verify digital signature of current or marked files"))
1817
1818     (define-key map
1819       [menu-bar operate epa-dired-do-sign]
1820       '(menu-item "Sign..." epa-dired-do-sign
1821                   :help "Create digital signature of current or marked files"))
1822
1823     (define-key map
1824       [menu-bar operate epa-dired-do-encrypt]
1825       '(menu-item "Encrypt..." epa-dired-do-encrypt
1826                   :help "Encrypt current or marked files"))
1827
1828     (define-key map [menu-bar operate dashes-3]
1829       '("--"))
1830
1831     (define-key map [menu-bar operate query-replace]
1832       '(menu-item "Query Replace in Files..." dired-do-query-replace-regexp
1833                   :help "Replace regexp in marked files"))
1834     (define-key map [menu-bar operate search]
1835       '(menu-item "Search Files..." dired-do-search
1836                   :help "Search marked files for regexp"))
1837     (define-key map [menu-bar operate isearch-regexp]
1838       '(menu-item "Isearch Regexp Files..." dired-do-isearch-regexp
1839                   :help "Incrementally search marked files for regexp"))
1840     (define-key map [menu-bar operate isearch]
1841       '(menu-item "Isearch Files..." dired-do-isearch
1842                   :help "Incrementally search marked files for string"))
1843     (define-key map [menu-bar operate chown]
1844       '(menu-item "Change Owner..." dired-do-chown
1845                   :visible (not (memq system-type '(ms-dos windows-nt)))
1846                   :help "Change the owner of marked files"))
1847     (define-key map [menu-bar operate chgrp]
1848       '(menu-item "Change Group..." dired-do-chgrp
1849                   :visible (not (memq system-type '(ms-dos windows-nt)))
1850                   :help "Change the group of marked files"))
1851     (define-key map [menu-bar operate chmod]
1852       '(menu-item "Change Mode..." dired-do-chmod
1853                   :help "Change mode (attributes) of marked files"))
1854     (define-key map [menu-bar operate touch]
1855       '(menu-item "Change Timestamp..." dired-do-touch
1856                   :help "Change timestamp of marked files"))
1857     (define-key map [menu-bar operate load]
1858       '(menu-item "Load" dired-do-load
1859                   :help "Load marked Emacs Lisp files"))
1860     (define-key map [menu-bar operate compile]
1861       '(menu-item "Byte-compile" dired-do-byte-compile
1862                   :help "Byte-compile marked Emacs Lisp files"))
1863     (define-key map [menu-bar operate compress]
1864       '(menu-item "Compress" dired-do-compress
1865                   :help "Compress/uncompress marked files"))
1866     (define-key map [menu-bar operate print]
1867       '(menu-item "Print..." dired-do-print
1868                   :help "Ask for print command and print marked files"))
1869     (define-key map [menu-bar operate hardlink]
1870       '(menu-item "Hardlink to..." dired-do-hardlink
1871                   :help "Make hard links for current or marked files"))
1872     (define-key map [menu-bar operate symlink]
1873       '(menu-item "Symlink to..." dired-do-symlink
1874                   :visible (fboundp 'make-symbolic-link)
1875                   :help "Make symbolic links for current or marked files"))
1876     (define-key map [menu-bar operate async-command]
1877       '(menu-item "Asynchronous Shell Command..." dired-do-async-shell-command
1878                   :help "Run a shell command asynchronously on current or marked files"))
1879     (define-key map [menu-bar operate command]
1880       '(menu-item "Shell Command..." dired-do-shell-command
1881                   :help "Run a shell command on current or marked files"))
1882     (define-key map [menu-bar operate delete]
1883       '(menu-item "Delete" dired-do-delete
1884                   :help "Delete current file or all marked files"))
1885     (define-key map [menu-bar operate rename]
1886       '(menu-item "Rename to..." dired-do-rename
1887                   :help "Rename current file or move marked files"))
1888     (define-key map [menu-bar operate copy]
1889       '(menu-item "Copy to..." dired-do-copy
1890                   :help "Copy current file or all marked files"))
1891
1892     map)
1893   "Local keymap for Dired mode buffers.")
1894 \f
1895 ;; Dired mode is suitable only for specially formatted data.
1896 (put 'dired-mode 'mode-class 'special)
1897
1898 ;; Autoload cookie needed by desktop.el
1899 ;;;###autoload
1900 (defun dired-mode (&optional dirname switches)
1901   "\
1902 Mode for \"editing\" directory listings.
1903 In Dired, you are \"editing\" a list of the files in a directory and
1904   (optionally) its subdirectories, in the format of `ls -lR'.
1905   Each directory is a page: use \\[backward-page] and \\[forward-page] to move pagewise.
1906 \"Editing\" means that you can run shell commands on files, visit,
1907   compress, load or byte-compile them, change their file attributes
1908   and insert subdirectories into the same buffer.  You can \"mark\"
1909   files for later commands or \"flag\" them for deletion, either file
1910   by file or all files matching certain criteria.
1911 You can move using the usual cursor motion commands.\\<dired-mode-map>
1912 The buffer is read-only.  Digits are prefix arguments.
1913 Type \\[dired-flag-file-deletion] to flag a file `D' for deletion.
1914 Type \\[dired-mark] to Mark a file or subdirectory for later commands.
1915   Most commands operate on the marked files and use the current file
1916   if no files are marked.  Use a numeric prefix argument to operate on
1917   the next ARG (or previous -ARG if ARG<0) files, or just `1'
1918   to operate on the current file only.  Prefix arguments override marks.
1919   Mark-using commands display a list of failures afterwards.  Type \\[dired-summary]
1920   to see why something went wrong.
1921 Type \\[dired-unmark] to Unmark a file or all files of an inserted subdirectory.
1922 Type \\[dired-unmark-backward] to back up one line and unmark or unflag.
1923 Type \\[dired-do-flagged-delete] to delete (eXpunge) the files flagged `D'.
1924 Type \\[dired-find-file] to Find the current line's file
1925   (or dired it in another buffer, if it is a directory).
1926 Type \\[dired-find-file-other-window] to find file or Dired directory in Other window.
1927 Type \\[dired-maybe-insert-subdir] to Insert a subdirectory in this buffer.
1928 Type \\[dired-do-rename] to Rename a file or move the marked files to another directory.
1929 Type \\[dired-do-copy] to Copy files.
1930 Type \\[dired-sort-toggle-or-edit] to toggle Sorting by name/date or change the `ls' switches.
1931 Type \\[revert-buffer] to read all currently expanded directories aGain.
1932   This retains all marks and hides subdirs again that were hidden before.
1933 Use `SPC' and `DEL' to move down and up by lines.
1934
1935 If Dired ever gets confused, you can either type \\[revert-buffer] \
1936 to read the
1937 directories again, type \\[dired-do-redisplay] \
1938 to relist the file at point or the marked files or a
1939 subdirectory, or type \\[dired-build-subdir-alist] to parse the buffer
1940 again for the directory tree.
1941
1942 Customization variables (rename this buffer and type \\[describe-variable] on each line
1943 for more info):
1944
1945   `dired-listing-switches'
1946   `dired-trivial-filenames'
1947   `dired-marker-char'
1948   `dired-del-marker'
1949   `dired-keep-marker-rename'
1950   `dired-keep-marker-copy'
1951   `dired-keep-marker-hardlink'
1952   `dired-keep-marker-symlink'
1953
1954 Hooks (use \\[describe-variable] to see their documentation):
1955
1956   `dired-before-readin-hook'
1957   `dired-after-readin-hook'
1958   `dired-mode-hook'
1959   `dired-load-hook'
1960
1961 Keybindings:
1962 \\{dired-mode-map}"
1963   ;; Not to be called interactively (e.g. dired-directory will be set
1964   ;; to default-directory, which is wrong with wildcards).
1965   (kill-all-local-variables)
1966   (use-local-map dired-mode-map)
1967   (dired-advertise)                     ; default-directory is already set
1968   (setq major-mode 'dired-mode
1969         mode-name "Dired"
1970         ;; case-fold-search nil
1971         buffer-read-only t
1972         selective-display t             ; for subdirectory hiding
1973         mode-line-buffer-identification
1974         (propertized-buffer-identification "%17b"))
1975   ;; Ignore dired-hide-details-* value of invisible text property by default.
1976   (when (eq buffer-invisibility-spec t)
1977     (setq buffer-invisibility-spec (list t)))
1978   (setq-local revert-buffer-function (function dired-revert))
1979   (setq-local buffer-stale-function (function dired-buffer-stale-p))
1980   (setq-local page-delimiter "\n\n")
1981   (setq-local dired-directory (or dirname default-directory))
1982   ;; list-buffers uses this to display the dir being edited in this buffer.
1983   (setq list-buffers-directory
1984         (expand-file-name (if (listp dired-directory)
1985                               (car dired-directory)
1986                             dired-directory)))
1987   (setq-local dired-actual-switches (or switches dired-listing-switches))
1988   (setq-local font-lock-defaults
1989               '(dired-font-lock-keywords t nil nil beginning-of-line))
1990   (setq-local desktop-save-buffer 'dired-desktop-buffer-misc-data)
1991   (setq dired-switches-alist nil)
1992   (hack-dir-local-variables-non-file-buffer) ; before sorting
1993   (dired-sort-other dired-actual-switches t)
1994   (when (featurep 'dnd)
1995     (setq-local dnd-protocol-alist
1996                 (append dired-dnd-protocol-alist dnd-protocol-alist)))
1997   (add-hook 'file-name-at-point-functions 'dired-file-name-at-point nil t)
1998   (add-hook 'isearch-mode-hook 'dired-isearch-filenames-setup nil t)
1999   (run-mode-hooks 'dired-mode-hook))
2000 \f
2001 ;; Idiosyncratic dired commands that don't deal with marks.
2002
2003 (defun dired-summary ()
2004   "Summarize basic Dired commands and show recent Dired errors."
2005   (interactive)
2006   (dired-why)
2007   ;>> this should check the key-bindings and use substitute-command-keys if non-standard
2008   (message
2009    "d-elete, u-ndelete, x-punge, f-ind, o-ther window, R-ename, C-opy, h-elp"))
2010
2011 (defun dired-undo ()
2012   "Undo in a Dired buffer.
2013 This doesn't recover lost files, it just undoes changes in the buffer itself.
2014 You can use it to recover marks, killed lines or subdirs."
2015   (interactive)
2016   (let ((inhibit-read-only t))
2017     (undo))
2018   (dired-build-subdir-alist)
2019   (message "Change in Dired buffer undone.
2020 Actual changes in files cannot be undone by Emacs."))
2021
2022 (defun dired-toggle-read-only ()
2023   "Edit Dired buffer with Wdired, or make it read-only.
2024 If the current buffer can be edited with Wdired, (i.e. the major
2025 mode is `dired-mode'), call `wdired-change-to-wdired-mode'.
2026 Otherwise, toggle `read-only-mode'."
2027   (interactive)
2028   (if (derived-mode-p 'dired-mode)
2029       (wdired-change-to-wdired-mode)
2030     (read-only-mode 'toggle)))
2031
2032 (defun dired-next-line (arg)
2033   "Move down lines then position at filename.
2034 Optional prefix ARG says how many lines to move; default is one line."
2035   (interactive "^p")
2036   (let ((line-move-visual)
2037         (goal-column))
2038     (line-move arg t))
2039   ;; We never want to move point into an invisible line.
2040   (while (and (invisible-p (point))
2041               (not (if (and arg (< arg 0)) (bobp) (eobp))))
2042     (forward-char (if (and arg (< arg 0)) -1 1)))
2043   (dired-move-to-filename))
2044
2045 (defun dired-previous-line (arg)
2046   "Move up lines then position at filename.
2047 Optional prefix ARG says how many lines to move; default is one line."
2048   (interactive "^p")
2049   (dired-next-line (- (or arg 1))))
2050
2051 (defun dired-next-dirline (arg &optional opoint)
2052   "Goto ARGth next directory file line."
2053   (interactive "p")
2054   (or opoint (setq opoint (point)))
2055   (if (if (> arg 0)
2056           (re-search-forward dired-re-dir nil t arg)
2057         (beginning-of-line)
2058         (re-search-backward dired-re-dir nil t (- arg)))
2059       (dired-move-to-filename)          ; user may type `i' or `f'
2060     (goto-char opoint)
2061     (error "No more subdirectories")))
2062
2063 (defun dired-prev-dirline (arg)
2064   "Goto ARGth previous directory file line."
2065   (interactive "p")
2066   (dired-next-dirline (- arg)))
2067
2068 (defun dired-up-directory (&optional other-window)
2069   "Run Dired on parent directory of current directory.
2070 Find the parent directory either in this buffer or another buffer.
2071 Creates a buffer if necessary.
2072 If OTHER-WINDOW (the optional prefix arg), display the parent
2073 directory in another window."
2074   (interactive "P")
2075   (let* ((dir (dired-current-directory))
2076          (up (file-name-directory (directory-file-name dir))))
2077     (or (dired-goto-file (directory-file-name dir))
2078         ;; Only try dired-goto-subdir if buffer has more than one dir.
2079         (and (cdr dired-subdir-alist)
2080              (dired-goto-subdir up))
2081         (progn
2082           (if other-window
2083               (dired-other-window up)
2084             (dired up))
2085           (dired-goto-file dir)))))
2086
2087 (defun dired-get-file-for-visit ()
2088   "Get the current line's file name, with an error if file does not exist."
2089   (interactive)
2090   ;; We pass t for second arg so that we don't get error for `.' and `..'.
2091   (let ((raw (dired-get-filename nil t))
2092         file-name)
2093     (if (null raw)
2094         (error "No file on this line"))
2095     (setq file-name (file-name-sans-versions raw t))
2096     (if (file-exists-p file-name)
2097         file-name
2098       (if (file-symlink-p file-name)
2099           (error "File is a symlink to a nonexistent target")
2100         (error "File no longer exists; type `g' to update Dired buffer")))))
2101
2102 ;; Force C-m keybinding rather than `f' or `e' in the mode doc:
2103 (define-obsolete-function-alias 'dired-advertised-find-file 'dired-find-file "23.2")
2104 (defun dired-find-file ()
2105   "In Dired, visit the file or directory named on this line."
2106   (interactive)
2107   ;; Bind `find-file-run-dired' so that the command works on directories
2108   ;; too, independent of the user's setting.
2109   (let ((find-file-run-dired t))
2110     (find-file (dired-get-file-for-visit))))
2111
2112 (defun dired-find-alternate-file ()
2113   "In Dired, visit this file or directory instead of the Dired buffer."
2114   (interactive)
2115   (set-buffer-modified-p nil)
2116   (find-alternate-file (dired-get-file-for-visit)))
2117 ;; Don't override the setting from .emacs.
2118 ;;;###autoload (put 'dired-find-alternate-file 'disabled t)
2119
2120 (defun dired-mouse-find-file-other-window (event)
2121   "In Dired, visit the file or directory name you click on."
2122   (interactive "e")
2123   (let (window pos file)
2124     (save-excursion
2125       (setq window (posn-window (event-end event))
2126             pos (posn-point (event-end event)))
2127       (if (not (windowp window))
2128           (error "No file chosen"))
2129       (set-buffer (window-buffer window))
2130       (goto-char pos)
2131       (setq file (dired-get-file-for-visit)))
2132     (if (file-directory-p file)
2133         (or (and (cdr dired-subdir-alist)
2134                  (dired-goto-subdir file))
2135             (progn
2136               (select-window window)
2137               (dired-other-window file)))
2138       (select-window window)
2139       (find-file-other-window (file-name-sans-versions file t)))))
2140
2141 (defun dired-view-file ()
2142   "In Dired, examine a file in view mode, returning to Dired when done.
2143 When file is a directory, show it in this buffer if it is inserted.
2144 Otherwise, display it in another buffer."
2145   (interactive)
2146   (let ((file (dired-get-file-for-visit)))
2147     (if (file-directory-p file)
2148         (or (and (cdr dired-subdir-alist)
2149                  (dired-goto-subdir file))
2150             (dired file))
2151       (view-file file))))
2152
2153 (defun dired-find-file-other-window ()
2154   "In Dired, visit this file or directory in another window."
2155   (interactive)
2156   (find-file-other-window (dired-get-file-for-visit)))
2157
2158 (defun dired-display-file ()
2159   "In Dired, display this file or directory in another window."
2160   (interactive)
2161   (display-buffer (find-file-noselect (dired-get-file-for-visit))
2162                   t))
2163 \f
2164 ;;; Functions for extracting and manipulating file names in Dired buffers.
2165
2166 (defun dired-get-filename (&optional localp no-error-if-not-filep)
2167   "In Dired, return name of file mentioned on this line.
2168 Value returned normally includes the directory name.
2169 Optional arg LOCALP with value `no-dir' means don't include directory
2170 name in result.  A value of `verbatim' means to return the name exactly as
2171 it occurs in the buffer, and a value of t means construct name relative to
2172 `default-directory', which still may contain slashes if in a subdirectory.
2173 Optional arg NO-ERROR-IF-NOT-FILEP means treat `.' and `..' as
2174 regular filenames and return nil if no filename on this line.
2175 Otherwise, an error occurs in these cases."
2176   (let (case-fold-search file p1 p2 already-absolute)
2177     (save-excursion
2178       (if (setq p1 (dired-move-to-filename (not no-error-if-not-filep)))
2179           (setq p2 (dired-move-to-end-of-filename no-error-if-not-filep))))
2180     ;; nil if no file on this line, but no-error-if-not-filep is t:
2181     (if (setq file (and p1 p2 (buffer-substring p1 p2)))
2182         (progn
2183           ;; Get rid of the mouse-face property that file names have.
2184           (set-text-properties 0 (length file) nil file)
2185           ;; Unquote names quoted by ls or by dired-insert-directory.
2186           ;; This code was written using `read' to unquote, because
2187           ;; it's faster than substituting \007 (4 chars) -> ^G (1
2188           ;; char) etc. in a lisp loop.  Unfortunately, this decision
2189           ;; has necessitated hacks such as dealing with filenames
2190           ;; with quotation marks in their names.
2191           (while (string-match "\\(?:[^\\]\\|\\`\\)\\(\"\\)" file)
2192             (setq file (replace-match "\\\"" nil t file 1)))
2193           ;; Unescape any spaces escaped by ls -b (bug#10469).
2194           ;; Other -b quotes, eg \t, \n, work transparently.
2195           (if (dired-switches-escape-p dired-actual-switches)
2196               (let ((start 0)
2197                     (rep "")
2198                     (shift -1))
2199                 (if (eq localp 'verbatim)
2200                     (setq rep "\\\\"
2201                           shift +1))
2202                 (while (string-match "\\(\\\\\\) " file start)
2203                   (setq file (replace-match rep nil t file 1)
2204                         start (+ shift (match-end 0))))))
2205           (when (eq system-type 'windows-nt)
2206             (save-match-data
2207               (let ((start 0))
2208                 (while (string-match "\\\\" file start)
2209                   (aset file (match-beginning 0) ?/)
2210                   (setq start (match-end 0))))))
2211
2212           ;; Hence we don't need to worry about converting `\\' back to `\'.
2213           (setq file (read (concat "\"" file "\"")))
2214           ;; The above `read' will return a unibyte string if FILE
2215           ;; contains eight-bit-control/graphic characters.
2216           (if (and enable-multibyte-characters
2217                    (not (multibyte-string-p file)))
2218               (setq file (string-to-multibyte file)))))
2219     (and file (file-name-absolute-p file)
2220          ;; A relative file name can start with ~.
2221          ;; Don't treat it as absolute in this context.
2222          (not (eq (aref file 0) ?~))
2223          (setq already-absolute t))
2224     (cond
2225      ((null file)
2226       nil)
2227      ((eq localp 'verbatim)
2228       file)
2229      ((and (not no-error-if-not-filep)
2230            (member file '("." "..")))
2231       (error "Cannot operate on `.' or `..'"))
2232      ((and (eq localp 'no-dir) already-absolute)
2233       (file-name-nondirectory file))
2234      (already-absolute
2235       (let ((handler (find-file-name-handler file nil)))
2236         ;; check for safe-magic property so that we won't
2237         ;; put /: for names that don't really need them.
2238         ;; For instance, .gz files when auto-compression-mode is on.
2239         (if (and handler (not (get handler 'safe-magic)))
2240             (concat "/:" file)
2241           file)))
2242      ((eq localp 'no-dir)
2243       file)
2244      ((equal (dired-current-directory) "/")
2245       (setq file (concat (dired-current-directory localp) file))
2246       (let ((handler (find-file-name-handler file nil)))
2247         ;; check for safe-magic property so that we won't
2248         ;; put /: for names that don't really need them.
2249         ;; For instance, .gz files when auto-compression-mode is on.
2250         (if (and handler (not (get handler 'safe-magic)))
2251             (concat "/:" file)
2252           file)))
2253      (t
2254       (concat (dired-current-directory localp) file)))))
2255
2256 (defun dired-string-replace-match (regexp string newtext
2257                                    &optional literal global)
2258   "Replace first match of REGEXP in STRING with NEWTEXT.
2259 If it does not match, nil is returned instead of the new string.
2260 Optional arg LITERAL means to take NEWTEXT literally.
2261 Optional arg GLOBAL means to replace all matches."
2262   (if global
2263       (let ((start 0) ret)
2264         (while (string-match regexp string start)
2265           (let ((from-end (- (length string) (match-end 0))))
2266             (setq ret (setq string (replace-match newtext t literal string)))
2267             (setq start (- (length string) from-end))))
2268           ret)
2269     (if (not (string-match regexp string 0))
2270         nil
2271       (replace-match newtext t literal string))))
2272
2273 (defun dired-make-absolute (file &optional dir)
2274   ;;"Convert FILE (a file name relative to DIR) to an absolute file name."
2275   ;; We can't always use expand-file-name as this would get rid of `.'
2276   ;; or expand in / instead default-directory if DIR=="".
2277   ;; This should be good enough for ange-ftp.
2278   ;; It should be reasonably fast, though, as it is called in
2279   ;; dired-get-filename.
2280   (concat (or dir default-directory) file))
2281
2282 (defun dired-make-relative (file &optional dir)
2283   "Convert FILE (an absolute file name) to a name relative to DIR.
2284 If DIR is omitted or nil, it defaults to `default-directory'.
2285 If FILE is not in the directory tree of DIR, return FILE
2286 unchanged."
2287   (or dir (setq dir default-directory))
2288   ;; This case comes into play if default-directory is set to
2289   ;; use ~.
2290   (if (and (> (length dir) 0) (= (aref dir 0) ?~))
2291       (setq dir (expand-file-name dir)))
2292   (if (string-match (concat "^" (regexp-quote dir)) file)
2293       (substring file (match-end 0))
2294     file))
2295 \f
2296 (define-minor-mode dired-hide-details-mode
2297   "Toggle visibility of detailed information in current Dired buffer.
2298 When this minor mode is enabled, details such as file ownership and
2299 permissions are hidden from view.
2300
2301 See options: `dired-hide-details-hide-symlink-targets' and
2302 `dired-hide-details-hide-information-lines'."
2303   :group 'dired
2304   (unless (derived-mode-p 'dired-mode)
2305     (error "Not a Dired buffer"))
2306   (dired-hide-details-update-invisibility-spec)
2307   (if dired-hide-details-mode
2308       (add-hook 'wdired-mode-hook
2309                 'dired-hide-details-update-invisibility-spec
2310                 nil
2311                 t)
2312     (remove-hook 'wdired-mode-hook
2313                  'dired-hide-details-update-invisibility-spec
2314                  t)))
2315
2316 (defun dired-hide-details-update-invisibility-spec ()
2317   (funcall (if dired-hide-details-mode
2318                'add-to-invisibility-spec
2319              'remove-from-invisibility-spec)
2320            'dired-hide-details-detail)
2321   (funcall (if (and dired-hide-details-mode
2322                     dired-hide-details-hide-information-lines)
2323                'add-to-invisibility-spec
2324              'remove-from-invisibility-spec)
2325            'dired-hide-details-information)
2326   (funcall (if (and dired-hide-details-mode
2327                     dired-hide-details-hide-symlink-targets
2328                     (not (derived-mode-p 'wdired-mode)))
2329                'add-to-invisibility-spec
2330              'remove-from-invisibility-spec)
2331            'dired-hide-details-link))
2332 \f
2333 ;;; Functions for finding the file name in a dired buffer line.
2334
2335 (defvar dired-permission-flags-regexp
2336   "\\([^ ]\\)[-r][-w]\\([^ ]\\)[-r][-w]\\([^ ]\\)[-r][-w]\\([^ ]\\)"
2337   "Regular expression to match the permission flags in `ls -l'.")
2338
2339 ;; Move to first char of filename on this line.
2340 ;; Returns position (point) or nil if no filename on this line."
2341 (defun dired-move-to-filename (&optional raise-error eol)
2342   "Move to the beginning of the filename on the current line.
2343 Return the position of the beginning of the filename, or nil if none found."
2344   ;; This is the UNIX version.
2345   (or eol (setq eol (line-end-position)))
2346   (beginning-of-line)
2347   ;; First try assuming `ls --dired' was used.
2348   (let ((change (next-single-property-change (point) 'dired-filename nil eol)))
2349     (cond
2350      ((and change (< change eol))
2351       (goto-char change))
2352      ((re-search-forward directory-listing-before-filename-regexp eol t)
2353       (goto-char (match-end 0)))
2354      ((re-search-forward dired-permission-flags-regexp eol t)
2355       ;; Ha!  There *is* a file.  Our regexp-from-hell just failed to find it.
2356       (if raise-error
2357           (error "Unrecognized line!  Check directory-listing-before-filename-regexp"))
2358       (beginning-of-line)
2359       nil)
2360      (raise-error
2361       (error "No file on this line")))))
2362
2363 (defun dired-move-to-end-of-filename (&optional no-error)
2364   ;; Assumes point is at beginning of filename,
2365   ;; thus the rwx bit re-search-backward below will succeed in *this*
2366   ;; line if at all.  So, it should be called only after
2367   ;; (dired-move-to-filename t).
2368   ;; On failure, signals an error (with non-nil NO-ERROR just returns nil).
2369   ;; This is the UNIX version.
2370   (if (get-text-property (point) 'dired-filename)
2371       (goto-char (next-single-property-change (point) 'dired-filename))
2372     (let (opoint file-type executable symlink hidden used-F eol)
2373       (setq used-F (dired-check-switches dired-actual-switches "F" "classify")
2374             opoint (point)
2375             eol (line-end-position)
2376             hidden (and selective-display
2377                         (save-excursion (search-forward "\r" eol t))))
2378       (if hidden
2379           nil
2380         (save-excursion ;; Find out what kind of file this is:
2381           ;; Restrict perm bits to be non-blank,
2382           ;; otherwise this matches one char to early (looking backward):
2383           ;; "l---------" (some systems make symlinks that way)
2384           ;; "----------" (plain file with zero perms)
2385           (if (re-search-backward
2386                dired-permission-flags-regexp nil t)
2387               (setq file-type (char-after (match-beginning 1))
2388                     symlink (eq file-type ?l)
2389                     ;; Only with -F we need to know whether it's an executable
2390                     executable (and
2391                                 used-F
2392                                 (string-match
2393                                  "[xst]" ;; execute bit set anywhere?
2394                                  (concat
2395                                   (match-string 2)
2396                                   (match-string 3)
2397                                   (match-string 4)))))
2398             (or no-error (error "No file on this line"))))
2399         ;; Move point to end of name:
2400         (if symlink
2401             (if (search-forward " -> " eol t)
2402                 (progn
2403                   (forward-char -4)
2404                   (and used-F
2405                        dired-ls-F-marks-symlinks
2406                        (eq (preceding-char) ?@) ;; did ls really mark the link?
2407                        (forward-char -1))))
2408           (goto-char eol) ;; else not a symbolic link
2409           ;; ls -lF marks dirs, sockets, fifos and executables with exactly
2410           ;; one trailing character. (Executable bits on symlinks ain't mean
2411           ;; a thing, even to ls, but we know it's not a symlink.)
2412           (and used-F
2413                (or (memq file-type '(?d ?s ?p))
2414                    executable)
2415                (forward-char -1))))
2416       (or no-error
2417           (not (eq opoint (point)))
2418           (error "%s" (if hidden
2419                      (substitute-command-keys
2420                       "File line is hidden, type \\[dired-hide-subdir] to unhide")
2421                    "No file on this line")))
2422       (if (eq opoint (point))
2423           nil
2424         (point)))))
2425
2426 \f
2427 ;;; COPY NAMES OF MARKED FILES INTO KILL-RING.
2428
2429 (defun dired-copy-filename-as-kill (&optional arg)
2430   "Copy names of marked (or next ARG) files into the kill ring.
2431 The names are separated by a space.
2432 With a zero prefix arg, use the absolute file name of each marked file.
2433 With \\[universal-argument], use the file name relative to the Dired buffer's
2434 `default-directory'.  (This still may contain slashes if in a subdirectory.)
2435
2436 If on a subdir headerline, use absolute subdirname instead;
2437 prefix arg and marked files are ignored in this case.
2438
2439 You can then feed the file name(s) to other commands with \\[yank]."
2440   (interactive "P")
2441   (let ((string
2442          (or (dired-get-subdir)
2443              (mapconcat (function identity)
2444                         (if arg
2445                             (cond ((zerop (prefix-numeric-value arg))
2446                                    (dired-get-marked-files))
2447                                   ((consp arg)
2448                                    (dired-get-marked-files t))
2449                                   (t
2450                                    (dired-get-marked-files
2451                                     'no-dir (prefix-numeric-value arg))))
2452                           (dired-get-marked-files 'no-dir))
2453                         " "))))
2454     (if (eq last-command 'kill-region)
2455         (kill-append string nil)
2456       (kill-new string))
2457     (message "%s" string)))
2458
2459 \f
2460 ;; Keeping Dired buffers in sync with the filesystem and with each other
2461
2462 (defun dired-buffers-for-dir (dir &optional file)
2463 ;; Return a list of buffers for DIR (top level or in-situ subdir).
2464 ;; If FILE is non-nil, include only those whose wildcard pattern (if any)
2465 ;; matches FILE.
2466 ;; The list is in reverse order of buffer creation, most recent last.
2467 ;; As a side effect, killed dired buffers for DIR are removed from
2468 ;; dired-buffers.
2469   (setq dir (file-name-as-directory dir))
2470   (let (result buf)
2471     (dolist (elt dired-buffers)
2472       (setq buf (cdr elt))
2473       (cond
2474        ((null (buffer-name buf))
2475         ;; Buffer is killed - clean up:
2476         (setq dired-buffers (delq elt dired-buffers)))
2477        ((dired-in-this-tree dir (car elt))
2478         (with-current-buffer buf
2479           (and (assoc dir dired-subdir-alist)
2480                (or (null file)
2481                    (if (stringp dired-directory)
2482                        (let ((wildcards (file-name-nondirectory
2483                                          dired-directory)))
2484                          (or (zerop (length wildcards))
2485                              (string-match-p (dired-glob-regexp wildcards)
2486                                              file)))
2487                      (member (expand-file-name file dir)
2488                              (cdr dired-directory))))
2489                (setq result (cons buf result)))))))
2490     result))
2491
2492 (defun dired-glob-regexp (pattern)
2493   "Convert glob-pattern PATTERN to a regular expression."
2494   (let ((matched-in-pattern 0)  ;; How many chars of PATTERN we've handled.
2495         regexp)
2496     (while (string-match "[[?*]" pattern matched-in-pattern)
2497       (let ((op-end (match-end 0))
2498             (next-op (aref pattern (match-beginning 0))))
2499         (setq regexp (concat regexp
2500                              (regexp-quote
2501                               (substring pattern matched-in-pattern
2502                                          (match-beginning 0)))))
2503         (cond ((= next-op ??)
2504                (setq regexp (concat regexp "."))
2505                (setq matched-in-pattern op-end))
2506               ((= next-op ?\[)
2507                ;; Fails to handle ^ yet ????
2508                (let* ((set-start (match-beginning 0))
2509                       (set-cont
2510                        (if (= (aref pattern (1+ set-start)) ?^)
2511                            (+ 3 set-start)
2512                          (+ 2 set-start)))
2513                       (set-end (string-match-p "]" pattern set-cont))
2514                       (set (substring pattern set-start (1+ set-end))))
2515                  (setq regexp (concat regexp set))
2516                  (setq matched-in-pattern (1+ set-end))))
2517               ((= next-op ?*)
2518                (setq regexp (concat regexp ".*"))
2519                (setq matched-in-pattern op-end)))))
2520     (concat "\\`"
2521             regexp
2522             (regexp-quote
2523              (substring pattern matched-in-pattern))
2524             "\\'")))
2525
2526
2527
2528 (defun dired-advertise ()
2529   ;;"Advertise in variable `dired-buffers' that we dired `default-directory'."
2530   ;; With wildcards we actually advertise too much.
2531   (let ((expanded-default (expand-file-name default-directory)))
2532     (if (memq (current-buffer) (dired-buffers-for-dir expanded-default))
2533         t                               ; we have already advertised ourselves
2534       (setq dired-buffers
2535             (cons (cons expanded-default (current-buffer))
2536                   dired-buffers)))))
2537
2538 (defun dired-unadvertise (dir)
2539   ;; Remove DIR from the buffer alist in variable dired-buffers.
2540   ;; This has the effect of removing any buffer whose main directory is DIR.
2541   ;; It does not affect buffers in which DIR is a subdir.
2542   ;; Removing is also done as a side-effect in dired-buffer-for-dir.
2543   (setq dired-buffers
2544         (delq (assoc (expand-file-name dir) dired-buffers) dired-buffers)))
2545 \f
2546 ;; Tree Dired
2547
2548 ;;; utility functions
2549
2550 (defun dired-in-this-tree (file dir)
2551   ;;"Is FILE part of the directory tree starting at DIR?"
2552   (let (case-fold-search)
2553     (string-match-p (concat "^" (regexp-quote dir)) file)))
2554
2555 (defun dired-normalize-subdir (dir)
2556   ;; Prepend default-directory to DIR if relative file name.
2557   ;; dired-get-filename must be able to make a valid file name from a
2558   ;; file and its directory DIR.
2559   (file-name-as-directory
2560    (if (file-name-absolute-p dir)
2561        dir
2562      (expand-file-name dir default-directory))))
2563
2564 (defun dired-get-subdir ()
2565   ;;"Return the subdir name on this line, or nil if not on a headerline."
2566   ;; Look up in the alist whether this is a headerline.
2567   (save-excursion
2568     (let ((cur-dir (dired-current-directory)))
2569       (beginning-of-line)               ; alist stores b-o-l positions
2570       (and (zerop (- (point)
2571                      (dired-get-subdir-min (assoc cur-dir
2572                                                   dired-subdir-alist))))
2573            cur-dir))))
2574
2575 ;; can't use macro,  must be redefinable for other alist format in dired-nstd.
2576 (defalias 'dired-get-subdir-min 'cdr)
2577
2578 (defun dired-get-subdir-max (elt)
2579   (save-excursion
2580     (goto-char (dired-get-subdir-min elt))
2581     (dired-subdir-max)))
2582
2583 (defun dired-clear-alist ()
2584   (while dired-subdir-alist
2585     (set-marker (dired-get-subdir-min (car dired-subdir-alist)) nil)
2586     (setq dired-subdir-alist (cdr dired-subdir-alist))))
2587
2588 (defun dired-subdir-index (dir)
2589   ;; Return an index into alist for use with nth
2590   ;; for the sake of subdir moving commands.
2591   (let (found (index 0) (alist dired-subdir-alist))
2592     (while alist
2593       (if (string= dir (car (car alist)))
2594           (setq alist nil found t)
2595         (setq alist (cdr alist) index (1+ index))))
2596     (if found index nil)))
2597
2598 (defun dired-next-subdir (arg &optional no-error-if-not-found no-skip)
2599   "Go to next subdirectory, regardless of level."
2600   ;; Use 0 arg to go to this directory's header line.
2601   ;; NO-SKIP prevents moving to end of header line, returning whatever
2602   ;; position was found in dired-subdir-alist.
2603   (interactive "p")
2604   (let ((this-dir (dired-current-directory))
2605         pos index)
2606     ;; nth with negative arg does not return nil but the first element
2607     (setq index (- (dired-subdir-index this-dir) arg))
2608     (setq pos (if (>= index 0)
2609                   (dired-get-subdir-min (nth index dired-subdir-alist))))
2610     (if pos
2611         (progn
2612           (goto-char pos)
2613           (or no-skip (skip-chars-forward "^\n\r"))
2614           (point))
2615       (if no-error-if-not-found
2616           nil                           ; return nil if not found
2617         (error "%s directory" (if (> arg 0) "Last" "First"))))))
2618
2619 (defun dired-build-subdir-alist (&optional switches)
2620   "Build `dired-subdir-alist' by parsing the buffer.
2621 Returns the new value of the alist.
2622 If optional arg SWITCHES is non-nil, use its value
2623 instead of `dired-actual-switches'."
2624   (interactive)
2625   (dired-clear-alist)
2626   (save-excursion
2627     (let* ((count 0)
2628            (inhibit-read-only t)
2629            (buffer-undo-list t)
2630            (switches (or switches dired-actual-switches))
2631            new-dir-name
2632            (R-ftp-base-dir-regex
2633             ;; Used to expand subdirectory names correctly in recursive
2634             ;; ange-ftp listings.
2635             (and (dired-switches-recursive-p switches)
2636                  (string-match "\\`/.*:\\(/.*\\)" default-directory)
2637                  (concat "\\`" (match-string 1 default-directory)))))
2638       (goto-char (point-min))
2639       (setq dired-subdir-alist nil)
2640       (while (re-search-forward dired-subdir-regexp nil t)
2641         ;; Avoid taking a file name ending in a colon
2642         ;; as a subdir name.
2643         (unless (save-excursion
2644                   (goto-char (match-beginning 0))
2645                   (beginning-of-line)
2646                   (forward-char 2)
2647                   (looking-at-p dired-re-perms))
2648           (save-excursion
2649             (goto-char (match-beginning 1))
2650             (setq new-dir-name
2651                   (buffer-substring-no-properties (point) (match-end 1))
2652                   new-dir-name
2653                   (save-match-data
2654                     (if (and R-ftp-base-dir-regex
2655                              (not (string= new-dir-name default-directory))
2656                              (string-match R-ftp-base-dir-regex new-dir-name))
2657                         (concat default-directory
2658                                 (substring new-dir-name (match-end 0)))
2659                       (expand-file-name new-dir-name))))
2660             (delete-region (point) (match-end 1))
2661             (insert new-dir-name))
2662           (setq count (1+ count))
2663           ;; Undo any escaping of newlines and \ by dired-insert-directory.
2664           ;; Convert "n" preceded by odd number of \ to newline, and \\ to \.
2665           (when (and (dired-switches-escape-p switches)
2666                      (string-match-p "\\\\" new-dir-name))
2667             (let (temp res)
2668               (mapc (lambda (char)
2669                       (cond ((equal char ?\\)
2670                              (if temp
2671                                  (setq res (concat res "\\")
2672                                        temp nil)
2673                                (setq temp "\\")))
2674                             ((and temp (equal char ?n))
2675                              (setq res (concat res "\n")
2676                                    temp nil))
2677                             (t
2678                              (setq res (concat res temp (char-to-string char))
2679                                    temp nil))))
2680                     new-dir-name)
2681               (setq new-dir-name res)))
2682           (dired-alist-add-1 new-dir-name
2683            ;; Place a sub directory boundary between lines.
2684            (save-excursion
2685              (goto-char (match-beginning 0))
2686              (beginning-of-line)
2687              (point-marker)))))
2688       (if (and (> count 1) (called-interactively-p 'interactive))
2689           (message "Buffer includes %d directories" count)))
2690     ;; We don't need to sort it because it is in buffer order per
2691     ;; constructionem.  Return new alist:
2692     dired-subdir-alist))
2693
2694 (defun dired-alist-add-1 (dir new-marker)
2695   ;; Add new DIR at NEW-MARKER.  Don't sort.
2696   (setq dired-subdir-alist
2697         (cons (cons (dired-normalize-subdir dir) new-marker)
2698               dired-subdir-alist)))
2699
2700 (defun dired-goto-next-nontrivial-file ()
2701   ;; Position point on first nontrivial file after point.
2702   (dired-goto-next-file);; so there is a file to compare with
2703   (if (stringp dired-trivial-filenames)
2704       (while (and (not (eobp))
2705                   (string-match-p dired-trivial-filenames
2706                                   (file-name-nondirectory
2707                                    (or (dired-get-filename nil t) ""))))
2708         (forward-line 1)
2709         (dired-move-to-filename))))
2710
2711 (defun dired-goto-next-file ()
2712   (let ((max (1- (dired-subdir-max))))
2713     (while (and (not (dired-move-to-filename)) (< (point) max))
2714       (forward-line 1))))
2715
2716 (defun dired-goto-file (file)
2717   "Go to line describing file FILE in this Dired buffer."
2718   ;; Return value of point on success, else nil.
2719   ;; FILE must be an absolute file name.
2720   ;; Loses if FILE contains control chars like "\007" for which ls
2721   ;; either inserts "?" or "\\007" into the buffer, so we won't find
2722   ;; it in the buffer.
2723   (interactive
2724    (prog1                               ; let push-mark display its message
2725        (list (expand-file-name
2726               (read-file-name "Goto file: "
2727                               (dired-current-directory))))
2728      (push-mark)))
2729   (unless (file-name-absolute-p file)
2730     (error "File name `%s' is not absolute" file))
2731   (setq file (directory-file-name file)) ; does no harm if not a directory
2732   (let* ((case-fold-search nil)
2733          (dir (file-name-directory file))
2734          (found (or
2735                  ;; First, look for a listing under the absolute name.
2736                  (save-excursion
2737                    (goto-char (point-min))
2738                    (dired-goto-file-1 file file (point-max)))
2739                  ;; Otherwise, look for it as a relative name.  The
2740                  ;; hair is to get the result of `dired-goto-subdir'
2741                  ;; without calling it if we don't have any subdirs.
2742                  (save-excursion
2743                    (when (if (string= dir (expand-file-name default-directory))
2744                              (goto-char (point-min))
2745                            (and (cdr dired-subdir-alist)
2746                                 (dired-goto-subdir dir)))
2747                      (dired-goto-file-1 (file-name-nondirectory file)
2748                                         file
2749                                         (dired-subdir-max)))))))
2750     ;; Return buffer position, if found.
2751     (if found
2752         (goto-char found))))
2753
2754 (defun dired-goto-file-1 (file full-name limit)
2755   "Advance to the Dired listing labeled by FILE; return its position.
2756 Return nil if the listing is not found.  If FILE contains
2757 characters that would not appear in a Dired buffer, search using
2758 the quoted forms of those characters.
2759
2760 FULL-NAME specifies the actual file name the listing must have,
2761 as returned by `dired-get-filename'.  LIMIT is the search limit."
2762   (let (str)
2763     (setq str (replace-regexp-in-string "\^m" "\\^m"  file nil t))
2764     (setq str (replace-regexp-in-string "\\\\" "\\\\" str nil t))
2765     (and (dired-switches-escape-p dired-actual-switches)
2766          (string-match-p "[ \t\n]" str)
2767          ;; FIXME: to fix this for embedded control characters etc, we
2768          ;; should escape everything that `ls -b' does.
2769          (setq str (replace-regexp-in-string " " "\\ "  str nil t)
2770                str (replace-regexp-in-string "\t" "\\t" str nil t)
2771                str (replace-regexp-in-string "\n" "\\n" str nil t)))
2772     (let ((found nil)
2773           ;; filenames are preceded by SPC, this makes the search faster
2774           ;; (e.g. for the filename "-").
2775           (search-string (concat " " str)))
2776       (while (and (not found)
2777                   (search-forward search-string limit 'move))
2778         ;; Check that we are in the right place.  Match could have
2779         ;; BASE just as initial substring or in permission bits etc.
2780         (if (equal full-name (dired-get-filename nil t))
2781             (setq found (dired-move-to-filename))
2782           (forward-line 1)))
2783       found)))
2784
2785 (defvar dired-find-subdir)
2786
2787 ;; FIXME document whatever dired-x is doing.
2788 (defun dired-initial-position (dirname)
2789   "Where point should go in a new listing of DIRNAME.
2790 Point is assumed to be at the beginning of new subdir line.
2791 It runs the hook `dired-initial-position-hook'."
2792   (end-of-line)
2793   (and (featurep 'dired-x) dired-find-subdir
2794        (dired-goto-subdir dirname))
2795   (if dired-trivial-filenames (dired-goto-next-nontrivial-file))
2796   (run-hooks 'dired-initial-position-hook))
2797 \f
2798 ;; These are hooks which make tree dired work.
2799 ;; They are in this file because other parts of dired need to call them.
2800 ;; But they don't call the rest of tree dired unless there are subdirs loaded.
2801
2802 ;; This function is called for each retrieved filename.
2803 ;; It could stand to be faster, though it's mostly function call
2804 ;; overhead.  Avoiding the function call seems to save about 10% in
2805 ;; dired-get-filename.  Make it a defsubst?
2806 (defun dired-current-directory (&optional localp)
2807   "Return the name of the subdirectory to which this line belongs.
2808 This returns a string with trailing slash, like `default-directory'.
2809 Optional argument means return a file name relative to `default-directory',
2810 in which case the value could be an empty string if `default-directory'
2811 is the directory where the file on this line resides."
2812   (let ((here (point))
2813         (alist (or dired-subdir-alist
2814                    ;; probably because called in a non-dired buffer
2815                    (error "No subdir-alist in %s" (current-buffer))))
2816         elt dir)
2817     (while alist
2818       (setq elt (car alist)
2819             dir (car elt)
2820             ;; use `<=' (not `<') as subdir line is part of subdir
2821             alist (if (<= (dired-get-subdir-min elt) here)
2822                       nil               ; found
2823                     (cdr alist))))
2824     (if localp
2825         (dired-make-relative dir default-directory)
2826       dir)))
2827
2828 ;; Subdirs start at the beginning of their header lines and end just
2829 ;; before the beginning of the next header line (or end of buffer).
2830
2831 (defun dired-subdir-max ()
2832   (save-excursion
2833     (if (or (null (cdr dired-subdir-alist)) (not (dired-next-subdir 1 t t)))
2834         (point-max)
2835       (point))))
2836 \f
2837 ;; Deleting files
2838
2839 (defcustom dired-recursive-deletes 'top
2840   "Whether Dired deletes directories recursively.
2841 If nil, Dired will not delete non-empty directories.
2842 `always' means to delete non-empty directories recursively,
2843 without asking.  This is dangerous!
2844 `top' means to ask for each top-level directory specified by the
2845 Dired deletion command, and delete its subdirectories without
2846 asking.
2847 Any other value means to ask for each directory."
2848   :type '(choice :tag "Delete non-empty directories"
2849                  (const :tag "Yes" always)
2850                  (const :tag "No--only delete empty directories" nil)
2851                  (const :tag "Confirm for each directory" t)
2852                  (const :tag "Confirm for each top directory only" top))
2853   :group 'dired)
2854
2855 ;; Match anything but `.' and `..'.
2856 (defvar dired-re-no-dot "^\\([^.]\\|\\.\\([^.]\\|\\..\\)\\).*")
2857
2858 ;; Delete file, possibly delete a directory and all its files.
2859 ;; This function is useful outside of dired.  One could change its name
2860 ;; to e.g. recursive-delete-file and put it somewhere else.
2861 (defun dired-delete-file (file &optional recursive trash) "\
2862 Delete FILE or directory (possibly recursively if optional RECURSIVE is true.)
2863 RECURSIVE determines what to do with a non-empty directory.  The effect of
2864 its possible values is:
2865
2866   nil           -- do not delete.
2867   `always'      -- delete recursively without asking.
2868   `top'         -- ask for each directory at top level.
2869   Anything else -- ask for each sub-directory.
2870
2871 TRASH non-nil means to trash the file instead of deleting, provided
2872 `delete-by-moving-to-trash' (which see) is non-nil."
2873   ;; This test is equivalent to
2874   ;; (and (file-directory-p fn) (not (file-symlink-p fn)))
2875   ;; but more efficient
2876   (if (not (eq t (car (file-attributes file))))
2877       (delete-file file trash)
2878     (if (and recursive
2879              (directory-files file t dired-re-no-dot) ; Not empty.
2880              (or (eq recursive 'always)
2881                  (yes-or-no-p (format "Recursively %s %s? "
2882                                       (if (and trash
2883                                                delete-by-moving-to-trash)
2884                                           "trash"
2885                                         "delete")
2886                                       (dired-make-relative file)))))
2887         (if (eq recursive 'top) (setq recursive 'always)) ; Don't ask again.
2888       (setq recursive nil))
2889     (delete-directory file recursive trash)))
2890
2891 (defun dired-do-flagged-delete (&optional nomessage)
2892   "In Dired, delete the files flagged for deletion.
2893 If NOMESSAGE is non-nil, we don't display any message
2894 if there are no flagged files.
2895 `dired-recursive-deletes' controls whether deletion of
2896 non-empty directories is allowed."
2897   (interactive)
2898   (let* ((dired-marker-char dired-del-marker)
2899          (regexp (dired-marker-regexp))
2900          case-fold-search)
2901     (if (save-excursion (goto-char (point-min))
2902                         (re-search-forward regexp nil t))
2903         (dired-internal-do-deletions
2904          ;; this can't move point since ARG is nil
2905          (dired-map-over-marks (cons (dired-get-filename) (point))
2906                                nil)
2907          nil t)
2908       (or nomessage
2909           (message "(No deletions requested)")))))
2910
2911 (defun dired-do-delete (&optional arg)
2912   "Delete all marked (or next ARG) files.
2913 `dired-recursive-deletes' controls whether deletion of
2914 non-empty directories is allowed."
2915   ;; This is more consistent with the file marking feature than
2916   ;; dired-do-flagged-delete.
2917   (interactive "P")
2918   (dired-internal-do-deletions
2919    ;; this may move point if ARG is an integer
2920    (dired-map-over-marks (cons (dired-get-filename) (point))
2921                          arg)
2922    arg t))
2923
2924 (defvar dired-deletion-confirmer 'yes-or-no-p) ; or y-or-n-p?
2925
2926 (defun dired-internal-do-deletions (l arg &optional trash)
2927   ;; L is an alist of files to delete, with their buffer positions.
2928   ;; ARG is the prefix arg.
2929   ;; Filenames are absolute.
2930   ;; (car L) *must* be the *last* (bottommost) file in the dired buffer.
2931   ;; That way as changes are made in the buffer they do not shift the
2932   ;; lines still to be changed, so the (point) values in L stay valid.
2933   ;; Also, for subdirs in natural order, a subdir's files are deleted
2934   ;; before the subdir itself - the other way around would not work.
2935   (let* ((files (mapcar (function car) l))
2936          (count (length l))
2937          (succ 0)
2938          (trashing (and trash delete-by-moving-to-trash)))
2939     ;; canonicalize file list for pop up
2940     (setq files (nreverse (mapcar (function dired-make-relative) files)))
2941     (if (dired-mark-pop-up
2942          " *Deletions*" 'delete files dired-deletion-confirmer
2943          (format "%s %s "
2944                  (if trashing "Trash" "Delete")
2945                  (dired-mark-prompt arg files)))
2946         (save-excursion
2947           (let ((progress-reporter
2948                  (make-progress-reporter
2949                   (if trashing "Trashing..." "Deleting...")
2950                   succ count))
2951                 failures) ;; files better be in reverse order for this loop!
2952             (while l
2953               (goto-char (cdr (car l)))
2954               (let ((inhibit-read-only t))
2955                 (condition-case err
2956                     (let ((fn (car (car l))))
2957                       (dired-delete-file fn dired-recursive-deletes trash)
2958                       ;; if we get here, removing worked
2959                       (setq succ (1+ succ))
2960                       (progress-reporter-update progress-reporter succ)
2961                       (dired-fun-in-all-buffers
2962                        (file-name-directory fn) (file-name-nondirectory fn)
2963                        (function dired-delete-entry) fn))
2964                   (error ;; catch errors from failed deletions
2965                    (dired-log "%s\n" err)
2966                    (setq failures (cons (car (car l)) failures)))))
2967               (setq l (cdr l)))
2968             (if (not failures)
2969                 (progress-reporter-done progress-reporter)
2970               (dired-log-summary
2971                (format "%d of %d deletion%s failed"
2972                        (length failures) count
2973                        (dired-plural-s count))
2974                failures))))
2975       (message "(No deletions performed)")))
2976   (dired-move-to-filename))
2977
2978 (defun dired-fun-in-all-buffers (directory file fun &rest args)
2979   ;; In all buffers dired'ing DIRECTORY, run FUN with ARGS.
2980   ;; If the buffer has a wildcard pattern, check that it matches FILE.
2981   ;; (FILE does not include a directory component.)
2982   ;; FILE may be nil, in which case ignore it.
2983   ;; Return list of buffers where FUN succeeded (i.e., returned non-nil).
2984   (let (success-list)
2985     (dolist (buf (dired-buffers-for-dir (expand-file-name directory)
2986                                         file))
2987       (with-current-buffer buf
2988         (if (apply fun args)
2989             (setq success-list (cons (buffer-name buf) success-list)))))
2990     success-list))
2991
2992 ;; Delete the entry for FILE from
2993 (defun dired-delete-entry (file)
2994   (save-excursion
2995     (and (dired-goto-file file)
2996          (let ((inhibit-read-only t))
2997            (delete-region (progn (beginning-of-line) (point))
2998                           (save-excursion (forward-line 1) (point))))))
2999   (dired-clean-up-after-deletion file))
3000
3001 (defvar dired-clean-up-buffers-too)
3002
3003 (defun dired-clean-up-after-deletion (fn)
3004   "Clean up after a deleted file or directory FN.
3005 Removes any expanded subdirectory of deleted directory.
3006 If `dired-x' is loaded and `dired-clean-up-buffers-too' is non-nil,
3007 also offers to kill buffers visiting deleted files and directories."
3008   (save-excursion (and (cdr dired-subdir-alist)
3009                        (dired-goto-subdir fn)
3010                        (dired-kill-subdir)))
3011   ;; Offer to kill buffer of deleted file FN.
3012   (when (and (featurep 'dired-x) dired-clean-up-buffers-too)
3013     (let ((buf (get-file-buffer fn)))
3014       (and buf
3015            (funcall #'y-or-n-p
3016                     (format "Kill buffer of %s, too? "
3017                             (file-name-nondirectory fn)))
3018            (kill-buffer buf)))
3019     (let ((buf-list (dired-buffers-for-dir (expand-file-name fn))))
3020       (and buf-list
3021            (y-or-n-p (format "Kill Dired buffer%s of %s, too? "
3022                              (dired-plural-s (length buf-list))
3023                              (file-name-nondirectory fn)))
3024            (dolist (buf buf-list)
3025              (kill-buffer buf))))))
3026
3027 \f
3028 ;; Confirmation
3029
3030 (defun dired-marker-regexp ()
3031   (concat "^" (regexp-quote (char-to-string dired-marker-char))))
3032
3033 (defun dired-plural-s (count)
3034   (if (= 1 count) "" "s"))
3035
3036 (defun dired-mark-prompt (arg files)
3037   "Return a string suitable for use in a Dired prompt.
3038 ARG is normally the prefix argument for the calling command.
3039 FILES should be a list of file names.
3040
3041 The return value has a form like \"foo.txt\", \"[next 3 files]\",
3042 or \"* [3 files]\"."
3043   ;; distinguish-one-marked can cause the first element to be just t.
3044   (if (eq (car files) t) (setq files (cdr files)))
3045   (let ((count (length files)))
3046     (if (= count 1)
3047         (car files)
3048       ;; more than 1 file:
3049       (if (integerp arg)
3050           ;; abs(arg) = count
3051           ;; Perhaps this is nicer, but it also takes more screen space:
3052           ;;(format "[%s %d files]" (if (> arg 0) "next" "previous")
3053           ;;                        count)
3054           (format "[next %d files]" arg)
3055         (format "%c [%d files]" dired-marker-char count)))))
3056
3057 (defun dired-pop-to-buffer (buf)
3058   "Pop up buffer BUF in a way suitable for Dired."
3059   (declare (obsolete dired-mark-pop-up "24.3"))
3060   (let ((split-window-preferred-function
3061          (lambda (window)
3062            (or (and (let ((split-height-threshold 0))
3063                       (window-splittable-p (selected-window)))
3064                     ;; Try to split the selected window vertically if
3065                     ;; that's possible.  (Bug#1806)
3066                     (split-window-below))
3067                ;; Otherwise, try to split WINDOW sensibly.
3068                (split-window-sensibly window))))
3069         pop-up-frames)
3070     (pop-to-buffer (get-buffer-create buf)))
3071   ;; See Bug#12281.
3072   (set-window-start nil (point-min))
3073   ;; If dired-shrink-to-fit is t, make its window fit its contents.
3074   (when dired-shrink-to-fit
3075     ;; Try to not delete window when we want to display less than
3076     ;; `window-min-height' lines.
3077     (fit-window-to-buffer (get-buffer-window buf) nil 1 nil nil t)))
3078
3079 (defcustom dired-no-confirm nil
3080   "A list of symbols for commands Dired should not confirm, or t.
3081 Command symbols are `byte-compile', `chgrp', `chmod', `chown', `compress',
3082 `copy', `delete', `hardlink', `load', `move', `print', `shell', `symlink',
3083 `touch' and `uncompress'.
3084 If t, confirmation is never needed."
3085   :group 'dired
3086   :type '(choice (const :tag "Confirmation never needed" t)
3087                  (set (const byte-compile) (const chgrp)
3088                       (const chmod) (const chown) (const compress)
3089                       (const copy) (const delete) (const hardlink)
3090                       (const load) (const move) (const print)
3091                       (const shell) (const symlink) (const touch)
3092                       (const uncompress))))
3093
3094 (defun dired-mark-pop-up (buffer-or-name op-symbol files function &rest args)
3095   "Return FUNCTION's result on ARGS after showing which files are marked.
3096 Displays the file names in a window showing a buffer named
3097 BUFFER-OR-NAME; the default name being \" *Marked Files*\".  The
3098 window is not shown if there is just one file, `dired-no-confirm'
3099 is t, or OP-SYMBOL is a member of the list in `dired-no-confirm'.
3100
3101 By default, Dired shrinks the display buffer to fit the marked files.
3102 To disable this, use the Customization interface to add a new rule
3103 to `display-buffer-alist' where condition regexp is \"^ \\*Marked Files\\*$\",
3104 action argument symbol is `window-height' and its value is nil.
3105
3106 FILES is the list of marked files.  It can also be (t FILENAME)
3107 in the case of one marked file, to distinguish that from using
3108 just the current file.
3109
3110 FUNCTION should not manipulate files, just read input (an
3111 argument or confirmation)."
3112   (if (or (eq dired-no-confirm t)
3113           (memq op-symbol dired-no-confirm)
3114           ;; If FILES defaulted to the current line's file.
3115           (= (length files) 1))
3116       (apply function args)
3117     (let ((buffer (get-buffer-create (or buffer-or-name " *Marked Files*")))
3118           ;; Mark *Marked Files* window as softly-dedicated, to prevent
3119           ;; other buffers e.g. *Completions* from reusing it (bug#17554).
3120           (display-buffer-mark-dedicated 'soft))
3121       (with-displayed-buffer-window
3122        buffer
3123        (cons 'display-buffer-below-selected
3124              '((window-height . fit-window-to-buffer)
3125                (preserve-size . (nil . t))))
3126        #'(lambda (window _value)
3127            (with-selected-window window
3128              (unwind-protect
3129                  (apply function args)
3130                (when (window-live-p window)
3131                  (quit-restore-window window 'kill)))))
3132        ;; Handle (t FILE) just like (FILE), here.  That value is
3133        ;; used (only in some cases), to mean just one file that was
3134        ;; marked, rather than the current line file.
3135        (with-current-buffer buffer
3136          (dired-format-columns-of-files
3137           (if (eq (car files) t) (cdr files) files))
3138          (remove-text-properties (point-min) (point-max)
3139                                  '(mouse-face nil help-echo nil)))))))
3140
3141 (defun dired-format-columns-of-files (files)
3142   (let ((beg (point)))
3143     (completion--insert-strings files)
3144     (put-text-property beg (point) 'mouse-face nil)))
3145 \f
3146 ;; Commands to mark or flag file(s) at or near current line.
3147
3148 (defun dired-repeat-over-lines (arg function)
3149   ;; This version skips non-file lines.
3150   (let ((pos (make-marker)))
3151     (beginning-of-line)
3152     (while (and (> arg 0) (not (eobp)))
3153       (setq arg (1- arg))
3154       (beginning-of-line)
3155       (while (and (not (eobp)) (dired-between-files)) (forward-line 1))
3156       (save-excursion
3157         (forward-line 1)
3158         (move-marker pos (1+ (point))))
3159       (save-excursion (funcall function))
3160       ;; Advance to the next line--actually, to the line that *was* next.
3161       ;; (If FUNCTION inserted some new lines in between, skip them.)
3162       (goto-char pos))
3163     (while (and (< arg 0) (not (bobp)))
3164       (setq arg (1+ arg))
3165       (forward-line -1)
3166       (while (and (not (bobp)) (dired-between-files)) (forward-line -1))
3167       (beginning-of-line)
3168       (save-excursion (funcall function)))
3169     (move-marker pos nil)
3170     (dired-move-to-filename)))
3171
3172 (defun dired-between-files ()
3173   ;; This used to be a regexp match of the `total ...' line output by
3174   ;; ls, which is slightly faster, but that is not very robust; notably,
3175   ;; it fails for non-english locales.
3176   (save-excursion (not (dired-move-to-filename))))
3177
3178 (defun dired-next-marked-file (arg &optional wrap opoint)
3179   "Move to the next marked file.
3180 If WRAP is non-nil, wrap around to the beginning of the buffer if
3181 we reach the end."
3182   (interactive "p\np")
3183   (or opoint (setq opoint (point)));; return to where interactively started
3184   (if (if (> arg 0)
3185           (re-search-forward dired-re-mark nil t arg)
3186         (beginning-of-line)
3187         (re-search-backward dired-re-mark nil t (- arg)))
3188       (dired-move-to-filename)
3189     (if (null wrap)
3190         (progn
3191           (goto-char opoint)
3192           (error "No next marked file"))
3193       (message "(Wraparound for next marked file)")
3194       (goto-char (if (> arg 0) (point-min) (point-max)))
3195       (dired-next-marked-file arg nil opoint))))
3196
3197 (defun dired-prev-marked-file (arg &optional wrap)
3198   "Move to the previous marked file.
3199 If WRAP is non-nil, wrap around to the end of the buffer if we
3200 reach the beginning of the buffer."
3201   (interactive "p\np")
3202   (dired-next-marked-file (- arg) wrap))
3203
3204 (defun dired-file-marker (file)
3205   ;; Return FILE's marker, or nil if unmarked.
3206   (save-excursion
3207     (and (dired-goto-file file)
3208          (progn
3209            (beginning-of-line)
3210            (if (not (equal ?\040 (following-char)))
3211                (following-char))))))
3212
3213 (defun dired-mark-files-in-region (start end)
3214   (let ((inhibit-read-only t))
3215     (if (> start end)
3216         (error "start > end"))
3217     (goto-char start)                   ; assumed at beginning of line
3218     (while (< (point) end)
3219       ;; Skip subdir line and following garbage like the `total' line:
3220       (while (and (< (point) end) (dired-between-files))
3221         (forward-line 1))
3222       (if (and (not (looking-at-p dired-re-dot))
3223                (dired-get-filename nil t))
3224           (progn
3225             (delete-char 1)
3226             (insert dired-marker-char)))
3227       (forward-line 1))))
3228
3229 (defun dired-mark (arg &optional interactive)
3230   "Mark the file at point in the Dired buffer.
3231 If the region is active, mark all files in the region.
3232 Otherwise, with a prefix arg, mark files on the next ARG lines.
3233
3234 If on a subdir headerline, mark all its files except `.' and `..'.
3235
3236 Use \\[dired-unmark-all-files] to remove all marks
3237 and \\[dired-unmark] on a subdir to remove the marks in
3238 this subdir."
3239   (interactive (list current-prefix-arg t))
3240   (cond
3241    ;; Mark files in the active region.
3242    ((and interactive (use-region-p))
3243     (save-excursion
3244       (let ((beg (region-beginning))
3245             (end (region-end)))
3246         (dired-mark-files-in-region
3247          (progn (goto-char beg) (line-beginning-position))
3248          (progn (goto-char end) (line-beginning-position))))))
3249    ;; Mark subdir files from the subdir headerline.
3250    ((dired-get-subdir)
3251     (save-excursion (dired-mark-subdir-files)))
3252    ;; Mark the current (or next ARG) files.
3253    (t
3254     (let ((inhibit-read-only t))
3255       (dired-repeat-over-lines
3256        (prefix-numeric-value arg)
3257        (function (lambda () (delete-char 1) (insert dired-marker-char))))))))
3258
3259 (defun dired-unmark (arg &optional interactive)
3260   "Unmark the file at point in the Dired buffer.
3261 If the region is active, unmark all files in the region.
3262 Otherwise, with a prefix arg, unmark files on the next ARG lines.
3263
3264 If looking at a subdir, unmark all its files except `.' and `..'.
3265 If the region is active in Transient Mark mode, unmark all files
3266 in the active region."
3267   (interactive (list current-prefix-arg t))
3268   (let ((dired-marker-char ?\040))
3269     (dired-mark arg interactive)))
3270
3271 (defun dired-flag-file-deletion (arg &optional interactive)
3272   "In Dired, flag the current line's file for deletion.
3273 If the region is active, flag all files in the region.
3274 Otherwise, with a prefix arg, flag files on the next ARG lines.
3275
3276 If on a subdir headerline, flag all its files except `.' and `..'.
3277 If the region is active in Transient Mark mode, flag all files
3278 in the active region."
3279   (interactive (list current-prefix-arg t))
3280   (let ((dired-marker-char dired-del-marker))
3281     (dired-mark arg interactive)))
3282
3283 (defun dired-unmark-backward (arg)
3284   "In Dired, move up lines and remove marks or deletion flags there.
3285 Optional prefix ARG says how many lines to unmark/unflag; default
3286 is one line.
3287 If the region is active in Transient Mark mode, unmark all files
3288 in the active region."
3289   (interactive "p")
3290   (dired-unmark (- arg)))
3291
3292 (defun dired-toggle-marks ()
3293   "Toggle marks: marked files become unmarked, and vice versa.
3294 Files marked with other flags (such as `D') are not affected.
3295 `.' and `..' are never toggled.
3296 As always, hidden subdirs are not affected."
3297   (interactive)
3298   (save-excursion
3299     (goto-char (point-min))
3300     (let ((inhibit-read-only t))
3301       (while (not (eobp))
3302         (or (dired-between-files)
3303             (looking-at-p dired-re-dot)
3304             ;; use subst instead of insdel because it does not move
3305             ;; the gap and thus should be faster and because
3306             ;; other characters are left alone automatically
3307             (apply 'subst-char-in-region
3308                    (point) (1+ (point))
3309                    (if (eq ?\040 (following-char)) ; SPC
3310                        (list ?\040 dired-marker-char)
3311                      (list dired-marker-char ?\040))))
3312         (forward-line 1)))))
3313 \f
3314 ;;; Commands to mark or flag files based on their characteristics or names.
3315
3316 (defvar dired-regexp-history nil
3317   "History list of regular expressions used in Dired commands.")
3318
3319 (defun dired-read-regexp (prompt &optional default history)
3320   "Read a regexp using `read-regexp'."
3321   (declare (obsolete read-regexp "24.5"))
3322   (read-regexp prompt default (or history 'dired-regexp-history)))
3323
3324 (defun dired-mark-files-regexp (regexp &optional marker-char)
3325   "Mark all files matching REGEXP for use in later commands.
3326 A prefix argument means to unmark them instead.
3327 `.' and `..' are never marked.
3328
3329 REGEXP is an Emacs regexp, not a shell wildcard.  Thus, use `\\.o$' for
3330 object files--just `.o' will mark more than you might think."
3331   (interactive
3332    (list (read-regexp (concat (if current-prefix-arg "Unmark" "Mark")
3333                               " files (regexp): ")
3334                       nil 'dired-regexp-history)
3335          (if current-prefix-arg ?\040)))
3336   (let ((dired-marker-char (or marker-char dired-marker-char)))
3337     (dired-mark-if
3338      (and (not (looking-at-p dired-re-dot))
3339           (not (eolp))                  ; empty line
3340           (let ((fn (dired-get-filename t t)))
3341             (and fn (string-match-p regexp fn))))
3342      "matching file")))
3343
3344 (defun dired-mark-files-containing-regexp (regexp &optional marker-char)
3345   "Mark all files with contents containing REGEXP for use in later commands.
3346 A prefix argument means to unmark them instead.
3347 `.' and `..' are never marked."
3348   (interactive
3349    (list (read-regexp (concat (if current-prefix-arg "Unmark" "Mark")
3350                               " files containing (regexp): ")
3351                       nil 'dired-regexp-history)
3352          (if current-prefix-arg ?\040)))
3353   (let ((dired-marker-char (or marker-char dired-marker-char)))
3354     (dired-mark-if
3355      (and (not (looking-at-p dired-re-dot))
3356           (not (eolp))                  ; empty line
3357           (let ((fn (dired-get-filename nil t)))
3358             (when (and fn (file-readable-p fn)
3359                        (not (file-directory-p fn)))
3360               (let ((prebuf (get-file-buffer fn)))
3361                 (message "Checking %s" fn)
3362                 ;; For now we do it inside emacs
3363                 ;; Grep might be better if there are a lot of files
3364                 (if prebuf
3365                     (with-current-buffer prebuf
3366                       (save-excursion
3367                         (goto-char (point-min))
3368                         (re-search-forward regexp nil t)))
3369                   (with-temp-buffer
3370                     (insert-file-contents fn)
3371                     (goto-char (point-min))
3372                     (re-search-forward regexp nil t))))
3373                       )))
3374      "matching file")))
3375
3376 (defun dired-flag-files-regexp (regexp)
3377   "In Dired, flag all files containing the specified REGEXP for deletion.
3378 The match is against the non-directory part of the filename.  Use `^'
3379   and `$' to anchor matches.  Exclude subdirs by hiding them.
3380 `.' and `..' are never flagged."
3381   (interactive (list (read-regexp "Flag for deletion (regexp): "
3382                                   nil 'dired-regexp-history)))
3383   (dired-mark-files-regexp regexp dired-del-marker))
3384
3385 (defun dired-mark-symlinks (unflag-p)
3386   "Mark all symbolic links.
3387 With prefix argument, unmark or unflag all those files."
3388   (interactive "P")
3389   (let ((dired-marker-char (if unflag-p ?\040 dired-marker-char)))
3390     (dired-mark-if (looking-at-p dired-re-sym) "symbolic link")))
3391
3392 (defun dired-mark-directories (unflag-p)
3393   "Mark all directory file lines except `.' and `..'.
3394 With prefix argument, unmark or unflag all those files."
3395   (interactive "P")
3396   (let ((dired-marker-char (if unflag-p ?\040 dired-marker-char)))
3397     (dired-mark-if (and (looking-at-p dired-re-dir)
3398                         (not (looking-at-p dired-re-dot)))
3399                    "directory file")))
3400
3401 (defun dired-mark-executables (unflag-p)
3402   "Mark all executable files.
3403 With prefix argument, unmark or unflag all those files."
3404   (interactive "P")
3405   (let ((dired-marker-char (if unflag-p ?\040 dired-marker-char)))
3406     (dired-mark-if (looking-at-p dired-re-exe) "executable file")))
3407
3408 ;; dired-x.el has a dired-mark-sexp interactive command: mark
3409 ;; files for which PREDICATE returns non-nil.
3410
3411 (defun dired-flag-auto-save-files (&optional unflag-p)
3412   "Flag for deletion files whose names suggest they are auto save files.
3413 A prefix argument says to unmark or unflag those files instead."
3414   (interactive "P")
3415   (let ((dired-marker-char (if unflag-p ?\040 dired-del-marker)))
3416     (dired-mark-if
3417      ;; It is less than general to check for # here,
3418      ;; but it's the only way this runs fast enough.
3419      (and (save-excursion (end-of-line)
3420                           (or
3421                            (eq (preceding-char) ?#)
3422                            ;; Handle executables in case of -F option.
3423                            ;; We need not worry about the other kinds
3424                            ;; of markings that -F makes, since they won't
3425                            ;; appear on real auto-save files.
3426                            (if (eq (preceding-char) ?*)
3427                                (progn
3428                                  (forward-char -1)
3429                                  (eq (preceding-char) ?#)))))
3430           (not (looking-at-p dired-re-dir))
3431           (let ((fn (dired-get-filename t t)))
3432             (if fn (auto-save-file-name-p
3433                     (file-name-nondirectory fn)))))
3434      "auto save file")))
3435
3436 (defcustom dired-garbage-files-regexp
3437   ;; `log' here is dubious, since it's typically used for useful log
3438   ;; files, not just TeX stuff.  -- fx
3439   (concat (regexp-opt
3440            '(".log" ".toc" ".dvi" ".bak" ".orig" ".rej" ".aux"))
3441           "\\'")
3442   "Regular expression to match \"garbage\" files for `dired-flag-garbage-files'."
3443   :type 'regexp
3444   :group 'dired)
3445
3446 (defun dired-flag-garbage-files ()
3447   "Flag for deletion all files that match `dired-garbage-files-regexp'."
3448   (interactive)
3449   (dired-flag-files-regexp dired-garbage-files-regexp))
3450
3451 (defun dired-flag-backup-files (&optional unflag-p)
3452   "Flag all backup files (names ending with `~') for deletion.
3453 With prefix argument, unmark or unflag these files."
3454   (interactive "P")
3455   (let ((dired-marker-char (if unflag-p ?\s dired-del-marker)))
3456     (dired-mark-if
3457      ;; Don't call backup-file-name-p unless the last character looks like
3458      ;; it might be the end of a backup file name.  This isn't very general,
3459      ;; but it's the only way this runs fast enough.
3460      (and (save-excursion (end-of-line)
3461                           ;; Handle executables in case of -F option.
3462                           ;; We need not worry about the other kinds
3463                           ;; of markings that -F makes, since they won't
3464                           ;; appear on real backup files.
3465                           (if (eq (preceding-char) ?*)
3466                               (forward-char -1))
3467                           (eq (preceding-char) ?~))
3468           (not (looking-at-p dired-re-dir))
3469           (let ((fn (dired-get-filename t t)))
3470             (if fn (backup-file-name-p fn))))
3471      "backup file")))
3472
3473 (defun dired-change-marks (&optional old new)
3474   "Change all OLD marks to NEW marks.
3475 OLD and NEW are both characters used to mark files."
3476   (interactive
3477    (let* ((cursor-in-echo-area t)
3478           (old (progn (message "Change (old mark): ") (read-char)))
3479           (new (progn (message  "Change %c marks to (new mark): " old)
3480                       (read-char))))
3481      (list old new)))
3482   (if (or (eq old ?\r) (eq new ?\r))
3483       (ding)
3484     (let ((string (format "\n%c" old))
3485           (inhibit-read-only t))
3486       (save-excursion
3487         (goto-char (point-min))
3488         (while (search-forward string nil t)
3489           (if (if (= old ?\s)
3490                   (save-match-data
3491                     (dired-get-filename 'no-dir t))
3492                 t)
3493               (subst-char-in-region (match-beginning 0)
3494                                     (match-end 0) old new)))))))
3495
3496 (defun dired-unmark-all-marks ()
3497   "Remove all marks from all files in the Dired buffer."
3498   (interactive)
3499   (dired-unmark-all-files ?\r))
3500
3501 ;; Bound in dired-unmark-all-files
3502 (defvar dired-unmark-all-files-query)
3503
3504 (defun dired-unmark-all-files (mark &optional arg)
3505   "Remove a specific mark (or any mark) from every file.
3506 After this command, type the mark character to remove,
3507 or type RET to remove all marks.
3508 With prefix arg, query for each marked file.
3509 Type \\[help-command] at that time for help."
3510   (interactive "cRemove marks (RET means all): \nP")
3511   (save-excursion
3512     (let* ((count 0)
3513            (inhibit-read-only t) case-fold-search
3514            dired-unmark-all-files-query
3515            (string (format "\n%c" mark))
3516            (help-form "\
3517 Type SPC or `y' to unmark one file, DEL or `n' to skip to next,
3518 `!' to unmark all remaining files with no more questions."))
3519       (goto-char (point-min))
3520       (while (if (eq mark ?\r)
3521                  (re-search-forward dired-re-mark nil t)
3522                (search-forward string nil t))
3523         (if (or (not arg)
3524                 (let ((file (dired-get-filename t t)))
3525                   (and file
3526                        (dired-query 'dired-unmark-all-files-query
3527                                     "Unmark file `%s'? "
3528                                     file))))
3529             (progn (subst-char-in-region (1- (point)) (point)
3530                                          (preceding-char) ?\s)
3531                    (setq count (1+ count)))))
3532       (message (if (= count 1) "1 mark removed"
3533                  "%d marks removed")
3534                count))))
3535 \f
3536 ;; Logging failures operating on files, and showing the results.
3537
3538 (defvar dired-log-buffer "*Dired log*")
3539
3540 (defun dired-why ()
3541   "Pop up a buffer with error log output from Dired.
3542 A group of errors from a single command ends with a formfeed.
3543 Thus, use \\[backward-page] to find the beginning of a group of errors."
3544   (interactive)
3545   (if (get-buffer dired-log-buffer)
3546       (let ((owindow (selected-window))
3547             (window (display-buffer (get-buffer dired-log-buffer))))
3548         (unwind-protect
3549             (progn
3550               (select-window window)
3551               (goto-char (point-max))
3552               (forward-line -1)
3553               (backward-page 1)
3554               (recenter 0))
3555           (select-window owindow)))))
3556
3557 (defun dired-log (log &rest args)
3558   ;; Log a message or the contents of a buffer.
3559   ;; If LOG is a string and there are more args, it is formatted with
3560   ;; those ARGS.  Usually the LOG string ends with a \n.
3561   ;; End each bunch of errors with (dired-log t):
3562   ;; this inserts the current time and buffer at the start of the page,
3563   ;; and \f (formfeed) at the end.
3564   (let ((obuf (current-buffer)))
3565     (with-current-buffer (get-buffer-create dired-log-buffer)
3566       (goto-char (point-max))
3567       (let ((inhibit-read-only t))
3568         (cond ((stringp log)
3569                (insert (if args
3570                            (apply #'format-message log args)
3571                          log)))
3572               ((bufferp log)
3573                (insert-buffer-substring log))
3574               ((eq t log)
3575                (backward-page 1)
3576                (unless (bolp)
3577                  (insert "\n"))
3578                (insert (current-time-string)
3579                        (format-message "\tBuffer `%s'\n" (buffer-name obuf)))
3580                (goto-char (point-max))
3581                (insert "\f\n")))))))
3582
3583 (defun dired-log-summary (string failures)
3584   "State a summary of a command's failures, in echo area and log buffer.
3585 STRING is an overall summary of the failures.
3586 FAILURES is a list of file names that we failed to operate on,
3587 or nil if file names are not applicable."
3588   (if (= (length failures) 1)
3589       (message "%s"
3590                (with-current-buffer dired-log-buffer
3591                  (goto-char (point-max))
3592                  (backward-page 1)
3593                  (if (eolp) (forward-line 1))
3594                  (buffer-substring (point) (point-max))))
3595     (message (if failures "%s--type ? for details (%s)"
3596                "%s--type ? for details")
3597              string failures))
3598   ;; Log a summary describing a bunch of errors.
3599   (dired-log (concat "\n" string "\n"))
3600   (dired-log t))
3601 \f
3602 ;;; Sorting
3603
3604 ;; Most ls can only sort by name or by date (with -t), nothing else.
3605 ;; GNU ls sorts on size with -S, on extension with -X, and unsorted with -U.
3606 ;; So anything that does not contain these is sort "by name".
3607
3608 (defvar dired-ls-sorting-switches "SXU"
3609   "String of `ls' switches (single letters) except \"t\" that influence sorting.
3610
3611 This indicates to Dired which option switches to watch out for because they
3612 will change the sorting order behavior of `ls'.
3613
3614 To change the default sorting order (e.g. add a `-v' option), see the
3615 variable `dired-listing-switches'.  To temporarily override the listing
3616 format, use `\\[universal-argument] \\[dired]'.")
3617
3618 (defvar dired-sort-by-date-regexp
3619   (concat "\\(\\`\\| \\)-[^- ]*t"
3620           ;; `dired-ls-sorting-switches' after -t overrides -t.
3621           "[^ " dired-ls-sorting-switches "]*"
3622           "\\(\\(\\`\\| +\\)\\(--[^ ]+\\|-[^- t"
3623           dired-ls-sorting-switches "]+\\)\\)* *$")
3624   "Regexp recognized by Dired to set `by date' mode.")
3625
3626 (defvar dired-sort-by-name-regexp
3627   (concat "\\`\\(\\(\\`\\| +\\)\\(--[^ ]+\\|"
3628           "-[^- t" dired-ls-sorting-switches "]+\\)\\)* *$")
3629   "Regexp recognized by Dired to set `by name' mode.")
3630
3631 (defvar dired-sort-inhibit nil
3632   "Non-nil means the Dired sort command is disabled.
3633 The idea is to set this buffer-locally in special Dired buffers.")
3634
3635 (defun dired-sort-set-mode-line ()
3636   ;; Set mode line display according to dired-actual-switches.
3637   ;; Mode line display of "by name" or "by date" guarantees the user a
3638   ;; match with the corresponding regexps.  Non-matching switches are
3639   ;; shown literally.
3640   (when (eq major-mode 'dired-mode)
3641     (setq mode-name
3642           (let (case-fold-search)
3643             (cond ((string-match-p
3644                     dired-sort-by-name-regexp dired-actual-switches)
3645                    "Dired by name")
3646                   ((string-match-p
3647                     dired-sort-by-date-regexp dired-actual-switches)
3648                    "Dired by date")
3649                   (t
3650                    (concat "Dired " dired-actual-switches)))))
3651     (force-mode-line-update)))
3652
3653 (define-obsolete-function-alias 'dired-sort-set-modeline
3654   'dired-sort-set-mode-line "24.3")
3655
3656 (defun dired-sort-toggle-or-edit (&optional arg)
3657   "Toggle sorting by date, and refresh the Dired buffer.
3658 With a prefix argument, edit the current listing switches instead."
3659   (interactive "P")
3660   (when dired-sort-inhibit
3661     (error "Cannot sort this Dired buffer"))
3662   (if arg
3663       (dired-sort-other
3664        (read-string "ls switches (must contain -l): " dired-actual-switches))
3665     (dired-sort-toggle)))
3666
3667 (defun dired-sort-toggle ()
3668   ;; Toggle between sort by date/name.  Reverts the buffer.
3669   (let ((sorting-by-date (string-match-p dired-sort-by-date-regexp
3670                                          dired-actual-switches))
3671         ;; Regexp for finding (possibly embedded) -t switches.
3672         (switch-regexp "\\(\\`\\| \\)-\\([a-su-zA-Z]*\\)\\(t\\)\\([^ ]*\\)")
3673         case-fold-search)
3674     ;; Remove the -t switch.
3675     (while (string-match switch-regexp dired-actual-switches)
3676       (if (and (equal (match-string 2 dired-actual-switches) "")
3677                (equal (match-string 4 dired-actual-switches) ""))
3678           ;; Remove a stand-alone -t switch.
3679           (setq dired-actual-switches
3680                 (replace-match "" t t dired-actual-switches))
3681         ;; Remove a switch of the form -XtY for some X and Y.
3682         (setq dired-actual-switches
3683               (replace-match "" t t dired-actual-switches 3))))
3684
3685     ;; Now, if we weren't sorting by date before, add the -t switch.
3686     ;; Some simple-minded ls implementations (eg ftp servers) only
3687     ;; allow a single option string, so try not to add " -t" if possible.
3688     (unless sorting-by-date
3689       (setq dired-actual-switches
3690             (concat dired-actual-switches
3691                     (if (string-match-p "\\`-[[:alnum:]]+\\'"
3692                                         dired-actual-switches)
3693                         "t"
3694                       " -t")))))
3695   (dired-sort-set-mode-line)
3696   (revert-buffer))
3697
3698 ;; Some user code loads dired especially for this.
3699 ;; Don't do that--use replace-regexp-in-string instead.
3700 (defun dired-replace-in-string (regexp newtext string)
3701   ;; Replace REGEXP with NEWTEXT everywhere in STRING and return result.
3702   ;; NEWTEXT is taken literally---no \\DIGIT escapes will be recognized.
3703   (let ((result "") (start 0) mb me)
3704     (while (string-match regexp string start)
3705       (setq mb (match-beginning 0)
3706             me (match-end 0)
3707             result (concat result (substring string start mb) newtext)
3708             start me))
3709     (concat result (substring string start))))
3710
3711 (defun dired-sort-other (switches &optional no-revert)
3712   "Specify new `ls' SWITCHES for current Dired buffer.
3713 Values matching `dired-sort-by-date-regexp' or `dired-sort-by-name-regexp'
3714 set the minor mode accordingly, others appear literally in the mode line.
3715 With optional second arg NO-REVERT, don't refresh the listing afterwards."
3716   (dired-sort-R-check switches)
3717   (setq dired-actual-switches switches)
3718   (dired-sort-set-mode-line)
3719   (or no-revert (revert-buffer)))
3720
3721 (defvar-local dired-subdir-alist-pre-R nil
3722   "Value of `dired-subdir-alist' before -R switch added.")
3723
3724 (defun dired-sort-R-check (switches)
3725   "Additional processing of -R in ls option string SWITCHES.
3726 Saves `dired-subdir-alist' when R is set and restores saved value
3727 minus any directories explicitly deleted when R is cleared.
3728 To be called first in body of `dired-sort-other', etc."
3729   (cond
3730    ((and (dired-switches-recursive-p switches)
3731          (not (dired-switches-recursive-p dired-actual-switches)))
3732     ;; Adding -R to ls switches -- save `dired-subdir-alist':
3733     (setq dired-subdir-alist-pre-R dired-subdir-alist))
3734    ((and (dired-switches-recursive-p dired-actual-switches)
3735          (not (dired-switches-recursive-p switches)))
3736     ;; Deleting -R from ls switches -- revert to pre-R subdirs
3737     ;; that are still present:
3738     (setq dired-subdir-alist
3739           (if dired-subdir-alist-pre-R
3740               (let (subdirs)
3741                 (while dired-subdir-alist-pre-R
3742                   (if (assoc (caar dired-subdir-alist-pre-R)
3743                              dired-subdir-alist)
3744                       ;; subdir still present...
3745                       (setq subdirs
3746                             (cons (car dired-subdir-alist-pre-R)
3747                                   subdirs)))
3748                   (setq dired-subdir-alist-pre-R
3749                         (cdr dired-subdir-alist-pre-R)))
3750                 (reverse subdirs))
3751             ;; No pre-R subdir alist, so revert to main directory
3752             ;; listing:
3753             (list (car (reverse dired-subdir-alist))))))))
3754 \f
3755
3756 ;;;;  Drag and drop support
3757
3758 (defcustom dired-recursive-copies 'top
3759   "Whether Dired copies directories recursively.
3760 If nil, never copy recursively.
3761 `always' means to copy recursively without asking.
3762 `top' means to ask for each directory at top level.
3763 Any other value means to ask for each directory."
3764   :type '(choice :tag "Copy directories"
3765                  (const :tag "No recursive copies" nil)
3766                  (const :tag "Ask for each directory" t)
3767                  (const :tag "Ask for each top directory only" top)
3768                  (const :tag "Copy directories without asking" always))
3769   :group 'dired)
3770
3771 (defun dired-dnd-popup-notice ()
3772   (message-box
3773    "Dired recursive copies are currently disabled.\nSee the variable `dired-recursive-copies'."))
3774
3775 (declare-function x-popup-menu "menu.c" (position menu))
3776
3777 (defun dired-dnd-do-ask-action (uri)
3778   ;; No need to get actions and descriptions from the source,
3779   ;; we only have three actions anyway.
3780   (let ((action (x-popup-menu
3781                  t
3782                  (list "What action?"
3783                        (cons ""
3784                              '(("Copy here" . copy)
3785                                ("Move here" . move)
3786                                ("Link here" . link)
3787                                "--"
3788                                ("Cancel" . nil)))))))
3789     (if action
3790         (dired-dnd-handle-local-file uri action)
3791       nil)))
3792
3793 (declare-function dired-relist-entry "dired-aux" (file))
3794 (declare-function make-symbolic-link "fileio.c")
3795
3796 ;; Only used when (featurep 'dnd).
3797 (declare-function dnd-get-local-file-name "dnd" (uri &optional must-exist))
3798 (declare-function dnd-get-local-file-uri "dnd" (uri))
3799
3800 (defvar dired-overwrite-confirmed)      ;Defined in dired-aux.
3801
3802 (defun dired-dnd-handle-local-file (uri action)
3803   "Copy, move or link a file to the Dired directory.
3804 URI is the file to handle, ACTION is one of copy, move, link or ask.
3805 Ask means pop up a menu for the user to select one of copy, move or link."
3806   (require 'dired-aux)
3807   (let* ((from (dnd-get-local-file-name uri t))
3808          (to (when from
3809                (concat (dired-current-directory)
3810                        (file-name-nondirectory from)))))
3811     (when from
3812       (cond ((eq action 'ask)
3813              (dired-dnd-do-ask-action uri))
3814             ;; If copying a directory and dired-recursive-copies is
3815             ;; nil, dired-copy-file fails.  Pop up a notice.
3816             ((and (memq action '(copy private))
3817                   (file-directory-p from)
3818                   (not dired-recursive-copies))
3819              (dired-dnd-popup-notice))
3820             ((memq action '(copy private move link))
3821              (let ((overwrite (and (file-exists-p to)
3822                                    (y-or-n-p
3823                                     (format-message
3824                                      "Overwrite existing file `%s'? " to))))
3825                    ;; Binding dired-overwrite-confirmed to nil makes
3826                    ;; dired-handle-overwrite a no-op.  We instead use
3827                    ;; y-or-n-p, which pops a graphical menu.
3828                    dired-overwrite-confirmed backup-file)
3829                (when (and overwrite
3830                           ;; d-b-o is defined in dired-aux.
3831                           (boundp 'dired-backup-overwrite)
3832                           dired-backup-overwrite
3833                           (setq backup-file
3834                                 (car (find-backup-file-name to)))
3835                           (or (eq dired-backup-overwrite 'always)
3836                               (y-or-n-p
3837                                (format-message
3838                                 "Make backup for existing file `%s'? " to))))
3839                  (rename-file to backup-file 0)
3840                  (dired-relist-entry backup-file))
3841                (cond ((memq action '(copy private))
3842                       (dired-copy-file from to overwrite))
3843                      ((eq action 'move)
3844                       (dired-rename-file from to overwrite))
3845                      ((eq action 'link)
3846                       (make-symbolic-link from to overwrite)))
3847                (dired-relist-entry to)
3848                action))))))
3849
3850 (defun dired-dnd-handle-file (uri action)
3851   "Copy, move or link a file to the Dired directory if it is a local file.
3852 URI is the file to handle.  If the hostname in the URI isn't local, do nothing.
3853 ACTION is one of copy, move, link or ask.
3854 Ask means pop up a menu for the user to select one of copy, move or link."
3855   (let ((local-file (dnd-get-local-file-uri uri)))
3856     (if local-file (dired-dnd-handle-local-file local-file action)
3857       nil)))
3858 \f
3859
3860 ;;;;  Desktop support
3861
3862 (eval-when-compile (require 'desktop))
3863 (declare-function desktop-file-name "desktop" (filename dirname))
3864
3865 (defun dired-desktop-buffer-misc-data (dirname)
3866   "Auxiliary information to be saved in desktop file."
3867   (cons
3868    ;; Value of `dired-directory'.
3869    (if (consp dired-directory)
3870        ;; Directory name followed by list of files.
3871        (cons (desktop-file-name (car dired-directory) dirname)
3872              (cdr dired-directory))
3873      ;; Directory name, optionally with shell wildcard.
3874      (desktop-file-name dired-directory dirname))
3875    ;; Subdirectories in `dired-subdir-alist'.
3876    (cdr
3877      (nreverse
3878        (mapcar
3879          (function (lambda (f) (desktop-file-name (car f) dirname)))
3880          dired-subdir-alist)))))
3881
3882 (defun dired-restore-desktop-buffer (_file-name
3883                                      _buffer-name
3884                                      misc-data)
3885   "Restore a Dired buffer specified in a desktop file."
3886   ;; First element of `misc-data' is the value of `dired-directory'.
3887   ;; This value is a directory name, optionally with shell wildcard or
3888   ;; a directory name followed by list of files.
3889   (let* ((dired-dir (car misc-data))
3890          (dir (if (consp dired-dir) (car dired-dir) dired-dir)))
3891     (if (file-directory-p (file-name-directory dir))
3892         (with-demoted-errors "Desktop: Problem restoring directory: %S"
3893           (dired dired-dir)
3894           ;; The following elements of `misc-data' are the keys
3895           ;; from `dired-subdir-alist'.
3896           (mapc 'dired-maybe-insert-subdir (cdr misc-data))
3897           (current-buffer))
3898       (message "Desktop: Directory %s no longer exists." dir)
3899       (when desktop-missing-file-warning (sit-for 1))
3900       nil)))
3901
3902 (add-to-list 'desktop-buffer-mode-handlers
3903              '(dired-mode . dired-restore-desktop-buffer))
3904
3905 \f
3906 ;;; Start of automatically extracted autoloads.
3907 \f
3908 ;;;### (autoloads nil "dired-aux" "dired-aux.el" "17b411edeac40022109eb6f705b83079")
3909 ;;; Generated autoloads from dired-aux.el
3910
3911 (autoload 'dired-diff "dired-aux" "\
3912 Compare file at point with file FILE using `diff'.
3913 If called interactively, prompt for FILE.  If the file at point
3914 has a backup file, use that as the default.  If the file at point
3915 is a backup file, use its original.  If the mark is active
3916 in Transient Mark mode, use the file at the mark as the default.
3917 \(That's the mark set by \\[set-mark-command], not by Dired's
3918 \\[dired-mark] command.)
3919
3920 FILE is the first file given to `diff'.  The file at point
3921 is the second file given to `diff'.
3922
3923 With prefix arg, prompt for second argument SWITCHES, which is
3924 the string of command switches for the third argument of `diff'.
3925
3926 \(fn FILE &optional SWITCHES)" t nil)
3927
3928 (autoload 'dired-backup-diff "dired-aux" "\
3929 Diff this file with its backup file or vice versa.
3930 Uses the latest backup, if there are several numerical backups.
3931 If this file is a backup, diff it with its original.
3932 The backup file is the first file given to `diff'.
3933 With prefix arg, prompt for argument SWITCHES which is options for `diff'.
3934
3935 \(fn &optional SWITCHES)" t nil)
3936
3937 (autoload 'dired-compare-directories "dired-aux" "\
3938 Mark files with different file attributes in two dired buffers.
3939 Compare file attributes of files in the current directory
3940 with file attributes in directory DIR2 using PREDICATE on pairs of files
3941 with the same name.  Mark files for which PREDICATE returns non-nil.
3942 Mark files with different names if PREDICATE is nil (or interactively
3943 with empty input at the predicate prompt).
3944
3945 PREDICATE is a Lisp expression that can refer to the following variables:
3946
3947     size1, size2   - file size in bytes
3948     mtime1, mtime2 - last modification time in seconds, as a float
3949     fa1, fa2       - list of file attributes
3950                      returned by function `file-attributes'
3951
3952     where 1 refers to attribute of file in the current dired buffer
3953     and 2 to attribute of file in second dired buffer.
3954
3955 Examples of PREDICATE:
3956
3957     (> mtime1 mtime2) - mark newer files
3958     (not (= size1 size2)) - mark files with different sizes
3959     (not (string= (nth 8 fa1) (nth 8 fa2))) - mark files with different modes
3960     (not (and (= (nth 2 fa1) (nth 2 fa2))   - mark files with different UID
3961               (= (nth 3 fa1) (nth 3 fa2))))   and GID.
3962
3963 \(fn DIR2 PREDICATE)" t nil)
3964
3965 (autoload 'dired-do-chmod "dired-aux" "\
3966 Change the mode of the marked (or next ARG) files.
3967 Symbolic modes like `g+w' are allowed.
3968 Type M-n to pull the file attributes of the file at point
3969 into the minibuffer.
3970
3971 \(fn &optional ARG)" t nil)
3972
3973 (autoload 'dired-do-chgrp "dired-aux" "\
3974 Change the group of the marked (or next ARG) files.
3975 Type M-n to pull the file attributes of the file at point
3976 into the minibuffer.
3977
3978 \(fn &optional ARG)" t nil)
3979
3980 (autoload 'dired-do-chown "dired-aux" "\
3981 Change the owner of the marked (or next ARG) files.
3982 Type M-n to pull the file attributes of the file at point
3983 into the minibuffer.
3984
3985 \(fn &optional ARG)" t nil)
3986
3987 (autoload 'dired-do-touch "dired-aux" "\
3988 Change the timestamp of the marked (or next ARG) files.
3989 This calls touch.
3990 Type M-n to pull the file attributes of the file at point
3991 into the minibuffer.
3992
3993 \(fn &optional ARG)" t nil)
3994
3995 (autoload 'dired-do-print "dired-aux" "\
3996 Print the marked (or next ARG) files.
3997 Uses the shell command coming from variables `lpr-command' and
3998 `lpr-switches' as default.
3999
4000 \(fn &optional ARG)" t nil)
4001
4002 (autoload 'dired-clean-directory "dired-aux" "\
4003 Flag numerical backups for deletion.
4004 Spares `dired-kept-versions' latest versions, and `kept-old-versions' oldest.
4005 Positive prefix arg KEEP overrides `dired-kept-versions';
4006 Negative prefix arg KEEP overrides `kept-old-versions' with KEEP made positive.
4007
4008 To clear the flags on these files, you can use \\[dired-flag-backup-files]
4009 with a prefix argument.
4010
4011 \(fn KEEP)" t nil)
4012
4013 (autoload 'dired-do-async-shell-command "dired-aux" "\
4014 Run a shell command COMMAND on the marked files asynchronously.
4015
4016 Like `dired-do-shell-command', but adds `&' at the end of COMMAND
4017 to execute it asynchronously.
4018
4019 When operating on multiple files, asynchronous commands
4020 are executed in the background on each file in parallel.
4021 In shell syntax this means separating the individual commands
4022 with `&'.  However, when COMMAND ends in `;' or `;&' then commands
4023 are executed in the background on each file sequentially waiting
4024 for each command to terminate before running the next command.
4025 In shell syntax this means separating the individual commands with `;'.
4026
4027 The output appears in the buffer `*Async Shell Command*'.
4028
4029 \(fn COMMAND &optional ARG FILE-LIST)" t nil)
4030
4031 (autoload 'dired-do-shell-command "dired-aux" "\
4032 Run a shell command COMMAND on the marked files.
4033 If no files are marked or a numeric prefix arg is given,
4034 the next ARG files are used.  Just \\[universal-argument] means the current file.
4035 The prompt mentions the file(s) or the marker, as appropriate.
4036
4037 If there is a `*' in COMMAND, surrounded by whitespace, this runs
4038 COMMAND just once with the entire file list substituted there.
4039
4040 If there is no `*', but there is a `?' in COMMAND, surrounded by
4041 whitespace, this runs COMMAND on each file individually with the
4042 file name substituted for `?'.
4043
4044 Otherwise, this runs COMMAND on each file individually with the
4045 file name added at the end of COMMAND (separated by a space).
4046
4047 `*' and `?' when not surrounded by whitespace have no special
4048 significance for `dired-do-shell-command', and are passed through
4049 normally to the shell, but you must confirm first.
4050
4051 If you want to use `*' as a shell wildcard with whitespace around
4052 it, write `*\"\"' in place of just `*'.  This is equivalent to just
4053 `*' in the shell, but avoids Dired's special handling.
4054
4055 If COMMAND ends in `&', `;', or `;&', it is executed in the
4056 background asynchronously, and the output appears in the buffer
4057 `*Async Shell Command*'.  When operating on multiple files and COMMAND
4058 ends in `&', the shell command is executed on each file in parallel.
4059 However, when COMMAND ends in `;' or `;&' then commands are executed
4060 in the background on each file sequentially waiting for each command
4061 to terminate before running the next command.  You can also use
4062 `dired-do-async-shell-command' that automatically adds `&'.
4063
4064 Otherwise, COMMAND is executed synchronously, and the output
4065 appears in the buffer `*Shell Command Output*'.
4066
4067 This feature does not try to redisplay Dired buffers afterward, as
4068 there's no telling what files COMMAND may have changed.
4069 Type \\[dired-do-redisplay] to redisplay the marked files.
4070
4071 When COMMAND runs, its working directory is the top-level directory
4072 of the Dired buffer, so output files usually are created there
4073 instead of in a subdir.
4074
4075 In a noninteractive call (from Lisp code), you must specify
4076 the list of file names explicitly with the FILE-LIST argument, which
4077 can be produced by `dired-get-marked-files', for example.
4078
4079 \(fn COMMAND &optional ARG FILE-LIST)" t nil)
4080
4081 (autoload 'dired-run-shell-command "dired-aux" "\
4082
4083
4084 \(fn COMMAND)" nil nil)
4085
4086 (autoload 'dired-do-kill-lines "dired-aux" "\
4087 Kill all marked lines (not the files).
4088 With a prefix argument, kill that many lines starting with the current line.
4089 \(A negative argument kills backward.)
4090 If you use this command with a prefix argument to kill the line
4091 for a file that is a directory, which you have inserted in the
4092 Dired buffer as a subdirectory, then it deletes that subdirectory
4093 from the buffer as well.
4094 To kill an entire subdirectory (without killing its line in the
4095 parent directory), go to its directory header line and use this
4096 command with a prefix argument (the value does not matter).
4097
4098 \(fn &optional ARG FMT)" t nil)
4099
4100 (autoload 'dired-do-compress-to "dired-aux" "\
4101 Compress selected files and directories to an archive.
4102 You are prompted for the archive name.
4103 The archiving command is chosen based on the archive name extension and
4104 `dired-compress-files-alist'.
4105
4106 \(fn)" t nil)
4107
4108 (autoload 'dired-compress-file "dired-aux" "\
4109 Compress or uncompress FILE.
4110 Return the name of the compressed or uncompressed file.
4111 Return nil if no change in files.
4112
4113 \(fn FILE)" nil nil)
4114
4115 (autoload 'dired-query "dired-aux" "\
4116 Format PROMPT with ARGS, query user, and store the result in SYM.
4117 The return value is either nil or t.
4118
4119 The user may type y or SPC to accept once; n or DEL to skip once;
4120 ! to accept this and subsequent queries; or q or ESC to decline
4121 this and subsequent queries.
4122
4123 If SYM is already bound to a non-nil value, this function may
4124 return automatically without querying the user.  If SYM is !,
4125 return t; if SYM is q or ESC, return nil.
4126
4127 \(fn SYM PROMPT &rest ARGS)" nil nil)
4128
4129 (autoload 'dired-do-compress "dired-aux" "\
4130 Compress or uncompress marked (or next ARG) files.
4131
4132 \(fn &optional ARG)" t nil)
4133
4134 (autoload 'dired-do-byte-compile "dired-aux" "\
4135 Byte compile marked (or next ARG) Emacs Lisp files.
4136
4137 \(fn &optional ARG)" t nil)
4138
4139 (autoload 'dired-do-load "dired-aux" "\
4140 Load the marked (or next ARG) Emacs Lisp files.
4141
4142 \(fn &optional ARG)" t nil)
4143
4144 (autoload 'dired-do-redisplay "dired-aux" "\
4145 Redisplay all marked (or next ARG) files.
4146 If on a subdir line, redisplay that subdirectory.  In that case,
4147 a prefix arg lets you edit the `ls' switches used for the new listing.
4148
4149 Dired remembers switches specified with a prefix arg, so that reverting
4150 the buffer will not reset them.  However, using `dired-undo' to re-insert
4151 or delete subdirectories can bypass this machinery.  Hence, you sometimes
4152 may have to reset some subdirectory switches after a `dired-undo'.
4153 You can reset all subdirectory switches to the default using
4154 \\<dired-mode-map>\\[dired-reset-subdir-switches].
4155 See Info node `(emacs)Subdir switches' for more details.
4156
4157 \(fn &optional ARG TEST-FOR-SUBDIR)" t nil)
4158
4159 (autoload 'dired-add-file "dired-aux" "\
4160
4161
4162 \(fn FILENAME &optional MARKER-CHAR)" nil nil)
4163
4164 (autoload 'dired-remove-file "dired-aux" "\
4165
4166
4167 \(fn FILE)" nil nil)
4168
4169 (autoload 'dired-relist-file "dired-aux" "\
4170 Create or update the line for FILE in all Dired buffers it would belong in.
4171
4172 \(fn FILE)" nil nil)
4173
4174 (autoload 'dired-copy-file "dired-aux" "\
4175
4176
4177 \(fn FROM TO OK-FLAG)" nil nil)
4178
4179 (autoload 'dired-rename-file "dired-aux" "\
4180
4181
4182 \(fn FILE NEWNAME OK-IF-ALREADY-EXISTS)" nil nil)
4183
4184 (autoload 'dired-create-directory "dired-aux" "\
4185 Create a directory called DIRECTORY.
4186 If DIRECTORY already exists, signal an error.
4187
4188 \(fn DIRECTORY)" t nil)
4189
4190 (autoload 'dired-do-copy "dired-aux" "\
4191 Copy all marked (or next ARG) files, or copy the current file.
4192 When operating on just the current file, prompt for the new name.
4193
4194 When operating on multiple or marked files, prompt for a target
4195 directory, and make the new copies in that directory, with the
4196 same names as the original files.  The initial suggestion for the
4197 target directory is the Dired buffer's current directory (or, if
4198 `dired-dwim-target' is non-nil, the current directory of a
4199 neighboring Dired window).
4200
4201 If `dired-copy-preserve-time' is non-nil, this command preserves
4202 the modification time of each old file in the copy, similar to
4203 the \"-p\" option for the \"cp\" shell command.
4204
4205 This command copies symbolic links by creating new ones, similar
4206 to the \"-d\" option for the \"cp\" shell command.
4207
4208 \(fn &optional ARG)" t nil)
4209
4210 (autoload 'dired-do-symlink "dired-aux" "\
4211 Make symbolic links to current file or all marked (or next ARG) files.
4212 When operating on just the current file, you specify the new name.
4213 When operating on multiple or marked files, you specify a directory
4214 and new symbolic links are made in that directory
4215 with the same names that the files currently have.  The default
4216 suggested for the target directory depends on the value of
4217 `dired-dwim-target', which see.
4218
4219 For relative symlinks, use \\[dired-do-relsymlink].
4220
4221 \(fn &optional ARG)" t nil)
4222
4223 (autoload 'dired-do-hardlink "dired-aux" "\
4224 Add names (hard links) current file or all marked (or next ARG) files.
4225 When operating on just the current file, you specify the new name.
4226 When operating on multiple or marked files, you specify a directory
4227 and new hard links are made in that directory
4228 with the same names that the files currently have.  The default
4229 suggested for the target directory depends on the value of
4230 `dired-dwim-target', which see.
4231
4232 \(fn &optional ARG)" t nil)
4233
4234 (autoload 'dired-do-rename "dired-aux" "\
4235 Rename current file or all marked (or next ARG) files.
4236 When renaming just the current file, you specify the new name.
4237 When renaming multiple or marked files, you specify a directory.
4238 This command also renames any buffers that are visiting the files.
4239 The default suggested for the target directory depends on the value
4240 of `dired-dwim-target', which see.
4241
4242 \(fn &optional ARG)" t nil)
4243
4244 (autoload 'dired-do-rename-regexp "dired-aux" "\
4245 Rename selected files whose names match REGEXP to NEWNAME.
4246
4247 With non-zero prefix argument ARG, the command operates on the next ARG
4248 files.  Otherwise, it operates on all the marked files, or the current
4249 file if none are marked.
4250
4251 As each match is found, the user must type a character saying
4252   what to do with it.  For directions, type \\[help-command] at that time.
4253 NEWNAME may contain \\=\\<n> or \\& as in `query-replace-regexp'.
4254 REGEXP defaults to the last regexp used.
4255
4256 With a zero prefix arg, renaming by regexp affects the absolute file name.
4257 Normally, only the non-directory part of the file name is used and changed.
4258
4259 \(fn REGEXP NEWNAME &optional ARG WHOLE-NAME)" t nil)
4260
4261 (autoload 'dired-do-copy-regexp "dired-aux" "\
4262 Copy selected files whose names match REGEXP to NEWNAME.
4263 See function `dired-do-rename-regexp' for more info.
4264
4265 \(fn REGEXP NEWNAME &optional ARG WHOLE-NAME)" t nil)
4266
4267 (autoload 'dired-do-hardlink-regexp "dired-aux" "\
4268 Hardlink selected files whose names match REGEXP to NEWNAME.
4269 See function `dired-do-rename-regexp' for more info.
4270
4271 \(fn REGEXP NEWNAME &optional ARG WHOLE-NAME)" t nil)
4272
4273 (autoload 'dired-do-symlink-regexp "dired-aux" "\
4274 Symlink selected files whose names match REGEXP to NEWNAME.
4275 See function `dired-do-rename-regexp' for more info.
4276
4277 \(fn REGEXP NEWNAME &optional ARG WHOLE-NAME)" t nil)
4278
4279 (autoload 'dired-upcase "dired-aux" "\
4280 Rename all marked (or next ARG) files to upper case.
4281
4282 \(fn &optional ARG)" t nil)
4283
4284 (autoload 'dired-downcase "dired-aux" "\
4285 Rename all marked (or next ARG) files to lower case.
4286
4287 \(fn &optional ARG)" t nil)
4288
4289 (autoload 'dired-maybe-insert-subdir "dired-aux" "\
4290 Insert this subdirectory into the same dired buffer.
4291 If it is already present, just move to it (type \\[dired-do-redisplay] to refresh),
4292   else inserts it at its natural place (as `ls -lR' would have done).
4293 With a prefix arg, you may edit the ls switches used for this listing.
4294   You can add `R' to the switches to expand the whole tree starting at
4295   this subdirectory.
4296 This function takes some pains to conform to `ls -lR' output.
4297
4298 Dired remembers switches specified with a prefix arg, so that reverting
4299 the buffer will not reset them.  However, using `dired-undo' to re-insert
4300 or delete subdirectories can bypass this machinery.  Hence, you sometimes
4301 may have to reset some subdirectory switches after a `dired-undo'.
4302 You can reset all subdirectory switches to the default using
4303 \\<dired-mode-map>\\[dired-reset-subdir-switches].
4304 See Info node `(emacs)Subdir switches' for more details.
4305
4306 \(fn DIRNAME &optional SWITCHES NO-ERROR-IF-NOT-DIR-P)" t nil)
4307
4308 (autoload 'dired-insert-subdir "dired-aux" "\
4309 Insert this subdirectory into the same Dired buffer.
4310 If it is already present, overwrite the previous entry;
4311   otherwise, insert it at its natural place (as `ls -lR' would
4312   have done).
4313 With a prefix arg, you may edit the `ls' switches used for this listing.
4314   You can add `R' to the switches to expand the whole tree starting at
4315   this subdirectory.
4316 This function takes some pains to conform to `ls -lR' output.
4317
4318 \(fn DIRNAME &optional SWITCHES NO-ERROR-IF-NOT-DIR-P)" t nil)
4319
4320 (autoload 'dired-prev-subdir "dired-aux" "\
4321 Go to previous subdirectory, regardless of level.
4322 When called interactively and not on a subdir line, go to this subdir's line.
4323
4324 \(fn ARG &optional NO-ERROR-IF-NOT-FOUND NO-SKIP)" t nil)
4325
4326 (autoload 'dired-goto-subdir "dired-aux" "\
4327 Go to end of header line of DIR in this dired buffer.
4328 Return value of point on success, otherwise return nil.
4329 The next char is either \\n, or \\r if DIR is hidden.
4330
4331 \(fn DIR)" t nil)
4332
4333 (autoload 'dired-mark-subdir-files "dired-aux" "\
4334 Mark all files except `.' and `..' in current subdirectory.
4335 If the Dired buffer shows multiple directories, this command
4336 marks the files listed in the subdirectory that point is in.
4337
4338 \(fn)" t nil)
4339
4340 (autoload 'dired-kill-subdir "dired-aux" "\
4341 Remove all lines of current subdirectory.
4342 Lower levels are unaffected.
4343
4344 \(fn &optional REMEMBER-MARKS)" t nil)
4345
4346 (autoload 'dired-tree-up "dired-aux" "\
4347 Go up ARG levels in the dired tree.
4348
4349 \(fn ARG)" t nil)
4350
4351 (autoload 'dired-tree-down "dired-aux" "\
4352 Go down in the dired tree.
4353
4354 \(fn)" t nil)
4355
4356 (autoload 'dired-hide-subdir "dired-aux" "\
4357 Hide or unhide the current subdirectory and move to next directory.
4358 Optional prefix arg is a repeat factor.
4359 Use \\[dired-hide-all] to (un)hide all directories.
4360
4361 \(fn ARG)" t nil)
4362
4363 (autoload 'dired-hide-all "dired-aux" "\
4364 Hide all subdirectories, leaving only their header lines.
4365 If there is already something hidden, make everything visible again.
4366 Use \\[dired-hide-subdir] to (un)hide a particular subdirectory.
4367
4368 \(fn &optional IGNORED)" t nil)
4369
4370 (autoload 'dired-isearch-filenames-setup "dired-aux" "\
4371 Set up isearch to search in Dired file names.
4372 Intended to be added to `isearch-mode-hook'.
4373
4374 \(fn)" nil nil)
4375
4376 (autoload 'dired-isearch-filenames "dired-aux" "\
4377 Search for a string using Isearch only in file names in the Dired buffer.
4378
4379 \(fn)" t nil)
4380
4381 (autoload 'dired-isearch-filenames-regexp "dired-aux" "\
4382 Search for a regexp using Isearch only in file names in the Dired buffer.
4383
4384 \(fn)" t nil)
4385
4386 (autoload 'dired-do-isearch "dired-aux" "\
4387 Search for a string through all marked files using Isearch.
4388
4389 \(fn)" t nil)
4390
4391 (autoload 'dired-do-isearch-regexp "dired-aux" "\
4392 Search for a regexp through all marked files using Isearch.
4393
4394 \(fn)" t nil)
4395
4396 (autoload 'dired-do-search "dired-aux" "\
4397 Search through all marked files for a match for REGEXP.
4398 Stops when a match is found.
4399 To continue searching for next match, use command \\[tags-loop-continue].
4400
4401 \(fn REGEXP)" t nil)
4402
4403 (autoload 'dired-do-query-replace-regexp "dired-aux" "\
4404 Do `query-replace-regexp' of FROM with TO, on all marked files.
4405 Third arg DELIMITED (prefix arg) means replace only word-delimited matches.
4406 If you exit (\\[keyboard-quit], RET or q), you can resume the query replace
4407 with the command \\[tags-loop-continue].
4408
4409 \(fn FROM TO &optional DELIMITED)" t nil)
4410
4411 (autoload 'dired-do-find-regexp "dired-aux" "\
4412 Find all matches for REGEXP in all marked files, recursively.
4413
4414 \(fn REGEXP)" t nil)
4415
4416 (autoload 'dired-do-find-regexp-and-replace "dired-aux" "\
4417 Replace matches of FROM with TO, in all marked files, recursively.
4418
4419 \(fn FROM TO)" t nil)
4420
4421 (autoload 'dired-show-file-type "dired-aux" "\
4422 Print the type of FILE, according to the `file' command.
4423 If you give a prefix to this command, and FILE is a symbolic
4424 link, then the type of the file linked to by FILE is printed
4425 instead.
4426
4427 \(fn FILE &optional DEREF-SYMLINKS)" t nil)
4428
4429 ;;;***
4430 \f
4431 ;;;### (autoloads nil "dired-x" "dired-x.el" "8dae922d1549647835460b6cb70af4df")
4432 ;;; Generated autoloads from dired-x.el
4433
4434 (autoload 'dired-jump "dired-x" "\
4435 Jump to Dired buffer corresponding to current buffer.
4436 If in a file, Dired the current directory and move to file's line.
4437 If in Dired already, pop up a level and goto old directory's line.
4438 In case the proper Dired file line cannot be found, refresh the dired
4439 buffer and try again.
4440 When OTHER-WINDOW is non-nil, jump to Dired buffer in other window.
4441 Interactively with prefix argument, read FILE-NAME and
4442 move to its line in dired.
4443
4444 \(fn &optional OTHER-WINDOW FILE-NAME)" t nil)
4445
4446 (autoload 'dired-jump-other-window "dired-x" "\
4447 Like \\[dired-jump] (`dired-jump') but in other window.
4448
4449 \(fn &optional FILE-NAME)" t nil)
4450
4451 (autoload 'dired-do-relsymlink "dired-x" "\
4452 Relative symlink all marked (or next ARG) files into a directory.
4453 Otherwise make a relative symbolic link to the current file.
4454 This creates relative symbolic links like
4455
4456     foo -> ../bar/foo
4457
4458 not absolute ones like
4459
4460     foo -> /ugly/file/name/that/may/change/any/day/bar/foo
4461
4462 For absolute symlinks, use \\[dired-do-symlink].
4463
4464 \(fn &optional ARG)" t nil)
4465
4466 ;;;***
4467 \f
4468 ;;; End of automatically extracted autoloads.
4469
4470 (provide 'dired)
4471
4472 (run-hooks 'dired-load-hook)            ; for your customizations
4473
4474 ;;; dired.el ends here