code.delx.au - gnu-emacs/blob - configure.ac

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the 'configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl If you changed any AC_DEFINES, also run autoheader.
   6 dnl
   7 dnl Copyright (C) 1994-1996, 1999-2016 Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation, either version 3 of the License, or
  14 dnl  (at your option) any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 AC_PREREQ(2.65)
  25 dnl Note this is parsed by (at least) make-dist and lisp/cedet/ede/emacs.el.
  26 AC_INIT(GNU Emacs, 25.1.50, bug-gnu-emacs@gnu.org)
  27
  28 dnl Set emacs_config_options to the options of 'configure', quoted for the shell,
  29 dnl and then quoted again for a C string.  Separate options with spaces.
  30 dnl Add some environment variables, if they were passed via the environment
  31 dnl rather than on the command-line.
  32 emacs_config_options=
  33 optsep=
  34 dnl This is the documented way to record the args passed to configure,
  35 dnl rather than $ac_configure_args.
  36 for opt in "$@" CFLAGS CPPFLAGS LDFLAGS; do
  37   case $opt in
  38     -n | --no-create | --no-recursion)
  39       continue ;;
  40     CFLAGS | CPPFLAGS | LDFLAGS)
  41       eval 'test "${'$opt'+set}" = set' || continue
  42       case " $*" in
  43         *" $opt="*) continue ;;
  44       esac
  45       eval opt=$opt=\$$opt ;;
  46   esac
  47
  48   emacs_shell_specials=$IFS\''"#$&()*;<>?@<:@\\`{|~'
  49   case $opt in
  50     *[["$emacs_shell_specials"]]*)
  51       case $opt in
  52         *\'*)
  53           emacs_quote_apostrophes="s/'/'\\\\''/g"
  54           opt=`AS_ECHO(["$opt"]) | sed "$emacs_quote_apostrophes"` ;;
  55       esac
  56       opt="'$opt'"
  57       case $opt in
  58         *[['"\\']]*)
  59           emacs_quote_for_c='s/[["\\]]/\\&/g; $!s/$/\\n\\/'
  60           opt=`AS_ECHO(["$opt"]) | sed "$emacs_quote_for_c"` ;;
  61       esac ;;
  62   esac
  63   AS_VAR_APPEND([emacs_config_options], ["$optsep$opt"])
  64   optsep=' '
  65 done
  66
  67 AC_CONFIG_HEADERS(src/config.h:src/config.in)
  68 AC_CONFIG_SRCDIR(src/lisp.h)
  69 AC_CONFIG_AUX_DIR(build-aux)
  70 dnl automake 1.13 and later understand this, making -I m4 unnecessary.
  71 dnl With older versions this is a no-op.
  72 AC_CONFIG_MACRO_DIR(m4)
  73
  74 xcsdkdir=
  75 AC_CHECK_PROGS(XCRUN, [xcrun])
  76 if test -n "$XCRUN"; then
  77   if test -z "$MAKE"; then
  78     dnl Call the variable MAKE_PROG, not MAKE, to avoid confusion with
  79     dnl the usual MAKE variable that 'make' itself uses.
  80     AC_CHECK_PROG([MAKE_PROG], [make], [yes])
  81     if test -z "$MAKE_PROG"; then
  82       MAKE="$XCRUN MAKE"
  83       export MAKE
  84       xcsdkdir=`$XCRUN --show-sdk-path 2>/dev/null`
  85     fi
  86   fi
  87 fi
  88
  89 dnl GNU Make is required, so don't test for its individual features.
  90 am_cv_make_support_nested_variables=yes
  91 AC_DEFUN([AC_PROG_MAKE_SET],
  92   [SET_MAKE=
  93    AC_SUBST([SET_MAKE])])
  94
  95 dnl Check for GNU Make and possibly set MAKE before running AM_INIT_AUTOMAKE.
  96 [emacs_check_gnu_make ()
  97 {
  98   emacs_makeout=`($1 --version) 2>/dev/null` &&
  99   case $emacs_makeout in
 100     'GNU Make '3.8[1-9]* | 'GNU Make '3.9[0-9]* | \
 101     'GNU Make '3.[1-9][0-9][0-9]* | 'GNU Make '[4-9]* | 'GNU Make '[1-9][0-9]* )
 102        ac_path_MAKE_found=:;;
 103   esac
 104 }]
 105 AC_CACHE_CHECK([for GNU Make], [ac_cv_path_MAKE],
 106   [ac_path_MAKE_found=false
 107    if test -n "$MAKE"; then
 108      emacs_check_gnu_make "$MAKE"
 109      ac_cv_path_MAKE=$MAKE
 110    else
 111      emacs_tried_make=false
 112      emacs_tried_gmake=false
 113      emacs_tried_gnumake=false
 114      AC_PATH_PROGS_FEATURE_CHECK([MAKE], [make gmake gnumake],
 115        [[emacs_check_gnu_make "$ac_path_MAKE"
 116          if $ac_path_MAKE_found; then
 117            # Use the fully-qualified program name only if the basename
 118            # would not resolve to it.
 119            if eval \$emacs_tried_$ac_prog; then
 120              ac_cv_path_MAKE=$ac_path_MAKE
 121            else
 122              ac_cv_path_MAKE=$ac_prog
 123            fi
 124          fi
 125          eval emacs_tried_$ac_prog=:]])
 126    fi])
 127 $ac_path_MAKE_found || {
 128 AC_MSG_ERROR([[Building Emacs requires GNU Make, at least version 3.81.
 129 If you have it installed under another name, configure with 'MAKE=...'.
 130 For example, run '$0 MAKE=gnu-make'.]])
 131 }
 132 MAKE=$ac_cv_path_MAKE
 133 export MAKE
 134
 135 dnl Fairly arbitrary, older versions might work too.
 136 AM_INIT_AUTOMAKE(1.11)
 137
 138 dnl Canonicalize the configuration name.
 139 AC_CANONICAL_HOST
 140
 141 case $host in
 142  *-mingw*)
 143
 144   if test -z "$host_alias"; then
 145
 146       # No --host argument was given to 'configure'; therefore $host
 147       # was set to a default value based on the build platform.  But
 148       # this default value may be wrong if we are building from a
 149       # 64-bit MSYS[2] pre-configured to build 32-bit MinGW programs.
 150       # Therefore, we'll try to get the right host platform from the
 151       # compiler's target.
 152
 153       AC_MSG_CHECKING([the compiler's target])
 154       if test -z "$CC"; then
 155           cc=gcc
 156       else
 157           cc=$CC
 158       fi
 159       cc_target=`$cc -v 2>&1 | sed -n 's/Target: //p'`
 160       case "$cc_target" in
 161           *-*) host=$cc_target
 162               ;;
 163           "") AC_MSG_ERROR([Impossible to obtain $cc compiler target.
 164 Please explicitly provide --host.])
 165               ;;
 166           *) AC_MSG_WARN([Compiler reported non-standard target.
 167 Defaulting to $host.])
 168               ;;
 169       esac
 170       AC_MSG_RESULT([$host])
 171   fi
 172
 173   . $srcdir/nt/mingw-cfg.site
 174
 175   case $srcdir in
 176     /* | ?:*)
 177       # srcdir is an absolute path.  In this case, force the format
 178       # "/c/foo/bar", to simplify later conversions to native Windows
 179       # format ("c:/foo/bar").
 180       srcdir=`cd "${srcdir}" && pwd -W`
 181       # 'eval' pacifies strict POSIX non-MinGW shells (Bug#18612).
 182       eval 'srcdir="/${srcdir:0:1}${srcdir:2}"'
 183       ;;
 184   esac;;
 185 esac
 186
 187 canonical=$host
 188 configuration=${host_alias-${build_alias-$host}}
 189
 190 dnl Support for --program-prefix, --program-suffix and
 191 dnl --program-transform-name options
 192 AC_ARG_PROGRAM
 193
 194 dnl It is important that variables on the RHS not be expanded here,
 195 dnl hence the single quotes.  This is per the GNU coding standards, see
 196 dnl (autoconf) Installation Directory Variables
 197 dnl See also epaths.h below.
 198 lispdir='${datadir}/emacs/${version}/lisp'
 199 standardlisppath='${lispdir}'
 200 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
 201 '${datadir}/emacs/site-lisp'
 202 lisppath='${locallisppath}:${standardlisppath}'
 203 etcdir='${datadir}/emacs/${version}/etc'
 204 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
 205 etcdocdir='${datadir}/emacs/${version}/etc'
 206 gamedir='${localstatedir}/games/emacs'
 207
 208 dnl Special option to disable the most of other options.
 209 AC_ARG_WITH(all,
 210 [AS_HELP_STRING([--without-all],
 211                 [omit almost all features and build
 212                 small executable with minimal dependencies])],
 213   [with_features=$withval],
 214   [with_features=yes])
 215
 216 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
 217 dnl Create a new --with option that defaults to being disabled.
 218 dnl NAME is the base name of the option.  The shell variable with_NAME
 219 dnl   will be set to either the user's value (if the option is
 220 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
 221 dnl   option is not specified).  Note that the shell variable name is
 222 dnl   constructed as autoconf does, by replacing non-alphanumeric
 223 dnl   characters with "_".
 224 dnl HELP-STRING is the help text for the option.
 225 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
 226   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
 227     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
 228 ])dnl
 229
 230 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
 231 dnl Create a new --with option that defaults to $with_features.
 232 dnl NAME is the base name of the option.  The shell variable with_NAME
 233 dnl   will be set either to 'no' (for a plain --without-NAME) or to
 234 dnl   'yes' (if the option is not specified).  Note that the shell
 235 dnl   variable name is constructed as autoconf does, by replacing
 236 dnl   non-alphanumeric characters with "_".
 237 dnl HELP-STRING is the help text for the option.
 238 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
 239   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
 240    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=$with_features])dnl
 241 ])dnl
 242
 243 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
 244 if test "$with_pop" = yes; then
 245    AC_DEFINE(MAIL_USE_POP)
 246 fi
 247 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
 248
 249 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
 250 if test "$with_kerberos" != no; then
 251    AC_DEFINE(KERBEROS)
 252 fi
 253 AH_TEMPLATE(KERBEROS,
 254             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
 255
 256 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
 257 if test "${with_kerberos5}" != no; then
 258   if test "${with_kerberos}" = no; then
 259     with_kerberos=yes
 260     AC_DEFINE(KERBEROS)
 261   fi
 262   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
 263 fi
 264
 265 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
 266 dnl FIXME hesiod support may not be present, so it seems like an error
 267 dnl to define, or at least use, this unconditionally.
 268 if test "$with_hesiod" != no; then
 269   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
 270 fi
 271
 272 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
 273 if test "$with_mail_unlink" != no; then
 274    AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
 275 fi
 276
 277 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
 278     [string giving default POP mail host])],
 279     AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
 280
 281 AC_ARG_WITH([sound],[AS_HELP_STRING([--with-sound=VALUE],
 282   [compile with sound support (VALUE one of: yes, alsa, oss, bsd-ossaudio, no;
 283 default yes).  Only for GNU/Linux, FreeBSD, NetBSD, MinGW, Cygwin.])],
 284   [ case "${withval}" in
 285       yes|no|alsa|oss|bsd-ossaudio) val=$withval ;;
 286       *) AC_MSG_ERROR(['--with-sound=$withval' is invalid;
 287 this option's value should be 'yes', 'no', 'alsa', 'oss', or 'bsd-ossaudio'.])
 288       ;;
 289     esac
 290     with_sound=$val
 291   ],
 292   [with_sound=$with_features])
 293
 294 dnl FIXME currently it is not the last.
 295 dnl This should be the last --with option, because --with-x is
 296 dnl added later on when we find the file name of X, and it's best to
 297 dnl keep them together visually.
 298 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 299  [use an X toolkit (KIT one of: yes or gtk, gtk2, gtk3, lucid or athena, motif, no)])],
 300 [         case "${withval}" in
 301             y | ye | yes )      val=gtk ;;
 302             n | no )            val=no  ;;
 303             l | lu | luc | luci | lucid )       val=lucid ;;
 304             a | at | ath | athe | athen | athena )      val=athena ;;
 305             m | mo | mot | moti | motif )       val=motif ;;
 306             g | gt | gtk  )     val=gtk ;;
 307             gtk2  )     val=gtk2 ;;
 308             gtk3  )     val=gtk3 ;;
 309             * )
 310 AC_MSG_ERROR(['--with-x-toolkit=$withval' is invalid;
 311 this option's value should be 'yes', 'no', 'lucid', 'athena', 'motif', 'gtk',
 312 'gtk2' or 'gtk3'.  'yes' and 'gtk' are synonyms.
 313 'athena' and 'lucid' are synonyms.])
 314             ;;
 315           esac
 316           with_x_toolkit=$val
 317 ])
 318
 319 OPTION_DEFAULT_OFF([wide-int], [prefer wide Emacs integers (typically 62-bit); allows buffer and string size up to 2GB on 32-bit hosts, at the cost of 10% to 30% slowdown of Lisp interpreter and larger memory footprint])
 320 if test "$with_wide_int" = yes; then
 321   AC_DEFINE([WIDE_EMACS_INT], 1, [Use long long for EMACS_INT if available.])
 322 fi
 323
 324 dnl _ON results in a '--without' option in the --help output, so
 325 dnl the help text should refer to "don't compile", etc.
 326 with_xpm_set=${with_xpm+set}
 327 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 328 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 329 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 330 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 331 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 332 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 333 OPTION_DEFAULT_ON([libsystemd],[don't compile with libsystemd support])
 334 OPTION_DEFAULT_OFF([cairo],[compile with Cairo drawing (experimental)])
 335 OPTION_DEFAULT_ON([xml2],[don't compile with XML parsing support])
 336 OPTION_DEFAULT_ON([imagemagick],[don't compile with ImageMagick image support])
 337
 338 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 339 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 340 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 341
 342 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 343 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 344 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 345 AC_ARG_WITH([ns],[AS_HELP_STRING([--with-ns],
 346 [use Nextstep (OS X Cocoa or GNUstep) windowing system.
 347 On by default on Mac OS X.])],[],[with_ns=maybe])
 348 OPTION_DEFAULT_OFF([w32], [use native MS Windows GUI in a Cygwin build])
 349
 350 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 351 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 352 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 353 OPTION_DEFAULT_ON([gsettings],[don't compile with GSettings support])
 354 OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support])
 355 OPTION_DEFAULT_ON([gnutls],[don't use -lgnutls for SSL/TLS support])
 356 OPTION_DEFAULT_ON([zlib],[don't compile with zlib decompression support])
 357 OPTION_DEFAULT_OFF([modules],[compile with dynamic modules support])
 358
 359 AC_ARG_WITH([file-notification],[AS_HELP_STRING([--with-file-notification=LIB],
 360  [use a file notification library (LIB one of: yes, inotify, kqueue, gfile, w32, no)])],
 361  [ case "${withval}" in
 362     y | ye | yes )      val=yes ;;
 363     n | no )            val=no  ;;
 364     i | in | ino | inot | inoti | inotif | inotify )    val=inotify ;;
 365     k | kq | kqu | kque | kqueu | kqueue )      val=kqueue ;;
 366     g | gf | gfi | gfil | gfile )       val=gfile ;;
 367     w | w3 | w32 )      val=w32 ;;
 368     * ) AC_MSG_ERROR(['--with-file-notification=$withval' is invalid;
 369 this option's value should be 'yes', 'no', 'inotify', 'kqueue', 'gfile' or 'w32'.
 370 'yes' is a synonym for 'w32' on MS-Windows, for 'no' on Nextstep,
 371 otherwise for the first of 'inotify', 'kqueue' or 'gfile' that is usable.])
 372     ;;
 373    esac
 374    with_file_notification=$val
 375  ],
 376  [with_file_notification=$with_features])
 377
 378 OPTION_DEFAULT_OFF([xwidgets],
 379   [enable use of some gtk widgets in Emacs buffers (requires gtk3)])
 380
 381 ## For the times when you want to build Emacs but don't have
 382 ## a suitable makeinfo, and can live without the manuals.
 383 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 384 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 385
 386 ## This might be a 'configure' arg.
 387 AC_SUBST([ACLOCAL_PATH])
 388
 389 ## Makefile.in needs the cache file name.
 390 AC_SUBST(cache_file)
 391
 392 ## This is an option because I do not know if all info/man support
 393 ## compressed files, nor how to test if they do so.
 394 OPTION_DEFAULT_ON([compress-install],
 395   [don't compress some files (.el, .info, etc.) when installing.  Equivalent to:
 396 make GZIP_PROG= install])
 397
 398 AC_ARG_WITH(gameuser,dnl
 399 [AS_HELP_STRING([--with-gameuser=USER_OR_GROUP],
 400                 [user for shared game score files.
 401                 An argument prefixed by ':' specifies a group instead.])])
 402 gameuser=
 403 gamegroup=
 404 # We don't test if we can actually chown/chgrp here, because configure
 405 # may run without root privileges.  lib-src/Makefile.in will handle
 406 # any errors due to missing user/group gracefully.
 407 case ${with_gameuser} in
 408   no) ;;
 409   "" | yes) gamegroup=games ;;
 410   :*) gamegroup=${with_gameuser#:} ;;
 411   *) gameuser=${with_gameuser} ;;
 412 esac
 413
 414 AC_ARG_WITH([gnustep-conf],dnl
 415 [AS_HELP_STRING([--with-gnustep-conf=FILENAME],
 416    [name of GNUstep configuration file to use on systems where the command
 417     'gnustep-config' does not work; default $GNUSTEP_CONFIG_FILE, or
 418     /etc/GNUstep/GNUstep.conf])])
 419 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 420   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 421 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 422      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 423
 424 AC_ARG_ENABLE(ns-self-contained,
 425 [AS_HELP_STRING([--disable-ns-self-contained],
 426                 [disable self contained build under NeXTstep])],
 427    EN_NS_SELF_CONTAINED=$enableval,
 428    EN_NS_SELF_CONTAINED=yes)
 429
 430 locallisppathset=no
 431 AC_ARG_ENABLE(locallisppath,
 432 [AS_HELP_STRING([--enable-locallisppath=PATH],
 433                 [directories Emacs should search for lisp files specific
 434                  to this site])],
 435 if test "${enableval}" = "no"; then
 436   locallisppath=
 437 elif test "${enableval}" != "yes"; then
 438   locallisppath=${enableval} locallisppathset=yes
 439 fi)
 440
 441 AC_ARG_ENABLE(checking,
 442 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 443                 [enable expensive run-time checks.  With LIST,
 444                  enable only specific categories of checks.
 445                  Categories are: all,yes,no.
 446                  Flags are: stringbytes, stringoverrun, stringfreelist,
 447                  xmallocoverrun, conslist, glyphs])],
 448 [ac_checking_flags="${enableval}"],[])
 449 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 450 for check in $ac_checking_flags
 451 do
 452         case $check in
 453         # these set all the flags to specific states
 454         yes)            ac_enable_checking=1 ;;
 455         no)             ac_enable_checking= ;
 456                         ac_gc_check_stringbytes= ;
 457                         ac_gc_check_string_overrun= ;
 458                         ac_gc_check_string_free_list= ;
 459                         ac_xmalloc_overrun= ;
 460                         ac_gc_check_cons_list= ;
 461                         ac_glyphs_debug= ;;
 462         all)            ac_enable_checking=1 ;
 463                         ac_gc_check_stringbytes=1 ;
 464                         ac_gc_check_string_overrun=1 ;
 465                         ac_gc_check_string_free_list=1 ;
 466                         ac_xmalloc_overrun=1 ;
 467                         ac_gc_check_cons_list=1 ;
 468                         ac_glyphs_debug=1 ;;
 469         # these enable particular checks
 470         stringbytes)    ac_gc_check_stringbytes=1 ;;
 471         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 472         stringfreelist) ac_gc_check_string_free_list=1 ;;
 473         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 474         conslist)       ac_gc_check_cons_list=1 ;;
 475         glyphs)         ac_glyphs_debug=1 ;;
 476         *)      AC_MSG_ERROR(unknown check category $check) ;;
 477         esac
 478 done
 479 IFS="$ac_save_IFS"
 480
 481 if test x$ac_enable_checking != x ; then
 482   AC_DEFINE(ENABLE_CHECKING, 1,
 483 [Define to 1 if expensive run-time data type and consistency checks are enabled.])
 484 fi
 485 if test x$ac_gc_check_stringbytes != x ; then
 486   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 487 [Define this temporarily to hunt a bug.  If defined, the size of
 488    strings is redundantly recorded in sdata structures so that it can
 489    be compared to the sizes recorded in Lisp strings.])
 490 fi
 491 if test x$ac_gc_check_string_overrun != x ; then
 492   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 493 [Define this to check for short string overrun.])
 494 fi
 495 if test x$ac_gc_check_string_free_list != x ; then
 496   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 497 [Define this to check the string free list.])
 498 fi
 499 if test x$ac_xmalloc_overrun != x ; then
 500   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 501 [Define this to check for malloc buffer overrun.])
 502 fi
 503 if test x$ac_gc_check_cons_list != x ; then
 504   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 505 [Define this to check for errors in cons list.])
 506 fi
 507 if test x$ac_glyphs_debug != x ; then
 508   AC_DEFINE(GLYPH_DEBUG, 1,
 509 [Define this to enable glyphs debugging code.])
 510 fi
 511
 512 AC_ARG_ENABLE(check-lisp-object-type,
 513 [AS_HELP_STRING([--enable-check-lisp-object-type],
 514                 [enable compile time checks for the Lisp_Object data type.
 515                 This is useful for development for catching certain types of bugs.])],
 516 if test "${enableval}" != "no"; then
 517    AC_DEFINE(CHECK_LISP_OBJECT_TYPE, 1,
 518    [Define this to enable compile time checks for the Lisp_Object data type.])
 519 fi)
 520
 521
 522 dnl The name of this option is unfortunate.  It predates, and has no
 523 dnl relation to, the "sampling-based elisp profiler" added in 24.3.
 524 dnl Actually, it stops it working.
 525 dnl http://lists.gnu.org/archive/html/emacs-devel/2012-11/msg00393.html
 526 AC_ARG_ENABLE(profiling,
 527 [AS_HELP_STRING([--enable-profiling],
 528                 [build emacs with low-level, gprof profiling support.
 529                 Mainly useful for debugging Emacs itself.  May not work on
 530                 all platforms.  Stops profiler.el working.])],
 531 [ac_enable_profiling="${enableval}"],[])
 532 if test x$ac_enable_profiling != x ; then
 533    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 534 else
 535    PROFILING_CFLAGS=
 536 fi
 537 AC_SUBST(PROFILING_CFLAGS)
 538
 539 AC_ARG_ENABLE(autodepend,
 540 [AS_HELP_STRING([--enable-autodepend],
 541                 [automatically generate dependencies to .h-files.
 542                  Requires gcc, enabled if found.])],
 543 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 544
 545 AC_ARG_ENABLE(gtk-deprecation-warnings,
 546 [AS_HELP_STRING([--enable-gtk-deprecation-warnings],
 547                 [Show Gtk+/Gdk deprecation warnings for Gtk+ >= 3.0])],
 548 [ac_enable_gtk_deprecation_warnings="${enableval}"],[])
 549
 550 BUILD_DETAILS=
 551 AC_ARG_ENABLE([build-details],
 552   [AS_HELP_STRING([--disable-build-details],
 553                   [Make the build more deterministic by omitting host
 554                    names, time stamps, etc. from the output.])],
 555   [test "$enableval" = no && BUILD_DETAILS=--no-build-details])
 556 AC_SUBST([BUILD_DETAILS])
 557
 558 dnl This used to use changequote, but, apart from 'changequote is evil'
 559 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 560 dnl the great gob of text.  Thus it's not processed for possible expansion.
 561 dnl Just make sure the brackets remain balanced.
 562 dnl
 563 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 564 dnl indicated by comments.
 565 dnl quotation begins
 566 [
 567
 568 ### If you add support for a new configuration, add code to this
 569 ### switch statement to recognize your configuration name and select
 570 ### the appropriate opsys.
 571
 572 ### As far as handling version numbers on operating systems is
 573 ### concerned, make sure things will fail in a fixable way.  If
 574 ### /etc/MACHINES doesn't say anything about version numbers, be
 575 ### prepared to handle anything reasonably.  If version numbers
 576 ### matter, be sure /etc/MACHINES says something about it.
 577
 578 opsys='' unported=no
 579 case "${canonical}" in
 580
 581   ## GNU/Linux and similar ports
 582   *-*-linux* )
 583     opsys=gnu-linux
 584   ;;
 585
 586   ## FreeBSD ports
 587   *-*-freebsd* )
 588     opsys=freebsd
 589   ;;
 590
 591   ## DragonFly ports
 592   *-*-dragonfly* )
 593     opsys=dragonfly
 594   ;;
 595
 596   ## FreeBSD kernel + glibc based userland
 597   *-*-kfreebsd*gnu* )
 598     opsys=gnu-kfreebsd
 599   ;;
 600
 601   ## NetBSD ports
 602   *-*-netbsd* )
 603     opsys=netbsd
 604   ;;
 605
 606   ## OpenBSD ports
 607   *-*-openbsd* | *-*-mirbsd* )
 608     opsys=openbsd
 609   ;;
 610
 611   ## Apple Darwin / Mac OS X
 612   *-apple-darwin* )
 613     case "${canonical}" in
 614       *-apple-darwin[0-9].*) unported=yes ;;
 615       i[3456]86-* | x86_64-* )  ;;
 616       * )            unported=yes ;;
 617     esac
 618     opsys=darwin
 619     ## FIXME: Find a way to use Fink if available (Bug#11507).
 620   ;;
 621
 622   ## Chromium Native Client
 623   *-nacl )
 624     opsys=nacl
 625   ;;
 626
 627   ## Cygwin ports
 628   *-*-cygwin )
 629     opsys=cygwin
 630   ;;
 631
 632   ## HP 9000 series 700 and 800, running HP/UX
 633   hppa*-hp-hpux10.2* )
 634     opsys=hpux10-20
 635   ;;
 636   hppa*-hp-hpux1[1-9]* )
 637     opsys=hpux11
 638     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 639   ;;
 640
 641   ## IBM machines
 642   rs6000-ibm-aix4.[23]* )
 643     opsys=aix4-2
 644   ;;
 645   powerpc-ibm-aix4.[23]*  )
 646     opsys=aix4-2
 647   ;;
 648   rs6000-ibm-aix[56]* )
 649     opsys=aix4-2
 650   ;;
 651   powerpc-ibm-aix[5-9]* | powerpc-ibm-aix[1-9][0-9]* )
 652     opsys=aix4-2
 653   ;;
 654
 655   ## Suns
 656   *-sun-solaris* \
 657     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 658     | x86_64-*-solaris2*    | x86_64-*-sunos5*)
 659     case "${canonical}" in
 660       i[3456]86-*-* )   ;;
 661       amd64-*-*|x86_64-*-*) ;;
 662       sparc* )          ;;
 663       * )               unported=yes ;;
 664     esac
 665     case "${canonical}" in
 666       *-sunos5.[1-9][0-9]* | *-solaris2.[1-9][0-9]* )
 667                 opsys=sol2-10
 668                 emacs_check_sunpro_c=yes
 669                 ;;
 670       *-sunos5.[1-5]* | *-solaris2.[1-5]* ) unported=yes ;;
 671       ## Note that Emacs 23.1's NEWS said the following would be dropped.
 672       *-sunos5.6* | *-solaris2.6* )
 673                 opsys=sol2-6
 674                 RANLIB="ar -ts"
 675                 ;;
 676       ## 5.7 EOL Aug 2008, 5.8 EOL Mar 2012.
 677       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 678                 opsys=sol2-6
 679                 emacs_check_sunpro_c=yes
 680                 ;;
 681     esac
 682     ## Watch out for a compiler that we know will not work.
 683     case "${canonical}" in
 684      *-solaris* | *-sunos5* )
 685                 if [ "x$CC" = x/usr/ucb/cc ]; then
 686                   ## /usr/ucb/cc doesn't work;
 687                   ## we should find some other compiler that does work.
 688                   unset CC
 689                 fi
 690                 ;;
 691       *) ;;
 692     esac
 693   ;;
 694
 695   ## Intel 386 machines where we don't care about the manufacturer.
 696   i[3456]86-*-* )
 697     case "${canonical}" in
 698       *-darwin* )               opsys=darwin ;;
 699       *-mingw* )
 700                 opsys=mingw32
 701                 # MinGW overrides and adds some system headers in nt/inc.
 702                 GCC_TEST_OPTIONS="-I $srcdir/nt/inc"
 703                 ;;
 704       *-sysv4.2uw* )            opsys=unixware ;;
 705       *-sysv5uw* )              opsys=unixware ;;
 706       *-sysv5OpenUNIX* )        opsys=unixware ;;
 707       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 708     esac
 709   ;;
 710
 711   # MinGW64
 712   x86_64-*-* )
 713     case "${canonical}" in
 714       *-mingw* )
 715                 opsys=mingw32
 716                 # MinGW overrides and adds some system headers in nt/inc.
 717                 GCC_TEST_OPTIONS="-I $srcdir/nt/inc"
 718                 ;;
 719       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 720     esac
 721   ;;
 722
 723   * )
 724     unported=yes
 725   ;;
 726 esac
 727
 728 ### If the code above didn't choose an operating system, just choose
 729 ### an operating system based on the configuration name.  You really
 730 ### only want to use this when you have no idea what the right
 731 ### operating system is; if you know what operating systems a machine
 732 ### runs, it's cleaner to make it explicit in the case statement
 733 ### above.
 734 if test x"${opsys}" = x; then
 735   case "${canonical}" in
 736     *-gnu* )                            opsys=gnu ;;
 737     * )
 738       unported=yes
 739     ;;
 740   esac
 741 fi
 742
 743 ]
 744 dnl quotation ends
 745
 746 if test $unported = yes; then
 747   AC_MSG_ERROR([Emacs does not support '${canonical}' systems.
 748 If you think it should, please send a report to ${PACKAGE_BUGREPORT}.
 749 Check 'etc/MACHINES' for recognized configuration names.])
 750 fi
 751
 752 #### Choose a compiler.
 753
 754 dnl Don't bother to test for C89.
 755 AC_DEFUN([_AC_PROG_CC_C89], [$2])
 756
 757 dnl Sets GCC=yes if using gcc.
 758 AC_PROG_CC([gcc cc cl clang "$XCRUN gcc" "$XCRUN clang"])
 759 if test -n "$XCRUN"; then
 760   AC_CHECK_PROGS(AR, [ar "$XCRUN ar"])
 761   test -n "$AR" && export AR
 762 fi
 763
 764 dnl Emacs needs C99 or later.
 765 gl_PROG_CC_C99
 766
 767 AM_PROG_CC_C_O
 768
 769 if test x$GCC = xyes; then
 770   test "x$GCC_TEST_OPTIONS" != x && CC="$CC $GCC_TEST_OPTIONS"
 771 fi
 772
 773 dnl This is used in lib/Makefile.am to use nt/gnulib.mk, the
 774 dnl alternative to lib/gnulib.mk, so as to avoid generating header files
 775 dnl that clash with MinGW.
 776 AM_CONDITIONAL([BUILDING_FOR_WINDOWSNT], [test "x$opsys" = "xmingw32"])
 777
 778 # Avoid gnulib's tests for -lcrypto, so that there's no static dependency on it.
 779 AC_DEFUN([gl_CRYPTO_CHECK])
 780 # Avoid gnulib's tests for HAVE_WORKING_O_NOATIME and HAVE_WORKING_O_NOFOLLOW,
 781 # as we don't use them.
 782 AC_DEFUN([gl_FCNTL_O_FLAGS])
 783 # Avoid gnulib's test for pthread_sigmask.
 784 funcs=
 785 for func in $ac_func_list; do
 786   test $func = pthread_sigmask || AS_VAR_APPEND([funcs], [" $func"])
 787 done
 788 ac_func_list=$funcs
 789 # Use the system putenv even if it lacks GNU features, as we don't need them,
 790 # and the gnulib replacement runs afoul of a FreeBSD 10.1 bug; see Bug#19874.
 791 AC_CHECK_FUNCS_ONCE([putenv])
 792 AC_DEFUN([gl_FUNC_PUTENV],
 793   [test "$ac_cv_func_putenv" = yes || REPLACE_PUTENV=1])
 794
 795 # Initialize gnulib right after choosing the compiler.
 796 dnl Amongst other things, this sets AR and ARFLAGS.
 797 gl_EARLY
 798
 799 if test "$ac_test_CFLAGS" != set; then
 800   # It's helpful to have C macros available to GDB, so prefer -g3 to -g
 801   # if -g3 works and the user does not specify CFLAGS.
 802   # This test must follow gl_EARLY; otherwise AC_LINK_IFELSE complains.
 803   case $CFLAGS in
 804     '-g')
 805       emacs_g3_CFLAGS='-g3';;
 806     '-g -O2')
 807       emacs_g3_CFLAGS='-g3 -O2';;
 808     *)
 809       emacs_g3_CFLAGS='';;
 810   esac
 811   if test -n "$emacs_g3_CFLAGS"; then
 812     emacs_save_CFLAGS=$CFLAGS
 813     CFLAGS=$emacs_g3_CFLAGS
 814     AC_CACHE_CHECK([whether $CC accepts $emacs_g3_CFLAGS],
 815       [emacs_cv_prog_cc_g3],
 816       [AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 817          [emacs_cv_prog_cc_g3=yes],
 818          [emacs_cv_prog_cc_g3=no])])
 819     if test $emacs_cv_prog_cc_g3 != yes; then
 820       CFLAGS=$emacs_save_CFLAGS
 821     fi
 822     if test $opsys = mingw32; then
 823       CFLAGS="$CFLAGS -gdwarf-2"
 824     fi
 825   fi
 826
 827   case $CFLAGS in
 828     *-O*) ;;
 829     *)
 830       # No optimization flag was inferred for this non-GCC compiler.
 831       # Try -O.  This is needed for xlc on AIX; see Bug#14258.
 832       emacs_save_CFLAGS=$CFLAGS
 833       test -z "$CFLAGS" || CFLAGS="$CFLAGS "
 834       CFLAGS=${CFLAGS}-O
 835       AC_CACHE_CHECK([whether $CC accepts -O],
 836         [emacs_cv_prog_cc_o],
 837         [AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 838            [emacs_cv_prog_cc_o=yes],
 839            [emacs_cv_prog_cc_o=no])])
 840       if test $emacs_cv_prog_cc_o != yes; then
 841         CFLAGS=$emacs_save_CFLAGS
 842       fi ;;
 843   esac
 844 fi
 845
 846 # gl_GCC_VERSION_IFELSE([major], [minor], [run-if-found], [run-if-not-found])
 847 # ---------------------------------------------------------------------------
 848 # If $CPP is gcc-MAJOR.MINOR or newer, then run RUN-IF-FOUND.
 849 # Otherwise, run RUN-IF-NOT-FOUND.
 850 AC_DEFUN([gl_GCC_VERSION_IFELSE],
 851   [AC_PREPROC_IFELSE(
 852     [AC_LANG_PROGRAM(
 853       [[
 854 #if ($1) < __GNUC__ || (($1) == __GNUC__ && ($2) <= __GNUC_MINOR__)
 855 /* ok */
 856 #else
 857 # error "your version of gcc is older than $1.$2"
 858 #endif
 859       ]]),
 860     ], [$3], [$4])
 861   ]
 862 )
 863
 864 AC_ARG_ENABLE([gcc-warnings],
 865   [AS_HELP_STRING([--enable-gcc-warnings@<:@=TYPE@:>@],
 866                   [control generation of GCC warnings.  The TYPE 'yes'
 867                    means to fail if any warnings are issued; 'warn-only'
 868                    means issue warnings without failing (default for
 869                    developer builds); 'no' means disable warnings
 870                    (default for non-developer builds).])],
 871   [case $enableval in
 872      yes|no|warn-only) ;;
 873      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
 874    esac
 875    gl_gcc_warnings=$enableval],
 876   [# By default, use 'warn-only' if it looks like the invoker of 'configure'
 877    # is a developer as opposed to a builder.  This is most likely true
 878    # if GCC is recent enough and there is a .git directory or file;
 879    # however, if there is also a .tarball-version file it is probably
 880    # just a release imported into Git for patch management.
 881    gl_gcc_warnings=no
 882    if test -e "$srcdir"/.git && test ! -f "$srcdir"/.tarball-version; then
 883      gl_GCC_VERSION_IFELSE([5], [3], [gl_gcc_warnings=warn-only])]
 884    fi
 885 )
 886
 887 # clang is unduly picky about some things.
 888 AC_CACHE_CHECK([whether the compiler is clang], [emacs_cv_clang],
 889   [AC_COMPILE_IFELSE(
 890      [AC_LANG_PROGRAM([[
 891           #ifndef __clang__
 892             error "not clang";
 893           #endif
 894         ]])],
 895      [emacs_cv_clang=yes],
 896      [emacs_cv_clang=no])])
 897
 898 # When compiling with GCC, prefer -isystem to -I when including system
 899 # include files, to avoid generating useless diagnostics for the files.
 900 AS_IF([test $gl_gcc_warnings = no],
 901  [
 902   isystem='-I'
 903   AS_IF([test "$emacs_cv_clang" = yes],
 904    [
 905      # Turn off some warnings if supported.
 906      gl_WARN_ADD([-Wno-switch])
 907      gl_WARN_ADD([-Wno-tautological-constant-out-of-range-compare])
 908      gl_WARN_ADD([-Wno-pointer-sign])
 909      gl_WARN_ADD([-Wno-string-plus-int])
 910      gl_WARN_ADD([-Wno-unknown-attributes])
 911    ])
 912  ],[
 913   isystem='-isystem '
 914
 915   # This, $nw, is the list of warnings we disable.
 916   nw=
 917
 918   case $with_x_toolkit in
 919     lucid | athena | motif)
 920        # Old toolkits mishandle 'const'.
 921        nw="$nw -Wwrite-strings"
 922        ;;
 923   esac
 924   AS_IF([test $gl_gcc_warnings = yes],
 925     [gl_WARN_ADD([-Werror], [WERROR_CFLAGS])])
 926   AC_SUBST([WERROR_CFLAGS])
 927
 928   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
 929   nw="$nw -Woverlength-strings"     # Not a problem these days
 930   nw="$nw -Wformat-nonliteral"      # we do this a lot
 931   nw="$nw -Wvla"                    # Emacs uses <vla.h>.
 932   nw="$nw -Wswitch-default"         # Too many warnings for now
 933   nw="$nw -Wunused-const-variable=2" # lisp.h declares const objects.
 934   nw="$nw -Winline"                 # OK to ignore 'inline'
 935   nw="$nw -Wstrict-overflow"        # OK to optimize assuming that
 936                                     # signed overflow has undefined behavior
 937   nw="$nw -Wsync-nand"              # irrelevant here, and provokes ObjC warning
 938   nw="$nw -Wunsafe-loop-optimizations" # OK to suppress unsafe optimizations
 939   nw="$nw -Wbad-function-cast"      # These casts are no worse than others.
 940
 941   # Emacs doesn't care about shadowing; see
 942   # <http://lists.gnu.org/archive/html/emacs-diffs/2011-11/msg00265.html>.
 943   nw="$nw -Wshadow"
 944
 945   # Emacs's use of alloca inhibits protecting the stack.
 946   nw="$nw -Wstack-protector"
 947
 948   # Emacs's use of partly-const functions such as Fgnutls_available_p
 949   # make this option problematic.
 950   nw="$nw -Wsuggest-attribute=const"
 951
 952   # Emacs's use of partly-pure functions such as CHECK_TYPE make this
 953   # option problematic.
 954   nw="$nw -Wsuggest-attribute=pure"
 955
 956   # This part is merely for shortening the command line,
 957   # since -Wall implies -Wswitch.
 958   nw="$nw -Wswitch"
 959
 960   # This part is merely for shortening the command line,
 961   # since -Wno-FOO needs to be added below regardless.
 962   nw="$nw -Wmissing-field-initializers"
 963   nw="$nw -Wtype-limits"
 964   nw="$nw -Wunused-parameter"
 965
 966   if test $emacs_cv_clang = yes; then
 967     nw="$nw -Wcast-align"
 968   fi
 969
 970   gl_MANYWARN_ALL_GCC([ws])
 971   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
 972   for w in $ws; do
 973     gl_WARN_ADD([$w])
 974   done
 975   gl_WARN_ADD([-Wredundant-decls])     # Prefer this, as we don't use Bison.
 976   gl_WARN_ADD([-Wno-missing-field-initializers]) # We need this one
 977   gl_WARN_ADD([-Wno-sign-compare])     # Too many warnings for now
 978   gl_WARN_ADD([-Wno-type-limits])      # Too many warnings for now
 979   gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now
 980   gl_WARN_ADD([-Wno-format-nonliteral])
 981
 982   # More things that clang is unduly picky about.
 983   if test $emacs_cv_clang = yes; then
 984     gl_WARN_ADD([-Wno-format-extra-args])
 985     gl_WARN_ADD([-Wno-tautological-constant-out-of-range-compare])
 986     gl_WARN_ADD([-Wno-unused-command-line-argument])
 987     gl_WARN_ADD([-Wno-unused-value])
 988   fi
 989
 990   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 991   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 992   AH_VERBATIM([GNULIB_PORTCHECK_FORTIFY_SOURCE],
 993   [/* Enable compile-time and run-time bounds-checking, and some warnings,
 994       without upsetting glibc 2.15+. */
 995    #if (defined GNULIB_PORTCHECK && !defined _FORTIFY_SOURCE \
 996         && defined __OPTIMIZE__ && __OPTIMIZE__)
 997    # define _FORTIFY_SOURCE 2
 998    #endif
 999   ])
1000
1001   # We use a slightly smaller set of warning options for lib/.
1002   # Remove the following and save the result in GNULIB_WARN_CFLAGS.
1003   nw=
1004   nw="$nw -Wunused-macros"
1005
1006   gl_MANYWARN_COMPLEMENT([GNULIB_WARN_CFLAGS], [$WARN_CFLAGS], [$nw])
1007   AC_SUBST([GNULIB_WARN_CFLAGS])
1008  ])
1009
1010 edit_cflags="
1011   s,///*,/,g
1012   s/^/ /
1013   s/ -I/ $isystem/g
1014   s/^ //
1015 "
1016
1017 AC_ARG_ENABLE(link-time-optimization,
1018 [AS_HELP_STRING([--enable-link-time-optimization],
1019                 [build emacs with link-time optimization.
1020                  This requires GCC 4.5.0 or later, or clang.
1021                  (Note that clang support is experimental - see INSTALL.)
1022                  It also makes Emacs harder to debug, and when we tried it
1023                  with GCC 4.9.0 x86-64 it made Emacs slower, so it's not
1024                  recommended for typical use.])],
1025 if test "${enableval}" != "no"; then
1026    ac_lto_supported=no
1027    if test $emacs_cv_clang = yes; then
1028       AC_MSG_CHECKING([whether link-time optimization is supported by clang])
1029       GOLD_PLUGIN=`$CC -print-file-name=LLVMgold.so 2>/dev/null`
1030       if test -x "$GOLD_PLUGIN"; then
1031          LTO="-flto"
1032       fi
1033    elif test x$GCC = xyes; then
1034       AC_MSG_CHECKING([whether link-time optimization is supported by gcc])
1035       CPUS=`getconf _NPROCESSORS_ONLN 2>/dev/null`
1036       if test x$CPUS != x; then
1037          LTO="-flto=$CPUS"
1038       else
1039          LTO="-flto"
1040       fi
1041    else
1042       AC_MSG_ERROR([Link-time optimization is not supported with your compiler.])
1043    fi
1044    if test -z "$LTO"; then
1045       ac_lto_supported=no
1046    else
1047       old_CFLAGS=$CFLAGS
1048       CFLAGS="$CFLAGS $LTO"
1049       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])],
1050          [ac_lto_supported=yes], [ac_lto_supported=no])
1051          CFLAGS="$old_CFLAGS"
1052    fi
1053    AC_MSG_RESULT([$ac_lto_supported])
1054    if test "$ac_lto_supported" = "yes"; then
1055       CFLAGS="$CFLAGS $LTO"
1056       if test x$emacs_cv_clang = xyes; then
1057          AC_MSG_WARN([Please read INSTALL before using link-time optimization with clang])
1058          # WARNING: 'ar --plugin ...' doesn't work without
1059          # command, so plugin name is appended to ARFLAGS.
1060          ARFLAGS="cru --plugin $GOLD_PLUGIN"
1061          RANLIB="$RANLIB --plugin $GOLD_PLUGIN"
1062       else
1063         dnl The following is needed for GCC 4.9.0.  The GCC 4.9.0 release notes
1064         dnl suggest that instead of -ffat-lto-objects we should use gcc-ar and
1065         dnl gcc-ranlib in place of ar and ranlib, but gcc-ar makes /usr/bin/ar
1066         dnl dump core on Fedora 20, so play it safe for now.
1067         gl_COMPILER_OPTION_IF([-ffat-lto-objects],
1068           [CFLAGS="$CFLAGS -ffat-lto-objects"])
1069       fi
1070    fi
1071 fi)
1072
1073 dnl Prefer silent make output.  For verbose output, use
1074 dnl 'configure --disable-silent-rules' or 'make V=1' .
1075 AM_SILENT_RULES([yes])
1076 dnl Port to Automake 1.11.
1077 dnl This section can be removed once we assume Automake 1.14 or later.
1078 : ${AM_V=$AM_DEFAULT_VERBOSITY}
1079 : ${AM_DEFAULT_V=$AM_DEFAULT_VERBOSITY}
1080 AC_SUBST([AM_V])
1081 AM_SUBST_NOTMAKE([AM_V])
1082 AC_SUBST([AM_DEFAULT_V])
1083 AM_SUBST_NOTMAKE([AM_DEFAULT_V])
1084 AC_SUBST([AM_DEFAULT_VERBOSITY])
1085
1086 dnl Some other nice autoconf tests.
1087 dnl These are commented out, since gl_EARLY and/or Autoconf already does them.
1088 dnl AC_PROG_INSTALL
1089 dnl AC_PROG_MKDIR_P
1090 dnl if test "x$RANLIB" = x; then
1091 dnl   AC_PROG_RANLIB
1092 dnl fi
1093
1094
1095 dnl Sadly, AC_PROG_LN_S is too restrictive.  It also tests whether links
1096 dnl can be made to directories.  This is not relevant for our usage, and
1097 dnl excludes some cases that work fine for us.  Eg MS Windows or files
1098 dnl hosted on AFS, both examples where simple links work, but links to
1099 dnl directories fail.  We use a cut-down version instead.
1100 dnl AC_PROG_LN_S
1101
1102 AC_MSG_CHECKING([whether ln -s works for files in the same directory])
1103 rm -f conf$$ conf$$.file
1104
1105 LN_S_FILEONLY='cp -p'
1106
1107 dnl On MinGW, ensure we will call the MSYS /bin/ln.exe, not some
1108 dnl random program in the current directory.
1109 if (echo >conf$$.file) 2>/dev/null; then
1110   if ln -s conf$$.file conf$$ 2>/dev/null; then
1111     if test "$opsys" = "mingw32"; then
1112       LN_S_FILEONLY='/bin/ln -s'
1113     else
1114       LN_S_FILEONLY='ln -s'
1115     fi
1116   elif ln conf$$.file conf$$ 2>/dev/null; then
1117     if test "$opsys" = "mingw32"; then
1118       LN_S_FILEONLY=/bin/ln
1119     else
1120       LN_S_FILEONLY=ln
1121     fi
1122   fi
1123 fi
1124
1125 rm -f conf$$ conf$$.file
1126
1127 if test "$LN_S_FILEONLY" = "ln -s"; then
1128    AC_MSG_RESULT([yes])
1129 else
1130    AC_MSG_RESULT([no, using $LN_S_FILEONLY])
1131 fi
1132
1133 AC_SUBST(LN_S_FILEONLY)
1134
1135
1136 dnl AC_PROG_LN_S sets LN_S to 'cp -pR' for MinGW, on the premise that 'ln'
1137 dnl doesn't support links to directories, as in "ln file dir".  But that
1138 dnl use is non-portable, and OTOH MinGW wants to use hard links for Emacs
1139 dnl executables at "make install" time.
1140 dnl See http://lists.gnu.org/archive/html/emacs-devel/2013-04/msg00475.html
1141 dnl for more details.
1142 if test "$opsys" = "mingw32"; then
1143   LN_S="/bin/ln"
1144 fi
1145
1146 dnl On some Debian versions, "install-info" prints irritating messages
1147 dnl "This is not dpkg install-info anymore, but GNU install-info"
1148 dnl if called via an absolute file name.
1149 dnl Use the entirely-identical-but-quieter ginstall-info instead if present.
1150 dnl Sadly some people may have an old ginstall-info installed on
1151 dnl non-Debian systems, so we can't use this.
1152 dnl AC_PATH_PROGS(INSTALL_INFO, [ginstall-info install-info], :,
1153 dnl   $PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin)
1154
1155 AC_PATH_PROG(INSTALL_INFO, install-info, :,
1156   $PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin)
1157 dnl Don't use GZIP, which is used by gzip for additional parameters.
1158 AC_PATH_PROG(GZIP_PROG, gzip)
1159
1160 test $with_compress_install != yes && test -n "$GZIP_PROG" && \
1161    GZIP_PROG=" # $GZIP_PROG # (disabled by configure --without-compress-install)"
1162
1163 PAXCTL_dumped=
1164 PAXCTL_notdumped=
1165 if test $opsys = gnu-linux; then
1166   if test "${SETFATTR+set}" != set; then
1167     AC_CACHE_CHECK([for setfattr],
1168       [emacs_cv_prog_setfattr],
1169       [touch conftest.tmp
1170        if (setfattr -n user.pax.flags conftest.tmp) >/dev/null 2>&1; then
1171          emacs_cv_prog_setfattr=yes
1172        else
1173          emacs_cv_prog_setfattr=no
1174        fi])
1175     if test "$emacs_cv_prog_setfattr" = yes; then
1176       PAXCTL_notdumped='$(SETFATTR) -n user.pax.flags -v er'
1177       SETFATTR=setfattr
1178     else
1179       SETFATTR=
1180     fi
1181     rm -f conftest.tmp
1182     AC_SUBST([SETFATTR])
1183   fi
1184 fi
1185 case $opsys,$PAXCTL_notdumped in
1186   gnu-linux, | netbsd,)
1187     AC_PATH_PROG([PAXCTL], [paxctl], [],
1188       [$PATH$PATH_SEPARATOR/sbin$PATH_SEPARATOR/usr/sbin])
1189     if test -n "$PAXCTL"; then
1190       if test "$opsys" = netbsd; then
1191         PAXCTL_dumped='$(PAXCTL) +a'
1192         PAXCTL_notdumped=$PAXCTL_dumped
1193       else
1194         AC_MSG_CHECKING([whether binaries have a PT_PAX_FLAGS header])
1195         AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
1196           [if $PAXCTL -v conftest$EXEEXT >/dev/null 2>&1; then
1197              AC_MSG_RESULT([yes])
1198            else
1199              AC_MSG_RESULT([no])
1200              PAXCTL=
1201            fi])
1202         if test -n "$PAXCTL"; then
1203           PAXCTL_dumped='$(PAXCTL) -zex'
1204           PAXCTL_notdumped='$(PAXCTL) -r'
1205         fi
1206       fi
1207     fi;;
1208 esac
1209 AC_SUBST([PAXCTL_dumped])
1210 AC_SUBST([PAXCTL_notdumped])
1211
1212 ## Need makeinfo >= 4.7 (?) to build the manuals.
1213 if test "$MAKEINFO" != "no"; then
1214   if test "$MAKEINFO" = "${am_missing_run}makeinfo"; then
1215     MAKEINFO=makeinfo
1216   fi
1217   case `($MAKEINFO --version) 2>/dev/null` in
1218     *' (GNU texinfo) '4.[[7-9]]* | \
1219     *' (GNU texinfo) '4.[[1-9][0-9]]* | \
1220     *' (GNU texinfo) '[[5-9]]* | \
1221     *' (GNU texinfo) '[[1-9][0-9]]* ) ;;
1222     *) MAKEINFO=no;;
1223   esac
1224 fi
1225
1226 ## Makeinfo is unusual.  For a released Emacs, the manuals are
1227 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
1228 ## therefore in the category of "special tools" not normally required, which
1229 ## configure does not have to check for (eg autoconf itself).
1230 ## In a repository checkout on the other hand, the manuals are not included.
1231 ## So makeinfo is a requirement to build from the repository, and configure
1232 ## should test for it as it does for any other build requirement.
1233 ## We use the presence of $srcdir/info/emacs to distinguish a release,
1234 ## with pre-built manuals, from a repository checkout.
1235 HAVE_MAKEINFO=yes
1236
1237 if test "$MAKEINFO" = "no"; then
1238   MAKEINFO=makeinfo
1239   if test "x${with_makeinfo}" = "xno"; then
1240     HAVE_MAKEINFO=no
1241   elif test ! -e "$srcdir/info/emacs" && test ! -e "$srcdir/info/emacs.info"; then
1242     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.7, and your
1243 source tree does not seem to have pre-built manuals in the 'info' directory.
1244 Either install a suitable version of makeinfo, or re-run configure
1245 with the '--without-makeinfo' option to build without the manuals.] )
1246   fi
1247 fi
1248 AC_SUBST(HAVE_MAKEINFO)
1249
1250 if test $opsys = mingw32; then
1251    DOCMISC_W32=efaq-w32
1252 else
1253    DOCMISC_W32=
1254 fi
1255 AC_SUBST(DOCMISC_W32)
1256
1257 dnl Add our options to ac_link now, after it is set up.
1258
1259 if test x$GCC = xyes; then
1260   test "x$GCC_LINK_TEST_OPTIONS" != x && \
1261     ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
1262 else
1263   test "x$NON_GCC_LINK_TEST_OPTIONS" != x && \
1264     ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
1265 fi
1266
1267 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
1268 dnl If we can link with the flag, it shouldn't do any harm anyhow.
1269 dnl Treat GCC specially since it just gives a non-fatal 'unrecognized option'
1270 dnl if not built to support GNU ld.
1271
1272 dnl For a long time, -znocombreloc was added to LDFLAGS rather than
1273 dnl LD_SWITCH_SYSTEM_TEMACS.  That is:
1274 dnl * inappropriate, as LDFLAGS is a user option but this is essential.
1275 dnl   Eg "make LDFLAGS=... all" could run into problems,
1276 dnl   http://bugs.debian.org/684788
1277 dnl * unnecessary, since temacs is the only thing that actually needs it.
1278 dnl   Indeed this is where it was originally, prior to:
1279 dnl   http://lists.gnu.org/archive/html/emacs-pretest-bug/2004-03/msg00170.html
1280 late_LDFLAGS="$LDFLAGS"
1281 if test x$GCC = xyes; then
1282   LDFLAGS_NOCOMBRELOC="-Wl,-znocombreloc"
1283 else
1284   LDFLAGS_NOCOMBRELOC="-znocombreloc"
1285 fi
1286
1287 LDFLAGS="$LDFLAGS $LDFLAGS_NOCOMBRELOC"
1288
1289 AC_MSG_CHECKING([for -znocombreloc])
1290 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
1291   [AC_MSG_RESULT(yes)],
1292   LDFLAGS_NOCOMBRELOC=
1293   [AC_MSG_RESULT(no)])
1294
1295 LDFLAGS="$late_LDFLAGS"
1296
1297 AC_CACHE_CHECK([whether addresses are sanitized],
1298   [emacs_cv_sanitize_address],
1299   [AC_COMPILE_IFELSE(
1300      [AC_LANG_PROGRAM(
1301         [[#ifndef __has_feature
1302           #define __has_feature(f) 0
1303           #endif
1304           #if defined __SANITIZE_ADDRESS__ || __has_feature (address_sanitizer)
1305           #else
1306            error "Addresses are not sanitized.";
1307           #endif
1308         ]])],
1309      [emacs_cv_sanitize_address=yes],
1310      [emacs_cv_sanitize_address=no])])
1311
1312 dnl The function dump-emacs will not be defined and temacs will do
1313 dnl (load "loadup") automatically unless told otherwise.
1314 test "x$CANNOT_DUMP" = "x" && CANNOT_DUMP=no
1315 case "$opsys" in
1316   nacl) CANNOT_DUMP=yes ;;
1317 esac
1318
1319 if test "$CANNOT_DUMP" = "yes"; then
1320   AC_DEFINE(CANNOT_DUMP, 1, [Define if Emacs cannot be dumped on your system.])
1321 elif test "$emacs_cv_sanitize_address" = yes; then
1322   AC_MSG_WARN([[Addresses are sanitized; suggest CANNOT_DUMP=yes]])
1323 fi
1324
1325 AC_SUBST(CANNOT_DUMP)
1326
1327
1328 UNEXEC_OBJ=unexelf.o
1329 case "$opsys" in
1330   # MSDOS uses unexcoff.o
1331   aix4-2)
1332    UNEXEC_OBJ=unexaix.o
1333    ;;
1334   cygwin)
1335    UNEXEC_OBJ=unexcw.o
1336    ;;
1337   darwin)
1338    UNEXEC_OBJ=unexmacosx.o
1339    ;;
1340   hpux10-20 | hpux11)
1341    UNEXEC_OBJ=unexhp9k800.o
1342    ;;
1343   mingw32)
1344    UNEXEC_OBJ=unexw32.o
1345    ;;
1346   sol2-10)
1347    # Use the Solaris dldump() function, called from unexsol.c, to dump
1348    # emacs, instead of the generic ELF dump code found in unexelf.c.
1349    # The resulting binary has a complete symbol table, and is better
1350    # for debugging and other observability tools (debuggers, pstack, etc).
1351    #
1352    # If you encounter a problem using dldump(), please consider sending
1353    # a message to the OpenSolaris tools-linking mailing list:
1354    #      http://mail.opensolaris.org/mailman/listinfo/tools-linking
1355    #
1356    # It is likely that dldump() works with older Solaris too, but this has
1357    # not been tested, so for now this change is for Solaris 10 or newer.
1358    UNEXEC_OBJ=unexsol.o
1359    ;;
1360 esac
1361
1362 LD_SWITCH_SYSTEM=
1363 case "$opsys" in
1364   freebsd|dragonfly)
1365    ## Let 'ld' find image libs and similar things in /usr/local/lib.
1366    ## The system compiler, GCC, has apparently been modified to not
1367    ## look there, contrary to what a stock GCC would do.
1368 ### It's not our place to do this.  See bug#10313#17.
1369 ###   LD_SWITCH_SYSTEM=-L/usr/local/lib
1370       :
1371    ;;
1372
1373   gnu-linux)
1374    ## cpp test was "ifdef __mips__", but presumably this is equivalent...
1375    case $host_cpu in mips*) LD_SWITCH_SYSTEM="-G 0";; esac
1376    ;;
1377
1378   netbsd)
1379 ### It's not our place to do this.  See bug#10313#17.
1380 ###   LD_SWITCH_SYSTEM="-Wl,-rpath,/usr/pkg/lib -L/usr/pkg/lib -Wl,-rpath,/usr/local/lib -L/usr/local/lib"
1381       :
1382    ;;
1383
1384   openbsd)
1385    ## Han Boetes <han@boetes.org> says this is necessary,
1386    ## otherwise Emacs dumps core on elf systems.
1387    LD_SWITCH_SYSTEM="-Z"
1388    ;;
1389 esac
1390 AC_SUBST(LD_SWITCH_SYSTEM)
1391
1392 ac_link="$ac_link $LD_SWITCH_SYSTEM"
1393
1394 ## This setting of LD_SWITCH_SYSTEM references LD_SWITCH_X_SITE_RPATH,
1395 ## which has not been defined yet.  When this was handled with cpp,
1396 ## it was expanded to null when configure sourced the s/*.h file.
1397 ## Thus LD_SWITCH_SYSTEM had different values in configure and the Makefiles.
1398 ## FIXME it would be cleaner to put this in LD_SWITCH_SYSTEM_TEMACS
1399 ## (or somesuch), but because it is supposed to go at the _front_
1400 ## of LD_SWITCH_SYSTEM, we cannot do that in exactly the same way.
1401 ## Compare with the gnu-linux case below, which added to the end
1402 ## of LD_SWITCH_SYSTEM, and so can instead go at the front of
1403 ## LD_SWITCH_SYSTEM_TEMACS.
1404 case "$opsys" in
1405   netbsd|openbsd)
1406    LD_SWITCH_SYSTEM="\$(LD_SWITCH_X_SITE_RPATH) $LD_SWITCH_SYSTEM" ;;
1407 esac
1408
1409
1410 C_SWITCH_MACHINE=
1411 case $canonical in
1412  alpha*)
1413   AC_CHECK_DECL([__ELF__])
1414   if test "$ac_cv_have_decl___ELF__" = "yes"; then
1415     ## With ELF, make sure that all common symbols get allocated to in the
1416     ## data section.  Otherwise, the dump of temacs may miss variables in
1417     ## the shared library that have been initialized.  For example, with
1418     ## GNU libc, __malloc_initialized would normally be resolved to the
1419     ## shared library's .bss section, which is fatal.
1420     if test "x$GCC" = "xyes"; then
1421       C_SWITCH_MACHINE="-fno-common"
1422     else
1423       AC_MSG_ERROR([Non-GCC compilers are not supported.])
1424     fi
1425   else
1426       dnl This was the unexalpha.c case.  Removed in 24.1, 2010-07-24,
1427       dnl albeit under the mistaken assumption that said file
1428       dnl was no longer used.
1429       AC_MSG_ERROR([Non-ELF systems are not supported since Emacs 24.1.])
1430   fi
1431   ;;
1432 esac
1433 AC_SUBST(C_SWITCH_MACHINE)
1434
1435 AC_SUBST(UNEXEC_OBJ)
1436
1437 C_SWITCH_SYSTEM=
1438 ## Some programs in src produce warnings saying certain subprograms
1439 ## are too complex and need a MAXMEM value greater than 2000 for
1440 ## additional optimization.  --nils@exp-math.uni-essen.de
1441 test "$opsys" = "aix4.2" && test "x$GCC" != "xyes" && \
1442   C_SWITCH_SYSTEM="-ma -qmaxmem=4000"
1443 if test "$opsys" = "mingw32"; then
1444   case "$canonical" in
1445     x86_64-*-mingw*) C_SWITCH_SYSTEM="-mtune=generic" ;;
1446     *) C_SWITCH_SYSTEM="-mtune=pentium4" ;;
1447   esac
1448 fi
1449 ## gnu-linux might need -D_BSD_SOURCE on old libc5 systems.
1450 ## It is redundant in glibc2, since we define _GNU_SOURCE.
1451 AC_SUBST(C_SWITCH_SYSTEM)
1452
1453
1454 LIBS_SYSTEM=
1455 case "$opsys" in
1456   ## IBM's X11R5 uses -lIM and -liconv in AIX 3.2.2.
1457   aix4-2) LIBS_SYSTEM="-lrts -lIM -liconv" ;;
1458
1459   freebsd|dragonfly) LIBS_SYSTEM="-lutil" ;;
1460
1461   hpux*) LIBS_SYSTEM="-l:libdld.sl" ;;
1462
1463   sol2*) LIBS_SYSTEM="-lsocket -lnsl" ;;
1464
1465   ## Motif needs -lgen.
1466   unixware) LIBS_SYSTEM="-lsocket -lnsl -lelf -lgen" ;;
1467 esac
1468
1469 AC_SUBST(LIBS_SYSTEM)
1470
1471 ### Make sure subsequent tests use flags consistent with the build flags.
1472
1473 if test x"${OVERRIDE_CPPFLAGS}" != x; then
1474   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
1475 else
1476   CPPFLAGS="$C_SWITCH_SYSTEM $C_SWITCH_MACHINE $CPPFLAGS"
1477 fi
1478
1479 # Suppress obsolescent Autoconf test for size_t; Emacs assumes C99 or better.
1480 AC_DEFUN([AC_TYPE_SIZE_T])
1481 # Likewise for obsolescent test for uid_t, gid_t; Emacs assumes them.
1482 AC_DEFUN([AC_TYPE_UID_T])
1483
1484 # sqrt and other floating-point functions such as fmod and frexp
1485 # are found in -lm on many systems.
1486 OLD_LIBS=$LIBS
1487 AC_SEARCH_LIBS([sqrt], [m])
1488 if test "X$LIBS" = "X$OLD_LIBS"; then
1489   LIB_MATH=
1490 else
1491   LIB_MATH=$ac_cv_search_sqrt
1492 fi
1493 LIBS=$OLD_LIBS
1494
1495 dnl Current possibilities handled by sed (aix4-2 -> aix,
1496 dnl gnu-linux -> gnu/linux, etc.):
1497 dnl gnu, gnu/linux, gnu/kfreebsd, aix, cygwin, darwin, hpux.
1498 dnl And special cases: berkeley-unix, usg-unix-v, ms-dos, windows-nt.
1499 SYSTEM_TYPE=`echo $opsys | sed -e 's/[[0-9]].*//' -e 's|-|/|'`
1500
1501 case $opsys in
1502   cygwin )
1503     LIB_MATH=
1504     ;;
1505   darwin )
1506     ## Adding -lm confuses the dynamic linker, so omit it.
1507     LIB_MATH=
1508     ;;
1509   freebsd | dragonfly )
1510     SYSTEM_TYPE=berkeley-unix
1511     ;;
1512   gnu-linux | gnu-kfreebsd )
1513     ;;
1514   hpux10-20 | hpux11 )
1515     ;;
1516   mingw32 )
1517     LIB_MATH=
1518     SYSTEM_TYPE=windows-nt
1519     ;;
1520   dnl NB this may be adjusted below.
1521   netbsd | openbsd )
1522     SYSTEM_TYPE=berkeley-unix
1523     ;;
1524
1525   sol2* | unixware )
1526     SYSTEM_TYPE=usg-unix-v
1527     ;;
1528
1529 esac
1530
1531 AC_SUBST(LIB_MATH)
1532 AC_DEFINE_UNQUOTED(SYSTEM_TYPE, "$SYSTEM_TYPE",
1533   [The type of system you are compiling for; sets 'system-type'.])
1534
1535
1536 pre_PKG_CONFIG_CFLAGS=$CFLAGS
1537 pre_PKG_CONFIG_LIBS=$LIBS
1538
1539 PKG_PROG_PKG_CONFIG(0.9.0)
1540
1541 dnl EMACS_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4)
1542 dnl acts like PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4,
1543 dnl HAVE_GSTUFF=yes, HAVE_GSTUFF=no) -- see pkg-config man page --
1544 dnl except that it postprocesses CFLAGS as needed for --enable-gcc-warnings.
1545 dnl EMACS_CHECK_MODULES accepts optional 3rd and 4th arguments that
1546 dnl can take the place of the default HAVE_GSTUFF=yes and HAVE_GSTUFF=no
1547 dnl actions.
1548 AC_DEFUN([EMACS_CHECK_MODULES],
1549   [PKG_CHECK_MODULES([$1], [$2],
1550      [$1_CFLAGS=`AS_ECHO(["$$1_CFLAGS"]) | sed -e "$edit_cflags"`
1551       m4_default([$3], [HAVE_$1=yes])],
1552      [m4_default([$4], [HAVE_$1=no])])])
1553
1554 HAVE_SOUND=no
1555 if test "${with_sound}" != "no"; then
1556   # Sound support for GNU/Linux, the free BSDs, MinGW, and Cygwin.
1557   AC_CHECK_HEADERS([machine/soundcard.h sys/soundcard.h soundcard.h mmsystem.h],
1558     have_sound_header=yes, [], [
1559     #ifdef __MINGW32__
1560     #define WIN32_LEAN_AND_MEAN
1561     #include <windows.h>
1562     #endif
1563     ])
1564   test "${with_sound}" = "oss" && test "${have_sound_header}" != "yes" && \
1565     AC_MSG_ERROR([OSS sound support requested but not found.])
1566
1567   if test "${with_sound}" = "bsd-ossaudio" || test "${with_sound}" = "yes"; then
1568     # Emulation library used on NetBSD.
1569     AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1570     test "${with_sound}" = "bsd-ossaudio" && test -z "$LIBSOUND" && \
1571       AC_MSG_ERROR([bsd-ossaudio sound support requested but not found.])
1572     dnl FIXME?  If we did find ossaudio, should we set with_sound=bsd-ossaudio?
1573     dnl Traditionally, we go on to check for alsa too.  Does that make sense?
1574   fi
1575   AC_SUBST(LIBSOUND)
1576
1577   if test "${with_sound}" = "alsa" || test "${with_sound}" = "yes"; then
1578     ALSA_REQUIRED=1.0.0
1579     ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1580     EMACS_CHECK_MODULES([ALSA], [$ALSA_MODULES])
1581     if test $HAVE_ALSA = yes; then
1582       SAVE_CFLAGS="$CFLAGS"
1583       SAVE_LIBS="$LIBS"
1584       CFLAGS="$ALSA_CFLAGS $CFLAGS"
1585       LIBS="$ALSA_LIBS $LIBS"
1586       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <asoundlib.h>]], [[snd_lib_error_set_handler (0);]])],
1587                       emacs_alsa_normal=yes,
1588                     emacs_alsa_normal=no)
1589       if test "$emacs_alsa_normal" != yes; then
1590         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <alsa/asoundlib.h>]],
1591                        [[snd_lib_error_set_handler (0);]])],
1592                        emacs_alsa_subdir=yes,
1593                      emacs_alsa_subdir=no)
1594         if test "$emacs_alsa_subdir" != yes; then
1595           AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1596         fi
1597         ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1598       fi
1599
1600       CFLAGS="$SAVE_CFLAGS"
1601       LIBS="$SAVE_LIBS"
1602       LIBSOUND="$LIBSOUND $ALSA_LIBS"
1603       CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1604       AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1605     elif test "${with_sound}" = "alsa"; then
1606       AC_MSG_ERROR([ALSA sound support requested but not found.])
1607     fi
1608   fi                            dnl with_sound = alsa|yes
1609
1610   dnl Define HAVE_SOUND if we have sound support.  We know it works and
1611   dnl compiles only on the specified platforms.  For others, it
1612   dnl probably doesn't make sense to try.
1613   dnl FIXME So surely we should bypass this whole section if not using
1614   dnl one of these platforms?
1615   if test x$have_sound_header = xyes || test $HAVE_ALSA = yes; then
1616      case "$opsys" in
1617        dnl defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
1618        dnl Adjust the --with-sound help text if you change this.
1619        gnu-linux|freebsd|netbsd|mingw32|cygwin)
1620          AC_DEFINE(HAVE_SOUND, 1, [Define to 1 if you have sound support.])
1621          HAVE_SOUND=yes
1622          ;;
1623      esac
1624   fi
1625
1626   AC_SUBST(CFLAGS_SOUND)
1627 fi
1628
1629 dnl checks for header files
1630 AC_CHECK_HEADERS_ONCE(
1631   malloc.h
1632   sys/systeminfo.h
1633   sys/sysinfo.h
1634   coff.h pty.h
1635   sys/resource.h
1636   sys/utsname.h pwd.h utmp.h util.h)
1637
1638 AC_MSG_CHECKING(if personality LINUX32 can be set)
1639 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/personality.h>]], [[personality (PER_LINUX32)]])],
1640                emacs_cv_personality_linux32=yes,
1641                emacs_cv_personality_linux32=no)
1642 AC_MSG_RESULT($emacs_cv_personality_linux32)
1643
1644 if test $emacs_cv_personality_linux32 = yes; then
1645   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1646             [Define to 1 if personality LINUX32 can be set.])
1647 fi
1648
1649 # Note that Solaris has sys/sysinfo.h which defines struct
1650 # sysinfo as well.  To make sure that we're using GNU/Linux
1651 # sysinfo, we explicitly set one of its fields.
1652 if test "$ac_cv_header_sys_sysinfo_h" = yes; then
1653   AC_MSG_CHECKING([if Linux sysinfo may be used])
1654   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/sysinfo.h>]],
1655                                      [[struct sysinfo si;
1656                                        si.totalram = 0;
1657                                        sysinfo (&si)]])],
1658     emacs_cv_linux_sysinfo=yes, emacs_cv_linux_sysinfo=no)
1659   AC_MSG_RESULT($emacs_cv_linux_sysinfo)
1660   if test $emacs_cv_linux_sysinfo = yes; then
1661     AC_DEFINE([HAVE_LINUX_SYSINFO], 1, [Define to 1 if you have Linux sysinfo function.])
1662     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/sysinfo.h>]],
1663                                        [[struct sysinfo si; return si.mem_unit]])],
1664       AC_DEFINE(LINUX_SYSINFO_UNIT, 1,
1665                 [Define to 1 if Linux sysinfo sizes are in multiples of mem_unit bytes.]))
1666   fi
1667 fi
1668
1669 dnl On Solaris 8 there's a compilation warning for term.h because
1670 dnl it doesn't define 'bool'.
1671 AC_CHECK_HEADERS(term.h, , , -)
1672 AC_HEADER_TIME
1673 AC_CHECK_DECLS([sys_siglist], [], [], [[#include <signal.h>
1674                                       ]])
1675 if test $ac_cv_have_decl_sys_siglist != yes; then
1676   # For Tru64, at least:
1677   AC_CHECK_DECLS([__sys_siglist], [], [], [[#include <signal.h>
1678                                           ]])
1679 fi
1680 AC_HEADER_SYS_WAIT
1681
1682 AC_CHECK_HEADERS_ONCE(sys/socket.h)
1683 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1684 #if HAVE_SYS_SOCKET_H
1685 #include <sys/socket.h>
1686 #endif])
1687 AC_CHECK_HEADERS(ifaddrs.h, , , [AC_INCLUDES_DEFAULT
1688 #if HAVE_SYS_SOCKET_H
1689 #include <sys/socket.h>
1690 #endif])
1691 AC_CHECK_HEADERS(net/if_dl.h, , , [AC_INCLUDES_DEFAULT
1692 #if HAVE_SYS_SOCKET_H
1693 #include <sys/socket.h>
1694 #endif])
1695
1696 dnl checks for structure members
1697 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1698                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1699                   struct ifreq.ifr_addr,
1700                   struct ifreq.ifr_addr.sa_len], , ,
1701                  [AC_INCLUDES_DEFAULT
1702 #if HAVE_SYS_SOCKET_H
1703 #include <sys/socket.h>
1704 #endif
1705 #if HAVE_NET_IF_H
1706 #include <net/if.h>
1707 #endif])
1708
1709 dnl Check for endianness.
1710 dnl AC_C_BIGENDIAN is done by gnulib.
1711
1712 dnl check for Make feature
1713
1714 AUTO_DEPEND=no
1715 dnl check if we have GCC and autodepend is on.
1716 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1717    AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1718    SAVE_CFLAGS="$CFLAGS"
1719    CFLAGS="$CFLAGS -MMD -MF deps.d -MP"
1720    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], , ac_enable_autodepend=no)
1721    CFLAGS="$SAVE_CFLAGS"
1722    test -f deps.d || ac_enable_autodepend=no
1723    rm -rf deps.d
1724    AC_MSG_RESULT([$ac_enable_autodepend])
1725    if test $ac_enable_autodepend = yes; then
1726       AUTO_DEPEND=yes
1727    fi
1728 fi
1729 AC_SUBST(AUTO_DEPEND)
1730
1731 dnl checks for operating system services
1732 AC_SYS_LONG_FILE_NAMES
1733
1734 #### Choose a window system.
1735
1736 ## We leave window_system equal to none if
1737 ## we end up building without one.  Any new window system should
1738 ## set window_system to an appropriate value and add objects to
1739 ## window-system-specific substs.
1740
1741 window_system=none
1742 AC_PATH_X
1743 if test "$no_x" != yes; then
1744   window_system=x11
1745 fi
1746
1747 LD_SWITCH_X_SITE_RPATH=
1748 if test "${x_libraries}" != NONE; then
1749   if test -n "${x_libraries}"; then
1750     LD_SWITCH_X_SITE=-L`AS_ECHO(["$x_libraries"]) | sed -e 's/:/ -L/g'`
1751     LD_SWITCH_X_SITE_RPATH=-Wl,-rpath,`
1752       AS_ECHO(["$x_libraries"]) | sed -e 's/:/ -Wl,-rpath,/g'
1753     `
1754   fi
1755   x_default_search_path=""
1756   x_search_path=${x_libraries}
1757   if test -z "${x_search_path}"; then
1758     x_search_path=/usr/lib
1759   fi
1760   for x_library in `AS_ECHO(["$x_search_path:"]) | \
1761                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1762     x_search_path="\
1763 ${x_library}/X11/%L/%T/%N%C%S:\
1764 ${x_library}/X11/%l/%T/%N%C%S:\
1765 ${x_library}/X11/%T/%N%C%S:\
1766 ${x_library}/X11/%L/%T/%N%S:\
1767 ${x_library}/X11/%l/%T/%N%S:\
1768 ${x_library}/X11/%T/%N%S"
1769     if test x"${x_default_search_path}" = x; then
1770       x_default_search_path=${x_search_path}
1771     else
1772       x_default_search_path="${x_search_path}:${x_default_search_path}"
1773     fi
1774   done
1775 fi
1776 AC_SUBST(LD_SWITCH_X_SITE_RPATH)
1777
1778 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1779   C_SWITCH_X_SITE=$isystem`AS_ECHO(["$x_includes"]) | sed -e "s/:/ $isystem/g"`
1780 fi
1781
1782 if test x"${x_includes}" = x; then
1783   bitmapdir=/usr/include/X11/bitmaps
1784 else
1785   # accumulate include directories that have X11 bitmap subdirectories
1786   bmd_acc=
1787   for bmd in `AS_ECHO(["$x_includes"]) | sed -e 's/:/ /g'`; do
1788     if test -d "${bmd}/X11/bitmaps"; then
1789       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1790     fi
1791     if test -d "${bmd}/bitmaps"; then
1792       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1793     fi
1794   done
1795   bitmapdir=${bmd_acc#:}
1796 fi
1797
1798 test "${with_ns}" = maybe && test "${opsys}" != darwin && with_ns=no
1799 HAVE_NS=no
1800 NS_GNUSTEP_CONFIG=no
1801 NS_IMPL_COCOA=no
1802 NS_IMPL_GNUSTEP=no
1803 tmp_CPPFLAGS="$CPPFLAGS"
1804 tmp_CFLAGS="$CFLAGS"
1805 CPPFLAGS="$CPPFLAGS -x objective-c"
1806 CFLAGS="$CFLAGS -x objective-c"
1807 GNU_OBJC_CFLAGS=
1808 LIBS_GNUSTEP=
1809 if test "${with_ns}" != no; then
1810   if test "${opsys}" = darwin; then
1811      NS_IMPL_COCOA=yes
1812      ns_appdir=`pwd`/nextstep/Emacs.app
1813      ns_appbindir=${ns_appdir}/Contents/MacOS
1814      ns_appresdir=${ns_appdir}/Contents/Resources
1815      ns_appsrc=Cocoa/Emacs.base
1816      ns_fontfile=macfont.o
1817   elif flags=$( (gnustep-config --objc-flags) 2>/dev/null); then
1818      NS_IMPL_GNUSTEP=yes
1819      NS_GNUSTEP_CONFIG=yes
1820      GNU_OBJC_CFLAGS=$flags
1821      LIBS_GNUSTEP=$(gnustep-config --gui-libs) || exit
1822   elif test -f $GNUSTEP_CONFIG_FILE; then
1823      NS_IMPL_GNUSTEP=yes
1824      dnl FIXME sourcing this several times in subshells seems inefficient.
1825      GNUSTEP_SYSTEM_HEADERS=$(
1826        . $GNUSTEP_CONFIG_FILE
1827        AS_ECHO(["$GNUSTEP_SYSTEM_HEADERS"])
1828      )
1829      GNUSTEP_SYSTEM_LIBRARIES=$(
1830        . $GNUSTEP_CONFIG_FILE
1831        AS_ECHO(["$GNUSTEP_SYSTEM_LIBRARIES"])
1832      )
1833      dnl I seemed to need these as well with GNUstep-startup 0.25.
1834      GNUSTEP_LOCAL_HEADERS=$(
1835        . $GNUSTEP_CONFIG_FILE
1836        AS_ECHO(["$GNUSTEP_LOCAL_HEADERS"])
1837      )
1838      GNUSTEP_LOCAL_LIBRARIES=$(
1839        . $GNUSTEP_CONFIG_FILE
1840        AS_ECHO(["$GNUSTEP_LOCAL_LIBRARIES"])
1841      )
1842      test "x${GNUSTEP_LOCAL_HEADERS}" != "x" && \
1843        GNUSTEP_LOCAL_HEADERS="-I${GNUSTEP_LOCAL_HEADERS}"
1844      test "x${GNUSTEP_LOCAL_LIBRARIES}" != "x" && \
1845        GNUSTEP_LOCAL_LIBRARIES="-L${GNUSTEP_LOCAL_LIBRARIES}"
1846      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1847      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1848      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES}"
1849      LIBS_GNUSTEP="-lgnustep-gui -lgnustep-base -lobjc -lpthread"
1850      dnl GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS to 0 or 1.
1851      dnl If they had chosen to either define it or not, we could have
1852      dnl just used AC_CHECK_DECL here.
1853      AC_CACHE_CHECK(if GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS,
1854        emacs_cv_objc_exceptions,
1855 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <GNUstepBase/GSConfig.h>]],
1856 [[#if defined BASE_NATIVE_OBJC_EXCEPTIONS && BASE_NATIVE_OBJC_EXCEPTIONS > 0
1857 1;
1858 #else
1859 fail;
1860 #endif]])], emacs_cv_objc_exceptions=yes, emacs_cv_objc_exceptions=no ) )
1861      if test $emacs_cv_objc_exceptions = yes; then
1862        dnl _NATIVE_OBJC_EXCEPTIONS is used by the GNUstep headers.
1863        AC_DEFINE(_NATIVE_OBJC_EXCEPTIONS, 1,
1864          [Define if GNUstep uses ObjC exceptions.])
1865        GNU_OBJC_CFLAGS="-fobjc-exceptions"
1866      fi
1867   fi
1868   if test $NS_IMPL_GNUSTEP = yes; then
1869      ns_appdir=`pwd`/nextstep/Emacs.app
1870      ns_appbindir=${ns_appdir}
1871      ns_appresdir=${ns_appdir}/Resources
1872      ns_appsrc=GNUstep/Emacs.base
1873      ns_fontfile=nsfont.o
1874   fi
1875
1876   dnl This is only used while we test the NS headers, it gets reset below.
1877   CPPFLAGS="$CPPFLAGS $GNU_OBJC_CFLAGS"
1878   CFLAGS="$CFLAGS $GNU_OBJC_CFLAGS"
1879
1880   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1881                   [AC_MSG_ERROR([The include files (AppKit/AppKit.h etc) that
1882 are required for a Nextstep build are missing or cannot be compiled.
1883 Either fix this, or re-configure with the option '--without-ns'.])])
1884
1885   macfont_file=""
1886   if test "${NS_IMPL_COCOA}" = "yes"; then
1887     AC_MSG_CHECKING([for OSX 10.6 or newer])
1888     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <AppKit/AppKit.h>],
1889                                      [
1890 #ifdef MAC_OS_X_VERSION_MAX_ALLOWED
1891 #if MAC_OS_X_VERSION_MAX_ALLOWED >= 1060
1892  ; /* OK */
1893 #else
1894  error "OSX 10.6 or newer required";
1895 #endif
1896 #endif
1897                     ])],
1898                     ns_osx_have_106=yes,
1899                     ns_osx_have_106=no)
1900     AC_MSG_RESULT([$ns_osx_have_106])
1901
1902     if test $ns_osx_have_106 = no; then
1903        AC_MSG_ERROR([OSX 10.6 or newer is required]);
1904     fi
1905   fi
1906 fi
1907
1908 AC_SUBST(LIBS_GNUSTEP)
1909
1910 INSTALL_ARCH_INDEP_EXTRA=install-etc
1911 ns_self_contained=no
1912 NS_OBJ=
1913 NS_OBJC_OBJ=
1914 if test "${HAVE_NS}" = yes; then
1915   if test "$with_toolkit_scroll_bars" = "no"; then
1916     AC_MSG_ERROR([Non-toolkit scroll bars are not implemented for Nextstep.])
1917   fi
1918
1919   window_system=nextstep
1920   # set up packaging dirs
1921   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1922      ns_self_contained=yes
1923      prefix=${ns_appresdir}
1924      exec_prefix=${ns_appbindir}
1925      dnl This one isn't really used, only archlibdir is.
1926      libexecdir="\${ns_appbindir}/libexec"
1927      archlibdir="\${ns_appbindir}/libexec"
1928      etcdocdir="\${ns_appresdir}/etc"
1929      etcdir="\${ns_appresdir}/etc"
1930      dnl FIXME maybe set datarootdir instead.
1931      dnl That would also get applications, icons, man.
1932      infodir="\${ns_appresdir}/info"
1933      mandir="\${ns_appresdir}/man"
1934      lispdir="\${ns_appresdir}/lisp"
1935      test "$locallisppathset" = no && locallisppath=""
1936      INSTALL_ARCH_INDEP_EXTRA=
1937   fi
1938
1939   NS_OBJC_OBJ="nsterm.o nsfns.o nsmenu.o nsselect.o nsimage.o $ns_fontfile"
1940 fi
1941 CFLAGS="$tmp_CFLAGS"
1942 CPPFLAGS="$tmp_CPPFLAGS"
1943 AC_SUBST(INSTALL_ARCH_INDEP_EXTRA)
1944 AC_SUBST(ns_self_contained)
1945 AC_SUBST(NS_OBJ)
1946 AC_SUBST(NS_OBJC_OBJ)
1947
1948 HAVE_W32=no
1949 W32_OBJ=
1950 W32_LIBS=
1951 EMACSRES=
1952 CLIENTRES=
1953 CLIENTW=
1954 W32_RES_LINK=
1955 EMACS_MANIFEST=
1956 UPDATE_MANIFEST=
1957 if test "${with_w32}" != no; then
1958   case "${opsys}" in
1959     cygwin)
1960       AC_CHECK_HEADER([windows.h], [HAVE_W32=yes],
1961              [AC_MSG_ERROR(['--with-w32' was specified, but windows.h
1962                    cannot be found.])])
1963     ;;
1964     mingw32)
1965     ## Using --with-w32 with MinGW is a no-op, but we allow it.
1966     ;;
1967     *)
1968       AC_MSG_ERROR([Using w32 with an autotools build is only supported for Cygwin and MinGW32.])
1969     ;;
1970   esac
1971 fi
1972
1973 if test "${opsys}" = "mingw32"; then
1974   AC_MSG_CHECKING([whether Windows API headers are recent enough])
1975   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1976      #include <windows.h>
1977      #include <usp10.h>]],
1978    [[PIMAGE_NT_HEADERS pHeader;
1979      PIMAGE_SECTION_HEADER pSection = IMAGE_FIRST_SECTION(pHeader)]])],
1980    [emacs_cv_w32api=yes
1981     HAVE_W32=yes],
1982    emacs_cv_w32api=no)
1983   AC_MSG_RESULT($emacs_cv_w32api)
1984   if test "${emacs_cv_w32api}" = "no"; then
1985     AC_MSG_ERROR([the Windows API headers are too old to support this build.])
1986   fi
1987 fi
1988
1989 FIRSTFILE_OBJ=
1990 NTDIR=
1991 LIBS_ECLIENT=
1992 LIB_WSOCK32=
1993 NTLIB=
1994 CM_OBJ="cm.o"
1995 XARGS_LIMIT=
1996 if test "${HAVE_W32}" = "yes"; then
1997   AC_DEFINE(HAVE_NTGUI, 1, [Define to use native MS Windows GUI.])
1998   if test "$with_toolkit_scroll_bars" = "no"; then
1999     AC_MSG_ERROR([Non-toolkit scroll bars are not implemented for w32 build.])
2000   fi
2001   AC_CHECK_TOOL(WINDRES, [windres],
2002                 [AC_MSG_ERROR([No resource compiler found.])])
2003   W32_OBJ="w32fns.o w32menu.o w32reg.o w32font.o w32term.o"
2004   W32_OBJ="$W32_OBJ w32xfns.o w32select.o w32uniscribe.o"
2005   EMACSRES="emacs.res"
2006   case "$canonical" in
2007     x86_64-*-*) EMACS_MANIFEST="emacs-x64.manifest" ;;
2008     *) EMACS_MANIFEST="emacs-x86.manifest" ;;
2009   esac
2010   dnl Construct something of the form "24,4,0,0" with 4 components.
2011   comma_version=`echo "${PACKAGE_VERSION}.0.0" | sed -e 's/\./,/g' -e 's/^\([[^,]]*,[[^,]]*,[[^,]]*,[[^,]]*\).*/\1/'`
2012
2013   comma_space_version=`echo "$comma_version" | sed 's/,/, /g'`
2014   AC_SUBST(comma_version)
2015   AC_SUBST(comma_space_version)
2016   AC_CONFIG_FILES([nt/emacs.rc nt/emacsclient.rc])
2017   if test "${opsys}" = "cygwin"; then
2018     W32_LIBS="$W32_LIBS -lkernel32 -luser32 -lgdi32 -lole32 -lcomdlg32"
2019     W32_LIBS="$W32_LIBS -lusp10 -lcomctl32 -lwinspool"
2020     # Tell the linker that emacs.res is an object (which we compile from
2021     # the rc file), not a linker script.
2022     W32_RES_LINK="-Wl,emacs.res"
2023   else
2024     UPDATE_MANIFEST=update-game-score.exe.manifest
2025     W32_OBJ="$W32_OBJ w32.o w32console.o w32heap.o w32inevt.o w32proc.o"
2026     W32_LIBS="$W32_LIBS -lwinmm -lgdi32 -lcomdlg32"
2027     W32_LIBS="$W32_LIBS -lmpr -lwinspool -lole32 -lcomctl32 -lusp10"
2028     W32_RES_LINK="\$(EMACSRES)"
2029     CLIENTRES="emacsclient.res"
2030     CLIENTW="emacsclientw\$(EXEEXT)"
2031     FIRSTFILE_OBJ=firstfile.o
2032     NTDIR=nt
2033     CM_OBJ=
2034     LIBS_ECLIENT="-lcomctl32"
2035     LIB_WSOCK32="-lwsock32"
2036     NTLIB="ntlib.$ac_objext"
2037     XARGS_LIMIT="-s 10000"
2038   fi
2039 fi
2040 AC_SUBST(W32_OBJ)
2041 AC_SUBST(W32_LIBS)
2042 AC_SUBST(EMACSRES)
2043 AC_SUBST(EMACS_MANIFEST)
2044 AC_SUBST(UPDATE_MANIFEST)
2045 AC_SUBST(CLIENTRES)
2046 AC_SUBST(CLIENTW)
2047 AC_SUBST(W32_RES_LINK)
2048 AC_SUBST(FIRSTFILE_OBJ)
2049 AC_SUBST(NTDIR)
2050 AC_SUBST(CM_OBJ)
2051 AC_SUBST(LIBS_ECLIENT)
2052 AC_SUBST(LIB_WSOCK32)
2053 AC_SUBST(NTLIB)
2054 AC_SUBST(XARGS_LIMIT)
2055
2056 if test "${HAVE_W32}" = "yes"; then
2057   window_system=w32
2058   with_xft=no
2059 fi
2060
2061 ## $window_system is now set to the window system we will
2062 ## ultimately use.
2063
2064 term_header=
2065 HAVE_X_WINDOWS=no
2066 HAVE_X11=no
2067 USE_X_TOOLKIT=none
2068
2069 case "${window_system}" in
2070   x11 )
2071     HAVE_X_WINDOWS=yes
2072     HAVE_X11=yes
2073     term_header=xterm.h
2074     case "${with_x_toolkit}" in
2075       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
2076       motif ) USE_X_TOOLKIT=MOTIF ;;
2077       gtk ) with_gtk=yes
2078             term_header=gtkutil.h
2079 dnl Don't set this for GTK.  A lot of tests below assumes Xt when
2080 dnl USE_X_TOOLKIT is set.
2081             USE_X_TOOLKIT=none ;;
2082       gtk2 ) with_gtk2=yes
2083              term_header=gtkutil.h
2084              USE_X_TOOLKIT=none ;;
2085       gtk3 ) with_gtk3=yes
2086              term_header=gtkutil.h
2087              USE_X_TOOLKIT=none ;;
2088       no ) USE_X_TOOLKIT=none ;;
2089 dnl If user did not say whether to use a toolkit, make this decision later:
2090 dnl use the toolkit if we have gtk, or X11R5 or newer.
2091       * ) USE_X_TOOLKIT=maybe ;;
2092     esac
2093   ;;
2094   nextstep )
2095     term_header=nsterm.h
2096   ;;
2097   w32 )
2098     term_header=w32term.h
2099   ;;
2100 esac
2101
2102 if test "$window_system" = none && test "X$with_x" != "Xno"; then
2103    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
2104    if test "$HAVE_XSERVER" = true ||
2105       test -n "$DISPLAY" ||
2106       {
2107         for emacs_libX11 in /usr/lib/libX11.*; do break; done
2108         test "$emacs_libX11" != '/usr/lib/libX11.*'
2109       }
2110    then
2111         AC_MSG_ERROR([You seem to be running X, but no X development libraries
2112 were found.  You should install the relevant development files for X
2113 and for the toolkit you want, such as Gtk+ or Motif.  Also make
2114 sure you have development files for image handling, i.e.
2115 tiff, gif, jpeg, png and xpm.
2116 If you are sure you want Emacs compiled without X window support, pass
2117   --without-x
2118 to configure.])
2119    fi
2120 fi
2121
2122 # Does the opsystem file prohibit the use of the GNU malloc?
2123 # Assume not, until told otherwise.
2124 GNU_MALLOC=yes
2125
2126 AC_CACHE_CHECK(
2127   [whether malloc is Doug Lea style],
2128   [emacs_cv_var_doug_lea_malloc],
2129   [emacs_cv_var_doug_lea_malloc=no
2130    dnl Hooks do not work with address sanitization.
2131    if test "$emacs_cv_sanitize_address" != yes; then
2132      AC_LINK_IFELSE(
2133        [AC_LANG_PROGRAM(
2134           [[#include <malloc.h>
2135             static void hook (void) {}]],
2136           [[malloc_set_state (malloc_get_state ());
2137             __after_morecore_hook = hook;
2138             __malloc_initialize_hook = hook;]])],
2139        [emacs_cv_var_doug_lea_malloc=yes])
2140    fi])
2141 doug_lea_malloc=$emacs_cv_var_doug_lea_malloc
2142
2143 system_malloc=$emacs_cv_sanitize_address
2144
2145 hybrid_malloc=
2146
2147 case "$opsys" in
2148   ## darwin ld insists on the use of malloc routines in the System framework.
2149   darwin | mingw32 | nacl | sol2-10) system_malloc=yes ;;
2150   cygwin) hybrid_malloc=yes;;
2151 esac
2152
2153 if test "${system_malloc}" != yes && test "${doug_lea_malloc}" != yes \
2154    && test "${UNEXEC_OBJ}" = unexelf.o; then
2155   hybrid_malloc=yes
2156 fi
2157
2158 GMALLOC_OBJ=
2159 HYBRID_MALLOC=
2160 if test "${system_malloc}" = "yes"; then
2161   AC_DEFINE([SYSTEM_MALLOC], 1,
2162     [Define to 1 to use the system memory allocator, even if it is not
2163      Doug Lea style.])
2164   GNU_MALLOC=no
2165   GNU_MALLOC_reason="
2166     (The GNU allocators don't work with this system configuration.)"
2167   VMLIMIT_OBJ=
2168 elif test "$hybrid_malloc" = yes; then
2169   AC_DEFINE(HYBRID_MALLOC, 1,
2170     [Define to use gmalloc before dumping and the system malloc after.])
2171   HYBRID_MALLOC=1
2172   GNU_MALLOC=
2173   GNU_MALLOC_reason="only before dumping"
2174   GMALLOC_OBJ=gmalloc.o
2175   VMLIMIT_OBJ=
2176 else
2177   test "$doug_lea_malloc" != "yes" && GMALLOC_OBJ=gmalloc.o
2178   VMLIMIT_OBJ=vm-limit.o
2179
2180   AC_CHECK_HEADERS([sys/vlimit.h])
2181   AC_CACHE_CHECK([for data_start], [emacs_cv_data_start],
2182     [AC_LINK_IFELSE(
2183        [AC_LANG_PROGRAM(
2184          [[extern char data_start[]; char ch;]],
2185          [[return data_start < &ch;]])],
2186        [emacs_cv_data_start=yes],
2187        [emacs_cv_data_start=no])])
2188   if test $emacs_cv_data_start = yes; then
2189     AC_DEFINE([HAVE_DATA_START], 1,
2190       [Define to 1 if data_start is the address of the start
2191        of the main data segment.])
2192   fi
2193 fi
2194 AC_SUBST([HYBRID_MALLOC])
2195 AM_CONDITIONAL([HYBRID_MALLOC_LIB], [test -n "$HYBRID_MALLOC"])
2196 AC_SUBST(GMALLOC_OBJ)
2197 AC_SUBST(VMLIMIT_OBJ)
2198
2199 if test "$doug_lea_malloc" = "yes" && test "$hybrid_malloc" != yes; then
2200   if test "$GNU_MALLOC" = yes ; then
2201     GNU_MALLOC_reason="
2202       (Using Doug Lea's new malloc from the GNU C Library.)"
2203   fi
2204   AC_DEFINE(DOUG_LEA_MALLOC, 1,
2205     [Define to 1 if the system memory allocator is Doug Lea style,
2206      with malloc hooks and malloc_set_state.])
2207
2208   ## Use mmap directly for allocating larger buffers.
2209   ## FIXME this comes from src/s/{gnu,gnu-linux}.h:
2210   ## #ifdef DOUG_LEA_MALLOC; #undef REL_ALLOC; #endif
2211   ## Does the AC_FUNC_MMAP test below make this check unnecessary?
2212   case "$opsys" in
2213     mingw32|gnu*) REL_ALLOC=no ;;
2214   esac
2215 fi
2216
2217 if test x"${REL_ALLOC}" = x; then
2218   REL_ALLOC=${GNU_MALLOC}
2219 fi
2220
2221 use_mmap_for_buffers=no
2222 case "$opsys" in
2223   cygwin|mingw32) use_mmap_for_buffers=yes ;;
2224 esac
2225
2226 AC_FUNC_MMAP
2227 if test $use_mmap_for_buffers = yes; then
2228   AC_DEFINE(USE_MMAP_FOR_BUFFERS, 1, [Define to use mmap to allocate buffer text.])
2229   REL_ALLOC=no
2230 fi
2231
2232 LIBS="$LIBS_SYSTEM $LIBS"
2233
2234 dnl FIXME replace main with a function we actually want from this library.
2235 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
2236
2237 dnl Check for the POSIX thread library.
2238 LIB_PTHREAD=
2239 AC_CHECK_HEADERS_ONCE(pthread.h)
2240 if test "$ac_cv_header_pthread_h" && test "$opsys" != "mingw32"; then
2241   AC_CACHE_CHECK([for pthread library],
2242     [emacs_cv_pthread_lib],
2243     [emacs_cv_pthread_lib=no
2244      OLD_LIBS=$LIBS
2245      for emacs_pthread_lib in 'none needed' -lpthread; do
2246        case $emacs_pthread_lib in
2247          -*) LIBS="$OLD_LIBS $emacs_pthread_lib";;
2248        esac
2249        AC_LINK_IFELSE(
2250          [AC_LANG_PROGRAM(
2251             [[#include <pthread.h>
2252               #include <signal.h>
2253               sigset_t old_mask, new_mask;
2254               void noop (void) {}]],
2255             [[pthread_t th = pthread_self ();
2256               int status = 0;
2257               status += pthread_create (&th, 0, 0, 0);
2258               status += pthread_sigmask (SIG_BLOCK, &new_mask, &old_mask);
2259               status += pthread_kill (th, 0);
2260               #if ! (defined SYSTEM_MALLOC || defined HYBRID_MALLOC \
2261                      || defined DOUG_LEA_MALLOC)
2262               /* Test for pthread_atfork only if gmalloc uses it,
2263                  as older-style hosts like MirBSD 10 lack it.  */
2264               status += pthread_atfork (noop, noop, noop);
2265               #endif
2266               return status;]])],
2267          [emacs_cv_pthread_lib=$emacs_pthread_lib])
2268        LIBS=$OLD_LIBS
2269        if test "$emacs_cv_pthread_lib" != no; then
2270          break
2271        fi
2272      done])
2273   if test "$emacs_cv_pthread_lib" != no; then
2274     AC_DEFINE([HAVE_PTHREAD], 1, [Define to 1 if you have POSIX threads.])
2275     case $emacs_cv_pthread_lib in
2276       -*) LIB_PTHREAD=$emacs_cv_pthread_lib;;
2277     esac
2278     ac_cv_func_pthread_sigmask=yes
2279     # Some systems optimize for single-threaded programs by default, and
2280     # need special flags to disable these optimizations. For example, the
2281     # definition of 'errno' in <errno.h>.
2282     case $opsys in
2283       hpux* | sol*)
2284         AC_DEFINE([_REENTRANT], 1,
2285           [Define to 1 if your system requires this in multithreaded code.]);;
2286       aix4-2)
2287         AC_DEFINE([_THREAD_SAFE], 1,
2288           [Define to 1 if your system requires this in multithreaded code.]);;
2289     esac
2290   fi
2291 fi
2292 AC_SUBST([LIB_PTHREAD])
2293
2294 dnl Check for need for bigtoc support on IBM AIX
2295
2296 case ${host_os} in
2297 aix*)
2298   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
2299     case $GCC in
2300     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
2301     *) gdb_cv_bigtoc=-bbigtoc ;;
2302     esac
2303
2304     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
2305     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[int i;]])], [], [gdb_cv_bigtoc=])
2306   ])
2307   ;;
2308 esac
2309
2310 # Change CFLAGS, CPPFLAGS, and LIBS temporarily so that C_SWITCH_X_SITE
2311 # is for the tests that follow.  We set them back later on.
2312
2313 REAL_CFLAGS="$CFLAGS"
2314 REAL_CPPFLAGS="$CPPFLAGS"
2315 REAL_LIBS="$LIBS"
2316
2317 if test "${HAVE_X11}" = "yes"; then
2318   DEFS="$C_SWITCH_X_SITE $DEFS"
2319   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
2320   LIBS="-lX11 $LIBS"
2321   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
2322   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
2323
2324   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
2325   # This is handled by LD_SWITCH_X_SITE_RPATH during the real build,
2326   # but it's more convenient here to set LD_RUN_PATH since this
2327   # also works on hosts that don't understand LD_SWITCH_X_SITE_RPATH.
2328   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
2329     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
2330     export LD_RUN_PATH
2331   fi
2332
2333   if test "${opsys}" = "gnu-linux"; then
2334     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
2335     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
2336      [[XOpenDisplay ("foo");]])],
2337      [xgnu_linux_first_failure=no],
2338      [xgnu_linux_first_failure=yes])
2339     if test "${xgnu_linux_first_failure}" = "yes"; then
2340       OLD_CPPFLAGS="$CPPFLAGS"
2341       OLD_LIBS="$LIBS"
2342       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
2343       LIBS="$LIBS -b i486-linuxaout"
2344       AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
2345        [[XOpenDisplay ("foo");]])],
2346        [xgnu_linux_second_failure=no],
2347        [xgnu_linux_second_failure=yes])
2348       if test "${xgnu_linux_second_failure}" = "yes"; then
2349         # If we get the same failure with -b, there is no use adding -b.
2350         # So leave it out.  This plays safe.
2351         AC_MSG_RESULT(no)
2352       else
2353         LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
2354         C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
2355         AC_MSG_RESULT(yes)
2356       fi
2357       CPPFLAGS=$OLD_CPPFLAGS
2358       LIBS=$OLD_LIBS
2359     else
2360       AC_MSG_RESULT(no)
2361     fi
2362   fi
2363
2364   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
2365   # header files included from there.
2366   AC_MSG_CHECKING(for Xkb)
2367   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
2368 #include <X11/XKBlib.h>]],
2369         [[XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);]])],
2370         emacs_xkb=yes, emacs_xkb=no)
2371   AC_MSG_RESULT($emacs_xkb)
2372   if test $emacs_xkb = yes; then
2373     AC_DEFINE(HAVE_XKB, 1, [Define to 1 if you have the Xkb extension.])
2374   fi
2375
2376   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
2377 XScreenNumberOfScreen)
2378 fi
2379
2380 if test "${window_system}" = "x11"; then
2381   AC_MSG_CHECKING(X11 version 6)
2382   AC_CACHE_VAL(emacs_cv_x11_version_6,
2383   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>]],
2384 [[#if XlibSpecificationRelease < 6
2385 fail;
2386 #endif
2387 ]])], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
2388   if test $emacs_cv_x11_version_6 = yes; then
2389     AC_MSG_RESULT(6 or newer)
2390     AC_DEFINE(HAVE_X11R6, 1,
2391               [Define to 1 if you have the X11R6 or newer version of Xlib.])
2392     AC_DEFINE(HAVE_X_I18N, 1, [Define if you have usable i18n support.])
2393     ## inoue@ainet.or.jp says Solaris has a bug related to X11R6-style
2394     ## XIM support.
2395     case "$opsys" in
2396       sol2-*) : ;;
2397       *) AC_DEFINE(HAVE_X11R6_XIM, 1,
2398            [Define if you have usable X11R6-style XIM support.])
2399          ;;
2400     esac
2401   else
2402     AC_MSG_RESULT(before 6)
2403   fi
2404 fi
2405
2406
2407 ### Use -lrsvg-2 if available, unless '--with-rsvg=no' is specified.
2408 HAVE_RSVG=no
2409 if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes" || test "${opsys}" = "mingw32"; then
2410   if test "${with_rsvg}" != "no"; then
2411     RSVG_REQUIRED=2.11.0
2412     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
2413
2414     EMACS_CHECK_MODULES([RSVG], [$RSVG_MODULE])
2415     AC_SUBST(RSVG_CFLAGS)
2416     AC_SUBST(RSVG_LIBS)
2417
2418     if test $HAVE_RSVG = yes; then
2419       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
2420       CFLAGS="$CFLAGS $RSVG_CFLAGS"
2421       # Windows loads librsvg dynamically
2422       if test "${opsys}" = "mingw32"; then
2423         RSVG_LIBS=
2424       fi
2425     fi
2426   fi
2427 fi
2428
2429 HAVE_IMAGEMAGICK=no
2430 if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes" || test "${HAVE_W32}" = "yes"; then
2431   if test "${with_imagemagick}" != "no"; then
2432     ## 6.3.5 is the earliest version known to work; see Bug#17339.
2433     ## 6.8.2 makes Emacs crash; see Bug#13867.
2434     IMAGEMAGICK_MODULE="Wand >= 6.3.5 Wand != 6.8.2"
2435     EMACS_CHECK_MODULES([IMAGEMAGICK], [$IMAGEMAGICK_MODULE])
2436     AC_SUBST(IMAGEMAGICK_CFLAGS)
2437     AC_SUBST(IMAGEMAGICK_LIBS)
2438
2439     if test $HAVE_IMAGEMAGICK = yes; then
2440       AC_DEFINE(HAVE_IMAGEMAGICK, 1, [Define to 1 if using imagemagick.])
2441       OLD_CFLAGS=$CFLAGS
2442       OLD_LIBS=$LIBS
2443       CFLAGS="$CFLAGS $IMAGEMAGICK_CFLAGS"
2444       LIBS="$IMAGEMAGICK_LIBS $LIBS"
2445       AC_CHECK_FUNCS(MagickExportImagePixels MagickMergeImageLayers MagickAutoOrientImage)
2446       CFLAGS=$OLD_CFLAGS
2447       LIBS=$OLD_LIBS
2448     fi
2449   fi
2450 fi
2451
2452 AC_CHECK_LIB(anl, getaddrinfo_a, HAVE_GETADDRINFO_A=yes)
2453 if test "${HAVE_GETADDRINFO_A}" = "yes"; then
2454   AC_DEFINE(HAVE_GETADDRINFO_A, 1,
2455 [Define to 1 if you have getaddrinfo_a for asynchronous DNS resolution.])
2456   GETADDRINFO_A_LIBS="-lanl"
2457   AC_SUBST(GETADDRINFO_A_LIBS)
2458 fi
2459
2460 HAVE_GTK=no
2461 GTK_OBJ=
2462 gtk_term_header=$term_header
2463 check_gtk2=no
2464 gtk3_pkg_errors=
2465 if test "${opsys}" != "mingw32"; then
2466   if test "${with_gtk3}" = "yes" || test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
2467     GLIB_REQUIRED=2.28
2468     GTK_REQUIRED=3.0
2469     GTK_MODULES="gtk+-3.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
2470
2471     dnl Checks for libraries.
2472     EMACS_CHECK_MODULES([GTK], [$GTK_MODULES],
2473       [pkg_check_gtk=yes], [pkg_check_gtk=no])
2474     if test "$pkg_check_gtk" = "no" && test "$with_gtk3" = "yes"; then
2475        AC_MSG_ERROR($GTK_PKG_ERRORS)
2476     fi
2477     if test "$pkg_check_gtk" = "yes"; then
2478        AC_DEFINE(HAVE_GTK3, 1, [Define to 1 if using GTK 3 or later.])
2479        GTK_OBJ=emacsgtkfixed.o
2480        gtk_term_header=gtkutil.h
2481        USE_GTK_TOOLKIT="GTK3"
2482        if test "x$ac_enable_gtk_deprecation_warnings" = x; then
2483          AC_DEFINE([GDK_DISABLE_DEPRECATION_WARNINGS], [1],
2484            [Define to 1 to disable GTK+/GDK deprecation warnings.])
2485          AC_DEFINE([GLIB_DISABLE_DEPRECATION_WARNINGS], [1],
2486            [Define to 1 to disable Glib deprecation warnings.])
2487        fi
2488     else
2489        check_gtk2=yes
2490        gtk3_pkg_errors="$GTK_PKG_ERRORS "
2491     fi
2492   fi
2493
2494   if test "${with_gtk2}" = "yes" || test "$check_gtk2" = "yes"; then
2495     GLIB_REQUIRED=2.10
2496     GTK_REQUIRED=2.10
2497     GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
2498
2499     dnl Checks for libraries.
2500     EMACS_CHECK_MODULES([GTK], [$GTK_MODULES],
2501       [pkg_check_gtk=yes], [pkg_check_gtk=no])
2502     if test "$pkg_check_gtk" = "no" &&
2503        { test "$with_gtk" = yes || test "$with_gtk2" = "yes"; }
2504     then
2505       AC_MSG_ERROR($gtk3_pkg_errors$GTK_PKG_ERRORS)
2506     fi
2507     test "$pkg_check_gtk" = "yes" && USE_GTK_TOOLKIT="GTK2"
2508   fi
2509 fi
2510
2511 OLD_CFLAGS=$CFLAGS
2512 OLD_LIBS=$LIBS
2513
2514 if test x"$pkg_check_gtk" = xyes; then
2515
2516   AC_SUBST(GTK_LIBS)
2517   CFLAGS="$CFLAGS $GTK_CFLAGS"
2518   LIBS="$GTK_LIBS $LIBS"
2519   dnl Try to compile a simple GTK program.
2520   AC_MSG_CHECKING([whether GTK compiles])
2521   GTK_COMPILES=no
2522   AC_LINK_IFELSE(
2523     [AC_LANG_PROGRAM(
2524        [[/* Check the Gtk and Glib APIs.  */
2525          #include <gtk/gtk.h>
2526          #include <glib-object.h>
2527          static void
2528          callback (GObject *go, GParamSpec *spec, gpointer user_data)
2529          {}
2530        ]],
2531        [[
2532          GtkSettings *gs = 0;
2533          /* Use G_CALLBACK to make sure function pointers can be cast to void *;
2534             strict C prohibits this.  Use gtk_main_iteration to test that the
2535             libraries are there.  */
2536          if (g_signal_handler_find (G_OBJECT (gs), G_SIGNAL_MATCH_FUNC,
2537                                     0, 0, 0, G_CALLBACK (callback), 0))
2538            gtk_main_iteration ();
2539        ]])],
2540     [GTK_COMPILES=yes])
2541   AC_MSG_RESULT([$GTK_COMPILES])
2542   if test "${GTK_COMPILES}" != "yes"; then
2543     GTK_OBJ=
2544     if test "$USE_X_TOOLKIT" != "maybe"; then
2545       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
2546     fi
2547   else
2548     C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
2549     HAVE_GTK=yes
2550     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
2551     GTK_OBJ="gtkutil.o $GTK_OBJ"
2552     term_header=$gtk_term_header
2553     USE_X_TOOLKIT=none
2554     AC_MSG_WARN([[Your version of Gtk+ will have problems with
2555        closing open displays.  This is no problem if you just use
2556        one display, but if you use more than one and close one of them
2557        Emacs may crash.
2558        See http://bugzilla.gnome.org/show_bug.cgi?id=85715]])
2559     sleep 3
2560   fi
2561
2562 fi
2563 AC_SUBST(GTK_OBJ)
2564
2565
2566 if test "${HAVE_GTK}" = "yes"; then
2567
2568   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
2569   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
2570   if test "$with_toolkit_scroll_bars" != no; then
2571     with_toolkit_scroll_bars=yes
2572   fi
2573
2574   dnl  Check if we have the old file selection dialog declared and
2575   dnl  in the link library.  In 2.x it may be in the library,
2576   dnl  but not declared if deprecated featured has been selected out.
2577   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
2578   HAVE_GTK_FILE_SELECTION=no
2579   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
2580                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
2581 #include <gtk/gtk.h>])
2582   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
2583     AC_CHECK_FUNCS(gtk_file_selection_new)
2584   fi
2585
2586   dnl Same as above for gtk_handle_box.
2587   HAVE_GTK_HANDLE_BOX=no
2588   AC_CHECK_DECL(GTK_TYPE_HANDLE_BOX, HAVE_GTK_HANDLE_BOX=yes,
2589                    HAVE_GTK_HANDLE_BOX=no, [AC_INCLUDES_DEFAULT
2590 #include <gtk/gtk.h>])
2591   if test "$HAVE_GTK_HANDLE_BOX" = yes; then
2592     AC_CHECK_FUNCS(gtk_handle_box_new)
2593   fi
2594
2595   dnl Same as above for gtk_tearoff_menu_item.
2596   HAVE_GTK_TEAROFF_MENU_ITEM=no
2597   AC_CHECK_DECL(GTK_TYPE_TEAROFF_MENU_ITEM, HAVE_GTK_TEAROFF_MENU_ITEM=yes,
2598                    HAVE_GTK_TEAROFF_MENU_ITEM=no, [AC_INCLUDES_DEFAULT
2599 #include <gtk/gtk.h>])
2600   if test "$HAVE_GTK_TEAROFF_MENU_ITEM" = yes; then
2601     AC_CHECK_FUNCS(gtk_tearoff_menu_item_new)
2602   fi
2603
2604   dnl Check for functions introduced in 2.14 and later.
2605   AC_CHECK_FUNCS(gtk_widget_get_window gtk_widget_set_has_window \
2606                  gtk_dialog_get_action_area gtk_widget_get_sensitive \
2607                  gtk_widget_get_mapped gtk_adjustment_get_page_size \
2608                  gtk_orientable_set_orientation \
2609                  gtk_window_set_has_resize_grip)
2610
2611  term_header=gtkutil.h
2612 fi
2613
2614
2615 dnl Enable xwidgets if GTK3 and WebKitGTK+ are available.
2616 HAVE_XWIDGETS=no
2617 XWIDGETS_OBJ=
2618 if test "$with_xwidgets" != "no"; then
2619   test "$USE_GTK_TOOLKIT" = "GTK3" && test "$window_system" != "none" ||
2620     AC_MSG_ERROR([xwidgets requested but gtk3 not used.])
2621
2622   WEBKIT_REQUIRED=1.4.0
2623   WEBKIT_MODULES="webkitgtk-3.0 >= $WEBKIT_REQUIRED"
2624   EMACS_CHECK_MODULES([WEBKIT], [$WEBKIT_MODULES])
2625   HAVE_XWIDGETS=$HAVE_WEBKIT
2626   test $HAVE_XWIDGETS = yes ||
2627     AC_MSG_ERROR([xwidgets requested but WebKitGTK+ not found.])
2628
2629   XWIDGETS_OBJ=xwidget.o
2630   AC_DEFINE([HAVE_XWIDGETS], 1, [Define to 1 if you have xwidgets support.])
2631 fi
2632 AC_SUBST(XWIDGETS_OBJ)
2633
2634 CFLAGS=$OLD_CFLAGS
2635 LIBS=$OLD_LIBS
2636
2637 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
2638 dnl other platforms.
2639 HAVE_DBUS=no
2640 DBUS_OBJ=
2641 if test "${with_dbus}" = "yes"; then
2642    EMACS_CHECK_MODULES([DBUS], [dbus-1 >= 1.0])
2643    if test "$HAVE_DBUS" = yes; then
2644      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
2645      dnl dbus_watch_get_unix_fd has been introduced in D-Bus 1.1.1.
2646      dnl dbus_type_is_valid and dbus_validate_* have been introduced in
2647      dnl D-Bus 1.5.12.
2648      OLD_LIBS=$LIBS
2649      LIBS="$LIBS $DBUS_LIBS"
2650      AC_CHECK_FUNCS(dbus_watch_get_unix_fd \
2651                     dbus_type_is_valid \
2652                     dbus_validate_bus_name \
2653                     dbus_validate_path \
2654                     dbus_validate_interface \
2655                     dbus_validate_member)
2656      LIBS=$OLD_LIBS
2657      DBUS_OBJ=dbusbind.o
2658    fi
2659 fi
2660 AC_SUBST(DBUS_CFLAGS)
2661 AC_SUBST(DBUS_LIBS)
2662 AC_SUBST(DBUS_OBJ)
2663
2664 dnl GSettings has been tested under GNU/Linux only.
2665 HAVE_GSETTINGS=no
2666 if test "${HAVE_X11}" = "yes" && test "${with_gsettings}" = "yes"; then
2667    EMACS_CHECK_MODULES([GSETTINGS], [gio-2.0 >= 2.26])
2668    if test "$HAVE_GSETTINGS" = "yes"; then
2669       old_CFLAGS=$CFLAGS
2670       CFLAGS="$CFLAGS $GSETTINGS_CFLAGS"
2671       old_LIBS=$LIBS
2672       LIBS="$LIBS $GSETTINGS_LIBS"
2673       AC_MSG_CHECKING([whether GSettings is in gio])
2674       AC_LINK_IFELSE(
2675          [AC_LANG_PROGRAM(
2676              [[/* Check that gsettings really is present.  */
2677              #include <glib-object.h>
2678              #include <gio/gio.h>
2679              ]],
2680              [[
2681                GSettings *settings;
2682                GVariant *val = g_settings_get_value (settings, "");
2683              ]])],
2684          [], HAVE_GSETTINGS=no)
2685       AC_MSG_RESULT([$HAVE_GSETTINGS])
2686
2687       if test "$HAVE_GSETTINGS" = "yes"; then
2688         AC_DEFINE(HAVE_GSETTINGS, 1, [Define to 1 if using GSettings.])
2689         SETTINGS_CFLAGS="$GSETTINGS_CFLAGS"
2690         SETTINGS_LIBS="$GSETTINGS_LIBS"
2691       fi
2692       CFLAGS=$old_CFLAGS
2693       LIBS=$old_LIBS
2694    fi
2695 fi
2696
2697 dnl GConf has been tested under GNU/Linux only.
2698 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
2699 HAVE_GCONF=no
2700 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
2701    EMACS_CHECK_MODULES([GCONF], [gconf-2.0 >= 2.13])
2702    if test "$HAVE_GCONF" = yes; then
2703       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
2704       dnl Newer GConf doesn't link with g_objects, so this is not defined.
2705       SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GCONF_CFLAGS"
2706       SETTINGS_LIBS="$SETTINGS_LIBS $GCONF_LIBS"
2707    fi
2708 fi
2709
2710 if test "$HAVE_GSETTINGS" = "yes" || test "$HAVE_GCONF" = "yes"; then
2711     EMACS_CHECK_MODULES([GOBJECT], [gobject-2.0 >= 2.0])
2712     if test "$HAVE_GOBJECT" = "yes"; then
2713        SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GOBJECT_CFLAGS"
2714        SETTINGS_LIBS="$SETTINGS_LIBS $GOBJECT_LIBS"
2715     fi
2716     SAVE_CFLAGS="$CFLAGS"
2717     SAVE_LIBS="$LIBS"
2718     CFLAGS="$SETTINGS_CFLAGS $CFLAGS"
2719     LIBS="$SETTINGS_LIBS $LIBS"
2720     CFLAGS="$SAVE_CFLAGS"
2721     LIBS="$SAVE_LIBS"
2722 fi
2723 AC_SUBST(SETTINGS_CFLAGS)
2724 AC_SUBST(SETTINGS_LIBS)
2725
2726
2727 dnl SELinux is available for GNU/Linux only.
2728 HAVE_LIBSELINUX=no
2729 LIBSELINUX_LIBS=
2730 if test "${with_selinux}" = "yes"; then
2731    AC_CHECK_LIB([selinux], [lgetfilecon], HAVE_LIBSELINUX=yes, HAVE_LIBSELINUX=no)
2732    if test "$HAVE_LIBSELINUX" = yes; then
2733       AC_DEFINE(HAVE_LIBSELINUX, 1, [Define to 1 if using SELinux.])
2734       LIBSELINUX_LIBS=-lselinux
2735    fi
2736 fi
2737 AC_SUBST(LIBSELINUX_LIBS)
2738
2739 HAVE_GNUTLS=no
2740 if test "${with_gnutls}" = "yes" ; then
2741   EMACS_CHECK_MODULES([LIBGNUTLS], [gnutls >= 2.6.6],
2742     [HAVE_GNUTLS=yes], [HAVE_GNUTLS=no])
2743   if test "${HAVE_GNUTLS}" = "yes"; then
2744     AC_DEFINE(HAVE_GNUTLS, 1, [Define if using GnuTLS.])
2745     EMACS_CHECK_MODULES([LIBGNUTLS3], [gnutls >= 3.0.0],
2746       [AC_DEFINE(HAVE_GNUTLS3, 1, [Define if using GnuTLS v3.])], [])
2747   fi
2748
2749   # Windows loads GnuTLS dynamically
2750   if test "${opsys}" = "mingw32"; then
2751     LIBGNUTLS_LIBS=
2752   fi
2753 fi
2754
2755 AC_SUBST(LIBGNUTLS_LIBS)
2756 AC_SUBST(LIBGNUTLS_CFLAGS)
2757
2758 HAVE_LIBSYSTEMD=no
2759 if test "${with_libsystemd}" = "yes" ; then
2760   dnl This code has been tested with libsystemd 222 and later.
2761   dnl FIXME: Find the earliest version number for which Emacs should work,
2762   dnl and change '222' to that number.
2763   EMACS_CHECK_MODULES([LIBSYSTEMD], [libsystemd >= 222],
2764     [HAVE_LIBSYSTEMD=yes], [HAVE_LIBSYSTEMD=no])
2765   if test "${HAVE_LIBSYSTEMD}" = "yes"; then
2766     AC_DEFINE(HAVE_LIBSYSTEMD, 1, [Define if using libsystemd.])
2767   fi
2768 fi
2769
2770 AC_SUBST(LIBSYSTEMD_LIBS)
2771 AC_SUBST(LIBSYSTEMD_CFLAGS)
2772
2773 NOTIFY_OBJ=
2774 NOTIFY_SUMMARY=no
2775
2776 dnl MS Windows native file monitor is available for mingw32 only.
2777 case $with_file_notification,$opsys in
2778   w32,cygwin)
2779     AC_MSG_ERROR(['--with-file-notification=w32' was specified, but
2780     this is only supported on MS-Windows native and MinGW32 builds.
2781     Consider using gfile instead.])
2782     ;;
2783   w32,* | yes,mingw32)
2784     AC_CHECK_HEADER(windows.h)
2785     if test "$ac_cv_header_windows_h" = yes ; then
2786        AC_DEFINE(HAVE_W32NOTIFY, 1, [Define to 1 to use w32notify.])
2787        NOTIFY_OBJ=w32notify.o
2788        NOTIFY_SUMMARY="yes (w32)"
2789     fi ;;
2790 esac
2791
2792 dnl inotify is available only on GNU/Linux.
2793 case $with_file_notification,$NOTIFY_OBJ in
2794   inotify, | yes,)
2795     AC_CHECK_HEADER(sys/inotify.h)
2796     if test "$ac_cv_header_sys_inotify_h" = yes ; then
2797         AC_CHECK_FUNC(inotify_init1)
2798         if test "$ac_cv_func_inotify_init1" = yes; then
2799           AC_DEFINE(HAVE_INOTIFY, 1, [Define to 1 to use inotify.])
2800           NOTIFY_OBJ=inotify.o
2801           NOTIFY_SUMMARY="yes -lglibc (inotify)"
2802        fi
2803     fi ;;
2804 esac
2805
2806 dnl kqueue is available on BSD-like systems.
2807 case $with_file_notification,$NOTIFY_OBJ in
2808   kqueue,* | yes,)
2809     EMACS_CHECK_MODULES([KQUEUE], [libkqueue])
2810     if test "$HAVE_KQUEUE" = "yes"; then
2811        AC_DEFINE(HAVE_KQUEUE, 1, [Define to 1 to use kqueue.])
2812        CPPFLAGS="$CPPFLAGS -I/usr/include/kqueue"
2813        NOTIFY_CFLAGS=$KQUEUE_CFLAGS
2814        NOTIFY_LIBS=$KQUEUE_LIBS
2815        NOTIFY_OBJ=kqueue.o
2816        NOTIFY_SUMMARY="yes -lkqueue"
2817     else
2818        AC_SEARCH_LIBS(kqueue, [])
2819        if test "$ac_cv_search_kqueue" != no; then
2820          AC_DEFINE(HAVE_KQUEUE, 1, [Define to 1 to use kqueue.])
2821          NOTIFY_OBJ=kqueue.o
2822          NOTIFY_SUMMARY="yes (kqueue)"
2823        fi
2824     fi ;;
2825 esac
2826
2827 dnl g_file_monitor exists since glib 2.18.  G_FILE_MONITOR_EVENT_MOVED
2828 dnl has been added in glib 2.24.  It has been tested under
2829 dnl GNU/Linux only.
2830 case $with_file_notification,$NOTIFY_OBJ in
2831   gfile,* | yes,)
2832     if test "${HAVE_NS}" = yes; then
2833        AC_MSG_ERROR(['--with-file-notification=gfile' is not supported in NextStep builds.
2834 Consider kqueue instead.])
2835     else
2836        EMACS_CHECK_MODULES([GFILENOTIFY], [gio-2.0 >= 2.24])
2837        if test "$HAVE_GFILENOTIFY" = "yes"; then
2838           AC_DEFINE(HAVE_GFILENOTIFY, 1, [Define to 1 if using GFile.])
2839           NOTIFY_CFLAGS=$GFILENOTIFY_CFLAGS
2840           NOTIFY_LIBS=$GFILENOTIFY_LIBS
2841           NOTIFY_OBJ=gfilenotify.o
2842           NOTIFY_SUMMARY="yes -lgio (gfile)"
2843        fi
2844     fi ;;
2845 esac
2846
2847 case $with_file_notification,$NOTIFY_OBJ in
2848   yes,* | no,* | *,?*) ;;
2849   *) AC_MSG_ERROR([File notification '$with_file_notification' requested but requirements not found.]) ;;
2850 esac
2851
2852 if test -n "$NOTIFY_OBJ"; then
2853    AC_DEFINE(USE_FILE_NOTIFY, 1, [Define to 1 if using file notifications.])
2854 fi
2855 AC_SUBST(NOTIFY_CFLAGS)
2856 AC_SUBST(NOTIFY_LIBS)
2857 AC_SUBST(NOTIFY_OBJ)
2858
2859 dnl Do not put whitespace before the #include statements below.
2860 dnl Older compilers (eg sunos4 cc) choke on it.
2861 HAVE_XAW3D=no
2862 LUCID_LIBW=
2863 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
2864   if test "$with_xaw3d" != no; then
2865     AC_CACHE_VAL(emacs_cv_xaw3d,
2866     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2867 #include <X11/Intrinsic.h>
2868 #include <X11/Xaw3d/Simple.h>]],
2869       [[]])],
2870       [AC_CHECK_LIB(Xaw3d, XawScrollbarSetThumb,
2871                     emacs_cv_xaw3d=yes, emacs_cv_xaw3d=no)],
2872       emacs_cv_xaw3d=no)])
2873   else
2874     emacs_cv_xaw3d=no
2875   fi
2876   if test $emacs_cv_xaw3d = yes; then
2877     AC_MSG_CHECKING(for xaw3d)
2878     AC_MSG_RESULT([yes; using Lucid toolkit])
2879     USE_X_TOOLKIT=LUCID
2880     HAVE_XAW3D=yes
2881     LUCID_LIBW=-lXaw3d
2882     AC_DEFINE(HAVE_XAW3D, 1,
2883               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
2884   else
2885     AC_MSG_CHECKING(for xaw3d)
2886     AC_MSG_RESULT(no)
2887     AC_MSG_CHECKING(for libXaw)
2888     AC_CACHE_VAL(emacs_cv_xaw,
2889     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2890 #include <X11/Intrinsic.h>
2891 #include <X11/Xaw/Simple.h>]],
2892       [[]])],
2893       emacs_cv_xaw=yes,
2894       emacs_cv_xaw=no)])
2895     if test $emacs_cv_xaw = yes; then
2896       AC_MSG_RESULT([yes; using Lucid toolkit])
2897       USE_X_TOOLKIT=LUCID
2898       LUCID_LIBW=-lXaw
2899     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
2900       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
2901     else
2902       AC_MSG_ERROR([No X toolkit could be found.
2903 If you are sure you want Emacs compiled without an X toolkit, pass
2904   --with-x-toolkit=no
2905 to configure.  Otherwise, install the development libraries for the toolkit
2906 that you want to use (e.g. Gtk+) and re-run configure.])
2907     fi
2908   fi
2909 fi
2910
2911 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
2912
2913 LIBXTR6=
2914 LIBXMU=
2915 if test "${USE_X_TOOLKIT}" != "none"; then
2916   AC_MSG_CHECKING(X11 toolkit version)
2917   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
2918   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Intrinsic.h>]],
2919 [[#if XtSpecificationRelease < 6
2920 fail;
2921 #endif
2922 ]])], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
2923   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
2924   if test $emacs_cv_x11_toolkit_version_6 = yes; then
2925     AC_MSG_RESULT(6 or newer)
2926     AC_DEFINE(HAVE_X11XTR6, 1,
2927               [Define to 1 if you have the X11R6 or newer version of Xt.])
2928     LIBXTR6="-lSM -lICE"
2929     case "$opsys" in
2930       ## Use libw.a along with X11R6 Xt.
2931       unixware) LIBXTR6="$LIBXTR6 -lw" ;;
2932     esac
2933   else
2934     AC_MSG_RESULT(before 6)
2935   fi
2936
2937 dnl If using toolkit, check whether libXmu.a exists.
2938 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
2939   OLDLIBS="$LIBS"
2940   if test x$HAVE_X11XTR6 = xyes; then
2941     OTHERLIBS='-lXt -lSM -lICE'
2942   else
2943     OTHERLIBS='-lXt'
2944   fi
2945   AC_SEARCH_LIBS([XmuConvertStandardSelection], [Xmu], [], [], [$OTHERLIBS])
2946   if test "X$LIBS" != "X$OLDLIBS"; then
2947     LIBXMU=$ac_cv_search_XmuConvertStandardSelection
2948   fi
2949   LIBS=$OLDLIBS
2950   dnl ac_cv_search_XmuConvertStandardSelection is also referenced below.
2951 fi
2952 AC_SUBST(LIBXTR6)
2953 AC_SUBST(LIBXMU)
2954
2955 LIBXP=
2956 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2957   # OpenMotif may be installed in such a way on some GNU/Linux systems.
2958   if test -d /usr/include/openmotif; then
2959     CPPFLAGS="-I/usr/include/openmotif $CPPFLAGS"
2960     emacs_cv_openmotif=yes
2961     case "$canonical" in
2962       x86_64-*-linux-gnu* | powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*)
2963       test -d /usr/lib64/openmotif && LDFLAGS="-L/usr/lib64/openmotif $LDFLAGS"
2964       ;;
2965       *)
2966       test -d /usr/lib/openmotif && LDFLAGS="-L/usr/lib/openmotif $LDFLAGS"
2967     esac
2968   else
2969     emacs_cv_openmotif=no
2970   fi
2971   AC_CACHE_CHECK(for (Open)Motif version 2.1, emacs_cv_motif_version_2_1,
2972   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <Xm/Xm.h>]],
2973     [[#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
2974 int x = 5;
2975 #else
2976 Motif version prior to 2.1.
2977 #endif]])],
2978     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
2979   if test $emacs_cv_motif_version_2_1 = yes; then
2980     AC_CHECK_LIB(Xp, XpCreateContext, LIBXP=-lXp)
2981     if test x$emacs_cv_openmotif = xyes; then
2982       REAL_CPPFLAGS="-I/usr/include/openmotif $REAL_CPPFLAGS"
2983     fi
2984   else
2985     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
2986     # We put this in CFLAGS temporarily to precede other -I options
2987     # that might be in CFLAGS temporarily.
2988     # We put this in CPPFLAGS where it precedes the other -I options.
2989     OLD_CPPFLAGS=$CPPFLAGS
2990     OLD_CFLAGS=$CFLAGS
2991     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
2992     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
2993     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>]],
2994       [[int x = 5;]])],
2995       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
2996     if test $emacs_cv_lesstif = yes; then
2997       # Make sure this -I option remains in CPPFLAGS after it is set
2998       # back to REAL_CPPFLAGS.
2999       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
3000       # have those other -I options anyway.  Ultimately, having this
3001       # directory ultimately in CPPFLAGS will be enough.
3002       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
3003       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
3004     else
3005       CFLAGS=$OLD_CFLAGS
3006       CPPFLAGS=$OLD_CPPFLAGS
3007     fi
3008   fi
3009   AC_CHECK_HEADER([Xm/BulletinB.h], [],
3010     [AC_MSG_ERROR([Motif toolkit requested but requirements not found.])])
3011 fi
3012
3013 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
3014 dnl using Motif or Xaw3d is available, and unless
3015 dnl --with-toolkit-scroll-bars=no was specified.
3016
3017 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
3018             [Define to 1 if we should use toolkit scroll bars.])dnl
3019 USE_TOOLKIT_SCROLL_BARS=no
3020 if test "${with_toolkit_scroll_bars}" != "no"; then
3021   if test "${USE_X_TOOLKIT}" != "none"; then
3022     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
3023       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
3024       HAVE_XAW3D=no
3025       USE_TOOLKIT_SCROLL_BARS=yes
3026     elif test "${HAVE_XAW3D}" = "yes" || test "${USE_X_TOOLKIT}" = "LUCID"; then
3027       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
3028       USE_TOOLKIT_SCROLL_BARS=yes
3029     fi
3030   elif test "${HAVE_GTK}" = "yes"; then
3031     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
3032     USE_TOOLKIT_SCROLL_BARS=yes
3033   elif test "${HAVE_NS}" = "yes"; then
3034     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
3035     USE_TOOLKIT_SCROLL_BARS=yes
3036   elif test "${HAVE_W32}" = "yes"; then
3037     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
3038     USE_TOOLKIT_SCROLL_BARS=yes
3039   fi
3040 fi
3041
3042 dnl See if XIM is available.
3043 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
3044           #include <X11/Xlib.h>
3045           #include <X11/Xresource.h>]],
3046          [[XIMProc  callback;]])],
3047          [HAVE_XIM=yes
3048          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
3049          HAVE_XIM=no)
3050
3051 dnl '--with-xim' now controls only the initial value of use_xim at run time.
3052
3053 if test "${with_xim}" != "no"; then
3054   AC_DEFINE(USE_XIM, 1,
3055             [Define to 1 if we should use XIM, if it is available.])
3056 fi
3057
3058
3059 if test "${HAVE_XIM}" != "no"; then
3060   late_CFLAGS=$CFLAGS
3061   if test "$GCC" = yes; then
3062     CFLAGS="$CFLAGS --pedantic-errors"
3063   fi
3064   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
3065 #include <X11/Xlib.h>
3066 #include <X11/Xresource.h>]],
3067 [[Display *display;
3068 XrmDatabase db;
3069 char *res_name;
3070 char *res_class;
3071 XIMProc  callback;
3072 XPointer *client_data;
3073 #ifndef __GNUC__
3074 /* If we're not using GCC, it's probably not XFree86, and this is
3075    probably right, but we can't use something like --pedantic-errors.  */
3076 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
3077                                            char*, XIMProc, XPointer*);
3078 #endif
3079 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
3080    client_data);]])],
3081     [emacs_cv_arg6_star=yes])
3082   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
3083          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
3084 either XPointer or XPointer*.])dnl
3085   if test "$emacs_cv_arg6_star" = yes; then
3086     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
3087   else
3088     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
3089   fi
3090   CFLAGS=$late_CFLAGS
3091 fi
3092
3093 ### Start of font-backend (under any platform) section.
3094 # (nothing here yet -- this is a placeholder)
3095 ### End of font-backend (under any platform) section.
3096
3097 ### Start of font-backend (under X11) section.
3098 if test "${HAVE_X11}" = "yes"; then
3099     ## Use -lXft if available, unless '--with-xft=no'.
3100     HAVE_XFT=maybe
3101     if test "x${with_x}" = "xno"; then
3102       with_xft="no";
3103     fi
3104
3105     if test "$with_xft" != no; then
3106       EMACS_CHECK_MODULES([FONTCONFIG], [fontconfig >= 2.2.0])
3107       with_xft=$HAVE_FONTCONFIG
3108     fi
3109
3110     if test "x${with_xft}" != "xno"; then
3111
3112       EMACS_CHECK_MODULES([XFT], [xft >= 0.13.0], [], [HAVE_XFT=no])
3113       ## Because xftfont.c uses XRenderQueryExtension, we also
3114       ## need to link to -lXrender.
3115       HAVE_XRENDER=no
3116       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
3117       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
3118         OLD_CPPFLAGS="$CPPFLAGS"
3119         OLD_CFLAGS="$CFLAGS"
3120         OLD_LIBS="$LIBS"
3121         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
3122         CFLAGS="$CFLAGS $XFT_CFLAGS"
3123         XFT_LIBS="-lXrender $XFT_LIBS"
3124         LIBS="$XFT_LIBS $LIBS"
3125         AC_CHECK_HEADER(X11/Xft/Xft.h,
3126           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS) , ,
3127           [[#include <X11/X.h>]])
3128
3129         if test "${HAVE_XFT}" = "yes"; then
3130           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
3131             AC_SUBST(XFT_LIBS)
3132           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
3133         fi                        # "${HAVE_XFT}" = "yes"
3134         CPPFLAGS=$OLD_CPPFLAGS
3135         CFLAGS=$OLD_CFLAGS
3136         LIBS=$OLD_LIBS
3137       fi                          # "$HAVE_XFT" != no
3138     fi                            # "x${with_xft}" != "xno"
3139
3140     ## We used to allow building with FreeType and without Xft.
3141     ## However, the ftx font backend driver is not in good shape.
3142     if test "$HAVE_XFT" != "yes"; then
3143        dnl For the "Does Emacs use" message at the end.
3144        HAVE_XFT=no
3145        HAVE_FREETYPE=no
3146     else
3147        dnl Strict linkers fail with
3148        dnl ftfont.o: undefined reference to symbol 'FT_New_Face'
3149        dnl if -lfreetype is not specified.
3150        dnl The following is needed to set FREETYPE_LIBS.
3151        EMACS_CHECK_MODULES([FREETYPE], [freetype2])
3152
3153        test "$HAVE_FREETYPE" = "no" && AC_MSG_ERROR(libxft requires libfreetype)
3154     fi
3155
3156     HAVE_LIBOTF=no
3157     if test "${HAVE_FREETYPE}" = "yes"; then
3158       AC_DEFINE(HAVE_FREETYPE, 1,
3159                 [Define to 1 if using the freetype and fontconfig libraries.])
3160       if test "${with_libotf}" != "no"; then
3161         EMACS_CHECK_MODULES([LIBOTF], [libotf])
3162         if test "$HAVE_LIBOTF" = "yes"; then
3163           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
3164           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
3165                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
3166                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
3167           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
3168             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
3169                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
3170           fi
3171         fi
3172       fi
3173     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
3174     dnl Does the new font backend require it, or can it work without it?
3175     fi
3176
3177     HAVE_M17N_FLT=no
3178     if test "${HAVE_LIBOTF}" = yes; then
3179       if test "${with_m17n_flt}" != "no"; then
3180         EMACS_CHECK_MODULES([M17N_FLT], [m17n-flt])
3181         if test "$HAVE_M17N_FLT" = "yes"; then
3182           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
3183         fi
3184       fi
3185     fi
3186 else
3187     HAVE_XFT=no
3188     HAVE_FREETYPE=no
3189     HAVE_LIBOTF=no
3190     HAVE_M17N_FLT=no
3191 fi
3192
3193 ### End of font-backend (under X11) section.
3194
3195 AC_SUBST(FREETYPE_CFLAGS)
3196 AC_SUBST(FREETYPE_LIBS)
3197 AC_SUBST(FONTCONFIG_CFLAGS)
3198 AC_SUBST(FONTCONFIG_LIBS)
3199 AC_SUBST(LIBOTF_CFLAGS)
3200 AC_SUBST(LIBOTF_LIBS)
3201 AC_SUBST(M17N_FLT_CFLAGS)
3202 AC_SUBST(M17N_FLT_LIBS)
3203
3204 HAVE_CAIRO=no
3205 if test "${HAVE_X11}" = "yes"; then
3206   if test "${with_cairo}" != "no"; then
3207     CAIRO_REQUIRED=1.12.0
3208     CAIRO_MODULE="cairo >= $CAIRO_REQUIRED"
3209     EMACS_CHECK_MODULES(CAIRO, $CAIRO_MODULE)
3210     if test $HAVE_CAIRO = yes; then
3211       AC_DEFINE(USE_CAIRO, 1, [Define to 1 if using cairo.])
3212     else
3213       AC_MSG_ERROR([cairo requested but not found.])
3214     fi
3215
3216     CFLAGS="$CFLAGS $CAIRO_CFLAGS"
3217     LIBS="$LIBS $CAIRO_LIBS"
3218     AC_SUBST(CAIRO_CFLAGS)
3219     AC_SUBST(CAIRO_LIBS)
3220   fi
3221 fi
3222
3223 if test "${HAVE_X11}" = "yes"; then
3224   AC_CHECK_HEADER(X11/Xlib-xcb.h,
3225     AC_CHECK_LIB(xcb, xcb_translate_coordinates, HAVE_XCB=yes))
3226   if test "${HAVE_XCB}" = "yes"; then
3227     AC_CHECK_LIB(X11-xcb, XGetXCBConnection, HAVE_X11_XCB=yes)
3228     if test "${HAVE_X11_XCB}" = "yes"; then
3229       AC_DEFINE(USE_XCB, 1,
3230 [Define to 1 if you have the XCB library and X11-XCB library for mixed
3231    X11/XCB programming.])
3232       XCB_LIBS="-lX11-xcb -lxcb"
3233       AC_SUBST(XCB_LIBS)
3234     fi
3235   fi
3236 fi
3237
3238 ### Use -lXpm if available, unless '--with-xpm=no'.
3239 ### mingw32 doesn't use -lXpm, since it loads the library dynamically.
3240 ### In the Cygwin-w32 build, we need to use /usr/include/noX/X11/xpm.h
3241 ### rather than /usr/include/X11/xpm.h, so we set CPPFLAGS (and
3242 ### LDFLAGS) accordingly.
3243 HAVE_XPM=no
3244 LIBXPM=
3245 if test "${HAVE_W32}" = "yes" && test "${opsys}" = "cygwin"; then
3246   if test "${with_xpm}" != "no"; then
3247     SAVE_CPPFLAGS="$CPPFLAGS"
3248     SAVE_LDFLAGS="$LDFLAGS"
3249     CPPFLAGS="$CPPFLAGS -I/usr/include/noX"
3250     LDFLAGS="$LDFLAGS -L/usr/lib/noX"
3251     AC_CHECK_HEADER(X11/xpm.h,
3252       [AC_CHECK_LIB(Xpm, XpmReadFileToImage, HAVE_XPM=yes)])
3253     if test "${HAVE_XPM}" = "yes"; then
3254       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
3255       AC_EGREP_CPP(no_return_alloc_pixels,
3256       [#include "X11/xpm.h"
3257 #ifndef XpmReturnAllocPixels
3258 no_return_alloc_pixels
3259 #endif
3260       ], HAVE_XPM=no, HAVE_XPM=yes)
3261
3262       if test "${HAVE_XPM}" = "yes"; then
3263         REAL_CPPFLAGS="$REAL_CPPFLAGS -I/usr/include/noX"
3264         AC_MSG_RESULT(yes)
3265       else
3266         AC_MSG_RESULT(no)
3267         CPPFLAGS="$SAVE_CPPFLAGS"
3268         LDFLAGS="$SAVE_LDFLAGS"
3269       fi
3270     fi
3271   fi
3272
3273   if test "${HAVE_XPM}" = "yes"; then
3274     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
3275     LIBXPM=-lXpm
3276   fi
3277 fi
3278
3279 if test "${HAVE_X11}" = "yes"; then
3280   dnl Avoid Xpm on AIX unless requested, as it crashes; see Bug#17598.
3281   test "$opsys$with_xpm_set" = aix4-2 && with_xpm=no
3282
3283   if test "${with_xpm}" != "no"; then
3284     AC_CHECK_HEADER(X11/xpm.h,
3285       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
3286     if test "${HAVE_XPM}" = "yes"; then
3287       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
3288       AC_EGREP_CPP(no_return_alloc_pixels,
3289       [#include "X11/xpm.h"
3290 #ifndef XpmReturnAllocPixels
3291 no_return_alloc_pixels
3292 #endif
3293       ], HAVE_XPM=no, HAVE_XPM=yes)
3294
3295       if test "${HAVE_XPM}" = "yes"; then
3296         AC_MSG_RESULT(yes)
3297       else
3298         AC_MSG_RESULT(no)
3299       fi
3300     fi
3301   fi
3302
3303   if test "${HAVE_XPM}" = "yes"; then
3304     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
3305     LIBXPM=-lXpm
3306   elif test "$opsys,$LUCID_LIBW" = aix4-2,-lXaw; then
3307     dnl AIX -lXaw needs -lXpm linked too; see Bug#17598 Message#152.
3308     LIBXPM=-lXpm
3309   fi
3310 fi
3311
3312 ### FIXME: Perhaps regroup to minimize code duplication due to MinGW's
3313 ### slightly different requirements wrt image libraries (it doesn't
3314 ### use -lXpm because it loads the xpm shared library dynamically at
3315 ### run time).
3316 if test "${opsys}" = "mingw32"; then
3317   if test "${with_xpm}" != "no"; then
3318     AC_CHECK_HEADER(X11/xpm.h, HAVE_XPM=yes, HAVE_XPM=no, [
3319 #define FOR_MSW 1])
3320   fi
3321
3322   if test "${HAVE_XPM}" = "yes"; then
3323     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
3324   fi
3325 fi
3326
3327 AC_SUBST(LIBXPM)
3328
3329 ### Use -ljpeg if available, unless '--with-jpeg=no'.
3330 HAVE_JPEG=no
3331 LIBJPEG=
3332 if test "${with_jpeg}" != "no"; then
3333   AC_CACHE_CHECK([for jpeglib 6b or later],
3334     [emacs_cv_jpeglib],
3335     [OLD_LIBS=$LIBS
3336      for emacs_cv_jpeglib in yes -ljpeg no; do
3337        case $emacs_cv_jpeglib in
3338          yes) ;;
3339          no) break;;
3340          *) LIBS="$LIBS $emacs_cv_jpeglib";;
3341        esac
3342        AC_LINK_IFELSE(
3343          [AC_LANG_PROGRAM(
3344             [[#undef HAVE_STDLIB_H /* Avoid config.h/jpeglib.h collision.  */
3345               #include <stdio.h> /* jpeglib.h needs FILE and size_t.  */
3346               #include <jpeglib.h>
3347               #include <jerror.h>
3348               char verify[JPEG_LIB_VERSION < 62 ? -1 : 1];
3349               struct jpeg_decompress_struct cinfo;
3350             ]],
3351             [[
3352               jpeg_create_decompress (&cinfo);
3353               WARNMS (&cinfo, JWRN_JPEG_EOF);
3354               jpeg_destroy_decompress (&cinfo);
3355             ]])],
3356          [emacs_link_ok=yes],
3357          [emacs_link_ok=no])
3358        LIBS=$OLD_LIBS
3359        test $emacs_link_ok = yes && break
3360      done])
3361   if test "$emacs_cv_jpeglib" != no; then
3362     HAVE_JPEG=yes
3363     AC_DEFINE([HAVE_JPEG], 1,
3364       [Define to 1 if you have the jpeg library (typically -ljpeg).])
3365     ### mingw32 doesn't use -ljpeg, since it loads the library
3366     ### dynamically when needed, and doesn't want a run-time
3367     ### dependency on the jpeglib DLL.
3368     test "$emacs_cv_jpeglib" != yes && test "${opsys}" != "mingw32" \
3369     && LIBJPEG=$emacs_cv_jpeglib
3370   fi
3371 fi
3372 AC_SUBST(LIBJPEG)
3373
3374 HAVE_ZLIB=no
3375 LIBZ=
3376 if test "${with_zlib}" != "no"; then
3377   OLIBS=$LIBS
3378   AC_SEARCH_LIBS([inflateEnd], [z], [HAVE_ZLIB=yes])
3379   LIBS=$OLIBS
3380   case $ac_cv_search_inflateEnd in
3381     -*) LIBZ=$ac_cv_search_inflateEnd ;;
3382   esac
3383 fi
3384 if test "${HAVE_ZLIB}" = "yes"; then
3385   AC_DEFINE([HAVE_ZLIB], 1, [Define to 1 if you have the zlib library (-lz).])
3386   ### mingw32 doesn't use -lz, since it loads the library dynamically.
3387   if test "${opsys}" = "mingw32"; then
3388      LIBZ=
3389   fi
3390 fi
3391 AC_SUBST(LIBZ)
3392
3393 ### Dynamic modules support
3394 LIBMODULES=
3395 HAVE_MODULES=no
3396 MODULES_OBJ=
3397 MODULES_SUFFIX=
3398 if test "${with_modules}" != "no"; then
3399   case $opsys in
3400     gnu|gnu-linux)
3401       LIBMODULES="-ldl"
3402       MODULES_SUFFIX=".so"
3403       HAVE_MODULES=yes
3404       ;;
3405     cygwin|mingw32)
3406       MODULES_SUFFIX=".dll"
3407       HAVE_MODULES=yes
3408       ;;
3409     darwin)
3410       MODULES_SUFFIX=".so"
3411       HAVE_MODULES=yes
3412       ;;
3413     *)
3414       # BSD systems have dlopen in libc.
3415       AC_CHECK_FUNC([dlopen],
3416         [MODULES_SUFFIX=".so"
3417          HAVE_MODULES=yes])
3418       ;;
3419   esac
3420
3421   if test "${HAVE_MODULES}" = no; then
3422     AC_MSG_ERROR([Dynamic modules are not supported on your system])
3423   else
3424     SAVE_LIBS=$LIBS
3425     LIBS="$LIBS $LIBMODULES"
3426     AC_CHECK_FUNCS([dladdr dlfunc])
3427     LIBS=$SAVE_LIBS
3428   fi
3429 fi
3430
3431 if test "${HAVE_MODULES}" = yes; then
3432    MODULES_OBJ="dynlib.o emacs-module.o"
3433    AC_DEFINE(HAVE_MODULES, 1, [Define to 1 if dynamic modules are enabled])
3434    AC_DEFINE_UNQUOTED(MODULES_SUFFIX, "$MODULES_SUFFIX",
3435      [System extension for dynamic libraries])
3436 fi
3437 AC_SUBST(MODULES_OBJ)
3438 AC_SUBST(LIBMODULES)
3439
3440 ### Use -lpng if available, unless '--with-png=no'.
3441 HAVE_PNG=no
3442 LIBPNG=
3443 PNG_CFLAGS=
3444 if test "${NS_IMPL_COCOA}" = yes; then
3445   : # Nothing to do
3446 elif test "${with_png}" != no; then
3447   # mingw32 loads the library dynamically.
3448   if test "$opsys" = mingw32; then
3449     AC_CHECK_HEADER([png.h], [HAVE_PNG=yes])
3450   elif test "${HAVE_X11}" = "yes" || test "${HAVE_W32}" = "yes"; then
3451     AC_MSG_CHECKING([for png])
3452     png_cflags=`(libpng-config --cflags) 2>&AS_MESSAGE_LOG_FD` &&
3453     png_libs=`(libpng-config --libs) 2>&AS_MESSAGE_LOG_FD` || {
3454       # libpng-config does not work; configure by hand.
3455       # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
3456       # in /usr/include/libpng.
3457       if test -r /usr/include/libpng/png.h &&
3458          test ! -r /usr/include/png.h; then
3459         png_cflags=-I/usr/include/libpng
3460       else
3461         png_cflags=
3462       fi
3463       png_libs='-lpng'
3464     }
3465     SAVE_CFLAGS=$CFLAGS
3466     SAVE_LIBS=$LIBS
3467     CFLAGS="$CFLAGS $png_cflags"
3468     LIBS="$png_libs -lz -lm $LIBS"
3469     AC_LINK_IFELSE(
3470       [AC_LANG_PROGRAM([[#include <png.h>]],
3471          [[return !png_get_channels (0, 0);]])],
3472       [HAVE_PNG=yes
3473        PNG_CFLAGS=`AS_ECHO(["$png_cflags"]) | sed -e "$edit_cflags"`
3474        LIBPNG=$png_libs
3475        # $LIBPNG requires explicit -lz in some cases.
3476        # We don't know what those cases are, exactly, so play it safe and
3477        # append -lz to any nonempty $LIBPNG, unless we're already using LIBZ.
3478        if test -n "$LIBPNG" && test -z "$LIBZ"; then
3479          LIBPNG="$LIBPNG -lz"
3480        fi])
3481     CFLAGS=$SAVE_CFLAGS
3482     LIBS=$SAVE_LIBS
3483     AC_MSG_RESULT([$HAVE_PNG])
3484   fi
3485 fi
3486 if test $HAVE_PNG = yes; then
3487   AC_DEFINE([HAVE_PNG], [1], [Define to 1 if you have the png library.])
3488
3489   SAVE_CFLAGS=$CFLAGS
3490   CFLAGS="$CFLAGS $PNG_CFLAGS"
3491   AC_CHECK_DECL([png_longjmp],
3492     [],
3493     [AC_DEFINE([PNG_DEPSTRUCT], [],
3494        [Define to empty to suppress deprecation warnings when building
3495         with --enable-gcc-warnings and with libpng versions before 1.5,
3496         which lack png_longjmp.])],
3497     [[#include <png.h>
3498     ]])
3499   CFLAGS=$SAVE_CFLAGS
3500 fi
3501 AC_SUBST(LIBPNG)
3502 AC_SUBST(PNG_CFLAGS)
3503
3504 ### Use -ltiff if available, unless '--with-tiff=no'.
3505 ### mingw32 doesn't use -ltiff, since it loads the library dynamically.
3506 HAVE_TIFF=no
3507 LIBTIFF=
3508 if test "${opsys}" = "mingw32"; then
3509   if test "${with_tiff}" != "no"; then
3510     AC_CHECK_HEADER(tiffio.h, HAVE_TIFF=yes, HAVE_TIFF=no)
3511   fi
3512   if test "${HAVE_TIFF}" = "yes"; then
3513     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
3514   fi
3515 elif test "${HAVE_X11}" = "yes" || test "${HAVE_W32}" = "yes"; then
3516   if test "${with_tiff}" != "no"; then
3517     AC_CHECK_HEADER(tiffio.h,
3518       [tifflibs="-lz -lm"
3519       # At least one tiff package requires the jpeg library.
3520       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
3521       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
3522   fi
3523
3524   if test "${HAVE_TIFF}" = "yes"; then
3525     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
3526     dnl FIXME -lz -lm, as per libpng?
3527     LIBTIFF=-ltiff
3528   fi
3529 fi
3530 AC_SUBST(LIBTIFF)
3531
3532 ### Use -lgif or -lungif if available, unless '--with-gif=no'.
3533 ### mingw32 doesn't use -lgif/-lungif, since it loads the library dynamically.
3534 HAVE_GIF=no
3535 LIBGIF=
3536 if test "${opsys}" = "mingw32"; then
3537   if test "${with_gif}" != "no"; then
3538     AC_CHECK_HEADER(gif_lib.h, HAVE_GIF=yes, HAVE_GIF=no)
3539   fi
3540   if test "${HAVE_GIF}" = "yes"; then
3541     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
3542   fi
3543 elif test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no" \
3544         || test "${HAVE_W32}" = "yes"; then
3545   AC_CHECK_HEADER(gif_lib.h,
3546 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
3547 # Earlier versions can crash Emacs, but version 5.0 removes EGifPutExtensionLast.
3548     [AC_CHECK_LIB(gif, GifMakeMapObject, HAVE_GIF=yes,
3549         [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])])
3550
3551   if test "$HAVE_GIF" = yes; then
3552     LIBGIF=-lgif
3553   elif test "$HAVE_GIF" = maybe; then
3554 # If gif_lib.h but no libgif, try libungif.
3555     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
3556     test "$HAVE_GIF" = yes && LIBGIF=-lungif
3557   fi
3558
3559   if test "${HAVE_GIF}" = "yes"; then
3560     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
3561   fi
3562 fi
3563 AC_SUBST(LIBGIF)
3564
3565 dnl Check for required libraries.
3566 if test "${HAVE_X11}" = "yes"; then
3567   MISSING=""
3568   WITH_NO=""
3569   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
3570     MISSING="libXpm" && WITH_NO="--with-xpm=no"
3571   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
3572     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
3573   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
3574     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
3575   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
3576     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
3577   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
3578     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
3579
3580   if test "X${MISSING}" != X; then
3581     AC_MSG_ERROR([The following required libraries were not found:
3582     $MISSING
3583 Maybe some development libraries/packages are missing?
3584 If you don't want to link with them give
3585     $WITH_NO
3586 as options to configure])
3587   fi
3588 fi
3589
3590 ### Use -lgpm if available, unless '--with-gpm=no'.
3591 HAVE_GPM=no
3592 LIBGPM=
3593 if test "${with_gpm}" != "no"; then
3594   AC_CHECK_HEADER(gpm.h,
3595     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
3596
3597   if test "${HAVE_GPM}" = "yes"; then
3598     AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
3599     LIBGPM=-lgpm
3600   fi
3601 fi
3602 AC_SUBST(LIBGPM)
3603
3604 dnl Check for malloc/malloc.h on darwin
3605 AC_CHECK_HEADERS_ONCE(malloc/malloc.h)
3606
3607 GNUSTEP_CFLAGS=
3608 ### Use NeXTstep API to implement GUI.
3609 if test "${HAVE_NS}" = "yes"; then
3610   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
3611   if test "${NS_IMPL_COCOA}" = "yes"; then
3612     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
3613   fi
3614   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
3615     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
3616     if test $NS_GNUSTEP_CONFIG != yes; then
3617       # See also .m.o rule in src/Makefile.in.  */
3618       # FIXME: are all these flags really needed?  Document here why.  */
3619       GNUSTEP_CFLAGS="-D_REENTRANT -fPIC -fno-strict-aliasing -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
3620       ## Extra CFLAGS applied to src/*.m files.
3621       GNU_OBJC_CFLAGS="$GNU_OBJC_CFLAGS -fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
3622     fi
3623   fi
3624   OTHER_FILES=ns-app
3625 fi
3626
3627 ### Use session management (-lSM -lICE) if available
3628 HAVE_X_SM=no
3629 LIBXSM=
3630 if test "${HAVE_X11}" = "yes"; then
3631   AC_CHECK_HEADER(X11/SM/SMlib.h,
3632     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
3633
3634   if test "${HAVE_X_SM}" = "yes"; then
3635     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
3636     LIBXSM="-lSM -lICE"
3637   fi
3638 fi
3639 AC_SUBST(LIBXSM)
3640
3641 ### Use XRandr (-lXrandr) if available
3642 HAVE_XRANDR=no
3643 if test "${HAVE_X11}" = "yes"; then
3644   XRANDR_REQUIRED=1.2.2
3645   XRANDR_MODULES="xrandr >= $XRANDR_REQUIRED"
3646   EMACS_CHECK_MODULES([XRANDR], [$XRANDR_MODULES])
3647   if test $HAVE_XRANDR = no; then
3648     # Test old way in case pkg-config doesn't have it (older machines).
3649     # Include Xrender.h by hand to work around bug in older Xrandr.h
3650     # (e.g. RHEL5) and silence (harmless) configure warning (bug#18465).
3651     AC_CHECK_HEADER(X11/extensions/Xrandr.h,
3652       [AC_CHECK_LIB(Xrandr, XRRGetScreenResources, HAVE_XRANDR=yes)],
3653       [], [AC_INCLUDES_DEFAULT
3654 #include <X11/extensions/Xrender.h>])
3655     if test $HAVE_XRANDR = yes; then
3656       XRANDR_LIBS=-lXrandr
3657     fi
3658   fi
3659   if test $HAVE_XRANDR = yes; then
3660     AC_DEFINE(HAVE_XRANDR, 1, [Define to 1 if you have the XRandr extension.])
3661   fi
3662 fi
3663 AC_SUBST(XRANDR_CFLAGS)
3664 AC_SUBST(XRANDR_LIBS)
3665
3666 ### Use Xinerama (-lXinerama) if available
3667 HAVE_XINERAMA=no
3668 if test "${HAVE_X11}" = "yes"; then
3669   XINERAMA_REQUIRED=1.0.2
3670   XINERAMA_MODULES="xinerama >= $XINERAMA_REQUIRED"
3671   EMACS_CHECK_MODULES([XINERAMA], [$XINERAMA_MODULES])
3672   if test $HAVE_XINERAMA = no; then
3673     # Test old way in case pkg-config doesn't have it (older machines).
3674     AC_CHECK_HEADER(X11/extensions/Xinerama.h,
3675       [AC_CHECK_LIB(Xinerama, XineramaQueryExtension, HAVE_XINERAMA=yes)])
3676     if test $HAVE_XINERAMA = yes; then
3677       XINERAMA_LIBS=-lXinerama
3678     fi
3679   fi
3680   if test $HAVE_XINERAMA = yes; then
3681     AC_DEFINE(HAVE_XINERAMA, 1, [Define to 1 if you have the Xinerama extension.])
3682   fi
3683 fi
3684 AC_SUBST(XINERAMA_CFLAGS)
3685 AC_SUBST(XINERAMA_LIBS)
3686
3687 ### Use Xfixes (-lXfixes) if available
3688 HAVE_XFIXES=no
3689 if test "${HAVE_X11}" = "yes"; then
3690   XFIXES_REQUIRED=4.0.0
3691   XFIXES_MODULES="xfixes >= $XFIXES_REQUIRED"
3692   EMACS_CHECK_MODULES([XFIXES], [$XFIXES_MODULES])
3693   if test $HAVE_XFIXES = no; then
3694     # Test old way in case pkg-config doesn't have it (older machines).
3695     AC_CHECK_HEADER(X11/extensions/Xfixes.h,
3696       [AC_CHECK_LIB(Xfixes, XFixesHideCursor, HAVE_XFIXES=yes)])
3697     if test $HAVE_XFIXES = yes; then
3698       XFIXES_LIBS=-lXfixes
3699     fi
3700   fi
3701   if test $HAVE_XFIXES = yes; then
3702     AC_DEFINE(HAVE_XFIXES, 1, [Define to 1 if you have the Xfixes extension.])
3703   fi
3704 fi
3705 AC_SUBST(XFIXES_CFLAGS)
3706 AC_SUBST(XFIXES_LIBS)
3707
3708 ### Use libxml (-lxml2) if available
3709 ### mingw32 doesn't use -lxml2, since it loads the library dynamically.
3710 HAVE_LIBXML2=no
3711 if test "${with_xml2}" != "no"; then
3712   ### I'm not sure what the version number should be, so I just guessed.
3713   EMACS_CHECK_MODULES([LIBXML2], [libxml-2.0 > 2.6.17])
3714   # Built-in libxml2 on OS X 10.8 lacks libxml-2.0.pc.
3715   if test "${HAVE_LIBXML2}" != "yes" && test "$opsys" = "darwin"; then
3716     SAVE_CPPFLAGS="$CPPFLAGS"
3717     if test -z "$xcsdkdir" -a -n "$XCRUN" -a ! -d /usr/include; then
3718       dnl /usr/include is not found.  Try Xcode SDK dir if it is sane.
3719       xcsdkdir=`$XCRUN --show-sdk-path 2>/dev/null`
3720       case $xcsdkdir in
3721         *[[\\\"\#\$\&\'\`$am_lf\ \      ]]*)
3722         xcsdkdir="" ;;
3723       esac
3724     fi
3725     CPPFLAGS="$CPPFLAGS -I$xcsdkdir/usr/include/libxml2"
3726     AC_CHECK_HEADER(libxml/HTMLparser.h,
3727       [AC_CHECK_DECL(HTML_PARSE_RECOVER, HAVE_LIBXML2=yes, ,
3728                      [#include <libxml/HTMLparser.h>])])
3729     CPPFLAGS="$SAVE_CPPFLAGS"
3730     if test "${HAVE_LIBXML2}" = "yes"; then
3731       LIBXML2_CFLAGS="-I'$xcsdkdir/usr/include/libxml2'"
3732       LIBXML2_LIBS="-lxml2"
3733     fi
3734   fi
3735   if test "${HAVE_LIBXML2}" = "yes"; then
3736     if test "${opsys}" != "mingw32"; then
3737       AC_CHECK_LIB(xml2, htmlReadMemory, HAVE_LIBXML2=yes, HAVE_LIBXML2=no,
3738         [$LIBXML2_LIBS])
3739     else
3740       LIBXML2_LIBS=""
3741     fi
3742     if test "${HAVE_LIBXML2}" = "yes"; then
3743       AC_DEFINE(HAVE_LIBXML2, 1, [Define to 1 if you have the libxml library (-lxml2).])
3744     else
3745       LIBXML2_LIBS=""
3746       LIBXML2_CFLAGS=""
3747     fi
3748   fi
3749 fi
3750 AC_SUBST(LIBXML2_LIBS)
3751 AC_SUBST(LIBXML2_CFLAGS)
3752
3753 # Check for mail-locking functions in a "mail" library.  Probably this should
3754 # have the same check as for liblockfile below.
3755 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
3756 if test $have_mail = yes; then
3757   LIBS_MAIL=-lmail
3758   AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the 'mail' library (-lmail).])
3759
3760   OLD_LIBS=$LIBS
3761   LIBS="$LIBS_MAIL $LIBS"
3762   AC_CHECK_FUNCS(touchlock)
3763   LIBS=$OLD_LIBS
3764 else
3765   LIBS_MAIL=
3766 fi
3767 dnl Debian, at least:
3768 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
3769 if test $have_lockfile = yes; then
3770    LIBS_MAIL=-llockfile
3771    AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the 'lockfile' library (-llockfile).])
3772 else
3773 # If we have the shared liblockfile, assume we must use it for mail
3774 # locking (e.g. Debian).  If we couldn't link against liblockfile
3775 # (no liblockfile.a installed), ensure that we don't need to.
3776   dnl This works for files generally, not just executables.
3777   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
3778   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
3779                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
3780   if test $ac_cv_prog_liblockfile = yes; then
3781     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
3782 This probably means that movemail could lose mail.
3783 There may be a 'development' package to install containing liblockfile.])
3784   fi
3785 fi
3786 AC_CHECK_HEADERS_ONCE(maillock.h)
3787 AC_SUBST(LIBS_MAIL)
3788
3789 ## Define MAIL_USE_FLOCK (or LOCKF) if the mailer uses flock (or lockf) to
3790 ## interlock access to the mail spool.  The alternative is a lock file named
3791 ## /usr/spool/mail/$USER.lock.
3792 mail_lock=no
3793 case "$opsys" in
3794   aix4-2) mail_lock="lockf" ;;
3795
3796   gnu|freebsd|dragonfly|netbsd|openbsd|darwin) mail_lock="flock" ;;
3797
3798   ## On GNU/Linux systems, both methods are used by various mail programs.
3799   ## I assume most people are using newer mailers that have heard of flock.
3800   ## Change this if you need to.
3801   ## Debian contains a patch which says: "On Debian/GNU/Linux systems,
3802   ## configure gets the right answers, and that means *NOT* using flock.
3803   ## Using flock is guaranteed to be the wrong thing. See Debian Policy
3804   ## for details." and then uses '#ifdef DEBIAN'.  Unfortunately the
3805   ## Debian maintainer hasn't provided a clean fix for Emacs.
3806   ## movemail.c will use 'maillock' when MAILDIR, HAVE_LIBMAIL and
3807   ## HAVE_MAILLOCK_H are defined, so the following appears to be the
3808   ## correct logic.  -- fx
3809   ## We must check for HAVE_LIBLOCKFILE too, as movemail does.
3810   ## liblockfile is a Free Software replacement for libmail, used on
3811   ## Debian systems and elsewhere. -rfr.
3812   gnu-*)
3813     mail_lock="flock"
3814     if test $have_mail = yes || test $have_lockfile = yes; then
3815       test $ac_cv_header_maillock_h = yes && mail_lock=no
3816     fi
3817     ;;
3818
3819   mingw32)
3820     mail_lock="none-needed" ;;
3821 esac
3822
3823 BLESSMAIL_TARGET=
3824 case "$mail_lock" in
3825   flock) AC_DEFINE(MAIL_USE_FLOCK, 1, [Define if the mailer uses flock to interlock the mail spool.]) ;;
3826
3827   lockf) AC_DEFINE(MAIL_USE_LOCKF, 1, [Define if the mailer uses lockf to interlock the mail spool.]) ;;
3828
3829   none-needed) ;;
3830
3831   *) BLESSMAIL_TARGET="need-blessmail" ;;
3832 esac
3833 AC_SUBST(BLESSMAIL_TARGET)
3834
3835 OLD_LIBS=$LIBS
3836 LIBS="$LIB_PTHREAD $LIB_MATH $LIBS"
3837 AC_CHECK_FUNCS(accept4 fchdir gethostname \
3838 getrusage get_current_dir_name \
3839 lrand48 random rint \
3840 select getpagesize setlocale newlocale \
3841 getrlimit setrlimit shutdown \
3842 pthread_sigmask strsignal setitimer \
3843 sendto recvfrom getsockname getpeername getifaddrs freeifaddrs \
3844 gai_strerror sync \
3845 getpwent endpwent getgrent endgrent \
3846 cfmakeraw cfsetspeed copysign __executable_start log2)
3847 LIBS=$OLD_LIBS
3848
3849 dnl No need to check for posix_memalign if aligned_alloc works.
3850 AC_CHECK_FUNCS([aligned_alloc posix_memalign], [break])
3851 AC_CHECK_DECLS([aligned_alloc], [], [], [[#include <stdlib.h>]])
3852
3853 dnl Cannot use AC_CHECK_FUNCS
3854 AC_CACHE_CHECK([for __builtin_unwind_init],
3855                emacs_cv_func___builtin_unwind_init,
3856 [AC_LINK_IFELSE([AC_LANG_PROGRAM([], [__builtin_unwind_init ();])],
3857                 emacs_cv_func___builtin_unwind_init=yes,
3858                 emacs_cv_func___builtin_unwind_init=no)])
3859 if test $emacs_cv_func___builtin_unwind_init = yes; then
3860   AC_DEFINE(HAVE___BUILTIN_UNWIND_INIT, 1,
3861             [Define to 1 if you have the '__builtin_unwind_init' function.])
3862 fi
3863
3864 AC_CHECK_HEADERS_ONCE(sys/un.h)
3865
3866 AC_FUNC_FSEEKO
3867
3868 # UNIX98 PTYs.
3869 AC_CHECK_FUNCS(grantpt)
3870
3871 # PTY-related GNU extensions.
3872 AC_CHECK_FUNCS(getpt posix_openpt)
3873
3874 # Check this now, so that we will NOT find the above functions in ncurses.
3875 # That is because we have not set up to link ncurses in lib-src.
3876 # It's better to believe a function is not available
3877 # than to expect to find it in ncurses.
3878 # Also we need tputs and friends to be able to build at all.
3879 AC_MSG_CHECKING([for library containing tputs])
3880 # Run a test program that contains a call to tputs, a call that is
3881 # never executed.  This tests whether a pre-'main' dynamic linker
3882 # works with the library.  It's too much trouble to actually call
3883 # tputs in the test program, due to portability hassles.  When
3884 # cross-compiling, assume the test program will run if it links.
3885 AC_DEFUN([tputs_link_source], [
3886   AC_LANG_SOURCE(
3887      [[extern void tputs (const char *, int, int (*)(int));
3888        int main (int argc, char **argv)
3889        {
3890           if (argc == 10000)
3891             tputs (argv[0], 0, 0);
3892           return 0;
3893        }]])
3894 ])
3895 if test "${opsys}" = "mingw32"; then
3896   msg='none required'
3897 else
3898   # Maybe curses should be tried earlier?
3899   # See http://debbugs.gnu.org/cgi/bugreport.cgi?bug=9736#35
3900   for tputs_library in '' tinfo ncurses terminfo termcap curses; do
3901     OLIBS=$LIBS
3902     if test -z "$tputs_library"; then
3903       LIBS_TERMCAP=
3904       msg='none required'
3905     else
3906       LIBS_TERMCAP=-l$tputs_library
3907       msg=$LIBS_TERMCAP
3908       LIBS="$LIBS_TERMCAP $LIBS"
3909     fi
3910     AC_RUN_IFELSE([tputs_link_source], [], [msg=no],
3911       [AC_LINK_IFELSE([tputs_link_source], [], [msg=no])])
3912     LIBS=$OLIBS
3913     if test "X$msg" != Xno; then
3914       break
3915     fi
3916   done
3917 fi
3918 AC_MSG_RESULT([$msg])
3919 if test "X$msg" = Xno; then
3920   AC_MSG_ERROR([The required function 'tputs' was not found in any library.
3921 The following libraries were tried (in order):
3922   libtinfo, libncurses, libterminfo, libtermcap, libcurses
3923 Please try installing whichever of these libraries is most appropriate
3924 for your system, together with its header files.
3925 For example, a libncurses-dev(el) or similar package.])
3926 fi
3927
3928 ## Use termcap instead of terminfo?
3929 ## Only true for: freebsd < 40000, ms-w32, msdos, netbsd < 599002500.
3930 TERMINFO=yes
3931 ## FIXME?  In the cases below where we unconditionally set
3932 ## LIBS_TERMCAP="-lncurses", this overrides LIBS_TERMCAP = -ltinfo,
3933 ## if that was found above to have tputs.
3934 ## Should we use the gnu* logic everywhere?
3935 case "$opsys" in
3936   ## darwin: Prevents crashes when running Emacs in Terminal.app under 10.2.
3937   ##  The ncurses library has been moved out of the System framework in
3938   ##  Mac OS X 10.2.  So if configure detects it, set the command-line
3939   ##  option to use it.
3940   darwin) LIBS_TERMCAP="-lncurses" ;;
3941
3942   gnu*) test -z "$LIBS_TERMCAP" && LIBS_TERMCAP="-lncurses" ;;
3943
3944   freebsd)
3945     AC_MSG_CHECKING([whether FreeBSD is new enough to use terminfo])
3946     AC_CACHE_VAL(emacs_cv_freebsd_terminfo,
3947     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <osreldate.h>]],
3948 [[#if __FreeBSD_version < 400000
3949 fail;
3950 #endif
3951 ]])], emacs_cv_freebsd_terminfo=yes, emacs_cv_freebsd_terminfo=no)])
3952
3953     AC_MSG_RESULT($emacs_cv_freebsd_terminfo)
3954
3955     if test $emacs_cv_freebsd_terminfo = yes; then
3956       LIBS_TERMCAP="-lncurses"
3957     else
3958       TERMINFO=no
3959       LIBS_TERMCAP="-ltermcap"
3960     fi
3961     ;;
3962
3963   mingw32)
3964     TERMINFO=no
3965     LIBS_TERMCAP=
3966     ;;
3967
3968   netbsd)
3969     if test "x$LIBS_TERMCAP" != "x-lterminfo"; then
3970       TERMINFO=no
3971       LIBS_TERMCAP="-ltermcap"
3972     fi
3973     ;;
3974
3975   openbsd | dragonfly) LIBS_TERMCAP="-lncurses" ;;
3976
3977   ## hpux: Make sure we get select from libc rather than from libcurses
3978   ##  because libcurses on HPUX 10.10 has a broken version of select.
3979   ##  We used to use -lc -lcurses, but this may be cleaner.
3980   ## FIXME?  But TERMINFO = yes on hpux (it used to be explicitly
3981   # set that way, now it uses the default).  Isn't this a contradiction?
3982   hpux*) LIBS_TERMCAP="-ltermcap" ;;
3983
3984 esac
3985
3986 TERMCAP_OBJ=tparam.o
3987 if test $TERMINFO = yes; then
3988   AC_DEFINE(TERMINFO, 1, [Define to 1 if you use terminfo instead of termcap.])
3989   TERMCAP_OBJ=terminfo.o
3990 fi
3991 if test "X$LIBS_TERMCAP" = "X-lncurses"; then
3992   AC_DEFINE(USE_NCURSES, 1, [Define to 1 if you use ncurses.])
3993 fi
3994 AC_SUBST(LIBS_TERMCAP)
3995 AC_SUBST(TERMCAP_OBJ)
3996
3997 # GNU/Linux-specific timer functions.
3998 AC_CACHE_CHECK([for timerfd interface], [emacs_cv_have_timerfd],
3999   [AC_COMPILE_IFELSE(
4000      [AC_LANG_PROGRAM([[#include <sys/timerfd.h>
4001                       ]],
4002                       [[timerfd_create (CLOCK_REALTIME,
4003                                         TFD_CLOEXEC | TFD_NONBLOCK);
4004                         timerfd_settime (0, TFD_TIMER_ABSTIME, 0, 0);]])],
4005      [emacs_cv_have_timerfd=yes],
4006      [emacs_cv_have_timerfd=no])])
4007 if test "$emacs_cv_have_timerfd" = yes; then
4008   AC_DEFINE([HAVE_TIMERFD], 1,
4009     [Define to 1 if timerfd functions are supported as in GNU/Linux.])
4010 fi
4011
4012 # Alternate stack for signal handlers.
4013 AC_CACHE_CHECK([whether signals can be handled on alternate stack],
4014                [emacs_cv_alternate_stack],
4015   [AC_COMPILE_IFELSE(
4016      [AC_LANG_PROGRAM([[#include <signal.h>
4017                       ]],
4018                       [[stack_t ss;
4019                         struct sigaction sa;
4020                         ss.ss_sp = malloc (SIGSTKSZ);
4021                         ss.ss_size = SIGSTKSZ;
4022                         sa.sa_flags = SA_SIGINFO | SA_ONSTACK;
4023                         sigaltstack (&ss, 0);
4024                         sigaction (SIGSEGV, &sa, 0);]])],
4025      [emacs_cv_alternate_stack=yes],
4026      [emacs_cv_alternate_stack=no])])
4027
4028 # Do we need the Hesiod library to provide the support routines?
4029 dnl FIXME?  Should we be skipping this on Darwin too?
4030 LIBHESIOD=
4031 LIBRESOLV=
4032 if test "$with_hesiod" != no ; then
4033   # Don't set $LIBS here -- see comments above.  FIXME which comments?
4034   resolv=no
4035   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
4036      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
4037                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
4038   if test "$resolv" = yes ; then
4039     RESOLVLIB=-lresolv
4040   else
4041     RESOLVLIB=
4042   fi
4043   hesiod=no
4044   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
4045         hesiod=yes, :, $RESOLVLIB)])
4046
4047   if test x"$hesiod" = xyes; then
4048     LIBHESIOD=-lhesiod
4049     LIBRESOLV=$RESOLVLIB
4050   fi
4051 fi
4052 AC_SUBST(LIBHESIOD)
4053 AC_SUBST(LIBRESOLV)
4054
4055 # These tell us which Kerberos-related libraries to use.
4056 COM_ERRLIB=
4057 CRYPTOLIB=
4058 KRB5LIB=
4059 DESLIB=
4060 KRB4LIB=
4061
4062 if test "${with_kerberos}" != no; then
4063   OLD_LIBS=$LIBS
4064   AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
4065   if test $have_com_err = yes; then
4066     COM_ERRLIB=-lcom_err
4067     LIBS="$COM_ERRLIB $LIBS"
4068   fi
4069   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
4070   if test $have_crypto = yes; then
4071     CRYPTOLIB=-lcrypto
4072     LIBS="$CRYPTOLIB $LIBS"
4073   fi
4074   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
4075   if test $have_k5crypto = yes; then
4076     CRYPTOLIB=-lk5crypto
4077     LIBS="$CRYPTOLIB $LIBS"
4078   fi
4079   AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
4080   if test $have_krb5=yes; then
4081     KRB5LIB=-lkrb5
4082     LIBS="$KRB5LIB $LIBS"
4083   fi
4084   dnl FIXME Simplify.  Does not match 22 logic, thanks to default_off?
4085   if test "${with_kerberos5}" = no; then
4086     AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
4087     if test $have_des425 = yes; then
4088       DESLIB=-ldes425
4089       LIBS="$DESLIB $LIBS"
4090     else
4091       AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
4092       if test $have_des = yes; then
4093         DESLIB=-ldes
4094         LIBS="$DESLIB $LIBS"
4095       fi
4096     fi
4097     AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
4098     if test $have_krb4 = yes; then
4099       KRB4LIB=-lkrb4
4100       LIBS="$KRB4LIB $LIBS"
4101     else
4102       AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
4103       if test $have_krb = yes; then
4104         KRB4LIB=-lkrb
4105         LIBS="$KRB4LIB $LIBS"
4106       fi
4107     fi
4108   fi
4109
4110   if test "${with_kerberos5}" != no; then
4111     AC_CHECK_HEADERS(krb5.h,
4112       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
4113                         [#include <krb5.h>])])
4114   else
4115     AC_CHECK_HEADERS(krb.h,,
4116                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
4117                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
4118   fi
4119   AC_CHECK_HEADERS(com_err.h)
4120   LIBS=$OLD_LIBS
4121 fi
4122
4123 AC_SUBST(COM_ERRLIB)
4124 AC_SUBST(CRYPTOLIB)
4125 AC_SUBST(KRB5LIB)
4126 AC_SUBST(DESLIB)
4127 AC_SUBST(KRB4LIB)
4128
4129 AC_CHECK_HEADERS(valgrind/valgrind.h)
4130
4131 AC_CHECK_MEMBERS([struct unipair.unicode], [], [], [[#include <linux/kd.h>]])
4132
4133 AC_CHECK_FUNCS_ONCE(tzset)
4134
4135 ok_so_far=yes
4136 AC_CHECK_FUNC(socket, , ok_so_far=no)
4137 if test $ok_so_far = yes; then
4138   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
4139 fi
4140 if test $ok_so_far = yes; then
4141   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
4142 fi
4143 if test $ok_so_far = yes; then
4144 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
4145   AC_DEFINE(HAVE_INET_SOCKETS, 1,
4146             [Define to 1 if you have inet sockets.])
4147 fi
4148
4149 AC_FUNC_FORK
4150
4151 AC_CHECK_FUNCS(snprintf)
4152
4153 dnl Check for glib.  This differs from other library checks in that
4154 dnl Emacs need not link to glib unless some other library is already
4155 dnl linking to glib.  Although glib provides no facilities that Emacs
4156 dnl needs for its own purposes, when glib is present Emacs needs to
4157 dnl use primitives like g_main_context_query to avoid clashing with
4158 dnl glib at a low level.
4159 dnl
4160 dnl Check this late, since it depends on $GTK_CFLAGS etc.
4161 XGSELOBJ=
4162 OLDCFLAGS="$CFLAGS"
4163 OLDLIBS="$LIBS"
4164 CFLAGS="$CFLAGS $GTK_CFLAGS $RSVG_CFLAGS $DBUS_CFLAGS $SETTINGS_CFLAGS"
4165 LIBS="$LIBS $GTK_LIBS $RSVG_LIBS $DBUS_LIBS $SETTINGS_LIBS"
4166 CFLAGS="$CFLAGS $NOTIFY_CFLAGS $CAIRO_CFLAGS"
4167 LIBS="$LIBS $NOTIFY_LIBS $CAIRO_LIBS"
4168 AC_MSG_CHECKING([whether GLib is linked in])
4169 AC_LINK_IFELSE([AC_LANG_PROGRAM(
4170         [[#include <glib.h>
4171         ]],
4172         [[g_print ("Hello world");]])],
4173      [links_glib=yes],
4174      [links_glib=no])
4175 AC_MSG_RESULT([$links_glib])
4176 if test "${links_glib}" = "yes"; then
4177   AC_DEFINE(HAVE_GLIB, 1, [Define to 1 if GLib is linked in.])
4178   if test "$HAVE_NS" = no;then
4179     XGSELOBJ=xgselect.o
4180   fi
4181 fi
4182 CFLAGS="$OLDCFLAGS"
4183 LIBS="$OLDLIBS"
4184 AC_SUBST(XGSELOBJ)
4185
4186 dnl Adapted from Haible's version.
4187 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
4188   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
4189     [[char* cs = nl_langinfo(CODESET);]])],
4190     emacs_cv_langinfo_codeset=yes,
4191     emacs_cv_langinfo_codeset=no)
4192   ])
4193 if test $emacs_cv_langinfo_codeset = yes; then
4194   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
4195     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
4196 fi
4197
4198 AC_TYPE_MBSTATE_T
4199
4200 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
4201 dnl how the tty code is related to POSIX and/or other versions of termios.
4202 dnl The following looks like a useful start.
4203 dnl
4204 dnl AC_SYS_POSIX_TERMIOS
4205 dnl if test $ac_cv_sys_posix_termios = yes; then
4206 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
4207 dnl                                and macros for terminal control.])
4208 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
4209 dnl fi
4210
4211 dnl Turned on June 1996 supposing nobody will mind it.
4212 dnl MinGW emulates passwd database, so this feature doesn't make sense there.
4213 if test "${opsys}" != "mingw32"; then
4214    AC_DEFINE(AMPERSAND_FULL_NAME, 1, [Define to use the convention that &
4215      in the full name stands for the login id.])
4216 fi
4217
4218 dnl Everybody supports this, except MS.
4219 dnl Seems like the kind of thing we should be testing for, though.
4220 ## Note: PTYs are broken on darwin <6.  Use at your own risk.
4221 if test "${opsys}" != "mingw32"; then
4222   AC_DEFINE(HAVE_PTYS, 1, [Define if the system supports pty devices.])
4223 fi
4224
4225 dnl Everybody supports this, except MS-DOS.
4226 dnl Seems like the kind of thing we should be testing for, though.
4227 dnl Compare with HAVE_INET_SOCKETS (which is unused...) above.
4228 AC_DEFINE(HAVE_SOCKETS, 1, [Define if the system supports
4229   4.2-compatible sockets.])
4230
4231 AH_TEMPLATE(INTERNAL_TERMINAL, [This is substituted when $TERM is "internal".])
4232
4233 AH_TEMPLATE(NULL_DEVICE, [Name of the file to open to get
4234   a null file, or a data sink.])
4235 if test "${opsys}" = "mingw32"; then
4236   AC_DEFINE(NULL_DEVICE, ["NUL:"])
4237 else
4238   AC_DEFINE(NULL_DEVICE, ["/dev/null"])
4239 fi
4240
4241 if test "${opsys}" = "mingw32"; then
4242   SEPCHAR=';'
4243 else
4244   SEPCHAR=':'
4245 fi
4246 AC_DEFINE_UNQUOTED(SEPCHAR, ['$SEPCHAR'], [Character that separates PATH elements.])
4247 dnl This is for MinGW, and is used in test/Makefile.in.
4248 dnl The MSYS Bash has heuristics for replacing ':' with ';' when it
4249 dnl decides that a command-line argument to be passed to a MinGW program
4250 dnl is a PATH-style list of directories.  But that heuristics plays it
4251 dnl safe, and only does the replacement when it is _absolutely_ sure it
4252 dnl sees a colon-separated list of file names; e.g. ":." is left alone,
4253 dnl which breaks in-tree builds.  So we do this manually instead.
4254 dnl Note that we cannot rely on PATH_SEPARATOR, as that one will always
4255 dnl be computed as ':' in MSYS Bash.
4256 AC_SUBST(SEPCHAR)
4257
4258 dnl Everybody supports this, except MS-DOS.
4259 AC_DEFINE(subprocesses, 1, [Define to enable asynchronous subprocesses.])
4260
4261 AC_DEFINE(USER_FULL_NAME, [pw->pw_gecos], [How to get a user's full name.])
4262
4263
4264 AC_DEFINE(DIRECTORY_SEP, ['/'],
4265   [Character that separates directories in a file name.])
4266
4267 if test "${opsys}" = "mingw32"; then
4268   AC_DEFINE(IS_DEVICE_SEP(_c_), [((_c_) == ':')],
4269     [Returns true if character is a device separator.])
4270
4271   AC_DEFINE(IS_DIRECTORY_SEP(_c_), [((_c_) == '/' || (_c_) == '\\')],
4272     [Returns true if character is a directory separator.])
4273
4274   AC_DEFINE(IS_ANY_SEP(_c_), [(IS_DIRECTORY_SEP (_c_) || IS_DEVICE_SEP(_c_))],
4275     [Returns true if character is any form of separator.])
4276 else
4277   AC_DEFINE(IS_DEVICE_SEP(_c_), 0,
4278     [Returns true if character is a device separator.])
4279
4280   AC_DEFINE(IS_DIRECTORY_SEP(_c_), [((_c_) == DIRECTORY_SEP)],
4281     [Returns true if character is a directory separator.])
4282
4283   AC_DEFINE(IS_ANY_SEP(_c_), [(IS_DIRECTORY_SEP (_c_))],
4284     [Returns true if character is any form of separator.])
4285 fi
4286
4287 AH_TEMPLATE(NO_EDITRES, [Define if XEditRes should not be used.])
4288
4289 case $opsys in
4290   aix4-2)
4291     dnl Unfortunately without libXmu we cannot support EditRes.
4292     if test "x$ac_cv_search_XmuConvertStandardSelection" = xno; then
4293       AC_DEFINE(NO_EDITRES, 1)
4294     fi
4295     ;;
4296
4297   hpux*)
4298     dnl Assar Westerlund <assar@sics.se> says this is necessary for
4299     dnl HP-UX 10.20, and that it works for HP-UX 0 as well.
4300     AC_DEFINE(NO_EDITRES, 1)
4301     ;;
4302 esac
4303
4304
4305 case $opsys in
4306   sol2* | unixware )
4307     dnl Some SVr4s don't define NSIG in sys/signal.h for ANSI environments;
4308     dnl instead, there's a system variable _sys_nsig.  Unfortunately, we
4309     dnl need the constant to dimension an array.  So wire in the appropriate
4310     dnl value here.
4311     AC_DEFINE(NSIG_MINIMUM, 32, [Minimum value of NSIG.])
4312     ;;
4313 esac
4314
4315 emacs_broken_SIGIO=no
4316
4317 case $opsys in
4318   dnl SIGIO exists, but the feature doesn't work in the way Emacs needs.
4319   dnl See eg <http://article.gmane.org/gmane.os.openbsd.ports/46831>.
4320   hpux* | nacl | openbsd | sol2* | unixware )
4321     emacs_broken_SIGIO=yes
4322     ;;
4323
4324   aix4-2)
4325     dnl On AIX Emacs uses the gmalloc.c malloc implementation.  But given
4326     dnl the way this system works, libc functions that return malloced
4327     dnl memory use the libc malloc implementation. Calling xfree or
4328     dnl xrealloc on the results of such functions results in a crash.
4329     dnl
4330     dnl One solution for this could be to define SYSTEM_MALLOC in configure,
4331     dnl but that does not currently work on this system.
4332     dnl
4333     dnl It is possible to completely override the malloc implementation on
4334     dnl AIX, but that involves putting the malloc functions in a shared
4335     dnl library and setting the MALLOCTYPE environment variable to point to
4336     dnl that shared library.
4337     dnl
4338     dnl Emacs currently calls xrealloc on the results of get_current_dir name,
4339     dnl to avoid a crash just use the Emacs implementation for that function.
4340     dnl
4341     dnl FIXME We could change the AC_CHECK_FUNCS call near the start
4342     dnl of this file, so that we do not check for get_current_dir_name
4343     dnl on AIX.  But that might be fragile if something else ends
4344     dnl up testing for get_current_dir_name as a dependency.
4345     AC_DEFINE(BROKEN_GET_CURRENT_DIR_NAME, 1, [Define if
4346       get_current_dir_name should not be used.])
4347     ;;
4348
4349   freebsd)
4350     dnl Circumvent a bug in FreeBSD.  In the following sequence of
4351     dnl writes/reads on a PTY, read(2) returns bogus data:
4352     dnl
4353     dnl write(2)  1022 bytes
4354     dnl write(2)   954 bytes, get EAGAIN
4355     dnl read(2)   1024 bytes in process_read_output
4356     dnl read(2)     11 bytes in process_read_output
4357     dnl
4358     dnl That is, read(2) returns more bytes than have ever been written
4359     dnl successfully.  The 1033 bytes read are the 1022 bytes written
4360     dnl successfully after processing (for example with CRs added if the
4361     dnl terminal is set up that way which it is here).  The same bytes will
4362     dnl be seen again in a later read(2), without the CRs.
4363     AC_DEFINE(BROKEN_PTY_READ_AFTER_EAGAIN, 1, [Define on FreeBSD to
4364       work around an issue when reading from a PTY.])
4365     ;;
4366 esac
4367
4368 case $opsys in
4369   gnu-* | sol2-10 )
4370     dnl FIXME Can't we test if this exists (eg /proc/$$)?
4371     AC_DEFINE(HAVE_PROCFS, 1, [Define if you have the /proc filesystem.])
4372   ;;
4373 esac
4374
4375 case $opsys in
4376   darwin | dragonfly | freebsd | netbsd | openbsd )
4377     AC_DEFINE(DONT_REOPEN_PTY, 1, [Define if process.c does not need to
4378       close a pty to make it a controlling terminal (it is already a
4379       controlling terminal of the subprocess, because we did ioctl TIOCSCTTY).])
4380   ;;
4381 esac
4382
4383 dnl FIXME Surely we can test for this rather than hard-code it.
4384 case $opsys in
4385   netbsd | openbsd) sound_device="/dev/audio" ;;
4386   *) sound_device="/dev/dsp" ;;
4387 esac
4388
4389 dnl Used in sound.c
4390 AC_DEFINE_UNQUOTED(DEFAULT_SOUND_DEVICE, "$sound_device",
4391   [Name of the default sound device.])
4392
4393
4394 dnl Emacs can read input using SIGIO and buffering characters itself,
4395 dnl or using CBREAK mode and making C-g cause SIGINT.
4396 dnl The choice is controlled by the variable interrupt_input.
4397 dnl
4398 dnl Define INTERRUPT_INPUT to make interrupt_input = 1 the default (use SIGIO)
4399 dnl
4400 dnl Emacs uses the presence of the USABLE_SIGIO macro
4401 dnl to indicate whether or not signal-driven I/O is possible.  It uses
4402 dnl INTERRUPT_INPUT to decide whether to use it by default.
4403 dnl
4404 dnl SIGIO can be used only on systems that implement it (4.2 and 4.3).
4405 dnl CBREAK mode has two disadvantages
4406 dnl 1) At least in 4.2, it is impossible to handle the Meta key properly.
4407 dnl I hear that in system V this problem does not exist.
4408 dnl 2) Control-G causes output to be discarded.
4409 dnl I do not know whether this can be fixed in system V.
4410 dnl
4411 dnl Another method of doing input is planned but not implemented.
4412 dnl It would have Emacs fork off a separate process
4413 dnl to read the input and send it to the true Emacs process
4414 dnl through a pipe.
4415 case $opsys in
4416   darwin | gnu-linux | gnu-kfreebsd )
4417     AC_DEFINE(INTERRUPT_INPUT, 1, [Define to read input using SIGIO.])
4418   ;;
4419 esac
4420
4421
4422 dnl If the system's imake configuration file defines 'NeedWidePrototypes'
4423 dnl as 'NO', we must define NARROWPROTO manually.  Such a define is
4424 dnl generated in the Makefile generated by 'xmkmf'.  If we don't define
4425 dnl NARROWPROTO, we will see the wrong function prototypes for X functions
4426 dnl taking float or double parameters.
4427 case $opsys in
4428   cygwin|gnu|gnu-linux|gnu-kfreebsd|freebsd|netbsd|openbsd)
4429     AC_DEFINE(NARROWPROTO, 1, [Define if system's imake configuration
4430       file defines 'NeedWidePrototypes' as 'NO'.])
4431   ;;
4432 esac
4433
4434
4435 dnl Used in process.c, this must be a loop, even if it only runs once.
4436 AH_TEMPLATE(PTY_ITERATION, [How to iterate over PTYs.])
4437 dnl Only used if !PTY_ITERATION.  Iterate from FIRST_PTY_LETTER to z,
4438 dnl trying suffixes 0-16.
4439 AH_TEMPLATE(FIRST_PTY_LETTER, [Letter to use in finding device name of
4440   first PTY, if PTYs are supported.])
4441 AH_TEMPLATE(PTY_OPEN, [How to open a PTY, if non-standard.])
4442 AH_TEMPLATE(PTY_NAME_SPRINTF, [How to get the device name of the control
4443   end of a PTY, if non-standard.])
4444 AH_TEMPLATE(PTY_TTY_NAME_SPRINTF, [How to get device name of the tty
4445   end of a PTY, if non-standard.])
4446
4447 case $opsys in
4448   aix4-2 )
4449     AC_DEFINE(PTY_ITERATION, [int c; for (c = 0; !c ; c++)])
4450     dnl You allocate a pty by opening /dev/ptc to get the master side.
4451     dnl To get the name of the slave side, you just ttyname() the master side.
4452     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptc");])
4453     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [strcpy (pty_name, ttyname (fd));])
4454     ;;
4455
4456   cygwin )
4457     AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
4458     dnl multi-line AC_DEFINEs are hard. :(
4459     AC_DEFINE(PTY_OPEN, [ do { int dummy; sigset_t blocked, procmask; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, &procmask); if (-1 == openpty (&fd, &dummy, pty_name, 0, 0)) fd = -1; pthread_sigmask (SIG_SETMASK, &procmask, 0); if (fd >= 0) emacs_close (dummy); } while (false)])
4460     AC_DEFINE(PTY_NAME_SPRINTF, [])
4461     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
4462     ;;
4463
4464   gnu | openbsd )
4465     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4466     ;;
4467
4468   gnu-linux | gnu-kfreebsd | dragonfly | freebsd | netbsd | darwin | nacl )
4469     dnl if HAVE_GRANTPT
4470     if test "x$ac_cv_func_grantpt" = xyes; then
4471       AC_DEFINE(UNIX98_PTYS, 1, [Define if the system has Unix98 PTYs.])
4472       AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
4473       dnl Note that grantpt and unlockpt may fork.  We must block SIGCHLD
4474       dnl to prevent sigchld_handler from intercepting the child's death.
4475       AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptyname = 0; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); if (grantpt (fd) != -1 && unlockpt (fd) != -1) ptyname = ptsname(fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (!ptyname) { emacs_close (fd); return -1; } snprintf (pty_name, PTY_NAME_SIZE, "%s", ptyname); }])
4476       dnl if HAVE_POSIX_OPENPT
4477       if test "x$ac_cv_func_posix_openpt" = xyes; then
4478         AC_DEFINE(PTY_OPEN, [do { fd = posix_openpt (O_RDWR | O_CLOEXEC | O_NOCTTY); if (fd < 0 && errno == EINVAL) fd = posix_openpt (O_RDWR | O_NOCTTY); } while (false)])
4479         AC_DEFINE(PTY_NAME_SPRINTF, [])
4480       dnl if HAVE_GETPT
4481       elif test "x$ac_cv_func_getpt" = xyes; then
4482         AC_DEFINE(PTY_OPEN, [fd = getpt ()])
4483         AC_DEFINE(PTY_NAME_SPRINTF, [])
4484       else
4485         AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptmx");])
4486       fi
4487     else
4488       AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4489     fi
4490     ;;
4491
4492   hpux*)
4493     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4494     AC_DEFINE(PTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/ptym/pty%c%x", c, i);])
4495     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/pty/tty%c%x", c, i);])
4496     ;;
4497
4498   sol2* )
4499     dnl On SysVr4, grantpt(3) forks a subprocess, so do not use
4500     dnl O_CLOEXEC when opening the pty, and keep the SIGCHLD handler
4501     dnl from intercepting that death.  If any child but grantpt's should die
4502     dnl within, it should be caught after sigrelse(2).
4503     AC_DEFINE(PTY_OPEN, [fd = open (pty_name, O_RDWR | O_NONBLOCK)])
4504     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptsname (int), *ptyname; int grantpt_result; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); grantpt_result = grantpt (fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (grantpt_result == -1 || unlockpt (fd) == -1 || !(ptyname = ptsname (fd))) { emacs_close (fd); return -1; } snprintf (pty_name, PTY_NAME_SIZE, "%s", ptyname); }])
4505     ;;
4506
4507   unixware )
4508     dnl Comments are as per sol2*.
4509     AC_DEFINE(PTY_OPEN, [fd = open (pty_name, O_RDWR | O_NONBLOCK)])
4510     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptsname (int), *ptyname; int grantpt_result; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); grantpt_result = grantpt (fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (grantpt_result == -1) fatal("could not grant slave pty"); if (unlockpt(fd) == -1) fatal("could not unlock slave pty"); if (!(ptyname = ptsname(fd))) fatal ("could not enable slave pty"); snprintf (pty_name, PTY_NAME_SIZE, "%s", ptyname); }])
4511     ;;
4512 esac
4513
4514
4515 case $opsys in
4516   sol2* | unixware )
4517     dnl This change means that we don't loop through allocate_pty too
4518     dnl many times in the (rare) event of a failure.
4519     AC_DEFINE(FIRST_PTY_LETTER, ['z'])
4520     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptmx");])
4521     dnl Push various streams modules onto a PTY channel.  Used in process.c.
4522     AC_DEFINE(SETUP_SLAVE_PTY, [if (ioctl (forkin, I_PUSH, "ptem") == -1) fatal ("ioctl I_PUSH ptem"); if (ioctl (forkin, I_PUSH, "ldterm") == -1) fatal ("ioctl I_PUSH ldterm"); if (ioctl (forkin, I_PUSH, "ttcompat") == -1) fatal ("ioctl I_PUSH ttcompat");], [How to set up a slave PTY, if needed.])
4523     ;;
4524 esac
4525
4526
4527 AH_TEMPLATE(SIGNALS_VIA_CHARACTERS, [Make process_send_signal work by
4528 "typing" a signal character on the pty.])
4529
4530 case $opsys in
4531   dnl Perry Smith <pedz@ddivt1.austin.ibm.com> says this is correct for AIX.
4532   aix4-2 | cygwin | gnu | dragonfly | freebsd | netbsd | openbsd | darwin )
4533     AC_DEFINE(SIGNALS_VIA_CHARACTERS, 1)
4534     ;;
4535
4536   dnl 21 Jun 06: Eric Hanchrow <offby1@blarg.net> says this works.
4537   dnl FIXME Does gnu-kfreebsd have linux/version.h?  It seems unlikely...
4538   gnu-linux | gnu-kfreebsd )
4539
4540     AC_MSG_CHECKING([for signals via characters])
4541     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4542 #include <linux/version.h>
4543 #if LINUX_VERSION_CODE < 0x20400
4544 # error "Linux version too old"
4545 #endif
4546       ]], [[]])], emacs_signals_via_chars=yes, emacs_signals_via_chars=no)
4547
4548     AC_MSG_RESULT([$emacs_signals_via_chars])
4549     test $emacs_signals_via_chars = yes && AC_DEFINE(SIGNALS_VIA_CHARACTERS, 1)
4550     ;;
4551 esac
4552
4553
4554 AH_TEMPLATE(TAB3, [Undocumented.])
4555
4556 case $opsys in
4557   darwin) AC_DEFINE(TAB3, OXTABS) ;;
4558
4559   gnu | dragonfly | freebsd | netbsd | openbsd )
4560     AC_DEFINE(TABDLY, OXTABS, [Undocumented.])
4561     AC_DEFINE(TAB3, OXTABS)
4562     ;;
4563
4564   gnu-linux | gnu-kfreebsd )
4565     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4566 #ifndef __ia64__
4567 # error "not ia64"
4568 #endif
4569       ]], [[]])], AC_DEFINE(GC_MARK_SECONDARY_STACK(),
4570         [do { extern void *__libc_ia64_register_backing_store_base; __builtin_ia64_flushrs (); mark_memory (__libc_ia64_register_backing_store_base, __builtin_ia64_bsp ());} while (false)],
4571         [Mark a secondary stack, like the register stack on the ia64.]), [])
4572     ;;
4573
4574   hpux*)
4575     AC_DEFINE(RUN_TIME_REMAP, 1, [Define if emacs.c needs to call
4576       run_time_remap; for HPUX.])
4577     ;;
4578 esac
4579
4580
4581 dnl This won't be used automatically yet.  We also need to know, at least,
4582 dnl that the stack is continuous.
4583 AH_TEMPLATE(GC_SETJMP_WORKS, [Define if setjmp is known to save all
4584   registers relevant for conservative garbage collection in the jmp_buf.])
4585
4586
4587 case $opsys in
4588   dnl Not all the architectures are tested, but there are Debian packages
4589   dnl for SCM and/or Guile on them, so the technique must work.  See also
4590   dnl comments in alloc.c concerning setjmp and gcc.
4591   dnl Fixme: it's probably safe to just use the GCC conditional below.
4592   gnu-linux | gnu-kfreebsd )
4593     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4594 #if defined __i386__ || defined __sparc__ || defined __mc68000__ \
4595   || defined __alpha__ || defined __mips__ || defined __s390__ \
4596   || defined __arm__ || defined __powerpc__ || defined __amd64__ \
4597   || defined __ia64__ || defined __sh__
4598 /* ok */
4599 #else
4600 # error "setjmp not known to work on this arch"
4601 #endif
4602     ]], [[]])], AC_DEFINE(GC_SETJMP_WORKS, 1))
4603     ;;
4604 esac
4605
4606
4607 if test x$GCC = xyes; then
4608    dnl GC_SETJMP_WORKS is nearly always appropriate for GCC.
4609    AC_DEFINE(GC_SETJMP_WORKS, 1)
4610 else
4611   case $opsys in
4612     aix* | dragonfly | freebsd | netbsd | openbsd | sol2* )
4613       AC_DEFINE(GC_SETJMP_WORKS, 1)
4614       ;;
4615   esac
4616 fi                              dnl GCC?
4617
4618 dnl In a weird quirk, MS runtime uses _setjmp and longjmp.
4619 AC_CACHE_CHECK([for _setjmp], [emacs_cv_func__setjmp],
4620   [AC_LINK_IFELSE(
4621      [AC_LANG_PROGRAM(
4622        [[#include <setjmp.h>
4623          #ifdef __MINGW32__
4624          # define _longjmp longjmp
4625          #endif
4626        ]],
4627        [[jmp_buf j;
4628          if (! _setjmp (j))
4629            _longjmp (j, 1);]])],
4630      [emacs_cv_func__setjmp=yes],
4631      [emacs_cv_func__setjmp=no])])
4632 if test $emacs_cv_func__setjmp = yes; then
4633   AC_DEFINE([HAVE__SETJMP], 1, [Define to 1 if _setjmp and _longjmp work.])
4634 fi
4635
4636 # We need to preserve signal mask to handle C stack overflows.
4637 AC_CACHE_CHECK([for sigsetjmp], [emacs_cv_func_sigsetjmp],
4638   [AC_LINK_IFELSE(
4639      [AC_LANG_PROGRAM(
4640        [[#include <setjmp.h>
4641        ]],
4642        [[sigjmp_buf j;
4643          if (! sigsetjmp (j, 1))
4644            siglongjmp (j, 1);]])],
4645      [emacs_cv_func_sigsetjmp=yes],
4646      [emacs_cv_func_sigsetjmp=no])])
4647 if test $emacs_cv_func_sigsetjmp = yes; then
4648   AC_DEFINE([HAVE_SIGSETJMP], 1,
4649     [Define to 1 if sigsetjmp and siglongjmp work.])
4650 fi
4651
4652 case $emacs_cv_func_sigsetjmp,$emacs_cv_alternate_stack,$opsys in
4653   yes,yes,* | *,*,mingw32)
4654     AC_DEFINE([HAVE_STACK_OVERFLOW_HANDLING], 1,
4655       [Define to 1 if C stack overflow can be handled in some cases.]);;
4656 esac
4657
4658 case $opsys in
4659   sol2* | unixware )
4660     dnl TIOCGPGRP is broken in SysVr4, so we can't send signals to PTY
4661     dnl subprocesses the usual way.  But TIOCSIGNAL does work for PTYs,
4662     dnl and this is all we need.
4663     AC_DEFINE(TIOCSIGSEND, TIOCSIGNAL, [Some platforms redefine this.])
4664     ;;
4665 esac
4666
4667
4668 case $opsys in
4669   hpux* | sol2* )
4670     dnl Used in xfaces.c.
4671     AC_DEFINE(XOS_NEEDS_TIME_H, 1, [Compensate for a bug in Xos.h on
4672       some systems, where it requires time.h.])
4673     ;;
4674 esac
4675
4676
4677 dnl Define symbols to identify the version of Unix this is.
4678 dnl Define all the symbols that apply correctly.
4679 AH_TEMPLATE(DOS_NT, [Define if the system is MS DOS or MS Windows.])
4680 AH_TEMPLATE(MSDOS, [Define if the system is MS DOS.])
4681 AH_TEMPLATE(USG, [Define if the system is compatible with System III.])
4682 AH_TEMPLATE(USG5_4, [Define if the system is compatible with System V Release 4.])
4683
4684 case $opsys in
4685   aix4-2)
4686     AC_DEFINE(USG, [])
4687     dnl This symbol should be defined on AIX Version 3  ???????
4688     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4689 #ifndef _AIX
4690 # error "_AIX not defined"
4691 #endif
4692     ]], [[]])], [], AC_DEFINE(_AIX, [], [Define if the system is AIX.]))
4693     ;;
4694
4695   cygwin)
4696     AC_DEFINE(CYGWIN, 1, [Define if the system is Cygwin.])
4697     ;;
4698
4699   darwin)
4700     dnl Not __APPLE__, as this may not be defined on non-OSX Darwin.
4701     dnl Not DARWIN, because Panther and lower CoreFoundation.h use DARWIN to
4702     dnl distinguish OS X from pure Darwin.
4703     AC_DEFINE(DARWIN_OS, [], [Define if the system is Darwin.])
4704     ;;
4705
4706   gnu-linux | gnu-kfreebsd )
4707     AC_DEFINE(USG, [])
4708     AC_DEFINE(GNU_LINUX, [], [Define if ths system is compatible with GNU/Linux.])
4709     ;;
4710
4711   hpux*)
4712     AC_DEFINE(USG, [])
4713     AC_DEFINE(HPUX, [], [Define if the system is HPUX.])
4714     ;;
4715
4716   mingw32)
4717     AC_DEFINE(DOS_NT, [])
4718     AC_DEFINE(WINDOWSNT, 1, [Define if compiling for native MS Windows.])
4719     if test "x$ac_enable_checking" != "x" ; then
4720       AC_DEFINE(EMACSDEBUG, 1, [Define to 1 to enable w32 debug facilities.])
4721     fi
4722     ;;
4723
4724   sol2*)
4725     AC_DEFINE(USG, [])
4726     AC_DEFINE(USG5_4, [])
4727     AC_DEFINE(SOLARIS2, [], [Define if the system is Solaris.])
4728     ;;
4729
4730   unixware)
4731     AC_DEFINE(USG, [])
4732     AC_DEFINE(USG5_4, [])
4733     ;;
4734 esac
4735
4736 AC_CACHE_CHECK([for usable FIONREAD], [emacs_cv_usable_FIONREAD],
4737   [case $opsys in
4738      aix4-2 | nacl)
4739        dnl BUILD 9008 - FIONREAD problem still exists in X-Windows.
4740        emacs_cv_usable_FIONREAD=no
4741        ;;
4742
4743      mingw32)
4744        emacs_cv_usable_FIONREAD=yes
4745        ;;
4746
4747      *)
4748        AC_COMPILE_IFELSE(
4749          [AC_LANG_PROGRAM([[#include <sys/types.h>
4750                             #include <sys/ioctl.h>
4751                             #ifdef USG5_4
4752                             # include <sys/filio.h>
4753                             #endif
4754                           ]],
4755                           [[int foo = ioctl (0, FIONREAD, &foo);]])],
4756          [emacs_cv_usable_FIONREAD=yes],
4757          [emacs_cv_usable_FIONREAD=no])
4758        ;;
4759    esac])
4760 if test $emacs_cv_usable_FIONREAD = yes; then
4761   AC_DEFINE([USABLE_FIONREAD], [1], [Define to 1 if FIONREAD is usable.])
4762
4763   if test $emacs_broken_SIGIO = no; then
4764     AC_CACHE_CHECK([for usable SIGIO], [emacs_cv_usable_SIGIO],
4765       [AC_COMPILE_IFELSE(
4766          [AC_LANG_PROGRAM([[#include <fcntl.h>
4767                             #include <signal.h>
4768                           ]],
4769                           [[int foo = SIGIO | F_SETFL | FASYNC;]])],
4770          [emacs_cv_usable_SIGIO=yes],
4771          [emacs_cv_usable_SIGIO=no])],
4772       [emacs_cv_usable_SIGIO=yes],
4773       [emacs_cv_usable_SIGIO=no])
4774     if test $emacs_cv_usable_SIGIO = yes; then
4775       AC_DEFINE([USABLE_SIGIO], [1], [Define to 1 if SIGIO is usable.])
4776     fi
4777   fi
4778 fi
4779
4780 case $opsys in
4781   hpux11)
4782     dnl It works to open the pty's tty in the parent (Emacs), then
4783     dnl close and reopen it in the child.
4784     AC_DEFINE(USG_SUBTTY_WORKS, 1, [Define for USG systems where it
4785       works to open a pty's tty in the parent process, then close and
4786       reopen it in the child.])
4787     ;;
4788
4789   sol2-10)
4790     AC_DEFINE(_STRUCTURED_PROC, 1, [Needed for system_process_attributes
4791       on Solaris.])
4792     ;;
4793 esac
4794
4795 # Set up the CFLAGS for real compilation, so we can substitute it.
4796 CFLAGS="$REAL_CFLAGS"
4797 CPPFLAGS="$REAL_CPPFLAGS"
4798 LIBS="$REAL_LIBS"
4799
4800 ## Hack to detect a buggy GCC version.
4801 if test "$GCC" = yes && \
4802    $CC --version 2> /dev/null | grep 'gcc.* 4.5.0' >/dev/null; then
4803   case $CFLAGS in
4804     *-fno-optimize-sibling-calls*) ;;
4805     *-O@<:@23@:>@*)
4806       AC_MSG_ERROR([GCC 4.5.0 has problems compiling Emacs; see etc/PROBLEMS.]);;
4807   esac
4808 fi
4809
4810 version=$PACKAGE_VERSION
4811
4812 copyright="Copyright (C) 2016 Free Software Foundation, Inc."
4813 AC_DEFINE_UNQUOTED(COPYRIGHT, ["$copyright"],
4814   [Short copyright string for this version of Emacs.])
4815 AC_SUBST(copyright)
4816
4817 ### Specify what sort of things we'll be editing into Makefile and config.h.
4818 ### Use configuration here uncanonicalized to avoid exceeding size limits.
4819 AC_SUBST(version)
4820 AC_SUBST(configuration)
4821 ## Unused?
4822 AC_SUBST(canonical)
4823 AC_SUBST(srcdir)
4824 AC_SUBST(prefix)
4825 AC_SUBST(exec_prefix)
4826 AC_SUBST(bindir)
4827 AC_SUBST(datadir)
4828 AC_SUBST(sharedstatedir)
4829 AC_SUBST(libexecdir)
4830 AC_SUBST(mandir)
4831 AC_SUBST(infodir)
4832 AC_SUBST(lispdir)
4833 AC_SUBST(standardlisppath)
4834 AC_SUBST(locallisppath)
4835 AC_SUBST(lisppath)
4836 AC_SUBST(x_default_search_path)
4837 AC_SUBST(etcdir)
4838 AC_SUBST(archlibdir)
4839 AC_SUBST(etcdocdir)
4840 AC_SUBST(bitmapdir)
4841 AC_SUBST(gamedir)
4842 AC_SUBST(gameuser)
4843 AC_SUBST(gamegroup)
4844 ## FIXME? Nothing uses @LD_SWITCH_X_SITE@.
4845 ## src/Makefile.in did add LD_SWITCH_X_SITE (as a cpp define) to the
4846 ## end of LIBX_BASE, but nothing ever set it.
4847 AC_SUBST(LD_SWITCH_X_SITE)
4848 AC_SUBST(C_SWITCH_X_SITE)
4849 AC_SUBST(GNUSTEP_CFLAGS)
4850 AC_SUBST(CFLAGS)
4851 ## Used in lwlib/Makefile.in.
4852 AC_SUBST(X_TOOLKIT_TYPE)
4853 AC_SUBST(ns_appdir)
4854 AC_SUBST(ns_appbindir)
4855 AC_SUBST(ns_appresdir)
4856 AC_SUBST(ns_appsrc)
4857 AC_SUBST(GNU_OBJC_CFLAGS)
4858 AC_SUBST(OTHER_FILES)
4859
4860 if test -n "${term_header}"; then
4861     AC_DEFINE_UNQUOTED(TERM_HEADER, "${term_header}",
4862         [Define to the header for the built-in window system.])
4863 fi
4864
4865 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
4866                    [Define to the canonical Emacs configuration name.])
4867 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${emacs_config_options}",
4868                    [Define to the options passed to configure.])
4869 AH_TEMPLATE(config_opsysfile, [Some platforms that do not use configure
4870   define this to include extra configuration information.])
4871
4872 case $opsys in
4873   mingw32)
4874     AC_DEFINE(config_opsysfile, <ms-w32.h>, [])
4875     ;;
4876 esac
4877
4878 XMENU_OBJ=
4879 XOBJ=
4880 FONT_OBJ=
4881 if test "${HAVE_X_WINDOWS}" = "yes" ; then
4882   AC_DEFINE(HAVE_X_WINDOWS, 1,
4883             [Define to 1 if you want to use the X window system.])
4884   XMENU_OBJ=xmenu.o
4885   XOBJ="xterm.o xfns.o xselect.o xrdb.o xsmfns.o xsettings.o"
4886   FONT_OBJ=xfont.o
4887   if test "$HAVE_CAIRO" = "yes"; then
4888     FONT_OBJ="ftfont.o ftcrfont.o"
4889   elif test "$HAVE_XFT" = "yes"; then
4890     FONT_OBJ="$FONT_OBJ ftfont.o xftfont.o ftxfont.o"
4891   elif test "$HAVE_FREETYPE" = "yes"; then
4892     FONT_OBJ="$FONT_OBJ ftfont.o ftxfont.o"
4893   fi
4894   AC_SUBST(FONT_OBJ)
4895 fi
4896 AC_SUBST(XMENU_OBJ)
4897 AC_SUBST(XOBJ)
4898 AC_SUBST(FONT_OBJ)
4899
4900 WIDGET_OBJ=
4901 MOTIF_LIBW=
4902 if test "${USE_X_TOOLKIT}" != "none" ; then
4903   WIDGET_OBJ=widget.o
4904   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
4905   if test "${USE_X_TOOLKIT}" = "LUCID"; then
4906     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
4907   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
4908     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
4909     MOTIF_LIBW=-lXm
4910     case "$opsys" in
4911       gnu-linux)
4912         ## Paul Abrahams <abrahams at equinox.shaysnet.com> says this is needed.
4913         MOTIF_LIBW="$MOTIF_LIBW -lXpm"
4914         ;;
4915
4916       unixware)
4917         ## Richard Anthony Ryan <ryanr at ellingtn.ftc.nrcs.usda.gov>
4918         ## says -lXimp is needed in UNIX_SV ... 4.2 1.1.2.
4919         MOTIF_LIBW="MOTIF_LIBW -lXimp"
4920         ;;
4921
4922       aix4-2)
4923         ## olson@mcs.anl.gov says -li18n is needed by -lXm.
4924         MOTIF_LIBW="$MOTIF_LIBW -li18n"
4925         ;;
4926     esac
4927     MOTIF_LIBW="$MOTIF_LIBW $LIBXP"
4928   fi
4929 fi
4930 AC_SUBST(WIDGET_OBJ)
4931
4932 TOOLKIT_LIBW=
4933 case "$USE_X_TOOLKIT" in
4934   MOTIF) TOOLKIT_LIBW="$MOTIF_LIBW" ;;
4935   LUCID) TOOLKIT_LIBW="$LUCID_LIBW" ;;
4936   none) test "x$HAVE_GTK" = "xyes" && TOOLKIT_LIBW="$GTK_LIBS" ;;
4937 esac
4938 if test "$HAVE_XWIDGETS" = "yes"; then
4939   TOOLKIT_LIBW="$TOOLKIT_LIBW -lXcomposite"
4940 fi
4941 AC_SUBST(TOOLKIT_LIBW)
4942
4943 if test "${opsys}" != "mingw32"; then
4944   if test "$USE_X_TOOLKIT" = "none"; then
4945     LIBXT_OTHER="\$(LIBXSM)"
4946   else
4947     LIBXT_OTHER="\$(LIBXMU) -lXt \$(LIBXTR6) -lXext"
4948   fi
4949 fi
4950 AC_SUBST(LIBXT_OTHER)
4951
4952 if test "${HAVE_X11}" = "yes" ; then
4953   AC_DEFINE(HAVE_X11, 1,
4954             [Define to 1 if you want to use version 11 of X windows.])
4955   LIBX_OTHER="\$(LIBXT) \$(LIBX_EXTRA)"
4956 else
4957   LIBX_OTHER=
4958 fi
4959 AC_SUBST(LIBX_OTHER)
4960
4961 if test "$HAVE_GTK" = yes || test "$HAVE_X11" != yes; then
4962   LIBXMENU=
4963 elif test "$USE_X_TOOLKIT" = none; then
4964   LIBXMENU='$(oldXMenudir)/libXMenu11.a'
4965 else
4966   LIBXMENU='$(lwlibdir)/liblw.a'
4967 fi
4968 AC_SUBST(LIBXMENU)
4969
4970 AC_CACHE_CHECK([for struct alignment],
4971   [emacs_cv_struct_alignment],
4972   [AC_COMPILE_IFELSE(
4973      [AC_LANG_PROGRAM([[#include <stddef.h>
4974                         struct __attribute__ ((aligned (8))) s { char c; };
4975                         struct t { char c; struct s s; };
4976                         char verify[offsetof (struct t, s) == 8 ? 1 : -1];
4977                       ]])],
4978      [emacs_cv_struct_alignment=yes],
4979      [emacs_cv_struct_alignment=no])])
4980 if test "$emacs_cv_struct_alignment" = yes; then
4981   AC_DEFINE([HAVE_STRUCT_ATTRIBUTE_ALIGNED], 1,
4982     [Define to 1 if 'struct __attribute__ ((aligned (N)))' aligns the
4983      structure to an N-byte boundary.])
4984 fi
4985
4986 if test "${GNU_MALLOC}" = "yes" ; then
4987   AC_DEFINE(GNU_MALLOC, 1,
4988             [Define to 1 if you want to use the GNU memory allocator.])
4989 fi
4990
4991 RALLOC_OBJ=
4992 if test "${REL_ALLOC}" = "yes" ; then
4993   AC_DEFINE(REL_ALLOC, 1,
4994             [Define REL_ALLOC if you want to use the relocating allocator for
4995              buffer space.])
4996
4997   test "$system_malloc" != "yes" && RALLOC_OBJ=ralloc.o
4998 fi
4999 AC_SUBST(RALLOC_OBJ)
5000
5001 if test "$opsys" = "cygwin"; then
5002   CYGWIN_OBJ="cygw32.o"
5003   ## Cygwin differs because of its unexec().
5004   PRE_ALLOC_OBJ=
5005   POST_ALLOC_OBJ=lastfile.o
5006 elif test "$opsys" = "mingw32"; then
5007   CYGWIN_OBJ=
5008   PRE_ALLOC_OBJ=
5009   POST_ALLOC_OBJ=lastfile.o
5010 else
5011   CYGWIN_OBJ=
5012   PRE_ALLOC_OBJ=lastfile.o
5013   POST_ALLOC_OBJ=
5014 fi
5015 AC_SUBST(CYGWIN_OBJ)
5016 AC_SUBST(PRE_ALLOC_OBJ)
5017 AC_SUBST(POST_ALLOC_OBJ)
5018
5019 dnl Call this 'FORTIFY_SOUR' so that it sorts before the 'FORTIFY_SOURCE'
5020 dnl verbatim defined above.  The tricky name is apropos, as this hack
5021 dnl makes Fortify go sour!
5022 AH_VERBATIM([FORTIFY_SOUR],
5023 [/* Without the following workaround, Emacs runs slowly on OS X 10.8.
5024    The workaround disables some useful run-time checking, so it
5025    should be conditional to the platforms with the performance bug.
5026    Perhaps Apple will fix this some day; also see m4/extern-inline.m4.  */
5027 #if defined __APPLE__ && defined __GNUC__
5028 # ifndef _DONT_USE_CTYPE_INLINE_
5029 #  define _DONT_USE_CTYPE_INLINE_
5030 # endif
5031 # ifndef _FORTIFY_SOURCE
5032 #  define _FORTIFY_SOURCE 0
5033 # endif
5034 #endif
5035 ])
5036
5037 # If user asks to omit features, disable optional features that gnulib
5038 # might otherwise enable.
5039 if test "$with_features" = no && test "$enable_acl" != yes; then
5040   enable_acl=no
5041 fi
5042
5043 # Configure gnulib.  Although this does not affect CFLAGS or LIBS permanently.
5044 # it temporarily reverts them to their pre-pkg-config values,
5045 # because gnulib needs to work with both src (which uses the
5046 # pkg-config stuff) and lib-src (which does not).  For example, gnulib
5047 # may need to determine whether LIB_CLOCK_GETTIME should contain -lrt,
5048 # and it therefore needs to run in an environment where LIBS does not
5049 # already contain -lrt merely because 'pkg-config --libs' printed '-lrt'
5050 # for some package unrelated to lib-src.
5051 SAVE_CFLAGS=$CFLAGS
5052 SAVE_LIBS=$LIBS
5053 CFLAGS=$pre_PKG_CONFIG_CFLAGS
5054 LIBS="$LIB_PTHREAD $pre_PKG_CONFIG_LIBS"
5055 gl_ASSERT_NO_GNULIB_POSIXCHECK
5056 gl_ASSERT_NO_GNULIB_TESTS
5057 gl_INIT
5058 CFLAGS=$SAVE_CFLAGS
5059 LIBS=$SAVE_LIBS
5060
5061 if test "${opsys}" = "mingw32"; then
5062   CPPFLAGS="$CPPFLAGS -DUSE_CRT_DLL=1 -I \${abs_top_srcdir}/nt/inc"
5063   # Remove unneeded switches from the value of CC that goes to Makefiles
5064   CC=`AS_ECHO(["$CC"]) | sed -e "s,$GCC_TEST_OPTIONS,,"`
5065 fi
5066
5067 case "$opsys" in
5068   aix4-2) LD_SWITCH_SYSTEM_TEMACS="-Wl,-bnodelcsect" ;;
5069
5070   cygwin) LD_SWITCH_SYSTEM_TEMACS="-Wl,-stack,0x00800000" ;;
5071
5072   darwin)
5073    ## The -headerpad option tells ld (see man page) to leave room at the
5074    ## end of the header for adding load commands.  Needed for dumping.
5075    ## 0x1000 is enough for roughly 52 load commands on the x86_64
5076    ## architecture (where they are 78 bytes each). The actual number of
5077    ## load commands added is not consistent but normally ranges from
5078    ## about 14 to about 34. Setting it high gets us plenty of slop and
5079    ## only costs about 1.5K of wasted binary space.
5080    headerpad_extra=1000
5081    if test "$HAVE_NS" = "yes"; then
5082      libs_nsgui="-framework AppKit"
5083      if test "$NS_IMPL_COCOA" = "yes"; then
5084         libs_nsgui="$libs_nsgui -framework IOKit"
5085      fi
5086    else
5087      libs_nsgui=
5088    fi
5089    LD_SWITCH_SYSTEM_TEMACS="-fno-pie -prebind $libs_nsgui -Xlinker -headerpad -Xlinker $headerpad_extra"
5090
5091    ## This is here because src/Makefile.in did some extra fiddling around
5092    ## with LD_SWITCH_SYSTEM.  It seems cleaner to put this in
5093    ## LD_SWITCH_SYSTEM_TEMACS instead,
5094    test "x$LD_SWITCH_SYSTEM" = "x" && test "x$GCC" != "xyes" && \
5095      LD_SWITCH_SYSTEM_TEMACS="-X $LD_SWITCH_SYSTEM_TEMACS"
5096    ;;
5097
5098   ## LD_SWITCH_X_SITE_RPATH is a -rpath option saying where to
5099   ## find X at run-time.
5100   ## When handled by cpp, this was in LD_SWITCH_SYSTEM.  However, at the
5101   ## point where configure sourced the s/*.h file, LD_SWITCH_X_SITE_RPATH
5102   ## had not yet been defined and was expanded to null.  Hence LD_SWITCH_SYSTEM
5103   ## had different values in configure (in ac_link) and src/Makefile.in.
5104   ## It seems clearer therefore to put this piece in LD_SWITCH_SYSTEM_TEMACS.
5105   gnu*) LD_SWITCH_SYSTEM_TEMACS="\$(LD_SWITCH_X_SITE_RPATH)" ;;
5106
5107   mingw32)
5108    ## Is it any better under MinGW64 to relocate emacs into higher addresses?
5109    case "$canonical" in
5110      x86_64-*-*) LD_SWITCH_SYSTEM_TEMACS="-Wl,-stack,0x00800000 -Wl,-heap,0x00100000 -Wl,-image-base,0x400000000 -Wl,-entry,__start -Wl,-Map,./temacs.map" ;;
5111      *) LD_SWITCH_SYSTEM_TEMACS="-Wl,-stack,0x00800000 -Wl,-heap,0x00100000 -Wl,-image-base,0x01000000 -Wl,-entry,__start -Wl,-Map,./temacs.map" ;;
5112    esac
5113    ;;
5114
5115   *) LD_SWITCH_SYSTEM_TEMACS= ;;
5116 esac
5117
5118 # -nopie fixes a temacs segfault on Gentoo, OpenBSD, and other systems
5119 # with "hardened" GCC configurations for some reason (Bug#18784).
5120 # We don't know why -nopie works, but not segfaulting is better than
5121 # segfaulting.  Use ac_c_werror_flag=yes when trying -nopie, otherwise
5122 # clang keeps warning that it does not understand -nopie, and pre-4.6
5123 # GCC has a similar problem (Bug#20338).
5124 AC_CACHE_CHECK([whether $CC accepts -nopie],
5125   [emacs_cv_prog_cc_nopie],
5126   [emacs_save_c_werror_flag=$ac_c_werror_flag
5127    emacs_save_LDFLAGS=$LDFLAGS
5128    ac_c_werror_flag=yes
5129    LDFLAGS="$LDFLAGS -nopie"
5130    AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
5131      [emacs_cv_prog_cc_nopie=yes],
5132      [emacs_cv_prog_cc_nopie=no])
5133    ac_c_werror_flag=$emacs_save_c_werror_flag
5134    LDFLAGS=$emacs_save_LDFLAGS])
5135 if test "$emacs_cv_prog_cc_nopie" = yes; then
5136   LD_SWITCH_SYSTEM_TEMACS="$LD_SWITCH_SYSTEM_TEMACS -nopie"
5137 fi
5138
5139 if test x$ac_enable_profiling != x ; then
5140   case $opsys in
5141     *freebsd | gnu-linux) ;;
5142     *) LD_SWITCH_SYSTEM_TEMACS="$LD_SWITCH_SYSTEM_TEMACS -pg" ;;
5143   esac
5144 fi
5145
5146 LD_SWITCH_SYSTEM_TEMACS="$LDFLAGS_NOCOMBRELOC $LD_SWITCH_SYSTEM_TEMACS"
5147
5148 AC_SUBST(LD_SWITCH_SYSTEM_TEMACS)
5149
5150 ## Common for all window systems
5151 if test "$window_system" != "none"; then
5152   AC_DEFINE(HAVE_WINDOW_SYSTEM, 1, [Define if you have a window system.])
5153   AC_DEFINE(POLL_FOR_INPUT, 1, [Define if you poll periodically to detect C-g.])
5154   WINDOW_SYSTEM_OBJ="fontset.o fringe.o image.o"
5155 fi
5156
5157 AC_SUBST(WINDOW_SYSTEM_OBJ)
5158
5159 AH_TOP([/* GNU Emacs site configuration template file.
5160
5161 Copyright (C) 1988, 1993-1994, 1999-2002, 2004-2016
5162   Free Software Foundation, Inc.
5163
5164 This file is part of GNU Emacs.
5165
5166 GNU Emacs is free software: you can redistribute it and/or modify
5167 it under the terms of the GNU General Public License as published by
5168 the Free Software Foundation, either version 3 of the License, or (at
5169 your option) any later version.
5170
5171 GNU Emacs is distributed in the hope that it will be useful,
5172 but WITHOUT ANY WARRANTY; without even the implied warranty of
5173 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
5174 GNU General Public License for more details.
5175
5176 You should have received a copy of the GNU General Public License
5177 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
5178
5179
5180 /* No code in Emacs #includes config.h twice, but some bits of code
5181    intended to work with other packages as well (like gmalloc.c)
5182    think they can include it as many times as they like.  */
5183 #ifndef EMACS_CONFIG_H
5184 #define EMACS_CONFIG_H
5185 ])dnl
5186
5187 AH_BOTTOM([#include <conf_post.h>
5188
5189 #endif /* EMACS_CONFIG_H */
5190
5191 /*
5192 Local Variables:
5193 mode: c
5194 End:
5195 */
5196 ])dnl
5197
5198 #### Report on what we decided to do.
5199 #### Report GTK as a toolkit, even if it doesn't use Xt.
5200 #### It makes printing result more understandable as using GTK sets
5201 #### toolkit_scroll_bars to yes by default.
5202 if test "${HAVE_GTK}" = "yes"; then
5203   USE_X_TOOLKIT="$USE_GTK_TOOLKIT"
5204 fi
5205
5206 if test $USE_ACL -ne 0; then
5207   ACL_SUMMARY="yes $LIB_ACL"
5208 else
5209   ACL_SUMMARY=no
5210 fi
5211
5212 emacs_standard_dirs='Standard dirs'
5213 AS_ECHO(["
5214 Configured for '${canonical}'.
5215
5216   Where should the build process find the source code?    ${srcdir}
5217   What compiler should emacs be built with?               ${CC} ${CFLAGS}
5218   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
5219   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
5220   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
5221   What window system should Emacs use?                    ${window_system}
5222   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}
5223   Where do we find X Windows header files?                ${x_includes:-$emacs_standard_dirs}
5224   Where do we find X Windows libraries?                   ${x_libraries:-$emacs_standard_dirs}"])
5225
5226 optsep=
5227 emacs_config_features=
5228 for opt in XAW3D XPM JPEG TIFF GIF PNG RSVG CAIRO IMAGEMAGICK SOUND GPM DBUS \
5229   GCONF GSETTINGS NOTIFY ACL LIBSELINUX GNUTLS LIBXML2 FREETYPE M17N_FLT \
5230   LIBOTF XFT ZLIB TOOLKIT_SCROLL_BARS X_TOOLKIT X11 NS MODULES \
5231   XWIDGETS LIBSYSTEMD; do
5232
5233     case $opt in
5234       NOTIFY|ACL) eval val=\${${opt}_SUMMARY} ;;
5235       TOOLKIT_SCROLL_BARS|X_TOOLKIT) eval val=\${USE_$opt} ;;
5236       *) eval val=\${HAVE_$opt} ;;
5237     esac
5238     case x$val in
5239       xno|xnone|x) continue ;;
5240     esac
5241     case $opt in
5242       X_TOOLKIT)
5243         case $val in
5244           GTK*|LUCID|MOTIF) opt=$val ;;
5245           *) continue ;;
5246         esac
5247       ;;
5248     esac
5249     AS_VAR_APPEND([emacs_config_features], ["$optsep$opt"])
5250     optsep=' '
5251 done
5252 AC_DEFINE_UNQUOTED(EMACS_CONFIG_FEATURES, "${emacs_config_features}",
5253   [Summary of some of the main features enabled by configure.])
5254
5255 AS_ECHO(["  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}
5256   Does Emacs use -lXpm?                                   ${HAVE_XPM}
5257   Does Emacs use -ljpeg?                                  ${HAVE_JPEG}
5258   Does Emacs use -ltiff?                                  ${HAVE_TIFF}
5259   Does Emacs use a gif library?                           ${HAVE_GIF} $LIBGIF
5260   Does Emacs use a png library?                           ${HAVE_PNG} $LIBPNG
5261   Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}
5262   Does Emacs use cairo?                                   ${HAVE_CAIRO}
5263   Does Emacs use imagemagick?                             ${HAVE_IMAGEMAGICK}
5264   Does Emacs support sound?                               ${HAVE_SOUND}
5265   Does Emacs use -lgpm?                                   ${HAVE_GPM}
5266   Does Emacs use -ldbus?                                  ${HAVE_DBUS}
5267   Does Emacs use -lgconf?                                 ${HAVE_GCONF}
5268   Does Emacs use GSettings?                               ${HAVE_GSETTINGS}
5269   Does Emacs use a file notification library?             ${NOTIFY_SUMMARY}
5270   Does Emacs use access control lists?                    ${ACL_SUMMARY}
5271   Does Emacs use -lselinux?                               ${HAVE_LIBSELINUX}
5272   Does Emacs use -lgnutls?                                ${HAVE_GNUTLS}
5273   Does Emacs use -lxml2?                                  ${HAVE_LIBXML2}
5274   Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}
5275   Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}
5276   Does Emacs use -lotf?                                   ${HAVE_LIBOTF}
5277   Does Emacs use -lxft?                                   ${HAVE_XFT}
5278   Does Emacs use -lsystemd?                               ${HAVE_LIBSYSTEMD}
5279   Does Emacs directly use zlib?                           ${HAVE_ZLIB}
5280   Does Emacs have dynamic modules support?                ${HAVE_MODULES}
5281   Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}
5282   Does Emacs support Xwidgets (requires gtk3)?            ${HAVE_XWIDGETS}
5283 "])
5284
5285 if test -n "${EMACSDATA}"; then
5286    AS_ECHO(["  Environment variable EMACSDATA set to:                  $EMACSDATA"])
5287 fi
5288 if test -n "${EMACSDOC}"; then
5289    AS_ECHO(["  Environment variable EMACSDOC set to:                   $EMACSDOC"])
5290 fi
5291
5292 echo
5293
5294 if test "$HAVE_NS" = "yes"; then
5295    echo
5296    AS_ECHO(["You must run \"${MAKE-make} install\" in order to test the built application.
5297 The installed application will go to nextstep/Emacs.app and can be
5298 run or moved from there."])
5299    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
5300       echo "The application will be fully self-contained."
5301     else
5302       AS_ECHO(["The lisp resources for the application will be installed under ${prefix}.
5303 You may need to run \"${MAKE-make} install\" with sudo.  The application will fail
5304 to run if these resources are not installed."])
5305    fi
5306    echo
5307 fi
5308
5309 if test "${opsys}" = "cygwin"; then
5310   case `uname -r` in
5311     1.5.*) AC_MSG_WARN([[building Emacs on Cygwin 1.5 is not supported.]])
5312            echo
5313            ;;
5314   esac
5315 fi
5316
5317 # Remove any trailing slashes in these variables.
5318 case $prefix in
5319   */) prefix=`AS_DIRNAME(["$prefix."])`;;
5320 esac
5321 case $exec_prefix in
5322   */) exec_prefix=`AS_DIRNAME(["$exec_prefix."])`;;
5323 esac
5324
5325 if test "$HAVE_NS" = "yes"; then
5326   if test "$NS_IMPL_GNUSTEP" = yes; then
5327     AC_CONFIG_FILES([nextstep/GNUstep/Emacs.base/Resources/Info-gnustep.plist:nextstep/templates/Info-gnustep.plist.in \
5328       nextstep/GNUstep/Emacs.base/Resources/Emacs.desktop:nextstep/templates/Emacs.desktop.in])
5329     ns_check_file=Resources/Info-gnustep.plist
5330   else
5331     AC_CONFIG_FILES([nextstep/Cocoa/Emacs.base/Contents/Info.plist:nextstep/templates/Info.plist.in \
5332       nextstep/Cocoa/Emacs.base/Contents/Resources/English.lproj/InfoPlist.strings:nextstep/templates/InfoPlist.strings.in])
5333     ns_check_file=Contents/Info.plist
5334   fi
5335   AC_SUBST(ns_check_file)
5336 fi
5337
5338 dnl config.status treats $srcdir specially, so I think this is ok...
5339 AC_CONFIG_FILES([$srcdir/doc/man/emacs.1])
5340
5341 dnl Obviously there is duplication here wrt $SUBDIR_MAKEFILES.
5342 dnl You _can_ use that variable in AC_CONFIG_FILES, so long as any directory
5343 dnl using automake (ie lib/) is explicitly listed and not "hidden" in a variable
5344 dnl (else you get "no 'Makefile.am' found for any configure output").
5345 dnl This will work, but you get a config.status that is not quite right
5346 dnl (see http://lists.gnu.org/archive/html/bug-autoconf/2008-08/msg00028.html).
5347 dnl That doesn't have any obvious consequences for Emacs, but on the whole
5348 dnl it seems better to just live with the duplication.
5349 SUBDIR_MAKEFILES="lib/Makefile lib-src/Makefile oldXMenu/Makefile doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile leim/Makefile nextstep/Makefile nt/Makefile"
5350
5351 AC_CONFIG_FILES([Makefile lib/Makefile lib-src/Makefile oldXMenu/Makefile \
5352        doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
5353        doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile \
5354        leim/Makefile nextstep/Makefile nt/Makefile])
5355
5356 dnl test/ is not present in release tarfiles.
5357 opt_makefile=test/Makefile
5358
5359 if test -f "$srcdir/$opt_makefile.in"; then
5360   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES $opt_makefile"
5361   dnl Again, it's best not to use a variable.  Though you can add
5362   dnl ", [], [opt_makefile='$opt_makefile']" and it should work.
5363   AC_CONFIG_FILES([test/Makefile])
5364 fi
5365
5366
5367 dnl The admin/ directory used to be excluded from tarfiles.
5368 if test -d $srcdir/admin; then
5369   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES admin/charsets/Makefile admin/unidata/Makefile admin/grammars/Makefile"
5370   AC_CONFIG_FILES([admin/charsets/Makefile])
5371   AC_CONFIG_FILES([admin/unidata/Makefile])
5372   AC_CONFIG_FILES([admin/grammars/Makefile])
5373 fi                              dnl -d admin
5374
5375
5376 SUBDIR_MAKEFILES_IN=`echo " ${SUBDIR_MAKEFILES}" | sed -e 's| | $(srcdir)/|g' -e 's|Makefile|Makefile.in|g'`
5377
5378 AC_SUBST(SUBDIR_MAKEFILES_IN)
5379
5380 dnl You might wonder (I did) why epaths.h is generated by running make,
5381 dnl rather than just letting configure generate it from epaths.in.
5382 dnl One reason is that the various paths are not fully expanded (see above);
5383 dnl eg gamedir=${prefix}/var/games/emacs.
5384 dnl Secondly, the GNU Coding standards require that one should be able
5385 dnl to run 'make prefix=/some/where/else' and override the values set
5386 dnl by configure.  This also explains the 'move-if-change' test and
5387 dnl the use of force in the 'epaths-force' rule in Makefile.in.
5388 AC_CONFIG_COMMANDS([src/epaths.h], [
5389 if test "${opsys}" = "mingw32"; then
5390   ${MAKE-make} MAKEFILE_NAME=do-not-make-Makefile epaths-force-w32
5391 else
5392   ${MAKE-make} MAKEFILE_NAME=do-not-make-Makefile epaths-force
5393 fi || AC_MSG_ERROR(['src/epaths.h' could not be made.])
5394 ], [GCC="$GCC" CPPFLAGS="$CPPFLAGS" opsys="$opsys"])
5395
5396 dnl NB we have to cheat and use the ac_... version because abs_top_srcdir
5397 dnl is not yet set, sigh.  Or we could use ../$srcdir/src/.gdbinit,
5398 dnl or a symlink?
5399 AC_CONFIG_COMMANDS([src/.gdbinit], [
5400 if test ! -f src/.gdbinit && test -f "$srcdir/src/.gdbinit"; then
5401   AS_ECHO(["source $ac_abs_top_srcdir/src/.gdbinit"]) > src/.gdbinit
5402 fi
5403 ])
5404
5405 dnl Perhaps this would be better named doc-emacs-emacsver.texi?
5406 dnl See comments for etc-refcards-emacsver.tex.
5407 dnl Since we get a doc/emacs directory generated anyway, for the Makefile,
5408 dnl it is not quite the same.  But we are generating in $srcdir.
5409 AC_CONFIG_COMMANDS([doc/emacs/emacsver.texi], [
5410 ${MAKE-make} -s --no-print-directory -C doc/emacs doc-emacsver || \
5411 AC_MSG_ERROR(['doc/emacs/emacsver.texi' could not be made.])
5412 ])
5413
5414 dnl If we give this the more natural name, etc/refcards/emacsver.texi,
5415 dnl then a directory etc/refcards is created in the build directory,
5416 dnl which is probably harmless, but confusing (in out-of-tree builds).
5417 dnl (If we were to generate etc/refcards/Makefile, this might change.)
5418 dnl It is really $srcdir/etc/refcards/emacsver.tex that we generate.
5419 AC_CONFIG_COMMANDS([etc-refcards-emacsver.tex], [
5420 ${MAKE-make} -s MAKEFILE_NAME=do-not-make-Makefile etc-emacsver || \
5421 AC_MSG_ERROR(['etc/refcards/emacsver.tex' could not be made.])
5422 ])
5423
5424 AC_OUTPUT
5425
5426 test "$MAKE" = make || AC_MSG_NOTICE([Now you can run '$MAKE'.])