code.delx.au - gnu-emacs/blob - lisp/erc/erc-backend.el

   1 ;;; erc-backend.el --- Backend network communication for ERC
   2
   3 ;; Copyright (C) 2004-2015 Free Software Foundation, Inc.
   4
   5 ;; Filename: erc-backend.el
   6 ;; Author: Lawrence Mitchell <wence@gmx.li>
   7 ;; Maintainer: emacs-devel@gnu.org
   8 ;; Created: 2004-05-7
   9 ;; Keywords: IRC chat client internet
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software: you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation, either version 3 of the License, or
  16 ;; (at your option) any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  25
  26 ;;; Commentary:
  27
  28 ;; This file defines backend network communication handlers for ERC.
  29 ;;
  30 ;; How things work:
  31 ;;
  32 ;; You define a new handler with `define-erc-response-handler'.  This
  33 ;; defines a function, a corresponding hook variable, and populates a
  34 ;; global hash table `erc-server-responses' with a map from response
  35 ;; to hook variable.  See the function documentation for more
  36 ;; information.
  37 ;;
  38 ;; Upon receiving a line from the server, `erc-parse-server-response'
  39 ;; is called on it.
  40 ;;
  41 ;; A line generally looks like:
  42 ;;
  43 ;; LINE := ':' SENDER ' ' COMMAND ' ' (COMMAND-ARGS ' ')* ':' CONTENTS
  44 ;; SENDER := Not ':' | ' '
  45 ;; COMMAND := Not ':' | ' '
  46 ;; COMMAND-ARGS := Not ':' | ' '
  47 ;;
  48 ;; This gets parsed and stuffed into an `erc-response' struct.  You
  49 ;; can access the fields of the struct with:
  50 ;;
  51 ;; COMMAND --- `erc-response.command'
  52 ;; COMMAND-ARGS --- `erc-response.command-args'
  53 ;; CONTENTS --- `erc-response.contents'
  54 ;; SENDER --- `erc-response.sender'
  55 ;; LINE --- `erc-response.unparsed'
  56 ;;
  57 ;; WARNING, WARNING!!
  58 ;; It's probably not a good idea to destructively modify the list
  59 ;; of command-args in your handlers, since other functions down the
  60 ;; line may well need to access the arguments too.
  61 ;;
  62 ;; That is, unless you're /absolutely/ sure that your handler doesn't
  63 ;; invoke some other function that needs to use COMMAND-ARGS, don't do
  64 ;; something like
  65 ;;
  66 ;; (while (erc-response.command-args parsed)
  67 ;;   (let ((a (pop (erc-response.command-args parsed))))
  68 ;;     ...))
  69 ;;
  70 ;; The parsed response is handed over to
  71 ;; `erc-handle-parsed-server-response', which checks whether it should
  72 ;; carry out duplicate suppression, and then runs `erc-call-hooks'.
  73 ;; `erc-call-hooks' retrieves the relevant hook variable from
  74 ;; `erc-server-responses' and runs it.
  75 ;;
  76 ;; Most handlers then destructure the parsed response in some way
  77 ;; (depending on what the handler is, the arguments have different
  78 ;; meanings), and generally display something, usually using
  79 ;; `erc-display-message'.
  80
  81 ;;; TODO:
  82
  83 ;; o Generalize the display-line code so that we can use it to
  84 ;;   display the stuff we send, as well as the stuff we receive.
  85 ;;   Then, move all display-related code into another backend-like
  86 ;;   file, erc-display.el, say.
  87 ;;
  88 ;; o Clean up the handlers using new display code (has to be written
  89 ;;   first).
  90
  91 ;;; History:
  92
  93 ;; 2004/05/10 -- Handler bodies taken out of erc.el and ported to new
  94 ;;               interface.
  95
  96 ;; 2005-08-13 -- Moved sending commands from erc.el.
  97
  98 ;;; Code:
  99
 100 (require 'erc-compat)
 101 (eval-when-compile (require 'cl-lib))
 102 ;; There's a fairly strong mutual dependency between erc.el and erc-backend.el.
 103 ;; Luckily, erc.el does not need erc-backend.el for macroexpansion whereas the
 104 ;; reverse is true:
 105 (provide 'erc-backend)
 106 (require 'erc)
 107
 108 ;;;; Variables and options
 109
 110 (defvar erc-server-responses (make-hash-table :test #'equal)
 111   "Hashtable mapping server responses to their handler hooks.")
 112
 113 (cl-defstruct (erc-response (:conc-name erc-response.))
 114   (unparsed "" :type string)
 115   (sender "" :type string)
 116   (command "" :type string)
 117   (command-args '() :type list)
 118   (contents "" :type string))
 119
 120 ;;; User data
 121
 122 (defvar erc-server-current-nick nil
 123   "Nickname on the current server.
 124 Use `erc-current-nick' to access this.")
 125 (make-variable-buffer-local 'erc-server-current-nick)
 126
 127 ;;; Server attributes
 128
 129 (defvar erc-server-process nil
 130   "The process object of the corresponding server connection.")
 131 (make-variable-buffer-local 'erc-server-process)
 132
 133 (defvar erc-session-server nil
 134   "The server name used to connect to for this session.")
 135 (make-variable-buffer-local 'erc-session-server)
 136
 137 (defvar erc-session-connector nil
 138   "The function used to connect to this session (nil for the default).")
 139 (make-variable-buffer-local 'erc-session-connector)
 140
 141 (defvar erc-session-port nil
 142   "The port used to connect to.")
 143 (make-variable-buffer-local 'erc-session-port)
 144
 145 (defvar erc-server-announced-name nil
 146   "The name the server announced to use.")
 147 (make-variable-buffer-local 'erc-server-announced-name)
 148
 149 (defvar erc-server-version nil
 150   "The name and version of the server's ircd.")
 151 (make-variable-buffer-local 'erc-server-version)
 152
 153 (defvar erc-server-parameters nil
 154   "Alist listing the supported server parameters.
 155
 156 This is only set if the server sends 005 messages saying what is
 157 supported on the server.
 158
 159 Entries are of the form:
 160   (PARAMETER . VALUE)
 161 or
 162   (PARAMETER) if no value is provided.
 163
 164 Some examples of possible parameters sent by servers:
 165 CHANMODES=b,k,l,imnpst - list of supported channel modes
 166 CHANNELLEN=50 - maximum length of channel names
 167 CHANTYPES=#&!+ - supported channel prefixes
 168 CHARMAPPING=rfc1459 - character mapping used for nickname and channels
 169 KICKLEN=160 - maximum allowed kick message length
 170 MAXBANS=30 - maximum number of bans per channel
 171 MAXCHANNELS=10 - maximum number of channels allowed to join
 172 NETWORK=EFnet -  the network identifier
 173 NICKLEN=9 - maximum allowed length of nicknames
 174 PREFIX=(ov)@+ - list of channel modes and the user prefixes if user has mode
 175 RFC2812 - server supports RFC 2812 features
 176 SILENCE=10 - supports the SILENCE command, maximum allowed number of entries
 177 TOPICLEN=160 - maximum allowed topic length
 178 WALLCHOPS - supports sending messages to all operators in a channel")
 179 (make-variable-buffer-local 'erc-server-parameters)
 180
 181 ;;; Server and connection state
 182
 183 (defvar erc-server-ping-timer-alist nil
 184   "Mapping of server buffers to their specific ping timer.")
 185
 186 (defvar erc-server-connected nil
 187   "Non-nil if the current buffer has been used by ERC to establish
 188 an IRC connection.
 189
 190 If you wish to determine whether an IRC connection is currently
 191 active, use the `erc-server-process-alive' function instead.")
 192 (make-variable-buffer-local 'erc-server-connected)
 193
 194 (defvar erc-server-reconnect-count 0
 195   "Number of times we have failed to reconnect to the current server.")
 196 (make-variable-buffer-local 'erc-server-reconnect-count)
 197
 198 (defvar erc-server-quitting nil
 199   "Non-nil if the user requests a quit.")
 200 (make-variable-buffer-local 'erc-server-quitting)
 201
 202 (defvar erc-server-reconnecting nil
 203   "Non-nil if the user requests an explicit reconnect, and the
 204 current IRC process is still alive.")
 205 (make-variable-buffer-local 'erc-server-reconnecting)
 206
 207 (defvar erc-server-timed-out nil
 208   "Non-nil if the IRC server failed to respond to a ping.")
 209 (make-variable-buffer-local 'erc-server-timed-out)
 210
 211 (defvar erc-server-banned nil
 212   "Non-nil if the user is denied access because of a server ban.")
 213 (make-variable-buffer-local 'erc-server-banned)
 214
 215 (defvar erc-server-error-occurred nil
 216   "Non-nil if the user triggers some server error.")
 217 (make-variable-buffer-local 'erc-server-error-occurred)
 218
 219 (defvar erc-server-lines-sent nil
 220   "Line counter.")
 221 (make-variable-buffer-local 'erc-server-lines-sent)
 222
 223 (defvar erc-server-last-peers '(nil . nil)
 224   "Last peers used, both sender and receiver.
 225 Those are used for /MSG destination shortcuts.")
 226 (make-variable-buffer-local 'erc-server-last-peers)
 227
 228 (defvar erc-server-last-sent-time nil
 229   "Time the message was sent.
 230 This is useful for flood protection.")
 231 (make-variable-buffer-local 'erc-server-last-sent-time)
 232
 233 (defvar erc-server-last-ping-time nil
 234   "Time the last ping was sent.
 235 This is useful for flood protection.")
 236 (make-variable-buffer-local 'erc-server-last-ping-time)
 237
 238 (defvar erc-server-last-received-time nil
 239   "Time the last message was received from the server.
 240 This is useful for detecting hung connections.")
 241 (make-variable-buffer-local 'erc-server-last-received-time)
 242
 243 (defvar erc-server-lag nil
 244   "Calculated server lag time in seconds.
 245 This variable is only set in a server buffer.")
 246 (make-variable-buffer-local 'erc-server-lag)
 247
 248 (defvar erc-server-filter-data nil
 249   "The data that arrived from the server
 250 but has not been processed yet.")
 251 (make-variable-buffer-local 'erc-server-filter-data)
 252
 253 (defvar erc-server-duplicates (make-hash-table :test 'equal)
 254   "Internal variable used to track duplicate messages.")
 255 (make-variable-buffer-local 'erc-server-duplicates)
 256
 257 ;; From Circe
 258 (defvar erc-server-processing-p nil
 259   "Non-nil when we're currently processing a message.
 260
 261 When ERC receives a private message, it sets up a new buffer for
 262 this query.  These in turn, though, do start flyspell. This
 263 involves starting an external process, in which case Emacs will
 264 wait - and when it waits, it does accept other stuff from, say,
 265 network exceptions.  So, if someone sends you two messages
 266 quickly after each other, ispell is started for the first, but
 267 might take long enough for the second message to be processed
 268 first.")
 269 (make-variable-buffer-local 'erc-server-processing-p)
 270
 271 (defvar erc-server-flood-last-message 0
 272   "When we sent the last message.
 273 See `erc-server-flood-margin' for an explanation of the flood
 274 protection algorithm.")
 275 (make-variable-buffer-local 'erc-server-flood-last-message)
 276
 277 (defvar erc-server-flood-queue nil
 278   "The queue of messages waiting to be sent to the server.
 279 See `erc-server-flood-margin' for an explanation of the flood
 280 protection algorithm.")
 281 (make-variable-buffer-local 'erc-server-flood-queue)
 282
 283 (defvar erc-server-flood-timer nil
 284   "The timer to resume sending.")
 285 (make-variable-buffer-local 'erc-server-flood-timer)
 286
 287 ;;; IRC protocol and misc options
 288
 289 (defgroup erc-server nil
 290   "Parameters for dealing with IRC servers."
 291   :group 'erc)
 292
 293 (defcustom erc-server-auto-reconnect t
 294   "Non-nil means that ERC will attempt to reestablish broken connections.
 295
 296 Reconnection will happen automatically for any unexpected disconnection."
 297   :group 'erc-server
 298   :type 'boolean)
 299
 300 (defcustom erc-server-reconnect-attempts 2
 301   "The number of times that ERC will attempt to reestablish a
 302 broken connection, or t to always attempt to reconnect.
 303
 304 This only has an effect if `erc-server-auto-reconnect' is non-nil."
 305   :group 'erc-server
 306   :type '(choice (const :tag "Always reconnect" t)
 307                  integer))
 308
 309 (defcustom erc-server-reconnect-timeout 1
 310   "The amount of time, in seconds, that ERC will wait between
 311 successive reconnect attempts.
 312
 313 If a key is pressed while ERC is waiting, it will stop waiting."
 314   :group 'erc-server
 315   :type 'number)
 316
 317 (defcustom erc-split-line-length 440
 318   "The maximum length of a single message.
 319 If a message exceeds this size, it is broken into multiple ones.
 320
 321 IRC allows for lines up to 512 bytes. Two of them are CR LF.
 322 And a typical message looks like this:
 323
 324   :nicky!uhuser@host212223.dialin.fnordisp.net PRIVMSG #lazybastards :Hello!
 325
 326 You can limit here the maximum length of the \"Hello!\" part.
 327 Good luck."
 328   :type 'integer
 329   :group 'erc-server)
 330
 331 (defcustom erc-coding-system-precedence '(utf-8 undecided)
 332   "List of coding systems to be preferred when receiving a string from the server.
 333 This will only be consulted if the coding system in
 334 `erc-server-coding-system' is `undecided'."
 335   :group 'erc-server
 336   :version "24.1"
 337   :type '(repeat coding-system))
 338
 339 (defcustom erc-server-coding-system (if (and (fboundp 'coding-system-p)
 340                                              (coding-system-p 'undecided)
 341                                              (coding-system-p 'utf-8))
 342                                         '(utf-8 . undecided)
 343                                       nil)
 344   "The default coding system for incoming and outgoing text.
 345 This is either a coding system, a cons, a function, or nil.
 346
 347 If a cons, the encoding system for outgoing text is in the car
 348 and the decoding system for incoming text is in the cdr. The most
 349 interesting use for this is to put `undecided' in the cdr. This
 350 means that `erc-coding-system-precedence' will be consulted, and the
 351 first match there will be used.
 352
 353 If a function, it is called with the argument `target' and should
 354 return a coding system or a cons as described above.
 355
 356 If you need to send non-ASCII text to people not using a client that
 357 does decoding on its own, you must tell ERC what encoding to use.
 358 Emacs cannot guess it, since it does not know what the people on the
 359 other end of the line are using."
 360   :group 'erc-server
 361   :type '(choice (const :tag "None" nil)
 362                  coding-system
 363                  (cons (coding-system :tag "encoding" :value utf-8)
 364                        (coding-system :tag "decoding" :value undecided))
 365                  function))
 366
 367 (defcustom erc-encoding-coding-alist nil
 368   "Alist of target regexp and coding-system pairs to use.
 369 This overrides `erc-server-coding-system' depending on the
 370 current target as returned by `erc-default-target'.
 371
 372 Example: If you know that the channel #linux-ru uses the coding-system
 373 `cyrillic-koi8', then add '(\"#linux-ru\" . cyrillic-koi8) to the
 374 alist."
 375   :group 'erc-server
 376   :type '(repeat (cons (string :tag "Target")
 377                        coding-system)))
 378
 379 (defcustom erc-server-connect-function 'open-network-stream
 380   "Function used to initiate a connection.
 381 It should take same arguments as `open-network-stream' does."
 382   :group 'erc-server
 383   :type 'function)
 384
 385 (defcustom erc-server-prevent-duplicates '("301")
 386   "Either nil or a list of strings.
 387 Each string is a IRC message type, like PRIVMSG or NOTICE.
 388 All Message types in that list of subjected to duplicate prevention."
 389   :type '(choice (const nil) (list string))
 390   :group 'erc-server)
 391
 392 (defcustom erc-server-duplicate-timeout 60
 393   "The time allowed in seconds between duplicate messages.
 394
 395 If two identical messages arrive within this value of one another, the second
 396 isn't displayed."
 397   :type 'integer
 398   :group 'erc-server)
 399
 400 (defcustom erc-server-timestamp-format "%Y-%m-%d %T"
 401   "Timestamp format used with server response messages.
 402 This string is processed using `format-time-string'."
 403   :version "24.3"
 404   :type 'string
 405   :group 'erc-server)
 406
 407 ;;; Flood-related
 408
 409 ;; Most of this is courtesy of Jorgen Schaefer and Circe
 410 ;; (http://www.nongnu.org/circe)
 411
 412 (defcustom erc-server-flood-margin 10
 413   "A margin on how much excess data we send.
 414 The flood protection algorithm of ERC works like the one
 415 detailed in RFC 2813, section 5.8 \"Flood control of clients\".
 416
 417   * If `erc-server-flood-last-message' is less than the current
 418     time, set it equal.
 419   * While `erc-server-flood-last-message' is less than
 420     `erc-server-flood-margin' seconds ahead of the current
 421     time, send a message, and increase
 422     `erc-server-flood-last-message' by
 423     `erc-server-flood-penalty' for each message."
 424   :type 'integer
 425   :group 'erc-server)
 426
 427 (defcustom erc-server-flood-penalty 3
 428   "How much we penalize a message.
 429 See `erc-server-flood-margin' for an explanation of the flood
 430 protection algorithm."
 431   :type 'integer
 432   :group 'erc-server)
 433
 434 ;; Ping handling
 435
 436 (defcustom erc-server-send-ping-interval 30
 437   "Interval of sending pings to the server, in seconds.
 438 If this is set to nil, pinging the server is disabled."
 439   :group 'erc-server
 440   :type '(choice (const :tag "Disabled" nil)
 441                  (integer :tag "Seconds")))
 442
 443 (defcustom erc-server-send-ping-timeout 120
 444   "If the time between ping and response is greater than this, reconnect.
 445 The time is in seconds.
 446
 447 This must be greater than or equal to the value for
 448 `erc-server-send-ping-interval'.
 449
 450 If this is set to nil, never try to reconnect."
 451   :group 'erc-server
 452   :type '(choice (const :tag "Disabled" nil)
 453                  (integer :tag "Seconds")))
 454
 455 (defvar erc-server-ping-handler nil
 456   "This variable holds the periodic ping timer.")
 457 (make-variable-buffer-local 'erc-server-ping-handler)
 458
 459 ;;;; Helper functions
 460
 461 ;; From Circe
 462 (defun erc-split-line (longline)
 463   "Return a list of lines which are not too long for IRC.
 464 The length is specified in `erc-split-line-length'.
 465
 466 Currently this is called by `erc-send-input'."
 467   (if (< (length longline)
 468          erc-split-line-length)
 469       (list longline)
 470     (with-temp-buffer
 471       (insert longline)
 472       (let ((fill-column erc-split-line-length))
 473         (fill-region (point-min) (point-max)
 474                      nil t))
 475       (split-string (buffer-string) "\n"))))
 476
 477 ;; Used by CTCP functions
 478 (defun erc-upcase-first-word (str)
 479   "Upcase the first word in STR."
 480   (with-temp-buffer
 481     (insert str)
 482     (goto-char (point-min))
 483     (upcase-word 1)
 484     (buffer-string)))
 485
 486 (defun erc-server-setup-periodical-ping (buffer)
 487   "Set up a timer to periodically ping the current server.
 488 The current buffer is given by BUFFER."
 489   (with-current-buffer buffer
 490     (and erc-server-ping-handler (erc-cancel-timer erc-server-ping-handler))
 491     (when erc-server-send-ping-interval
 492       (setq erc-server-ping-handler (run-with-timer
 493                                      4 erc-server-send-ping-interval
 494                                      #'erc-server-send-ping
 495                                      buffer))
 496       (setq erc-server-ping-timer-alist (cons (cons buffer
 497                                                     erc-server-ping-handler)
 498                                               erc-server-ping-timer-alist)))))
 499
 500 (defun erc-server-process-alive (&optional buffer)
 501   "Return non-nil when BUFFER has an `erc-server-process' open or running."
 502   (with-current-buffer (or buffer (current-buffer))
 503     (and erc-server-process
 504          (processp erc-server-process)
 505          (memq (process-status erc-server-process) '(run open)))))
 506
 507 ;;;; Connecting to a server
 508
 509 (defun erc-server-connect (server port buffer)
 510   "Perform the connection and login using the specified SERVER and PORT.
 511 We will store server variables in the buffer given by BUFFER."
 512   (let ((msg (erc-format-message 'connect ?S server ?p port)))
 513     (message "%s" msg)
 514     (let ((process (funcall erc-server-connect-function
 515                             (format "erc-%s-%s" server port)
 516                             nil server port)))
 517       (unless (processp process)
 518         (error "Connection attempt failed"))
 519       (message "%s...done" msg)
 520       ;; Misc server variables
 521       (with-current-buffer buffer
 522         (setq erc-server-process process)
 523         (setq erc-server-quitting nil)
 524         (setq erc-server-reconnecting nil)
 525         (setq erc-server-timed-out nil)
 526         (setq erc-server-banned nil)
 527         (setq erc-server-error-occurred nil)
 528         (let ((time (erc-current-time)))
 529           (setq erc-server-last-sent-time time)
 530           (setq erc-server-last-ping-time time)
 531           (setq erc-server-last-received-time time))
 532         (setq erc-server-lines-sent 0)
 533         ;; last peers (sender and receiver)
 534         (setq erc-server-last-peers '(nil . nil)))
 535       ;; we do our own encoding and decoding
 536       (when (fboundp 'set-process-coding-system)
 537         (set-process-coding-system process 'raw-text))
 538       ;; process handlers
 539       (set-process-sentinel process 'erc-process-sentinel)
 540       (set-process-filter process 'erc-server-filter-function)
 541       (set-process-buffer process buffer)))
 542   (erc-log "\n\n\n********************************************\n")
 543   (message "%s" (erc-format-message
 544             'login ?n
 545             (with-current-buffer buffer (erc-current-nick))))
 546   ;; wait with script loading until we receive a confirmation (first
 547   ;; MOTD line)
 548   (if (eq erc-server-connect-function 'open-network-stream-nowait)
 549       ;; it's a bit unclear otherwise that it's attempting to establish a
 550       ;; connection
 551       (erc-display-message nil nil buffer "Opening connection..\n")
 552     (erc-login)))
 553
 554 (defun erc-server-reconnect ()
 555 "Reestablish the current IRC connection.
 556 Make sure you are in an ERC buffer when running this."
 557   (let ((buffer (erc-server-buffer)))
 558     (unless (buffer-live-p buffer)
 559       (if (eq major-mode 'erc-mode)
 560           (setq buffer (current-buffer))
 561         (error "Reconnect must be run from an ERC buffer")))
 562     (with-current-buffer buffer
 563       (erc-update-mode-line)
 564       (erc-set-active-buffer (current-buffer))
 565       (setq erc-server-last-sent-time 0)
 566       (setq erc-server-lines-sent 0)
 567       (let ((erc-server-connect-function (or erc-session-connector
 568                                              'open-network-stream)))
 569         (erc-open erc-session-server erc-session-port erc-server-current-nick
 570                   erc-session-user-full-name t erc-session-password)))))
 571
 572 (defun erc-server-filter-function (process string)
 573   "The process filter for the ERC server."
 574   (with-current-buffer (process-buffer process)
 575     (setq erc-server-last-received-time (erc-current-time))
 576     ;; If you think this is written in a weird way - please refer to the
 577     ;; docstring of `erc-server-processing-p'
 578     (if erc-server-processing-p
 579         (setq erc-server-filter-data
 580               (if erc-server-filter-data
 581                   (concat erc-server-filter-data string)
 582                 string))
 583       ;; This will be true even if another process is spawned!
 584       (let ((erc-server-processing-p t))
 585         (setq erc-server-filter-data (if erc-server-filter-data
 586                                            (concat erc-server-filter-data
 587                                                    string)
 588                                          string))
 589         (while (and erc-server-filter-data
 590                     (string-match "[\n\r]+" erc-server-filter-data))
 591           (let ((line (substring erc-server-filter-data
 592                                  0 (match-beginning 0))))
 593             (setq erc-server-filter-data
 594                   (if (= (match-end 0)
 595                          (length erc-server-filter-data))
 596                       nil
 597                     (substring erc-server-filter-data
 598                                (match-end 0))))
 599             (erc-log-irc-protocol line nil)
 600             (erc-parse-server-response process line)))))))
 601
 602 (defsubst erc-server-reconnect-p (event)
 603   "Return non-nil if ERC should attempt to reconnect automatically.
 604 EVENT is the message received from the closed connection process."
 605   (or erc-server-reconnecting
 606       (and erc-server-auto-reconnect
 607            (not erc-server-banned)
 608            (not erc-server-error-occurred)
 609            ;; make sure we don't infinitely try to reconnect, unless the
 610            ;; user wants that
 611            (or (eq erc-server-reconnect-attempts t)
 612                (and (integerp erc-server-reconnect-attempts)
 613                     (< erc-server-reconnect-count
 614                        erc-server-reconnect-attempts)))
 615            (or erc-server-timed-out
 616                (not (string-match "^deleted" event)))
 617            ;; open-network-stream-nowait error for connection refused
 618            (not (string-match "^failed with code 111" event)))))
 619
 620 (defun erc-process-sentinel-2 (event buffer)
 621   "Called when `erc-process-sentinel-1' has detected an unexpected disconnect."
 622   (if (not (buffer-live-p buffer))
 623       (erc-update-mode-line)
 624     (with-current-buffer buffer
 625       (let ((reconnect-p (erc-server-reconnect-p event)))
 626         (erc-display-message nil 'error (current-buffer)
 627                              (if reconnect-p 'disconnected
 628                                'disconnected-noreconnect))
 629         (if (not reconnect-p)
 630             ;; terminate, do not reconnect
 631             (progn
 632               (erc-display-message nil 'error (current-buffer)
 633                                    'terminated ?e event)
 634               ;; Update mode line indicators
 635               (erc-update-mode-line)
 636               (set-buffer-modified-p nil))
 637           ;; reconnect
 638           (condition-case err
 639               (progn
 640                 (setq erc-server-reconnecting nil)
 641                 (erc-server-reconnect)
 642                 (setq erc-server-reconnect-count 0))
 643             (error (when (buffer-live-p buffer)
 644                      (set-buffer buffer)
 645                      (if (integerp erc-server-reconnect-attempts)
 646                          (setq erc-server-reconnect-count
 647                                (1+ erc-server-reconnect-count))
 648                        (message "%s ... %s"
 649                                 "Reconnecting until we succeed"
 650                                 "kill the ERC server buffer to stop"))
 651                      (if (numberp erc-server-reconnect-timeout)
 652                          (run-at-time erc-server-reconnect-timeout nil
 653                                       #'erc-process-sentinel-2
 654                                       event buffer)
 655                        (error (concat "`erc-server-reconnect-timeout'"
 656                                       " must be a number")))))))))))
 657
 658 (defun erc-process-sentinel-1 (event buffer)
 659   "Called when `erc-process-sentinel' has decided that we're disconnecting.
 660 Determine whether user has quit or whether erc has been terminated.
 661 Conditionally try to reconnect and take appropriate action."
 662   (with-current-buffer buffer
 663     (if erc-server-quitting
 664         ;; normal quit
 665         (progn
 666           (erc-display-message nil 'error (current-buffer) 'finished)
 667           ;; Update mode line indicators
 668           (erc-update-mode-line)
 669           ;; Kill server buffer if user wants it
 670           (set-buffer-modified-p nil)
 671           (when erc-kill-server-buffer-on-quit
 672             (kill-buffer (current-buffer))))
 673       ;; unexpected disconnect
 674       (erc-process-sentinel-2 event buffer))))
 675
 676 (defun erc-process-sentinel (cproc event)
 677   "Sentinel function for ERC process."
 678   (let ((buf (process-buffer cproc)))
 679     (when (buffer-live-p buf)
 680       (with-current-buffer buf
 681         (erc-log (format
 682                   "SENTINEL: proc: %S    status: %S  event: %S (quitting: %S)"
 683                   cproc (process-status cproc) event erc-server-quitting))
 684         (if (string-match "^open" event)
 685             ;; newly opened connection (no wait)
 686             (erc-login)
 687           ;; assume event is 'failed
 688           (erc-with-all-buffers-of-server cproc nil
 689                                           (setq erc-server-connected nil))
 690           (when erc-server-ping-handler
 691             (progn (erc-cancel-timer erc-server-ping-handler)
 692                    (setq erc-server-ping-handler nil)))
 693           (run-hook-with-args 'erc-disconnected-hook
 694                               (erc-current-nick) (system-name) "")
 695           ;; Remove the prompt
 696           (goto-char (or (marker-position erc-input-marker) (point-max)))
 697           (forward-line 0)
 698           (erc-remove-text-properties-region (point) (point-max))
 699           (delete-region (point) (point-max))
 700           ;; Decide what to do with the buffer
 701           ;; Restart if disconnected
 702           (erc-process-sentinel-1 event buf))))))
 703
 704 ;;;; Sending messages
 705
 706 (defun erc-coding-system-for-target (target)
 707   "Return the coding system or cons cell appropriate for TARGET.
 708 This is determined via `erc-encoding-coding-alist' or
 709 `erc-server-coding-system'."
 710   (unless target (setq target (erc-default-target)))
 711   (or (when target
 712         (let ((case-fold-search t))
 713           (catch 'match
 714             (dolist (pat erc-encoding-coding-alist)
 715               (when (string-match (car pat) target)
 716                 (throw 'match (cdr pat)))))))
 717       (and (functionp erc-server-coding-system)
 718            (funcall erc-server-coding-system target))
 719       erc-server-coding-system))
 720
 721 (defun erc-decode-string-from-target (str target)
 722   "Decode STR as appropriate for TARGET.
 723 This is indicated by `erc-encoding-coding-alist', defaulting to the value of
 724 `erc-server-coding-system'."
 725   (unless (stringp str)
 726     (setq str ""))
 727   (let ((coding (erc-coding-system-for-target target)))
 728     (when (consp coding)
 729       (setq coding (cdr coding)))
 730     (when (eq coding 'undecided)
 731       (let ((codings (detect-coding-string str))
 732             (precedence erc-coding-system-precedence))
 733         (while (and precedence
 734                     (not (memq (car precedence) codings)))
 735           (pop precedence))
 736         (when precedence
 737           (setq coding (car precedence)))))
 738     (erc-decode-coding-string str coding)))
 739
 740 ;; proposed name, not used by anything yet
 741 (defun erc-send-line (text display-fn)
 742   "Send TEXT to the current server.  Wrapping and flood control apply.
 743 Use DISPLAY-FN to show the results."
 744   (mapc (lambda (line)
 745           (erc-server-send line)
 746           (funcall display-fn))
 747         (erc-split-line text)))
 748
 749 ;; From Circe, with modifications
 750 (defun erc-server-send (string &optional forcep target)
 751   "Send STRING to the current server.
 752 If FORCEP is non-nil, no flood protection is done - the string is
 753 sent directly. This might cause the messages to arrive in a wrong
 754 order.
 755
 756 If TARGET is specified, look up encoding information for that
 757 channel in `erc-encoding-coding-alist' or
 758 `erc-server-coding-system'.
 759
 760 See `erc-server-flood-margin' for an explanation of the flood
 761 protection algorithm."
 762   (erc-log (concat "erc-server-send: " string "(" (buffer-name) ")"))
 763   (setq erc-server-last-sent-time (erc-current-time))
 764   (let ((encoding (erc-coding-system-for-target target)))
 765     (when (consp encoding)
 766       (setq encoding (car encoding)))
 767     (if (erc-server-process-alive)
 768         (erc-with-server-buffer
 769           (let ((str (concat string "\r\n")))
 770             (if forcep
 771                 (progn
 772                   (setq erc-server-flood-last-message
 773                         (+ erc-server-flood-penalty
 774                            erc-server-flood-last-message))
 775                   (erc-log-irc-protocol str 'outbound)
 776                   (condition-case err
 777                       (progn
 778                         ;; Set encoding just before sending the string
 779                         (when (fboundp 'set-process-coding-system)
 780                           (set-process-coding-system erc-server-process
 781                                                      'raw-text encoding))
 782                         (process-send-string erc-server-process str))
 783                     ;; See `erc-server-send-queue' for full
 784                     ;; explanation of why we need this condition-case
 785                     (error nil)))
 786               (setq erc-server-flood-queue
 787                     (append erc-server-flood-queue
 788                             (list (cons str encoding))))
 789               (erc-server-send-queue (current-buffer))))
 790           t)
 791       (message "ERC: No process running")
 792       nil)))
 793
 794 (defun erc-server-send-ping (buf)
 795   "Send a ping to the IRC server buffer in BUF.
 796 Additionally, detect whether the IRC process has hung."
 797   (if (buffer-live-p buf)
 798       (with-current-buffer buf
 799         (if (and erc-server-send-ping-timeout
 800                  (>
 801                   (erc-time-diff (erc-current-time)
 802                                  erc-server-last-received-time)
 803                   erc-server-send-ping-timeout))
 804             (progn
 805               ;; if the process is hung, kill it
 806               (setq erc-server-timed-out t)
 807               (delete-process erc-server-process))
 808           (erc-server-send (format "PING %.0f" (erc-current-time)))))
 809     ;; remove timer if the server buffer has been killed
 810     (let ((timer (assq buf erc-server-ping-timer-alist)))
 811       (when timer
 812         (erc-cancel-timer (cdr timer))
 813         (setcdr timer nil)))))
 814
 815 ;; From Circe
 816 (defun erc-server-send-queue (buffer)
 817   "Send messages in `erc-server-flood-queue'.
 818 See `erc-server-flood-margin' for an explanation of the flood
 819 protection algorithm."
 820   (with-current-buffer buffer
 821     (let ((now (erc-current-time)))
 822       (when erc-server-flood-timer
 823         (erc-cancel-timer erc-server-flood-timer)
 824         (setq erc-server-flood-timer nil))
 825       (when (< erc-server-flood-last-message
 826                now)
 827         (setq erc-server-flood-last-message now))
 828       (while (and erc-server-flood-queue
 829                   (< erc-server-flood-last-message
 830                      (+ now erc-server-flood-margin)))
 831         (let ((msg (caar erc-server-flood-queue))
 832               (encoding (cdar erc-server-flood-queue)))
 833           (setq erc-server-flood-queue (cdr erc-server-flood-queue)
 834                 erc-server-flood-last-message
 835                 (+ erc-server-flood-last-message
 836                    erc-server-flood-penalty))
 837           (erc-log-irc-protocol msg 'outbound)
 838           (erc-log (concat "erc-server-send-queue: "
 839                            msg "(" (buffer-name buffer) ")"))
 840           (when (erc-server-process-alive)
 841             (condition-case err
 842                 ;; Set encoding just before sending the string
 843                 (progn
 844                   (when (fboundp 'set-process-coding-system)
 845                     (set-process-coding-system erc-server-process
 846                                                'raw-text encoding))
 847                   (process-send-string erc-server-process msg))
 848               ;; Sometimes the send can occur while the process is
 849               ;; being killed, which results in a weird SIGPIPE error.
 850               ;; Catch this and ignore it.
 851               (error nil)))))
 852       (when erc-server-flood-queue
 853         (setq erc-server-flood-timer
 854               (run-at-time (+ 0.2 erc-server-flood-penalty)
 855                            nil #'erc-server-send-queue buffer))))))
 856
 857 (defun erc-message (message-command line &optional force)
 858   "Send LINE to the server as a privmsg or a notice.
 859 MESSAGE-COMMAND should be either \"PRIVMSG\" or \"NOTICE\".
 860 If the target is \",\", the last person you've got a message from will
 861 be used. If the target is \".\", the last person you've sent a message
 862 to will be used."
 863   (cond
 864    ((string-match "^\\s-*\\(\\S-+\\) ?\\(.*\\)" line)
 865     (let ((tgt (match-string 1 line))
 866           (s (match-string 2 line)))
 867       (erc-log (format "cmd: MSG(%s): [%s] %s" message-command tgt s))
 868       (cond
 869        ((string= tgt ",")
 870         (if (car erc-server-last-peers)
 871             (setq tgt (car erc-server-last-peers))
 872           (setq tgt nil)))
 873        ((string= tgt ".")
 874         (if (cdr erc-server-last-peers)
 875             (setq tgt (cdr erc-server-last-peers))
 876           (setq tgt nil))))
 877       (cond
 878        (tgt
 879         (setcdr erc-server-last-peers tgt)
 880         (erc-server-send (format "%s %s :%s" message-command tgt s)
 881                          force))
 882        (t
 883         (erc-display-message nil 'error (current-buffer) 'no-target))))
 884     t)
 885    (t nil)))
 886
 887 ;;; CTCP
 888
 889 (defun erc-send-ctcp-message (tgt l &optional force)
 890   "Send CTCP message L to TGT.
 891
 892 If TGT is nil the message is not sent.
 893 The command must contain neither a prefix nor a trailing `\\n'.
 894
 895 See also `erc-server-send'."
 896   (let ((l (erc-upcase-first-word l)))
 897     (cond
 898      (tgt
 899       (erc-log (format "erc-send-CTCP-message: [%s] %s" tgt l))
 900       (erc-server-send (format "PRIVMSG %s :\C-a%s\C-a" tgt l)
 901                        force)))))
 902
 903 (defun erc-send-ctcp-notice (tgt l &optional force)
 904   "Send CTCP notice L to TGT.
 905
 906 If TGT is nil the message is not sent.
 907 The command must contain neither a prefix nor a trailing `\\n'.
 908
 909 See also `erc-server-send'."
 910   (let ((l (erc-upcase-first-word l)))
 911     (cond
 912      (tgt
 913       (erc-log (format "erc-send-CTCP-notice: [%s] %s" tgt l))
 914       (erc-server-send (format "NOTICE %s :\C-a%s\C-a" tgt l)
 915                        force)))))
 916
 917 ;;;; Handling responses
 918
 919 (defun erc-parse-server-response (proc string)
 920   "Parse and act upon a complete line from an IRC server.
 921 PROC is the process (connection) from which STRING was received.
 922 PROCs `process-buffer' is `current-buffer' when this function is called."
 923   (unless (string= string "") ;; Ignore empty strings
 924     (save-match-data
 925       (let ((posn (if (eq (aref string 0) ?:)
 926                       (string-match " " string)
 927                     0))
 928             (msg (make-erc-response :unparsed string)))
 929
 930         (setf (erc-response.sender msg)
 931               (if (eq posn 0)
 932                   erc-session-server
 933                 (substring string 1 posn)))
 934
 935         (setf (erc-response.command msg)
 936               (let* ((bposn (string-match "[^ \n]" string posn))
 937                      (eposn (string-match " " string bposn)))
 938                 (setq posn (and eposn
 939                                 (string-match "[^ \n]" string eposn)))
 940                 (substring string bposn eposn)))
 941
 942         (while (and posn
 943                     (not (eq (aref string posn) ?:)))
 944           (push (let* ((bposn posn)
 945                        (eposn (string-match " " string bposn)))
 946                   (setq posn (and eposn
 947                                   (string-match "[^ \n]" string eposn)))
 948                   (substring string bposn eposn))
 949                 (erc-response.command-args msg)))
 950         (when posn
 951       (let ((str (substring string (1+ posn))))
 952         (push str (erc-response.command-args msg))))
 953
 954     (setf (erc-response.contents msg)
 955           (car (erc-response.command-args msg)))
 956
 957     (setf (erc-response.command-args msg)
 958           (nreverse (erc-response.command-args msg)))
 959
 960     (erc-decode-parsed-server-response msg)
 961
 962     (erc-handle-parsed-server-response proc msg)))))
 963
 964 (defun erc-decode-parsed-server-response (parsed-response)
 965   "Decode a pre-parsed PARSED-RESPONSE before it can be handled.
 966
 967 If there is a channel name in `erc-response.command-args', decode
 968 `erc-response' according to this channel name and
 969 `erc-encoding-coding-alist', or use `erc-server-coding-system'
 970 for decoding."
 971   (let ((args (erc-response.command-args parsed-response))
 972         (decode-target nil)
 973         (decoded-args ()))
 974     (dolist (arg args nil)
 975       (when (string-match "^[#&].*" arg)
 976         (setq decode-target arg)))
 977     (when (stringp decode-target)
 978       (setq decode-target (erc-decode-string-from-target decode-target nil)))
 979     (setf (erc-response.unparsed parsed-response)
 980           (erc-decode-string-from-target
 981            (erc-response.unparsed parsed-response)
 982            decode-target))
 983     (setf (erc-response.sender parsed-response)
 984           (erc-decode-string-from-target
 985            (erc-response.sender parsed-response)
 986            decode-target))
 987     (setf (erc-response.command parsed-response)
 988           (erc-decode-string-from-target
 989            (erc-response.command parsed-response)
 990            decode-target))
 991     (dolist (arg (nreverse args) nil)
 992       (push (erc-decode-string-from-target arg decode-target)
 993             decoded-args))
 994     (setf (erc-response.command-args parsed-response) decoded-args)
 995     (setf (erc-response.contents parsed-response)
 996           (erc-decode-string-from-target
 997            (erc-response.contents parsed-response)
 998            decode-target))))
 999
1000 (defun erc-handle-parsed-server-response (process parsed-response)
1001   "Handle a pre-parsed PARSED-RESPONSE from PROCESS.
1002
1003 Hands off to helper functions via `erc-call-hooks'."
1004   (if (member (erc-response.command parsed-response)
1005               erc-server-prevent-duplicates)
1006       (let ((m (erc-response.unparsed parsed-response)))
1007         ;; duplicate suppression
1008         (if (< (or (gethash m erc-server-duplicates) 0)
1009                (- (erc-current-time) erc-server-duplicate-timeout))
1010             (erc-call-hooks process parsed-response))
1011         (puthash m (erc-current-time) erc-server-duplicates))
1012     ;; Hand off to the relevant handler.
1013     (erc-call-hooks process parsed-response)))
1014
1015 (defun erc-get-hook (command)
1016   "Return the hook variable associated with COMMAND.
1017
1018 See also `erc-server-responses'."
1019   (gethash (format (if (numberp command) "%03i" "%s") command)
1020            erc-server-responses))
1021
1022 (defun erc-call-hooks (process message)
1023   "Call hooks associated with MESSAGE in PROCESS.
1024
1025 Finds hooks by looking in the `erc-server-responses' hashtable."
1026   (let ((hook (or (erc-get-hook (erc-response.command message))
1027                   'erc-default-server-functions)))
1028     (run-hook-with-args-until-success hook process message)
1029     (erc-with-server-buffer
1030       (run-hook-with-args 'erc-timer-hook (erc-current-time)))))
1031
1032 (add-hook 'erc-default-server-functions 'erc-handle-unknown-server-response)
1033
1034 (defun erc-handle-unknown-server-response (proc parsed)
1035   "Display unknown server response's message."
1036   (let ((line (concat (erc-response.sender parsed)
1037                       " "
1038                       (erc-response.command parsed)
1039                       " "
1040                       (mapconcat 'identity (erc-response.command-args parsed)
1041                                  " "))))
1042     (erc-display-message parsed 'notice proc line)))
1043
1044
1045 (put 'define-erc-response-handler 'edebug-form-spec
1046      '(&define :name erc-response-handler
1047                (name &rest name)
1048                &optional sexp sexp def-body))
1049
1050 (cl-defmacro define-erc-response-handler ((name &rest aliases)
1051                                         &optional extra-fn-doc extra-var-doc
1052                                         &rest fn-body)
1053   "Define an ERC handler hook/function pair.
1054 NAME is the response name as sent by the server (see the IRC RFC for
1055 meanings).
1056
1057 This creates:
1058  - a hook variable `erc-server-NAME-functions' initialized to `erc-server-NAME'.
1059  - a function `erc-server-NAME' with body FN-BODY.
1060
1061 If ALIASES is non-nil, each alias in ALIASES is `defalias'ed to
1062 `erc-server-NAME'.
1063 Alias hook variables are created as `erc-server-ALIAS-functions' and
1064 initialized to the same default value as `erc-server-NAME-functions'.
1065
1066 FN-BODY is the body of `erc-server-NAME' it may refer to the two
1067 function arguments PROC and PARSED.
1068
1069 If EXTRA-FN-DOC is non-nil, it is inserted at the beginning of the
1070 defined function's docstring.
1071
1072 If EXTRA-VAR-DOC is non-nil, it is inserted at the beginning of the
1073 defined variable's docstring.
1074
1075 As an example:
1076
1077   (define-erc-response-handler (311 WHOIS WI)
1078     \"Some non-generic function documentation.\"
1079     \"Some non-generic variable documentation.\"
1080     (do-stuff-with-whois proc parsed))
1081
1082 Would expand to:
1083
1084   (prog2
1085       (defvar erc-server-311-functions \\='erc-server-311
1086         \"Some non-generic variable documentation.
1087
1088   Hook called upon receiving a 311 server response.
1089   Each function is called with two arguments, the process associated
1090   with the response and the parsed response.
1091   See also `erc-server-311'.\")
1092
1093       (defun erc-server-311 (proc parsed)
1094         \"Some non-generic function documentation.
1095
1096   Handler for a 311 server response.
1097   PROC is the server process which returned the response.
1098   PARSED is the actual response as an `erc-response' struct.
1099   If you want to add responses don't modify this function, but rather
1100   add things to `erc-server-311-functions' instead.\"
1101         (do-stuff-with-whois proc parsed))
1102
1103     (puthash \"311\" \\='erc-server-311-functions erc-server-responses)
1104     (puthash \"WHOIS\" \\='erc-server-WHOIS-functions erc-server-responses)
1105     (puthash \"WI\" \\='erc-server-WI-functions erc-server-responses)
1106
1107     (defalias \\='erc-server-WHOIS \\='erc-server-311)
1108     (defvar erc-server-WHOIS-functions \\='erc-server-311
1109       \"Some non-generic variable documentation.
1110
1111   Hook called upon receiving a WHOIS server response.
1112
1113   Each function is called with two arguments, the process associated
1114   with the response and the parsed response.  If the function returns
1115   non-nil, stop processing the hook.  Otherwise, continue.
1116
1117   See also `erc-server-311'.\")
1118
1119     (defalias \\='erc-server-WI \\='erc-server-311)
1120     (defvar erc-server-WI-functions \\='erc-server-311
1121       \"Some non-generic variable documentation.
1122
1123   Hook called upon receiving a WI server response.
1124   Each function is called with two arguments, the process associated
1125   with the response and the parsed response.  If the function returns
1126   non-nil, stop processing the hook.  Otherwise, continue.
1127
1128   See also `erc-server-311'.\"))
1129
1130 \(fn (NAME &rest ALIASES) &optional EXTRA-FN-DOC EXTRA-VAR-DOC &rest FN-BODY)"
1131   (if (numberp name) (setq name (intern (format "%03i" name))))
1132   (setq aliases (mapcar (lambda (a)
1133                           (if (numberp a)
1134                               (format "%03i" a)
1135                             a))
1136                         aliases))
1137   (let* ((hook-name (intern (format "erc-server-%s-functions" name)))
1138          (fn-name (intern (format "erc-server-%s" name)))
1139          (hook-doc (format-message "\
1140 %sHook called upon receiving a %%s server response.
1141 Each function is called with two arguments, the process associated
1142 with the response and the parsed response.  If the function returns
1143 non-nil, stop processing the hook.  Otherwise, continue.
1144
1145 See also `%s'."
1146                            (if extra-var-doc
1147                                (concat extra-var-doc "\n\n")
1148                              "")
1149                            fn-name))
1150          (fn-doc (format-message "\
1151 %sHandler for a %s server response.
1152 PROC is the server process which returned the response.
1153 PARSED is the actual response as an `erc-response' struct.
1154 If you want to add responses don't modify this function, but rather
1155 add things to `%s' instead."
1156                          (if extra-fn-doc
1157                              (concat extra-fn-doc "\n\n")
1158                            "")
1159                          name hook-name))
1160          (fn-alternates
1161           (cl-loop for alias in aliases
1162                    collect (intern (format "erc-server-%s" alias))))
1163          (var-alternates
1164           (cl-loop for alias in aliases
1165                    collect (intern (format "erc-server-%s-functions" alias)))))
1166     `(prog2
1167          ;; Normal hook variable.  The variable may already have a
1168          ;; value at this point, so I default to nil, and (add-hook)
1169          ;; unconditionally
1170          (defvar ,hook-name nil ,(format hook-doc name))
1171          (add-to-list ',hook-name ',fn-name)
1172          ;; Handler function
1173          (defun ,fn-name (proc parsed)
1174            ,fn-doc
1175            ,@fn-body)
1176
1177        ;; Make find-function and find-variable find them
1178        (put ',fn-name 'definition-name ',name)
1179        (put ',hook-name 'definition-name ',name)
1180
1181        ;; Hashtable map of responses to hook variables
1182        ,@(cl-loop for response in (cons name aliases)
1183                   for var in (cons hook-name var-alternates)
1184                   collect `(puthash ,(format "%s" response) ',var
1185                                     erc-server-responses))
1186        ;; Alternates.
1187        ;; Functions are defaliased, hook variables are defvared so we
1188        ;; can add hooks to one alias, but not another.
1189        ,@(cl-loop for fn in fn-alternates
1190                   for var in var-alternates
1191                   for a in aliases
1192                   nconc (list `(defalias ',fn ',fn-name)
1193                               `(defvar ,var ',fn-name ,(format hook-doc a))
1194                               `(put ',var 'definition-name ',hook-name))))))
1195
1196 (define-erc-response-handler (ERROR)
1197   "Handle an ERROR command from the server." nil
1198   (setq erc-server-error-occurred t)
1199   (erc-display-message
1200    parsed 'error nil 'ERROR
1201    ?s (erc-response.sender parsed) ?c (erc-response.contents parsed)))
1202
1203 (define-erc-response-handler (INVITE)
1204   "Handle invitation messages."
1205   nil
1206   (let ((target (car (erc-response.command-args parsed)))
1207         (chnl (erc-response.contents parsed)))
1208     (pcase-let ((`(,nick ,login ,host)
1209                  (erc-parse-user (erc-response.sender parsed))))
1210       (setq erc-invitation chnl)
1211       (when (string= target (erc-current-nick))
1212         (erc-display-message
1213          parsed 'notice 'active
1214          'INVITE ?n nick ?u login ?h host ?c chnl)))))
1215
1216 (define-erc-response-handler (JOIN)
1217   "Handle join messages."
1218   nil
1219   (let ((chnl (erc-response.contents parsed))
1220         (buffer nil))
1221     (pcase-let ((`(,nick ,login ,host)
1222                  (erc-parse-user (erc-response.sender parsed))))
1223       ;; strip the stupid combined JOIN facility (IRC 2.9)
1224       (if (string-match "^\\(.*\\)?\^g.*$" chnl)
1225           (setq chnl (match-string 1 chnl)))
1226       (save-excursion
1227         (let* ((str (cond
1228                      ;; If I have joined a channel
1229                      ((erc-current-nick-p nick)
1230                       (setq buffer (erc-open erc-session-server erc-session-port
1231                                              nick erc-session-user-full-name
1232                                              nil nil
1233                                              (list chnl) chnl
1234                                              erc-server-process))
1235                       (when buffer
1236                         (set-buffer buffer)
1237                         (erc-add-default-channel chnl)
1238                         (erc-server-send (format "MODE %s" chnl)))
1239                       (erc-with-buffer (chnl proc)
1240                         (erc-channel-begin-receiving-names))
1241                       (erc-update-mode-line)
1242                       (run-hooks 'erc-join-hook)
1243                       (erc-make-notice
1244                        (erc-format-message 'JOIN-you ?c chnl)))
1245                      (t
1246                       (setq buffer (erc-get-buffer chnl proc))
1247                       (erc-make-notice
1248                        (erc-format-message
1249                         'JOIN ?n nick ?u login ?h host ?c chnl))))))
1250           (when buffer (set-buffer buffer))
1251           (erc-update-channel-member chnl nick nick t nil nil nil nil nil host login)
1252           ;; on join, we want to stay in the new channel buffer
1253           ;;(set-buffer ob)
1254           (erc-display-message parsed nil buffer str))))))
1255
1256 (define-erc-response-handler (KICK)
1257   "Handle kick messages received from the server." nil
1258   (let* ((ch (nth 0 (erc-response.command-args parsed)))
1259          (tgt (nth 1 (erc-response.command-args parsed)))
1260          (reason (erc-trim-string (erc-response.contents parsed)))
1261          (buffer (erc-get-buffer ch proc)))
1262     (pcase-let ((`(,nick ,login ,host)
1263                  (erc-parse-user (erc-response.sender parsed))))
1264       (erc-remove-channel-member buffer tgt)
1265       (cond
1266        ((string= tgt (erc-current-nick))
1267         (erc-display-message
1268          parsed 'notice buffer
1269          'KICK-you ?n nick ?u login ?h host ?c ch ?r reason)
1270         (run-hook-with-args 'erc-kick-hook buffer)
1271         (erc-with-buffer
1272             (buffer)
1273           (erc-remove-channel-users))
1274         (erc-delete-default-channel ch buffer)
1275         (erc-update-mode-line buffer))
1276        ((string= nick (erc-current-nick))
1277         (erc-display-message
1278          parsed 'notice buffer
1279          'KICK-by-you ?k tgt ?c ch ?r reason))
1280        (t (erc-display-message
1281              parsed 'notice buffer
1282              'KICK ?k tgt ?n nick ?u login ?h host ?c ch ?r reason))))))
1283
1284 (define-erc-response-handler (MODE)
1285   "Handle server mode changes." nil
1286   (let ((tgt (car (erc-response.command-args parsed)))
1287         (mode (mapconcat 'identity (cdr (erc-response.command-args parsed))
1288                          " ")))
1289     (pcase-let ((`(,nick ,login ,host)
1290                  (erc-parse-user (erc-response.sender parsed))))
1291       (erc-log (format "MODE: %s -> %s: %s" nick tgt mode))
1292       ;; dirty hack
1293       (let ((buf (cond ((erc-channel-p tgt)
1294                         (erc-get-buffer tgt proc))
1295                        ((string= tgt (erc-current-nick)) nil)
1296                        ((erc-active-buffer) (erc-active-buffer))
1297                        (t (erc-get-buffer tgt)))))
1298         (with-current-buffer (or buf
1299                                  (current-buffer))
1300           (erc-update-modes tgt mode nick host login))
1301           (if (or (string= login "") (string= host ""))
1302               (erc-display-message parsed 'notice buf
1303                                    'MODE-nick ?n nick
1304                                    ?t tgt ?m mode)
1305             (erc-display-message parsed 'notice buf
1306                                  'MODE ?n nick ?u login
1307                                  ?h host ?t tgt ?m mode)))
1308       (erc-banlist-update proc parsed))))
1309
1310 (define-erc-response-handler (NICK)
1311   "Handle nick change messages." nil
1312   (let ((nn (erc-response.contents parsed))
1313         bufs)
1314     (pcase-let ((`(,nick ,login ,host)
1315                  (erc-parse-user (erc-response.sender parsed))))
1316       (setq bufs (erc-buffer-list-with-nick nick proc))
1317       (erc-log (format "NICK: %s -> %s" nick nn))
1318       ;; if we had a query with this user, make sure future messages will be
1319       ;; sent to the correct nick. also add to bufs, since the user will want
1320       ;; to see the nick change in the query, and if it's a newly begun query,
1321       ;; erc-channel-users won't contain it
1322       (erc-buffer-filter
1323        (lambda ()
1324          (when (equal (erc-default-target) nick)
1325            (setq erc-default-recipients
1326                  (cons nn (cdr erc-default-recipients)))
1327            (rename-buffer nn t)         ; bug#12002
1328            (erc-update-mode-line)
1329            (add-to-list 'bufs (current-buffer)))))
1330       (erc-update-user-nick nick nn host nil nil login)
1331       (cond
1332        ((string= nick (erc-current-nick))
1333         (add-to-list 'bufs (erc-server-buffer))
1334         (erc-set-current-nick nn)
1335         (erc-update-mode-line)
1336         (setq erc-nick-change-attempt-count 0)
1337         (setq erc-default-nicks (if (consp erc-nick) erc-nick (list erc-nick)))
1338         (erc-display-message
1339          parsed 'notice bufs
1340          'NICK-you ?n nick ?N nn)
1341         (run-hook-with-args 'erc-nick-changed-functions nn nick))
1342        (t
1343         (erc-handle-user-status-change 'nick (list nick login host) (list nn))
1344         (erc-display-message parsed 'notice bufs 'NICK ?n nick
1345                              ?u login ?h host ?N nn))))))
1346
1347 (define-erc-response-handler (PART)
1348   "Handle part messages." nil
1349   (let* ((chnl (car (erc-response.command-args parsed)))
1350          (reason (erc-trim-string (erc-response.contents parsed)))
1351          (buffer (erc-get-buffer chnl proc)))
1352     (pcase-let ((`(,nick ,login ,host)
1353                  (erc-parse-user (erc-response.sender parsed))))
1354       (erc-remove-channel-member buffer nick)
1355       (erc-display-message parsed 'notice buffer
1356                            'PART ?n nick ?u login
1357                            ?h host ?c chnl ?r (or reason ""))
1358       (when (string= nick (erc-current-nick))
1359         (run-hook-with-args 'erc-part-hook buffer)
1360         (erc-with-buffer
1361             (buffer)
1362           (erc-remove-channel-users))
1363         (erc-delete-default-channel chnl buffer)
1364         (erc-update-mode-line buffer)
1365         (when erc-kill-buffer-on-part
1366           (kill-buffer buffer))))))
1367
1368 (define-erc-response-handler (PING)
1369   "Handle ping messages." nil
1370   (let ((pinger (car (erc-response.command-args parsed))))
1371     (erc-log (format "PING: %s" pinger))
1372     ;; ping response to the server MUST be forced, or you can lose big
1373     (erc-server-send (format "PONG :%s" pinger) t)
1374     (when erc-verbose-server-ping
1375       (erc-display-message
1376        parsed 'error proc
1377        'PING ?s (erc-time-diff erc-server-last-ping-time (erc-current-time))))
1378     (setq erc-server-last-ping-time (erc-current-time))))
1379
1380 (define-erc-response-handler (PONG)
1381   "Handle pong messages." nil
1382   (let ((time (string-to-number (erc-response.contents parsed))))
1383     (when (> time 0)
1384       (setq erc-server-lag (erc-time-diff time (erc-current-time)))
1385       (when erc-verbose-server-ping
1386         (erc-display-message
1387          parsed 'notice proc 'PONG
1388          ?h (car (erc-response.command-args parsed)) ?i erc-server-lag
1389          ?s (if (/= erc-server-lag 1) "s" "")))
1390       (erc-update-mode-line))))
1391
1392 (define-erc-response-handler (PRIVMSG NOTICE)
1393   "Handle private messages, including messages in channels." nil
1394   (let ((sender-spec (erc-response.sender parsed))
1395         (cmd (erc-response.command parsed))
1396         (tgt (car (erc-response.command-args parsed)))
1397         (msg (erc-response.contents parsed)))
1398     (if (or (erc-ignored-user-p sender-spec)
1399             (erc-ignored-reply-p msg tgt proc))
1400         (when erc-minibuffer-ignored
1401           (message "Ignored %s from %s to %s" cmd sender-spec tgt))
1402       (let* ((sndr (erc-parse-user sender-spec))
1403              (nick (nth 0 sndr))
1404              (login (nth 1 sndr))
1405              (host (nth 2 sndr))
1406              (msgp (string= cmd "PRIVMSG"))
1407              (noticep (string= cmd "NOTICE"))
1408              ;; S.B. downcase *both* tgt and current nick
1409              (privp (erc-current-nick-p tgt))
1410              s buffer
1411              fnick)
1412         (setf (erc-response.contents parsed) msg)
1413         (setq buffer (erc-get-buffer (if privp nick tgt) proc))
1414         (when buffer
1415           (with-current-buffer buffer
1416             ;; update the chat partner info.  Add to the list if private
1417             ;; message.  We will accumulate private identities indefinitely
1418             ;; at this point.
1419             (erc-update-channel-member (if privp nick tgt) nick nick
1420                                        privp nil nil nil nil nil host login nil nil t)
1421             (let ((cdata (erc-get-channel-user nick)))
1422               (setq fnick (funcall erc-format-nick-function
1423                                    (car cdata) (cdr cdata))))))
1424         (cond
1425          ((erc-is-message-ctcp-p msg)
1426           (setq s (if msgp
1427                       (erc-process-ctcp-query proc parsed nick login host)
1428                     (erc-process-ctcp-reply proc parsed nick login host
1429                                             (match-string 1 msg)))))
1430          (t
1431           (setcar erc-server-last-peers nick)
1432           (setq s (erc-format-privmessage
1433                    (or fnick nick) msg
1434                    ;; If buffer is a query buffer,
1435                    ;; format the nick as for a channel.
1436                    (and (not (and buffer
1437                                   (erc-query-buffer-p buffer)
1438                                   erc-format-query-as-channel-p))
1439                         privp)
1440                    msgp))))
1441         (when s
1442           (if (and noticep privp)
1443               (progn
1444                 (run-hook-with-args 'erc-echo-notice-always-hook
1445                                     s parsed buffer nick)
1446                 (run-hook-with-args-until-success
1447                  'erc-echo-notice-hook s parsed buffer nick))
1448             (erc-display-message parsed nil buffer s)))
1449         (when (string= cmd "PRIVMSG")
1450           (erc-auto-query proc parsed))))))
1451
1452 ;; FIXME: need clean way of specifying extra hooks in
1453 ;; define-erc-response-handler.
1454 (add-hook 'erc-server-PRIVMSG-functions 'erc-auto-query)
1455
1456 (define-erc-response-handler (QUIT)
1457   "Another user has quit IRC." nil
1458   (let ((reason (erc-response.contents parsed))
1459         bufs)
1460     (pcase-let ((`(,nick ,login ,host)
1461                  (erc-parse-user (erc-response.sender parsed))))
1462       (setq bufs (erc-buffer-list-with-nick nick proc))
1463       (erc-remove-user nick)
1464       (setq reason (erc-wash-quit-reason reason nick login host))
1465       (erc-display-message parsed 'notice bufs
1466                            'QUIT ?n nick ?u login
1467                            ?h host ?r reason))))
1468
1469 (define-erc-response-handler (TOPIC)
1470   "The channel topic has changed." nil
1471   (let* ((ch (car (erc-response.command-args parsed)))
1472          (topic (erc-trim-string (erc-response.contents parsed)))
1473          (time (format-time-string erc-server-timestamp-format)))
1474     (pcase-let ((`(,nick ,login ,host)
1475                  (erc-parse-user (erc-response.sender parsed))))
1476       (erc-update-channel-member ch nick nick nil nil nil nil nil nil host login)
1477       (erc-update-channel-topic ch (format "%s\C-o (%s, %s)" topic nick time))
1478       (erc-display-message parsed 'notice (erc-get-buffer ch proc)
1479                            'TOPIC ?n nick ?u login ?h host
1480                            ?c ch ?T topic))))
1481
1482 (define-erc-response-handler (WALLOPS)
1483   "Display a WALLOPS message." nil
1484   (let ((message (erc-response.contents parsed)))
1485     (pcase-let ((`(,nick ,login ,host)
1486                  (erc-parse-user (erc-response.sender parsed))))
1487       (erc-display-message
1488        parsed 'notice nil
1489        'WALLOPS ?n nick ?m message))))
1490
1491 (define-erc-response-handler (001)
1492   "Set `erc-server-current-nick' to reflect server settings and display the welcome message."
1493   nil
1494   (erc-set-current-nick (car (erc-response.command-args parsed)))
1495   (erc-update-mode-line)                ; needed here?
1496   (setq erc-nick-change-attempt-count 0)
1497   (setq erc-default-nicks (if (consp erc-nick) erc-nick (list erc-nick)))
1498   (erc-display-message
1499    parsed 'notice 'active (erc-response.contents parsed)))
1500
1501 (define-erc-response-handler (MOTD 002 003 371 372 374 375)
1502   "Display the server's message of the day." nil
1503   (erc-handle-login)
1504   (erc-display-message
1505    parsed 'notice (if erc-server-connected 'active proc)
1506    (erc-response.contents parsed)))
1507
1508 (define-erc-response-handler (376 422)
1509   "End of MOTD/MOTD is missing." nil
1510   (erc-server-MOTD proc parsed)
1511   (erc-connection-established proc parsed))
1512
1513 (define-erc-response-handler (004)
1514   "Display the server's identification." nil
1515   (pcase-let ((`(,server-name ,server-version)
1516                (cdr (erc-response.command-args parsed))))
1517     (setq erc-server-version server-version)
1518     (setq erc-server-announced-name server-name)
1519     (erc-update-mode-line-buffer (process-buffer proc))
1520     (erc-display-message
1521      parsed 'notice proc
1522      's004 ?s server-name ?v server-version
1523      ?U (nth 3 (erc-response.command-args parsed))
1524      ?C (nth 4 (erc-response.command-args parsed)))))
1525
1526 (define-erc-response-handler (005)
1527   "Set the variable `erc-server-parameters' and display the received message.
1528
1529 According to RFC 2812, suggests alternate servers on the network.
1530 Many servers, however, use this code to show which parameters they have set,
1531 for example, the network identifier, maximum allowed topic length, whether
1532 certain commands are accepted and more.  See documentation for
1533 `erc-server-parameters' for more information on the parameters sent.
1534
1535 A server may send more than one 005 message."
1536   nil
1537   (let ((line (mapconcat 'identity
1538                          (setf (erc-response.command-args parsed)
1539                                (cdr (erc-response.command-args parsed)))
1540                          " ")))
1541     (while (erc-response.command-args parsed)
1542       (let ((section (pop (erc-response.command-args parsed))))
1543         ;; fill erc-server-parameters
1544         (when (string-match "^\\([A-Z]+\\)\=\\(.*\\)$\\|^\\([A-Z]+\\)$"
1545                             section)
1546           (add-to-list 'erc-server-parameters
1547                        `(,(or (match-string 1 section)
1548                               (match-string 3 section))
1549                          .
1550                          ,(match-string 2 section))))))
1551     (erc-display-message parsed 'notice proc line)))
1552
1553 (define-erc-response-handler (221)
1554   "Display the current user modes." nil
1555   (let* ((nick (car (erc-response.command-args parsed)))
1556          (modes (mapconcat 'identity
1557                            (cdr (erc-response.command-args parsed)) " ")))
1558     (erc-set-modes nick modes)
1559     (erc-display-message parsed 'notice 'active 's221 ?n nick ?m modes)))
1560
1561 (define-erc-response-handler (252)
1562   "Display the number of IRC operators online." nil
1563   (erc-display-message parsed 'notice 'active 's252
1564                        ?i (cadr (erc-response.command-args parsed))))
1565
1566 (define-erc-response-handler (253)
1567   "Display the number of unknown connections." nil
1568   (erc-display-message parsed 'notice 'active 's253
1569                        ?i (cadr (erc-response.command-args parsed))))
1570
1571 (define-erc-response-handler (254)
1572   "Display the number of channels formed." nil
1573   (erc-display-message parsed 'notice 'active 's254
1574                        ?i (cadr (erc-response.command-args parsed))))
1575
1576 (define-erc-response-handler (250 251 255 256 257 258 259 265 266 377 378)
1577   "Generic display of server messages as notices.
1578
1579 See `erc-display-server-message'." nil
1580   (erc-display-server-message proc parsed))
1581
1582 (define-erc-response-handler (275)
1583   "Display secure connection message." nil
1584   (pcase-let ((`(,nick ,user ,message)
1585                (cdr (erc-response.command-args parsed))))
1586     (erc-display-message
1587      parsed 'notice 'active 's275
1588      ?n nick
1589      ?m (mapconcat 'identity (cddr (erc-response.command-args parsed))
1590                    " "))))
1591
1592 (define-erc-response-handler (290)
1593   "Handle dancer-ircd CAPAB messages." nil nil)
1594
1595 (define-erc-response-handler (301)
1596   "AWAY notice." nil
1597   (erc-display-message parsed 'notice 'active 's301
1598                        ?n (cadr (erc-response.command-args parsed))
1599                        ?r (erc-response.contents parsed)))
1600
1601 (define-erc-response-handler (303)
1602   "ISON reply" nil
1603   (erc-display-message parsed 'notice 'active 's303
1604                        ?n (cadr (erc-response.command-args parsed))))
1605
1606 (define-erc-response-handler (305)
1607   "Return from AWAYness." nil
1608   (erc-process-away proc nil)
1609   (erc-display-message parsed 'notice 'active
1610                        's305 ?m (erc-response.contents parsed)))
1611
1612 (define-erc-response-handler (306)
1613   "Set AWAYness." nil
1614   (erc-process-away proc t)
1615   (erc-display-message parsed 'notice 'active
1616                        's306 ?m (erc-response.contents parsed)))
1617
1618 (define-erc-response-handler (307)
1619   "Display nick-identified message." nil
1620   (pcase-let ((`(,nick ,user ,message)
1621                (cdr (erc-response.command-args parsed))))
1622     (erc-display-message
1623      parsed 'notice 'active 's307
1624      ?n nick
1625      ?m (mapconcat 'identity (cddr (erc-response.command-args parsed))
1626                    " "))))
1627
1628 (define-erc-response-handler (311 314)
1629   "WHOIS/WHOWAS notices." nil
1630   (let ((fname (erc-response.contents parsed))
1631         (catalog-entry (intern (format "s%s" (erc-response.command parsed)))))
1632     (pcase-let ((`(,nick ,user ,host)
1633                  (cdr (erc-response.command-args parsed))))
1634       (erc-update-user-nick nick nick host nil fname user)
1635       (erc-display-message
1636        parsed 'notice 'active catalog-entry
1637        ?n nick ?f fname ?u user ?h host))))
1638
1639 (define-erc-response-handler (312)
1640   "Server name response in WHOIS." nil
1641   (pcase-let ((`(,nick ,server-host)
1642               (cdr (erc-response.command-args parsed))))
1643     (erc-display-message
1644      parsed 'notice 'active 's312
1645      ?n nick ?s server-host ?c (erc-response.contents parsed))))
1646
1647 (define-erc-response-handler (313)
1648   "IRC Operator response in WHOIS." nil
1649   (erc-display-message
1650    parsed 'notice 'active 's313
1651    ?n (cadr (erc-response.command-args parsed))))
1652
1653 (define-erc-response-handler (315 318 323 369)
1654   ;; 315 - End of WHO
1655   ;; 318 - End of WHOIS list
1656   ;; 323 - End of channel LIST
1657   ;; 369 - End of WHOWAS
1658   "End of WHO/WHOIS/LIST/WHOWAS notices." nil
1659   (ignore proc parsed))
1660
1661 (define-erc-response-handler (317)
1662   "IDLE notice." nil
1663   (pcase-let ((`(,nick ,seconds-idle ,on-since ,time)
1664                (cdr (erc-response.command-args parsed))))
1665     (setq time (when on-since
1666                  (format-time-string erc-server-timestamp-format
1667                                      (erc-string-to-emacs-time on-since))))
1668     (erc-update-user-nick nick nick nil nil nil
1669                           (and time (format "on since %s" time)))
1670     (if time
1671         (erc-display-message
1672          parsed 'notice 'active 's317-on-since
1673          ?n nick ?i (erc-sec-to-time (string-to-number seconds-idle)) ?t time)
1674       (erc-display-message
1675        parsed 'notice 'active 's317
1676        ?n nick ?i (erc-sec-to-time (string-to-number seconds-idle))))))
1677
1678 (define-erc-response-handler (319)
1679   "Channel names in WHOIS response." nil
1680   (erc-display-message
1681    parsed 'notice 'active 's319
1682    ?n (cadr (erc-response.command-args parsed))
1683    ?c (erc-response.contents parsed)))
1684
1685 (define-erc-response-handler (320)
1686   "Identified user in WHOIS." nil
1687   (erc-display-message
1688    parsed 'notice 'active 's320
1689    ?n (cadr (erc-response.command-args parsed))))
1690
1691 (define-erc-response-handler (321)
1692   "LIST header." nil
1693   (setq erc-channel-list nil))
1694
1695 (defun erc-server-321-message (proc parsed)
1696   "Display a message for the 321 event."
1697   (erc-display-message parsed 'notice proc 's321)
1698   nil)
1699 (add-hook 'erc-server-321-functions 'erc-server-321-message t)
1700
1701 (define-erc-response-handler (322)
1702   "LIST notice." nil
1703   (let ((topic (erc-response.contents parsed)))
1704     (pcase-let ((`(,channel ,num-users)
1705                  (cdr (erc-response.command-args parsed))))
1706       (add-to-list 'erc-channel-list (list channel))
1707       (erc-update-channel-topic channel topic))))
1708
1709 (defun erc-server-322-message (proc parsed)
1710   "Display a message for the 322 event."
1711   (let ((topic (erc-response.contents parsed)))
1712     (pcase-let ((`(,channel ,num-users)
1713                  (cdr (erc-response.command-args parsed))))
1714       (erc-display-message
1715        parsed 'notice proc 's322
1716        ?c channel ?u num-users ?t (or topic "")))))
1717 (add-hook 'erc-server-322-functions 'erc-server-322-message t)
1718
1719 (define-erc-response-handler (324)
1720   "Channel or nick modes." nil
1721   (let ((channel (cadr (erc-response.command-args parsed)))
1722         (modes (mapconcat 'identity (cddr (erc-response.command-args parsed))
1723                           " ")))
1724     (erc-set-modes channel modes)
1725     (erc-display-message
1726      parsed 'notice (erc-get-buffer channel proc)
1727      's324 ?c channel ?m modes)))
1728
1729 (define-erc-response-handler (328)
1730   "Channel URL (on freenode network)." nil
1731   (let ((channel (cadr (erc-response.command-args parsed)))
1732         (url (erc-response.contents parsed)))
1733     (erc-display-message parsed 'notice (erc-get-buffer channel proc)
1734                          's328 ?c channel ?u url)))
1735
1736 (define-erc-response-handler (329)
1737   "Channel creation date." nil
1738   (let ((channel (cadr (erc-response.command-args parsed)))
1739         (time (erc-string-to-emacs-time
1740                (nth 2 (erc-response.command-args parsed)))))
1741     (erc-display-message
1742      parsed 'notice (erc-get-buffer channel proc)
1743      's329 ?c channel ?t (format-time-string erc-server-timestamp-format
1744                                              time))))
1745
1746 (define-erc-response-handler (330)
1747   "Nick is authed as (on Quakenet network)." nil
1748   ;; FIXME: I don't know what the magic numbers mean.  Mummy, make
1749   ;; the magic numbers go away.
1750   ;; No seriously, I have no clue about the format of this command,
1751   ;; and don't sit on Quakenet, so can't test.  Originally we had:
1752   ;; nick == (aref parsed 3)
1753   ;; authaccount == (aref parsed 4)
1754   ;; authmsg == (aref parsed 5)
1755   ;; The guesses below are, well, just that. -- Lawrence 2004/05/10
1756   (let ((nick (cadr (erc-response.command-args parsed)))
1757         (authaccount (nth 2 (erc-response.command-args parsed)))
1758         (authmsg (erc-response.contents parsed)))
1759     (erc-display-message parsed 'notice 'active 's330
1760                          ?n nick ?a authmsg ?i authaccount)))
1761
1762 (define-erc-response-handler (331)
1763   "No topic set for channel." nil
1764   (let ((channel (cadr (erc-response.command-args parsed)))
1765         (topic (erc-response.contents parsed)))
1766     (erc-display-message parsed 'notice (erc-get-buffer channel proc)
1767                          's331 ?c channel)))
1768
1769 (define-erc-response-handler (332)
1770   "TOPIC notice." nil
1771   (let ((channel (cadr (erc-response.command-args parsed)))
1772         (topic (erc-response.contents parsed)))
1773     (erc-update-channel-topic channel topic)
1774     (erc-display-message parsed 'notice (erc-get-buffer channel proc)
1775                          's332 ?c channel ?T topic)))
1776
1777 (define-erc-response-handler (333)
1778   "Who set the topic, and when." nil
1779   (pcase-let ((`(,channel ,nick ,time)
1780                (cdr (erc-response.command-args parsed))))
1781     (setq time (format-time-string erc-server-timestamp-format
1782                                    (erc-string-to-emacs-time time)))
1783     (erc-update-channel-topic channel
1784                               (format "\C-o (%s, %s)" nick time)
1785                               'append)
1786     (erc-display-message parsed 'notice (erc-get-buffer channel proc)
1787                          's333 ?c channel ?n nick ?t time)))
1788
1789 (define-erc-response-handler (341)
1790   "Let user know when an INVITE attempt has been sent successfully."
1791   nil
1792   (pcase-let ((`(,nick ,channel)
1793                (cdr (erc-response.command-args parsed))))
1794     (erc-display-message parsed 'notice (erc-get-buffer channel proc)
1795                          's341 ?n nick ?c channel)))
1796
1797 (define-erc-response-handler (352)
1798   "WHO notice." nil
1799   (pcase-let ((`(,channel ,user ,host ,server ,nick ,away-flag)
1800                (cdr (erc-response.command-args parsed))))
1801     (let ((full-name (erc-response.contents parsed))
1802           hopcount)
1803       (when (string-match "\\(^[0-9]+ \\)\\(.*\\)$" full-name)
1804         (setq hopcount (match-string 1 full-name))
1805         (setq full-name (match-string 2 full-name)))
1806       (erc-update-channel-member channel nick nick nil nil nil nil nil nil host user full-name)
1807       (erc-display-message parsed 'notice 'active 's352
1808                            ?c channel ?n nick ?a away-flag
1809                            ?u user ?h host ?f full-name))))
1810
1811 (define-erc-response-handler (353)
1812   "NAMES notice." nil
1813   (let ((channel (nth 2 (erc-response.command-args parsed)))
1814         (users (erc-response.contents parsed)))
1815     (erc-display-message parsed 'notice (or (erc-get-buffer channel proc)
1816                                             'active)
1817                          's353 ?c channel ?u users)
1818     (erc-with-buffer (channel proc)
1819       (erc-channel-receive-names users))))
1820
1821 (define-erc-response-handler (366)
1822   "End of NAMES." nil
1823   (erc-with-buffer ((cadr (erc-response.command-args parsed)) proc)
1824     (erc-channel-end-receiving-names)))
1825
1826 (define-erc-response-handler (367)
1827   "Channel ban list entries." nil
1828   (pcase-let ((`(,channel ,banmask ,setter ,time)
1829                (cdr (erc-response.command-args parsed))))
1830     ;; setter and time are not standard
1831     (if setter
1832         (erc-display-message parsed 'notice 'active 's367-set-by
1833                              ?c channel
1834                              ?b banmask
1835                              ?s setter
1836                              ?t (or time ""))
1837       (erc-display-message parsed 'notice 'active 's367
1838                            ?c channel
1839                            ?b banmask))))
1840
1841 (define-erc-response-handler (368)
1842   "End of channel ban list." nil
1843   (let ((channel (cadr (erc-response.command-args parsed))))
1844     (erc-display-message parsed 'notice 'active 's368
1845                          ?c channel)))
1846
1847 (define-erc-response-handler (379)
1848   "Forwarding to another channel." nil
1849   ;; FIXME: Yet more magic numbers in original code, I'm guessing this
1850   ;; command takes two arguments, and doesn't have any "contents". --
1851   ;; Lawrence 2004/05/10
1852   (pcase-let ((`(,from ,to)
1853                (cdr (erc-response.command-args parsed))))
1854     (erc-display-message parsed 'notice 'active
1855                          's379 ?c from ?f to)))
1856
1857 (define-erc-response-handler (391)
1858   "Server's time string." nil
1859   (erc-display-message
1860    parsed 'notice 'active
1861    's391 ?s (cadr (erc-response.command-args parsed))
1862    ?t (nth 2 (erc-response.command-args parsed))))
1863
1864 (define-erc-response-handler (401)
1865   "No such nick/channel." nil
1866   (let ((nick/channel (cadr (erc-response.command-args parsed))))
1867     (when erc-whowas-on-nosuchnick
1868       (erc-log (format "cmd: WHOWAS: %s" nick/channel))
1869       (erc-server-send (format "WHOWAS %s 1" nick/channel)))
1870     (erc-display-message parsed '(notice error) 'active
1871                          's401 ?n nick/channel)))
1872
1873 (define-erc-response-handler (403)
1874   "No such channel." nil
1875   (erc-display-message parsed '(notice error) 'active
1876                        's403 ?c (cadr (erc-response.command-args parsed))))
1877
1878 (define-erc-response-handler (404)
1879   "Cannot send to channel." nil
1880   (erc-display-message parsed '(notice error) 'active
1881                        's404 ?c (cadr (erc-response.command-args parsed))))
1882
1883
1884 (define-erc-response-handler (405)
1885   "Can't join that many channels." nil
1886   (erc-display-message parsed '(notice error) 'active
1887                        's405 ?c (cadr (erc-response.command-args parsed))))
1888
1889 (define-erc-response-handler (406)
1890   "No such nick." nil
1891   (erc-display-message parsed '(notice error) 'active
1892                        's406 ?n (cadr (erc-response.command-args parsed))))
1893
1894 (define-erc-response-handler (412)
1895   "No text to send." nil
1896   (erc-display-message parsed '(notice error) 'active 's412))
1897
1898 (define-erc-response-handler (421)
1899   "Unknown command." nil
1900   (erc-display-message parsed '(notice error) 'active 's421
1901                        ?c (cadr (erc-response.command-args parsed))))
1902
1903 (define-erc-response-handler (432)
1904   "Bad nick." nil
1905   (erc-display-message parsed '(notice error) 'active 's432
1906                        ?n (cadr (erc-response.command-args parsed))))
1907
1908 (define-erc-response-handler (433)
1909   "Login-time \"nick in use\"." nil
1910   (erc-nickname-in-use (cadr (erc-response.command-args parsed))
1911                        "already in use"))
1912
1913 (define-erc-response-handler (437)
1914   "Nick temporarily unavailable (on IRCnet)." nil
1915   (let ((nick/channel (cadr (erc-response.command-args parsed))))
1916     (unless (erc-channel-p nick/channel)
1917       (erc-nickname-in-use nick/channel "temporarily unavailable"))))
1918
1919 (define-erc-response-handler (442)
1920   "Not on channel." nil
1921   (erc-display-message parsed '(notice error) 'active 's442
1922                        ?c (cadr (erc-response.command-args parsed))))
1923
1924 (define-erc-response-handler (461)
1925   "Not enough parameters for command." nil
1926   (erc-display-message parsed '(notice error)  'active 's461
1927                        ?c (cadr (erc-response.command-args parsed))
1928                        ?m (erc-response.contents parsed)))
1929
1930 (define-erc-response-handler (465)
1931   "You are banned from this server." nil
1932   (setq erc-server-banned t)
1933   ;; show the server's message, as a reason might be provided
1934   (erc-display-error-notice
1935    parsed
1936    (erc-response.contents parsed)))
1937
1938 (define-erc-response-handler (474)
1939   "Banned from channel errors." nil
1940   (erc-display-message parsed '(notice error) nil
1941                        (intern (format "s%s"
1942                                        (erc-response.command parsed)))
1943                        ?c (cadr (erc-response.command-args parsed))))
1944
1945 (define-erc-response-handler (475)
1946   "Channel key needed." nil
1947   (erc-display-message parsed '(notice error) nil 's475
1948                        ?c (cadr (erc-response.command-args parsed)))
1949   (when erc-prompt-for-channel-key
1950     (let ((channel (cadr (erc-response.command-args parsed)))
1951           (key (read-from-minibuffer
1952                 (format "Channel %s is mode +k.  Enter key (RET to cancel): "
1953                         (cadr (erc-response.command-args parsed))))))
1954       (when (and key (> (length key) 0))
1955           (erc-cmd-JOIN channel key)))))
1956
1957 (define-erc-response-handler (477)
1958   "Channel doesn't support modes." nil
1959   (let ((channel (cadr (erc-response.command-args parsed)))
1960         (message (erc-response.contents parsed)))
1961     (erc-display-message parsed 'notice (erc-get-buffer channel proc)
1962                          (format "%s: %s" channel message))))
1963
1964 (define-erc-response-handler (482)
1965   "You need to be a channel operator to do that." nil
1966   (let ((channel (cadr (erc-response.command-args parsed)))
1967         (message (erc-response.contents parsed)))
1968     (erc-display-message parsed '(error notice) 'active 's482
1969                          ?c channel ?m message)))
1970
1971 (define-erc-response-handler (671)
1972   "Secure connection response in WHOIS." nil
1973   (let ((nick (cadr (erc-response.command-args parsed)))
1974         (securemsg (erc-response.contents parsed)))
1975     (erc-display-message parsed 'notice 'active 's671
1976                          ?n nick ?a securemsg)))
1977
1978 (define-erc-response-handler (431 445 446 451 462 463 464 481 483 484 485
1979                                   491 501 502)
1980   ;; 431 - No nickname given
1981   ;; 445 - SUMMON has been disabled
1982   ;; 446 - USERS has been disabled
1983   ;; 451 - You have not registered
1984   ;; 462 - Unauthorized command (already registered)
1985   ;; 463 - Your host isn't among the privileged
1986   ;; 464 - Password incorrect
1987   ;; 481 - Need IRCop privileges
1988   ;; 483 - You can't kill a server!
1989   ;; 484 - Your connection is restricted!
1990   ;; 485 - You're not the original channel operator
1991   ;; 491 - No O-lines for your host
1992   ;; 501 - Unknown MODE flag
1993   ;; 502 - Cannot change mode for other users
1994   "Generic display of server error messages.
1995
1996 See `erc-display-error-notice'." nil
1997   (erc-display-error-notice
1998    parsed
1999    (intern (format "s%s" (erc-response.command parsed)))))
2000
2001 ;; FIXME: These are yet to be implemented, they're just stubs for now
2002 ;; -- Lawrence 2004/05/12
2003
2004 ;; response numbers left here for reference
2005
2006 ;; (define-erc-response-handler (323 364 365 381 382 392 393 394 395
2007 ;;                               200 201 202 203 204 205 206 208 209 211 212 213
2008 ;;                               214 215 216 217 218 219 241 242 243 244 249 261
2009 ;;                               262 302 342 351 402 407 409 411 413 414 415
2010 ;;                               423 424 436 441 443 444 467 471 472 473 KILL)
2011 ;;   nil nil
2012 ;;   (ignore proc parsed))
2013
2014 (provide 'erc-backend)
2015
2016 ;;; erc-backend.el ends here
2017 ;; Local Variables:
2018 ;; indent-tabs-mode: nil
2019 ;; End: