code.delx.au - gnu-emacs/blob - configure.in

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl
   6 dnl  Copyright (C) 1994, 1995, 1996, 1999, 2000, 2001, 2002, 2003,
   7 dnl    2004, 2005, 2006, 2007, 2008  Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation, either version 3 of the License, or
  14 dnl  (at your option) any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 AC_PREREQ(2.61)
  25 AC_INIT(emacs, 23.0.60)
  26 AC_CONFIG_HEADER(src/config.h:src/config.in)
  27 AC_CONFIG_SRCDIR(src/lisp.h)
  28
  29 dnl Support for --program-prefix, --program-suffix and
  30 dnl --program-transform-name options
  31 AC_ARG_PROGRAM
  32
  33 lispdir='${datadir}/emacs/${version}/lisp'
  34 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  35 '${datadir}/emacs/site-lisp'
  36 lisppath='${locallisppath}:${lispdir}:${datadir}/emacs/${version}/leim'
  37 etcdir='${datadir}/emacs/${version}/etc'
  38 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  39 docdir='${datadir}/emacs/${version}/etc'
  40 gamedir='${localstatedir}/games/emacs'
  41
  42 gameuser=games
  43
  44 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
  45 dnl Create a new --with option that defaults to being disabled.
  46 dnl NAME is the base name of the option.  The shell variable with_NAME
  47 dnl   will be set to either the user's value (if the option is
  48 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
  49 dnl   option is not specified).  Note that the shell variable name is
  50 dnl   constructed as autoconf does, by replacing non-alphanumeric
  51 dnl   characters with "_".
  52 dnl HELP-STRING is the help text for the option.
  53 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
  54   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
  55     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
  56 ])dnl
  57
  58 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
  59 dnl Create a new --with option that defaults to being enabled.  NAME
  60 dnl   is the base name of the option.  The shell variable with_NAME
  61 dnl   will be set either to 'no' (for a plain --without-NAME) or to
  62 dnl   'yes' (if the option is not specified).  Note that the shell
  63 dnl   variable name is constructed as autoconf does, by replacing
  64 dnl   non-alphanumeric characters with "_".
  65 dnl HELP-STRING is the help text for the option.
  66 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
  67   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
  68    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=yes])dnl
  69 ])dnl
  70
  71 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
  72 if test "$with_pop" = yes; then
  73    AC_DEFINE(MAIL_USE_POP)
  74 fi
  75 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
  76
  77 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
  78 if test "$with_kerberos" != no; then
  79    AC_DEFINE(KERBEROS)
  80 fi
  81 AH_TEMPLATE(KERBEROS,
  82             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
  83
  84 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
  85 if test "${with_kerberos5}" != no; then
  86   if test "${with_kerberos}" = no; then
  87     with_kerberos=yes
  88     AC_DEFINE(KERBEROS)
  89   fi
  90   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
  91 fi
  92
  93 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
  94 if test "$with_hesiod" != no; then
  95   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
  96 fi
  97
  98 OPTION_DEFAULT_ON([sound],[don't compile with sound support])
  99
 100 OPTION_DEFAULT_ON([sync-input],[Process async input synchronously])
 101 if test "$with_sync_input" = yes; then
 102    AC_DEFINE(SYNC_INPUT, 1, [Process async input synchronously.])
 103 fi
 104
 105 dnl FIXME currently it is not the last.
 106 dnl This should be the last --with option, because --with-x is
 107 dnl added later on when we find the path of X, and it's best to
 108 dnl keep them together visually.
 109 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 110  [use an X toolkit (KIT one of: yes, lucid, athena, motif, gtk, no)])],
 111 [         case "${withval}" in
 112             y | ye | yes )      val=gtk ;;
 113             n | no )            val=no  ;;
 114             l | lu | luc | luci | lucid )       val=lucid ;;
 115             a | at | ath | athe | athen | athena )      val=athena ;;
 116             m | mo | mot | moti | motif )       val=motif ;;
 117             g | gt | gtk  )     val=gtk ;;
 118             * )
 119 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 120 this option's value should be `yes', `no', `lucid', `athena', `motif' or `gtk'.
 121 `yes' and `gtk' are synonyms. `athena' and `lucid' are synonyms.])
 122             ;;
 123           esac
 124           with_x_toolkit=$val
 125 ])
 126
 127 dnl _ON results in a '--without' option in the --help output, so
 128 dnl the help text should refer to "don't compile", etc.
 129 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 130 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 131 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 132 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 133 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 134 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 135
 136 OPTION_DEFAULT_ON([freetype],[don't use Freetype for local font support])
 137 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 138 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 139 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 140
 141 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 142 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 143 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 144 OPTION_DEFAULT_OFF([ns],[use nextstep (Cocoa or GNUstep) windowing system])
 145
 146 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 147 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 148
 149 ## For the times when you want to build Emacs but don't have
 150 ## a suitable makeinfo, and can live without the manuals.
 151 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 152 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 153
 154 dnl Can remove these in Emacs 24.
 155 AC_ARG_WITH([gtk],,
 156   [AC_MSG_ERROR([--with-gtk has been removed.  Use --with-x-toolkit to
 157 specify a toolkit.])],,)
 158
 159 AC_ARG_WITH([gcc],,
 160   [AC_MSG_ERROR([--with-gcc has been removed.  Set the `CC' environment
 161 variable to specify a compiler.])],,)
 162
 163 AC_ARG_WITH([pkg-config-prog],dnl
 164 [AS_HELP_STRING([--with-pkg-config-prog=PATH],
 165                   [Path to pkg-config for finding GTK and librsvg])])
 166 if test "X${with_pkg_config_prog}" != X; then
 167    if test "${with_pkg_config_prog}" != yes; then
 168       PKG_CONFIG="${with_pkg_config_prog}"
 169    fi
 170 fi
 171
 172 AC_ARG_ENABLE(cocoa-experimental-ctrl-g,
 173 [AS_HELP_STRING([--enable-cocoa-experimental-ctrl-g],
 174                 [enable experimental improved ctrl-g recognition])],
 175    EN_COCOA_EXPERIMENTAL_CTRL_G=$enableval,
 176    EN_COCOA_EXPERIMENTAL_CTRL_G=no)
 177
 178 AC_ARG_ENABLE(ns-self-contained,
 179 [AS_HELP_STRING([--disable-ns-self-contained],
 180                 [disable self contained build under NeXTstep])],
 181    EN_NS_SELF_CONTAINED=$enableval,
 182    EN_NS_SELF_CONTAINED=yes)
 183
 184 AC_ARG_ENABLE(asserts,
 185 [AS_HELP_STRING([--enable-asserts], [compile code with asserts enabled])],
 186       USE_XASSERTS=$enableval,
 187       USE_XASSERTS=no)
 188
 189 AC_ARG_ENABLE(maintainer-mode,
 190 [AS_HELP_STRING([--enable-maintainer-mode],
 191                 [enable make rules and dependencies not useful (and sometimes
 192                  confusing) to the casual installer])],
 193       USE_MAINTAINER_MODE=$enableval,
 194       USE_MAINTAINER_MODE=no)
 195 if test $USE_MAINTAINER_MODE = yes; then
 196   MAINT=
 197 else
 198   MAINT=#
 199 fi
 200 AC_SUBST(MAINT)
 201
 202 AC_ARG_ENABLE(locallisppath,
 203 [AS_HELP_STRING([--enable-locallisppath=PATH],
 204                 [directories Emacs should search for lisp files specific
 205                  to this site])],
 206 if test "${enableval}" = "no"; then
 207   locallisppath=
 208 elif test "${enableval}" != "yes"; then
 209   locallisppath=${enableval}
 210 fi)
 211
 212 #### Make srcdir absolute, if it isn't already.  It's important to
 213 #### avoid running the path through pwd unnecessarily, since pwd can
 214 #### give you automounter prefixes, which can go away.  We do all this
 215 #### so Emacs can find its files when run uninstalled.
 216 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 217 unset CDPATH
 218 case "${srcdir}" in
 219   /* ) ;;
 220   . )
 221     ## We may be able to use the $PWD environment variable to make this
 222     ## absolute.  But sometimes PWD is inaccurate.
 223     ## Note: we used to use ${PWD} at the end instead of `pwd`,
 224     ## but that tested only for a well-formed and valid PWD,
 225     ## it did not object when PWD was well-formed and valid but just wrong.
 226     if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`"  ;
 227     then
 228       srcdir="$PWD"
 229     else
 230       srcdir="`(cd ${srcdir}; pwd)`"
 231     fi
 232   ;;
 233   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
 234 esac
 235
 236 #### Check if the source directory already has a configured system in it.
 237 if test `pwd` != `(cd ${srcdir} && pwd)` \
 238    && test -f "${srcdir}/src/config.h" ; then
 239   AC_MSG_WARN([[The directory tree `${srcdir}' is being used
 240    as a build directory right now; it has been configured in its own
 241    right.  To configure in another directory as well, you MUST
 242    use GNU make.  If you do not have GNU make, then you must
 243    now do `make distclean' in ${srcdir},
 244    and then run $0 again.]])
 245 fi
 246
 247 #### Given the configuration name, set machfile and opsysfile to the
 248 #### names of the m/*.h and s/*.h files we should use.
 249
 250 ### Canonicalize the configuration name.
 251
 252 AC_CANONICAL_HOST
 253 canonical=$host
 254 configuration=${host_alias-${build_alias-$host}}
 255
 256 dnl This used to use changequote, but, apart from `changequote is evil'
 257 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 258 dnl the great gob of text.  Thus it's not processed for possible expansion.
 259 dnl Just make sure the brackets remain balanced.
 260 dnl
 261 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 262 dnl indicated by comments.
 263 dnl quotation begins
 264 [
 265
 266 ### If you add support for a new configuration, add code to this
 267 ### switch statement to recognize your configuration name and select
 268 ### the appropriate operating system and machine description files.
 269
 270 ### You would hope that you could choose an m/*.h file pretty much
 271 ### based on the machine portion of the configuration name, and an s-
 272 ### file based on the operating system portion.  However, it turns out
 273 ### that each m/*.h file is pretty manufacturer-specific - for
 274 ### example mips.h is MIPS
 275 ### So we basically have to have a special case for each
 276 ### configuration name.
 277 ###
 278 ### As far as handling version numbers on operating systems is
 279 ### concerned, make sure things will fail in a fixable way.  If
 280 ### /etc/MACHINES doesn't say anything about version numbers, be
 281 ### prepared to handle anything reasonably.  If version numbers
 282 ### matter, be sure /etc/MACHINES says something about it.
 283 ###
 284 ### Eric Raymond says we should accept strings like "sysvr4" to mean
 285 ### "System V Release 4"; he writes, "The old convention encouraged
 286 ### confusion between `system' and `release' levels'."
 287
 288 machine='' opsys='' unported=no
 289 case "${canonical}" in
 290
 291   ## FreeBSD ports
 292   *-*-freebsd* )
 293     opsys=freebsd
 294     case "${canonical}" in
 295       alpha*-*-freebsd*)        machine=alpha ;;
 296       arm*-*-freebsd*)          machine=arm ;;
 297       ia64-*-freebsd*)          machine=ia64 ;;
 298       sparc-*-freebsd*)         machine=sparc ;;
 299       sparc64-*-freebsd*)       machine=sparc ;;
 300       powerpc-*-freebsd*)       machine=macppc ;;
 301       i[3456]86-*-freebsd*)     machine=intel386 ;;
 302       amd64-*-freebsd*|x86_64-*-freebsd*) machine=amdx86-64 ;;
 303     esac
 304   ;;
 305
 306   ## FreeBSD kernel + glibc based userland
 307   *-*-kfreebsd*gnu* )
 308     opsys=gnu-kfreebsd
 309     case "${canonical}" in
 310       alpha*-*-kfreebsd*)       machine=alpha ;;
 311       ia64-*-kfreebsd*)         machine=ia64 ;;
 312       sparc-*-kfreebsd*)        machine=sparc ;;
 313       sparc64-*-kfreebsd*)      machine=sparc ;;
 314       powerpc-*-kfreebsd*)      machine=macppc ;;
 315       i[3456]86-*-kfreebsd*)    machine=intel386 ;;
 316       amd64-*-kfreebsd*|x86_64-*-kfreebsd*) machine=amdx86-64 ;;
 317     esac
 318   ;;
 319
 320   ## NetBSD ports
 321   *-*-netbsd* )
 322     opsys=netbsd
 323     if test -f /usr/lib/crti.o; then]
 324 dnl The close and open brackets here are because this section is quoted --
 325 dnl see the `changequote' comment above.
 326       AC_DEFINE(HAVE_CRTIN, [], [Define to 1 if you have /usr/lib/crti.o.])
 327 [   fi
 328
 329     case "${canonical}" in
 330       alpha*-*-netbsd*) machine=alpha ;;
 331       i[3456]86-*-netbsd*) machine=intel386 ;;
 332       powerpc-*-netbsd*) machine=macppc ;;
 333       sparc*-*-netbsd*) machine=sparc ;;
 334       vax-*-netbsd*)    machine=vax ;;
 335       arm-*-netbsd*)    machine=arm ;;
 336       x86_64-*-netbsd*) machine=amdx86-64 ;;
 337       hppa-*-netbsd*)   machine=hp800 ;;
 338     esac
 339   ;;
 340
 341   ## OpenBSD ports
 342   *-*-openbsd* )
 343     opsys=openbsd
 344     case "${canonical}" in
 345       alpha*-*-openbsd*)        machine=alpha ;;
 346       arm-*-openbsd*)          machine=arm ;;
 347       i386-*-openbsd*)         machine=intel386 ;;
 348       powerpc-*-openbsd*)      machine=macppc ;;
 349       sparc*-*-openbsd*)       machine=sparc ;;
 350       vax-*-openbsd*)          machine=vax ;;
 351       x86_64-*-openbsd*)       machine=amdx86-64 ;;
 352     esac
 353   ;;
 354
 355   ## LynxOS ports
 356   *-*-lynxos* )
 357     opsys=lynxos
 358     case "${canonical}" in
 359       i[3456]86-*-lynxos*) machine=intel386 ;;
 360       powerpc-*-lynxos*) machine=powerpc ;;
 361     esac
 362   ;;
 363
 364   alpha*-*-linux-gnu* )
 365     machine=alpha opsys=gnu-linux
 366   ;;
 367
 368   arm*-*-linux-gnu* )
 369     machine=arm opsys=gnu-linux
 370   ;;
 371
 372   ## Apple Darwin / Mac OS X
 373   *-apple-darwin* )
 374     case "${canonical}" in
 375       i[3456]86-* )  machine=intel386 ;;
 376       powerpc-* )    machine=macppc ;;
 377       * )            unported=yes ;;
 378     esac
 379     opsys=darwin
 380     # Define CPP as follows to make autoconf work correctly.
 381     CPP="${CC-cc} -E -no-cpp-precomp"
 382     # Use fink packages if available.
 383     if test -d /sw/include && test -d /sw/lib; then
 384       GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 385       CPP="${CPP} ${GCC_TEST_OPTIONS}"
 386       NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 387     fi
 388   ;;
 389
 390   ## HP 9000 series 700 and 800, running HP/UX
 391   hppa*-hp-hpux10.2* )
 392     machine=hp800 opsys=hpux10-20
 393   ;;
 394   hppa*-hp-hpux1[1-9]* )
 395     machine=hp800 opsys=hpux11
 396     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 397   ;;
 398
 399   hppa*-*-linux-gnu* )
 400     machine=hp800 opsys=gnu-linux
 401   ;;
 402
 403   ## IBM machines
 404   s390-*-linux-gnu* )
 405     machine=ibms390 opsys=gnu-linux
 406   ;;
 407   s390x-*-linux-gnu* )
 408     machine=ibms390x opsys=gnu-linux
 409   ;;
 410   rs6000-ibm-aix4.2* | powerpc-ibm-aix4.2*  )
 411     machine=ibmrs6000 opsys=aix4-2
 412   ;;
 413   rs6000-ibm-aix4.3* | powerpc-ibm-aix4.3*  )
 414     machine=ibmrs6000 opsys=aix4-2
 415   ;;
 416   rs6000-ibm-aix5* | powerpc-ibm-aix5*  )
 417     machine=ibmrs6000 opsys=aix4-2
 418   ;;
 419   rs6000-ibm-aix5* | powerpc-ibm-aix6*  )
 420     machine=ibmrs6000 opsys=aix4-2
 421   ;;
 422
 423   ## Macintosh PowerPC
 424   powerpc*-*-linux-gnu* )
 425     machine=macppc opsys=gnu-linux
 426   ;;
 427
 428   ## Silicon Graphics machines
 429   ## Iris 4D
 430   mips-sgi-irix6.5 )
 431     machine=iris4d opsys=irix6-5
 432     # Without defining _LANGUAGE_C, things get masked out in the headers
 433     # so that, for instance, grepping for `free' in stdlib.h fails and
 434     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 435     NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
 436     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 437   ;;
 438
 439   ## Suns
 440   sparc-*-linux-gnu* | sparc64-*-linux-gnu* )
 441     machine=sparc opsys=gnu-linux
 442   ;;
 443
 444   *-sun-solaris* \
 445     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* | powerpc*-*-solaris2* \
 446     | rs6000-*-solaris2*)
 447     case "${canonical}" in
 448       i[3456]86-*-* )     machine=intel386 ;;
 449       amd64-*-*|x86_64-*-*)     machine=amdx86-64 ;;
 450       powerpc* | rs6000* )  machine=ibmrs6000 ;;
 451       sparc* )          machine=sparc ;;
 452       * )               unported=yes ;;
 453     esac
 454     case "${canonical}" in
 455       *-sunos5.3* | *-solaris2.3* )
 456                 opsys=sol2-3
 457                 NON_GNU_CPP=/usr/ccs/lib/cpp
 458                 ;;
 459       *-sunos5.4* | *-solaris2.4* )
 460                 opsys=sol2-4
 461                 NON_GNU_CPP=/usr/ccs/lib/cpp
 462                 RANLIB="ar -ts"
 463                 ;;
 464       *-sunos5.5* | *-solaris2.5* )
 465                 opsys=sol2-5
 466                 NON_GNU_CPP=/usr/ccs/lib/cpp
 467                 RANLIB="ar -ts"
 468                 ;;
 469       *-sunos5.6* | *-solaris2.6* )
 470                 opsys=sol2-6
 471                 NON_GNU_CPP=/usr/ccs/lib/cpp
 472                 RANLIB="ar -ts"
 473                 ;;
 474       *-sunos5* | *-solaris* )
 475                 opsys=sol2-6
 476                 emacs_check_sunpro_c=yes
 477                 NON_GNU_CPP=/usr/ccs/lib/cpp
 478                 ;;
 479     esac
 480     ## Watch out for a compiler that we know will not work.
 481     case "${canonical}" in
 482      *-solaris* | *-sunos5* )
 483                 if [ "x$CC" = x/usr/ucb/cc ]; then
 484                   ## /usr/ucb/cc doesn't work;
 485                   ## we should find some other compiler that does work.
 486                   unset CC
 487                 fi
 488                 ;;
 489       *) ;;
 490     esac
 491   ;;
 492
 493   ## Vaxen.
 494   vax-dec-* )
 495     machine=vax
 496     case "${canonical}" in
 497       *-vms* )                                          opsys=vms ;;
 498       * )                                               unported=yes
 499     esac
 500   ;;
 501
 502   ## IA-64
 503   ia64*-*-linux* )
 504     machine=ia64 opsys=gnu-linux
 505   ;;
 506
 507   ## Intel 386 machines where we don't care about the manufacturer
 508   i[3456]86-*-* )
 509     machine=intel386
 510     case "${canonical}" in
 511       *-cygwin )                opsys=cygwin ;;
 512       *-darwin* )               opsys=darwin
 513                                 CPP="${CC-cc} -E -no-cpp-precomp"
 514                                 ;;
 515       *-linux-gnu* )            opsys=gnu-linux ;;
 516       *-sysv4.2uw* )            opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 517       *-sysv5uw* )              opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 518       *-sysv5OpenUNIX* )        opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 519       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 520     esac
 521   ;;
 522
 523   ## m68k Linux-based GNU system
 524   m68k-*-linux-gnu* )
 525     machine=m68k opsys=gnu-linux
 526   ;;
 527
 528   ## Mips Linux-based GNU system
 529   mips-*-linux-gnu* | mipsel-*-linux-gnu* )
 530     machine=mips opsys=gnu-linux
 531   ;;
 532
 533   ## AMD x86-64 Linux-based GNU system
 534   x86_64-*-linux-gnu* )
 535     machine=amdx86-64 opsys=gnu-linux
 536   ;;
 537
 538   ## Tensilica Xtensa Linux-based GNU system
 539   xtensa*-*-linux-gnu* )
 540     machine=xtensa opsys=gnu-linux
 541     ;;
 542
 543   * )
 544     unported=yes
 545   ;;
 546 esac
 547
 548 ### If the code above didn't choose an operating system, just choose
 549 ### an operating system based on the configuration name.  You really
 550 ### only want to use this when you have no idea what the right
 551 ### operating system is; if you know what operating systems a machine
 552 ### runs, it's cleaner to make it explicit in the case statement
 553 ### above.
 554 if test x"${opsys}" = x; then
 555   case "${canonical}" in
 556     *-gnu* )                            opsys=gnu ;;
 557     *-sysv4.2uw* )                      opsys=unixware ;;
 558     *-sysv5uw* )                        opsys=unixware ;;
 559     *-sysv5OpenUNIX* )                  opsys=unixware ;;
 560     *-sysv4.1* | *-sysvr4.1* )
 561         NON_GNU_CPP=/usr/lib/cpp
 562         opsys=usg5-4 ;;
 563     *-sysv4.[2-9]* | *-sysvr4.[2-9]* )
 564         if [ x$NON_GNU_CPP = x ]; then
 565           if [ -f /usr/ccs/lib/cpp ]; then
 566             NON_GNU_CPP=/usr/ccs/lib/cpp
 567           else
 568             NON_GNU_CPP=/lib/cpp
 569           fi
 570         fi
 571         opsys=usg5-4-2 ;;
 572     *-sysv4* | *-sysvr4* )              opsys=usg5-4 ;;
 573     * )
 574       unported=yes
 575     ;;
 576   esac
 577 fi
 578
 579 ]
 580 dnl quotation ends
 581
 582 if test $unported = yes; then
 583   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
 584 Check `etc/MACHINES' for recognized configuration names.])
 585 fi
 586
 587 machfile="m/${machine}.h"
 588 opsysfile="s/${opsys}.h"
 589
 590
 591 #### Choose a compiler.
 592 test -n "$CC" && cc_specified=yes
 593
 594 # Save the value of CFLAGS that the user specified.
 595 SPECIFIED_CFLAGS="$CFLAGS"
 596
 597 dnl Sets GCC=yes if using gcc.
 598 AC_PROG_CC
 599
 600 # On Suns, sometimes $CPP names a directory.
 601 if test -n "$CPP" && test -d "$CPP"; then
 602   CPP=
 603 fi
 604
 605 ## If not using gcc, and on Solaris, and no CPP specified, see if
 606 ## using a Sun compiler, which needs -Xs to prevent whitespace.
 607 if test x"$GCC" != xyes && test x"$emacs_check_sunpro_c" = xyes && \
 608  test x"$CPP" = x; then
 609   AC_MSG_CHECKING([whether we are using a Sun C compiler])
 610   AC_CACHE_VAL(emacs_cv_sunpro_c,
 611   [AC_TRY_LINK([],
 612 [#ifndef __SUNPRO_C
 613 fail;
 614 #endif
 615 ], emacs_cv_sunpro_c=yes, emacs_cv_sunpro_c=no)])
 616   AC_MSG_RESULT($emacs_cv_sunpro_c)
 617
 618   if test x"$emacs_cv_sunpro_c" = xyes; then
 619     NON_GNU_CPP="$CC -E -Xs"
 620   fi
 621 fi
 622
 623 #### Some systems specify a CPP to use unless we are using GCC.
 624 #### Now that we know whether we are using GCC, we can decide whether
 625 #### to use that one.
 626 if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x
 627 then
 628   CPP="$NON_GNU_CPP"
 629 fi
 630
 631 #### Some systems specify a CC to use unless we are using GCC.
 632 #### Now that we know whether we are using GCC, we can decide whether
 633 #### to use that one.
 634 if test "x$NON_GNU_CC" != x && test x$GCC != xyes &&
 635   test x$cc_specified != xyes
 636 then
 637   CC="$NON_GNU_CC"
 638 fi
 639
 640 if test x$GCC = xyes && test "x$GCC_TEST_OPTIONS" != x
 641 then
 642   CC="$CC $GCC_TEST_OPTIONS"
 643 fi
 644
 645 if test x$GCC = x && test "x$NON_GCC_TEST_OPTIONS" != x
 646 then
 647   CC="$CC $NON_GCC_TEST_OPTIONS"
 648 fi
 649
 650 dnl checks for Unix variants
 651 AC_USE_SYSTEM_EXTENSIONS
 652
 653 ### Use -Wno-pointer-sign if the compiler supports it
 654 AC_MSG_CHECKING([whether gcc understands -Wno-pointer-sign])
 655 SAVE_CFLAGS="$CFLAGS"
 656 CFLAGS="$CFLAGS -Wno-pointer-sign"
 657 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 658 if test $has_option = yes; then
 659    C_WARNINGS_SWITCH="-Wno-pointer-sign $C_WARNINGS_SWITCH"
 660 fi
 661 AC_MSG_RESULT($has_option)
 662 CFLAGS="$SAVE_CFLAGS"
 663 unset has_option
 664 unset SAVE_CFLAGS
 665
 666 #### Some other nice autoconf tests.
 667
 668 dnl checks for programs
 669 AC_PROG_LN_S
 670 AC_PROG_CPP
 671 AC_PROG_INSTALL
 672 if test "x$RANLIB" = x; then
 673   AC_PROG_RANLIB
 674 fi
 675 AC_PATH_PROG(INSTALL_INFO, install-info)
 676 AC_PATH_PROG(INSTALL_INFO, install-info,, /usr/sbin)
 677 AC_PATH_PROG(INSTALL_INFO, install-info,:, /sbin)
 678 dnl Don't use GZIP, which is used by gzip for additional parameters.
 679 AC_PATH_PROG(GZIP_PROG, gzip)
 680
 681
 682 ## Need makeinfo >= 4.6 (?) to build the manuals.
 683 AC_PATH_PROG(MAKEINFO, makeinfo, no)
 684 dnl By this stage, configure has already checked for egrep and set EGREP,
 685 dnl or exited with an error if no egrep was found.
 686 if test "$MAKEINFO" != "no" && \
 687   test x"`$MAKEINFO --version 2> /dev/null | $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[6-9]]|4\.[[1-5]][[0-9]]+)'`" = x; then
 688    MAKEINFO=no
 689 fi
 690
 691 ## Makeinfo is unusual.  For a released Emacs, the manuals are
 692 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
 693 ## therefore in the category of "special tools" not normally required, which
 694 ## configure does not have to check for (eg autoconf itself).
 695 ## In a CVS checkout on the other hand, the manuals are not included.
 696 ## So makeinfo is a requirement to build from CVS, and configure
 697 ## should test for it as it does for any other build requirement.
 698 ## We use the presence of $srcdir/info/emacs to distinguish a release,
 699 ## with pre-built manuals, from a CVS checkout.
 700 if test "$MAKEINFO" = "no"; then
 701   if test "x${with_makeinfo}" = "xno"; then
 702     MAKEINFO=off
 703   elif ! test -e $srcdir/info/emacs; then
 704     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.6, and your
 705 source tree does not seem to have pre-built manuals in the `info' directory.
 706 Either install a suitable version of makeinfo, or re-run configure
 707 with the `--without-makeinfo' option to build without the manuals.] )
 708   fi
 709 fi
 710
 711 dnl Add our options to ac_link now, after it is set up.
 712
 713 if test x$GCC = xyes && test "x$GCC_LINK_TEST_OPTIONS" != x
 714 then
 715   ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
 716 fi
 717
 718 if test x$GCC = x && test "x$NON_GCC_LINK_TEST_OPTIONS" != x
 719 then
 720   ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
 721 fi
 722
 723 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
 724 dnl If we can link with the flag, it shouldn't do any harm anyhow.
 725 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
 726 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
 727 dnl if not built to support GNU ld.
 728
 729 late_LDFLAGS=$LDFLAGS
 730 if test "$GCC" = yes; then
 731   LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
 732 else
 733   LDFLAGS="$LDFLAGS -znocombreloc"
 734 fi
 735
 736 AC_MSG_CHECKING([for -znocombreloc])
 737 AC_LINK_IFELSE([main(){return 0;}],
 738   [AC_MSG_RESULT(yes)],
 739   LDFLAGS=$late_LDFLAGS
 740   [AC_MSG_RESULT(no)])
 741
 742 #### Extract some information from the operating system and machine files.
 743
 744 AC_CHECKING([the machine- and system-dependent files to find out
 745  - which libraries the lib-src programs will want, and
 746  - whether the GNU malloc routines are usable])
 747
 748 ### First figure out CFLAGS (which we use for running the compiler here)
 749 ### and REAL_CFLAGS (which we use for real compilation).
 750 ### The two are the same except on a few systems, where they are made
 751 ### different to work around various lossages.  For example,
 752 ### GCC 2.5 on GNU/Linux needs them to be different because it treats -g
 753 ### as implying static linking.
 754
 755 ### If the CFLAGS env var is specified, we use that value
 756 ### instead of the default.
 757
 758 ### It's not important that this name contain the PID; you can't run
 759 ### two configures in the same directory and have anything work
 760 ### anyway.
 761 tempcname="conftest.c"
 762
 763 echo '
 764 #include "'${srcdir}'/src/'${opsysfile}'"
 765 #include "'${srcdir}'/src/'${machfile}'"
 766 #ifndef LIBS_MACHINE
 767 #define LIBS_MACHINE
 768 #endif
 769 #ifndef LIBS_SYSTEM
 770 #define LIBS_SYSTEM
 771 #endif
 772 #ifndef C_SWITCH_SYSTEM
 773 #define C_SWITCH_SYSTEM
 774 #endif
 775 #ifndef C_SWITCH_MACHINE
 776 #define C_SWITCH_MACHINE
 777 #endif
 778 configure___ libsrc_libs=LIBS_MACHINE LIBS_SYSTEM
 779 configure___ c_switch_system=C_SWITCH_SYSTEM
 780 configure___ c_switch_machine=C_SWITCH_MACHINE
 781
 782 #ifndef LIB_X11_LIB
 783 #define LIB_X11_LIB -lX11
 784 #endif
 785
 786 #ifndef LIBX11_SYSTEM
 787 #define LIBX11_SYSTEM
 788 #endif
 789 configure___ LIBX=LIB_X11_LIB LIBX11_SYSTEM
 790
 791 #ifdef UNEXEC
 792 configure___ unexec=UNEXEC
 793 #else
 794 configure___ unexec=unexec.o
 795 #endif
 796
 797 #ifdef SYSTEM_MALLOC
 798 configure___ system_malloc=yes
 799 #else
 800 configure___ system_malloc=no
 801 #endif
 802
 803 #ifdef USE_MMAP_FOR_BUFFERS
 804 configure___ use_mmap_for_buffers=yes
 805 #else
 806 configure___ use_mmap_for_buffers=no
 807 #endif
 808
 809 #ifndef C_DEBUG_SWITCH
 810 #define C_DEBUG_SWITCH -g
 811 #endif
 812
 813 #ifndef C_OPTIMIZE_SWITCH
 814 #ifdef __GNUC__
 815 #define C_OPTIMIZE_SWITCH -O2
 816 #else
 817 #define C_OPTIMIZE_SWITCH -O
 818 #endif
 819 #endif
 820
 821 #ifndef C_WARNINGS_SWITCH
 822 #define C_WARNINGS_SWITCH ${C_WARNINGS_SWITCH}
 823 #endif
 824
 825 #ifndef LD_SWITCH_MACHINE
 826 #define LD_SWITCH_MACHINE
 827 #endif
 828
 829 #ifndef LD_SWITCH_SYSTEM
 830 #define LD_SWITCH_SYSTEM
 831 #endif
 832
 833 #ifndef LD_SWITCH_X_SITE_AUX
 834 #define LD_SWITCH_X_SITE_AUX
 835 #endif
 836
 837 configure___ ld_switch_system=LD_SWITCH_SYSTEM
 838 configure___ ld_switch_machine=LD_SWITCH_MACHINE
 839
 840 #ifdef THIS_IS_CONFIGURE
 841
 842 /* Get the CFLAGS for tests in configure.  */
 843 #ifdef __GNUC__
 844 configure___ CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH '${SPECIFIED_CFLAGS}'
 845 #else
 846 configure___ CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
 847 #endif
 848
 849 #else /* not THIS_IS_CONFIGURE */
 850
 851 /* Get the CFLAGS for real compilation.  */
 852 #ifdef __GNUC__
 853 configure___ REAL_CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH C_WARNINGS_SWITCH '${SPECIFIED_CFLAGS}'
 854 #else
 855 configure___ REAL_CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
 856 #endif
 857
 858 #endif /* not THIS_IS_CONFIGURE */
 859 ' > ${tempcname}
 860
 861 # The value of CPP is a quoted variable reference, so we need to do this
 862 # to get its actual value...
 863 CPP=`eval "echo $CPP"`
 864 [eval `${CPP} -Isrc ${tempcname} \
 865        | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
 866 if test "x$SPECIFIED_CFLAGS" = x; then
 867   eval `${CPP} -Isrc -DTHIS_IS_CONFIGURE ${tempcname} \
 868          | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
 869 else
 870   REAL_CFLAGS="$CFLAGS"
 871 fi]
 872 rm ${tempcname}
 873
 874 ac_link="$ac_link $ld_switch_machine $ld_switch_system"
 875
 876 ### Make sure subsequent tests use flags consistent with the build flags.
 877
 878 if test x"${OVERRIDE_CPPFLAGS}" != x; then
 879   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
 880 else
 881   CPPFLAGS="$c_switch_system $c_switch_machine $CPPFLAGS"
 882 fi
 883
 884 dnl For AC_FUNC_GETLOADAVG, at least:
 885 AC_CONFIG_LIBOBJ_DIR(src)
 886
 887 dnl Do this early because it can frob feature test macros for Unix-98 &c.
 888 AC_SYS_LARGEFILE
 889
 890
 891 ### The standard library on x86-64 and s390x GNU/Linux distributions can
 892 ### be located in either /usr/lib64 or /usr/lib.
 893 case "${canonical}" in
 894   x86_64-*-linux-gnu* | s390x-*-linux-gnu* )
 895     if test -d /usr/lib64; then
 896       AC_DEFINE(HAVE_LIB64_DIR, 1,
 897         [Define to 1 if the directory /usr/lib64 exists.])
 898 fi
 899 esac
 900
 901 dnl This function defintion taken from Gnome 2.0
 902 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
 903 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
 904 dnl also defines GSTUFF_PKG_ERRORS on error
 905 AC_DEFUN([PKG_CHECK_MODULES], [
 906   succeeded=no
 907
 908   AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
 909
 910   if test "$PKG_CONFIG" = "no" ; then
 911      ifelse([$4], , [AC_MSG_ERROR([
 912       *** The pkg-config script could not be found. Make sure it is in your path, or give the full path to pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
 913   else
 914      PKG_CONFIG_MIN_VERSION=0.9.0
 915      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
 916         AC_MSG_CHECKING(for $2)
 917
 918         if $PKG_CONFIG --exists "$2" 2>&AS_MESSAGE_LOG_FD; then
 919             AC_MSG_RESULT(yes)
 920             succeeded=yes
 921
 922             AC_MSG_CHECKING($1_CFLAGS)
 923             $1_CFLAGS=`$PKG_CONFIG --cflags "$2"|sed -e 's,///*,/,g'`
 924             AC_MSG_RESULT($$1_CFLAGS)
 925
 926             AC_MSG_CHECKING($1_LIBS)
 927             $1_LIBS=`$PKG_CONFIG --libs "$2"|sed -e 's,///*,/,g'`
 928             AC_MSG_RESULT($$1_LIBS)
 929         else
 930             AC_MSG_RESULT(no)
 931             $1_CFLAGS=""
 932             $1_LIBS=""
 933             ## If we have a custom action on failure, don't print errors, but
 934             ## do set a variable so people can do so.
 935             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
 936             ifelse([$4], ,echo $$1_PKG_ERRORS,)
 937         fi
 938
 939         AC_SUBST($1_CFLAGS)
 940         AC_SUBST($1_LIBS)
 941      else
 942         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
 943         echo "*** See http://www.freedesktop.org/software/pkgconfig"
 944      fi
 945   fi
 946
 947   if test $succeeded = yes; then
 948      ifelse([$3], , :, [$3])
 949   else
 950      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
 951   fi
 952 ])
 953
 954
 955 if test "${with_sound}" != "no"; then
 956   # Sound support for GNU/Linux and the free BSDs.
 957   AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h)
 958   # Emulation library used on NetBSD.
 959   AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
 960   AC_SUBST(LIBSOUND)
 961
 962   ALSA_REQUIRED=1.0.0
 963   ALSA_MODULES="alsa >= $ALSA_REQUIRED"
 964   PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
 965   if test $HAVE_ALSA = yes; then
 966     SAVE_CFLAGS="$CFLAGS"
 967     SAVE_LDFLAGS="$LDFLAGS"
 968     CFLAGS="$ALSA_CFLAGS $CFLAGS"
 969     LDFLAGS="$ALSA_LIBS $LDFLAGS"
 970     AC_TRY_COMPILE([#include <asoundlib.h>], [snd_lib_error_set_handler (0);],
 971                     emacs_alsa_normal=yes,
 972                     emacs_alsa_normal=no)
 973     if test "$emacs_alsa_normal" != yes; then
 974       AC_TRY_COMPILE([#include <alsa/asoundlib.h>],
 975                      [snd_lib_error_set_handler (0);],
 976                      emacs_alsa_subdir=yes,
 977                      emacs_alsa_subdir=no)
 978       if test "$emacs_alsa_subdir" != yes; then
 979         AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
 980       fi
 981       ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
 982     fi
 983
 984     CFLAGS="$SAVE_CFLAGS"
 985     LDFLAGS="$SAVE_LDFLAGS"
 986     LIBSOUND="$LIBSOUND $ALSA_LIBS"
 987     CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
 988     AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
 989   fi
 990   AC_SUBST(CFLAGS_SOUND)
 991 fi
 992
 993 dnl checks for header files
 994 AC_CHECK_HEADERS(sys/select.h sys/timeb.h sys/time.h unistd.h utime.h \
 995   linux/version.h sys/systeminfo.h termios.h limits.h string.h stdlib.h \
 996   termcap.h stdio_ext.h fcntl.h strings.h coff.h pty.h sys/mman.h \
 997   sys/param.h sys/vlimit.h sys/resource.h locale.h sys/_mbstate_t.h \
 998   sys/utsname.h pwd.h)
 999
1000 AC_MSG_CHECKING(if personality LINUX32 can be set)
1001 AC_TRY_COMPILE([#include <sys/personality.h>], [personality (PER_LINUX32)],
1002                emacs_cv_personality_linux32=yes,
1003                emacs_cv_personality_linux32=no)
1004 AC_MSG_RESULT($emacs_cv_personality_linux32)
1005
1006 if test $emacs_cv_personality_linux32 = yes; then
1007   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1008             [Define to 1 if personality LINUX32 can be set.])
1009 fi
1010
1011 dnl On Solaris 8 there's a compilation warning for term.h because
1012 dnl it doesn't define `bool'.
1013 AC_CHECK_HEADERS(term.h, , , -)
1014 AC_HEADER_STDC
1015 AC_HEADER_TIME
1016 AC_CHECK_DECLS([sys_siglist])
1017 if test $ac_cv_have_decl_sys_siglist != yes; then
1018   # For Tru64, at least:
1019   AC_CHECK_DECLS([__sys_siglist])
1020   if test $ac_cv_have_decl___sys_siglist = yes; then
1021     AC_DEFINE(sys_siglist, __sys_siglist,
1022               [Define to any substitute for sys_siglist.])
1023   fi
1024 fi
1025 AC_HEADER_SYS_WAIT
1026
1027 dnl Some systems have utime.h but don't declare the struct anyplace.
1028 AC_CACHE_CHECK(for struct utimbuf, emacs_cv_struct_utimbuf,
1029 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1030 #include <sys/time.h>
1031 #include <time.h>
1032 #else
1033 #ifdef HAVE_SYS_TIME_H
1034 #include <sys/time.h>
1035 #else
1036 #include <time.h>
1037 #endif
1038 #endif
1039 #ifdef HAVE_UTIME_H
1040 #include <utime.h>
1041 #endif], [static struct utimbuf x; x.actime = x.modtime;],
1042   emacs_cv_struct_utimbuf=yes, emacs_cv_struct_utimbuf=no))
1043 if test $emacs_cv_struct_utimbuf = yes; then
1044   AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if `struct utimbuf' is declared by <utime.h>.])
1045 fi
1046
1047 dnl checks for typedefs
1048 AC_TYPE_SIGNAL
1049
1050 dnl Check for speed_t typedef.
1051 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1052   [AC_TRY_COMPILE([#include <termios.h>], [speed_t x = 1;],
1053     emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1054 if test $emacs_cv_speed_t = yes; then
1055   AC_DEFINE(HAVE_SPEED_T, 1,
1056            [Define to 1 if `speed_t' is declared by <termios.h>.])
1057 fi
1058
1059 AC_CACHE_CHECK(for struct timeval, emacs_cv_struct_timeval,
1060 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1061 #include <sys/time.h>
1062 #include <time.h>
1063 #else
1064 #ifdef HAVE_SYS_TIME_H
1065 #include <sys/time.h>
1066 #else
1067 #include <time.h>
1068 #endif
1069 #endif], [static struct timeval x; x.tv_sec = x.tv_usec;],
1070   emacs_cv_struct_timeval=yes, emacs_cv_struct_timeval=no))
1071 HAVE_TIMEVAL=$emacs_cv_struct_timeval
1072 if test $emacs_cv_struct_timeval = yes; then
1073   AC_DEFINE(HAVE_TIMEVAL, 1, [Define to 1 if `struct timeval' is declared by <sys/time.h>.])
1074 fi
1075
1076 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1077 AC_TRY_COMPILE([#include <math.h>],
1078 [static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;],
1079   emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1080 HAVE_EXCEPTION=$emacs_cv_struct_exception
1081 if test $emacs_cv_struct_exception != yes; then
1082   AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1083 fi
1084
1085 AC_CHECK_HEADERS(sys/socket.h)
1086 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1087 #if HAVE_SYS_SOCKET_H
1088 #include <sys/socket.h>
1089 #endif])
1090
1091 dnl checks for structure members
1092 AC_STRUCT_TM
1093 AC_STRUCT_TIMEZONE
1094 AC_CHECK_MEMBER(struct tm.tm_gmtoff,
1095                 [AC_DEFINE(HAVE_TM_GMTOFF, 1,
1096                            [Define to 1 if `tm_gmtoff' is member of `struct tm'.])],,
1097                 [#include <time.h>])
1098 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1099                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1100                   struct ifreq.ifr_addr], , ,
1101                  [AC_INCLUDES_DEFAULT
1102 #if HAVE_SYS_SOCKET_H
1103 #include <sys/socket.h>
1104 #endif
1105 #if HAVE_NET_IF_H
1106 #include <net/if.h>
1107 #endif])
1108
1109 dnl checks for compiler characteristics
1110
1111 dnl Testing __STDC__ to determine prototype support isn't good enough.
1112 dnl DEC C, for instance, doesn't define it with default options, and
1113 dnl is used on 64-bit systems (OSF Alphas).  Similarly for volatile
1114 dnl and void *.
1115 AC_C_PROTOTYPES
1116 AC_C_VOLATILE
1117 AC_C_CONST
1118 dnl This isn't useful because we can't turn on use of `inline' unless
1119 dnl the compiler groks `extern inline'.
1120 dnl AC_C_INLINE
1121 AC_CACHE_CHECK([for void * support], emacs_cv_void_star,
1122   [AC_TRY_COMPILE(, [void * foo;],
1123                    emacs_cv_void_star=yes, emacs_cv_void_star=no)])
1124 if test $emacs_cv_void_star = yes; then
1125   AC_DEFINE(POINTER_TYPE, void)
1126 else
1127   AC_DEFINE(POINTER_TYPE, char)
1128 fi
1129 AH_TEMPLATE(POINTER_TYPE,
1130             [Define as `void' if your compiler accepts `void *'; otherwise
1131              define as `char'.])dnl
1132
1133
1134
1135 dnl This could be used for targets which can have both byte sexes.
1136 dnl We could presumably replace the hardwired WORDS_BIG_ENDIAN generally.
1137 dnl AC_C_BIGENDIAN
1138
1139 dnl check for Make feature
1140 AC_PROG_MAKE_SET
1141
1142 dnl checks for operating system services
1143 AC_SYS_LONG_FILE_NAMES
1144
1145 #### Choose a window system.
1146
1147 AC_PATH_X
1148 if test "$no_x" = yes; then
1149   window_system=none
1150 else
1151   window_system=x11
1152 fi
1153
1154 ## Workaround for bug in autoconf <= 2.62.
1155 ## http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01551.html
1156 ## No need to do anything special for these standard directories.
1157 ## This is an experiment, take it out if it causes problems.
1158 if test -n "${x_libraries}" && test x"${x_libraries}" != xNONE; then
1159
1160    x_libraries=`echo :${x_libraries}: | sed -e 's|:/usr/lib64:|:|g' -e 's|:/lib64:|:|g' -e 's|^:||' -e 's|:$||'`
1161
1162 fi
1163
1164 if test "${x_libraries}" != NONE; then
1165   if test -n "${x_libraries}"; then
1166     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1167     LD_SWITCH_X_SITE_AUX=-R`echo ${x_libraries} | sed -e "s/:/ -R/g"`
1168   fi
1169   x_default_search_path=""
1170   x_search_path=${x_libraries}
1171   if test -z "${x_search_path}"; then
1172     x_search_path=/usr/lib
1173   fi
1174   for x_library in `echo ${x_search_path}: | \
1175                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1176     x_search_path="\
1177 ${x_library}/X11/%L/%T/%N%C%S:\
1178 ${x_library}/X11/%l/%T/%N%C%S:\
1179 ${x_library}/X11/%T/%N%C%S:\
1180 ${x_library}/X11/%L/%T/%N%S:\
1181 ${x_library}/X11/%l/%T/%N%S:\
1182 ${x_library}/X11/%T/%N%S"
1183     if test x"${x_default_search_path}" = x; then
1184       x_default_search_path=${x_search_path}
1185     else
1186       x_default_search_path="${x_search_path}:${x_default_search_path}"
1187     fi
1188   done
1189 fi
1190 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1191   C_SWITCH_X_SITE=-I`echo ${x_includes} | sed -e "s/:/ -I/g"`
1192 fi
1193
1194 if test x"${x_includes}" = x; then
1195   bitmapdir=/usr/include/X11/bitmaps
1196 else
1197   # accumulate include directories that have X11 bitmap subdirectories
1198   bmd_acc="dummyval"
1199   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1200     if test -d "${bmd}/X11/bitmaps"; then
1201       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1202     fi
1203     if test -d "${bmd}/bitmaps"; then
1204       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1205     fi
1206   done
1207   if test ${bmd_acc} != "dummyval"; then
1208     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1209   fi
1210 fi
1211
1212 HAVE_NS=no
1213 NS_IMPL_COCOA=no
1214 NS_IMPL_GNUSTEP=no
1215 tmp_CPPFLAGS="$CPPFLAGS"
1216 tmp_CFLAGS="$CFLAGS"
1217 CPPFLAGS="$CPPFLAGS -x objective-c"
1218 CFLAGS="$CFLAGS -x objective-c"
1219 if test "${with_ns}" != no; then
1220   if test "${opsys}" = darwin; then
1221      NS_IMPL_COCOA=yes
1222      ns_appdir=`pwd`/nextstep/Emacs.app
1223      ns_appbindir=`pwd`/nextstep/Emacs.app/Contents/MacOS
1224      ns_appresdir=`pwd`/nextstep/Emacs.app/Contents/Resources
1225      ns_appsrc=${srcdir}/nextstep/Cocoa/Emacs.base
1226   elif test -f /etc/GNUstep/GNUstep.conf; then
1227      NS_IMPL_GNUSTEP=yes
1228      ns_appdir=`pwd`/nextstep/Emacs.app
1229      ns_appbindir=`pwd`/nextstep/Emacs.app
1230      ns_appresdir=`pwd`/nextstep/Emacs.app/Resources
1231      ns_appsrc=${srcdir}/nextstep/GNUstep/Emacs.base
1232      GNUSTEP_MAKEFILES="$(source /etc/GNUstep/GNUstep.conf; echo $GNUSTEP_MAKEFILES)"
1233      GNUSTEP_SYSTEM_HEADERS="$(source /etc/GNUstep/GNUstep.conf; echo $GNUSTEP_SYSTEM_HEADERS)"
1234      GNUSTEP_SYSTEM_LIBRARIES="$(source /etc/GNUstep/GNUstep.conf; echo $GNUSTEP_SYSTEM_LIBRARIES)"
1235      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS}"
1236      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS}"
1237      REAL_CFLAGS="$REAL_CFLAGS -I${GNUSTEP_SYSTEM_HEADERS}"
1238      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES}"
1239   fi
1240   AC_CHECK_HEADER(AppKit/AppKit.h, HAVE_NS=yes)
1241   NS_HAVE_NSINTEGER=yes
1242   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <Foundation/NSObjCRuntime.h>],
1243                                      [NSInteger i;])],
1244                     ns_have_nsinteger=yes,
1245                     ns_have_nsinteger=no)
1246   if test $ns_have_nsinteger = no; then
1247     NS_HAVE_NSINTEGER=no
1248   fi
1249 fi
1250 if test "${HAVE_NS}" = yes; then
1251   window_system=nextstep
1252   with_xft=no
1253   with_freetype=no
1254   # set up packaging dirs
1255   exec_prefix=${ns_appbindir}
1256   libexecdir=${ns_appbindir}/libexec
1257   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1258      prefix=${ns_appresdir}
1259   fi
1260 fi
1261 CFLAGS="$tmp_CFLAGS"
1262 CPPFLAGS="$tmp_CPPFLAGS"
1263
1264 case "${window_system}" in
1265   x11 )
1266     HAVE_X_WINDOWS=yes
1267     HAVE_X11=yes
1268     case "${with_x_toolkit}" in
1269       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1270       motif ) USE_X_TOOLKIT=MOTIF ;;
1271       gtk ) with_gtk=yes
1272 dnl Dont set this for GTK.  A lot of tests below assumes Xt when
1273 dnl USE_X_TOOLKIT is set.
1274             USE_X_TOOLKIT=none ;;
1275       no ) USE_X_TOOLKIT=none ;;
1276 dnl If user did not say whether to use a toolkit, make this decision later:
1277 dnl use the toolkit if we have gtk, or X11R5 or newer.
1278       * ) USE_X_TOOLKIT=maybe ;;
1279     esac
1280   ;;
1281   nextstep | none )
1282     HAVE_X_WINDOWS=no
1283     HAVE_X11=no
1284     USE_X_TOOLKIT=none
1285   ;;
1286 esac
1287
1288 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1289    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1290    if test "$HAVE_XSERVER" = true ||
1291       test -n "$DISPLAY" ||
1292       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1293         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1294 were found.  You should install the relevant development files for X
1295 and for the toolkit you want, such as Gtk+, Lesstif or Motif.  Also make
1296 sure you have development files for image handling, i.e.
1297 tiff, gif, jpeg, png and xpm.
1298 If you are sure you want Emacs compiled without X window support, pass
1299   --without-x
1300 to configure.])
1301    fi
1302 fi
1303
1304 ### If we're using X11, we should use the X menu package.
1305 HAVE_MENUS=no
1306 case ${HAVE_X11} in
1307   yes ) HAVE_MENUS=yes ;;
1308 esac
1309
1310 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1311 # Assume not, until told otherwise.
1312 GNU_MALLOC=yes
1313 doug_lea_malloc=yes
1314 AC_CHECK_FUNC(malloc_get_state, ,doug_lea_malloc=no)
1315 AC_CHECK_FUNC(malloc_set_state, ,doug_lea_malloc=no)
1316 AC_CACHE_CHECK(whether __after_morecore_hook exists,
1317                emacs_cv_var___after_morecore_hook,
1318 [AC_TRY_LINK([extern void (* __after_morecore_hook)();],[__after_morecore_hook = 0],
1319   emacs_cv_var___after_morecore_hook=yes,
1320   emacs_cv_var___after_morecore_hook=no)])
1321 if test $emacs_cv_var___after_morecore_hook = no; then
1322   doug_lea_malloc=no
1323 fi
1324 if test "${system_malloc}" = "yes"; then
1325   GNU_MALLOC=no
1326   GNU_MALLOC_reason="
1327     (The GNU allocators don't work with this system configuration.)"
1328 fi
1329 if test "$doug_lea_malloc" = "yes" ; then
1330   if test "$GNU_MALLOC" = yes ; then
1331     GNU_MALLOC_reason="
1332       (Using Doug Lea's new malloc from the GNU C Library.)"
1333   fi
1334   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1335             [Define to 1 if you are using the GNU C Library.])
1336 fi
1337
1338 if test x"${REL_ALLOC}" = x; then
1339   REL_ALLOC=${GNU_MALLOC}
1340 fi
1341
1342 dnl For now, need to use an explicit `#define USE_MMAP_FOR_BUFFERS 1'
1343 dnl the system configuration file (s/*.h) to turn the use of mmap
1344 dnl in the relocating allocator on.
1345
1346 AC_FUNC_MMAP
1347 if test $use_mmap_for_buffers = yes; then
1348   REL_ALLOC=no
1349 fi
1350
1351 LIBS="$libsrc_libs $LIBS"
1352
1353 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1354 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1355 AC_CHECK_LIB(dnet, dnet_ntoa)
1356 dnl This causes -lresolv to get used in subsequent tests,
1357 dnl which causes failures on some systems such as HPUX 9.
1358 dnl AC_CHECK_LIB(resolv, gethostbyname)
1359
1360 dnl FIXME replace main with a function we actually want from this library.
1361 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1362
1363 AC_CHECK_LIB(pthreads, cma_open)
1364
1365 dnl Check for need for bigtoc support on IBM AIX
1366
1367 case ${host_os} in
1368 aix*)
1369   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1370     case $GCC in
1371     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1372     *) gdb_cv_bigtoc=-bbigtoc ;;
1373     esac
1374
1375     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1376     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1377   ])
1378   ;;
1379 esac
1380
1381 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1382 # used for the tests that follow.  We set them back to REAL_CFLAGS and
1383 # REAL_CPPFLAGS later on.
1384
1385 REAL_CPPFLAGS="$CPPFLAGS"
1386
1387 if test "${HAVE_X11}" = "yes"; then
1388   DEFS="$C_SWITCH_X_SITE $DEFS"
1389   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1390   LIBS="$LIBX $LIBS"
1391   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1392   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1393
1394   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1395   # This is handled by LD_SWITCH_X_SITE_AUX during the real build,
1396   # but it's more convenient here to set LD_RUN_PATH
1397   # since this also works on hosts that don't understand LD_SWITCH_X_SITE_AUX.
1398   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1399     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1400     export LD_RUN_PATH
1401   fi
1402
1403   if test "${opsys}" = "gnu-linux"; then
1404     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1405     AC_TRY_LINK([],
1406      [XOpenDisplay ("foo");],
1407      [xlinux_first_failure=no],
1408      [xlinux_first_failure=yes])
1409     if test "${xlinux_first_failure}" = "yes"; then
1410       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1411       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1412       OLD_CPPFLAGS="$CPPFLAGS"
1413       OLD_LIBS="$LIBS"
1414       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1415       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1416       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1417       LIBS="$LIBS -b i486-linuxaout"
1418       AC_TRY_LINK([],
1419        [XOpenDisplay ("foo");],
1420        [xlinux_second_failure=no],
1421        [xlinux_second_failure=yes])
1422       if test "${xlinux_second_failure}" = "yes"; then
1423         # If we get the same failure with -b, there is no use adding -b.
1424         # So take it out.  This plays safe.
1425         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1426         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1427         CPPFLAGS="$OLD_CPPFLAGS"
1428         LIBS="$OLD_LIBS"
1429         AC_MSG_RESULT(no)
1430       else
1431         AC_MSG_RESULT(yes)
1432       fi
1433     else
1434       AC_MSG_RESULT(no)
1435     fi
1436   fi
1437
1438   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1439   # header files included from there.
1440   AC_MSG_CHECKING(for Xkb)
1441   AC_TRY_LINK([#include <X11/Xlib.h>
1442 #include <X11/XKBlib.h>],
1443         [XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);],
1444         emacs_xkb=yes, emacs_xkb=no)
1445   AC_MSG_RESULT($emacs_xkb)
1446   if test $emacs_xkb = yes; then
1447     AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1448   fi
1449
1450   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1451 XScreenNumberOfScreen XSetWMProtocols)
1452 fi
1453
1454 if test "${window_system}" = "x11"; then
1455   AC_MSG_CHECKING(X11 version 6)
1456   AC_CACHE_VAL(emacs_cv_x11_version_6,
1457   [AC_TRY_LINK([#include <X11/Xlib.h>],
1458 [#if XlibSpecificationRelease < 6
1459 fail;
1460 #endif
1461 ], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1462   if test $emacs_cv_x11_version_6 = yes; then
1463     AC_MSG_RESULT(6 or newer)
1464     AC_DEFINE(HAVE_X11R6, 1,
1465               [Define to 1 if you have the X11R6 or newer version of Xlib.])
1466   else
1467     AC_MSG_RESULT(before 6)
1468   fi
1469 fi
1470
1471
1472 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
1473 HAVE_RSVG=no
1474 if test "${HAVE_X11}" = "yes"; then
1475   if test "${with_rsvg}" != "no"; then
1476     RSVG_REQUIRED=2.0.0
1477     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
1478
1479     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, :, :)
1480     AC_SUBST(RSVG_CFLAGS)
1481     AC_SUBST(RSVG_LIBS)
1482
1483     if test ".${RSVG_CFLAGS}" != "."; then
1484       HAVE_RSVG=yes
1485       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
1486       CFLAGS="$CFLAGS $RSVG_CFLAGS"
1487       LIBS="$RSVG_LIBS $LIBS"
1488     fi
1489   fi
1490 fi
1491
1492
1493 HAVE_GTK=no
1494 if test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
1495   GLIB_REQUIRED=2.6
1496   GTK_REQUIRED=2.6
1497   GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1498
1499   dnl Checks for libraries.
1500   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1501   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1502      AC_MSG_ERROR($GTK_PKG_ERRORS)
1503   fi
1504 fi
1505
1506
1507 if test x"$pkg_check_gtk" = xyes; then
1508
1509   AC_SUBST(GTK_CFLAGS)
1510   AC_SUBST(GTK_LIBS)
1511   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
1512   CFLAGS="$CFLAGS $GTK_CFLAGS"
1513   LIBS="$GTK_LIBS $LIBS"
1514   dnl Try to compile a simple GTK program.
1515   GTK_COMPILES=no
1516   AC_CHECK_FUNCS(gtk_main, GTK_COMPILES=yes)
1517   if test "${GTK_COMPILES}" != "yes"; then
1518     if test "$USE_X_TOOLKIT" != "maybe"; then
1519       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
1520     fi
1521   else
1522     HAVE_GTK=yes
1523     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
1524     USE_X_TOOLKIT=none
1525     if $PKG_CONFIG --atleast-version=2.10 gtk+-2.0; then
1526       :
1527     else
1528       AC_MSG_WARN([[Your version of Gtk+ will have problems with
1529        closing open displays.  This is no problem if you just use
1530        one display, but if you use more than one and close one of them
1531        Emacs may crash.]])
1532       sleep 3
1533     fi
1534   fi
1535
1536 fi
1537
1538
1539 if test "${HAVE_GTK}" = "yes"; then
1540
1541   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
1542   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
1543   if test "$with_toolkit_scroll_bars" != no; then
1544     with_toolkit_scroll_bars=yes
1545   fi
1546
1547   dnl  Check if we can use multiple displays with this GTK version.
1548   dnl  If gdk_display_open exists, assume all others are there also.
1549   HAVE_GTK_MULTIDISPLAY=no
1550   AC_CHECK_FUNCS(gdk_display_open, HAVE_GTK_MULTIDISPLAY=yes)
1551   if test "${HAVE_GTK_MULTIDISPLAY}" = "yes"; then
1552     AC_DEFINE(HAVE_GTK_MULTIDISPLAY, 1,
1553               [Define to 1 if GTK can handle more than one display.])
1554   fi
1555
1556   dnl  Check if we have the old file selection dialog.
1557   dnl  If gdk_display_open exists, assume all others are there also.
1558   HAVE_GTK_FILE_SELECTION=no
1559   AC_CHECK_FUNCS(gtk_file_selection_new, HAVE_GTK_FILE_SELECTION=yes)
1560
1561   dnl  Check if we have the new file chooser dialog
1562   dnl  If gdk_display_open exists, assume all others are there also.
1563   HAVE_GTK_FILE_CHOOSER=no
1564   AC_CHECK_FUNCS(gtk_file_chooser_dialog_new, HAVE_GTK_FILE_CHOOSER=yes)
1565
1566   if test "$HAVE_GTK_FILE_SELECTION" = yes \
1567      && test "$HAVE_GTK_FILE_CHOOSER" = yes;  then
1568     AC_DEFINE(HAVE_GTK_FILE_BOTH, 1,
1569               [Define to 1 if GTK has both file selection and chooser dialog.])
1570   fi
1571
1572   dnl Check if pthreads are available.  Emacs only needs this when using
1573   dnl gtk_file_chooser under Gnome.
1574   if test "$HAVE_GTK_FILE_CHOOSER" = yes; then
1575     HAVE_GTK_AND_PTHREAD=no
1576     AC_CHECK_HEADERS(pthread.h)
1577     if test "$ac_cv_header_pthread_h"; then
1578       AC_CHECK_LIB(pthread, pthread_self, HAVE_GTK_AND_PTHREAD=yes)
1579     fi
1580     if test "$HAVE_GTK_AND_PTHREAD" = yes; then
1581       case "${canonical}" in
1582         *-hpux*) ;;
1583         *) GTK_LIBS="$GTK_LIBS -lpthread" ;;
1584       esac
1585       AC_DEFINE(HAVE_GTK_AND_PTHREAD, 1,
1586                [Define to 1 if you have GTK and pthread (-lpthread).])
1587     fi
1588   fi
1589 fi
1590
1591 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
1592 dnl other platforms.  Support for higher D-Bus versions than 1.0 is
1593 dnl also not configured.
1594 HAVE_DBUS=no
1595 if test "${with_dbus}" = "yes"; then
1596    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
1597    if test "$HAVE_DBUS" = yes; then
1598       AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
1599    fi
1600 fi
1601
1602 dnl Do not put whitespace before the #include statements below.
1603 dnl Older compilers (eg sunos4 cc) choke on it.
1604 HAVE_XAW3D=no
1605 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
1606   if test "$with_xaw3d" != no; then
1607     AC_MSG_CHECKING(for xaw3d)
1608     AC_CACHE_VAL(emacs_cv_xaw3d,
1609     [AC_TRY_LINK([
1610 #include <X11/Intrinsic.h>
1611 #include <X11/Xaw3d/Simple.h>],
1612       [],
1613       emacs_cv_xaw3d=yes,
1614       emacs_cv_xaw3d=no)])
1615   else
1616     emacs_cv_xaw3d=no
1617   fi
1618   if test $emacs_cv_xaw3d = yes; then
1619     AC_MSG_RESULT([yes; using Lucid toolkit])
1620     USE_X_TOOLKIT=LUCID
1621     HAVE_XAW3D=yes
1622     AC_DEFINE(HAVE_XAW3D, 1,
1623               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
1624   else
1625     AC_MSG_RESULT(no)
1626     AC_MSG_CHECKING(for libXaw)
1627     AC_CACHE_VAL(emacs_cv_xaw,
1628     [AC_TRY_LINK([
1629 #include <X11/Intrinsic.h>
1630 #include <X11/Xaw/Simple.h>],
1631       [],
1632       emacs_cv_xaw=yes,
1633       emacs_cv_xaw=no)])
1634     if test $emacs_cv_xaw = yes; then
1635       AC_MSG_RESULT([yes; using Lucid toolkit])
1636       USE_X_TOOLKIT=LUCID
1637     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
1638       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
1639     else
1640       AC_MSG_RESULT([no; do not use toolkit by default])
1641       USE_X_TOOLKIT=none
1642     fi
1643   fi
1644 fi
1645
1646 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
1647
1648 if test "${USE_X_TOOLKIT}" != "none"; then
1649   AC_MSG_CHECKING(X11 toolkit version)
1650   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
1651   [AC_TRY_LINK([#include <X11/Intrinsic.h>],
1652 [#if XtSpecificationRelease < 6
1653 fail;
1654 #endif
1655 ], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
1656   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
1657   if test $emacs_cv_x11_toolkit_version_6 = yes; then
1658     AC_MSG_RESULT(6 or newer)
1659     AC_DEFINE(HAVE_X11XTR6, 1,
1660               [Define to 1 if you have the X11R6 or newer version of Xt.])
1661   else
1662     AC_MSG_RESULT(before 6)
1663   fi
1664
1665 dnl If using toolkit, check whether libXmu.a exists.
1666 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
1667   OLDLIBS="$LIBS"
1668   if test x$HAVE_X11XTR6 = xyes; then
1669     LIBS="-lXt -lSM -lICE $LIBS"
1670   else
1671     LIBS="-lXt $LIBS"
1672   fi
1673   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
1674   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
1675 fi
1676
1677 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
1678 if test "${HAVE_X11}" = "yes"; then
1679   if test "${USE_X_TOOLKIT}" != "none"; then
1680     AC_CHECK_LIB(Xext, XShapeQueryExtension)
1681   fi
1682 fi
1683
1684 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
1685   AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
1686   [AC_TRY_COMPILE([#include <Xm/Xm.h>],
1687     [#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
1688 int x = 5;
1689 #else
1690 Motif version prior to 2.1.
1691 #endif],
1692     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
1693   HAVE_MOTIF_2_1=$emacs_cv_motif_version_2_1
1694   if test $emacs_cv_motif_version_2_1 = yes; then
1695     HAVE_LIBXP=no
1696     AC_DEFINE(HAVE_MOTIF_2_1, 1,
1697               [Define to 1 if you have Motif 2.1 or newer.])
1698     AC_CHECK_LIB(Xp, XpCreateContext, HAVE_LIBXP=yes)
1699     if test ${HAVE_LIBXP} = yes; then
1700       AC_DEFINE(HAVE_LIBXP, 1,
1701                 [Define to 1 if you have the Xp library (-lXp).])
1702     fi
1703   else
1704     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
1705     # We put this in CFLAGS temporarily to precede other -I options
1706     # that might be in CFLAGS temporarily.
1707     # We put this in CPPFLAGS where it precedes the other -I options.
1708     OLD_CPPFLAGS=$CPPFLAGS
1709     OLD_CFLAGS=$CFLAGS
1710     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
1711     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
1712     [AC_TRY_COMPILE([#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>],
1713       [int x = 5;],
1714       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
1715     if test $emacs_cv_lesstif = yes; then
1716       # Make sure this -I option remains in CPPFLAGS after it is set
1717       # back to REAL_CPPFLAGS.
1718       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
1719       # have those other -I options anyway.  Ultimately, having this
1720       # directory ultimately in CPPFLAGS will be enough.
1721       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
1722       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
1723     else
1724       CFLAGS=$OLD_CFLAGS
1725       CPPFLAGS=$OLD_CPPFLAGS
1726     fi
1727   fi
1728 fi
1729
1730 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
1731 dnl using Motif or Xaw3d is available, and unless
1732 dnl --with-toolkit-scroll-bars=no was specified.
1733
1734 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
1735             [Define to 1 if we should use toolkit scroll bars.])dnl
1736 USE_TOOLKIT_SCROLL_BARS=no
1737 if test "${with_toolkit_scroll_bars}" != "no"; then
1738   if test "${USE_X_TOOLKIT}" != "none"; then
1739     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
1740       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1741       HAVE_XAW3D=no
1742       USE_TOOLKIT_SCROLL_BARS=yes
1743     elif test "${HAVE_XAW3D}" = "yes"; then
1744       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1745       USE_TOOLKIT_SCROLL_BARS=yes
1746     fi
1747   elif test "${HAVE_GTK}" = "yes"; then
1748     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1749     USE_TOOLKIT_SCROLL_BARS=yes
1750   elif test "${HAVE_NS}" = "yes"; then
1751     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1752     USE_TOOLKIT_SCROLL_BARS=yes
1753   fi
1754 fi
1755
1756 dnl See if XIM is available.
1757 AC_TRY_COMPILE([
1758           #include <X11/Xlib.h>
1759           #include <X11/Xresource.h>],
1760          [XIMProc  callback;],
1761          [HAVE_XIM=yes
1762          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
1763          HAVE_XIM=no)
1764
1765 dnl `--with-xim' now controls only the initial value of use_xim at run time.
1766
1767 if test "${with_xim}" != "no"; then
1768   AC_DEFINE(USE_XIM, 1,
1769             [Define to 1 if we should use XIM, if it is available.])
1770 fi
1771
1772
1773 if test "${HAVE_XIM}" != "no"; then
1774   late_CFLAGS=$CFLAGS
1775   if test "$GCC" = yes; then
1776     CFLAGS="$CFLAGS --pedantic-errors"
1777   fi
1778   AC_TRY_COMPILE([
1779 #include <X11/Xlib.h>
1780 #include <X11/Xresource.h>],
1781 [Display *display;
1782 XrmDatabase db;
1783 char *res_name;
1784 char *res_class;
1785 XIMProc  callback;
1786 XPointer *client_data;
1787 #ifndef __GNUC__
1788 /* If we're not using GCC, it's probably not XFree86, and this is
1789    probably right, but we can't use something like --pedantic-errors.  */
1790 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
1791                                            char*, XIMProc, XPointer*);
1792 #endif
1793 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
1794    client_data);],
1795     [emacs_cv_arg6_star=yes])
1796   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
1797          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
1798 either XPointer or XPointer*.])dnl
1799   if test "$emacs_cv_arg6_star" = yes; then
1800     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
1801   else
1802     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
1803   fi
1804   CFLAGS=$late_CFLAGS
1805 fi
1806
1807 ### Start of font-backend section.
1808
1809 ## Use -lXft if available, unless `--with-freetype=no' nor `--with-xft=no'.
1810 HAVE_XFT=maybe
1811 if test "x${with_freetype}" = "xno" || test "x${with_x}" = "xno"; then
1812   with_xft="no";
1813 fi
1814 if test "x${with_xft}" != "xno"; then
1815
1816   PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
1817   if test "$HAVE_XFT" != no; then
1818     OLD_CPPFLAGS="$CPPFLAGS"
1819     OLD_CFLAGS="$CFLAGS"
1820     OLD_LIBS="$LIBS"
1821     CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
1822     CFLAGS="$CFLAGS $XFT_CFLAGS"
1823     LIBS="$XFT_LIBS $LIBS"
1824     AC_CHECK_HEADER(X11/Xft/Xft.h,
1825       AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS))
1826
1827     if test "${HAVE_XFT}" = "yes"; then
1828       AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
1829         AC_SUBST(XFT_LIBS)
1830       C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
1831     else
1832       CPPFLAGS="$OLD_CPPFLAGS"
1833       CFLAGS="$OLD_CFLAGS"
1834       LIBS="$OLD_LIBS"
1835     fi                        # "${HAVE_XFT}" = "yes"
1836   fi                          # "$HAVE_XFT" != no
1837 fi                            # "x${with_xft}" != "xno"
1838
1839 dnl For the "Does Emacs use" message at the end.
1840 if test "$HAVE_XFT" != "yes"; then
1841    HAVE_XFT=no
1842 fi
1843
1844
1845 HAVE_FREETYPE=no
1846 ### Use -lfreetype if available, unless `--with-freetype=no'.
1847 if test "${HAVE_XFT}" = "yes"; then
1848   dnl As we use Xft, we anyway use freetype.
1849   dnl In this case, there's no need of additional CFLAGS and LIBS.
1850   HAVE_FREETYPE=yes
1851 elif test "x${with_freetype}" != "xno" && test "x${with_x}" != "xno"; then
1852
1853   PKG_CHECK_MODULES(FREETYPE, freetype2, HAVE_FREETYPE=yes, HAVE_FREETYPE=no)
1854   if test "${HAVE_FREETYPE}" = "yes"; then
1855     PKG_CHECK_MODULES(FONTCONFIG, fontconfig, HAVE_FC=yes, HAVE_FC=no)
1856     if test "${HAVE_FC}" = "no"; then
1857       dnl Without fontconfig, we can't use freetype at the moment.
1858       HAVE_FREETYPE=no
1859     fi
1860   fi
1861 fi
1862
1863 HAVE_LIBOTF=no
1864 if test "${HAVE_FREETYPE}" = "yes"; then
1865   AC_DEFINE(HAVE_FREETYPE, 1,
1866             [Define to 1 if using the freetype and fontconfig libraries.])
1867   if test "${with_libotf}" != "no"; then
1868     PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
1869                       HAVE_LIBOTF=no)
1870     if test "$HAVE_LIBOTF" = "yes"; then
1871       AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
1872     fi
1873   fi
1874 dnl FIXME should there be an error if HAVE_FREETYPE != yes?
1875 dnl Does the new font backend require it, or can it work without it?
1876 fi
1877
1878 HAVE_M17N_FLT=no
1879 if test "${with_m17n_flt}" != "no"; then
1880   PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no)
1881   if test "$HAVE_M17N_FLT" = "yes"; then
1882     AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
1883   fi
1884 fi
1885
1886 AC_SUBST(FREETYPE_CFLAGS)
1887 AC_SUBST(FREETYPE_LIBS)
1888 AC_SUBST(FONTCONFIG_CFLAGS)
1889 AC_SUBST(FONTCONFIG_LIBS)
1890 AC_SUBST(LIBOTF_CFLAGS)
1891 AC_SUBST(LIBOTF_LIBS)
1892 AC_SUBST(M17N_FLT_CFLAGS)
1893 AC_SUBST(M17N_FLT_LIBS)
1894
1895 ### End of font-backend section.
1896
1897 ### Use -lXpm if available, unless `--with-xpm=no'.
1898 HAVE_XPM=no
1899 if test "${HAVE_X11}" = "yes"; then
1900   if test "${with_xpm}" != "no"; then
1901     AC_CHECK_HEADER(X11/xpm.h,
1902       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
1903     if test "${HAVE_XPM}" = "yes"; then
1904       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
1905       AC_EGREP_CPP(no_return_alloc_pixels,
1906       [#include "X11/xpm.h"
1907 #ifndef XpmReturnAllocPixels
1908 no_return_alloc_pixels
1909 #endif
1910       ], HAVE_XPM=no, HAVE_XPM=yes)
1911
1912       if test "${HAVE_XPM}" = "yes"; then
1913         AC_MSG_RESULT(yes)
1914       else
1915         AC_MSG_RESULT(no)
1916       fi
1917     fi
1918   fi
1919
1920   if test "${HAVE_XPM}" = "yes"; then
1921     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm libary (-lXpm).])
1922   fi
1923 fi
1924
1925 ### Use -ljpeg if available, unless `--with-jpeg=no'.
1926 HAVE_JPEG=no
1927 if test "${HAVE_X11}" = "yes"; then
1928   if test "${with_jpeg}" != "no"; then
1929     dnl Checking for jpeglib.h can lose because of a redefinition of
1930     dnl  HAVE_STDLIB_H.
1931     AC_CHECK_HEADER(jerror.h,
1932       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
1933   fi
1934
1935   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
1936   if test "${HAVE_JPEG}" = "yes"; then
1937     AC_DEFINE(HAVE_JPEG)
1938     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
1939         [#include <jpeglib.h>
1940          version=JPEG_LIB_VERSION
1941 ],
1942         [AC_DEFINE(HAVE_JPEG)],
1943         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
1944         HAVE_JPEG=no])
1945   fi
1946 fi
1947
1948 ### Use -lpng if available, unless `--with-png=no'.
1949 HAVE_PNG=no
1950 if test "${HAVE_X11}" = "yes"; then
1951   if test "${with_png}" != "no"; then
1952     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
1953     # in /usr/include/libpng.
1954     AC_CHECK_HEADERS(png.h libpng/png.h)
1955     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
1956       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
1957     fi
1958   fi
1959
1960   if test "${HAVE_PNG}" = "yes"; then
1961     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
1962   fi
1963 fi
1964
1965 ### Use -ltiff if available, unless `--with-tiff=no'.
1966 HAVE_TIFF=no
1967 if test "${HAVE_X11}" = "yes"; then
1968   if test "${with_tiff}" != "no"; then
1969     AC_CHECK_HEADER(tiffio.h,
1970       [tifflibs="-lz -lm"
1971       # At least one tiff package requires the jpeg library.
1972       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
1973       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
1974   fi
1975
1976   if test "${HAVE_TIFF}" = "yes"; then
1977     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
1978   fi
1979 fi
1980
1981 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
1982 HAVE_GIF=no
1983 if test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no"; then
1984   AC_CHECK_HEADER(gif_lib.h,
1985 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
1986 # Earlier versions can crash Emacs.
1987     [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, try_libungif=yes)])
1988
1989   if test "$HAVE_GIF" = yes; then
1990       ac_gif_lib_name="-lgif"
1991   fi
1992
1993 # If gif_lib.h but no libgif, try libungif.
1994   if test x"$try_libungif" = xyes; then
1995     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes)
1996
1997     if test "$HAVE_GIF" = yes; then
1998       AC_DEFINE(LIBGIF, -lungif, [Compiler option to link with the gif library (if not -lgif).])
1999       ac_gif_lib_name="-lungif"
2000     fi
2001   fi
2002
2003   if test "${HAVE_GIF}" = "yes"; then
2004     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif library (default -lgif; otherwise specify with LIBGIF).])
2005   fi
2006 fi
2007
2008 dnl Check for required libraries.
2009 if test "${HAVE_X11}" = "yes"; then
2010   MISSING=""
2011   WITH_NO=""
2012   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
2013     MISSING="libXpm" && WITH_NO="--with-xpm=no"
2014   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
2015     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
2016   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
2017     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
2018   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
2019     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
2020   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
2021     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
2022
2023   if test "X${MISSING}" != X; then
2024     AC_MSG_ERROR([The following required libraries were not found:
2025     $MISSING
2026 Maybe some development libraries/packages are missing?
2027 If you don't want to link with them give
2028     $WITH_NO
2029 as options to configure])
2030   fi
2031 fi
2032
2033 ### Use -lgpm if available, unless `--with-gpm=no'.
2034 HAVE_GPM=no
2035 if test "${with_gpm}" != "no"; then
2036   AC_CHECK_HEADER(gpm.h,
2037     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
2038 fi
2039
2040 if test "${HAVE_GPM}" = "yes"; then
2041   AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
2042 fi
2043
2044 dnl Check for malloc/malloc.h on darwin
2045 AC_CHECK_HEADER(malloc/malloc.h, [AC_DEFINE(HAVE_MALLOC_MALLOC_H, 1, [Define to 1 if you have the <malloc/malloc.h> header file.])])
2046
2047 ### Use NeXTstep API to implement GUI.
2048 if test "${HAVE_NS}" = "yes"; then
2049   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
2050   if test "${NS_IMPL_COCOA}" = "yes"; then
2051     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
2052     GNU_OBJC_CFLAGS=
2053     LIB_SRC_EXTRA_INSTALLABLES=mac-fix-env
2054   fi
2055   if test "${EN_COCOA_EXPERIMENTAL_CTRL_G}" = "yes"; then
2056     AC_DEFINE(COCOA_EXPERIMENTAL_CTRL_G, 1, [Define to 1 if you are trying experimental enhanced Ctrl-g support using NS windowing under MacOS X.])
2057   fi
2058   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
2059     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
2060     GNU_OBJC_CFLAGS="-fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
2061   fi
2062   if test "${NS_HAVE_NSINTEGER}" = "yes"; then
2063     AC_DEFINE(NS_HAVE_NSINTEGER, 1, [Define to 1 if `NSInteger' is defined.])
2064   fi
2065   # We also have mouse menus.
2066   HAVE_MENUS=yes
2067 fi
2068
2069
2070 ### Use session management (-lSM -lICE) if available
2071 HAVE_X_SM=no
2072 if test "${HAVE_X11}" = "yes"; then
2073   AC_CHECK_HEADER(X11/SM/SMlib.h,
2074     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
2075
2076   if test "${HAVE_X_SM}" = "yes"; then
2077     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2078     case "$LIBS" in
2079       *-lSM*) ;;
2080       *)      LIBS="-lSM -lICE $LIBS" ;;
2081     esac
2082   fi
2083 fi
2084
2085 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2086 AC_CACHE_CHECK(whether netdb declares h_errno,
2087                emacs_cv_netdb_declares_h_errno,
2088 [AC_TRY_LINK([#include <netdb.h>],
2089   [return h_errno;],
2090   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2091 if test $emacs_cv_netdb_declares_h_errno = yes; then
2092   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2093 fi
2094
2095 AC_FUNC_ALLOCA
2096
2097 dnl src/alloca.c has been removed.  Could also check if $ALLOCA is set?
2098 dnl FIXME is there an autoconf test that does the right thing, without
2099 dnl needing to call A_M_E afterwards?
2100 if test x"$ac_cv_func_alloca_works" != xyes; then
2101    AC_MSG_ERROR( [a system implementation of alloca is required] )
2102 fi
2103
2104 # fmod, logb, and frexp are found in -lm on most systems.
2105 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2106 AC_CHECK_LIB(m, sqrt)
2107
2108 # Check for mail-locking functions in a "mail" library.  Probably this should
2109 # have the same check as for liblockfile below.
2110 AC_CHECK_LIB(mail, maillock)
2111 dnl Debian, at least:
2112 AC_CHECK_LIB(lockfile, maillock)
2113 # If we have the shared liblockfile, assume we must use it for mail
2114 # locking (e.g. Debian).  If we couldn't link against liblockfile
2115 # (no liblockfile.a installed), ensure that we don't need to.
2116 if test "$ac_cv_lib_lockfile_maillock" = no; then
2117   dnl This works for files generally, not just executables.
2118   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
2119   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2120                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2121   if test $ac_cv_prog_liblockfile = yes; then
2122     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2123 This probably means that movemail could lose mail.
2124 There may be a `development' package to install containing liblockfile.])
2125   else :
2126   fi
2127 fi
2128 AC_CHECK_FUNCS(touchlock)
2129 AC_CHECK_HEADERS(maillock.h)
2130
2131 AC_CHECK_FUNCS(gethostname getdomainname dup2 \
2132 rename closedir mkdir rmdir sysinfo getrusage get_current_dir_name \
2133 random lrand48 bcopy bcmp logb frexp fmod rint cbrt ftime setsid \
2134 strerror fpathconf select mktime euidaccess getpagesize tzset setlocale \
2135 utimes getrlimit setrlimit setpgid getcwd getwd shutdown getaddrinfo \
2136 __fpending mblen mbrlen mbsinit strsignal setitimer ualarm index rindex \
2137 sendto recvfrom getsockopt setsockopt getsockname getpeername \
2138 gai_strerror mkstemp getline getdelim mremap memmove fsync sync bzero \
2139 memset memcmp difftime memcpy mempcpy mblen mbrlen posix_memalign \
2140 cfmakeraw cfsetspeed)
2141
2142 AC_CHECK_HEADERS(sys/un.h)
2143
2144 AC_FUNC_MKTIME
2145 if test "$ac_cv_func_working_mktime" = no; then
2146   AC_DEFINE(BROKEN_MKTIME, 1, [Define to 1 if the mktime function is broken.])
2147 fi
2148
2149 AC_FUNC_GETLOADAVG
2150
2151 AC_FUNC_FSEEKO
2152
2153 # Configure getopt.
2154 m4_include([m4/getopt.m4])
2155 gl_GETOPT_IFELSE([
2156   gl_GETOPT_SUBSTITUTE_HEADER
2157   gl_PREREQ_GETOPT
2158   GETOPTOBJS='getopt.o getopt1.o'
2159 ])
2160 AC_SUBST(GETOPTOBJS)
2161
2162 AC_FUNC_GETPGRP
2163
2164 AC_FUNC_STRFTIME
2165
2166 # UNIX98 PTYs.
2167 AC_CHECK_FUNCS(grantpt)
2168
2169 # PTY-related GNU extensions.
2170 AC_CHECK_FUNCS(getpt)
2171
2172 # Check this now, so that we will NOT find the above functions in ncurses.
2173 # That is because we have not set up to link ncurses in lib-src.
2174 # It's better to believe a function is not available
2175 # than to expect to find it in ncurses.
2176 AC_CHECK_LIB(ncurses, tparm)
2177
2178 # Do we have res_init, for detecting changes in /etc/resolv.conf?
2179
2180 resolv=no
2181 AC_TRY_LINK([#include <netinet/in.h>
2182 #include <arpa/nameser.h>
2183 #include <resolv.h>],
2184     [return res_init();],
2185     have_res_init=yes, have_res_init=no)
2186 if test "$have_res_init" = no; then
2187   OLIBS="$LIBS"
2188   LIBS="$LIBS -lresolv"
2189   AC_MSG_CHECKING(for res_init with -lresolv)
2190   AC_TRY_LINK([#include <netinet/in.h>
2191 #include <arpa/nameser.h>
2192 #include <resolv.h>],
2193     [return res_init();],
2194     have_res_init=yes, have_res_init=no)
2195   AC_MSG_RESULT($have_res_init)
2196   if test "$have_res_init" = yes ; then
2197     resolv=yes
2198   fi
2199   LIBS="$OLIBS"
2200 fi
2201
2202 if test "$have_res_init" = yes; then
2203   AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
2204 fi
2205
2206 # Do we need the Hesiod library to provide the support routines?
2207 if test "$with_hesiod" != no ; then
2208   # Don't set $LIBS here -- see comments above.
2209   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
2210      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
2211                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
2212   if test "$resolv" = yes ; then
2213     RESOLVLIB=-lresolv
2214   else
2215     RESOLVLIB=
2216   fi
2217   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2218         [AC_DEFINE(HAVE_LIBHESIOD, 1,
2219                   [Define to 1 if you have the hesiod library (-lhesiod).])],
2220         :, $RESOLVLIB)])
2221 fi
2222
2223 # Do we need libresolv (due to res_init or Hesiod)?
2224 if test "$resolv" = yes ; then
2225   AC_DEFINE(HAVE_LIBRESOLV, 1,
2226             [Define to 1 if you have the resolv library (-lresolv).])
2227 fi
2228
2229 # These tell us which Kerberos-related libraries to use.
2230 if test "${with_kerberos}" != no; then
2231   AC_CHECK_LIB(com_err, com_err)
2232   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt)
2233   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt)
2234   AC_CHECK_LIB(krb5, krb5_init_context)
2235   if test "${with_kerberos5}" = no; then
2236     AC_CHECK_LIB(des425, des_cbc_encrypt,,
2237                  [AC_CHECK_LIB(des, des_cbc_encrypt)])
2238     AC_CHECK_LIB(krb4, krb_get_cred,,
2239                  [AC_CHECK_LIB(krb, krb_get_cred)])
2240   fi
2241
2242   if test "${with_kerberos5}" != no; then
2243     AC_CHECK_HEADERS(krb5.h,
2244       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
2245                         [#include <krb5.h>])])
2246   else
2247     AC_CHECK_HEADERS(des.h,,
2248                      [AC_CHECK_HEADERS(kerberosIV/des.h,,
2249                                        [AC_CHECK_HEADERS(kerberos/des.h)])])
2250     AC_CHECK_HEADERS(krb.h,,
2251                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
2252                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
2253   fi
2254   AC_CHECK_HEADERS(com_err.h)
2255 fi
2256
2257 # Solaris requires -lintl if you want strerror (which calls dgettext)
2258 # to return localized messages.
2259 AC_CHECK_LIB(intl, dgettext)
2260
2261 AC_MSG_CHECKING(whether localtime caches TZ)
2262 AC_CACHE_VAL(emacs_cv_localtime_cache,
2263 [if test x$ac_cv_func_tzset = xyes; then
2264 AC_TRY_RUN([#include <time.h>
2265 extern char **environ;
2266 unset_TZ ()
2267 {
2268   char **from, **to;
2269   for (to = from = environ; (*to = *from); from++)
2270     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
2271       to++;
2272 }
2273 char TZ_GMT0[] = "TZ=GMT0";
2274 char TZ_PST8[] = "TZ=PST8";
2275 main()
2276 {
2277   time_t now = time ((time_t *) 0);
2278   int hour_GMT0, hour_unset;
2279   if (putenv (TZ_GMT0) != 0)
2280     exit (1);
2281   hour_GMT0 = localtime (&now)->tm_hour;
2282   unset_TZ ();
2283   hour_unset = localtime (&now)->tm_hour;
2284   if (putenv (TZ_PST8) != 0)
2285     exit (1);
2286   if (localtime (&now)->tm_hour == hour_GMT0)
2287     exit (1);
2288   unset_TZ ();
2289   if (localtime (&now)->tm_hour != hour_unset)
2290     exit (1);
2291   exit (0);
2292 }], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
2293 [# If we have tzset, assume the worst when cross-compiling.
2294 emacs_cv_localtime_cache=yes])
2295 else
2296         # If we lack tzset, report that localtime does not cache TZ,
2297         # since we can't invalidate the cache if we don't have tzset.
2298         emacs_cv_localtime_cache=no
2299 fi])dnl
2300 AC_MSG_RESULT($emacs_cv_localtime_cache)
2301 if test $emacs_cv_localtime_cache = yes; then
2302   AC_DEFINE(LOCALTIME_CACHE, 1,
2303             [Define to 1 if localtime caches TZ.])
2304 fi
2305
2306 if test "x$HAVE_TIMEVAL" = xyes; then
2307   AC_CHECK_FUNCS(gettimeofday)
2308   if test $ac_cv_func_gettimeofday = yes; then
2309     AC_CACHE_CHECK(whether gettimeofday can accept two arguments,
2310                    emacs_cv_gettimeofday_two_arguments,
2311     [AC_TRY_COMPILE([
2312 #ifdef TIME_WITH_SYS_TIME
2313 #include <sys/time.h>
2314 #include <time.h>
2315 #else
2316 #ifdef HAVE_SYS_TIME_H
2317 #include <sys/time.h>
2318 #else
2319 #include <time.h>
2320 #endif
2321 #endif],
2322       [struct timeval time;
2323        gettimeofday (&time, 0);],
2324       emacs_cv_gettimeofday_two_arguments=yes,
2325       emacs_cv_gettimeofday_two_arguments=no)])
2326     if test $emacs_cv_gettimeofday_two_arguments = no; then
2327       AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT, 1,
2328                 [Define to 1 if gettimeofday accepts only one argument.])
2329     fi
2330   fi
2331 fi
2332
2333 ok_so_far=yes
2334 AC_CHECK_FUNC(socket, , ok_so_far=no)
2335 if test $ok_so_far = yes; then
2336   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
2337 fi
2338 if test $ok_so_far = yes; then
2339   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
2340 fi
2341 if test $ok_so_far = yes; then
2342 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
2343   AC_DEFINE(HAVE_INET_SOCKETS, 1,
2344             [Define to 1 if you have inet sockets.])
2345 fi
2346
2347 AC_CHECK_HEADERS(sys/ioctl.h)
2348
2349 if test -f /usr/lpp/X11/bin/smt.exp; then
2350   AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
2351             [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
2352 fi
2353
2354 AC_MSG_CHECKING(whether system supports dynamic ptys)
2355 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
2356   AC_MSG_RESULT(yes)
2357   AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
2358 else
2359   AC_MSG_RESULT(no)
2360 fi
2361
2362 AC_FUNC_FORK
2363
2364 dnl Adapted from Haible's version.
2365 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
2366   [AC_TRY_LINK([#include <langinfo.h>],
2367     [char* cs = nl_langinfo(CODESET);],
2368     emacs_cv_langinfo_codeset=yes,
2369     emacs_cv_langinfo_codeset=no)
2370   ])
2371 if test $emacs_cv_langinfo_codeset = yes; then
2372   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
2373     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
2374 fi
2375
2376 AC_CHECK_TYPES(size_t)
2377
2378 AC_TYPE_MBSTATE_T
2379
2380 dnl Restrict could probably be used effectively other than in regex.c.
2381 AC_CACHE_CHECK([for C restrict keyword], emacs_cv_c_restrict,
2382   [AC_TRY_COMPILE([void fred (int *restrict x);], [],
2383                   emacs_cv_c_restrict=yes,
2384                   [AC_TRY_COMPILE([void fred (int *__restrict x);], [],
2385                                   emacs_cv_c_restrict=__restrict,
2386                                   emacs_cv_c_restrict=no)])])
2387 case "$emacs_cv_c_restrict" in
2388   yes) emacs_restrict=restrict;;
2389   no) emacs_restrict="";;
2390   *) emacs_restrict="$emacs_cv_c_restrict";;
2391 esac
2392 if test "$emacs_restrict" != __restrict; then
2393   AC_DEFINE_UNQUOTED(__restrict, $emacs_restrict,
2394     [Define to compiler's equivalent of C99 restrict keyword.
2395      Don't define if equivalent is `__restrict'.])
2396 fi
2397
2398 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
2399   [AC_TRY_COMPILE([void fred (int x[__restrict]);], [],
2400                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
2401 if test "$emacs_cv_c_restrict_arr" = yes; then
2402   AC_DEFINE(__restrict_arr, __restrict,
2403     [Define to compiler's equivalent of C99 restrict keyword in array
2404      declarations.  Define as empty for no equivalent.])
2405 fi
2406
2407 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
2408 dnl how the tty code is related to POSIX and/or other versions of termios.
2409 dnl The following looks like a useful start.
2410 dnl
2411 dnl AC_SYS_POSIX_TERMIOS
2412 dnl if test $ac_cv_sys_posix_termios = yes; then
2413 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
2414 dnl                                and macros for terminal control.])
2415 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
2416 dnl fi
2417
2418 dnl Fixme: Use AC_FUNC_MEMCMP since memcmp is used.  (Needs libobj replacement.)
2419
2420 # Set up the CFLAGS for real compilation, so we can substitute it.
2421 CFLAGS="$REAL_CFLAGS"
2422 CPPFLAGS="$REAL_CPPFLAGS"
2423
2424 #### Find out which version of Emacs this is.
2425 [version=`grep 'defconst[        ]*emacs-version' ${srcdir}/lisp/version.el \
2426          | sed -e 's/^[^"]*"\([^"]*\)".*$/\1/'`]
2427 if test x"${version}" = x; then
2428   AC_MSG_ERROR([can't find current emacs version in `${srcdir}/lisp/version.el'.])
2429 fi
2430
2431 ### Specify what sort of things we'll be editing into Makefile and config.h.
2432 ### Use configuration here uncanonicalized to avoid exceeding size limits.
2433 AC_SUBST(version)
2434 AC_SUBST(configuration)
2435 AC_SUBST(canonical)
2436 AC_SUBST(srcdir)
2437 AC_SUBST(prefix)
2438 AC_SUBST(exec_prefix)
2439 AC_SUBST(bindir)
2440 AC_SUBST(datadir)
2441 AC_SUBST(sharedstatedir)
2442 AC_SUBST(libexecdir)
2443 AC_SUBST(mandir)
2444 AC_SUBST(infodir)
2445 AC_SUBST(lispdir)
2446 AC_SUBST(locallisppath)
2447 AC_SUBST(lisppath)
2448 AC_SUBST(x_default_search_path)
2449 AC_SUBST(etcdir)
2450 AC_SUBST(archlibdir)
2451 AC_SUBST(docdir)
2452 AC_SUBST(bitmapdir)
2453 AC_SUBST(gamedir)
2454 AC_SUBST(gameuser)
2455 AC_SUBST(c_switch_system)
2456 AC_SUBST(c_switch_machine)
2457 AC_SUBST(LD_SWITCH_X_SITE)
2458 AC_SUBST(LD_SWITCH_X_SITE_AUX)
2459 AC_SUBST(C_SWITCH_X_SITE)
2460 AC_SUBST(CFLAGS)
2461 AC_SUBST(X_TOOLKIT_TYPE)
2462 AC_SUBST(machfile)
2463 AC_SUBST(opsysfile)
2464 AC_SUBST(GETLOADAVG_LIBS)
2465 AC_SUBST(ns_appdir)
2466 AC_SUBST(ns_appbindir)
2467 AC_SUBST(ns_appresdir)
2468 AC_SUBST(ns_appsrc)
2469 AC_SUBST(GNUSTEP_MAKEFILES)
2470 AC_SUBST(GNUSTEP_SYSTEM_HEADERS)
2471 AC_SUBST(GNUSTEP_SYSTEM_LIBRARIES)
2472 AC_SUBST(GNU_OBJC_CFLAGS)
2473 AC_SUBST(LIB_SRC_EXTRA_INSTALLABLES)
2474
2475 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
2476                    [Define to the canonical Emacs configuration name.])
2477 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
2478                    [Define to the options passed to configure.])
2479 AC_DEFINE_UNQUOTED(config_machfile,  "${machfile}",
2480                    [Define to the used machine dependent file.])
2481 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}",
2482                    [Define to the used os dependent file.])
2483 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE, ${LD_SWITCH_X_SITE},
2484 [Define LD_SWITCH_X_SITE to contain any special flags your loader
2485  may need to deal with X Windows.  For instance, if you've defined
2486  HAVE_X_WINDOWS above and your X libraries aren't in a place that
2487  your loader can find on its own, you might want to add "-L/..." or
2488  something similar.])
2489 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE_AUX, ${LD_SWITCH_X_SITE_AUX},
2490                    [Define LD_SWITCH_X_SITE_AUX with an -R option
2491                     in case it's needed (for Solaris, for example).])
2492 AC_DEFINE_UNQUOTED(C_SWITCH_X_SITE,  ${C_SWITCH_X_SITE},
2493 [Define C_SWITCH_X_SITE to contain any special flags your compiler
2494  may need to deal with X Windows.  For instance, if you've defined
2495  HAVE_X_WINDOWS above and your X include files aren't in a place
2496  that your compiler can find on its own, you might want to add
2497  "-I/..." or something similar.])
2498 AC_DEFINE_UNQUOTED(UNEXEC_SRC,       ${UNEXEC_SRC},
2499                    [Define to the unexec source file name.])
2500
2501 if test "${HAVE_X_WINDOWS}" = "yes" ; then
2502   AC_DEFINE(HAVE_X_WINDOWS, 1,
2503             [Define to 1 if you want to use the X window system.])
2504 fi
2505 if test "${USE_X_TOOLKIT}" != "none" ; then
2506   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
2507   if test "${USE_X_TOOLKIT}" = "LUCID"; then
2508     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
2509   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
2510     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
2511   fi
2512 fi
2513 if test "${HAVE_X11}" = "yes" ; then
2514   AC_DEFINE(HAVE_X11, 1,
2515             [Define to 1 if you want to use version 11 of X windows.
2516              Otherwise, Emacs expects to use version 10.])
2517 fi
2518 if test "${HAVE_MENUS}" = "yes" ; then
2519   AC_DEFINE(HAVE_MENUS, 1,
2520             [Define to 1 if you have mouse menus.
2521              (This is automatic if you use X, but the option to specify it remains.)
2522              It is also defined with other window systems that support xmenu.c.])
2523 fi
2524 if test "${GNU_MALLOC}" = "yes" ; then
2525   AC_DEFINE(GNU_MALLOC, 1,
2526             [Define to 1 if you want to use the GNU memory allocator.])
2527 fi
2528 if test "${REL_ALLOC}" = "yes" ; then
2529   AC_DEFINE(REL_ALLOC, 1,
2530             [Define REL_ALLOC if you want to use the relocating allocator for
2531              buffer space.])
2532 fi
2533
2534
2535 AH_TOP([/* GNU Emacs site configuration template file.
2536    Copyright (C) 1988, 1993, 1994, 1999, 2000, 2001, 2002, 2004, 2005,
2537      2006, 2007, 2008  Free Software Foundation, Inc.
2538
2539 This file is part of GNU Emacs.
2540
2541 GNU Emacs is free software: you can redistribute it and/or modify
2542 it under the terms of the GNU General Public License as published by
2543 the Free Software Foundation, either version 3 of the License, or
2544 (at your option) any later version.
2545
2546 GNU Emacs is distributed in the hope that it will be useful,
2547 but WITHOUT ANY WARRANTY; without even the implied warranty of
2548 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
2549 GNU General Public License for more details.
2550
2551 You should have received a copy of the GNU General Public License
2552 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
2553
2554
2555 /* No code in Emacs #includes config.h twice, but some bits of code
2556    intended to work with other packages as well (like gmalloc.c)
2557    think they can include it as many times as they like.  */
2558 #ifndef EMACS_CONFIG_H
2559 #define EMACS_CONFIG_H
2560 ])dnl
2561
2562 AH_BOTTOM([
2563 /* If we're using X11/Carbon/GNUstep, define some consequences.  */
2564 #if defined(HAVE_X_WINDOWS) || defined(HAVE_NS)
2565 #define HAVE_WINDOW_SYSTEM
2566 #define HAVE_MOUSE
2567 #endif
2568
2569 /* Sadly for now, GNUstep dump does not work.  */
2570 #ifdef NS_IMPL_GNUSTEP
2571 #define CANNOT_DUMP
2572 #endif
2573
2574 /* Define AMPERSAND_FULL_NAME if you use the convention
2575    that & in the full name stands for the login id.  */
2576 /* Turned on June 1996 supposing nobody will mind it.  */
2577 #define AMPERSAND_FULL_NAME
2578
2579 /* Define HAVE_SOUND if we have sound support.  We know it works
2580    and compiles only on the specified platforms.   For others,
2581    it probably doesn't make sense to try.  */
2582
2583 #if defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
2584 #ifdef HAVE_MACHINE_SOUNDCARD_H
2585 #define HAVE_SOUND 1
2586 #endif
2587 #ifdef HAVE_SYS_SOUNDCARD_H
2588 #define HAVE_SOUND 1
2589 #endif
2590 #ifdef HAVE_SOUNDCARD_H
2591 #define HAVE_SOUND 1
2592 #endif
2593 #ifdef HAVE_ALSA
2594 #define HAVE_SOUND 1
2595 #endif
2596 #endif /* __FreeBSD__ || __NetBSD__ || __linux__  */
2597
2598 /* If using GNU, then support inline function declarations. */
2599 /* Don't try to switch on inline handling as detected by AC_C_INLINE
2600    generally, because even if non-gcc compilers accept `inline', they
2601    may reject `extern inline'.  */
2602 #if defined (__GNUC__) && defined (OPTIMIZE)
2603 #define INLINE __inline__
2604 #else
2605 #define INLINE
2606 #endif
2607
2608 /* `subprocesses' should be defined if you want to
2609    have code for asynchronous subprocesses
2610    (as used in M-x compile and M-x shell).
2611    Only MSDOS does not support this (it overrides
2612    this in its config_opsysfile below).  */
2613
2614 #define subprocesses
2615
2616 /* Include the os and machine dependent files.  */
2617 #include config_opsysfile
2618 #include config_machfile
2619
2620 /* Set up some defines, C and LD flags for NeXTstep interface on GNUstep.
2621   (There is probably a better place to do this, but right now the Cocoa
2622    side does this in s/darwin.h and we cannot
2623    parallel this exactly since GNUstep is multi-OS. */
2624 #ifdef HAVE_NS
2625 #define OTHER_FILES ns-app
2626 # ifdef NS_IMPL_GNUSTEP
2627 /* See also .m.o rule in Makefile.in */
2628 /* FIXME: are all these flags really needed?  Document here why.  */
2629 #  define C_SWITCH_X_SYSTEM -D_REENTRANT -fPIC -fno-strict-aliasing
2630 /* GNUStep needs a bit more pure memory.  Of the existing knobs,
2631 SYSTEM_PURESIZE_EXTRA seems like the least likely to cause problems.  */
2632 #  define SYSTEM_PURESIZE_EXTRA 30000
2633 # endif /* NS_IMPL_GNUSTEP */
2634 #endif /* HAVE_NS */
2635
2636 /* SIGTYPE is the macro we actually use.  */
2637 #ifndef SIGTYPE
2638 #define SIGTYPE RETSIGTYPE
2639 #endif
2640
2641 #ifdef emacs /* Don't do this for lib-src.  */
2642 /* Tell regex.c to use a type compatible with Emacs.  */
2643 #define RE_TRANSLATE_TYPE Lisp_Object
2644 #define RE_TRANSLATE(TBL, C) CHAR_TABLE_TRANSLATE (TBL, C)
2645 #ifdef make_number
2646 /* If make_number is a macro, use it.  */
2647 #define RE_TRANSLATE_P(TBL) (!EQ (TBL, make_number (0)))
2648 #else
2649 /* If make_number is a function, avoid it.  */
2650 #define RE_TRANSLATE_P(TBL) (!(INTEGERP (TBL) && XINT (TBL) == 0))
2651 #endif
2652 #endif
2653
2654 /* Avoid link-time collision with system mktime if we will use our own.  */
2655 #if ! HAVE_MKTIME || BROKEN_MKTIME
2656 #define mktime emacs_mktime
2657 #endif
2658
2659 #define my_strftime nstrftime   /* for strftime.c */
2660
2661 /* The rest of the code currently tests the CPP symbol BSTRING.
2662    Override any claims made by the system-description files.
2663    Note that on some SCO version it is possible to have bcopy and not bcmp.  */
2664 #undef BSTRING
2665 #if defined (HAVE_BCOPY) && defined (HAVE_BCMP)
2666 #define BSTRING
2667 #endif
2668
2669 /* Some of the files of Emacs which are intended for use with other
2670    programs assume that if you have a config.h file, you must declare
2671    the type of getenv.
2672
2673    This declaration shouldn't appear when alloca.s or Makefile.in
2674    includes config.h.  */
2675 #ifndef NOT_C_CODE
2676 extern char *getenv ();
2677 #endif
2678
2679 /* These default definitions are good for almost all machines.
2680    The exceptions override them in m/MACHINE.h.  */
2681
2682 #ifndef BITS_PER_CHAR
2683 #define BITS_PER_CHAR 8
2684 #endif
2685
2686 #ifndef BITS_PER_SHORT
2687 #define BITS_PER_SHORT 16
2688 #endif
2689
2690 /* Note that lisp.h uses this in a preprocessor conditional, so it
2691    would not work to use sizeof.  That being so, we do all of them
2692    without sizeof, for uniformity's sake.  */
2693 #ifndef BITS_PER_INT
2694 #define BITS_PER_INT 32
2695 #endif
2696
2697 #ifndef BITS_PER_LONG
2698 #ifdef _LP64
2699 #define BITS_PER_LONG 64
2700 #else
2701 #define BITS_PER_LONG 32
2702 #endif
2703 #endif
2704
2705 /* Define if the compiler supports function prototypes.  It may do so
2706    but not define __STDC__ (e.g. DEC C by default) or may define it as
2707    zero.  */
2708 #undef PROTOTYPES
2709 /* For mktime.c:  */
2710 #ifndef __P
2711 # if defined PROTOTYPES
2712 #  define __P(args) args
2713 # else
2714 #  define __P(args) ()
2715 # endif  /* GCC.  */
2716 #endif /* __P */
2717
2718 /* Don't include "string.h" or <stdlib.h> in non-C code.  */
2719 #ifndef NOT_C_CODE
2720 #ifdef HAVE_STRING_H
2721 #include "string.h"
2722 #endif
2723 #ifdef HAVE_STRINGS_H
2724 #include "strings.h"  /* May be needed for bcopy & al. */
2725 #endif
2726 #ifdef HAVE_STDLIB_H
2727 #include <stdlib.h>
2728 #endif
2729 #ifndef __GNUC__
2730 # ifdef HAVE_ALLOCA_H
2731 #  include <alloca.h>
2732 # else /* AIX files deal with #pragma.  */
2733 #  ifndef alloca /* predefined by HP cc +Olibcalls */
2734 char *alloca ();
2735 #  endif
2736 # endif /* HAVE_ALLOCA_H */
2737 #endif /* __GNUC__ */
2738 #ifndef HAVE_SIZE_T
2739 typedef unsigned size_t;
2740 #endif
2741 #endif /* NOT_C_CODE */
2742
2743 /* Define HAVE_X_I18N if we have usable i18n support.  */
2744
2745 #ifdef HAVE_X11R6
2746 #define HAVE_X_I18N
2747 #elif !defined X11R5_INHIBIT_I18N
2748 #define HAVE_X_I18N
2749 #endif
2750
2751 /* Define HAVE_X11R6_XIM if we have usable X11R6-style XIM support.  */
2752
2753 #if defined HAVE_X11R6 && !defined INHIBIT_X11R6_XIM
2754 #define HAVE_X11R6_XIM
2755 #endif
2756
2757 /* Should we enable expensive run-time checking of data types?  */
2758 #undef ENABLE_CHECKING
2759
2760 #if defined __GNUC__ && (__GNUC__ > 2 \
2761                          || (__GNUC__ == 2 && __GNUC_MINOR__ >= 5))
2762 #define NO_RETURN       __attribute__ ((__noreturn__))
2763 #else
2764 #define NO_RETURN       /* nothing */
2765 #endif
2766
2767 /* These won't be used automatically yet.  We also need to know, at least,
2768    that the stack is continuous.  */
2769 #ifdef __GNUC__
2770 #  ifndef GC_SETJMP_WORKS
2771   /* GC_SETJMP_WORKS is nearly always appropriate for GCC --
2772      see NON_SAVING_SETJMP in the target descriptions.  */
2773   /* Exceptions (see NON_SAVING_SETJMP in target description) are
2774      SCO5 non-ELF (but Emacs specifies ELF) and SVR3 on x86.
2775      Fixme: Deal with SVR3.  */
2776 #    define GC_SETJMP_WORKS 1
2777 #  endif
2778 #  ifndef GC_LISP_OBJECT_ALIGNMENT
2779 #    define GC_LISP_OBJECT_ALIGNMENT (__alignof__ (Lisp_Object))
2780 #  endif
2781 #endif
2782
2783 #ifndef HAVE_BCOPY
2784 #define bcopy(a,b,s) memcpy (b,a,s)
2785 #endif
2786 #ifndef HAVE_BZERO
2787 #define bzero(a,s) memset (a,0,s)
2788 #endif
2789 #ifndef HAVE_BCMP
2790 #define BCMP memcmp
2791 #endif
2792
2793 #endif /* EMACS_CONFIG_H */
2794
2795 /*
2796 Local Variables:
2797 mode: c
2798 End:
2799 */
2800 ])dnl
2801
2802 #### Report on what we decided to do.
2803 #### Report GTK as a toolkit, even if it doesn't use Xt.
2804 #### It makes printing result more understandable as using GTK sets
2805 #### toolkit_scroll_bars to yes by default.
2806 if test "${HAVE_GTK}" = "yes"; then
2807   USE_X_TOOLKIT=GTK
2808 fi
2809
2810 echo "
2811 Configured for \`${canonical}'.
2812
2813   Where should the build process find the source code?    ${srcdir}
2814   What operating system and machine description files should Emacs use?
2815         \`${opsysfile}' and \`${machfile}'
2816   What compiler should emacs be built with?               ${CC} ${CFLAGS}
2817   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
2818   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
2819   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
2820   What window system should Emacs use?                    ${window_system}
2821   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
2822
2823 if test -n "${x_includes}"; then
2824 echo "  Where do we find X Windows header files?                ${x_includes}"
2825 else
2826 echo "  Where do we find X Windows header files?                Standard dirs"
2827 fi
2828 if test -n "${x_libraries}"; then
2829 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
2830 else
2831 echo "  Where do we find X Windows libraries?                   Standard dirs"
2832 fi
2833
2834 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
2835 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
2836 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
2837 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
2838 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $ac_gif_lib_name"
2839 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
2840 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
2841 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
2842 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
2843
2844 echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
2845 echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
2846 echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
2847 echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
2848
2849 echo "  Does Emacs use X toolkit scroll bars?                   ${USE_TOOLKIT_SCROLL_BARS}"
2850 echo
2851
2852 if test $USE_XASSERTS = yes; then
2853    echo "  Compiling with asserts turned on."
2854    CPPFLAGS="$CPPFLAGS -DXASSERTS=1"
2855 fi
2856
2857 echo
2858
2859 if test "$USE_X_TOOLKIT" = GTK; then
2860   case "$canonical" in
2861   *cygwin*)
2862     echo "There are known problems with Emacs and Gtk+ on cygwin, so you
2863   will probably get a crash on startup.  If this happens, please use another
2864   toolkit for Emacs.  See etc/PROBLEMS for more information."
2865   ;;
2866   esac
2867 fi
2868
2869 if test "$HAVE_NS" = "yes"; then
2870    echo
2871    echo "You must run \"make install\" in order to test the built application.
2872 The installed application will go to nextstep/Emacs.app and can be
2873 run or moved from there."
2874    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
2875       echo "The application will be fully self-contained."
2876     else
2877       echo "The lisp resources for the application will be installed under ${prefix}.
2878 You may need to run \"make install\" with sudo.  The application will fail
2879 to run if these resources are not installed."
2880    fi
2881    echo
2882 fi
2883
2884 if test "$HAVE_DBUS" = yes && test "${opsys}" != "gnu-linux"; then
2885   echo "D-Bus integration has been tested for GNU/Linux only."
2886   echo
2887 fi
2888
2889
2890 # Remove any trailing slashes in these variables.
2891 [test "${prefix}" != NONE &&
2892   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
2893 test "${exec_prefix}" != NONE &&
2894   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
2895
2896 # Now get this: Some word that is part of the ${srcdir} directory name
2897 # or the ${configuration} value might, just might, happen to be an
2898 # identifier like `sun4' or `i386' or something, and be predefined by
2899 # the C preprocessor to some helpful value like 1, or maybe the empty
2900 # string.  Needless to say consequent macro substitutions are less
2901 # than conducive to the makefile finding the correct directory.
2902 [cpp_undefs="`echo $srcdir $configuration $canonical |
2903   sed -e 's/[^a-zA-Z0-9_]/ /g' -e 's/^/ /' -e 's/  *$//' \
2904   -e 's/  */ -U/g' -e 's/-U[0-9][^ ]*//g'`"]
2905
2906 ## Check if the C preprocessor will convert `..' to `. .'.  If so, set
2907 ## CPP_NEED_TRADITIONAL to `yes' so that the code to generate Makefile
2908 ## from Makefile.c can correctly provide the arg `-traditional' to the
2909 ## C preprocessor.
2910
2911 AC_EGREP_CPP(yes..yes,
2912         [yes..yes],
2913         CPP_NEED_TRADITIONAL=no,
2914         CPP_NEED_TRADITIONAL=yes)
2915
2916 AC_OUTPUT(Makefile lib-src/Makefile.c:lib-src/Makefile.in oldXMenu/Makefile \
2917         doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
2918         doc/lispref/Makefile src/Makefile.c:src/Makefile.in \
2919         lwlib/Makefile lisp/Makefile leim/Makefile, [
2920
2921 ### Make the necessary directories, if they don't exist.
2922 for dir in etc lisp ; do
2923   test -d ${dir} || mkdir ${dir}
2924 done
2925
2926 # Build src/Makefile from ${srcdir}/src/Makefile.c
2927 # and lib-src/Makefile from ${srcdir}/lib-src/Makefile.c
2928 # This must be done after src/config.h is built, since we rely on that file.
2929
2930 echo creating src/epaths.h
2931 ${MAKE-make} epaths-force
2932
2933 # As of 2000-11-19, newest development versions of GNU cpp preprocess
2934 # `..' to `. .'  unless invoked with -traditional
2935
2936 if test "x$GCC" = xyes && test "x$CPP_NEED_TRADITIONAL" = xyes; then
2937   CPPFLAGS="$CPPFLAGS -traditional"
2938 fi
2939
2940 echo creating lib-src/Makefile
2941 ( cd lib-src
2942   rm -f junk.c junk1.c junk2.c
2943   sed -e '/start of cpp stuff/q' \
2944       < Makefile.c > junk1.c
2945   sed -e '1,/start of cpp stuff/d'\
2946       -e 's,/\*\*/#\(.*\)$,/* \1 */,' \
2947       < Makefile.c > junk.c
2948   $CPP $cpp_undefs -I. -I$srcdir/src $CPPFLAGS junk.c | \
2949       sed -e 's/^ /     /' -e '/^#/d' -e '/^[   \f]*$/d' > junk2.c
2950   cat junk1.c junk2.c > Makefile.new
2951   rm -f junk.c junk1.c junk2.c
2952   chmod 444 Makefile.new
2953   mv -f Makefile.new Makefile
2954 )
2955
2956 echo creating src/Makefile
2957 ( cd src
2958   rm -f junk.c junk1.c junk2.c
2959   sed -e '/start of cpp stuff/q' \
2960       < Makefile.c > junk1.c
2961   sed -e '1,/start of cpp stuff/d'\
2962       -e 's,/\*\*/#\(.*\)$,/* \1 */,' \
2963       < Makefile.c > junk.c
2964   $CPP $cpp_undefs -I. -I$srcdir/src $CPPFLAGS junk.c | \
2965       sed -e 's/^ /     /' -e '/^#/d' -e '/^[   \f]*$/d' > junk2.c
2966   cat junk1.c junk2.c > Makefile.new
2967   rm -f junk.c junk1.c junk2.c
2968   chmod 444 Makefile.new
2969   mv -f Makefile.new Makefile
2970 )
2971
2972 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
2973   echo creating src/.gdbinit
2974   echo source $srcdir/src/.gdbinit > src/.gdbinit
2975 fi
2976
2977 ], [GCC="$GCC" NON_GNU_CPP="$NON_GNU_CPP" CPP="$CPP" CPP_NEED_TRADITIONAL="$CPP_NEED_TRADITIONAL" CPPFLAGS="$CPPFLAGS" cpp_undefs="$cpp_undefs"])
2978
2979 m4_if(dnl       Do not change this comment
2980    arch-tag: 156a4dd5-bddc-4d18-96ac-f37742cf6a5e
2981 )dnl