code.delx.au - gnu-emacs/blob - lisp/avoid.el

   1 ;;; avoid.el --- make mouse pointer stay out of the way of editing
   2
   3 ;; Copyright (C) 1993, 1994, 2000, 2002, 2003, 2004,
   4 ;;   2005, 2006 Free Software Foundation, Inc.
   5
   6 ;; Author: Boris Goldowsky <boris@gnu.org>
   7 ;; Keywords: mouse
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 ;; Boston, MA 02110-1301, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; For those who are annoyed by the mouse pointer obscuring text,
  29 ;; this mode moves the mouse pointer - either just a little out of
  30 ;; the way, or all the way to the corner of the frame.
  31 ;; To use, load or evaluate this file and type M-x mouse-avoidance-mode .
  32 ;; To set up permanently, put the following in your .emacs:
  33 ;;
  34 ;; (if (display-mouse-p) (mouse-avoidance-mode 'animate))
  35 ;;
  36 ;; Other legitimate alternatives include
  37 ;; `banish', `exile', `jump', `cat-and-mouse', and `proteus'.
  38 ;; They do somewhat different things.
  39 ;; See the documentation for function `mouse-avoidance-mode' for
  40 ;; details of the different modes.
  41 ;;
  42 ;; For added silliness, make the animatee animate...
  43 ;; put something similar to the following into your .emacs:
  44 ;;
  45 ;; (if (eq window-system 'x)
  46 ;;     (mouse-avoidance-set-pointer-shape
  47 ;;           (eval (nth (random 4)
  48 ;;                      '(x-pointer-man x-pointer-spider
  49 ;;                        x-pointer-gobbler x-pointer-gumby)))))
  50 ;;
  51 ;; For completely random pointer shape, replace the setq above with:
  52 ;; (setq x-pointer-shape (mouse-avoidance-random-shape))
  53 ;;
  54 ;; Bugs / Warnings / To-Do:
  55 ;;
  56 ;; - Using this code does slow Emacs down.  "banish" mode shouldn't
  57 ;;   be too bad, and on my workstation even "animate" is reasonable.
  58 ;;
  59 ;; - It ought to find out where any overlapping frames are and avoid them,
  60 ;;   rather than always raising the frame.
  61
  62 ;; Credits:
  63 ;; This code was helped by all those who contributed suggestions,
  64 ;;   fixes, and additions
  65 ;; Joe Harrington (and his advisor), for the original inspiration.
  66 ;; Ken Manheimer, for dreaming up the Protean mode.
  67 ;; Richard Stallman, for the awful cat-and-mouse pun, among other things.
  68 ;; Mike Williams, Denis Howe, Bill Benedetto, Chris Moore, Don Morris,
  69 ;; Simon Marshall, and M.S. Ashton, for their feedback.
  70
  71 ;;; Code:
  72
  73 (provide 'avoid)
  74
  75 (defgroup avoid nil
  76   "Make mouse pointer stay out of the way of editing."
  77   :prefix "mouse-avoidance-"
  78   :group 'mouse)
  79
  80 ;;;###autoload
  81 (defcustom mouse-avoidance-mode nil
  82   "Activate mouse avoidance mode.
  83 See function `mouse-avoidance-mode' for possible values.
  84 Setting this variable directly does not take effect;
  85 use either \\[customize] or the function `mouse-avoidance-mode'."
  86   :set (lambda (symbol value)
  87          ;; 'none below prevents toggling when value is nil.
  88          (mouse-avoidance-mode (or value 'none)))
  89   :initialize 'custom-initialize-default
  90   :type '(choice (const :tag "none" nil) (const banish) (const jump)
  91                  (const animate) (const exile) (const proteus)
  92                  )
  93   :group 'avoid
  94   :require 'avoid
  95   :version "20.3")
  96
  97
  98 (defcustom mouse-avoidance-nudge-dist 15
  99   "*Average distance that mouse will be moved when approached by cursor.
 100 Only applies in Mouse-Avoidance mode `jump' and its derivatives.
 101 For best results make this larger than `mouse-avoidance-threshold'."
 102   :type 'integer
 103   :group 'avoid)
 104
 105 (defcustom mouse-avoidance-nudge-var 10
 106   "*Variability of `mouse-avoidance-nudge-dist' (which see)."
 107   :type 'integer
 108   :group 'avoid)
 109
 110 (defcustom mouse-avoidance-animation-delay .01
 111   "Delay between animation steps, in seconds."
 112   :type 'number
 113   :group 'avoid)
 114
 115 (defcustom mouse-avoidance-threshold 5
 116   "*Mouse-pointer's flight distance.
 117 If the cursor gets closer than this, the mouse pointer will move away.
 118 Only applies in mouse-avoidance-modes `animate' and `jump'."
 119   :type 'integer
 120   :group 'avoid)
 121
 122 ;; Internal variables
 123 (defvar mouse-avoidance-state nil)
 124 (defvar mouse-avoidance-pointer-shapes nil)
 125 (defvar mouse-avoidance-n-pointer-shapes 0)
 126 (defvar mouse-avoidance-old-pointer-shape nil)
 127
 128 ;; This timer is used to run something when Emacs is idle.
 129 (defvar mouse-avoidance-timer nil)
 130
 131 ;;; Functions:
 132
 133 (defsubst mouse-avoidance-set-pointer-shape (shape)
 134   "Set the shape of the mouse pointer to SHAPE."
 135   (when (boundp 'x-pointer-shape)
 136     (setq x-pointer-shape shape)
 137     (set-mouse-color nil)))
 138
 139 (defun mouse-avoidance-point-position ()
 140   "Return the position of point as (FRAME X . Y).
 141 Analogous to `mouse-position'."
 142   (let ((edges (window-inside-edges))
 143         (x-y (posn-x-y (posn-at-point))))
 144     (cons (selected-frame)
 145           (cons (+ (car edges)
 146                    (/ (car x-y) (frame-char-width)))
 147                 (+ (car (cdr edges))
 148                    (/ (cdr x-y) (frame-char-height)))))))
 149
 150 ;(defun mouse-avoidance-point-position-test ()
 151 ;  (interactive)
 152 ;  (message (format "point=%s mouse=%s"
 153 ;                  (cdr (mouse-avoidance-point-position))
 154 ;                  (cdr (mouse-position)))))
 155
 156 (defun mouse-avoidance-set-mouse-position (pos)
 157   ;; Carefully set mouse position to given position (X . Y)
 158   ;; Ideally, should check if X,Y is in the current frame, and if not,
 159   ;; leave the mouse where it was.  However, this is currently
 160   ;; difficult to do, so we just raise the frame to avoid frame switches.
 161   ;; Returns t if it moved the mouse.
 162   (let ((f (selected-frame)))
 163     (raise-frame f)
 164     (set-mouse-position f (car pos) (cdr pos))
 165     t))
 166
 167 (defun mouse-avoidance-too-close-p (mouse)
 168   "Return t if mouse pointer and point cursor are too close.
 169 MOUSE is the current mouse position as returned by `mouse-position'.
 170 Acceptable distance is defined by `mouse-avoidance-threshold'."
 171   (let* ((frame (car mouse))
 172          (mouse-y (cdr (cdr mouse)))
 173          (tool-bar-lines (frame-parameter nil 'tool-bar-lines)))
 174     (or tool-bar-lines
 175         (setq tool-bar-lines 0))
 176     (if (and mouse-y (< mouse-y tool-bar-lines))
 177         nil
 178       (let ((point (mouse-avoidance-point-position))
 179             (mouse-x (car (cdr mouse))))
 180         (and (eq frame (car point))
 181              (not (null mouse-x))
 182              (< (abs (- mouse-x (car (cdr point))))
 183                 mouse-avoidance-threshold)
 184              (< (abs (- mouse-y (cdr (cdr point))))
 185                 mouse-avoidance-threshold))))))
 186
 187 (defun mouse-avoidance-banish-destination ()
 188   "The position to which Mouse-Avoidance mode `banish' moves the mouse.
 189 You can redefine this if you want the mouse banished to a different corner."
 190   (let* ((pos (window-edges)))
 191     (cons (- (nth 2 pos) 2)
 192           (nth 1 pos))))
 193
 194 (defun mouse-avoidance-banish-mouse ()
 195   ;; Put the mouse pointer in the upper-right corner of the current frame.
 196   (mouse-avoidance-set-mouse-position (mouse-avoidance-banish-destination)))
 197
 198 (defsubst mouse-avoidance-delta (cur delta dist var min max)
 199   ;; Decide how far to move in either dimension.
 200   ;; Args are the CURRENT location, the desired DELTA for
 201   ;; warp-conservation, the DISTANCE we like to move, the VARIABILITY
 202   ;; in distance allowed, and the MIN and MAX possible window positions.
 203   ;; Returns something as close to DELTA as possible within the constraints.
 204   (let ((L1 (max (- min cur) (+ (- dist) (- var))))
 205         (R1                  (+ (- dist)    var ))
 206         (L2                  (+    dist  (- var)))
 207         (R2 (min (- max cur) (+    dist     var))))
 208     (if (< R1 (- min cur)) (setq L1 nil R1 nil))
 209     (if (> L2 (- max cur)) (setq L2 nil R2 nil))
 210     (cond ((and L1 (< delta L1)) L1)
 211           ((and R1 (< delta R1)) delta)
 212           ((and R1 (< delta 0)) R1)
 213           ((and L2 (< delta L2)) L2)
 214           ((and R2 (< delta R2)) delta)
 215           (R2)
 216           ((or R1 L2))
 217           (t 0))))
 218
 219 (defun mouse-avoidance-nudge-mouse ()
 220   ;; Push the mouse a little way away, possibly animating the move.
 221   ;; For these modes, state keeps track of the total offset that we've
 222   ;; accumulated, and tries to keep it close to zero.
 223   (let* ((cur (mouse-position))
 224          (cur-frame (car cur))
 225          (cur-pos (cdr cur))
 226          (pos (window-edges))
 227          (wleft (pop pos))
 228          (wtop (pop pos))
 229          (wright (pop pos))
 230          (wbot (pop pos))
 231          (deltax (mouse-avoidance-delta
 232                   (car cur-pos) (- (random mouse-avoidance-nudge-var)
 233                                    (car mouse-avoidance-state))
 234                   mouse-avoidance-nudge-dist mouse-avoidance-nudge-var
 235                   wleft (1- wright)))
 236          (deltay (mouse-avoidance-delta
 237                   (cdr cur-pos) (- (random mouse-avoidance-nudge-var)
 238                                    (cdr mouse-avoidance-state))
 239                   mouse-avoidance-nudge-dist mouse-avoidance-nudge-var
 240                   wtop (1- wbot))))
 241     (setq mouse-avoidance-state
 242           (cons (+ (car mouse-avoidance-state) deltax)
 243                 (+ (cdr mouse-avoidance-state) deltay)))
 244     (if (or (eq mouse-avoidance-mode 'animate)
 245             (eq mouse-avoidance-mode 'proteus))
 246         (let ((i 0.0))
 247           (while (<= i 1)
 248             (mouse-avoidance-set-mouse-position
 249              (cons (+ (car cur-pos) (round (* i deltax)))
 250                    (+ (cdr cur-pos) (round (* i deltay)))))
 251             (setq i (+ i (max .1 (/ 1.0 mouse-avoidance-nudge-dist))))
 252             (if (eq mouse-avoidance-mode 'proteus)
 253                 (mouse-avoidance-set-pointer-shape
 254                  (mouse-avoidance-random-shape)))
 255             (sit-for mouse-avoidance-animation-delay)))
 256       (mouse-avoidance-set-mouse-position (cons (+ (car (cdr cur)) deltax)
 257                                                 (+ (cdr (cdr cur)) deltay))))))
 258
 259 (defun mouse-avoidance-random-shape ()
 260   "Return a random cursor shape.
 261 This assumes that any variable whose name begins with x-pointer- and
 262 has an integer value is a valid cursor shape.  You might want to
 263 redefine this function to suit your own tastes."
 264   (if (null mouse-avoidance-pointer-shapes)
 265       (progn
 266         (setq mouse-avoidance-pointer-shapes
 267               (mapcar (lambda (x) (symbol-value (intern x)))
 268                       (all-completions "x-pointer-" obarray
 269                                        (lambda (x)
 270                                           (and (boundp x)
 271                                                (integerp (symbol-value x)))))))
 272         (setq mouse-avoidance-n-pointer-shapes
 273               (length mouse-avoidance-pointer-shapes))))
 274   (nth (random mouse-avoidance-n-pointer-shapes)
 275        mouse-avoidance-pointer-shapes))
 276
 277 (defun mouse-avoidance-ignore-p ()
 278   (let ((mp (mouse-position)))
 279     (or executing-kbd-macro            ; don't check inside macro
 280         (null (cadr mp))               ; don't move unless in an Emacs frame
 281         (not (eq (car mp) (selected-frame)))
 282         ;; Don't do anything if last event was a mouse event.
 283         ;; FIXME: this code fails in the case where the mouse was moved
 284         ;; since the last key-press but without generating any event.
 285         (and (consp last-input-event)
 286              (symbolp (car last-input-event))
 287              (let ((modifiers (event-modifiers (car last-input-event))))
 288                (or (memq (car last-input-event)
 289                          '(mouse-movement scroll-bar-movement
 290                            select-window switch-frame))
 291                    (memq 'click modifiers)
 292                    (memq 'double modifiers)
 293                    (memq 'triple modifiers)
 294                    (memq 'drag modifiers)
 295                    (memq 'down modifiers)))))))
 296
 297 (defun mouse-avoidance-banish-hook ()
 298   (if (not (mouse-avoidance-ignore-p))
 299       (mouse-avoidance-banish-mouse)))
 300
 301 (defun mouse-avoidance-exile-hook ()
 302   ;; For exile mode, the state is nil when the mouse is in its normal
 303   ;; position, and set to the old mouse-position when the mouse is in exile.
 304   (if (not (mouse-avoidance-ignore-p))
 305       (let ((mp (mouse-position)))
 306         (cond ((and (not mouse-avoidance-state)
 307                     (mouse-avoidance-too-close-p mp))
 308                (setq mouse-avoidance-state mp)
 309                (mouse-avoidance-banish-mouse))
 310               ((and mouse-avoidance-state
 311                     (not (mouse-avoidance-too-close-p mouse-avoidance-state)))
 312                (if (and (eq (car mp) (selected-frame))
 313                         (equal (cdr mp) (mouse-avoidance-banish-destination)))
 314                    (mouse-avoidance-set-mouse-position
 315                     ;; move back only if user has not moved mouse
 316                     (cdr mouse-avoidance-state)))
 317                ;; but clear state anyway, to be ready for another move
 318                (setq mouse-avoidance-state nil))))))
 319
 320 (defun mouse-avoidance-fancy-hook ()
 321   ;; Used for the "fancy" modes, ie jump et al.
 322   (if (and (not (mouse-avoidance-ignore-p))
 323            (mouse-avoidance-too-close-p (mouse-position)))
 324       (let ((old-pos (mouse-position)))
 325         (mouse-avoidance-nudge-mouse)
 326         (if (not (eq (selected-frame) (car old-pos)))
 327             ;; This should never happen.
 328             (apply 'set-mouse-position old-pos)))))
 329
 330 ;;;###autoload
 331 (defun mouse-avoidance-mode (&optional mode)
 332   "Set cursor avoidance mode to MODE.
 333 MODE should be one of the symbols `banish', `exile', `jump', `animate',
 334 `cat-and-mouse', `proteus', or `none'.
 335
 336 If MODE is nil, toggle mouse avoidance between `none' and `banish'
 337 modes.  Positive numbers and symbols other than the above are treated
 338 as equivalent to `banish'; negative numbers and `-' are equivalent to `none'.
 339
 340 Effects of the different modes:
 341  * banish: Move the mouse to the upper-right corner on any keypress.
 342  * exile: Move the mouse to the corner only if the cursor gets too close,
 343      and allow it to return once the cursor is out of the way.
 344  * jump: If the cursor gets too close to the mouse, displace the mouse
 345      a random distance & direction.
 346  * animate: As `jump', but shows steps along the way for illusion of motion.
 347  * cat-and-mouse: Same as `animate'.
 348  * proteus: As `animate', but changes the shape of the mouse pointer too.
 349
 350 Whenever the mouse is moved, the frame is also raised.
 351
 352 \(see `mouse-avoidance-threshold' for definition of \"too close\",
 353 and `mouse-avoidance-nudge-dist' and `mouse-avoidance-nudge-var' for
 354 definition of \"random distance\".)"
 355   (interactive
 356    (list (intern (completing-read
 357                   "Select cursor avoidance technique (SPACE for list): "
 358                   '(("banish") ("exile") ("jump") ("animate")
 359                     ("cat-and-mouse") ("proteus") ("none"))
 360                   nil t))))
 361   (if (eq mode 'cat-and-mouse)
 362       (setq mode 'animate))
 363   (if mouse-avoidance-timer
 364       (cancel-timer mouse-avoidance-timer))
 365   (setq mouse-avoidance-timer nil)
 366
 367   ;; Restore pointer shape if necessary
 368   (if (eq mouse-avoidance-mode 'proteus)
 369       (mouse-avoidance-set-pointer-shape mouse-avoidance-old-pointer-shape))
 370
 371   ;; Do additional setup depending on version of mode requested
 372   (cond ((eq mode 'none)
 373          (setq mouse-avoidance-mode nil))
 374         ((or (eq mode 'jump)
 375              (eq mode 'animate)
 376              (eq mode 'proteus))
 377          (setq mouse-avoidance-timer
 378                (run-with-idle-timer 0.1 t 'mouse-avoidance-fancy-hook))
 379          (setq mouse-avoidance-mode mode
 380                mouse-avoidance-state (cons 0 0)
 381                mouse-avoidance-old-pointer-shape
 382                (and (boundp 'x-pointer-shape) x-pointer-shape)))
 383         ((eq mode 'exile)
 384          (setq mouse-avoidance-timer
 385                (run-with-idle-timer 0.1 t 'mouse-avoidance-exile-hook))
 386          (setq mouse-avoidance-mode mode
 387                mouse-avoidance-state nil))
 388         ((or (eq mode 'banish)
 389              (eq mode t)
 390              (and (null mode) (null mouse-avoidance-mode))
 391              (and mode (> (prefix-numeric-value mode) 0)))
 392          (setq mouse-avoidance-timer
 393                (run-with-idle-timer 0.1 t 'mouse-avoidance-banish-hook))
 394          (setq mouse-avoidance-mode 'banish))
 395         (t (setq mouse-avoidance-mode nil)))
 396   (force-mode-line-update))
 397
 398 ;; Most people who use avoid mode leave it on all the time, so it's not
 399 ;; very informative to announce it in the mode line.
 400 ;;(or (assq 'mouse-avoidance-mode minor-mode-alist)
 401 ;;    (setq minor-mode-alist (cons '(mouse-avoidance-mode " Avoid")
 402 ;;                               minor-mode-alist)))
 403
 404 ;; Needed for custom.
 405 (if mouse-avoidance-mode
 406     (mouse-avoidance-mode mouse-avoidance-mode))
 407
 408 ;; arch-tag: 64ad4ef8-a870-4183-8d96-3aa93b7a6800
 409 ;;; avoid.el ends here