code.delx.au - gnu-emacs/blob - lisp/progmodes/compile.el

   1 ;;; compile.el --- run compiler as inferior of Emacs, parse error messages
   2
   3 ;; Copyright (C) 1985, 1986, 1987, 1993, 1994, 1995, 1996, 1997, 1998, 1999,
   4 ;;   2001, 2003, 2004, 2005  Free Software Foundation, Inc.
   5
   6 ;; Authors: Roland McGrath <roland@gnu.org>,
   7 ;;          Daniel Pfeiffer <occitan@esperanto.org>
   8 ;; Maintainer: FSF
   9 ;; Keywords: tools, processes
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software; you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation; either version 2, or (at your option)
  16 ;; any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  25 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  26 ;; Boston, MA 02111-1307, USA.
  27
  28 ;;; Commentary:
  29
  30 ;; This package provides the compile facilities documented in the Emacs user's
  31 ;; manual.
  32
  33 ;; This mode uses some complex data-structures:
  34
  35 ;;   LOC (or location) is a list of (COLUMN LINE FILE-STRUCTURE)
  36
  37 ;; COLUMN and LINE are numbers parsed from an error message.  COLUMN and maybe
  38 ;; LINE will be nil for a message that doesn't contain them.  Then the
  39 ;; location refers to a indented beginning of line or beginning of file.
  40 ;; Once any location in some file has been jumped to, the list is extended to
  41 ;; (COLUMN LINE FILE-STRUCTURE MARKER . VISITED) for all LOCs pertaining to
  42 ;; that file.
  43 ;; MARKER initially points to LINE and COLUMN in a buffer visiting that file.
  44 ;; Being a marker it sticks to some text, when the buffer grows or shrinks
  45 ;; before that point.  VISITED is t if we have jumped there, else nil.
  46
  47 ;;   FILE-STRUCTURE is a list of
  48 ;;   ((FILENAME . DIRECTORY) FORMATS (LINE LOC ...) ...)
  49
  50 ;; FILENAME is a string parsed from an error message.  DIRECTORY is a string
  51 ;; obtained by following directory change messages.  DIRECTORY will be nil for
  52 ;; an absolute filename.  FORMATS is a list of formats to apply to FILENAME if
  53 ;; a file of that name can't be found.
  54 ;; The rest of the list is an alist of elements with LINE as key.  The keys
  55 ;; are either nil or line numbers.  If present, nil comes first, followed by
  56 ;; the numbers in decreasing order.  The LOCs for each line are again an alist
  57 ;; ordered the same way.  Note that the whole file structure is referenced in
  58 ;; every LOC.
  59
  60 ;;   MESSAGE is a list of (LOC TYPE END-LOC)
  61
  62 ;; TYPE is 0 for info or 1 for warning if the message matcher identified it as
  63 ;; such, 2 otherwise (for a real error).  END-LOC is a LOC pointing to the
  64 ;; other end, if the parsed message contained a range.  If the end of the
  65 ;; range didn't specify a COLUMN, it defaults to -1, meaning end of line.
  66 ;; These are the value of the `message' text-properties in the compilation
  67 ;; buffer.
  68
  69 ;;; Code:
  70
  71 (eval-when-compile (require 'cl))
  72
  73 (defgroup compilation nil
  74   "Run compiler as inferior of Emacs, parse error messages."
  75   :group 'tools
  76   :group 'processes)
  77
  78
  79 ;;;###autoload
  80 (defcustom compilation-mode-hook nil
  81   "*List of hook functions run by `compilation-mode' (see `run-hooks')."
  82   :type 'hook
  83   :group 'compilation)
  84
  85 ;;;###autoload
  86 (defcustom compilation-window-height nil
  87   "*Number of lines in a compilation window.  If nil, use Emacs default."
  88   :type '(choice (const :tag "Default" nil)
  89                  integer)
  90   :group 'compilation)
  91
  92 (defvar compilation-first-column 1
  93   "*This is how compilers number the first column, usually 1 or 0.")
  94
  95 (defvar compilation-parse-errors-filename-function nil
  96   "Function to call to post-process filenames while parsing error messages.
  97 It takes one arg FILENAME which is the name of a file as found
  98 in the compilation output, and should return a transformed file name.")
  99
 100 ;;;###autoload
 101 (defvar compilation-process-setup-function nil
 102   "*Function to call to customize the compilation process.
 103 This function is called immediately before the compilation process is
 104 started.  It can be used to set any variables or functions that are used
 105 while processing the output of the compilation process.  The function
 106 is called with variables `compilation-buffer' and `compilation-window'
 107 bound to the compilation buffer and window, respectively.")
 108
 109 ;;;###autoload
 110 (defvar compilation-buffer-name-function nil
 111   "Function to compute the name of a compilation buffer.
 112 The function receives one argument, the name of the major mode of the
 113 compilation buffer.  It should return a string.
 114 nil means compute the name with `(concat \"*\" (downcase major-mode) \"*\")'.")
 115
 116 ;;;###autoload
 117 (defvar compilation-finish-function nil
 118   "Function to call when a compilation process finishes.
 119 It is called with two arguments: the compilation buffer, and a string
 120 describing how the process finished.")
 121
 122 ;;;###autoload
 123 (defvar compilation-finish-functions nil
 124   "Functions to call when a compilation process finishes.
 125 Each function is called with two arguments: the compilation buffer,
 126 and a string describing how the process finished.")
 127
 128 (defvar compilation-in-progress nil
 129   "List of compilation processes now running.")
 130 (or (assq 'compilation-in-progress minor-mode-alist)
 131     (setq minor-mode-alist (cons '(compilation-in-progress " Compiling")
 132                                  minor-mode-alist)))
 133
 134 (defvar compilation-error "error"
 135   "Stem of message to print when no matches are found.")
 136
 137 (defvar compilation-arguments nil
 138   "Arguments that were given to `compilation-start'.")
 139
 140 (defvar compilation-num-errors-found)
 141
 142 (defconst compilation-error-regexp-alist-alist
 143   '((absoft
 144      "^\\(?:[Ee]rror on \\|[Ww]arning on\\( \\)\\)?[Ll]ine[ \t]+\\([0-9]+\\)[ \t]+\
 145 of[ \t]+\"?\\([a-zA-Z]?:?[^\":\n]+\\)\"?:" 3 2 nil (1))
 146
 147     (ada
 148      "\\(warning: .*\\)? at \\([^ \n]+\\):\\([0-9]+\\)$" 2 3 nil (1))
 149
 150     (aix
 151      " in line \\([0-9]+\\) of file \\([^ \n]+[^. \n]\\)\\.? " 2 1)
 152
 153     (ant
 154      "^[ \t]*\\[[^] \n]+\\][ \t]*\\([^: \n]+\\):\\([0-9]+\\):\\(?:\\([0-9]+\\):[0-9]+:[0-9]+:\\)?\
 155 \\( warning\\)?" 1 2 3 (4))
 156
 157     (bash
 158      "^\\([^: \n\t]+\\): line \\([0-9]+\\):" 1 2)
 159
 160     (borland
 161      "^\\(?:Error\\|Warnin\\(g\\)\\) \\(?:[FEW][0-9]+ \\)?\
 162 \\([a-zA-Z]?:?[^:( \t\n]+\\)\
 163  \\([0-9]+\\)\\(?:[) \t]\\|:[^0-9\n]\\)" 2 3 nil (1))
 164
 165     (caml
 166      "^ *File \\(\"?\\)\\([^,\" \n\t<>]+\\)\\1, lines? \\([0-9]+\\)-?\\([0-9]+\\)?\\(?:$\\|,\
 167 \\(?: characters? \\([0-9]+\\)-?\\([0-9]+\\)?:\\)?\\([ \n]Warning:\\)?\\)"
 168      2 (3 . 4) (5 . 6) (7))
 169
 170     (comma
 171      "^\"\\([^,\" \n\t]+\\)\", line \\([0-9]+\\)\
 172 \\(?:[(. pos]+\\([0-9]+\\))?\\)?[:.,; (-]\\( warning:\\|[-0-9 ]*(W)\\)?" 1 2 3 (4))
 173
 174     (edg-1
 175      "^\\([^ \n]+\\)(\\([0-9]+\\)): \\(?:error\\|warnin\\(g\\)\\|remar\\(k\\)\\)"
 176      1 2 nil (3 . 4))
 177     (edg-2
 178      "at line \\([0-9]+\\) of \"\\([^ \n]+\\)\"$"
 179      2 1 nil 0)
 180
 181     (epc
 182      "^Error [0-9]+ at (\\([0-9]+\\):\\([^)\n]+\\))" 2 1)
 183
 184     (ftnchek
 185      "\\(^Warning .*\\)? line[ \n]\\([0-9]+\\)[ \n]\\(?:col \\([0-9]+\\)[ \n]\\)?file \\([^ :;\n]+\\)"
 186      4 2 3 (1))
 187
 188     (iar
 189      "^\"\\(.*\\)\",\\([0-9]+\\)\\s-+\\(?:Error\\|Warnin\\(g\\)\\)\\[[0-9]+\\]:"
 190      1 2 nil (3))
 191
 192     (ibm
 193      "^\\([^( \n\t]+\\)(\\([0-9]+\\):\\([0-9]+\\)) :\
 194  \\(?:warnin\\(g\\)\\|informationa\\(l\\)\\)?" 1 2 3 (4 . 5))
 195
 196     ;; fixme: should be `mips'
 197     (irix
 198      "^[-[:alnum:]_/ ]+: \\(?:\\(?:[sS]evere\\|[eE]rror\\|[wW]arnin\\(g\\)\\|[iI]nf\\(o\\)\\)[0-9 ]*: \\)?\
 199 \\([^,\" \n\t]+\\)\\(?:, line\\|:\\) \\([0-9]+\\):" 3 4 nil (1 . 2))
 200
 201     (java
 202      "^\\(?:[ \t]+at \\|==[0-9]+== +\\(?:at\\|b\\(y\\)\\)\\).+(\\([^()\n]+\\):\\([0-9]+\\))$" 2 3 nil (1))
 203
 204     (jikes-file
 205      "^\\(?:Found\\|Issued\\) .* compiling \"\\(.+\\)\":$" 1 nil nil 0)
 206     (jikes-line
 207      "^ *\\([0-9]+\\)\\.[ \t]+.*\n +\\(<-*>\n\\*\\*\\* \\(?:Error\\|Warnin\\(g\\)\\)\\)"
 208      nil 1 nil 2 0
 209      (2 (compilation-face '(3))))
 210
 211     (gcc-include
 212      "^\\(?:In file included\\|                \\) from \
 213 \\(.+\\):\\([0-9]+\\)\\(?:\\(:\\)\\|\\(,\\)\\)?" 1 2 nil (3 . 4))
 214
 215     (gnu
 216      "^\\(?:[[:alpha:]][-[:alnum:].]+: ?\\)?\
 217 \\([/.]*[a-zA-Z]:?[^ \t\n:]*\\|{standard input}\\): ?\
 218 \\([0-9]+\\)\\([.:]?\\)\\([0-9]+\\)?\
 219 \\(?:-\\(?:\\([0-9]+\\)\\3\\)?\\.?\\([0-9]+\\)?\\)?:\
 220 \\(?: *\\(\\(?:Future\\|Runtime\\)?[Ww]arning\\|W:\\)\\|\
 221  *\\([Ii]nfo\\(?:\\>\\|rmationa?l?\\)\\|I:\\)\\)?"
 222      1 (2 . 5) (4 . 6) (7 . 8))
 223
 224     (lcc
 225      "^\\(?:E\\|\\(W\\)\\), \\([^(\n]+\\)(\\([0-9]+\\),[ \t]*\\([0-9]+\\)"
 226      2 3 4 (1))
 227
 228     (makepp
 229      "^makepp: \\(?:\\(?:warning\\(:\\).*?\\|\\(Scanning\\|[LR]e?l?oading makefile\\) \\|.*?\\)\
 230 `\\(\\(\\S +?\\)\\(?::\\([0-9]+\\)\\)?\\)'\\)"
 231      4 5 nil (1 . 2) 3
 232      ("`\\(\\(\\S +?\\)\\(?::\\([0-9]+\\)\\)?\\)'" nil nil
 233       (2 compilation-info-face)
 234       (3 compilation-line-face nil t)
 235       (1 (compilation-error-properties 2 3 nil nil nil 0 nil)
 236          append)))
 237
 238     ;; Should be lint-1, lint-2 (SysV lint)
 239     (mips-1
 240      " (\\([0-9]+\\)) in \\([^ \n]+\\)" 2 1)
 241     (mips-2
 242      " in \\([^()\n ]+\\)(\\([0-9]+\\))$" 1 2)
 243
 244     (msft
 245      "^\\(\\(?:[a-zA-Z]:\\)?[^:(\t\n]+\\)(\\([0-9]+\\)) \
 246 : \\(?:error\\|warnin\\(g\\)\\) C[0-9]+:" 1 2 nil (3))
 247
 248     (oracle
 249      "^\\(?:Semantic error\\|Error\\|PCC-[0-9]+:\\).* line \\([0-9]+\\)\
 250 \\(?:\\(?:,\\| at\\)? column \\([0-9]+\\)\\)?\
 251 \\(?:,\\| in\\| of\\)? file \\(.*?\\):?$"
 252      3 1 2)
 253
 254     (perl
 255      " at \\([^ \n]+\\) line \\([0-9]+\\)\\(?:[,.]\\|$\\)" 1 2)
 256
 257     (rxp
 258      "^\\(?:Error\\|Warnin\\(g\\)\\):.*\n.* line \\([0-9]+\\) char\
 259  \\([0-9]+\\) of file://\\(.+\\)"
 260      4 2 3 (1))
 261
 262     (sparc-pascal-file
 263      "^\\w\\w\\w \\w\\w\\w +[0-3]?[0-9] +[0-2][0-9]:[0-5][0-9]:[0-5][0-9]\
 264  [12][09][0-9][0-9] +\\(.*\\):$"
 265      1 nil nil 0)
 266     (sparc-pascal-line
 267      "^\\(\\(?:E\\|\\(w\\)\\) +[0-9]+\\) line \\([0-9]+\\) -  "
 268      nil 3 nil (2) nil (1 (compilation-face '(2))))
 269     (sparc-pascal-example
 270      "^ +\\([0-9]+\\) +.*\n\\(\\(?:e\\|\\(w\\)\\) [0-9]+\\)-+"
 271      nil 1 nil (3) nil (2 (compilation-face '(3))))
 272
 273     (sun
 274      ": \\(?:ERROR\\|WARNIN\\(G\\)\\|REMAR\\(K\\)\\) \\(?:[[:alnum:] ]+, \\)?\
 275 File = \\(.+\\), Line = \\([0-9]+\\)\\(?:, Column = \\([0-9]+\\)\\)?"
 276      3 4 5 (1 . 2))
 277
 278     (sun-ada
 279      "^\\([^, \n\t]+\\), line \\([0-9]+\\), char \\([0-9]+\\)[:., \(-]" 1 2 3)
 280
 281     (4bsd
 282      "\\(?:^\\|::  \\|\\S ( \\)\\(/[^ \n\t()]+\\)(\\([0-9]+\\))\
 283 \\(?:: \\(warning:\\)?\\|$\\| ),\\)" 1 2 nil (3))
 284
 285     (gcov-file
 286      "^ +-:    \\(0\\):Source:\\(.+\\)$" 2 1 nil 0)
 287     (gcov-bb-file
 288      "^ +-:    \\(0\\):Object:\\(?:.+\\)$" nil 1 nil 0)
 289     (gcov-never-called-line
 290      "^ +\\(#####\\): +\\([0-9]+\\):.+$" nil 2 nil 2 nil
 291      (1 compilation-error-face))
 292     (gcov-called-line
 293      "^ +[-0-9]+: +\\([1-9]\\|[0-9]\\{2,\\}\\):.*$" nil 1 nil 0)
 294 )
 295   "Alist of values for `compilation-error-regexp-alist'.")
 296
 297 (defcustom compilation-error-regexp-alist
 298   (mapcar 'car compilation-error-regexp-alist-alist)
 299   "Alist that specifies how to match errors in compiler output.
 300 Note that on Unix everything is a valid filename, so these
 301 matchers must make some common sense assumptions, which catch
 302 normal cases.  A shorter list will be lighter on resource usage.
 303
 304 Instead of an alist element, you can use a symbol, which is
 305 looked up in `compilation-error-regexp-alist-alist'.  You can see
 306 the predefined symbols and their effects in the file
 307 `etc/compilation.txt' (linked below if you are customizing this).
 308
 309 Each elt has the form (REGEXP FILE [LINE COLUMN TYPE HYPERLINK
 310 HIGHLIGHT...]).  If REGEXP matches, the FILE'th subexpression
 311 gives the file name, and the LINE'th subexpression gives the line
 312 number.  The COLUMN'th subexpression gives the column number on
 313 that line.
 314
 315 If FILE, LINE or COLUMN are nil or that index didn't match, that
 316 information is not present on the matched line.  In that case the
 317 file name is assumed to be the same as the previous one in the
 318 buffer, line number defaults to 1 and column defaults to
 319 beginning of line's indentation.
 320
 321 FILE can also have the form (FILE FORMAT...), where the FORMATs
 322 \(e.g. \"%s.c\") will be applied in turn to the recognized file
 323 name, until a file of that name is found.  Or FILE can also be a
 324 function to return the filename.
 325
 326 LINE can also be of the form (LINE . END-LINE) meaning a range
 327 of lines.  COLUMN can also be of the form (COLUMN . END-COLUMN)
 328 meaning a range of columns starting on LINE and ending on
 329 END-LINE, if that matched.
 330
 331 TYPE is 2 or nil for a real error or 1 for warning or 0 for info.
 332 TYPE can also be of the form (WARNING . INFO).  In that case this
 333 will be equivalent to 1 if the WARNING'th subexpression matched
 334 or else equivalent to 0 if the INFO'th subexpression matched.
 335 See `compilation-error-face', `compilation-warning-face',
 336 `compilation-info-face' and `compilation-skip-threshold'.
 337
 338 What matched the HYPERLINK'th subexpression has `mouse-face' and
 339 `compilation-message-face' applied.  If this is nil, the text
 340 matched by the whole REGEXP becomes the hyperlink.
 341
 342 Additional HIGHLIGHTs as described under `font-lock-keywords' can
 343 be added."
 344   :type `(set :menu-tag "Pick"
 345               ,@(mapcar (lambda (elt)
 346                           (list 'const (car elt)))
 347                         compilation-error-regexp-alist-alist))
 348   :link `(file-link :tag "example file"
 349                     ,(expand-file-name "compilation.txt" data-directory))
 350   :group 'compilation)
 351
 352 (defvar compilation-directory nil
 353   "Directory to restore to when doing `recompile'.")
 354
 355 (defvar compilation-directory-matcher
 356   '("\\(?:Entering\\|Leavin\\(g\\)\\) directory `\\(.+\\)'$" (2 . 1))
 357   "A list for tracking when directories are entered or left.
 358 Nil means not to track directories, e.g. if all file names are absolute.  The
 359 first element is the REGEXP matching these messages.  It can match any number
 360 of variants, e.g. different languages.  The remaining elements are all of the
 361 form (DIR .  LEAVE).  If for any one of these the DIR'th subexpression
 362 matches, that is a directory name.  If LEAVE is nil or the corresponding
 363 LEAVE'th subexpression doesn't match, this message is about going into another
 364 directory.  If it does match anything, this message is about going back to the
 365 directory we were in before the last entering message.  If you change this,
 366 you may also want to change `compilation-page-delimiter'.")
 367
 368 (defvar compilation-page-delimiter
 369   "^\\(?:\f\\|.*\\(?:Entering\\|Leaving\\) directory `.+'\n\\)+"
 370   "Value of `page-delimiter' in Compilation mode.")
 371
 372 (defvar compilation-mode-font-lock-keywords
 373    '(;; configure output lines.
 374      ("^[Cc]hecking \\(?:[Ff]or \\|[Ii]f \\|[Ww]hether \\(?:to \\)?\\)?\\(.+\\)\\.\\.\\. *\\(?:(cached) *\\)?\\(\\(yes\\(?: .+\\)?\\)\\|no\\|\\(.*\\)\\)$"
 375       (1 font-lock-variable-name-face)
 376       (2 (compilation-face '(4 . 3))))
 377      ;; Command output lines.  Recognize `make[n]:' lines too.
 378      ("^\\([[:alnum:]_/.+-]+\\)\\(\\[\\([0-9]+\\)\\]\\)?[ \t]*:"
 379       (1 font-lock-function-name-face) (3 compilation-line-face nil t))
 380      (" --?o\\(?:utfile\\|utput\\)?[= ]?\\(\\S +\\)" . 1)
 381      ("^Compilation finished" . compilation-info-face)
 382      ("^Compilation exited abnormally" . compilation-error-face))
 383    "Additional things to highlight in Compilation mode.
 384 This gets tacked on the end of the generated expressions.")
 385
 386 (defvar compilation-highlight-regexp t
 387   "Regexp matching part of visited source lines to highlight temporarily.
 388 Highlight entire line if t; don't highlight source lines if nil.")
 389
 390 (defvar compilation-highlight-overlay nil
 391   "Overlay used to temporarily highlight compilation matches.")
 392
 393 (defcustom compilation-error-screen-columns t
 394   "*If non-nil, column numbers in error messages are screen columns.
 395 Otherwise they are interpreted as character positions, with
 396 each character occupying one column.
 397 The default is to use screen columns, which requires that the compilation
 398 program and Emacs agree about the display width of the characters,
 399 especially the TAB character."
 400   :type 'boolean
 401   :group 'compilation
 402   :version "20.4")
 403
 404 (defcustom compilation-read-command t
 405   "*Non-nil means \\[compile] reads the compilation command to use.
 406 Otherwise, \\[compile] just uses the value of `compile-command'."
 407   :type 'boolean
 408   :group 'compilation)
 409
 410 ;;;###autoload
 411 (defcustom compilation-ask-about-save t
 412   "*Non-nil means \\[compile] asks which buffers to save before compiling.
 413 Otherwise, it saves all modified buffers without asking."
 414   :type 'boolean
 415   :group 'compilation)
 416
 417 ;;;###autoload
 418 (defcustom compilation-search-path '(nil)
 419   "*List of directories to search for source files named in error messages.
 420 Elements should be directory names, not file names of directories.
 421 nil as an element means to try the default directory."
 422   :type '(repeat (choice (const :tag "Default" nil)
 423                          (string :tag "Directory")))
 424   :group 'compilation)
 425
 426 (defcustom compile-command "make -k "
 427   "*Last shell command used to do a compilation; default for next compilation.
 428
 429 Sometimes it is useful for files to supply local values for this variable.
 430 You might also use mode hooks to specify it in certain modes, like this:
 431
 432     (add-hook 'c-mode-hook
 433        (lambda ()
 434          (unless (or (file-exists-p \"makefile\")
 435                      (file-exists-p \"Makefile\"))
 436            (set (make-local-variable 'compile-command)
 437                 (concat \"make -k \"
 438                         (file-name-sans-extension buffer-file-name))))))"
 439   :type 'string
 440   :group 'compilation)
 441
 442 ;; A weak per-compilation-buffer hash indexed by (FILENAME . DIRECTORY).  Each
 443 ;; value is a FILE-STRUCTURE as described above, with the car eq to the hash
 444 ;; key.  This holds the tree seen from root, for storing new nodes.
 445 (defvar compilation-locs ())
 446
 447 (defvar compilation-debug nil
 448   "*Set this to t before creating a *compilation* buffer.
 449 Then every error line will have a debug text property with the matcher that
 450 fit this line and the match data.  Use `describe-text-properties'.")
 451
 452 (defvar compilation-exit-message-function nil "\
 453 If non-nil, called when a compilation process dies to return a status message.
 454 This should be a function of three arguments: process status, exit status,
 455 and exit message; it returns a cons (MESSAGE . MODELINE) of the strings to
 456 write into the compilation buffer, and to put in its mode line.")
 457
 458 (defvar compilation-environment nil
 459   "*List of environment variables for compilation to inherit.
 460 Each element should be a string of the form ENVVARNAME=VALUE.
 461 This list is temporarily prepended to `process-environment' prior to
 462 starting the compilation process.")
 463
 464 ;; History of compile commands.
 465 (defvar compile-history nil)
 466
 467 (defface compilation-warning-face
 468   '((((class color) (min-colors 16)) (:foreground "Orange" :weight bold))
 469     (((class color)) (:foreground "cyan" :weight bold))
 470     (t (:weight bold)))
 471   "Face used to highlight compiler warnings."
 472   :group 'font-lock-highlighting-faces
 473   :version "22.1")
 474
 475 (defface compilation-info-face
 476   '((((class color) (min-colors 16) (background light))
 477      (:foreground "Green3" :weight bold))
 478     (((class color) (min-colors 88) (background dark))
 479      (:foreground "Green1" :weight bold))
 480     (((class color) (min-colors 16) (background dark))
 481      (:foreground "Green" :weight bold))
 482     (((class color)) (:foreground "green" :weight bold))
 483     (t (:weight bold)))
 484   "Face used to highlight compiler warnings."
 485   :group 'font-lock-highlighting-faces
 486   :version "22.1")
 487
 488 (defvar compilation-message-face nil
 489   "Face name to use for whole messages.
 490 Faces `compilation-error-face', `compilation-warning-face',
 491 `compilation-info-face', `compilation-line-face' and
 492 `compilation-column-face' get prepended to this, when applicable.")
 493
 494 (defvar compilation-error-face 'font-lock-warning-face
 495   "Face name to use for file name in error messages.")
 496
 497 (defvar compilation-warning-face 'compilation-warning-face
 498   "Face name to use for file name in warning messages.")
 499
 500 (defvar compilation-info-face 'compilation-info-face
 501   "Face name to use for file name in informational messages.")
 502
 503 (defvar compilation-line-face 'font-lock-variable-name-face
 504   "Face name to use for line number in message.")
 505
 506 (defvar compilation-column-face 'font-lock-type-face
 507   "Face name to use for column number in message.")
 508
 509 ;; same faces as dired uses
 510 (defvar compilation-enter-directory-face 'font-lock-function-name-face
 511   "Face name to use for column number in message.")
 512
 513 (defvar compilation-leave-directory-face 'font-lock-type-face
 514   "Face name to use for column number in message.")
 515
 516
 517
 518 ;; Used for compatibility with the old compile.el.
 519 (defvaralias 'compilation-last-buffer 'next-error-last-buffer)
 520 (defvar compilation-parsing-end (make-marker))
 521 (defvar compilation-parse-errors-function nil)
 522 (defvar compilation-error-list nil)
 523 (defvar compilation-old-error-list nil)
 524
 525 (defun compilation-face (type)
 526   (or (and (car type) (match-end (car type)) compilation-warning-face)
 527       (and (cdr type) (match-end (cdr type)) compilation-info-face)
 528       compilation-error-face))
 529
 530 ;; Internal function for calculating the text properties of a directory
 531 ;; change message.  The directory property is important, because it is
 532 ;; the stack of nested enter-messages.  Relative filenames on the following
 533 ;; lines are relative to the top of the stack.
 534 (defun compilation-directory-properties (idx leave)
 535   (if leave (setq leave (match-end leave)))
 536   ;; find previous stack, and push onto it, or if `leave' pop it
 537   (let ((dir (previous-single-property-change (point) 'directory)))
 538     (setq dir (if dir (or (get-text-property (1- dir) 'directory)
 539                           (get-text-property dir 'directory))))
 540     `(face ,(if leave
 541                 compilation-leave-directory-face
 542               compilation-enter-directory-face)
 543       directory ,(if leave
 544                      (or (cdr dir)
 545                          '(nil))        ; nil only isn't a property-change
 546                    (cons (match-string-no-properties idx) dir))
 547       mouse-face highlight
 548       keymap compilation-button-map
 549       help-echo "mouse-2: visit current directory")))
 550
 551 ;; Data type `reverse-ordered-alist' retriever.  This function retrieves the
 552 ;; KEY element from the ALIST, creating it in the right position if not already
 553 ;; present. ALIST structure is
 554 ;; '(ANCHOR (KEY1 ...) (KEY2 ...)... (KEYn ALIST ...))
 555 ;; ANCHOR is ignored, but necessary so that elements can be inserted.  KEY1
 556 ;; may be nil.  The other KEYs are ordered backwards so that growing line
 557 ;; numbers can be inserted in front and searching can abort after half the
 558 ;; list on average.
 559 (eval-when-compile                  ;Don't keep it at runtime if not needed.
 560 (defmacro compilation-assq (key alist)
 561   `(let* ((l1 ,alist)
 562           (l2 (cdr l1)))
 563      (car (if (if (null ,key)
 564                   (if l2 (null (caar l2)))
 565                 (while (if l2 (if (caar l2) (< ,key (caar l2)) t))
 566                   (setq l1 l2
 567                         l2 (cdr l1)))
 568                 (if l2 (eq ,key (caar l2))))
 569               l2
 570             (setcdr l1 (cons (list ,key) l2)))))))
 571
 572
 573 ;; This function is the central driver, called when font-locking to gather
 574 ;; all information needed to later jump to corresponding source code.
 575 ;; Return a property list with all meta information on this error location.
 576 (defun compilation-error-properties (file line end-line col end-col type fmt)
 577   (unless (< (next-single-property-change (match-beginning 0) 'directory nil (point))
 578              (point))
 579     (if file
 580         (if (functionp file)
 581             (setq file (funcall file))
 582           (let (dir)
 583             (setq file (match-string-no-properties file))
 584             (unless (file-name-absolute-p file)
 585               (setq dir (previous-single-property-change (point) 'directory)
 586                     dir (if dir (or (get-text-property (1- dir) 'directory)
 587                                     (get-text-property dir 'directory)))))
 588             (setq file (cons file (car dir)))))
 589       ;; This message didn't mention one, get it from previous
 590       (setq file (previous-single-property-change (point) 'message)
 591             file (or (if file
 592                          (car (nth 2 (car (or (get-text-property (1- file) 'message)
 593                                          (get-text-property file 'message))))))
 594                      '("*unknown*"))))
 595     ;; All of these fields are optional, get them only if we have an index, and
 596     ;; it matched some part of the message.
 597     (and line
 598          (setq line (match-string-no-properties line))
 599          (setq line (string-to-number line)))
 600     (and end-line
 601          (setq end-line (match-string-no-properties end-line))
 602          (setq end-line (string-to-number end-line)))
 603     (if col
 604         (if (functionp col)
 605             (setq col (funcall col))
 606           (and
 607            (setq col (match-string-no-properties col))
 608            (setq col (- (string-to-number col) compilation-first-column)))))
 609     (if (and end-col (functionp end-col))
 610         (setq end-col (funcall end-col))
 611       (if (and end-col (setq end-col (match-string-no-properties end-col)))
 612           (setq end-col (- (string-to-number end-col) compilation-first-column -1))
 613         (if end-line (setq end-col -1))))
 614     (if (consp type)                    ; not a static type, check what it is.
 615         (setq type (or (and (car type) (match-end (car type)) 1)
 616                        (and (cdr type) (match-end (cdr type)) 0)
 617                        2)))
 618     (compilation-internal-error-properties file line end-line col end-col type fmt)))
 619
 620 (defun compilation-move-to-column (col screen)
 621   "Go to column COL on the current line.
 622 If SCREEN is non-nil, columns are screen columns, otherwise, they are
 623 just char-counts."
 624   (if screen
 625       (move-to-column col)
 626     (goto-char (min (+ (line-beginning-position) col) (line-end-position)))))
 627
 628 (defun compilation-internal-error-properties (file line end-line col end-col type fmt)
 629   "Get the meta-info that will be added as text-properties.
 630 LINE, END-LINE, COL, END-COL are integers or nil.
 631 TYPE can be 0, 1, or 2.
 632 FILE should be (ABSOLUTE-FILENAME) or (RELATIVE-FILENAME . DIRNAME) or nil."
 633   (unless file (setq file '("*unknown*")))
 634   (setq file (compilation-get-file-structure file fmt))
 635   ;; Get first already existing marker (if any has one, all have one).
 636   ;; Do this first, as the compilation-assq`s may create new nodes.
 637   (let* ((marker-line (car (cddr file)))        ; a line structure
 638          (marker (nth 3 (cadr marker-line)))    ; its marker
 639          (compilation-error-screen-columns compilation-error-screen-columns)
 640          end-marker loc end-loc)
 641     (if (not (and marker (marker-buffer marker)))
 642         (setq marker)                   ; no valid marker for this file
 643       (setq loc (or line 1))            ; normalize no linenumber to line 1
 644       (catch 'marker                    ; find nearest loc, at least one exists
 645         (dolist (x (nthcdr 3 file))     ; loop over remaining lines
 646           (if (> (car x) loc)           ; still bigger
 647               (setq marker-line x)
 648             (if (> (- (or (car marker-line) 1) loc)
 649                    (- loc (car x)))     ; current line is nearer
 650                 (setq marker-line x))
 651             (throw 'marker t))))
 652       (setq marker (nth 3 (cadr marker-line))
 653             marker-line (or (car marker-line) 1))
 654       (with-current-buffer (marker-buffer marker)
 655         (save-restriction
 656           (widen)
 657           (goto-char (marker-position marker))
 658           (when (or end-col end-line)
 659             (beginning-of-line (- (or end-line line) marker-line -1))
 660             (if (or (null end-col) (< end-col 0))
 661                 (end-of-line)
 662               (compilation-move-to-column
 663                end-col compilation-error-screen-columns))
 664             (setq end-marker (list (point-marker))))
 665           (beginning-of-line (if end-line
 666                                  (- line end-line -1)
 667                                (- loc marker-line -1)))
 668           (if col
 669               (compilation-move-to-column
 670                col compilation-error-screen-columns)
 671             (forward-to-indentation 0))
 672           (setq marker (list (point-marker))))))
 673
 674     (setq loc (compilation-assq line (cdr file)))
 675     (if end-line
 676         (setq end-loc (compilation-assq end-line (cdr file))
 677               end-loc (compilation-assq end-col end-loc))
 678       (if end-col                       ; use same line element
 679           (setq end-loc (compilation-assq end-col loc))))
 680     (setq loc (compilation-assq col loc))
 681     ;; If they are new, make the loc(s) reference the file they point to.
 682     (or (cdr loc) (setcdr loc `(,line ,file ,@marker)))
 683     (if end-loc
 684         (or (cdr end-loc) (setcdr end-loc `(,(or end-line line) ,file ,@end-marker))))
 685
 686     ;; Must start with face
 687     `(face ,compilation-message-face
 688            message (,loc ,type ,end-loc)
 689            ,@(if compilation-debug
 690                  `(debug (,(assoc (with-no-warnings matcher) font-lock-keywords)
 691                           ,@(match-data))))
 692            help-echo ,(if col
 693                           "mouse-2: visit this file, line and column"
 694                         (if line
 695                             "mouse-2: visit this file and line"
 696                           "mouse-2: visit this file"))
 697            keymap compilation-button-map
 698            mouse-face highlight)))
 699
 700 (defun compilation-mode-font-lock-keywords ()
 701   "Return expressions to highlight in Compilation mode."
 702   (if compilation-parse-errors-function
 703       ;; An old package!  Try the compatibility code.
 704       '((compilation-compat-parse-errors))
 705     (append
 706      ;; make directory tracking
 707      (if compilation-directory-matcher
 708          `((,(car compilation-directory-matcher)
 709             ,@(mapcar (lambda (elt)
 710                         `(,(car elt)
 711                           (compilation-directory-properties
 712                            ,(car elt) ,(cdr elt))
 713                           t t))
 714                       (cdr compilation-directory-matcher)))))
 715
 716      ;; Compiler warning/error lines.
 717      (mapcar
 718       (lambda (item)
 719         (if (symbolp item)
 720             (setq item (cdr (assq item
 721                                   compilation-error-regexp-alist-alist))))
 722         (let ((file (nth 1 item))
 723               (line (nth 2 item))
 724               (col (nth 3 item))
 725               (type (nth 4 item))
 726               end-line end-col fmt)
 727           (if (consp file)      (setq fmt (cdr file)      file (car file)))
 728           (if (consp line)      (setq end-line (cdr line) line (car line)))
 729           (if (consp col)       (setq end-col (cdr col)   col (car col)))
 730
 731           (if (functionp line)
 732               ;; The old compile.el had here an undocumented hook that
 733               ;; allowed `line' to be a function that computed the actual
 734               ;; error location.  Let's do our best.
 735               `(,(car item)
 736                 (0 (save-match-data
 737                      (compilation-compat-error-properties
 738                       (funcall ',line (cons (match-string ,file)
 739                                             (cons default-directory
 740                                                   ',(nthcdr 4 item)))
 741                                ,(if col `(match-string ,col))))))
 742                 (,file compilation-error-face t))
 743
 744             (unless (or (null (nth 5 item)) (integerp (nth 5 item)))
 745               (error "HYPERLINK should be an integer: %s" (nth 5 item)))
 746
 747             `(,(nth 0 item)
 748
 749               ,@(when (integerp file)
 750                   `((,file ,(if (consp type)
 751                                 `(compilation-face ',type)
 752                               (aref [compilation-info-face
 753                                      compilation-warning-face
 754                                      compilation-error-face]
 755                                     (or type 2))))))
 756
 757               ,@(when line
 758                   `((,line compilation-line-face nil t)))
 759               ,@(when end-line
 760                   `((,end-line compilation-line-face nil t)))
 761
 762               ,@(when (integerp col)
 763                   `((,col compilation-column-face nil t)))
 764               ,@(when (integerp end-col)
 765                   `((,end-col compilation-column-face nil t)))
 766
 767               ,@(nthcdr 6 item)
 768               (,(or (nth 5 item) 0)
 769                (compilation-error-properties ',file ,line ,end-line
 770                                              ,col ,end-col ',(or type 2)
 771                                              ',fmt)
 772                append)))))              ; for compilation-message-face
 773       compilation-error-regexp-alist)
 774
 775      compilation-mode-font-lock-keywords)))
 776
 777 \f
 778 ;;;###autoload
 779 (defun compile (command &optional comint)
 780   "Compile the program including the current buffer.  Default: run `make'.
 781 Runs COMMAND, a shell command, in a separate process asynchronously
 782 with output going to the buffer `*compilation*'.
 783
 784 If optional second arg COMINT is t the buffer will be in Comint mode with
 785 `compilation-shell-minor-mode'.
 786
 787 You can then use the command \\[next-error] to find the next error message
 788 and move to the source code that caused it.
 789
 790 Interactively, prompts for the command if `compilation-read-command' is
 791 non-nil; otherwise uses `compile-command'.  With prefix arg, always prompts.
 792 Additionally, with universal prefix arg, compilation buffer will be in
 793 comint mode, i.e. interactive.
 794
 795 To run more than one compilation at once, start one and rename
 796 the \`*compilation*' buffer to some other name with
 797 \\[rename-buffer].  Then start the next one.  On most systems,
 798 termination of the main compilation process kills its
 799 subprocesses.
 800
 801 The name used for the buffer is actually whatever is returned by
 802 the function in `compilation-buffer-name-function', so you can set that
 803 to a function that generates a unique name."
 804   (interactive
 805    (list
 806     (let ((command (eval compile-command)))
 807       (if (or compilation-read-command current-prefix-arg)
 808           (read-from-minibuffer "Compile command: "
 809                                 command nil nil
 810                                 (if (equal (car compile-history) command)
 811                                     '(compile-history . 1)
 812                                   'compile-history))
 813         command))
 814     (consp current-prefix-arg)))
 815   (unless (equal command (eval compile-command))
 816     (setq compile-command command))
 817   (save-some-buffers (not compilation-ask-about-save) nil)
 818   (setq compilation-directory default-directory)
 819   (compilation-start command comint))
 820
 821 ;; run compile with the default command line
 822 (defun recompile ()
 823   "Re-compile the program including the current buffer.
 824 If this is run in a Compilation mode buffer, re-use the arguments from the
 825 original use.  Otherwise, recompile using `compile-command'."
 826   (interactive)
 827   (save-some-buffers (not compilation-ask-about-save) nil)
 828   (let ((default-directory
 829           (or (and (not (eq major-mode (nth 1 compilation-arguments)))
 830                    compilation-directory)
 831               default-directory)))
 832     (apply 'compilation-start (or compilation-arguments
 833                                   `(,(eval compile-command))))))
 834
 835 (defcustom compilation-scroll-output nil
 836   "*Non-nil to scroll the *compilation* buffer window as output appears.
 837
 838 Setting it causes the Compilation mode commands to put point at the
 839 end of their output window so that the end of the output is always
 840 visible rather than the beginning."
 841   :type 'boolean
 842   :version "20.3"
 843   :group 'compilation)
 844
 845
 846 (defun compilation-buffer-name (mode-name name-function)
 847   "Return the name of a compilation buffer to use.
 848 If NAME-FUNCTION is non-nil, call it with one argument MODE-NAME
 849 to determine the buffer name.
 850 Likewise if `compilation-buffer-name-function' is non-nil.
 851 If current buffer is in Compilation mode for the same mode name
 852 return the name of the current buffer, so that it gets reused.
 853 Otherwise, construct a buffer name from MODE-NAME."
 854   (cond (name-function
 855          (funcall name-function mode-name))
 856         (compilation-buffer-name-function
 857          (funcall compilation-buffer-name-function mode-name))
 858         ((eq major-mode (nth 1 compilation-arguments))
 859          (buffer-name))
 860         (t
 861          (concat "*" (downcase mode-name) "*"))))
 862
 863 ;; This is a rough emulation of the old hack, until the transition to new
 864 ;; compile is complete.
 865 (defun compile-internal (command error-message
 866                                  &optional name-of-mode parser
 867                                  error-regexp-alist name-function
 868                                  enter-regexp-alist leave-regexp-alist
 869                                  file-regexp-alist nomessage-regexp-alist
 870                                  no-async highlight-regexp local-map)
 871   (if parser
 872       (error "Compile now works very differently, see `compilation-error-regexp-alist'"))
 873   (let ((compilation-error-regexp-alist
 874          (append file-regexp-alist (or error-regexp-alist
 875                                        compilation-error-regexp-alist)))
 876         (compilation-error (replace-regexp-in-string "^No more \\(.+\\)s\\.?"
 877                                                      "\\1" error-message)))
 878     (compilation-start command nil name-function highlight-regexp)))
 879 (make-obsolete 'compile-internal 'compilation-start)
 880
 881 (defun compilation-start (command &optional mode name-function highlight-regexp)
 882   "Run compilation command COMMAND (low level interface).
 883 If COMMAND starts with a cd command, that becomes the `default-directory'.
 884 The rest of the arguments are optional; for them, nil means use the default.
 885
 886 MODE is the major mode to set in the compilation buffer.  Mode
 887 may also be t meaning use `compilation-shell-minor-mode' under `comint-mode'.
 888 NAME-FUNCTION is a function called to name the buffer.
 889
 890 If HIGHLIGHT-REGEXP is non-nil, `next-error' will temporarily highlight
 891 the matching section of the visited source line; the default is to use the
 892 global value of `compilation-highlight-regexp'.
 893
 894 Returns the compilation buffer created."
 895   (or mode (setq mode 'compilation-mode))
 896   (let* ((name-of-mode
 897           (if (eq mode t)
 898               (prog1 "compilation" (require 'comint))
 899             (replace-regexp-in-string "-mode$" "" (symbol-name mode))))
 900          (thisdir default-directory)
 901          outwin outbuf)
 902     (with-current-buffer
 903         (setq outbuf
 904               (get-buffer-create
 905                (compilation-buffer-name name-of-mode name-function)))
 906       (let ((comp-proc (get-buffer-process (current-buffer))))
 907         (if comp-proc
 908             (if (or (not (eq (process-status comp-proc) 'run))
 909                     (yes-or-no-p
 910                      (format "A %s process is running; kill it? "
 911                              name-of-mode)))
 912                 (condition-case ()
 913                     (progn
 914                       (interrupt-process comp-proc)
 915                       (sit-for 1)
 916                       (delete-process comp-proc))
 917                   (error nil))
 918               (error "Cannot have two processes in `%s' at once"
 919                      (buffer-name)))))
 920       (buffer-disable-undo (current-buffer))
 921       ;; first transfer directory from where M-x compile was called
 922       (setq default-directory thisdir)
 923       ;; Make compilation buffer read-only.  The filter can still write it.
 924       ;; Clear out the compilation buffer.
 925       (let ((inhibit-read-only t)
 926             (default-directory thisdir))
 927         ;; Then evaluate a cd command if any, but don't perform it yet, else start-command
 928         ;; would do it again through the shell: (cd "..") AND sh -c "cd ..; make"
 929         (cd (if (string-match "^\\s *cd\\(?:\\s +\\(\\S +?\\)\\)?\\s *[;&\n]" command)
 930                 (if (match-end 1)
 931                     (substitute-env-vars (match-string 1 command))
 932                   "~")
 933               default-directory))
 934         (erase-buffer)
 935         ;; output a mode setter, for saving and later reloading this buffer
 936         (insert "-*- mode: " name-of-mode
 937                 "; default-directory: " (prin1-to-string default-directory)
 938                 " -*-\n" command "\n")
 939         (setq thisdir default-directory))
 940       (set-buffer-modified-p nil))
 941     ;; If we're already in the compilation buffer, go to the end
 942     ;; of the buffer, so point will track the compilation output.
 943     (if (eq outbuf (current-buffer))
 944         (goto-char (point-max)))
 945     ;; Pop up the compilation buffer.
 946     (setq outwin (display-buffer outbuf nil t))
 947     (with-current-buffer outbuf
 948       (let ((process-environment
 949              (append
 950               compilation-environment
 951               (if (if (boundp 'system-uses-terminfo) ; `if' for compiler warning
 952                       system-uses-terminfo)
 953                   (list "TERM=dumb" "TERMCAP="
 954                         (format "COLUMNS=%d" (window-width)))
 955                 (list "TERM=emacs"
 956                       (format "TERMCAP=emacs:co#%d:tc=unknown:"
 957                               (window-width))))
 958               ;; Set the EMACS variable, but
 959               ;; don't override users' setting of $EMACS.
 960               (unless (getenv "EMACS") '("EMACS=t"))
 961               (copy-sequence process-environment))))
 962         (if (not (eq mode t))
 963             (funcall mode)
 964           (setq buffer-read-only nil)
 965           (with-no-warnings (comint-mode))
 966           (compilation-shell-minor-mode))
 967         (if highlight-regexp
 968             (set (make-local-variable 'compilation-highlight-regexp)
 969                  highlight-regexp))
 970         (set (make-local-variable 'compilation-arguments)
 971              (list command mode name-function highlight-regexp))
 972         (set (make-local-variable 'revert-buffer-function)
 973              'compilation-revert-buffer)
 974         (set-window-start outwin (point-min))
 975         (or (eq outwin (selected-window))
 976             (set-window-point outwin (if compilation-scroll-output
 977                                          (point)
 978                                        (point-min))))
 979         ;; The setup function is called before compilation-set-window-height
 980         ;; so it can set the compilation-window-height buffer locally.
 981         (if compilation-process-setup-function
 982             (funcall compilation-process-setup-function))
 983         (compilation-set-window-height outwin)
 984         ;; Start the compilation.
 985         (if (fboundp 'start-process)
 986             (let ((proc (if (eq mode t)
 987                             (get-buffer-process
 988                              (with-no-warnings
 989                               (comint-exec outbuf (downcase mode-name)
 990                                            shell-file-name nil `("-c" ,command))))
 991                           (start-process-shell-command (downcase mode-name)
 992                                                        outbuf command))))
 993               ;; Make the buffer's mode line show process state.
 994               (setq mode-line-process '(":%s"))
 995               (set-process-sentinel proc 'compilation-sentinel)
 996               (set-process-filter proc 'compilation-filter)
 997               (set-marker (process-mark proc) (point) outbuf)
 998               (setq compilation-in-progress
 999                     (cons proc compilation-in-progress)))
1000           ;; No asynchronous processes available.
1001           (message "Executing `%s'..." command)
1002           ;; Fake modeline display as if `start-process' were run.
1003           (setq mode-line-process ":run")
1004           (force-mode-line-update)
1005           (sit-for 0)                   ; Force redisplay
1006           (let* ((buffer-read-only nil) ; call-process needs to modify outbuf
1007                  (status (call-process shell-file-name nil outbuf nil "-c"
1008                                        command)))
1009             (cond ((numberp status)
1010                    (compilation-handle-exit 'exit status
1011                                             (if (zerop status)
1012                                                 "finished\n"
1013                                               (format "\
1014 exited abnormally with code %d\n"
1015                                                       status))))
1016                   ((stringp status)
1017                    (compilation-handle-exit 'signal status
1018                                             (concat status "\n")))
1019                   (t
1020                    (compilation-handle-exit 'bizarre status status))))
1021           ;; Without async subprocesses, the buffer is not yet
1022           ;; fontified, so fontify it now.
1023           (let ((font-lock-verbose nil)) ; shut up font-lock messages
1024             (font-lock-fontify-buffer))
1025           (set-buffer-modified-p nil)
1026           (message "Executing `%s'...done" command)))
1027       ;; Now finally cd to where the shell started make/grep/...
1028       (setq default-directory thisdir))
1029     (if (buffer-local-value 'compilation-scroll-output outbuf)
1030         (save-selected-window
1031           (select-window outwin)
1032           (goto-char (point-max))))
1033     ;; Make it so the next C-x ` will use this buffer.
1034     (setq next-error-last-buffer outbuf)))
1035
1036 (defun compilation-set-window-height (window)
1037   "Set the height of WINDOW according to `compilation-window-height'."
1038   (let ((height (buffer-local-value 'compilation-window-height (window-buffer window))))
1039     (and height
1040          (= (window-width window) (frame-width (window-frame window)))
1041          ;; If window is alone in its frame, aside from a minibuffer,
1042          ;; don't change its height.
1043          (not (eq window (frame-root-window (window-frame window))))
1044          ;; Stef said that doing the saves in this order is safer:
1045          (save-excursion
1046            (save-selected-window
1047              (select-window window)
1048              (enlarge-window (- height (window-height))))))))
1049
1050 (defvar compilation-menu-map
1051   (let ((map (make-sparse-keymap "Errors")))
1052     (define-key map [stop-subjob]
1053       '("Stop Compilation" . kill-compilation))
1054     (define-key map [compilation-mode-separator2]
1055       '("----" . nil))
1056     (define-key map [compilation-first-error]
1057       '("First Error" . first-error))
1058     (define-key map [compilation-previous-error]
1059       '("Previous Error" . previous-error))
1060     (define-key map [compilation-next-error]
1061       '("Next Error" . next-error))
1062     map))
1063
1064 (defvar compilation-minor-mode-map
1065   (let ((map (make-sparse-keymap)))
1066     (define-key map [mouse-2] 'compile-goto-error)
1067     (define-key map [follow-link] 'mouse-face)
1068     (define-key map "\C-c\C-c" 'compile-goto-error)
1069     (define-key map "\C-m" 'compile-goto-error)
1070     (define-key map "\C-c\C-k" 'kill-compilation)
1071     (define-key map "\M-n" 'compilation-next-error)
1072     (define-key map "\M-p" 'compilation-previous-error)
1073     (define-key map "\M-{" 'compilation-previous-file)
1074     (define-key map "\M-}" 'compilation-next-file)
1075     ;; Set up the menu-bar
1076     (define-key map [menu-bar compilation]
1077       (cons "Errors" compilation-menu-map))
1078     map)
1079   "Keymap for `compilation-minor-mode'.")
1080
1081 (defvar compilation-shell-minor-mode-map
1082   (let ((map (make-sparse-keymap)))
1083     (define-key map "\M-\C-m" 'compile-goto-error)
1084     (define-key map "\M-\C-n" 'compilation-next-error)
1085     (define-key map "\M-\C-p" 'compilation-previous-error)
1086     (define-key map "\M-{" 'compilation-previous-file)
1087     (define-key map "\M-}" 'compilation-next-file)
1088     ;; Set up the menu-bar
1089     (define-key map [menu-bar compilation]
1090       (cons "Errors" compilation-menu-map))
1091     map)
1092   "Keymap for `compilation-shell-minor-mode'.")
1093
1094 (defvar compilation-button-map
1095   (let ((map (make-sparse-keymap)))
1096     (define-key map [mouse-2] 'compile-goto-error)
1097     (define-key map [follow-link] 'mouse-face)
1098     (define-key map "\C-m" 'compile-goto-error)
1099     map)
1100   "Keymap for compilation-message buttons.")
1101 (fset 'compilation-button-map compilation-button-map)
1102
1103 (defvar compilation-mode-map
1104   (let ((map (make-sparse-keymap)))
1105     ;; Don't inherit from compilation-minor-mode-map,
1106     ;; because that introduces a menu bar item we don't want.
1107     ;; That confuses C-down-mouse-3.
1108     (define-key map [mouse-2] 'compile-goto-error)
1109     (define-key map [follow-link] 'mouse-face)
1110     (define-key map "\C-c\C-c" 'compile-goto-error)
1111     (define-key map "\C-m" 'compile-goto-error)
1112     (define-key map "\C-c\C-k" 'kill-compilation)
1113     (define-key map "\M-n" 'compilation-next-error)
1114     (define-key map "\M-p" 'compilation-previous-error)
1115     (define-key map "\M-{" 'compilation-previous-file)
1116     (define-key map "\M-}" 'compilation-next-file)
1117
1118     (define-key map " " 'scroll-up)
1119     (define-key map "\^?" 'scroll-down)
1120     (define-key map "\C-c\C-f" 'next-error-follow-minor-mode)
1121
1122     ;; Set up the menu-bar
1123     (let ((submap (make-sparse-keymap "Compile")))
1124       (define-key map [menu-bar compilation]
1125         (cons "Compile" submap))
1126       (set-keymap-parent submap compilation-menu-map))
1127     (define-key map [menu-bar compilation compilation-separator2]
1128       '("----" . nil))
1129     (define-key map [menu-bar compilation compilation-grep]
1130       '("Search Files (grep)" . grep))
1131     (define-key map [menu-bar compilation compilation-recompile]
1132       '("Recompile" . recompile))
1133     (define-key map [menu-bar compilation compilation-compile]
1134       '("Compile..." . compile))
1135     map)
1136   "Keymap for compilation log buffers.
1137 `compilation-minor-mode-map' is a parent of this.")
1138
1139 (put 'compilation-mode 'mode-class 'special)
1140
1141 (defvar compilation-skip-to-next-location t
1142   "*If non-nil, skip multiple error messages for the same source location.")
1143
1144 (defcustom compilation-skip-threshold 1
1145   "*Compilation motion commands skip less important messages.
1146 The value can be either 2 -- skip anything less than error, 1 --
1147 skip anything less than warning or 0 -- don't skip any messages.
1148 Note that all messages not positively identified as warning or
1149 info, are considered errors."
1150   :type '(choice (const :tag "Warnings and info" 2)
1151                  (const :tag "Info" 1)
1152                  (const :tag "None" 0))
1153   :group 'compilation
1154   :version "22.1")
1155
1156 (defcustom compilation-skip-visited nil
1157   "*Compilation motion commands skip visited messages if this is t.
1158 Visited messages are ones for which the file, line and column have been jumped
1159 to from the current content in the current compilation buffer, even if it was
1160 from a different message."
1161   :type 'boolean
1162   :group 'compilation
1163   :version "22.1")
1164
1165 ;;;###autoload
1166 (defun compilation-mode (&optional name-of-mode)
1167   "Major mode for compilation log buffers.
1168 \\<compilation-mode-map>To visit the source for a line-numbered error,
1169 move point to the error message line and type \\[compile-goto-error].
1170 To kill the compilation, type \\[kill-compilation].
1171
1172 Runs `compilation-mode-hook' with `run-hooks' (which see).
1173
1174 \\{compilation-mode-map}"
1175   (interactive)
1176   (kill-all-local-variables)
1177   (use-local-map compilation-mode-map)
1178   (setq major-mode 'compilation-mode
1179         mode-name (or name-of-mode "Compilation"))
1180   (set (make-local-variable 'page-delimiter)
1181        compilation-page-delimiter)
1182   (compilation-setup)
1183   (setq buffer-read-only t)
1184   (run-mode-hooks 'compilation-mode-hook))
1185
1186 (defmacro define-compilation-mode (mode name doc &rest body)
1187   "This is like `define-derived-mode' without the PARENT argument.
1188 The parent is always `compilation-mode' and the customizable `compilation-...'
1189 variables are also set from the name of the mode you have chosen, by replacing
1190 the fist word, e.g `compilation-scroll-output' from `grep-scroll-output' if that
1191 variable exists."
1192   (let ((mode-name (replace-regexp-in-string "-mode\\'" "" (symbol-name mode))))
1193     `(define-derived-mode ,mode compilation-mode ,name
1194        ,doc
1195        ,@(mapcar (lambda (v)
1196                    (setq v (cons v
1197                                  (intern-soft (replace-regexp-in-string
1198                                                "^compilation" mode-name
1199                                                (symbol-name v)))))
1200                    (and (cdr v)
1201                         (or (boundp (cdr v))
1202                             (if (boundp 'byte-compile-bound-variables)
1203                                 (memq (cdr v) byte-compile-bound-variables)))
1204                         `(set (make-local-variable ',(car v)) ,(cdr v))))
1205                  '(compilation-buffer-name-function
1206                    compilation-directory-matcher
1207                    compilation-error
1208                    compilation-error-regexp-alist
1209                    compilation-error-regexp-alist-alist
1210                    compilation-error-screen-columns
1211                    compilation-finish-function
1212                    compilation-finish-functions
1213                    compilation-first-column
1214                    compilation-mode-font-lock-keywords
1215                    compilation-page-delimiter
1216                    compilation-parse-errors-filename-function
1217                    compilation-process-setup-function
1218                    compilation-scroll-output
1219                    compilation-search-path
1220                    compilation-skip-threshold
1221                    compilation-window-height))
1222        ,@body)))
1223
1224 (defun compilation-revert-buffer (ignore-auto noconfirm)
1225   (if buffer-file-name
1226       (let (revert-buffer-function)
1227         (revert-buffer ignore-auto noconfirm))
1228     (if (or noconfirm (yes-or-no-p (format "Restart compilation? ")))
1229         (apply 'compilation-start compilation-arguments))))
1230
1231 (defvar compilation-current-error nil
1232   "Marker to the location from where the next error will be found.
1233 The global commands next/previous/first-error/goto-error use this.")
1234
1235 (defvar compilation-messages-start nil
1236   "Buffer position of the beginning of the compilation messages.
1237 If nil, use the beginning of buffer.")
1238
1239 ;; A function name can't be a hook, must be something with a value.
1240 (defconst compilation-turn-on-font-lock 'turn-on-font-lock)
1241
1242 (defun compilation-setup (&optional minor)
1243   "Prepare the buffer for the compilation parsing commands to work.
1244 Optional argument MINOR indicates this is called from
1245 `compilation-minor-mode'."
1246   (make-local-variable 'compilation-current-error)
1247   (make-local-variable 'compilation-messages-start)
1248   (make-local-variable 'compilation-error-screen-columns)
1249   (make-local-variable 'overlay-arrow-position)
1250   (set (make-local-variable 'overlay-arrow-string)
1251        (if (display-graphic-p) "=>" ""))
1252   (setq next-error-overlay-arrow-position nil)
1253   (add-hook 'kill-buffer-hook
1254             (lambda () (setq next-error-overlay-arrow-position nil)) nil t)
1255   ;; Note that compilation-next-error-function is for interfacing
1256   ;; with the next-error function in simple.el, and it's only
1257   ;; coincidentally named similarly to compilation-next-error.
1258   (setq next-error-function 'compilation-next-error-function)
1259   (set (make-local-variable 'font-lock-extra-managed-props)
1260        '(directory message help-echo mouse-face debug))
1261   (set (make-local-variable 'compilation-locs)
1262        (make-hash-table :test 'equal :weakness 'value))
1263   ;; lazy-lock would never find the message unless it's scrolled to.
1264   ;; jit-lock might fontify some things too late.
1265   (set (make-local-variable 'font-lock-support-mode) nil)
1266   (set (make-local-variable 'font-lock-maximum-size) nil)
1267   (let ((fld font-lock-defaults))
1268     (if (and minor fld)
1269         (font-lock-add-keywords nil (compilation-mode-font-lock-keywords))
1270       (setq font-lock-defaults '(compilation-mode-font-lock-keywords t)))
1271     (if minor
1272         (if font-lock-mode
1273             (if fld
1274                 (font-lock-fontify-buffer)
1275               (font-lock-change-mode)
1276               (turn-on-font-lock))
1277           (turn-on-font-lock))
1278       ;; maybe defer font-lock till after derived mode is set up
1279       (run-mode-hooks 'compilation-turn-on-font-lock))))
1280
1281 ;;;###autoload
1282 (define-minor-mode compilation-shell-minor-mode
1283   "Toggle compilation shell minor mode.
1284 With arg, turn compilation mode on if and only if arg is positive.
1285 In this minor mode, all the error-parsing commands of the
1286 Compilation major mode are available but bound to keys that don't
1287 collide with Shell mode.  See `compilation-mode'.
1288 Turning the mode on runs the normal hook `compilation-shell-minor-mode-hook'."
1289   nil " Shell-Compile"
1290   :group 'compilation
1291   (if compilation-shell-minor-mode
1292       (compilation-setup t)
1293     (font-lock-remove-keywords nil (compilation-mode-font-lock-keywords))
1294     (font-lock-fontify-buffer)))
1295
1296 ;;;###autoload
1297 (define-minor-mode compilation-minor-mode
1298   "Toggle compilation minor mode.
1299 With arg, turn compilation mode on if and only if arg is positive.
1300 In this minor mode, all the error-parsing commands of the
1301 Compilation major mode are available.  See `compilation-mode'.
1302 Turning the mode on runs the normal hook `compilation-minor-mode-hook'."
1303   nil " Compilation"
1304   :group 'compilation
1305   (if compilation-minor-mode
1306       (compilation-setup t)
1307     (font-lock-remove-keywords nil (compilation-mode-font-lock-keywords))
1308     (font-lock-fontify-buffer)))
1309
1310 (defun compilation-handle-exit (process-status exit-status msg)
1311   "Write MSG in the current buffer and hack its mode-line-process."
1312   (let ((inhibit-read-only t)
1313         (status (if compilation-exit-message-function
1314                     (funcall compilation-exit-message-function
1315                              process-status exit-status msg)
1316                   (cons msg exit-status)))
1317         (omax (point-max))
1318         (opoint (point)))
1319     ;; Record where we put the message, so we can ignore it later on.
1320     (goto-char omax)
1321     (insert ?\n mode-name " " (car status))
1322     (if (and (numberp compilation-window-height)
1323              (zerop compilation-window-height))
1324         (message "%s" (cdr status)))
1325     (if (bolp)
1326         (forward-char -1))
1327     (insert " at " (substring (current-time-string) 0 19))
1328     (goto-char (point-max))
1329     ;; Prevent that message from being recognized as a compilation error.
1330     (add-text-properties omax (point)
1331                          (append '(compilation-handle-exit t) nil))
1332     (setq mode-line-process (format ":%s [%s]" process-status (cdr status)))
1333     ;; Force mode line redisplay soon.
1334     (force-mode-line-update)
1335     (if (and opoint (< opoint omax))
1336         (goto-char opoint))
1337     (if compilation-finish-function
1338         (funcall compilation-finish-function (current-buffer) msg))
1339     (let ((functions compilation-finish-functions))
1340       (while functions
1341         (funcall (car functions) (current-buffer) msg)
1342         (setq functions (cdr functions))))))
1343
1344 ;; Called when compilation process changes state.
1345 (defun compilation-sentinel (proc msg)
1346   "Sentinel for compilation buffers."
1347   (if (memq (process-status proc) '(exit signal))
1348       (let ((buffer (process-buffer proc)))
1349         (if (null (buffer-name buffer))
1350             ;; buffer killed
1351             (set-process-buffer proc nil)
1352           (with-current-buffer buffer
1353             ;; Write something in the compilation buffer
1354             ;; and hack its mode line.
1355             (compilation-handle-exit (process-status proc)
1356                                      (process-exit-status proc)
1357                                      msg)
1358             ;; Since the buffer and mode line will show that the
1359             ;; process is dead, we can delete it now.  Otherwise it
1360             ;; will stay around until M-x list-processes.
1361             (delete-process proc)))
1362         (setq compilation-in-progress (delq proc compilation-in-progress)))))
1363
1364 (defun compilation-filter (proc string)
1365   "Process filter for compilation buffers.
1366 Just inserts the text, but uses `insert-before-markers'."
1367   (if (buffer-name (process-buffer proc))
1368       (with-current-buffer (process-buffer proc)
1369         (let ((inhibit-read-only t))
1370           (save-excursion
1371             (goto-char (process-mark proc))
1372             (insert-before-markers string)
1373             (run-hooks 'compilation-filter-hook))))))
1374
1375 ;;; test if a buffer is a compilation buffer, assuming we're in the buffer
1376 (defsubst compilation-buffer-internal-p ()
1377   "Test if inside a compilation buffer."
1378   (local-variable-p 'compilation-locs))
1379
1380 ;;; test if a buffer is a compilation buffer, using compilation-buffer-internal-p
1381 (defsubst compilation-buffer-p (buffer)
1382   "Test if BUFFER is a compilation buffer."
1383   (with-current-buffer buffer
1384     (compilation-buffer-internal-p)))
1385
1386 (defmacro compilation-loop (< property-change 1+ error)
1387   `(while (,< n 0)
1388       (or (setq pt (,property-change pt 'message))
1389           (error ,error compilation-error))
1390       ;; prop 'message usually has 2 changes, on and off, so re-search if off
1391       (or (setq msg (get-text-property pt 'message))
1392           (if (setq pt (,property-change pt 'message))
1393               (setq msg (get-text-property pt 'message)))
1394           (error ,error compilation-error))
1395       (or (< (cadr msg) compilation-skip-threshold)
1396           (if different-file
1397               (eq (prog1 last (setq last (nth 2 (car msg))))
1398                   last))
1399           (if compilation-skip-visited
1400               (nthcdr 4 (car msg)))
1401           (if compilation-skip-to-next-location
1402               (eq (car msg) loc))
1403           ;; count this message only if none of the above are true
1404           (setq n (,1+ n)))))
1405
1406 (defun compilation-next-error (n &optional different-file pt)
1407   "Move point to the next error in the compilation buffer.
1408 Prefix arg N says how many error messages to move forwards (or
1409 backwards, if negative).
1410 Does NOT find the source line like \\[next-error]."
1411   (interactive "p")
1412   (or (compilation-buffer-p (current-buffer))
1413       (error "Not in a compilation buffer"))
1414   (or pt (setq pt (point)))
1415   (let* ((msg (get-text-property pt 'message))
1416          (loc (car msg))
1417          last)
1418     (if (zerop n)
1419         (unless (or msg                 ; find message near here
1420                     (setq msg (get-text-property (max (1- pt) (point-min))
1421                                                  'message)))
1422           (setq pt (previous-single-property-change pt 'message nil
1423                                                     (line-beginning-position)))
1424           (unless (setq msg (get-text-property (max (1- pt) (point-min)) 'message))
1425             (setq pt (next-single-property-change pt 'message nil
1426                                                   (line-end-position)))
1427             (or (setq msg (get-text-property pt 'message))
1428                 (setq pt (point)))))
1429       (setq last (nth 2 (car msg)))
1430       (if (>= n 0)
1431           (compilation-loop > next-single-property-change 1-
1432                             (if (get-buffer-process (current-buffer))
1433                                 "No more %ss yet"
1434                               "Moved past last %s"))
1435         ;; Don't move "back" to message at or before point.
1436         ;; Pass an explicit (point-min) to make sure pt is non-nil.
1437         (setq pt (previous-single-property-change pt 'message nil (point-min)))
1438         (compilation-loop < previous-single-property-change 1+
1439                           "Moved back before first %s")))
1440     (goto-char pt)
1441     (or msg
1442         (error "No %s here" compilation-error))))
1443
1444 (defun compilation-previous-error (n)
1445   "Move point to the previous error in the compilation buffer.
1446 Prefix arg N says how many error messages to move backwards (or
1447 forwards, if negative).
1448 Does NOT find the source line like \\[previous-error]."
1449   (interactive "p")
1450   (compilation-next-error (- n)))
1451
1452 (defun compilation-next-file (n)
1453   "Move point to the next error for a different file than the current one.
1454 Prefix arg N says how many files to move forwards (or backwards, if negative)."
1455   (interactive "p")
1456   (compilation-next-error n t))
1457
1458 (defun compilation-previous-file (n)
1459   "Move point to the previous error for a different file than the current one.
1460 Prefix arg N says how many files to move backwards (or forwards, if negative)."
1461   (interactive "p")
1462   (compilation-next-file (- n)))
1463
1464 (defun kill-compilation ()
1465   "Kill the process made by the \\[compile] or \\[grep] commands."
1466   (interactive)
1467   (let ((buffer (compilation-find-buffer)))
1468     (if (get-buffer-process buffer)
1469         (interrupt-process (get-buffer-process buffer))
1470       (error "The compilation process is not running"))))
1471
1472 (defalias 'compile-mouse-goto-error 'compile-goto-error)
1473
1474 (defun compile-goto-error (&optional event)
1475   "Visit the source for the error message at point.
1476 Use this command in a compilation log buffer.  Sets the mark at point there."
1477   (interactive (list last-input-event))
1478   (if event (posn-set-point (event-end event)))
1479   (or (compilation-buffer-p (current-buffer))
1480       (error "Not in a compilation buffer"))
1481   (if (get-text-property (point) 'directory)
1482       (dired-other-window (car (get-text-property (point) 'directory)))
1483     (push-mark)
1484     (setq compilation-current-error (point))
1485     (next-error 0)))
1486
1487 ;; Return a compilation buffer.
1488 ;; If the current buffer is a compilation buffer, return it.
1489 ;; Otherwise, look for a compilation buffer and signal an error
1490 ;; if there are none.
1491 (defun compilation-find-buffer (&optional avoid-current)
1492   (next-error-find-buffer avoid-current 'compilation-buffer-internal-p))
1493
1494 ;;;###autoload
1495 (defun compilation-next-error-function (n &optional reset)
1496   (interactive "p")
1497   (set-buffer (compilation-find-buffer))
1498   (when reset
1499     (setq compilation-current-error nil))
1500   (let* ((columns compilation-error-screen-columns) ; buffer's local value
1501          (last 1)
1502          (loc (compilation-next-error (or n 1) nil
1503                                       (or compilation-current-error
1504                                           compilation-messages-start
1505                                           (point-min))))
1506          (end-loc (nth 2 loc))
1507          (marker (point-marker)))
1508     (setq compilation-current-error (point-marker)
1509           overlay-arrow-position
1510             (if (bolp)
1511                 compilation-current-error
1512               (copy-marker (line-beginning-position)))
1513           loc (car loc))
1514     ;; If loc contains no marker, no error in that file has been visited.  If
1515     ;; the marker is invalid the buffer has been killed.  So, recalculate all
1516     ;; markers for that file.
1517     (unless (and (nth 3 loc) (marker-buffer (nth 3 loc)))
1518       (with-current-buffer (compilation-find-file marker (caar (nth 2 loc))
1519                                                   (or (cdar (nth 2 loc))
1520                                                       default-directory))
1521         (save-restriction
1522           (widen)
1523           (goto-char (point-min))
1524           ;; Treat file's found lines in forward order, 1 by 1.
1525           (dolist (line (reverse (cddr (nth 2 loc))))
1526             (when (car line)            ; else this is a filename w/o a line#
1527               (beginning-of-line (- (car line) last -1))
1528               (setq last (car line)))
1529             ;; Treat line's found columns and store/update a marker for each.
1530             (dolist (col (cdr line))
1531               (if (car col)
1532                   (if (eq (car col) -1) ; special case for range end
1533                       (end-of-line)
1534                     (compilation-move-to-column (car col) columns))
1535                 (beginning-of-line)
1536                 (skip-chars-forward " \t"))
1537               (if (nth 3 col)
1538                   (set-marker (nth 3 col) (point))
1539                 (setcdr (nthcdr 2 col) `(,(point-marker)))))))))
1540     (compilation-goto-locus marker (nth 3 loc) (nth 3 end-loc))
1541     (setcdr (nthcdr 3 loc) t)))         ; Set this one as visited.
1542
1543 (defvar compilation-gcpro nil
1544   "Internal variable used to keep some values from being GC'd.")
1545 (make-variable-buffer-local 'compilation-gcpro)
1546
1547 (defun compilation-fake-loc (marker file &optional line col)
1548   "Preassociate MARKER with FILE.
1549 FILE should be ABSOLUTE-FILENAME or (RELATIVE-FILENAME . DIRNAME).
1550 This is useful when you compile temporary files, but want
1551 automatic translation of the messages to the real buffer from
1552 which the temporary file came.  This only works if done before a
1553 message about FILE appears!
1554
1555 Optional args LINE and COL default to 1 and beginning of
1556 indentation respectively.  The marker is expected to reflect
1557 this.  In the simplest case the marker points to the first line
1558 of the region that was saved to the temp file.
1559
1560 If you concatenate several regions into the temp file (e.g. a
1561 header with variable assignments and a code region), you must
1562 call this several times, once each for the last line of one
1563 region and the first line of the next region."
1564   (or (consp file) (setq file (list file)))
1565   (setq file (compilation-get-file-structure file))
1566   ;; Between the current call to compilation-fake-loc and the first occurrence
1567   ;; of an error message referring to `file', the data is only kept is the
1568   ;; weak hash-table compilation-locs, so we need to prevent this entry
1569   ;; in compilation-locs from being GC'd away.  --Stef
1570   (push file compilation-gcpro)
1571   (let ((loc (compilation-assq (or line 1) (cdr file))))
1572     (setq loc (compilation-assq col loc))
1573     (if (cdr loc)
1574         (setcdr (cddr loc) (list marker))
1575       (setcdr loc (list line file marker)))
1576     loc))
1577
1578 (defcustom compilation-context-lines 0
1579   "*Display this many lines of leading context before message.
1580 If nil, don't scroll the compilation output window."
1581   :type '(choice integer (const :tag "No window scrolling" nil))
1582   :group 'compilation
1583   :version "22.1")
1584
1585 (defsubst compilation-set-window (w mk)
1586   "Align the compilation output window W with marker MK near top."
1587   (if (integerp compilation-context-lines)
1588       (set-window-start w (save-excursion
1589                             (goto-char mk)
1590                             (beginning-of-line (- 1 compilation-context-lines))
1591                             (point))))
1592   (set-window-point w mk))
1593
1594 (defvar next-error-highlight-timer)
1595
1596 (defun compilation-goto-locus (msg mk end-mk)
1597   "Jump to an error corresponding to MSG at MK.
1598 All arguments are markers.  If END-MK is non-nil, mark is set there
1599 and overlay is highlighted between MK and END-MK."
1600   (if (eq (window-buffer (selected-window))
1601           (marker-buffer msg))
1602       ;; If the compilation buffer window is selected,
1603       ;; keep the compilation buffer in this window;
1604       ;; display the source in another window.
1605       (let ((pop-up-windows t))
1606         (pop-to-buffer (marker-buffer mk)))
1607     (if (window-dedicated-p (selected-window))
1608         (pop-to-buffer (marker-buffer mk))
1609       (switch-to-buffer (marker-buffer mk))))
1610   ;; If narrowing gets in the way of going to the right place, widen.
1611   (unless (eq (goto-char mk) (point))
1612     (widen)
1613     (goto-char mk))
1614   (if end-mk
1615       (push-mark end-mk t)
1616     (if mark-active (setq mark-active)))
1617   ;; If hideshow got in the way of
1618   ;; seeing the right place, open permanently.
1619   (dolist (ov (overlays-at (point)))
1620     (when (eq 'hs (overlay-get ov 'invisible))
1621       (delete-overlay ov)
1622       (goto-char mk)))
1623
1624   ;; Show compilation buffer in other window, scrolled to this error.
1625   (let* ((pop-up-windows t)
1626          ;; Use an existing window if it is in a visible frame.
1627          (w (or (get-buffer-window (marker-buffer msg) 'visible)
1628                 ;; Pop up a window.
1629                 (display-buffer (marker-buffer msg))))
1630          (highlight-regexp (with-current-buffer (marker-buffer msg)
1631                              ;; also do this while we change buffer
1632                              (compilation-set-window w msg)
1633                              compilation-highlight-regexp)))
1634     (compilation-set-window-height w)
1635
1636     (when highlight-regexp
1637       (if (timerp next-error-highlight-timer)
1638           (cancel-timer next-error-highlight-timer))
1639       (unless compilation-highlight-overlay
1640         (setq compilation-highlight-overlay
1641               (make-overlay (point-min) (point-min)))
1642         (overlay-put compilation-highlight-overlay 'face 'next-error))
1643       (with-current-buffer (marker-buffer mk)
1644         (save-excursion
1645           (if end-mk (goto-char end-mk) (end-of-line))
1646           (let ((end (point)))
1647             (if mk (goto-char mk) (beginning-of-line))
1648             (if (and (stringp highlight-regexp)
1649                      (re-search-forward highlight-regexp end t))
1650                 (progn
1651                   (goto-char (match-beginning 0))
1652                   (move-overlay compilation-highlight-overlay
1653                                 (match-beginning 0) (match-end 0)
1654                                 (current-buffer)))
1655               (move-overlay compilation-highlight-overlay
1656                             (point) end (current-buffer)))
1657             (if (numberp next-error-highlight)
1658                 (setq next-error-highlight-timer
1659                       (run-at-time next-error-highlight nil 'delete-overlay
1660                                    compilation-highlight-overlay)))
1661             (if (not (or (eq next-error-highlight t)
1662                          (numberp next-error-highlight)))
1663                 (delete-overlay compilation-highlight-overlay))))))
1664     (when (and (eq next-error-highlight 'fringe-arrow))
1665       (setq next-error-overlay-arrow-position
1666             (copy-marker (line-beginning-position))))))
1667
1668 \f
1669 (defun compilation-find-file (marker filename dir &rest formats)
1670   "Find a buffer for file FILENAME.
1671 Search the directories in `compilation-search-path'.
1672 A nil in `compilation-search-path' means to try the
1673 current directory, which is passed in DIR.
1674 If FILENAME is not found at all, ask the user where to find it.
1675 Pop up the buffer containing MARKER and scroll to MARKER if we ask the user."
1676   (or formats (setq formats '("%s")))
1677   (save-excursion
1678     (let ((dirs compilation-search-path)
1679           buffer thisdir fmts name)
1680       (if (file-name-absolute-p filename)
1681           ;; The file name is absolute.  Use its explicit directory as
1682           ;; the first in the search path, and strip it from FILENAME.
1683           (setq filename (abbreviate-file-name (expand-file-name filename))
1684                 dirs (cons (file-name-directory filename) dirs)
1685                 filename (file-name-nondirectory filename)))
1686       ;; Now search the path.
1687       (while (and dirs (null buffer))
1688         (setq thisdir (or (car dirs) dir)
1689               fmts formats)
1690         ;; For each directory, try each format string.
1691         (while (and fmts (null buffer))
1692           (setq name (expand-file-name (format (car fmts) filename) thisdir)
1693                 buffer (and (file-exists-p name)
1694                             (find-file-noselect name))
1695                 fmts (cdr fmts)))
1696         (setq dirs (cdr dirs)))
1697       (or buffer
1698           ;; The file doesn't exist.  Ask the user where to find it.
1699           (let ((pop-up-windows t))
1700             (compilation-set-window (display-buffer (marker-buffer marker))
1701                                     marker)
1702             (let ((name (expand-file-name
1703                          (read-file-name
1704                           (format "Find this error in: (default %s) "
1705                                   filename)
1706                           dir filename t))))
1707               (if (file-directory-p name)
1708                   (setq name (expand-file-name filename name)))
1709               (setq buffer (and (file-exists-p name)
1710                                 (find-file name))))))
1711       ;; Make intangible overlays tangible.
1712       (mapcar (function (lambda (ov)
1713                           (when (overlay-get ov 'intangible)
1714                             (overlay-put ov 'intangible nil))))
1715               (overlays-in (point-min) (point-max)))
1716       buffer)))
1717
1718 (defun compilation-get-file-structure (file &optional fmt)
1719   "Retrieve FILE's file-structure or create a new one.
1720 FILE should be (ABSOLUTE-FILENAME) or (RELATIVE-FILENAME . DIRNAME)."
1721
1722   (or (gethash file compilation-locs)
1723       ;; File was not previously encountered, at least not in the form passed.
1724       ;; Let's normalize it and look again.
1725       (let ((filename (car file))
1726             (default-directory (if (cdr file)
1727                                    (file-truename (cdr file))
1728                                  default-directory)))
1729
1730         ;; Check for a comint-file-name-prefix and prepend it if appropriate.
1731         ;; (This is very useful for compilation-minor-mode in an rlogin-mode
1732         ;; buffer.)
1733         (if (boundp 'comint-file-name-prefix)
1734             (if (file-name-absolute-p filename)
1735                 (setq filename
1736                       (concat (with-no-warnings comint-file-name-prefix) filename))
1737               (setq default-directory
1738                     (file-truename
1739                      (concat (with-no-warnings comint-file-name-prefix) default-directory)))))
1740
1741         ;; If compilation-parse-errors-filename-function is
1742         ;; defined, use it to process the filename.
1743         (when compilation-parse-errors-filename-function
1744           (setq filename
1745                 (funcall compilation-parse-errors-filename-function
1746                          filename)))
1747
1748         ;; Some compilers (e.g. Sun's java compiler, reportedly) produce bogus
1749         ;; file names like "./bar//foo.c" for file "bar/foo.c";
1750         ;; expand-file-name will collapse these into "/foo.c" and fail to find
1751         ;; the appropriate file.  So we look for doubled slashes in the file
1752         ;; name and fix them.
1753         (setq filename (command-line-normalize-file-name filename))
1754
1755         ;; Now eliminate any "..", because find-file would get them wrong.
1756         ;; Make relative and absolute filenames, with or without links, the
1757         ;; same.
1758         (setq filename
1759               (list (abbreviate-file-name
1760                      (file-truename (if (cdr file)
1761                                         (expand-file-name filename)
1762                                       filename)))))
1763
1764         ;; Store it for the possibly unnormalized name
1765         (puthash file
1766                  ;; Retrieve or create file-structure for normalized name
1767                  (or (gethash filename compilation-locs)
1768                      (puthash filename (list filename fmt) compilation-locs))
1769                  compilation-locs))))
1770
1771 (add-to-list 'debug-ignored-errors "^No more [-a-z ]+s yet$")
1772
1773 ;;; Compatibility with the old compile.el.
1774
1775 (defun compile-buffer-substring (n) (if n (match-string n)))
1776
1777 (defun compilation-compat-error-properties (err)
1778   "Map old-style error ERR to new-style message."
1779   ;; Old-style structure is (MARKER (FILE DIR) LINE COL) or
1780   ;; (MARKER . MARKER).
1781   (let ((dst (cdr err)))
1782     (if (markerp dst)
1783         ;; Must start with a face, for font-lock.
1784         `(face nil
1785           message ,(list (list nil nil nil dst) 2)
1786           help-echo "mouse-2: visit the source location"
1787           keymap compilation-button-map
1788           mouse-face highlight)
1789       ;; Too difficult to do it by hand: dispatch to the normal code.
1790       (let* ((file (pop dst))
1791              (line (pop dst))
1792              (col (pop dst))
1793              (filename (pop file))
1794              (dirname (pop file))
1795              (fmt (pop file)))
1796         (compilation-internal-error-properties
1797          (cons filename dirname) line nil col nil 2 fmt)))))
1798
1799 (defun compilation-compat-parse-errors (limit)
1800   (when compilation-parse-errors-function
1801     ;; FIXME: We should remove the rest of the compilation keywords
1802     ;; but we can't do that from here because font-lock is using
1803     ;; the value right now.  --stef
1804     (save-excursion
1805       (setq compilation-error-list nil)
1806       ;; Reset compilation-parsing-end each time because font-lock
1807       ;; might force us the re-parse many times (typically because
1808       ;; some code adds some text-property to the output that we
1809       ;; already parsed).  You might say "why reparse", well:
1810       ;; because font-lock has just removed the `message' property so
1811       ;; have to do it all over again.
1812       (if compilation-parsing-end
1813           (set-marker compilation-parsing-end (point))
1814         (setq compilation-parsing-end (point-marker)))
1815       (condition-case nil
1816           ;; Ignore any error: we're calling this function earlier than
1817           ;; in the old compile.el so things might not all be setup yet.
1818           (funcall compilation-parse-errors-function limit nil)
1819         (error nil))
1820       (dolist (err (if (listp compilation-error-list) compilation-error-list))
1821         (let* ((src (car err))
1822                (dst (cdr err))
1823                (loc (cond ((markerp dst) (list nil nil nil dst))
1824                           ((consp dst)
1825                            (list (nth 2 dst) (nth 1 dst)
1826                                  (cons (cdar dst) (caar dst)))))))
1827           (when loc
1828             (goto-char src)
1829             ;; (put-text-property src (line-end-position) 'font-lock-face 'font-lock-warning-face)
1830             (put-text-property src (line-end-position)
1831                                'message (list loc 2)))))))
1832   (goto-char limit)
1833   nil)
1834
1835 ;; Beware: this is not only compatiblity code.  New code stil uses it.  --Stef
1836 (defun compilation-forget-errors ()
1837   ;; In case we hit the same file/line specs, we want to recompute a new
1838   ;; marker for them, so flush our cache.
1839   (setq compilation-locs (make-hash-table :test 'equal :weakness 'value))
1840   (setq compilation-gcpro nil)
1841   ;; FIXME: the old code reset the directory-stack, so maybe we should
1842   ;; put a `directory change' marker of some sort, but where?  -stef
1843   ;;
1844   ;; FIXME: The old code moved compilation-current-error (which was
1845   ;; virtually represented by a mix of compilation-parsing-end and
1846   ;; compilation-error-list) to point-min, but that was only meaningful for
1847   ;; the internal uses of compilation-forget-errors: all calls from external
1848   ;; packages seem to be followed by a move of compilation-parsing-end to
1849   ;; something equivalent to point-max.  So we speculatively move
1850   ;; compilation-current-error to point-max (since the external package
1851   ;; won't know that it should do it).  --stef
1852   (setq compilation-current-error nil)
1853   (let* ((proc (get-buffer-process (current-buffer)))
1854          (mark (if proc (process-mark proc)))
1855          (pos (or mark (point-max))))
1856     (setq compilation-messages-start
1857           ;; In the future, ignore the text already present in the buffer.
1858           ;; Since many process filter functions insert before markers,
1859           ;; we need to put ours just before the insertion point rather
1860           ;; than at the insertion point.  If that's not possible, then
1861           ;; don't use a marker.  --Stef
1862           (if (> pos (point-min)) (copy-marker (1- pos)) pos))))
1863
1864 ;;;###autoload
1865 (add-to-list 'auto-mode-alist '("\\.gcov\\'" . compilation-mode))
1866
1867 (provide 'compile)
1868
1869 ;; arch-tag: 12465727-7382-4f72-b234-79855a00dd8c
1870 ;;; compile.el ends here