code.delx.au - gnu-emacs/blob - test/automated/package-test.el

   1 ;;; package-test.el --- Tests for the Emacs package system
   2
   3 ;; Copyright (C) 2013-2015 Free Software Foundation, Inc.
   4
   5 ;; Author: Daniel Hackney <dan@haxney.org>
   6 ;; Version: 1.0
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; You may want to run this from a separate Emacs instance from your
  26 ;; main one, because a bug in the code below could mess with your
  27 ;; installed packages.
  28
  29 ;; Run this in a clean Emacs session using:
  30 ;;
  31 ;;     $ emacs -Q --batch -L . -l package-test.el -l ert -f ert-run-tests-batch-and-exit
  32
  33 ;;; Code:
  34
  35 (require 'package)
  36 (require 'ert)
  37 (require 'cl-lib)
  38
  39 (defvar package-test-user-dir nil
  40   "Directory to use for installing packages during testing.")
  41
  42 (defvar package-test-file-dir (file-name-directory (or load-file-name
  43                                                        buffer-file-name))
  44   "Directory of the actual \"package-test.el\" file.")
  45
  46 (defvar simple-single-desc
  47   (package-desc-create :name 'simple-single
  48                        :version '(1 3)
  49                        :summary "A single-file package with no dependencies"
  50                        :kind 'single
  51                        :extras '((:url . "http://doodles.au")))
  52   "Expected `package-desc' parsed from simple-single-1.3.el.")
  53
  54 (defvar simple-depend-desc
  55   (package-desc-create :name 'simple-depend
  56                        :version '(1 0)
  57                        :summary "A single-file package with a dependency."
  58                        :kind 'single
  59                        :reqs '((simple-single (1 3))))
  60   "Expected `package-desc' parsed from simple-depend-1.0.el.")
  61
  62 (defvar multi-file-desc
  63   (package-desc-create :name 'multi-file
  64                        :version '(0 2 3)
  65                        :summary "Example of a multi-file tar package"
  66                        :kind 'tar
  67                        :extras '((:url . "http://puddles.li")))
  68   "Expected `package-desc' from \"multi-file-0.2.3.tar\".")
  69
  70 (defvar new-pkg-desc
  71   (package-desc-create :name 'new-pkg
  72                        :version '(1 0)
  73                        :kind 'single)
  74   "Expected `package-desc' parsed from new-pkg-1.0.el.")
  75
  76 (defvar package-test-data-dir (expand-file-name "data/package" package-test-file-dir)
  77   "Base directory of package test files.")
  78
  79 (defvar package-test-fake-contents-file
  80   (expand-file-name "archive-contents" package-test-data-dir)
  81   "Path to a static copy of \"archive-contents\".")
  82
  83 (cl-defmacro with-package-test ((&optional &key file
  84                                            basedir
  85                                            install
  86                                            update-news
  87                                            upload-base)
  88                                 &rest body)
  89   "Set up temporary locations and variables for testing."
  90   (declare (indent 1))
  91   `(let* ((package-test-user-dir (make-temp-file "pkg-test-user-dir-" t))
  92           (process-environment (cons (format "HOME=%s" package-test-user-dir)
  93                                      process-environment))
  94           (package-user-dir package-test-user-dir)
  95           (package-archives `(("gnu" . ,package-test-data-dir)))
  96           (old-yes-no-defn (symbol-function 'yes-or-no-p))
  97           (default-directory package-test-file-dir)
  98           package--initialized
  99           package-alist
 100           ,@(if update-news
 101                 '(package-update-news-on-upload t)
 102               (list (cl-gensym)))
 103           ,@(if upload-base
 104                 '((package-test-archive-upload-base (make-temp-file "pkg-archive-base-" t))
 105                   (package-archive-upload-base package-test-archive-upload-base))
 106               (list (cl-gensym)))) ;; Dummy value so `let' doesn't try to bind `nil'
 107      (unwind-protect
 108          (progn
 109            ,(if basedir `(cd ,basedir))
 110            (setf (symbol-function 'yes-or-no-p) #'(lambda (&rest r) t))
 111            (unless (file-directory-p package-user-dir)
 112              (mkdir package-user-dir))
 113            ,@(when install
 114                `((package-initialize)
 115                  (package-refresh-contents)
 116                  (mapc 'package-install ,install)))
 117            (with-temp-buffer
 118              ,(if file
 119                   `(insert-file-contents ,file))
 120              ,@body))
 121
 122        (when (file-directory-p package-test-user-dir)
 123          (delete-directory package-test-user-dir t))
 124
 125        (when (and (boundp 'package-test-archive-upload-base)
 126                   (file-directory-p package-test-archive-upload-base))
 127          (delete-directory package-test-archive-upload-base t))
 128        (setf (symbol-function 'yes-or-no-p) old-yes-no-defn))))
 129
 130 (defmacro with-fake-help-buffer (&rest body)
 131   "Execute BODY in a temp buffer which is treated as the \"*Help*\" buffer."
 132   `(with-temp-buffer
 133     (help-mode)
 134     ;; Trick `help-buffer' into using the temp buffer.
 135     (let ((help-xref-following t))
 136       ,@body)))
 137
 138 (defun package-test-strip-version (dir)
 139   (replace-regexp-in-string "-pkg\\.el\\'" "" (package--description-file dir)))
 140
 141 (defun package-test-suffix-matches (base suffix-list)
 142   "Return file names matching BASE concatenated with each item in SUFFIX-LIST"
 143   (cl-mapcan
 144    '(lambda (item) (file-expand-wildcards (concat base item)))
 145    suffix-list))
 146
 147 (defvar tar-parse-info)
 148 (declare-function tar-header-name "tar-mode" (cl-x) t) ; defstruct
 149
 150 (defun package-test-search-tar-file (filename)
 151   "Search the current buffer's `tar-parse-info' variable for FILENAME.
 152
 153 Must called from within a `tar-mode' buffer."
 154   (cl-dolist (header tar-parse-info)
 155     (let ((tar-name (tar-header-name header)))
 156       (when (string= tar-name filename)
 157         (cl-return t)))))
 158
 159 (defun package-test-desc-version-string (desc)
 160   "Return the package version as a string."
 161   (package-version-join (package-desc-version desc)))
 162
 163 (ert-deftest package-test-desc-from-buffer ()
 164   "Parse an elisp buffer to get a `package-desc' object."
 165   (with-package-test (:basedir "data/package" :file "simple-single-1.3.el")
 166     (should (equal (package-buffer-info) simple-single-desc)))
 167   (with-package-test (:basedir "data/package" :file "simple-depend-1.0.el")
 168     (should (equal (package-buffer-info) simple-depend-desc)))
 169   (with-package-test (:basedir "data/package"
 170                                :file "multi-file-0.2.3.tar")
 171     (tar-mode)
 172     (should (equal (package-tar-file-info) multi-file-desc))))
 173
 174 (ert-deftest package-test-install-single ()
 175   "Install a single file without using an archive."
 176   (with-package-test (:basedir "data/package" :file "simple-single-1.3.el")
 177     (should (package-install-from-buffer))
 178     (package-initialize)
 179     (should (package-installed-p 'simple-single))
 180     (let* ((simple-pkg-dir (file-name-as-directory
 181                             (expand-file-name
 182                              "simple-single-1.3"
 183                              package-test-user-dir)))
 184            (autoloads-file (expand-file-name "simple-single-autoloads.el"
 185                                              simple-pkg-dir)))
 186       (should (file-directory-p simple-pkg-dir))
 187       (with-temp-buffer
 188         (insert-file-contents (expand-file-name "simple-single-pkg.el"
 189                                                 simple-pkg-dir))
 190         (should (string= (buffer-string)
 191                          (concat ";;; -*- no-byte-compile: t -*-\n"
 192                                  "(define-package \"simple-single\" \"1.3\" "
 193                                  "\"A single-file package "
 194                                  "with no dependencies\" 'nil "
 195                                  ":url \"http://doodles.au\""
 196                                  ")\n"))))
 197       (should (file-exists-p autoloads-file))
 198       (should-not (get-file-buffer autoloads-file)))))
 199
 200 (ert-deftest package-test-install-dependency ()
 201   "Install a package which includes a dependency."
 202   (with-package-test ()
 203     (package-initialize)
 204     (package-refresh-contents)
 205     (package-install 'simple-depend)
 206     (should (package-installed-p 'simple-single))
 207     (should (package-installed-p 'simple-depend))))
 208
 209 (ert-deftest package-test-install-two-dependencies ()
 210   "Install a package which includes a dependency."
 211   (with-package-test ()
 212     (package-initialize)
 213     (package-refresh-contents)
 214     (package-install 'simple-two-depend)
 215     (should (package-installed-p 'simple-single))
 216     (should (package-installed-p 'simple-depend))
 217     (should (package-installed-p 'simple-two-depend))))
 218
 219 (ert-deftest package-test-refresh-contents ()
 220   "Parse an \"archive-contents\" file."
 221   (with-package-test ()
 222     (package-initialize)
 223     (package-refresh-contents)
 224     (should (eq 4 (length package-archive-contents)))))
 225
 226 (ert-deftest package-test-install-single-from-archive ()
 227   "Install a single package from a package archive."
 228   (with-package-test ()
 229     (package-initialize)
 230     (package-refresh-contents)
 231     (package-install 'simple-single)))
 232
 233 (ert-deftest package-test-install-prioritized ()
 234   "Install a lower version from a higher-prioritized archive."
 235   (with-package-test ()
 236     (let* ((newer-version (expand-file-name "data/package/newer-versions"
 237                                             package-test-file-dir))
 238            (package-archives `(("older" . ,package-test-data-dir)
 239                                ("newer" . ,newer-version)))
 240            (package-archive-priorities '(("older" . 100))))
 241
 242       (package-initialize)
 243       (package-refresh-contents)
 244       (package-install 'simple-single)
 245
 246       (let ((installed (cadr (assq 'simple-single package-alist))))
 247         (should (version-list-= '(1 3)
 248                                 (package-desc-version installed)))))))
 249
 250 (ert-deftest package-test-install-multifile ()
 251   "Check properties of the installed multi-file package."
 252   (with-package-test (:basedir "data/package" :install '(multi-file))
 253     (let ((autoload-file
 254            (expand-file-name "multi-file-autoloads.el"
 255                              (expand-file-name
 256                               "multi-file-0.2.3"
 257                               package-test-user-dir)))
 258           (installed-files '("dir" "multi-file.info" "multi-file-sub.elc"
 259                              "multi-file-autoloads.el" "multi-file.elc"))
 260           (autoload-forms '("^(defvar multi-file-custom-var"
 261                             "^(custom-autoload 'multi-file-custom-var"
 262                             "^(autoload 'multi-file-mode"))
 263           (pkg-dir (file-name-as-directory
 264                     (expand-file-name
 265                      "multi-file-0.2.3"
 266                      package-test-user-dir))))
 267       (package-refresh-contents)
 268       (should (package-installed-p 'multi-file))
 269       (with-temp-buffer
 270         (insert-file-contents-literally autoload-file)
 271         (dolist (fn installed-files)
 272           (should (file-exists-p (expand-file-name fn pkg-dir))))
 273         (dolist (re autoload-forms)
 274           (goto-char (point-min))
 275           (should (re-search-forward re nil t)))))))
 276
 277 (ert-deftest package-test-update-listing ()
 278   "Ensure installed package status is updated."
 279   (with-package-test ()
 280     (let ((buf (package-list-packages)))
 281       (search-forward-regexp "^ +simple-single")
 282       (package-menu-mark-install)
 283       (package-menu-execute)
 284       (should (package-installed-p 'simple-single))
 285       (switch-to-buffer "*Packages*")
 286       (goto-char (point-min))
 287       (should (re-search-forward "^\\s-+simple-single\\s-+1.3\\s-+installed" nil t))
 288       (goto-char (point-min))
 289       (should-not (re-search-forward "^\\s-+simple-single\\s-+1.3\\s-+\\(available\\|new\\)" nil t))
 290       (kill-buffer buf))))
 291
 292 (ert-deftest package-test-update-archives ()
 293   "Test updating package archives."
 294   (with-package-test ()
 295     (let ((buf (package-list-packages)))
 296       (package-menu-refresh)
 297       (search-forward-regexp "^ +simple-single")
 298       (package-menu-mark-install)
 299       (package-menu-execute)
 300       (should (package-installed-p 'simple-single))
 301       (let ((package-test-data-dir
 302              (expand-file-name "data/package/newer-versions" package-test-file-dir)))
 303         (setq package-archives `(("gnu" . ,package-test-data-dir)))
 304         (package-menu-refresh)
 305
 306         ;; New version should be available and old version should be installed
 307         (goto-char (point-min))
 308         (should (re-search-forward "^\\s-+simple-single\\s-+1.4\\s-+new" nil t))
 309         (should (re-search-forward "^\\s-+simple-single\\s-+1.3\\s-+installed" nil t))
 310
 311         (goto-char (point-min))
 312         (should (re-search-forward "^\\s-+new-pkg\\s-+1.0\\s-+\\(available\\|new\\)" nil t))
 313
 314         (package-menu-mark-upgrades)
 315         (package-menu-execute)
 316         (package-menu-refresh)
 317         (should (package-installed-p 'simple-single '(1 4)))))))
 318
 319 (ert-deftest package-test-describe-package ()
 320   "Test displaying help for a package."
 321
 322   (require 'finder-inf)
 323   ;; Built-in
 324   (with-fake-help-buffer
 325    (describe-package '5x5)
 326    (goto-char (point-min))
 327    (should (search-forward "5x5 is a built-in package." nil t))
 328    (should (search-forward "Status: Built-in." nil t))
 329    (should (search-forward "Summary: simple little puzzle game" nil t))
 330    (should (search-forward "The aim of 5x5" nil t)))
 331
 332   ;; Installed
 333   (with-package-test ()
 334     (package-initialize)
 335     (package-refresh-contents)
 336     (package-install 'simple-single)
 337     (with-fake-help-buffer
 338      (describe-package 'simple-single)
 339      (goto-char (point-min))
 340      (should (search-forward "simple-single is an installed package." nil t))
 341      (should (search-forward
 342               (format "Status: Installed in `%s/' (unsigned)."
 343                       (expand-file-name "simple-single-1.3" package-user-dir))
 344               nil t))
 345      (should (search-forward "Version: 1.3" nil t))
 346      (should (search-forward "Summary: A single-file package with no dependencies"
 347                              nil t))
 348      (should (search-forward "Homepage: http://doodles.au" nil t))
 349      (should (re-search-forward "Keywords: \\[?frobnicate\\]?" nil t))
 350      ;; No description, though. Because at this point we don't know
 351      ;; what archive the package originated from, and we don't have
 352      ;; its readme file saved.
 353      )))
 354
 355 (ert-deftest package-test-describe-non-installed-package ()
 356   "Test displaying of the readme for non-installed package."
 357
 358   (with-package-test ()
 359     (package-initialize)
 360     (package-refresh-contents)
 361     (with-fake-help-buffer
 362      (describe-package 'simple-single)
 363      (goto-char (point-min))
 364      (should (search-forward "Homepage: http://doodles.au" nil t))
 365      (should (search-forward "This package provides a minor mode to frobnicate"
 366                              nil t)))))
 367
 368 (ert-deftest package-test-describe-non-installed-multi-file-package ()
 369   "Test displaying of the readme for non-installed multi-file package."
 370
 371   (with-package-test ()
 372     (package-initialize)
 373     (package-refresh-contents)
 374     (with-fake-help-buffer
 375      (describe-package 'multi-file)
 376      (goto-char (point-min))
 377      (should (search-forward "Homepage: http://puddles.li" nil t))
 378      (should (search-forward "This is a bare-bones readme file for the multi-file"
 379                              nil t)))))
 380
 381 (ert-deftest package-test-signed ()
 382   "Test verifying package signature."
 383   (skip-unless (ignore-errors
 384                  (let ((homedir (make-temp-file "package-test" t)))
 385                    (unwind-protect
 386                        (let ((process-environment
 387                               (cons (format "HOME=%s" homedir)
 388                                     process-environment)))
 389                          (epg-check-configuration (epg-configuration))
 390                          t)
 391                      (delete-directory homedir t)))))
 392   (let* ((keyring (expand-file-name "key.pub" package-test-data-dir))
 393          (package-test-data-dir
 394            (expand-file-name "data/package/signed" package-test-file-dir)))
 395     (with-package-test ()
 396       (package-initialize)
 397       (package-import-keyring keyring)
 398       (package-refresh-contents)
 399       (should (package-install 'signed-good))
 400       (should-error (package-install 'signed-bad))
 401       ;; Check if the installed package status is updated.
 402       (let ((buf (package-list-packages)))
 403         (package-menu-refresh)
 404         (should (re-search-forward "^\\s-+signed-good\\s-+1\\.0\\s-+installed"
 405                                    nil t)))
 406       ;; Check if the package description is updated.
 407       (with-fake-help-buffer
 408        (describe-package 'signed-good)
 409        (goto-char (point-min))
 410        (should (search-forward "signed-good is an installed package." nil t))
 411        (should (search-forward
 412                 (format "Status: Installed in `%s/'."
 413                         (expand-file-name "signed-good-1.0" package-user-dir))
 414                 nil t))))))
 415
 416
 417 \f
 418 ;;; Tests for package-x features.
 419
 420 (require 'package-x)
 421
 422 (defvar package-x-test--single-archive-entry-1-3
 423   (cons 'simple-single
 424         (package-make-ac-desc '(1 3) nil
 425                               "A single-file package with no dependencies"
 426                               'single
 427                               '((:url . "http://doodles.au"))))
 428   "Expected contents of the archive entry from the \"simple-single\" package.")
 429
 430 (defvar package-x-test--single-archive-entry-1-4
 431   (cons 'simple-single
 432         (package-make-ac-desc '(1 4) nil
 433                               "A single-file package with no dependencies"
 434                               'single
 435                               nil))
 436   "Expected contents of the archive entry from the updated \"simple-single\" package.")
 437
 438 (ert-deftest package-x-test-upload-buffer ()
 439   "Test creating an \"archive-contents\" file"
 440   (with-package-test (:basedir "data/package"
 441                                :file "simple-single-1.3.el"
 442                                :upload-base t)
 443     (package-upload-buffer)
 444     (should (file-exists-p (expand-file-name "archive-contents"
 445                                              package-archive-upload-base)))
 446     (should (file-exists-p (expand-file-name "simple-single-1.3.el"
 447                                              package-archive-upload-base)))
 448     (should (file-exists-p (expand-file-name "simple-single-readme.txt"
 449                                              package-archive-upload-base)))
 450
 451     (let (archive-contents)
 452       (with-temp-buffer
 453         (insert-file-contents
 454          (expand-file-name "archive-contents"
 455                            package-archive-upload-base))
 456         (setq archive-contents
 457               (package-read-from-string
 458                (buffer-substring (point-min) (point-max)))))
 459       (should (equal archive-contents
 460                      (list 1 package-x-test--single-archive-entry-1-3))))))
 461
 462 (ert-deftest package-x-test-upload-new-version ()
 463   "Test uploading a new version of a package"
 464   (with-package-test (:basedir "data/package"
 465                                :file "simple-single-1.3.el"
 466                                :upload-base t)
 467     (package-upload-buffer)
 468     (with-temp-buffer
 469       (insert-file-contents "newer-versions/simple-single-1.4.el")
 470       (package-upload-buffer))
 471
 472     (let (archive-contents)
 473       (with-temp-buffer
 474         (insert-file-contents
 475          (expand-file-name "archive-contents"
 476                            package-archive-upload-base))
 477         (setq archive-contents
 478               (package-read-from-string
 479                (buffer-substring (point-min) (point-max)))))
 480       (should (equal archive-contents
 481                      (list 1 package-x-test--single-archive-entry-1-4))))))
 482
 483 (provide 'package-test)
 484
 485 ;;; package-test.el ends here