code.delx.au - gnu-emacs/blob - lisp/erc/erc-backend.el

   1 ;;; erc-backend.el --- Backend network communication for ERC
   2
   3 ;; Copyright (C) 2004-2015 Free Software Foundation, Inc.
   4
   5 ;; Filename: erc-backend.el
   6 ;; Author: Lawrence Mitchell <wence@gmx.li>
   7 ;; Maintainer: emacs-devel@gnu.org
   8 ;; Created: 2004-05-7
   9 ;; Keywords: IRC chat client internet
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software: you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation, either version 3 of the License, or
  16 ;; (at your option) any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  25
  26 ;;; Commentary:
  27
  28 ;; This file defines backend network communication handlers for ERC.
  29 ;;
  30 ;; How things work:
  31 ;;
  32 ;; You define a new handler with `define-erc-response-handler'.  This
  33 ;; defines a function, a corresponding hook variable, and populates a
  34 ;; global hash table `erc-server-responses' with a map from response
  35 ;; to hook variable.  See the function documentation for more
  36 ;; information.
  37 ;;
  38 ;; Upon receiving a line from the server, `erc-parse-server-response'
  39 ;; is called on it.
  40 ;;
  41 ;; A line generally looks like:
  42 ;;
  43 ;; LINE := ':' SENDER ' ' COMMAND ' ' (COMMAND-ARGS ' ')* ':' CONTENTS
  44 ;; SENDER := Not ':' | ' '
  45 ;; COMMAND := Not ':' | ' '
  46 ;; COMMAND-ARGS := Not ':' | ' '
  47 ;;
  48 ;; This gets parsed and stuffed into an `erc-response' struct.  You
  49 ;; can access the fields of the struct with:
  50 ;;
  51 ;; COMMAND --- `erc-response.command'
  52 ;; COMMAND-ARGS --- `erc-response.command-args'
  53 ;; CONTENTS --- `erc-response.contents'
  54 ;; SENDER --- `erc-response.sender'
  55 ;; LINE --- `erc-response.unparsed'
  56 ;;
  57 ;; WARNING, WARNING!!
  58 ;; It's probably not a good idea to destructively modify the list
  59 ;; of command-args in your handlers, since other functions down the
  60 ;; line may well need to access the arguments too.
  61 ;;
  62 ;; That is, unless you're /absolutely/ sure that your handler doesn't
  63 ;; invoke some other function that needs to use COMMAND-ARGS, don't do
  64 ;; something like
  65 ;;
  66 ;; (while (erc-response.command-args parsed)
  67 ;;   (let ((a (pop (erc-response.command-args parsed))))
  68 ;;     ...))
  69 ;;
  70 ;; The parsed response is handed over to
  71 ;; `erc-handle-parsed-server-response', which checks whether it should
  72 ;; carry out duplicate suppression, and then runs `erc-call-hooks'.
  73 ;; `erc-call-hooks' retrieves the relevant hook variable from
  74 ;; `erc-server-responses' and runs it.
  75 ;;
  76 ;; Most handlers then destructure the parsed response in some way
  77 ;; (depending on what the handler is, the arguments have different
  78 ;; meanings), and generally display something, usually using
  79 ;; `erc-display-message'.
  80
  81 ;;; TODO:
  82
  83 ;; o Generalize the display-line code so that we can use it to
  84 ;;   display the stuff we send, as well as the stuff we receive.
  85 ;;   Then, move all display-related code into another backend-like
  86 ;;   file, erc-display.el, say.
  87 ;;
  88 ;; o Clean up the handlers using new display code (has to be written
  89 ;;   first).
  90
  91 ;;; History:
  92
  93 ;; 2004/05/10 -- Handler bodies taken out of erc.el and ported to new
  94 ;;               interface.
  95
  96 ;; 2005-08-13 -- Moved sending commands from erc.el.
  97
  98 ;;; Code:
  99
 100 (require 'erc-compat)
 101 (eval-when-compile (require 'cl-lib))
 102 ;; There's a fairly strong mutual dependency between erc.el and erc-backend.el.
 103 ;; Luckily, erc.el does not need erc-backend.el for macroexpansion whereas the
 104 ;; reverse is true:
 105 (provide 'erc-backend)
 106 (require 'erc)
 107
 108 ;;;; Variables and options
 109
 110 (defvar erc-server-responses (make-hash-table :test #'equal)
 111   "Hashtable mapping server responses to their handler hooks.")
 112
 113 (cl-defstruct (erc-response (:conc-name erc-response.))
 114   (unparsed "" :type string)
 115   (sender "" :type string)
 116   (command "" :type string)
 117   (command-args '() :type list)
 118   (contents "" :type string))
 119
 120 ;;; User data
 121
 122 (defvar erc-server-current-nick nil
 123   "Nickname on the current server.
 124 Use `erc-current-nick' to access this.")
 125 (make-variable-buffer-local 'erc-server-current-nick)
 126
 127 ;;; Server attributes
 128
 129 (defvar erc-server-process nil
 130   "The process object of the corresponding server connection.")
 131 (make-variable-buffer-local 'erc-server-process)
 132
 133 (defvar erc-session-server nil
 134   "The server name used to connect to for this session.")
 135 (make-variable-buffer-local 'erc-session-server)
 136
 137 (defvar erc-session-connector nil
 138   "The function used to connect to this session (nil for the default).")
 139 (make-variable-buffer-local 'erc-session-connector)
 140
 141 (defvar erc-session-port nil
 142   "The port used to connect to.")
 143 (make-variable-buffer-local 'erc-session-port)
 144
 145 (defvar erc-server-announced-name nil
 146   "The name the server announced to use.")
 147 (make-variable-buffer-local 'erc-server-announced-name)
 148
 149 (defvar erc-server-version nil
 150   "The name and version of the server's ircd.")
 151 (make-variable-buffer-local 'erc-server-version)
 152
 153 (defvar erc-server-parameters nil
 154   "Alist listing the supported server parameters.
 155
 156 This is only set if the server sends 005 messages saying what is
 157 supported on the server.
 158
 159 Entries are of the form:
 160   (PARAMETER . VALUE)
 161 or
 162   (PARAMETER) if no value is provided.
 163
 164 Some examples of possible parameters sent by servers:
 165 CHANMODES=b,k,l,imnpst - list of supported channel modes
 166 CHANNELLEN=50 - maximum length of channel names
 167 CHANTYPES=#&!+ - supported channel prefixes
 168 CHARMAPPING=rfc1459 - character mapping used for nickname and channels
 169 KICKLEN=160 - maximum allowed kick message length
 170 MAXBANS=30 - maximum number of bans per channel
 171 MAXCHANNELS=10 - maximum number of channels allowed to join
 172 NETWORK=EFnet -  the network identifier
 173 NICKLEN=9 - maximum allowed length of nicknames
 174 PREFIX=(ov)@+ - list of channel modes and the user prefixes if user has mode
 175 RFC2812 - server supports RFC 2812 features
 176 SILENCE=10 - supports the SILENCE command, maximum allowed number of entries
 177 TOPICLEN=160 - maximum allowed topic length
 178 WALLCHOPS - supports sending messages to all operators in a channel")
 179 (make-variable-buffer-local 'erc-server-parameters)
 180
 181 ;;; Server and connection state
 182
 183 (defvar erc-server-ping-timer-alist nil
 184   "Mapping of server buffers to their specific ping timer.")
 185
 186 (defvar erc-server-connected nil
 187   "Non-nil if the current buffer has been used by ERC to establish
 188 an IRC connection.
 189
 190 If you wish to determine whether an IRC connection is currently
 191 active, use the `erc-server-process-alive' function instead.")
 192 (make-variable-buffer-local 'erc-server-connected)
 193
 194 (defvar erc-server-reconnect-count 0
 195   "Number of times we have failed to reconnect to the current server.")
 196 (make-variable-buffer-local 'erc-server-reconnect-count)
 197
 198 (defvar erc-server-quitting nil
 199   "Non-nil if the user requests a quit.")
 200 (make-variable-buffer-local 'erc-server-quitting)
 201
 202 (defvar erc-server-reconnecting nil
 203   "Non-nil if the user requests an explicit reconnect, and the
 204 current IRC process is still alive.")
 205 (make-variable-buffer-local 'erc-server-reconnecting)
 206
 207 (defvar erc-server-timed-out nil
 208   "Non-nil if the IRC server failed to respond to a ping.")
 209 (make-variable-buffer-local 'erc-server-timed-out)
 210
 211 (defvar erc-server-banned nil
 212   "Non-nil if the user is denied access because of a server ban.")
 213 (make-variable-buffer-local 'erc-server-banned)
 214
 215 (defvar erc-server-error-occurred nil
 216   "Non-nil if the user triggers some server error.")
 217 (make-variable-buffer-local 'erc-server-error-occurred)
 218
 219 (defvar erc-server-lines-sent nil
 220   "Line counter.")
 221 (make-variable-buffer-local 'erc-server-lines-sent)
 222
 223 (defvar erc-server-last-peers '(nil . nil)
 224   "Last peers used, both sender and receiver.
 225 Those are used for /MSG destination shortcuts.")
 226 (make-variable-buffer-local 'erc-server-last-peers)
 227
 228 (defvar erc-server-last-sent-time nil
 229   "Time the message was sent.
 230 This is useful for flood protection.")
 231 (make-variable-buffer-local 'erc-server-last-sent-time)
 232
 233 (defvar erc-server-last-ping-time nil
 234   "Time the last ping was sent.
 235 This is useful for flood protection.")
 236 (make-variable-buffer-local 'erc-server-last-ping-time)
 237
 238 (defvar erc-server-last-received-time nil
 239   "Time the last message was received from the server.
 240 This is useful for detecting hung connections.")
 241 (make-variable-buffer-local 'erc-server-last-received-time)
 242
 243 (defvar erc-server-lag nil
 244   "Calculated server lag time in seconds.
 245 This variable is only set in a server buffer.")
 246 (make-variable-buffer-local 'erc-server-lag)
 247
 248 (defvar erc-server-filter-data nil
 249   "The data that arrived from the server
 250 but has not been processed yet.")
 251 (make-variable-buffer-local 'erc-server-filter-data)
 252
 253 (defvar erc-server-duplicates (make-hash-table :test 'equal)
 254   "Internal variable used to track duplicate messages.")
 255 (make-variable-buffer-local 'erc-server-duplicates)
 256
 257 ;; From Circe
 258 (defvar erc-server-processing-p nil
 259   "Non-nil when we're currently processing a message.
 260
 261 When ERC receives a private message, it sets up a new buffer for
 262 this query.  These in turn, though, do start flyspell. This
 263 involves starting an external process, in which case Emacs will
 264 wait - and when it waits, it does accept other stuff from, say,
 265 network exceptions.  So, if someone sends you two messages
 266 quickly after each other, ispell is started for the first, but
 267 might take long enough for the second message to be processed
 268 first.")
 269 (make-variable-buffer-local 'erc-server-processing-p)
 270
 271 (defvar erc-server-flood-last-message 0
 272   "When we sent the last message.
 273 See `erc-server-flood-margin' for an explanation of the flood
 274 protection algorithm.")
 275 (make-variable-buffer-local 'erc-server-flood-last-message)
 276
 277 (defvar erc-server-flood-queue nil
 278   "The queue of messages waiting to be sent to the server.
 279 See `erc-server-flood-margin' for an explanation of the flood
 280 protection algorithm.")
 281 (make-variable-buffer-local 'erc-server-flood-queue)
 282
 283 (defvar erc-server-flood-timer nil
 284   "The timer to resume sending.")
 285 (make-variable-buffer-local 'erc-server-flood-timer)
 286
 287 ;;; IRC protocol and misc options
 288
 289 (defgroup erc-server nil
 290   "Parameters for dealing with IRC servers."
 291   :group 'erc)
 292
 293 (defcustom erc-server-auto-reconnect t
 294   "Non-nil means that ERC will attempt to reestablish broken connections.
 295
 296 Reconnection will happen automatically for any unexpected disconnection."
 297   :group 'erc-server
 298   :type 'boolean)
 299
 300 (defcustom erc-server-reconnect-attempts 2
 301   "The number of times that ERC will attempt to reestablish a
 302 broken connection, or t to always attempt to reconnect.
 303
 304 This only has an effect if `erc-server-auto-reconnect' is non-nil."
 305   :group 'erc-server
 306   :type '(choice (const :tag "Always reconnect" t)
 307                  integer))
 308
 309 (defcustom erc-server-reconnect-timeout 1
 310   "The amount of time, in seconds, that ERC will wait between
 311 successive reconnect attempts.
 312
 313 If a key is pressed while ERC is waiting, it will stop waiting."
 314   :group 'erc-server
 315   :type 'number)
 316
 317 (defcustom erc-split-line-length 440
 318   "The maximum length of a single message.
 319 If a message exceeds this size, it is broken into multiple ones.
 320
 321 IRC allows for lines up to 512 bytes. Two of them are CR LF.
 322 And a typical message looks like this:
 323
 324   :nicky!uhuser@host212223.dialin.fnordisp.net PRIVMSG #lazybastards :Hello!
 325
 326 You can limit here the maximum length of the \"Hello!\" part.
 327 Good luck."
 328   :type 'integer
 329   :group 'erc-server)
 330
 331 (defcustom erc-coding-system-precedence '(utf-8 undecided)
 332   "List of coding systems to be preferred when receiving a string from the server.
 333 This will only be consulted if the coding system in
 334 `erc-server-coding-system' is `undecided'."
 335   :group 'erc-server
 336   :version "24.1"
 337   :type '(repeat coding-system))
 338
 339 (defcustom erc-server-coding-system (if (and (fboundp 'coding-system-p)
 340                                              (coding-system-p 'undecided)
 341                                              (coding-system-p 'utf-8))
 342                                         '(utf-8 . undecided)
 343                                       nil)
 344   "The default coding system for incoming and outgoing text.
 345 This is either a coding system, a cons, a function, or nil.
 346
 347 If a cons, the encoding system for outgoing text is in the car
 348 and the decoding system for incoming text is in the cdr. The most
 349 interesting use for this is to put `undecided' in the cdr. This
 350 means that `erc-coding-system-precedence' will be consulted, and the
 351 first match there will be used.
 352
 353 If a function, it is called with the argument `target' and should
 354 return a coding system or a cons as described above.
 355
 356 If you need to send non-ASCII text to people not using a client that
 357 does decoding on its own, you must tell ERC what encoding to use.
 358 Emacs cannot guess it, since it does not know what the people on the
 359 other end of the line are using."
 360   :group 'erc-server
 361   :type '(choice (const :tag "None" nil)
 362                  coding-system
 363                  (cons (coding-system :tag "encoding" :value utf-8)
 364                        (coding-system :tag "decoding" :value undecided))
 365                  function))
 366
 367 (defcustom erc-encoding-coding-alist nil
 368   "Alist of target regexp and coding-system pairs to use.
 369 This overrides `erc-server-coding-system' depending on the
 370 current target as returned by `erc-default-target'.
 371
 372 Example: If you know that the channel #linux-ru uses the coding-system
 373 `cyrillic-koi8', then add (\"#linux-ru\" . cyrillic-koi8) to the
 374 alist."
 375   :group 'erc-server
 376   :type '(repeat (cons (string :tag "Target")
 377                        coding-system)))
 378
 379 (defcustom erc-server-connect-function 'erc-open-network-stream
 380   "Function used to initiate a connection.
 381 It should take same arguments as `open-network-stream' does."
 382   :group 'erc-server
 383   :type 'function)
 384
 385 (defcustom erc-server-prevent-duplicates '("301")
 386   "Either nil or a list of strings.
 387 Each string is a IRC message type, like PRIVMSG or NOTICE.
 388 All Message types in that list of subjected to duplicate prevention."
 389   :type '(choice (const nil) (list string))
 390   :group 'erc-server)
 391
 392 (defcustom erc-server-duplicate-timeout 60
 393   "The time allowed in seconds between duplicate messages.
 394
 395 If two identical messages arrive within this value of one another, the second
 396 isn't displayed."
 397   :type 'integer
 398   :group 'erc-server)
 399
 400 (defcustom erc-server-timestamp-format "%Y-%m-%d %T"
 401   "Timestamp format used with server response messages.
 402 This string is processed using `format-time-string'."
 403   :version "24.3"
 404   :type 'string
 405   :group 'erc-server)
 406
 407 ;;; Flood-related
 408
 409 ;; Most of this is courtesy of Jorgen Schaefer and Circe
 410 ;; (http://www.nongnu.org/circe)
 411
 412 (defcustom erc-server-flood-margin 10
 413   "A margin on how much excess data we send.
 414 The flood protection algorithm of ERC works like the one
 415 detailed in RFC 2813, section 5.8 \"Flood control of clients\".
 416
 417   * If `erc-server-flood-last-message' is less than the current
 418     time, set it equal.
 419   * While `erc-server-flood-last-message' is less than
 420     `erc-server-flood-margin' seconds ahead of the current
 421     time, send a message, and increase
 422     `erc-server-flood-last-message' by
 423     `erc-server-flood-penalty' for each message."
 424   :type 'integer
 425   :group 'erc-server)
 426
 427 (defcustom erc-server-flood-penalty 3
 428   "How much we penalize a message.
 429 See `erc-server-flood-margin' for an explanation of the flood
 430 protection algorithm."
 431   :type 'integer
 432   :group 'erc-server)
 433
 434 ;; Ping handling
 435
 436 (defcustom erc-server-send-ping-interval 30
 437   "Interval of sending pings to the server, in seconds.
 438 If this is set to nil, pinging the server is disabled."
 439   :group 'erc-server
 440   :type '(choice (const :tag "Disabled" nil)
 441                  (integer :tag "Seconds")))
 442
 443 (defcustom erc-server-send-ping-timeout 120
 444   "If the time between ping and response is greater than this, reconnect.
 445 The time is in seconds.
 446
 447 This must be greater than or equal to the value for
 448 `erc-server-send-ping-interval'.
 449
 450 If this is set to nil, never try to reconnect."
 451   :group 'erc-server
 452   :type '(choice (const :tag "Disabled" nil)
 453                  (integer :tag "Seconds")))
 454
 455 (defvar erc-server-ping-handler nil
 456   "This variable holds the periodic ping timer.")
 457 (make-variable-buffer-local 'erc-server-ping-handler)
 458
 459 ;;;; Helper functions
 460
 461 ;; From Circe
 462 (defun erc-split-line (longline)
 463   "Return a list of lines which are not too long for IRC.
 464 The length is specified in `erc-split-line-length'.
 465
 466 Currently this is called by `erc-send-input'."
 467   (if (< (length longline)
 468          erc-split-line-length)
 469       (list longline)
 470     (with-temp-buffer
 471       (insert longline)
 472       (let ((fill-column erc-split-line-length))
 473         (fill-region (point-min) (point-max)
 474                      nil t))
 475       (split-string (buffer-string) "\n"))))
 476
 477 ;; Used by CTCP functions
 478 (defun erc-upcase-first-word (str)
 479   "Upcase the first word in STR."
 480   (with-temp-buffer
 481     (insert str)
 482     (goto-char (point-min))
 483     (upcase-word 1)
 484     (buffer-string)))
 485
 486 (defun erc-server-setup-periodical-ping (buffer)
 487   "Set up a timer to periodically ping the current server.
 488 The current buffer is given by BUFFER."
 489   (with-current-buffer buffer
 490     (and erc-server-ping-handler (erc-cancel-timer erc-server-ping-handler))
 491     (when erc-server-send-ping-interval
 492       (setq erc-server-ping-handler (run-with-timer
 493                                      4 erc-server-send-ping-interval
 494                                      #'erc-server-send-ping
 495                                      buffer))
 496
 497       ;; I check the timer alist for an existing timer. If one exists,
 498       ;; I get rid of it
 499       (let ((timer-tuple (assq buffer erc-server-ping-timer-alist)))
 500         (if timer-tuple
 501             ;; this buffer already has a timer. Cancel it and set the new one
 502             (progn
 503               (erc-cancel-timer (cdr timer-tuple))
 504               (setf (cdr (assq buffer erc-server-ping-timer-alist)) erc-server-ping-handler))
 505
 506           ;; no existing timer for this buffer. Add new one
 507           (add-to-list 'erc-server-ping-timer-alist
 508                        (cons buffer erc-server-ping-handler)))))))
 509
 510 (defun erc-server-process-alive (&optional buffer)
 511   "Return non-nil when BUFFER has an `erc-server-process' open or running."
 512   (with-current-buffer (or buffer (current-buffer))
 513     (and erc-server-process
 514          (processp erc-server-process)
 515          (memq (process-status erc-server-process) '(run open)))))
 516
 517 ;;;; Connecting to a server
 518 (defun erc-open-network-stream (name buffer host service)
 519   "As `open-network-stream', but does non-blocking IO"
 520   (make-network-process :name name :buffer  buffer
 521                         :host host :service service :nowait t))
 522
 523 (defun erc-server-connect (server port buffer)
 524   "Perform the connection and login using the specified SERVER and PORT.
 525 We will store server variables in the buffer given by BUFFER."
 526   (let ((msg (erc-format-message 'connect ?S server ?p port)))
 527     (message "%s" msg)
 528     (let ((process (funcall erc-server-connect-function
 529                             (format "erc-%s-%s" server port)
 530                             nil server port)))
 531       (unless (processp process)
 532         (error "Connection attempt failed"))
 533       (message "%s...done" msg)
 534       ;; Misc server variables
 535       (with-current-buffer buffer
 536         (setq erc-server-process process)
 537         (setq erc-server-quitting nil)
 538         (setq erc-server-reconnecting nil)
 539         (setq erc-server-timed-out nil)
 540         (setq erc-server-banned nil)
 541         (setq erc-server-error-occurred nil)
 542         (let ((time (erc-current-time)))
 543           (setq erc-server-last-sent-time time)
 544           (setq erc-server-last-ping-time time)
 545           (setq erc-server-last-received-time time))
 546         (setq erc-server-lines-sent 0)
 547         ;; last peers (sender and receiver)
 548         (setq erc-server-last-peers '(nil . nil)))
 549       ;; we do our own encoding and decoding
 550       (when (fboundp 'set-process-coding-system)
 551         (set-process-coding-system process 'raw-text))
 552       ;; process handlers
 553       (set-process-sentinel process 'erc-process-sentinel)
 554       (set-process-filter process 'erc-server-filter-function)
 555       (set-process-buffer process buffer)))
 556   (erc-log "\n\n\n********************************************\n")
 557   (message "%s" (erc-format-message
 558             'login ?n
 559             (with-current-buffer buffer (erc-current-nick))))
 560   ;; wait with script loading until we receive a confirmation (first
 561   ;; MOTD line)
 562   (if (eq erc-server-connect-function 'open-network-stream-nowait)
 563       ;; it's a bit unclear otherwise that it's attempting to establish a
 564       ;; connection
 565       (erc-display-message nil nil buffer "Opening connection..\n")
 566     (erc-login)))
 567
 568 (defun erc-server-reconnect ()
 569 "Reestablish the current IRC connection.
 570 Make sure you are in an ERC buffer when running this."
 571   (let ((buffer (erc-server-buffer)))
 572     (unless (buffer-live-p buffer)
 573       (if (eq major-mode 'erc-mode)
 574           (setq buffer (current-buffer))
 575         (error "Reconnect must be run from an ERC buffer")))
 576     (with-current-buffer buffer
 577       (erc-update-mode-line)
 578       (erc-set-active-buffer (current-buffer))
 579       (setq erc-server-last-sent-time 0)
 580       (setq erc-server-lines-sent 0)
 581       (let ((erc-server-connect-function (or erc-session-connector
 582                                              'erc-open-network-stream)))
 583         (erc-open erc-session-server erc-session-port erc-server-current-nick
 584                   erc-session-user-full-name t erc-session-password)))))
 585
 586 (defun erc-server-delayed-reconnect (event buffer)
 587   (if (buffer-live-p buffer)
 588     (with-current-buffer buffer
 589       (erc-server-reconnect))))
 590
 591 (defun erc-server-filter-function (process string)
 592   "The process filter for the ERC server."
 593   (with-current-buffer (process-buffer process)
 594     (setq erc-server-last-received-time (erc-current-time))
 595     ;; If you think this is written in a weird way - please refer to the
 596     ;; docstring of `erc-server-processing-p'
 597     (if erc-server-processing-p
 598         (setq erc-server-filter-data
 599               (if erc-server-filter-data
 600                   (concat erc-server-filter-data string)
 601                 string))
 602       ;; This will be true even if another process is spawned!
 603       (let ((erc-server-processing-p t))
 604         (setq erc-server-filter-data (if erc-server-filter-data
 605                                            (concat erc-server-filter-data
 606                                                    string)
 607                                          string))
 608         (while (and erc-server-filter-data
 609                     (string-match "[\n\r]+" erc-server-filter-data))
 610           (let ((line (substring erc-server-filter-data
 611                                  0 (match-beginning 0))))
 612             (setq erc-server-filter-data
 613                   (if (= (match-end 0)
 614                          (length erc-server-filter-data))
 615                       nil
 616                     (substring erc-server-filter-data
 617                                (match-end 0))))
 618             (erc-log-irc-protocol line nil)
 619             (erc-parse-server-response process line)))))))
 620
 621 (defsubst erc-server-reconnect-p (event)
 622   "Return non-nil if ERC should attempt to reconnect automatically.
 623 EVENT is the message received from the closed connection process."
 624   (or erc-server-reconnecting
 625       (and erc-server-auto-reconnect
 626            (not erc-server-banned)
 627            (not erc-server-error-occurred)
 628            ;; make sure we don't infinitely try to reconnect, unless the
 629            ;; user wants that
 630            (or (eq erc-server-reconnect-attempts t)
 631                (and (integerp erc-server-reconnect-attempts)
 632                     (< erc-server-reconnect-count
 633                        erc-server-reconnect-attempts)))
 634            (or erc-server-timed-out
 635                (not (string-match "^deleted" event)))
 636            ;; open-network-stream-nowait error for connection refused
 637            (if (string-match "^failed with code 111" event) 'nonblocking t))))
 638
 639 (defun erc-process-sentinel-2 (event buffer)
 640   "Called when `erc-process-sentinel-1' has detected an unexpected disconnect."
 641   (if (not (buffer-live-p buffer))
 642       (erc-update-mode-line)
 643     (with-current-buffer buffer
 644       (let ((reconnect-p (erc-server-reconnect-p event)) message delay)
 645         (setq message (if reconnect-p 'disconnected 'disconnected-noreconnect))
 646         (erc-display-message nil 'error (current-buffer) message)
 647         (if (not reconnect-p)
 648             ;; terminate, do not reconnect
 649             (progn
 650               (erc-display-message nil 'error (current-buffer)
 651                                    'terminated ?e event)
 652               ;; Update mode line indicators
 653               (erc-update-mode-line)
 654               (set-buffer-modified-p nil))
 655           ;; reconnect
 656           (condition-case err
 657               (progn
 658                 (setq erc-server-reconnecting   nil
 659                       erc-server-reconnect-count (1+ erc-server-reconnect-count))
 660                 (setq delay erc-server-reconnect-timeout)
 661                 (run-at-time delay nil
 662                              #'erc-server-delayed-reconnect event buffer))
 663             (error (unless (integerp erc-server-reconnect-attempts)
 664                      (message "%s ... %s"
 665                               "Reconnecting until we succeed"
 666                               "kill the ERC server buffer to stop"))
 667                    (erc-server-delayed-reconnect event buffer))))))))
 668
 669 (defun erc-process-sentinel-1 (event buffer)
 670   "Called when `erc-process-sentinel' has decided that we're disconnecting.
 671 Determine whether user has quit or whether erc has been terminated.
 672 Conditionally try to reconnect and take appropriate action."
 673   (with-current-buffer buffer
 674     (if erc-server-quitting
 675         ;; normal quit
 676         (progn
 677           (erc-display-message nil 'error (current-buffer) 'finished)
 678           ;; Update mode line indicators
 679           (erc-update-mode-line)
 680           ;; Kill server buffer if user wants it
 681           (set-buffer-modified-p nil)
 682           (when erc-kill-server-buffer-on-quit
 683             (kill-buffer (current-buffer))))
 684       ;; unexpected disconnect
 685       (erc-process-sentinel-2 event buffer))))
 686
 687 (defun erc-process-sentinel (cproc event)
 688   "Sentinel function for ERC process."
 689   (let ((buf (process-buffer cproc)))
 690     (when (buffer-live-p buf)
 691       (with-current-buffer buf
 692         (erc-log (format
 693                   "SENTINEL: proc: %S    status: %S  event: %S (quitting: %S)"
 694                   cproc (process-status cproc) event erc-server-quitting))
 695         (if (string-match "^open" event)
 696             ;; newly opened connection (no wait)
 697             (erc-login)
 698           ;; assume event is 'failed
 699           (erc-with-all-buffers-of-server cproc nil
 700                                           (setq erc-server-connected nil))
 701           (when erc-server-ping-handler
 702             (progn (erc-cancel-timer erc-server-ping-handler)
 703                    (setq erc-server-ping-handler nil)))
 704           (run-hook-with-args 'erc-disconnected-hook
 705                               (erc-current-nick) (system-name) "")
 706           ;; Remove the prompt
 707           (goto-char (or (marker-position erc-input-marker) (point-max)))
 708           (forward-line 0)
 709           (erc-remove-text-properties-region (point) (point-max))
 710           (delete-region (point) (point-max))
 711           ;; Decide what to do with the buffer
 712           ;; Restart if disconnected
 713           (erc-process-sentinel-1 event buf))))))
 714
 715 ;;;; Sending messages
 716
 717 (defun erc-coding-system-for-target (target)
 718   "Return the coding system or cons cell appropriate for TARGET.
 719 This is determined via `erc-encoding-coding-alist' or
 720 `erc-server-coding-system'."
 721   (unless target (setq target (erc-default-target)))
 722   (or (when target
 723         (let ((case-fold-search t))
 724           (catch 'match
 725             (dolist (pat erc-encoding-coding-alist)
 726               (when (string-match (car pat) target)
 727                 (throw 'match (cdr pat)))))))
 728       (and (functionp erc-server-coding-system)
 729            (funcall erc-server-coding-system target))
 730       erc-server-coding-system))
 731
 732 (defun erc-decode-string-from-target (str target)
 733   "Decode STR as appropriate for TARGET.
 734 This is indicated by `erc-encoding-coding-alist', defaulting to the value of
 735 `erc-server-coding-system'."
 736   (unless (stringp str)
 737     (setq str ""))
 738   (let ((coding (erc-coding-system-for-target target)))
 739     (when (consp coding)
 740       (setq coding (cdr coding)))
 741     (when (eq coding 'undecided)
 742       (let ((codings (detect-coding-string str))
 743             (precedence erc-coding-system-precedence))
 744         (while (and precedence
 745                     (not (memq (car precedence) codings)))
 746           (pop precedence))
 747         (when precedence
 748           (setq coding (car precedence)))))
 749     (erc-decode-coding-string str coding)))
 750
 751 ;; proposed name, not used by anything yet
 752 (defun erc-send-line (text display-fn)
 753   "Send TEXT to the current server.  Wrapping and flood control apply.
 754 Use DISPLAY-FN to show the results."
 755   (mapc (lambda (line)
 756           (erc-server-send line)
 757           (funcall display-fn))
 758         (erc-split-line text)))
 759
 760 ;; From Circe, with modifications
 761 (defun erc-server-send (string &optional forcep target)
 762   "Send STRING to the current server.
 763 If FORCEP is non-nil, no flood protection is done - the string is
 764 sent directly. This might cause the messages to arrive in a wrong
 765 order.
 766
 767 If TARGET is specified, look up encoding information for that
 768 channel in `erc-encoding-coding-alist' or
 769 `erc-server-coding-system'.
 770
 771 See `erc-server-flood-margin' for an explanation of the flood
 772 protection algorithm."
 773   (erc-log (concat "erc-server-send: " string "(" (buffer-name) ")"))
 774   (setq erc-server-last-sent-time (erc-current-time))
 775   (let ((encoding (erc-coding-system-for-target target)))
 776     (when (consp encoding)
 777       (setq encoding (car encoding)))
 778     (if (erc-server-process-alive)
 779         (erc-with-server-buffer
 780           (let ((str (concat string "\r\n")))
 781             (if forcep
 782                 (progn
 783                   (setq erc-server-flood-last-message
 784                         (+ erc-server-flood-penalty
 785                            erc-server-flood-last-message))
 786                   (erc-log-irc-protocol str 'outbound)
 787                   (condition-case err
 788                       (progn
 789                         ;; Set encoding just before sending the string
 790                         (when (fboundp 'set-process-coding-system)
 791                           (set-process-coding-system erc-server-process
 792                                                      'raw-text encoding))
 793                         (process-send-string erc-server-process str))
 794                     ;; See `erc-server-send-queue' for full
 795                     ;; explanation of why we need this condition-case
 796                     (error nil)))
 797               (setq erc-server-flood-queue
 798                     (append erc-server-flood-queue
 799                             (list (cons str encoding))))
 800               (erc-server-send-queue (current-buffer))))
 801           t)
 802       (message "ERC: No process running")
 803       nil)))
 804
 805 (defun erc-server-send-ping (buf)
 806   "Send a ping to the IRC server buffer in BUF.
 807 Additionally, detect whether the IRC process has hung."
 808   (if (buffer-live-p buf)
 809       (with-current-buffer buf
 810         (if (and erc-server-send-ping-timeout
 811                  (>
 812                   (erc-time-diff (erc-current-time)
 813                                  erc-server-last-received-time)
 814                   erc-server-send-ping-timeout))
 815             (progn
 816               ;; if the process is hung, kill it
 817               (setq erc-server-timed-out t)
 818               (delete-process erc-server-process))
 819           (erc-server-send (format "PING %.0f" (erc-current-time)))))
 820     ;; remove timer if the server buffer has been killed
 821     (let ((timer (assq buf erc-server-ping-timer-alist)))
 822       (when timer
 823         (erc-cancel-timer (cdr timer))
 824         (setcdr timer nil)))))
 825
 826 ;; From Circe
 827 (defun erc-server-send-queue (buffer)
 828   "Send messages in `erc-server-flood-queue'.
 829 See `erc-server-flood-margin' for an explanation of the flood
 830 protection algorithm."
 831   (with-current-buffer buffer
 832     (let ((now (erc-current-time)))
 833       (when erc-server-flood-timer
 834         (erc-cancel-timer erc-server-flood-timer)
 835         (setq erc-server-flood-timer nil))
 836       (when (< erc-server-flood-last-message
 837                now)
 838         (setq erc-server-flood-last-message now))
 839       (while (and erc-server-flood-queue
 840                   (< erc-server-flood-last-message
 841                      (+ now erc-server-flood-margin)))
 842         (let ((msg (caar erc-server-flood-queue))
 843               (encoding (cdar erc-server-flood-queue)))
 844           (setq erc-server-flood-queue (cdr erc-server-flood-queue)
 845                 erc-server-flood-last-message
 846                 (+ erc-server-flood-last-message
 847                    erc-server-flood-penalty))
 848           (erc-log-irc-protocol msg 'outbound)
 849           (erc-log (concat "erc-server-send-queue: "
 850                            msg "(" (buffer-name buffer) ")"))
 851           (when (erc-server-process-alive)
 852             (condition-case err
 853                 ;; Set encoding just before sending the string
 854                 (progn
 855                   (when (fboundp 'set-process-coding-system)
 856                     (set-process-coding-system erc-server-process
 857                                                'raw-text encoding))
 858                   (process-send-string erc-server-process msg))
 859               ;; Sometimes the send can occur while the process is
 860               ;; being killed, which results in a weird SIGPIPE error.
 861               ;; Catch this and ignore it.
 862               (error nil)))))
 863       (when erc-server-flood-queue
 864         (setq erc-server-flood-timer
 865               (run-at-time (+ 0.2 erc-server-flood-penalty)
 866                            nil #'erc-server-send-queue buffer))))))
 867
 868 (defun erc-message (message-command line &optional force)
 869   "Send LINE to the server as a privmsg or a notice.
 870 MESSAGE-COMMAND should be either \"PRIVMSG\" or \"NOTICE\".
 871 If the target is \",\", the last person you've got a message from will
 872 be used. If the target is \".\", the last person you've sent a message
 873 to will be used."
 874   (cond
 875    ((string-match "^\\s-*\\(\\S-+\\) ?\\(.*\\)" line)
 876     (let ((tgt (match-string 1 line))
 877           (s (match-string 2 line)))
 878       (erc-log (format "cmd: MSG(%s): [%s] %s" message-command tgt s))
 879       (cond
 880        ((string= tgt ",")
 881         (if (car erc-server-last-peers)
 882             (setq tgt (car erc-server-last-peers))
 883           (setq tgt nil)))
 884        ((string= tgt ".")
 885         (if (cdr erc-server-last-peers)
 886             (setq tgt (cdr erc-server-last-peers))
 887           (setq tgt nil))))
 888       (cond
 889        (tgt
 890         (setcdr erc-server-last-peers tgt)
 891         (erc-server-send (format "%s %s :%s" message-command tgt s)
 892                          force))
 893        (t
 894         (erc-display-message nil 'error (current-buffer) 'no-target))))
 895     t)
 896    (t nil)))
 897
 898 ;;; CTCP
 899
 900 (defun erc-send-ctcp-message (tgt l &optional force)
 901   "Send CTCP message L to TGT.
 902
 903 If TGT is nil the message is not sent.
 904 The command must contain neither a prefix nor a trailing `\\n'.
 905
 906 See also `erc-server-send'."
 907   (let ((l (erc-upcase-first-word l)))
 908     (cond
 909      (tgt
 910       (erc-log (format "erc-send-CTCP-message: [%s] %s" tgt l))
 911       (erc-server-send (format "PRIVMSG %s :\C-a%s\C-a" tgt l)
 912                        force)))))
 913
 914 (defun erc-send-ctcp-notice (tgt l &optional force)
 915   "Send CTCP notice L to TGT.
 916
 917 If TGT is nil the message is not sent.
 918 The command must contain neither a prefix nor a trailing `\\n'.
 919
 920 See also `erc-server-send'."
 921   (let ((l (erc-upcase-first-word l)))
 922     (cond
 923      (tgt
 924       (erc-log (format "erc-send-CTCP-notice: [%s] %s" tgt l))
 925       (erc-server-send (format "NOTICE %s :\C-a%s\C-a" tgt l)
 926                        force)))))
 927
 928 ;;;; Handling responses
 929
 930 (defun erc-parse-server-response (proc string)
 931   "Parse and act upon a complete line from an IRC server.
 932 PROC is the process (connection) from which STRING was received.
 933 PROCs `process-buffer' is `current-buffer' when this function is called."
 934   (unless (string= string "") ;; Ignore empty strings
 935     (save-match-data
 936       (let ((posn (if (eq (aref string 0) ?:)
 937                       (string-match " " string)
 938                     0))
 939             (msg (make-erc-response :unparsed string)))
 940
 941         (setf (erc-response.sender msg)
 942               (if (eq posn 0)
 943                   erc-session-server
 944                 (substring string 1 posn)))
 945
 946         (setf (erc-response.command msg)
 947               (let* ((bposn (string-match "[^ \n]" string posn))
 948                      (eposn (string-match " " string bposn)))
 949                 (setq posn (and eposn
 950                                 (string-match "[^ \n]" string eposn)))
 951                 (substring string bposn eposn)))
 952
 953         (while (and posn
 954                     (not (eq (aref string posn) ?:)))
 955           (push (let* ((bposn posn)
 956                        (eposn (string-match " " string bposn)))
 957                   (setq posn (and eposn
 958                                   (string-match "[^ \n]" string eposn)))
 959                   (substring string bposn eposn))
 960                 (erc-response.command-args msg)))
 961         (when posn
 962       (let ((str (substring string (1+ posn))))
 963         (push str (erc-response.command-args msg))))
 964
 965     (setf (erc-response.contents msg)
 966           (car (erc-response.command-args msg)))
 967
 968     (setf (erc-response.command-args msg)
 969           (nreverse (erc-response.command-args msg)))
 970
 971     (erc-decode-parsed-server-response msg)
 972
 973     (erc-handle-parsed-server-response proc msg)))))
 974
 975 (defun erc-decode-parsed-server-response (parsed-response)
 976   "Decode a pre-parsed PARSED-RESPONSE before it can be handled.
 977
 978 If there is a channel name in `erc-response.command-args', decode
 979 `erc-response' according to this channel name and
 980 `erc-encoding-coding-alist', or use `erc-server-coding-system'
 981 for decoding."
 982   (let ((args (erc-response.command-args parsed-response))
 983         (decode-target nil)
 984         (decoded-args ()))
 985     (dolist (arg args nil)
 986       (when (string-match "^[#&].*" arg)
 987         (setq decode-target arg)))
 988     (when (stringp decode-target)
 989       (setq decode-target (erc-decode-string-from-target decode-target nil)))
 990     (setf (erc-response.unparsed parsed-response)
 991           (erc-decode-string-from-target
 992            (erc-response.unparsed parsed-response)
 993            decode-target))
 994     (setf (erc-response.sender parsed-response)
 995           (erc-decode-string-from-target
 996            (erc-response.sender parsed-response)
 997            decode-target))
 998     (setf (erc-response.command parsed-response)
 999           (erc-decode-string-from-target
1000            (erc-response.command parsed-response)
1001            decode-target))
1002     (dolist (arg (nreverse args) nil)
1003       (push (erc-decode-string-from-target arg decode-target)
1004             decoded-args))
1005     (setf (erc-response.command-args parsed-response) decoded-args)
1006     (setf (erc-response.contents parsed-response)
1007           (erc-decode-string-from-target
1008            (erc-response.contents parsed-response)
1009            decode-target))))
1010
1011 (defun erc-handle-parsed-server-response (process parsed-response)
1012   "Handle a pre-parsed PARSED-RESPONSE from PROCESS.
1013
1014 Hands off to helper functions via `erc-call-hooks'."
1015   (if (member (erc-response.command parsed-response)
1016               erc-server-prevent-duplicates)
1017       (let ((m (erc-response.unparsed parsed-response)))
1018         ;; duplicate suppression
1019         (if (< (or (gethash m erc-server-duplicates) 0)
1020                (- (erc-current-time) erc-server-duplicate-timeout))
1021             (erc-call-hooks process parsed-response))
1022         (puthash m (erc-current-time) erc-server-duplicates))
1023     ;; Hand off to the relevant handler.
1024     (erc-call-hooks process parsed-response)))
1025
1026 (defun erc-get-hook (command)
1027   "Return the hook variable associated with COMMAND.
1028
1029 See also `erc-server-responses'."
1030   (gethash (format (if (numberp command) "%03i" "%s") command)
1031            erc-server-responses))
1032
1033 (defun erc-call-hooks (process message)
1034   "Call hooks associated with MESSAGE in PROCESS.
1035
1036 Finds hooks by looking in the `erc-server-responses' hashtable."
1037   (let ((hook (or (erc-get-hook (erc-response.command message))
1038                   'erc-default-server-functions)))
1039     (run-hook-with-args-until-success hook process message)
1040     (erc-with-server-buffer
1041       (run-hook-with-args 'erc-timer-hook (erc-current-time)))))
1042
1043 (add-hook 'erc-default-server-functions 'erc-handle-unknown-server-response)
1044
1045 (defun erc-handle-unknown-server-response (proc parsed)
1046   "Display unknown server response's message."
1047   (let ((line (concat (erc-response.sender parsed)
1048                       " "
1049                       (erc-response.command parsed)
1050                       " "
1051                       (mapconcat 'identity (erc-response.command-args parsed)
1052                                  " "))))
1053     (erc-display-message parsed 'notice proc line)))
1054
1055
1056 (put 'define-erc-response-handler 'edebug-form-spec
1057      '(&define :name erc-response-handler
1058                (name &rest name)
1059                &optional sexp sexp def-body))
1060
1061 (cl-defmacro define-erc-response-handler ((name &rest aliases)
1062                                         &optional extra-fn-doc extra-var-doc
1063                                         &rest fn-body)
1064   "Define an ERC handler hook/function pair.
1065 NAME is the response name as sent by the server (see the IRC RFC for
1066 meanings).
1067
1068 This creates:
1069  - a hook variable `erc-server-NAME-functions' initialized to `erc-server-NAME'.
1070  - a function `erc-server-NAME' with body FN-BODY.
1071
1072 If ALIASES is non-nil, each alias in ALIASES is `defalias'ed to
1073 `erc-server-NAME'.
1074 Alias hook variables are created as `erc-server-ALIAS-functions' and
1075 initialized to the same default value as `erc-server-NAME-functions'.
1076
1077 FN-BODY is the body of `erc-server-NAME' it may refer to the two
1078 function arguments PROC and PARSED.
1079
1080 If EXTRA-FN-DOC is non-nil, it is inserted at the beginning of the
1081 defined function's docstring.
1082
1083 If EXTRA-VAR-DOC is non-nil, it is inserted at the beginning of the
1084 defined variable's docstring.
1085
1086 As an example:
1087
1088   (define-erc-response-handler (311 WHOIS WI)
1089     \"Some non-generic function documentation.\"
1090     \"Some non-generic variable documentation.\"
1091     (do-stuff-with-whois proc parsed))
1092
1093 Would expand to:
1094
1095   (prog2
1096       (defvar erc-server-311-functions \\='erc-server-311
1097         \"Some non-generic variable documentation.
1098
1099   Hook called upon receiving a 311 server response.
1100   Each function is called with two arguments, the process associated
1101   with the response and the parsed response.
1102   See also `erc-server-311'.\")
1103
1104       (defun erc-server-311 (proc parsed)
1105         \"Some non-generic function documentation.
1106
1107   Handler for a 311 server response.
1108   PROC is the server process which returned the response.
1109   PARSED is the actual response as an `erc-response' struct.
1110   If you want to add responses don't modify this function, but rather
1111   add things to `erc-server-311-functions' instead.\"
1112         (do-stuff-with-whois proc parsed))
1113
1114     (puthash \"311\" \\='erc-server-311-functions erc-server-responses)
1115     (puthash \"WHOIS\" \\='erc-server-WHOIS-functions erc-server-responses)
1116     (puthash \"WI\" \\='erc-server-WI-functions erc-server-responses)
1117
1118     (defalias \\='erc-server-WHOIS \\='erc-server-311)
1119     (defvar erc-server-WHOIS-functions \\='erc-server-311
1120       \"Some non-generic variable documentation.
1121
1122   Hook called upon receiving a WHOIS server response.
1123
1124   Each function is called with two arguments, the process associated
1125   with the response and the parsed response.  If the function returns
1126   non-nil, stop processing the hook.  Otherwise, continue.
1127
1128   See also `erc-server-311'.\")
1129
1130     (defalias \\='erc-server-WI \\='erc-server-311)
1131     (defvar erc-server-WI-functions \\='erc-server-311
1132       \"Some non-generic variable documentation.
1133
1134   Hook called upon receiving a WI server response.
1135   Each function is called with two arguments, the process associated
1136   with the response and the parsed response.  If the function returns
1137   non-nil, stop processing the hook.  Otherwise, continue.
1138
1139   See also `erc-server-311'.\"))
1140
1141 \(fn (NAME &rest ALIASES) &optional EXTRA-FN-DOC EXTRA-VAR-DOC &rest FN-BODY)"
1142   (if (numberp name) (setq name (intern (format "%03i" name))))
1143   (setq aliases (mapcar (lambda (a)
1144                           (if (numberp a)
1145                               (format "%03i" a)
1146                             a))
1147                         aliases))
1148   (let* ((hook-name (intern (format "erc-server-%s-functions" name)))
1149          (fn-name (intern (format "erc-server-%s" name)))
1150          (hook-doc (format-message "\
1151 %sHook called upon receiving a %%s server response.
1152 Each function is called with two arguments, the process associated
1153 with the response and the parsed response.  If the function returns
1154 non-nil, stop processing the hook.  Otherwise, continue.
1155
1156 See also `%s'."
1157                            (if extra-var-doc
1158                                (concat extra-var-doc "\n\n")
1159                              "")
1160                            fn-name))
1161          (fn-doc (format-message "\
1162 %sHandler for a %s server response.
1163 PROC is the server process which returned the response.
1164 PARSED is the actual response as an `erc-response' struct.
1165 If you want to add responses don't modify this function, but rather
1166 add things to `%s' instead."
1167                          (if extra-fn-doc
1168                              (concat extra-fn-doc "\n\n")
1169                            "")
1170                          name hook-name))
1171          (fn-alternates
1172           (cl-loop for alias in aliases
1173                    collect (intern (format "erc-server-%s" alias))))
1174          (var-alternates
1175           (cl-loop for alias in aliases
1176                    collect (intern (format "erc-server-%s-functions" alias)))))
1177     `(prog2
1178          ;; Normal hook variable.  The variable may already have a
1179          ;; value at this point, so I default to nil, and (add-hook)
1180          ;; unconditionally
1181          (defvar ,hook-name nil ,(format hook-doc name))
1182          (add-to-list ',hook-name ',fn-name)
1183          ;; Handler function
1184          (defun ,fn-name (proc parsed)
1185            ,fn-doc
1186            ,@fn-body)
1187
1188        ;; Make find-function and find-variable find them
1189        (put ',fn-name 'definition-name ',name)
1190        (put ',hook-name 'definition-name ',name)
1191
1192        ;; Hashtable map of responses to hook variables
1193        ,@(cl-loop for response in (cons name aliases)
1194                   for var in (cons hook-name var-alternates)
1195                   collect `(puthash ,(format "%s" response) ',var
1196                                     erc-server-responses))
1197        ;; Alternates.
1198        ;; Functions are defaliased, hook variables are defvared so we
1199        ;; can add hooks to one alias, but not another.
1200        ,@(cl-loop for fn in fn-alternates
1201                   for var in var-alternates
1202                   for a in aliases
1203                   nconc (list `(defalias ',fn ',fn-name)
1204                               `(defvar ,var ',fn-name ,(format hook-doc a))
1205                               `(put ',var 'definition-name ',hook-name))))))
1206
1207 (define-erc-response-handler (ERROR)
1208   "Handle an ERROR command from the server." nil
1209   (setq erc-server-error-occurred t)
1210   (erc-display-message
1211    parsed 'error nil 'ERROR
1212    ?s (erc-response.sender parsed) ?c (erc-response.contents parsed)))
1213
1214 (define-erc-response-handler (INVITE)
1215   "Handle invitation messages."
1216   nil
1217   (let ((target (car (erc-response.command-args parsed)))
1218         (chnl (erc-response.contents parsed)))
1219     (pcase-let ((`(,nick ,login ,host)
1220                  (erc-parse-user (erc-response.sender parsed))))
1221       (setq erc-invitation chnl)
1222       (when (string= target (erc-current-nick))
1223         (erc-display-message
1224          parsed 'notice 'active
1225          'INVITE ?n nick ?u login ?h host ?c chnl)))))
1226
1227 (define-erc-response-handler (JOIN)
1228   "Handle join messages."
1229   nil
1230   (let ((chnl (erc-response.contents parsed))
1231         (buffer nil))
1232     (pcase-let ((`(,nick ,login ,host)
1233                  (erc-parse-user (erc-response.sender parsed))))
1234       ;; strip the stupid combined JOIN facility (IRC 2.9)
1235       (if (string-match "^\\(.*\\)?\^g.*$" chnl)
1236           (setq chnl (match-string 1 chnl)))
1237       (save-excursion
1238         (let* ((str (cond
1239                      ;; If I have joined a channel
1240                      ((erc-current-nick-p nick)
1241                       (setq buffer (erc-open erc-session-server erc-session-port
1242                                              nick erc-session-user-full-name
1243                                              nil nil
1244                                              (list chnl) chnl
1245                                              erc-server-process))
1246                       (when buffer
1247                         (set-buffer buffer)
1248                         (erc-add-default-channel chnl)
1249                         (erc-server-send (format "MODE %s" chnl)))
1250                       (erc-with-buffer (chnl proc)
1251                         (erc-channel-begin-receiving-names))
1252                       (erc-update-mode-line)
1253                       (run-hooks 'erc-join-hook)
1254                       (erc-make-notice
1255                        (erc-format-message 'JOIN-you ?c chnl)))
1256                      (t
1257                       (setq buffer (erc-get-buffer chnl proc))
1258                       (erc-make-notice
1259                        (erc-format-message
1260                         'JOIN ?n nick ?u login ?h host ?c chnl))))))
1261           (when buffer (set-buffer buffer))
1262           (erc-update-channel-member chnl nick nick t nil nil nil nil nil host login)
1263           ;; on join, we want to stay in the new channel buffer
1264           ;;(set-buffer ob)
1265           (erc-display-message parsed nil buffer str))))))
1266
1267 (define-erc-response-handler (KICK)
1268   "Handle kick messages received from the server." nil
1269   (let* ((ch (nth 0 (erc-response.command-args parsed)))
1270          (tgt (nth 1 (erc-response.command-args parsed)))
1271          (reason (erc-trim-string (erc-response.contents parsed)))
1272          (buffer (erc-get-buffer ch proc)))
1273     (pcase-let ((`(,nick ,login ,host)
1274                  (erc-parse-user (erc-response.sender parsed))))
1275       (erc-remove-channel-member buffer tgt)
1276       (cond
1277        ((string= tgt (erc-current-nick))
1278         (erc-display-message
1279          parsed 'notice buffer
1280          'KICK-you ?n nick ?u login ?h host ?c ch ?r reason)
1281         (run-hook-with-args 'erc-kick-hook buffer)
1282         (erc-with-buffer
1283             (buffer)
1284           (erc-remove-channel-users))
1285         (erc-delete-default-channel ch buffer)
1286         (erc-update-mode-line buffer))
1287        ((string= nick (erc-current-nick))
1288         (erc-display-message
1289          parsed 'notice buffer
1290          'KICK-by-you ?k tgt ?c ch ?r reason))
1291        (t (erc-display-message
1292              parsed 'notice buffer
1293              'KICK ?k tgt ?n nick ?u login ?h host ?c ch ?r reason))))))
1294
1295 (define-erc-response-handler (MODE)
1296   "Handle server mode changes." nil
1297   (let ((tgt (car (erc-response.command-args parsed)))
1298         (mode (mapconcat 'identity (cdr (erc-response.command-args parsed))
1299                          " ")))
1300     (pcase-let ((`(,nick ,login ,host)
1301                  (erc-parse-user (erc-response.sender parsed))))
1302       (erc-log (format "MODE: %s -> %s: %s" nick tgt mode))
1303       ;; dirty hack
1304       (let ((buf (cond ((erc-channel-p tgt)
1305                         (erc-get-buffer tgt proc))
1306                        ((string= tgt (erc-current-nick)) nil)
1307                        ((erc-active-buffer) (erc-active-buffer))
1308                        (t (erc-get-buffer tgt)))))
1309         (with-current-buffer (or buf
1310                                  (current-buffer))
1311           (erc-update-modes tgt mode nick host login))
1312           (if (or (string= login "") (string= host ""))
1313               (erc-display-message parsed 'notice buf
1314                                    'MODE-nick ?n nick
1315                                    ?t tgt ?m mode)
1316             (erc-display-message parsed 'notice buf
1317                                  'MODE ?n nick ?u login
1318                                  ?h host ?t tgt ?m mode)))
1319       (erc-banlist-update proc parsed))))
1320
1321 (define-erc-response-handler (NICK)
1322   "Handle nick change messages." nil
1323   (let ((nn (erc-response.contents parsed))
1324         bufs)
1325     (pcase-let ((`(,nick ,login ,host)
1326                  (erc-parse-user (erc-response.sender parsed))))
1327       (setq bufs (erc-buffer-list-with-nick nick proc))
1328       (erc-log (format "NICK: %s -> %s" nick nn))
1329       ;; if we had a query with this user, make sure future messages will be
1330       ;; sent to the correct nick. also add to bufs, since the user will want
1331       ;; to see the nick change in the query, and if it's a newly begun query,
1332       ;; erc-channel-users won't contain it
1333       (erc-buffer-filter
1334        (lambda ()
1335          (when (equal (erc-default-target) nick)
1336            (setq erc-default-recipients
1337                  (cons nn (cdr erc-default-recipients)))
1338            (rename-buffer nn t)         ; bug#12002
1339            (erc-update-mode-line)
1340            (add-to-list 'bufs (current-buffer)))))
1341       (erc-update-user-nick nick nn host nil nil login)
1342       (cond
1343        ((string= nick (erc-current-nick))
1344         (add-to-list 'bufs (erc-server-buffer))
1345         (erc-set-current-nick nn)
1346         (erc-update-mode-line)
1347         (setq erc-nick-change-attempt-count 0)
1348         (setq erc-default-nicks (if (consp erc-nick) erc-nick (list erc-nick)))
1349         (erc-display-message
1350          parsed 'notice bufs
1351          'NICK-you ?n nick ?N nn)
1352         (run-hook-with-args 'erc-nick-changed-functions nn nick))
1353        (t
1354         (erc-handle-user-status-change 'nick (list nick login host) (list nn))
1355         (erc-display-message parsed 'notice bufs 'NICK ?n nick
1356                              ?u login ?h host ?N nn))))))
1357
1358 (define-erc-response-handler (PART)
1359   "Handle part messages." nil
1360   (let* ((chnl (car (erc-response.command-args parsed)))
1361          (reason (erc-trim-string (erc-response.contents parsed)))
1362          (buffer (erc-get-buffer chnl proc)))
1363     (pcase-let ((`(,nick ,login ,host)
1364                  (erc-parse-user (erc-response.sender parsed))))
1365       (erc-remove-channel-member buffer nick)
1366       (erc-display-message parsed 'notice buffer
1367                            'PART ?n nick ?u login
1368                            ?h host ?c chnl ?r (or reason ""))
1369       (when (string= nick (erc-current-nick))
1370         (run-hook-with-args 'erc-part-hook buffer)
1371         (erc-with-buffer
1372             (buffer)
1373           (erc-remove-channel-users))
1374         (erc-delete-default-channel chnl buffer)
1375         (erc-update-mode-line buffer)
1376         (when erc-kill-buffer-on-part
1377           (kill-buffer buffer))))))
1378
1379 (define-erc-response-handler (PING)
1380   "Handle ping messages." nil
1381   (let ((pinger (car (erc-response.command-args parsed))))
1382     (erc-log (format "PING: %s" pinger))
1383     ;; ping response to the server MUST be forced, or you can lose big
1384     (erc-server-send (format "PONG :%s" pinger) t)
1385     (when erc-verbose-server-ping
1386       (erc-display-message
1387        parsed 'error proc
1388        'PING ?s (erc-time-diff erc-server-last-ping-time (erc-current-time))))
1389     (setq erc-server-last-ping-time (erc-current-time))))
1390
1391 (define-erc-response-handler (PONG)
1392   "Handle pong messages." nil
1393   (let ((time (string-to-number (erc-response.contents parsed))))
1394     (when (> time 0)
1395       (setq erc-server-lag (erc-time-diff time (erc-current-time)))
1396       (when erc-verbose-server-ping
1397         (erc-display-message
1398          parsed 'notice proc 'PONG
1399          ?h (car (erc-response.command-args parsed)) ?i erc-server-lag
1400          ?s (if (/= erc-server-lag 1) "s" "")))
1401       (erc-update-mode-line))))
1402
1403 (define-erc-response-handler (PRIVMSG NOTICE)
1404   "Handle private messages, including messages in channels." nil
1405   (let ((sender-spec (erc-response.sender parsed))
1406         (cmd (erc-response.command parsed))
1407         (tgt (car (erc-response.command-args parsed)))
1408         (msg (erc-response.contents parsed)))
1409     (if (or (erc-ignored-user-p sender-spec)
1410             (erc-ignored-reply-p msg tgt proc))
1411         (when erc-minibuffer-ignored
1412           (message "Ignored %s from %s to %s" cmd sender-spec tgt))
1413       (let* ((sndr (erc-parse-user sender-spec))
1414              (nick (nth 0 sndr))
1415              (login (nth 1 sndr))
1416              (host (nth 2 sndr))
1417              (msgp (string= cmd "PRIVMSG"))
1418              (noticep (string= cmd "NOTICE"))
1419              ;; S.B. downcase *both* tgt and current nick
1420              (privp (erc-current-nick-p tgt))
1421              s buffer
1422              fnick)
1423         (setf (erc-response.contents parsed) msg)
1424         (setq buffer (erc-get-buffer (if privp nick tgt) proc))
1425         (when buffer
1426           (with-current-buffer buffer
1427             ;; update the chat partner info.  Add to the list if private
1428             ;; message.  We will accumulate private identities indefinitely
1429             ;; at this point.
1430             (erc-update-channel-member (if privp nick tgt) nick nick
1431                                        privp nil nil nil nil nil host login nil nil t)
1432             (let ((cdata (erc-get-channel-user nick)))
1433               (setq fnick (funcall erc-format-nick-function
1434                                    (car cdata) (cdr cdata))))))
1435         (cond
1436          ((erc-is-message-ctcp-p msg)
1437           (setq s (if msgp
1438                       (erc-process-ctcp-query proc parsed nick login host)
1439                     (erc-process-ctcp-reply proc parsed nick login host
1440                                             (match-string 1 msg)))))
1441          (t
1442           (setcar erc-server-last-peers nick)
1443           (setq s (erc-format-privmessage
1444                    (or fnick nick) msg
1445                    ;; If buffer is a query buffer,
1446                    ;; format the nick as for a channel.
1447                    (and (not (and buffer
1448                                   (erc-query-buffer-p buffer)
1449                                   erc-format-query-as-channel-p))
1450                         privp)
1451                    msgp))))
1452         (when s
1453           (if (and noticep privp)
1454               (progn
1455                 (run-hook-with-args 'erc-echo-notice-always-hook
1456                                     s parsed buffer nick)
1457                 (run-hook-with-args-until-success
1458                  'erc-echo-notice-hook s parsed buffer nick))
1459             (erc-display-message parsed nil buffer s)))
1460         (when (string= cmd "PRIVMSG")
1461           (erc-auto-query proc parsed))))))
1462
1463 ;; FIXME: need clean way of specifying extra hooks in
1464 ;; define-erc-response-handler.
1465 (add-hook 'erc-server-PRIVMSG-functions 'erc-auto-query)
1466
1467 (define-erc-response-handler (QUIT)
1468   "Another user has quit IRC." nil
1469   (let ((reason (erc-response.contents parsed))
1470         bufs)
1471     (pcase-let ((`(,nick ,login ,host)
1472                  (erc-parse-user (erc-response.sender parsed))))
1473       (setq bufs (erc-buffer-list-with-nick nick proc))
1474       (erc-remove-user nick)
1475       (setq reason (erc-wash-quit-reason reason nick login host))
1476       (erc-display-message parsed 'notice bufs
1477                            'QUIT ?n nick ?u login
1478                            ?h host ?r reason))))
1479
1480 (define-erc-response-handler (TOPIC)
1481   "The channel topic has changed." nil
1482   (let* ((ch (car (erc-response.command-args parsed)))
1483          (topic (erc-trim-string (erc-response.contents parsed)))
1484          (time (format-time-string erc-server-timestamp-format)))
1485     (pcase-let ((`(,nick ,login ,host)
1486                  (erc-parse-user (erc-response.sender parsed))))
1487       (erc-update-channel-member ch nick nick nil nil nil nil nil nil host login)
1488       (erc-update-channel-topic ch (format "%s\C-o (%s, %s)" topic nick time))
1489       (erc-display-message parsed 'notice (erc-get-buffer ch proc)
1490                            'TOPIC ?n nick ?u login ?h host
1491                            ?c ch ?T topic))))
1492
1493 (define-erc-response-handler (WALLOPS)
1494   "Display a WALLOPS message." nil
1495   (let ((message (erc-response.contents parsed)))
1496     (pcase-let ((`(,nick ,login ,host)
1497                  (erc-parse-user (erc-response.sender parsed))))
1498       (erc-display-message
1499        parsed 'notice nil
1500        'WALLOPS ?n nick ?m message))))
1501
1502 (define-erc-response-handler (001)
1503   "Set `erc-server-current-nick' to reflect server settings and display the welcome message."
1504   nil
1505   (erc-set-current-nick (car (erc-response.command-args parsed)))
1506   (erc-update-mode-line)                ; needed here?
1507   (setq erc-nick-change-attempt-count 0)
1508   (setq erc-default-nicks (if (consp erc-nick) erc-nick (list erc-nick)))
1509   (erc-display-message
1510    parsed 'notice 'active (erc-response.contents parsed)))
1511
1512 (define-erc-response-handler (MOTD 002 003 371 372 374 375)
1513   "Display the server's message of the day." nil
1514   (erc-handle-login)
1515   (erc-display-message
1516    parsed 'notice (if erc-server-connected 'active proc)
1517    (erc-response.contents parsed)))
1518
1519 (define-erc-response-handler (376 422)
1520   "End of MOTD/MOTD is missing." nil
1521   (erc-server-MOTD proc parsed)
1522   (erc-connection-established proc parsed))
1523
1524 (define-erc-response-handler (004)
1525   "Display the server's identification." nil
1526   (pcase-let ((`(,server-name ,server-version)
1527                (cdr (erc-response.command-args parsed))))
1528     (setq erc-server-version server-version)
1529     (setq erc-server-announced-name server-name)
1530     (erc-update-mode-line-buffer (process-buffer proc))
1531     (erc-display-message
1532      parsed 'notice proc
1533      's004 ?s server-name ?v server-version
1534      ?U (nth 3 (erc-response.command-args parsed))
1535      ?C (nth 4 (erc-response.command-args parsed)))))
1536
1537 (define-erc-response-handler (005)
1538   "Set the variable `erc-server-parameters' and display the received message.
1539
1540 According to RFC 2812, suggests alternate servers on the network.
1541 Many servers, however, use this code to show which parameters they have set,
1542 for example, the network identifier, maximum allowed topic length, whether
1543 certain commands are accepted and more.  See documentation for
1544 `erc-server-parameters' for more information on the parameters sent.
1545
1546 A server may send more than one 005 message."
1547   nil
1548   (let ((line (mapconcat 'identity
1549                          (setf (erc-response.command-args parsed)
1550                                (cdr (erc-response.command-args parsed)))
1551                          " ")))
1552     (while (erc-response.command-args parsed)
1553       (let ((section (pop (erc-response.command-args parsed))))
1554         ;; fill erc-server-parameters
1555         (when (string-match "^\\([A-Z]+\\)=\\(.*\\)$\\|^\\([A-Z]+\\)$"
1556                             section)
1557           (add-to-list 'erc-server-parameters
1558                        `(,(or (match-string 1 section)
1559                               (match-string 3 section))
1560                          .
1561                          ,(match-string 2 section))))))
1562     (erc-display-message parsed 'notice proc line)))
1563
1564 (define-erc-response-handler (221)
1565   "Display the current user modes." nil
1566   (let* ((nick (car (erc-response.command-args parsed)))
1567          (modes (mapconcat 'identity
1568                            (cdr (erc-response.command-args parsed)) " ")))
1569     (erc-set-modes nick modes)
1570     (erc-display-message parsed 'notice 'active 's221 ?n nick ?m modes)))
1571
1572 (define-erc-response-handler (252)
1573   "Display the number of IRC operators online." nil
1574   (erc-display-message parsed 'notice 'active 's252
1575                        ?i (cadr (erc-response.command-args parsed))))
1576
1577 (define-erc-response-handler (253)
1578   "Display the number of unknown connections." nil
1579   (erc-display-message parsed 'notice 'active 's253
1580                        ?i (cadr (erc-response.command-args parsed))))
1581
1582 (define-erc-response-handler (254)
1583   "Display the number of channels formed." nil
1584   (erc-display-message parsed 'notice 'active 's254
1585                        ?i (cadr (erc-response.command-args parsed))))
1586
1587 (define-erc-response-handler (250 251 255 256 257 258 259 265 266 377 378)
1588   "Generic display of server messages as notices.
1589
1590 See `erc-display-server-message'." nil
1591   (erc-display-server-message proc parsed))
1592
1593 (define-erc-response-handler (275)
1594   "Display secure connection message." nil
1595   (pcase-let ((`(,nick ,user ,message)
1596                (cdr (erc-response.command-args parsed))))
1597     (erc-display-message
1598      parsed 'notice 'active 's275
1599      ?n nick
1600      ?m (mapconcat 'identity (cddr (erc-response.command-args parsed))
1601                    " "))))
1602
1603 (define-erc-response-handler (290)
1604   "Handle dancer-ircd CAPAB messages." nil nil)
1605
1606 (define-erc-response-handler (301)
1607   "AWAY notice." nil
1608   (erc-display-message parsed 'notice 'active 's301
1609                        ?n (cadr (erc-response.command-args parsed))
1610                        ?r (erc-response.contents parsed)))
1611
1612 (define-erc-response-handler (303)
1613   "ISON reply" nil
1614   (erc-display-message parsed 'notice 'active 's303
1615                        ?n (cadr (erc-response.command-args parsed))))
1616
1617 (define-erc-response-handler (305)
1618   "Return from AWAYness." nil
1619   (erc-process-away proc nil)
1620   (erc-display-message parsed 'notice 'active
1621                        's305 ?m (erc-response.contents parsed)))
1622
1623 (define-erc-response-handler (306)
1624   "Set AWAYness." nil
1625   (erc-process-away proc t)
1626   (erc-display-message parsed 'notice 'active
1627                        's306 ?m (erc-response.contents parsed)))
1628
1629 (define-erc-response-handler (307)
1630   "Display nick-identified message." nil
1631   (pcase-let ((`(,nick ,user ,message)
1632                (cdr (erc-response.command-args parsed))))
1633     (erc-display-message
1634      parsed 'notice 'active 's307
1635      ?n nick
1636      ?m (mapconcat 'identity (cddr (erc-response.command-args parsed))
1637                    " "))))
1638
1639 (define-erc-response-handler (311 314)
1640   "WHOIS/WHOWAS notices." nil
1641   (let ((fname (erc-response.contents parsed))
1642         (catalog-entry (intern (format "s%s" (erc-response.command parsed)))))
1643     (pcase-let ((`(,nick ,user ,host)
1644                  (cdr (erc-response.command-args parsed))))
1645       (erc-update-user-nick nick nick host nil fname user)
1646       (erc-display-message
1647        parsed 'notice 'active catalog-entry
1648        ?n nick ?f fname ?u user ?h host))))
1649
1650 (define-erc-response-handler (312)
1651   "Server name response in WHOIS." nil
1652   (pcase-let ((`(,nick ,server-host)
1653               (cdr (erc-response.command-args parsed))))
1654     (erc-display-message
1655      parsed 'notice 'active 's312
1656      ?n nick ?s server-host ?c (erc-response.contents parsed))))
1657
1658 (define-erc-response-handler (313)
1659   "IRC Operator response in WHOIS." nil
1660   (erc-display-message
1661    parsed 'notice 'active 's313
1662    ?n (cadr (erc-response.command-args parsed))))
1663
1664 (define-erc-response-handler (315 318 323 369)
1665   ;; 315 - End of WHO
1666   ;; 318 - End of WHOIS list
1667   ;; 323 - End of channel LIST
1668   ;; 369 - End of WHOWAS
1669   "End of WHO/WHOIS/LIST/WHOWAS notices." nil
1670   (ignore proc parsed))
1671
1672 (define-erc-response-handler (317)
1673   "IDLE notice." nil
1674   (pcase-let ((`(,nick ,seconds-idle ,on-since ,time)
1675                (cdr (erc-response.command-args parsed))))
1676     (setq time (when on-since
1677                  (format-time-string erc-server-timestamp-format
1678                                      (erc-string-to-emacs-time on-since))))
1679     (erc-update-user-nick nick nick nil nil nil
1680                           (and time (format "on since %s" time)))
1681     (if time
1682         (erc-display-message
1683          parsed 'notice 'active 's317-on-since
1684          ?n nick ?i (erc-sec-to-time (string-to-number seconds-idle)) ?t time)
1685       (erc-display-message
1686        parsed 'notice 'active 's317
1687        ?n nick ?i (erc-sec-to-time (string-to-number seconds-idle))))))
1688
1689 (define-erc-response-handler (319)
1690   "Channel names in WHOIS response." nil
1691   (erc-display-message
1692    parsed 'notice 'active 's319
1693    ?n (cadr (erc-response.command-args parsed))
1694    ?c (erc-response.contents parsed)))
1695
1696 (define-erc-response-handler (320)
1697   "Identified user in WHOIS." nil
1698   (erc-display-message
1699    parsed 'notice 'active 's320
1700    ?n (cadr (erc-response.command-args parsed))))
1701
1702 (define-erc-response-handler (321)
1703   "LIST header." nil
1704   (setq erc-channel-list nil))
1705
1706 (defun erc-server-321-message (proc parsed)
1707   "Display a message for the 321 event."
1708   (erc-display-message parsed 'notice proc 's321)
1709   nil)
1710 (add-hook 'erc-server-321-functions 'erc-server-321-message t)
1711
1712 (define-erc-response-handler (322)
1713   "LIST notice." nil
1714   (let ((topic (erc-response.contents parsed)))
1715     (pcase-let ((`(,channel ,num-users)
1716                  (cdr (erc-response.command-args parsed))))
1717       (add-to-list 'erc-channel-list (list channel))
1718       (erc-update-channel-topic channel topic))))
1719
1720 (defun erc-server-322-message (proc parsed)
1721   "Display a message for the 322 event."
1722   (let ((topic (erc-response.contents parsed)))
1723     (pcase-let ((`(,channel ,num-users)
1724                  (cdr (erc-response.command-args parsed))))
1725       (erc-display-message
1726        parsed 'notice proc 's322
1727        ?c channel ?u num-users ?t (or topic "")))))
1728 (add-hook 'erc-server-322-functions 'erc-server-322-message t)
1729
1730 (define-erc-response-handler (324)
1731   "Channel or nick modes." nil
1732   (let ((channel (cadr (erc-response.command-args parsed)))
1733         (modes (mapconcat 'identity (cddr (erc-response.command-args parsed))
1734                           " ")))
1735     (erc-set-modes channel modes)
1736     (erc-display-message
1737      parsed 'notice (erc-get-buffer channel proc)
1738      's324 ?c channel ?m modes)))
1739
1740 (define-erc-response-handler (328)
1741   "Channel URL (on freenode network)." nil
1742   (let ((channel (cadr (erc-response.command-args parsed)))
1743         (url (erc-response.contents parsed)))
1744     (erc-display-message parsed 'notice (erc-get-buffer channel proc)
1745                          's328 ?c channel ?u url)))
1746
1747 (define-erc-response-handler (329)
1748   "Channel creation date." nil
1749   (let ((channel (cadr (erc-response.command-args parsed)))
1750         (time (erc-string-to-emacs-time
1751                (nth 2 (erc-response.command-args parsed)))))
1752     (erc-display-message
1753      parsed 'notice (erc-get-buffer channel proc)
1754      's329 ?c channel ?t (format-time-string erc-server-timestamp-format
1755                                              time))))
1756
1757 (define-erc-response-handler (330)
1758   "Nick is authed as (on Quakenet network)." nil
1759   ;; FIXME: I don't know what the magic numbers mean.  Mummy, make
1760   ;; the magic numbers go away.
1761   ;; No seriously, I have no clue about the format of this command,
1762   ;; and don't sit on Quakenet, so can't test.  Originally we had:
1763   ;; nick == (aref parsed 3)
1764   ;; authaccount == (aref parsed 4)
1765   ;; authmsg == (aref parsed 5)
1766   ;; The guesses below are, well, just that. -- Lawrence 2004/05/10
1767   (let ((nick (cadr (erc-response.command-args parsed)))
1768         (authaccount (nth 2 (erc-response.command-args parsed)))
1769         (authmsg (erc-response.contents parsed)))
1770     (erc-display-message parsed 'notice 'active 's330
1771                          ?n nick ?a authmsg ?i authaccount)))
1772
1773 (define-erc-response-handler (331)
1774   "No topic set for channel." nil
1775   (let ((channel (cadr (erc-response.command-args parsed)))
1776         (topic (erc-response.contents parsed)))
1777     (erc-display-message parsed 'notice (erc-get-buffer channel proc)
1778                          's331 ?c channel)))
1779
1780 (define-erc-response-handler (332)
1781   "TOPIC notice." nil
1782   (let ((channel (cadr (erc-response.command-args parsed)))
1783         (topic (erc-response.contents parsed)))
1784     (erc-update-channel-topic channel topic)
1785     (erc-display-message parsed 'notice (erc-get-buffer channel proc)
1786                          's332 ?c channel ?T topic)))
1787
1788 (define-erc-response-handler (333)
1789   "Who set the topic, and when." nil
1790   (pcase-let ((`(,channel ,nick ,time)
1791                (cdr (erc-response.command-args parsed))))
1792     (setq time (format-time-string erc-server-timestamp-format
1793                                    (erc-string-to-emacs-time time)))
1794     (erc-update-channel-topic channel
1795                               (format "\C-o (%s, %s)" nick time)
1796                               'append)
1797     (erc-display-message parsed 'notice (erc-get-buffer channel proc)
1798                          's333 ?c channel ?n nick ?t time)))
1799
1800 (define-erc-response-handler (341)
1801   "Let user know when an INVITE attempt has been sent successfully."
1802   nil
1803   (pcase-let ((`(,nick ,channel)
1804                (cdr (erc-response.command-args parsed))))
1805     (erc-display-message parsed 'notice (erc-get-buffer channel proc)
1806                          's341 ?n nick ?c channel)))
1807
1808 (define-erc-response-handler (352)
1809   "WHO notice." nil
1810   (pcase-let ((`(,channel ,user ,host ,server ,nick ,away-flag)
1811                (cdr (erc-response.command-args parsed))))
1812     (let ((full-name (erc-response.contents parsed))
1813           hopcount)
1814       (when (string-match "\\(^[0-9]+ \\)\\(.*\\)$" full-name)
1815         (setq hopcount (match-string 1 full-name))
1816         (setq full-name (match-string 2 full-name)))
1817       (erc-update-channel-member channel nick nick nil nil nil nil nil nil host user full-name)
1818       (erc-display-message parsed 'notice 'active 's352
1819                            ?c channel ?n nick ?a away-flag
1820                            ?u user ?h host ?f full-name))))
1821
1822 (define-erc-response-handler (353)
1823   "NAMES notice." nil
1824   (let ((channel (nth 2 (erc-response.command-args parsed)))
1825         (users (erc-response.contents parsed)))
1826     (erc-display-message parsed 'notice (or (erc-get-buffer channel proc)
1827                                             'active)
1828                          's353 ?c channel ?u users)
1829     (erc-with-buffer (channel proc)
1830       (erc-channel-receive-names users))))
1831
1832 (define-erc-response-handler (366)
1833   "End of NAMES." nil
1834   (erc-with-buffer ((cadr (erc-response.command-args parsed)) proc)
1835     (erc-channel-end-receiving-names)))
1836
1837 (define-erc-response-handler (367)
1838   "Channel ban list entries." nil
1839   (pcase-let ((`(,channel ,banmask ,setter ,time)
1840                (cdr (erc-response.command-args parsed))))
1841     ;; setter and time are not standard
1842     (if setter
1843         (erc-display-message parsed 'notice 'active 's367-set-by
1844                              ?c channel
1845                              ?b banmask
1846                              ?s setter
1847                              ?t (or time ""))
1848       (erc-display-message parsed 'notice 'active 's367
1849                            ?c channel
1850                            ?b banmask))))
1851
1852 (define-erc-response-handler (368)
1853   "End of channel ban list." nil
1854   (let ((channel (cadr (erc-response.command-args parsed))))
1855     (erc-display-message parsed 'notice 'active 's368
1856                          ?c channel)))
1857
1858 (define-erc-response-handler (379)
1859   "Forwarding to another channel." nil
1860   ;; FIXME: Yet more magic numbers in original code, I'm guessing this
1861   ;; command takes two arguments, and doesn't have any "contents". --
1862   ;; Lawrence 2004/05/10
1863   (pcase-let ((`(,from ,to)
1864                (cdr (erc-response.command-args parsed))))
1865     (erc-display-message parsed 'notice 'active
1866                          's379 ?c from ?f to)))
1867
1868 (define-erc-response-handler (391)
1869   "Server's time string." nil
1870   (erc-display-message
1871    parsed 'notice 'active
1872    's391 ?s (cadr (erc-response.command-args parsed))
1873    ?t (nth 2 (erc-response.command-args parsed))))
1874
1875 (define-erc-response-handler (401)
1876   "No such nick/channel." nil
1877   (let ((nick/channel (cadr (erc-response.command-args parsed))))
1878     (when erc-whowas-on-nosuchnick
1879       (erc-log (format "cmd: WHOWAS: %s" nick/channel))
1880       (erc-server-send (format "WHOWAS %s 1" nick/channel)))
1881     (erc-display-message parsed '(notice error) 'active
1882                          's401 ?n nick/channel)))
1883
1884 (define-erc-response-handler (403)
1885   "No such channel." nil
1886   (erc-display-message parsed '(notice error) 'active
1887                        's403 ?c (cadr (erc-response.command-args parsed))))
1888
1889 (define-erc-response-handler (404)
1890   "Cannot send to channel." nil
1891   (erc-display-message parsed '(notice error) 'active
1892                        's404 ?c (cadr (erc-response.command-args parsed))))
1893
1894
1895 (define-erc-response-handler (405)
1896   "Can't join that many channels." nil
1897   (erc-display-message parsed '(notice error) 'active
1898                        's405 ?c (cadr (erc-response.command-args parsed))))
1899
1900 (define-erc-response-handler (406)
1901   "No such nick." nil
1902   (erc-display-message parsed '(notice error) 'active
1903                        's406 ?n (cadr (erc-response.command-args parsed))))
1904
1905 (define-erc-response-handler (412)
1906   "No text to send." nil
1907   (erc-display-message parsed '(notice error) 'active 's412))
1908
1909 (define-erc-response-handler (421)
1910   "Unknown command." nil
1911   (erc-display-message parsed '(notice error) 'active 's421
1912                        ?c (cadr (erc-response.command-args parsed))))
1913
1914 (define-erc-response-handler (432)
1915   "Bad nick." nil
1916   (erc-display-message parsed '(notice error) 'active 's432
1917                        ?n (cadr (erc-response.command-args parsed))))
1918
1919 (define-erc-response-handler (433)
1920   "Login-time \"nick in use\"." nil
1921   (erc-nickname-in-use (cadr (erc-response.command-args parsed))
1922                        "already in use"))
1923
1924 (define-erc-response-handler (437)
1925   "Nick temporarily unavailable (on IRCnet)." nil
1926   (let ((nick/channel (cadr (erc-response.command-args parsed))))
1927     (unless (erc-channel-p nick/channel)
1928       (erc-nickname-in-use nick/channel "temporarily unavailable"))))
1929
1930 (define-erc-response-handler (442)
1931   "Not on channel." nil
1932   (erc-display-message parsed '(notice error) 'active 's442
1933                        ?c (cadr (erc-response.command-args parsed))))
1934
1935 (define-erc-response-handler (461)
1936   "Not enough parameters for command." nil
1937   (erc-display-message parsed '(notice error)  'active 's461
1938                        ?c (cadr (erc-response.command-args parsed))
1939                        ?m (erc-response.contents parsed)))
1940
1941 (define-erc-response-handler (465)
1942   "You are banned from this server." nil
1943   (setq erc-server-banned t)
1944   ;; show the server's message, as a reason might be provided
1945   (erc-display-error-notice
1946    parsed
1947    (erc-response.contents parsed)))
1948
1949 (define-erc-response-handler (474)
1950   "Banned from channel errors." nil
1951   (erc-display-message parsed '(notice error) nil
1952                        (intern (format "s%s"
1953                                        (erc-response.command parsed)))
1954                        ?c (cadr (erc-response.command-args parsed))))
1955
1956 (define-erc-response-handler (475)
1957   "Channel key needed." nil
1958   (erc-display-message parsed '(notice error) nil 's475
1959                        ?c (cadr (erc-response.command-args parsed)))
1960   (when erc-prompt-for-channel-key
1961     (let ((channel (cadr (erc-response.command-args parsed)))
1962           (key (read-from-minibuffer
1963                 (format "Channel %s is mode +k.  Enter key (RET to cancel): "
1964                         (cadr (erc-response.command-args parsed))))))
1965       (when (and key (> (length key) 0))
1966           (erc-cmd-JOIN channel key)))))
1967
1968 (define-erc-response-handler (477)
1969   "Channel doesn't support modes." nil
1970   (let ((channel (cadr (erc-response.command-args parsed)))
1971         (message (erc-response.contents parsed)))
1972     (erc-display-message parsed 'notice (erc-get-buffer channel proc)
1973                          (format "%s: %s" channel message))))
1974
1975 (define-erc-response-handler (482)
1976   "You need to be a channel operator to do that." nil
1977   (let ((channel (cadr (erc-response.command-args parsed)))
1978         (message (erc-response.contents parsed)))
1979     (erc-display-message parsed '(error notice) 'active 's482
1980                          ?c channel ?m message)))
1981
1982 (define-erc-response-handler (671)
1983   "Secure connection response in WHOIS." nil
1984   (let ((nick (cadr (erc-response.command-args parsed)))
1985         (securemsg (erc-response.contents parsed)))
1986     (erc-display-message parsed 'notice 'active 's671
1987                          ?n nick ?a securemsg)))
1988
1989 (define-erc-response-handler (431 445 446 451 462 463 464 481 483 484 485
1990                                   491 501 502)
1991   ;; 431 - No nickname given
1992   ;; 445 - SUMMON has been disabled
1993   ;; 446 - USERS has been disabled
1994   ;; 451 - You have not registered
1995   ;; 462 - Unauthorized command (already registered)
1996   ;; 463 - Your host isn't among the privileged
1997   ;; 464 - Password incorrect
1998   ;; 481 - Need IRCop privileges
1999   ;; 483 - You can't kill a server!
2000   ;; 484 - Your connection is restricted!
2001   ;; 485 - You're not the original channel operator
2002   ;; 491 - No O-lines for your host
2003   ;; 501 - Unknown MODE flag
2004   ;; 502 - Cannot change mode for other users
2005   "Generic display of server error messages.
2006
2007 See `erc-display-error-notice'." nil
2008   (erc-display-error-notice
2009    parsed
2010    (intern (format "s%s" (erc-response.command parsed)))))
2011
2012 ;; FIXME: These are yet to be implemented, they're just stubs for now
2013 ;; -- Lawrence 2004/05/12
2014
2015 ;; response numbers left here for reference
2016
2017 ;; (define-erc-response-handler (323 364 365 381 382 392 393 394 395
2018 ;;                               200 201 202 203 204 205 206 208 209 211 212 213
2019 ;;                               214 215 216 217 218 219 241 242 243 244 249 261
2020 ;;                               262 302 342 351 402 407 409 411 413 414 415
2021 ;;                               423 424 436 441 443 444 467 471 472 473 KILL)
2022 ;;   nil nil
2023 ;;   (ignore proc parsed))
2024
2025 (provide 'erc-backend)
2026
2027 ;;; erc-backend.el ends here
2028 ;; Local Variables:
2029 ;; indent-tabs-mode: nil
2030 ;; End: