code.delx.au - gnu-emacs/blob - configure.ac

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl If you changed any AC_DEFINES, also run autoheader.
   6 dnl
   7 dnl Copyright (C) 1994-1996, 1999-2012 Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation, either version 3 of the License, or
  14 dnl  (at your option) any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 AC_PREREQ(2.65)
  25 AC_INIT(emacs, 24.1.50)
  26 AC_CONFIG_HEADER(src/config.h:src/config.in)
  27 AC_CONFIG_SRCDIR(src/lisp.h)
  28 AC_CONFIG_AUX_DIR(build-aux)
  29 AM_INIT_AUTOMAKE
  30
  31 dnl Support for --program-prefix, --program-suffix and
  32 dnl --program-transform-name options
  33 AC_ARG_PROGRAM
  34
  35 dnl It is important that variables on the RHS not be expanded here,
  36 dnl hence the single quotes.  This is per the GNU coding standards, see
  37 dnl (autoconf) Installation Directory Variables
  38 dnl See also epaths.h below.
  39 lispdir='${datadir}/emacs/${version}/lisp'
  40 leimdir='${datadir}/emacs/${version}/leim'
  41 standardlisppath='${lispdir}:${leimdir}'
  42 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  43 '${datadir}/emacs/site-lisp'
  44 lisppath='${locallisppath}:${standardlisppath}'
  45 etcdir='${datadir}/emacs/${version}/etc'
  46 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  47 docdir='${datadir}/emacs/${version}/etc'
  48 gamedir='${localstatedir}/games/emacs'
  49
  50 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
  51 dnl Create a new --with option that defaults to being disabled.
  52 dnl NAME is the base name of the option.  The shell variable with_NAME
  53 dnl   will be set to either the user's value (if the option is
  54 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
  55 dnl   option is not specified).  Note that the shell variable name is
  56 dnl   constructed as autoconf does, by replacing non-alphanumeric
  57 dnl   characters with "_".
  58 dnl HELP-STRING is the help text for the option.
  59 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
  60   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
  61     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
  62 ])dnl
  63
  64 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
  65 dnl Create a new --with option that defaults to being enabled.  NAME
  66 dnl   is the base name of the option.  The shell variable with_NAME
  67 dnl   will be set either to 'no' (for a plain --without-NAME) or to
  68 dnl   'yes' (if the option is not specified).  Note that the shell
  69 dnl   variable name is constructed as autoconf does, by replacing
  70 dnl   non-alphanumeric characters with "_".
  71 dnl HELP-STRING is the help text for the option.
  72 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
  73   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
  74    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=yes])dnl
  75 ])dnl
  76
  77 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
  78 if test "$with_pop" = yes; then
  79    AC_DEFINE(MAIL_USE_POP)
  80 fi
  81 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
  82
  83 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
  84 if test "$with_kerberos" != no; then
  85    AC_DEFINE(KERBEROS)
  86 fi
  87 AH_TEMPLATE(KERBEROS,
  88             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
  89
  90 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
  91 if test "${with_kerberos5}" != no; then
  92   if test "${with_kerberos}" = no; then
  93     with_kerberos=yes
  94     AC_DEFINE(KERBEROS)
  95   fi
  96   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
  97 fi
  98
  99 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
 100 dnl FIXME hesiod support may not be present, so it seems like an error
 101 dnl to define, or at least use, this unconditionally.
 102 if test "$with_hesiod" != no; then
 103   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
 104 fi
 105
 106 OPTION_DEFAULT_OFF([mmdf],[support MMDF mailboxes])
 107 if test "$with_mmdf" != no; then
 108    AC_DEFINE(MAIL_USE_MMDF, 1, [Define to support MMDF mailboxes in movemail.])
 109 fi
 110
 111 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
 112 if test "$with_mail_unlink" != no; then
 113    AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
 114 fi
 115
 116 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
 117     [string giving default POP mail host])],
 118     AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
 119
 120 OPTION_DEFAULT_ON([sound],[don't compile with sound support])
 121
 122 OPTION_DEFAULT_ON([sync-input],[process async input synchronously])
 123 if test "$with_sync_input" = yes; then
 124    AC_DEFINE(SYNC_INPUT, 1, [Process async input synchronously.])
 125 fi
 126
 127 dnl FIXME currently it is not the last.
 128 dnl This should be the last --with option, because --with-x is
 129 dnl added later on when we find the path of X, and it's best to
 130 dnl keep them together visually.
 131 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 132  [use an X toolkit (KIT one of: yes or gtk, gtk3, lucid or athena, motif, no)])],
 133 [         case "${withval}" in
 134             y | ye | yes )      val=gtk ;;
 135             n | no )            val=no  ;;
 136             l | lu | luc | luci | lucid )       val=lucid ;;
 137             a | at | ath | athe | athen | athena )      val=athena ;;
 138             m | mo | mot | moti | motif )       val=motif ;;
 139             g | gt | gtk  )     val=gtk ;;
 140             gtk3  )     val=gtk3 ;;
 141             * )
 142 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 143 this option's value should be `yes', `no', `lucid', `athena', `motif', `gtk' or
 144 `gtk3'.  `yes' and `gtk' are synonyms. `athena' and `lucid' are synonyms.])
 145             ;;
 146           esac
 147           with_x_toolkit=$val
 148 ])
 149
 150 OPTION_DEFAULT_OFF([wide-int], [prefer wide Emacs integers (typically 62-bit)])
 151 if test "$with_wide_int" = yes; then
 152   AC_DEFINE([WIDE_EMACS_INT], 1, [Use long long for EMACS_INT if available.])
 153 fi
 154
 155 dnl _ON results in a '--without' option in the --help output, so
 156 dnl the help text should refer to "don't compile", etc.
 157 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 158 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 159 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 160 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 161 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 162 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 163 OPTION_DEFAULT_ON([xml2],[don't compile with XML parsing support])
 164 OPTION_DEFAULT_ON([imagemagick],[don't compile with ImageMagick image support])
 165
 166 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 167 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 168 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 169
 170 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 171 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 172 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 173 OPTION_DEFAULT_OFF([ns],[use NeXTstep (Cocoa or GNUstep) windowing system])
 174
 175 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 176 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 177 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 178 OPTION_DEFAULT_ON([gsettings],[don't compile with GSettings support])
 179 OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support])
 180 OPTION_DEFAULT_ON([gnutls],[don't use -lgnutls for SSL/TLS support])
 181
 182 ## For the times when you want to build Emacs but don't have
 183 ## a suitable makeinfo, and can live without the manuals.
 184 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 185 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 186
 187 ## Makefile.in needs the cache file name.
 188 AC_SUBST(cache_file)
 189
 190 ## This is an option because I do not know if all info/man support
 191 ## compressed files, nor how to test if they do so.
 192 OPTION_DEFAULT_ON([compress-info],[don't compress the installed Info pages])
 193 if test $with_compress_info = yes; then
 194    GZIP_INFO=yes
 195 else
 196    GZIP_INFO=
 197 fi
 198 AC_SUBST(GZIP_INFO)
 199
 200 AC_ARG_WITH([pkg-config-prog],dnl
 201 [AS_HELP_STRING([--with-pkg-config-prog=PATH],
 202                   [path to pkg-config for finding GTK and librsvg])])
 203 if test "X${with_pkg_config_prog}" != X; then
 204    if test "${with_pkg_config_prog}" != yes; then
 205       PKG_CONFIG="${with_pkg_config_prog}"
 206    fi
 207 fi
 208
 209 CRT_DIR=
 210 AC_ARG_WITH([crt-dir],dnl
 211 [AS_HELP_STRING([--with-crt-dir=DIR],[directory containing crtn.o etc.
 212 The default is /usr/lib, or /usr/lib64 on some platforms.])])
 213 CRT_DIR="${with_crt_dir}"
 214
 215 AC_ARG_WITH(gameuser,dnl
 216 [AS_HELP_STRING([--with-gameuser=USER],[user for shared game score files])])
 217 test "X${with_gameuser}" != X && test "${with_gameuser}" != yes \
 218   && gameuser="${with_gameuser}"
 219 test "X$gameuser" = X && gameuser=games
 220
 221 AC_ARG_WITH([gnustep-conf],dnl
 222 [AS_HELP_STRING([--with-gnustep-conf=PATH],[path to GNUstep.conf; default $GNUSTEP_CONFIG_FILE, or /etc/GNUstep/GNUstep.conf])])
 223 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 224   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 225 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 226      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 227
 228 AC_ARG_ENABLE(ns-self-contained,
 229 [AS_HELP_STRING([--disable-ns-self-contained],
 230                 [disable self contained build under NeXTstep])],
 231    EN_NS_SELF_CONTAINED=$enableval,
 232    EN_NS_SELF_CONTAINED=yes)
 233
 234 AC_ARG_ENABLE(locallisppath,
 235 [AS_HELP_STRING([--enable-locallisppath=PATH],
 236                 [directories Emacs should search for lisp files specific
 237                  to this site])],
 238 if test "${enableval}" = "no"; then
 239   locallisppath=
 240 elif test "${enableval}" != "yes"; then
 241   locallisppath=${enableval}
 242 fi)
 243
 244 AC_ARG_ENABLE(checking,
 245 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 246                 [enable expensive run-time checks.  With LIST,
 247                  enable only specific categories of checks.
 248                  Categories are: all,yes,no.
 249                  Flags are: stringbytes, stringoverrun, stringfreelist,
 250                  xmallocoverrun, conslist, glyphs])],
 251 [ac_checking_flags="${enableval}"],[])
 252 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 253 for check in $ac_checking_flags
 254 do
 255         case $check in
 256         # these set all the flags to specific states
 257         yes)            ac_enable_checking=1 ;;
 258         no)             ac_enable_checking= ;
 259                         ac_gc_check_stringbytes= ;
 260                         ac_gc_check_string_overrun= ;
 261                         ac_gc_check_string_free_list= ;
 262                         ac_xmalloc_overrun= ;
 263                         ac_gc_check_cons_list= ;
 264                         ac_glyphs_debug= ;;
 265         all)            ac_enable_checking=1 ;
 266                         ac_gc_check_stringbytes=1 ;
 267                         ac_gc_check_string_overrun=1 ;
 268                         ac_gc_check_string_free_list=1 ;
 269                         ac_xmalloc_overrun=1 ;
 270                         ac_gc_check_cons_list=1 ;
 271                         ac_glyphs_debug=1 ;;
 272         # these enable particular checks
 273         stringbytes)    ac_gc_check_stringbytes=1 ;;
 274         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 275         stringfreelist) ac_gc_check_string_free_list=1 ;;
 276         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 277         conslist)       ac_gc_check_cons_list=1 ;;
 278         glyphs)         ac_glyphs_debug=1 ;;
 279         *)      AC_MSG_ERROR(unknown check category $check) ;;
 280         esac
 281 done
 282 IFS="$ac_save_IFS"
 283
 284 if test x$ac_enable_checking != x ; then
 285   AC_DEFINE(ENABLE_CHECKING, 1,
 286 [Define to 1 if expensive run-time data type and consistency checks are enabled.])
 287 fi
 288 if test x$ac_gc_check_stringbytes != x ; then
 289   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 290 [Define this temporarily to hunt a bug.  If defined, the size of
 291    strings is redundantly recorded in sdata structures so that it can
 292    be compared to the sizes recorded in Lisp strings.])
 293 fi
 294 if test x$ac_gc_check_string_overrun != x ; then
 295   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 296 [Define this to check for short string overrun.])
 297 fi
 298 if test x$ac_gc_check_string_free_list != x ; then
 299   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 300 [Define this to check the string free list.])
 301 fi
 302 if test x$ac_xmalloc_overrun != x ; then
 303   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 304 [Define this to check for malloc buffer overrun.])
 305 fi
 306 if test x$ac_gc_check_cons_list != x ; then
 307   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 308 [Define this to check for errors in cons list.])
 309 fi
 310 if test x$ac_glyphs_debug != x ; then
 311   AC_DEFINE(GLYPH_DEBUG, 1,
 312 [Define this to enable glyphs debugging code.])
 313 fi
 314
 315 AC_ARG_ENABLE(check-lisp-object-type,
 316 [AS_HELP_STRING([--enable-check-lisp-object-type],
 317                 [enable compile time checks for the Lisp_Object data type.
 318                 This is useful for development for catching certain types of bugs.])],
 319 if test "${enableval}" != "no"; then
 320    AC_DEFINE(CHECK_LISP_OBJECT_TYPE, 1,
 321    [Define this to enable compile time checks for the Lisp_Object data type.])
 322 fi)
 323
 324
 325 AC_ARG_ENABLE(profiling,
 326 [AS_HELP_STRING([--enable-profiling],
 327                 [build emacs with profiling support.
 328                  This might not work on all platforms])],
 329 [ac_enable_profiling="${enableval}"],[])
 330 if test x$ac_enable_profiling != x ; then
 331    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 332 else
 333    PROFILING_CFLAGS=
 334 fi
 335 AC_SUBST(PROFILING_CFLAGS)
 336
 337 AC_ARG_ENABLE(autodepend,
 338 [AS_HELP_STRING([--enable-autodepend],
 339                 [automatically generate dependencies to .h-files.
 340                  Requires GNU Make and Gcc. Enabled if GNU Make and Gcc is
 341                  found])],
 342 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 343
 344 #### Make srcdir absolute, if it isn't already.  It's important to
 345 #### avoid running the path through pwd unnecessarily, since pwd can
 346 #### give you automounter prefixes, which can go away.  We do all this
 347 #### so Emacs can find its files when run uninstalled.
 348 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 349 unset CDPATH
 350 case "${srcdir}" in
 351   /* ) ;;
 352   . )
 353     ## We may be able to use the $PWD environment variable to make this
 354     ## absolute.  But sometimes PWD is inaccurate.
 355     ## Note: we used to use ${PWD} at the end instead of `pwd`,
 356     ## but that tested only for a well-formed and valid PWD,
 357     ## it did not object when PWD was well-formed and valid but just wrong.
 358     if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`"  ;
 359     then
 360       srcdir="$PWD"
 361     else
 362       srcdir="`(cd ${srcdir}; pwd)`"
 363     fi
 364   ;;
 365   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
 366 esac
 367
 368 ### Canonicalize the configuration name.
 369
 370 AC_CANONICAL_HOST
 371 canonical=$host
 372 configuration=${host_alias-${build_alias-$host}}
 373
 374 dnl This used to use changequote, but, apart from `changequote is evil'
 375 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 376 dnl the great gob of text.  Thus it's not processed for possible expansion.
 377 dnl Just make sure the brackets remain balanced.
 378 dnl
 379 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 380 dnl indicated by comments.
 381 dnl quotation begins
 382 [
 383
 384 ### If you add support for a new configuration, add code to this
 385 ### switch statement to recognize your configuration name and select
 386 ### the appropriate operating system file.
 387
 388 ### You would hope that you could choose an s/*.h
 389 ### file based on the operating system portion.  However, it turns out
 390 ### that each s/*.h file is pretty manufacturer-specific.
 391 ### So we basically have to have a special case for each
 392 ### configuration name.
 393 ###
 394 ### As far as handling version numbers on operating systems is
 395 ### concerned, make sure things will fail in a fixable way.  If
 396 ### /etc/MACHINES doesn't say anything about version numbers, be
 397 ### prepared to handle anything reasonably.  If version numbers
 398 ### matter, be sure /etc/MACHINES says something about it.
 399
 400 opsys='' unported=no
 401 case "${canonical}" in
 402
 403   ## GNU/Linux and similar ports
 404   *-*-linux* )
 405     opsys=gnu-linux
 406   ;;
 407
 408   ## FreeBSD ports
 409   *-*-freebsd* )
 410     opsys=freebsd
 411   ;;
 412
 413   ## FreeBSD kernel + glibc based userland
 414   *-*-kfreebsd*gnu* )
 415     opsys=gnu-kfreebsd
 416   ;;
 417
 418   ## NetBSD ports
 419   *-*-netbsd* )
 420     opsys=netbsd
 421   ;;
 422
 423   ## OpenBSD ports
 424   *-*-openbsd* )
 425     opsys=openbsd
 426   ;;
 427
 428   ## Apple Darwin / Mac OS X
 429   *-apple-darwin* )
 430     case "${canonical}" in
 431       i[3456]86-* )  ;;
 432       powerpc-* )    ;;
 433       x86_64-* )     ;;
 434       * )            unported=yes ;;
 435     esac
 436     opsys=darwin
 437     ## Use fink packages if available.
 438     ## FIXME find a better way to do this: http://debbugs.gnu.org/11507
 439 ##    if test -d /sw/include && test -d /sw/lib; then
 440 ##      GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 441 ##      NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 442 ##    fi
 443   ;;
 444
 445   ## HP 9000 series 700 and 800, running HP/UX
 446   hppa*-hp-hpux10.2* )
 447     opsys=hpux10-20
 448   ;;
 449   hppa*-hp-hpux1[1-9]* )
 450     opsys=hpux11
 451     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 452   ;;
 453
 454   ## IBM machines
 455   rs6000-ibm-aix4.[23]* )
 456     opsys=aix4-2
 457   ;;
 458   powerpc-ibm-aix4.[23]*  )
 459     opsys=aix4-2
 460   ;;
 461   rs6000-ibm-aix[56]* )
 462     opsys=aix4-2
 463   ;;
 464   powerpc-ibm-aix[56]*  )
 465     opsys=aix4-2
 466   ;;
 467
 468   ## Silicon Graphics machines
 469   ## Iris 4D
 470   mips-sgi-irix6.5 )
 471     opsys=irix6-5
 472     # Without defining _LANGUAGE_C, things get masked out in the headers
 473     # so that, for instance, grepping for `free' in stdlib.h fails and
 474     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 475     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 476   ;;
 477
 478   ## Suns
 479   *-sun-solaris* \
 480     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 481     | x86_64-*-solaris2*    | x86_64-*-sunos5*)
 482     case "${canonical}" in
 483       i[3456]86-*-* )   ;;
 484       amd64-*-*|x86_64-*-*) ;;
 485       sparc* )          ;;
 486       * )               unported=yes ;;
 487     esac
 488     case "${canonical}" in
 489       *-sunos5.6* | *-solaris2.6* )
 490                 opsys=sol2-6
 491                 RANLIB="ar -ts"
 492                 ;;
 493       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 494                 opsys=sol2-6
 495                 emacs_check_sunpro_c=yes
 496                 ;;
 497       *-sunos5* | *-solaris* )
 498                 opsys=sol2-10
 499                 emacs_check_sunpro_c=yes
 500                 ;;
 501     esac
 502     ## Watch out for a compiler that we know will not work.
 503     case "${canonical}" in
 504      *-solaris* | *-sunos5* )
 505                 if [ "x$CC" = x/usr/ucb/cc ]; then
 506                   ## /usr/ucb/cc doesn't work;
 507                   ## we should find some other compiler that does work.
 508                   unset CC
 509                 fi
 510                 ;;
 511       *) ;;
 512     esac
 513   ;;
 514
 515   ## Intel 386 machines where we don't care about the manufacturer.
 516   i[3456]86-*-* )
 517     case "${canonical}" in
 518       *-cygwin )                opsys=cygwin ;;
 519       *-darwin* )               opsys=darwin ;;
 520       *-sysv4.2uw* )            opsys=unixware ;;
 521       *-sysv5uw* )              opsys=unixware ;;
 522       *-sysv5OpenUNIX* )        opsys=unixware ;;
 523       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 524     esac
 525   ;;
 526
 527   * )
 528     unported=yes
 529   ;;
 530 esac
 531
 532 ### If the code above didn't choose an operating system, just choose
 533 ### an operating system based on the configuration name.  You really
 534 ### only want to use this when you have no idea what the right
 535 ### operating system is; if you know what operating systems a machine
 536 ### runs, it's cleaner to make it explicit in the case statement
 537 ### above.
 538 if test x"${opsys}" = x; then
 539   case "${canonical}" in
 540     *-gnu* )                            opsys=gnu ;;
 541     * )
 542       unported=yes
 543     ;;
 544   esac
 545 fi
 546
 547 ]
 548 dnl quotation ends
 549
 550 if test $unported = yes; then
 551   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
 552 Check `etc/MACHINES' for recognized configuration names.])
 553 fi
 554
 555
 556 #### Choose a compiler.
 557
 558 dnl Sets GCC=yes if using gcc.
 559 AC_PROG_CC
 560 AM_PROG_CC_C_O
 561
 562 if test x$GCC = xyes; then
 563   test "x$GCC_TEST_OPTIONS" != x && CC="$CC $GCC_TEST_OPTIONS"
 564 else
 565   test "x$NON_GCC_TEST_OPTIONS" != x && CC="$CC $NON_GCC_TEST_OPTIONS"
 566 fi
 567
 568 # Initialize gnulib right after choosing the compiler.
 569 gl_EARLY
 570
 571 AC_ARG_ENABLE([gcc-warnings],
 572   [AS_HELP_STRING([--enable-gcc-warnings],
 573                   [turn on lots of GCC warnings. This is intended for
 574                    developers, and may generate false alarms when used
 575                    with older or non-GNU development tools.])],
 576   [case $enableval in
 577      yes|no) ;;
 578      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
 579    esac
 580    gl_gcc_warnings=$enableval],
 581   [gl_gcc_warnings=no]
 582 )
 583
 584 AC_ARG_ENABLE(link-time-optimization,
 585 [AS_HELP_STRING([--enable-link-time-optimization],
 586                 [build emacs with link-time optimization.
 587                  This is supported only for GCC since 4.5.0.])],
 588 if test "${enableval}" != "no"; then
 589    AC_MSG_CHECKING([whether link-time optimization is supported])
 590    ac_lto_supported=no
 591    if test x$GCC = xyes; then
 592       CPUS=`getconf _NPROCESSORS_ONLN 2>/dev/null`
 593       if test x$CPUS != x; then
 594          LTO="-flto=$CPUS"
 595       else
 596          LTO="-flto"
 597       fi
 598       old_CFLAGS=$CFLAGS
 599       CFLAGS="$CFLAGS $LTO"
 600       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])],
 601         [ac_lto_supported=yes], [ac_lto_supported=no])
 602       CFLAGS="$old_CFLAGS"
 603    fi
 604    AC_MSG_RESULT([$ac_lto_supported])
 605    if test "$ac_lto_supported" = "yes"; then
 606       CFLAGS="$CFLAGS $LTO"
 607    fi
 608 fi)
 609
 610 # gl_GCC_VERSION_IFELSE([major], [minor], [run-if-found], [run-if-not-found])
 611 # ------------------------------------------------
 612 # If $CPP is gcc-MAJOR.MINOR or newer, then run RUN-IF-FOUND.
 613 # Otherwise, run RUN-IF-NOT-FOUND.
 614 AC_DEFUN([gl_GCC_VERSION_IFELSE],
 615   [AC_PREPROC_IFELSE(
 616     [AC_LANG_PROGRAM(
 617       [[
 618 #if ($1) < __GNUC__ || (($1) == __GNUC__ && ($2) <= __GNUC_MINOR__)
 619 /* ok */
 620 #else
 621 # error "your version of gcc is older than $1.$2"
 622 #endif
 623       ]]),
 624     ], [$3], [$4])
 625   ]
 626 )
 627
 628 # When compiling with GCC, prefer -isystem to -I when including system
 629 # include files, to avoid generating useless diagnostics for the files.
 630 if test "$gl_gcc_warnings" != yes; then
 631   isystem='-I'
 632 else
 633   isystem='-isystem '
 634
 635   # This, $nw, is the list of warnings we disable.
 636   nw=
 637
 638   case $with_x_toolkit in
 639     lucid | athena | motif)
 640        # Old toolkits mishandle 'const'.
 641        nw="$nw -Wwrite-strings"
 642        ;;
 643     *)
 644        gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
 645        ;;
 646   esac
 647   AC_SUBST([WERROR_CFLAGS])
 648
 649   nw="$nw -Waggregate-return"       # anachronistic
 650   nw="$nw -Wlong-long"              # C90 is anachronistic
 651   nw="$nw -Wc++-compat"             # We don't care about C++ compilers
 652   nw="$nw -Wundef"                  # Warns on '#if GNULIB_FOO' etc in gnulib
 653   nw="$nw -Wtraditional"            # Warns on #elif which we use often
 654   nw="$nw -Wcast-qual"              # Too many warnings for now
 655   nw="$nw -Wconversion"             # Too many warnings for now
 656   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
 657   nw="$nw -Wsign-conversion"        # Too many warnings for now
 658   nw="$nw -Woverlength-strings"     # Not a problem these days
 659   nw="$nw -Wtraditional-conversion" # Too many warnings for now
 660   nw="$nw -Wunreachable-code"       # so buggy that it's now silently ignored
 661   nw="$nw -Wpadded"                 # Our structs are not padded
 662   nw="$nw -Wredundant-decls"        # we regularly (re)declare functions
 663   nw="$nw -Wlogical-op"             # any use of fwrite provokes this
 664   nw="$nw -Wformat-nonliteral"      # we do this a lot
 665   nw="$nw -Wvla"                    # warnings in gettext.h
 666   nw="$nw -Wnested-externs"         # use of XARGMATCH/verify_function__
 667   nw="$nw -Wswitch-enum"            # Too many warnings for now
 668   nw="$nw -Wswitch-default"         # Too many warnings for now
 669   nw="$nw -Wfloat-equal"            # warns about high-quality code
 670   nw="$nw -Winline"                 # OK to ignore 'inline'
 671   nw="$nw -Wsync-nand"              # irrelevant here, and provokes ObjC warning
 672   nw="$nw -Wunsafe-loop-optimizations" # OK to suppress unsafe optimizations
 673
 674   # Emacs doesn't care about shadowing; see
 675   # <http://lists.gnu.org/archive/html/emacs-diffs/2011-11/msg00265.html>.
 676   nw="$nw -Wshadow"
 677
 678   # The following lines should be removable at some point.
 679   nw="$nw -Wstack-protector"
 680   nw="$nw -Wstrict-overflow"
 681   nw="$nw -Wsuggest-attribute=pure"
 682
 683   gl_MANYWARN_ALL_GCC([ws])
 684   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
 685   for w in $ws; do
 686     gl_WARN_ADD([$w])
 687   done
 688   gl_WARN_ADD([-Wno-missing-field-initializers]) # We need this one
 689   gl_WARN_ADD([-Wno-sign-compare])     # Too many warnings for now
 690   gl_WARN_ADD([-Wno-type-limits])      # Too many warnings for now
 691   gl_WARN_ADD([-Wno-switch])           # Too many warnings for now
 692   gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now
 693   gl_WARN_ADD([-Wno-format-nonliteral])
 694
 695   # In spite of excluding -Wlogical-op above, it is enabled, as of
 696   # gcc 4.5.0 20090517.
 697   gl_WARN_ADD([-Wno-logical-op])
 698
 699   gl_WARN_ADD([-fdiagnostics-show-option])
 700   gl_WARN_ADD([-funit-at-a-time])
 701
 702   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 703   AC_DEFINE([_FORTIFY_SOURCE], [2],
 704     [enable compile-time and run-time bounds-checking, and some warnings])
 705   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 706
 707   # We use a slightly smaller set of warning options for lib/.
 708   # Remove the following and save the result in GNULIB_WARN_CFLAGS.
 709   nw=
 710   nw="$nw -Wunused-macros"
 711
 712   gl_MANYWARN_COMPLEMENT([GNULIB_WARN_CFLAGS], [$WARN_CFLAGS], [$nw])
 713   AC_SUBST([GNULIB_WARN_CFLAGS])
 714 fi
 715
 716
 717
 718 dnl Some other nice autoconf tests.
 719 dnl These are commented out, since gl_EARLY and/or Autoconf already does them.
 720 dnl AC_PROG_INSTALL
 721 dnl AC_PROG_MKDIR_P
 722 dnl if test "x$RANLIB" = x; then
 723 dnl   AC_PROG_RANLIB
 724 dnl fi
 725
 726 AC_PATH_PROG(INSTALL_INFO, install-info, :,
 727   $PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin)
 728 dnl Don't use GZIP, which is used by gzip for additional parameters.
 729 AC_PATH_PROG(GZIP_PROG, gzip)
 730
 731 if test $opsys = gnu-linux; then
 732   AC_PATH_PROG(PAXCTL, paxctl,,
 733     [$PATH$PATH_SEPARATOR/sbin$PATH_SEPARATOR/usr/sbin])
 734   if test "X$PAXCTL" != X; then
 735     AC_MSG_CHECKING([whether binaries have a PT_PAX_FLAGS header])
 736     AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
 737       [if $PAXCTL -v conftest$EXEEXT >/dev/null 2>&1; then AC_MSG_RESULT(yes)
 738       else AC_MSG_RESULT(no); PAXCTL=""; fi])
 739   fi
 740 fi
 741
 742 ## Need makeinfo >= 4.7 (?) to build the manuals.
 743 AC_PATH_PROG(MAKEINFO, makeinfo, no)
 744 dnl By this stage, configure has already checked for egrep and set EGREP,
 745 dnl or exited with an error if no egrep was found.
 746 if test "$MAKEINFO" != "no" && \
 747   test x"`$MAKEINFO --version 2> /dev/null | $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[7-9]]|4\.[[1-6]][[0-9]]+)'`" = x; then
 748    MAKEINFO=no
 749 fi
 750
 751 ## Makeinfo is unusual.  For a released Emacs, the manuals are
 752 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
 753 ## therefore in the category of "special tools" not normally required, which
 754 ## configure does not have to check for (eg autoconf itself).
 755 ## In a Bazaar checkout on the other hand, the manuals are not included.
 756 ## So makeinfo is a requirement to build from Bazaar, and configure
 757 ## should test for it as it does for any other build requirement.
 758 ## We use the presence of $srcdir/info/emacs to distinguish a release,
 759 ## with pre-built manuals, from a Bazaar checkout.
 760 HAVE_MAKEINFO=yes
 761
 762 if test "$MAKEINFO" = "no"; then
 763   MAKEINFO=makeinfo
 764   if test "x${with_makeinfo}" = "xno"; then
 765     HAVE_MAKEINFO=no
 766   elif test ! -e $srcdir/info/emacs; then
 767     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.7, and your
 768 source tree does not seem to have pre-built manuals in the `info' directory.
 769 Either install a suitable version of makeinfo, or re-run configure
 770 with the `--without-makeinfo' option to build without the manuals.] )
 771   fi
 772 fi
 773 AC_SUBST(HAVE_MAKEINFO)
 774
 775 dnl Just so that there is only a single place we need to edit.
 776 INFO_EXT=.info
 777 INFO_OPTS=--no-split
 778 AC_SUBST(INFO_EXT)
 779 AC_SUBST(INFO_OPTS)
 780
 781 dnl Add our options to ac_link now, after it is set up.
 782
 783 if test x$GCC = xyes; then
 784   test "x$GCC_LINK_TEST_OPTIONS" != x && \
 785     ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
 786 else
 787   test "x$NON_GCC_LINK_TEST_OPTIONS" != x && \
 788     ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
 789 fi
 790
 791 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
 792 dnl If we can link with the flag, it shouldn't do any harm anyhow.
 793 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
 794 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
 795 dnl if not built to support GNU ld.
 796
 797 late_LDFLAGS=$LDFLAGS
 798 if test x$GCC = xyes; then
 799   LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
 800 else
 801   LDFLAGS="$LDFLAGS -znocombreloc"
 802 fi
 803
 804 AC_MSG_CHECKING([for -znocombreloc])
 805 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
 806   [AC_MSG_RESULT(yes)],
 807   LDFLAGS=$late_LDFLAGS
 808   [AC_MSG_RESULT(no)])
 809
 810
 811 dnl The function dump-emacs will not be defined and temacs will do
 812 dnl (load "loadup") automatically unless told otherwise.
 813 test "x$CANNOT_DUMP" = "x" && CANNOT_DUMP=no
 814 case "$opsys" in
 815   your-opsys-here) CANNOT_DUMP=yes ;;
 816 esac
 817
 818 test "$CANNOT_DUMP" = "yes" && \
 819   AC_DEFINE(CANNOT_DUMP, 1, [Define if Emacs cannot be dumped on your system.])
 820
 821 AC_SUBST(CANNOT_DUMP)
 822
 823
 824 UNEXEC_OBJ=unexelf.o
 825 case "$opsys" in
 826   # MSDOS uses unexcoff.o
 827   # MSWindows uses unexw32.o
 828   aix4-2)
 829    UNEXEC_OBJ=unexaix.o
 830    ;;
 831   cygwin)
 832    UNEXEC_OBJ=unexcw.o
 833    ;;
 834   darwin)
 835    UNEXEC_OBJ=unexmacosx.o
 836    ;;
 837   hpux10-20 | hpux11)
 838    UNEXEC_OBJ=unexhp9k800.o
 839    ;;
 840   sol2-10)
 841    # Use the Solaris dldump() function, called from unexsol.c, to dump
 842    # emacs, instead of the generic ELF dump code found in unexelf.c.
 843    # The resulting binary has a complete symbol table, and is better
 844    # for debugging and other observability tools (debuggers, pstack, etc).
 845    #
 846    # If you encounter a problem using dldump(), please consider sending
 847    # a message to the OpenSolaris tools-linking mailing list:
 848    #      http://mail.opensolaris.org/mailman/listinfo/tools-linking
 849    #
 850    # It is likely that dldump() works with older Solaris too, but this has
 851    # not been tested, so for now this change is for Solaris 10 or newer.
 852    UNEXEC_OBJ=unexsol.o
 853    ;;
 854 esac
 855
 856 LD_SWITCH_SYSTEM=
 857 case "$opsys" in
 858   freebsd)
 859    ## Let `ld' find image libs and similar things in /usr/local/lib.
 860    ## The system compiler, GCC, has apparently been modified to not
 861    ## look there, contrary to what a stock GCC would do.
 862 ### It's not our place to do this.  See bug#10313#17.
 863 ###   LD_SWITCH_SYSTEM=-L/usr/local/lib
 864       :
 865    ;;
 866
 867   gnu-linux)
 868    ## cpp test was "ifdef __mips__", but presumably this is equivalent...
 869    case $host_cpu in mips*) LD_SWITCH_SYSTEM="-G 0";; esac
 870    ;;
 871
 872   netbsd)
 873 ### It's not our place to do this.  See bug#10313#17.
 874 ###   LD_SWITCH_SYSTEM="-Wl,-rpath,/usr/pkg/lib -L/usr/pkg/lib -Wl,-rpath,/usr/local/lib -L/usr/local/lib"
 875       :
 876    ;;
 877
 878   openbsd)
 879    ## Han Boetes <han@mijncomputer.nl> says this is necessary,
 880    ## otherwise Emacs dumps core on elf systems.
 881    LD_SWITCH_SYSTEM="-Z"
 882    ;;
 883 esac
 884 AC_SUBST(LD_SWITCH_SYSTEM)
 885
 886 ac_link="$ac_link $LD_SWITCH_SYSTEM"
 887
 888 ## This setting of LD_SWITCH_SYSTEM references LD_SWITCH_X_SITE_RPATH,
 889 ## which has not been defined yet.  When this was handled with cpp,
 890 ## it was expanded to null when configure sourced the s/*.h file.
 891 ## Thus LD_SWITCH_SYSTEM had different values in configure and the Makefiles.
 892 ## FIXME it would be cleaner to put this in LD_SWITCH_SYSTEM_TEMACS
 893 ## (or somesuch), but because it is supposed to go at the _front_
 894 ## of LD_SWITCH_SYSTEM, we cannot do that in exactly the same way.
 895 ## Compare with the gnu-linux case below, which added to the end
 896 ## of LD_SWITCH_SYSTEM, and so can instead go at the front of
 897 ## LD_SWITCH_SYSTEM_TEMACS.
 898 case "$opsys" in
 899   netbsd|openbsd)
 900    LD_SWITCH_SYSTEM="\$(LD_SWITCH_X_SITE_RPATH) $LD_SWITCH_SYSTEM" ;;
 901 esac
 902
 903
 904 C_SWITCH_MACHINE=
 905 case $canonical in
 906  alpha*)
 907   AC_CHECK_DECL([__ELF__])
 908   if test "$ac_cv_have_decl___ELF__" = "yes"; then
 909     ## With ELF, make sure that all common symbols get allocated to in the
 910     ## data section.  Otherwise, the dump of temacs may miss variables in
 911     ## the shared library that have been initialized.  For example, with
 912     ## GNU libc, __malloc_initialized would normally be resolved to the
 913     ## shared library's .bss section, which is fatal.
 914     if test "x$GCC" = "xyes"; then
 915       C_SWITCH_MACHINE="-fno-common"
 916     else
 917       AC_MSG_ERROR([What gives?  Fix me if DEC Unix supports ELF now.])
 918     fi
 919   else
 920     UNEXEC_OBJ=unexalpha.o
 921   fi
 922   ;;
 923 esac
 924 AC_SUBST(C_SWITCH_MACHINE)
 925
 926 AC_SUBST(UNEXEC_OBJ)
 927
 928 C_SWITCH_SYSTEM=
 929 ## Some programs in src produce warnings saying certain subprograms
 930 ## are too complex and need a MAXMEM value greater than 2000 for
 931 ## additional optimization.  --nils@exp-math.uni-essen.de
 932 test "$opsys" = "aix4.2" && test "x$GCC" != "xyes" && \
 933   C_SWITCH_SYSTEM="-ma -qmaxmem=4000"
 934 ## gnu-linux might need -D_BSD_SOURCE on old libc5 systems.
 935 ## It is redundant in glibc2, since we define _GNU_SOURCE.
 936 AC_SUBST(C_SWITCH_SYSTEM)
 937
 938
 939 LIBS_SYSTEM=
 940 case "$opsys" in
 941   ## IBM's X11R5 uses -lIM and -liconv in AIX 3.2.2.
 942   aix4-2) LIBS_SYSTEM="-lrts -lIM -liconv" ;;
 943
 944   freebsd) LIBS_SYSTEM="-lutil" ;;
 945
 946   hpux*) LIBS_SYSTEM="-l:libdld.sl" ;;
 947
 948   sol2*) LIBS_SYSTEM="-lsocket -lnsl" ;;
 949
 950   ## Motif needs -lgen.
 951   unixware) LIBS_SYSTEM="-lsocket -lnsl -lelf -lgen" ;;
 952 esac
 953 AC_SUBST(LIBS_SYSTEM)
 954
 955
 956 ### Make sure subsequent tests use flags consistent with the build flags.
 957
 958 if test x"${OVERRIDE_CPPFLAGS}" != x; then
 959   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
 960 else
 961   CPPFLAGS="$C_SWITCH_SYSTEM $C_SWITCH_MACHINE $CPPFLAGS"
 962 fi
 963
 964 # Suppress obsolescent Autoconf test for size_t; Emacs assumes C89 or better.
 965 AC_DEFUN([AC_TYPE_SIZE_T])
 966 # Likewise for obsolescent test for uid_t, gid_t; Emacs assumes them.
 967 AC_DEFUN([AC_TYPE_UID_T])
 968
 969
 970 LIB_MATH=-lm
 971 LIB_STANDARD=
 972 START_FILES=
 973 dnl Current possibilities handled by sed (aix4-2 -> aix,
 974 dnl gnu-linux -> gnu/linux, etc.):
 975 dnl gnu, gnu/linux, gnu/kfreebsd, aix, cygwin, darwin, hpux, irix.
 976 dnl And special cases: berkeley-unix, usg-unix-v, ms-dos, windows-nt.
 977 SYSTEM_TYPE=`echo $opsys | sed -e 's/[[0-9]].*//' -e 's|-|/|'`
 978
 979 dnl NB do not use CRT_DIR unquoted here, since it might not be set yet.
 980 case $opsys in
 981   cygwin )
 982     LIB_MATH=
 983     START_FILES='pre-crt0.o'
 984     ;;
 985   darwin )
 986     ## Adding -lm confuses the dynamic linker, so omit it.
 987     LIB_MATH=
 988     START_FILES='pre-crt0.o'
 989     ;;
 990   freebsd )
 991     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtn.o'
 992     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o'
 993     SYSTEM_TYPE=berkeley-unix
 994     ;;
 995   gnu-linux | gnu-kfreebsd )
 996     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtn.o'
 997     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o'
 998     ;;
 999   hpux10-20 | hpux11 )
1000     LIB_STANDARD=-lc
1001     START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o'
1002     ;;
1003   dnl NB this may be adjusted below.
1004   netbsd | openbsd )
1005     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o'
1006     START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crtbegin.o'
1007     SYSTEM_TYPE=berkeley-unix
1008     ;;
1009
1010   sol2* | unixware )
1011     SYSTEM_TYPE=usg-unix-v
1012     ;;
1013
1014 esac
1015
1016 AC_SUBST(LIB_MATH)
1017 AC_SUBST(START_FILES)
1018 AC_DEFINE_UNQUOTED(SYSTEM_TYPE, "$SYSTEM_TYPE",
1019   [The type of system you are compiling for; sets `system-type'.])
1020
1021 dnl Not all platforms use crtn.o files.  Check if the current one does.
1022 crt_files=
1023
1024 for file in x $LIB_STANDARD $START_FILES; do
1025   case "$file" in
1026     *CRT_DIR*) crt_files="$crt_files `echo $file | sed -e 's|.*/||'`" ;;
1027   esac
1028 done
1029
1030 if test "x$crt_files" != x; then
1031
1032   ## If user specified a crt-dir, use that unconditionally.
1033   crt_gcc=no
1034
1035   if test "X$CRT_DIR" = "X"; then
1036
1037     CRT_DIR=/usr/lib            # default
1038
1039     case "$canonical" in
1040       x86_64-*-linux-gnu* | s390x-*-linux-gnu*)
1041       ## On x86-64 and s390x GNU/Linux distributions, the standard library
1042       ## can be in a variety of places.  We only try /usr/lib64 and /usr/lib.
1043       ## For anything else (eg /usr/lib32), it is up the user to specify
1044       ## the location (bug#5655).
1045       ## Test for crtn.o, not just the directory, because sometimes the
1046       ## directory exists but does not have the relevant files (bug#1287).
1047       ## FIXME better to test for binary compatibility somehow.
1048       test -e /usr/lib64/crtn.o && CRT_DIR=/usr/lib64
1049       ;;
1050
1051       powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*) CRT_DIR=/usr/lib64 ;;
1052     esac
1053
1054     case "$opsys" in
1055       hpux10-20) CRT_DIR=/lib ;;
1056     esac
1057
1058     test "x${GCC}" = xyes && crt_gcc=yes
1059
1060   fi                            # CRT_DIR = ""
1061
1062   crt_missing=
1063
1064   for file in $crt_files; do
1065
1066     ## If we're using gcc, try to determine it automatically by asking
1067     ## gcc.  [If this doesn't work, CRT_DIR will remain at the
1068     ## system-dependent default from above.]
1069     if test $crt_gcc = yes && test ! -e $CRT_DIR/$file; then
1070
1071        crt_file=`$CC --print-file-name=$file 2>/dev/null`
1072        case "$crt_file" in
1073          */*)
1074            CRT_DIR=`AS_DIRNAME(["$crt_file"])`
1075            ;;
1076        esac
1077     fi
1078
1079     dnl We expect all the files to be in a single directory, so after the
1080     dnl first there is no point asking gcc.
1081     crt_gcc=no
1082
1083     test -e $CRT_DIR/$file || crt_missing="$crt_missing $file"
1084   done                          # $crt_files
1085
1086   test "x$crt_missing" = x || \
1087     AC_MSG_ERROR([Required file(s) not found:$crt_missing
1088 Try using the --with-crt-dir option.])
1089
1090 fi                              # crt_files != ""
1091
1092 AC_SUBST(CRT_DIR)
1093
1094 case $opsys in
1095   netbsd | openbsd )
1096     if test -f $CRT_DIR/crti.o; then
1097
1098         test -f $CRT_DIR/crtn.o || \
1099           AC_MSG_ERROR([Required file not found: crtn.o])
1100
1101         LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1102         START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1103     fi
1104     ;;
1105 esac
1106
1107
1108 pre_PKG_CONFIG_CFLAGS=$CFLAGS
1109 pre_PKG_CONFIG_LIBS=$LIBS
1110
1111 AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1112
1113 dnl This function definition taken from Gnome 2.0
1114 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1115 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1116 dnl also defines GSTUFF_PKG_ERRORS on error
1117 AC_DEFUN([PKG_CHECK_MODULES], [
1118   succeeded=no
1119
1120   if test "$PKG_CONFIG" = "no" ; then
1121      ifelse([$4], , [AC_MSG_ERROR([
1122       *** The pkg-config script could not be found. Make sure it is in your path, or give the full path to pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
1123   else
1124      PKG_CONFIG_MIN_VERSION=0.9.0
1125      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1126         AC_MSG_CHECKING(for $2)
1127
1128         if $PKG_CONFIG --exists "$2" 2>&AS_MESSAGE_LOG_FD &&
1129            $1_CFLAGS=`$PKG_CONFIG --cflags "$2" 2>&AS_MESSAGE_LOG_FD` &&
1130            $1_LIBS=`$PKG_CONFIG --libs "$2" 2>&AS_MESSAGE_LOG_FD`; then
1131             edit_cflags="
1132               s,///*,/,g
1133               s/^/ /
1134               s/ -I/ $isystem/g
1135               s/^ //
1136             "
1137             $1_CFLAGS=`AS_ECHO(["$$1_CFLAGS"]) | sed -e "$edit_cflags"`
1138             $1_LIBS=`AS_ECHO(["$$1_LIBS"]) | sed -e 's,///*,/,g'`
1139             AC_MSG_RESULT([yes CFLAGS='$$1_CFLAGS' LIBS='$$1_LIBS'])
1140             succeeded=yes
1141         else
1142             AC_MSG_RESULT(no)
1143             $1_CFLAGS=""
1144             $1_LIBS=""
1145             ## If we have a custom action on failure, don't print errors, but
1146             ## do set a variable so people can do so.
1147             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
1148             ifelse([$4], ,echo $$1_PKG_ERRORS,)
1149         fi
1150
1151         AC_SUBST($1_CFLAGS)
1152         AC_SUBST($1_LIBS)
1153      else
1154         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1155         echo "*** See http://www.freedesktop.org/software/pkgconfig"
1156      fi
1157   fi
1158
1159   if test $succeeded = yes; then
1160      ifelse([$3], , :, [$3])
1161   else
1162      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
1163   fi
1164 ])
1165
1166
1167 if test "${with_sound}" != "no"; then
1168   # Sound support for GNU/Linux and the free BSDs.
1169   AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h,
1170     have_sound_header=yes)
1171   # Emulation library used on NetBSD.
1172   AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1173   AC_SUBST(LIBSOUND)
1174
1175   ALSA_REQUIRED=1.0.0
1176   ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1177   PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
1178   if test $HAVE_ALSA = yes; then
1179     SAVE_CFLAGS="$CFLAGS"
1180     SAVE_LIBS="$LIBS"
1181     CFLAGS="$ALSA_CFLAGS $CFLAGS"
1182     LIBS="$ALSA_LIBS $LIBS"
1183     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <asoundlib.h>]], [[snd_lib_error_set_handler (0);]])],
1184                     emacs_alsa_normal=yes,
1185                     emacs_alsa_normal=no)
1186     if test "$emacs_alsa_normal" != yes; then
1187       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <alsa/asoundlib.h>]],
1188                      [[snd_lib_error_set_handler (0);]])],
1189                      emacs_alsa_subdir=yes,
1190                      emacs_alsa_subdir=no)
1191       if test "$emacs_alsa_subdir" != yes; then
1192         AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1193       fi
1194       ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1195     fi
1196
1197     CFLAGS="$SAVE_CFLAGS"
1198     LIBS="$SAVE_LIBS"
1199     LIBSOUND="$LIBSOUND $ALSA_LIBS"
1200     CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1201     AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1202   fi
1203
1204   dnl Define HAVE_SOUND if we have sound support.  We know it works and
1205   dnl compiles only on the specified platforms.  For others, it
1206   dnl probably doesn't make sense to try.
1207   if test x$have_sound_header = xyes || test $HAVE_ALSA = yes; then
1208      case "$opsys" in
1209        dnl defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
1210        gnu-linux|freebsd|netbsd)
1211          AC_DEFINE(HAVE_SOUND, 1, [Define to 1 if you have sound support.])
1212          ;;
1213      esac
1214   fi
1215
1216   AC_SUBST(CFLAGS_SOUND)
1217 fi
1218
1219 dnl checks for header files
1220 AC_CHECK_HEADERS_ONCE(
1221   linux/version.h sys/systeminfo.h
1222   stdio_ext.h fcntl.h coff.h pty.h
1223   sys/vlimit.h sys/resource.h
1224   sys/utsname.h pwd.h utmp.h dirent.h util.h)
1225
1226 AC_MSG_CHECKING(if personality LINUX32 can be set)
1227 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/personality.h>]], [[personality (PER_LINUX32)]])],
1228                emacs_cv_personality_linux32=yes,
1229                emacs_cv_personality_linux32=no)
1230 AC_MSG_RESULT($emacs_cv_personality_linux32)
1231
1232 if test $emacs_cv_personality_linux32 = yes; then
1233   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1234             [Define to 1 if personality LINUX32 can be set.])
1235 fi
1236
1237 dnl On Solaris 8 there's a compilation warning for term.h because
1238 dnl it doesn't define `bool'.
1239 AC_CHECK_HEADERS(term.h, , , -)
1240 AC_HEADER_TIME
1241 AC_CHECK_DECLS([sys_siglist])
1242 if test $ac_cv_have_decl_sys_siglist != yes; then
1243   # For Tru64, at least:
1244   AC_CHECK_DECLS([__sys_siglist])
1245   if test $ac_cv_have_decl___sys_siglist = yes; then
1246     AC_DEFINE(sys_siglist, __sys_siglist,
1247               [Define to any substitute for sys_siglist.])
1248   fi
1249 fi
1250 AC_HEADER_SYS_WAIT
1251
1252 dnl Check for speed_t typedef.
1253 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1254   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <termios.h>]], [[speed_t x = 1;]])],
1255     emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1256 if test $emacs_cv_speed_t = yes; then
1257   AC_DEFINE(HAVE_SPEED_T, 1,
1258            [Define to 1 if `speed_t' is declared by <termios.h>.])
1259 fi
1260
1261 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1262 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]],
1263 [[static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;]])],
1264   emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1265 HAVE_EXCEPTION=$emacs_cv_struct_exception
1266 dnl Define on Darwin so emacs symbols will not conflict with those
1267 dnl in the System framework.  Otherwise -prebind will not work.
1268 if test $emacs_cv_struct_exception != yes || test $opsys = darwin; then
1269   AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1270 fi
1271
1272 AC_CHECK_HEADERS_ONCE(sys/socket.h)
1273 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1274 #if HAVE_SYS_SOCKET_H
1275 #include <sys/socket.h>
1276 #endif])
1277 AC_CHECK_HEADERS(ifaddrs.h, , , [AC_INCLUDES_DEFAULT
1278 #if HAVE_SYS_SOCKET_H
1279 #include <sys/socket.h>
1280 #endif])
1281 AC_CHECK_HEADERS(net/if_dl.h, , , [AC_INCLUDES_DEFAULT
1282 #if HAVE_SYS_SOCKET_H
1283 #include <sys/socket.h>
1284 #endif])
1285
1286 dnl checks for structure members
1287 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1288                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1289                   struct ifreq.ifr_addr,
1290                   struct ifreq.ifr_addr.sa_len], , ,
1291                  [AC_INCLUDES_DEFAULT
1292 #if HAVE_SYS_SOCKET_H
1293 #include <sys/socket.h>
1294 #endif
1295 #if HAVE_NET_IF_H
1296 #include <net/if.h>
1297 #endif])
1298
1299 dnl Check for endianness.
1300 dnl AC_C_BIGENDIAN is done by gnulib.
1301
1302 dnl check for Make feature
1303 dnl AC_PROG_MAKE_SET is done by Automake.
1304
1305 DEPFLAGS=
1306 MKDEPDIR=":"
1307 deps_frag=deps.mk
1308 dnl check for GNU Make if we have GCC and autodepend is on.
1309 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1310    AC_MSG_CHECKING([whether we are using GNU Make])
1311    HAVE_GNU_MAKE=no
1312    testval=`${MAKE-make} --version 2>/dev/null | grep 'GNU Make'`
1313    if test "x$testval" != x; then
1314       HAVE_GNU_MAKE=yes
1315    else
1316       ac_enable_autodepend=no
1317    fi
1318    AC_MSG_RESULT([$HAVE_GNU_MAKE])
1319    if test $HAVE_GNU_MAKE = yes; then
1320       AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1321       SAVE_CFLAGS="$CFLAGS"
1322       CFLAGS="$CFLAGS -MMD -MF deps.d -MP"
1323       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], , ac_enable_autodepend=no)
1324       CFLAGS="$SAVE_CFLAGS"
1325       test -f deps.d || ac_enable_autodepend=no
1326       rm -rf deps.d
1327       AC_MSG_RESULT([$ac_enable_autodepend])
1328    fi
1329    if test $ac_enable_autodepend = yes; then
1330       DEPFLAGS='-MMD -MF ${DEPDIR}/$*.d -MP'
1331       ## MKDIR_P is documented (see AC_PROG_MKDIR_P) to be parallel-safe.
1332       MKDEPDIR='${MKDIR_P} ${DEPDIR}'
1333       deps_frag=autodeps.mk
1334    fi
1335 fi
1336 deps_frag=$srcdir/src/$deps_frag
1337 AC_SUBST(MKDEPDIR)
1338 AC_SUBST(DEPFLAGS)
1339 AC_SUBST_FILE(deps_frag)
1340
1341
1342 lisp_frag=$srcdir/src/lisp.mk
1343 AC_SUBST_FILE(lisp_frag)
1344
1345
1346 dnl checks for operating system services
1347 AC_SYS_LONG_FILE_NAMES
1348
1349 #### Choose a window system.
1350
1351 AC_PATH_X
1352 if test "$no_x" = yes; then
1353   window_system=none
1354 else
1355   window_system=x11
1356 fi
1357
1358 LD_SWITCH_X_SITE_RPATH=
1359 if test "${x_libraries}" != NONE; then
1360   if test -n "${x_libraries}"; then
1361     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1362     LD_SWITCH_X_SITE_RPATH=-Wl,-rpath,`echo ${x_libraries} | sed -e "s/:/ -Wl,-rpath,/g"`
1363   fi
1364   x_default_search_path=""
1365   x_search_path=${x_libraries}
1366   if test -z "${x_search_path}"; then
1367     x_search_path=/usr/lib
1368   fi
1369   for x_library in `echo ${x_search_path}: | \
1370                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1371     x_search_path="\
1372 ${x_library}/X11/%L/%T/%N%C%S:\
1373 ${x_library}/X11/%l/%T/%N%C%S:\
1374 ${x_library}/X11/%T/%N%C%S:\
1375 ${x_library}/X11/%L/%T/%N%S:\
1376 ${x_library}/X11/%l/%T/%N%S:\
1377 ${x_library}/X11/%T/%N%S"
1378     if test x"${x_default_search_path}" = x; then
1379       x_default_search_path=${x_search_path}
1380     else
1381       x_default_search_path="${x_search_path}:${x_default_search_path}"
1382     fi
1383   done
1384 fi
1385 AC_SUBST(LD_SWITCH_X_SITE_RPATH)
1386
1387 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1388   C_SWITCH_X_SITE="$isystem"`echo ${x_includes} | sed -e "s/:/ $isystem/g"`
1389 fi
1390
1391 if test x"${x_includes}" = x; then
1392   bitmapdir=/usr/include/X11/bitmaps
1393 else
1394   # accumulate include directories that have X11 bitmap subdirectories
1395   bmd_acc="dummyval"
1396   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1397     if test -d "${bmd}/X11/bitmaps"; then
1398       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1399     fi
1400     if test -d "${bmd}/bitmaps"; then
1401       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1402     fi
1403   done
1404   if test ${bmd_acc} != "dummyval"; then
1405     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1406   fi
1407 fi
1408
1409 HAVE_NS=no
1410 NS_IMPL_COCOA=no
1411 NS_IMPL_GNUSTEP=no
1412 tmp_CPPFLAGS="$CPPFLAGS"
1413 tmp_CFLAGS="$CFLAGS"
1414 CPPFLAGS="$CPPFLAGS -x objective-c"
1415 CFLAGS="$CFLAGS -x objective-c"
1416 TEMACS_LDFLAGS2="\${LDFLAGS}"
1417 GNU_OBJC_CFLAGS=
1418 if test "${with_ns}" != no; then
1419   if test "${opsys}" = darwin; then
1420      NS_IMPL_COCOA=yes
1421      ns_appdir=`pwd`/nextstep/Emacs.app
1422      ns_appbindir=${ns_appdir}/Contents/MacOS
1423      ns_appresdir=${ns_appdir}/Contents/Resources
1424      ns_appsrc=${srcdir}/nextstep/Cocoa/Emacs.base
1425   elif test -f $GNUSTEP_CONFIG_FILE; then
1426      NS_IMPL_GNUSTEP=yes
1427      ns_appdir=`pwd`/nextstep/Emacs.app
1428      ns_appbindir=${ns_appdir}
1429      ns_appresdir=${ns_appdir}/Resources
1430      ns_appsrc=${srcdir}/nextstep/GNUstep/Emacs.base
1431      dnl FIXME sourcing this several times in subshells seems inefficient.
1432      GNUSTEP_SYSTEM_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_HEADERS)"
1433      GNUSTEP_SYSTEM_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_LIBRARIES)"
1434      dnl I seemed to need these as well with GNUstep-startup 0.25.
1435      GNUSTEP_LOCAL_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_HEADERS)"
1436      GNUSTEP_LOCAL_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_LIBRARIES)"
1437      test "x${GNUSTEP_LOCAL_HEADERS}" != "x" && \
1438        GNUSTEP_LOCAL_HEADERS="-I${GNUSTEP_LOCAL_HEADERS}"
1439      test "x${GNUSTEP_LOCAL_LIBRARIES}" != "x" && \
1440        GNUSTEP_LOCAL_LIBRARIES="-L${GNUSTEP_LOCAL_LIBRARIES}"
1441      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1442      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1443      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES}"
1444      LIB_STANDARD=
1445      START_FILES=
1446      TEMACS_LDFLAGS2=
1447      dnl GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS to 0 or 1.
1448      dnl If they had chosen to either define it or not, we could have
1449      dnl just used AC_CHECK_DECL here.
1450      AC_CACHE_CHECK(if GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS,
1451        emacs_cv_objc_exceptions,
1452 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <GNUstepBase/GSConfig.h>]],
1453 [[#if defined BASE_NATIVE_OBJC_EXCEPTIONS && BASE_NATIVE_OBJC_EXCEPTIONS > 0
1454 1;
1455 #else
1456 fail;
1457 #endif]])], emacs_cv_objc_exceptions=yes, emacs_cv_objc_exceptions=no ) )
1458      if test $emacs_cv_objc_exceptions = yes; then
1459        dnl _NATIVE_OBJC_EXCEPTIONS is used by the GNUstep headers.
1460        AC_DEFINE(_NATIVE_OBJC_EXCEPTIONS, 1,
1461          [Define if GNUstep uses ObjC exceptions.])
1462        GNU_OBJC_CFLAGS="-fobjc-exceptions"
1463      fi
1464   fi
1465
1466   dnl This is only used while we test the NS headers, it gets reset below.
1467   CFLAGS="$CFLAGS $GNU_OBJC_CFLAGS"
1468
1469   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1470                   [AC_MSG_ERROR([`--with-ns' was specified, but the include
1471   files are missing or cannot be compiled.])])
1472   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <Foundation/NSObjCRuntime.h>],
1473                                      [NSInteger i;])],
1474                     ns_have_nsinteger=yes,
1475                     ns_have_nsinteger=no)
1476   if test $ns_have_nsinteger = yes; then
1477     AC_DEFINE(NS_HAVE_NSINTEGER, 1, [Define to 1 if `NSInteger' is defined.])
1478   fi
1479 fi
1480 AC_SUBST(TEMACS_LDFLAGS2)
1481
1482 INSTALL_ARCH_INDEP_EXTRA=install-etc
1483 ns_self_contained=no
1484 ns_frag=/dev/null
1485 NS_OBJ=
1486 NS_OBJC_OBJ=
1487 if test "${HAVE_NS}" = yes; then
1488   if test "$with_toolkit_scroll_bars" = "no"; then
1489     AC_MSG_ERROR([Non-toolkit scroll bars are not implemented for Nextstep.])
1490   fi
1491
1492   window_system=nextstep
1493   with_xft=no
1494   # set up packaging dirs
1495   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1496      ns_self_contained=yes
1497      prefix=${ns_appresdir}
1498      exec_prefix=${ns_appbindir}
1499      dnl This one isn't really used, only archlibdir is.
1500      libexecdir="\${ns_appbindir}/libexec"
1501      archlibdir="\${ns_appbindir}/libexec"
1502      docdir="\${ns_appresdir}/etc"
1503      etcdir="\${ns_appresdir}/etc"
1504      dnl FIXME maybe set datarootdir instead.
1505      dnl That would also get applications, icons, man.
1506      infodir="\${ns_appresdir}/info"
1507      mandir="\${ns_appresdir}/man"
1508      lispdir="\${ns_appresdir}/lisp"
1509      leimdir="\${ns_appresdir}/leim"
1510      INSTALL_ARCH_INDEP_EXTRA=
1511   fi
1512   ns_frag=$srcdir/src/ns.mk
1513   NS_OBJ="fontset.o fringe.o image.o"
1514   NS_OBJC_OBJ="nsterm.o nsfns.o nsmenu.o nsselect.o nsimage.o nsfont.o"
1515 fi
1516 CFLAGS="$tmp_CFLAGS"
1517 CPPFLAGS="$tmp_CPPFLAGS"
1518 AC_SUBST(INSTALL_ARCH_INDEP_EXTRA)
1519 AC_SUBST(ns_self_contained)
1520 AC_SUBST(NS_OBJ)
1521 AC_SUBST(NS_OBJC_OBJ)
1522 AC_SUBST(LIB_STANDARD)
1523 AC_SUBST_FILE(ns_frag)
1524
1525 case "${window_system}" in
1526   x11 )
1527     HAVE_X_WINDOWS=yes
1528     HAVE_X11=yes
1529     case "${with_x_toolkit}" in
1530       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1531       motif ) USE_X_TOOLKIT=MOTIF ;;
1532       gtk ) with_gtk=yes
1533 dnl Don't set this for GTK.  A lot of tests below assumes Xt when
1534 dnl USE_X_TOOLKIT is set.
1535             USE_X_TOOLKIT=none ;;
1536       gtk3 ) with_gtk3=yes
1537              USE_X_TOOLKIT=none ;;
1538       no ) USE_X_TOOLKIT=none ;;
1539 dnl If user did not say whether to use a toolkit, make this decision later:
1540 dnl use the toolkit if we have gtk, or X11R5 or newer.
1541       * ) USE_X_TOOLKIT=maybe ;;
1542     esac
1543   ;;
1544   nextstep | none )
1545     HAVE_X_WINDOWS=no
1546     HAVE_X11=no
1547     USE_X_TOOLKIT=none
1548   ;;
1549 esac
1550
1551 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1552    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1553    if test "$HAVE_XSERVER" = true ||
1554       test -n "$DISPLAY" ||
1555       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1556         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1557 were found.  You should install the relevant development files for X
1558 and for the toolkit you want, such as Gtk+, Lesstif or Motif.  Also make
1559 sure you have development files for image handling, i.e.
1560 tiff, gif, jpeg, png and xpm.
1561 If you are sure you want Emacs compiled without X window support, pass
1562   --without-x
1563 to configure.])
1564    fi
1565 fi
1566
1567 ### If we're using X11, we should use the X menu package.
1568 HAVE_MENUS=no
1569 case ${HAVE_X11} in
1570   yes ) HAVE_MENUS=yes ;;
1571 esac
1572
1573 # Does the opsystem file prohibit the use of the GNU malloc?
1574 # Assume not, until told otherwise.
1575 GNU_MALLOC=yes
1576
1577 AC_CACHE_CHECK(
1578   [whether malloc is Doug Lea style],
1579   [emacs_cv_var_doug_lea_malloc],
1580   [AC_LINK_IFELSE(
1581      [AC_LANG_PROGRAM(
1582         [[#include <malloc.h>
1583           static void hook (void) {}]],
1584         [[malloc_set_state (malloc_get_state ());
1585           __after_morecore_hook = hook;
1586           __malloc_initialize_hook = hook;]])],
1587      [emacs_cv_var_doug_lea_malloc=yes],
1588      [emacs_cv_var_doug_lea_malloc=no])])
1589 doug_lea_malloc=$emacs_cv_var_doug_lea_malloc
1590
1591
1592 dnl See comments in aix4-2.h about maybe using system malloc there.
1593 system_malloc=no
1594 case "$opsys" in
1595   ## darwin ld insists on the use of malloc routines in the System framework.
1596   darwin|sol2-10) system_malloc=yes ;;
1597 esac
1598
1599 if test "${system_malloc}" = "yes"; then
1600   AC_DEFINE(SYSTEM_MALLOC, 1, [Define to use system malloc.])
1601   GNU_MALLOC=no
1602   GNU_MALLOC_reason="
1603     (The GNU allocators don't work with this system configuration.)"
1604   GMALLOC_OBJ=
1605   VMLIMIT_OBJ=
1606 else
1607   test "$doug_lea_malloc" != "yes" && GMALLOC_OBJ=gmalloc.o
1608   VMLIMIT_OBJ=vm-limit.o
1609 fi
1610 AC_SUBST(GMALLOC_OBJ)
1611 AC_SUBST(VMLIMIT_OBJ)
1612
1613 if test "$doug_lea_malloc" = "yes" ; then
1614   if test "$GNU_MALLOC" = yes ; then
1615     GNU_MALLOC_reason="
1616       (Using Doug Lea's new malloc from the GNU C Library.)"
1617   fi
1618   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1619             [Define to 1 if you are using the GNU C Library.])
1620
1621   ## Use mmap directly for allocating larger buffers.
1622   ## FIXME this comes from src/s/{gnu,gnu-linux}.h:
1623   ## #ifdef DOUG_LEA_MALLOC; #undef REL_ALLOC; #endif
1624   ## Does the AC_FUNC_MMAP test below make this check unnecessary?
1625   case "$opsys" in
1626     gnu*) REL_ALLOC=no ;;
1627   esac
1628 fi
1629
1630 if test x"${REL_ALLOC}" = x; then
1631   REL_ALLOC=${GNU_MALLOC}
1632 fi
1633
1634 use_mmap_for_buffers=no
1635 case "$opsys" in
1636   cygwin|freebsd|irix6-5) use_mmap_for_buffers=yes ;;
1637 esac
1638
1639 AC_FUNC_MMAP
1640 if test $use_mmap_for_buffers = yes; then
1641   AC_DEFINE(USE_MMAP_FOR_BUFFERS, 1, [Define to use mmap to allocate buffer text.])
1642   REL_ALLOC=no
1643 fi
1644
1645 LIBS="$LIBS_SYSTEM $LIBS"
1646
1647 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1648 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1649 AC_CHECK_LIB(dnet, dnet_ntoa)
1650 dnl This causes -lresolv to get used in subsequent tests,
1651 dnl which causes failures on some systems such as HPUX 9.
1652 dnl AC_CHECK_LIB(resolv, gethostbyname)
1653
1654 dnl FIXME replace main with a function we actually want from this library.
1655 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1656
1657 dnl Check if pthreads is available.
1658 LIB_PTHREAD=
1659 AC_CHECK_HEADERS_ONCE(pthread.h)
1660 if test "$ac_cv_header_pthread_h"; then
1661   dnl gmalloc.c uses pthread_atfork, which is not available on older-style
1662   dnl hosts such as MirBSD 10, so test for pthread_atfork instead of merely
1663   dnl testing for pthread_self if Emacs uses gmalloc.c.
1664   if test "$GMALLOC_OBJ" = gmalloc.o; then
1665     emacs_pthread_function=pthread_atfork
1666   else
1667     emacs_pthread_function=pthread_self
1668   fi
1669   AC_CHECK_LIB(pthread, $emacs_pthread_function, HAVE_PTHREAD=yes)
1670 fi
1671 if test "$HAVE_PTHREAD" = yes; then
1672   case "${canonical}" in
1673     *-hpux*) ;;
1674     *) LIB_PTHREAD="-lpthread"
1675        LIBS="$LIB_PTHREAD $LIBS" ;;
1676   esac
1677   AC_DEFINE(HAVE_PTHREAD, 1, [Define to 1 if you have pthread (-lpthread).])
1678 fi
1679 AC_SUBST([LIB_PTHREAD])
1680
1681 AC_CHECK_LIB(pthreads, cma_open)
1682
1683 ## Note: when using cpp in s/aix4.2.h, this definition depended on
1684 ## HAVE_LIBPTHREADS.  That was not defined earlier in configure when
1685 ## the system file was sourced.  Hence the value of LIBS_SYSTEM
1686 ## added to LIBS in configure would never contain the pthreads part,
1687 ## but the value used in Makefiles might.  FIXME?
1688 ##
1689 ## -lpthreads seems to be necessary for Xlib in X11R6, and should
1690 ## be harmless on older versions of X where it happens to exist.
1691 test "$opsys" = "aix4-2" && \
1692   test $ac_cv_lib_pthreads_cma_open = yes && \
1693   LIBS_SYSTEM="$LIBS_SYSTEM -lpthreads"
1694
1695 dnl Check for need for bigtoc support on IBM AIX
1696
1697 case ${host_os} in
1698 aix*)
1699   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1700     case $GCC in
1701     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1702     *) gdb_cv_bigtoc=-bbigtoc ;;
1703     esac
1704
1705     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1706     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[int i;]])], [], [gdb_cv_bigtoc=])
1707   ])
1708   ;;
1709 esac
1710
1711 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1712 # used for the tests that follow.  We set them back to REAL_CFLAGS and
1713 # REAL_CPPFLAGS later on.
1714
1715 REAL_CFLAGS="$CFLAGS"
1716 REAL_CPPFLAGS="$CPPFLAGS"
1717
1718 if test "${HAVE_X11}" = "yes"; then
1719   DEFS="$C_SWITCH_X_SITE $DEFS"
1720   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1721   LIBS="-lX11 $LIBS"
1722   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1723   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1724
1725   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1726   # This is handled by LD_SWITCH_X_SITE_RPATH during the real build,
1727   # but it's more convenient here to set LD_RUN_PATH since this
1728   # also works on hosts that don't understand LD_SWITCH_X_SITE_RPATH.
1729   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1730     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1731     export LD_RUN_PATH
1732   fi
1733
1734   if test "${opsys}" = "gnu-linux"; then
1735     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1736     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
1737      [[XOpenDisplay ("foo");]])],
1738      [xgnu_linux_first_failure=no],
1739      [xgnu_linux_first_failure=yes])
1740     if test "${xgnu_linux_first_failure}" = "yes"; then
1741       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1742       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1743       OLD_CPPFLAGS="$CPPFLAGS"
1744       OLD_LIBS="$LIBS"
1745       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1746       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1747       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1748       LIBS="$LIBS -b i486-linuxaout"
1749       AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
1750        [[XOpenDisplay ("foo");]])],
1751        [xgnu_linux_second_failure=no],
1752        [xgnu_linux_second_failure=yes])
1753       if test "${xgnu_linux_second_failure}" = "yes"; then
1754         # If we get the same failure with -b, there is no use adding -b.
1755         # So take it out.  This plays safe.
1756         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1757         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1758         CPPFLAGS="$OLD_CPPFLAGS"
1759         LIBS="$OLD_LIBS"
1760         AC_MSG_RESULT(no)
1761       else
1762         AC_MSG_RESULT(yes)
1763       fi
1764     else
1765       AC_MSG_RESULT(no)
1766     fi
1767   fi
1768
1769   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1770   # header files included from there.
1771   AC_MSG_CHECKING(for Xkb)
1772   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
1773 #include <X11/XKBlib.h>]],
1774         [[XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);]])],
1775         emacs_xkb=yes, emacs_xkb=no)
1776   AC_MSG_RESULT($emacs_xkb)
1777   if test $emacs_xkb = yes; then
1778     AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1779   fi
1780
1781   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1782 XScreenNumberOfScreen)
1783 fi
1784
1785 if test "${window_system}" = "x11"; then
1786   AC_MSG_CHECKING(X11 version 6)
1787   AC_CACHE_VAL(emacs_cv_x11_version_6,
1788   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>]],
1789 [[#if XlibSpecificationRelease < 6
1790 fail;
1791 #endif
1792 ]])], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1793   if test $emacs_cv_x11_version_6 = yes; then
1794     AC_MSG_RESULT(6 or newer)
1795     AC_DEFINE(HAVE_X11R6, 1,
1796               [Define to 1 if you have the X11R6 or newer version of Xlib.])
1797     AC_DEFINE(HAVE_X_I18N, 1, [Define if you have usable i18n support.])
1798     ## inoue@ainet.or.jp says Solaris has a bug related to X11R6-style
1799     ## XIM support.
1800     case "$opsys" in
1801       sol2-*) : ;;
1802       *) AC_DEFINE(HAVE_X11R6_XIM, 1,
1803            [Define if you have usable X11R6-style XIM support.])
1804          ;;
1805     esac
1806   else
1807     AC_MSG_RESULT(before 6)
1808   fi
1809 fi
1810
1811
1812 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
1813 HAVE_RSVG=no
1814 if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes"; then
1815   if test "${with_rsvg}" != "no"; then
1816     RSVG_REQUIRED=2.11.0
1817     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
1818
1819     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, HAVE_RSVG=yes, :)
1820     AC_SUBST(RSVG_CFLAGS)
1821     AC_SUBST(RSVG_LIBS)
1822
1823     if test $HAVE_RSVG = yes; then
1824       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
1825       CFLAGS="$CFLAGS $RSVG_CFLAGS"
1826       LIBS="$RSVG_LIBS $LIBS"
1827     fi
1828   fi
1829 fi
1830
1831 HAVE_IMAGEMAGICK=no
1832 if test "${HAVE_X11}" = "yes"; then
1833   if test "${with_imagemagick}" != "no"; then
1834     ## 6.2.8 is the earliest version known to work, but earlier versions
1835     ## might work - let us know if you find one.
1836     ## 6.0.7 does not work.  See bug#7955.
1837     IMAGEMAGICK_MODULE="Wand >= 6.2.8"
1838     PKG_CHECK_MODULES(IMAGEMAGICK, $IMAGEMAGICK_MODULE, HAVE_IMAGEMAGICK=yes, :)
1839     AC_SUBST(IMAGEMAGICK_CFLAGS)
1840     AC_SUBST(IMAGEMAGICK_LIBS)
1841
1842     if test $HAVE_IMAGEMAGICK = yes; then
1843       AC_DEFINE(HAVE_IMAGEMAGICK, 1, [Define to 1 if using imagemagick.])
1844       CFLAGS="$CFLAGS $IMAGEMAGICK_CFLAGS"
1845       LIBS="$IMAGEMAGICK_LIBS $LIBS"
1846       AC_CHECK_FUNCS(MagickExportImagePixels MagickMergeImageLayers)
1847     fi
1848   fi
1849 fi
1850
1851
1852 HAVE_GTK=no
1853 GTK_OBJ=
1854 if test "${with_gtk3}" = "yes"; then
1855   GLIB_REQUIRED=2.28
1856   GTK_REQUIRED=3.0
1857   GTK_MODULES="gtk+-3.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1858
1859   dnl Checks for libraries.
1860   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1861   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1862      AC_MSG_ERROR($GTK_PKG_ERRORS)
1863   fi
1864   AC_DEFINE(HAVE_GTK3, 1, [Define to 1 if using GTK 3 or later.])
1865   GTK_OBJ=emacsgtkfixed.o
1866 fi
1867
1868 if test "$pkg_check_gtk" != "yes"; then
1869   HAVE_GTK=no
1870 if test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
1871   GLIB_REQUIRED=2.10
1872   GTK_REQUIRED=2.10
1873   GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1874
1875   dnl Checks for libraries.
1876   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1877   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1878      AC_MSG_ERROR($GTK_PKG_ERRORS)
1879   fi
1880 fi
1881 fi
1882
1883 if test x"$pkg_check_gtk" = xyes; then
1884
1885   AC_SUBST(GTK_CFLAGS)
1886   AC_SUBST(GTK_LIBS)
1887   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
1888   CFLAGS="$CFLAGS $GTK_CFLAGS"
1889   LIBS="$GTK_LIBS $LIBS"
1890   dnl Try to compile a simple GTK program.
1891   GTK_COMPILES=no
1892   AC_CHECK_FUNCS(gtk_main, GTK_COMPILES=yes)
1893   if test "${GTK_COMPILES}" != "yes"; then
1894     if test "$USE_X_TOOLKIT" != "maybe"; then
1895       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
1896     fi
1897   else
1898     HAVE_GTK=yes
1899     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
1900     GTK_OBJ="gtkutil.o $GTK_OBJ"
1901     USE_X_TOOLKIT=none
1902     if $PKG_CONFIG --atleast-version=2.10 gtk+-2.0; then
1903       :
1904     else
1905       AC_MSG_WARN([[Your version of Gtk+ will have problems with
1906        closing open displays.  This is no problem if you just use
1907        one display, but if you use more than one and close one of them
1908        Emacs may crash.]])
1909       sleep 3
1910     fi
1911   fi
1912
1913 fi
1914 AC_SUBST(GTK_OBJ)
1915
1916
1917 if test "${HAVE_GTK}" = "yes"; then
1918
1919   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
1920   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
1921   if test "$with_toolkit_scroll_bars" != no; then
1922     with_toolkit_scroll_bars=yes
1923   fi
1924
1925   dnl  Check if we have the old file selection dialog declared and
1926   dnl  in the link library.  In 2.x it may be in the library,
1927   dnl  but not declared if deprecated featured has been selected out.
1928   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
1929   HAVE_GTK_FILE_SELECTION=no
1930   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
1931                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
1932 #include <gtk/gtk.h>])
1933   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
1934     AC_CHECK_FUNCS(gtk_file_selection_new)
1935   fi
1936
1937
1938   dnl Check for functions introduced in 2.14 and later.
1939   AC_CHECK_FUNCS(gtk_widget_get_window gtk_widget_set_has_window \
1940                  gtk_dialog_get_action_area gtk_widget_get_sensitive \
1941                  gtk_widget_get_mapped gtk_adjustment_get_page_size \
1942                  gtk_orientable_set_orientation \
1943                  gtk_window_set_has_resize_grip)
1944 fi
1945
1946 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
1947 dnl other platforms.
1948 HAVE_DBUS=no
1949 DBUS_OBJ=
1950 if test "${with_dbus}" = "yes"; then
1951    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
1952    if test "$HAVE_DBUS" = yes; then
1953      LIBS="$LIBS $DBUS_LIBS"
1954      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
1955      dnl dbus_watch_get_unix_fd has been introduced in D-Bus 1.1.1.
1956      dnl dbus_type_is_valid and dbus_validate_* have been introduced in
1957      dnl D-Bus 1.5.12.
1958      AC_CHECK_FUNCS(dbus_watch_get_unix_fd \
1959                     dbus_type_is_valid \
1960                     dbus_validate_bus_name \
1961                     dbus_validate_path \
1962                     dbus_validate_interface \
1963                     dbus_validate_member)
1964      DBUS_OBJ=dbusbind.o
1965    fi
1966 fi
1967 AC_SUBST(DBUS_OBJ)
1968
1969 dnl GSettings has been tested under GNU/Linux only.
1970 HAVE_GSETTINGS=no
1971 if test "${HAVE_X11}" = "yes" && test "${with_gsettings}" = "yes"; then
1972    PKG_CHECK_MODULES(GSETTINGS, gio-2.0 >= 2.26, HAVE_GSETTINGS=yes, HAVE_GSETTINGS=no)
1973    if test "$HAVE_GSETTINGS" = "yes"; then
1974       AC_DEFINE(HAVE_GSETTINGS, 1, [Define to 1 if using GSettings.])
1975       SETTINGS_CFLAGS="$GSETTINGS_CFLAGS"
1976       SETTINGS_LIBS="$GSETTINGS_LIBS"
1977    fi
1978 fi
1979
1980 dnl GConf has been tested under GNU/Linux only.
1981 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
1982 HAVE_GCONF=no
1983 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
1984    PKG_CHECK_MODULES(GCONF, gconf-2.0 >= 2.13, HAVE_GCONF=yes, HAVE_GCONF=no)
1985    if test "$HAVE_GCONF" = yes; then
1986       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
1987       dnl Newer GConf doesn't link with g_objects, so this is not defined.
1988       SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GCONF_CFLAGS"
1989       SETTINGS_LIBS="$SETTINGS_LIBS $GCONF_LIBS"
1990    fi
1991 fi
1992
1993 if test "$HAVE_GSETTINGS" = "yes" || test "$HAVE_GCONF" = "yes"; then
1994     SAVE_CFLAGS="$CFLAGS"
1995     SAVE_LIBS="$LIBS"
1996     CFLAGS="$SETTINGS_CFLAGS $CFLAGS"
1997     LIBS="$SETTINGS_LIBS $LIBS"
1998     AC_CHECK_FUNCS([g_type_init])
1999     CFLAGS="$SAVE_CFLAGS"
2000     LIBS="$SAVE_LIBS"
2001 fi
2002 AC_SUBST(SETTINGS_CFLAGS)
2003 AC_SUBST(SETTINGS_LIBS)
2004
2005
2006 dnl SELinux is available for GNU/Linux only.
2007 HAVE_LIBSELINUX=no
2008 LIBSELINUX_LIBS=
2009 if test "${with_selinux}" = "yes"; then
2010    AC_CHECK_LIB([selinux], [lgetfilecon], HAVE_LIBSELINUX=yes, HAVE_LIBSELINUX=no)
2011    if test "$HAVE_LIBSELINUX" = yes; then
2012       AC_DEFINE(HAVE_LIBSELINUX, 1, [Define to 1 if using SELinux.])
2013       LIBSELINUX_LIBS=-lselinux
2014    fi
2015 fi
2016 AC_SUBST(LIBSELINUX_LIBS)
2017
2018 HAVE_GNUTLS=no
2019 HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY=no
2020 if test "${with_gnutls}" = "yes" ; then
2021   PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= 2.6.6], HAVE_GNUTLS=yes, HAVE_GNUTLS=no)
2022   if test "${HAVE_GNUTLS}" = "yes"; then
2023     AC_DEFINE(HAVE_GNUTLS, 1, [Define if using GnuTLS.])
2024   fi
2025
2026   CFLAGS="$CFLAGS $LIBGNUTLS_CFLAGS"
2027   LIBS="$LIBGNUTLS_LIBS $LIBS"
2028   AC_CHECK_FUNCS(gnutls_certificate_set_verify_function, HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY=yes)
2029
2030   if test "${HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY}" = "yes"; then
2031     AC_DEFINE(HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY, 1, [Define if using GnuTLS certificate verification callbacks.])
2032   fi
2033 fi
2034
2035 AC_SUBST(LIBGNUTLS_LIBS)
2036 AC_SUBST(LIBGNUTLS_CFLAGS)
2037
2038 dnl Do not put whitespace before the #include statements below.
2039 dnl Older compilers (eg sunos4 cc) choke on it.
2040 HAVE_XAW3D=no
2041 LUCID_LIBW=
2042 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
2043   if test "$with_xaw3d" != no; then
2044     AC_MSG_CHECKING(for xaw3d)
2045     AC_CACHE_VAL(emacs_cv_xaw3d,
2046     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2047 #include <X11/Intrinsic.h>
2048 #include <X11/Xaw3d/Simple.h>]],
2049       [[]])],
2050       [AC_CHECK_LIB(Xaw3d, XawScrollbarSetThumb,
2051                     emacs_cv_xaw3d=yes, emacs_cv_xaw3d=no)],
2052       emacs_cv_xaw3d=no)])
2053   else
2054     emacs_cv_xaw3d=no
2055   fi
2056   if test $emacs_cv_xaw3d = yes; then
2057     AC_MSG_RESULT([yes; using Lucid toolkit])
2058     USE_X_TOOLKIT=LUCID
2059     HAVE_XAW3D=yes
2060     LUCID_LIBW=-lXaw3d
2061     AC_DEFINE(HAVE_XAW3D, 1,
2062               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
2063   else
2064     AC_MSG_RESULT(no)
2065     AC_MSG_CHECKING(for libXaw)
2066     AC_CACHE_VAL(emacs_cv_xaw,
2067     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2068 #include <X11/Intrinsic.h>
2069 #include <X11/Xaw/Simple.h>]],
2070       [[]])],
2071       emacs_cv_xaw=yes,
2072       emacs_cv_xaw=no)])
2073     if test $emacs_cv_xaw = yes; then
2074       AC_MSG_RESULT([yes; using Lucid toolkit])
2075       USE_X_TOOLKIT=LUCID
2076       LUCID_LIBW=-lXaw
2077     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
2078       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
2079     else
2080       AC_MSG_ERROR([No X toolkit could be found.
2081 If you are sure you want Emacs compiled without an X toolkit, pass
2082   --with-x-toolkit=no
2083 to configure.  Otherwise, install the development libraries for the toolkit
2084 that you want to use (e.g. Gtk+) and re-run configure.])
2085     fi
2086   fi
2087 fi
2088
2089 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
2090
2091 LIBXTR6=
2092 if test "${USE_X_TOOLKIT}" != "none"; then
2093   AC_MSG_CHECKING(X11 toolkit version)
2094   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
2095   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Intrinsic.h>]],
2096 [[#if XtSpecificationRelease < 6
2097 fail;
2098 #endif
2099 ]])], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
2100   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
2101   if test $emacs_cv_x11_toolkit_version_6 = yes; then
2102     AC_MSG_RESULT(6 or newer)
2103     AC_DEFINE(HAVE_X11XTR6, 1,
2104               [Define to 1 if you have the X11R6 or newer version of Xt.])
2105     LIBXTR6="-lSM -lICE"
2106     case "$opsys" in
2107       ## Use libw.a along with X11R6 Xt.
2108       unixware) LIBXTR6="$LIBXTR6 -lw" ;;
2109     esac
2110   else
2111     AC_MSG_RESULT(before 6)
2112   fi
2113
2114 dnl If using toolkit, check whether libXmu.a exists.
2115 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
2116   OLDLIBS="$LIBS"
2117   if test x$HAVE_X11XTR6 = xyes; then
2118     LIBS="-lXt -lSM -lICE $LIBS"
2119   else
2120     LIBS="-lXt $LIBS"
2121   fi
2122   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
2123   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
2124   dnl ac_cv_lib_Xmu_XmuConvertStandardSelection is also referenced below.
2125 fi
2126 AC_SUBST(LIBXTR6)
2127
2128 dnl FIXME the logic here seems weird, but this is what cpp was doing.
2129 dnl Why not just test for libxmu in the normal way?
2130 LIBXMU=-lXmu
2131 case $opsys in
2132   ## These systems don't supply Xmu.
2133   hpux* | aix4-2 )
2134     test "X$ac_cv_lib_Xmu_XmuConvertStandardSelection" != "Xyes" && LIBXMU=
2135     ;;
2136 esac
2137 AC_SUBST(LIBXMU)
2138
2139 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
2140 if test "${HAVE_X11}" = "yes"; then
2141   if test "${USE_X_TOOLKIT}" != "none"; then
2142     AC_CHECK_LIB(Xext, XShapeQueryExtension)
2143   fi
2144 fi
2145
2146 LIBXP=
2147 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2148   # OpenMotif may be installed in such a way on some GNU/Linux systems.
2149   if test -d /usr/include/openmotif; then
2150     CPPFLAGS="-I/usr/include/openmotif $CPPFLAGS"
2151     emacs_cv_openmotif=yes
2152     case "$canonical" in
2153       x86_64-*-linux-gnu* | powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*)
2154       test -d /usr/lib64/openmotif && LDFLAGS="-L/usr/lib64/openmotif $LDFLAGS"
2155       ;;
2156       *)
2157       test -d /usr/lib/openmotif && LDFLAGS="-L/usr/lib/openmotif $LDFLAGS"
2158     esac
2159   else
2160     emacs_cv_openmotif=no
2161   fi
2162   AC_CACHE_CHECK(for (Open)Motif version 2.1, emacs_cv_motif_version_2_1,
2163   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <Xm/Xm.h>]],
2164     [[#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
2165 int x = 5;
2166 #else
2167 Motif version prior to 2.1.
2168 #endif]])],
2169     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
2170   if test $emacs_cv_motif_version_2_1 = yes; then
2171     AC_CHECK_LIB(Xp, XpCreateContext, LIBXP=-lXp)
2172     if test x$emacs_cv_openmotif = xyes; then
2173       REAL_CPPFLAGS="-I/usr/include/openmotif $REAL_CPPFLAGS"
2174     fi
2175   else
2176     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
2177     # We put this in CFLAGS temporarily to precede other -I options
2178     # that might be in CFLAGS temporarily.
2179     # We put this in CPPFLAGS where it precedes the other -I options.
2180     OLD_CPPFLAGS=$CPPFLAGS
2181     OLD_CFLAGS=$CFLAGS
2182     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
2183     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
2184     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>]],
2185       [[int x = 5;]])],
2186       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
2187     if test $emacs_cv_lesstif = yes; then
2188       # Make sure this -I option remains in CPPFLAGS after it is set
2189       # back to REAL_CPPFLAGS.
2190       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
2191       # have those other -I options anyway.  Ultimately, having this
2192       # directory ultimately in CPPFLAGS will be enough.
2193       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
2194       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
2195     else
2196       CFLAGS=$OLD_CFLAGS
2197       CPPFLAGS=$OLD_CPPFLAGS
2198     fi
2199   fi
2200   AC_CHECK_HEADER([Xm/BulletinB.h], [],
2201     [AC_MSG_ERROR([Motif toolkit requested but requirements not found.])])
2202 fi
2203
2204 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
2205 dnl using Motif or Xaw3d is available, and unless
2206 dnl --with-toolkit-scroll-bars=no was specified.
2207
2208 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
2209             [Define to 1 if we should use toolkit scroll bars.])dnl
2210 USE_TOOLKIT_SCROLL_BARS=no
2211 if test "${with_toolkit_scroll_bars}" != "no"; then
2212   if test "${USE_X_TOOLKIT}" != "none"; then
2213     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2214       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2215       HAVE_XAW3D=no
2216       USE_TOOLKIT_SCROLL_BARS=yes
2217     elif test "${HAVE_XAW3D}" = "yes" || test "${USE_X_TOOLKIT}" = "LUCID"; then
2218       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2219       USE_TOOLKIT_SCROLL_BARS=yes
2220     fi
2221   elif test "${HAVE_GTK}" = "yes"; then
2222     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2223     USE_TOOLKIT_SCROLL_BARS=yes
2224   elif test "${HAVE_NS}" = "yes"; then
2225     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2226     USE_TOOLKIT_SCROLL_BARS=yes
2227   fi
2228 fi
2229
2230 dnl See if XIM is available.
2231 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2232           #include <X11/Xlib.h>
2233           #include <X11/Xresource.h>]],
2234          [[XIMProc  callback;]])],
2235          [HAVE_XIM=yes
2236          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
2237          HAVE_XIM=no)
2238
2239 dnl `--with-xim' now controls only the initial value of use_xim at run time.
2240
2241 if test "${with_xim}" != "no"; then
2242   AC_DEFINE(USE_XIM, 1,
2243             [Define to 1 if we should use XIM, if it is available.])
2244 fi
2245
2246
2247 if test "${HAVE_XIM}" != "no"; then
2248   late_CFLAGS=$CFLAGS
2249   if test "$GCC" = yes; then
2250     CFLAGS="$CFLAGS --pedantic-errors"
2251   fi
2252   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2253 #include <X11/Xlib.h>
2254 #include <X11/Xresource.h>]],
2255 [[Display *display;
2256 XrmDatabase db;
2257 char *res_name;
2258 char *res_class;
2259 XIMProc  callback;
2260 XPointer *client_data;
2261 #ifndef __GNUC__
2262 /* If we're not using GCC, it's probably not XFree86, and this is
2263    probably right, but we can't use something like --pedantic-errors.  */
2264 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
2265                                            char*, XIMProc, XPointer*);
2266 #endif
2267 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
2268    client_data);]])],
2269     [emacs_cv_arg6_star=yes])
2270   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
2271          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
2272 either XPointer or XPointer*.])dnl
2273   if test "$emacs_cv_arg6_star" = yes; then
2274     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
2275   else
2276     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
2277   fi
2278   CFLAGS=$late_CFLAGS
2279 fi
2280
2281 ### Start of font-backend (under any platform) section.
2282 # (nothing here yet -- this is a placeholder)
2283 ### End of font-backend (under any platform) section.
2284
2285 ### Start of font-backend (under X11) section.
2286 if test "${HAVE_X11}" = "yes"; then
2287    PKG_CHECK_MODULES(FONTCONFIG, fontconfig >= 2.2.0, HAVE_FC=yes, HAVE_FC=no)
2288
2289    ## Use -lXft if available, unless `--with-xft=no'.
2290    HAVE_XFT=maybe
2291     if test "${HAVE_FC}" = "no" || test "x${with_x}" = "xno"; then
2292       with_xft="no";
2293     fi
2294     if test "x${with_xft}" != "xno"; then
2295
2296       PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
2297       ## Because xftfont.c uses XRenderQueryExtension, we also
2298       ## need to link to -lXrender.
2299       HAVE_XRENDER=no
2300       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
2301       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
2302         OLD_CPPFLAGS="$CPPFLAGS"
2303         OLD_CFLAGS="$CFLAGS"
2304         OLD_LIBS="$LIBS"
2305         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
2306         CFLAGS="$CFLAGS $XFT_CFLAGS"
2307         XFT_LIBS="-lXrender $XFT_LIBS"
2308         LIBS="$XFT_LIBS $LIBS"
2309         AC_CHECK_HEADER(X11/Xft/Xft.h,
2310           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS))
2311
2312         if test "${HAVE_XFT}" = "yes"; then
2313           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
2314             AC_SUBST(XFT_LIBS)
2315           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
2316         else
2317           CPPFLAGS="$OLD_CPPFLAGS"
2318           CFLAGS="$OLD_CFLAGS"
2319           LIBS="$OLD_LIBS"
2320         fi                        # "${HAVE_XFT}" = "yes"
2321       fi                          # "$HAVE_XFT" != no
2322     fi                            # "x${with_xft}" != "xno"
2323
2324     ## We used to allow building with FreeType and without Xft.
2325     ## However, the ftx font backend driver is not in good shape.
2326     if test "$HAVE_XFT" != "yes"; then
2327        dnl For the "Does Emacs use" message at the end.
2328        HAVE_XFT=no
2329        HAVE_FREETYPE=no
2330     else
2331        dnl Strict linkers fail with
2332        dnl ftfont.o: undefined reference to symbol 'FT_New_Face'
2333        dnl if -lfreetype is not specified.
2334        dnl The following is needed to set FREETYPE_LIBS.
2335        PKG_CHECK_MODULES(FREETYPE, freetype2, HAVE_FREETYPE=yes,
2336                          HAVE_FREETYPE=no)
2337
2338        test "$HAVE_FREETYPE" = "no" && AC_MSG_ERROR(libxft requires libfreetype)
2339     fi
2340
2341     HAVE_LIBOTF=no
2342     if test "${HAVE_FREETYPE}" = "yes"; then
2343       AC_DEFINE(HAVE_FREETYPE, 1,
2344                 [Define to 1 if using the freetype and fontconfig libraries.])
2345       if test "${with_libotf}" != "no"; then
2346         PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
2347                           HAVE_LIBOTF=no)
2348         if test "$HAVE_LIBOTF" = "yes"; then
2349           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
2350           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
2351                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
2352                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
2353           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
2354             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
2355                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
2356           fi
2357         fi
2358       fi
2359     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
2360     dnl Does the new font backend require it, or can it work without it?
2361     fi
2362
2363     HAVE_M17N_FLT=no
2364     if test "${HAVE_LIBOTF}" = yes; then
2365       if test "${with_m17n_flt}" != "no"; then
2366         PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no)
2367         if test "$HAVE_M17N_FLT" = "yes"; then
2368           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
2369         fi
2370       fi
2371     fi
2372 else
2373     HAVE_XFT=no
2374     HAVE_FREETYPE=no
2375     HAVE_LIBOTF=no
2376     HAVE_M17N_FLT=no
2377 fi
2378
2379 ### End of font-backend (under X11) section.
2380
2381 AC_SUBST(FREETYPE_CFLAGS)
2382 AC_SUBST(FREETYPE_LIBS)
2383 AC_SUBST(FONTCONFIG_CFLAGS)
2384 AC_SUBST(FONTCONFIG_LIBS)
2385 AC_SUBST(LIBOTF_CFLAGS)
2386 AC_SUBST(LIBOTF_LIBS)
2387 AC_SUBST(M17N_FLT_CFLAGS)
2388 AC_SUBST(M17N_FLT_LIBS)
2389
2390 ### Use -lXpm if available, unless `--with-xpm=no'.
2391 HAVE_XPM=no
2392 LIBXPM=
2393 if test "${HAVE_X11}" = "yes"; then
2394   if test "${with_xpm}" != "no"; then
2395     AC_CHECK_HEADER(X11/xpm.h,
2396       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
2397     if test "${HAVE_XPM}" = "yes"; then
2398       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2399       AC_EGREP_CPP(no_return_alloc_pixels,
2400       [#include "X11/xpm.h"
2401 #ifndef XpmReturnAllocPixels
2402 no_return_alloc_pixels
2403 #endif
2404       ], HAVE_XPM=no, HAVE_XPM=yes)
2405
2406       if test "${HAVE_XPM}" = "yes"; then
2407         AC_MSG_RESULT(yes)
2408       else
2409         AC_MSG_RESULT(no)
2410       fi
2411     fi
2412   fi
2413
2414   if test "${HAVE_XPM}" = "yes"; then
2415     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
2416     LIBXPM=-lXpm
2417   fi
2418 fi
2419 AC_SUBST(LIBXPM)
2420
2421 ### Use -ljpeg if available, unless `--with-jpeg=no'.
2422 HAVE_JPEG=no
2423 LIBJPEG=
2424 if test "${HAVE_X11}" = "yes"; then
2425   if test "${with_jpeg}" != "no"; then
2426     dnl Checking for jpeglib.h can lose because of a redefinition of
2427     dnl  HAVE_STDLIB_H.
2428     AC_CHECK_HEADER(jerror.h,
2429       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
2430   fi
2431
2432   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
2433   if test "${HAVE_JPEG}" = "yes"; then
2434     AC_DEFINE(HAVE_JPEG)
2435     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
2436         [#include <jpeglib.h>
2437          version=JPEG_LIB_VERSION
2438 ],
2439         [AC_DEFINE(HAVE_JPEG)],
2440         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
2441         HAVE_JPEG=no])
2442   fi
2443   if test "${HAVE_JPEG}" = "yes"; then
2444     LIBJPEG=-ljpeg
2445   fi
2446 fi
2447 AC_SUBST(LIBJPEG)
2448
2449 ### Use -lpng if available, unless `--with-png=no'.
2450 HAVE_PNG=no
2451 LIBPNG=
2452 if test "${HAVE_X11}" = "yes"; then
2453   if test "${with_png}" != "no"; then
2454     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
2455     # in /usr/include/libpng.
2456     AC_CHECK_HEADERS(png.h libpng/png.h, break)
2457     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
2458       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
2459     fi
2460   fi
2461
2462   if test "${HAVE_PNG}" = "yes"; then
2463     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2464     LIBPNG="-lpng -lz -lm"
2465
2466     AC_CHECK_DECL(png_longjmp,
2467       [],
2468       [AC_DEFINE(PNG_DEPSTRUCT, [],
2469          [Define to empty to suppress deprecation warnings when building
2470           with --enable-gcc-warnings and with libpng versions before 1.5,
2471           which lack png_longjmp.])],
2472       [[#ifdef HAVE_LIBPNG_PNG_H
2473         # include <libpng/png.h>
2474         #else
2475         # include <png.h>
2476         #endif
2477       ]])
2478   fi
2479 fi
2480 AC_SUBST(LIBPNG)
2481
2482 ### Use -ltiff if available, unless `--with-tiff=no'.
2483 HAVE_TIFF=no
2484 LIBTIFF=
2485 if test "${HAVE_X11}" = "yes"; then
2486   if test "${with_tiff}" != "no"; then
2487     AC_CHECK_HEADER(tiffio.h,
2488       [tifflibs="-lz -lm"
2489       # At least one tiff package requires the jpeg library.
2490       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
2491       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
2492   fi
2493
2494   if test "${HAVE_TIFF}" = "yes"; then
2495     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2496     dnl FIXME -lz -lm, as per libpng?
2497     LIBTIFF=-ltiff
2498   fi
2499 fi
2500 AC_SUBST(LIBTIFF)
2501
2502 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
2503 HAVE_GIF=no
2504 LIBGIF=
2505 if test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no"; then
2506   AC_CHECK_HEADER(gif_lib.h,
2507 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2508 # Earlier versions can crash Emacs.
2509     [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])
2510
2511   if test "$HAVE_GIF" = yes; then
2512     LIBGIF=-lgif
2513   elif test "$HAVE_GIF" = maybe; then
2514 # If gif_lib.h but no libgif, try libungif.
2515     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
2516     test "$HAVE_GIF" = yes && LIBGIF=-lungif
2517   fi
2518
2519   if test "${HAVE_GIF}" = "yes"; then
2520     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
2521   fi
2522 fi
2523 AC_SUBST(LIBGIF)
2524
2525 dnl Check for required libraries.
2526 if test "${HAVE_X11}" = "yes"; then
2527   MISSING=""
2528   WITH_NO=""
2529   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
2530     MISSING="libXpm" && WITH_NO="--with-xpm=no"
2531   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
2532     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
2533   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
2534     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
2535   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
2536     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
2537   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
2538     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
2539
2540   if test "X${MISSING}" != X; then
2541     AC_MSG_ERROR([The following required libraries were not found:
2542     $MISSING
2543 Maybe some development libraries/packages are missing?
2544 If you don't want to link with them give
2545     $WITH_NO
2546 as options to configure])
2547   fi
2548 fi
2549
2550 ### Use -lgpm if available, unless `--with-gpm=no'.
2551 HAVE_GPM=no
2552 LIBGPM=
2553 if test "${with_gpm}" != "no"; then
2554   AC_CHECK_HEADER(gpm.h,
2555     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
2556
2557   if test "${HAVE_GPM}" = "yes"; then
2558     AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
2559     LIBGPM=-lgpm
2560   fi
2561 fi
2562 AC_SUBST(LIBGPM)
2563
2564 dnl Check for malloc/malloc.h on darwin
2565 AC_CHECK_HEADERS_ONCE(malloc/malloc.h)
2566
2567 GNUSTEP_CFLAGS=
2568 ### Use NeXTstep API to implement GUI.
2569 if test "${HAVE_NS}" = "yes"; then
2570   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
2571   if test "${NS_IMPL_COCOA}" = "yes"; then
2572     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
2573   fi
2574   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
2575     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
2576     # See also .m.o rule in Makefile.in */
2577     # FIXME: are all these flags really needed?  Document here why.  */
2578     GNUSTEP_CFLAGS="-D_REENTRANT -fPIC -fno-strict-aliasing -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
2579     ## Extra CFLAGS applied to src/*.m files.
2580     GNU_OBJC_CFLAGS="$GNU_OBJC_CFLAGS -fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
2581   fi
2582   # We also have mouse menus.
2583   HAVE_MENUS=yes
2584   OTHER_FILES=ns-app
2585 fi
2586
2587
2588 ### Use session management (-lSM -lICE) if available
2589 HAVE_X_SM=no
2590 LIBXSM=
2591 if test "${HAVE_X11}" = "yes"; then
2592   AC_CHECK_HEADER(X11/SM/SMlib.h,
2593     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
2594
2595   if test "${HAVE_X_SM}" = "yes"; then
2596     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2597     LIBXSM="-lSM -lICE"
2598     case "$LIBS" in
2599       *-lSM*) ;;
2600       *)      LIBS="$LIBXSM $LIBS" ;;
2601     esac
2602   fi
2603 fi
2604 AC_SUBST(LIBXSM)
2605
2606 ### Use libxml (-lxml2) if available
2607 HAVE_LIBXML2=no
2608 if test "${with_xml2}" != "no"; then
2609   ### I'm not sure what the version number should be, so I just guessed.
2610   PKG_CHECK_MODULES(LIBXML2, libxml-2.0 > 2.6.17, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
2611   if test "${HAVE_LIBXML2}" = "yes"; then
2612     LIBS="$LIBXML2_LIBS $LIBS"
2613     AC_CHECK_LIB(xml2, htmlReadMemory, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
2614     if test "${HAVE_LIBXML2}" = "yes"; then
2615       AC_DEFINE(HAVE_LIBXML2, 1, [Define to 1 if you have the libxml library (-lxml2).])
2616     else
2617       LIBXML2_LIBS=""
2618       LIBXML2_CFLAGS=""
2619     fi
2620   fi
2621 fi
2622 AC_SUBST(LIBXML2_LIBS)
2623 AC_SUBST(LIBXML2_CFLAGS)
2624
2625 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2626 AC_CACHE_CHECK(whether netdb declares h_errno,
2627                emacs_cv_netdb_declares_h_errno,
2628 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
2629   [[return h_errno;]])],
2630   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2631 if test $emacs_cv_netdb_declares_h_errno = yes; then
2632   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2633 fi
2634
2635 # fmod, logb, and frexp are found in -lm on most systems.
2636 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2637 AC_CHECK_LIB(m, sqrt)
2638
2639 # Check for mail-locking functions in a "mail" library.  Probably this should
2640 # have the same check as for liblockfile below.
2641 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
2642 if test $have_mail = yes; then
2643   LIBS_MAIL=-lmail
2644   LIBS="$LIBS_MAIL $LIBS"
2645   AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the `mail' library (-lmail).])
2646 else
2647   LIBS_MAIL=
2648 fi
2649 dnl Debian, at least:
2650 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
2651 if test $have_lockfile = yes; then
2652    LIBS_MAIL=-llockfile
2653    LIBS="$LIBS_MAIL $LIBS"
2654    AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the `lockfile' library (-llockfile).])
2655 else
2656 # If we have the shared liblockfile, assume we must use it for mail
2657 # locking (e.g. Debian).  If we couldn't link against liblockfile
2658 # (no liblockfile.a installed), ensure that we don't need to.
2659   dnl This works for files generally, not just executables.
2660   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
2661   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2662                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2663   if test $ac_cv_prog_liblockfile = yes; then
2664     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2665 This probably means that movemail could lose mail.
2666 There may be a `development' package to install containing liblockfile.])
2667   fi
2668 fi
2669 AC_CHECK_HEADERS_ONCE(maillock.h)
2670 AC_SUBST(LIBS_MAIL)
2671
2672 ## Define MAIL_USE_FLOCK (or LOCKF) if the mailer uses flock (or lockf) to
2673 ## interlock access to the mail spool.  The alternative is a lock file named
2674 ## /usr/spool/mail/$USER.lock.
2675 mail_lock=no
2676 case "$opsys" in
2677   aix4-2) mail_lock="lockf" ;;
2678
2679   gnu|freebsd|netbsd|openbsd|darwin|irix6-5) mail_lock="flock" ;;
2680
2681   ## On GNU/Linux systems, both methods are used by various mail programs.
2682   ## I assume most people are using newer mailers that have heard of flock.
2683   ## Change this if you need to.
2684   ## Debian contains a patch which says: ``On Debian/GNU/Linux systems,
2685   ## configure gets the right answers, and that means *NOT* using flock.
2686   ## Using flock is guaranteed to be the wrong thing. See Debian Policy
2687   ## for details.'' and then uses `#ifdef DEBIAN'.  Unfortunately the
2688   ## Debian maintainer hasn't provided a clean fix for Emacs.
2689   ## movemail.c will use `maillock' when MAILDIR, HAVE_LIBMAIL and
2690   ## HAVE_MAILLOCK_H are defined, so the following appears to be the
2691   ## correct logic.  -- fx
2692   ## We must check for HAVE_LIBLOCKFILE too, as movemail does.
2693   ## liblockfile is a Free Software replacement for libmail, used on
2694   ## Debian systems and elsewhere. -rfr.
2695   gnu-*)
2696     mail_lock="flock"
2697     if test $have_mail = yes || test $have_lockfile = yes; then
2698       test $ac_cv_header_maillock_h = yes && mail_lock=no
2699     fi
2700     ;;
2701 esac
2702
2703 BLESSMAIL_TARGET=
2704 case "$mail_lock" in
2705   flock) AC_DEFINE(MAIL_USE_FLOCK, 1, [Define if the mailer uses flock to interlock the mail spool.]) ;;
2706
2707   lockf) AC_DEFINE(MAIL_USE_LOCKF, 1, [Define if the mailer uses lockf to interlock the mail spool.]) ;;
2708
2709   *) BLESSMAIL_TARGET="need-blessmail" ;;
2710 esac
2711 AC_SUBST(BLESSMAIL_TARGET)
2712
2713
2714 AC_CHECK_FUNCS(gethostname \
2715 closedir getrusage get_current_dir_name \
2716 lrand48 logb frexp fmod cbrt setsid \
2717 fpathconf select euidaccess getpagesize setlocale \
2718 utimes getrlimit setrlimit setpgid getcwd shutdown getaddrinfo \
2719 __fpending strsignal setitimer \
2720 sendto recvfrom getsockname getpeername getifaddrs freeifaddrs \
2721 gai_strerror mkstemp getline getdelim fsync sync \
2722 difftime posix_memalign \
2723 getpwent endpwent getgrent endgrent \
2724 touchlock \
2725 cfmakeraw cfsetspeed copysign __executable_start)
2726
2727 dnl getwd appears to be buggy on SVR4.2, so we don't use it.
2728 if test $opsys = unixware; then
2729   dnl In case some other test ends up checking for getwd.
2730   AC_DEFINE(BROKEN_GETWD, 1, [Define if getwd should not be used.])
2731 else
2732   AC_CHECK_FUNCS(getwd)
2733 fi
2734
2735 ## Eric Backus <ericb@lsid.hp.com> says, HP-UX 9.x on HP 700 machines
2736 ## has a broken `rint' in some library versions including math library
2737 ## version number A.09.05.
2738 ## You can fix the math library by installing patch number PHSS_4630.
2739 ## But we can fix it more reliably for Emacs by just not using rint.
2740 ## We also skip HAVE_RANDOM - see comments in src/conf_post.h.
2741 case $opsys in
2742    hpux*) : ;;
2743    *) AC_CHECK_FUNCS(random rint) ;;
2744 esac
2745
2746 dnl Cannot use AC_CHECK_FUNCS
2747 AC_CACHE_CHECK([for __builtin_unwind_init],
2748                emacs_cv_func___builtin_unwind_init,
2749 [AC_LINK_IFELSE([AC_LANG_PROGRAM([], [__builtin_unwind_init ();])],
2750                 emacs_cv_func___builtin_unwind_init=yes,
2751                 emacs_cv_func___builtin_unwind_init=no)])
2752 if test $emacs_cv_func___builtin_unwind_init = yes; then
2753   AC_DEFINE(HAVE___BUILTIN_UNWIND_INIT, 1,
2754             [Define to 1 if you have the `__builtin_unwind_init' function.])
2755 fi
2756
2757 AC_CHECK_HEADERS_ONCE(sys/un.h)
2758
2759 AC_FUNC_FSEEKO
2760
2761 AC_FUNC_GETPGRP
2762
2763 # UNIX98 PTYs.
2764 AC_CHECK_FUNCS(grantpt)
2765
2766 # PTY-related GNU extensions.
2767 AC_CHECK_FUNCS(getpt)
2768
2769 # Check this now, so that we will NOT find the above functions in ncurses.
2770 # That is because we have not set up to link ncurses in lib-src.
2771 # It's better to believe a function is not available
2772 # than to expect to find it in ncurses.
2773 # Also we need tputs and friends to be able to build at all.
2774 AC_MSG_CHECKING([for library containing tputs])
2775 # Run a test program that contains a call to tputs, a call that is
2776 # never executed.  This tests whether a pre-'main' dynamic linker
2777 # works with the library.  It's too much trouble to actually call
2778 # tputs in the test program, due to portability hassles.  When
2779 # cross-compiling, assume the test program will run if it links.
2780 AC_DEFUN([tputs_link_source], [
2781   AC_LANG_SOURCE(
2782      [[extern void tputs (const char *, int, int (*)(int));
2783        int main (int argc, char **argv)
2784        {
2785           if (argc == 10000)
2786             tputs (argv[0], 0, 0);
2787           return 0;
2788        }]])
2789 ])
2790 # Maybe curses should be tried earlier?
2791 # See http://debbugs.gnu.org/cgi/bugreport.cgi?bug=9736#35
2792 for tputs_library in '' tinfo ncurses terminfo termcap curses; do
2793   OLIBS=$LIBS
2794   if test -z "$tputs_library"; then
2795     LIBS_TERMCAP=
2796     msg='none required'
2797   else
2798     LIBS_TERMCAP=-l$tputs_library
2799     msg=$LIBS_TERMCAP
2800     LIBS="$LIBS_TERMCAP $LIBS"
2801   fi
2802   AC_RUN_IFELSE([tputs_link_source], [], [msg=no],
2803     [AC_LINK_IFELSE([tputs_link_source], [], [msg=no])])
2804   LIBS=$OLIBS
2805   if test "X$msg" != Xno; then
2806     break
2807   fi
2808 done
2809 AC_MSG_RESULT([$msg])
2810 if test "X$msg" = Xno; then
2811   AC_MSG_ERROR([The required function `tputs' was not found in any library.
2812 The following libraries were tried (in order):
2813   libtinfo, libncurses, libterminfo, libtermcap, libcurses
2814 Please try installing whichever of these libraries is most appropriate
2815 for your system, together with its header files.
2816 For example, a libncurses-dev(el) or similar package.])
2817 fi
2818
2819 ## Use termcap instead of terminfo?
2820 ## Only true for: freebsd < 40000, ms-w32, msdos, netbsd < 599002500.
2821 TERMINFO=yes
2822 ## FIXME?  In the cases below where we unconditionally set
2823 ## LIBS_TERMCAP="-lncurses", this overrides LIBS_TERMCAP = -ltinfo,
2824 ## if that was found above to have tputs.
2825 ## Should we use the gnu* logic everywhere?
2826 case "$opsys" in
2827   ## darwin: Prevents crashes when running Emacs in Terminal.app under 10.2.
2828   ##  The ncurses library has been moved out of the System framework in
2829   ##  Mac OS X 10.2.  So if configure detects it, set the command-line
2830   ##  option to use it.
2831   darwin) LIBS_TERMCAP="-lncurses" ;;
2832
2833   gnu*) test -z "$LIBS_TERMCAP" && LIBS_TERMCAP="-lncurses" ;;
2834
2835   freebsd)
2836     AC_MSG_CHECKING([whether FreeBSD is new enough to use terminfo])
2837     AC_CACHE_VAL(emacs_cv_freebsd_terminfo,
2838     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <osreldate.h>]],
2839 [[#if __FreeBSD_version < 400000
2840 fail;
2841 #endif
2842 ]])], emacs_cv_freebsd_terminfo=yes, emacs_cv_freebsd_terminfo=no)])
2843
2844     AC_MSG_RESULT($emacs_cv_freebsd_terminfo)
2845
2846     if test $emacs_cv_freebsd_terminfo = yes; then
2847       LIBS_TERMCAP="-lncurses"
2848     else
2849       TERMINFO=no
2850       LIBS_TERMCAP="-ltermcap"
2851     fi
2852     ;;
2853
2854   netbsd)
2855     if test "x$LIBS_TERMCAP" != "x-lterminfo"; then
2856       TERMINFO=no
2857       LIBS_TERMCAP="-ltermcap"
2858     fi
2859     ;;
2860
2861   openbsd) LIBS_TERMCAP="-lncurses" ;;
2862
2863   ## hpux: Make sure we get select from libc rather than from libcurses
2864   ##  because libcurses on HPUX 10.10 has a broken version of select.
2865   ##  We used to use -lc -lcurses, but this may be cleaner.
2866   ## FIXME?  But TERMINFO = yes on hpux (it used to be explicitly
2867   # set that way, now it uses the default).  Isn't this a contradiction?
2868   hpux*) LIBS_TERMCAP="-ltermcap" ;;
2869
2870 esac
2871
2872 TERMCAP_OBJ=tparam.o
2873 if test $TERMINFO = yes; then
2874   AC_DEFINE(TERMINFO, 1, [Define to 1 if you use terminfo instead of termcap.])
2875   TERMCAP_OBJ=terminfo.o
2876 fi
2877 AC_SUBST(LIBS_TERMCAP)
2878 AC_SUBST(TERMCAP_OBJ)
2879
2880
2881 # Do we have res_init, for detecting changes in /etc/resolv.conf?
2882 # On Darwin, res_init appears not to be useful: see bug#562 and
2883 # http://lists.gnu.org/archive/html/emacs-devel/2007-11/msg01467.html
2884 resolv=no
2885
2886 if test $opsys != darwin; then
2887
2888   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
2889 #include <arpa/nameser.h>
2890 #include <resolv.h>]],
2891     [[return res_init();]])],
2892     have_res_init=yes, have_res_init=no)
2893   if test "$have_res_init" = no; then
2894     OLIBS="$LIBS"
2895     LIBS="$LIBS -lresolv"
2896     AC_MSG_CHECKING(for res_init with -lresolv)
2897     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
2898 #include <arpa/nameser.h>
2899 #include <resolv.h>]],
2900       [[return res_init();]])],
2901       have_res_init=yes, have_res_init=no)
2902     AC_MSG_RESULT($have_res_init)
2903     if test "$have_res_init" = yes ; then
2904       resolv=yes
2905     fi
2906     LIBS="$OLIBS"
2907   fi
2908
2909   if test "$have_res_init" = yes; then
2910     AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
2911   fi
2912 fi                              dnl !darwin
2913
2914 # Do we need the Hesiod library to provide the support routines?
2915 dnl FIXME?  Should we be skipping this on Darwin too?
2916 LIBHESIOD=
2917 if test "$with_hesiod" != no ; then
2918   # Don't set $LIBS here -- see comments above.  FIXME which comments?
2919   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
2920      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
2921                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
2922   if test "$resolv" = yes ; then
2923     RESOLVLIB=-lresolv
2924   else
2925     RESOLVLIB=
2926   fi
2927   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2928         hesiod=yes, :, $RESOLVLIB)])
2929
2930   if test x"$hesiod" = xyes; then
2931     AC_DEFINE(HAVE_LIBHESIOD, 1,
2932               [Define to 1 if you have the hesiod library (-lhesiod).])
2933     LIBHESIOD=-lhesiod
2934   fi
2935 fi
2936 AC_SUBST(LIBHESIOD)
2937
2938 # Do we need libresolv (due to res_init or Hesiod)?
2939 if test "$resolv" = yes && test $opsys != darwin; then
2940   AC_DEFINE(HAVE_LIBRESOLV, 1,
2941             [Define to 1 if you have the resolv library (-lresolv).])
2942   LIBRESOLV=-lresolv
2943 else
2944   LIBRESOLV=
2945 fi
2946 AC_SUBST(LIBRESOLV)
2947
2948 # These tell us which Kerberos-related libraries to use.
2949 COM_ERRLIB=
2950 CRYPTOLIB=
2951 KRB5LIB=
2952 DESLIB=
2953 KRB4LIB=
2954
2955 if test "${with_kerberos}" != no; then
2956   AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
2957   if test $have_com_err = yes; then
2958     COM_ERRLIB=-lcom_err
2959     LIBS="$COM_ERRLIB $LIBS"
2960     AC_DEFINE(HAVE_LIBCOM_ERR, 1, [Define to 1 if you have the `com_err' library (-lcom_err).])
2961   fi
2962   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
2963   if test $have_crypto = yes; then
2964     CRYPTOLIB=-lcrypto
2965     LIBS="$CRYPTOLIB $LIBS"
2966     AC_DEFINE(HAVE_LIBCRYPTO, 1, [Define to 1 if you have the `crypto' library (-lcrypto).])
2967   fi
2968   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
2969   if test $have_k5crypto = yes; then
2970     CRYPTOLIB=-lk5crypto
2971     LIBS="$CRYPTOLIB $LIBS"
2972     AC_DEFINE(HAVE_LIBK5CRYPTO, 1, [Define to 1 if you have the `k5crypto' library (-lk5crypto).])
2973   fi
2974   AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
2975   if test $have_krb5=yes; then
2976     KRB5LIB=-lkrb5
2977     LIBS="$KRB5LIB $LIBS"
2978     AC_DEFINE(HAVE_LIBKRB5, 1, [Define to 1 if you have the `krb5' library (-lkrb5).])
2979   fi
2980   dnl FIXME Simplify.  Does not match 22 logic, thanks to default_off?
2981   if test "${with_kerberos5}" = no; then
2982     AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
2983     if test $have_des425 = yes; then
2984       DESLIB=-ldes425
2985       LIBS="$DESLIB $LIBS"
2986       AC_DEFINE(HAVE_LIBDES425, 1, [Define to 1 if you have the `des425' library (-ldes425).])
2987     else
2988       AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
2989       if test $have_des = yes; then
2990         DESLIB=-ldes
2991         LIBS="$DESLIB $LIBS"
2992         AC_DEFINE(HAVE_LIBDES, 1, [Define to 1 if you have the `des' library (-ldes).])
2993       fi
2994     fi
2995     AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
2996     if test $have_krb4 = yes; then
2997       KRB4LIB=-lkrb4
2998       LIBS="$KRB4LIB $LIBS"
2999       AC_DEFINE(HAVE_LIBKRB4, 1, [Define to 1 if you have the `krb4' library (-lkrb4).])
3000     else
3001       AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
3002       if test $have_krb = yes; then
3003         KRB4LIB=-lkrb
3004         LIBS="$KRB4LIB $LIBS"
3005         AC_DEFINE(HAVE_LIBKRB, 1, [Define to 1 if you have the `krb' library (-lkrb).])
3006       fi
3007     fi
3008   fi
3009
3010   if test "${with_kerberos5}" != no; then
3011     AC_CHECK_HEADERS(krb5.h,
3012       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
3013                         [#include <krb5.h>])])
3014   else
3015     AC_CHECK_HEADERS(des.h,,
3016                      [AC_CHECK_HEADERS(kerberosIV/des.h,,
3017                                        [AC_CHECK_HEADERS(kerberos/des.h)])])
3018     AC_CHECK_HEADERS(krb.h,,
3019                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
3020                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
3021   fi
3022   AC_CHECK_HEADERS(com_err.h)
3023 fi
3024
3025 AC_SUBST(COM_ERRLIB)
3026 AC_SUBST(CRYPTOLIB)
3027 AC_SUBST(KRB5LIB)
3028 AC_SUBST(DESLIB)
3029 AC_SUBST(KRB4LIB)
3030
3031 AC_CHECK_FUNCS_ONCE(tzset)
3032 AC_MSG_CHECKING(whether localtime caches TZ)
3033 AC_CACHE_VAL(emacs_cv_localtime_cache,
3034 [if test x$ac_cv_func_tzset = xyes; then
3035 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <time.h>
3036 char TZ_GMT0[] = "TZ=GMT0";
3037 char TZ_PST8[] = "TZ=PST8";
3038 main()
3039 {
3040   time_t now = time ((time_t *) 0);
3041   int hour_GMT0, hour_unset;
3042   if (putenv (TZ_GMT0) != 0)
3043     exit (1);
3044   hour_GMT0 = localtime (&now)->tm_hour;
3045   unsetenv("TZ");
3046   hour_unset = localtime (&now)->tm_hour;
3047   if (putenv (TZ_PST8) != 0)
3048     exit (1);
3049   if (localtime (&now)->tm_hour == hour_GMT0)
3050     exit (1);
3051   unsetenv("TZ");
3052   if (localtime (&now)->tm_hour != hour_unset)
3053     exit (1);
3054   exit (0);
3055 }]])], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
3056 [# If we have tzset, assume the worst when cross-compiling.
3057 emacs_cv_localtime_cache=yes])
3058 else
3059         # If we lack tzset, report that localtime does not cache TZ,
3060         # since we can't invalidate the cache if we don't have tzset.
3061         emacs_cv_localtime_cache=no
3062 fi])dnl
3063 AC_MSG_RESULT($emacs_cv_localtime_cache)
3064 if test $emacs_cv_localtime_cache = yes; then
3065   AC_DEFINE(LOCALTIME_CACHE, 1,
3066             [Define to 1 if localtime caches TZ.])
3067 fi
3068
3069 ok_so_far=yes
3070 AC_CHECK_FUNC(socket, , ok_so_far=no)
3071 if test $ok_so_far = yes; then
3072   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
3073 fi
3074 if test $ok_so_far = yes; then
3075   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
3076 fi
3077 if test $ok_so_far = yes; then
3078 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
3079   AC_DEFINE(HAVE_INET_SOCKETS, 1,
3080             [Define to 1 if you have inet sockets.])
3081 fi
3082
3083 if test -f /usr/lpp/X11/bin/smt.exp; then
3084   AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
3085             [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
3086 fi
3087
3088 AC_MSG_CHECKING(whether system supports dynamic ptys)
3089 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
3090   AC_MSG_RESULT(yes)
3091   AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
3092 else
3093   AC_MSG_RESULT(no)
3094 fi
3095
3096 AC_FUNC_FORK
3097
3098 AC_CHECK_FUNCS(snprintf)
3099
3100 dnl Adapted from Haible's version.
3101 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
3102   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
3103     [[char* cs = nl_langinfo(CODESET);]])],
3104     emacs_cv_langinfo_codeset=yes,
3105     emacs_cv_langinfo_codeset=no)
3106   ])
3107 if test $emacs_cv_langinfo_codeset = yes; then
3108   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
3109     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
3110 fi
3111
3112 AC_TYPE_MBSTATE_T
3113
3114 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
3115   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[void fred (int x[__restrict]);]], [[]])],
3116                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
3117 if test "$emacs_cv_c_restrict_arr" = yes; then
3118   AC_DEFINE(__restrict_arr, __restrict,
3119     [Define to compiler's equivalent of C99 restrict keyword in array
3120      declarations.  Define as empty for no equivalent.])
3121 fi
3122
3123 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
3124 dnl how the tty code is related to POSIX and/or other versions of termios.
3125 dnl The following looks like a useful start.
3126 dnl
3127 dnl AC_SYS_POSIX_TERMIOS
3128 dnl if test $ac_cv_sys_posix_termios = yes; then
3129 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
3130 dnl                                and macros for terminal control.])
3131 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
3132 dnl fi
3133
3134 dnl Turned on June 1996 supposing nobody will mind it.
3135 AC_DEFINE(AMPERSAND_FULL_NAME, 1, [Define to use the convention that &
3136   in the full name stands for the login id.])
3137
3138 dnl Every platform that uses configure (ie every non-MS platform)
3139 dnl supports this.  There is a create-lockfiles option you can
3140 dnl customize if you do not want the lock files to be written.
3141 dnl So it is not clear that this #define still needs to exist.
3142 AC_DEFINE(CLASH_DETECTION, 1, [Define if you want lock files to be written,
3143   so that Emacs can tell instantly when you try to modify a file that
3144   someone else has modified in his/her Emacs.])
3145
3146 AH_TEMPLATE(FLOAT_CHECK_DOMAIN, [Define if the float library doesn't
3147   handle errors by either setting errno, or signaling SIGFPE/SIGILL.])
3148
3149 AH_TEMPLATE(HAVE_INVERSE_HYPERBOLIC, [Define if you have the functions
3150   acosh, asinh, and atanh.])
3151
3152 dnl Everybody supports this, except MS.
3153 dnl Seems like the kind of thing we should be testing for, though.
3154 ## Note: PTYs are broken on darwin <6.  Use at your own risk.
3155 AC_DEFINE(HAVE_PTYS, 1, [Define if the system supports pty devices.])
3156
3157 dnl Everybody supports this, except MS-DOS.
3158 dnl Seems like the kind of thing we should be testing for, though.
3159 dnl Compare with HAVE_INET_SOCKETS (which is unused...) above.
3160 AC_DEFINE(HAVE_SOCKETS, 1, [Define if the system supports
3161   4.2-compatible sockets.])
3162
3163 AH_TEMPLATE(INTERNAL_TERMINAL, [This is substituted when $TERM is "internal".])
3164
3165 AC_DEFINE(NULL_DEVICE, ["/dev/null"], [Name of the file to open to get
3166   a null file, or a data sink.])
3167
3168 AC_DEFINE(SEPCHAR, [':'], [Character that separates PATH elements.])
3169
3170 dnl Everybody supports this, except MS-DOS.
3171 AC_DEFINE(subprocesses, 1, [Define to enable asynchronous subprocesses.])
3172
3173 AC_DEFINE(USER_FULL_NAME, [pw->pw_gecos], [How to get a user's full name.])
3174
3175
3176 dnl Only used on MS platforms.
3177 AH_TEMPLATE(DEVICE_SEP, [Character that separates a device in a file name.])
3178
3179 AC_DEFINE(IS_DEVICE_SEP(_c_), 0,
3180   [Returns true if character is a device separator.])
3181
3182 AC_DEFINE(IS_DIRECTORY_SEP(_c_), [((_c_) == DIRECTORY_SEP)],
3183   [Returns true if character is a directory separator.])
3184
3185 dnl On MS, this also accepts IS_DEVICE_SEP.
3186 AC_DEFINE(IS_ANY_SEP(_c_), [(IS_DIRECTORY_SEP (_c_))],
3187   [Returns true if character is any form of separator.])
3188
3189
3190 AH_TEMPLATE(NO_EDITRES, [Define if XEditRes should not be used.])
3191
3192 case $opsys in
3193   aix4-2)
3194     dnl Unfortunately without libXmu we cannot support EditRes.
3195     if test x$ac_cv_lib_Xmu_XmuConvertStandardSelection != xyes; then
3196       AC_DEFINE(NO_EDITRES, 1)
3197     fi
3198     ;;
3199
3200   hpux*)
3201     dnl Assar Westerlund <assar@sics.se> says this is necessary for
3202     dnl HP-UX 10.20, and that it works for HP-UX 0 as well.
3203     AC_DEFINE(NO_EDITRES, 1)
3204     ;;
3205 esac
3206
3207
3208 case $opsys in
3209   darwin | gnu | hpux* | *bsd )
3210     AC_DEFINE(NO_TERMIO, 1, [Define if termio.h should not be included.])
3211     ;;
3212
3213   irix6-5 | sol2* | unixware )
3214     dnl Some SVr4s don't define NSIG in sys/signal.h for ANSI environments;
3215     dnl instead, there's a system variable _sys_nsig.  Unfortunately, we
3216     dnl need the constant to dimension an array.  So wire in the appropriate
3217     dnl value here.
3218     AC_DEFINE(NSIG_MINIMUM, 32, [Minimum value of NSIG.])
3219     ;;
3220 esac
3221
3222
3223 case $opsys in
3224   dnl SIGIO exists, but the feature doesn't work in the way Emacs needs.
3225   dnl See eg <http://article.gmane.org/gmane.os.openbsd.ports/46831>.
3226   hpux* | irix6-5 | openbsd | sol2* | unixware )
3227     AC_DEFINE(BROKEN_SIGIO, 1, [Define if SIGIO should not be used.])
3228     ;;
3229
3230   aix4-2)
3231     dnl BUILD 9008 - FIONREAD problem still exists in X-Windows.
3232     AC_DEFINE(BROKEN_FIONREAD, 1, [Define if FIONREAD should not be used.])
3233     dnl As we define BROKEN_FIONREAD, SIGIO will be undefined in systty.h.
3234     dnl But, on AIX, SIGAIO, SIGPTY, and SIGPOLL are defined as SIGIO,
3235     dnl which causes compilation error at init_signals in sysdep.c.
3236     dnl So, we define these macros so that syssignal.h detects them
3237     dnl and undefine SIGAIO, SIGPTY and SIGPOLL.
3238     AC_DEFINE(BROKEN_SIGAIO, 1, [Define if SIGAIO should not be used.])
3239     AC_DEFINE(BROKEN_SIGPOLL,1, [Define if SIGPOLL should not be used.])
3240     AC_DEFINE(BROKEN_SIGPTY, 1, [Define if SIGPTY should not be used.])
3241
3242     dnl On AIX Emacs uses the gmalloc.c malloc implementation.  But given
3243     dnl the way this system works, libc functions that return malloced
3244     dnl memory use the libc malloc implementation. Calling xfree or
3245     dnl xrealloc on the results of such functions results in a crash.
3246     dnl
3247     dnl One solution for this could be to define SYSTEM_MALLOC in configure,
3248     dnl but that does not currently work on this system.
3249     dnl
3250     dnl It is possible to completely override the malloc implementation on
3251     dnl AIX, but that involves putting the malloc functions in a shared
3252     dnl library and setting the MALLOCTYPE environment variable to point to
3253     dnl that shared library.
3254     dnl
3255     dnl Emacs currently calls xrealloc on the results of get_current_dir name,
3256     dnl to avoid a crash just use the Emacs implementation for that function.
3257     dnl
3258     dnl FIXME We could change the AC_CHECK_FUNCS call near the start
3259     dnl of this file, so that we do not check for get_current_dir_name
3260     dnl on AIX.  But that might be fragile if something else ends
3261     dnl up testing for get_current_dir_name as a dependency.
3262     AC_DEFINE(BROKEN_GET_CURRENT_DIR_NAME, 1, [Define if
3263       get_current_dir_name should not be used.])
3264     ;;
3265
3266   freebsd)
3267     dnl Circumvent a bug in FreeBSD.  In the following sequence of
3268     dnl writes/reads on a PTY, read(2) returns bogus data:
3269     dnl
3270     dnl write(2)  1022 bytes
3271     dnl write(2)   954 bytes, get EAGAIN
3272     dnl read(2)   1024 bytes in process_read_output
3273     dnl read(2)     11 bytes in process_read_output
3274     dnl
3275     dnl That is, read(2) returns more bytes than have ever been written
3276     dnl successfully.  The 1033 bytes read are the 1022 bytes written
3277     dnl successfully after processing (for example with CRs added if the
3278     dnl terminal is set up that way which it is here).  The same bytes will
3279     dnl be seen again in a later read(2), without the CRs.
3280     AC_DEFINE(BROKEN_PTY_READ_AFTER_EAGAIN, 1, [Define on FreeBSD to
3281       work around an issue when reading from a PTY.])
3282     ;;
3283
3284   dnl Define the following so emacs symbols will not conflict with those
3285   dnl in the System framework.  Otherwise -prebind will not work.
3286   darwin)
3287     AC_DEFINE(NO_ABORT, 1, [Do not define abort in emacs.c.])
3288     ;;
3289 esac
3290
3291 case $opsys in
3292   gnu-* | sol2-10 )
3293     dnl FIXME Can't we test if this exists (eg /proc/$$)?
3294     AC_DEFINE(HAVE_PROCFS, 1, [Define if you have the /proc filesystem.])
3295   ;;
3296 esac
3297
3298 case $opsys in
3299   darwin | freebsd | netbsd | openbsd )
3300     AC_DEFINE(DONT_REOPEN_PTY, 1, [Define if process.c does not need to
3301       close a pty to make it a controlling terminal (it is already a
3302       controlling terminal of the subprocess, because we did ioctl TIOCSCTTY).])
3303   ;;
3304 esac
3305
3306 dnl FIXME Surely we can test for this rather than hard-code it.
3307 case $opsys in
3308   netbsd | openbsd) sound_device="/dev/audio" ;;
3309   *) sound_device="/dev/dsp" ;;
3310 esac
3311
3312 dnl Used in sound.c
3313 AC_DEFINE_UNQUOTED(DEFAULT_SOUND_DEVICE, "$sound_device",
3314   [Name of the default sound device.])
3315
3316
3317 dnl Emacs can read input using SIGIO and buffering characters itself,
3318 dnl or using CBREAK mode and making C-g cause SIGINT.
3319 dnl The choice is controlled by the variable interrupt_input.
3320 dnl
3321 dnl Define INTERRUPT_INPUT to make interrupt_input = 1 the default (use SIGIO)
3322 dnl
3323 dnl Emacs uses the presence or absence of the SIGIO and BROKEN_SIGIO macros
3324 dnl to indicate whether or not signal-driven I/O is possible.  It uses
3325 dnl INTERRUPT_INPUT to decide whether to use it by default.
3326 dnl
3327 dnl SIGIO can be used only on systems that implement it (4.2 and 4.3).
3328 dnl CBREAK mode has two disadvantages
3329 dnl 1) At least in 4.2, it is impossible to handle the Meta key properly.
3330 dnl I hear that in system V this problem does not exist.
3331 dnl 2) Control-G causes output to be discarded.
3332 dnl I do not know whether this can be fixed in system V.
3333 dnl
3334 dnl Another method of doing input is planned but not implemented.
3335 dnl It would have Emacs fork off a separate process
3336 dnl to read the input and send it to the true Emacs process
3337 dnl through a pipe.
3338 case $opsys in
3339   darwin | gnu-linux | gnu-kfreebsd )
3340     AC_DEFINE(INTERRUPT_INPUT, 1, [Define to read input using SIGIO.])
3341   ;;
3342 esac
3343
3344
3345 dnl If the system's imake configuration file defines `NeedWidePrototypes'
3346 dnl as `NO', we must define NARROWPROTO manually.  Such a define is
3347 dnl generated in the Makefile generated by `xmkmf'.  If we don't define
3348 dnl NARROWPROTO, we will see the wrong function prototypes for X functions
3349 dnl taking float or double parameters.
3350 case $opsys in
3351   cygwin|gnu|gnu-linux|gnu-kfreebsd|irix6-5|freebsd|netbsd|openbsd)
3352     AC_DEFINE(NARROWPROTO, 1, [Define if system's imake configuration
3353       file defines `NeedWidePrototypes' as `NO'.])
3354   ;;
3355 esac
3356
3357
3358 dnl Used in process.c, this must be a loop, even if it only runs once.
3359 dnl (Except on SGI; see below.  Take that, clarity and consistency!)
3360 AH_TEMPLATE(PTY_ITERATION, [How to iterate over PTYs.])
3361 dnl Only used if !PTY_ITERATION.  Iterate from FIRST_PTY_LETTER to z,
3362 dnl trying suffixes 0-16.
3363 AH_TEMPLATE(FIRST_PTY_LETTER, [Letter to use in finding device name of
3364   first PTY, if PTYs are supported.])
3365 AH_TEMPLATE(PTY_OPEN, [How to open a PTY, if non-standard.])
3366 AH_TEMPLATE(PTY_NAME_SPRINTF, [How to get the device name of the control
3367   end of a PTY, if non-standard.])
3368 AH_TEMPLATE(PTY_TTY_NAME_SPRINTF, [How to get device name of the tty
3369   end of a PTY, if non-standard.])
3370
3371 case $opsys in
3372   aix4-2 )
3373     AC_DEFINE(PTY_ITERATION, [int c; for (c = 0; !c ; c++)])
3374     dnl You allocate a pty by opening /dev/ptc to get the master side.
3375     dnl To get the name of the slave side, you just ttyname() the master side.
3376     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptc");])
3377     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [strcpy (pty_name, ttyname (fd));])
3378     ;;
3379
3380   cygwin )
3381     AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
3382     dnl multi-line AC_DEFINEs are hard. :(
3383     AC_DEFINE(PTY_OPEN, [ do { int dummy; SIGMASKTYPE mask; mask = sigblock (sigmask (SIGCHLD)); if (-1 == openpty (&fd, &dummy, pty_name, 0, 0)) fd = -1; sigsetmask (mask); if (fd >= 0) emacs_close (dummy); } while (0)])
3384     AC_DEFINE(PTY_NAME_SPRINTF, [])
3385     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
3386     ;;
3387
3388   darwin )
3389     AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
3390     dnl Not used, because PTY_ITERATION is defined.
3391     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
3392     dnl Note that openpty may fork via grantpt on Mac OS X 10.4/Darwin 8.
3393     dnl But we don't have to block SIGCHLD because it is blocked in the
3394     dnl implementation of grantpt.
3395     AC_DEFINE(PTY_OPEN, [ do { int slave; if (openpty (&fd, &slave, pty_name, NULL, NULL) == -1) fd = -1; else emacs_close (slave); } while (0)])
3396     AC_DEFINE(PTY_NAME_SPRINTF, [])
3397     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
3398     ;;
3399
3400   gnu | freebsd | netbsd | openbsd )
3401     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
3402     ;;
3403
3404   gnu-linux | gnu-kfreebsd )
3405     dnl if HAVE_GRANTPT
3406     if test "x$ac_cv_func_grantpt" = xyes; then
3407       AC_DEFINE(UNIX98_PTYS, 1, [Define if the system has Unix98 PTYs.])
3408       AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
3409       dnl Note that grantpt and unlockpt may fork.  We must block SIGCHLD
3410       dnl to prevent sigchld_handler from intercepting the child's death.
3411       AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptyname; sigblock (sigmask (SIGCHLD)); if (grantpt (fd) == -1 || unlockpt (fd) == -1 || !(ptyname = ptsname(fd))) { sigunblock (sigmask (SIGCHLD)); close (fd); return -1; } snprintf (pty_name, sizeof pty_name, "%s", ptyname); sigunblock (sigmask (SIGCHLD)); }])
3412       dnl if HAVE_GETPT
3413       if test "x$ac_cv_func_getpt" = xyes; then
3414         AC_DEFINE(PTY_OPEN, [fd = getpt ()])
3415         AC_DEFINE(PTY_NAME_SPRINTF, [])
3416       else
3417         AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptmx");])
3418       fi
3419     else
3420       AC_DEFINE(FIRST_PTY_LETTER, ['p'])
3421     fi
3422     ;;
3423
3424   hpux*)
3425     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
3426     AC_DEFINE(PTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/ptym/pty%c%x", c, i);])
3427     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/pty/tty%c%x", c, i);])
3428     ;;
3429
3430   irix6-5 )
3431     dnl It looks like this cannot be right, because it is not a loop.
3432     dnl However, process.c actually does this:
3433     dnl # ifndef __sgi
3434     dnl   continue;
3435     dnl # else
3436     dnl   return -1;
3437     dnl # endif
3438     dnl which presumably makes it OK, since irix == sgi (?).
3439     dnl FIXME it seems like this special treatment is unnecessary?
3440     dnl Why can't irix use a single-trip loop like eg cygwin?
3441     AC_DEFINE(PTY_ITERATION, [])
3442     dnl Not used, because PTY_ITERATION is defined.
3443     AC_DEFINE(FIRST_PTY_LETTER, ['q'])
3444     AC_DEFINE(PTY_OPEN, [ { struct sigaction ocstat, cstat; struct stat stb; char * name; sigemptyset(&cstat.sa_mask); cstat.sa_handler = SIG_DFL; cstat.sa_flags = 0; sigaction(SIGCLD, &cstat, &ocstat); name = _getpty (&fd, O_RDWR | O_NDELAY, 0600, 0); sigaction(SIGCLD, &ocstat, (struct sigaction *)0); if (name == 0) return -1; if (fd < 0) return -1; if (fstat (fd, &stb) < 0) return -1; strcpy (pty_name, name); }])
3445     dnl No need to get the pty name at all.
3446     AC_DEFINE(PTY_NAME_SPRINTF, [])
3447     dnl No need to use sprintf to get the tty name--we get that from _getpty.
3448     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
3449     ;;
3450
3451   sol2* )
3452     dnl Uses sigblock/sigunblock rather than sighold/sigrelse,
3453     dnl which appear to be BSD4.1 specific.  It may also be appropriate
3454     dnl for SVR4.x (x<2) but I'm not sure.   fnf@cygnus.com
3455     dnl On SysVr4, grantpt(3) forks a subprocess, so keep sigchld_handler()
3456     dnl from intercepting that death.  If any child but grantpt's should die
3457     dnl within, it should be caught after sigrelse(2).
3458     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptsname (int), *ptyname; sigblock (sigmask (SIGCLD)); if (grantpt (fd) == -1) { emacs_close (fd); return -1; } sigunblock (sigmask (SIGCLD)); if (unlockpt (fd) == -1) { emacs_close (fd); return -1; } if (!(ptyname = ptsname (fd))) { emacs_close (fd); return -1; } snprintf (pty_name, sizeof pty_name, "%s", ptyname); }])
3459     ;;
3460
3461   unixware )
3462     dnl Comments are as per sol2*.
3463     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptsname (int), *ptyname; sigblock(sigmask(SIGCLD)); if (grantpt(fd) == -1) fatal("could not grant slave pty"); sigunblock(sigmask(SIGCLD)); if (unlockpt(fd) == -1) fatal("could not unlock slave pty"); if (!(ptyname = ptsname(fd))) fatal ("could not enable slave pty"); snprintf (pty_name, sizeof pty_name, "%s", ptyname); }])
3464     ;;
3465 esac
3466
3467
3468 case $opsys in
3469   sol2* | unixware )
3470     dnl This change means that we don't loop through allocate_pty too
3471     dnl many times in the (rare) event of a failure.
3472     AC_DEFINE(FIRST_PTY_LETTER, ['z'])
3473     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptmx");])
3474     dnl Push various streams modules onto a PTY channel.  Used in process.c.
3475     AC_DEFINE(SETUP_SLAVE_PTY, [if (ioctl (xforkin, I_PUSH, "ptem") == -1) fatal ("ioctl I_PUSH ptem"); if (ioctl (xforkin, I_PUSH, "ldterm") == -1) fatal ("ioctl I_PUSH ldterm"); if (ioctl (xforkin, I_PUSH, "ttcompat") == -1) fatal ("ioctl I_PUSH ttcompat");], [How to set up a slave PTY, if needed.])
3476     ;;
3477 esac
3478
3479
3480 AH_TEMPLATE(SIGNALS_VIA_CHARACTERS, [Make process_send_signal work by
3481 "typing" a signal character on the pty.])
3482
3483 case $opsys in
3484   dnl Perry Smith <pedz@ddivt1.austin.ibm.com> says this is correct for AIX.
3485   dnl thomas@mathematik.uni-bremen.de says this is needed for IRIX.
3486   aix4-2 | cygwin | gnu | irix6-5 | freebsd | netbsd | openbsd )
3487     AC_DEFINE(SIGNALS_VIA_CHARACTERS, 1)
3488     ;;
3489
3490   dnl 21 Jun 06: Eric Hanchrow <offby1@blarg.net> says this works.
3491   dnl FIXME Does gnu-kfreebsd have linux/version.h?  It seems unlikely...
3492   gnu-linux | gnu-kfreebsd )
3493
3494     AC_MSG_CHECKING([for signals via characters])
3495     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
3496 #include <linux/version.h>
3497 #if LINUX_VERSION_CODE < 0x20400
3498 # error "Linux version too old"
3499 #endif
3500       ]], [[]])], emacs_signals_via_chars=yes, emacs_signals_via_chars=no)
3501
3502     AC_MSG_RESULT([$emacs_signals_via_chars])
3503     test $emacs_signals_via_chars = yes && AC_DEFINE(SIGNALS_VIA_CHARACTERS, 1)
3504     ;;
3505 esac
3506
3507
3508 dnl Used in dispnew.c
3509 AH_TEMPLATE(PENDING_OUTPUT_COUNT, [Number of chars of output in the
3510   buffer of a stdio stream.])
3511
3512 AC_MSG_CHECKING([whether we are using the GNU C library])
3513 AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
3514 #include <features.h>
3515 #ifndef __GNU_LIBRARY__
3516 # error "this is not the GNU C library"
3517 #endif
3518   ]], [[]])], emacs_glibc=yes, emacs_glibc=no)
3519 AC_MSG_RESULT([$emacs_glibc])
3520
3521 if test $emacs_glibc = yes; then
3522
3523   emacs_pending_output=unknown
3524
3525   case $opsys in
3526     gnu | gnu-linux | gnu-kfreebsd )
3527       AC_MSG_CHECKING([for style of pending output formalism])
3528       dnl In autoconf 2.67 and later, we could use a single test
3529       dnl since the preprocessed output is accessible in "conftest.i".
3530       AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
3531 #include <stdio.h>
3532 #if !defined (_IO_STDIO_H) && !defined (_STDIO_USES_IOSTREAM)
3533 # error "stdio definitions not found"
3534 #endif
3535         ]], [[]])], emacs_pending_output=new, [])
3536
3537       if test $emacs_pending_output = unknown; then
3538         case $opsys in
3539           gnu-linux | gnu-kfreebsd)
3540             AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
3541 #include <stdio.h>
3542 #ifndef __UCLIBC__
3543 # error "not using uclibc"
3544 #endif
3545             ]], [[]])], emacs_pending_output=uclibc, emacs_pending_output=old)
3546             ;;
3547         esac
3548       fi
3549
3550       AC_MSG_RESULT([$emacs_pending_output])
3551
3552       case $emacs_pending_output in
3553         new)
3554           dnl New C libio names.
3555           AC_DEFINE(PENDING_OUTPUT_COUNT(FILE),
3556             [((FILE)->_IO_write_ptr - (FILE)->_IO_write_base)])
3557           ;;
3558         uclibc)
3559           dnl Using the uClibc library.
3560           AC_DEFINE(PENDING_OUTPUT_COUNT(FILE),
3561             [((FILE)->__bufpos - (FILE)->__bufstart)])
3562           ;;
3563         old)
3564           dnl Old C++ iostream names.
3565           AC_DEFINE(PENDING_OUTPUT_COUNT(FILE),
3566             [((FILE)->_pptr - (FILE)->_pbase)])
3567           ;;
3568       esac
3569     ;;
3570   esac                          dnl opsys
3571
3572   if test $emacs_pending_output = unknown; then
3573     AC_DEFINE(PENDING_OUTPUT_COUNT(FILE), [((FILE)->__bufp - (FILE)->__buffer)])
3574   fi
3575
3576 else                            dnl !emacs_glibc
3577
3578   case $opsys in
3579     cygwin | darwin | freebsd | netbsd | openbsd )
3580       AC_DEFINE(PENDING_OUTPUT_COUNT(FILE), [((FILE)->_p - (FILE)->_bf._base)])
3581       ;;
3582
3583     unixware)
3584       AC_DEFINE(PENDING_OUTPUT_COUNT(FILE), [((FILE)->__ptr - (FILE)->__base)])
3585       ;;
3586
3587     *)
3588       dnl HAVE_STDIO_EXT_H && HAVE___FPENDING
3589       if test x$ac_cv_header_stdio_ext_h = xyes && \
3590         test x$ac_cv_func___fpending = xyes; then
3591         AC_DEFINE(PENDING_OUTPUT_COUNT(FILE), [__fpending (FILE)])
3592         AC_DEFINE(DISPNEW_NEEDS_STDIO_EXT, 1,
3593           [Define if dispnew.c should include stdio_ext.h.])
3594       else
3595         AC_DEFINE(PENDING_OUTPUT_COUNT(FILE), [((FILE)->_ptr - (FILE)->_base)])
3596       fi
3597       ;;
3598   esac
3599 fi                              dnl emacs_glibc
3600
3601
3602 dnl Used in vm-limit.c
3603 AH_TEMPLATE(DATA_START, [Address of the start of the data segment.])
3604 dnl Used in lisp.h, emacs.c, mem-limits.h
3605 dnl NEWS.18 describes this as "a number which contains
3606 dnl the high bits to be inclusive or'ed with pointers that are unpacked."
3607 AH_TEMPLATE(DATA_SEG_BITS, [Extra bits to be or'd in with any pointers
3608 stored in a Lisp_Object.])
3609 dnl if Emacs uses fewer than 32 bits for the value field of a LISP_OBJECT.
3610
3611 case $opsys in
3612   gnu)
3613     dnl libc defines data_start.
3614     AC_DEFINE(DATA_START, [({ extern int data_start; (char *) &data_start; })])
3615     ;;
3616
3617   hpux*)
3618     dnl The data segment on this machine always starts at address 0x40000000.
3619     AC_DEFINE(DATA_START, [0x40000000])
3620     AC_DEFINE(DATA_SEG_BITS, [0x40000000])
3621     ;;
3622   irix6-5)
3623     AC_DEFINE(DATA_START, [0x10000000])
3624     AC_DEFINE(DATA_SEG_BITS, [0x10000000])
3625     ;;
3626 esac
3627
3628
3629 AH_TEMPLATE(ULIMIT_BREAK_VALUE, [Undocumented.])
3630 AH_TEMPLATE(TAB3, [Undocumented.])
3631
3632 case $opsys in
3633   darwin) AC_DEFINE(TAB3, OXTABS) ;;
3634
3635   gnu | freebsd | netbsd | openbsd )
3636     AC_DEFINE(TABDLY, OXTABS, [Undocumented.])
3637     AC_DEFINE(TAB3, OXTABS)
3638     ;;
3639
3640   gnu-linux | gnu-kfreebsd )
3641     dnl libc-linux/sysdeps/linux/i386/ulimit.c says that due to shared
3642     dnl library, we cannot get the maximum address for brk.
3643     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
3644 #ifndef __i386__
3645 # error "not i386"
3646 #endif
3647       ]], [[]])], AC_DEFINE(ULIMIT_BREAK_VALUE, [(32*1024*1024)]), [])
3648
3649     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
3650 #ifndef __ia64__
3651 # error "not ia64"
3652 #endif
3653       ]], [[]])], AC_DEFINE(GC_MARK_SECONDARY_STACK(),
3654         [do { extern void *__libc_ia64_register_backing_store_base; __builtin_ia64_flushrs (); mark_memory (__libc_ia64_register_backing_store_base, __builtin_ia64_bsp ());} while (0)],
3655         [Mark a secondary stack, like the register stack on the ia64.]), [])
3656     ;;
3657
3658   hpux*)
3659     AC_DEFINE(RUN_TIME_REMAP, 1, [Define if emacs.c needs to call
3660       run_time_remap; for HPUX.])
3661     ;;
3662
3663   irix6-5)
3664     dnl Ulimit(UL_GMEMLIM) is busted...
3665     AC_DEFINE(ULIMIT_BREAK_VALUE, [0x14000000])
3666     ;;
3667 esac
3668
3669
3670 dnl These won't be used automatically yet.  We also need to know, at least,
3671 dnl that the stack is continuous.
3672 AH_TEMPLATE(GC_SETJMP_WORKS, [Define if setjmp is known to save all
3673   registers relevant for conservative garbage collection in the jmp_buf.])
3674
3675 AH_TEMPLATE(GC_MARK_STACK, [Define to GC_USE_GCPROS_AS_BEFORE if
3676   conservative garbage collection is not known to work.])
3677
3678
3679 case $opsys in
3680   aix4-2 | hpux* | unixware)
3681     dnl Conservative garbage collection has not been tested, so for now
3682     dnl play it safe and stick with the old-fashioned way of marking.
3683     AC_DEFINE(GC_MARK_STACK, [GC_USE_GCPROS_AS_BEFORE])
3684     ;;
3685
3686   dnl Not all the architectures are tested, but there are Debian packages
3687   dnl for SCM and/or Guile on them, so the technique must work.  See also
3688   dnl comments in alloc.c concerning setjmp and gcc.
3689   dnl Fixme: it's probably safe to just use the GCC conditional below.
3690   gnu-linux | gnu-kfreebsd )
3691     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
3692 #if defined __i386__ || defined __sparc__ || defined __mc68000__ \
3693   || defined __alpha__ || defined __mips__ || defined __s390__ \
3694   || defined __arm__ || defined __powerpc__ || defined __amd64__ \
3695   || defined __ia64__ || defined __sh__
3696 /* ok */
3697 #else
3698 # error "setjmp not known to work on this arch"
3699 #endif
3700     ]], [[]])], AC_DEFINE(GC_SETJMP_WORKS, 1),
3701       AC_DEFINE(GC_MARK_STACK, [GC_USE_GCPROS_AS_BEFORE]) )
3702     ;;
3703 esac
3704
3705
3706 if test x$GCC = xyes; then
3707    dnl GC_SETJMP_WORKS is nearly always appropriate for GCC.
3708    AC_DEFINE(GC_SETJMP_WORKS, 1)
3709 else
3710   case $opsys in
3711     dnl irix: Tested on Irix 6.5.  SCM worked on earlier versions.
3712     freebsd | netbsd | openbsd | irix6-5 | sol2* )
3713       AC_DEFINE(GC_SETJMP_WORKS, 1)
3714       ;;
3715   esac
3716 fi                              dnl GCC?
3717
3718
3719 case $opsys in
3720   sol2* | unixware )
3721     dnl setjmp and longjmp can safely replace _setjmp and _longjmp,
3722     dnl but they will run more slowly.
3723     AC_DEFINE(_setjmp, setjmp, [Some platforms redefine this.])
3724     AC_DEFINE(_longjmp, longjmp, [Some platforms redefine this.])
3725     dnl TIOCGPGRP is broken in SysVr4, so we can't send signals to PTY
3726     dnl subprocesses the usual way.  But TIOCSIGNAL does work for PTYs,
3727     dnl and this is all we need.
3728     AC_DEFINE(TIOCSIGSEND, TIOCSIGNAL, [Some platforms redefine this.])
3729     ;;
3730 esac
3731
3732
3733 case $opsys in
3734   hpux* | sol2* )
3735     dnl Used in xfaces.c.
3736     AC_DEFINE(XOS_NEEDS_TIME_H, 1, [Compensate for a bug in Xos.h on
3737       some systems, where it requires time.h.])
3738     ;;
3739
3740   netbsd | openbsd )
3741     dnl Greg A. Woods <woods@weird.com> says we must include signal.h
3742     dnl before syssignal.h is included, to work around interface conflicts
3743     dnl that are handled with CPP __RENAME() macro in signal.h.
3744     AC_DEFINE(SIGNAL_H_AHB, 1, [Define if AH_BOTTOM should include signal.h.])
3745     ;;
3746 esac
3747
3748
3749 dnl Define symbols to identify the version of Unix this is.
3750 dnl Define all the symbols that apply correctly.
3751 AH_TEMPLATE(BSD4_2, [Define if the system is compatible with BSD 4.2.])
3752 AH_TEMPLATE(BSD_SYSTEM, [Define if the system is compatible with BSD 4.2.])
3753 AH_TEMPLATE(DOS_NT, [Define if the system is MS DOS or MS Windows.])
3754 AH_TEMPLATE(MSDOS, [Define if the system is MS DOS.])
3755 AH_TEMPLATE(USG, [Define if the system is compatible with System III.])
3756 AH_TEMPLATE(USG5, [Define if the system is compatible with System V.])
3757 AH_TEMPLATE(USG5_4, [Define if the system is compatible with System V Release 4.])
3758
3759 case $opsys in
3760   aix4-2)
3761     AC_DEFINE(USG, [])
3762     AC_DEFINE(USG5, [])
3763     dnl This symbol should be defined on AIX Version 3  ???????
3764     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
3765 #ifndef _AIX
3766 # error "_AIX not defined"
3767 #endif
3768     ]], [[]])], [], AC_DEFINE(_AIX, [], [Define if the system is AIX.]))
3769     ;;
3770
3771   cygwin)
3772     AC_DEFINE(CYGWIN, 1, [Define if the system is Cygwin.])
3773     ;;
3774
3775   darwin)
3776     dnl BSD4_3 and BSD4_4 are already defined in sys/param.h.
3777     AC_DEFINE(BSD4_2, [])
3778     AC_DEFINE(BSD_SYSTEM, [])
3779     dnl More specific than the above two.  We cannot use __APPLE__ as this
3780     dnl may not be defined on non-OSX Darwin, and we cannot define DARWIN
3781     dnl here because Panther and lower CoreFoundation.h uses DARWIN to
3782     dnl distinguish OS X from pure Darwin.
3783     AC_DEFINE(DARWIN_OS, [], [Define if the system is Darwin.])
3784     ;;
3785
3786   freebsd)
3787     AC_DEFINE(BSD4_2, [])
3788     dnl Hack to avoid calling AC_PREPROC_IFELSE multiple times.
3789     dnl Would not be needed with autoconf >= 2.67, where the
3790     dnl preprocessed output is accessible in "conftest.i".
3791     AC_DEFINE(BSD_SYSTEM_AHB, 1, [Define if AH_BOTTOM should change BSD_SYSTEM.])
3792     ;;
3793
3794   gnu | netbsd | openbsd )
3795     AC_DEFINE(BSD4_2, [])
3796     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
3797 #ifndef BSD_SYSTEM
3798 # error "BSD_SYSTEM not defined"
3799 #endif
3800     ]], [[]])], [], AC_DEFINE(BSD_SYSTEM, 43) )
3801     ;;
3802
3803   gnu-linux | gnu-kfreebsd )
3804     AC_DEFINE(USG, [])
3805     AC_DEFINE(GNU_LINUX, [], [Define if ths system is compatible with GNU/Linux.])
3806     ;;
3807
3808   hpux*)
3809     AC_DEFINE(USG, [])
3810     AC_DEFINE(USG5, [])
3811     AC_DEFINE(HPUX, [], [Define if the system is HPUX.])
3812     ;;
3813
3814   irix6-5)
3815     AC_DEFINE(USG, [])
3816     AC_DEFINE(USG5, [])
3817     AC_DEFINE(USG5_4, [])
3818     AC_DEFINE(IRIX6_5, [], [Define if the system is IRIX.])
3819     ;;
3820
3821   sol2*)
3822     AC_DEFINE(USG, [])
3823     AC_DEFINE(USG5, [])
3824     AC_DEFINE(USG5_4, [])
3825     AC_DEFINE(SOLARIS2, [], [Define if the system is Solaris.])
3826     ;;
3827
3828   unixware)
3829     AC_DEFINE(USG, [])
3830     AC_DEFINE(USG5, [])
3831     AC_DEFINE(USG5_4, [])
3832     ;;
3833 esac
3834
3835
3836 case $opsys in
3837   dnl Emacs supplies its own malloc, but glib (part of Gtk+) calls
3838   dnl memalign and on Cygwin, that becomes the Cygwin-supplied memalign.
3839   dnl As malloc is not the Cygwin malloc, the Cygwin memalign always
3840   dnl returns ENOSYS.  A workaround is to set G_SLICE=always-malloc. */
3841   cygwin)
3842     AC_DEFINE(G_SLICE_ALWAYS_MALLOC, 1, [Define to set the
3843       G_SLICE environment variable to "always-malloc" at startup, if
3844       using GTK.])
3845     ;;
3846
3847   hpux11)
3848     dnl See comments in sysdep.c:sys_signal.
3849     dnl SA_RESTART resets the timeout of `select' on hpux11.
3850     dnl Defining BROKEN_SA_RESTART is not the same as undef'ing SA_RESTART.
3851     AC_DEFINE(BROKEN_SA_RESTART, 1, [Define if SA_RESTART should only
3852       be used in batch mode.])
3853     dnl It works to open the pty's tty in the parent (Emacs), then
3854     dnl close and reopen it in the child.
3855     AC_DEFINE(USG_SUBTTY_WORKS, 1, [Define for USG systems where it
3856       works to open a pty's tty in the parent process, then close and
3857       reopen it in the child.])
3858     ;;
3859
3860   irix6-5)
3861     AC_DEFINE(PREFER_VSUSP, 1, [Define if process_send_signal should
3862       use VSUSP instead of VSWTCH.])
3863     AC_DEFINE(SETPGRP_RELEASES_CTTY, 1, [Define if process.c:child_setup
3864       should not call setpgrp.])
3865     ;;
3866
3867   sol2-10)
3868     AC_DEFINE(_STRUCTURED_PROC, 1, [Needed for system_process_attributes
3869       on Solaris.])
3870     ;;
3871 esac
3872
3873 # Set up the CFLAGS for real compilation, so we can substitute it.
3874 CFLAGS="$REAL_CFLAGS"
3875 CPPFLAGS="$REAL_CPPFLAGS"
3876
3877 ## Hack to detect a buggy GCC version.
3878 if test "x$GCC" = xyes \
3879    && test x"`$CC --version 2> /dev/null | grep 'gcc.* 4.5.0'`" != x \
3880    && test x"`echo $CFLAGS | grep '\-O@<:@23@:>@'`" != x \
3881    && test x"`echo $CFLAGS | grep '\-fno-optimize-sibling-calls'`" = x; then
3882    AC_MSG_ERROR([GCC 4.5.0 has problems compiling Emacs; see etc/PROBLEMS'.])
3883 fi
3884
3885 version=$PACKAGE_VERSION
3886
3887 ### Specify what sort of things we'll be editing into Makefile and config.h.
3888 ### Use configuration here uncanonicalized to avoid exceeding size limits.
3889 AC_SUBST(version)
3890 AC_SUBST(configuration)
3891 ## Unused?
3892 AC_SUBST(canonical)
3893 AC_SUBST(srcdir)
3894 AC_SUBST(prefix)
3895 AC_SUBST(exec_prefix)
3896 AC_SUBST(bindir)
3897 AC_SUBST(datadir)
3898 AC_SUBST(sharedstatedir)
3899 AC_SUBST(libexecdir)
3900 AC_SUBST(mandir)
3901 AC_SUBST(infodir)
3902 AC_SUBST(lispdir)
3903 AC_SUBST(leimdir)
3904 AC_SUBST(standardlisppath)
3905 AC_SUBST(locallisppath)
3906 AC_SUBST(lisppath)
3907 AC_SUBST(x_default_search_path)
3908 AC_SUBST(etcdir)
3909 AC_SUBST(archlibdir)
3910 AC_SUBST(docdir)
3911 AC_SUBST(bitmapdir)
3912 AC_SUBST(gamedir)
3913 AC_SUBST(gameuser)
3914 ## FIXME? Nothing uses @LD_SWITCH_X_SITE@.
3915 ## src/Makefile.in did add LD_SWITCH_X_SITE (as a cpp define) to the
3916 ## end of LIBX_BASE, but nothing ever set it.
3917 AC_SUBST(LD_SWITCH_X_SITE)
3918 AC_SUBST(C_SWITCH_X_SITE)
3919 AC_SUBST(GNUSTEP_CFLAGS)
3920 AC_SUBST(CFLAGS)
3921 ## Used in lwlib/Makefile.in.
3922 AC_SUBST(X_TOOLKIT_TYPE)
3923 AC_SUBST(ns_appdir)
3924 AC_SUBST(ns_appbindir)
3925 AC_SUBST(ns_appresdir)
3926 AC_SUBST(ns_appsrc)
3927 AC_SUBST(GNU_OBJC_CFLAGS)
3928 AC_SUBST(OTHER_FILES)
3929
3930 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
3931                    [Define to the canonical Emacs configuration name.])
3932 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
3933                    [Define to the options passed to configure.])
3934 AH_TEMPLATE(config_opsysfile, [Some platforms that do not use configure
3935   define this to include extra configuration information.])
3936
3937 XMENU_OBJ=
3938 XOBJ=
3939 FONT_OBJ=
3940 if test "${HAVE_X_WINDOWS}" = "yes" ; then
3941   AC_DEFINE(HAVE_X_WINDOWS, 1,
3942             [Define to 1 if you want to use the X window system.])
3943   XMENU_OBJ=xmenu.o
3944   XOBJ="xterm.o xfns.o xselect.o xrdb.o fontset.o xsmfns.o fringe.o image.o xsettings.o xgselect.o"
3945   FONT_OBJ=xfont.o
3946   if test "$HAVE_XFT" = "yes"; then
3947     FONT_OBJ="$FONT_OBJ ftfont.o xftfont.o ftxfont.o"
3948   elif test "$HAVE_FREETYPE" = "yes"; then
3949     FONT_OBJ="$FONT_OBJ ftfont.o ftxfont.o"
3950   fi
3951   AC_SUBST(FONT_OBJ)
3952 fi
3953 AC_SUBST(XMENU_OBJ)
3954 AC_SUBST(XOBJ)
3955 AC_SUBST(FONT_OBJ)
3956
3957 WIDGET_OBJ=
3958 MOTIF_LIBW=
3959 if test "${USE_X_TOOLKIT}" != "none" ; then
3960   WIDGET_OBJ=widget.o
3961   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
3962   if test "${USE_X_TOOLKIT}" = "LUCID"; then
3963     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
3964   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
3965     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
3966     MOTIF_LIBW=-lXm
3967     case "$opsys" in
3968       gnu-linux)
3969         ## Paul Abrahams <abrahams at equinox.shaysnet.com> says this is needed.
3970         MOTIF_LIBW="$MOTIF_LIBW -lXpm"
3971         ;;
3972
3973       unixware)
3974         ## Richard Anthony Ryan <ryanr at ellingtn.ftc.nrcs.usda.gov>
3975         ## says -lXimp is needed in UNIX_SV ... 4.2 1.1.2.
3976         MOTIF_LIBW="MOTIF_LIBW -lXimp"
3977         ;;
3978
3979       aix4-2)
3980         ## olson@mcs.anl.gov says -li18n is needed by -lXm.
3981         MOTIF_LIBW="$MOTIF_LIBW -li18n"
3982         ;;
3983     esac
3984     MOTIF_LIBW="$MOTIF_LIBW $LIBXP"
3985   fi
3986 fi
3987 AC_SUBST(WIDGET_OBJ)
3988
3989 TOOLKIT_LIBW=
3990 case "$USE_X_TOOLKIT" in
3991   MOTIF) TOOLKIT_LIBW="$MOTIF_LIBW" ;;
3992   LUCID) TOOLKIT_LIBW="$LUCID_LIBW" ;;
3993   none) test "x$HAVE_GTK" = "xyes" && TOOLKIT_LIBW="$GTK_LIBS" ;;
3994 esac
3995 AC_SUBST(TOOLKIT_LIBW)
3996
3997 if test "$USE_X_TOOLKIT" = "none"; then
3998   LIBXT_OTHER="\$(LIBXSM)"
3999   OLDXMENU_TARGET="really-oldXMenu"
4000 else
4001   LIBXT_OTHER="\$(LIBXMU) -lXt \$(LIBXTR6) -lXext"
4002   OLDXMENU_TARGET="really-lwlib"
4003 fi
4004 AC_SUBST(LIBXT_OTHER)
4005
4006 ## The X Menu stuff is present in the X10 distribution, but missing
4007 ## from X11.  If we have X10, just use the installed library;
4008 ## otherwise, use our own copy.
4009 if test "${HAVE_X11}" = "yes" ; then
4010   AC_DEFINE(HAVE_X11, 1,
4011             [Define to 1 if you want to use version 11 of X windows.
4012              Otherwise, Emacs expects to use version 10.])
4013
4014   if test "$USE_X_TOOLKIT" = "none"; then
4015     OLDXMENU="\${oldXMenudir}/libXMenu11.a"
4016   else
4017     OLDXMENU="\${lwlibdir}/liblw.a"
4018   fi
4019   LIBXMENU="\$(OLDXMENU)"
4020   LIBX_OTHER="\$(LIBXT) \$(LIBX_EXTRA)"
4021   OLDXMENU_DEPS="\${OLDXMENU} ../src/\${OLDXMENU}"
4022 else
4023   ## For a syntactically valid Makefile; not actually used for anything.
4024   ## See comments in src/Makefile.in.
4025   OLDXMENU=nothing
4026   ## FIXME This case (!HAVE_X11 && HAVE_X_WINDOWS) is no longer possible(?).
4027   if test "${HAVE_X_WINDOWS}" = "yes"; then
4028     LIBXMENU="-lXMenu"
4029   else
4030     LIBXMENU=
4031   fi
4032   LIBX_OTHER=
4033   OLDXMENU_DEPS=
4034 fi
4035
4036 if test "$HAVE_GTK" = "yes" || test "$HAVE_MENUS" != "yes"; then
4037   OLDXMENU_TARGET=
4038   OLDXMENU=nothing
4039   LIBXMENU=
4040   OLDXMENU_DEPS=
4041 fi
4042
4043 AC_SUBST(OLDXMENU_TARGET)
4044 AC_SUBST(OLDXMENU)
4045 AC_SUBST(LIBXMENU)
4046 AC_SUBST(LIBX_OTHER)
4047 AC_SUBST(OLDXMENU_DEPS)
4048
4049 if test "${HAVE_MENUS}" = "yes" ; then
4050   AC_DEFINE(HAVE_MENUS, 1,
4051             [Define to 1 if you have mouse menus.
4052              (This is automatic if you use X, but the option to specify it remains.)
4053              It is also defined with other window systems that support xmenu.c.])
4054 fi
4055
4056 if test "${GNU_MALLOC}" = "yes" ; then
4057   AC_DEFINE(GNU_MALLOC, 1,
4058             [Define to 1 if you want to use the GNU memory allocator.])
4059 fi
4060
4061 RALLOC_OBJ=
4062 if test "${REL_ALLOC}" = "yes" ; then
4063   AC_DEFINE(REL_ALLOC, 1,
4064             [Define REL_ALLOC if you want to use the relocating allocator for
4065              buffer space.])
4066
4067   test "$system_malloc" != "yes" && RALLOC_OBJ=ralloc.o
4068 fi
4069 AC_SUBST(RALLOC_OBJ)
4070
4071 if test "$opsys" = "cygwin"; then
4072   CYGWIN_OBJ="sheap.o"
4073   ## Cygwin differs because of its unexec().
4074   PRE_ALLOC_OBJ=
4075   POST_ALLOC_OBJ=lastfile.o
4076 else
4077   CYGWIN_OBJ=
4078   PRE_ALLOC_OBJ=lastfile.o
4079   POST_ALLOC_OBJ=
4080 fi
4081 AC_SUBST(CYGWIN_OBJ)
4082 AC_SUBST(PRE_ALLOC_OBJ)
4083 AC_SUBST(POST_ALLOC_OBJ)
4084
4085 # Configure gnulib.  Although this does not affect CFLAGS or LIBS permanently.
4086 # it temporarily reverts them to their pre-pkg-config values,
4087 # because gnulib needs to work with both src (which uses the
4088 # pkg-config stuff) and lib-src (which does not).  For example, gnulib
4089 # may need to determine whether LIB_CLOCK_GETTIME should contain -lrt,
4090 # and it therefore needs to run in an environment where LIBS does not
4091 # already contain -lrt merely because 'pkg-config --libs' printed '-lrt'
4092 # for some package unrelated to lib-src.
4093 SAVE_CFLAGS=$CFLAGS
4094 SAVE_LIBS=$LIBS
4095 CFLAGS=$pre_PKG_CONFIG_CFLAGS
4096 LIBS="$LIB_PTHREAD $pre_PKG_CONFIG_LIBS"
4097 gl_ASSERT_NO_GNULIB_POSIXCHECK
4098 gl_ASSERT_NO_GNULIB_TESTS
4099 gl_INIT
4100 CFLAGS=$SAVE_CFLAGS
4101 LIBS=$SAVE_LIBS
4102
4103 case "$opsys" in
4104   aix4-2) LD_SWITCH_SYSTEM_TEMACS="-Wl,-bnodelcsect" ;;
4105
4106   darwin)
4107    ## The -headerpad option tells ld (see man page) to leave room at the
4108    ## end of the header for adding load commands.  Needed for dumping.
4109    ## 0x690 is the total size of 30 segment load commands (at 56
4110    ## each); under Cocoa 31 commands are required.
4111    if test "$HAVE_NS" = "yes"; then
4112      libs_nsgui="-framework AppKit"
4113      headerpad_extra=6C8
4114    else
4115      libs_nsgui=
4116      headerpad_extra=690
4117    fi
4118    LD_SWITCH_SYSTEM_TEMACS="-fno-pie -prebind $libs_nsgui -Xlinker -headerpad -Xlinker $headerpad_extra"
4119
4120    ## This is here because src/Makefile.in did some extra fiddling around
4121    ## with LD_SWITCH_SYSTEM.  The cpp logic was:
4122    ##   #ifndef LD_SWITCH_SYSTEM
4123    ##   #if !defined (__GNUC__) && ((defined (BSD_SYSTEM) && !defined (COFF)))
4124    ## Since all the *bsds define LD_SWITCH_SYSTEM, this simplifies to:
4125    ## not using gcc, darwin.
4126    ## Because this was done in src/Makefile.in, the resulting part of
4127    ## LD_SWITCH_SYSTEM was not used in configure (ie, in ac_link).
4128    ## It therefore seems cleaner to put this in LD_SWITCH_SYSTEM_TEMACS,
4129    ## rather than LD_SWITCH_SYSTEM.
4130    test "x$LD_SWITCH_SYSTEM" = "x" && test "x$GCC" != "xyes" && \
4131      LD_SWITCH_SYSTEM_TEMACS="-X $LD_SWITCH_SYSTEM_TEMACS"
4132    ;;
4133
4134   ## LD_SWITCH_X_SITE_RPATH is a -rpath option saying where to
4135   ## find X at run-time.
4136   ## When handled by cpp, this was in LD_SWITCH_SYSTEM.  However, at the
4137   ## point where configure sourced the s/*.h file, LD_SWITCH_X_SITE_RPATH
4138   ## had not yet been defined and was expanded to null.  Hence LD_SWITCH_SYSTEM
4139   ## had different values in configure (in ac_link) and src/Makefile.in.
4140   ## It seems clearer therefore to put this piece in LD_SWITCH_SYSTEM_TEMACS.
4141   gnu*) LD_SWITCH_SYSTEM_TEMACS="\$(LD_SWITCH_X_SITE_RPATH)" ;;
4142
4143   *) LD_SWITCH_SYSTEM_TEMACS= ;;
4144 esac
4145
4146 if test "$NS_IMPL_GNUSTEP" = "yes"; then
4147   LD_SWITCH_SYSTEM_TEMACS="${LD_SWITCH_SYSTEM_TEMACS} -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES} -lgnustep-gui -lgnustep-base -lobjc -lpthread"
4148 fi
4149
4150 AC_SUBST(LD_SWITCH_SYSTEM_TEMACS)
4151
4152
4153 LD_FIRSTFLAG=
4154 ORDINARY_LINK=
4155 case "$opsys" in
4156   ## gnu: GNU needs its own crt0.
4157   aix4-2|cygwin|darwin|gnu|hpux*|irix6-5|sol2*|unixware) ORDINARY_LINK=yes ;;
4158
4159   ## On post 1.3 releases of NetBSD, gcc -nostdlib also clears the
4160   ## library search parth, i.e. it won't search /usr/lib for libc and
4161   ## friends.  Using -nostartfiles instead avoids this problem, and
4162   ## will also work on earlier NetBSD releases.
4163   netbsd|openbsd) LD_FIRSTFLAG="-nostartfiles" ;;
4164
4165   ## powerpc*: NAKAJI Hiroyuki <nakaji@tutrp.tut.ac.jp> says
4166   ##   MkLinux/LinuxPPC needs this.
4167   ## s390x-* only supports opsys = gnu-linux so it can be added here.
4168   gnu-*)
4169     case "$canonical" in
4170       powerpc*|s390x-*) LD_FIRSTFLAG="-nostdlib" ;;
4171     esac
4172     ;;
4173 esac
4174
4175
4176 if test "x$ORDINARY_LINK" = "xyes"; then
4177
4178   LD_FIRSTFLAG=""
4179   AC_DEFINE(ORDINARY_LINK, 1, [Define if the C compiler is the linker.])
4180
4181 ## The system files defining neither ORDINARY_LINK nor LD_FIRSTFLAG are:
4182 ## freebsd, gnu-* not on powerpc*|s390x*.
4183 elif test "x$GCC" = "xyes" && test "x$LD_FIRSTFLAG" = "x"; then
4184
4185   ## Versions of GCC >= 2.0 put their library, libgcc.a, in obscure
4186   ## places that are difficult to figure out at make time.  Fortunately,
4187   ## these same versions allow you to pass arbitrary flags on to the
4188   ## linker, so there is no reason not to use it as a linker.
4189   ##
4190   ## Well, it is not quite perfect.  The "-nostdlib" keeps GCC from
4191   ## searching for libraries in its internal directories, so we have to
4192   ## ask GCC explicitly where to find libgcc.a (LIB_GCC below).
4193   LD_FIRSTFLAG="-nostdlib"
4194 fi
4195
4196 ## FIXME? What setting of EDIT_LDFLAGS should this have?
4197 test "$NS_IMPL_GNUSTEP" = "yes" && LD_FIRSTFLAG="-rdynamic"
4198
4199 AC_SUBST(LD_FIRSTFLAG)
4200
4201
4202 ## FIXME? The logic here is not precisely the same as that above.
4203 ## There is no check here for a pre-defined LD_FIRSTFLAG.
4204 ## Should we only be setting LIB_GCC if LD ~ -nostdlib?
4205 LIB_GCC=
4206 if test "x$GCC" = "xyes" && test "x$ORDINARY_LINK" != "xyes"; then
4207
4208   case "$opsys" in
4209     freebsd|netbsd|openbsd) LIB_GCC= ;;
4210
4211     gnu-*)
4212       ## armin76@gentoo.org reported that the lgcc_s flag is necessary to
4213       ## build on ARM EABI under GNU/Linux.  (Bug#5518)
4214       case $host_cpu in
4215       arm*)
4216         LIB_GCC="-lgcc_s"
4217         ;;
4218       *)
4219         ## FIXME? s/gnu-linux.h used to define LIB_GCC as below, then
4220         ## immediately undefine it again and redefine it to empty.
4221         ## Was the C_SWITCH_X_SITE part really necessary?
4222 ##      LIB_GCC=`$CC $C_SWITCH_X_SITE -print-libgcc-file-name`
4223         LIB_GCC=
4224         ;;
4225       esac
4226       ;;
4227
4228     ## Ask GCC where to find libgcc.a.
4229     *) LIB_GCC=`$CC -print-libgcc-file-name 2> /dev/null` ;;
4230   esac
4231 fi                              dnl if $GCC
4232 AC_SUBST(LIB_GCC)
4233
4234
4235 ## If we're using X11/GNUstep, define some consequences.
4236 if test "$HAVE_X_WINDOWS" = "yes" || test "$HAVE_NS" = "yes"; then
4237   AC_DEFINE(HAVE_WINDOW_SYSTEM, 1, [Define if you have a window system.])
4238   AC_DEFINE(HAVE_MOUSE, 1, [Define if you have mouse support.])
4239 fi
4240
4241
4242 AH_TOP([/* GNU Emacs site configuration template file.
4243
4244 Copyright (C) 1988, 1993-1994, 1999-2002, 2004-2012
4245   Free Software Foundation, Inc.
4246
4247 This file is part of GNU Emacs.
4248
4249 GNU Emacs is free software: you can redistribute it and/or modify
4250 it under the terms of the GNU General Public License as published by
4251 the Free Software Foundation, either version 3 of the License, or
4252 (at your option) any later version.
4253
4254 GNU Emacs is distributed in the hope that it will be useful,
4255 but WITHOUT ANY WARRANTY; without even the implied warranty of
4256 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
4257 GNU General Public License for more details.
4258
4259 You should have received a copy of the GNU General Public License
4260 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
4261
4262
4263 /* No code in Emacs #includes config.h twice, but some bits of code
4264    intended to work with other packages as well (like gmalloc.c)
4265    think they can include it as many times as they like.  */
4266 #ifndef EMACS_CONFIG_H
4267 #define EMACS_CONFIG_H
4268 ])dnl
4269
4270 AH_BOTTOM([#include <conf_post.h>
4271
4272 #endif /* EMACS_CONFIG_H */
4273
4274 /*
4275 Local Variables:
4276 mode: c
4277 End:
4278 */
4279 ])dnl
4280
4281 #### Report on what we decided to do.
4282 #### Report GTK as a toolkit, even if it doesn't use Xt.
4283 #### It makes printing result more understandable as using GTK sets
4284 #### toolkit_scroll_bars to yes by default.
4285 if test "${HAVE_GTK}" = "yes"; then
4286   if test "${with_gtk3}" = "yes"; then
4287     USE_X_TOOLKIT=GTK3
4288   else
4289     USE_X_TOOLKIT=GTK
4290   fi
4291 fi
4292
4293 echo "
4294 Configured for \`${canonical}'.
4295
4296   Where should the build process find the source code?    ${srcdir}
4297   What compiler should emacs be built with?               ${CC} ${CFLAGS}
4298   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
4299   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
4300   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
4301   What window system should Emacs use?                    ${window_system}
4302   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
4303
4304 if test -n "${x_includes}"; then
4305 echo "  Where do we find X Windows header files?                ${x_includes}"
4306 else
4307 echo "  Where do we find X Windows header files?                Standard dirs"
4308 fi
4309 if test -n "${x_libraries}"; then
4310 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
4311 else
4312 echo "  Where do we find X Windows libraries?                   Standard dirs"
4313 fi
4314
4315 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
4316 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
4317 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
4318 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
4319 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $LIBGIF"
4320 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
4321 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
4322 echo "  Does Emacs use imagemagick?                             ${HAVE_IMAGEMAGICK}"
4323
4324 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
4325 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
4326 echo "  Does Emacs use -lgconf?                                 ${HAVE_GCONF}"
4327 echo "  Does Emacs use GSettings?                               ${HAVE_GSETTINGS}"
4328 echo "  Does Emacs use -lselinux?                               ${HAVE_LIBSELINUX}"
4329 echo "  Does Emacs use -lgnutls?                                ${HAVE_GNUTLS}"
4330 echo "  Does Emacs use -lxml2?                                  ${HAVE_LIBXML2}"
4331
4332 echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
4333 echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
4334 echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
4335 echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
4336
4337 echo "  Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}"
4338 echo
4339
4340 if test -n "${EMACSDATA}"; then
4341    echo "  Environment variable EMACSDATA set to:                  $EMACSDATA"
4342 fi
4343 if test -n "${EMACSDOC}"; then
4344    echo "  Environment variable EMACSDOC set to:                   $EMACSDOC"
4345 fi
4346
4347 echo
4348
4349 if test "$HAVE_NS" = "yes"; then
4350    echo
4351    echo "You must run \"${MAKE-make} install\" in order to test the built application.
4352 The installed application will go to nextstep/Emacs.app and can be
4353 run or moved from there."
4354    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
4355       echo "The application will be fully self-contained."
4356     else
4357       echo "The lisp resources for the application will be installed under ${prefix}.
4358 You may need to run \"${MAKE-make} install\" with sudo.  The application will fail
4359 to run if these resources are not installed."
4360    fi
4361    echo
4362 fi
4363
4364 if test "${opsys}" = "cygwin"; then
4365   case `uname -r` in
4366     1.5.*) AC_MSG_WARN([[building Emacs on Cygwin 1.5 is not supported.]])
4367            echo
4368            ;;
4369   esac
4370 fi
4371
4372 # Remove any trailing slashes in these variables.
4373 [test "${prefix}" != NONE &&
4374   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
4375 test "${exec_prefix}" != NONE &&
4376   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
4377
4378 dnl Obviously there is duplication here wrt $SUBDIR_MAKEFILES.
4379 dnl You _can_ use that variable in AC_CONFIG_FILES, so long as any directory
4380 dnl using automake (ie lib/) is explicitly listed and not "hidden" in a variable
4381 dnl (else you get "no `Makefile.am' found for any configure output").
4382 dnl This will work, but you get a config.status that is not quite right
4383 dnl (see http://lists.gnu.org/archive/html/bug-autoconf/2008-08/msg00028.html).
4384 dnl That doesn't have any obvious consequences for Emacs, but on the whole
4385 dnl it seems better to just live with the duplication.
4386 SUBDIR_MAKEFILES="lib/Makefile lib-src/Makefile oldXMenu/Makefile doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile leim/Makefile"
4387
4388 AC_CONFIG_FILES([Makefile lib/Makefile lib-src/Makefile oldXMenu/Makefile \
4389        doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
4390        doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile \
4391        leim/Makefile])
4392
4393 dnl test/ is not present in release tarfiles.
4394 opt_makefile=test/automated/Makefile
4395
4396 if test -f $srcdir/${opt_makefile}.in; then
4397   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES $opt_makefile"
4398   dnl Again, it's best not to use a variable.  Though you can add
4399   dnl ", [], [opt_makefile='$opt_makefile']" and it should work.
4400   AC_CONFIG_FILES([test/automated/Makefile])
4401 fi
4402
4403
4404 dnl admin/ may or may not be present.
4405 opt_makefile=admin/unidata/Makefile
4406
4407 if test -f $srcdir/${opt_makefile}.in; then
4408   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES $opt_makefile"
4409   AC_CONFIG_FILES([admin/unidata/Makefile])
4410 fi
4411
4412
4413 SUBDIR_MAKEFILES_IN=`echo " ${SUBDIR_MAKEFILES}" | sed -e 's| | $(srcdir)/|g' -e 's|Makefile|Makefile.in|g'`
4414
4415 AC_SUBST(SUBDIR_MAKEFILES_IN)
4416
4417 dnl Make the necessary directories, if they don't exist.
4418 AC_CONFIG_COMMANDS([mkdirs], [
4419 for dir in etc lisp ; do
4420   test -d ${dir} || mkdir ${dir}
4421 done
4422 ])
4423
4424 dnl You might wonder (I did) why epaths.h is generated by running make,
4425 dnl rather than just letting configure generate it from epaths.in.
4426 dnl One reason is that the various paths are not fully expanded (see above);
4427 dnl eg gamedir=${prefix}/var/games/emacs.
4428 dnl Secondly, the GNU Coding standards require that one should be able
4429 dnl to run `make prefix=/some/where/else' and override the values set
4430 dnl by configure.  This also explains the `move-if-change' test and
4431 dnl the use of force in the `epaths-force' rule in Makefile.in.
4432 AC_CONFIG_COMMANDS([epaths], [
4433 echo creating src/epaths.h
4434 ${MAKE-make} MAKEFILE_NAME=do-not-make-Makefile epaths-force
4435 ], [GCC="$GCC" CPPFLAGS="$CPPFLAGS"])
4436
4437 AC_CONFIG_COMMANDS([gdbinit], [
4438 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
4439   echo creating src/.gdbinit
4440   echo source $srcdir/src/.gdbinit > src/.gdbinit
4441 fi
4442 ])
4443
4444 AC_OUTPUT