code.delx.au - gnu-emacs/blob - lisp/progmodes/compile.el

   1 ;;; compile.el --- run compiler as inferior of Emacs, parse error messages
   2
   3 ;; Copyright (C) 1985, 1986, 1987, 1993, 1994, 1995, 1996, 1997, 1998, 1999,
   4 ;;   2001, 2003, 2004, 2005  Free Software Foundation, Inc.
   5
   6 ;; Authors: Roland McGrath <roland@gnu.org>,
   7 ;;          Daniel Pfeiffer <occitan@esperanto.org>
   8 ;; Maintainer: FSF
   9 ;; Keywords: tools, processes
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software; you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation; either version 2, or (at your option)
  16 ;; any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  25 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  26 ;; Boston, MA 02110-1301, USA.
  27
  28 ;;; Commentary:
  29
  30 ;; This package provides the compile facilities documented in the Emacs user's
  31 ;; manual.
  32
  33 ;; This mode uses some complex data-structures:
  34
  35 ;;   LOC (or location) is a list of (COLUMN LINE FILE-STRUCTURE)
  36
  37 ;; COLUMN and LINE are numbers parsed from an error message.  COLUMN and maybe
  38 ;; LINE will be nil for a message that doesn't contain them.  Then the
  39 ;; location refers to a indented beginning of line or beginning of file.
  40 ;; Once any location in some file has been jumped to, the list is extended to
  41 ;; (COLUMN LINE FILE-STRUCTURE MARKER . VISITED) for all LOCs pertaining to
  42 ;; that file.
  43 ;; MARKER initially points to LINE and COLUMN in a buffer visiting that file.
  44 ;; Being a marker it sticks to some text, when the buffer grows or shrinks
  45 ;; before that point.  VISITED is t if we have jumped there, else nil.
  46
  47 ;;   FILE-STRUCTURE is a list of
  48 ;;   ((FILENAME . DIRECTORY) FORMATS (LINE LOC ...) ...)
  49
  50 ;; FILENAME is a string parsed from an error message.  DIRECTORY is a string
  51 ;; obtained by following directory change messages.  DIRECTORY will be nil for
  52 ;; an absolute filename.  FORMATS is a list of formats to apply to FILENAME if
  53 ;; a file of that name can't be found.
  54 ;; The rest of the list is an alist of elements with LINE as key.  The keys
  55 ;; are either nil or line numbers.  If present, nil comes first, followed by
  56 ;; the numbers in decreasing order.  The LOCs for each line are again an alist
  57 ;; ordered the same way.  Note that the whole file structure is referenced in
  58 ;; every LOC.
  59
  60 ;;   MESSAGE is a list of (LOC TYPE END-LOC)
  61
  62 ;; TYPE is 0 for info or 1 for warning if the message matcher identified it as
  63 ;; such, 2 otherwise (for a real error).  END-LOC is a LOC pointing to the
  64 ;; other end, if the parsed message contained a range.  If the end of the
  65 ;; range didn't specify a COLUMN, it defaults to -1, meaning end of line.
  66 ;; These are the value of the `message' text-properties in the compilation
  67 ;; buffer.
  68
  69 ;;; Code:
  70
  71 (eval-when-compile (require 'cl))
  72
  73 (defgroup compilation nil
  74   "Run compiler as inferior of Emacs, parse error messages."
  75   :group 'tools
  76   :group 'processes)
  77
  78
  79 ;;;###autoload
  80 (defcustom compilation-mode-hook nil
  81   "*List of hook functions run by `compilation-mode' (see `run-mode-hooks')."
  82   :type 'hook
  83   :group 'compilation)
  84
  85 ;;;###autoload
  86 (defcustom compilation-window-height nil
  87   "*Number of lines in a compilation window.  If nil, use Emacs default."
  88   :type '(choice (const :tag "Default" nil)
  89                  integer)
  90   :group 'compilation)
  91
  92 (defvar compilation-first-column 1
  93   "*This is how compilers number the first column, usually 1 or 0.")
  94
  95 (defvar compilation-parse-errors-filename-function nil
  96   "Function to call to post-process filenames while parsing error messages.
  97 It takes one arg FILENAME which is the name of a file as found
  98 in the compilation output, and should return a transformed file name.")
  99
 100 ;;;###autoload
 101 (defvar compilation-process-setup-function nil
 102   "*Function to call to customize the compilation process.
 103 This function is called immediately before the compilation process is
 104 started.  It can be used to set any variables or functions that are used
 105 while processing the output of the compilation process.  The function
 106 is called with variables `compilation-buffer' and `compilation-window'
 107 bound to the compilation buffer and window, respectively.")
 108
 109 ;;;###autoload
 110 (defvar compilation-buffer-name-function nil
 111   "Function to compute the name of a compilation buffer.
 112 The function receives one argument, the name of the major mode of the
 113 compilation buffer.  It should return a string.
 114 nil means compute the name with `(concat \"*\" (downcase major-mode) \"*\")'.")
 115
 116 ;;;###autoload
 117 (defvar compilation-finish-function nil
 118   "Function to call when a compilation process finishes.
 119 It is called with two arguments: the compilation buffer, and a string
 120 describing how the process finished.")
 121
 122 (make-obsolete-variable 'compilation-finish-function
 123   "Use `compilation-finish-functions', but it works a little differently."
 124   "22.1")
 125
 126 ;;;###autoload
 127 (defvar compilation-finish-functions nil
 128   "Functions to call when a compilation process finishes.
 129 Each function is called with two arguments: the compilation buffer,
 130 and a string describing how the process finished.")
 131
 132 (defvar compilation-in-progress nil
 133   "List of compilation processes now running.")
 134 (or (assq 'compilation-in-progress minor-mode-alist)
 135     (setq minor-mode-alist (cons '(compilation-in-progress " Compiling")
 136                                  minor-mode-alist)))
 137
 138 (defvar compilation-error "error"
 139   "Stem of message to print when no matches are found.")
 140
 141 (defvar compilation-arguments nil
 142   "Arguments that were given to `compilation-start'.")
 143
 144 (defvar compilation-num-errors-found)
 145
 146 (defconst compilation-error-regexp-alist-alist
 147   '((absoft
 148      "^\\(?:[Ee]rror on \\|[Ww]arning on\\( \\)\\)?[Ll]ine[ \t]+\\([0-9]+\\)[ \t]+\
 149 of[ \t]+\"?\\([a-zA-Z]?:?[^\":\n]+\\)\"?:" 3 2 nil (1))
 150
 151     (ada
 152      "\\(warning: .*\\)? at \\([^ \n]+\\):\\([0-9]+\\)$" 2 3 nil (1))
 153
 154     (aix
 155      " in line \\([0-9]+\\) of file \\([^ \n]+[^. \n]\\)\\.? " 2 1)
 156
 157     (ant
 158      "^[ \t]*\\[[^] \n]+\\][ \t]*\\([^: \n]+\\):\\([0-9]+\\):\\(?:\\([0-9]+\\):[0-9]+:[0-9]+:\\)?\
 159 \\( warning\\)?" 1 2 3 (4))
 160
 161     (bash
 162      "^\\([^: \n\t]+\\): line \\([0-9]+\\):" 1 2)
 163
 164     (borland
 165      "^\\(?:Error\\|Warnin\\(g\\)\\) \\(?:[FEW][0-9]+ \\)?\
 166 \\([a-zA-Z]?:?[^:( \t\n]+\\)\
 167  \\([0-9]+\\)\\(?:[) \t]\\|:[^0-9\n]\\)" 2 3 nil (1))
 168
 169     (caml
 170      "^ *File \\(\"?\\)\\([^,\" \n\t<>]+\\)\\1, lines? \\([0-9]+\\)-?\\([0-9]+\\)?\\(?:$\\|,\
 171 \\(?: characters? \\([0-9]+\\)-?\\([0-9]+\\)?:\\)?\\([ \n]Warning:\\)?\\)"
 172      2 (3 . 4) (5 . 6) (7))
 173
 174     (comma
 175      "^\"\\([^,\" \n\t]+\\)\", line \\([0-9]+\\)\
 176 \\(?:[(. pos]+\\([0-9]+\\))?\\)?[:.,; (-]\\( warning:\\|[-0-9 ]*(W)\\)?" 1 2 3 (4))
 177
 178     (edg-1
 179      "^\\([^ \n]+\\)(\\([0-9]+\\)): \\(?:error\\|warnin\\(g\\)\\|remar\\(k\\)\\)"
 180      1 2 nil (3 . 4))
 181     (edg-2
 182      "at line \\([0-9]+\\) of \"\\([^ \n]+\\)\"$"
 183      2 1 nil 0)
 184
 185     (epc
 186      "^Error [0-9]+ at (\\([0-9]+\\):\\([^)\n]+\\))" 2 1)
 187
 188     (ftnchek
 189      "\\(^Warning .*\\)? line[ \n]\\([0-9]+\\)[ \n]\\(?:col \\([0-9]+\\)[ \n]\\)?file \\([^ :;\n]+\\)"
 190      4 2 3 (1))
 191
 192     (iar
 193      "^\"\\(.*\\)\",\\([0-9]+\\)\\s-+\\(?:Error\\|Warnin\\(g\\)\\)\\[[0-9]+\\]:"
 194      1 2 nil (3))
 195
 196     (ibm
 197      "^\\([^( \n\t]+\\)(\\([0-9]+\\):\\([0-9]+\\)) :\
 198  \\(?:warnin\\(g\\)\\|informationa\\(l\\)\\)?" 1 2 3 (4 . 5))
 199
 200     ;; fixme: should be `mips'
 201     (irix
 202      "^[-[:alnum:]_/ ]+: \\(?:\\(?:[sS]evere\\|[eE]rror\\|[wW]arnin\\(g\\)\\|[iI]nf\\(o\\)\\)[0-9 ]*: \\)?\
 203 \\([^,\" \n\t]+\\)\\(?:, line\\|:\\) \\([0-9]+\\):" 3 4 nil (1 . 2))
 204
 205     (java
 206      "^\\(?:[ \t]+at \\|==[0-9]+== +\\(?:at\\|b\\(y\\)\\)\\).+(\\([^()\n]+\\):\\([0-9]+\\))$" 2 3 nil (1))
 207
 208     (jikes-file
 209      "^\\(?:Found\\|Issued\\) .* compiling \"\\(.+\\)\":$" 1 nil nil 0)
 210     (jikes-line
 211      "^ *\\([0-9]+\\)\\.[ \t]+.*\n +\\(<-*>\n\\*\\*\\* \\(?:Error\\|Warnin\\(g\\)\\)\\)"
 212      nil 1 nil 2 0
 213      (2 (compilation-face '(3))))
 214
 215     (gcc-include
 216      "^\\(?:In file included\\|                \\) from \
 217 \\(.+\\):\\([0-9]+\\)\\(?:\\(:\\)\\|\\(,\\)\\)?" 1 2 nil (3 . 4))
 218
 219     (gnu
 220      "^\\(?:[[:alpha:]][-[:alnum:].]+: ?\\)?\
 221 \\([/.]*[a-zA-Z]:?[^ \t\n:]*\\|{standard input}\\): ?\
 222 \\([0-9]+\\)\\([.:]?\\)\\([0-9]+\\)?\
 223 \\(?:-\\(?:\\([0-9]+\\)\\3\\)?\\.?\\([0-9]+\\)?\\)?:\
 224 \\(?: *\\(\\(?:Future\\|Runtime\\)?[Ww]arning\\|W:\\)\\|\
 225  *\\([Ii]nfo\\(?:\\>\\|rmationa?l?\\)\\|I:\\)\\)?"
 226      1 (2 . 5) (4 . 6) (7 . 8))
 227
 228     (lcc
 229      "^\\(?:E\\|\\(W\\)\\), \\([^(\n]+\\)(\\([0-9]+\\),[ \t]*\\([0-9]+\\)"
 230      2 3 4 (1))
 231
 232     (makepp
 233      "^makepp: \\(?:\\(?:warning\\(:\\).*?\\|\\(Scanning\\|[LR]e?l?oading makefile\\) \\|.*?\\)\
 234 `\\(\\(\\S +?\\)\\(?::\\([0-9]+\\)\\)?\\)['(]\\)"
 235      4 5 nil (1 . 2) 3
 236      ("`\\(\\(\\S +?\\)\\(?::\\([0-9]+\\)\\)?\\)['(]" nil nil
 237       (2 compilation-info-face)
 238       (3 compilation-line-face nil t)
 239       (1 (compilation-error-properties 2 3 nil nil nil 0 nil)
 240          append)))
 241
 242     ;; Should be lint-1, lint-2 (SysV lint)
 243     (mips-1
 244      " (\\([0-9]+\\)) in \\([^ \n]+\\)" 2 1)
 245     (mips-2
 246      " in \\([^()\n ]+\\)(\\([0-9]+\\))$" 1 2)
 247
 248     (msft
 249      "^\\([0-9]+>\\)?\\(\\(?:[a-zA-Z]:\\)?[^:(\t\n]+\\)(\\([0-9]+\\)) \
 250 : \\(?:error\\|warnin\\(g\\)\\) C[0-9]+:" 2 3 nil (4))
 251
 252     (oracle
 253      "^\\(?:Semantic error\\|Error\\|PCC-[0-9]+:\\).* line \\([0-9]+\\)\
 254 \\(?:\\(?:,\\| at\\)? column \\([0-9]+\\)\\)?\
 255 \\(?:,\\| in\\| of\\)? file \\(.*?\\):?$"
 256      3 1 2)
 257
 258     (perl
 259      " at \\([^ \n]+\\) line \\([0-9]+\\)\\(?:[,.]\\|$\\)" 1 2)
 260
 261     (rxp
 262      "^\\(?:Error\\|Warnin\\(g\\)\\):.*\n.* line \\([0-9]+\\) char\
 263  \\([0-9]+\\) of file://\\(.+\\)"
 264      4 2 3 (1))
 265
 266     (sparc-pascal-file
 267      "^\\w\\w\\w \\w\\w\\w +[0-3]?[0-9] +[0-2][0-9]:[0-5][0-9]:[0-5][0-9]\
 268  [12][09][0-9][0-9] +\\(.*\\):$"
 269      1 nil nil 0)
 270     (sparc-pascal-line
 271      "^\\(\\(?:E\\|\\(w\\)\\) +[0-9]+\\) line \\([0-9]+\\) -  "
 272      nil 3 nil (2) nil (1 (compilation-face '(2))))
 273     (sparc-pascal-example
 274      "^ +\\([0-9]+\\) +.*\n\\(\\(?:e\\|\\(w\\)\\) [0-9]+\\)-+"
 275      nil 1 nil (3) nil (2 (compilation-face '(3))))
 276
 277     (sun
 278      ": \\(?:ERROR\\|WARNIN\\(G\\)\\|REMAR\\(K\\)\\) \\(?:[[:alnum:] ]+, \\)?\
 279 File = \\(.+\\), Line = \\([0-9]+\\)\\(?:, Column = \\([0-9]+\\)\\)?"
 280      3 4 5 (1 . 2))
 281
 282     (sun-ada
 283      "^\\([^, \n\t]+\\), line \\([0-9]+\\), char \\([0-9]+\\)[:., \(-]" 1 2 3)
 284
 285     (4bsd
 286      "\\(?:^\\|::  \\|\\S ( \\)\\(/[^ \n\t()]+\\)(\\([0-9]+\\))\
 287 \\(?:: \\(warning:\\)?\\|$\\| ),\\)" 1 2 nil (3))
 288
 289     (gcov-file
 290      "^ +-:    \\(0\\):Source:\\(.+\\)$" 2 1 nil 0)
 291     (gcov-bb-file
 292      "^ +-:    \\(0\\):Object:\\(?:.+\\)$" nil 1 nil 0)
 293     (gcov-never-called-line
 294      "^ +\\(#####\\): +\\([0-9]+\\):.+$" nil 2 nil 2 nil
 295      (1 compilation-error-face))
 296     (gcov-called-line
 297      "^ +[-0-9]+: +\\([1-9]\\|[0-9]\\{2,\\}\\):.*$" nil 1 nil 0)
 298 )
 299   "Alist of values for `compilation-error-regexp-alist'.")
 300
 301 (defcustom compilation-error-regexp-alist
 302   (mapcar 'car compilation-error-regexp-alist-alist)
 303   "Alist that specifies how to match errors in compiler output.
 304 Note that on Unix everything is a valid filename, so these
 305 matchers must make some common sense assumptions, which catch
 306 normal cases.  A shorter list will be lighter on resource usage.
 307
 308 Instead of an alist element, you can use a symbol, which is
 309 looked up in `compilation-error-regexp-alist-alist'.  You can see
 310 the predefined symbols and their effects in the file
 311 `etc/compilation.txt' (linked below if you are customizing this).
 312
 313 Each elt has the form (REGEXP FILE [LINE COLUMN TYPE HYPERLINK
 314 HIGHLIGHT...]).  If REGEXP matches, the FILE'th subexpression
 315 gives the file name, and the LINE'th subexpression gives the line
 316 number.  The COLUMN'th subexpression gives the column number on
 317 that line.
 318
 319 If FILE, LINE or COLUMN are nil or that index didn't match, that
 320 information is not present on the matched line.  In that case the
 321 file name is assumed to be the same as the previous one in the
 322 buffer, line number defaults to 1 and column defaults to
 323 beginning of line's indentation.
 324
 325 FILE can also have the form (FILE FORMAT...), where the FORMATs
 326 \(e.g. \"%s.c\") will be applied in turn to the recognized file
 327 name, until a file of that name is found.  Or FILE can also be a
 328 function to return the filename.
 329
 330 LINE can also be of the form (LINE . END-LINE) meaning a range
 331 of lines.  COLUMN can also be of the form (COLUMN . END-COLUMN)
 332 meaning a range of columns starting on LINE and ending on
 333 END-LINE, if that matched.
 334
 335 TYPE is 2 or nil for a real error or 1 for warning or 0 for info.
 336 TYPE can also be of the form (WARNING . INFO).  In that case this
 337 will be equivalent to 1 if the WARNING'th subexpression matched
 338 or else equivalent to 0 if the INFO'th subexpression matched.
 339 See `compilation-error-face', `compilation-warning-face',
 340 `compilation-info-face' and `compilation-skip-threshold'.
 341
 342 What matched the HYPERLINK'th subexpression has `mouse-face' and
 343 `compilation-message-face' applied.  If this is nil, the text
 344 matched by the whole REGEXP becomes the hyperlink.
 345
 346 Additional HIGHLIGHTs as described under `font-lock-keywords' can
 347 be added."
 348   :type `(set :menu-tag "Pick"
 349               ,@(mapcar (lambda (elt)
 350                           (list 'const (car elt)))
 351                         compilation-error-regexp-alist-alist))
 352   :link `(file-link :tag "example file"
 353                     ,(expand-file-name "compilation.txt" data-directory))
 354   :group 'compilation)
 355
 356 (defvar compilation-directory nil
 357   "Directory to restore to when doing `recompile'.")
 358
 359 (defvar compilation-directory-matcher
 360   '("\\(?:Entering\\|Leavin\\(g\\)\\) directory `\\(.+\\)'$" (2 . 1))
 361   "A list for tracking when directories are entered or left.
 362 Nil means not to track directories, e.g. if all file names are absolute.  The
 363 first element is the REGEXP matching these messages.  It can match any number
 364 of variants, e.g. different languages.  The remaining elements are all of the
 365 form (DIR .  LEAVE).  If for any one of these the DIR'th subexpression
 366 matches, that is a directory name.  If LEAVE is nil or the corresponding
 367 LEAVE'th subexpression doesn't match, this message is about going into another
 368 directory.  If it does match anything, this message is about going back to the
 369 directory we were in before the last entering message.  If you change this,
 370 you may also want to change `compilation-page-delimiter'.")
 371
 372 (defvar compilation-page-delimiter
 373   "^\\(?:\f\\|.*\\(?:Entering\\|Leaving\\) directory `.+'\n\\)+"
 374   "Value of `page-delimiter' in Compilation mode.")
 375
 376 (defvar compilation-mode-font-lock-keywords
 377    '(;; configure output lines.
 378      ("^[Cc]hecking \\(?:[Ff]or \\|[Ii]f \\|[Ww]hether \\(?:to \\)?\\)?\\(.+\\)\\.\\.\\. *\\(?:(cached) *\\)?\\(\\(yes\\(?: .+\\)?\\)\\|no\\|\\(.*\\)\\)$"
 379       (1 font-lock-variable-name-face)
 380       (2 (compilation-face '(4 . 3))))
 381      ;; Command output lines.  Recognize `make[n]:' lines too.
 382      ("^\\([[:alnum:]_/.+-]+\\)\\(\\[\\([0-9]+\\)\\]\\)?[ \t]*:"
 383       (1 font-lock-function-name-face) (3 compilation-line-face nil t))
 384      (" --?o\\(?:utfile\\|utput\\)?[= ]?\\(\\S +\\)" . 1)
 385      ("^Compilation finished" . compilation-info-face)
 386      ("^Compilation exited abnormally" . compilation-error-face))
 387    "Additional things to highlight in Compilation mode.
 388 This gets tacked on the end of the generated expressions.")
 389
 390 (defvar compilation-highlight-regexp t
 391   "Regexp matching part of visited source lines to highlight temporarily.
 392 Highlight entire line if t; don't highlight source lines if nil.")
 393
 394 (defvar compilation-highlight-overlay nil
 395   "Overlay used to temporarily highlight compilation matches.")
 396
 397 (defcustom compilation-error-screen-columns t
 398   "*If non-nil, column numbers in error messages are screen columns.
 399 Otherwise they are interpreted as character positions, with
 400 each character occupying one column.
 401 The default is to use screen columns, which requires that the compilation
 402 program and Emacs agree about the display width of the characters,
 403 especially the TAB character."
 404   :type 'boolean
 405   :group 'compilation
 406   :version "20.4")
 407
 408 (defcustom compilation-read-command t
 409   "*Non-nil means \\[compile] reads the compilation command to use.
 410 Otherwise, \\[compile] just uses the value of `compile-command'."
 411   :type 'boolean
 412   :group 'compilation)
 413
 414 ;;;###autoload
 415 (defcustom compilation-ask-about-save t
 416   "*Non-nil means \\[compile] asks which buffers to save before compiling.
 417 Otherwise, it saves all modified buffers without asking."
 418   :type 'boolean
 419   :group 'compilation)
 420
 421 ;;;###autoload
 422 (defcustom compilation-search-path '(nil)
 423   "*List of directories to search for source files named in error messages.
 424 Elements should be directory names, not file names of directories.
 425 nil as an element means to try the default directory."
 426   :type '(repeat (choice (const :tag "Default" nil)
 427                          (string :tag "Directory")))
 428   :group 'compilation)
 429
 430 (defcustom compile-command "make -k "
 431   "*Last shell command used to do a compilation; default for next compilation.
 432
 433 Sometimes it is useful for files to supply local values for this variable.
 434 You might also use mode hooks to specify it in certain modes, like this:
 435
 436     (add-hook 'c-mode-hook
 437        (lambda ()
 438          (unless (or (file-exists-p \"makefile\")
 439                      (file-exists-p \"Makefile\"))
 440            (set (make-local-variable 'compile-command)
 441                 (concat \"make -k \"
 442                         (file-name-sans-extension buffer-file-name))))))"
 443   :type 'string
 444   :group 'compilation)
 445
 446 ;; A weak per-compilation-buffer hash indexed by (FILENAME . DIRECTORY).  Each
 447 ;; value is a FILE-STRUCTURE as described above, with the car eq to the hash
 448 ;; key.  This holds the tree seen from root, for storing new nodes.
 449 (defvar compilation-locs ())
 450
 451 (defvar compilation-debug nil
 452   "*Set this to t before creating a *compilation* buffer.
 453 Then every error line will have a debug text property with the matcher that
 454 fit this line and the match data.  Use `describe-text-properties'.")
 455
 456 (defvar compilation-exit-message-function nil "\
 457 If non-nil, called when a compilation process dies to return a status message.
 458 This should be a function of three arguments: process status, exit status,
 459 and exit message; it returns a cons (MESSAGE . MODELINE) of the strings to
 460 write into the compilation buffer, and to put in its mode line.")
 461
 462 (defvar compilation-environment nil
 463   "*List of environment variables for compilation to inherit.
 464 Each element should be a string of the form ENVVARNAME=VALUE.
 465 This list is temporarily prepended to `process-environment' prior to
 466 starting the compilation process.")
 467
 468 ;; History of compile commands.
 469 (defvar compile-history nil)
 470
 471 (defface compilation-warning
 472   '((((class color) (min-colors 16)) (:foreground "Orange" :weight bold))
 473     (((class color)) (:foreground "cyan" :weight bold))
 474     (t (:weight bold)))
 475   "Face used to highlight compiler warnings."
 476   :group 'font-lock-highlighting-faces
 477   :version "22.1")
 478 ;; backward-compatibility alias
 479 (put 'compilation-warning-face 'face-alias 'compilation-warning)
 480
 481 (defface compilation-info
 482   '((((class color) (min-colors 16) (background light))
 483      (:foreground "Green3" :weight bold))
 484     (((class color) (min-colors 88) (background dark))
 485      (:foreground "Green1" :weight bold))
 486     (((class color) (min-colors 16) (background dark))
 487      (:foreground "Green" :weight bold))
 488     (((class color)) (:foreground "green" :weight bold))
 489     (t (:weight bold)))
 490   "Face used to highlight compiler warnings."
 491   :group 'font-lock-highlighting-faces
 492   :version "22.1")
 493 ;; backward-compatibility alias
 494 (put 'compilation-info-face 'face-alias 'compilation-info)
 495
 496 (defface compilation-error-file-name
 497   '((default :inherit font-lock-warning-face)
 498     (((supports :underline t)) :underline t))
 499   "Face for displaying file names in compilation errors."
 500   :group 'font-lock-highlighting-faces
 501   :version "22.1")
 502
 503 (defface compilation-warning-file-name
 504   '((default :inherit font-lock-warning-face)
 505     (((supports :underline t)) :underline t))
 506   "Face for displaying file names in compilation errors."
 507   :group 'font-lock-highlighting-faces
 508   :version "22.1")
 509
 510 (defface compilation-info-file-name
 511   '((default :inherit compilation-info)
 512     (((supports :underline t)) :underline t))
 513   "Face for displaying file names in compilation errors."
 514   :group 'font-lock-highlighting-faces
 515   :version "22.1")
 516
 517 (defface compilation-line-number
 518   '((default :inherit font-lock-variable-name-face)
 519     (((supports :underline t)) :underline t))
 520   "Face for displaying file names in compilation errors."
 521   :group 'font-lock-highlighting-faces
 522   :version "22.1")
 523
 524 (defface compilation-column-number
 525   '((default :inherit font-lock-type-face)
 526     (((supports :underline t)) :underline t))
 527   "Face for displaying file names in compilation errors."
 528   :group 'font-lock-highlighting-faces
 529   :version "22.1")
 530
 531 (defvar compilation-message-face nil
 532   "Face name to use for whole messages.
 533 Faces `compilation-error-face', `compilation-warning-face',
 534 `compilation-info-face', `compilation-line-face' and
 535 `compilation-column-face' get prepended to this, when applicable.")
 536
 537 (defvar compilation-error-face 'compilation-error-file-name
 538   "Face name to use for file name in error messages.")
 539
 540 (defvar compilation-warning-face 'compilation-warning-file-name
 541   "Face name to use for file name in warning messages.")
 542
 543 (defvar compilation-info-face 'compilation-info-file-name
 544   "Face name to use for file name in informational messages.")
 545
 546 (defvar compilation-line-face 'compilation-line-number
 547   "Face name to use for line number in message.")
 548
 549 (defvar compilation-column-face 'compilation-column-number
 550   "Face name to use for column number in message.")
 551
 552 ;; same faces as dired uses
 553 (defvar compilation-enter-directory-face 'font-lock-function-name-face
 554   "Face name to use for column number in message.")
 555
 556 (defvar compilation-leave-directory-face 'font-lock-type-face
 557   "Face name to use for column number in message.")
 558
 559
 560
 561 ;; Used for compatibility with the old compile.el.
 562 (defvaralias 'compilation-last-buffer 'next-error-last-buffer)
 563 (defvar compilation-parsing-end (make-marker))
 564 (defvar compilation-parse-errors-function nil)
 565 (defvar compilation-error-list nil)
 566 (defvar compilation-old-error-list nil)
 567
 568 (defun compilation-face (type)
 569   (or (and (car type) (match-end (car type)) compilation-warning-face)
 570       (and (cdr type) (match-end (cdr type)) compilation-info-face)
 571       compilation-error-face))
 572
 573 ;; Internal function for calculating the text properties of a directory
 574 ;; change message.  The directory property is important, because it is
 575 ;; the stack of nested enter-messages.  Relative filenames on the following
 576 ;; lines are relative to the top of the stack.
 577 (defun compilation-directory-properties (idx leave)
 578   (if leave (setq leave (match-end leave)))
 579   ;; find previous stack, and push onto it, or if `leave' pop it
 580   (let ((dir (previous-single-property-change (point) 'directory)))
 581     (setq dir (if dir (or (get-text-property (1- dir) 'directory)
 582                           (get-text-property dir 'directory))))
 583     `(face ,(if leave
 584                 compilation-leave-directory-face
 585               compilation-enter-directory-face)
 586       directory ,(if leave
 587                      (or (cdr dir)
 588                          '(nil))        ; nil only isn't a property-change
 589                    (cons (match-string-no-properties idx) dir))
 590       mouse-face highlight
 591       keymap compilation-button-map
 592       help-echo "mouse-2: visit current directory")))
 593
 594 ;; Data type `reverse-ordered-alist' retriever.  This function retrieves the
 595 ;; KEY element from the ALIST, creating it in the right position if not already
 596 ;; present. ALIST structure is
 597 ;; '(ANCHOR (KEY1 ...) (KEY2 ...)... (KEYn ALIST ...))
 598 ;; ANCHOR is ignored, but necessary so that elements can be inserted.  KEY1
 599 ;; may be nil.  The other KEYs are ordered backwards so that growing line
 600 ;; numbers can be inserted in front and searching can abort after half the
 601 ;; list on average.
 602 (eval-when-compile                  ;Don't keep it at runtime if not needed.
 603 (defmacro compilation-assq (key alist)
 604   `(let* ((l1 ,alist)
 605           (l2 (cdr l1)))
 606      (car (if (if (null ,key)
 607                   (if l2 (null (caar l2)))
 608                 (while (if l2 (if (caar l2) (< ,key (caar l2)) t))
 609                   (setq l1 l2
 610                         l2 (cdr l1)))
 611                 (if l2 (eq ,key (caar l2))))
 612               l2
 613             (setcdr l1 (cons (list ,key) l2)))))))
 614
 615
 616 ;; This function is the central driver, called when font-locking to gather
 617 ;; all information needed to later jump to corresponding source code.
 618 ;; Return a property list with all meta information on this error location.
 619 (defun compilation-error-properties (file line end-line col end-col type fmt)
 620   (unless (< (next-single-property-change (match-beginning 0) 'directory nil (point))
 621              (point))
 622     (if file
 623         (if (functionp file)
 624             (setq file (funcall file))
 625           (let (dir)
 626             (setq file (match-string-no-properties file))
 627             (unless (file-name-absolute-p file)
 628               (setq dir (previous-single-property-change (point) 'directory)
 629                     dir (if dir (or (get-text-property (1- dir) 'directory)
 630                                     (get-text-property dir 'directory)))))
 631             (setq file (cons file (car dir)))))
 632       ;; This message didn't mention one, get it from previous
 633       (setq file (previous-single-property-change (point) 'message)
 634             file (or (if file
 635                          (car (nth 2 (car (or (get-text-property (1- file) 'message)
 636                                          (get-text-property file 'message))))))
 637                      '("*unknown*"))))
 638     ;; All of these fields are optional, get them only if we have an index, and
 639     ;; it matched some part of the message.
 640     (and line
 641          (setq line (match-string-no-properties line))
 642          (setq line (string-to-number line)))
 643     (and end-line
 644          (setq end-line (match-string-no-properties end-line))
 645          (setq end-line (string-to-number end-line)))
 646     (if col
 647         (if (functionp col)
 648             (setq col (funcall col))
 649           (and
 650            (setq col (match-string-no-properties col))
 651            (setq col (- (string-to-number col) compilation-first-column)))))
 652     (if (and end-col (functionp end-col))
 653         (setq end-col (funcall end-col))
 654       (if (and end-col (setq end-col (match-string-no-properties end-col)))
 655           (setq end-col (- (string-to-number end-col) compilation-first-column -1))
 656         (if end-line (setq end-col -1))))
 657     (if (consp type)                    ; not a static type, check what it is.
 658         (setq type (or (and (car type) (match-end (car type)) 1)
 659                        (and (cdr type) (match-end (cdr type)) 0)
 660                        2)))
 661     (compilation-internal-error-properties file line end-line col end-col type fmt)))
 662
 663 (defun compilation-move-to-column (col screen)
 664   "Go to column COL on the current line.
 665 If SCREEN is non-nil, columns are screen columns, otherwise, they are
 666 just char-counts."
 667   (if screen
 668       (move-to-column col)
 669     (goto-char (min (+ (line-beginning-position) col) (line-end-position)))))
 670
 671 (defun compilation-internal-error-properties (file line end-line col end-col type fmt)
 672   "Get the meta-info that will be added as text-properties.
 673 LINE, END-LINE, COL, END-COL are integers or nil.
 674 TYPE can be 0, 1, or 2.
 675 FILE should be (ABSOLUTE-FILENAME) or (RELATIVE-FILENAME . DIRNAME) or nil."
 676   (unless file (setq file '("*unknown*")))
 677   (setq file (compilation-get-file-structure file fmt))
 678   ;; Get first already existing marker (if any has one, all have one).
 679   ;; Do this first, as the compilation-assq`s may create new nodes.
 680   (let* ((marker-line (car (cddr file)))        ; a line structure
 681          (marker (nth 3 (cadr marker-line)))    ; its marker
 682          (compilation-error-screen-columns compilation-error-screen-columns)
 683          end-marker loc end-loc)
 684     (if (not (and marker (marker-buffer marker)))
 685         (setq marker)                   ; no valid marker for this file
 686       (setq loc (or line 1))            ; normalize no linenumber to line 1
 687       (catch 'marker                    ; find nearest loc, at least one exists
 688         (dolist (x (nthcdr 3 file))     ; loop over remaining lines
 689           (if (> (car x) loc)           ; still bigger
 690               (setq marker-line x)
 691             (if (> (- (or (car marker-line) 1) loc)
 692                    (- loc (car x)))     ; current line is nearer
 693                 (setq marker-line x))
 694             (throw 'marker t))))
 695       (setq marker (nth 3 (cadr marker-line))
 696             marker-line (or (car marker-line) 1))
 697       (with-current-buffer (marker-buffer marker)
 698         (save-restriction
 699           (widen)
 700           (goto-char (marker-position marker))
 701           (when (or end-col end-line)
 702             (beginning-of-line (- (or end-line line) marker-line -1))
 703             (if (or (null end-col) (< end-col 0))
 704                 (end-of-line)
 705               (compilation-move-to-column
 706                end-col compilation-error-screen-columns))
 707             (setq end-marker (list (point-marker))))
 708           (beginning-of-line (if end-line
 709                                  (- line end-line -1)
 710                                (- loc marker-line -1)))
 711           (if col
 712               (compilation-move-to-column
 713                col compilation-error-screen-columns)
 714             (forward-to-indentation 0))
 715           (setq marker (list (point-marker))))))
 716
 717     (setq loc (compilation-assq line (cdr file)))
 718     (if end-line
 719         (setq end-loc (compilation-assq end-line (cdr file))
 720               end-loc (compilation-assq end-col end-loc))
 721       (if end-col                       ; use same line element
 722           (setq end-loc (compilation-assq end-col loc))))
 723     (setq loc (compilation-assq col loc))
 724     ;; If they are new, make the loc(s) reference the file they point to.
 725     (or (cdr loc) (setcdr loc `(,line ,file ,@marker)))
 726     (if end-loc
 727         (or (cdr end-loc) (setcdr end-loc `(,(or end-line line) ,file ,@end-marker))))
 728
 729     ;; Must start with face
 730     `(face ,compilation-message-face
 731            message (,loc ,type ,end-loc)
 732            ,@(if compilation-debug
 733                  `(debug (,(assoc (with-no-warnings matcher) font-lock-keywords)
 734                           ,@(match-data))))
 735            help-echo ,(if col
 736                           "mouse-2: visit this file, line and column"
 737                         (if line
 738                             "mouse-2: visit this file and line"
 739                           "mouse-2: visit this file"))
 740            keymap compilation-button-map
 741            mouse-face highlight)))
 742
 743 (defun compilation-mode-font-lock-keywords ()
 744   "Return expressions to highlight in Compilation mode."
 745   (if compilation-parse-errors-function
 746       ;; An old package!  Try the compatibility code.
 747       '((compilation-compat-parse-errors))
 748     (append
 749      ;; make directory tracking
 750      (if compilation-directory-matcher
 751          `((,(car compilation-directory-matcher)
 752             ,@(mapcar (lambda (elt)
 753                         `(,(car elt)
 754                           (compilation-directory-properties
 755                            ,(car elt) ,(cdr elt))
 756                           t t))
 757                       (cdr compilation-directory-matcher)))))
 758
 759      ;; Compiler warning/error lines.
 760      (mapcar
 761       (lambda (item)
 762         (if (symbolp item)
 763             (setq item (cdr (assq item
 764                                   compilation-error-regexp-alist-alist))))
 765         (let ((file (nth 1 item))
 766               (line (nth 2 item))
 767               (col (nth 3 item))
 768               (type (nth 4 item))
 769               end-line end-col fmt)
 770           (if (consp file)      (setq fmt (cdr file)      file (car file)))
 771           (if (consp line)      (setq end-line (cdr line) line (car line)))
 772           (if (consp col)       (setq end-col (cdr col)   col (car col)))
 773
 774           (if (functionp line)
 775               ;; The old compile.el had here an undocumented hook that
 776               ;; allowed `line' to be a function that computed the actual
 777               ;; error location.  Let's do our best.
 778               `(,(car item)
 779                 (0 (save-match-data
 780                      (compilation-compat-error-properties
 781                       (funcall ',line (cons (match-string ,file)
 782                                             (cons default-directory
 783                                                   ',(nthcdr 4 item)))
 784                                ,(if col `(match-string ,col))))))
 785                 (,file compilation-error-face t))
 786
 787             (unless (or (null (nth 5 item)) (integerp (nth 5 item)))
 788               (error "HYPERLINK should be an integer: %s" (nth 5 item)))
 789
 790             `(,(nth 0 item)
 791
 792               ,@(when (integerp file)
 793                   `((,file ,(if (consp type)
 794                                 `(compilation-face ',type)
 795                               (aref [compilation-info-face
 796                                      compilation-warning-face
 797                                      compilation-error-face]
 798                                     (or type 2))))))
 799
 800               ,@(when line
 801                   `((,line compilation-line-face nil t)))
 802               ,@(when end-line
 803                   `((,end-line compilation-line-face nil t)))
 804
 805               ,@(when (integerp col)
 806                   `((,col compilation-column-face nil t)))
 807               ,@(when (integerp end-col)
 808                   `((,end-col compilation-column-face nil t)))
 809
 810               ,@(nthcdr 6 item)
 811               (,(or (nth 5 item) 0)
 812                (compilation-error-properties ',file ,line ,end-line
 813                                              ,col ,end-col ',(or type 2)
 814                                              ',fmt)
 815                append)))))              ; for compilation-message-face
 816       compilation-error-regexp-alist)
 817
 818      compilation-mode-font-lock-keywords)))
 819
 820 \f
 821 ;;;###autoload
 822 (defun compile (command &optional comint)
 823   "Compile the program including the current buffer.  Default: run `make'.
 824 Runs COMMAND, a shell command, in a separate process asynchronously
 825 with output going to the buffer `*compilation*'.
 826
 827 If optional second arg COMINT is t the buffer will be in Comint mode with
 828 `compilation-shell-minor-mode'.
 829
 830 You can then use the command \\[next-error] to find the next error message
 831 and move to the source code that caused it.
 832
 833 Interactively, prompts for the command if `compilation-read-command' is
 834 non-nil; otherwise uses `compile-command'.  With prefix arg, always prompts.
 835 Additionally, with universal prefix arg, compilation buffer will be in
 836 comint mode, i.e. interactive.
 837
 838 To run more than one compilation at once, start one and rename
 839 the \`*compilation*' buffer to some other name with
 840 \\[rename-buffer].  Then start the next one.  On most systems,
 841 termination of the main compilation process kills its
 842 subprocesses.
 843
 844 The name used for the buffer is actually whatever is returned by
 845 the function in `compilation-buffer-name-function', so you can set that
 846 to a function that generates a unique name."
 847   (interactive
 848    (list
 849     (let ((command (eval compile-command)))
 850       (if (or compilation-read-command current-prefix-arg)
 851           (read-from-minibuffer "Compile command: "
 852                                 command nil nil
 853                                 (if (equal (car compile-history) command)
 854                                     '(compile-history . 1)
 855                                   'compile-history))
 856         command))
 857     (consp current-prefix-arg)))
 858   (unless (equal command (eval compile-command))
 859     (setq compile-command command))
 860   (save-some-buffers (not compilation-ask-about-save) nil)
 861   (setq compilation-directory default-directory)
 862   (compilation-start command comint))
 863
 864 ;; run compile with the default command line
 865 (defun recompile ()
 866   "Re-compile the program including the current buffer.
 867 If this is run in a Compilation mode buffer, re-use the arguments from the
 868 original use.  Otherwise, recompile using `compile-command'."
 869   (interactive)
 870   (save-some-buffers (not compilation-ask-about-save) nil)
 871   (let ((default-directory
 872           (or (and (not (eq major-mode (nth 1 compilation-arguments)))
 873                    compilation-directory)
 874               default-directory)))
 875     (apply 'compilation-start (or compilation-arguments
 876                                   `(,(eval compile-command))))))
 877
 878 (defcustom compilation-scroll-output nil
 879   "*Non-nil to scroll the *compilation* buffer window as output appears.
 880
 881 Setting it causes the Compilation mode commands to put point at the
 882 end of their output window so that the end of the output is always
 883 visible rather than the beginning."
 884   :type 'boolean
 885   :version "20.3"
 886   :group 'compilation)
 887
 888
 889 (defun compilation-buffer-name (mode-name name-function)
 890   "Return the name of a compilation buffer to use.
 891 If NAME-FUNCTION is non-nil, call it with one argument MODE-NAME
 892 to determine the buffer name.
 893 Likewise if `compilation-buffer-name-function' is non-nil.
 894 If current buffer is in Compilation mode for the same mode name
 895 return the name of the current buffer, so that it gets reused.
 896 Otherwise, construct a buffer name from MODE-NAME."
 897   (cond (name-function
 898          (funcall name-function mode-name))
 899         (compilation-buffer-name-function
 900          (funcall compilation-buffer-name-function mode-name))
 901         ((eq major-mode (nth 1 compilation-arguments))
 902          (buffer-name))
 903         (t
 904          (concat "*" (downcase mode-name) "*"))))
 905
 906 ;; This is a rough emulation of the old hack, until the transition to new
 907 ;; compile is complete.
 908 (defun compile-internal (command error-message
 909                                  &optional name-of-mode parser
 910                                  error-regexp-alist name-function
 911                                  enter-regexp-alist leave-regexp-alist
 912                                  file-regexp-alist nomessage-regexp-alist
 913                                  no-async highlight-regexp local-map)
 914   (if parser
 915       (error "Compile now works very differently, see `compilation-error-regexp-alist'"))
 916   (let ((compilation-error-regexp-alist
 917          (append file-regexp-alist (or error-regexp-alist
 918                                        compilation-error-regexp-alist)))
 919         (compilation-error (replace-regexp-in-string "^No more \\(.+\\)s\\.?"
 920                                                      "\\1" error-message)))
 921     (compilation-start command nil name-function highlight-regexp)))
 922 (make-obsolete 'compile-internal 'compilation-start)
 923
 924 (defun compilation-start (command &optional mode name-function highlight-regexp)
 925   "Run compilation command COMMAND (low level interface).
 926 If COMMAND starts with a cd command, that becomes the `default-directory'.
 927 The rest of the arguments are optional; for them, nil means use the default.
 928
 929 MODE is the major mode to set in the compilation buffer.  Mode
 930 may also be t meaning use `compilation-shell-minor-mode' under `comint-mode'.
 931 NAME-FUNCTION is a function called to name the buffer.
 932
 933 If HIGHLIGHT-REGEXP is non-nil, `next-error' will temporarily highlight
 934 the matching section of the visited source line; the default is to use the
 935 global value of `compilation-highlight-regexp'.
 936
 937 Returns the compilation buffer created."
 938   (or mode (setq mode 'compilation-mode))
 939   (let* ((name-of-mode
 940           (if (eq mode t)
 941               (prog1 "compilation" (require 'comint))
 942             (replace-regexp-in-string "-mode$" "" (symbol-name mode))))
 943          (thisdir default-directory)
 944          outwin outbuf)
 945     (with-current-buffer
 946         (setq outbuf
 947               (get-buffer-create
 948                (compilation-buffer-name name-of-mode name-function)))
 949       (let ((comp-proc (get-buffer-process (current-buffer))))
 950         (if comp-proc
 951             (if (or (not (eq (process-status comp-proc) 'run))
 952                     (yes-or-no-p
 953                      (format "A %s process is running; kill it? "
 954                              name-of-mode)))
 955                 (condition-case ()
 956                     (progn
 957                       (interrupt-process comp-proc)
 958                       (sit-for 1)
 959                       (delete-process comp-proc))
 960                   (error nil))
 961               (error "Cannot have two processes in `%s' at once"
 962                      (buffer-name)))))
 963       (buffer-disable-undo (current-buffer))
 964       ;; first transfer directory from where M-x compile was called
 965       (setq default-directory thisdir)
 966       ;; Make compilation buffer read-only.  The filter can still write it.
 967       ;; Clear out the compilation buffer.
 968       (let ((inhibit-read-only t)
 969             (default-directory thisdir))
 970         ;; Then evaluate a cd command if any, but don't perform it yet, else start-command
 971         ;; would do it again through the shell: (cd "..") AND sh -c "cd ..; make"
 972         (cd (if (string-match "^\\s *cd\\(?:\\s +\\(\\S +?\\)\\)?\\s *[;&\n]" command)
 973                 (if (match-end 1)
 974                     (substitute-env-vars (match-string 1 command))
 975                   "~")
 976               default-directory))
 977         (erase-buffer)
 978         ;; Select the desired mode.
 979         (if (not (eq mode t))
 980             (funcall mode)
 981           (setq buffer-read-only nil)
 982           (with-no-warnings (comint-mode))
 983           (compilation-shell-minor-mode))
 984         (if highlight-regexp
 985             (set (make-local-variable 'compilation-highlight-regexp)
 986                  highlight-regexp))
 987         ;; Output a mode setter, for saving and later reloading this buffer.
 988         (insert "-*- mode: " name-of-mode
 989                 "; default-directory: " (prin1-to-string default-directory)
 990                 " -*-\n" command "\n")
 991         (setq thisdir default-directory))
 992       (set-buffer-modified-p nil))
 993     ;; If we're already in the compilation buffer, go to the end
 994     ;; of the buffer, so point will track the compilation output.
 995     (if (eq outbuf (current-buffer))
 996         (goto-char (point-max)))
 997     ;; Pop up the compilation buffer.
 998     (setq outwin (display-buffer outbuf nil t))
 999     (with-current-buffer outbuf
1000       (let ((process-environment
1001              (append
1002               compilation-environment
1003               (if (if (boundp 'system-uses-terminfo) ; `if' for compiler warning
1004                       system-uses-terminfo)
1005                   (list "TERM=dumb" "TERMCAP="
1006                         (format "COLUMNS=%d" (window-width)))
1007                 (list "TERM=emacs"
1008                       (format "TERMCAP=emacs:co#%d:tc=unknown:"
1009                               (window-width))))
1010               ;; Set the EMACS variable, but
1011               ;; don't override users' setting of $EMACS.
1012               (unless (getenv "EMACS") '("EMACS=t"))
1013               (copy-sequence process-environment))))
1014         (set (make-local-variable 'compilation-arguments)
1015              (list command mode name-function highlight-regexp))
1016         (set (make-local-variable 'revert-buffer-function)
1017              'compilation-revert-buffer)
1018         (set-window-start outwin (point-min))
1019         (or (eq outwin (selected-window))
1020             (set-window-point outwin (if compilation-scroll-output
1021                                          (point)
1022                                        (point-min))))
1023         ;; The setup function is called before compilation-set-window-height
1024         ;; so it can set the compilation-window-height buffer locally.
1025         (if compilation-process-setup-function
1026             (funcall compilation-process-setup-function))
1027         (compilation-set-window-height outwin)
1028         ;; Start the compilation.
1029         (if (fboundp 'start-process)
1030             (let ((proc (if (eq mode t)
1031                             (get-buffer-process
1032                              (with-no-warnings
1033                               (comint-exec outbuf (downcase mode-name)
1034                                            shell-file-name nil `("-c" ,command))))
1035                           (start-process-shell-command (downcase mode-name)
1036                                                        outbuf command))))
1037               ;; Make the buffer's mode line show process state.
1038               (setq mode-line-process '(":%s"))
1039               (set-process-sentinel proc 'compilation-sentinel)
1040               (set-process-filter proc 'compilation-filter)
1041               (set-marker (process-mark proc) (point) outbuf)
1042               (setq compilation-in-progress
1043                     (cons proc compilation-in-progress)))
1044           ;; No asynchronous processes available.
1045           (message "Executing `%s'..." command)
1046           ;; Fake modeline display as if `start-process' were run.
1047           (setq mode-line-process ":run")
1048           (force-mode-line-update)
1049           (sit-for 0)                   ; Force redisplay
1050           (let* ((buffer-read-only nil) ; call-process needs to modify outbuf
1051                  (status (call-process shell-file-name nil outbuf nil "-c"
1052                                        command)))
1053             (cond ((numberp status)
1054                    (compilation-handle-exit 'exit status
1055                                             (if (zerop status)
1056                                                 "finished\n"
1057                                               (format "\
1058 exited abnormally with code %d\n"
1059                                                       status))))
1060                   ((stringp status)
1061                    (compilation-handle-exit 'signal status
1062                                             (concat status "\n")))
1063                   (t
1064                    (compilation-handle-exit 'bizarre status status))))
1065           ;; Without async subprocesses, the buffer is not yet
1066           ;; fontified, so fontify it now.
1067           (let ((font-lock-verbose nil)) ; shut up font-lock messages
1068             (font-lock-fontify-buffer))
1069           (set-buffer-modified-p nil)
1070           (message "Executing `%s'...done" command)))
1071       ;; Now finally cd to where the shell started make/grep/...
1072       (setq default-directory thisdir))
1073     (if (buffer-local-value 'compilation-scroll-output outbuf)
1074         (save-selected-window
1075           (select-window outwin)
1076           (goto-char (point-max))))
1077     ;; Make it so the next C-x ` will use this buffer.
1078     (setq next-error-last-buffer outbuf)))
1079
1080 (defun compilation-set-window-height (window)
1081   "Set the height of WINDOW according to `compilation-window-height'."
1082   (let ((height (buffer-local-value 'compilation-window-height (window-buffer window))))
1083     (and height
1084          (= (window-width window) (frame-width (window-frame window)))
1085          ;; If window is alone in its frame, aside from a minibuffer,
1086          ;; don't change its height.
1087          (not (eq window (frame-root-window (window-frame window))))
1088          ;; Stef said that doing the saves in this order is safer:
1089          (save-excursion
1090            (save-selected-window
1091              (select-window window)
1092              (enlarge-window (- height (window-height))))))))
1093
1094 (defvar compilation-menu-map
1095   (let ((map (make-sparse-keymap "Errors")))
1096     (define-key map [stop-subjob]
1097       '("Stop Compilation" . kill-compilation))
1098     (define-key map [compilation-mode-separator2]
1099       '("----" . nil))
1100     (define-key map [compilation-first-error]
1101       '("First Error" . first-error))
1102     (define-key map [compilation-previous-error]
1103       '("Previous Error" . previous-error))
1104     (define-key map [compilation-next-error]
1105       '("Next Error" . next-error))
1106     map))
1107
1108 (defvar compilation-minor-mode-map
1109   (let ((map (make-sparse-keymap)))
1110     (define-key map [mouse-2] 'compile-goto-error)
1111     (define-key map [follow-link] 'mouse-face)
1112     (define-key map "\C-c\C-c" 'compile-goto-error)
1113     (define-key map "\C-m" 'compile-goto-error)
1114     (define-key map "\C-c\C-k" 'kill-compilation)
1115     (define-key map "\M-n" 'compilation-next-error)
1116     (define-key map "\M-p" 'compilation-previous-error)
1117     (define-key map "\M-{" 'compilation-previous-file)
1118     (define-key map "\M-}" 'compilation-next-file)
1119     ;; Set up the menu-bar
1120     (define-key map [menu-bar compilation]
1121       (cons "Errors" compilation-menu-map))
1122     map)
1123   "Keymap for `compilation-minor-mode'.")
1124
1125 (defvar compilation-shell-minor-mode-map
1126   (let ((map (make-sparse-keymap)))
1127     (define-key map "\M-\C-m" 'compile-goto-error)
1128     (define-key map "\M-\C-n" 'compilation-next-error)
1129     (define-key map "\M-\C-p" 'compilation-previous-error)
1130     (define-key map "\M-{" 'compilation-previous-file)
1131     (define-key map "\M-}" 'compilation-next-file)
1132     ;; Set up the menu-bar
1133     (define-key map [menu-bar compilation]
1134       (cons "Errors" compilation-menu-map))
1135     map)
1136   "Keymap for `compilation-shell-minor-mode'.")
1137
1138 (defvar compilation-button-map
1139   (let ((map (make-sparse-keymap)))
1140     (define-key map [mouse-2] 'compile-goto-error)
1141     (define-key map [follow-link] 'mouse-face)
1142     (define-key map "\C-m" 'compile-goto-error)
1143     map)
1144   "Keymap for compilation-message buttons.")
1145 (fset 'compilation-button-map compilation-button-map)
1146
1147 (defvar compilation-mode-map
1148   (let ((map (make-sparse-keymap)))
1149     ;; Don't inherit from compilation-minor-mode-map,
1150     ;; because that introduces a menu bar item we don't want.
1151     ;; That confuses C-down-mouse-3.
1152     (define-key map [mouse-2] 'compile-goto-error)
1153     (define-key map [follow-link] 'mouse-face)
1154     (define-key map "\C-c\C-c" 'compile-goto-error)
1155     (define-key map "\C-m" 'compile-goto-error)
1156     (define-key map "\C-c\C-k" 'kill-compilation)
1157     (define-key map "\M-n" 'compilation-next-error)
1158     (define-key map "\M-p" 'compilation-previous-error)
1159     (define-key map "\M-{" 'compilation-previous-file)
1160     (define-key map "\M-}" 'compilation-next-file)
1161
1162     (define-key map " " 'scroll-up)
1163     (define-key map "\^?" 'scroll-down)
1164     (define-key map "\C-c\C-f" 'next-error-follow-minor-mode)
1165
1166     ;; Set up the menu-bar
1167     (let ((submap (make-sparse-keymap "Compile")))
1168       (define-key map [menu-bar compilation]
1169         (cons "Compile" submap))
1170       (set-keymap-parent submap compilation-menu-map))
1171     (define-key map [menu-bar compilation compilation-separator2]
1172       '("----" . nil))
1173     (define-key map [menu-bar compilation compilation-grep]
1174       '("Search Files (grep)" . grep))
1175     (define-key map [menu-bar compilation compilation-recompile]
1176       '("Recompile" . recompile))
1177     (define-key map [menu-bar compilation compilation-compile]
1178       '("Compile..." . compile))
1179     map)
1180   "Keymap for compilation log buffers.
1181 `compilation-minor-mode-map' is a parent of this.")
1182
1183 (put 'compilation-mode 'mode-class 'special)
1184
1185 (defvar compilation-skip-to-next-location t
1186   "*If non-nil, skip multiple error messages for the same source location.")
1187
1188 (defcustom compilation-skip-threshold 1
1189   "*Compilation motion commands skip less important messages.
1190 The value can be either 2 -- skip anything less than error, 1 --
1191 skip anything less than warning or 0 -- don't skip any messages.
1192 Note that all messages not positively identified as warning or
1193 info, are considered errors."
1194   :type '(choice (const :tag "Warnings and info" 2)
1195                  (const :tag "Info" 1)
1196                  (const :tag "None" 0))
1197   :group 'compilation
1198   :version "22.1")
1199
1200 (defcustom compilation-skip-visited nil
1201   "*Compilation motion commands skip visited messages if this is t.
1202 Visited messages are ones for which the file, line and column have been jumped
1203 to from the current content in the current compilation buffer, even if it was
1204 from a different message."
1205   :type 'boolean
1206   :group 'compilation
1207   :version "22.1")
1208
1209 ;;;###autoload
1210 (defun compilation-mode (&optional name-of-mode)
1211   "Major mode for compilation log buffers.
1212 \\<compilation-mode-map>To visit the source for a line-numbered error,
1213 move point to the error message line and type \\[compile-goto-error].
1214 To kill the compilation, type \\[kill-compilation].
1215
1216 Runs `compilation-mode-hook' with `run-mode-hooks' (which see).
1217
1218 \\{compilation-mode-map}"
1219   (interactive)
1220   (kill-all-local-variables)
1221   (use-local-map compilation-mode-map)
1222   (setq major-mode 'compilation-mode
1223         mode-name (or name-of-mode "Compilation"))
1224   (set (make-local-variable 'page-delimiter)
1225        compilation-page-delimiter)
1226   (compilation-setup)
1227   (setq buffer-read-only t)
1228   (run-mode-hooks 'compilation-mode-hook))
1229
1230 (defmacro define-compilation-mode (mode name doc &rest body)
1231   "This is like `define-derived-mode' without the PARENT argument.
1232 The parent is always `compilation-mode' and the customizable `compilation-...'
1233 variables are also set from the name of the mode you have chosen, by replacing
1234 the fist word, e.g `compilation-scroll-output' from `grep-scroll-output' if that
1235 variable exists."
1236   (let ((mode-name (replace-regexp-in-string "-mode\\'" "" (symbol-name mode))))
1237     `(define-derived-mode ,mode compilation-mode ,name
1238        ,doc
1239        ,@(mapcar (lambda (v)
1240                    (setq v (cons v
1241                                  (intern-soft (replace-regexp-in-string
1242                                                "^compilation" mode-name
1243                                                (symbol-name v)))))
1244                    (and (cdr v)
1245                         (or (boundp (cdr v))
1246                             (if (boundp 'byte-compile-bound-variables)
1247                                 (memq (cdr v) byte-compile-bound-variables)))
1248                         `(set (make-local-variable ',(car v)) ,(cdr v))))
1249                  '(compilation-buffer-name-function
1250                    compilation-directory-matcher
1251                    compilation-error
1252                    compilation-error-regexp-alist
1253                    compilation-error-regexp-alist-alist
1254                    compilation-error-screen-columns
1255                    compilation-finish-function
1256                    compilation-finish-functions
1257                    compilation-first-column
1258                    compilation-mode-font-lock-keywords
1259                    compilation-page-delimiter
1260                    compilation-parse-errors-filename-function
1261                    compilation-process-setup-function
1262                    compilation-scroll-output
1263                    compilation-search-path
1264                    compilation-skip-threshold
1265                    compilation-window-height))
1266        ,@body)))
1267
1268 (defun compilation-revert-buffer (ignore-auto noconfirm)
1269   (if buffer-file-name
1270       (let (revert-buffer-function)
1271         (revert-buffer ignore-auto noconfirm))
1272     (if (or noconfirm (yes-or-no-p (format "Restart compilation? ")))
1273         (apply 'compilation-start compilation-arguments))))
1274
1275 (defvar compilation-current-error nil
1276   "Marker to the location from where the next error will be found.
1277 The global commands next/previous/first-error/goto-error use this.")
1278
1279 (defvar compilation-messages-start nil
1280   "Buffer position of the beginning of the compilation messages.
1281 If nil, use the beginning of buffer.")
1282
1283 ;; A function name can't be a hook, must be something with a value.
1284 (defconst compilation-turn-on-font-lock 'turn-on-font-lock)
1285
1286 (defun compilation-setup (&optional minor)
1287   "Prepare the buffer for the compilation parsing commands to work.
1288 Optional argument MINOR indicates this is called from
1289 `compilation-minor-mode'."
1290   (make-local-variable 'compilation-current-error)
1291   (make-local-variable 'compilation-messages-start)
1292   (make-local-variable 'compilation-error-screen-columns)
1293   (make-local-variable 'overlay-arrow-position)
1294   (set (make-local-variable 'overlay-arrow-string) "")
1295   (setq next-error-overlay-arrow-position nil)
1296   (add-hook 'kill-buffer-hook
1297             (lambda () (setq next-error-overlay-arrow-position nil)) nil t)
1298   ;; Note that compilation-next-error-function is for interfacing
1299   ;; with the next-error function in simple.el, and it's only
1300   ;; coincidentally named similarly to compilation-next-error.
1301   (setq next-error-function 'compilation-next-error-function)
1302   (set (make-local-variable 'font-lock-extra-managed-props)
1303        '(directory message help-echo mouse-face debug))
1304   (set (make-local-variable 'compilation-locs)
1305        (make-hash-table :test 'equal :weakness 'value))
1306   ;; lazy-lock would never find the message unless it's scrolled to.
1307   ;; jit-lock might fontify some things too late.
1308   (set (make-local-variable 'font-lock-support-mode) nil)
1309   (set (make-local-variable 'font-lock-maximum-size) nil)
1310   (let ((fld font-lock-defaults))
1311     (if (and minor fld)
1312         (font-lock-add-keywords nil (compilation-mode-font-lock-keywords))
1313       (setq font-lock-defaults '(compilation-mode-font-lock-keywords t)))
1314     (if minor
1315         (if font-lock-mode
1316             (if fld
1317                 (font-lock-fontify-buffer)
1318               (font-lock-change-mode)
1319               (turn-on-font-lock))
1320           (turn-on-font-lock))
1321       ;; maybe defer font-lock till after derived mode is set up
1322       (run-mode-hooks 'compilation-turn-on-font-lock))))
1323
1324 ;;;###autoload
1325 (define-minor-mode compilation-shell-minor-mode
1326   "Toggle compilation shell minor mode.
1327 With arg, turn compilation mode on if and only if arg is positive.
1328 In this minor mode, all the error-parsing commands of the
1329 Compilation major mode are available but bound to keys that don't
1330 collide with Shell mode.  See `compilation-mode'.
1331 Turning the mode on runs the normal hook `compilation-shell-minor-mode-hook'."
1332   nil " Shell-Compile"
1333   :group 'compilation
1334   (if compilation-shell-minor-mode
1335       (compilation-setup t)
1336     (font-lock-remove-keywords nil (compilation-mode-font-lock-keywords))
1337     (font-lock-fontify-buffer)))
1338
1339 ;;;###autoload
1340 (define-minor-mode compilation-minor-mode
1341   "Toggle compilation minor mode.
1342 With arg, turn compilation mode on if and only if arg is positive.
1343 In this minor mode, all the error-parsing commands of the
1344 Compilation major mode are available.  See `compilation-mode'.
1345 Turning the mode on runs the normal hook `compilation-minor-mode-hook'."
1346   nil " Compilation"
1347   :group 'compilation
1348   (if compilation-minor-mode
1349       (compilation-setup t)
1350     (font-lock-remove-keywords nil (compilation-mode-font-lock-keywords))
1351     (font-lock-fontify-buffer)))
1352
1353 (defun compilation-handle-exit (process-status exit-status msg)
1354   "Write MSG in the current buffer and hack its mode-line-process."
1355   (let ((inhibit-read-only t)
1356         (status (if compilation-exit-message-function
1357                     (funcall compilation-exit-message-function
1358                              process-status exit-status msg)
1359                   (cons msg exit-status)))
1360         (omax (point-max))
1361         (opoint (point)))
1362     ;; Record where we put the message, so we can ignore it later on.
1363     (goto-char omax)
1364     (insert ?\n mode-name " " (car status))
1365     (if (and (numberp compilation-window-height)
1366              (zerop compilation-window-height))
1367         (message "%s" (cdr status)))
1368     (if (bolp)
1369         (forward-char -1))
1370     (insert " at " (substring (current-time-string) 0 19))
1371     (goto-char (point-max))
1372     ;; Prevent that message from being recognized as a compilation error.
1373     (add-text-properties omax (point)
1374                          (append '(compilation-handle-exit t) nil))
1375     (setq mode-line-process (format ":%s [%s]" process-status (cdr status)))
1376     ;; Force mode line redisplay soon.
1377     (force-mode-line-update)
1378     (if (and opoint (< opoint omax))
1379         (goto-char opoint))
1380     (with-no-warnings
1381       (if compilation-finish-function
1382           (funcall compilation-finish-function (current-buffer) msg)))
1383     (let ((functions compilation-finish-functions))
1384       (while functions
1385         (funcall (car functions) (current-buffer) msg)
1386         (setq functions (cdr functions))))))
1387
1388 ;; Called when compilation process changes state.
1389 (defun compilation-sentinel (proc msg)
1390   "Sentinel for compilation buffers."
1391   (if (memq (process-status proc) '(exit signal))
1392       (let ((buffer (process-buffer proc)))
1393         (if (null (buffer-name buffer))
1394             ;; buffer killed
1395             (set-process-buffer proc nil)
1396           (with-current-buffer buffer
1397             ;; Write something in the compilation buffer
1398             ;; and hack its mode line.
1399             (compilation-handle-exit (process-status proc)
1400                                      (process-exit-status proc)
1401                                      msg)
1402             ;; Since the buffer and mode line will show that the
1403             ;; process is dead, we can delete it now.  Otherwise it
1404             ;; will stay around until M-x list-processes.
1405             (delete-process proc)))
1406         (setq compilation-in-progress (delq proc compilation-in-progress)))))
1407
1408 (defun compilation-filter (proc string)
1409   "Process filter for compilation buffers.
1410 Just inserts the text, but uses `insert-before-markers'."
1411   (if (buffer-name (process-buffer proc))
1412       (with-current-buffer (process-buffer proc)
1413         (let ((inhibit-read-only t))
1414           (save-excursion
1415             (goto-char (process-mark proc))
1416             (insert-before-markers string)
1417             (run-hooks 'compilation-filter-hook))))))
1418
1419 ;;; test if a buffer is a compilation buffer, assuming we're in the buffer
1420 (defsubst compilation-buffer-internal-p ()
1421   "Test if inside a compilation buffer."
1422   (local-variable-p 'compilation-locs))
1423
1424 ;;; test if a buffer is a compilation buffer, using compilation-buffer-internal-p
1425 (defsubst compilation-buffer-p (buffer)
1426   "Test if BUFFER is a compilation buffer."
1427   (with-current-buffer buffer
1428     (compilation-buffer-internal-p)))
1429
1430 (defmacro compilation-loop (< property-change 1+ error)
1431   `(while (,< n 0)
1432       (or (setq pt (,property-change pt 'message))
1433           (error ,error compilation-error))
1434       ;; prop 'message usually has 2 changes, on and off, so re-search if off
1435       (or (setq msg (get-text-property pt 'message))
1436           (if (setq pt (,property-change pt 'message))
1437               (setq msg (get-text-property pt 'message)))
1438           (error ,error compilation-error))
1439       (or (< (cadr msg) compilation-skip-threshold)
1440           (if different-file
1441               (eq (prog1 last (setq last (nth 2 (car msg))))
1442                   last))
1443           (if compilation-skip-visited
1444               (nthcdr 4 (car msg)))
1445           (if compilation-skip-to-next-location
1446               (eq (car msg) loc))
1447           ;; count this message only if none of the above are true
1448           (setq n (,1+ n)))))
1449
1450 (defun compilation-next-error (n &optional different-file pt)
1451   "Move point to the next error in the compilation buffer.
1452 Prefix arg N says how many error messages to move forwards (or
1453 backwards, if negative).
1454 Does NOT find the source line like \\[next-error]."
1455   (interactive "p")
1456   (or (compilation-buffer-p (current-buffer))
1457       (error "Not in a compilation buffer"))
1458   (or pt (setq pt (point)))
1459   (let* ((msg (get-text-property pt 'message))
1460          (loc (car msg))
1461          last)
1462     (if (zerop n)
1463         (unless (or msg                 ; find message near here
1464                     (setq msg (get-text-property (max (1- pt) (point-min))
1465                                                  'message)))
1466           (setq pt (previous-single-property-change pt 'message nil
1467                                                     (line-beginning-position)))
1468           (unless (setq msg (get-text-property (max (1- pt) (point-min)) 'message))
1469             (setq pt (next-single-property-change pt 'message nil
1470                                                   (line-end-position)))
1471             (or (setq msg (get-text-property pt 'message))
1472                 (setq pt (point)))))
1473       (setq last (nth 2 (car msg)))
1474       (if (>= n 0)
1475           (compilation-loop > next-single-property-change 1-
1476                             (if (get-buffer-process (current-buffer))
1477                                 "No more %ss yet"
1478                               "Moved past last %s"))
1479         ;; Don't move "back" to message at or before point.
1480         ;; Pass an explicit (point-min) to make sure pt is non-nil.
1481         (setq pt (previous-single-property-change pt 'message nil (point-min)))
1482         (compilation-loop < previous-single-property-change 1+
1483                           "Moved back before first %s")))
1484     (goto-char pt)
1485     (or msg
1486         (error "No %s here" compilation-error))))
1487
1488 (defun compilation-previous-error (n)
1489   "Move point to the previous error in the compilation buffer.
1490 Prefix arg N says how many error messages to move backwards (or
1491 forwards, if negative).
1492 Does NOT find the source line like \\[previous-error]."
1493   (interactive "p")
1494   (compilation-next-error (- n)))
1495
1496 (defun compilation-next-file (n)
1497   "Move point to the next error for a different file than the current one.
1498 Prefix arg N says how many files to move forwards (or backwards, if negative)."
1499   (interactive "p")
1500   (compilation-next-error n t))
1501
1502 (defun compilation-previous-file (n)
1503   "Move point to the previous error for a different file than the current one.
1504 Prefix arg N says how many files to move backwards (or forwards, if negative)."
1505   (interactive "p")
1506   (compilation-next-file (- n)))
1507
1508 (defun kill-compilation ()
1509   "Kill the process made by the \\[compile] or \\[grep] commands."
1510   (interactive)
1511   (let ((buffer (compilation-find-buffer)))
1512     (if (get-buffer-process buffer)
1513         (interrupt-process (get-buffer-process buffer))
1514       (error "The compilation process is not running"))))
1515
1516 (defalias 'compile-mouse-goto-error 'compile-goto-error)
1517
1518 (defun compile-goto-error (&optional event)
1519   "Visit the source for the error message at point.
1520 Use this command in a compilation log buffer.  Sets the mark at point there."
1521   (interactive (list last-input-event))
1522   (if event (posn-set-point (event-end event)))
1523   (or (compilation-buffer-p (current-buffer))
1524       (error "Not in a compilation buffer"))
1525   (if (get-text-property (point) 'directory)
1526       (dired-other-window (car (get-text-property (point) 'directory)))
1527     (push-mark)
1528     (setq compilation-current-error (point))
1529     (next-error 0)))
1530
1531 ;; Return a compilation buffer.
1532 ;; If the current buffer is a compilation buffer, return it.
1533 ;; Otherwise, look for a compilation buffer and signal an error
1534 ;; if there are none.
1535 (defun compilation-find-buffer (&optional avoid-current)
1536   (next-error-find-buffer avoid-current 'compilation-buffer-internal-p))
1537
1538 ;;;###autoload
1539 (defun compilation-next-error-function (n &optional reset)
1540   "Advance to the next error message and visit the file where the error was.
1541 This is the value of `next-error-function' in Compilation buffers."
1542   (interactive "p")
1543   (when reset
1544     (setq compilation-current-error nil))
1545   (let* ((columns compilation-error-screen-columns) ; buffer's local value
1546          (last 1)
1547          (loc (compilation-next-error (or n 1) nil
1548                                       (or compilation-current-error
1549                                           compilation-messages-start
1550                                           (point-min))))
1551          (end-loc (nth 2 loc))
1552          (marker (point-marker)))
1553     (setq compilation-current-error (point-marker)
1554           overlay-arrow-position
1555             (if (bolp)
1556                 compilation-current-error
1557               (copy-marker (line-beginning-position)))
1558           loc (car loc))
1559     ;; If loc contains no marker, no error in that file has been visited.  If
1560     ;; the marker is invalid the buffer has been killed.  So, recalculate all
1561     ;; markers for that file.
1562     (unless (and (nth 3 loc) (marker-buffer (nth 3 loc)))
1563       (with-current-buffer (compilation-find-file marker (caar (nth 2 loc))
1564                                                   (or (cdar (nth 2 loc))
1565                                                       default-directory))
1566         (save-restriction
1567           (widen)
1568           (goto-char (point-min))
1569           ;; Treat file's found lines in forward order, 1 by 1.
1570           (dolist (line (reverse (cddr (nth 2 loc))))
1571             (when (car line)            ; else this is a filename w/o a line#
1572               (beginning-of-line (- (car line) last -1))
1573               (setq last (car line)))
1574             ;; Treat line's found columns and store/update a marker for each.
1575             (dolist (col (cdr line))
1576               (if (car col)
1577                   (if (eq (car col) -1) ; special case for range end
1578                       (end-of-line)
1579                     (compilation-move-to-column (car col) columns))
1580                 (beginning-of-line)
1581                 (skip-chars-forward " \t"))
1582               (if (nth 3 col)
1583                   (set-marker (nth 3 col) (point))
1584                 (setcdr (nthcdr 2 col) `(,(point-marker)))))))))
1585     (compilation-goto-locus marker (nth 3 loc) (nth 3 end-loc))
1586     (setcdr (nthcdr 3 loc) t)))         ; Set this one as visited.
1587
1588 (defvar compilation-gcpro nil
1589   "Internal variable used to keep some values from being GC'd.")
1590 (make-variable-buffer-local 'compilation-gcpro)
1591
1592 (defun compilation-fake-loc (marker file &optional line col)
1593   "Preassociate MARKER with FILE.
1594 FILE should be ABSOLUTE-FILENAME or (RELATIVE-FILENAME . DIRNAME).
1595 This is useful when you compile temporary files, but want
1596 automatic translation of the messages to the real buffer from
1597 which the temporary file came.  This only works if done before a
1598 message about FILE appears!
1599
1600 Optional args LINE and COL default to 1 and beginning of
1601 indentation respectively.  The marker is expected to reflect
1602 this.  In the simplest case the marker points to the first line
1603 of the region that was saved to the temp file.
1604
1605 If you concatenate several regions into the temp file (e.g. a
1606 header with variable assignments and a code region), you must
1607 call this several times, once each for the last line of one
1608 region and the first line of the next region."
1609   (or (consp file) (setq file (list file)))
1610   (setq file (compilation-get-file-structure file))
1611   ;; Between the current call to compilation-fake-loc and the first occurrence
1612   ;; of an error message referring to `file', the data is only kept is the
1613   ;; weak hash-table compilation-locs, so we need to prevent this entry
1614   ;; in compilation-locs from being GC'd away.  --Stef
1615   (push file compilation-gcpro)
1616   (let ((loc (compilation-assq (or line 1) (cdr file))))
1617     (setq loc (compilation-assq col loc))
1618     (if (cdr loc)
1619         (setcdr (cddr loc) (list marker))
1620       (setcdr loc (list line file marker)))
1621     loc))
1622
1623 (defcustom compilation-context-lines nil
1624   "Display this many lines of leading context before the current message.
1625 If nil and the left fringe is displayed, don't scroll the
1626 compilation output window; an arrow in the left fringe points to
1627 the current message.  If nil and there is no left fringe, the message
1628 displays at the top of the window; there is no arrow."
1629   :type '(choice integer (const :tag "No window scrolling" nil))
1630   :group 'compilation
1631   :version "22.1")
1632
1633 (defsubst compilation-set-window (w mk)
1634   "Align the compilation output window W with marker MK near top."
1635   (if (integerp compilation-context-lines)
1636       (set-window-start w (save-excursion
1637                             (goto-char mk)
1638                             (beginning-of-line
1639                              (- 1 compilation-context-lines))
1640                             (point)))
1641     ;; If there is no left fringe.
1642     (if (equal (car (window-fringes)) 0)
1643         (set-window-start w (save-excursion
1644                               (goto-char mk)
1645                             (beginning-of-line 1)
1646                             (point)))))
1647     (set-window-point w mk))
1648
1649 (defvar next-error-highlight-timer)
1650
1651 (defun compilation-goto-locus (msg mk end-mk)
1652   "Jump to an error corresponding to MSG at MK.
1653 All arguments are markers.  If END-MK is non-nil, mark is set there
1654 and overlay is highlighted between MK and END-MK."
1655   (if (eq (window-buffer (selected-window))
1656           (marker-buffer msg))
1657       ;; If the compilation buffer window is selected,
1658       ;; keep the compilation buffer in this window;
1659       ;; display the source in another window.
1660       (let ((pop-up-windows t))
1661         (pop-to-buffer (marker-buffer mk)))
1662     (if (window-dedicated-p (selected-window))
1663         (pop-to-buffer (marker-buffer mk))
1664       (switch-to-buffer (marker-buffer mk))))
1665   ;; If narrowing gets in the way of going to the right place, widen.
1666   (unless (eq (goto-char mk) (point))
1667     (widen)
1668     (goto-char mk))
1669   (if end-mk
1670       (push-mark end-mk t)
1671     (if mark-active (setq mark-active)))
1672   ;; If hideshow got in the way of
1673   ;; seeing the right place, open permanently.
1674   (dolist (ov (overlays-at (point)))
1675     (when (eq 'hs (overlay-get ov 'invisible))
1676       (delete-overlay ov)
1677       (goto-char mk)))
1678
1679   ;; Show compilation buffer in other window, scrolled to this error.
1680   (let* ((pop-up-windows t)
1681          ;; Use an existing window if it is in a visible frame.
1682          (w (or (get-buffer-window (marker-buffer msg) 'visible)
1683                 ;; Pop up a window.
1684                 (display-buffer (marker-buffer msg))))
1685          (highlight-regexp (with-current-buffer (marker-buffer msg)
1686                              ;; also do this while we change buffer
1687                              (compilation-set-window w msg)
1688                              compilation-highlight-regexp)))
1689     (compilation-set-window-height w)
1690
1691     (when highlight-regexp
1692       (if (timerp next-error-highlight-timer)
1693           (cancel-timer next-error-highlight-timer))
1694       (unless compilation-highlight-overlay
1695         (setq compilation-highlight-overlay
1696               (make-overlay (point-min) (point-min)))
1697         (overlay-put compilation-highlight-overlay 'face 'next-error))
1698       (with-current-buffer (marker-buffer mk)
1699         (save-excursion
1700           (if end-mk (goto-char end-mk) (end-of-line))
1701           (let ((end (point)))
1702             (if mk (goto-char mk) (beginning-of-line))
1703             (if (and (stringp highlight-regexp)
1704                      (re-search-forward highlight-regexp end t))
1705                 (progn
1706                   (goto-char (match-beginning 0))
1707                   (move-overlay compilation-highlight-overlay
1708                                 (match-beginning 0) (match-end 0)
1709                                 (current-buffer)))
1710               (move-overlay compilation-highlight-overlay
1711                             (point) end (current-buffer)))
1712             (if (numberp next-error-highlight)
1713                 (setq next-error-highlight-timer
1714                       (run-at-time next-error-highlight nil 'delete-overlay
1715                                    compilation-highlight-overlay)))
1716             (if (not (or (eq next-error-highlight t)
1717                          (numberp next-error-highlight)))
1718                 (delete-overlay compilation-highlight-overlay))))))
1719     (when (and (eq next-error-highlight 'fringe-arrow))
1720       (setq next-error-overlay-arrow-position
1721             (copy-marker (line-beginning-position))))))
1722
1723 \f
1724 (defun compilation-find-file (marker filename dir &rest formats)
1725   "Find a buffer for file FILENAME.
1726 Search the directories in `compilation-search-path'.
1727 A nil in `compilation-search-path' means to try the
1728 current directory, which is passed in DIR.
1729 If FILENAME is not found at all, ask the user where to find it.
1730 Pop up the buffer containing MARKER and scroll to MARKER if we ask the user."
1731   (or formats (setq formats '("%s")))
1732   (save-excursion
1733     (let ((dirs compilation-search-path)
1734           buffer thisdir fmts name)
1735       (if (file-name-absolute-p filename)
1736           ;; The file name is absolute.  Use its explicit directory as
1737           ;; the first in the search path, and strip it from FILENAME.
1738           (setq filename (abbreviate-file-name (expand-file-name filename))
1739                 dirs (cons (file-name-directory filename) dirs)
1740                 filename (file-name-nondirectory filename)))
1741       ;; Now search the path.
1742       (while (and dirs (null buffer))
1743         (setq thisdir (or (car dirs) dir)
1744               fmts formats)
1745         ;; For each directory, try each format string.
1746         (while (and fmts (null buffer))
1747           (setq name (expand-file-name (format (car fmts) filename) thisdir)
1748                 buffer (and (file-exists-p name)
1749                             (find-file-noselect name))
1750                 fmts (cdr fmts)))
1751         (setq dirs (cdr dirs)))
1752       (or buffer
1753           ;; The file doesn't exist.  Ask the user where to find it.
1754           (let ((pop-up-windows t))
1755             (compilation-set-window (display-buffer (marker-buffer marker))
1756                                     marker)
1757             (let ((name (expand-file-name
1758                          (read-file-name
1759                           (format "Find this error in: (default %s) "
1760                                   filename)
1761                           dir filename t))))
1762               (if (file-directory-p name)
1763                   (setq name (expand-file-name filename name)))
1764               (setq buffer (and (file-exists-p name)
1765                                 (find-file name))))))
1766       ;; Make intangible overlays tangible.
1767       (mapcar (function (lambda (ov)
1768                           (when (overlay-get ov 'intangible)
1769                             (overlay-put ov 'intangible nil))))
1770               (overlays-in (point-min) (point-max)))
1771       buffer)))
1772
1773 (defun compilation-get-file-structure (file &optional fmt)
1774   "Retrieve FILE's file-structure or create a new one.
1775 FILE should be (ABSOLUTE-FILENAME) or (RELATIVE-FILENAME . DIRNAME)."
1776
1777   (or (gethash file compilation-locs)
1778       ;; File was not previously encountered, at least not in the form passed.
1779       ;; Let's normalize it and look again.
1780       (let ((filename (car file))
1781             (default-directory (if (cdr file)
1782                                    (file-truename (cdr file))
1783                                  default-directory)))
1784
1785         ;; Check for a comint-file-name-prefix and prepend it if appropriate.
1786         ;; (This is very useful for compilation-minor-mode in an rlogin-mode
1787         ;; buffer.)
1788         (if (boundp 'comint-file-name-prefix)
1789             (if (file-name-absolute-p filename)
1790                 (setq filename
1791                       (concat (with-no-warnings comint-file-name-prefix) filename))
1792               (setq default-directory
1793                     (file-truename
1794                      (concat (with-no-warnings comint-file-name-prefix) default-directory)))))
1795
1796         ;; If compilation-parse-errors-filename-function is
1797         ;; defined, use it to process the filename.
1798         (when compilation-parse-errors-filename-function
1799           (setq filename
1800                 (funcall compilation-parse-errors-filename-function
1801                          filename)))
1802
1803         ;; Some compilers (e.g. Sun's java compiler, reportedly) produce bogus
1804         ;; file names like "./bar//foo.c" for file "bar/foo.c";
1805         ;; expand-file-name will collapse these into "/foo.c" and fail to find
1806         ;; the appropriate file.  So we look for doubled slashes in the file
1807         ;; name and fix them.
1808         (setq filename (command-line-normalize-file-name filename))
1809
1810         ;; Now eliminate any "..", because find-file would get them wrong.
1811         ;; Make relative and absolute filenames, with or without links, the
1812         ;; same.
1813         (setq filename
1814               (list (abbreviate-file-name
1815                      (file-truename (if (cdr file)
1816                                         (expand-file-name filename)
1817                                       filename)))))
1818
1819         ;; Store it for the possibly unnormalized name
1820         (puthash file
1821                  ;; Retrieve or create file-structure for normalized name
1822                  (or (gethash filename compilation-locs)
1823                      (puthash filename (list filename fmt) compilation-locs))
1824                  compilation-locs))))
1825
1826 (add-to-list 'debug-ignored-errors "^No more [-a-z ]+s yet$")
1827
1828 ;;; Compatibility with the old compile.el.
1829
1830 (defun compile-buffer-substring (n) (if n (match-string n)))
1831
1832 (defun compilation-compat-error-properties (err)
1833   "Map old-style error ERR to new-style message."
1834   ;; Old-style structure is (MARKER (FILE DIR) LINE COL) or
1835   ;; (MARKER . MARKER).
1836   (let ((dst (cdr err)))
1837     (if (markerp dst)
1838         ;; Must start with a face, for font-lock.
1839         `(face nil
1840           message ,(list (list nil nil nil dst) 2)
1841           help-echo "mouse-2: visit the source location"
1842           keymap compilation-button-map
1843           mouse-face highlight)
1844       ;; Too difficult to do it by hand: dispatch to the normal code.
1845       (let* ((file (pop dst))
1846              (line (pop dst))
1847              (col (pop dst))
1848              (filename (pop file))
1849              (dirname (pop file))
1850              (fmt (pop file)))
1851         (compilation-internal-error-properties
1852          (cons filename dirname) line nil col nil 2 fmt)))))
1853
1854 (defun compilation-compat-parse-errors (limit)
1855   (when compilation-parse-errors-function
1856     ;; FIXME: We should remove the rest of the compilation keywords
1857     ;; but we can't do that from here because font-lock is using
1858     ;; the value right now.  --stef
1859     (save-excursion
1860       (setq compilation-error-list nil)
1861       ;; Reset compilation-parsing-end each time because font-lock
1862       ;; might force us the re-parse many times (typically because
1863       ;; some code adds some text-property to the output that we
1864       ;; already parsed).  You might say "why reparse", well:
1865       ;; because font-lock has just removed the `message' property so
1866       ;; have to do it all over again.
1867       (if compilation-parsing-end
1868           (set-marker compilation-parsing-end (point))
1869         (setq compilation-parsing-end (point-marker)))
1870       (condition-case nil
1871           ;; Ignore any error: we're calling this function earlier than
1872           ;; in the old compile.el so things might not all be setup yet.
1873           (funcall compilation-parse-errors-function limit nil)
1874         (error nil))
1875       (dolist (err (if (listp compilation-error-list) compilation-error-list))
1876         (let* ((src (car err))
1877                (dst (cdr err))
1878                (loc (cond ((markerp dst) (list nil nil nil dst))
1879                           ((consp dst)
1880                            (list (nth 2 dst) (nth 1 dst)
1881                                  (cons (cdar dst) (caar dst)))))))
1882           (when loc
1883             (goto-char src)
1884             ;; (put-text-property src (line-end-position) 'font-lock-face 'font-lock-warning-face)
1885             (put-text-property src (line-end-position)
1886                                'message (list loc 2)))))))
1887   (goto-char limit)
1888   nil)
1889
1890 ;; Beware: this is not only compatiblity code.  New code stil uses it.  --Stef
1891 (defun compilation-forget-errors ()
1892   ;; In case we hit the same file/line specs, we want to recompute a new
1893   ;; marker for them, so flush our cache.
1894   (setq compilation-locs (make-hash-table :test 'equal :weakness 'value))
1895   (setq compilation-gcpro nil)
1896   ;; FIXME: the old code reset the directory-stack, so maybe we should
1897   ;; put a `directory change' marker of some sort, but where?  -stef
1898   ;;
1899   ;; FIXME: The old code moved compilation-current-error (which was
1900   ;; virtually represented by a mix of compilation-parsing-end and
1901   ;; compilation-error-list) to point-min, but that was only meaningful for
1902   ;; the internal uses of compilation-forget-errors: all calls from external
1903   ;; packages seem to be followed by a move of compilation-parsing-end to
1904   ;; something equivalent to point-max.  So we speculatively move
1905   ;; compilation-current-error to point-max (since the external package
1906   ;; won't know that it should do it).  --stef
1907   (setq compilation-current-error nil)
1908   (let* ((proc (get-buffer-process (current-buffer)))
1909          (mark (if proc (process-mark proc)))
1910          (pos (or mark (point-max))))
1911     (setq compilation-messages-start
1912           ;; In the future, ignore the text already present in the buffer.
1913           ;; Since many process filter functions insert before markers,
1914           ;; we need to put ours just before the insertion point rather
1915           ;; than at the insertion point.  If that's not possible, then
1916           ;; don't use a marker.  --Stef
1917           (if (> pos (point-min)) (copy-marker (1- pos)) pos))))
1918
1919 ;;;###autoload
1920 (add-to-list 'auto-mode-alist '("\\.gcov\\'" . compilation-mode))
1921
1922 (provide 'compile)
1923
1924 ;; arch-tag: 12465727-7382-4f72-b234-79855a00dd8c
1925 ;;; compile.el ends here