code.delx.au - gnu-emacs/blob - test/automated/vc-tests.el

   1 ;;; vc-tests.el --- Tests of different backends of vc.el
   2
   3 ;; Copyright (C) 2014-2016 Free Software Foundation, Inc.
   4
   5 ;; Author: Michael Albinus <michael.albinus@gmx.de>
   6
   7 ;; This program is free software: you can redistribute it and/or
   8 ;; modify it under the terms of the GNU General Public License as
   9 ;; published by the Free Software Foundation, either version 3 of the
  10 ;; License, or (at your option) any later version.
  11 ;;
  12 ;; This program is distributed in the hope that it will be useful, but
  13 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15 ;; General Public License for more details.
  16 ;;
  17 ;; You should have received a copy of the GNU General Public License
  18 ;; along with this program.  If not, see `http://www.gnu.org/licenses/'.
  19
  20 ;;; Commentary:
  21
  22 ;; For every supported VC on the machine, different test cases are
  23 ;; generated automatically.
  24
  25 ;; Functions to be tested (see Commentary of vc.el).  Mandatory
  26 ;; functions are marked with `*', optional functions are marked with `-':
  27
  28 ;; BACKEND PROPERTIES
  29 ;;
  30 ;; * revision-granularity                                       DONE
  31
  32 ;; STATE-QUERYING FUNCTIONS
  33 ;;
  34 ;; * registered (file)                                          DONE
  35 ;; * state (file)                                               DONE
  36 ;; - dir-status (dir update-function)
  37 ;; - dir-status-files (dir files default-state update-function)
  38 ;; - dir-extra-headers (dir)
  39 ;; - dir-printer (fileinfo)
  40 ;; - status-fileinfo-extra (file)
  41 ;; * working-revision (file)                                    DONE
  42 ;; - latest-on-branch-p (file)
  43 ;; * checkout-model (files)                                     DONE
  44 ;; - mode-line-string (file)
  45
  46 ;; STATE-CHANGING FUNCTIONS
  47 ;;
  48 ;; * create-repo (backend)                                      DONE
  49 ;; * register (files &optional comment)                         DONE
  50 ;; - responsible-p (file)
  51 ;; - receive-file (file rev)
  52 ;; - unregister (file)                                          DONE
  53 ;; * checkin (files comment)
  54 ;; * find-revision (file rev buffer)
  55 ;; * checkout (file &optional rev)
  56 ;; * revert (file &optional contents-done)
  57 ;; - rollback (files)
  58 ;; - merge-file (file rev1 rev2)
  59 ;; - merge-branch ()
  60 ;; - merge-news (file)
  61 ;; - pull (prompt)
  62 ;; - steal-lock (file &optional revision)
  63 ;; - modify-change-comment (files rev comment)
  64 ;; - mark-resolved (files)
  65 ;; - find-admin-dir (file)
  66
  67 ;; HISTORY FUNCTIONS
  68 ;;
  69 ;; * print-log (files buffer &optional shortlog start-revision limit)
  70 ;; * log-outgoing (backend remote-location)
  71 ;; * log-incoming (backend remote-location)
  72 ;; - log-view-mode ()
  73 ;; - show-log-entry (revision)
  74 ;; - comment-history (file)
  75 ;; - update-changelog (files)
  76 ;; * diff (files &optional async rev1 rev2 buffer)
  77 ;; - revision-completion-table (files)
  78 ;; - annotate-command (file buf &optional rev)
  79 ;; - annotate-time ()
  80 ;; - annotate-current-time ()
  81 ;; - annotate-extract-revision-at-line ()
  82 ;; - region-history (FILE BUFFER LFROM LTO)
  83 ;; - region-history-mode ()
  84
  85 ;; TAG SYSTEM
  86 ;;
  87 ;; - create-tag (dir name branchp)
  88 ;; - retrieve-tag (dir name update)
  89
  90 ;; MISCELLANEOUS
  91 ;;
  92 ;; - make-version-backups-p (file)
  93 ;; - root (file)
  94 ;; - ignore (file &optional directory)
  95 ;; - ignore-completion-table
  96 ;; - previous-revision (file rev)
  97 ;; - next-revision (file rev)
  98 ;; - log-edit-mode ()
  99 ;; - check-headers ()
 100 ;; - delete-file (file)
 101 ;; - rename-file (old new)
 102 ;; - find-file-hook ()
 103 ;; - extra-menu ()
 104 ;; - extra-dir-menu ()
 105 ;; - conflicted-files (dir)
 106
 107 ;;; Code:
 108
 109 (require 'ert)
 110 (require 'vc)
 111
 112 ;; The working horses.
 113
 114 (defvar vc-test--cleanup-hook nil
 115   "Functions for cleanup at the end of an ert test.
 116 Don't set it globally, the functions shall be let-bound.")
 117
 118 (defun vc-test--revision-granularity-function (backend)
 119   "Run the `vc-revision-granularity' backend function."
 120   (funcall (intern (downcase (format "vc-%s-revision-granularity" backend)))))
 121
 122 (defun vc-test--create-repo-function (backend)
 123   "Run the `vc-create-repo' backend function.
 124 For backends which dont support it, it is emulated."
 125
 126   (cond
 127    ((eq backend 'CVS)
 128     (let ((tmp-dir
 129            (expand-file-name
 130             (make-temp-name "vc-test") temporary-file-directory)))
 131       (make-directory (expand-file-name "module" tmp-dir) 'parents)
 132       (make-directory (expand-file-name "CVSROOT" tmp-dir) 'parents)
 133       (if (not (fboundp 'w32-application-type))
 134           (shell-command-to-string (format "cvs -Q -d:local:%s co module"
 135                                            tmp-dir))
 136         (let ((cvs-prog (executable-find "cvs"))
 137               (tdir tmp-dir))
 138           ;; If CVS executable is an MSYS program, reformat the file
 139           ;; name of TMP-DIR to have the /d/foo/bar form supported by
 140           ;; MSYS programs.  (FIXME: What about Cygwin cvs.exe?)
 141           (if (eq (w32-application-type cvs-prog) 'msys)
 142               (setq tdir
 143                     (concat "/" (substring tmp-dir 0 1) (substring tmp-dir 2))))
 144           (shell-command-to-string (format "cvs -Q -d:local:%s co module"
 145                                            tdir))))
 146       (rename-file "module/CVS" default-directory)
 147       (delete-directory "module" 'recursive)
 148       ;; We must cleanup the "remote" CVS repo as well.
 149       (add-hook 'vc-test--cleanup-hook
 150                 `(lambda () (delete-directory ,tmp-dir 'recursive)))))
 151
 152    ((eq backend 'Arch)
 153     (let ((archive-name (format "%s--%s" user-mail-address (random))))
 154       (when (string-match
 155              "no arch user id set" (shell-command-to-string "tla my-id"))
 156         (shell-command-to-string
 157          (format "tla my-id \"<%s>\"" user-mail-address)))
 158       (shell-command-to-string
 159        (format "tla make-archive %s %s" archive-name default-directory))
 160       (shell-command-to-string
 161        (format "tla my-default-archive %s" archive-name))))
 162
 163    ((eq backend 'Mtn)
 164     (let ((archive-name "foo.mtn"))
 165       (shell-command-to-string
 166        (format
 167         "mtn db init --db=%s"
 168         (expand-file-name archive-name default-directory)))
 169       (shell-command-to-string
 170        (format "mtn --db=%s --branch=foo setup ." archive-name))))
 171
 172    (t (vc-create-repo backend))))
 173
 174 (defun vc-test--create-repo (backend)
 175   "Create a test repository in `default-directory', a temporary directory."
 176
 177   (let ((vc-handled-backends `(,backend))
 178         (default-directory
 179           (file-name-as-directory
 180            (expand-file-name
 181             (make-temp-name "vc-test") temporary-file-directory)))
 182         vc-test--cleanup-hook)
 183
 184     (unwind-protect
 185         (progn
 186           ;; Cleanup.
 187           (add-hook
 188            'vc-test--cleanup-hook
 189            `(lambda () (delete-directory ,default-directory 'recursive)))
 190
 191           ;; Check the revision granularity.
 192           (should (memq (vc-test--revision-granularity-function backend)
 193                         '(file repository)))
 194
 195           ;; Create empty repository.
 196           (make-directory default-directory)
 197           (should (file-directory-p default-directory))
 198           (vc-test--create-repo-function backend)
 199           (should (eq (vc-responsible-backend default-directory) backend)))
 200
 201       ;; Save exit.
 202       (ignore-errors (run-hooks 'vc-test--cleanup-hook)))))
 203
 204 ;; Why isn't there `vc-unregister'?
 205 (defun vc-test--unregister-function (backend file)
 206   "Run the `vc-unregister' backend function.
 207 For backends which dont support it, `vc-not-supported' is signalled."
 208
 209   (let ((symbol (intern (downcase (format "vc-%s-unregister" backend)))))
 210     (if (functionp symbol)
 211         (funcall symbol file)
 212       ;; CVS, SVN, SCCS, SRC and Mtn are not supported.
 213       (signal 'vc-not-supported (list 'unregister backend)))))
 214
 215 (defun vc-test--register (backend)
 216   "Register and unregister a file."
 217
 218   (let ((vc-handled-backends `(,backend))
 219         (default-directory
 220           (file-name-as-directory
 221            (expand-file-name
 222             (make-temp-name "vc-test") temporary-file-directory)))
 223         vc-test--cleanup-hook)
 224
 225     (unwind-protect
 226         (progn
 227           ;; Cleanup.
 228           (add-hook
 229            'vc-test--cleanup-hook
 230            `(lambda () (delete-directory ,default-directory 'recursive)))
 231
 232           ;; Create empty repository.
 233           (make-directory default-directory)
 234           (vc-test--create-repo-function backend)
 235
 236           (let ((tmp-name1 (expand-file-name "foo" default-directory))
 237                 (tmp-name2 "bla"))
 238             ;; Register files.  Check for it.
 239             (write-region "foo" nil tmp-name1 nil 'nomessage)
 240             (should (file-exists-p tmp-name1))
 241             (should-not (vc-registered tmp-name1))
 242             (write-region "bla" nil tmp-name2 nil 'nomessage)
 243             (should (file-exists-p tmp-name2))
 244             (should-not (vc-registered tmp-name2))
 245             (vc-register (list backend (list tmp-name1 tmp-name2)))
 246             (should (file-exists-p tmp-name1))
 247             (should (vc-registered tmp-name1))
 248             (should (file-exists-p tmp-name2))
 249             (should (vc-registered tmp-name2))
 250
 251             ;; Unregister the files.
 252             (condition-case err
 253                 (progn
 254                   (vc-test--unregister-function backend tmp-name1)
 255                   (should-not (vc-registered tmp-name1))
 256                   (vc-test--unregister-function backend tmp-name2)
 257                   (should-not (vc-registered tmp-name2)))
 258               ;; CVS, SVN, SCCS, SRC and Mtn are not supported.
 259               (vc-not-supported t))
 260             ;; The files shall still exist.
 261             (should (file-exists-p tmp-name1))
 262             (should (file-exists-p tmp-name2))))
 263
 264       ;; Save exit.
 265       (ignore-errors (run-hooks 'vc-test--cleanup-hook)))))
 266
 267 (defun vc-test--state (backend)
 268   "Check the different states of a file."
 269
 270   (let ((vc-handled-backends `(,backend))
 271         (default-directory
 272           (file-name-as-directory
 273            (expand-file-name
 274             (make-temp-name "vc-test") temporary-file-directory)))
 275         vc-test--cleanup-hook)
 276
 277     (unwind-protect
 278         (progn
 279           ;; Cleanup.
 280           (add-hook
 281            'vc-test--cleanup-hook
 282            `(lambda () (delete-directory ,default-directory 'recursive)))
 283
 284           ;; Create empty repository.  Check repository state.
 285           (make-directory default-directory)
 286           (vc-test--create-repo-function backend)
 287
 288           ;; nil: Hg Mtn RCS
 289           ;; added: Git
 290           ;; unregistered: CVS SCCS SRC
 291           ;; up-to-date: Bzr SVN
 292           (message "vc-state1 %s" (vc-state default-directory))
 293           ;;(should (eq (vc-state default-directory)
 294                       ;;(vc-state default-directory backend)))
 295           (should (memq (vc-state default-directory)
 296                         '(nil added unregistered up-to-date)))
 297
 298           (let ((tmp-name (expand-file-name "foo" default-directory)))
 299             ;; Check state of an empty file.
 300
 301             ;; nil: Hg Mtn SRC SVN
 302             ;; added: Git
 303             ;; unregistered: RCS SCCS
 304             ;; up-to-date: Bzr CVS
 305             (message "vc-state2 %s" (vc-state tmp-name))
 306             ;;(should (eq (vc-state tmp-name) (vc-state tmp-name backend)))
 307             (should (memq (vc-state tmp-name)
 308                           '(nil added unregistered up-to-date)))
 309
 310             ;; Write a new file.  Check state.
 311             (write-region "foo" nil tmp-name nil 'nomessage)
 312
 313             ;; nil: Mtn
 314             ;; added: Git
 315             ;; unregistered: Hg RCS SCCS SRC SVN
 316             ;; up-to-date: Bzr CVS
 317             (message "vc-state3 %s" (vc-state tmp-name))
 318             ;;(should (eq (vc-state tmp-name) (vc-state tmp-name backend)))
 319             (should (memq (vc-state tmp-name)
 320                           '(nil added unregistered up-to-date)))
 321
 322             ;; Register a file.  Check state.
 323             (vc-register
 324              (list backend (list (file-name-nondirectory tmp-name))))
 325
 326             ;; added: Git Mtn
 327             ;; unregistered: Hg RCS SCCS SRC SVN
 328             ;; up-to-date: Bzr CVS
 329             (message "vc-state4 %s" (vc-state tmp-name))
 330             ;;(should (eq (vc-state tmp-name) (vc-state tmp-name backend)))
 331             (should (memq (vc-state tmp-name)
 332                           '(nil added unregistered up-to-date)))
 333
 334             ;; Unregister the file.  Check state.
 335             (condition-case nil
 336                 (progn
 337                   (vc-test--unregister-function backend tmp-name)
 338
 339                   ;; added: Git
 340                   ;; unregistered: Hg RCS
 341                   ;; unsupported: CVS Mtn SCCS SRC SVN
 342                   ;; up-to-date: Bzr
 343                   (message "vc-state5 %s" (vc-state tmp-name))
 344                   ;;(should (eq (vc-state tmp-name) (vc-state tmp-name backend)))
 345                   (should (memq (vc-state tmp-name)
 346                                 '(nil added unregistered up-to-date))))
 347               (vc-not-supported (message "vc-state5 unsupported")))))
 348
 349       ;; Save exit.
 350       (ignore-errors (run-hooks 'vc-test--cleanup-hook)))))
 351
 352 (defun vc-test--working-revision (backend)
 353   "Check the working revision of a repository."
 354
 355   (let ((vc-handled-backends `(,backend))
 356         (default-directory
 357           (file-name-as-directory
 358            (expand-file-name
 359             (make-temp-name "vc-test") temporary-file-directory)))
 360         vc-test--cleanup-hook)
 361
 362     (unwind-protect
 363         (progn
 364           ;; Cleanup.
 365           (add-hook
 366            'vc-test--cleanup-hook
 367            `(lambda () (delete-directory ,default-directory 'recursive)))
 368
 369           ;; Create empty repository.  Check working revision of
 370           ;; repository, should be nil.
 371           (make-directory default-directory)
 372           (vc-test--create-repo-function backend)
 373
 374           ;; nil: CVS Git Mtn RCS SCCS
 375           ;; "0": Bzr Hg SRC SVN
 376           (message
 377            "vc-working-revision1 %s" (vc-working-revision default-directory))
 378           ;;(should (eq (vc-working-revision default-directory)
 379                       ;;(vc-working-revision default-directory backend)))
 380           (should (member (vc-working-revision default-directory) '(nil "0")))
 381
 382           (let ((tmp-name (expand-file-name "foo" default-directory)))
 383             ;; Check initial working revision, should be nil until
 384             ;; it's registered.
 385
 386             ;; nil: CVS Git Mtn RCS SCCS SVN
 387             ;; "0": Bzr Hg SRC
 388             (message "vc-working-revision2 %s" (vc-working-revision tmp-name))
 389             ;;(should (eq (vc-working-revision tmp-name)
 390                         ;;(vc-working-revision tmp-name backend)))
 391             (should (member (vc-working-revision tmp-name) '(nil "0")))
 392
 393             ;; Write a new file.  Check working revision.
 394             (write-region "foo" nil tmp-name nil 'nomessage)
 395
 396             ;; nil: CVS Git Mtn RCS SCCS SVN
 397             ;; "0": Bzr Hg SRC
 398             (message "vc-working-revision3 %s" (vc-working-revision tmp-name))
 399             ;;(should (eq (vc-working-revision tmp-name)
 400                         ;;(vc-working-revision tmp-name backend)))
 401             (should (member (vc-working-revision tmp-name) '(nil "0")))
 402
 403             ;; Register a file.  Check working revision.
 404             (vc-register
 405              (list backend (list (file-name-nondirectory tmp-name))))
 406
 407             ;; nil: Mtn Git RCS SCCS
 408             ;; "0": Bzr CVS Hg SRC SVN
 409             (message "vc-working-revision4 %s" (vc-working-revision tmp-name))
 410             ;;(should (eq (vc-working-revision tmp-name)
 411                         ;;(vc-working-revision tmp-name backend)))
 412             (should (member (vc-working-revision tmp-name) '(nil "0")))
 413
 414             ;; Unregister the file.  Check working revision.
 415             (condition-case nil
 416                 (progn
 417                   (vc-test--unregister-function backend tmp-name)
 418
 419                   ;; nil: Git RCS
 420                   ;; "0": Bzr Hg
 421                   ;; unsupported: CVS Mtn SCCS SRC SVN
 422                   (message
 423                    "vc-working-revision5 %s" (vc-working-revision tmp-name))
 424                   ;;(should (eq (vc-working-revision tmp-name)
 425                               ;;(vc-working-revision tmp-name backend)))
 426                   (should (member (vc-working-revision tmp-name) '(nil "0"))))
 427               (vc-not-supported (message "vc-working-revision5 unsupported")))))
 428
 429       ;; Save exit.
 430       (ignore-errors (run-hooks 'vc-test--cleanup-hook)))))
 431
 432 (defun vc-test--checkout-model (backend)
 433   "Check the checkout model of a repository."
 434
 435   (let ((vc-handled-backends `(,backend))
 436         (default-directory
 437           (file-name-as-directory
 438            (expand-file-name
 439             (make-temp-name "vc-test") temporary-file-directory)))
 440         vc-test--cleanup-hook)
 441
 442     (unwind-protect
 443         (progn
 444           ;; Cleanup.
 445           (add-hook
 446            'vc-test--cleanup-hook
 447            `(lambda () (delete-directory ,default-directory 'recursive)))
 448
 449           ;; Create empty repository.  Check repository checkout model.
 450           (make-directory default-directory)
 451           (vc-test--create-repo-function backend)
 452
 453           ;; Surprisingly, none of the backends returns 'announce.
 454           ;; nil: RCS
 455           ;; implicit: Bzr CVS Git Hg Mtn SRC SVN
 456           ;; locking: SCCS
 457           (message
 458            "vc-checkout-model1 %s"
 459            (vc-checkout-model backend default-directory))
 460           (should (memq (vc-checkout-model backend default-directory)
 461                         '(announce implicit locking)))
 462
 463           (let ((tmp-name (expand-file-name "foo" default-directory)))
 464             ;; Check checkout model of an empty file.
 465
 466             ;; nil: RCS
 467             ;; implicit: Bzr CVS Git Hg Mtn SRC SVN
 468             ;; locking: SCCS
 469             (message
 470              "vc-checkout-model2 %s" (vc-checkout-model backend tmp-name))
 471             (should (memq (vc-checkout-model backend tmp-name)
 472                           '(announce implicit locking)))
 473
 474             ;; Write a new file.  Check checkout model.
 475             (write-region "foo" nil tmp-name nil 'nomessage)
 476
 477             ;; nil: RCS
 478             ;; implicit: Bzr CVS Git Hg Mtn SRC SVN
 479             ;; locking: SCCS
 480             (message
 481              "vc-checkout-model3 %s" (vc-checkout-model backend tmp-name))
 482             (should (memq (vc-checkout-model backend tmp-name)
 483                           '(announce implicit locking)))
 484
 485             ;; Register a file.  Check checkout model.
 486             (vc-register
 487              (list backend (list (file-name-nondirectory tmp-name))))
 488
 489             ;; nil: RCS
 490             ;; implicit: Bzr CVS Git Hg Mtn SRC SVN
 491             ;; locking: SCCS
 492             (message
 493              "vc-checkout-model4 %s" (vc-checkout-model backend tmp-name))
 494             (should (memq (vc-checkout-model backend tmp-name)
 495                           '(announce implicit locking)))
 496
 497             ;; Unregister the file.  Check checkout model.
 498             (condition-case nil
 499                 (progn
 500                   (vc-test--unregister-function backend tmp-name)
 501
 502                   ;; nil: RCS
 503                   ;; implicit: Bzr Git Hg
 504                   ;; unsupported: CVS Mtn SCCS SRC SVN
 505                   (message
 506                    "vc-checkout-model5 %s" (vc-checkout-model backend tmp-name))
 507                   (should (memq (vc-checkout-model backend tmp-name)
 508                                 '(announce implicit locking))))
 509               (vc-not-supported (message "vc-checkout-model5 unsupported")))))
 510
 511       ;; Save exit.
 512       (ignore-errors (run-hooks 'vc-test--cleanup-hook)))))
 513
 514 ;; Create the test cases.
 515
 516 (defun vc-test--rcs-enabled ()
 517   (executable-find "rcs"))
 518
 519 (defun vc-test--cvs-enabled ()
 520   (executable-find "cvs"))
 521
 522 (defvar vc-svn-program)
 523 (defun vc-test--svn-enabled ()
 524   (executable-find vc-svn-program))
 525
 526 (defun vc-test--sccs-enabled ()
 527   (executable-find "sccs"))
 528
 529 (defvar vc-src-program)
 530 (defun vc-test--src-enabled ()
 531   (executable-find vc-src-program))
 532
 533 (defvar vc-bzr-program)
 534 (defun vc-test--bzr-enabled ()
 535   (executable-find vc-bzr-program))
 536
 537 (defvar vc-git-program)
 538 (defun vc-test--git-enabled ()
 539   (executable-find vc-git-program))
 540
 541 (defvar vc-hg-program)
 542 (defun vc-test--hg-enabled ()
 543   (executable-find vc-hg-program))
 544
 545 (defvar vc-mtn-program)
 546 (defun vc-test--mtn-enabled ()
 547   (executable-find vc-mtn-program))
 548
 549 ;; Obsoleted.
 550 (defvar vc-arch-program)
 551 (defun vc-test--arch-enabled ()
 552   (executable-find vc-arch-program))
 553
 554 ;; Create the test cases.
 555 (dolist (backend vc-handled-backends)
 556   (let ((backend-string (downcase (symbol-name backend))))
 557     (require (intern (format "vc-%s" backend-string)))
 558     (eval
 559      ;; Check, whether the backend is supported.
 560      `(when (funcall ',(intern (format "vc-test--%s-enabled" backend-string)))
 561
 562         (ert-deftest
 563             ,(intern (format "vc-test-%s00-create-repo" backend-string)) ()
 564           ,(format "Check `vc-create-repo' for the %s backend."
 565                    backend-string)
 566           (vc-test--create-repo ',backend))
 567
 568         (ert-deftest
 569             ,(intern (format "vc-test-%s01-register" backend-string)) ()
 570           ,(format
 571             "Check `vc-register' and `vc-registered' for the %s backend."
 572             backend-string)
 573           (skip-unless
 574            (ert-test-passed-p
 575             (ert-test-most-recent-result
 576              (ert-get-test
 577               ',(intern
 578                  (format "vc-test-%s00-create-repo" backend-string))))))
 579           (vc-test--register ',backend))
 580
 581         (ert-deftest
 582             ,(intern (format "vc-test-%s02-state" backend-string)) ()
 583           ,(format "Check `vc-state' for the %s backend." backend-string)
 584           (skip-unless
 585            (ert-test-passed-p
 586             (ert-test-most-recent-result
 587              (ert-get-test
 588               ',(intern
 589                  (format "vc-test-%s01-register" backend-string))))))
 590           (vc-test--state ',backend))
 591
 592         (ert-deftest
 593             ,(intern (format "vc-test-%s03-working-revision" backend-string)) ()
 594           ,(format "Check `vc-working-revision' for the %s backend."
 595                    backend-string)
 596           (skip-unless
 597            (ert-test-passed-p
 598             (ert-test-most-recent-result
 599              (ert-get-test
 600               ',(intern
 601                  (format "vc-test-%s01-register" backend-string))))))
 602           (vc-test--working-revision ',backend))
 603
 604         (ert-deftest
 605             ,(intern (format "vc-test-%s04-checkout-model" backend-string)) ()
 606           ,(format "Check `vc-checkout-model' for the %s backend."
 607                    backend-string)
 608           ;; FIXME make this pass.
 609           :expected-result ,(if (equal backend 'RCS) :failed :passed)
 610           (skip-unless
 611            (ert-test-passed-p
 612             (ert-test-most-recent-result
 613              (ert-get-test
 614               ',(intern
 615                  (format "vc-test-%s01-register" backend-string))))))
 616           (vc-test--checkout-model ',backend))))))
 617
 618 (provide 'vc-tests)
 619 ;;; vc-tests.el ends here