code.delx.au - gnu-emacs/blob - configure.ac

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the 'configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl If you changed any AC_DEFINES, also run autoheader.
   6 dnl
   7 dnl Copyright (C) 1994-1996, 1999-2015 Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation, either version 3 of the License, or
  14 dnl  (at your option) any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 AC_PREREQ(2.65)
  25 dnl Note this is parsed by (at least) make-dist and lisp/cedet/ede/emacs.el.
  26 AC_INIT(GNU Emacs, 25.0.50, bug-gnu-emacs@gnu.org)
  27
  28 dnl Set emacs_config_options to the options of 'configure', quoted for the shell,
  29 dnl and then quoted again for a C string.  Separate options with spaces.
  30 dnl Add some environment variables, if they were passed via the environment
  31 dnl rather than on the command-line.
  32 emacs_config_options=
  33 optsep=
  34 dnl This is the documented way to record the args passed to configure,
  35 dnl rather than $ac_configure_args.
  36 for opt in ${1+"$@"} CFLAGS CPPFLAGS LDFLAGS; do
  37   case $opt in
  38     -n | --no-create | --no-recursion)
  39       continue ;;
  40     CFLAGS | CPPFLAGS | LDFLAGS)
  41       eval 'test "${'$opt'+set}" = set' || continue
  42       case " $*" in
  43         *" $opt="*) continue ;;
  44       esac
  45       eval opt=$opt=\$$opt ;;
  46   esac
  47
  48   emacs_shell_specials=$IFS\''"#$&()*;<>?@<:@\\`{|~'
  49   case $opt in
  50     *[["$emacs_shell_specials"]]*)
  51       case $opt in
  52         *\'*)
  53           emacs_quote_apostrophes="s/'/'\\\\''/g"
  54           opt=`AS_ECHO(["$opt"]) | sed "$emacs_quote_apostrophes"` ;;
  55       esac
  56       opt="'$opt'"
  57       case $opt in
  58         *[['"\\']]*)
  59           emacs_quote_for_c='s/[["\\]]/\\&/g; $!s/$/\\n\\/'
  60           opt=`AS_ECHO(["$opt"]) | sed "$emacs_quote_for_c"` ;;
  61       esac ;;
  62   esac
  63   AS_VAR_APPEND([emacs_config_options], ["$optsep$opt"])
  64   optsep=' '
  65 done
  66
  67 AC_CONFIG_HEADERS(src/config.h:src/config.in)
  68 AC_CONFIG_SRCDIR(src/lisp.h)
  69 AC_CONFIG_AUX_DIR(build-aux)
  70 dnl automake 1.13 and later understand this, making -I m4 unnecessary.
  71 dnl With older versions this is a no-op.
  72 AC_CONFIG_MACRO_DIR(m4)
  73
  74 xcsdkdir=
  75 AC_CHECK_PROGS(XCRUN, [xcrun])
  76 if test -n "$XCRUN"; then
  77   if test -z "$MAKE"; then
  78     dnl Call the variable MAKE_PROG, not MAKE, to avoid confusion with
  79     dnl the usual MAKE variable that 'make' itself uses.
  80     AC_CHECK_PROG([MAKE_PROG], [make], [yes])
  81     if test -z "$MAKE_PROG"; then
  82       MAKE="$XCRUN MAKE"
  83       export MAKE
  84       xcsdkdir=`$XCRUN --show-sdk-path 2>/dev/null`
  85     fi
  86   fi
  87 fi
  88
  89 dnl GNU Make is required, so don't test for its individual features.
  90 am_cv_make_support_nested_variables=yes
  91 AC_DEFUN([AC_PROG_MAKE_SET],
  92   [SET_MAKE=
  93    AC_SUBST([SET_MAKE])])
  94
  95 dnl Check for GNU Make and possibly set MAKE before running AM_INIT_AUTOMAKE.
  96 [emacs_check_gnu_make ()
  97 {
  98   emacs_makeout=`($1 --version) 2>/dev/null` &&
  99   case $emacs_makeout in
 100     'GNU Make '3.8[1-9]* | 'GNU Make '3.9[0-9]* | \
 101     'GNU Make '3.[1-9][0-9][0-9]* | 'GNU Make '[4-9]* | 'GNU Make '[1-9][0-9]* )
 102        ac_path_MAKE_found=:;;
 103   esac
 104 }]
 105 AC_CACHE_CHECK([for GNU Make], [ac_cv_path_MAKE],
 106   [ac_path_MAKE_found=false
 107    if test -n "$MAKE"; then
 108      emacs_check_gnu_make "$MAKE"
 109      ac_cv_path_MAKE=$MAKE
 110    else
 111      emacs_tried_make=false
 112      emacs_tried_gmake=false
 113      emacs_tried_gnumake=false
 114      AC_PATH_PROGS_FEATURE_CHECK([MAKE], [make gmake gnumake],
 115        [[emacs_check_gnu_make "$ac_path_MAKE"
 116          if $ac_path_MAKE_found; then
 117            # Use the fully-qualified program name only if the basename
 118            # would not resolve to it.
 119            if eval \$emacs_tried_$ac_prog; then
 120              ac_cv_path_MAKE=$ac_path_MAKE
 121            else
 122              ac_cv_path_MAKE=$ac_prog
 123            fi
 124          fi
 125          eval emacs_tried_$ac_prog=:]])
 126    fi])
 127 $ac_path_MAKE_found || {
 128 AC_MSG_ERROR([[Building Emacs requires GNU Make, at least version 3.81.
 129 If you have it installed under another name, configure with 'MAKE=...'.
 130 For example, run '$0 MAKE=gnu-make'.]])
 131 }
 132 MAKE=$ac_cv_path_MAKE
 133 export MAKE
 134
 135 dnl Fairly arbitrary, older versions might work too.
 136 AM_INIT_AUTOMAKE(1.11)
 137
 138 dnl Canonicalize the configuration name.
 139 AC_CANONICAL_HOST
 140
 141 case $host in
 142  *-mingw*)
 143
 144   if test -z "$host_alias"; then
 145
 146       # No --host argument was given to 'configure'; therefore $host
 147       # was set to a default value based on the build platform.  But
 148       # this default value may be wrong if we are building from a
 149       # 64-bit MSYS[2] pre-configured to build 32-bit MinGW programs.
 150       # Therefore, we'll try to get the right host platform from the
 151       # compiler's target.
 152
 153       AC_MSG_CHECKING([the compiler's target])
 154       if test -z "$CC"; then
 155           cc=gcc
 156       else
 157           cc=$CC
 158       fi
 159       cc_target=`$cc -v 2>&1 | sed -n 's/Target: //p'`
 160       case "$cc_target" in
 161           *-*) host=$cc_target
 162               ;;
 163           "") AC_MSG_ERROR([Impossible to obtain $cc compiler target.
 164 Please explicitly provide --host.])
 165               ;;
 166           *) AC_MSG_WARN([Compiler reported non-standard target.
 167 Defaulting to $host.])
 168               ;;
 169       esac
 170       AC_MSG_RESULT([$host])
 171   fi
 172
 173   . $srcdir/nt/mingw-cfg.site
 174
 175   case $srcdir in
 176     /* | ?:*)
 177       # srcdir is an absolute path.  In this case, force the format
 178       # "/c/foo/bar", to simplify later conversions to native Windows
 179       # format ("c:/foo/bar").
 180       srcdir=`cd "${srcdir}" && pwd -W`
 181       # 'eval' pacifies strict POSIX non-MinGW shells (Bug#18612).
 182       eval 'srcdir="/${srcdir:0:1}${srcdir:2}"'
 183       ;;
 184   esac;;
 185 esac
 186
 187 canonical=$host
 188 configuration=${host_alias-${build_alias-$host}}
 189
 190 dnl Support for --program-prefix, --program-suffix and
 191 dnl --program-transform-name options
 192 AC_ARG_PROGRAM
 193
 194 dnl It is important that variables on the RHS not be expanded here,
 195 dnl hence the single quotes.  This is per the GNU coding standards, see
 196 dnl (autoconf) Installation Directory Variables
 197 dnl See also epaths.h below.
 198 lispdir='${datadir}/emacs/${version}/lisp'
 199 standardlisppath='${lispdir}'
 200 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
 201 '${datadir}/emacs/site-lisp'
 202 lisppath='${locallisppath}:${standardlisppath}'
 203 etcdir='${datadir}/emacs/${version}/etc'
 204 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
 205 etcdocdir='${datadir}/emacs/${version}/etc'
 206 gamedir='${localstatedir}/games/emacs'
 207
 208 dnl Special option to disable the most of other options.
 209 AC_ARG_WITH(all,
 210 [AS_HELP_STRING([--without-all],
 211                 [omit almost all features and build
 212                 small executable with minimal dependencies])],
 213   [with_features=$withval],
 214   [with_features=yes])
 215
 216 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
 217 dnl Create a new --with option that defaults to being disabled.
 218 dnl NAME is the base name of the option.  The shell variable with_NAME
 219 dnl   will be set to either the user's value (if the option is
 220 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
 221 dnl   option is not specified).  Note that the shell variable name is
 222 dnl   constructed as autoconf does, by replacing non-alphanumeric
 223 dnl   characters with "_".
 224 dnl HELP-STRING is the help text for the option.
 225 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
 226   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
 227     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
 228 ])dnl
 229
 230 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
 231 dnl Create a new --with option that defaults to $with_features.
 232 dnl NAME is the base name of the option.  The shell variable with_NAME
 233 dnl   will be set either to 'no' (for a plain --without-NAME) or to
 234 dnl   'yes' (if the option is not specified).  Note that the shell
 235 dnl   variable name is constructed as autoconf does, by replacing
 236 dnl   non-alphanumeric characters with "_".
 237 dnl HELP-STRING is the help text for the option.
 238 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
 239   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
 240    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=$with_features])dnl
 241 ])dnl
 242
 243 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
 244 if test "$with_pop" = yes; then
 245    AC_DEFINE(MAIL_USE_POP)
 246 fi
 247 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
 248
 249 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
 250 if test "$with_kerberos" != no; then
 251    AC_DEFINE(KERBEROS)
 252 fi
 253 AH_TEMPLATE(KERBEROS,
 254             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
 255
 256 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
 257 if test "${with_kerberos5}" != no; then
 258   if test "${with_kerberos}" = no; then
 259     with_kerberos=yes
 260     AC_DEFINE(KERBEROS)
 261   fi
 262   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
 263 fi
 264
 265 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
 266 dnl FIXME hesiod support may not be present, so it seems like an error
 267 dnl to define, or at least use, this unconditionally.
 268 if test "$with_hesiod" != no; then
 269   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
 270 fi
 271
 272 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
 273 if test "$with_mail_unlink" != no; then
 274    AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
 275 fi
 276
 277 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
 278     [string giving default POP mail host])],
 279     AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
 280
 281 AC_ARG_WITH([sound],[AS_HELP_STRING([--with-sound=VALUE],
 282   [compile with sound support (VALUE one of: yes, alsa, oss, bsd-ossaudio, no;
 283 default yes).  Only for GNU/Linux, FreeBSD, NetBSD, MinGW, Cygwin.])],
 284   [ case "${withval}" in
 285       yes|no|alsa|oss|bsd-ossaudio) val=$withval ;;
 286       *) AC_MSG_ERROR(['--with-sound=$withval' is invalid;
 287 this option's value should be 'yes', 'no', 'alsa', 'oss', or 'bsd-ossaudio'.])
 288       ;;
 289     esac
 290     with_sound=$val
 291   ],
 292   [with_sound=$with_features])
 293
 294 dnl FIXME currently it is not the last.
 295 dnl This should be the last --with option, because --with-x is
 296 dnl added later on when we find the file name of X, and it's best to
 297 dnl keep them together visually.
 298 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 299  [use an X toolkit (KIT one of: yes or gtk, gtk2, gtk3, lucid or athena, motif, no)])],
 300 [         case "${withval}" in
 301             y | ye | yes )      val=gtk ;;
 302             n | no )            val=no  ;;
 303             l | lu | luc | luci | lucid )       val=lucid ;;
 304             a | at | ath | athe | athen | athena )      val=athena ;;
 305             m | mo | mot | moti | motif )       val=motif ;;
 306             g | gt | gtk  )     val=gtk ;;
 307             gtk2  )     val=gtk2 ;;
 308             gtk3  )     val=gtk3 ;;
 309             * )
 310 AC_MSG_ERROR(['--with-x-toolkit=$withval' is invalid;
 311 this option's value should be 'yes', 'no', 'lucid', 'athena', 'motif', 'gtk',
 312 'gtk2' or 'gtk3'.  'yes' and 'gtk' are synonyms.
 313 'athena' and 'lucid' are synonyms.])
 314             ;;
 315           esac
 316           with_x_toolkit=$val
 317 ])
 318
 319 OPTION_DEFAULT_OFF([wide-int], [prefer wide Emacs integers (typically 62-bit)])
 320 if test "$with_wide_int" = yes; then
 321   AC_DEFINE([WIDE_EMACS_INT], 1, [Use long long for EMACS_INT if available.])
 322 fi
 323
 324 dnl _ON results in a '--without' option in the --help output, so
 325 dnl the help text should refer to "don't compile", etc.
 326 with_xpm_set=${with_xpm+set}
 327 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 328 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 329 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 330 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 331 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 332 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 333 OPTION_DEFAULT_OFF([cairo],[compile with Cairo drawing])
 334 OPTION_DEFAULT_ON([xml2],[don't compile with XML parsing support])
 335 OPTION_DEFAULT_ON([imagemagick],[don't compile with ImageMagick image support])
 336
 337 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 338 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 339 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 340
 341 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 342 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 343 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 344 AC_ARG_WITH([ns],[AS_HELP_STRING([--with-ns],
 345 [use Nextstep (OS X Cocoa or GNUstep) windowing system.
 346 On by default on Mac OS X.])],[],[with_ns=maybe])
 347 OPTION_DEFAULT_OFF([w32], [use native MS Windows GUI in a Cygwin build])
 348
 349 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 350 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 351 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 352 OPTION_DEFAULT_ON([gsettings],[don't compile with GSettings support])
 353 OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support])
 354 OPTION_DEFAULT_ON([gnutls],[don't use -lgnutls for SSL/TLS support])
 355 OPTION_DEFAULT_ON([zlib],[don't compile with zlib decompression support])
 356
 357 AC_ARG_WITH([file-notification],[AS_HELP_STRING([--with-file-notification=LIB],
 358  [use a file notification library (LIB one of: yes, gfile, inotify, w32, no)])],
 359  [ case "${withval}" in
 360     y | ye | yes )      val=yes ;;
 361     n | no )            val=no  ;;
 362     g | gf | gfi | gfil | gfile )       val=gfile ;;
 363     i | in | ino | inot | inoti | inotif | inotify )    val=inotify ;;
 364     w | w3 | w32 )      val=w32 ;;
 365     * ) AC_MSG_ERROR(['--with-file-notification=$withval' is invalid;
 366 this option's value should be 'yes', 'no', 'gfile', 'inotify' or 'w32'.
 367 'yes' is a synonym for 'w32' on MS-Windows, for 'no' on Nextstep,
 368 otherwise for the first of 'inotify' or 'gfile' that is usable.])
 369     ;;
 370    esac
 371    with_file_notification=$val
 372  ],
 373  [with_file_notification=$with_features])
 374
 375 ## For the times when you want to build Emacs but don't have
 376 ## a suitable makeinfo, and can live without the manuals.
 377 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 378 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 379
 380 ## This might be a 'configure' arg.
 381 AC_SUBST([ACLOCAL_PATH])
 382
 383 ## Makefile.in needs the cache file name.
 384 AC_SUBST(cache_file)
 385
 386 ## This is an option because I do not know if all info/man support
 387 ## compressed files, nor how to test if they do so.
 388 OPTION_DEFAULT_ON([compress-install],
 389   [don't compress some files (.el, .info, etc.) when installing.  Equivalent to:
 390 make GZIP_PROG= install])
 391
 392 AC_ARG_WITH(gameuser,dnl
 393 [AS_HELP_STRING([--with-gameuser=USER_OR_GROUP],
 394                 [user for shared game score files.
 395                 An argument prefixed by ':' specifies a group instead.])])
 396 gameuser=
 397 gamegroup=
 398 # We don't test if we can actually chown/chgrp here, because configure
 399 # may run without root privileges.  lib-src/Makefile.in will handle
 400 # any errors due to missing user/group gracefully.
 401 case ${with_gameuser} in
 402   no) ;;
 403   "" | yes) gamegroup=games ;;
 404   :*) gamegroup=${with_gameuser#:} ;;
 405   *) gameuser=${with_gameuser} ;;
 406 esac
 407
 408 AC_ARG_WITH([gnustep-conf],dnl
 409 [AS_HELP_STRING([--with-gnustep-conf=FILENAME],
 410    [name of GNUstep configuration file to use on systems where the command
 411     'gnustep-config' does not work; default $GNUSTEP_CONFIG_FILE, or
 412     /etc/GNUstep/GNUstep.conf])])
 413 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 414   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 415 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 416      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 417
 418 AC_ARG_ENABLE(ns-self-contained,
 419 [AS_HELP_STRING([--disable-ns-self-contained],
 420                 [disable self contained build under NeXTstep])],
 421    EN_NS_SELF_CONTAINED=$enableval,
 422    EN_NS_SELF_CONTAINED=yes)
 423
 424 locallisppathset=no
 425 AC_ARG_ENABLE(locallisppath,
 426 [AS_HELP_STRING([--enable-locallisppath=PATH],
 427                 [directories Emacs should search for lisp files specific
 428                  to this site])],
 429 if test "${enableval}" = "no"; then
 430   locallisppath=
 431 elif test "${enableval}" != "yes"; then
 432   locallisppath=${enableval} locallisppathset=yes
 433 fi)
 434
 435 AC_ARG_ENABLE(checking,
 436 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 437                 [enable expensive run-time checks.  With LIST,
 438                  enable only specific categories of checks.
 439                  Categories are: all,yes,no.
 440                  Flags are: stringbytes, stringoverrun, stringfreelist,
 441                  xmallocoverrun, conslist, glyphs])],
 442 [ac_checking_flags="${enableval}"],[])
 443 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 444 for check in $ac_checking_flags
 445 do
 446         case $check in
 447         # these set all the flags to specific states
 448         yes)            ac_enable_checking=1 ;;
 449         no)             ac_enable_checking= ;
 450                         ac_gc_check_stringbytes= ;
 451                         ac_gc_check_string_overrun= ;
 452                         ac_gc_check_string_free_list= ;
 453                         ac_xmalloc_overrun= ;
 454                         ac_gc_check_cons_list= ;
 455                         ac_glyphs_debug= ;;
 456         all)            ac_enable_checking=1 ;
 457                         ac_gc_check_stringbytes=1 ;
 458                         ac_gc_check_string_overrun=1 ;
 459                         ac_gc_check_string_free_list=1 ;
 460                         ac_xmalloc_overrun=1 ;
 461                         ac_gc_check_cons_list=1 ;
 462                         ac_glyphs_debug=1 ;;
 463         # these enable particular checks
 464         stringbytes)    ac_gc_check_stringbytes=1 ;;
 465         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 466         stringfreelist) ac_gc_check_string_free_list=1 ;;
 467         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 468         conslist)       ac_gc_check_cons_list=1 ;;
 469         glyphs)         ac_glyphs_debug=1 ;;
 470         *)      AC_MSG_ERROR(unknown check category $check) ;;
 471         esac
 472 done
 473 IFS="$ac_save_IFS"
 474
 475 if test x$ac_enable_checking != x ; then
 476   AC_DEFINE(ENABLE_CHECKING, 1,
 477 [Define to 1 if expensive run-time data type and consistency checks are enabled.])
 478 fi
 479 if test x$ac_gc_check_stringbytes != x ; then
 480   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 481 [Define this temporarily to hunt a bug.  If defined, the size of
 482    strings is redundantly recorded in sdata structures so that it can
 483    be compared to the sizes recorded in Lisp strings.])
 484 fi
 485 if test x$ac_gc_check_string_overrun != x ; then
 486   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 487 [Define this to check for short string overrun.])
 488 fi
 489 if test x$ac_gc_check_string_free_list != x ; then
 490   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 491 [Define this to check the string free list.])
 492 fi
 493 if test x$ac_xmalloc_overrun != x ; then
 494   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 495 [Define this to check for malloc buffer overrun.])
 496 fi
 497 if test x$ac_gc_check_cons_list != x ; then
 498   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 499 [Define this to check for errors in cons list.])
 500 fi
 501 if test x$ac_glyphs_debug != x ; then
 502   AC_DEFINE(GLYPH_DEBUG, 1,
 503 [Define this to enable glyphs debugging code.])
 504 fi
 505
 506 AC_ARG_ENABLE(check-lisp-object-type,
 507 [AS_HELP_STRING([--enable-check-lisp-object-type],
 508                 [enable compile time checks for the Lisp_Object data type.
 509                 This is useful for development for catching certain types of bugs.])],
 510 if test "${enableval}" != "no"; then
 511    AC_DEFINE(CHECK_LISP_OBJECT_TYPE, 1,
 512    [Define this to enable compile time checks for the Lisp_Object data type.])
 513 fi)
 514
 515
 516 dnl The name of this option is unfortunate.  It predates, and has no
 517 dnl relation to, the "sampling-based elisp profiler" added in 24.3.
 518 dnl Actually, it stops it working.
 519 dnl http://lists.gnu.org/archive/html/emacs-devel/2012-11/msg00393.html
 520 AC_ARG_ENABLE(profiling,
 521 [AS_HELP_STRING([--enable-profiling],
 522                 [build emacs with low-level, gprof profiling support.
 523                 Mainly useful for debugging Emacs itself.  May not work on
 524                 all platforms.  Stops profiler.el working.])],
 525 [ac_enable_profiling="${enableval}"],[])
 526 if test x$ac_enable_profiling != x ; then
 527    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 528 else
 529    PROFILING_CFLAGS=
 530 fi
 531 AC_SUBST(PROFILING_CFLAGS)
 532
 533 AC_ARG_ENABLE(autodepend,
 534 [AS_HELP_STRING([--enable-autodepend],
 535                 [automatically generate dependencies to .h-files.
 536                  Requires gcc, enabled if found.])],
 537 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 538
 539 AC_ARG_ENABLE(gtk-deprecation-warnings,
 540 [AS_HELP_STRING([--enable-gtk-deprecation-warnings],
 541                 [Show Gtk+/Gdk deprecation warnings for Gtk+ >= 3.0])],
 542 [ac_enable_gtk_deprecation_warnings="${enableval}"],[])
 543
 544 dnl This used to use changequote, but, apart from 'changequote is evil'
 545 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 546 dnl the great gob of text.  Thus it's not processed for possible expansion.
 547 dnl Just make sure the brackets remain balanced.
 548 dnl
 549 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 550 dnl indicated by comments.
 551 dnl quotation begins
 552 [
 553
 554 ### If you add support for a new configuration, add code to this
 555 ### switch statement to recognize your configuration name and select
 556 ### the appropriate opsys.
 557
 558 ### As far as handling version numbers on operating systems is
 559 ### concerned, make sure things will fail in a fixable way.  If
 560 ### /etc/MACHINES doesn't say anything about version numbers, be
 561 ### prepared to handle anything reasonably.  If version numbers
 562 ### matter, be sure /etc/MACHINES says something about it.
 563
 564 opsys='' unported=no
 565 case "${canonical}" in
 566
 567   ## GNU/Linux and similar ports
 568   *-*-linux* )
 569     opsys=gnu-linux
 570   ;;
 571
 572   ## FreeBSD ports
 573   *-*-freebsd* )
 574     opsys=freebsd
 575   ;;
 576
 577   ## DragonFly ports
 578   *-*-dragonfly* )
 579     opsys=dragonfly
 580   ;;
 581
 582   ## FreeBSD kernel + glibc based userland
 583   *-*-kfreebsd*gnu* )
 584     opsys=gnu-kfreebsd
 585   ;;
 586
 587   ## NetBSD ports
 588   *-*-netbsd* )
 589     opsys=netbsd
 590   ;;
 591
 592   ## OpenBSD ports
 593   *-*-openbsd* | *-*-mirbsd* )
 594     opsys=openbsd
 595   ;;
 596
 597   ## Apple Darwin / Mac OS X
 598   *-apple-darwin* )
 599     case "${canonical}" in
 600       *-apple-darwin[0-9].*) unported=yes ;;
 601       i[3456]86-* | x86_64-* )  ;;
 602       * )            unported=yes ;;
 603     esac
 604     opsys=darwin
 605     ## Use fink packages if available.
 606     ## FIXME find a better way to do this: http://debbugs.gnu.org/11507
 607 ##    if test -d /sw/include && test -d /sw/lib; then
 608 ##      GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 609 ##      NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 610 ##    fi
 611   ;;
 612
 613   ## Chromium Native Client
 614   *-nacl )
 615     opsys=nacl
 616   ;;
 617
 618   ## Cygwin ports
 619   *-*-cygwin )
 620     opsys=cygwin
 621   ;;
 622
 623   ## HP 9000 series 700 and 800, running HP/UX
 624   hppa*-hp-hpux10.2* )
 625     opsys=hpux10-20
 626   ;;
 627   hppa*-hp-hpux1[1-9]* )
 628     opsys=hpux11
 629     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 630   ;;
 631
 632   ## IBM machines
 633   rs6000-ibm-aix4.[23]* )
 634     opsys=aix4-2
 635   ;;
 636   powerpc-ibm-aix4.[23]*  )
 637     opsys=aix4-2
 638   ;;
 639   rs6000-ibm-aix[56]* )
 640     opsys=aix4-2
 641   ;;
 642   powerpc-ibm-aix[5-9]* | powerpc-ibm-aix[1-9][0-9]* )
 643     opsys=aix4-2
 644   ;;
 645
 646   ## Silicon Graphics machines
 647   ## Iris 4D
 648   mips-sgi-irix6.5 )
 649     opsys=irix6-5
 650     # Without defining _LANGUAGE_C, things get masked out in the headers
 651     # so that, for instance, grepping for 'free' in stdlib.h fails and
 652     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 653     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 654   ;;
 655
 656   ## Suns
 657   *-sun-solaris* \
 658     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 659     | x86_64-*-solaris2*    | x86_64-*-sunos5*)
 660     case "${canonical}" in
 661       i[3456]86-*-* )   ;;
 662       amd64-*-*|x86_64-*-*) ;;
 663       sparc* )          ;;
 664       * )               unported=yes ;;
 665     esac
 666     case "${canonical}" in
 667       *-sunos5.[1-9][0-9]* | *-solaris2.[1-9][0-9]* )
 668                 opsys=sol2-10
 669                 emacs_check_sunpro_c=yes
 670                 ;;
 671       *-sunos5.[1-5]* | *-solaris2.[1-5]* ) unported=yes ;;
 672       ## Note that Emacs 23.1's NEWS said the following would be dropped.
 673       *-sunos5.6* | *-solaris2.6* )
 674                 opsys=sol2-6
 675                 RANLIB="ar -ts"
 676                 ;;
 677       ## 5.7 EOL Aug 2008, 5.8 EOL Mar 2012.
 678       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 679                 opsys=sol2-6
 680                 emacs_check_sunpro_c=yes
 681                 ;;
 682     esac
 683     ## Watch out for a compiler that we know will not work.
 684     case "${canonical}" in
 685      *-solaris* | *-sunos5* )
 686                 if [ "x$CC" = x/usr/ucb/cc ]; then
 687                   ## /usr/ucb/cc doesn't work;
 688                   ## we should find some other compiler that does work.
 689                   unset CC
 690                 fi
 691                 ;;
 692       *) ;;
 693     esac
 694   ;;
 695
 696   ## Intel 386 machines where we don't care about the manufacturer.
 697   i[3456]86-*-* )
 698     case "${canonical}" in
 699       *-darwin* )               opsys=darwin ;;
 700       *-mingw* )
 701                 opsys=mingw32
 702                 # MinGW overrides and adds some system headers in nt/inc.
 703                 GCC_TEST_OPTIONS="-I $srcdir/nt/inc"
 704                 ;;
 705       *-sysv4.2uw* )            opsys=unixware ;;
 706       *-sysv5uw* )              opsys=unixware ;;
 707       *-sysv5OpenUNIX* )        opsys=unixware ;;
 708       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 709     esac
 710   ;;
 711
 712   # MinGW64
 713   x86_64-*-* )
 714     case "${canonical}" in
 715       *-mingw* )
 716                 opsys=mingw32
 717                 # MinGW overrides and adds some system headers in nt/inc.
 718                 GCC_TEST_OPTIONS="-I $srcdir/nt/inc"
 719                 ;;
 720       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 721     esac
 722   ;;
 723
 724   * )
 725     unported=yes
 726   ;;
 727 esac
 728
 729 ### If the code above didn't choose an operating system, just choose
 730 ### an operating system based on the configuration name.  You really
 731 ### only want to use this when you have no idea what the right
 732 ### operating system is; if you know what operating systems a machine
 733 ### runs, it's cleaner to make it explicit in the case statement
 734 ### above.
 735 if test x"${opsys}" = x; then
 736   case "${canonical}" in
 737     *-gnu* )                            opsys=gnu ;;
 738     * )
 739       unported=yes
 740     ;;
 741   esac
 742 fi
 743
 744 ]
 745 dnl quotation ends
 746
 747 if test $unported = yes; then
 748   AC_MSG_ERROR([Emacs does not support '${canonical}' systems.
 749 If you think it should, please send a report to ${PACKAGE_BUGREPORT}.
 750 Check 'etc/MACHINES' for recognized configuration names.])
 751 fi
 752
 753 #### Choose a compiler.
 754
 755 dnl Don't bother to test for C89.
 756 AC_DEFUN([_AC_PROG_CC_C89], [$2])
 757
 758 dnl Sets GCC=yes if using gcc.
 759 AC_PROG_CC([gcc cc cl clang "$XCRUN gcc" "$XCRUN clang"])
 760 if test -n "$XCRUN"; then
 761   AC_CHECK_PROGS(AR, [ar "$XCRUN ar"])
 762   test -n "$AR" && export AR
 763 fi
 764
 765 dnl Emacs needs C99 or later.
 766 gl_PROG_CC_C99
 767
 768 AM_PROG_CC_C_O
 769
 770 if test x$GCC = xyes; then
 771   test "x$GCC_TEST_OPTIONS" != x && CC="$CC $GCC_TEST_OPTIONS"
 772 else
 773   test "x$NON_GCC_TEST_OPTIONS" != x && CC="$CC $NON_GCC_TEST_OPTIONS"
 774 fi
 775
 776 dnl This is used in lib/Makefile.am to use nt/gnulib.mk, the
 777 dnl alternative to lib/gnulib.mk, so as to avoid generating header files
 778 dnl that clash with MinGW.
 779 AM_CONDITIONAL([BUILDING_FOR_WINDOWSNT], [test "x$opsys" = "xmingw32"])
 780
 781 # Avoid gnulib's tests for -lcrypto, so that there's no static dependency on it.
 782 AC_DEFUN([gl_CRYPTO_CHECK])
 783 # Avoid gnulib's tests for HAVE_WORKING_O_NOATIME and HAVE_WORKING_O_NOFOLLOW,
 784 # as we don't use them.
 785 AC_DEFUN([gl_FCNTL_O_FLAGS])
 786 # Avoid gnulib's test for pthread_sigmask.
 787 funcs=
 788 for func in $ac_func_list; do
 789   test $func = pthread_sigmask || AS_VAR_APPEND([funcs], [" $func"])
 790 done
 791 ac_func_list=$funcs
 792 # Use the system putenv even if it lacks GNU features, as we don't need them,
 793 # and the gnulib replacement runs afoul of a FreeBSD 10.1 bug; see Bug#19874.
 794 AC_CHECK_FUNCS_ONCE([putenv])
 795 AC_DEFUN([gl_FUNC_PUTENV],
 796   [test "$ac_cv_func_putenv" = yes || REPLACE_PUTENV=1])
 797
 798 # Initialize gnulib right after choosing the compiler.
 799 dnl Amongst other things, this sets AR and ARFLAGS.
 800 gl_EARLY
 801
 802 if test "$ac_test_CFLAGS" != set; then
 803   # It's helpful to have C macros available to GDB, so prefer -g3 to -g
 804   # if -g3 works and the user does not specify CFLAGS.
 805   # This test must follow gl_EARLY; otherwise AC_LINK_IFELSE complains.
 806   case $CFLAGS in
 807     '-g')
 808       emacs_g3_CFLAGS='-g3';;
 809     '-g -O2')
 810       emacs_g3_CFLAGS='-g3 -O2';;
 811     *)
 812       emacs_g3_CFLAGS='';;
 813   esac
 814   if test -n "$emacs_g3_CFLAGS"; then
 815     emacs_save_CFLAGS=$CFLAGS
 816     CFLAGS=$emacs_g3_CFLAGS
 817     AC_CACHE_CHECK([whether $CC accepts $emacs_g3_CFLAGS],
 818       [emacs_cv_prog_cc_g3],
 819       [AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 820          [emacs_cv_prog_cc_g3=yes],
 821          [emacs_cv_prog_cc_g3=no])])
 822     if test $emacs_cv_prog_cc_g3 != yes; then
 823       CFLAGS=$emacs_save_CFLAGS
 824     fi
 825     if test $opsys = mingw32; then
 826       CFLAGS="$CFLAGS -gdwarf-2"
 827     fi
 828   fi
 829
 830   case $CFLAGS in
 831     *-O*) ;;
 832     *)
 833       # No optimization flag was inferred for this non-GCC compiler.
 834       # Try -O.  This is needed for xlc on AIX; see Bug#14258.
 835       emacs_save_CFLAGS=$CFLAGS
 836       test -z "$CFLAGS" || CFLAGS="$CFLAGS "
 837       CFLAGS=${CFLAGS}-O
 838       AC_CACHE_CHECK([whether $CC accepts -O],
 839         [emacs_cv_prog_cc_o],
 840         [AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 841            [emacs_cv_prog_cc_o=yes],
 842            [emacs_cv_prog_cc_o=no])])
 843       if test $emacs_cv_prog_cc_o != yes; then
 844         CFLAGS=$emacs_save_CFLAGS
 845       fi ;;
 846   esac
 847 fi
 848
 849 AC_ARG_ENABLE([gcc-warnings],
 850   [AS_HELP_STRING([--enable-gcc-warnings],
 851                   [turn on lots of GCC warnings/errors. This is intended for
 852                    developers, and may generate false alarms when used
 853                    with older or non-GNU development tools.])],
 854   [case $enableval in
 855      yes|no) ;;
 856      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
 857    esac
 858    gl_gcc_warnings=$enableval],
 859   [gl_gcc_warnings=no]
 860 )
 861
 862 # clang is unduly picky about some things.
 863 AC_CACHE_CHECK([whether the compiler is clang], [emacs_cv_clang],
 864   [AC_COMPILE_IFELSE(
 865      [AC_LANG_PROGRAM([[
 866           #ifndef __clang__
 867             error "not clang";
 868           #endif
 869         ]])],
 870      [emacs_cv_clang=yes],
 871      [emacs_cv_clang=no])])
 872
 873 # When compiling with GCC, prefer -isystem to -I when including system
 874 # include files, to avoid generating useless diagnostics for the files.
 875 if test "$gl_gcc_warnings" != yes; then
 876   isystem='-I'
 877   if test "$emacs_cv_clang" = yes
 878   then
 879      # Turn off some warnings if supported.
 880      gl_WARN_ADD([-Wno-switch])
 881      gl_WARN_ADD([-Wno-tautological-constant-out-of-range-compare])
 882      gl_WARN_ADD([-Wno-pointer-sign])
 883      gl_WARN_ADD([-Wno-string-plus-int])
 884      gl_WARN_ADD([-Wno-unknown-attributes])
 885   fi
 886 else
 887   isystem='-isystem '
 888
 889   # This, $nw, is the list of warnings we disable.
 890   nw=
 891
 892   case $with_x_toolkit in
 893     lucid | athena | motif)
 894        # Old toolkits mishandle 'const'.
 895        nw="$nw -Wwrite-strings"
 896        ;;
 897     *)
 898        gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
 899        ;;
 900   esac
 901   AC_SUBST([WERROR_CFLAGS])
 902
 903   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
 904   nw="$nw -Woverlength-strings"     # Not a problem these days
 905   nw="$nw -Wformat-nonliteral"      # we do this a lot
 906   nw="$nw -Wvla"                    # Emacs uses <vla.h>.
 907   nw="$nw -Wswitch-default"         # Too many warnings for now
 908   nw="$nw -Winline"                 # OK to ignore 'inline'
 909   nw="$nw -Wjump-misses-init"       # We sometimes safely jump over init.
 910   nw="$nw -Wstrict-overflow"        # OK to optimize assuming that
 911                                     # signed overflow has undefined behavior
 912   nw="$nw -Wsync-nand"              # irrelevant here, and provokes ObjC warning
 913   nw="$nw -Wunsafe-loop-optimizations" # OK to suppress unsafe optimizations
 914   nw="$nw -Wbad-function-cast"      # These casts are no worse than others.
 915
 916   # Emacs doesn't care about shadowing; see
 917   # <http://lists.gnu.org/archive/html/emacs-diffs/2011-11/msg00265.html>.
 918   nw="$nw -Wshadow"
 919
 920   # Emacs's use of alloca inhibits protecting the stack.
 921   nw="$nw -Wstack-protector"
 922
 923   # Emacs's use of partly-const functions such as Fgnutls_available_p
 924   # make this option problematic.
 925   nw="$nw -Wsuggest-attribute=const"
 926
 927   # Emacs's use of partly-pure functions such as CHECK_TYPE make this
 928   # option problematic.
 929   nw="$nw -Wsuggest-attribute=pure"
 930
 931   # This part is merely for shortening the command line,
 932   # since -Wall implies -Wswitch.
 933   nw="$nw -Wswitch"
 934
 935   # This part is merely for shortening the command line,
 936   # since -Wno-FOO needs to be added below regardless.
 937   nw="$nw -Wmissing-field-initializers"
 938   nw="$nw -Wtype-limits"
 939   nw="$nw -Wunused-parameter"
 940
 941   if test $emacs_cv_clang = yes; then
 942     nw="$nw -Wcast-align"
 943   fi
 944
 945   gl_MANYWARN_ALL_GCC([ws])
 946   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
 947   for w in $ws; do
 948     gl_WARN_ADD([$w])
 949   done
 950   gl_WARN_ADD([-Wredundant-decls])     # Prefer this, as we don't use Bison.
 951   gl_WARN_ADD([-Wno-missing-field-initializers]) # We need this one
 952   gl_WARN_ADD([-Wno-sign-compare])     # Too many warnings for now
 953   gl_WARN_ADD([-Wno-type-limits])      # Too many warnings for now
 954   gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now
 955   gl_WARN_ADD([-Wno-format-nonliteral])
 956
 957   # More things that clang is unduly picky about.
 958   if test $emacs_cv_clang = yes; then
 959     gl_WARN_ADD([-Wno-format-extra-args])
 960     gl_WARN_ADD([-Wno-tautological-constant-out-of-range-compare])
 961     gl_WARN_ADD([-Wno-unused-command-line-argument])
 962     gl_WARN_ADD([-Wno-unused-value])
 963   fi
 964
 965   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 966   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 967   AH_VERBATIM([GNULIB_PORTCHECK_FORTIFY_SOURCE],
 968   [/* Enable compile-time and run-time bounds-checking, and some warnings,
 969       without upsetting glibc 2.15+. */
 970    #if (defined GNULIB_PORTCHECK && !defined _FORTIFY_SOURCE \
 971         && defined __OPTIMIZE__ && __OPTIMIZE__)
 972    # define _FORTIFY_SOURCE 2
 973    #endif
 974   ])
 975
 976   # We use a slightly smaller set of warning options for lib/.
 977   # Remove the following and save the result in GNULIB_WARN_CFLAGS.
 978   nw=
 979   nw="$nw -Wunused-macros"
 980
 981   gl_MANYWARN_COMPLEMENT([GNULIB_WARN_CFLAGS], [$WARN_CFLAGS], [$nw])
 982   AC_SUBST([GNULIB_WARN_CFLAGS])
 983 fi
 984
 985 edit_cflags="
 986   s,///*,/,g
 987   s/^/ /
 988   s/ -I/ $isystem/g
 989   s/^ //
 990 "
 991
 992 AC_ARG_ENABLE(link-time-optimization,
 993 [AS_HELP_STRING([--enable-link-time-optimization],
 994                 [build emacs with link-time optimization.
 995                  This requires GCC 4.5.0 or later, or clang.
 996                  (Note that clang support is experimental - see INSTALL.)
 997                  It also makes Emacs harder to debug, and when we tried it
 998                  with GCC 4.9.0 x86-64 it made Emacs slower, so it's not
 999                  recommended for typical use.])],
1000 if test "${enableval}" != "no"; then
1001    ac_lto_supported=no
1002    if test $emacs_cv_clang = yes; then
1003       AC_MSG_CHECKING([whether link-time optimization is supported by clang])
1004       GOLD_PLUGIN=`$CC -print-file-name=LLVMgold.so 2>/dev/null`
1005       if test -x "$GOLD_PLUGIN"; then
1006          LTO="-flto"
1007       fi
1008    elif test x$GCC = xyes; then
1009       AC_MSG_CHECKING([whether link-time optimization is supported by gcc])
1010       CPUS=`getconf _NPROCESSORS_ONLN 2>/dev/null`
1011       if test x$CPUS != x; then
1012          LTO="-flto=$CPUS"
1013       else
1014          LTO="-flto"
1015       fi
1016    else
1017       AC_MSG_ERROR([Link-time optimization is not supported with your compiler.])
1018    fi
1019    if test -z "$LTO"; then
1020       ac_lto_supported=no
1021    else
1022       old_CFLAGS=$CFLAGS
1023       CFLAGS="$CFLAGS $LTO"
1024       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])],
1025          [ac_lto_supported=yes], [ac_lto_supported=no])
1026          CFLAGS="$old_CFLAGS"
1027    fi
1028    AC_MSG_RESULT([$ac_lto_supported])
1029    if test "$ac_lto_supported" = "yes"; then
1030       CFLAGS="$CFLAGS $LTO"
1031       if test x$emacs_cv_clang = xyes; then
1032          AC_MSG_WARN([Please read INSTALL before using link-time optimization with clang])
1033          # WARNING: 'ar --plugin ...' doesn't work without
1034          # command, so plugin name is appended to ARFLAGS.
1035          ARFLAGS="cru --plugin $GOLD_PLUGIN"
1036          RANLIB="$RANLIB --plugin $GOLD_PLUGIN"
1037       else
1038         dnl The following is needed for GCC 4.9.0.  The GCC 4.9.0 release notes
1039         dnl suggest that instead of -ffat-lto-objects we should use gcc-ar and
1040         dnl gcc-ranlib in place of ar and ranlib, but gcc-ar makes /usr/bin/ar
1041         dnl dump core on Fedora 20, so play it safe for now.
1042         gl_COMPILER_OPTION_IF([-ffat-lto-objects],
1043           [CFLAGS="$CFLAGS -ffat-lto-objects"])
1044       fi
1045    fi
1046 fi)
1047
1048 dnl Prefer silent make output.  For verbose output, use
1049 dnl 'configure --disable-silent-rules' or 'make V=1' .
1050 AM_SILENT_RULES([yes])
1051 dnl Port to Automake 1.11.
1052 dnl This section can be removed once we assume Automake 1.14 or later.
1053 : ${AM_V=$AM_DEFAULT_VERBOSITY}
1054 : ${AM_DEFAULT_V=$AM_DEFAULT_VERBOSITY}
1055 AC_SUBST([AM_V])
1056 AM_SUBST_NOTMAKE([AM_V])
1057 AC_SUBST([AM_DEFAULT_V])
1058 AM_SUBST_NOTMAKE([AM_DEFAULT_V])
1059 AC_SUBST([AM_DEFAULT_VERBOSITY])
1060
1061 dnl Some other nice autoconf tests.
1062 dnl These are commented out, since gl_EARLY and/or Autoconf already does them.
1063 dnl AC_PROG_INSTALL
1064 dnl AC_PROG_MKDIR_P
1065 dnl if test "x$RANLIB" = x; then
1066 dnl   AC_PROG_RANLIB
1067 dnl fi
1068
1069
1070 dnl Sadly, AC_PROG_LN_S is too restrictive.  It also tests whether links
1071 dnl can be made to directories.  This is not relevant for our usage, and
1072 dnl excludes some cases that work fine for us.  Eg MS Windows or files
1073 dnl hosted on AFS, both examples where simple links work, but links to
1074 dnl directories fail.  We use a cut-down version instead.
1075 dnl AC_PROG_LN_S
1076
1077 AC_MSG_CHECKING([whether ln -s works for files in the same directory])
1078 rm -f conf$$ conf$$.file
1079
1080 LN_S_FILEONLY='cp -p'
1081
1082 dnl On MinGW, ensure we will call the MSYS /bin/ln.exe, not some
1083 dnl random program in the current directory.
1084 if (echo >conf$$.file) 2>/dev/null; then
1085   if ln -s conf$$.file conf$$ 2>/dev/null; then
1086     if test "$opsys" = "mingw32"; then
1087       LN_S_FILEONLY='/bin/ln -s'
1088     else
1089       LN_S_FILEONLY='ln -s'
1090     fi
1091   elif ln conf$$.file conf$$ 2>/dev/null; then
1092     if test "$opsys" = "mingw32"; then
1093       LN_S_FILEONLY=/bin/ln
1094     else
1095       LN_S_FILEONLY=ln
1096     fi
1097   fi
1098 fi
1099
1100 rm -f conf$$ conf$$.file
1101
1102 if test "$LN_S_FILEONLY" = "ln -s"; then
1103    AC_MSG_RESULT([yes])
1104 else
1105    AC_MSG_RESULT([no, using $LN_S_FILEONLY])
1106 fi
1107
1108 AC_SUBST(LN_S_FILEONLY)
1109
1110
1111 dnl AC_PROG_LN_S sets LN_S to 'cp -pR' for MinGW, on the premise that 'ln'
1112 dnl doesn't support links to directories, as in "ln file dir".  But that
1113 dnl use is non-portable, and OTOH MinGW wants to use hard links for Emacs
1114 dnl executables at "make install" time.
1115 dnl See http://lists.gnu.org/archive/html/emacs-devel/2013-04/msg00475.html
1116 dnl for more details.
1117 if test "$opsys" = "mingw32"; then
1118   LN_S="/bin/ln"
1119 fi
1120
1121 dnl On some Debian versions, "install-info" prints irritating messages
1122 dnl "This is not dpkg install-info anymore, but GNU install-info"
1123 dnl if called via an absolute file name.
1124 dnl Use the entirely-identical-but-quieter ginstall-info instead if present.
1125 dnl Sadly some people may have an old ginstall-info installed on
1126 dnl non-Debian systems, so we can't use this.
1127 dnl AC_PATH_PROGS(INSTALL_INFO, [ginstall-info install-info], :,
1128 dnl   $PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin)
1129
1130 AC_PATH_PROG(INSTALL_INFO, install-info, :,
1131   $PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin)
1132 dnl Don't use GZIP, which is used by gzip for additional parameters.
1133 AC_PATH_PROG(GZIP_PROG, gzip)
1134
1135 test $with_compress_install != yes && test -n "$GZIP_PROG" && \
1136    GZIP_PROG=" # $GZIP_PROG # (disabled by configure --without-compress-install)"
1137
1138 if test $opsys = gnu-linux; then
1139   AC_PATH_PROG(PAXCTL, paxctl,,
1140     [$PATH$PATH_SEPARATOR/sbin$PATH_SEPARATOR/usr/sbin])
1141   if test "X$PAXCTL" != X; then
1142     AC_MSG_CHECKING([whether binaries have a PT_PAX_FLAGS header])
1143     AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
1144       [if $PAXCTL -v conftest$EXEEXT >/dev/null 2>&1; then AC_MSG_RESULT(yes)
1145       else AC_MSG_RESULT(no); PAXCTL=""; fi])
1146   fi
1147
1148   if test "${SETFATTR+set}" != set; then
1149     AC_CACHE_CHECK([for setfattr],
1150       [emacs_cv_prog_setfattr],
1151       [touch conftest.tmp
1152        if (setfattr -n user.pax.flags conftest.tmp) >/dev/null 2>&1; then
1153          emacs_cv_prog_setfattr=yes
1154        else
1155          emacs_cv_prog_setfattr=no
1156        fi])
1157     if test "$emacs_cv_prog_setfattr" = yes; then
1158       SETFATTR=setfattr
1159     else
1160       SETFATTR=
1161     fi
1162     rm -f conftest.tmp
1163     AC_SUBST([SETFATTR])
1164   fi
1165 fi
1166
1167 ## Need makeinfo >= 4.7 (?) to build the manuals.
1168 if test "$MAKEINFO" != "no"; then
1169   if test "$MAKEINFO" = "${am_missing_run}makeinfo"; then
1170     MAKEINFO=makeinfo
1171   fi
1172   case `($MAKEINFO --version) 2>/dev/null` in
1173     *' (GNU texinfo) '4.[[7-9]]* | \
1174     *' (GNU texinfo) '4.[[1-9][0-9]]* | \
1175     *' (GNU texinfo) '[[5-9]]* | \
1176     *' (GNU texinfo) '[[1-9][0-9]]* ) ;;
1177     *) MAKEINFO=no;;
1178   esac
1179 fi
1180
1181 ## Makeinfo is unusual.  For a released Emacs, the manuals are
1182 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
1183 ## therefore in the category of "special tools" not normally required, which
1184 ## configure does not have to check for (eg autoconf itself).
1185 ## In a repository checkout on the other hand, the manuals are not included.
1186 ## So makeinfo is a requirement to build from the repository, and configure
1187 ## should test for it as it does for any other build requirement.
1188 ## We use the presence of $srcdir/info/emacs to distinguish a release,
1189 ## with pre-built manuals, from a repository checkout.
1190 HAVE_MAKEINFO=yes
1191
1192 if test "$MAKEINFO" = "no"; then
1193   MAKEINFO=makeinfo
1194   if test "x${with_makeinfo}" = "xno"; then
1195     HAVE_MAKEINFO=no
1196   elif test ! -e "$srcdir/info/emacs" && test ! -e "$srcdir/info/emacs.info"; then
1197     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.7, and your
1198 source tree does not seem to have pre-built manuals in the 'info' directory.
1199 Either install a suitable version of makeinfo, or re-run configure
1200 with the '--without-makeinfo' option to build without the manuals.] )
1201   fi
1202 fi
1203 AC_SUBST(HAVE_MAKEINFO)
1204
1205 if test $opsys = mingw32; then
1206    DOCMISC_W32=efaq-w32
1207 else
1208    DOCMISC_W32=
1209 fi
1210 AC_SUBST(DOCMISC_W32)
1211
1212 dnl Add our options to ac_link now, after it is set up.
1213
1214 if test x$GCC = xyes; then
1215   test "x$GCC_LINK_TEST_OPTIONS" != x && \
1216     ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
1217 else
1218   test "x$NON_GCC_LINK_TEST_OPTIONS" != x && \
1219     ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
1220 fi
1221
1222 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
1223 dnl If we can link with the flag, it shouldn't do any harm anyhow.
1224 dnl (Don't use '-z nocombreloc' as -z takes no arg on Irix.)
1225 dnl Treat GCC specially since it just gives a non-fatal 'unrecognized option'
1226 dnl if not built to support GNU ld.
1227
1228 dnl For a long time, -znocombreloc was added to LDFLAGS rather than
1229 dnl LD_SWITCH_SYSTEM_TEMACS.  That is:
1230 dnl * inappropriate, as LDFLAGS is a user option but this is essential.
1231 dnl   Eg "make LDFLAGS=... all" could run into problems,
1232 dnl   http://bugs.debian.org/684788
1233 dnl * unnecessary, since temacs is the only thing that actually needs it.
1234 dnl   Indeed this is where it was originally, prior to:
1235 dnl   http://lists.gnu.org/archive/html/emacs-pretest-bug/2004-03/msg00170.html
1236 late_LDFLAGS="$LDFLAGS"
1237 if test x$GCC = xyes; then
1238   LDFLAGS_NOCOMBRELOC="-Wl,-znocombreloc"
1239 else
1240   LDFLAGS_NOCOMBRELOC="-znocombreloc"
1241 fi
1242
1243 LDFLAGS="$LDFLAGS $LDFLAGS_NOCOMBRELOC"
1244
1245 AC_MSG_CHECKING([for -znocombreloc])
1246 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
1247   [AC_MSG_RESULT(yes)],
1248   LDFLAGS_NOCOMBRELOC=
1249   [AC_MSG_RESULT(no)])
1250
1251 LDFLAGS="$late_LDFLAGS"
1252
1253 AC_CACHE_CHECK([whether addresses are sanitized],
1254   [emacs_cv_sanitize_address],
1255   [AC_COMPILE_IFELSE(
1256      [AC_LANG_PROGRAM(
1257         [[#ifndef __has_feature
1258           #define __has_feature(f) 0
1259           #endif
1260           #if defined __SANITIZE_ADDRESS__ || __has_feature (address_sanitizer)
1261           #else
1262            error "Addresses are not sanitized.";
1263           #endif
1264         ]])],
1265      [emacs_cv_sanitize_address=yes],
1266      [emacs_cv_sanitize_address=no])])
1267
1268 dnl The function dump-emacs will not be defined and temacs will do
1269 dnl (load "loadup") automatically unless told otherwise.
1270 test "x$CANNOT_DUMP" = "x" && CANNOT_DUMP=no
1271 case "$opsys" in
1272   nacl) CANNOT_DUMP=yes ;;
1273 esac
1274
1275 if test "$CANNOT_DUMP" = "yes"; then
1276   AC_DEFINE(CANNOT_DUMP, 1, [Define if Emacs cannot be dumped on your system.])
1277 elif test "$emacs_cv_sanitize_address" = yes; then
1278   AC_MSG_WARN([[Addresses are sanitized; suggest CANNOT_DUMP=yes]])
1279 fi
1280
1281 AC_SUBST(CANNOT_DUMP)
1282
1283
1284 UNEXEC_OBJ=unexelf.o
1285 case "$opsys" in
1286   # MSDOS uses unexcoff.o
1287   aix4-2)
1288    UNEXEC_OBJ=unexaix.o
1289    ;;
1290   cygwin)
1291    UNEXEC_OBJ=unexcw.o
1292    ;;
1293   darwin)
1294    UNEXEC_OBJ=unexmacosx.o
1295    ;;
1296   hpux10-20 | hpux11)
1297    UNEXEC_OBJ=unexhp9k800.o
1298    ;;
1299   mingw32)
1300    UNEXEC_OBJ=unexw32.o
1301    ;;
1302   sol2-10)
1303    # Use the Solaris dldump() function, called from unexsol.c, to dump
1304    # emacs, instead of the generic ELF dump code found in unexelf.c.
1305    # The resulting binary has a complete symbol table, and is better
1306    # for debugging and other observability tools (debuggers, pstack, etc).
1307    #
1308    # If you encounter a problem using dldump(), please consider sending
1309    # a message to the OpenSolaris tools-linking mailing list:
1310    #      http://mail.opensolaris.org/mailman/listinfo/tools-linking
1311    #
1312    # It is likely that dldump() works with older Solaris too, but this has
1313    # not been tested, so for now this change is for Solaris 10 or newer.
1314    UNEXEC_OBJ=unexsol.o
1315    ;;
1316 esac
1317
1318 LD_SWITCH_SYSTEM=
1319 case "$opsys" in
1320   freebsd|dragonfly)
1321    ## Let 'ld' find image libs and similar things in /usr/local/lib.
1322    ## The system compiler, GCC, has apparently been modified to not
1323    ## look there, contrary to what a stock GCC would do.
1324 ### It's not our place to do this.  See bug#10313#17.
1325 ###   LD_SWITCH_SYSTEM=-L/usr/local/lib
1326       :
1327    ;;
1328
1329   gnu-linux)
1330    ## cpp test was "ifdef __mips__", but presumably this is equivalent...
1331    case $host_cpu in mips*) LD_SWITCH_SYSTEM="-G 0";; esac
1332    ;;
1333
1334   netbsd)
1335 ### It's not our place to do this.  See bug#10313#17.
1336 ###   LD_SWITCH_SYSTEM="-Wl,-rpath,/usr/pkg/lib -L/usr/pkg/lib -Wl,-rpath,/usr/local/lib -L/usr/local/lib"
1337       :
1338    ;;
1339
1340   openbsd)
1341    ## Han Boetes <han@boetes.org> says this is necessary,
1342    ## otherwise Emacs dumps core on elf systems.
1343    LD_SWITCH_SYSTEM="-Z"
1344    ;;
1345 esac
1346 AC_SUBST(LD_SWITCH_SYSTEM)
1347
1348 ac_link="$ac_link $LD_SWITCH_SYSTEM"
1349
1350 ## This setting of LD_SWITCH_SYSTEM references LD_SWITCH_X_SITE_RPATH,
1351 ## which has not been defined yet.  When this was handled with cpp,
1352 ## it was expanded to null when configure sourced the s/*.h file.
1353 ## Thus LD_SWITCH_SYSTEM had different values in configure and the Makefiles.
1354 ## FIXME it would be cleaner to put this in LD_SWITCH_SYSTEM_TEMACS
1355 ## (or somesuch), but because it is supposed to go at the _front_
1356 ## of LD_SWITCH_SYSTEM, we cannot do that in exactly the same way.
1357 ## Compare with the gnu-linux case below, which added to the end
1358 ## of LD_SWITCH_SYSTEM, and so can instead go at the front of
1359 ## LD_SWITCH_SYSTEM_TEMACS.
1360 case "$opsys" in
1361   netbsd|openbsd)
1362    LD_SWITCH_SYSTEM="\$(LD_SWITCH_X_SITE_RPATH) $LD_SWITCH_SYSTEM" ;;
1363 esac
1364
1365
1366 C_SWITCH_MACHINE=
1367 case $canonical in
1368  alpha*)
1369   AC_CHECK_DECL([__ELF__])
1370   if test "$ac_cv_have_decl___ELF__" = "yes"; then
1371     ## With ELF, make sure that all common symbols get allocated to in the
1372     ## data section.  Otherwise, the dump of temacs may miss variables in
1373     ## the shared library that have been initialized.  For example, with
1374     ## GNU libc, __malloc_initialized would normally be resolved to the
1375     ## shared library's .bss section, which is fatal.
1376     if test "x$GCC" = "xyes"; then
1377       C_SWITCH_MACHINE="-fno-common"
1378     else
1379       AC_MSG_ERROR([Non-GCC compilers are not supported.])
1380     fi
1381   else
1382       dnl This was the unexalpha.c case.  Removed in 24.1, 2010-07-24,
1383       dnl albeit under the mistaken assumption that said file
1384       dnl was no longer used.
1385       AC_MSG_ERROR([Non-ELF systems are not supported since Emacs 24.1.])
1386   fi
1387   ;;
1388 esac
1389 AC_SUBST(C_SWITCH_MACHINE)
1390
1391 AC_SUBST(UNEXEC_OBJ)
1392
1393 C_SWITCH_SYSTEM=
1394 ## Some programs in src produce warnings saying certain subprograms
1395 ## are too complex and need a MAXMEM value greater than 2000 for
1396 ## additional optimization.  --nils@exp-math.uni-essen.de
1397 test "$opsys" = "aix4.2" && test "x$GCC" != "xyes" && \
1398   C_SWITCH_SYSTEM="-ma -qmaxmem=4000"
1399 if test "$opsys" = "mingw32"; then
1400   case "$canonical" in
1401     x86_64-*-mingw*) C_SWITCH_SYSTEM="-mtune=generic" ;;
1402     *) C_SWITCH_SYSTEM="-mtune=pentium4" ;;
1403   esac
1404 fi
1405 ## gnu-linux might need -D_BSD_SOURCE on old libc5 systems.
1406 ## It is redundant in glibc2, since we define _GNU_SOURCE.
1407 AC_SUBST(C_SWITCH_SYSTEM)
1408
1409
1410 LIBS_SYSTEM=
1411 case "$opsys" in
1412   ## IBM's X11R5 uses -lIM and -liconv in AIX 3.2.2.
1413   aix4-2) LIBS_SYSTEM="-lrts -lIM -liconv" ;;
1414
1415   freebsd|dragonfly) LIBS_SYSTEM="-lutil" ;;
1416
1417   hpux*) LIBS_SYSTEM="-l:libdld.sl" ;;
1418
1419   sol2*) LIBS_SYSTEM="-lsocket -lnsl" ;;
1420
1421   ## Motif needs -lgen.
1422   unixware) LIBS_SYSTEM="-lsocket -lnsl -lelf -lgen" ;;
1423 esac
1424
1425 AC_SUBST(LIBS_SYSTEM)
1426
1427 ### Make sure subsequent tests use flags consistent with the build flags.
1428
1429 if test x"${OVERRIDE_CPPFLAGS}" != x; then
1430   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
1431 else
1432   CPPFLAGS="$C_SWITCH_SYSTEM $C_SWITCH_MACHINE $CPPFLAGS"
1433 fi
1434
1435 # Suppress obsolescent Autoconf test for size_t; Emacs assumes C99 or better.
1436 AC_DEFUN([AC_TYPE_SIZE_T])
1437 # Likewise for obsolescent test for uid_t, gid_t; Emacs assumes them.
1438 AC_DEFUN([AC_TYPE_UID_T])
1439
1440 # sqrt and other floating-point functions such as fmod and frexp
1441 # are found in -lm on many systems.
1442 OLD_LIBS=$LIBS
1443 AC_SEARCH_LIBS([sqrt], [m])
1444 if test "X$LIBS" = "X$OLD_LIBS"; then
1445   LIB_MATH=
1446 else
1447   LIB_MATH=$ac_cv_search_sqrt
1448 fi
1449 LIBS=$OLD_LIBS
1450
1451 dnl Current possibilities handled by sed (aix4-2 -> aix,
1452 dnl gnu-linux -> gnu/linux, etc.):
1453 dnl gnu, gnu/linux, gnu/kfreebsd, aix, cygwin, darwin, hpux, irix.
1454 dnl And special cases: berkeley-unix, usg-unix-v, ms-dos, windows-nt.
1455 SYSTEM_TYPE=`echo $opsys | sed -e 's/[[0-9]].*//' -e 's|-|/|'`
1456
1457 case $opsys in
1458   cygwin )
1459     LIB_MATH=
1460     ;;
1461   darwin )
1462     ## Adding -lm confuses the dynamic linker, so omit it.
1463     LIB_MATH=
1464     ;;
1465   freebsd | dragonfly )
1466     SYSTEM_TYPE=berkeley-unix
1467     ;;
1468   gnu-linux | gnu-kfreebsd )
1469     ;;
1470   hpux10-20 | hpux11 )
1471     ;;
1472   mingw32 )
1473     LIB_MATH=
1474     SYSTEM_TYPE=windows-nt
1475     ;;
1476   dnl NB this may be adjusted below.
1477   netbsd | openbsd )
1478     SYSTEM_TYPE=berkeley-unix
1479     ;;
1480
1481   sol2* | unixware )
1482     SYSTEM_TYPE=usg-unix-v
1483     ;;
1484
1485 esac
1486
1487 AC_SUBST(LIB_MATH)
1488 AC_DEFINE_UNQUOTED(SYSTEM_TYPE, "$SYSTEM_TYPE",
1489   [The type of system you are compiling for; sets 'system-type'.])
1490
1491
1492 pre_PKG_CONFIG_CFLAGS=$CFLAGS
1493 pre_PKG_CONFIG_LIBS=$LIBS
1494
1495 PKG_PROG_PKG_CONFIG(0.9.0)
1496
1497 dnl EMACS_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4)
1498 dnl acts like PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4,
1499 dnl HAVE_GSTUFF=yes, HAVE_GSTUFF=no) -- see pkg-config man page --
1500 dnl except that it postprocesses CFLAGS as needed for --enable-gcc-warnings.
1501 dnl EMACS_CHECK_MODULES accepts optional 3rd and 4th arguments that
1502 dnl can take the place of the default HAVE_GSTUFF=yes and HAVE_GSTUFF=no
1503 dnl actions.
1504 AC_DEFUN([EMACS_CHECK_MODULES],
1505   [PKG_CHECK_MODULES([$1], [$2],
1506      [$1_CFLAGS=`AS_ECHO(["$$1_CFLAGS"]) | sed -e "$edit_cflags"`
1507       m4_default([$3], [HAVE_$1=yes])],
1508      [m4_default([$4], [HAVE_$1=no])])])
1509
1510 HAVE_SOUND=no
1511 if test "${with_sound}" != "no"; then
1512   # Sound support for GNU/Linux, the free BSDs, MinGW, and Cygwin.
1513   AC_CHECK_HEADERS([machine/soundcard.h sys/soundcard.h soundcard.h mmsystem.h],
1514     have_sound_header=yes, [], [
1515     #ifdef __MINGW32__
1516     #define WIN32_LEAN_AND_MEAN
1517     #include <windows.h>
1518     #endif
1519     ])
1520   test "${with_sound}" = "oss" && test "${have_sound_header}" != "yes" && \
1521     AC_MSG_ERROR([OSS sound support requested but not found.])
1522
1523   if test "${with_sound}" = "bsd-ossaudio" || test "${with_sound}" = "yes"; then
1524     # Emulation library used on NetBSD.
1525     AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1526     test "${with_sound}" = "bsd-ossaudio" && test -z "$LIBSOUND" && \
1527       AC_MSG_ERROR([bsd-ossaudio sound support requested but not found.])
1528     dnl FIXME?  If we did find ossaudio, should we set with_sound=bsd-ossaudio?
1529     dnl Traditionally, we go on to check for alsa too.  Does that make sense?
1530   fi
1531   AC_SUBST(LIBSOUND)
1532
1533   if test "${with_sound}" = "alsa" || test "${with_sound}" = "yes"; then
1534     ALSA_REQUIRED=1.0.0
1535     ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1536     EMACS_CHECK_MODULES([ALSA], [$ALSA_MODULES])
1537     if test $HAVE_ALSA = yes; then
1538       SAVE_CFLAGS="$CFLAGS"
1539       SAVE_LIBS="$LIBS"
1540       CFLAGS="$ALSA_CFLAGS $CFLAGS"
1541       LIBS="$ALSA_LIBS $LIBS"
1542       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <asoundlib.h>]], [[snd_lib_error_set_handler (0);]])],
1543                       emacs_alsa_normal=yes,
1544                     emacs_alsa_normal=no)
1545       if test "$emacs_alsa_normal" != yes; then
1546         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <alsa/asoundlib.h>]],
1547                        [[snd_lib_error_set_handler (0);]])],
1548                        emacs_alsa_subdir=yes,
1549                      emacs_alsa_subdir=no)
1550         if test "$emacs_alsa_subdir" != yes; then
1551           AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1552         fi
1553         ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1554       fi
1555
1556       CFLAGS="$SAVE_CFLAGS"
1557       LIBS="$SAVE_LIBS"
1558       LIBSOUND="$LIBSOUND $ALSA_LIBS"
1559       CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1560       AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1561     elif test "${with_sound}" = "alsa"; then
1562       AC_MSG_ERROR([ALSA sound support requested but not found.])
1563     fi
1564   fi                            dnl with_sound = alsa|yes
1565
1566   dnl Define HAVE_SOUND if we have sound support.  We know it works and
1567   dnl compiles only on the specified platforms.  For others, it
1568   dnl probably doesn't make sense to try.
1569   dnl FIXME So surely we should bypass this whole section if not using
1570   dnl one of these platforms?
1571   if test x$have_sound_header = xyes || test $HAVE_ALSA = yes; then
1572      case "$opsys" in
1573        dnl defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
1574        dnl Adjust the --with-sound help text if you change this.
1575        gnu-linux|freebsd|netbsd|mingw32|cygwin)
1576          AC_DEFINE(HAVE_SOUND, 1, [Define to 1 if you have sound support.])
1577          HAVE_SOUND=yes
1578          ;;
1579      esac
1580   fi
1581
1582   AC_SUBST(CFLAGS_SOUND)
1583 fi
1584
1585 dnl checks for header files
1586 AC_CHECK_HEADERS_ONCE(
1587   sys/systeminfo.h
1588   sys/sysinfo.h
1589   coff.h pty.h
1590   sys/resource.h
1591   sys/utsname.h pwd.h utmp.h util.h)
1592
1593 AC_MSG_CHECKING(if personality LINUX32 can be set)
1594 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/personality.h>]], [[personality (PER_LINUX32)]])],
1595                emacs_cv_personality_linux32=yes,
1596                emacs_cv_personality_linux32=no)
1597 AC_MSG_RESULT($emacs_cv_personality_linux32)
1598
1599 if test $emacs_cv_personality_linux32 = yes; then
1600   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1601             [Define to 1 if personality LINUX32 can be set.])
1602 fi
1603
1604 # Note that Solaris has sys/sysinfo.h which defines struct
1605 # sysinfo as well.  To make sure that we're using GNU/Linux
1606 # sysinfo, we explicitly set one of its fields.
1607 if test "$ac_cv_header_sys_sysinfo_h" = yes; then
1608   AC_MSG_CHECKING([if Linux sysinfo may be used])
1609   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/sysinfo.h>]],
1610                                      [[struct sysinfo si;
1611                                        si.totalram = 0;
1612                                        sysinfo (&si)]])],
1613     emacs_cv_linux_sysinfo=yes, emacs_cv_linux_sysinfo=no)
1614   AC_MSG_RESULT($emacs_cv_linux_sysinfo)
1615   if test $emacs_cv_linux_sysinfo = yes; then
1616     AC_DEFINE([HAVE_LINUX_SYSINFO], 1, [Define to 1 if you have Linux sysinfo function.])
1617     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/sysinfo.h>]],
1618                                        [[struct sysinfo si; return si.mem_unit]])],
1619       AC_DEFINE(LINUX_SYSINFO_UNIT, 1,
1620                 [Define to 1 if Linux sysinfo sizes are in multiples of mem_unit bytes.]))
1621   fi
1622 fi
1623
1624 dnl On Solaris 8 there's a compilation warning for term.h because
1625 dnl it doesn't define 'bool'.
1626 AC_CHECK_HEADERS(term.h, , , -)
1627 AC_HEADER_TIME
1628 AC_CHECK_DECLS([sys_siglist], [], [], [[#include <signal.h>
1629                                       ]])
1630 if test $ac_cv_have_decl_sys_siglist != yes; then
1631   # For Tru64, at least:
1632   AC_CHECK_DECLS([__sys_siglist], [], [], [[#include <signal.h>
1633                                           ]])
1634 fi
1635 AC_HEADER_SYS_WAIT
1636
1637 AC_CHECK_HEADERS_ONCE(sys/socket.h)
1638 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1639 #if HAVE_SYS_SOCKET_H
1640 #include <sys/socket.h>
1641 #endif])
1642 AC_CHECK_HEADERS(ifaddrs.h, , , [AC_INCLUDES_DEFAULT
1643 #if HAVE_SYS_SOCKET_H
1644 #include <sys/socket.h>
1645 #endif])
1646 AC_CHECK_HEADERS(net/if_dl.h, , , [AC_INCLUDES_DEFAULT
1647 #if HAVE_SYS_SOCKET_H
1648 #include <sys/socket.h>
1649 #endif])
1650
1651 dnl checks for structure members
1652 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1653                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1654                   struct ifreq.ifr_addr,
1655                   struct ifreq.ifr_addr.sa_len], , ,
1656                  [AC_INCLUDES_DEFAULT
1657 #if HAVE_SYS_SOCKET_H
1658 #include <sys/socket.h>
1659 #endif
1660 #if HAVE_NET_IF_H
1661 #include <net/if.h>
1662 #endif])
1663
1664 dnl Check for endianness.
1665 dnl AC_C_BIGENDIAN is done by gnulib.
1666
1667 dnl check for Make feature
1668
1669 AUTO_DEPEND=no
1670 dnl check if we have GCC and autodepend is on.
1671 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1672    AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1673    SAVE_CFLAGS="$CFLAGS"
1674    CFLAGS="$CFLAGS -MMD -MF deps.d -MP"
1675    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], , ac_enable_autodepend=no)
1676    CFLAGS="$SAVE_CFLAGS"
1677    test -f deps.d || ac_enable_autodepend=no
1678    rm -rf deps.d
1679    AC_MSG_RESULT([$ac_enable_autodepend])
1680    if test $ac_enable_autodepend = yes; then
1681       AUTO_DEPEND=yes
1682    fi
1683 fi
1684 AC_SUBST(AUTO_DEPEND)
1685
1686 dnl checks for operating system services
1687 AC_SYS_LONG_FILE_NAMES
1688
1689 #### Choose a window system.
1690
1691 ## We leave window_system equal to none if
1692 ## we end up building without one.  Any new window system should
1693 ## set window_system to an appropriate value and add objects to
1694 ## window-system-specific substs.
1695
1696 window_system=none
1697 AC_PATH_X
1698 if test "$no_x" != yes; then
1699   window_system=x11
1700 fi
1701
1702 LD_SWITCH_X_SITE_RPATH=
1703 if test "${x_libraries}" != NONE; then
1704   if test -n "${x_libraries}"; then
1705     LD_SWITCH_X_SITE=-L`AS_ECHO(["$x_libraries"]) | sed -e 's/:/ -L/g'`
1706     LD_SWITCH_X_SITE_RPATH=-Wl,-rpath,`
1707       AS_ECHO(["$x_libraries"]) | sed -e 's/:/ -Wl,-rpath,/g'
1708     `
1709   fi
1710   x_default_search_path=""
1711   x_search_path=${x_libraries}
1712   if test -z "${x_search_path}"; then
1713     x_search_path=/usr/lib
1714   fi
1715   for x_library in `AS_ECHO(["$x_search_path:"]) | \
1716                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1717     x_search_path="\
1718 ${x_library}/X11/%L/%T/%N%C%S:\
1719 ${x_library}/X11/%l/%T/%N%C%S:\
1720 ${x_library}/X11/%T/%N%C%S:\
1721 ${x_library}/X11/%L/%T/%N%S:\
1722 ${x_library}/X11/%l/%T/%N%S:\
1723 ${x_library}/X11/%T/%N%S"
1724     if test x"${x_default_search_path}" = x; then
1725       x_default_search_path=${x_search_path}
1726     else
1727       x_default_search_path="${x_search_path}:${x_default_search_path}"
1728     fi
1729   done
1730 fi
1731 AC_SUBST(LD_SWITCH_X_SITE_RPATH)
1732
1733 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1734   C_SWITCH_X_SITE=$isystem`AS_ECHO(["$x_includes"]) | sed -e "s/:/ $isystem/g"`
1735 fi
1736
1737 if test x"${x_includes}" = x; then
1738   bitmapdir=/usr/include/X11/bitmaps
1739 else
1740   # accumulate include directories that have X11 bitmap subdirectories
1741   bmd_acc=
1742   for bmd in `AS_ECHO(["$x_includes"]) | sed -e 's/:/ /g'`; do
1743     if test -d "${bmd}/X11/bitmaps"; then
1744       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1745     fi
1746     if test -d "${bmd}/bitmaps"; then
1747       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1748     fi
1749   done
1750   bitmapdir=${bmdacc#:}
1751 fi
1752
1753 test "${with_ns}" = maybe && test "${opsys}" != darwin && with_ns=no
1754 HAVE_NS=no
1755 NS_GNUSTEP_CONFIG=no
1756 NS_IMPL_COCOA=no
1757 NS_IMPL_GNUSTEP=no
1758 tmp_CPPFLAGS="$CPPFLAGS"
1759 tmp_CFLAGS="$CFLAGS"
1760 CPPFLAGS="$CPPFLAGS -x objective-c"
1761 CFLAGS="$CFLAGS -x objective-c"
1762 GNU_OBJC_CFLAGS=
1763 LIBS_GNUSTEP=
1764 if test "${with_ns}" != no; then
1765   if test "${opsys}" = darwin; then
1766      NS_IMPL_COCOA=yes
1767      ns_appdir=`pwd`/nextstep/Emacs.app
1768      ns_appbindir=${ns_appdir}/Contents/MacOS
1769      ns_appresdir=${ns_appdir}/Contents/Resources
1770      ns_appsrc=Cocoa/Emacs.base
1771      ns_fontfile=macfont.o
1772   elif flags=$( (gnustep-config --objc-flags) 2>/dev/null); then
1773      NS_IMPL_GNUSTEP=yes
1774      NS_GNUSTEP_CONFIG=yes
1775      GNU_OBJC_CFLAGS=$flags
1776      LIBS_GNUSTEP=$(gnustep-config --gui-libs) || exit
1777   elif test -f $GNUSTEP_CONFIG_FILE; then
1778      NS_IMPL_GNUSTEP=yes
1779      dnl FIXME sourcing this several times in subshells seems inefficient.
1780      GNUSTEP_SYSTEM_HEADERS=$(
1781        . $GNUSTEP_CONFIG_FILE
1782        AS_ECHO(["$GNUSTEP_SYSTEM_HEADERS"])
1783      )
1784      GNUSTEP_SYSTEM_LIBRARIES=$(
1785        . $GNUSTEP_CONFIG_FILE
1786        AS_ECHO(["$GNUSTEP_SYSTEM_LIBRARIES"])
1787      )
1788      dnl I seemed to need these as well with GNUstep-startup 0.25.
1789      GNUSTEP_LOCAL_HEADERS=$(
1790        . $GNUSTEP_CONFIG_FILE
1791        AS_ECHO(["$GNUSTEP_LOCAL_HEADERS"])
1792      )
1793      GNUSTEP_LOCAL_LIBRARIES=$(
1794        . $GNUSTEP_CONFIG_FILE
1795        AS_ECHO(["$GNUSTEP_LOCAL_LIBRARIES"])
1796      )
1797      test "x${GNUSTEP_LOCAL_HEADERS}" != "x" && \
1798        GNUSTEP_LOCAL_HEADERS="-I${GNUSTEP_LOCAL_HEADERS}"
1799      test "x${GNUSTEP_LOCAL_LIBRARIES}" != "x" && \
1800        GNUSTEP_LOCAL_LIBRARIES="-L${GNUSTEP_LOCAL_LIBRARIES}"
1801      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1802      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1803      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES}"
1804      LIBS_GNUSTEP="-lgnustep-gui -lgnustep-base -lobjc -lpthread"
1805      dnl GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS to 0 or 1.
1806      dnl If they had chosen to either define it or not, we could have
1807      dnl just used AC_CHECK_DECL here.
1808      AC_CACHE_CHECK(if GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS,
1809        emacs_cv_objc_exceptions,
1810 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <GNUstepBase/GSConfig.h>]],
1811 [[#if defined BASE_NATIVE_OBJC_EXCEPTIONS && BASE_NATIVE_OBJC_EXCEPTIONS > 0
1812 1;
1813 #else
1814 fail;
1815 #endif]])], emacs_cv_objc_exceptions=yes, emacs_cv_objc_exceptions=no ) )
1816      if test $emacs_cv_objc_exceptions = yes; then
1817        dnl _NATIVE_OBJC_EXCEPTIONS is used by the GNUstep headers.
1818        AC_DEFINE(_NATIVE_OBJC_EXCEPTIONS, 1,
1819          [Define if GNUstep uses ObjC exceptions.])
1820        GNU_OBJC_CFLAGS="-fobjc-exceptions"
1821      fi
1822   fi
1823   if test $NS_IMPL_GNUSTEP = yes; then
1824      ns_appdir=`pwd`/nextstep/Emacs.app
1825      ns_appbindir=${ns_appdir}
1826      ns_appresdir=${ns_appdir}/Resources
1827      ns_appsrc=GNUstep/Emacs.base
1828      ns_fontfile=nsfont.o
1829   fi
1830
1831   dnl This is only used while we test the NS headers, it gets reset below.
1832   CPPFLAGS="$CPPFLAGS $GNU_OBJC_CFLAGS"
1833   CFLAGS="$CFLAGS $GNU_OBJC_CFLAGS"
1834
1835   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1836                   [AC_MSG_ERROR([The include files (AppKit/AppKit.h etc) that
1837 are required for a Nextstep build are missing or cannot be compiled.
1838 Either fix this, or re-configure with the option '--without-ns'.])])
1839
1840   macfont_file=""
1841   if test "${NS_IMPL_COCOA}" = "yes"; then
1842     AC_MSG_CHECKING([for OSX 10.6 or newer])
1843     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <AppKit/AppKit.h>],
1844                                      [
1845 #ifdef MAC_OS_X_VERSION_MAX_ALLOWED
1846 #if MAC_OS_X_VERSION_MAX_ALLOWED >= 1060
1847  ; /* OK */
1848 #else
1849  error "OSX 10.6 or newer required";
1850 #endif
1851 #endif
1852                     ])],
1853                     ns_osx_have_106=yes,
1854                     ns_osx_have_106=no)
1855     AC_MSG_RESULT([$ns_osx_have_106])
1856
1857     if test $ns_osx_have_106 = no; then
1858        AC_MSG_ERROR([OSX 10.6 or newer is required]);
1859     fi
1860   fi
1861 fi
1862
1863 AC_SUBST(LIBS_GNUSTEP)
1864
1865 INSTALL_ARCH_INDEP_EXTRA=install-etc
1866 ns_self_contained=no
1867 NS_OBJ=
1868 NS_OBJC_OBJ=
1869 if test "${HAVE_NS}" = yes; then
1870   if test "$with_toolkit_scroll_bars" = "no"; then
1871     AC_MSG_ERROR([Non-toolkit scroll bars are not implemented for Nextstep.])
1872   fi
1873
1874   window_system=nextstep
1875   # set up packaging dirs
1876   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1877      ns_self_contained=yes
1878      prefix=${ns_appresdir}
1879      exec_prefix=${ns_appbindir}
1880      dnl This one isn't really used, only archlibdir is.
1881      libexecdir="\${ns_appbindir}/libexec"
1882      archlibdir="\${ns_appbindir}/libexec"
1883      etcdocdir="\${ns_appresdir}/etc"
1884      etcdir="\${ns_appresdir}/etc"
1885      dnl FIXME maybe set datarootdir instead.
1886      dnl That would also get applications, icons, man.
1887      infodir="\${ns_appresdir}/info"
1888      mandir="\${ns_appresdir}/man"
1889      lispdir="\${ns_appresdir}/lisp"
1890      test "$locallisppathset" = no && locallisppath=""
1891      INSTALL_ARCH_INDEP_EXTRA=
1892   fi
1893
1894   NS_OBJC_OBJ="nsterm.o nsfns.o nsmenu.o nsselect.o nsimage.o $ns_fontfile"
1895 fi
1896 CFLAGS="$tmp_CFLAGS"
1897 CPPFLAGS="$tmp_CPPFLAGS"
1898 AC_SUBST(INSTALL_ARCH_INDEP_EXTRA)
1899 AC_SUBST(ns_self_contained)
1900 AC_SUBST(NS_OBJ)
1901 AC_SUBST(NS_OBJC_OBJ)
1902
1903 HAVE_W32=no
1904 W32_OBJ=
1905 W32_LIBS=
1906 EMACSRES=
1907 CLIENTRES=
1908 CLIENTW=
1909 W32_RES_LINK=
1910 EMACS_MANIFEST=
1911 UPDATE_MANIFEST=
1912 if test "${with_w32}" != no; then
1913   case "${opsys}" in
1914     cygwin)
1915       AC_CHECK_HEADER([windows.h], [HAVE_W32=yes],
1916              [AC_MSG_ERROR(['--with-w32' was specified, but windows.h
1917                    cannot be found.])])
1918     ;;
1919     mingw32)
1920     ## Using --with-w32 with MinGW is a no-op, but we allow it.
1921     ;;
1922     *)
1923       AC_MSG_ERROR([Using w32 with an autotools build is only supported for Cygwin and MinGW32.])
1924     ;;
1925   esac
1926 fi
1927
1928 if test "${opsys}" = "mingw32"; then
1929   AC_MSG_CHECKING([whether Windows API headers are recent enough])
1930   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1931      #include <windows.h>
1932      #include <usp10.h>]],
1933    [[PIMAGE_NT_HEADERS pHeader;
1934      PIMAGE_SECTION_HEADER pSection = IMAGE_FIRST_SECTION(pHeader)]])],
1935    [emacs_cv_w32api=yes
1936     HAVE_W32=yes],
1937    emacs_cv_w32api=no)
1938   AC_MSG_RESULT($emacs_cv_w32api)
1939   if test "${emacs_cv_w32api}" = "no"; then
1940     AC_MSG_ERROR([the Windows API headers are too old to support this build.])
1941   fi
1942 fi
1943
1944 FIRSTFILE_OBJ=
1945 NTDIR=
1946 LIBS_ECLIENT=
1947 LIB_WSOCK32=
1948 NTLIB=
1949 CM_OBJ="cm.o"
1950 XARGS_LIMIT=
1951 if test "${HAVE_W32}" = "yes"; then
1952   AC_DEFINE(HAVE_NTGUI, 1, [Define to use native MS Windows GUI.])
1953   if test "$with_toolkit_scroll_bars" = "no"; then
1954     AC_MSG_ERROR([Non-toolkit scroll bars are not implemented for w32 build.])
1955   fi
1956   AC_CHECK_TOOL(WINDRES, [windres],
1957                 [AC_MSG_ERROR([No resource compiler found.])])
1958   W32_OBJ="w32fns.o w32menu.o w32reg.o w32font.o w32term.o"
1959   W32_OBJ="$W32_OBJ w32xfns.o w32select.o w32uniscribe.o"
1960   EMACSRES="emacs.res"
1961   case "$canonical" in
1962     x86_64-*-*) EMACS_MANIFEST="emacs-x64.manifest" ;;
1963     *) EMACS_MANIFEST="emacs-x86.manifest" ;;
1964   esac
1965   dnl Construct something of the form "24,4,0,0" with 4 components.
1966   comma_version=`echo "${PACKAGE_VERSION}.0.0" | sed -e 's/\./,/g' -e 's/^\([[^,]]*,[[^,]]*,[[^,]]*,[[^,]]*\).*/\1/'`
1967
1968   comma_space_version=`echo "$comma_version" | sed 's/,/, /g'`
1969   AC_SUBST(comma_version)
1970   AC_SUBST(comma_space_version)
1971   AC_CONFIG_FILES([nt/emacs.rc nt/emacsclient.rc])
1972   if test "${opsys}" = "cygwin"; then
1973     W32_LIBS="$W32_LIBS -lkernel32 -luser32 -lgdi32 -lole32 -lcomdlg32"
1974     W32_LIBS="$W32_LIBS -lusp10 -lcomctl32 -lwinspool"
1975     # Tell the linker that emacs.res is an object (which we compile from
1976     # the rc file), not a linker script.
1977     W32_RES_LINK="-Wl,emacs.res"
1978   else
1979     UPDATE_MANIFEST=update-game-score.exe.manifest
1980     W32_OBJ="$W32_OBJ w32.o w32console.o w32heap.o w32inevt.o w32proc.o"
1981     W32_LIBS="$W32_LIBS -lwinmm -lgdi32 -lcomdlg32"
1982     W32_LIBS="$W32_LIBS -lmpr -lwinspool -lole32 -lcomctl32 -lusp10"
1983     W32_RES_LINK="\$(EMACSRES)"
1984     CLIENTRES="emacsclient.res"
1985     CLIENTW="emacsclientw\$(EXEEXT)"
1986     FIRSTFILE_OBJ=firstfile.o
1987     NTDIR=nt
1988     CM_OBJ=
1989     LIBS_ECLIENT="-lcomctl32"
1990     LIB_WSOCK32="-lwsock32"
1991     NTLIB="ntlib.$ac_objext"
1992     XARGS_LIMIT="-s 10000"
1993   fi
1994 fi
1995 AC_SUBST(W32_OBJ)
1996 AC_SUBST(W32_LIBS)
1997 AC_SUBST(EMACSRES)
1998 AC_SUBST(EMACS_MANIFEST)
1999 AC_SUBST(UPDATE_MANIFEST)
2000 AC_SUBST(CLIENTRES)
2001 AC_SUBST(CLIENTW)
2002 AC_SUBST(W32_RES_LINK)
2003 AC_SUBST(FIRSTFILE_OBJ)
2004 AC_SUBST(NTDIR)
2005 AC_SUBST(CM_OBJ)
2006 AC_SUBST(LIBS_ECLIENT)
2007 AC_SUBST(LIB_WSOCK32)
2008 AC_SUBST(NTLIB)
2009 AC_SUBST(XARGS_LIMIT)
2010
2011 if test "${HAVE_W32}" = "yes"; then
2012   window_system=w32
2013   with_xft=no
2014 fi
2015
2016 ## $window_system is now set to the window system we will
2017 ## ultimately use.
2018
2019 if test "$window_system" = none && test "$gl_gcc_warnings" = yes; then
2020    # Too many warnings for now.
2021    nw=
2022    nw="$nw -Wsuggest-attribute=noreturn"
2023    gl_MANYWARN_COMPLEMENT([WARN_CFLAGS], [$WARN_CFLAGS], [$nw])
2024
2025    gl_WARN_ADD([-Wno-unused-variable])
2026    gl_WARN_ADD([-Wno-unused-but-set-variable])
2027    gl_WARN_ADD([-Wno-unused-but-set-parameter])
2028 fi
2029
2030 term_header=
2031 HAVE_X_WINDOWS=no
2032 HAVE_X11=no
2033 USE_X_TOOLKIT=none
2034
2035 case "${window_system}" in
2036   x11 )
2037     HAVE_X_WINDOWS=yes
2038     HAVE_X11=yes
2039     term_header=xterm.h
2040     case "${with_x_toolkit}" in
2041       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
2042       motif ) USE_X_TOOLKIT=MOTIF ;;
2043       gtk ) with_gtk=yes
2044             term_header=gtkutil.h
2045 dnl Don't set this for GTK.  A lot of tests below assumes Xt when
2046 dnl USE_X_TOOLKIT is set.
2047             USE_X_TOOLKIT=none ;;
2048       gtk2 ) with_gtk2=yes
2049              term_header=gtkutil.h
2050              USE_X_TOOLKIT=none ;;
2051       gtk3 ) with_gtk3=yes
2052              term_header=gtkutil.h
2053              USE_X_TOOLKIT=none ;;
2054       no ) USE_X_TOOLKIT=none ;;
2055 dnl If user did not say whether to use a toolkit, make this decision later:
2056 dnl use the toolkit if we have gtk, or X11R5 or newer.
2057       * ) USE_X_TOOLKIT=maybe ;;
2058     esac
2059   ;;
2060   nextstep )
2061     term_header=nsterm.h
2062   ;;
2063   w32 )
2064     term_header=w32term.h
2065   ;;
2066 esac
2067
2068 if test "$window_system" = none && test "X$with_x" != "Xno"; then
2069    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
2070    if test "$HAVE_XSERVER" = true ||
2071       test -n "$DISPLAY" ||
2072       {
2073         for emacs_libX11 in /usr/lib/libX11.*; do break; done
2074         test "$emacs_libX11" != '/usr/lib/libX11.*'
2075       }
2076    then
2077         AC_MSG_ERROR([You seem to be running X, but no X development libraries
2078 were found.  You should install the relevant development files for X
2079 and for the toolkit you want, such as Gtk+ or Motif.  Also make
2080 sure you have development files for image handling, i.e.
2081 tiff, gif, jpeg, png and xpm.
2082 If you are sure you want Emacs compiled without X window support, pass
2083   --without-x
2084 to configure.])
2085    fi
2086 fi
2087
2088 # Does the opsystem file prohibit the use of the GNU malloc?
2089 # Assume not, until told otherwise.
2090 GNU_MALLOC=yes
2091
2092 AC_CACHE_CHECK(
2093   [whether malloc is Doug Lea style],
2094   [emacs_cv_var_doug_lea_malloc],
2095   [emacs_cv_var_doug_lea_malloc=no
2096    dnl Hooks do not work with address sanitization.
2097    if test "$emacs_cv_sanitize_address" != yes; then
2098      AC_LINK_IFELSE(
2099        [AC_LANG_PROGRAM(
2100           [[#include <malloc.h>
2101             static void hook (void) {}]],
2102           [[malloc_set_state (malloc_get_state ());
2103             __after_morecore_hook = hook;
2104             __malloc_initialize_hook = hook;]])],
2105        [emacs_cv_var_doug_lea_malloc=yes])])
2106    fi
2107 doug_lea_malloc=$emacs_cv_var_doug_lea_malloc
2108
2109 system_malloc=$emacs_cv_sanitize_address
2110
2111 hybrid_malloc=
2112
2113 case "$opsys" in
2114   ## darwin ld insists on the use of malloc routines in the System framework.
2115   darwin | mingw32 | nacl | sol2-10) system_malloc=yes ;;
2116   cygwin) hybrid_malloc=yes;;
2117 esac
2118
2119 GMALLOC_OBJ=
2120 if test "${system_malloc}" = "yes"; then
2121   AC_DEFINE([SYSTEM_MALLOC], 1,
2122     [Define to 1 to use the system memory allocator, even if it is not
2123      Doug Lea style.])
2124   GNU_MALLOC=no
2125   GNU_MALLOC_reason="
2126     (The GNU allocators don't work with this system configuration.)"
2127   VMLIMIT_OBJ=
2128 elif test "$hybrid_malloc" = yes; then
2129   AC_DEFINE(HYBRID_MALLOC, 1,
2130     [Define to use gmalloc before dumping and the system malloc after.])
2131   GNU_MALLOC=
2132   GNU_MALLOC_reason="only before dumping"
2133   GMALLOC_OBJ=gmalloc.o
2134   VMLIMIT_OBJ=
2135 else
2136   test "$doug_lea_malloc" != "yes" && GMALLOC_OBJ=gmalloc.o
2137   VMLIMIT_OBJ=vm-limit.o
2138
2139   AC_CHECK_HEADERS([sys/vlimit.h])
2140   AC_CACHE_CHECK([for data_start], [emacs_cv_data_start],
2141     [AC_LINK_IFELSE(
2142        [AC_LANG_PROGRAM(
2143          [[extern char data_start[]; char ch;]],
2144          [[return data_start < &ch;]])],
2145        [emacs_cv_data_start=yes],
2146        [emacs_cv_data_start=no])])
2147   if test $emacs_cv_data_start = yes; then
2148     AC_DEFINE([HAVE_DATA_START], 1,
2149       [Define to 1 if data_start is the address of the start
2150        of the main data segment.])
2151   fi
2152 fi
2153 AC_SUBST(GMALLOC_OBJ)
2154 AC_SUBST(VMLIMIT_OBJ)
2155
2156 if test "$doug_lea_malloc" = "yes" ; then
2157   if test "$GNU_MALLOC" = yes ; then
2158     GNU_MALLOC_reason="
2159       (Using Doug Lea's new malloc from the GNU C Library.)"
2160   fi
2161   AC_DEFINE(DOUG_LEA_MALLOC, 1,
2162     [Define to 1 if the system memory allocator is Doug Lea style,
2163      with malloc hooks and malloc_set_state.])
2164
2165   ## Use mmap directly for allocating larger buffers.
2166   ## FIXME this comes from src/s/{gnu,gnu-linux}.h:
2167   ## #ifdef DOUG_LEA_MALLOC; #undef REL_ALLOC; #endif
2168   ## Does the AC_FUNC_MMAP test below make this check unnecessary?
2169   case "$opsys" in
2170     mingw32|gnu*) REL_ALLOC=no ;;
2171   esac
2172 fi
2173
2174 if test x"${REL_ALLOC}" = x; then
2175   REL_ALLOC=${GNU_MALLOC}
2176 fi
2177
2178 use_mmap_for_buffers=no
2179 case "$opsys" in
2180   cygwin|mingw32|freebsd|irix6-5) use_mmap_for_buffers=yes ;;
2181 esac
2182
2183 AC_FUNC_MMAP
2184 if test $use_mmap_for_buffers = yes; then
2185   AC_DEFINE(USE_MMAP_FOR_BUFFERS, 1, [Define to use mmap to allocate buffer text.])
2186   REL_ALLOC=no
2187 fi
2188
2189 LIBS="$LIBS_SYSTEM $LIBS"
2190
2191 dnl FIXME replace main with a function we actually want from this library.
2192 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
2193
2194 dnl Check for the POSIX thread library.
2195 LIB_PTHREAD=
2196 AC_CHECK_HEADERS_ONCE(pthread.h)
2197 if test "$ac_cv_header_pthread_h" && test "$opsys" != "mingw32"; then
2198   AC_CACHE_CHECK([for pthread library],
2199     [emacs_cv_pthread_lib],
2200     [emacs_cv_pthread_lib=no
2201      OLD_CPPFLAGS=$CPPFLAGS
2202      OLD_LIBS=$LIBS
2203      for emacs_pthread_lib in 'none needed' -lpthread; do
2204        case $emacs_pthread_lib in
2205          -*) LIBS="$OLD_LIBS $emacs_pthread_lib";;
2206        esac
2207        AC_LINK_IFELSE(
2208          [AC_LANG_PROGRAM(
2209             [[#include <pthread.h>
2210               #include <signal.h>
2211               sigset_t old_mask, new_mask;
2212               void noop (void) {}]],
2213             [[pthread_t th = pthread_self ();
2214               int status = 0;
2215               status += pthread_create (&th, 0, 0, 0);
2216               status += pthread_sigmask (SIG_BLOCK, &new_mask, &old_mask);
2217               status += pthread_kill (th, 0);
2218               #if ! (defined SYSTEM_MALLOC || defined HYBRID_MALLOC \
2219                      || defined DOUG_LEA_MALLOC)
2220               /* Test for pthread_atfork only if gmalloc uses it,
2221                  as older-style hosts like MirBSD 10 lack it.  */
2222               status += pthread_atfork (noop, noop, noop);
2223               #endif
2224               return status;]])],
2225          [emacs_cv_pthread_lib=$emacs_pthread_lib])
2226        LIBS=$OLD_LIBS
2227        if test "$emacs_cv_pthread_lib" != no; then
2228          break
2229        fi
2230      done
2231      CPPFLAGS=$OLD_CPPFLAGS])
2232   if test "$emacs_cv_pthread_lib" != no; then
2233     AC_DEFINE([HAVE_PTHREAD], 1, [Define to 1 if you have POSIX threads.])
2234     case $emacs_cv_pthread_lib in
2235       -*) LIB_PTHREAD=$emacs_cv_pthread_lib;;
2236     esac
2237     ac_cv_func_pthread_sigmask=yes
2238     # Some systems optimize for single-threaded programs by default, and
2239     # need special flags to disable these optimizations. For example, the
2240     # definition of 'errno' in <errno.h>.
2241     case $opsys in
2242       hpux* | sol*)
2243         AC_DEFINE([_REENTRANT], 1,
2244           [Define to 1 if your system requires this in multithreaded code.]);;
2245       aix4-2)
2246         AC_DEFINE([_THREAD_SAFE], 1,
2247           [Define to 1 if your system requires this in multithreaded code.]);;
2248     esac
2249   fi
2250 fi
2251 AC_SUBST([LIB_PTHREAD])
2252
2253 dnl Check for need for bigtoc support on IBM AIX
2254
2255 case ${host_os} in
2256 aix*)
2257   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
2258     case $GCC in
2259     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
2260     *) gdb_cv_bigtoc=-bbigtoc ;;
2261     esac
2262
2263     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
2264     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[int i;]])], [], [gdb_cv_bigtoc=])
2265   ])
2266   ;;
2267 esac
2268
2269 # Change CFLAGS, CPPFLAGS, and LIBS temporarily so that C_SWITCH_X_SITE
2270 # is for the tests that follow.  We set them back later on.
2271
2272 REAL_CFLAGS="$CFLAGS"
2273 REAL_CPPFLAGS="$CPPFLAGS"
2274 REAL_LIBS="$LIBS"
2275
2276 if test "${HAVE_X11}" = "yes"; then
2277   DEFS="$C_SWITCH_X_SITE $DEFS"
2278   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
2279   LIBS="-lX11 $LIBS"
2280   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
2281   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
2282
2283   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
2284   # This is handled by LD_SWITCH_X_SITE_RPATH during the real build,
2285   # but it's more convenient here to set LD_RUN_PATH since this
2286   # also works on hosts that don't understand LD_SWITCH_X_SITE_RPATH.
2287   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
2288     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
2289     export LD_RUN_PATH
2290   fi
2291
2292   if test "${opsys}" = "gnu-linux"; then
2293     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
2294     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
2295      [[XOpenDisplay ("foo");]])],
2296      [xgnu_linux_first_failure=no],
2297      [xgnu_linux_first_failure=yes])
2298     if test "${xgnu_linux_first_failure}" = "yes"; then
2299       OLD_CPPFLAGS="$CPPFLAGS"
2300       OLD_LIBS="$LIBS"
2301       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
2302       LIBS="$LIBS -b i486-linuxaout"
2303       AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
2304        [[XOpenDisplay ("foo");]])],
2305        [xgnu_linux_second_failure=no],
2306        [xgnu_linux_second_failure=yes])
2307       if test "${xgnu_linux_second_failure}" = "yes"; then
2308         # If we get the same failure with -b, there is no use adding -b.
2309         # So leave it out.  This plays safe.
2310         AC_MSG_RESULT(no)
2311       else
2312         LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
2313         C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
2314         AC_MSG_RESULT(yes)
2315       fi
2316       CPPFLAGS=$OLD_CPPFLAGS
2317       LIBS=$OLD_LIBS
2318     else
2319       AC_MSG_RESULT(no)
2320     fi
2321   fi
2322
2323   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
2324   # header files included from there.
2325   AC_MSG_CHECKING(for Xkb)
2326   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
2327 #include <X11/XKBlib.h>]],
2328         [[XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);]])],
2329         emacs_xkb=yes, emacs_xkb=no)
2330   AC_MSG_RESULT($emacs_xkb)
2331   if test $emacs_xkb = yes; then
2332     AC_DEFINE(HAVE_XKB, 1, [Define to 1 if you have the Xkb extension.])
2333   fi
2334
2335   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
2336 XScreenNumberOfScreen)
2337 fi
2338
2339 if test "${window_system}" = "x11"; then
2340   AC_MSG_CHECKING(X11 version 6)
2341   AC_CACHE_VAL(emacs_cv_x11_version_6,
2342   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>]],
2343 [[#if XlibSpecificationRelease < 6
2344 fail;
2345 #endif
2346 ]])], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
2347   if test $emacs_cv_x11_version_6 = yes; then
2348     AC_MSG_RESULT(6 or newer)
2349     AC_DEFINE(HAVE_X11R6, 1,
2350               [Define to 1 if you have the X11R6 or newer version of Xlib.])
2351     AC_DEFINE(HAVE_X_I18N, 1, [Define if you have usable i18n support.])
2352     ## inoue@ainet.or.jp says Solaris has a bug related to X11R6-style
2353     ## XIM support.
2354     case "$opsys" in
2355       sol2-*) : ;;
2356       *) AC_DEFINE(HAVE_X11R6_XIM, 1,
2357            [Define if you have usable X11R6-style XIM support.])
2358          ;;
2359     esac
2360   else
2361     AC_MSG_RESULT(before 6)
2362   fi
2363 fi
2364
2365
2366 ### Use -lrsvg-2 if available, unless '--with-rsvg=no' is specified.
2367 HAVE_RSVG=no
2368 if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes" || test "${opsys}" = "mingw32"; then
2369   if test "${with_rsvg}" != "no"; then
2370     RSVG_REQUIRED=2.11.0
2371     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
2372
2373     EMACS_CHECK_MODULES([RSVG], [$RSVG_MODULE])
2374     AC_SUBST(RSVG_CFLAGS)
2375     AC_SUBST(RSVG_LIBS)
2376
2377     if test $HAVE_RSVG = yes; then
2378       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
2379       CFLAGS="$CFLAGS $RSVG_CFLAGS"
2380       # Windows loads librsvg dynamically
2381       if test "${opsys}" = "mingw32"; then
2382         RSVG_LIBS=
2383       fi
2384     fi
2385   fi
2386 fi
2387
2388 HAVE_IMAGEMAGICK=no
2389 if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes" || test "${HAVE_W32}" = "yes"; then
2390   if test "${with_imagemagick}" != "no"; then
2391     ## 6.3.5 is the earliest version known to work; see Bug#17339.
2392     ## 6.8.2 makes Emacs crash; see Bug#13867.
2393     IMAGEMAGICK_MODULE="Wand >= 6.3.5 Wand != 6.8.2"
2394     EMACS_CHECK_MODULES([IMAGEMAGICK], [$IMAGEMAGICK_MODULE])
2395     AC_SUBST(IMAGEMAGICK_CFLAGS)
2396     AC_SUBST(IMAGEMAGICK_LIBS)
2397
2398     if test $HAVE_IMAGEMAGICK = yes; then
2399       AC_DEFINE(HAVE_IMAGEMAGICK, 1, [Define to 1 if using imagemagick.])
2400       OLD_CFLAGS=$CFLAGS
2401       OLD_LIBS=$LIBS
2402       CFLAGS="$CFLAGS $IMAGEMAGICK_CFLAGS"
2403       LIBS="$IMAGEMAGICK_LIBS $LIBS"
2404       AC_CHECK_FUNCS(MagickExportImagePixels MagickMergeImageLayers)
2405       CFLAGS=$OLD_CFLAGS
2406       LIBS=$OLD_LIBS
2407     fi
2408   fi
2409 fi
2410
2411
2412 HAVE_GTK=no
2413 GTK_OBJ=
2414 gtk_term_header=$term_header
2415 check_gtk2=no
2416 gtk3_pkg_errors=
2417 if test "${opsys}" != "mingw32"; then
2418   if test "${with_gtk3}" = "yes" || test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
2419     GLIB_REQUIRED=2.28
2420     GTK_REQUIRED=3.0
2421     GTK_MODULES="gtk+-3.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
2422
2423     dnl Checks for libraries.
2424     EMACS_CHECK_MODULES([GTK], [$GTK_MODULES],
2425       [pkg_check_gtk=yes], [pkg_check_gtk=no])
2426     if test "$pkg_check_gtk" = "no" && test "$with_gtk3" = "yes"; then
2427        AC_MSG_ERROR($GTK_PKG_ERRORS)
2428     fi
2429     if test "$pkg_check_gtk" = "yes"; then
2430        AC_DEFINE(HAVE_GTK3, 1, [Define to 1 if using GTK 3 or later.])
2431        GTK_OBJ=emacsgtkfixed.o
2432        gtk_term_header=gtkutil.h
2433        USE_GTK_TOOLKIT="GTK3"
2434        if test "x$ac_enable_gtk_deprecation_warnings" = x; then
2435          AC_DEFINE([GDK_DISABLE_DEPRECATION_WARNINGS], [1],
2436            [Define to 1 to disable GTK+/GDK deprecation warnings.])
2437          AC_DEFINE([GLIB_DISABLE_DEPRECATION_WARNINGS], [1],
2438            [Define to 1 to disable Glib deprecation warnings.])
2439        fi
2440     else
2441        check_gtk2=yes
2442        gtk3_pkg_errors="$GTK_PKG_ERRORS "
2443     fi
2444   fi
2445
2446   if test "${with_gtk2}" = "yes" || test "$check_gtk2" = "yes"; then
2447     GLIB_REQUIRED=2.10
2448     GTK_REQUIRED=2.10
2449     GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
2450
2451     dnl Checks for libraries.
2452     EMACS_CHECK_MODULES([GTK], [$GTK_MODULES],
2453       [pkg_check_gtk=yes], [pkg_check_gtk=no])
2454     if test "$pkg_check_gtk" = "no" &&
2455        { test "$with_gtk" = yes || test "$with_gtk2" = "yes"; }
2456     then
2457       AC_MSG_ERROR($gtk3_pkg_errors$GTK_PKG_ERRORS)
2458     fi
2459     test "$pkg_check_gtk" = "yes" && USE_GTK_TOOLKIT="GTK2"
2460   fi
2461 fi
2462
2463 OLD_CFLAGS=$CFLAGS
2464 OLD_LIBS=$LIBS
2465
2466 if test x"$pkg_check_gtk" = xyes; then
2467
2468   AC_SUBST(GTK_LIBS)
2469   CFLAGS="$CFLAGS $GTK_CFLAGS"
2470   LIBS="$GTK_LIBS $LIBS"
2471   dnl Try to compile a simple GTK program.
2472   AC_MSG_CHECKING([whether GTK compiles])
2473   GTK_COMPILES=no
2474   AC_LINK_IFELSE(
2475     [AC_LANG_PROGRAM(
2476        [[/* Check the Gtk and Glib APIs.  */
2477          #include <gtk/gtk.h>
2478          #include <glib-object.h>
2479          static void
2480          callback (GObject *go, GParamSpec *spec, gpointer user_data)
2481          {}
2482        ]],
2483        [[
2484          GtkSettings *gs = 0;
2485          /* Use G_CALLBACK to make sure function pointers can be cast to void *;
2486             strict C prohibits this.  Use gtk_main_iteration to test that the
2487             libraries are there.  */
2488          if (g_signal_handler_find (G_OBJECT (gs), G_SIGNAL_MATCH_FUNC,
2489                                     0, 0, 0, G_CALLBACK (callback), 0))
2490            gtk_main_iteration ();
2491        ]])],
2492     [GTK_COMPILES=yes])
2493   AC_MSG_RESULT([$GTK_COMPILES])
2494   if test "${GTK_COMPILES}" != "yes"; then
2495     GTK_OBJ=
2496     if test "$USE_X_TOOLKIT" != "maybe"; then
2497       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
2498     fi
2499   else
2500     C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
2501     HAVE_GTK=yes
2502     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
2503     GTK_OBJ="gtkutil.o $GTK_OBJ"
2504     term_header=$gtk_term_header
2505     USE_X_TOOLKIT=none
2506     AC_MSG_WARN([[Your version of Gtk+ will have problems with
2507        closing open displays.  This is no problem if you just use
2508        one display, but if you use more than one and close one of them
2509        Emacs may crash.
2510        See http://bugzilla.gnome.org/show_bug.cgi?id=85715]])
2511     sleep 3
2512   fi
2513
2514 fi
2515 AC_SUBST(GTK_OBJ)
2516
2517
2518 if test "${HAVE_GTK}" = "yes"; then
2519
2520   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
2521   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
2522   if test "$with_toolkit_scroll_bars" != no; then
2523     with_toolkit_scroll_bars=yes
2524   fi
2525
2526   dnl  Check if we have the old file selection dialog declared and
2527   dnl  in the link library.  In 2.x it may be in the library,
2528   dnl  but not declared if deprecated featured has been selected out.
2529   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
2530   HAVE_GTK_FILE_SELECTION=no
2531   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
2532                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
2533 #include <gtk/gtk.h>])
2534   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
2535     AC_CHECK_FUNCS(gtk_file_selection_new)
2536   fi
2537
2538   dnl Same as above for gtk_handle_box.
2539   HAVE_GTK_HANDLE_BOX=no
2540   AC_CHECK_DECL(GTK_TYPE_HANDLE_BOX, HAVE_GTK_HANDLE_BOX=yes,
2541                    HAVE_GTK_HANDLE_BOX=no, [AC_INCLUDES_DEFAULT
2542 #include <gtk/gtk.h>])
2543   if test "$HAVE_GTK_HANDLE_BOX" = yes; then
2544     AC_CHECK_FUNCS(gtk_handle_box_new)
2545   fi
2546
2547   dnl Same as above for gtk_tearoff_menu_item.
2548   HAVE_GTK_TEAROFF_MENU_ITEM=no
2549   AC_CHECK_DECL(GTK_TYPE_TEAROFF_MENU_ITEM, HAVE_GTK_TEAROFF_MENU_ITEM=yes,
2550                    HAVE_GTK_TEAROFF_MENU_ITEM=no, [AC_INCLUDES_DEFAULT
2551 #include <gtk/gtk.h>])
2552   if test "$HAVE_GTK_TEAROFF_MENU_ITEM" = yes; then
2553     AC_CHECK_FUNCS(gtk_tearoff_menu_item_new)
2554   fi
2555
2556   dnl Check for functions introduced in 2.14 and later.
2557   AC_CHECK_FUNCS(gtk_widget_get_window gtk_widget_set_has_window \
2558                  gtk_dialog_get_action_area gtk_widget_get_sensitive \
2559                  gtk_widget_get_mapped gtk_adjustment_get_page_size \
2560                  gtk_orientable_set_orientation \
2561                  gtk_window_set_has_resize_grip)
2562
2563  term_header=gtkutil.h
2564 fi
2565
2566 CFLAGS=$OLD_CFLAGS
2567 LIBS=$OLD_LIBS
2568
2569 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
2570 dnl other platforms.
2571 HAVE_DBUS=no
2572 DBUS_OBJ=
2573 if test "${with_dbus}" = "yes"; then
2574    EMACS_CHECK_MODULES([DBUS], [dbus-1 >= 1.0])
2575    if test "$HAVE_DBUS" = yes; then
2576      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
2577      dnl dbus_watch_get_unix_fd has been introduced in D-Bus 1.1.1.
2578      dnl dbus_type_is_valid and dbus_validate_* have been introduced in
2579      dnl D-Bus 1.5.12.
2580      OLD_LIBS=$LIBS
2581      LIBS="$LIBS $DBUS_LIBS"
2582      AC_CHECK_FUNCS(dbus_watch_get_unix_fd \
2583                     dbus_type_is_valid \
2584                     dbus_validate_bus_name \
2585                     dbus_validate_path \
2586                     dbus_validate_interface \
2587                     dbus_validate_member)
2588      LIBS=$OLD_LIBS
2589      DBUS_OBJ=dbusbind.o
2590    fi
2591 fi
2592 AC_SUBST(DBUS_CFLAGS)
2593 AC_SUBST(DBUS_LIBS)
2594 AC_SUBST(DBUS_OBJ)
2595
2596 dnl GSettings has been tested under GNU/Linux only.
2597 HAVE_GSETTINGS=no
2598 if test "${HAVE_X11}" = "yes" && test "${with_gsettings}" = "yes"; then
2599    EMACS_CHECK_MODULES([GSETTINGS], [gio-2.0 >= 2.26])
2600    if test "$HAVE_GSETTINGS" = "yes"; then
2601       old_CFLAGS=$CFLAGS
2602       CFLAGS="$CFLAGS $GSETTINGS_CFLAGS"
2603       old_LIBS=$LIBS
2604       LIBS="$LIBS $GSETTINGS_LIBS"
2605       AC_MSG_CHECKING([whether GSettings is in gio])
2606       AC_LINK_IFELSE(
2607          [AC_LANG_PROGRAM(
2608              [[/* Check that gsettings really is present.  */
2609              #include <glib-object.h>
2610              #include <gio/gio.h>
2611              ]],
2612              [[
2613                GSettings *settings;
2614                GVariant *val = g_settings_get_value (settings, "");
2615              ]])],
2616          [], HAVE_GSETTINGS=no)
2617       AC_MSG_RESULT([$HAVE_GSETTINGS])
2618
2619       if test "$HAVE_GSETTINGS" = "yes"; then
2620         AC_DEFINE(HAVE_GSETTINGS, 1, [Define to 1 if using GSettings.])
2621         SETTINGS_CFLAGS="$GSETTINGS_CFLAGS"
2622         SETTINGS_LIBS="$GSETTINGS_LIBS"
2623       fi
2624       CFLAGS=$old_CFLAGS
2625       LIBS=$old_LIBS
2626    fi
2627 fi
2628
2629 dnl GConf has been tested under GNU/Linux only.
2630 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
2631 HAVE_GCONF=no
2632 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
2633    EMACS_CHECK_MODULES([GCONF], [gconf-2.0 >= 2.13])
2634    if test "$HAVE_GCONF" = yes; then
2635       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
2636       dnl Newer GConf doesn't link with g_objects, so this is not defined.
2637       SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GCONF_CFLAGS"
2638       SETTINGS_LIBS="$SETTINGS_LIBS $GCONF_LIBS"
2639    fi
2640 fi
2641
2642 if test "$HAVE_GSETTINGS" = "yes" || test "$HAVE_GCONF" = "yes"; then
2643     EMACS_CHECK_MODULES([GOBJECT], [gobject-2.0 >= 2.0])
2644     if test "$HAVE_GOBJECT" = "yes"; then
2645        SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GOBJECT_CFLAGS"
2646        SETTINGS_LIBS="$SETTINGS_LIBS $GOBJECT_LIBS"
2647     fi
2648     SAVE_CFLAGS="$CFLAGS"
2649     SAVE_LIBS="$LIBS"
2650     CFLAGS="$SETTINGS_CFLAGS $CFLAGS"
2651     LIBS="$SETTINGS_LIBS $LIBS"
2652     CFLAGS="$SAVE_CFLAGS"
2653     LIBS="$SAVE_LIBS"
2654 fi
2655 AC_SUBST(SETTINGS_CFLAGS)
2656 AC_SUBST(SETTINGS_LIBS)
2657
2658
2659 dnl SELinux is available for GNU/Linux only.
2660 HAVE_LIBSELINUX=no
2661 LIBSELINUX_LIBS=
2662 if test "${with_selinux}" = "yes"; then
2663    AC_CHECK_LIB([selinux], [lgetfilecon], HAVE_LIBSELINUX=yes, HAVE_LIBSELINUX=no)
2664    if test "$HAVE_LIBSELINUX" = yes; then
2665       AC_DEFINE(HAVE_LIBSELINUX, 1, [Define to 1 if using SELinux.])
2666       LIBSELINUX_LIBS=-lselinux
2667    fi
2668 fi
2669 AC_SUBST(LIBSELINUX_LIBS)
2670
2671 HAVE_GNUTLS=no
2672 if test "${with_gnutls}" = "yes" ; then
2673   EMACS_CHECK_MODULES([LIBGNUTLS], [gnutls >= 2.6.6],
2674     [HAVE_GNUTLS=yes], [HAVE_GNUTLS=no])
2675   if test "${HAVE_GNUTLS}" = "yes"; then
2676     AC_DEFINE(HAVE_GNUTLS, 1, [Define if using GnuTLS.])
2677     EMACS_CHECK_MODULES([LIBGNUTLS3], [gnutls >= 3.0.0],
2678       [AC_DEFINE(HAVE_GNUTLS3, 1, [Define if using GnuTLS v3.])], [])
2679   fi
2680
2681   # Windows loads GnuTLS dynamically
2682   if test "${opsys}" = "mingw32"; then
2683     LIBGNUTLS_LIBS=
2684   fi
2685 fi
2686
2687 AC_SUBST(LIBGNUTLS_LIBS)
2688 AC_SUBST(LIBGNUTLS_CFLAGS)
2689
2690 NOTIFY_OBJ=
2691 NOTIFY_SUMMARY=no
2692
2693 dnl FIXME?  Don't auto-detect on NS, but do allow someone to specify
2694 dnl a particular library.  This doesn't make much sense?
2695 if test "${HAVE_NS}" = yes && test ${with_file_notification} = yes; then
2696   with_file_notification=no
2697 fi
2698
2699 dnl MS Windows native file monitor is available for mingw32 only.
2700 case $with_file_notification,$opsys in
2701   w32,cygwin)
2702     AC_MSG_ERROR(['--with-file-notification=w32' was specified, but
2703     this is only supported on MS-Windows native and MinGW32 builds.
2704     Consider using gfile instead.])
2705     ;;
2706   w32,* | yes,mingw32)
2707     AC_CHECK_HEADER(windows.h)
2708     if test "$ac_cv_header_windows_h" = yes ; then
2709        AC_DEFINE(HAVE_W32NOTIFY, 1, [Define to 1 to use w32notify.])
2710        NOTIFY_OBJ=w32notify.o
2711        NOTIFY_SUMMARY="yes (w32)"
2712     fi ;;
2713 esac
2714
2715 dnl inotify is available only on GNU/Linux.
2716 case $with_file_notification,$NOTIFY_OBJ in
2717   inotify, | yes,)
2718     AC_CHECK_HEADER(sys/inotify.h)
2719     if test "$ac_cv_header_sys_inotify_h" = yes ; then
2720         AC_CHECK_FUNC(inotify_init1)
2721         if test "$ac_cv_func_inotify_init1" = yes; then
2722           AC_DEFINE(HAVE_INOTIFY, 1, [Define to 1 to use inotify.])
2723           NOTIFY_OBJ=inotify.o
2724           NOTIFY_SUMMARY="yes -lglibc (inotify)"
2725        fi
2726     fi ;;
2727 esac
2728
2729 dnl g_file_monitor exists since glib 2.18.  G_FILE_MONITOR_EVENT_MOVED
2730 dnl has been added in glib 2.24.  It has been tested under
2731 dnl GNU/Linux only.
2732 case $with_file_notification,$NOTIFY_OBJ in
2733   gfile,* | yes,)
2734     EMACS_CHECK_MODULES([GFILENOTIFY], [gio-2.0 >= 2.24])
2735     if test "$HAVE_GFILENOTIFY" = "yes"; then
2736        AC_DEFINE(HAVE_GFILENOTIFY, 1, [Define to 1 if using GFile.])
2737        NOTIFY_OBJ=gfilenotify.o
2738        NOTIFY_SUMMARY="yes -lgio (gfile)"
2739     fi ;;
2740 esac
2741
2742 case $with_file_notification,$NOTIFY_OBJ in
2743   yes,* | no,* | *,?*) ;;
2744   *) AC_MSG_ERROR([File notification '$with_file_notification' requested but requirements not found.]) ;;
2745 esac
2746
2747 if test -n "$NOTIFY_OBJ"; then
2748    AC_DEFINE(USE_FILE_NOTIFY, 1, [Define to 1 if using file notifications.])
2749 fi
2750 AC_SUBST(NOTIFY_OBJ)
2751 AC_SUBST(GFILENOTIFY_CFLAGS)
2752 AC_SUBST(GFILENOTIFY_LIBS)
2753
2754 dnl Do not put whitespace before the #include statements below.
2755 dnl Older compilers (eg sunos4 cc) choke on it.
2756 HAVE_XAW3D=no
2757 LUCID_LIBW=
2758 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
2759   if test "$with_xaw3d" != no; then
2760     AC_CACHE_VAL(emacs_cv_xaw3d,
2761     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2762 #include <X11/Intrinsic.h>
2763 #include <X11/Xaw3d/Simple.h>]],
2764       [[]])],
2765       [AC_CHECK_LIB(Xaw3d, XawScrollbarSetThumb,
2766                     emacs_cv_xaw3d=yes, emacs_cv_xaw3d=no)],
2767       emacs_cv_xaw3d=no)])
2768   else
2769     emacs_cv_xaw3d=no
2770   fi
2771   if test $emacs_cv_xaw3d = yes; then
2772     AC_MSG_CHECKING(for xaw3d)
2773     AC_MSG_RESULT([yes; using Lucid toolkit])
2774     USE_X_TOOLKIT=LUCID
2775     HAVE_XAW3D=yes
2776     LUCID_LIBW=-lXaw3d
2777     AC_DEFINE(HAVE_XAW3D, 1,
2778               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
2779   else
2780     AC_MSG_CHECKING(for xaw3d)
2781     AC_MSG_RESULT(no)
2782     AC_MSG_CHECKING(for libXaw)
2783     AC_CACHE_VAL(emacs_cv_xaw,
2784     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2785 #include <X11/Intrinsic.h>
2786 #include <X11/Xaw/Simple.h>]],
2787       [[]])],
2788       emacs_cv_xaw=yes,
2789       emacs_cv_xaw=no)])
2790     if test $emacs_cv_xaw = yes; then
2791       AC_MSG_RESULT([yes; using Lucid toolkit])
2792       USE_X_TOOLKIT=LUCID
2793       LUCID_LIBW=-lXaw
2794     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
2795       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
2796     else
2797       AC_MSG_ERROR([No X toolkit could be found.
2798 If you are sure you want Emacs compiled without an X toolkit, pass
2799   --with-x-toolkit=no
2800 to configure.  Otherwise, install the development libraries for the toolkit
2801 that you want to use (e.g. Gtk+) and re-run configure.])
2802     fi
2803   fi
2804 fi
2805
2806 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
2807
2808 LIBXTR6=
2809 LIBXMU=
2810 if test "${USE_X_TOOLKIT}" != "none"; then
2811   AC_MSG_CHECKING(X11 toolkit version)
2812   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
2813   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Intrinsic.h>]],
2814 [[#if XtSpecificationRelease < 6
2815 fail;
2816 #endif
2817 ]])], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
2818   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
2819   if test $emacs_cv_x11_toolkit_version_6 = yes; then
2820     AC_MSG_RESULT(6 or newer)
2821     AC_DEFINE(HAVE_X11XTR6, 1,
2822               [Define to 1 if you have the X11R6 or newer version of Xt.])
2823     LIBXTR6="-lSM -lICE"
2824     case "$opsys" in
2825       ## Use libw.a along with X11R6 Xt.
2826       unixware) LIBXTR6="$LIBXTR6 -lw" ;;
2827     esac
2828   else
2829     AC_MSG_RESULT(before 6)
2830   fi
2831
2832 dnl If using toolkit, check whether libXmu.a exists.
2833 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
2834   OLDLIBS="$LIBS"
2835   if test x$HAVE_X11XTR6 = xyes; then
2836     OTHERLIBS='-lXt -lSM -lICE'
2837   else
2838     OTHERLIBS='-lXt'
2839   fi
2840   AC_SEARCH_LIBS([XmuConvertStandardSelection], [Xmu], [], [], [$OTHERLIBS])
2841   if test "X$LIBS" != "X$OLDLIBS"; then
2842     LIBXMU=$ac_cv_search_XmuConvertStandardSelection
2843   fi
2844   LIBS=$OLDLIBS
2845   dnl ac_cv_search_XmuConvertStandardSelection is also referenced below.
2846 fi
2847 AC_SUBST(LIBXTR6)
2848 AC_SUBST(LIBXMU)
2849
2850 LIBXP=
2851 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2852   # OpenMotif may be installed in such a way on some GNU/Linux systems.
2853   if test -d /usr/include/openmotif; then
2854     CPPFLAGS="-I/usr/include/openmotif $CPPFLAGS"
2855     emacs_cv_openmotif=yes
2856     case "$canonical" in
2857       x86_64-*-linux-gnu* | powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*)
2858       test -d /usr/lib64/openmotif && LDFLAGS="-L/usr/lib64/openmotif $LDFLAGS"
2859       ;;
2860       *)
2861       test -d /usr/lib/openmotif && LDFLAGS="-L/usr/lib/openmotif $LDFLAGS"
2862     esac
2863   else
2864     emacs_cv_openmotif=no
2865   fi
2866   AC_CACHE_CHECK(for (Open)Motif version 2.1, emacs_cv_motif_version_2_1,
2867   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <Xm/Xm.h>]],
2868     [[#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
2869 int x = 5;
2870 #else
2871 Motif version prior to 2.1.
2872 #endif]])],
2873     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
2874   if test $emacs_cv_motif_version_2_1 = yes; then
2875     AC_CHECK_LIB(Xp, XpCreateContext, LIBXP=-lXp)
2876     if test x$emacs_cv_openmotif = xyes; then
2877       REAL_CPPFLAGS="-I/usr/include/openmotif $REAL_CPPFLAGS"
2878     fi
2879   else
2880     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
2881     # We put this in CFLAGS temporarily to precede other -I options
2882     # that might be in CFLAGS temporarily.
2883     # We put this in CPPFLAGS where it precedes the other -I options.
2884     OLD_CPPFLAGS=$CPPFLAGS
2885     OLD_CFLAGS=$CFLAGS
2886     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
2887     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
2888     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>]],
2889       [[int x = 5;]])],
2890       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
2891     if test $emacs_cv_lesstif = yes; then
2892       # Make sure this -I option remains in CPPFLAGS after it is set
2893       # back to REAL_CPPFLAGS.
2894       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
2895       # have those other -I options anyway.  Ultimately, having this
2896       # directory ultimately in CPPFLAGS will be enough.
2897       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
2898       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
2899     else
2900       CFLAGS=$OLD_CFLAGS
2901       CPPFLAGS=$OLD_CPPFLAGS
2902     fi
2903   fi
2904   AC_CHECK_HEADER([Xm/BulletinB.h], [],
2905     [AC_MSG_ERROR([Motif toolkit requested but requirements not found.])])
2906 fi
2907
2908 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
2909 dnl using Motif or Xaw3d is available, and unless
2910 dnl --with-toolkit-scroll-bars=no was specified.
2911
2912 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
2913             [Define to 1 if we should use toolkit scroll bars.])dnl
2914 USE_TOOLKIT_SCROLL_BARS=no
2915 if test "${with_toolkit_scroll_bars}" != "no"; then
2916   if test "${USE_X_TOOLKIT}" != "none"; then
2917     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2918       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2919       HAVE_XAW3D=no
2920       USE_TOOLKIT_SCROLL_BARS=yes
2921     elif test "${HAVE_XAW3D}" = "yes" || test "${USE_X_TOOLKIT}" = "LUCID"; then
2922       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2923       USE_TOOLKIT_SCROLL_BARS=yes
2924     fi
2925   elif test "${HAVE_GTK}" = "yes"; then
2926     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2927     USE_TOOLKIT_SCROLL_BARS=yes
2928   elif test "${HAVE_NS}" = "yes"; then
2929     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2930     USE_TOOLKIT_SCROLL_BARS=yes
2931   elif test "${HAVE_W32}" = "yes"; then
2932     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2933     USE_TOOLKIT_SCROLL_BARS=yes
2934   fi
2935 fi
2936
2937 dnl See if XIM is available.
2938 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2939           #include <X11/Xlib.h>
2940           #include <X11/Xresource.h>]],
2941          [[XIMProc  callback;]])],
2942          [HAVE_XIM=yes
2943          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
2944          HAVE_XIM=no)
2945
2946 dnl '--with-xim' now controls only the initial value of use_xim at run time.
2947
2948 if test "${with_xim}" != "no"; then
2949   AC_DEFINE(USE_XIM, 1,
2950             [Define to 1 if we should use XIM, if it is available.])
2951 fi
2952
2953
2954 if test "${HAVE_XIM}" != "no"; then
2955   late_CFLAGS=$CFLAGS
2956   if test "$GCC" = yes; then
2957     CFLAGS="$CFLAGS --pedantic-errors"
2958   fi
2959   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2960 #include <X11/Xlib.h>
2961 #include <X11/Xresource.h>]],
2962 [[Display *display;
2963 XrmDatabase db;
2964 char *res_name;
2965 char *res_class;
2966 XIMProc  callback;
2967 XPointer *client_data;
2968 #ifndef __GNUC__
2969 /* If we're not using GCC, it's probably not XFree86, and this is
2970    probably right, but we can't use something like --pedantic-errors.  */
2971 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
2972                                            char*, XIMProc, XPointer*);
2973 #endif
2974 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
2975    client_data);]])],
2976     [emacs_cv_arg6_star=yes])
2977   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
2978          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
2979 either XPointer or XPointer*.])dnl
2980   if test "$emacs_cv_arg6_star" = yes; then
2981     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
2982   else
2983     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
2984   fi
2985   CFLAGS=$late_CFLAGS
2986 fi
2987
2988 ### Start of font-backend (under any platform) section.
2989 # (nothing here yet -- this is a placeholder)
2990 ### End of font-backend (under any platform) section.
2991
2992 ### Start of font-backend (under X11) section.
2993 if test "${HAVE_X11}" = "yes"; then
2994     ## Use -lXft if available, unless '--with-xft=no'.
2995     HAVE_XFT=maybe
2996     if test "x${with_x}" = "xno"; then
2997       with_xft="no";
2998     fi
2999
3000     if test "$with_xft" != no; then
3001       EMACS_CHECK_MODULES([FONTCONFIG], [fontconfig >= 2.2.0])
3002       with_xft=$HAVE_FONTCONFIG
3003     fi
3004
3005     if test "x${with_xft}" != "xno"; then
3006
3007       EMACS_CHECK_MODULES([XFT], [xft >= 0.13.0], [], [HAVE_XFT=no])
3008       ## Because xftfont.c uses XRenderQueryExtension, we also
3009       ## need to link to -lXrender.
3010       HAVE_XRENDER=no
3011       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
3012       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
3013         OLD_CPPFLAGS="$CPPFLAGS"
3014         OLD_CFLAGS="$CFLAGS"
3015         OLD_LIBS="$LIBS"
3016         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
3017         CFLAGS="$CFLAGS $XFT_CFLAGS"
3018         XFT_LIBS="-lXrender $XFT_LIBS"
3019         LIBS="$XFT_LIBS $LIBS"
3020         AC_CHECK_HEADER(X11/Xft/Xft.h,
3021           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS) , ,
3022           [[#include <X11/X.h>]])
3023
3024         if test "${HAVE_XFT}" = "yes"; then
3025           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
3026             AC_SUBST(XFT_LIBS)
3027           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
3028         fi                        # "${HAVE_XFT}" = "yes"
3029         CPPFLAGS=$OLD_CPPFLAGS
3030         CFLAGS=$OLD_CFLAGS
3031         LIBS=$OLD_LIBS
3032       fi                          # "$HAVE_XFT" != no
3033     fi                            # "x${with_xft}" != "xno"
3034
3035     ## We used to allow building with FreeType and without Xft.
3036     ## However, the ftx font backend driver is not in good shape.
3037     if test "$HAVE_XFT" != "yes"; then
3038        dnl For the "Does Emacs use" message at the end.
3039        HAVE_XFT=no
3040        HAVE_FREETYPE=no
3041     else
3042        dnl Strict linkers fail with
3043        dnl ftfont.o: undefined reference to symbol 'FT_New_Face'
3044        dnl if -lfreetype is not specified.
3045        dnl The following is needed to set FREETYPE_LIBS.
3046        EMACS_CHECK_MODULES([FREETYPE], [freetype2])
3047
3048        test "$HAVE_FREETYPE" = "no" && AC_MSG_ERROR(libxft requires libfreetype)
3049     fi
3050
3051     HAVE_LIBOTF=no
3052     if test "${HAVE_FREETYPE}" = "yes"; then
3053       AC_DEFINE(HAVE_FREETYPE, 1,
3054                 [Define to 1 if using the freetype and fontconfig libraries.])
3055       if test "${with_libotf}" != "no"; then
3056         EMACS_CHECK_MODULES([LIBOTF], [libotf])
3057         if test "$HAVE_LIBOTF" = "yes"; then
3058           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
3059           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
3060                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
3061                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
3062           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
3063             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
3064                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
3065           fi
3066         fi
3067       fi
3068     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
3069     dnl Does the new font backend require it, or can it work without it?
3070     fi
3071
3072     HAVE_M17N_FLT=no
3073     if test "${HAVE_LIBOTF}" = yes; then
3074       if test "${with_m17n_flt}" != "no"; then
3075         EMACS_CHECK_MODULES([M17N_FLT], [m17n-flt])
3076         if test "$HAVE_M17N_FLT" = "yes"; then
3077           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
3078         fi
3079       fi
3080     fi
3081 else
3082     HAVE_XFT=no
3083     HAVE_FREETYPE=no
3084     HAVE_LIBOTF=no
3085     HAVE_M17N_FLT=no
3086 fi
3087
3088 ### End of font-backend (under X11) section.
3089
3090 AC_SUBST(FREETYPE_CFLAGS)
3091 AC_SUBST(FREETYPE_LIBS)
3092 AC_SUBST(FONTCONFIG_CFLAGS)
3093 AC_SUBST(FONTCONFIG_LIBS)
3094 AC_SUBST(LIBOTF_CFLAGS)
3095 AC_SUBST(LIBOTF_LIBS)
3096 AC_SUBST(M17N_FLT_CFLAGS)
3097 AC_SUBST(M17N_FLT_LIBS)
3098
3099 USE_CAIRO=no
3100 if test "${HAVE_X11}" = "yes"; then
3101   if test "${with_cairo}" != "no"; then
3102     CAIRO_REQUIRED=1.12.0
3103     CAIRO_MODULE="cairo >= $CAIRO_REQUIRED"
3104     PKG_CHECK_MODULES(CAIRO, $CAIRO_MODULE, USE_CAIRO=yes, :)
3105     if test $USE_CAIRO = yes; then
3106       AC_DEFINE(USE_CAIRO, 1, [Define to 1 if using cairo.])
3107     else
3108       AC_MSG_ERROR([cairo requested but not found.])
3109     fi
3110
3111     CFLAGS="$CFLAGS $CAIRO_CFLAGS"
3112     LIBS="$LIBS $CAIRO_LIBS"
3113     AC_SUBST(CAIRO_CFLAGS)
3114     AC_SUBST(CAIRO_LIBS)
3115   fi
3116 fi
3117
3118 ### Use -lXpm if available, unless '--with-xpm=no'.
3119 ### mingw32 doesn't use -lXpm, since it loads the library dynamically.
3120 ### In the Cygwin-w32 build, we need to use /usr/include/noX/X11/xpm.h
3121 ### rather than /usr/include/X11/xpm.h, so we set CPPFLAGS (and
3122 ### LDFLAGS) accordingly.
3123 HAVE_XPM=no
3124 LIBXPM=
3125 if test "${HAVE_W32}" = "yes" && test "${opsys}" = "cygwin"; then
3126   if test "${with_xpm}" != "no"; then
3127     SAVE_CPPFLAGS="$CPPFLAGS"
3128     SAVE_LDFLAGS="$LDFLAGS"
3129     CPPFLAGS="$CPPFLAGS -I/usr/include/noX"
3130     LDFLAGS="$LDFLAGS -L/usr/lib/noX"
3131     AC_CHECK_HEADER(X11/xpm.h,
3132       [AC_CHECK_LIB(Xpm, XpmReadFileToImage, HAVE_XPM=yes)])
3133     if test "${HAVE_XPM}" = "yes"; then
3134       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
3135       AC_EGREP_CPP(no_return_alloc_pixels,
3136       [#include "X11/xpm.h"
3137 #ifndef XpmReturnAllocPixels
3138 no_return_alloc_pixels
3139 #endif
3140       ], HAVE_XPM=no, HAVE_XPM=yes)
3141
3142       if test "${HAVE_XPM}" = "yes"; then
3143         REAL_CPPFLAGS="$REAL_CPPFLAGS -I/usr/include/noX"
3144         AC_MSG_RESULT(yes)
3145       else
3146         AC_MSG_RESULT(no)
3147         CPPFLAGS="$SAVE_CPPFLAGS"
3148         LDFLAGS="$SAVE_LDFLAGS"
3149       fi
3150     fi
3151   fi
3152
3153   if test "${HAVE_XPM}" = "yes"; then
3154     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
3155     LIBXPM=-lXpm
3156   fi
3157 fi
3158
3159 if test "${HAVE_X11}" = "yes"; then
3160   dnl Avoid Xpm on AIX unless requested, as it crashes; see Bug#17598.
3161   test "$opsys$with_xpm_set" = aix4-2 && with_xpm=no
3162
3163   if test "${with_xpm}" != "no"; then
3164     AC_CHECK_HEADER(X11/xpm.h,
3165       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
3166     if test "${HAVE_XPM}" = "yes"; then
3167       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
3168       AC_EGREP_CPP(no_return_alloc_pixels,
3169       [#include "X11/xpm.h"
3170 #ifndef XpmReturnAllocPixels
3171 no_return_alloc_pixels
3172 #endif
3173       ], HAVE_XPM=no, HAVE_XPM=yes)
3174
3175       if test "${HAVE_XPM}" = "yes"; then
3176         AC_MSG_RESULT(yes)
3177       else
3178         AC_MSG_RESULT(no)
3179       fi
3180     fi
3181   fi
3182
3183   if test "${HAVE_XPM}" = "yes"; then
3184     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
3185     LIBXPM=-lXpm
3186   elif test "$opsys,$LUCID_LIBW" = aix4-2,-lXaw; then
3187     dnl AIX -lXaw needs -lXpm linked too; see Bug#17598 Message#152.
3188     LIBXPM=-lXpm
3189   fi
3190 fi
3191
3192 ### FIXME: Perhaps regroup to minimize code duplication due to MinGW's
3193 ### slightly different requirements wrt image libraries (it doesn't
3194 ### use -lXpm because it loads the xpm shared library dynamically at
3195 ### run time).
3196 if test "${opsys}" = "mingw32"; then
3197   if test "${with_xpm}" != "no"; then
3198     AC_CHECK_HEADER(X11/xpm.h, HAVE_XPM=yes, HAVE_XPM=no, [
3199 #define FOR_MSW 1])
3200   fi
3201
3202   if test "${HAVE_XPM}" = "yes"; then
3203     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
3204   fi
3205 fi
3206
3207 AC_SUBST(LIBXPM)
3208
3209 ### Use -ljpeg if available, unless '--with-jpeg=no'.
3210 HAVE_JPEG=no
3211 LIBJPEG=
3212 if test "${with_jpeg}" != "no"; then
3213   AC_CACHE_CHECK([for jpeglib 6b or later],
3214     [emacs_cv_jpeglib],
3215     [OLD_LIBS=$LIBS
3216      for emacs_cv_jpeglib in yes -ljpeg no; do
3217        case $emacs_cv_jpeglib in
3218          yes) ;;
3219          no) break;;
3220          *) LIBS="$LIBS $emacs_cv_jpeglib";;
3221        esac
3222        AC_LINK_IFELSE(
3223          [AC_LANG_PROGRAM(
3224             [[#undef HAVE_STDLIB_H /* Avoid config.h/jpeglib.h collision.  */
3225               #include <stdio.h> /* jpeglib.h needs FILE and size_t.  */
3226               #include <jpeglib.h>
3227               #include <jerror.h>
3228               char verify[JPEG_LIB_VERSION < 62 ? -1 : 1];
3229               struct jpeg_decompress_struct cinfo;
3230             ]],
3231             [[
3232               jpeg_create_decompress (&cinfo);
3233               WARNMS (&cinfo, JWRN_JPEG_EOF);
3234               jpeg_destroy_decompress (&cinfo);
3235             ]])],
3236          [emacs_link_ok=yes],
3237          [emacs_link_ok=no])
3238        LIBS=$OLD_LIBS
3239        test $emacs_link_ok = yes && break
3240      done])
3241   if test "$emacs_cv_jpeglib" != no; then
3242     HAVE_JPEG=yes
3243     AC_DEFINE([HAVE_JPEG], 1,
3244       [Define to 1 if you have the jpeg library (typically -ljpeg).])
3245     ### mingw32 doesn't use -ljpeg, since it loads the library
3246     ### dynamically when needed, and doesn't want a run-time
3247     ### dependency on the jpeglib DLL.
3248     test "$emacs_cv_jpeglib" != yes && test "${opsys}" != "mingw32" \
3249     && LIBJPEG=$emacs_cv_jpeglib
3250   fi
3251 fi
3252 AC_SUBST(LIBJPEG)
3253
3254 HAVE_ZLIB=no
3255 LIBZ=
3256 if test "${with_zlib}" != "no"; then
3257   OLIBS=$LIBS
3258   AC_SEARCH_LIBS([inflateEnd], [z], [HAVE_ZLIB=yes])
3259   LIBS=$OLIBS
3260   case $ac_cv_search_inflateEnd in
3261     -*) LIBZ=$ac_cv_search_inflateEnd ;;
3262   esac
3263 fi
3264 if test "${HAVE_ZLIB}" = "yes"; then
3265   AC_DEFINE([HAVE_ZLIB], 1, [Define to 1 if you have the zlib library (-lz).])
3266   ### mingw32 doesn't use -lz, since it loads the library dynamically.
3267   if test "${opsys}" = "mingw32"; then
3268      LIBZ=
3269   fi
3270 fi
3271 AC_SUBST(LIBZ)
3272
3273 ### Use -lpng if available, unless '--with-png=no'.
3274 HAVE_PNG=no
3275 LIBPNG=
3276 PNG_CFLAGS=
3277 if test "${NS_IMPL_COCOA}" = yes; then
3278   : # Nothing to do
3279 elif test "${with_png}" != no; then
3280   # mingw32 loads the library dynamically.
3281   if test "$opsys" = mingw32; then
3282     AC_CHECK_HEADER([png.h], [HAVE_PNG=yes])
3283   elif test "${HAVE_X11}" = "yes" || test "${HAVE_W32}" = "yes"; then
3284     AC_MSG_CHECKING([for png])
3285     png_cflags=`(libpng-config --cflags) 2>&AS_MESSAGE_LOG_FD` &&
3286     png_libs=`(libpng-config --libs) 2>&AS_MESSAGE_LOG_FD` || {
3287       # libpng-config does not work; configure by hand.
3288       # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
3289       # in /usr/include/libpng.
3290       if test -r /usr/include/libpng/png.h &&
3291          test ! -r /usr/include/png.h; then
3292         png_cflags=-I/usr/include/libpng
3293       else
3294         png_cflags=
3295       fi
3296       png_libs='-lpng'
3297     }
3298     SAVE_CFLAGS=$CFLAGS
3299     SAVE_LIBS=$LIBS
3300     CFLAGS="$CFLAGS $png_cflags"
3301     LIBS="$png_libs -lz -lm $LIBS"
3302     AC_LINK_IFELSE(
3303       [AC_LANG_PROGRAM([[#include <png.h>]],
3304          [[return !png_get_channels (0, 0);]])],
3305       [HAVE_PNG=yes
3306        PNG_CFLAGS=`AS_ECHO(["$png_cflags"]) | sed -e "$edit_cflags"`
3307        LIBPNG=$png_libs
3308        # $LIBPNG requires explicit -lz in some cases.
3309        # We don't know what those cases are, exactly, so play it safe and
3310        # append -lz to any nonempty $LIBPNG, unless we're already using LIBZ.
3311        if test -n "$LIBPNG" && test -z "$LIBZ"; then
3312          LIBPNG="$LIBPNG -lz"
3313        fi])
3314     CFLAGS=$SAVE_CFLAGS
3315     LIBS=$SAVE_LIBS
3316     AC_MSG_RESULT([$HAVE_PNG])
3317   fi
3318 fi
3319 if test $HAVE_PNG = yes; then
3320   AC_DEFINE([HAVE_PNG], [1], [Define to 1 if you have the png library.])
3321
3322   SAVE_CFLAGS=$CFLAGS
3323   CFLAGS="$CFLAGS $PNG_CFLAGS"
3324   AC_CHECK_DECL([png_longjmp],
3325     [],
3326     [AC_DEFINE([PNG_DEPSTRUCT], [],
3327        [Define to empty to suppress deprecation warnings when building
3328         with --enable-gcc-warnings and with libpng versions before 1.5,
3329         which lack png_longjmp.])],
3330     [[#include <png.h>
3331     ]])
3332   CFLAGS=$SAVE_CFLAGS
3333 fi
3334 AC_SUBST(LIBPNG)
3335 AC_SUBST(PNG_CFLAGS)
3336
3337 ### Use -ltiff if available, unless '--with-tiff=no'.
3338 ### mingw32 doesn't use -ltiff, since it loads the library dynamically.
3339 HAVE_TIFF=no
3340 LIBTIFF=
3341 if test "${opsys}" = "mingw32"; then
3342   if test "${with_tiff}" != "no"; then
3343     AC_CHECK_HEADER(tiffio.h, HAVE_TIFF=yes, HAVE_TIFF=no)
3344   fi
3345   if test "${HAVE_TIFF}" = "yes"; then
3346     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
3347   fi
3348 elif test "${HAVE_X11}" = "yes" || test "${HAVE_W32}" = "yes"; then
3349   if test "${with_tiff}" != "no"; then
3350     AC_CHECK_HEADER(tiffio.h,
3351       [tifflibs="-lz -lm"
3352       # At least one tiff package requires the jpeg library.
3353       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
3354       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
3355   fi
3356
3357   if test "${HAVE_TIFF}" = "yes"; then
3358     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
3359     dnl FIXME -lz -lm, as per libpng?
3360     LIBTIFF=-ltiff
3361   fi
3362 fi
3363 AC_SUBST(LIBTIFF)
3364
3365 ### Use -lgif or -lungif if available, unless '--with-gif=no'.
3366 ### mingw32 doesn't use -lgif/-lungif, since it loads the library dynamically.
3367 HAVE_GIF=no
3368 LIBGIF=
3369 if test "${opsys}" = "mingw32"; then
3370   if test "${with_gif}" != "no"; then
3371     AC_CHECK_HEADER(gif_lib.h, HAVE_GIF=yes, HAVE_GIF=no)
3372   fi
3373   if test "${HAVE_GIF}" = "yes"; then
3374     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
3375   fi
3376 elif test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no" \
3377         || test "${HAVE_W32}" = "yes"; then
3378   AC_CHECK_HEADER(gif_lib.h,
3379 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
3380 # Earlier versions can crash Emacs, but version 5.0 removes EGifPutExtensionLast.
3381     [AC_CHECK_LIB(gif, GifMakeMapObject, HAVE_GIF=yes,
3382         [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])])
3383
3384   if test "$HAVE_GIF" = yes; then
3385     LIBGIF=-lgif
3386   elif test "$HAVE_GIF" = maybe; then
3387 # If gif_lib.h but no libgif, try libungif.
3388     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
3389     test "$HAVE_GIF" = yes && LIBGIF=-lungif
3390   fi
3391
3392   if test "${HAVE_GIF}" = "yes"; then
3393     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
3394   fi
3395 fi
3396 AC_SUBST(LIBGIF)
3397
3398 dnl Check for required libraries.
3399 if test "${HAVE_X11}" = "yes"; then
3400   MISSING=""
3401   WITH_NO=""
3402   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
3403     MISSING="libXpm" && WITH_NO="--with-xpm=no"
3404   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
3405     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
3406   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
3407     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
3408   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
3409     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
3410   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
3411     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
3412
3413   if test "X${MISSING}" != X; then
3414     AC_MSG_ERROR([The following required libraries were not found:
3415     $MISSING
3416 Maybe some development libraries/packages are missing?
3417 If you don't want to link with them give
3418     $WITH_NO
3419 as options to configure])
3420   fi
3421 fi
3422
3423 ### Use -lgpm if available, unless '--with-gpm=no'.
3424 HAVE_GPM=no
3425 LIBGPM=
3426 if test "${with_gpm}" != "no"; then
3427   AC_CHECK_HEADER(gpm.h,
3428     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
3429
3430   if test "${HAVE_GPM}" = "yes"; then
3431     AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
3432     LIBGPM=-lgpm
3433   fi
3434 fi
3435 AC_SUBST(LIBGPM)
3436
3437 dnl Check for malloc/malloc.h on darwin
3438 AC_CHECK_HEADERS_ONCE(malloc/malloc.h)
3439
3440 GNUSTEP_CFLAGS=
3441 ### Use NeXTstep API to implement GUI.
3442 if test "${HAVE_NS}" = "yes"; then
3443   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
3444   if test "${NS_IMPL_COCOA}" = "yes"; then
3445     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
3446   fi
3447   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
3448     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
3449     if test $NS_GNUSTEP_CONFIG != yes; then
3450       # See also .m.o rule in src/Makefile.in.  */
3451       # FIXME: are all these flags really needed?  Document here why.  */
3452       GNUSTEP_CFLAGS="-D_REENTRANT -fPIC -fno-strict-aliasing -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
3453       ## Extra CFLAGS applied to src/*.m files.
3454       GNU_OBJC_CFLAGS="$GNU_OBJC_CFLAGS -fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
3455     fi
3456   fi
3457   OTHER_FILES=ns-app
3458 fi
3459
3460 ### Use session management (-lSM -lICE) if available
3461 HAVE_X_SM=no
3462 LIBXSM=
3463 if test "${HAVE_X11}" = "yes"; then
3464   AC_CHECK_HEADER(X11/SM/SMlib.h,
3465     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
3466
3467   if test "${HAVE_X_SM}" = "yes"; then
3468     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
3469     LIBXSM="-lSM -lICE"
3470   fi
3471 fi
3472 AC_SUBST(LIBXSM)
3473
3474 ### Use XRandr (-lXrandr) if available
3475 HAVE_XRANDR=no
3476 if test "${HAVE_X11}" = "yes"; then
3477   XRANDR_REQUIRED=1.2.2
3478   XRANDR_MODULES="xrandr >= $XRANDR_REQUIRED"
3479   EMACS_CHECK_MODULES([XRANDR], [$XRANDR_MODULES])
3480   if test $HAVE_XRANDR = no; then
3481     # Test old way in case pkg-config doesn't have it (older machines).
3482     # Include Xrender.h by hand to work around bug in older Xrandr.h
3483     # (e.g. RHEL5) and silence (harmless) configure warning (bug#18465).
3484     AC_CHECK_HEADER(X11/extensions/Xrandr.h,
3485       [AC_CHECK_LIB(Xrandr, XRRGetScreenResources, HAVE_XRANDR=yes)],
3486       [], [AC_INCLUDES_DEFAULT
3487 #include <X11/extensions/Xrender.h>])
3488     if test $HAVE_XRANDR = yes; then
3489       XRANDR_LIBS=-lXrandr
3490     fi
3491   fi
3492   if test $HAVE_XRANDR = yes; then
3493     SAVE_CFLAGS="$CFLAGS"
3494     SAVE_LIBS="$LIBS"
3495     CFLAGS="$XRANDR_CFLAGS $CFLAGS"
3496     LIBS="$XRANDR_LIBS $LIBS"
3497     AC_CHECK_FUNCS(XRRGetOutputPrimary XRRGetScreenResourcesCurrent)
3498     CFLAGS="$SAVE_CFLAGS"
3499     LIBS="$SAVE_LIBS"
3500
3501     AC_DEFINE(HAVE_XRANDR, 1, [Define to 1 if you have the XRandr extension.])
3502   fi
3503 fi
3504 AC_SUBST(XRANDR_CFLAGS)
3505 AC_SUBST(XRANDR_LIBS)
3506
3507 ### Use Xinerama (-lXinerama) if available
3508 HAVE_XINERAMA=no
3509 if test "${HAVE_X11}" = "yes"; then
3510   XINERAMA_REQUIRED=1.0.2
3511   XINERAMA_MODULES="xinerama >= $XINERAMA_REQUIRED"
3512   EMACS_CHECK_MODULES([XINERAMA], [$XINERAMA_MODULES])
3513   if test $HAVE_XINERAMA = no; then
3514     # Test old way in case pkg-config doesn't have it (older machines).
3515     AC_CHECK_HEADER(X11/extensions/Xinerama.h,
3516       [AC_CHECK_LIB(Xinerama, XineramaQueryExtension, HAVE_XINERAMA=yes)])
3517     if test $HAVE_XINERAMA = yes; then
3518       XINERAMA_LIBS=-lXinerama
3519     fi
3520   fi
3521   if test $HAVE_XINERAMA = yes; then
3522     AC_DEFINE(HAVE_XINERAMA, 1, [Define to 1 if you have the Xinerama extension.])
3523   fi
3524 fi
3525 AC_SUBST(XINERAMA_CFLAGS)
3526 AC_SUBST(XINERAMA_LIBS)
3527
3528 ### Use Xfixes (-lXfixes) if available
3529 HAVE_XFIXES=no
3530 if test "${HAVE_X11}" = "yes"; then
3531   XFIXES_REQUIRED=4.0.0
3532   XFIXES_MODULES="xfixes >= $XFIXES_REQUIRED"
3533   EMACS_CHECK_MODULES([XFIXES], [$XFIXES_MODULES])
3534   if test $HAVE_XFIXES = no; then
3535     # Test old way in case pkg-config doesn't have it (older machines).
3536     AC_CHECK_HEADER(X11/extensions/Xfixes.h,
3537       [AC_CHECK_LIB(Xfixes, XFixesHideCursor, HAVE_XFIXES=yes)])
3538     if test $HAVE_XFIXES = yes; then
3539       XFIXES_LIBS=-lXfixes
3540     fi
3541   fi
3542   if test $HAVE_XFIXES = yes; then
3543     AC_DEFINE(HAVE_XFIXES, 1, [Define to 1 if you have the Xfixes extension.])
3544   fi
3545 fi
3546 AC_SUBST(XFIXES_CFLAGS)
3547 AC_SUBST(XFIXES_LIBS)
3548
3549 ### Use libxml (-lxml2) if available
3550 ### mingw32 doesn't use -lxml2, since it loads the library dynamically.
3551 HAVE_LIBXML2=no
3552 if test "${with_xml2}" != "no"; then
3553   ### I'm not sure what the version number should be, so I just guessed.
3554   EMACS_CHECK_MODULES([LIBXML2], [libxml-2.0 > 2.6.17])
3555   # Built-in libxml2 on OS X 10.8 lacks libxml-2.0.pc.
3556   if test "${HAVE_LIBXML2}" != "yes" && test "$opsys" = "darwin"; then
3557     SAVE_CPPFLAGS="$CPPFLAGS"
3558     CPPFLAGS="$CPPFLAGS -I$xcsdkdir/usr/include/libxml2"
3559     AC_CHECK_HEADER(libxml/HTMLparser.h,
3560       [AC_CHECK_DECL(HTML_PARSE_RECOVER, HAVE_LIBXML2=yes, ,
3561                      [#include <libxml/HTMLparser.h>])])
3562     CPPFLAGS="$SAVE_CPPFLAGS"
3563     if test "${HAVE_LIBXML2}" = "yes"; then
3564       LIBXML2_CFLAGS="-I'$xcsdkdir/usr/include/libxml2'"
3565       LIBXML2_LIBS="-lxml2"
3566     fi
3567   fi
3568   if test "${HAVE_LIBXML2}" = "yes"; then
3569     if test "${opsys}" != "mingw32"; then
3570       AC_CHECK_LIB(xml2, htmlReadMemory, HAVE_LIBXML2=yes, HAVE_LIBXML2=no,
3571         [$LIBXML2_LIBS])
3572     else
3573       LIBXML2_LIBS=""
3574     fi
3575     if test "${HAVE_LIBXML2}" = "yes"; then
3576       AC_DEFINE(HAVE_LIBXML2, 1, [Define to 1 if you have the libxml library (-lxml2).])
3577     else
3578       LIBXML2_LIBS=""
3579       LIBXML2_CFLAGS=""
3580     fi
3581   fi
3582 fi
3583 AC_SUBST(LIBXML2_LIBS)
3584 AC_SUBST(LIBXML2_CFLAGS)
3585
3586 # If netdb.h doesn't declare h_errno, we must declare it by hand.
3587 # On MinGW, that is provided by nt/inc/sys/socket.h and w32.c.
3588 if test "${opsys}" = "mingw32"; then
3589   emacs_cv_netdb_declares_h_errno=yes
3590 fi
3591 AC_CACHE_CHECK(whether netdb declares h_errno,
3592                emacs_cv_netdb_declares_h_errno,
3593 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
3594   [[return h_errno;]])],
3595   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
3596 if test $emacs_cv_netdb_declares_h_errno = yes; then
3597   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
3598 fi
3599
3600 # Check for mail-locking functions in a "mail" library.  Probably this should
3601 # have the same check as for liblockfile below.
3602 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
3603 if test $have_mail = yes; then
3604   LIBS_MAIL=-lmail
3605   AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the 'mail' library (-lmail).])
3606
3607   OLD_LIBS=$LIBS
3608   LIBS="$LIBS_MAIL $LIBS"
3609   AC_CHECK_FUNCS(touchlock)
3610   LIBS=$OLD_LIBS
3611 else
3612   LIBS_MAIL=
3613 fi
3614 dnl Debian, at least:
3615 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
3616 if test $have_lockfile = yes; then
3617    LIBS_MAIL=-llockfile
3618    AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the 'lockfile' library (-llockfile).])
3619 else
3620 # If we have the shared liblockfile, assume we must use it for mail
3621 # locking (e.g. Debian).  If we couldn't link against liblockfile
3622 # (no liblockfile.a installed), ensure that we don't need to.
3623   dnl This works for files generally, not just executables.
3624   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
3625   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
3626                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
3627   if test $ac_cv_prog_liblockfile = yes; then
3628     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
3629 This probably means that movemail could lose mail.
3630 There may be a 'development' package to install containing liblockfile.])
3631   fi
3632 fi
3633 AC_CHECK_HEADERS_ONCE(maillock.h)
3634 AC_SUBST(LIBS_MAIL)
3635
3636 ## Define MAIL_USE_FLOCK (or LOCKF) if the mailer uses flock (or lockf) to
3637 ## interlock access to the mail spool.  The alternative is a lock file named
3638 ## /usr/spool/mail/$USER.lock.
3639 mail_lock=no
3640 case "$opsys" in
3641   aix4-2) mail_lock="lockf" ;;
3642
3643   gnu|freebsd|dragonfly|netbsd|openbsd|darwin|irix6-5) mail_lock="flock" ;;
3644
3645   ## On GNU/Linux systems, both methods are used by various mail programs.
3646   ## I assume most people are using newer mailers that have heard of flock.
3647   ## Change this if you need to.
3648   ## Debian contains a patch which says: "On Debian/GNU/Linux systems,
3649   ## configure gets the right answers, and that means *NOT* using flock.
3650   ## Using flock is guaranteed to be the wrong thing. See Debian Policy
3651   ## for details." and then uses '#ifdef DEBIAN'.  Unfortunately the
3652   ## Debian maintainer hasn't provided a clean fix for Emacs.
3653   ## movemail.c will use 'maillock' when MAILDIR, HAVE_LIBMAIL and
3654   ## HAVE_MAILLOCK_H are defined, so the following appears to be the
3655   ## correct logic.  -- fx
3656   ## We must check for HAVE_LIBLOCKFILE too, as movemail does.
3657   ## liblockfile is a Free Software replacement for libmail, used on
3658   ## Debian systems and elsewhere. -rfr.
3659   gnu-*)
3660     mail_lock="flock"
3661     if test $have_mail = yes || test $have_lockfile = yes; then
3662       test $ac_cv_header_maillock_h = yes && mail_lock=no
3663     fi
3664     ;;
3665
3666   mingw32)
3667     mail_lock="none-needed" ;;
3668 esac
3669
3670 BLESSMAIL_TARGET=
3671 case "$mail_lock" in
3672   flock) AC_DEFINE(MAIL_USE_FLOCK, 1, [Define if the mailer uses flock to interlock the mail spool.]) ;;
3673
3674   lockf) AC_DEFINE(MAIL_USE_LOCKF, 1, [Define if the mailer uses lockf to interlock the mail spool.]) ;;
3675
3676   none-needed) ;;
3677
3678   *) BLESSMAIL_TARGET="need-blessmail" ;;
3679 esac
3680 AC_SUBST(BLESSMAIL_TARGET)
3681
3682 OLD_LIBS=$LIBS
3683 LIBS="$LIB_PTHREAD $LIB_MATH $LIBS"
3684 AC_CHECK_FUNCS(accept4 fchdir gethostname \
3685 getrusage get_current_dir_name \
3686 lrand48 random rint \
3687 select getpagesize setlocale newlocale \
3688 getrlimit setrlimit shutdown getaddrinfo \
3689 pthread_sigmask strsignal setitimer \
3690 sendto recvfrom getsockname getpeername getifaddrs freeifaddrs \
3691 gai_strerror sync \
3692 getpwent endpwent getgrent endgrent \
3693 cfmakeraw cfsetspeed copysign __executable_start log2)
3694 LIBS=$OLD_LIBS
3695
3696 dnl No need to check for aligned_alloc and posix_memalign if using
3697 dnl gmalloc.o, as it supplies them, unless we're using hybrid_malloc.
3698 dnl Don't use these functions on Darwin as they are incompatible with
3699 dnl unexmacosx.c.
3700 if (test -z "$GMALLOC_OBJ" || test "$hybrid_malloc" = yes) \
3701   && test "$opsys" != darwin; then
3702   AC_CHECK_FUNCS([aligned_alloc posix_memalign], [break])
3703 fi
3704
3705 dnl Cannot use AC_CHECK_FUNCS
3706 AC_CACHE_CHECK([for __builtin_unwind_init],
3707                emacs_cv_func___builtin_unwind_init,
3708 [AC_LINK_IFELSE([AC_LANG_PROGRAM([], [__builtin_unwind_init ();])],
3709                 emacs_cv_func___builtin_unwind_init=yes,
3710                 emacs_cv_func___builtin_unwind_init=no)])
3711 if test $emacs_cv_func___builtin_unwind_init = yes; then
3712   AC_DEFINE(HAVE___BUILTIN_UNWIND_INIT, 1,
3713             [Define to 1 if you have the '__builtin_unwind_init' function.])
3714 fi
3715
3716 AC_CHECK_HEADERS_ONCE(sys/un.h)
3717
3718 AC_FUNC_FSEEKO
3719
3720 # UNIX98 PTYs.
3721 AC_CHECK_FUNCS(grantpt)
3722
3723 # PTY-related GNU extensions.
3724 AC_CHECK_FUNCS(getpt posix_openpt)
3725
3726 # Check this now, so that we will NOT find the above functions in ncurses.
3727 # That is because we have not set up to link ncurses in lib-src.
3728 # It's better to believe a function is not available
3729 # than to expect to find it in ncurses.
3730 # Also we need tputs and friends to be able to build at all.
3731 AC_MSG_CHECKING([for library containing tputs])
3732 # Run a test program that contains a call to tputs, a call that is
3733 # never executed.  This tests whether a pre-'main' dynamic linker
3734 # works with the library.  It's too much trouble to actually call
3735 # tputs in the test program, due to portability hassles.  When
3736 # cross-compiling, assume the test program will run if it links.
3737 AC_DEFUN([tputs_link_source], [
3738   AC_LANG_SOURCE(
3739      [[extern void tputs (const char *, int, int (*)(int));
3740        int main (int argc, char **argv)
3741        {
3742           if (argc == 10000)
3743             tputs (argv[0], 0, 0);
3744           return 0;
3745        }]])
3746 ])
3747 if test "${opsys}" = "mingw32"; then
3748   msg='none required'
3749 else
3750   # Maybe curses should be tried earlier?
3751   # See http://debbugs.gnu.org/cgi/bugreport.cgi?bug=9736#35
3752   for tputs_library in '' tinfo ncurses terminfo termcap curses; do
3753     OLIBS=$LIBS
3754     if test -z "$tputs_library"; then
3755       LIBS_TERMCAP=
3756       msg='none required'
3757     else
3758       LIBS_TERMCAP=-l$tputs_library
3759       msg=$LIBS_TERMCAP
3760       LIBS="$LIBS_TERMCAP $LIBS"
3761     fi
3762     AC_RUN_IFELSE([tputs_link_source], [], [msg=no],
3763       [AC_LINK_IFELSE([tputs_link_source], [], [msg=no])])
3764     LIBS=$OLIBS
3765     if test "X$msg" != Xno; then
3766       break
3767     fi
3768   done
3769 fi
3770 AC_MSG_RESULT([$msg])
3771 if test "X$msg" = Xno; then
3772   AC_MSG_ERROR([The required function 'tputs' was not found in any library.
3773 The following libraries were tried (in order):
3774   libtinfo, libncurses, libterminfo, libtermcap, libcurses
3775 Please try installing whichever of these libraries is most appropriate
3776 for your system, together with its header files.
3777 For example, a libncurses-dev(el) or similar package.])
3778 fi
3779
3780 ## Use termcap instead of terminfo?
3781 ## Only true for: freebsd < 40000, ms-w32, msdos, netbsd < 599002500.
3782 TERMINFO=yes
3783 ## FIXME?  In the cases below where we unconditionally set
3784 ## LIBS_TERMCAP="-lncurses", this overrides LIBS_TERMCAP = -ltinfo,
3785 ## if that was found above to have tputs.
3786 ## Should we use the gnu* logic everywhere?
3787 case "$opsys" in
3788   ## darwin: Prevents crashes when running Emacs in Terminal.app under 10.2.
3789   ##  The ncurses library has been moved out of the System framework in
3790   ##  Mac OS X 10.2.  So if configure detects it, set the command-line
3791   ##  option to use it.
3792   darwin) LIBS_TERMCAP="-lncurses" ;;
3793
3794   gnu*) test -z "$LIBS_TERMCAP" && LIBS_TERMCAP="-lncurses" ;;
3795
3796   freebsd)
3797     AC_MSG_CHECKING([whether FreeBSD is new enough to use terminfo])
3798     AC_CACHE_VAL(emacs_cv_freebsd_terminfo,
3799     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <osreldate.h>]],
3800 [[#if __FreeBSD_version < 400000
3801 fail;
3802 #endif
3803 ]])], emacs_cv_freebsd_terminfo=yes, emacs_cv_freebsd_terminfo=no)])
3804
3805     AC_MSG_RESULT($emacs_cv_freebsd_terminfo)
3806
3807     if test $emacs_cv_freebsd_terminfo = yes; then
3808       LIBS_TERMCAP="-lncurses"
3809     else
3810       TERMINFO=no
3811       LIBS_TERMCAP="-ltermcap"
3812     fi
3813     ;;
3814
3815   mingw32)
3816     TERMINFO=no
3817     LIBS_TERMCAP=
3818     ;;
3819
3820   netbsd)
3821     if test "x$LIBS_TERMCAP" != "x-lterminfo"; then
3822       TERMINFO=no
3823       LIBS_TERMCAP="-ltermcap"
3824     fi
3825     ;;
3826
3827   openbsd | dragonfly) LIBS_TERMCAP="-lncurses" ;;
3828
3829   ## hpux: Make sure we get select from libc rather than from libcurses
3830   ##  because libcurses on HPUX 10.10 has a broken version of select.
3831   ##  We used to use -lc -lcurses, but this may be cleaner.
3832   ## FIXME?  But TERMINFO = yes on hpux (it used to be explicitly
3833   # set that way, now it uses the default).  Isn't this a contradiction?
3834   hpux*) LIBS_TERMCAP="-ltermcap" ;;
3835
3836 esac
3837
3838 TERMCAP_OBJ=tparam.o
3839 if test $TERMINFO = yes; then
3840   AC_DEFINE(TERMINFO, 1, [Define to 1 if you use terminfo instead of termcap.])
3841   TERMCAP_OBJ=terminfo.o
3842 fi
3843 if test "X$LIBS_TERMCAP" = "X-lncurses"; then
3844   AC_DEFINE(USE_NCURSES, 1, [Define to 1 if you use ncurses.])
3845 fi
3846 AC_SUBST(LIBS_TERMCAP)
3847 AC_SUBST(TERMCAP_OBJ)
3848
3849 # GNU/Linux-specific timer functions.
3850 AC_CACHE_CHECK([for timerfd interface], [emacs_cv_have_timerfd],
3851   [AC_COMPILE_IFELSE(
3852      [AC_LANG_PROGRAM([[#include <sys/timerfd.h>
3853                       ]],
3854                       [[timerfd_create (CLOCK_REALTIME,
3855                                         TFD_CLOEXEC | TFD_NONBLOCK);
3856                         timerfd_settime (0, TFD_TIMER_ABSTIME, 0, 0);]])],
3857      [emacs_cv_have_timerfd=yes],
3858      [emacs_cv_have_timerfd=no])])
3859 if test "$emacs_cv_have_timerfd" = yes; then
3860   AC_DEFINE([HAVE_TIMERFD], 1,
3861     [Define to 1 if timerfd functions are supported as in GNU/Linux.])
3862 fi
3863
3864 # Alternate stack for signal handlers.
3865 AC_CACHE_CHECK([whether signals can be handled on alternate stack],
3866                [emacs_cv_alternate_stack],
3867   [AC_COMPILE_IFELSE(
3868      [AC_LANG_PROGRAM([[#include <signal.h>
3869                       ]],
3870                       [[stack_t ss;
3871                         struct sigaction sa;
3872                         ss.ss_sp = malloc (SIGSTKSZ);
3873                         ss.ss_size = SIGSTKSZ;
3874                         sa.sa_flags = SA_SIGINFO | SA_ONSTACK;
3875                         sigaltstack (&ss, 0);
3876                         sigaction (SIGSEGV, &sa, 0);]])],
3877      [emacs_cv_alternate_stack=yes],
3878      [emacs_cv_alternate_stack=no])])
3879
3880 # Do we have res_init, for detecting changes in /etc/resolv.conf?
3881 # On Darwin, res_init appears not to be useful: see bug#562 and
3882 # http://lists.gnu.org/archive/html/emacs-devel/2007-11/msg01467.html
3883 resolv=no
3884
3885 if test $opsys != darwin; then
3886
3887   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
3888 #include <arpa/nameser.h>
3889 #include <resolv.h>]],
3890     [[return res_init();]])],
3891     have_res_init=yes, have_res_init=no)
3892   if test "$have_res_init" = no; then
3893     OLIBS="$LIBS"
3894     LIBS="$LIBS -lresolv"
3895     AC_MSG_CHECKING(for res_init with -lresolv)
3896     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
3897 #include <arpa/nameser.h>
3898 #include <resolv.h>]],
3899       [[return res_init();]])],
3900       have_res_init=yes, have_res_init=no)
3901     AC_MSG_RESULT($have_res_init)
3902     if test "$have_res_init" = yes ; then
3903       resolv=yes
3904     fi
3905     LIBS="$OLIBS"
3906   fi
3907
3908   if test "$have_res_init" = yes; then
3909     AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
3910   fi
3911 fi                              dnl !darwin
3912
3913 # Do we need the Hesiod library to provide the support routines?
3914 dnl FIXME?  Should we be skipping this on Darwin too?
3915 LIBHESIOD=
3916 if test "$with_hesiod" != no ; then
3917   # Don't set $LIBS here -- see comments above.  FIXME which comments?
3918   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
3919      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
3920                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
3921   if test "$resolv" = yes ; then
3922     RESOLVLIB=-lresolv
3923   else
3924     RESOLVLIB=
3925   fi
3926   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
3927         hesiod=yes, :, $RESOLVLIB)])
3928
3929   if test x"$hesiod" = xyes; then
3930     LIBHESIOD=-lhesiod
3931   fi
3932 fi
3933 AC_SUBST(LIBHESIOD)
3934
3935 # Do we need libresolv (due to res_init or Hesiod)?
3936 if test "$resolv" = yes && test $opsys != darwin; then
3937   LIBRESOLV=-lresolv
3938 else
3939   LIBRESOLV=
3940 fi
3941 AC_SUBST(LIBRESOLV)
3942
3943 # These tell us which Kerberos-related libraries to use.
3944 COM_ERRLIB=
3945 CRYPTOLIB=
3946 KRB5LIB=
3947 DESLIB=
3948 KRB4LIB=
3949
3950 if test "${with_kerberos}" != no; then
3951   OLD_LIBS=$LIBS
3952   AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
3953   if test $have_com_err = yes; then
3954     COM_ERRLIB=-lcom_err
3955     LIBS="$COM_ERRLIB $LIBS"
3956   fi
3957   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
3958   if test $have_crypto = yes; then
3959     CRYPTOLIB=-lcrypto
3960     LIBS="$CRYPTOLIB $LIBS"
3961   fi
3962   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
3963   if test $have_k5crypto = yes; then
3964     CRYPTOLIB=-lk5crypto
3965     LIBS="$CRYPTOLIB $LIBS"
3966   fi
3967   AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
3968   if test $have_krb5=yes; then
3969     KRB5LIB=-lkrb5
3970     LIBS="$KRB5LIB $LIBS"
3971   fi
3972   dnl FIXME Simplify.  Does not match 22 logic, thanks to default_off?
3973   if test "${with_kerberos5}" = no; then
3974     AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
3975     if test $have_des425 = yes; then
3976       DESLIB=-ldes425
3977       LIBS="$DESLIB $LIBS"
3978     else
3979       AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
3980       if test $have_des = yes; then
3981         DESLIB=-ldes
3982         LIBS="$DESLIB $LIBS"
3983       fi
3984     fi
3985     AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
3986     if test $have_krb4 = yes; then
3987       KRB4LIB=-lkrb4
3988       LIBS="$KRB4LIB $LIBS"
3989     else
3990       AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
3991       if test $have_krb = yes; then
3992         KRB4LIB=-lkrb
3993         LIBS="$KRB4LIB $LIBS"
3994       fi
3995     fi
3996   fi
3997
3998   if test "${with_kerberos5}" != no; then
3999     AC_CHECK_HEADERS(krb5.h,
4000       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
4001                         [#include <krb5.h>])])
4002   else
4003     AC_CHECK_HEADERS(krb.h,,
4004                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
4005                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
4006   fi
4007   AC_CHECK_HEADERS(com_err.h)
4008   LIBS=$OLD_LIBS
4009 fi
4010
4011 AC_SUBST(COM_ERRLIB)
4012 AC_SUBST(CRYPTOLIB)
4013 AC_SUBST(KRB5LIB)
4014 AC_SUBST(DESLIB)
4015 AC_SUBST(KRB4LIB)
4016
4017 AC_CHECK_HEADERS(valgrind/valgrind.h)
4018
4019 AC_CHECK_MEMBERS([struct unipair.unicode], [], [], [[#include <linux/kd.h>]])
4020
4021 AC_CHECK_FUNCS_ONCE(tzset)
4022
4023 ok_so_far=yes
4024 AC_CHECK_FUNC(socket, , ok_so_far=no)
4025 if test $ok_so_far = yes; then
4026   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
4027 fi
4028 if test $ok_so_far = yes; then
4029   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
4030 fi
4031 if test $ok_so_far = yes; then
4032 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
4033   AC_DEFINE(HAVE_INET_SOCKETS, 1,
4034             [Define to 1 if you have inet sockets.])
4035 fi
4036
4037 AC_FUNC_FORK
4038
4039 AC_CHECK_FUNCS(snprintf)
4040
4041 dnl Check for glib.  This differs from other library checks in that
4042 dnl Emacs need not link to glib unless some other library is already
4043 dnl linking to glib.  Although glib provides no facilities that Emacs
4044 dnl needs for its own purposes, when glib is present Emacs needs to
4045 dnl use primitives like g_main_context_query to avoid clashing with
4046 dnl glib at a low level.
4047 dnl
4048 dnl Check this late, since it depends on $GTK_CFLAGS etc.
4049 XGSELOBJ=
4050 OLDCFLAGS="$CFLAGS"
4051 OLDLIBS="$LIBS"
4052 CFLAGS="$CFLAGS $GTK_CFLAGS $RSVG_CFLAGS $DBUS_CFLAGS $SETTINGS_CFLAGS"
4053 LIBS="$LIBS $GTK_LIBS $RSVG_LIBS $DBUS_LIBS $SETTINGS_LIBS"
4054 CFLAGS="$CFLAGS $GFILENOTIFY_CFLAGS $CAIRO_CFLAGS"
4055 LIBS="$LIBS $GFILENOTIFY_LIBS $CAIRO_LIBS"
4056 AC_MSG_CHECKING([whether GLib is linked in])
4057 AC_LINK_IFELSE([AC_LANG_PROGRAM(
4058         [[#include <glib.h>
4059         ]],
4060         [[g_print ("Hello world");]])],
4061      [links_glib=yes],
4062      [links_glib=no])
4063 AC_MSG_RESULT([$links_glib])
4064 if test "${links_glib}" = "yes"; then
4065   AC_DEFINE(HAVE_GLIB, 1, [Define to 1 if GLib is linked in.])
4066   if test "$HAVE_NS" = no;then
4067     XGSELOBJ=xgselect.o
4068   fi
4069 fi
4070 CFLAGS="$OLDCFLAGS"
4071 LIBS="$OLDLIBS"
4072 AC_SUBST(XGSELOBJ)
4073
4074 dnl Adapted from Haible's version.
4075 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
4076   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
4077     [[char* cs = nl_langinfo(CODESET);]])],
4078     emacs_cv_langinfo_codeset=yes,
4079     emacs_cv_langinfo_codeset=no)
4080   ])
4081 if test $emacs_cv_langinfo_codeset = yes; then
4082   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
4083     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
4084 fi
4085
4086 AC_TYPE_MBSTATE_T
4087
4088 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
4089 dnl how the tty code is related to POSIX and/or other versions of termios.
4090 dnl The following looks like a useful start.
4091 dnl
4092 dnl AC_SYS_POSIX_TERMIOS
4093 dnl if test $ac_cv_sys_posix_termios = yes; then
4094 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
4095 dnl                                and macros for terminal control.])
4096 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
4097 dnl fi
4098
4099 dnl Turned on June 1996 supposing nobody will mind it.
4100 dnl MinGW emulates passwd database, so this feature doesn't make sense there.
4101 if test "${opsys}" != "mingw32"; then
4102    AC_DEFINE(AMPERSAND_FULL_NAME, 1, [Define to use the convention that &
4103      in the full name stands for the login id.])
4104 fi
4105
4106 dnl Everybody supports this, except MS.
4107 dnl Seems like the kind of thing we should be testing for, though.
4108 ## Note: PTYs are broken on darwin <6.  Use at your own risk.
4109 if test "${opsys}" != "mingw32"; then
4110   AC_DEFINE(HAVE_PTYS, 1, [Define if the system supports pty devices.])
4111 fi
4112
4113 dnl Everybody supports this, except MS-DOS.
4114 dnl Seems like the kind of thing we should be testing for, though.
4115 dnl Compare with HAVE_INET_SOCKETS (which is unused...) above.
4116 AC_DEFINE(HAVE_SOCKETS, 1, [Define if the system supports
4117   4.2-compatible sockets.])
4118
4119 AH_TEMPLATE(INTERNAL_TERMINAL, [This is substituted when $TERM is "internal".])
4120
4121 AH_TEMPLATE(NULL_DEVICE, [Name of the file to open to get
4122   a null file, or a data sink.])
4123 if test "${opsys}" = "mingw32"; then
4124   AC_DEFINE(NULL_DEVICE, ["NUL:"])
4125 else
4126   AC_DEFINE(NULL_DEVICE, ["/dev/null"])
4127 fi
4128
4129 if test "${opsys}" = "mingw32"; then
4130   SEPCHAR=';'
4131 else
4132   SEPCHAR=':'
4133 fi
4134 AC_DEFINE_UNQUOTED(SEPCHAR, ['$SEPCHAR'], [Character that separates PATH elements.])
4135 dnl This is for MinGW, and is used in test/automated/Makefile.in.
4136 dnl The MSYS Bash has heuristics for replacing ':' with ';' when it
4137 dnl decides that a command-line argument to be passed to a MinGW program
4138 dnl is a PATH-style list of directories.  But that heuristics plays it
4139 dnl safe, and only does the replacement when it is _absolutely_ sure it
4140 dnl sees a colon-separated list of file names; e.g. ":." is left alone,
4141 dnl which breaks in-tree builds.  So we do this manually instead.
4142 dnl Note that we cannot rely on PATH_SEPARATOR, as that one will always
4143 dnl be computed as ':' in MSYS Bash.
4144 AC_SUBST(SEPCHAR)
4145
4146 dnl Everybody supports this, except MS-DOS.
4147 AC_DEFINE(subprocesses, 1, [Define to enable asynchronous subprocesses.])
4148
4149 AC_DEFINE(USER_FULL_NAME, [pw->pw_gecos], [How to get a user's full name.])
4150
4151
4152 AC_DEFINE(DIRECTORY_SEP, ['/'],
4153   [Character that separates directories in a file name.])
4154
4155 if test "${opsys}" = "mingw32"; then
4156   AC_DEFINE(IS_DEVICE_SEP(_c_), [((_c_) == ':')],
4157     [Returns true if character is a device separator.])
4158
4159   AC_DEFINE(IS_DIRECTORY_SEP(_c_), [((_c_) == '/' || (_c_) == '\\')],
4160     [Returns true if character is a directory separator.])
4161
4162   AC_DEFINE(IS_ANY_SEP(_c_), [(IS_DIRECTORY_SEP (_c_) || IS_DEVICE_SEP(_c_))],
4163     [Returns true if character is any form of separator.])
4164 else
4165   AC_DEFINE(IS_DEVICE_SEP(_c_), 0,
4166     [Returns true if character is a device separator.])
4167
4168   AC_DEFINE(IS_DIRECTORY_SEP(_c_), [((_c_) == DIRECTORY_SEP)],
4169     [Returns true if character is a directory separator.])
4170
4171   AC_DEFINE(IS_ANY_SEP(_c_), [(IS_DIRECTORY_SEP (_c_))],
4172     [Returns true if character is any form of separator.])
4173 fi
4174
4175 AH_TEMPLATE(NO_EDITRES, [Define if XEditRes should not be used.])
4176
4177 case $opsys in
4178   aix4-2)
4179     dnl Unfortunately without libXmu we cannot support EditRes.
4180     if test "x$ac_cv_search_XmuConvertStandardSelection" = xno; then
4181       AC_DEFINE(NO_EDITRES, 1)
4182     fi
4183     ;;
4184
4185   hpux*)
4186     dnl Assar Westerlund <assar@sics.se> says this is necessary for
4187     dnl HP-UX 10.20, and that it works for HP-UX 0 as well.
4188     AC_DEFINE(NO_EDITRES, 1)
4189     ;;
4190 esac
4191
4192
4193 case $opsys in
4194   irix6-5 | sol2* | unixware )
4195     dnl Some SVr4s don't define NSIG in sys/signal.h for ANSI environments;
4196     dnl instead, there's a system variable _sys_nsig.  Unfortunately, we
4197     dnl need the constant to dimension an array.  So wire in the appropriate
4198     dnl value here.
4199     AC_DEFINE(NSIG_MINIMUM, 32, [Minimum value of NSIG.])
4200     ;;
4201 esac
4202
4203 emacs_broken_SIGIO=no
4204
4205 case $opsys in
4206   dnl SIGIO exists, but the feature doesn't work in the way Emacs needs.
4207   dnl See eg <http://article.gmane.org/gmane.os.openbsd.ports/46831>.
4208   hpux* | irix6-5 | nacl | openbsd | sol2* | unixware )
4209     emacs_broken_SIGIO=yes
4210     ;;
4211
4212   aix4-2)
4213     dnl On AIX Emacs uses the gmalloc.c malloc implementation.  But given
4214     dnl the way this system works, libc functions that return malloced
4215     dnl memory use the libc malloc implementation. Calling xfree or
4216     dnl xrealloc on the results of such functions results in a crash.
4217     dnl
4218     dnl One solution for this could be to define SYSTEM_MALLOC in configure,
4219     dnl but that does not currently work on this system.
4220     dnl
4221     dnl It is possible to completely override the malloc implementation on
4222     dnl AIX, but that involves putting the malloc functions in a shared
4223     dnl library and setting the MALLOCTYPE environment variable to point to
4224     dnl that shared library.
4225     dnl
4226     dnl Emacs currently calls xrealloc on the results of get_current_dir name,
4227     dnl to avoid a crash just use the Emacs implementation for that function.
4228     dnl
4229     dnl FIXME We could change the AC_CHECK_FUNCS call near the start
4230     dnl of this file, so that we do not check for get_current_dir_name
4231     dnl on AIX.  But that might be fragile if something else ends
4232     dnl up testing for get_current_dir_name as a dependency.
4233     AC_DEFINE(BROKEN_GET_CURRENT_DIR_NAME, 1, [Define if
4234       get_current_dir_name should not be used.])
4235     ;;
4236
4237   freebsd)
4238     dnl Circumvent a bug in FreeBSD.  In the following sequence of
4239     dnl writes/reads on a PTY, read(2) returns bogus data:
4240     dnl
4241     dnl write(2)  1022 bytes
4242     dnl write(2)   954 bytes, get EAGAIN
4243     dnl read(2)   1024 bytes in process_read_output
4244     dnl read(2)     11 bytes in process_read_output
4245     dnl
4246     dnl That is, read(2) returns more bytes than have ever been written
4247     dnl successfully.  The 1033 bytes read are the 1022 bytes written
4248     dnl successfully after processing (for example with CRs added if the
4249     dnl terminal is set up that way which it is here).  The same bytes will
4250     dnl be seen again in a later read(2), without the CRs.
4251     AC_DEFINE(BROKEN_PTY_READ_AFTER_EAGAIN, 1, [Define on FreeBSD to
4252       work around an issue when reading from a PTY.])
4253     ;;
4254 esac
4255
4256 case $opsys in
4257   gnu-* | sol2-10 )
4258     dnl FIXME Can't we test if this exists (eg /proc/$$)?
4259     AC_DEFINE(HAVE_PROCFS, 1, [Define if you have the /proc filesystem.])
4260   ;;
4261 esac
4262
4263 case $opsys in
4264   darwin | dragonfly | freebsd | netbsd | openbsd )
4265     AC_DEFINE(DONT_REOPEN_PTY, 1, [Define if process.c does not need to
4266       close a pty to make it a controlling terminal (it is already a
4267       controlling terminal of the subprocess, because we did ioctl TIOCSCTTY).])
4268   ;;
4269 esac
4270
4271 dnl FIXME Surely we can test for this rather than hard-code it.
4272 case $opsys in
4273   netbsd | openbsd) sound_device="/dev/audio" ;;
4274   *) sound_device="/dev/dsp" ;;
4275 esac
4276
4277 dnl Used in sound.c
4278 AC_DEFINE_UNQUOTED(DEFAULT_SOUND_DEVICE, "$sound_device",
4279   [Name of the default sound device.])
4280
4281
4282 dnl Emacs can read input using SIGIO and buffering characters itself,
4283 dnl or using CBREAK mode and making C-g cause SIGINT.
4284 dnl The choice is controlled by the variable interrupt_input.
4285 dnl
4286 dnl Define INTERRUPT_INPUT to make interrupt_input = 1 the default (use SIGIO)
4287 dnl
4288 dnl Emacs uses the presence of the USABLE_SIGIO macro
4289 dnl to indicate whether or not signal-driven I/O is possible.  It uses
4290 dnl INTERRUPT_INPUT to decide whether to use it by default.
4291 dnl
4292 dnl SIGIO can be used only on systems that implement it (4.2 and 4.3).
4293 dnl CBREAK mode has two disadvantages
4294 dnl 1) At least in 4.2, it is impossible to handle the Meta key properly.
4295 dnl I hear that in system V this problem does not exist.
4296 dnl 2) Control-G causes output to be discarded.
4297 dnl I do not know whether this can be fixed in system V.
4298 dnl
4299 dnl Another method of doing input is planned but not implemented.
4300 dnl It would have Emacs fork off a separate process
4301 dnl to read the input and send it to the true Emacs process
4302 dnl through a pipe.
4303 case $opsys in
4304   darwin | gnu-linux | gnu-kfreebsd )
4305     AC_DEFINE(INTERRUPT_INPUT, 1, [Define to read input using SIGIO.])
4306   ;;
4307 esac
4308
4309
4310 dnl If the system's imake configuration file defines 'NeedWidePrototypes'
4311 dnl as 'NO', we must define NARROWPROTO manually.  Such a define is
4312 dnl generated in the Makefile generated by 'xmkmf'.  If we don't define
4313 dnl NARROWPROTO, we will see the wrong function prototypes for X functions
4314 dnl taking float or double parameters.
4315 case $opsys in
4316   cygwin|gnu|gnu-linux|gnu-kfreebsd|irix6-5|freebsd|netbsd|openbsd)
4317     AC_DEFINE(NARROWPROTO, 1, [Define if system's imake configuration
4318       file defines 'NeedWidePrototypes' as 'NO'.])
4319   ;;
4320 esac
4321
4322
4323 dnl Used in process.c, this must be a loop, even if it only runs once.
4324 dnl (Except on SGI; see below.  Take that, clarity and consistency!)
4325 AH_TEMPLATE(PTY_ITERATION, [How to iterate over PTYs.])
4326 dnl Only used if !PTY_ITERATION.  Iterate from FIRST_PTY_LETTER to z,
4327 dnl trying suffixes 0-16.
4328 AH_TEMPLATE(FIRST_PTY_LETTER, [Letter to use in finding device name of
4329   first PTY, if PTYs are supported.])
4330 AH_TEMPLATE(PTY_OPEN, [How to open a PTY, if non-standard.])
4331 AH_TEMPLATE(PTY_NAME_SPRINTF, [How to get the device name of the control
4332   end of a PTY, if non-standard.])
4333 AH_TEMPLATE(PTY_TTY_NAME_SPRINTF, [How to get device name of the tty
4334   end of a PTY, if non-standard.])
4335
4336 case $opsys in
4337   aix4-2 )
4338     AC_DEFINE(PTY_ITERATION, [int c; for (c = 0; !c ; c++)])
4339     dnl You allocate a pty by opening /dev/ptc to get the master side.
4340     dnl To get the name of the slave side, you just ttyname() the master side.
4341     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptc");])
4342     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [strcpy (pty_name, ttyname (fd));])
4343     ;;
4344
4345   cygwin )
4346     AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
4347     dnl multi-line AC_DEFINEs are hard. :(
4348     AC_DEFINE(PTY_OPEN, [ do { int dummy; sigset_t blocked, procmask; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, &procmask); if (-1 == openpty (&fd, &dummy, pty_name, 0, 0)) fd = -1; pthread_sigmask (SIG_SETMASK, &procmask, 0); if (fd >= 0) emacs_close (dummy); } while (false)])
4349     AC_DEFINE(PTY_NAME_SPRINTF, [])
4350     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
4351     ;;
4352
4353   dnl FIXME?  Maybe use same as freebsd - see bug#12040.
4354   darwin )
4355     AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
4356     dnl Not used, because PTY_ITERATION is defined.
4357     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4358     dnl Note that openpty may fork via grantpt on Mac OS X 10.4/Darwin 8.
4359     dnl But we don't have to block SIGCHLD because it is blocked in the
4360     dnl implementation of grantpt.
4361     AC_DEFINE(PTY_OPEN, [ do { int slave; if (openpty (&fd, &slave, pty_name, NULL, NULL) == -1) fd = -1; else emacs_close (slave); } while (false)])
4362     AC_DEFINE(PTY_NAME_SPRINTF, [])
4363     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
4364     ;;
4365
4366   gnu | openbsd )
4367     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4368     ;;
4369
4370   gnu-linux | gnu-kfreebsd | dragonfly | freebsd | netbsd | nacl )
4371     dnl if HAVE_GRANTPT
4372     if test "x$ac_cv_func_grantpt" = xyes; then
4373       AC_DEFINE(UNIX98_PTYS, 1, [Define if the system has Unix98 PTYs.])
4374       AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
4375       dnl Note that grantpt and unlockpt may fork.  We must block SIGCHLD
4376       dnl to prevent sigchld_handler from intercepting the child's death.
4377       AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptyname = 0; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); if (grantpt (fd) != -1 && unlockpt (fd) != -1) ptyname = ptsname(fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (!ptyname) { emacs_close (fd); return -1; } snprintf (pty_name, PTY_NAME_SIZE, "%s", ptyname); }])
4378       dnl if HAVE_POSIX_OPENPT
4379       if test "x$ac_cv_func_posix_openpt" = xyes; then
4380         AC_DEFINE(PTY_OPEN, [do { fd = posix_openpt (O_RDWR | O_CLOEXEC | O_NOCTTY); if (fd < 0 && errno == EINVAL) fd = posix_openpt (O_RDWR | O_NOCTTY); } while (false)])
4381         AC_DEFINE(PTY_NAME_SPRINTF, [])
4382       dnl if HAVE_GETPT
4383       elif test "x$ac_cv_func_getpt" = xyes; then
4384         AC_DEFINE(PTY_OPEN, [fd = getpt ()])
4385         AC_DEFINE(PTY_NAME_SPRINTF, [])
4386       else
4387         AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptmx");])
4388       fi
4389     else
4390       AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4391     fi
4392     ;;
4393
4394   hpux*)
4395     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4396     AC_DEFINE(PTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/ptym/pty%c%x", c, i);])
4397     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/pty/tty%c%x", c, i);])
4398     ;;
4399
4400   irix6-5 )
4401     dnl It looks like this cannot be right, because it is not a loop.
4402     dnl However, process.c actually does this:
4403     dnl # ifndef __sgi
4404     dnl   continue;
4405     dnl # else
4406     dnl   return -1;
4407     dnl # endif
4408     dnl which presumably makes it OK, since irix == sgi (?).
4409     dnl FIXME it seems like this special treatment is unnecessary?
4410     dnl Why can't irix use a single-trip loop like eg cygwin?
4411     AC_DEFINE(PTY_ITERATION, [])
4412     dnl Not used, because PTY_ITERATION is defined.
4413     AC_DEFINE(FIRST_PTY_LETTER, ['q'])
4414     AC_DEFINE(PTY_OPEN, [ { struct sigaction ocstat, cstat; struct stat stb; char * name; sigemptyset(&cstat.sa_mask); cstat.sa_handler = SIG_DFL; cstat.sa_flags = 0; sigaction(SIGCHLD, &cstat, &ocstat); name = _getpty (&fd, O_RDWR | O_NDELAY, 0600, 0); sigaction(SIGCHLD, &ocstat, (struct sigaction *)0); if (name == 0) return -1; if (fd < 0) return -1; if (fstat (fd, &stb) < 0) return -1; strcpy (pty_name, name); }])
4415     dnl No need to get the pty name at all.
4416     AC_DEFINE(PTY_NAME_SPRINTF, [])
4417     dnl No need to use sprintf to get the tty name--we get that from _getpty.
4418     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
4419     ;;
4420
4421   sol2* )
4422     dnl On SysVr4, grantpt(3) forks a subprocess, so do not use
4423     dnl O_CLOEXEC when opening the pty, and keep the SIGCHLD handler
4424     dnl from intercepting that death.  If any child but grantpt's should die
4425     dnl within, it should be caught after sigrelse(2).
4426     AC_DEFINE(PTY_OPEN, [fd = open (pty_name, O_RDWR | O_NONBLOCK)])
4427     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptsname (int), *ptyname; int grantpt_result; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); grantpt_result = grantpt (fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (grantpt_result == -1 || unlockpt (fd) == -1 || !(ptyname = ptsname (fd))) { emacs_close (fd); return -1; } snprintf (pty_name, PTY_NAME_SIZE, "%s", ptyname); }])
4428     ;;
4429
4430   unixware )
4431     dnl Comments are as per sol2*.
4432     AC_DEFINE(PTY_OPEN, [fd = open (pty_name, O_RDWR | O_NONBLOCK)])
4433     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptsname (int), *ptyname; int grantpt_result; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); grantpt_result = grantpt (fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (grantpt_result == -1) fatal("could not grant slave pty"); if (unlockpt(fd) == -1) fatal("could not unlock slave pty"); if (!(ptyname = ptsname(fd))) fatal ("could not enable slave pty"); snprintf (pty_name, PTY_NAME_SIZE, "%s", ptyname); }])
4434     ;;
4435 esac
4436
4437
4438 case $opsys in
4439   sol2* | unixware )
4440     dnl This change means that we don't loop through allocate_pty too
4441     dnl many times in the (rare) event of a failure.
4442     AC_DEFINE(FIRST_PTY_LETTER, ['z'])
4443     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptmx");])
4444     dnl Push various streams modules onto a PTY channel.  Used in process.c.
4445     AC_DEFINE(SETUP_SLAVE_PTY, [if (ioctl (forkin, I_PUSH, "ptem") == -1) fatal ("ioctl I_PUSH ptem"); if (ioctl (forkin, I_PUSH, "ldterm") == -1) fatal ("ioctl I_PUSH ldterm"); if (ioctl (forkin, I_PUSH, "ttcompat") == -1) fatal ("ioctl I_PUSH ttcompat");], [How to set up a slave PTY, if needed.])
4446     ;;
4447 esac
4448
4449
4450 AH_TEMPLATE(SIGNALS_VIA_CHARACTERS, [Make process_send_signal work by
4451 "typing" a signal character on the pty.])
4452
4453 case $opsys in
4454   dnl Perry Smith <pedz@ddivt1.austin.ibm.com> says this is correct for AIX.
4455   dnl thomas@mathematik.uni-bremen.de says this is needed for IRIX.
4456   aix4-2 | cygwin | gnu | irix6-5 | dragonfly | freebsd | netbsd | openbsd | darwin )
4457     AC_DEFINE(SIGNALS_VIA_CHARACTERS, 1)
4458     ;;
4459
4460   dnl 21 Jun 06: Eric Hanchrow <offby1@blarg.net> says this works.
4461   dnl FIXME Does gnu-kfreebsd have linux/version.h?  It seems unlikely...
4462   gnu-linux | gnu-kfreebsd )
4463
4464     AC_MSG_CHECKING([for signals via characters])
4465     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4466 #include <linux/version.h>
4467 #if LINUX_VERSION_CODE < 0x20400
4468 # error "Linux version too old"
4469 #endif
4470       ]], [[]])], emacs_signals_via_chars=yes, emacs_signals_via_chars=no)
4471
4472     AC_MSG_RESULT([$emacs_signals_via_chars])
4473     test $emacs_signals_via_chars = yes && AC_DEFINE(SIGNALS_VIA_CHARACTERS, 1)
4474     ;;
4475 esac
4476
4477
4478 AH_TEMPLATE(TAB3, [Undocumented.])
4479
4480 case $opsys in
4481   darwin) AC_DEFINE(TAB3, OXTABS) ;;
4482
4483   gnu | dragonfly | freebsd | netbsd | openbsd )
4484     AC_DEFINE(TABDLY, OXTABS, [Undocumented.])
4485     AC_DEFINE(TAB3, OXTABS)
4486     ;;
4487
4488   gnu-linux | gnu-kfreebsd )
4489     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4490 #ifndef __ia64__
4491 # error "not ia64"
4492 #endif
4493       ]], [[]])], AC_DEFINE(GC_MARK_SECONDARY_STACK(),
4494         [do { extern void *__libc_ia64_register_backing_store_base; __builtin_ia64_flushrs (); mark_memory (__libc_ia64_register_backing_store_base, __builtin_ia64_bsp ());} while (false)],
4495         [Mark a secondary stack, like the register stack on the ia64.]), [])
4496     ;;
4497
4498   hpux*)
4499     AC_DEFINE(RUN_TIME_REMAP, 1, [Define if emacs.c needs to call
4500       run_time_remap; for HPUX.])
4501     ;;
4502 esac
4503
4504
4505 dnl This won't be used automatically yet.  We also need to know, at least,
4506 dnl that the stack is continuous.
4507 AH_TEMPLATE(GC_SETJMP_WORKS, [Define if setjmp is known to save all
4508   registers relevant for conservative garbage collection in the jmp_buf.])
4509
4510
4511 case $opsys in
4512   dnl Not all the architectures are tested, but there are Debian packages
4513   dnl for SCM and/or Guile on them, so the technique must work.  See also
4514   dnl comments in alloc.c concerning setjmp and gcc.
4515   dnl Fixme: it's probably safe to just use the GCC conditional below.
4516   gnu-linux | gnu-kfreebsd )
4517     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4518 #if defined __i386__ || defined __sparc__ || defined __mc68000__ \
4519   || defined __alpha__ || defined __mips__ || defined __s390__ \
4520   || defined __arm__ || defined __powerpc__ || defined __amd64__ \
4521   || defined __ia64__ || defined __sh__
4522 /* ok */
4523 #else
4524 # error "setjmp not known to work on this arch"
4525 #endif
4526     ]], [[]])], AC_DEFINE(GC_SETJMP_WORKS, 1))
4527     ;;
4528 esac
4529
4530
4531 if test x$GCC = xyes; then
4532    dnl GC_SETJMP_WORKS is nearly always appropriate for GCC.
4533    AC_DEFINE(GC_SETJMP_WORKS, 1)
4534 else
4535   case $opsys in
4536     dnl irix: Tested on Irix 6.5.  SCM worked on earlier versions.
4537     aix* | dragonfly | freebsd | netbsd | openbsd | irix6-5 | sol2* )
4538       AC_DEFINE(GC_SETJMP_WORKS, 1)
4539       ;;
4540   esac
4541 fi                              dnl GCC?
4542
4543 dnl In a weird quirk, MS runtime uses _setjmp and longjmp.
4544 AC_CACHE_CHECK([for _setjmp], [emacs_cv_func__setjmp],
4545   [AC_LINK_IFELSE(
4546      [AC_LANG_PROGRAM(
4547        [[#include <setjmp.h>
4548          #ifdef __MINGW32__
4549          # define _longjmp longjmp
4550          #endif
4551        ]],
4552        [[jmp_buf j;
4553          if (! _setjmp (j))
4554            _longjmp (j, 1);]])],
4555      [emacs_cv_func__setjmp=yes],
4556      [emacs_cv_func__setjmp=no])])
4557 if test $emacs_cv_func__setjmp = yes; then
4558   AC_DEFINE([HAVE__SETJMP], 1, [Define to 1 if _setjmp and _longjmp work.])
4559 fi
4560
4561 # We need to preserve signal mask to handle C stack overflows.
4562 AC_CACHE_CHECK([for sigsetjmp], [emacs_cv_func_sigsetjmp],
4563   [AC_LINK_IFELSE(
4564      [AC_LANG_PROGRAM(
4565        [[#include <setjmp.h>
4566        ]],
4567        [[sigjmp_buf j;
4568          if (! sigsetjmp (j, 1))
4569            siglongjmp (j, 1);]])],
4570      [emacs_cv_func_sigsetjmp=yes],
4571      [emacs_cv_func_sigsetjmp=no])])
4572 if test $emacs_cv_func_sigsetjmp = yes; then
4573   AC_DEFINE([HAVE_SIGSETJMP], 1,
4574     [Define to 1 if sigsetjmp and siglongjmp work.])
4575 fi
4576
4577 case $emacs_cv_func_sigsetjmp,$emacs_cv_alternate_stack,$opsys in
4578   yes,yes,* | *,*,mingw32)
4579     AC_DEFINE([HAVE_STACK_OVERFLOW_HANDLING], 1,
4580       [Define to 1 if C stack overflow can be handled in some cases.]);;
4581 esac
4582
4583 case $opsys in
4584   sol2* | unixware )
4585     dnl TIOCGPGRP is broken in SysVr4, so we can't send signals to PTY
4586     dnl subprocesses the usual way.  But TIOCSIGNAL does work for PTYs,
4587     dnl and this is all we need.
4588     AC_DEFINE(TIOCSIGSEND, TIOCSIGNAL, [Some platforms redefine this.])
4589     ;;
4590 esac
4591
4592
4593 case $opsys in
4594   hpux* | sol2* )
4595     dnl Used in xfaces.c.
4596     AC_DEFINE(XOS_NEEDS_TIME_H, 1, [Compensate for a bug in Xos.h on
4597       some systems, where it requires time.h.])
4598     ;;
4599 esac
4600
4601
4602 dnl Define symbols to identify the version of Unix this is.
4603 dnl Define all the symbols that apply correctly.
4604 AH_TEMPLATE(DOS_NT, [Define if the system is MS DOS or MS Windows.])
4605 AH_TEMPLATE(MSDOS, [Define if the system is MS DOS.])
4606 AH_TEMPLATE(USG, [Define if the system is compatible with System III.])
4607 AH_TEMPLATE(USG5_4, [Define if the system is compatible with System V Release 4.])
4608
4609 case $opsys in
4610   aix4-2)
4611     AC_DEFINE(USG, [])
4612     dnl This symbol should be defined on AIX Version 3  ???????
4613     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4614 #ifndef _AIX
4615 # error "_AIX not defined"
4616 #endif
4617     ]], [[]])], [], AC_DEFINE(_AIX, [], [Define if the system is AIX.]))
4618     ;;
4619
4620   cygwin)
4621     AC_DEFINE(CYGWIN, 1, [Define if the system is Cygwin.])
4622     ;;
4623
4624   darwin)
4625     dnl Not __APPLE__, as this may not be defined on non-OSX Darwin.
4626     dnl Not DARWIN, because Panther and lower CoreFoundation.h use DARWIN to
4627     dnl distinguish OS X from pure Darwin.
4628     AC_DEFINE(DARWIN_OS, [], [Define if the system is Darwin.])
4629     ;;
4630
4631   gnu-linux | gnu-kfreebsd )
4632     AC_DEFINE(USG, [])
4633     AC_DEFINE(GNU_LINUX, [], [Define if ths system is compatible with GNU/Linux.])
4634     ;;
4635
4636   hpux*)
4637     AC_DEFINE(USG, [])
4638     AC_DEFINE(HPUX, [], [Define if the system is HPUX.])
4639     ;;
4640
4641   irix6-5)
4642     AC_DEFINE(USG, [])
4643     AC_DEFINE(USG5_4, [])
4644     AC_DEFINE(IRIX6_5, [], [Define if the system is IRIX.])
4645     ;;
4646
4647   mingw32)
4648     AC_DEFINE(DOS_NT, [])
4649     AC_DEFINE(WINDOWSNT, 1, [Define if compiling for native MS Windows.])
4650     if test "x$ac_enable_checking" != "x" ; then
4651       AC_DEFINE(EMACSDEBUG, 1, [Define to 1 to enable w32 debug facilities.])
4652     fi
4653     ;;
4654
4655   sol2*)
4656     AC_DEFINE(USG, [])
4657     AC_DEFINE(USG5_4, [])
4658     AC_DEFINE(SOLARIS2, [], [Define if the system is Solaris.])
4659     ;;
4660
4661   unixware)
4662     AC_DEFINE(USG, [])
4663     AC_DEFINE(USG5_4, [])
4664     ;;
4665 esac
4666
4667 AC_CACHE_CHECK([for usable FIONREAD], [emacs_cv_usable_FIONREAD],
4668   [case $opsys in
4669      aix4-2 | nacl)
4670        dnl BUILD 9008 - FIONREAD problem still exists in X-Windows.
4671        emacs_cv_usable_FIONREAD=no
4672        ;;
4673
4674      mingw32)
4675        emacs_cv_usable_FIONREAD=yes
4676        ;;
4677
4678      *)
4679        AC_COMPILE_IFELSE(
4680          [AC_LANG_PROGRAM([[#include <sys/types.h>
4681                             #include <sys/ioctl.h>
4682                             #ifdef USG5_4
4683                             # include <sys/filio.h>
4684                             #endif
4685                           ]],
4686                           [[int foo = ioctl (0, FIONREAD, &foo);]])],
4687          [emacs_cv_usable_FIONREAD=yes],
4688          [emacs_cv_usable_FIONREAD=no])
4689        ;;
4690    esac])
4691 if test $emacs_cv_usable_FIONREAD = yes; then
4692   AC_DEFINE([USABLE_FIONREAD], [1], [Define to 1 if FIONREAD is usable.])
4693
4694   if test $emacs_broken_SIGIO = no; then
4695     AC_CACHE_CHECK([for usable SIGIO], [emacs_cv_usable_SIGIO],
4696       [AC_COMPILE_IFELSE(
4697          [AC_LANG_PROGRAM([[#include <fcntl.h>
4698                             #include <signal.h>
4699                           ]],
4700                           [[int foo = SIGIO | F_SETFL | FASYNC;]])],
4701          [emacs_cv_usable_SIGIO=yes],
4702          [emacs_cv_usable_SIGIO=no])],
4703       [emacs_cv_usable_SIGIO=yes],
4704       [emacs_cv_usable_SIGIO=no])
4705     if test $emacs_cv_usable_SIGIO = yes; then
4706       AC_DEFINE([USABLE_SIGIO], [1], [Define to 1 if SIGIO is usable.])
4707     fi
4708   fi
4709 fi
4710
4711 case $opsys in
4712   hpux11)
4713     dnl It works to open the pty's tty in the parent (Emacs), then
4714     dnl close and reopen it in the child.
4715     AC_DEFINE(USG_SUBTTY_WORKS, 1, [Define for USG systems where it
4716       works to open a pty's tty in the parent process, then close and
4717       reopen it in the child.])
4718     ;;
4719
4720   irix6-5)
4721     AC_DEFINE(PREFER_VSUSP, 1, [Define if process_send_signal should
4722       use VSUSP instead of VSWTCH.])
4723     ;;
4724
4725   sol2-10)
4726     AC_DEFINE(_STRUCTURED_PROC, 1, [Needed for system_process_attributes
4727       on Solaris.])
4728     ;;
4729 esac
4730
4731 # Set up the CFLAGS for real compilation, so we can substitute it.
4732 CFLAGS="$REAL_CFLAGS"
4733 CPPFLAGS="$REAL_CPPFLAGS"
4734 LIBS="$REAL_LIBS"
4735
4736 ## Hack to detect a buggy GCC version.
4737 if test "$GCC" = yes && \
4738    $CC --version 2> /dev/null | grep 'gcc.* 4.5.0' >/dev/null; then
4739   case $CFLAGS in
4740     *-fno-optimize-sibling-calls*) ;;
4741     *-O@<:@23@:>@*)
4742       AC_MSG_ERROR([GCC 4.5.0 has problems compiling Emacs; see etc/PROBLEMS.]);;
4743   esac
4744 fi
4745
4746 version=$PACKAGE_VERSION
4747
4748 copyright="Copyright (C) 2015 Free Software Foundation, Inc."
4749 AC_DEFINE_UNQUOTED(COPYRIGHT, ["$copyright"],
4750   [Short copyright string for this version of Emacs.])
4751 AC_SUBST(copyright)
4752
4753 ### Specify what sort of things we'll be editing into Makefile and config.h.
4754 ### Use configuration here uncanonicalized to avoid exceeding size limits.
4755 AC_SUBST(version)
4756 AC_SUBST(configuration)
4757 ## Unused?
4758 AC_SUBST(canonical)
4759 AC_SUBST(srcdir)
4760 AC_SUBST(prefix)
4761 AC_SUBST(exec_prefix)
4762 AC_SUBST(bindir)
4763 AC_SUBST(datadir)
4764 AC_SUBST(sharedstatedir)
4765 AC_SUBST(libexecdir)
4766 AC_SUBST(mandir)
4767 AC_SUBST(infodir)
4768 AC_SUBST(lispdir)
4769 AC_SUBST(standardlisppath)
4770 AC_SUBST(locallisppath)
4771 AC_SUBST(lisppath)
4772 AC_SUBST(x_default_search_path)
4773 AC_SUBST(etcdir)
4774 AC_SUBST(archlibdir)
4775 AC_SUBST(etcdocdir)
4776 AC_SUBST(bitmapdir)
4777 AC_SUBST(gamedir)
4778 AC_SUBST(gameuser)
4779 AC_SUBST(gamegroup)
4780 ## FIXME? Nothing uses @LD_SWITCH_X_SITE@.
4781 ## src/Makefile.in did add LD_SWITCH_X_SITE (as a cpp define) to the
4782 ## end of LIBX_BASE, but nothing ever set it.
4783 AC_SUBST(LD_SWITCH_X_SITE)
4784 AC_SUBST(C_SWITCH_X_SITE)
4785 AC_SUBST(GNUSTEP_CFLAGS)
4786 AC_SUBST(CFLAGS)
4787 ## Used in lwlib/Makefile.in.
4788 AC_SUBST(X_TOOLKIT_TYPE)
4789 AC_SUBST(ns_appdir)
4790 AC_SUBST(ns_appbindir)
4791 AC_SUBST(ns_appresdir)
4792 AC_SUBST(ns_appsrc)
4793 AC_SUBST(GNU_OBJC_CFLAGS)
4794 AC_SUBST(OTHER_FILES)
4795
4796 if test -n "${term_header}"; then
4797     AC_DEFINE_UNQUOTED(TERM_HEADER, "${term_header}",
4798         [Define to the header for the built-in window system.])
4799 fi
4800
4801 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
4802                    [Define to the canonical Emacs configuration name.])
4803 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${emacs_config_options}",
4804                    [Define to the options passed to configure.])
4805 AH_TEMPLATE(config_opsysfile, [Some platforms that do not use configure
4806   define this to include extra configuration information.])
4807
4808 case $opsys in
4809   mingw32)
4810     AC_DEFINE(config_opsysfile, <ms-w32.h>, [])
4811     ;;
4812 esac
4813
4814 XMENU_OBJ=
4815 XOBJ=
4816 FONT_OBJ=
4817 if test "${HAVE_X_WINDOWS}" = "yes" ; then
4818   AC_DEFINE(HAVE_X_WINDOWS, 1,
4819             [Define to 1 if you want to use the X window system.])
4820   XMENU_OBJ=xmenu.o
4821   XOBJ="xterm.o xfns.o xselect.o xrdb.o xsmfns.o xsettings.o"
4822   FONT_OBJ=xfont.o
4823   if test "$USE_CAIRO" = "yes"; then
4824     FONT_OBJ="ftfont.o ftcrfont.o"
4825   elif test "$HAVE_XFT" = "yes"; then
4826     FONT_OBJ="$FONT_OBJ ftfont.o xftfont.o ftxfont.o"
4827   elif test "$HAVE_FREETYPE" = "yes"; then
4828     FONT_OBJ="$FONT_OBJ ftfont.o ftxfont.o"
4829   fi
4830   AC_SUBST(FONT_OBJ)
4831 fi
4832 AC_SUBST(XMENU_OBJ)
4833 AC_SUBST(XOBJ)
4834 AC_SUBST(FONT_OBJ)
4835
4836 WIDGET_OBJ=
4837 MOTIF_LIBW=
4838 if test "${USE_X_TOOLKIT}" != "none" ; then
4839   WIDGET_OBJ=widget.o
4840   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
4841   if test "${USE_X_TOOLKIT}" = "LUCID"; then
4842     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
4843   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
4844     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
4845     MOTIF_LIBW=-lXm
4846     case "$opsys" in
4847       gnu-linux)
4848         ## Paul Abrahams <abrahams at equinox.shaysnet.com> says this is needed.
4849         MOTIF_LIBW="$MOTIF_LIBW -lXpm"
4850         ;;
4851
4852       unixware)
4853         ## Richard Anthony Ryan <ryanr at ellingtn.ftc.nrcs.usda.gov>
4854         ## says -lXimp is needed in UNIX_SV ... 4.2 1.1.2.
4855         MOTIF_LIBW="MOTIF_LIBW -lXimp"
4856         ;;
4857
4858       aix4-2)
4859         ## olson@mcs.anl.gov says -li18n is needed by -lXm.
4860         MOTIF_LIBW="$MOTIF_LIBW -li18n"
4861         ;;
4862     esac
4863     MOTIF_LIBW="$MOTIF_LIBW $LIBXP"
4864   fi
4865 fi
4866 AC_SUBST(WIDGET_OBJ)
4867
4868 TOOLKIT_LIBW=
4869 case "$USE_X_TOOLKIT" in
4870   MOTIF) TOOLKIT_LIBW="$MOTIF_LIBW" ;;
4871   LUCID) TOOLKIT_LIBW="$LUCID_LIBW" ;;
4872   none) test "x$HAVE_GTK" = "xyes" && TOOLKIT_LIBW="$GTK_LIBS" ;;
4873 esac
4874 AC_SUBST(TOOLKIT_LIBW)
4875
4876 if test "${opsys}" != "mingw32"; then
4877   if test "$USE_X_TOOLKIT" = "none"; then
4878     LIBXT_OTHER="\$(LIBXSM)"
4879   else
4880     LIBXT_OTHER="\$(LIBXMU) -lXt \$(LIBXTR6) -lXext"
4881   fi
4882 fi
4883 AC_SUBST(LIBXT_OTHER)
4884
4885 if test "${HAVE_X11}" = "yes" ; then
4886   AC_DEFINE(HAVE_X11, 1,
4887             [Define to 1 if you want to use version 11 of X windows.])
4888   LIBX_OTHER="\$(LIBXT) \$(LIBX_EXTRA)"
4889 else
4890   LIBX_OTHER=
4891 fi
4892 AC_SUBST(LIBX_OTHER)
4893
4894 if test "$HAVE_GTK" = yes || test "$HAVE_X11" != yes; then
4895   LIBXMENU=
4896 elif test "$USE_X_TOOLKIT" = none; then
4897   LIBXMENU='$(oldXMenudir)/libXMenu11.a'
4898 else
4899   LIBXMENU='$(lwlibdir)/liblw.a'
4900 fi
4901 AC_SUBST(LIBXMENU)
4902
4903 AC_CACHE_CHECK([for struct alignment],
4904   [emacs_cv_struct_alignment],
4905   [AC_COMPILE_IFELSE(
4906      [AC_LANG_PROGRAM([[#include <stddef.h>
4907                         struct __attribute__ ((aligned (8))) s { char c; };
4908                         struct t { char c; struct s s; };
4909                         char verify[offsetof (struct t, s) == 8 ? 1 : -1];
4910                       ]])],
4911      [emacs_cv_struct_alignment=yes],
4912      [emacs_cv_struct_alignment=no])])
4913 if test "$emacs_cv_struct_alignment" = yes; then
4914   AC_DEFINE([HAVE_STRUCT_ATTRIBUTE_ALIGNED], 1,
4915     [Define to 1 if 'struct __attribute__ ((aligned (N)))' aligns the
4916      structure to an N-byte boundary.])
4917 fi
4918
4919 if test "${GNU_MALLOC}" = "yes" ; then
4920   AC_DEFINE(GNU_MALLOC, 1,
4921             [Define to 1 if you want to use the GNU memory allocator.])
4922 fi
4923
4924 RALLOC_OBJ=
4925 if test "${REL_ALLOC}" = "yes" ; then
4926   AC_DEFINE(REL_ALLOC, 1,
4927             [Define REL_ALLOC if you want to use the relocating allocator for
4928              buffer space.])
4929
4930   test "$system_malloc" != "yes" && RALLOC_OBJ=ralloc.o
4931 fi
4932 AC_SUBST(RALLOC_OBJ)
4933
4934 if test "$opsys" = "cygwin"; then
4935   CYGWIN_OBJ="sheap.o cygw32.o"
4936   ## Cygwin differs because of its unexec().
4937   PRE_ALLOC_OBJ=
4938   POST_ALLOC_OBJ=lastfile.o
4939 elif test "$opsys" = "mingw32"; then
4940   CYGWIN_OBJ=
4941   PRE_ALLOC_OBJ=
4942   POST_ALLOC_OBJ=lastfile.o
4943 else
4944   CYGWIN_OBJ=
4945   PRE_ALLOC_OBJ=lastfile.o
4946   POST_ALLOC_OBJ=
4947 fi
4948 AC_SUBST(CYGWIN_OBJ)
4949 AC_SUBST(PRE_ALLOC_OBJ)
4950 AC_SUBST(POST_ALLOC_OBJ)
4951
4952 dnl Call this 'FORTIFY_SOUR' so that it sorts before the 'FORTIFY_SOURCE'
4953 dnl verbatim defined above.  The tricky name is apropos, as this hack
4954 dnl makes Fortify go sour!
4955 AH_VERBATIM([FORTIFY_SOUR],
4956 [/* Without the following workaround, Emacs runs slowly on OS X 10.8.
4957    The workaround disables some useful run-time checking, so it
4958    should be conditional to the platforms with the performance bug.
4959    Perhaps Apple will fix this some day; also see m4/extern-inline.m4.  */
4960 #if defined __APPLE__ && defined __GNUC__
4961 # ifndef _DONT_USE_CTYPE_INLINE_
4962 #  define _DONT_USE_CTYPE_INLINE_
4963 # endif
4964 # ifndef _FORTIFY_SOURCE
4965 #  define _FORTIFY_SOURCE 0
4966 # endif
4967 #endif
4968 ])
4969
4970 # If user asks to omit features, disable optional features that gnulib
4971 # might otherwise enable.
4972 if test "$with_features" = no && test "$enable_acl" != yes; then
4973   enable_acl=no
4974 fi
4975
4976 # Configure gnulib.  Although this does not affect CFLAGS or LIBS permanently.
4977 # it temporarily reverts them to their pre-pkg-config values,
4978 # because gnulib needs to work with both src (which uses the
4979 # pkg-config stuff) and lib-src (which does not).  For example, gnulib
4980 # may need to determine whether LIB_CLOCK_GETTIME should contain -lrt,
4981 # and it therefore needs to run in an environment where LIBS does not
4982 # already contain -lrt merely because 'pkg-config --libs' printed '-lrt'
4983 # for some package unrelated to lib-src.
4984 SAVE_CFLAGS=$CFLAGS
4985 SAVE_LIBS=$LIBS
4986 CFLAGS=$pre_PKG_CONFIG_CFLAGS
4987 LIBS="$LIB_PTHREAD $pre_PKG_CONFIG_LIBS"
4988 gl_ASSERT_NO_GNULIB_POSIXCHECK
4989 gl_ASSERT_NO_GNULIB_TESTS
4990 gl_INIT
4991 CFLAGS=$SAVE_CFLAGS
4992 LIBS=$SAVE_LIBS
4993
4994 if test "${opsys}" = "mingw32"; then
4995   CPPFLAGS="$CPPFLAGS -DUSE_CRT_DLL=1 -I \${abs_top_srcdir}/nt/inc"
4996   # Remove unneeded switches from the value of CC that goes to Makefiles
4997   CC=`AS_ECHO(["$CC"]) | sed -e "s,$GCC_TEST_OPTIONS,,"`
4998 fi
4999
5000 case "$opsys" in
5001   aix4-2) LD_SWITCH_SYSTEM_TEMACS="-Wl,-bnodelcsect" ;;
5002
5003   cygwin) LD_SWITCH_SYSTEM_TEMACS="-Wl,-stack,0x00800000" ;;
5004
5005   darwin)
5006    ## The -headerpad option tells ld (see man page) to leave room at the
5007    ## end of the header for adding load commands.  Needed for dumping.
5008    ## 0x1000 is enough for roughly 52 load commands on the x86_64
5009    ## architecture (where they are 78 bytes each). The actual number of
5010    ## load commands added is not consistent but normally ranges from
5011    ## about 14 to about 34. Setting it high gets us plenty of slop and
5012    ## only costs about 1.5K of wasted binary space.
5013    headerpad_extra=1000
5014    if test "$HAVE_NS" = "yes"; then
5015      libs_nsgui="-framework AppKit"
5016      if test "$NS_IMPL_COCOA" = "yes"; then
5017         libs_nsgui="$libs_nsgui -framework IOKit"
5018      fi
5019    else
5020      libs_nsgui=
5021    fi
5022    LD_SWITCH_SYSTEM_TEMACS="-fno-pie -prebind $libs_nsgui -Xlinker -headerpad -Xlinker $headerpad_extra"
5023
5024    ## This is here because src/Makefile.in did some extra fiddling around
5025    ## with LD_SWITCH_SYSTEM.  It seems cleaner to put this in
5026    ## LD_SWITCH_SYSTEM_TEMACS instead,
5027    test "x$LD_SWITCH_SYSTEM" = "x" && test "x$GCC" != "xyes" && \
5028      LD_SWITCH_SYSTEM_TEMACS="-X $LD_SWITCH_SYSTEM_TEMACS"
5029    ;;
5030
5031   ## LD_SWITCH_X_SITE_RPATH is a -rpath option saying where to
5032   ## find X at run-time.
5033   ## When handled by cpp, this was in LD_SWITCH_SYSTEM.  However, at the
5034   ## point where configure sourced the s/*.h file, LD_SWITCH_X_SITE_RPATH
5035   ## had not yet been defined and was expanded to null.  Hence LD_SWITCH_SYSTEM
5036   ## had different values in configure (in ac_link) and src/Makefile.in.
5037   ## It seems clearer therefore to put this piece in LD_SWITCH_SYSTEM_TEMACS.
5038   gnu*) LD_SWITCH_SYSTEM_TEMACS="\$(LD_SWITCH_X_SITE_RPATH)" ;;
5039
5040   mingw32)
5041    ## Is it any better under MinGW64 to relocate emacs into higher addresses?
5042    case "$canonical" in
5043      x86_64-*-*) LD_SWITCH_SYSTEM_TEMACS="-Wl,-stack,0x00800000 -Wl,-heap,0x00100000 -Wl,-image-base,0x400000000 -Wl,-entry,__start -Wl,-Map,./temacs.map" ;;
5044      *) LD_SWITCH_SYSTEM_TEMACS="-Wl,-stack,0x00800000 -Wl,-heap,0x00100000 -Wl,-image-base,0x01000000 -Wl,-entry,__start -Wl,-Map,./temacs.map" ;;
5045    esac
5046    ;;
5047
5048   *) LD_SWITCH_SYSTEM_TEMACS= ;;
5049 esac
5050
5051 # -nopie fixes a temacs segfault on Gentoo, OpenBSD, and other systems
5052 # with "hardened" GCC configurations for some reason (Bug#18784).
5053 # We don't know why -nopie works, but not segfaulting is better than
5054 # segfaulting.  Use ac_c_werror_flag=yes when trying -nopie, otherwise
5055 # clang keeps warning that it does not understand -nopie, and pre-4.6
5056 # GCC has a similar problem (Bug#20338).
5057 AC_CACHE_CHECK([whether $CC accepts -nopie],
5058   [emacs_cv_prog_cc_nopie],
5059   [emacs_save_c_werror_flag=$ac_c_werror_flag
5060    emacs_save_LDFLAGS=$LDFLAGS
5061    ac_c_werror_flag=yes
5062    LDFLAGS="$LDFLAGS -nopie"
5063    AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
5064      [emacs_cv_prog_cc_nopie=yes],
5065      [emacs_cv_prog_cc_nopie=no])
5066    ac_c_werror_flag=$emacs_save_c_werror_flag
5067    LDFLAGS=$emacs_save_LDFLAGS])
5068 if test "$emacs_cv_prog_cc_nopie" = yes; then
5069   LD_SWITCH_SYSTEM_TEMACS="$LD_SWITCH_SYSTEM_TEMACS -nopie"
5070 fi
5071
5072 if test x$ac_enable_profiling != x ; then
5073   case $opsys in
5074     *freebsd | gnu-linux) ;;
5075     *) LD_SWITCH_SYSTEM_TEMACS="$LD_SWITCH_SYSTEM_TEMACS -pg" ;;
5076   esac
5077 fi
5078
5079 LD_SWITCH_SYSTEM_TEMACS="$LDFLAGS_NOCOMBRELOC $LD_SWITCH_SYSTEM_TEMACS"
5080
5081 AC_SUBST(LD_SWITCH_SYSTEM_TEMACS)
5082
5083 ## Common for all window systems
5084 if test "$window_system" != "none"; then
5085   AC_DEFINE(HAVE_WINDOW_SYSTEM, 1, [Define if you have a window system.])
5086   AC_DEFINE(POLL_FOR_INPUT, 1, [Define if you poll periodically to detect C-g.])
5087   WINDOW_SYSTEM_OBJ="fontset.o fringe.o image.o"
5088 fi
5089
5090 AC_SUBST(WINDOW_SYSTEM_OBJ)
5091
5092 AH_TOP([/* GNU Emacs site configuration template file.
5093
5094 Copyright (C) 1988, 1993-1994, 1999-2002, 2004-2015
5095   Free Software Foundation, Inc.
5096
5097 This file is part of GNU Emacs.
5098
5099 GNU Emacs is free software: you can redistribute it and/or modify
5100 it under the terms of the GNU General Public License as published by
5101 the Free Software Foundation, either version 3 of the License, or
5102 (at your option) any later version.
5103
5104 GNU Emacs is distributed in the hope that it will be useful,
5105 but WITHOUT ANY WARRANTY; without even the implied warranty of
5106 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
5107 GNU General Public License for more details.
5108
5109 You should have received a copy of the GNU General Public License
5110 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
5111
5112
5113 /* No code in Emacs #includes config.h twice, but some bits of code
5114    intended to work with other packages as well (like gmalloc.c)
5115    think they can include it as many times as they like.  */
5116 #ifndef EMACS_CONFIG_H
5117 #define EMACS_CONFIG_H
5118 ])dnl
5119
5120 AH_BOTTOM([#include <conf_post.h>
5121
5122 #endif /* EMACS_CONFIG_H */
5123
5124 /*
5125 Local Variables:
5126 mode: c
5127 End:
5128 */
5129 ])dnl
5130
5131 #### Report on what we decided to do.
5132 #### Report GTK as a toolkit, even if it doesn't use Xt.
5133 #### It makes printing result more understandable as using GTK sets
5134 #### toolkit_scroll_bars to yes by default.
5135 if test "${HAVE_GTK}" = "yes"; then
5136   USE_X_TOOLKIT="$USE_GTK_TOOLKIT"
5137 fi
5138
5139 if test $USE_ACL -ne 0; then
5140   ACL_SUMMARY="yes $LIB_ACL"
5141 else
5142   ACL_SUMMARY=no
5143 fi
5144
5145 emacs_standard_dirs='Standard dirs'
5146 AS_ECHO(["
5147 Configured for '${canonical}'.
5148
5149   Where should the build process find the source code?    ${srcdir}
5150   What compiler should emacs be built with?               ${CC} ${CFLAGS}
5151   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
5152   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
5153   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
5154   What window system should Emacs use?                    ${window_system}
5155   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}
5156   Where do we find X Windows header files?                ${x_includes:-$emacs_standard_dirs}
5157   Where do we find X Windows libraries?                   ${x_libraries:-$emacs_standard_dirs}"])
5158
5159 optsep=
5160 emacs_config_features=
5161 for opt in XAW3D XPM JPEG TIFF GIF PNG RSVG CAIRO IMAGEMAGICK SOUND GPM DBUS \
5162   GCONF GSETTINGS NOTIFY ACL LIBSELINUX GNUTLS LIBXML2 FREETYPE M17N_FLT \
5163   LIBOTF XFT ZLIB TOOLKIT_SCROLL_BARS X_TOOLKIT X11 NS; do
5164
5165     case $opt in
5166       NOTIFY|ACL) eval val=\${${opt}_SUMMARY} ;;
5167       CAIRO|TOOLKIT_SCROLL_BARS|X_TOOLKIT) eval val=\${USE_$opt} ;;
5168       *) eval val=\${HAVE_$opt} ;;
5169     esac
5170     case x$val in
5171       xno|xnone|x) continue ;;
5172     esac
5173     case $opt in
5174       X_TOOLKIT)
5175         case $val in
5176           GTK*|LUCID|MOTIF) opt=$val ;;
5177           *) continue ;;
5178         esac
5179       ;;
5180     esac
5181     AS_VAR_APPEND([emacs_config_features], ["$optsep$opt"])
5182     optsep=' '
5183 done
5184 AC_DEFINE_UNQUOTED(EMACS_CONFIG_FEATURES, "${emacs_config_features}",
5185   [Summary of some of the main features enabled by configure.])
5186
5187 AS_ECHO(["  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}
5188   Does Emacs use -lXpm?                                   ${HAVE_XPM}
5189   Does Emacs use -ljpeg?                                  ${HAVE_JPEG}
5190   Does Emacs use -ltiff?                                  ${HAVE_TIFF}
5191   Does Emacs use a gif library?                           ${HAVE_GIF} $LIBGIF
5192   Does Emacs use a png library?                           ${HAVE_PNG} $LIBPNG
5193   Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}
5194   Does Emacs use cairo?                                   ${USE_CAIRO}
5195   Does Emacs use imagemagick?                             ${HAVE_IMAGEMAGICK}
5196   Does Emacs support sound?                               ${HAVE_SOUND}
5197   Does Emacs use -lgpm?                                   ${HAVE_GPM}
5198   Does Emacs use -ldbus?                                  ${HAVE_DBUS}
5199   Does Emacs use -lgconf?                                 ${HAVE_GCONF}
5200   Does Emacs use GSettings?                               ${HAVE_GSETTINGS}
5201   Does Emacs use a file notification library?             ${NOTIFY_SUMMARY}
5202   Does Emacs use access control lists?                    ${ACL_SUMMARY}
5203   Does Emacs use -lselinux?                               ${HAVE_LIBSELINUX}
5204   Does Emacs use -lgnutls?                                ${HAVE_GNUTLS}
5205   Does Emacs use -lxml2?                                  ${HAVE_LIBXML2}
5206   Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}
5207   Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}
5208   Does Emacs use -lotf?                                   ${HAVE_LIBOTF}
5209   Does Emacs use -lxft?                                   ${HAVE_XFT}
5210   Does Emacs directly use zlib?                           ${HAVE_ZLIB}
5211   Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}
5212 "])
5213
5214 if test -n "${EMACSDATA}"; then
5215    AS_ECHO(["  Environment variable EMACSDATA set to:                  $EMACSDATA"])
5216 fi
5217 if test -n "${EMACSDOC}"; then
5218    AS_ECHO(["  Environment variable EMACSDOC set to:                   $EMACSDOC"])
5219 fi
5220
5221 echo
5222
5223 if test "$HAVE_NS" = "yes"; then
5224    echo
5225    AS_ECHO(["You must run \"${MAKE-make} install\" in order to test the built application.
5226 The installed application will go to nextstep/Emacs.app and can be
5227 run or moved from there."])
5228    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
5229       echo "The application will be fully self-contained."
5230     else
5231       AS_ECHO(["The lisp resources for the application will be installed under ${prefix}.
5232 You may need to run \"${MAKE-make} install\" with sudo.  The application will fail
5233 to run if these resources are not installed."])
5234    fi
5235    echo
5236 fi
5237
5238 if test "${opsys}" = "cygwin"; then
5239   case `uname -r` in
5240     1.5.*) AC_MSG_WARN([[building Emacs on Cygwin 1.5 is not supported.]])
5241            echo
5242            ;;
5243   esac
5244 fi
5245
5246 # Remove any trailing slashes in these variables.
5247 case $prefix in
5248   */) prefix=`AS_DIRNAME(["$prefix."])`;;
5249 esac
5250 case $exec_prefix in
5251   */) exec_prefix=`AS_DIRNAME(["$exec_prefix."])`;;
5252 esac
5253
5254 if test "$HAVE_NS" = "yes"; then
5255   if test "$NS_IMPL_GNUSTEP" = yes; then
5256     AC_CONFIG_FILES([nextstep/GNUstep/Emacs.base/Resources/Info-gnustep.plist:nextstep/templates/Info-gnustep.plist.in \
5257       nextstep/GNUstep/Emacs.base/Resources/Emacs.desktop:nextstep/templates/Emacs.desktop.in])
5258     ns_check_file=Resources/Info-gnustep.plist
5259   else
5260     AC_CONFIG_FILES([nextstep/Cocoa/Emacs.base/Contents/Info.plist:nextstep/templates/Info.plist.in \
5261       nextstep/Cocoa/Emacs.base/Contents/Resources/English.lproj/InfoPlist.strings:nextstep/templates/InfoPlist.strings.in])
5262     ns_check_file=Contents/Info.plist
5263   fi
5264   AC_SUBST(ns_check_file)
5265 fi
5266
5267 dnl config.status treats $srcdir specially, so I think this is ok...
5268 AC_CONFIG_FILES([$srcdir/doc/man/emacs.1])
5269
5270 dnl Obviously there is duplication here wrt $SUBDIR_MAKEFILES.
5271 dnl You _can_ use that variable in AC_CONFIG_FILES, so long as any directory
5272 dnl using automake (ie lib/) is explicitly listed and not "hidden" in a variable
5273 dnl (else you get "no 'Makefile.am' found for any configure output").
5274 dnl This will work, but you get a config.status that is not quite right
5275 dnl (see http://lists.gnu.org/archive/html/bug-autoconf/2008-08/msg00028.html).
5276 dnl That doesn't have any obvious consequences for Emacs, but on the whole
5277 dnl it seems better to just live with the duplication.
5278 SUBDIR_MAKEFILES="lib/Makefile lib-src/Makefile oldXMenu/Makefile doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile leim/Makefile nextstep/Makefile nt/Makefile"
5279
5280 AC_CONFIG_FILES([Makefile lib/Makefile lib-src/Makefile oldXMenu/Makefile \
5281        doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
5282        doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile \
5283        leim/Makefile nextstep/Makefile nt/Makefile])
5284
5285 dnl test/ is not present in release tarfiles.
5286 opt_makefile=test/automated/Makefile
5287
5288 if test -f "$srcdir/$opt_makefile.in"; then
5289   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES $opt_makefile"
5290   dnl Again, it's best not to use a variable.  Though you can add
5291   dnl ", [], [opt_makefile='$opt_makefile']" and it should work.
5292   AC_CONFIG_FILES([test/automated/Makefile])
5293 fi
5294
5295
5296 dnl The admin/ directory used to be excluded from tarfiles.
5297 if test -d $srcdir/admin; then
5298   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES admin/charsets/Makefile admin/unidata/Makefile admin/grammars/Makefile"
5299   AC_CONFIG_FILES([admin/charsets/Makefile])
5300   AC_CONFIG_FILES([admin/unidata/Makefile])
5301   AC_CONFIG_FILES([admin/grammars/Makefile])
5302 fi                              dnl -d admin
5303
5304
5305 SUBDIR_MAKEFILES_IN=`echo " ${SUBDIR_MAKEFILES}" | sed -e 's| | $(srcdir)/|g' -e 's|Makefile|Makefile.in|g'`
5306
5307 AC_SUBST(SUBDIR_MAKEFILES_IN)
5308
5309 dnl You might wonder (I did) why epaths.h is generated by running make,
5310 dnl rather than just letting configure generate it from epaths.in.
5311 dnl One reason is that the various paths are not fully expanded (see above);
5312 dnl eg gamedir=${prefix}/var/games/emacs.
5313 dnl Secondly, the GNU Coding standards require that one should be able
5314 dnl to run 'make prefix=/some/where/else' and override the values set
5315 dnl by configure.  This also explains the 'move-if-change' test and
5316 dnl the use of force in the 'epaths-force' rule in Makefile.in.
5317 AC_CONFIG_COMMANDS([src/epaths.h], [
5318 if test "${opsys}" = "mingw32"; then
5319   ${MAKE-make} MAKEFILE_NAME=do-not-make-Makefile epaths-force-w32
5320 else
5321   ${MAKE-make} MAKEFILE_NAME=do-not-make-Makefile epaths-force
5322 fi || AC_MSG_ERROR(['src/epaths.h' could not be made.])
5323 ], [GCC="$GCC" CPPFLAGS="$CPPFLAGS" opsys="$opsys"])
5324
5325 dnl NB we have to cheat and use the ac_... version because abs_top_srcdir
5326 dnl is not yet set, sigh.  Or we could use ../$srcdir/src/.gdbinit,
5327 dnl or a symlink?
5328 AC_CONFIG_COMMANDS([src/.gdbinit], [
5329 if test ! -f src/.gdbinit && test -f "$srcdir/src/.gdbinit"; then
5330   AS_ECHO(["source $ac_abs_top_srcdir/src/.gdbinit"]) > src/.gdbinit
5331 fi
5332 ])
5333
5334 dnl Perhaps this would be better named doc-emacs-emacsver.texi?
5335 dnl See comments for etc-refcards-emacsver.tex.
5336 dnl Since we get a doc/emacs directory generated anyway, for the Makefile,
5337 dnl it is not quite the same.  But we are generating in $srcdir.
5338 AC_CONFIG_COMMANDS([doc/emacs/emacsver.texi], [
5339 ${MAKE-make} -s --no-print-directory -C doc/emacs doc-emacsver || \
5340 AC_MSG_ERROR(['doc/emacs/emacsver.texi' could not be made.])
5341 ])
5342
5343 dnl If we give this the more natural name, etc/refcards/emacsver.texi,
5344 dnl then a directory etc/refcards is created in the build directory,
5345 dnl which is probably harmless, but confusing (in out-of-tree builds).
5346 dnl (If we were to generate etc/refcards/Makefile, this might change.)
5347 dnl It is really $srcdir/etc/refcards/emacsver.tex that we generate.
5348 AC_CONFIG_COMMANDS([etc-refcards-emacsver.tex], [
5349 ${MAKE-make} -s MAKEFILE_NAME=do-not-make-Makefile etc-emacsver || \
5350 AC_MSG_ERROR(['etc/refcards/emacsver.tex' could not be made.])
5351 ])
5352
5353 AC_OUTPUT
5354
5355 test "$MAKE" = make || AC_MSG_NOTICE([Now you can run '$MAKE'.])