code.delx.au - gnu-emacs/blob - lisp/ibuf-ext.el

   1 ;;; ibuf-ext.el --- extensions for ibuffer
   2
   3 ;; Copyright (C) 2000, 2001, 2002, 2003, 2004,
   4 ;;   2005, 2006 Free Software Foundation, Inc.
   5
   6 ;; Author: Colin Walters <walters@verbum.org>
   7 ;; Maintainer: John Paul Wallington <jpw@gnu.org>
   8 ;; Created: 2 Dec 2001
   9 ;; Keywords: buffer, convenience
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; This program is free software; you can redistribute it and/or
  14 ;; modify it under the terms of the GNU General Public License as
  15 ;; published by the Free Software Foundation; either version 2, or (at
  16 ;; your option) any later version.
  17
  18 ;; This program is distributed in the hope that it will be useful, but
  19 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  21 ;; General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with this program ; see the file COPYING.  If not, write to
  25 ;; the Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  26 ;; Boston, MA 02110-1301, USA.
  27
  28 ;;; Commentary:
  29
  30 ;; These functions should be automatically loaded when called, but you
  31 ;; can explicity (require 'ibuf-ext) in your ~/.emacs to have them
  32 ;; preloaded.
  33
  34 ;;; Code:
  35
  36 (require 'ibuffer)
  37
  38 (eval-when-compile
  39   (require 'ibuf-macs)
  40   (require 'cl))
  41
  42 ;;; Utility functions
  43 (defun ibuffer-delete-alist (key alist)
  44   "Delete all entries in ALIST that have a key equal to KEY."
  45   (let (entry)
  46     (while (setq entry (assoc key alist))
  47       (setq alist (delete entry alist)))
  48     alist))
  49
  50 ;; borrowed from Gnus
  51 (defun ibuffer-remove-duplicates (list)
  52   "Return a copy of LIST with duplicate elements removed."
  53   (let ((new nil)
  54         (tail list))
  55     (while tail
  56       (or (member (car tail) new)
  57           (setq new (cons (car tail) new)))
  58       (setq tail (cdr tail)))
  59     (nreverse new)))
  60
  61 (defun ibuffer-split-list (ibuffer-split-list-fn ibuffer-split-list-elts)
  62   (let ((hip-crowd nil)
  63         (lamers nil))
  64     (dolist (ibuffer-split-list-elt ibuffer-split-list-elts)
  65       (if (funcall ibuffer-split-list-fn ibuffer-split-list-elt)
  66           (push ibuffer-split-list-elt hip-crowd)
  67         (push ibuffer-split-list-elt lamers)))
  68     ;; Too bad Emacs Lisp doesn't have multiple values.
  69     (list (nreverse hip-crowd) (nreverse lamers))))
  70
  71 (defcustom ibuffer-never-show-predicates nil
  72   "A list of predicates (a regexp or function) for buffers not to display.
  73 If a regexp, then it will be matched against the buffer's name.
  74 If a function, it will be called with the buffer as an argument, and
  75 should return non-nil if this buffer should not be shown."
  76   :type '(repeat (choice regexp function))
  77   :require 'ibuf-ext
  78   :group 'ibuffer)
  79
  80 (defcustom ibuffer-always-show-predicates nil
  81   "A list of predicates (a regexp or function) for buffers to always display.
  82 If a regexp, then it will be matched against the buffer's name.
  83 If a function, it will be called with the buffer as an argument, and
  84 should return non-nil if this buffer should be shown.
  85 Note that buffers matching one of these predicates will be shown
  86 regardless of any active filters in this buffer."
  87   :type '(repeat (choice regexp function))
  88   :group 'ibuffer)
  89
  90 (defvar ibuffer-tmp-hide-regexps nil
  91   "A list of regexps which should match buffer names to not show.")
  92
  93 (defvar ibuffer-tmp-show-regexps nil
  94   "A list of regexps which should match buffer names to always show.")
  95
  96 (defvar ibuffer-auto-mode nil
  97   "If non-nil, Ibuffer auto-mode should be enabled for this buffer.
  98 Do not set this variable directly!  Use the function
  99 `ibuffer-auto-mode' instead.")
 100
 101 (defvar ibuffer-auto-buffers-changed nil)
 102
 103 (defcustom ibuffer-saved-filters '(("gnus"
 104                                     ((or (mode . message-mode)
 105                                          (mode . mail-mode)
 106                                          (mode . gnus-group-mode)
 107                                          (mode . gnus-summary-mode)
 108                                          (mode . gnus-article-mode))))
 109                                    ("programming"
 110                                     ((or (mode . emacs-lisp-mode)
 111                                          (mode . cperl-mode)
 112                                          (mode . c-mode)
 113                                          (mode . java-mode)
 114                                          (mode . idl-mode)
 115                                          (mode . lisp-mode)))))
 116
 117   "An alist of filter qualifiers to switch between.
 118
 119 This variable should look like ((\"STRING\" QUALIFIERS)
 120                                 (\"STRING\" QUALIFIERS) ...), where
 121 QUALIFIERS is a list of the same form as
 122 `ibuffer-filtering-qualifiers'.
 123 See also the variables `ibuffer-filtering-qualifiers',
 124 `ibuffer-filtering-alist', and the functions
 125 `ibuffer-switch-to-saved-filters', `ibuffer-save-filters'."
 126   :type '(repeat sexp)
 127   :group 'ibuffer)
 128
 129 (defvar ibuffer-filtering-qualifiers nil
 130   "A list like (SYMBOL . QUALIFIER) which filters the current buffer list.
 131 See also `ibuffer-filtering-alist'.")
 132
 133 ;; This is now frobbed by `define-ibuffer-filter'.
 134 (defvar ibuffer-filtering-alist nil
 135   "An alist of (SYMBOL DESCRIPTION FUNCTION) which describes a filter.
 136
 137 You most likely do not want to modify this variable directly; see
 138 `define-ibuffer-filter'.
 139
 140 SYMBOL is the symbolic name of the filter.  DESCRIPTION is used when
 141 displaying information to the user.  FUNCTION is given a buffer and
 142 the value of the qualifier, and returns non-nil if and only if the
 143 buffer should be displayed.")
 144
 145 (defcustom ibuffer-filter-format-alist nil
 146   "An alist which has special formats used when a filter is active.
 147 The contents of this variable should look like:
 148  ((FILTER (FORMAT FORMAT ...)) (FILTER (FORMAT FORMAT ...)) ...)
 149
 150 For example, suppose that when you add a filter for buffers whose
 151 major mode is `emacs-lisp-mode', you only want to see the mark and the
 152 name of the buffer.  You could accomplish that by adding:
 153  (mode ((mark \" \" name)))
 154 to this variable."
 155   :type '(repeat (list :tag "Association" (symbol :tag "Filter")
 156                        (list :tag "Formats" (repeat (sexp :tag "Format")))))
 157   :group 'ibuffer)
 158
 159 (defvar ibuffer-cached-filter-formats nil)
 160 (defvar ibuffer-compiled-filter-formats nil)
 161
 162 (defvar ibuffer-filter-groups nil
 163   "A list like ((\"NAME\" ((SYMBOL . QUALIFIER) ...) ...) which groups buffers.
 164 The SYMBOL should be one from `ibuffer-filtering-alist'.
 165 The QUALIFIER should be the same as QUALIFIER in
 166 `ibuffer-filtering-qualifiers'.")
 167
 168 (defcustom ibuffer-show-empty-filter-groups t
 169   "If non-nil, then show the names of filter groups which are empty."
 170   :type 'boolean
 171   :group 'ibuffer)
 172
 173 (defcustom ibuffer-saved-filter-groups nil
 174   "An alist of filtering groups to switch between.
 175
 176 This variable should look like ((\"STRING\" QUALIFIERS)
 177                                 (\"STRING\" QUALIFIERS) ...), where
 178 QUALIFIERS is a list of the same form as
 179 `ibuffer-filtering-qualifiers'.
 180
 181 See also the variables `ibuffer-filter-groups',
 182 `ibuffer-filtering-qualifiers', `ibuffer-filtering-alist', and the
 183 functions `ibuffer-switch-to-saved-filter-group',
 184 `ibuffer-save-filter-group'."
 185   :type '(repeat sexp)
 186   :group 'ibuffer)
 187
 188 (defvar ibuffer-hidden-filter-groups nil
 189   "A list of filtering groups which are currently hidden.")
 190
 191 (defvar ibuffer-filter-group-kill-ring nil)
 192
 193 (defcustom ibuffer-old-time 72
 194   "The number of hours before a buffer is considered \"old\"."
 195   :type '(choice (const :tag "72 hours (3 days)" 72)
 196                  (const :tag "48 hours (2 days)" 48)
 197                  (const :tag "24 hours (1 day)" 24)
 198                  (integer :tag "hours"))
 199   :group 'ibuffer)
 200
 201 (defcustom ibuffer-save-with-custom t
 202   "If non-nil, then use Custom to save interactively changed variables.
 203 Currently, this only applies to `ibuffer-saved-filters' and
 204 `ibuffer-saved-filter-groups'."
 205   :type 'boolean
 206   :group 'ibuffer)
 207
 208 (defun ibuffer-ext-visible-p (buf all &optional ibuffer-buf)
 209   (or
 210    (ibuffer-buf-matches-predicates buf ibuffer-tmp-show-regexps)
 211    (and (not
 212          (or
 213           (ibuffer-buf-matches-predicates buf ibuffer-tmp-hide-regexps)
 214           (ibuffer-buf-matches-predicates buf ibuffer-never-show-predicates)))
 215         (or all
 216             (not
 217              (ibuffer-buf-matches-predicates buf ibuffer-maybe-show-predicates)))
 218         (or ibuffer-view-ibuffer
 219             (and ibuffer-buf
 220                  (not (eq ibuffer-buf buf))))
 221         (or
 222          (ibuffer-included-in-filters-p buf ibuffer-filtering-qualifiers)
 223          (ibuffer-buf-matches-predicates buf ibuffer-always-show-predicates)))))
 224
 225 (defun ibuffer-auto-update-changed ()
 226   (when (frame-or-buffer-changed-p 'ibuffer-auto-buffers-changed)
 227     (mapcar #'(lambda (buf)
 228                 (ignore-errors
 229                   (with-current-buffer buf
 230                     (when (and ibuffer-auto-mode
 231                                (eq major-mode 'ibuffer-mode))
 232                       (ibuffer-update nil t)))))
 233             (buffer-list))))
 234
 235 ;;;###autoload
 236 (defun ibuffer-auto-mode (&optional arg)
 237   "Toggle use of Ibuffer's auto-update facility.
 238 With numeric ARG, enable auto-update if and only if ARG is positive."
 239   (interactive)
 240   (unless (eq major-mode 'ibuffer-mode)
 241     (error "This buffer is not in Ibuffer mode"))
 242   (set (make-local-variable 'ibuffer-auto-mode)
 243        (if arg
 244            (plusp arg)
 245          (not ibuffer-auto-mode)))
 246   (frame-or-buffer-changed-p 'ibuffer-auto-buffers-changed)
 247   (add-hook 'post-command-hook 'ibuffer-auto-update-changed)
 248   (ibuffer-update-mode-name))
 249
 250 ;;;###autoload
 251 (defun ibuffer-mouse-filter-by-mode (event)
 252   "Enable or disable filtering by the major mode chosen via mouse."
 253   (interactive "e")
 254   (ibuffer-interactive-filter-by-mode event))
 255
 256 ;;;###autoload
 257 (defun ibuffer-interactive-filter-by-mode (event-or-point)
 258   "Enable or disable filtering by the major mode at point."
 259   (interactive "d")
 260   (if (eventp event-or-point)
 261       (posn-set-point (event-end event-or-point))
 262     (goto-char event-or-point))
 263   (let ((buf (ibuffer-current-buffer)))
 264     (if (assq 'mode ibuffer-filtering-qualifiers)
 265         (setq ibuffer-filtering-qualifiers
 266               (ibuffer-delete-alist 'mode ibuffer-filtering-qualifiers))
 267       (ibuffer-push-filter (cons 'mode
 268                                 (with-current-buffer buf
 269                                   major-mode)))))
 270   (ibuffer-update nil t))
 271
 272 ;;;###autoload
 273 (defun ibuffer-mouse-toggle-filter-group (event)
 274   "Toggle the display status of the filter group chosen with the mouse."
 275   (interactive "e")
 276   (ibuffer-toggle-filter-group-1 (save-excursion
 277                                    (mouse-set-point event)
 278                                    (point))))
 279
 280 ;;;###autoload
 281 (defun ibuffer-toggle-filter-group ()
 282   "Toggle the display status of the filter group on this line."
 283   (interactive)
 284   (ibuffer-toggle-filter-group-1 (point)))
 285
 286 (defun ibuffer-toggle-filter-group-1 (posn)
 287   (let ((name (get-text-property posn 'ibuffer-filter-group-name)))
 288     (unless (stringp name)
 289       (error "No filtering group name present"))
 290     (if (member name ibuffer-hidden-filter-groups)
 291         (setq ibuffer-hidden-filter-groups
 292               (delete name ibuffer-hidden-filter-groups))
 293       (push name ibuffer-hidden-filter-groups))
 294     (ibuffer-update nil t)))
 295
 296 ;;;###autoload
 297 (defun ibuffer-forward-filter-group (&optional count)
 298   "Move point forwards by COUNT filtering groups."
 299   (interactive "P")
 300   (unless count
 301     (setq count 1))
 302   (when (> count 0)
 303     (when (get-text-property (point) 'ibuffer-filter-group-name)
 304       (goto-char (next-single-property-change
 305                   (point) 'ibuffer-filter-group-name
 306                   nil (point-max))))
 307     (goto-char (next-single-property-change
 308                 (point) 'ibuffer-filter-group-name
 309                 nil (point-max)))
 310     (ibuffer-forward-filter-group (1- count)))
 311   (ibuffer-forward-line 0))
 312
 313 ;;;###autoload
 314 (defun ibuffer-backward-filter-group (&optional count)
 315   "Move point backwards by COUNT filtering groups."
 316   (interactive "P")
 317   (unless count
 318     (setq count 1))
 319   (when (> count 0)
 320     (when (get-text-property (point) 'ibuffer-filter-group-name)
 321       (goto-char (previous-single-property-change
 322                   (point) 'ibuffer-filter-group-name
 323                   nil (point-min))))
 324     (goto-char (previous-single-property-change
 325                 (point) 'ibuffer-filter-group-name
 326                 nil (point-min)))
 327     (ibuffer-backward-filter-group (1- count)))
 328   (when (= (point) (point-min))
 329     (goto-char (point-max))
 330     (ibuffer-backward-filter-group 1))
 331   (ibuffer-forward-line 0))
 332
 333 ;;;###autoload (autoload 'ibuffer-do-shell-command-pipe "ibuf-ext")
 334 (define-ibuffer-op shell-command-pipe (command)
 335   "Pipe the contents of each marked buffer to shell command COMMAND."
 336   (:interactive "sPipe to shell command: "
 337    :opstring "Shell command executed on"
 338    :modifier-p nil)
 339   (shell-command-on-region
 340    (point-min) (point-max) command
 341    (get-buffer-create "* ibuffer-shell-output*")))
 342
 343 ;;;###autoload (autoload 'ibuffer-do-shell-command-pipe-replace "ibuf-ext")
 344 (define-ibuffer-op shell-command-pipe-replace (command)
 345   "Replace the contents of marked buffers with output of pipe to COMMAND."
 346   (:interactive "sPipe to shell command (replace): "
 347    :opstring "Buffer contents replaced in"
 348    :active-opstring "replace buffer contents in"
 349    :dangerous t
 350    :modifier-p t)
 351   (with-current-buffer buf
 352     (shell-command-on-region (point-min) (point-max)
 353                              command nil t)))
 354
 355 ;;;###autoload (autoload 'ibuffer-do-shell-command-file "ibuf-ext")
 356 (define-ibuffer-op shell-command-file (command)
 357   "Run shell command COMMAND separately on files of marked buffers."
 358   (:interactive "sShell command on buffer's file: "
 359    :opstring "Shell command executed on"
 360    :modifier-p nil)
 361   (shell-command (concat command " "
 362                          (shell-quote-argument
 363                           (if buffer-file-name
 364                               buffer-file-name
 365                             (make-temp-file
 366                              (substring (buffer-name) 0 (min 10 (length (buffer-name))))))))))
 367
 368 ;;;###autoload (autoload 'ibuffer-do-eval "ibuf-ext")
 369 (define-ibuffer-op eval (form)
 370   "Evaluate FORM in each of the buffers.
 371 Does not display the buffer during evaluation. See
 372 `ibuffer-do-view-and-eval' for that."
 373   (:interactive "xEval in buffers (form): "
 374    :opstring "evaluated in"
 375    :modifier-p :maybe)
 376   (eval form))
 377
 378 ;;;###autoload (autoload 'ibuffer-do-view-and-eval "ibuf-ext")
 379 (define-ibuffer-op view-and-eval (form)
 380   "Evaluate FORM while displaying each of the marked buffers.
 381 To evaluate a form without viewing the buffer, see `ibuffer-do-eval'."
 382   (:interactive "xEval viewing buffers (form): "
 383    :opstring "evaluated in"
 384    :complex t
 385    :modifier-p :maybe)
 386   (let ((ibuffer-buf (current-buffer)))
 387     (unwind-protect
 388         (progn
 389           (switch-to-buffer buf)
 390           (eval form))
 391       (switch-to-buffer ibuffer-buf))))
 392
 393 ;;;###autoload (autoload 'ibuffer-do-rename-uniquely "ibuf-ext")
 394 (define-ibuffer-op rename-uniquely ()
 395   "Rename marked buffers as with `rename-uniquely'."
 396   (:opstring "renamed"
 397    :modifier-p t)
 398   (rename-uniquely))
 399
 400 ;;;###autoload (autoload 'ibuffer-do-revert "ibuf-ext")
 401 (define-ibuffer-op revert ()
 402   "Revert marked buffers as with `revert-buffer'."
 403   (:dangerous t
 404    :opstring "reverted"
 405    :active-opstring "revert"
 406    :modifier-p :maybe)
 407   (revert-buffer t t))
 408
 409 ;;;###autoload (autoload 'ibuffer-do-replace-regexp "ibuf-ext")
 410 (define-ibuffer-op replace-regexp (from-str to-str)
 411   "Perform a `replace-regexp' in marked buffers."
 412   (:interactive
 413    (let* ((from-str (read-from-minibuffer "Replace regexp: "))
 414           (to-str (read-from-minibuffer (concat "Replace " from-str
 415                                                 " with: "))))
 416      (list from-str to-str))
 417    :opstring "replaced in"
 418    :complex t
 419    :modifier-p :maybe)
 420   (save-window-excursion
 421     (switch-to-buffer buf)
 422     (save-excursion
 423       (goto-char (point-min))
 424       (let ((case-fold-search ibuffer-case-fold-search))
 425         (while (re-search-forward from-str nil t)
 426           (replace-match to-str))))
 427     t))
 428
 429 ;;;###autoload (autoload 'ibuffer-do-query-replace "ibuf-ext")
 430 (define-ibuffer-op query-replace (&rest args)
 431   "Perform a `query-replace' in marked buffers."
 432   (:interactive
 433    (query-replace-read-args "Query replace" t t)
 434    :opstring "replaced in"
 435    :complex t
 436    :modifier-p :maybe)
 437   (save-window-excursion
 438     (switch-to-buffer buf)
 439     (save-excursion
 440       (let ((case-fold-search ibuffer-case-fold-search))
 441         (goto-char (point-min))
 442         (apply #'query-replace args)))
 443     t))
 444
 445 ;;;###autoload (autoload 'ibuffer-do-query-replace-regexp "ibuf-ext")
 446 (define-ibuffer-op query-replace-regexp (&rest args)
 447   "Perform a `query-replace-regexp' in marked buffers."
 448   (:interactive
 449    (query-replace-read-args "Query replace regexp" t t)
 450    :opstring "replaced in"
 451    :complex t
 452    :modifier-p :maybe)
 453   (save-window-excursion
 454     (switch-to-buffer buf)
 455     (save-excursion
 456       (let ((case-fold-search ibuffer-case-fold-search))
 457         (goto-char (point-min))
 458         (apply #'query-replace-regexp args)))
 459     t))
 460
 461 ;;;###autoload (autoload 'ibuffer-do-print "ibuf-ext")
 462 (define-ibuffer-op print ()
 463   "Print marked buffers as with `print-buffer'."
 464   (:opstring "printed"
 465    :modifier-p nil)
 466   (print-buffer))
 467
 468 ;;;###autoload
 469 (defun ibuffer-included-in-filters-p (buf filters)
 470   (not
 471    (memq nil ;; a filter will return nil if it failed
 472          (mapcar
 473           ;; filter should be like (TYPE . QUALIFIER), or
 474           ;; (or (TYPE . QUALIFIER) (TYPE . QUALIFIER) ...)
 475           #'(lambda (qual)
 476               (ibuffer-included-in-filter-p buf qual))
 477           filters))))
 478
 479 (defun ibuffer-included-in-filter-p (buf filter)
 480   (if (eq (car filter) 'not)
 481       (not (ibuffer-included-in-filter-p-1 buf (cdr filter)))
 482     (ibuffer-included-in-filter-p-1 buf filter)))
 483
 484 (defun ibuffer-included-in-filter-p-1 (buf filter)
 485   (not
 486    (not
 487     (case (car filter)
 488       (or
 489        (memq t (mapcar #'(lambda (x)
 490                            (ibuffer-included-in-filter-p buf x))
 491                        (cdr filter))))
 492       (saved
 493        (let ((data
 494               (assoc (cdr filter)
 495                      ibuffer-saved-filters)))
 496          (unless data
 497            (ibuffer-filter-disable)
 498            (error "Unknown saved filter %s" (cdr filter)))
 499          (ibuffer-included-in-filters-p buf (cadr data))))
 500       (t
 501        (let ((filterdat (assq (car filter)
 502                               ibuffer-filtering-alist)))
 503          ;; filterdat should be like (TYPE DESCRIPTION FUNC)
 504          ;; just a sanity check
 505         (unless filterdat
 506           (ibuffer-filter-disable)
 507           (error "Undefined filter %s" (car filter)))
 508         (not
 509          (not
 510           (funcall (caddr filterdat)
 511                    buf
 512                    (cdr filter))))))))))
 513
 514 (defun ibuffer-generate-filter-groups (bmarklist &optional noempty nodefault)
 515   (let ((filter-group-alist (if nodefault
 516                                 ibuffer-filter-groups
 517                               (append ibuffer-filter-groups
 518                                       (list (cons "Default" nil))))))
 519 ;;     (dolist (hidden ibuffer-hidden-filter-groups)
 520 ;;       (setq filter-group-alist (ibuffer-delete-alist
 521 ;;                                 hidden filter-group-alist)))
 522     (let ((vec (make-vector (length filter-group-alist) nil))
 523           (i 0))
 524       (dolist (filtergroup filter-group-alist)
 525         (let ((filterset (cdr filtergroup)))
 526           (multiple-value-bind (hip-crowd lamers)
 527               (ibuffer-split-list (lambda (bufmark)
 528                                     (ibuffer-included-in-filters-p (car bufmark)
 529                                                                    filterset))
 530                                   bmarklist)
 531             (aset vec i hip-crowd)
 532             (incf i)
 533             (setq bmarklist lamers))))
 534       (let (ret)
 535         (dotimes (j i ret)
 536           (let ((bufs (aref vec j)))
 537             (unless (and noempty (null bufs))
 538               (push (cons (car (nth j filter-group-alist))
 539                           bufs)
 540                     ret))))))))
 541
 542 ;;;###autoload
 543 (defun ibuffer-filters-to-filter-group (name)
 544   "Make the current filters into a filtering group."
 545   (interactive "sName for filtering group: ")
 546   (when (null ibuffer-filtering-qualifiers)
 547     (error "No filters in effect"))
 548   (push (cons name ibuffer-filtering-qualifiers) ibuffer-filter-groups)
 549   (ibuffer-filter-disable))
 550
 551 ;;;###autoload
 552 (defun ibuffer-set-filter-groups-by-mode ()
 553   "Set the current filter groups to filter by mode."
 554   (interactive)
 555   (setq ibuffer-filter-groups
 556         (mapcar (lambda (mode)
 557                   (cons (format "%s" mode) `((mode . ,mode))))
 558                 (let ((modes
 559                        (ibuffer-remove-duplicates
 560                         (mapcar (lambda (buf)
 561                                   (with-current-buffer buf major-mode))
 562                                 (buffer-list)))))
 563                   (if ibuffer-view-ibuffer
 564                       modes
 565                     (delq 'ibuffer-mode modes)))))
 566   (ibuffer-update nil t))
 567
 568 ;;;###autoload
 569 (defun ibuffer-pop-filter-group ()
 570   "Remove the first filter group."
 571   (interactive)
 572   (when (null ibuffer-filter-groups)
 573     (error "No filter groups active"))
 574   (setq ibuffer-hidden-filter-groups
 575         (delete (pop ibuffer-filter-groups)
 576                 ibuffer-hidden-filter-groups))
 577   (ibuffer-update nil t))
 578
 579 (defun ibuffer-read-filter-group-name (msg &optional nodefault noerror)
 580   (when (and (not noerror) (null ibuffer-filter-groups))
 581     (error "No filter groups active"))
 582   ;; `ibuffer-generate-filter-groups' returns all non-hidden filter
 583   ;; groups, possibly excluding empty groups or Default.
 584   ;; We add `ibuffer-hidden-filter-groups' to the list, excluding
 585   ;; Default if necessary.
 586   (completing-read msg (nconc
 587                         (ibuffer-generate-filter-groups
 588                          (ibuffer-current-state-list)
 589                          (not ibuffer-show-empty-filter-groups)
 590                          nodefault)
 591                         (if nodefault
 592                             (remove "Default" ibuffer-hidden-filter-groups)
 593                           ibuffer-hidden-filter-groups))
 594                    nil t))
 595
 596 ;;;###autoload
 597 (defun ibuffer-decompose-filter-group (group)
 598   "Decompose the filter group GROUP into active filters."
 599   (interactive
 600    (list (ibuffer-read-filter-group-name "Decompose filter group: " t)))
 601   (let ((data (cdr (assoc group ibuffer-filter-groups))))
 602     (setq ibuffer-filter-groups (ibuffer-delete-alist
 603                                  group ibuffer-filter-groups)
 604           ibuffer-filtering-qualifiers data))
 605   (ibuffer-update nil t))
 606
 607 ;;;###autoload
 608 (defun ibuffer-clear-filter-groups ()
 609   "Remove all filter groups."
 610   (interactive)
 611   (setq ibuffer-filter-groups nil
 612         ibuffer-hidden-filter-groups nil)
 613   (ibuffer-update nil t))
 614
 615 (defun ibuffer-current-filter-groups-with-position ()
 616   (save-excursion
 617     (goto-char (point-min))
 618     (let ((pos nil)
 619           (result nil))
 620       (while (and (not (eobp))
 621                   (setq pos (next-single-property-change
 622                              (point) 'ibuffer-filter-group-name)))
 623         (goto-char pos)
 624         (push (cons (get-text-property (point) 'ibuffer-filter-group-name)
 625                     pos)
 626               result)
 627         (goto-char (next-single-property-change
 628                     pos 'ibuffer-filter-group-name)))
 629       (nreverse result))))
 630
 631 ;;;###autoload
 632 (defun ibuffer-jump-to-filter-group (name)
 633   "Move point to the filter group whose name is NAME."
 634   (interactive
 635    (list (ibuffer-read-filter-group-name "Jump to filter group: ")))
 636   (ibuffer-aif (assoc name (ibuffer-current-filter-groups-with-position))
 637       (goto-char (cdr it))
 638     (error "No filter group with name %s" name)))
 639
 640 ;;;###autoload
 641 (defun ibuffer-kill-filter-group (name)
 642   "Kill the filter group named NAME.
 643 The group will be added to `ibuffer-filter-group-kill-ring'."
 644   (interactive (list (ibuffer-read-filter-group-name "Kill filter group: " t)))
 645   (when (equal name "Default")
 646     (error "Can't kill default filter group"))
 647   (ibuffer-aif (assoc name ibuffer-filter-groups)
 648       (progn
 649         (push (copy-tree it) ibuffer-filter-group-kill-ring)
 650         (setq ibuffer-filter-groups (ibuffer-delete-alist
 651                                      name ibuffer-filter-groups))
 652         (setq ibuffer-hidden-filter-groups
 653               (delete name ibuffer-hidden-filter-groups)))
 654     (error "No filter group with name \"%s\"" name))
 655   (ibuffer-update nil t))
 656
 657 ;;;###autoload
 658 (defun ibuffer-kill-line (&optional arg interactive-p)
 659   "Kill the filter group at point.
 660 See also `ibuffer-kill-filter-group'."
 661   (interactive "P\np")
 662   (ibuffer-aif (save-excursion
 663                  (ibuffer-forward-line 0)
 664                  (get-text-property (point) 'ibuffer-filter-group-name))
 665       (progn
 666         (ibuffer-kill-filter-group it))
 667       (funcall (if interactive-p #'call-interactively #'funcall)
 668                #'kill-line arg)))
 669
 670 (defun ibuffer-insert-filter-group-before (newgroup group)
 671   (let* ((found nil)
 672          (pos (let ((groups (mapcar #'car ibuffer-filter-groups))
 673                     (res 0))
 674                 (while groups
 675                   (if (equal (car groups) group)
 676                       (setq found t
 677                             groups nil)
 678                     (incf res)
 679                     (setq groups (cdr groups))))
 680                 res)))
 681     (cond ((not found)
 682            (setq ibuffer-filter-groups
 683                  (nconc ibuffer-filter-groups (list newgroup))))
 684           ((zerop pos)
 685            (push newgroup ibuffer-filter-groups))
 686           (t
 687            (let ((cell (nthcdr pos ibuffer-filter-groups)))
 688              (setf (cdr cell) (cons (car cell) (cdr cell)))
 689              (setf (car cell) newgroup))))))
 690
 691 ;;;###autoload
 692 (defun ibuffer-yank ()
 693   "Yank the last killed filter group before group at point."
 694   (interactive)
 695   (ibuffer-yank-filter-group
 696    (or (get-text-property (point) 'ibuffer-filter-group-name)
 697        (get-text-property (point) 'ibuffer-filter-group)
 698        (error "No filter group at point"))))
 699
 700 ;;;###autoload
 701 (defun ibuffer-yank-filter-group (name)
 702   "Yank the last killed filter group before group named NAME."
 703   (interactive (list (ibuffer-read-filter-group-name
 704                         "Yank filter group before group: ")))
 705   (unless ibuffer-filter-group-kill-ring
 706     (error "The Ibuffer filter group kill-ring is empty"))
 707   (save-excursion
 708     (ibuffer-forward-line 0)
 709     (ibuffer-insert-filter-group-before (pop ibuffer-filter-group-kill-ring)
 710                                         name))
 711   (ibuffer-update nil t))
 712
 713 ;;;###autoload
 714 (defun ibuffer-save-filter-groups (name groups)
 715   "Save all active filter groups GROUPS as NAME.
 716 They are added to `ibuffer-saved-filter-groups'.  Interactively,
 717 prompt for NAME, and use the current filters."
 718   (interactive
 719    (if (null ibuffer-filter-groups)
 720        (error "No filter groups active")
 721      (list
 722       (read-from-minibuffer "Save current filter groups as: ")
 723       ibuffer-filter-groups)))
 724   (ibuffer-aif (assoc name ibuffer-saved-filter-groups)
 725       (setcdr it groups)
 726     (push (cons name groups) ibuffer-saved-filter-groups))
 727   (ibuffer-maybe-save-stuff)
 728   (ibuffer-update-mode-name))
 729
 730 ;;;###autoload
 731 (defun ibuffer-delete-saved-filter-groups (name)
 732   "Delete saved filter groups with NAME.
 733 They are removed from `ibuffer-saved-filter-groups'."
 734   (interactive
 735    (list
 736     (if (null ibuffer-saved-filter-groups)
 737         (error "No saved filter groups")
 738       (completing-read "Delete saved filter group: "
 739                        ibuffer-saved-filter-groups nil t))))
 740   (setq ibuffer-saved-filter-groups
 741         (ibuffer-delete-alist name ibuffer-saved-filter-groups))
 742   (ibuffer-maybe-save-stuff)
 743   (ibuffer-update nil t))
 744
 745 ;;;###autoload
 746 (defun ibuffer-switch-to-saved-filter-groups (name)
 747   "Set this buffer's filter groups to saved version with NAME.
 748 The value from `ibuffer-saved-filters' is used.
 749 If prefix argument ADD is non-nil, then add the saved filters instead
 750 of replacing the current filters."
 751   (interactive
 752    (list
 753     (if (null ibuffer-saved-filter-groups)
 754         (error "No saved filters")
 755       (completing-read "Switch to saved filter group: "
 756                        ibuffer-saved-filter-groups nil t))))
 757   (setq ibuffer-filter-groups (cdr (assoc name ibuffer-saved-filter-groups))
 758         ibuffer-hidden-filter-groups nil)
 759   (ibuffer-update nil t))
 760
 761 ;;;###autoload
 762 (defun ibuffer-filter-disable ()
 763   "Disable all filters currently in effect in this buffer."
 764   (interactive)
 765   (setq ibuffer-filtering-qualifiers nil)
 766   (let ((buf (ibuffer-current-buffer)))
 767     (ibuffer-update nil t)
 768     (when buf
 769       (ibuffer-jump-to-buffer (buffer-name buf)))))
 770
 771 ;;;###autoload
 772 (defun ibuffer-pop-filter ()
 773   "Remove the top filter in this buffer."
 774   (interactive)
 775   (when (null ibuffer-filtering-qualifiers)
 776     (error "No filters in effect"))
 777   (pop ibuffer-filtering-qualifiers)
 778   (let ((buf (ibuffer-current-buffer)))
 779     (ibuffer-update nil t)
 780     (when buf
 781       (ibuffer-jump-to-buffer (buffer-name buf)))))
 782
 783 (defun ibuffer-push-filter (qualifier)
 784   "Add QUALIFIER to `ibuffer-filtering-qualifiers'."
 785   (push qualifier ibuffer-filtering-qualifiers))
 786
 787 ;;;###autoload
 788 (defun ibuffer-decompose-filter ()
 789   "Separate the top compound filter (OR, NOT, or SAVED) in this buffer.
 790
 791 This means that the topmost filter on the filtering stack, which must
 792 be a complex filter like (OR [name: foo] [mode: bar-mode]), will be
 793 turned into two separate filters [name: foo] and [mode: bar-mode]."
 794   (interactive)
 795   (when (null ibuffer-filtering-qualifiers)
 796     (error "No filters in effect"))
 797   (let ((lim (pop ibuffer-filtering-qualifiers)))
 798     (case (car lim)
 799       (or
 800        (setq ibuffer-filtering-qualifiers (append
 801                                           (cdr lim)
 802                                           ibuffer-filtering-qualifiers)))
 803       (saved
 804        (let ((data
 805               (assoc (cdr lim)
 806                      ibuffer-saved-filters)))
 807          (unless data
 808            (ibuffer-filter-disable)
 809            (error "Unknown saved filter %s" (cdr lim)))
 810          (setq ibuffer-filtering-qualifiers (append
 811                                             (cadr data)
 812                                             ibuffer-filtering-qualifiers))))
 813       (not
 814        (push (cdr lim)
 815              ibuffer-filtering-qualifiers))
 816       (t
 817        (error "Filter type %s is not compound" (car lim)))))
 818   (ibuffer-update nil t))
 819
 820 ;;;###autoload
 821 (defun ibuffer-exchange-filters ()
 822   "Exchange the top two filters on the stack in this buffer."
 823   (interactive)
 824   (when (< (length ibuffer-filtering-qualifiers)
 825            2)
 826     (error "Need two filters to exchange"))
 827   (let ((first (pop ibuffer-filtering-qualifiers))
 828         (second (pop ibuffer-filtering-qualifiers)))
 829     (push first ibuffer-filtering-qualifiers)
 830     (push second ibuffer-filtering-qualifiers))
 831   (ibuffer-update nil t))
 832
 833 ;;;###autoload
 834 (defun ibuffer-negate-filter ()
 835   "Negate the sense of the top filter in the current buffer."
 836   (interactive)
 837   (when (null ibuffer-filtering-qualifiers)
 838     (error "No filters in effect"))
 839   (let ((lim (pop ibuffer-filtering-qualifiers)))
 840     (push (if (eq (car lim) 'not)
 841               (cdr lim)
 842             (cons 'not lim))
 843           ibuffer-filtering-qualifiers))
 844   (ibuffer-update nil t))
 845
 846 ;;;###autoload
 847 (defun ibuffer-or-filter (&optional reverse)
 848   "Replace the top two filters in this buffer with their logical OR.
 849 If optional argument REVERSE is non-nil, instead break the top OR
 850 filter into parts."
 851   (interactive "P")
 852   (if reverse
 853       (progn
 854         (when (or (null ibuffer-filtering-qualifiers)
 855                   (not (eq 'or (caar ibuffer-filtering-qualifiers))))
 856           (error "Top filter is not an OR"))
 857         (let ((lim (pop ibuffer-filtering-qualifiers)))
 858           (setq ibuffer-filtering-qualifiers
 859                 (nconc (cdr lim) ibuffer-filtering-qualifiers))))
 860     (when (< (length ibuffer-filtering-qualifiers) 2)
 861       (error "Need two filters to OR"))
 862     ;; If the second filter is an OR, just add to it.
 863     (let ((first (pop ibuffer-filtering-qualifiers))
 864           (second (pop ibuffer-filtering-qualifiers)))
 865       (if (eq 'or (car second))
 866           (push (nconc (list 'or first) (cdr second))
 867                 ibuffer-filtering-qualifiers)
 868         (push (list 'or first second)
 869               ibuffer-filtering-qualifiers))))
 870   (ibuffer-update nil t))
 871
 872 (defun ibuffer-maybe-save-stuff ()
 873   (when ibuffer-save-with-custom
 874     (if (fboundp 'customize-save-variable)
 875         (progn
 876           (customize-save-variable 'ibuffer-saved-filters
 877                                    ibuffer-saved-filters)
 878           (customize-save-variable 'ibuffer-saved-filter-groups
 879                                    ibuffer-saved-filter-groups))
 880       (message "Not saved permanently: Customize not available"))))
 881
 882 ;;;###autoload
 883 (defun ibuffer-save-filters (name filters)
 884   "Save FILTERS in this buffer with name NAME in `ibuffer-saved-filters'.
 885 Interactively, prompt for NAME, and use the current filters."
 886   (interactive
 887    (if (null ibuffer-filtering-qualifiers)
 888        (error "No filters currently in effect")
 889      (list
 890       (read-from-minibuffer "Save current filters as: ")
 891       ibuffer-filtering-qualifiers)))
 892   (ibuffer-aif (assoc name ibuffer-saved-filters)
 893       (setcdr it filters)
 894     (push (list name filters) ibuffer-saved-filters))
 895   (ibuffer-maybe-save-stuff)
 896   (ibuffer-update-mode-name))
 897
 898 ;;;###autoload
 899 (defun ibuffer-delete-saved-filters (name)
 900   "Delete saved filters with NAME from `ibuffer-saved-filters'."
 901   (interactive
 902    (list
 903     (if (null ibuffer-saved-filters)
 904         (error "No saved filters")
 905       (completing-read "Delete saved filters: "
 906                        ibuffer-saved-filters nil t))))
 907   (setq ibuffer-saved-filters
 908         (ibuffer-delete-alist name ibuffer-saved-filters))
 909   (ibuffer-maybe-save-stuff)
 910   (ibuffer-update nil t))
 911
 912 ;;;###autoload
 913 (defun ibuffer-add-saved-filters (name)
 914   "Add saved filters from `ibuffer-saved-filters' to this buffer's filters."
 915   (interactive
 916    (list
 917     (if (null ibuffer-saved-filters)
 918         (error "No saved filters")
 919       (completing-read "Add saved filters: "
 920                        ibuffer-saved-filters nil t))))
 921   (push (cons 'saved name) ibuffer-filtering-qualifiers)
 922   (ibuffer-update nil t))
 923
 924 ;;;###autoload
 925 (defun ibuffer-switch-to-saved-filters (name)
 926   "Set this buffer's filters to filters with NAME from `ibuffer-saved-filters'.
 927 If prefix argument ADD is non-nil, then add the saved filters instead
 928 of replacing the current filters."
 929   (interactive
 930    (list
 931     (if (null ibuffer-saved-filters)
 932         (error "No saved filters")
 933       (completing-read "Switch to saved filters: "
 934                        ibuffer-saved-filters nil t))))
 935   (setq ibuffer-filtering-qualifiers (list (cons 'saved name)))
 936   (ibuffer-update nil t))
 937
 938 (defun ibuffer-format-filter-group-data (filter)
 939   (if (equal filter "Default")
 940       ""
 941     (concat "Filter:" (mapconcat #'ibuffer-format-qualifier
 942                                  (cdr (assq filter ibuffer-filter-groups))
 943                                  " "))))
 944
 945 (defun ibuffer-format-qualifier (qualifier)
 946   (if (eq (car-safe qualifier) 'not)
 947       (concat " [NOT" (ibuffer-format-qualifier-1 (cdr qualifier)) "]")
 948     (ibuffer-format-qualifier-1 qualifier)))
 949
 950 (defun ibuffer-format-qualifier-1 (qualifier)
 951   (case (car qualifier)
 952     (saved
 953      (concat " [filter: " (cdr qualifier) "]"))
 954     (or
 955      (concat " [OR" (mapconcat #'ibuffer-format-qualifier
 956                                (cdr qualifier) "") "]"))
 957     (t
 958      (let ((type (assq (car qualifier) ibuffer-filtering-alist)))
 959        (unless qualifier
 960          (error "Ibuffer: bad qualifier %s" qualifier))
 961        (concat " [" (cadr type) ": " (format "%s]" (cdr qualifier)))))))
 962
 963
 964 (defun ibuffer-list-buffer-modes ()
 965   "Create an alist of buffer modes currently in use.
 966 The list returned will be of the form (\"MODE-NAME\" . MODE-SYMBOL)."
 967   (let ((bufs (buffer-list))
 968         (modes)
 969         (this-mode))
 970     (while bufs
 971       (setq this-mode
 972             (with-current-buffer
 973                 (car bufs)
 974               major-mode)
 975             bufs (cdr bufs))
 976       (add-to-list
 977        'modes
 978        `(,(symbol-name this-mode) .
 979          ,this-mode)))
 980     modes))
 981
 982
 983 ;;; Extra operation definitions
 984
 985 ;;;###autoload (autoload 'ibuffer-filter-by-mode "ibuf-ext")
 986 (define-ibuffer-filter mode
 987   "Toggle current view to buffers with major mode QUALIFIER."
 988   (:description "major mode"
 989    :reader
 990    (intern
 991     (completing-read "Filter by major mode: " obarray
 992                      #'(lambda (e)
 993                          (string-match "-mode$"
 994                                        (symbol-name e)))
 995                      t
 996                      (let ((buf (ibuffer-current-buffer)))
 997                        (if (and buf (buffer-live-p buf))
 998                            (with-current-buffer buf
 999                              (symbol-name major-mode))
1000                          "")))))
1001   (eq qualifier (with-current-buffer buf major-mode)))
1002
1003 ;;;###autoload (autoload 'ibuffer-filter-by-used-mode "ibuf-ext")
1004 (define-ibuffer-filter used-mode
1005   "Toggle current view to buffers with major mode QUALIFIER.
1006 Called interactively, this function allows selection of modes
1007 currently used by buffers."
1008   (:description "major mode in use"
1009                 :reader
1010                 (intern
1011                  (completing-read "Filter by major mode: "
1012                                   (ibuffer-list-buffer-modes)
1013                                   nil
1014                                   t
1015                                   (let ((buf (ibuffer-current-buffer)))
1016                                     (if (and buf (buffer-live-p buf))
1017                                         (with-current-buffer buf
1018                                           (symbol-name major-mode))
1019                                       "")))))
1020   (eq qualifier (with-current-buffer buf major-mode)))
1021
1022 ;;;###autoload (autoload 'ibuffer-filter-by-name "ibuf-ext")
1023 (define-ibuffer-filter name
1024   "Toggle current view to buffers with name matching QUALIFIER."
1025   (:description "buffer name"
1026    :reader (read-from-minibuffer "Filter by name (regexp): "))
1027   (string-match qualifier (buffer-name buf)))
1028
1029 ;;;###autoload (autoload 'ibuffer-filter-by-filename "ibuf-ext")
1030 (define-ibuffer-filter filename
1031   "Toggle current view to buffers with filename matching QUALIFIER."
1032   (:description "filename"
1033    :reader (read-from-minibuffer "Filter by filename (regexp): "))
1034   (ibuffer-awhen (with-current-buffer buf
1035                    (or buffer-file-name
1036                        (and (boundp 'dired-directory)
1037                             (let ((dired-dir
1038                                    (if (stringp dired-directory)
1039                                        dired-directory
1040                                      (car dired-directory))))
1041                               (and dired-dir
1042                                    (expand-file-name dired-dir))))))
1043     (string-match qualifier it)))
1044
1045 ;;;###autoload (autoload 'ibuffer-filter-by-size-gt  "ibuf-ext")
1046 (define-ibuffer-filter size-gt
1047   "Toggle current view to buffers with size greater than QUALIFIER."
1048   (:description "size greater than"
1049    :reader
1050    (string-to-number (read-from-minibuffer "Filter by size greater than: ")))
1051   (> (with-current-buffer buf (buffer-size))
1052      qualifier))
1053
1054 ;;;###autoload (autoload 'ibuffer-filter-by-size-lt  "ibuf-ext")
1055 (define-ibuffer-filter size-lt
1056    "Toggle current view to buffers with size less than QUALIFIER."
1057   (:description "size less than"
1058    :reader
1059    (string-to-number (read-from-minibuffer "Filter by size less than: ")))
1060   (< (with-current-buffer buf (buffer-size))
1061      qualifier))
1062
1063 ;;;###autoload (autoload 'ibuffer-filter-by-content "ibuf-ext")
1064 (define-ibuffer-filter content
1065    "Toggle current view to buffers whose contents match QUALIFIER."
1066   (:description "content"
1067    :reader (read-from-minibuffer "Filter by content (regexp): "))
1068   (with-current-buffer buf
1069     (save-excursion
1070       (goto-char (point-min))
1071       (re-search-forward qualifier nil t))))
1072
1073 ;;;###autoload (autoload 'ibuffer-filter-by-predicate "ibuf-ext")
1074 (define-ibuffer-filter predicate
1075    "Toggle current view to buffers for which QUALIFIER returns non-nil."
1076   (:description "predicate"
1077    :reader (read-minibuffer "Filter by predicate (form): "))
1078   (with-current-buffer buf
1079     (eval qualifier)))
1080
1081 ;;; Sorting
1082
1083 ;;;###autoload
1084 (defun ibuffer-toggle-sorting-mode ()
1085   "Toggle the current sorting mode.
1086 Default sorting modes are:
1087  Recency - the last time the buffer was viewed
1088  Name - the name of the buffer
1089  Major Mode - the name of the major mode of the buffer
1090  Size - the size of the buffer"
1091   (interactive)
1092   (let ((modes (mapcar 'car ibuffer-sorting-functions-alist)))
1093     (add-to-list 'modes 'recency)
1094     (setq modes (sort modes 'string-lessp))
1095     (let ((next (or (car-safe (cdr-safe (memq ibuffer-sorting-mode modes)))
1096                     (car modes))))
1097       (setq ibuffer-sorting-mode next)
1098       (message "Sorting by %s" next)))
1099   (ibuffer-redisplay t))
1100
1101 ;;;###autoload
1102 (defun ibuffer-invert-sorting ()
1103   "Toggle whether or not sorting is in reverse order."
1104   (interactive)
1105   (setq ibuffer-sorting-reversep (not ibuffer-sorting-reversep))
1106   (message "Sorting order %s"
1107            (if ibuffer-sorting-reversep
1108                "reversed"
1109              "normal"))
1110   (ibuffer-redisplay t))
1111
1112 ;;;###autoload (autoload 'ibuffer-do-sort-by-major-mode "ibuf-ext")
1113 (define-ibuffer-sorter major-mode
1114   "Sort the buffers by major modes.
1115 Ordering is lexicographic."
1116   (:description "major mode")
1117   (string-lessp (downcase
1118                  (symbol-name (with-current-buffer
1119                                   (car a)
1120                                 major-mode)))
1121                 (downcase
1122                  (symbol-name (with-current-buffer
1123                                   (car b)
1124                                 major-mode)))))
1125
1126 ;;;###autoload (autoload 'ibuffer-do-sort-by-mode-name "ibuf-ext")
1127 (define-ibuffer-sorter mode-name
1128   "Sort the buffers by their mode name.
1129 Ordering is lexicographic."
1130   (:description "major mode name")
1131   (string-lessp (downcase
1132                   (with-current-buffer
1133                       (car a)
1134                     mode-name))
1135                 (downcase
1136                  (with-current-buffer
1137                      (car b)
1138                    mode-name))))
1139
1140 ;;;###autoload (autoload 'ibuffer-do-sort-by-alphabetic "ibuf-ext")
1141 (define-ibuffer-sorter alphabetic
1142   "Sort the buffers by their names.
1143 Ordering is lexicographic."
1144   (:description "buffer name")
1145   (string-lessp
1146    (buffer-name (car a))
1147    (buffer-name (car b))))
1148
1149 ;;;###autoload (autoload 'ibuffer-do-sort-by-size "ibuf-ext")
1150 (define-ibuffer-sorter size
1151  "Sort the buffers by their size."
1152   (:description "size")
1153   (< (with-current-buffer (car a)
1154        (buffer-size))
1155      (with-current-buffer (car b)
1156        (buffer-size))))
1157
1158 ;;; Functions to emulate bs.el
1159
1160 ;;;###autoload
1161 (defun ibuffer-bs-show ()
1162   "Emulate `bs-show' from the bs.el package."
1163   (interactive)
1164   (ibuffer t "*Ibuffer-bs*" '((filename . ".*")) nil t)
1165   (define-key (current-local-map) "a" 'ibuffer-bs-toggle-all))
1166
1167 (defun ibuffer-bs-toggle-all ()
1168   "Emulate `bs-toggle-show-all' from the bs.el package."
1169   (interactive)
1170   (if ibuffer-filtering-qualifiers
1171       (ibuffer-pop-filter)
1172     (progn (ibuffer-push-filter '(filename . ".*"))
1173            (ibuffer-update nil t))))
1174
1175 ;;; Handy functions
1176
1177 ;;;###autoload
1178 (defun ibuffer-add-to-tmp-hide (regexp)
1179   "Add REGEXP to `ibuffer-tmp-hide-regexps'.
1180 This means that buffers whose name matches REGEXP will not be shown
1181 for this Ibuffer session."
1182   (interactive
1183    (list
1184     (read-from-minibuffer "Never show buffers matching: "
1185                           (regexp-quote (buffer-name (ibuffer-current-buffer t))))))
1186   (push regexp ibuffer-tmp-hide-regexps))
1187
1188 ;;;###autoload
1189 (defun ibuffer-add-to-tmp-show (regexp)
1190   "Add REGEXP to `ibuffer-tmp-show-regexps'.
1191 This means that buffers whose name matches REGEXP will always be shown
1192 for this Ibuffer session."
1193   (interactive
1194    (list
1195     (read-from-minibuffer "Always show buffers matching: "
1196                           (regexp-quote (buffer-name (ibuffer-current-buffer t))))))
1197   (push regexp ibuffer-tmp-show-regexps))
1198
1199 ;;;###autoload
1200 (defun ibuffer-forward-next-marked (&optional count mark direction)
1201   "Move forward by COUNT marked buffers (default 1).
1202
1203 If MARK is non-nil, it should be a character denoting the type of mark
1204 to move by.  The default is `ibuffer-marked-char'.
1205
1206 If DIRECTION is non-nil, it should be an integer; negative integers
1207 mean move backwards, non-negative integers mean move forwards."
1208   (interactive "P")
1209   (unless count
1210     (setq count 1))
1211   (unless mark
1212     (setq mark ibuffer-marked-char))
1213   (unless direction
1214     (setq direction 1))
1215   ;; Skip the title
1216   (ibuffer-forward-line 0)
1217   (let ((opos (point))
1218         curmark)
1219     (ibuffer-forward-line direction)
1220     (while (not (or (= (point) opos)
1221                     (eq (setq curmark (ibuffer-current-mark))
1222                         mark)))
1223       (ibuffer-forward-line direction))
1224     (when (and (= (point) opos)
1225                (not (eq (ibuffer-current-mark) mark)))
1226       (error "No buffers with mark %c" mark))))
1227
1228 ;;;###autoload
1229 (defun ibuffer-backwards-next-marked (&optional count mark)
1230    "Move backwards by COUNT marked buffers (default 1).
1231
1232 If MARK is non-nil, it should be a character denoting the type of mark
1233 to move by.  The default is `ibuffer-marked-char'."
1234    (interactive "P")
1235    (ibuffer-forward-next-marked count mark -1))
1236
1237 ;;;###autoload
1238 (defun ibuffer-do-kill-lines ()
1239   "Hide all of the currently marked lines."
1240   (interactive)
1241   (if (= (ibuffer-count-marked-lines) 0)
1242       (message "No buffers marked; use 'm' to mark a buffer")
1243     (let ((count
1244            (ibuffer-map-marked-lines
1245             #'(lambda (buf mark)
1246                 'kill))))
1247       (message "Killed %s lines" count))))
1248
1249 ;;;###autoload
1250 (defun ibuffer-jump-to-buffer (name)
1251   "Move point to the buffer whose name is NAME.
1252
1253 If called interactively, prompt for a buffer name and go to the
1254 corresponding line in the Ibuffer buffer.  If said buffer is in a
1255 hidden group filter, open it.
1256
1257 If `ibuffer-jump-offer-only-visible-buffers' is non-nil, only offer
1258 visible buffers in the completion list.  Calling the command with
1259 a prefix argument reverses the meaning of that variable."
1260   (interactive (list
1261                 (let ((only-visible ibuffer-jump-offer-only-visible-buffers))
1262                   (when current-prefix-arg
1263                     (setq only-visible (not only-visible)))
1264                   (if only-visible
1265                       (let ((table (mapcar #'(lambda (x)
1266                                                (buffer-name (car x)))
1267                                            (ibuffer-current-state-list))))
1268                         (when (null table)
1269                           (error "No buffers!"))
1270                         (completing-read "Jump to buffer: "
1271                                          table nil t))
1272                     (read-buffer "Jump to buffer: " nil t)))))
1273   (when (not (string= "" name))
1274     (let (buf-point)
1275       ;; Blindly search for our buffer: it is very likely that it is
1276       ;; not in a hidden filter group.
1277       (ibuffer-map-lines #'(lambda (buf marks)
1278                              (when (string= (buffer-name buf) name)
1279                                (setq buf-point (point))
1280                                nil))
1281                          t nil)
1282       (when (and
1283              (null buf-point)
1284              (not (null ibuffer-hidden-filter-groups)))
1285         ;; We did not find our buffer.  It must be in a hidden filter
1286         ;; group, so go through all hidden filter groups to find it.
1287         (catch 'found
1288           (dolist (group ibuffer-hidden-filter-groups)
1289             (ibuffer-jump-to-filter-group group)
1290             (ibuffer-toggle-filter-group)
1291             (ibuffer-map-lines #'(lambda (buf marks)
1292                                    (when (string= (buffer-name buf) name)
1293                                      (setq buf-point (point))
1294                                      nil))
1295                                t group)
1296             (if buf-point
1297                 (throw 'found nil)
1298               (ibuffer-toggle-filter-group)))))
1299       (if (null buf-point)
1300           ;; Still not found even though we expanded all hidden filter
1301           ;; groups: that must be because it's hidden by predicate:
1302           ;; we won't bother trying to display it.
1303           (error "No buffer with name %s" name)
1304         (goto-char buf-point)))))
1305
1306 ;;;###autoload
1307 (defun ibuffer-diff-with-file ()
1308   "View the differences between this buffer and its associated file.
1309 This requires the external program \"diff\" to be in your `exec-path'."
1310   (interactive)
1311   (let ((buf (ibuffer-current-buffer)))
1312     (unless (buffer-live-p buf)
1313       (error "Buffer %s has been killed" buf))
1314     (diff-buffer-with-file buf)))
1315
1316 ;;;###autoload
1317 (defun ibuffer-copy-filename-as-kill (&optional arg)
1318   "Copy filenames of marked buffers into the kill ring.
1319
1320 The names are separated by a space.
1321 If a buffer has no filename, it is ignored.
1322
1323 With no prefix arg, use the filename sans its directory of each marked file.
1324 With a zero prefix arg, use the complete filename of each marked file.
1325 With \\[universal-argument], use the filename of each marked file relative
1326 to `ibuffer-default-directory' iff non-nil, otherwise `default-directory'.
1327
1328 You can then feed the file name(s) to other commands with \\[yank]."
1329   (interactive "p")
1330   (if (zerop (ibuffer-count-marked-lines))
1331       (message "No buffers marked; use 'm' to mark a buffer")
1332     (let ((ibuffer-copy-filename-as-kill-result "")
1333           (type (cond ((zerop arg)
1334                        'full)
1335                       ((= arg 4)
1336                        'relative)
1337                       (t
1338                        'name))))
1339       (ibuffer-map-marked-lines
1340        #'(lambda (buf mark)
1341            (setq ibuffer-copy-filename-as-kill-result
1342                  (concat ibuffer-copy-filename-as-kill-result
1343                          (let ((name (buffer-file-name buf)))
1344                            (if name
1345                                (case type
1346                                  (full
1347                                   name)
1348                                  (relative
1349                                   (file-relative-name
1350                                    name (or ibuffer-default-directory
1351                                             default-directory)))
1352                                  (t
1353                                   (file-name-nondirectory name)))
1354                              ""))
1355                          " "))))
1356       (kill-new ibuffer-copy-filename-as-kill-result))))
1357
1358 (defun ibuffer-mark-on-buffer (func &optional ibuffer-mark-on-buffer-mark group)
1359   (let ((count
1360          (ibuffer-map-lines
1361           #'(lambda (buf mark)
1362               (when (funcall func buf)
1363                 (ibuffer-set-mark-1 (or ibuffer-mark-on-buffer-mark
1364                                         ibuffer-marked-char))
1365                 t))
1366           nil
1367           group)))
1368     (ibuffer-redisplay t)
1369     (message "Marked %s buffers" count)))
1370
1371 ;;;###autoload
1372 (defun ibuffer-mark-by-name-regexp (regexp)
1373   "Mark all buffers whose name matches REGEXP."
1374   (interactive "sMark by name (regexp): ")
1375   (ibuffer-mark-on-buffer
1376    #'(lambda (buf)
1377        (string-match regexp (buffer-name buf)))))
1378
1379 ;;;###autoload
1380 (defun ibuffer-mark-by-mode-regexp (regexp)
1381   "Mark all buffers whose major mode matches REGEXP."
1382   (interactive "sMark by major mode (regexp): ")
1383   (ibuffer-mark-on-buffer
1384    #'(lambda (buf)
1385        (with-current-buffer buf
1386          (string-match regexp mode-name)))))
1387
1388 ;;;###autoload
1389 (defun ibuffer-mark-by-file-name-regexp (regexp)
1390   "Mark all buffers whose file name matches REGEXP."
1391   (interactive "sMark by file name (regexp): ")
1392   (ibuffer-mark-on-buffer
1393    #'(lambda (buf)
1394        (let ((name (or (buffer-file-name buf)
1395                        (with-current-buffer buf
1396                          (and
1397                           (boundp 'dired-directory)
1398                           (stringp dired-directory)
1399                           dired-directory)))))
1400          (when name
1401            (string-match regexp name))))))
1402
1403 ;;;###autoload
1404 (defun ibuffer-mark-by-mode (mode)
1405   "Mark all buffers whose major mode equals MODE."
1406   (interactive
1407    (list (intern (completing-read "Mark by major mode: " obarray
1408                                   #'(lambda (e)
1409                                       ;; kind of a hack...
1410                                       (and (fboundp e)
1411                                            (string-match "-mode$"
1412                                                          (symbol-name e))))
1413                                   t
1414                                   (let ((buf (ibuffer-current-buffer)))
1415                                     (if (and buf (buffer-live-p buf))
1416                                         (with-current-buffer buf
1417                                           (cons (symbol-name major-mode)
1418                                                 0))
1419                                       ""))))))
1420   (ibuffer-mark-on-buffer
1421    #'(lambda (buf)
1422        (with-current-buffer buf
1423          (eq major-mode mode)))))
1424
1425 ;;;###autoload
1426 (defun ibuffer-mark-modified-buffers ()
1427   "Mark all modified buffers."
1428   (interactive)
1429   (ibuffer-mark-on-buffer
1430    #'(lambda (buf) (buffer-modified-p buf))))
1431
1432 ;;;###autoload
1433 (defun ibuffer-mark-unsaved-buffers ()
1434   "Mark all modified buffers that have an associated file."
1435   (interactive)
1436   (ibuffer-mark-on-buffer
1437    #'(lambda (buf) (and (with-current-buffer buf buffer-file-name)
1438                         (buffer-modified-p buf)))))
1439
1440 ;;;###autoload
1441 (defun ibuffer-mark-dissociated-buffers ()
1442   "Mark all buffers whose associated file does not exist."
1443   (interactive)
1444   (ibuffer-mark-on-buffer
1445    #'(lambda (buf)
1446        (with-current-buffer buf
1447          (or
1448           (and buffer-file-name
1449                (not (file-exists-p buffer-file-name)))
1450           (and (eq major-mode 'dired-mode)
1451                (boundp 'dired-directory)
1452                (stringp dired-directory)
1453                (not (file-exists-p (file-name-directory dired-directory)))))))))
1454
1455 ;;;###autoload
1456 (defun ibuffer-mark-help-buffers ()
1457   "Mark buffers like *Help*, *Apropos*, *Info*."
1458   (interactive)
1459   (ibuffer-mark-on-buffer
1460    #'(lambda (buf)
1461        (with-current-buffer buf
1462          (memq major-mode ibuffer-help-buffer-modes)))))
1463
1464 ;;;###autoload
1465 (defun ibuffer-mark-compressed-file-buffers ()
1466   "Mark buffers whose associated file is compressed."
1467   (interactive)
1468   (ibuffer-mark-on-buffer
1469    #'(lambda (buf)
1470        (with-current-buffer buf
1471          (and buffer-file-name
1472               (string-match ibuffer-compressed-file-name-regexp
1473                            buffer-file-name))))))
1474
1475 ;;;###autoload
1476 (defun ibuffer-mark-old-buffers ()
1477   "Mark buffers which have not been viewed in `ibuffer-old-time' days."
1478   (interactive)
1479   (ibuffer-mark-on-buffer
1480    #'(lambda (buf)
1481        (with-current-buffer buf
1482          ;; hacked from midnight.el
1483          (when buffer-display-time
1484            (let* ((tm (current-time))
1485                   (now (+ (* (float (ash 1 16)) (car tm))
1486                           (float (cadr tm)) (* 0.0000001 (caddr tm))))
1487                   (then (+ (* (float (ash 1 16))
1488                               (car buffer-display-time))
1489                            (float (cadr buffer-display-time))
1490                            (* 0.0000001 (caddr buffer-display-time)))))
1491              (> (- now then) (* 60 60 ibuffer-old-time))))))))
1492
1493 ;;;###autoload
1494 (defun ibuffer-mark-special-buffers ()
1495   "Mark all buffers whose name begins and ends with '*'."
1496   (interactive)
1497   (ibuffer-mark-on-buffer
1498    #'(lambda (buf) (string-match "^\\*.+\\*$"
1499                                  (buffer-name buf)))))
1500
1501 ;;;###autoload
1502 (defun ibuffer-mark-read-only-buffers ()
1503   "Mark all read-only buffers."
1504   (interactive)
1505   (ibuffer-mark-on-buffer
1506    #'(lambda (buf)
1507        (with-current-buffer buf
1508          buffer-read-only))))
1509
1510 ;;;###autoload
1511 (defun ibuffer-mark-dired-buffers ()
1512   "Mark all `dired' buffers."
1513   (interactive)
1514   (ibuffer-mark-on-buffer
1515    #'(lambda (buf)
1516        (with-current-buffer buf
1517          (eq major-mode 'dired-mode)))))
1518
1519 ;;;###autoload
1520 (defun ibuffer-do-occur (regexp &optional nlines)
1521   "View lines which match REGEXP in all marked buffers.
1522 Optional argument NLINES says how many lines of context to display: it
1523 defaults to one."
1524   (interactive (occur-read-primary-args))
1525   (if (or (not (integerp nlines))
1526           (< nlines 0))
1527       (setq nlines 0))
1528   (when (zerop (ibuffer-count-marked-lines))
1529     (ibuffer-set-mark ibuffer-marked-char))
1530   (let ((ibuffer-do-occur-bufs nil))
1531     ;; Accumulate a list of marked buffers
1532     (ibuffer-map-marked-lines
1533      #'(lambda (buf mark)
1534          (push buf ibuffer-do-occur-bufs)))
1535     (occur-1 regexp nlines ibuffer-do-occur-bufs)))
1536
1537 (provide 'ibuf-ext)
1538
1539 ;;; arch-tag: 9af21953-deda-4c30-b76d-f81d9128e76d
1540 ;;; ibuf-ext.el ends here