code.delx.au - gnu-emacs/blob - test/automated/package-test.el

   1 ;;; package-test.el --- Tests for the Emacs package system
   2
   3 ;; Copyright (C) 2013-2015 Free Software Foundation, Inc.
   4
   5 ;; Author: Daniel Hackney <dan@haxney.org>
   6 ;; Version: 1.0
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; You may want to run this from a separate Emacs instance from your
  26 ;; main one, because a bug in the code below could mess with your
  27 ;; installed packages.
  28
  29 ;; Run this in a clean Emacs session using:
  30 ;;
  31 ;;     $ emacs -Q --batch -L . -l package-test.el -l ert -f ert-run-tests-batch-and-exit
  32
  33 ;;; Code:
  34
  35 (require 'package)
  36 (require 'ert)
  37 (require 'cl-lib)
  38
  39 (setq package-menu-async nil)
  40
  41 (defvar package-test-user-dir nil
  42   "Directory to use for installing packages during testing.")
  43
  44 (defvar package-test-file-dir (file-name-directory (or load-file-name
  45                                                        buffer-file-name))
  46   "Directory of the actual \"package-test.el\" file.")
  47
  48 (defvar simple-single-desc
  49   (package-desc-create :name 'simple-single
  50                        :version '(1 3)
  51                        :summary "A single-file package with no dependencies"
  52                        :kind 'single
  53                        :extras '((:url . "http://doodles.au")))
  54   "Expected `package-desc' parsed from simple-single-1.3.el.")
  55
  56 (defvar simple-depend-desc
  57   (package-desc-create :name 'simple-depend
  58                        :version '(1 0)
  59                        :summary "A single-file package with a dependency."
  60                        :kind 'single
  61                        :reqs '((simple-single (1 3))))
  62   "Expected `package-desc' parsed from simple-depend-1.0.el.")
  63
  64 (defvar multi-file-desc
  65   (package-desc-create :name 'multi-file
  66                        :version '(0 2 3)
  67                        :summary "Example of a multi-file tar package"
  68                        :kind 'tar
  69                        :extras '((:url . "http://puddles.li")))
  70   "Expected `package-desc' from \"multi-file-0.2.3.tar\".")
  71
  72 (defvar new-pkg-desc
  73   (package-desc-create :name 'new-pkg
  74                        :version '(1 0)
  75                        :kind 'single)
  76   "Expected `package-desc' parsed from new-pkg-1.0.el.")
  77
  78 (defvar simple-depend-desc-1
  79   (package-desc-create :name 'simple-depend-1
  80                        :version '(1 0)
  81                        :summary "A single-file package with a dependency."
  82                        :kind 'single
  83                        :reqs '((simple-depend (1 0))
  84                                (multi-file (0 1))))
  85   "`package-desc' used for testing dependencies.")
  86
  87 (defvar simple-depend-desc-2
  88   (package-desc-create :name 'simple-depend-2
  89                        :version '(1 0)
  90                        :summary "A single-file package with a dependency."
  91                        :kind 'single
  92                        :reqs '((simple-depend-1 (1 0))
  93                                (multi-file (0 1))))
  94   "`package-desc' used for testing dependencies.")
  95
  96 (defvar package-test-data-dir (expand-file-name "data/package" package-test-file-dir)
  97   "Base directory of package test files.")
  98
  99 (defvar package-test-fake-contents-file
 100   (expand-file-name "archive-contents" package-test-data-dir)
 101   "Path to a static copy of \"archive-contents\".")
 102
 103 (cl-defmacro with-package-test ((&optional &key file
 104                                            basedir
 105                                            install
 106                                            update-news
 107                                            upload-base)
 108                                 &rest body)
 109   "Set up temporary locations and variables for testing."
 110   (declare (indent 1))
 111   `(let* ((package-test-user-dir (make-temp-file "pkg-test-user-dir-" t))
 112           (process-environment (cons (format "HOME=%s" package-test-user-dir)
 113                                      process-environment))
 114           (package-user-dir package-test-user-dir)
 115           (package-archives `(("gnu" . ,package-test-data-dir)))
 116           (old-yes-no-defn (symbol-function 'yes-or-no-p))
 117           (default-directory package-test-file-dir)
 118           abbreviated-home-dir
 119           package--initialized
 120           package-alist
 121           ,@(if update-news
 122                 '(package-update-news-on-upload t)
 123               (list (cl-gensym)))
 124           ,@(if upload-base
 125                 '((package-test-archive-upload-base (make-temp-file "pkg-archive-base-" t))
 126                   (package-archive-upload-base package-test-archive-upload-base))
 127               (list (cl-gensym)))) ;; Dummy value so `let' doesn't try to bind `nil'
 128      (unwind-protect
 129          (progn
 130            ,(if basedir `(cd ,basedir))
 131            (setf (symbol-function 'yes-or-no-p) #'(lambda (&rest r) t))
 132            (unless (file-directory-p package-user-dir)
 133              (mkdir package-user-dir))
 134            ,@(when install
 135                `((package-initialize)
 136                  (package-refresh-contents)
 137                  (mapc 'package-install ,install)))
 138            (with-temp-buffer
 139              ,(if file
 140                   `(insert-file-contents ,file))
 141              ,@body))
 142
 143        (when (file-directory-p package-test-user-dir)
 144          (delete-directory package-test-user-dir t))
 145
 146        (when (and (boundp 'package-test-archive-upload-base)
 147                   (file-directory-p package-test-archive-upload-base))
 148          (delete-directory package-test-archive-upload-base t))
 149        (setf (symbol-function 'yes-or-no-p) old-yes-no-defn))))
 150
 151 (defmacro with-fake-help-buffer (&rest body)
 152   "Execute BODY in a temp buffer which is treated as the \"*Help*\" buffer."
 153   `(with-temp-buffer
 154     (help-mode)
 155     ;; Trick `help-buffer' into using the temp buffer.
 156     (let ((help-xref-following t))
 157       ,@body)))
 158
 159 (defun package-test-strip-version (dir)
 160   (replace-regexp-in-string "-pkg\\.el\\'" "" (package--description-file dir)))
 161
 162 (defun package-test-suffix-matches (base suffix-list)
 163   "Return file names matching BASE concatenated with each item in SUFFIX-LIST"
 164   (cl-mapcan
 165    '(lambda (item) (file-expand-wildcards (concat base item)))
 166    suffix-list))
 167
 168 (defvar tar-parse-info)
 169 (declare-function tar-header-name "tar-mode" (cl-x) t) ; defstruct
 170
 171 (defun package-test-search-tar-file (filename)
 172   "Search the current buffer's `tar-parse-info' variable for FILENAME.
 173
 174 Must called from within a `tar-mode' buffer."
 175   (cl-dolist (header tar-parse-info)
 176     (let ((tar-name (tar-header-name header)))
 177       (when (string= tar-name filename)
 178         (cl-return t)))))
 179
 180 (defun package-test-desc-version-string (desc)
 181   "Return the package version as a string."
 182   (package-version-join (package-desc-version desc)))
 183
 184 (ert-deftest package-test-desc-from-buffer ()
 185   "Parse an elisp buffer to get a `package-desc' object."
 186   (with-package-test (:basedir "data/package" :file "simple-single-1.3.el")
 187     (should (equal (package-buffer-info) simple-single-desc)))
 188   (with-package-test (:basedir "data/package" :file "simple-depend-1.0.el")
 189     (should (equal (package-buffer-info) simple-depend-desc)))
 190   (with-package-test (:basedir "data/package"
 191                                :file "multi-file-0.2.3.tar")
 192     (tar-mode)
 193     (should (equal (package-tar-file-info) multi-file-desc))))
 194
 195 (ert-deftest package-test-install-single ()
 196   "Install a single file without using an archive."
 197   (with-package-test (:basedir "data/package" :file "simple-single-1.3.el")
 198     (should (package-install-from-buffer))
 199     (package-initialize)
 200     (should (package-installed-p 'simple-single))
 201     (let* ((simple-pkg-dir (file-name-as-directory
 202                             (expand-file-name
 203                              "simple-single-1.3"
 204                              package-test-user-dir)))
 205            (autoloads-file (expand-file-name "simple-single-autoloads.el"
 206                                              simple-pkg-dir)))
 207       (should (file-directory-p simple-pkg-dir))
 208       (with-temp-buffer
 209         (insert-file-contents (expand-file-name "simple-single-pkg.el"
 210                                                 simple-pkg-dir))
 211         (should (string= (buffer-string)
 212                          (concat ";;; -*- no-byte-compile: t -*-\n"
 213                                  "(define-package \"simple-single\" \"1.3\" "
 214                                  "\"A single-file package "
 215                                  "with no dependencies\" 'nil "
 216                                  ":url \"http://doodles.au\""
 217                                  ")\n"))))
 218       (should (file-exists-p autoloads-file))
 219       (should-not (get-file-buffer autoloads-file)))))
 220
 221 (ert-deftest package-test-install-dependency ()
 222   "Install a package which includes a dependency."
 223   (with-package-test ()
 224     (package-initialize)
 225     (package-refresh-contents)
 226     (package-install 'simple-depend)
 227     (should (package-installed-p 'simple-single))
 228     (should (package-installed-p 'simple-depend))))
 229
 230 (ert-deftest package-test-install-two-dependencies ()
 231   "Install a package which includes a dependency."
 232   (with-package-test ()
 233     (package-initialize)
 234     (package-refresh-contents)
 235     (package-install 'simple-two-depend)
 236     (should (package-installed-p 'simple-single))
 237     (should (package-installed-p 'simple-depend))
 238     (should (package-installed-p 'simple-two-depend))))
 239
 240 (ert-deftest package-test-refresh-contents ()
 241   "Parse an \"archive-contents\" file."
 242   (with-package-test ()
 243     (package-initialize)
 244     (package-refresh-contents)
 245     (should (eq 4 (length package-archive-contents)))))
 246
 247 (ert-deftest package-test-install-single-from-archive ()
 248   "Install a single package from a package archive."
 249   (with-package-test ()
 250     (package-initialize)
 251     (package-refresh-contents)
 252     (package-install 'simple-single)))
 253
 254 (ert-deftest package-test-install-prioritized ()
 255   "Install a lower version from a higher-prioritized archive."
 256   (with-package-test ()
 257     (let* ((newer-version (expand-file-name "data/package/newer-versions"
 258                                             package-test-file-dir))
 259            (package-archives `(("older" . ,package-test-data-dir)
 260                                ("newer" . ,newer-version)))
 261            (package-archive-priorities '(("older" . 100))))
 262
 263       (package-initialize)
 264       (package-refresh-contents)
 265       (package-install 'simple-single)
 266
 267       (let ((installed (cadr (assq 'simple-single package-alist))))
 268         (should (version-list-= '(1 3)
 269                                 (package-desc-version installed)))))))
 270
 271 (ert-deftest package-test-install-multifile ()
 272   "Check properties of the installed multi-file package."
 273   (with-package-test (:basedir "data/package" :install '(multi-file))
 274     (let ((autoload-file
 275            (expand-file-name "multi-file-autoloads.el"
 276                              (expand-file-name
 277                               "multi-file-0.2.3"
 278                               package-test-user-dir)))
 279           (installed-files '("dir" "multi-file.info" "multi-file-sub.elc"
 280                              "multi-file-autoloads.el" "multi-file.elc"))
 281           (autoload-forms '("^(defvar multi-file-custom-var"
 282                             "^(custom-autoload 'multi-file-custom-var"
 283                             "^(autoload 'multi-file-mode"))
 284           (pkg-dir (file-name-as-directory
 285                     (expand-file-name
 286                      "multi-file-0.2.3"
 287                      package-test-user-dir))))
 288       (package-refresh-contents)
 289       (should (package-installed-p 'multi-file))
 290       (with-temp-buffer
 291         (insert-file-contents-literally autoload-file)
 292         (dolist (fn installed-files)
 293           (should (file-exists-p (expand-file-name fn pkg-dir))))
 294         (dolist (re autoload-forms)
 295           (goto-char (point-min))
 296           (should (re-search-forward re nil t)))))))
 297
 298 (ert-deftest package-test-update-listing ()
 299   "Ensure installed package status is updated."
 300   (with-package-test ()
 301     (let ((buf (package-list-packages)))
 302       (search-forward-regexp "^ +simple-single")
 303       (package-menu-mark-install)
 304       (package-menu-execute)
 305       (should (package-installed-p 'simple-single))
 306       (switch-to-buffer "*Packages*")
 307       (goto-char (point-min))
 308       (should (re-search-forward "^\\s-+simple-single\\s-+1.3\\s-+installed" nil t))
 309       (goto-char (point-min))
 310       (should-not (re-search-forward "^\\s-+simple-single\\s-+1.3\\s-+\\(available\\|new\\)" nil t))
 311       (kill-buffer buf))))
 312
 313 (ert-deftest package-test-update-archives ()
 314   "Test updating package archives."
 315   (with-package-test ()
 316     (let ((buf (package-list-packages)))
 317       (package-menu-refresh)
 318       (search-forward-regexp "^ +simple-single")
 319       (package-menu-mark-install)
 320       (package-menu-execute)
 321       (should (package-installed-p 'simple-single))
 322       (let ((package-test-data-dir
 323              (expand-file-name "data/package/newer-versions" package-test-file-dir)))
 324         (setq package-archives `(("gnu" . ,package-test-data-dir)))
 325         (package-menu-refresh)
 326
 327         ;; New version should be available and old version should be installed
 328         (goto-char (point-min))
 329         (should (re-search-forward "^\\s-+simple-single\\s-+1.4\\s-+available" nil t))
 330         (should (re-search-forward "^\\s-+simple-single\\s-+1.3\\s-+installed" nil t))
 331
 332         (goto-char (point-min))
 333         (should (re-search-forward "^\\s-+new-pkg\\s-+1.0\\s-+\\(available\\|new\\)" nil t))
 334
 335         (package-menu-mark-upgrades)
 336         (package-menu-execute)
 337         (package-menu-refresh)
 338         (should (package-installed-p 'simple-single '(1 4)))))))
 339
 340 (ert-deftest package-test-describe-package ()
 341   "Test displaying help for a package."
 342
 343   (require 'finder-inf)
 344   ;; Built-in
 345   (with-fake-help-buffer
 346    (describe-package '5x5)
 347    (goto-char (point-min))
 348    (should (search-forward "5x5 is a built-in package." nil t))
 349    (should (search-forward "Status: Built-in." nil t))
 350    (should (search-forward "Summary: simple little puzzle game" nil t))
 351    (should (search-forward "The aim of 5x5" nil t)))
 352
 353   ;; Installed
 354   (with-package-test ()
 355     (package-initialize)
 356     (package-refresh-contents)
 357     (package-install 'simple-single)
 358     (with-fake-help-buffer
 359      (describe-package 'simple-single)
 360      (goto-char (point-min))
 361      (should (search-forward "simple-single is an installed package." nil t))
 362      (should (search-forward
 363               "Status: Installed in `~/simple-single-1.3/' (unsigned)."
 364               nil t))
 365      (should (search-forward "Version: 1.3" nil t))
 366      (should (search-forward "Summary: A single-file package with no dependencies"
 367                              nil t))
 368      (should (search-forward "Homepage: http://doodles.au" nil t))
 369      (should (re-search-forward "Keywords: \\[?frobnicate\\]?" nil t))
 370      ;; No description, though. Because at this point we don't know
 371      ;; what archive the package originated from, and we don't have
 372      ;; its readme file saved.
 373      )))
 374
 375 (ert-deftest package-test-describe-non-installed-package ()
 376   "Test displaying of the readme for non-installed package."
 377
 378   (with-package-test ()
 379     (package-initialize)
 380     (package-refresh-contents)
 381     (with-fake-help-buffer
 382      (describe-package 'simple-single)
 383      (goto-char (point-min))
 384      (should (search-forward "Homepage: http://doodles.au" nil t))
 385      (should (search-forward "This package provides a minor mode to frobnicate"
 386                              nil t)))))
 387
 388 (ert-deftest package-test-describe-non-installed-multi-file-package ()
 389   "Test displaying of the readme for non-installed multi-file package."
 390
 391   (with-package-test ()
 392     (package-initialize)
 393     (package-refresh-contents)
 394     (with-fake-help-buffer
 395      (describe-package 'multi-file)
 396      (goto-char (point-min))
 397      (should (search-forward "Homepage: http://puddles.li" nil t))
 398      (should (search-forward "This is a bare-bones readme file for the multi-file"
 399                              nil t)))))
 400
 401 (ert-deftest package-test-signed ()
 402   "Test verifying package signature."
 403   (skip-unless (ignore-errors
 404                  (let ((homedir (make-temp-file "package-test" t)))
 405                    (unwind-protect
 406                        (let ((process-environment
 407                               (cons (format "HOME=%s" homedir)
 408                                     process-environment)))
 409                          (epg-check-configuration (epg-configuration))
 410                          t)
 411                      (delete-directory homedir t)))))
 412   (let* ((keyring (expand-file-name "key.pub" package-test-data-dir))
 413          (package-test-data-dir
 414            (expand-file-name "data/package/signed" package-test-file-dir)))
 415     (with-package-test ()
 416       (package-initialize)
 417       (package-import-keyring keyring)
 418       (package-refresh-contents)
 419       (should (package-install 'signed-good))
 420       (should-error (package-install 'signed-bad))
 421       ;; Check if the installed package status is updated.
 422       (let ((buf (package-list-packages)))
 423         (package-menu-refresh)
 424         (should (re-search-forward
 425                  "^\\s-+signed-good\\s-+\\(\\S-+\\)\\s-+\\(\\S-+\\)\\s-"
 426                  nil t))
 427         (should (string-equal (match-string-no-properties 1) "1.0"))
 428         (should (string-equal (match-string-no-properties 2) "installed")))
 429       ;; Check if the package description is updated.
 430       (with-fake-help-buffer
 431        (describe-package 'signed-good)
 432        (goto-char (point-min))
 433        (should (re-search-forward "signed-good is an? \\(\\S-+\\) package." nil t))
 434        (should (string-equal (match-string-no-properties 1) "installed"))
 435        (should (search-forward
 436                 "Status: Installed in `~/signed-good-1.0/'."
 437                 nil t))))))
 438
 439
 440 \f
 441 ;;; Tests for package-x features.
 442
 443 (require 'package-x)
 444
 445 (defvar package-x-test--single-archive-entry-1-3
 446   (cons 'simple-single
 447         (package-make-ac-desc '(1 3) nil
 448                               "A single-file package with no dependencies"
 449                               'single
 450                               '((:url . "http://doodles.au"))))
 451   "Expected contents of the archive entry from the \"simple-single\" package.")
 452
 453 (defvar package-x-test--single-archive-entry-1-4
 454   (cons 'simple-single
 455         (package-make-ac-desc '(1 4) nil
 456                               "A single-file package with no dependencies"
 457                               'single
 458                               nil))
 459   "Expected contents of the archive entry from the updated \"simple-single\" package.")
 460
 461 (ert-deftest package-x-test-upload-buffer ()
 462   "Test creating an \"archive-contents\" file"
 463   (with-package-test (:basedir "data/package"
 464                                :file "simple-single-1.3.el"
 465                                :upload-base t)
 466     (package-upload-buffer)
 467     (should (file-exists-p (expand-file-name "archive-contents"
 468                                              package-archive-upload-base)))
 469     (should (file-exists-p (expand-file-name "simple-single-1.3.el"
 470                                              package-archive-upload-base)))
 471     (should (file-exists-p (expand-file-name "simple-single-readme.txt"
 472                                              package-archive-upload-base)))
 473
 474     (let (archive-contents)
 475       (with-temp-buffer
 476         (insert-file-contents
 477          (expand-file-name "archive-contents"
 478                            package-archive-upload-base))
 479         (setq archive-contents
 480               (package-read-from-string
 481                (buffer-substring (point-min) (point-max)))))
 482       (should (equal archive-contents
 483                      (list 1 package-x-test--single-archive-entry-1-3))))))
 484
 485 (ert-deftest package-x-test-upload-new-version ()
 486   "Test uploading a new version of a package"
 487   (with-package-test (:basedir "data/package"
 488                                :file "simple-single-1.3.el"
 489                                :upload-base t)
 490     (package-upload-buffer)
 491     (with-temp-buffer
 492       (insert-file-contents "newer-versions/simple-single-1.4.el")
 493       (package-upload-buffer))
 494
 495     (let (archive-contents)
 496       (with-temp-buffer
 497         (insert-file-contents
 498          (expand-file-name "archive-contents"
 499                            package-archive-upload-base))
 500         (setq archive-contents
 501               (package-read-from-string
 502                (buffer-substring (point-min) (point-max)))))
 503       (should (equal archive-contents
 504                      (list 1 package-x-test--single-archive-entry-1-4))))))
 505
 506 (ert-deftest package-test-get-deps ()
 507   "Test `package--get-deps' with complex structures."
 508   (let ((package-alist
 509          (mapcar (lambda (p) (list (package-desc-name p) p))
 510            (list simple-single-desc
 511                  simple-depend-desc
 512                  multi-file-desc
 513                  new-pkg-desc
 514                  simple-depend-desc-1
 515                  simple-depend-desc-2))))
 516     (should
 517      (equal (package--get-deps 'simple-depend)
 518             '(simple-single)))
 519     (should
 520      (equal (package--get-deps 'simple-depend 'indirect)
 521             nil))
 522     (should
 523      (equal (package--get-deps 'simple-depend 'direct)
 524             '(simple-single)))
 525     (should
 526      (equal (package--get-deps 'simple-depend-2)
 527             '(simple-depend-1 multi-file simple-depend simple-single)))
 528     (should
 529      (equal (package--get-deps 'simple-depend-2 'indirect)
 530             '(simple-depend multi-file simple-single)))
 531     (should
 532      (equal (package--get-deps 'simple-depend-2 'direct)
 533             '(simple-depend-1 multi-file)))))
 534
 535 (ert-deftest package-test-sort-by-dependence ()
 536   "Test `package--sort-by-dependence' with complex structures."
 537   (let ((package-alist
 538          (mapcar (lambda (p) (list (package-desc-name p) p))
 539            (list simple-single-desc
 540                  simple-depend-desc
 541                  multi-file-desc
 542                  new-pkg-desc
 543                  simple-depend-desc-1
 544                  simple-depend-desc-2)))
 545         (delete-list
 546          (list simple-single-desc
 547                simple-depend-desc
 548                multi-file-desc
 549                new-pkg-desc
 550                simple-depend-desc-1
 551                simple-depend-desc-2)))
 552     (should
 553      (equal (package--sort-by-dependence delete-list)
 554             (list simple-depend-desc-2 simple-depend-desc-1 new-pkg-desc
 555                   multi-file-desc simple-depend-desc simple-single-desc)))
 556     (should
 557      (equal (package--sort-by-dependence (reverse delete-list))
 558             (list new-pkg-desc simple-depend-desc-2 simple-depend-desc-1
 559                   multi-file-desc simple-depend-desc simple-single-desc)))))
 560
 561 (provide 'package-test)
 562
 563 ;;; package-test.el ends here