code.delx.au - gnu-emacs/blob - test/lisp/emacs-lisp/map-tests.el

   1 ;;; map-tests.el --- Tests for map.el  -*- lexical-binding:t -*-
   2
   3 ;; Copyright (C) 2015-2016 Free Software Foundation, Inc.
   4
   5 ;; Author: Nicolas Petton <nicolas@petton.fr>
   6 ;; Maintainer: emacs-devel@gnu.org
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; Tests for map.el
  26
  27 ;;; Code:
  28
  29 (require 'ert)
  30 (require 'map)
  31
  32 (defmacro with-maps-do (var &rest body)
  33   "Successively bind VAR to an alist, vector and hash-table.
  34 Each map is built from the following alist data:
  35 '((0 . 3) (1 . 4) (2 . 5)).
  36 Evaluate BODY for each created map.
  37
  38 \(fn (var map) body)"
  39   (declare (indent 1) (debug t))
  40   (let ((alist (make-symbol "alist"))
  41         (vec (make-symbol "vec"))
  42         (ht (make-symbol "ht")))
  43    `(let ((,alist (list (cons 0 3)
  44                         (cons 1 4)
  45                         (cons 2 5)))
  46           (,vec (vector 3 4 5))
  47           (,ht (make-hash-table)))
  48       (puthash 0 3 ,ht)
  49       (puthash 1 4 ,ht)
  50       (puthash 2 5 ,ht)
  51       (dolist (,var (list ,alist ,vec ,ht))
  52         ,@body))))
  53
  54 (ert-deftest test-map-elt ()
  55   (with-maps-do map
  56     (should (= 3 (map-elt map 0)))
  57     (should (= 4 (map-elt map 1)))
  58     (should (= 5 (map-elt map 2)))
  59     (should (null (map-elt map -1)))
  60     (should (null (map-elt map 4)))))
  61
  62 (ert-deftest test-map-elt-default ()
  63   (with-maps-do map
  64     (should (= 5 (map-elt map 7 5)))))
  65
  66 (ert-deftest test-map-elt-with-nil-value ()
  67   (should (null (map-elt '((a . 1)
  68                            (b))
  69                          'b
  70                          '2))))
  71
  72 (ert-deftest test-map-put ()
  73   (with-maps-do map
  74     (setf (map-elt map 2) 'hello)
  75     (should (eq (map-elt map 2) 'hello)))
  76   (with-maps-do map
  77     (map-put map 2 'hello)
  78     (should (eq (map-elt map 2) 'hello)))
  79   (let ((ht (make-hash-table)))
  80     (setf (map-elt ht 2) 'a)
  81     (should (eq (map-elt ht 2)
  82                 'a)))
  83   (let ((alist '((0 . a) (1 . b) (2 . c))))
  84     (setf (map-elt alist 2) 'a)
  85     (should (eq (map-elt alist 2)
  86                 'a)))
  87   (let ((vec [3 4 5]))
  88    (should-error (setf (map-elt vec 3) 6))))
  89
  90 (ert-deftest test-map-put-alist-new-key ()
  91   "Regression test for Bug#23105."
  92   (let ((alist '((0 . a))))
  93     (map-put alist 2 'b)
  94     (should (eq (map-elt alist 2)
  95                 'b))))
  96
  97 (ert-deftest test-map-put-return-value ()
  98   (let ((ht (make-hash-table)))
  99     (should (eq (map-put ht 'a 'hello) 'hello))))
 100
 101 (ert-deftest test-map-delete ()
 102   (with-maps-do map
 103     (map-delete map 1)
 104     (should (null (map-elt map 1))))
 105   (with-maps-do map
 106     (map-delete map -2)
 107     (should (null (map-elt map -2)))))
 108
 109 (ert-deftest test-map-delete-return-value ()
 110   (let ((ht (make-hash-table)))
 111     (should (eq (map-delete ht 'a) ht))))
 112
 113 (ert-deftest test-map-nested-elt ()
 114   (let ((vec [a b [c d [e f]]]))
 115     (should (eq (map-nested-elt vec '(2 2 0)) 'e)))
 116   (let ((alist '((a . 1)
 117                  (b . ((c . 2)
 118                        (d . 3)
 119                        (e . ((f . 4)
 120                              (g . 5))))))))
 121     (should (eq (map-nested-elt alist '(b e f))
 122                 4)))
 123   (let ((ht (make-hash-table)))
 124     (setf (map-elt ht 'a) 1)
 125     (setf (map-elt ht 'b) (make-hash-table))
 126     (setf (map-elt (map-elt ht 'b) 'c) 2)
 127     (should (eq (map-nested-elt ht '(b c))
 128                 2))))
 129
 130 (ert-deftest test-map-nested-elt-default ()
 131   (let ((vec [a b [c d]]))
 132     (should (null (map-nested-elt vec '(2 3))))
 133     (should (null (map-nested-elt vec '(2 1 1))))
 134     (should (= 4 (map-nested-elt vec '(2 1 1) 4)))))
 135
 136 (ert-deftest test-mapp ()
 137   (should (mapp nil))
 138   (should (mapp '((a . b) (c . d))))
 139   (should (mapp '(a b c d)))
 140   (should (mapp []))
 141   (should (mapp [1 2 3]))
 142   (should (mapp (make-hash-table)))
 143   (should (mapp "hello"))
 144   (should (not (mapp 1)))
 145   (should (not (mapp 'hello))))
 146
 147 (ert-deftest test-map-keys ()
 148   (with-maps-do map
 149     (should (equal (map-keys map) '(0 1 2))))
 150   (should (null (map-keys nil)))
 151   (should (null (map-keys []))))
 152
 153 (ert-deftest test-map-values ()
 154   (with-maps-do map
 155     (should (equal (map-values map) '(3 4 5)))))
 156
 157 (ert-deftest test-map-pairs ()
 158   (with-maps-do map
 159     (should (equal (map-pairs map) '((0 . 3)
 160                                      (1 . 4)
 161                                      (2 . 5))))))
 162
 163 (ert-deftest test-map-length ()
 164   (let ((ht (make-hash-table)))
 165     (puthash 'a 1 ht)
 166     (puthash 'b 2 ht)
 167     (puthash 'c 3 ht)
 168     (puthash 'd 4 ht)
 169     (should (= 0 (map-length nil)))
 170     (should (= 0 (map-length [])))
 171     (should (= 0 (map-length (make-hash-table))))
 172     (should (= 5 (map-length [0 1 2 3 4])))
 173     (should (= 2 (map-length '((a . 1) (b . 2)))))
 174     (should (= 4 (map-length ht)))))
 175
 176 (ert-deftest test-map-copy ()
 177   (with-maps-do map
 178     (let ((copy (map-copy map)))
 179       (should (equal (map-keys map) (map-keys copy)))
 180       (should (equal (map-values map) (map-values copy)))
 181       (should (not (eq map copy))))))
 182
 183 (ert-deftest test-map-apply ()
 184   (with-maps-do map
 185     (should (equal (map-apply (lambda (k v) (cons (int-to-string k) v))
 186                               map)
 187                    '(("0" . 3) ("1" . 4) ("2" . 5)))))
 188   (let ((vec [a b c]))
 189     (should (equal (map-apply (lambda (k v) (cons (1+ k) v))
 190                               vec)
 191                    '((1 . a)
 192                      (2 . b)
 193                      (3 . c))))))
 194
 195 (ert-deftest test-map-do ()
 196   (with-maps-do map
 197     (let ((result nil))
 198       (map-do (lambda (k v)
 199                 (add-to-list 'result (list (int-to-string k) v)))
 200               map)
 201       (should (equal result '(("2" 5) ("1" 4) ("0" 3)))))))
 202
 203 (ert-deftest test-map-keys-apply ()
 204   (with-maps-do map
 205     (should (equal (map-keys-apply (lambda (k) (int-to-string k))
 206                                    map)
 207                    '("0" "1" "2"))))
 208   (let ((vec [a b c]))
 209     (should (equal (map-keys-apply (lambda (k) (1+ k))
 210                                    vec)
 211                    '(1 2 3)))))
 212
 213 (ert-deftest test-map-values-apply ()
 214   (with-maps-do map
 215     (should (equal (map-values-apply (lambda (v) (1+ v))
 216                                      map)
 217                    '(4 5 6))))
 218   (let ((vec [a b c]))
 219     (should (equal (map-values-apply (lambda (v) (symbol-name v))
 220                                      vec)
 221                    '("a" "b" "c")))))
 222
 223 (ert-deftest test-map-filter ()
 224   (with-maps-do map
 225     (should (equal (map-keys (map-filter (lambda (_k v)
 226                                            (<= 4 v))
 227                                          map))
 228                    '(1 2)))
 229     (should (null (map-filter (lambda (k _v)
 230                                 (eq 'd k))
 231                               map))))
 232   (should (null (map-filter (lambda (_k v)
 233                               (eq 3 v))
 234                             [1 2 4 5])))
 235   (should (equal (map-filter (lambda (k _v)
 236                                (eq 3 k))
 237                              [1 2 4 5])
 238                  '((3 . 5)))))
 239
 240 (ert-deftest test-map-remove ()
 241   (with-maps-do map
 242     (should (equal (map-keys (map-remove (lambda (_k v)
 243                                            (>= v 4))
 244                                          map))
 245                    '(0)))
 246     (should (equal (map-keys (map-remove (lambda (k _v)
 247                                            (eq 'd k))
 248                                          map))
 249                    (map-keys map))))
 250   (should (equal (map-remove (lambda (_k v)
 251                                (eq 3 v))
 252                              [1 2 4 5])
 253                  '((0 . 1)
 254                    (1 . 2)
 255                    (2 . 4)
 256                    (3 . 5))))
 257   (should (null (map-remove (lambda (k _v)
 258                               (>= k 0))
 259                             [1 2 4 5]))))
 260
 261 (ert-deftest test-map-empty-p ()
 262   (should (map-empty-p nil))
 263   (should (not (map-empty-p '((a . b) (c . d)))))
 264   (should (map-empty-p []))
 265   (should (not (map-empty-p [1 2 3])))
 266   (should (map-empty-p (make-hash-table)))
 267   (should (not (map-empty-p "hello")))
 268   (should (map-empty-p "")))
 269
 270 (ert-deftest test-map-contains-key ()
 271   (should (map-contains-key '((a . 1) (b . 2)) 'a))
 272   (should (not (map-contains-key '((a . 1) (b . 2)) 'c)))
 273   (should (map-contains-key '(("a" . 1)) "a"))
 274   (should (not (map-contains-key '(("a" . 1)) "a" #'eq)))
 275   (should (map-contains-key [a b c] 2))
 276   (should (not (map-contains-key [a b c] 3))))
 277
 278 (ert-deftest test-map-some ()
 279   (with-maps-do map
 280     (should (map-some (lambda (k _v)
 281                         (eq 1 k))
 282                       map))
 283     (should-not (map-some (lambda (k _v)
 284                             (eq 'd k))
 285                           map)))
 286   (let ((vec [a b c]))
 287     (should (map-some (lambda (k _v)
 288                         (> k 1))
 289                       vec))
 290     (should-not (map-some (lambda (k _v)
 291                             (> k 3))
 292                           vec))))
 293
 294 (ert-deftest test-map-every-p ()
 295   (with-maps-do map
 296     (should (map-every-p (lambda (k _v)
 297                            k)
 298                          map))
 299     (should (not (map-every-p (lambda (_k _v)
 300                                 nil)
 301                               map))))
 302   (let ((vec [a b c]))
 303     (should (map-every-p (lambda (k _v)
 304                            (>= k 0))
 305                          vec))
 306     (should (not (map-every-p (lambda (k _v)
 307                                 (> k 3))
 308                               vec)))))
 309
 310 (ert-deftest test-map-into ()
 311   (let* ((alist '((a . 1) (b . 2)))
 312          (ht (map-into alist 'hash-table)))
 313     (should (hash-table-p ht))
 314     (should (equal (map-into (map-into alist 'hash-table) 'list)
 315                    alist))
 316     (should (listp (map-into ht 'list)))
 317     (should (equal (map-keys (map-into (map-into ht 'list) 'hash-table))
 318                    (map-keys ht)))
 319     (should (equal (map-values (map-into (map-into ht 'list) 'hash-table))
 320                    (map-values ht)))
 321     (should (null (map-into nil 'list)))
 322     (should (map-empty-p (map-into nil 'hash-table)))
 323     (should-error (map-into [1 2 3] 'string))))
 324
 325 (ert-deftest test-map-let ()
 326   (map-let (foo bar baz) '((foo . 1) (bar . 2))
 327     (should (= foo 1))
 328     (should (= bar 2))
 329     (should (null baz)))
 330   (map-let (('foo a)
 331             ('bar b)
 332             ('baz c))
 333       '((foo . 1) (bar . 2))
 334     (should (= a 1))
 335     (should (= b 2))
 336     (should (null c))))
 337
 338 (ert-deftest test-map-merge-with ()
 339   (should (equal (map-merge-with 'list #'+
 340                                  '((1 . 2))
 341                                  '((1 . 3) (2 . 4))
 342                                  '((1 . 1) (2 . 5) (3 . 0)))
 343                  '((3 . 0) (2 . 9) (1 . 6)))))
 344
 345 (provide 'map-tests)
 346 ;;; map-tests.el ends here