code.delx.au - gnu-emacs/blob - test/automated/package-test.el

   1 ;;; package-test.el --- Tests for the Emacs package system
   2
   3 ;; Copyright (C) 2013-2015 Free Software Foundation, Inc.
   4
   5 ;; Author: Daniel Hackney <dan@haxney.org>
   6 ;; Version: 1.0
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; You may want to run this from a separate Emacs instance from your
  26 ;; main one, because a bug in the code below could mess with your
  27 ;; installed packages.
  28
  29 ;; Run this in a clean Emacs session using:
  30 ;;
  31 ;;     $ emacs -Q --batch -L . -l package-test.el -l ert -f ert-run-tests-batch-and-exit
  32
  33 ;;; Code:
  34
  35 (require 'package)
  36 (require 'ert)
  37 (require 'cl-lib)
  38
  39 (defvar package-test-user-dir nil
  40   "Directory to use for installing packages during testing.")
  41
  42 (defvar package-test-file-dir (file-name-directory (or load-file-name
  43                                                        buffer-file-name))
  44   "Directory of the actual \"package-test.el\" file.")
  45
  46 (defvar simple-single-desc
  47   (package-desc-create :name 'simple-single
  48                        :version '(1 3)
  49                        :summary "A single-file package with no dependencies"
  50                        :kind 'single
  51                        :extras '((:url . "http://doodles.au")))
  52   "Expected `package-desc' parsed from simple-single-1.3.el.")
  53
  54 (defvar simple-depend-desc
  55   (package-desc-create :name 'simple-depend
  56                        :version '(1 0)
  57                        :summary "A single-file package with a dependency."
  58                        :kind 'single
  59                        :reqs '((simple-single (1 3))))
  60   "Expected `package-desc' parsed from simple-depend-1.0.el.")
  61
  62 (defvar multi-file-desc
  63   (package-desc-create :name 'multi-file
  64                        :version '(0 2 3)
  65                        :summary "Example of a multi-file tar package"
  66                        :kind 'tar
  67                        :extras '((:url . "http://puddles.li")))
  68   "Expected `package-desc' from \"multi-file-0.2.3.tar\".")
  69
  70 (defvar new-pkg-desc
  71   (package-desc-create :name 'new-pkg
  72                        :version '(1 0)
  73                        :kind 'single)
  74   "Expected `package-desc' parsed from new-pkg-1.0.el.")
  75
  76 (defvar package-test-data-dir (expand-file-name "data/package" package-test-file-dir)
  77   "Base directory of package test files.")
  78
  79 (defvar package-test-fake-contents-file
  80   (expand-file-name "archive-contents" package-test-data-dir)
  81   "Path to a static copy of \"archive-contents\".")
  82
  83 (cl-defmacro with-package-test ((&optional &key file
  84                                            basedir
  85                                            install
  86                                            update-news
  87                                            upload-base)
  88                                 &rest body)
  89   "Set up temporary locations and variables for testing."
  90   (declare (indent 1))
  91   `(let* ((package-test-user-dir (make-temp-file "pkg-test-user-dir-" t))
  92           (process-environment (cons (format "HOME=%s" package-test-user-dir)
  93                                      process-environment))
  94           (package-user-dir package-test-user-dir)
  95           (package-archives `(("gnu" . ,package-test-data-dir)))
  96           (old-yes-no-defn (symbol-function 'yes-or-no-p))
  97           (default-directory package-test-file-dir)
  98           abbreviated-home-dir
  99           package--initialized
 100           package-alist
 101           ,@(if update-news
 102                 '(package-update-news-on-upload t)
 103               (list (cl-gensym)))
 104           ,@(if upload-base
 105                 '((package-test-archive-upload-base (make-temp-file "pkg-archive-base-" t))
 106                   (package-archive-upload-base package-test-archive-upload-base))
 107               (list (cl-gensym)))) ;; Dummy value so `let' doesn't try to bind `nil'
 108      (unwind-protect
 109          (progn
 110            ,(if basedir `(cd ,basedir))
 111            (setf (symbol-function 'yes-or-no-p) #'(lambda (&rest r) t))
 112            (unless (file-directory-p package-user-dir)
 113              (mkdir package-user-dir))
 114            ,@(when install
 115                `((package-initialize)
 116                  (package-refresh-contents)
 117                  (mapc 'package-install ,install)))
 118            (with-temp-buffer
 119              ,(if file
 120                   `(insert-file-contents ,file))
 121              ,@body))
 122
 123        (when (file-directory-p package-test-user-dir)
 124          (delete-directory package-test-user-dir t))
 125
 126        (when (and (boundp 'package-test-archive-upload-base)
 127                   (file-directory-p package-test-archive-upload-base))
 128          (delete-directory package-test-archive-upload-base t))
 129        (setf (symbol-function 'yes-or-no-p) old-yes-no-defn))))
 130
 131 (defmacro with-fake-help-buffer (&rest body)
 132   "Execute BODY in a temp buffer which is treated as the \"*Help*\" buffer."
 133   `(with-temp-buffer
 134     (help-mode)
 135     ;; Trick `help-buffer' into using the temp buffer.
 136     (let ((help-xref-following t))
 137       ,@body)))
 138
 139 (defun package-test-strip-version (dir)
 140   (replace-regexp-in-string "-pkg\\.el\\'" "" (package--description-file dir)))
 141
 142 (defun package-test-suffix-matches (base suffix-list)
 143   "Return file names matching BASE concatenated with each item in SUFFIX-LIST"
 144   (cl-mapcan
 145    '(lambda (item) (file-expand-wildcards (concat base item)))
 146    suffix-list))
 147
 148 (defvar tar-parse-info)
 149 (declare-function tar-header-name "tar-mode" (cl-x) t) ; defstruct
 150
 151 (defun package-test-search-tar-file (filename)
 152   "Search the current buffer's `tar-parse-info' variable for FILENAME.
 153
 154 Must called from within a `tar-mode' buffer."
 155   (cl-dolist (header tar-parse-info)
 156     (let ((tar-name (tar-header-name header)))
 157       (when (string= tar-name filename)
 158         (cl-return t)))))
 159
 160 (defun package-test-desc-version-string (desc)
 161   "Return the package version as a string."
 162   (package-version-join (package-desc-version desc)))
 163
 164 (ert-deftest package-test-desc-from-buffer ()
 165   "Parse an elisp buffer to get a `package-desc' object."
 166   (with-package-test (:basedir "data/package" :file "simple-single-1.3.el")
 167     (should (equal (package-buffer-info) simple-single-desc)))
 168   (with-package-test (:basedir "data/package" :file "simple-depend-1.0.el")
 169     (should (equal (package-buffer-info) simple-depend-desc)))
 170   (with-package-test (:basedir "data/package"
 171                                :file "multi-file-0.2.3.tar")
 172     (tar-mode)
 173     (should (equal (package-tar-file-info) multi-file-desc))))
 174
 175 (ert-deftest package-test-install-single ()
 176   "Install a single file without using an archive."
 177   (with-package-test (:basedir "data/package" :file "simple-single-1.3.el")
 178     (should (package-install-from-buffer))
 179     (package-initialize)
 180     (should (package-installed-p 'simple-single))
 181     (let* ((simple-pkg-dir (file-name-as-directory
 182                             (expand-file-name
 183                              "simple-single-1.3"
 184                              package-test-user-dir)))
 185            (autoloads-file (expand-file-name "simple-single-autoloads.el"
 186                                              simple-pkg-dir)))
 187       (should (file-directory-p simple-pkg-dir))
 188       (with-temp-buffer
 189         (insert-file-contents (expand-file-name "simple-single-pkg.el"
 190                                                 simple-pkg-dir))
 191         (should (string= (buffer-string)
 192                          (concat ";;; -*- no-byte-compile: t -*-\n"
 193                                  "(define-package \"simple-single\" \"1.3\" "
 194                                  "\"A single-file package "
 195                                  "with no dependencies\" 'nil "
 196                                  ":url \"http://doodles.au\""
 197                                  ")\n"))))
 198       (should (file-exists-p autoloads-file))
 199       (should-not (get-file-buffer autoloads-file)))))
 200
 201 (ert-deftest package-test-install-dependency ()
 202   "Install a package which includes a dependency."
 203   (with-package-test ()
 204     (package-initialize)
 205     (package-refresh-contents)
 206     (package-install 'simple-depend)
 207     (should (package-installed-p 'simple-single))
 208     (should (package-installed-p 'simple-depend))))
 209
 210 (ert-deftest package-test-install-two-dependencies ()
 211   "Install a package which includes a dependency."
 212   (with-package-test ()
 213     (package-initialize)
 214     (package-refresh-contents)
 215     (package-install 'simple-two-depend)
 216     (should (package-installed-p 'simple-single))
 217     (should (package-installed-p 'simple-depend))
 218     (should (package-installed-p 'simple-two-depend))))
 219
 220 (ert-deftest package-test-refresh-contents ()
 221   "Parse an \"archive-contents\" file."
 222   (with-package-test ()
 223     (package-initialize)
 224     (package-refresh-contents)
 225     (should (eq 4 (length package-archive-contents)))))
 226
 227 (ert-deftest package-test-install-single-from-archive ()
 228   "Install a single package from a package archive."
 229   (with-package-test ()
 230     (package-initialize)
 231     (package-refresh-contents)
 232     (package-install 'simple-single)))
 233
 234 (ert-deftest package-test-install-prioritized ()
 235   "Install a lower version from a higher-prioritized archive."
 236   (with-package-test ()
 237     (let* ((newer-version (expand-file-name "data/package/newer-versions"
 238                                             package-test-file-dir))
 239            (package-archives `(("older" . ,package-test-data-dir)
 240                                ("newer" . ,newer-version)))
 241            (package-archive-priorities '(("older" . 100))))
 242
 243       (package-initialize)
 244       (package-refresh-contents)
 245       (package-install 'simple-single)
 246
 247       (let ((installed (cadr (assq 'simple-single package-alist))))
 248         (should (version-list-= '(1 3)
 249                                 (package-desc-version installed)))))))
 250
 251 (ert-deftest package-test-install-multifile ()
 252   "Check properties of the installed multi-file package."
 253   (with-package-test (:basedir "data/package" :install '(multi-file))
 254     (let ((autoload-file
 255            (expand-file-name "multi-file-autoloads.el"
 256                              (expand-file-name
 257                               "multi-file-0.2.3"
 258                               package-test-user-dir)))
 259           (installed-files '("dir" "multi-file.info" "multi-file-sub.elc"
 260                              "multi-file-autoloads.el" "multi-file.elc"))
 261           (autoload-forms '("^(defvar multi-file-custom-var"
 262                             "^(custom-autoload 'multi-file-custom-var"
 263                             "^(autoload 'multi-file-mode"))
 264           (pkg-dir (file-name-as-directory
 265                     (expand-file-name
 266                      "multi-file-0.2.3"
 267                      package-test-user-dir))))
 268       (package-refresh-contents)
 269       (should (package-installed-p 'multi-file))
 270       (with-temp-buffer
 271         (insert-file-contents-literally autoload-file)
 272         (dolist (fn installed-files)
 273           (should (file-exists-p (expand-file-name fn pkg-dir))))
 274         (dolist (re autoload-forms)
 275           (goto-char (point-min))
 276           (should (re-search-forward re nil t)))))))
 277
 278 (ert-deftest package-test-update-listing ()
 279   "Ensure installed package status is updated."
 280   (with-package-test ()
 281     (let ((buf (package-list-packages)))
 282       (search-forward-regexp "^ +simple-single")
 283       (package-menu-mark-install)
 284       (package-menu-execute)
 285       (should (package-installed-p 'simple-single))
 286       (switch-to-buffer "*Packages*")
 287       (goto-char (point-min))
 288       (should (re-search-forward "^\\s-+simple-single\\s-+1.3\\s-+installed" nil t))
 289       (goto-char (point-min))
 290       (should-not (re-search-forward "^\\s-+simple-single\\s-+1.3\\s-+\\(available\\|new\\)" nil t))
 291       (kill-buffer buf))))
 292
 293 (ert-deftest package-test-update-archives ()
 294   "Test updating package archives."
 295   (with-package-test ()
 296     (let ((buf (package-list-packages)))
 297       (package-menu-refresh)
 298       (search-forward-regexp "^ +simple-single")
 299       (package-menu-mark-install)
 300       (package-menu-execute)
 301       (should (package-installed-p 'simple-single))
 302       (let ((package-test-data-dir
 303              (expand-file-name "data/package/newer-versions" package-test-file-dir)))
 304         (setq package-archives `(("gnu" . ,package-test-data-dir)))
 305         (package-menu-refresh)
 306
 307         ;; New version should be available and old version should be installed
 308         (goto-char (point-min))
 309         (should (re-search-forward "^\\s-+simple-single\\s-+1.4\\s-+new" nil t))
 310         (should (re-search-forward "^\\s-+simple-single\\s-+1.3\\s-+installed" nil t))
 311
 312         (goto-char (point-min))
 313         (should (re-search-forward "^\\s-+new-pkg\\s-+1.0\\s-+\\(available\\|new\\)" nil t))
 314
 315         (package-menu-mark-upgrades)
 316         (package-menu-execute)
 317         (package-menu-refresh)
 318         (should (package-installed-p 'simple-single '(1 4)))))))
 319
 320 (ert-deftest package-test-describe-package ()
 321   "Test displaying help for a package."
 322
 323   (require 'finder-inf)
 324   ;; Built-in
 325   (with-fake-help-buffer
 326    (describe-package '5x5)
 327    (goto-char (point-min))
 328    (should (search-forward "5x5 is a built-in package." nil t))
 329    (should (search-forward "Status: Built-in." nil t))
 330    (should (search-forward "Summary: simple little puzzle game" nil t))
 331    (should (search-forward "The aim of 5x5" nil t)))
 332
 333   ;; Installed
 334   (with-package-test ()
 335     (package-initialize)
 336     (package-refresh-contents)
 337     (package-install 'simple-single)
 338     (with-fake-help-buffer
 339      (describe-package 'simple-single)
 340      (goto-char (point-min))
 341      (should (search-forward "simple-single is an installed package." nil t))
 342      (should (search-forward
 343               "Status: Installed in `~/simple-single-1.3/' (unsigned)."
 344               nil t))
 345      (should (search-forward "Version: 1.3" nil t))
 346      (should (search-forward "Summary: A single-file package with no dependencies"
 347                              nil t))
 348      (should (search-forward "Homepage: http://doodles.au" nil t))
 349      (should (re-search-forward "Keywords: \\[?frobnicate\\]?" nil t))
 350      ;; No description, though. Because at this point we don't know
 351      ;; what archive the package originated from, and we don't have
 352      ;; its readme file saved.
 353      )))
 354
 355 (ert-deftest package-test-describe-non-installed-package ()
 356   "Test displaying of the readme for non-installed package."
 357
 358   (with-package-test ()
 359     (package-initialize)
 360     (package-refresh-contents)
 361     (with-fake-help-buffer
 362      (describe-package 'simple-single)
 363      (goto-char (point-min))
 364      (should (search-forward "Homepage: http://doodles.au" nil t))
 365      (should (search-forward "This package provides a minor mode to frobnicate"
 366                              nil t)))))
 367
 368 (ert-deftest package-test-describe-non-installed-multi-file-package ()
 369   "Test displaying of the readme for non-installed multi-file package."
 370
 371   (with-package-test ()
 372     (package-initialize)
 373     (package-refresh-contents)
 374     (with-fake-help-buffer
 375      (describe-package 'multi-file)
 376      (goto-char (point-min))
 377      (should (search-forward "Homepage: http://puddles.li" nil t))
 378      (should (search-forward "This is a bare-bones readme file for the multi-file"
 379                              nil t)))))
 380
 381 (ert-deftest package-test-signed ()
 382   "Test verifying package signature."
 383   (skip-unless (ignore-errors
 384                  (let ((homedir (make-temp-file "package-test" t)))
 385                    (unwind-protect
 386                        (let ((process-environment
 387                               (cons (format "HOME=%s" homedir)
 388                                     process-environment)))
 389                          (epg-check-configuration (epg-configuration))
 390                          t)
 391                      (delete-directory homedir t)))))
 392   (let* ((keyring (expand-file-name "key.pub" package-test-data-dir))
 393          (package-test-data-dir
 394            (expand-file-name "data/package/signed" package-test-file-dir)))
 395     (with-package-test ()
 396       (package-initialize)
 397       (package-import-keyring keyring)
 398       (package-refresh-contents)
 399       (should (package-install 'signed-good))
 400       (should-error (package-install 'signed-bad))
 401       ;; Check if the installed package status is updated.
 402       (let ((buf (package-list-packages)))
 403         (package-menu-refresh)
 404         (should (re-search-forward "^\\s-+signed-good\\s-+1\\.0\\s-+installed"
 405                                    nil t)))
 406       ;; Check if the package description is updated.
 407       (with-fake-help-buffer
 408        (describe-package 'signed-good)
 409        (goto-char (point-min))
 410        (should (search-forward "signed-good is an installed package." nil t))
 411        (should (search-forward
 412                 "Status: Installed in `~/signed-good-1.0/'."
 413                 nil t))))))
 414
 415
 416 \f
 417 ;;; Tests for package-x features.
 418
 419 (require 'package-x)
 420
 421 (defvar package-x-test--single-archive-entry-1-3
 422   (cons 'simple-single
 423         (package-make-ac-desc '(1 3) nil
 424                               "A single-file package with no dependencies"
 425                               'single
 426                               '((:url . "http://doodles.au"))))
 427   "Expected contents of the archive entry from the \"simple-single\" package.")
 428
 429 (defvar package-x-test--single-archive-entry-1-4
 430   (cons 'simple-single
 431         (package-make-ac-desc '(1 4) nil
 432                               "A single-file package with no dependencies"
 433                               'single
 434                               nil))
 435   "Expected contents of the archive entry from the updated \"simple-single\" package.")
 436
 437 (ert-deftest package-x-test-upload-buffer ()
 438   "Test creating an \"archive-contents\" file"
 439   (with-package-test (:basedir "data/package"
 440                                :file "simple-single-1.3.el"
 441                                :upload-base t)
 442     (package-upload-buffer)
 443     (should (file-exists-p (expand-file-name "archive-contents"
 444                                              package-archive-upload-base)))
 445     (should (file-exists-p (expand-file-name "simple-single-1.3.el"
 446                                              package-archive-upload-base)))
 447     (should (file-exists-p (expand-file-name "simple-single-readme.txt"
 448                                              package-archive-upload-base)))
 449
 450     (let (archive-contents)
 451       (with-temp-buffer
 452         (insert-file-contents
 453          (expand-file-name "archive-contents"
 454                            package-archive-upload-base))
 455         (setq archive-contents
 456               (package-read-from-string
 457                (buffer-substring (point-min) (point-max)))))
 458       (should (equal archive-contents
 459                      (list 1 package-x-test--single-archive-entry-1-3))))))
 460
 461 (ert-deftest package-x-test-upload-new-version ()
 462   "Test uploading a new version of a package"
 463   (with-package-test (:basedir "data/package"
 464                                :file "simple-single-1.3.el"
 465                                :upload-base t)
 466     (package-upload-buffer)
 467     (with-temp-buffer
 468       (insert-file-contents "newer-versions/simple-single-1.4.el")
 469       (package-upload-buffer))
 470
 471     (let (archive-contents)
 472       (with-temp-buffer
 473         (insert-file-contents
 474          (expand-file-name "archive-contents"
 475                            package-archive-upload-base))
 476         (setq archive-contents
 477               (package-read-from-string
 478                (buffer-substring (point-min) (point-max)))))
 479       (should (equal archive-contents
 480                      (list 1 package-x-test--single-archive-entry-1-4))))))
 481
 482 (provide 'package-test)
 483
 484 ;;; package-test.el ends here