code.delx.au - gnu-emacs/blob - lisp/avoid.el

   1 ;;; avoid.el --- make mouse pointer stay out of the way of editing
   2
   3 ;; Copyright (C) 1993, 1994, 2000, 2001, 2002, 2003, 2004,
   4 ;;   2005, 2006, 2007, 2008, 2009, 2010, 2011, 2012 Free Software Foundation, Inc.
   5
   6 ;; Author: Boris Goldowsky <boris@gnu.org>
   7 ;; Keywords: mouse
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; For those who are annoyed by the mouse pointer obscuring text,
  27 ;; this mode moves the mouse pointer - either just a little out of
  28 ;; the way, or all the way to the corner of the frame.
  29 ;; To use, load or evaluate this file and type M-x mouse-avoidance-mode .
  30 ;; To set up permanently, put the following in your .emacs:
  31 ;;
  32 ;; (if (display-mouse-p) (mouse-avoidance-mode 'animate))
  33 ;;
  34 ;; Other legitimate alternatives include
  35 ;; `banish', `exile', `jump', `cat-and-mouse', and `proteus'.
  36 ;; They do somewhat different things.
  37 ;; See the documentation for function `mouse-avoidance-mode' for
  38 ;; details of the different modes.
  39 ;;
  40 ;; For added silliness, make the animatee animate...
  41 ;; put something similar to the following into your .emacs:
  42 ;;
  43 ;; (if (eq window-system 'x)
  44 ;;     (mouse-avoidance-set-pointer-shape
  45 ;;           (eval (nth (random 4)
  46 ;;                      '(x-pointer-man x-pointer-spider
  47 ;;                        x-pointer-gobbler x-pointer-gumby)))))
  48 ;;
  49 ;; For completely random pointer shape, replace the setq above with:
  50 ;; (setq x-pointer-shape (mouse-avoidance-random-shape))
  51 ;;
  52 ;; Bugs / Warnings / To-Do:
  53 ;;
  54 ;; - Using this code does slow Emacs down.  "banish" mode shouldn't
  55 ;;   be too bad, and on my workstation even "animate" is reasonable.
  56 ;;
  57 ;; - It ought to find out where any overlapping frames are and avoid them,
  58 ;;   rather than always raising the frame.
  59
  60 ;; Credits:
  61 ;; This code was helped by all those who contributed suggestions,
  62 ;;   fixes, and additions
  63 ;; Joe Harrington (and his advisor), for the original inspiration.
  64 ;; Ken Manheimer, for dreaming up the Protean mode.
  65 ;; Richard Stallman, for the awful cat-and-mouse pun, among other things.
  66 ;; Mike Williams, Denis Howe, Bill Benedetto, Chris Moore, Don Morris,
  67 ;; Simon Marshall, and M.S. Ashton, for their feedback.
  68
  69 ;;; Code:
  70
  71 (provide 'avoid)
  72
  73 (defgroup avoid nil
  74   "Make mouse pointer stay out of the way of editing."
  75   :prefix "mouse-avoidance-"
  76   :group 'mouse)
  77
  78 ;;;###autoload
  79 (defcustom mouse-avoidance-mode nil
  80   "Activate Mouse Avoidance mode.
  81 See function `mouse-avoidance-mode' for possible values.
  82 Setting this variable directly does not take effect;
  83 use either \\[customize] or the function `mouse-avoidance-mode'."
  84   :set (lambda (symbol value)
  85          ;; 'none below prevents toggling when value is nil.
  86          (mouse-avoidance-mode (or value 'none)))
  87   :initialize 'custom-initialize-default
  88   :type '(choice (const :tag "none" nil) (const banish) (const jump)
  89                  (const animate) (const exile) (const proteus))
  90   :group 'avoid
  91   :require 'avoid
  92   :version "20.3")
  93
  94
  95 (defcustom mouse-avoidance-nudge-dist 15
  96   "Average distance that mouse will be moved when approached by cursor.
  97 Only applies in Mouse Avoidance mode `jump' and its derivatives.
  98 For best results make this larger than `mouse-avoidance-threshold'."
  99   :type 'integer
 100   :group 'avoid)
 101
 102 (defcustom mouse-avoidance-nudge-var 10
 103   "Variability of `mouse-avoidance-nudge-dist' (which see)."
 104   :type 'integer
 105   :group 'avoid)
 106
 107 (defcustom mouse-avoidance-animation-delay .01
 108   "Delay between animation steps, in seconds."
 109   :type 'number
 110   :group 'avoid)
 111
 112 (defcustom mouse-avoidance-threshold 5
 113   "Mouse-pointer's flight distance.
 114 If the cursor gets closer than this, the mouse pointer will move away.
 115 Only applies in Mouse Avoidance modes `animate' and `jump'."
 116   :type 'integer
 117   :group 'avoid)
 118
 119 ;; Internal variables
 120 (defvar mouse-avoidance-state nil)
 121 (defvar mouse-avoidance-pointer-shapes nil)
 122 (defvar mouse-avoidance-n-pointer-shapes 0)
 123 (defvar mouse-avoidance-old-pointer-shape nil)
 124 (defvar mouse-avoidance-animating-pointer nil)
 125
 126 ;; This timer is used to run something when Emacs is idle.
 127 (defvar mouse-avoidance-timer nil)
 128
 129 ;;; Functions:
 130
 131 (defsubst mouse-avoidance-set-pointer-shape (shape)
 132   "Set the shape of the mouse pointer to SHAPE."
 133   (when (boundp 'x-pointer-shape)
 134     (setq x-pointer-shape shape)
 135     (set-mouse-color nil)))
 136
 137 (defun mouse-avoidance-point-position ()
 138   "Return the position of point as (FRAME X . Y).
 139 Analogous to `mouse-position'."
 140   (let ((edges (window-inside-edges))
 141         (x-y (posn-x-y (posn-at-point))))
 142     (cons (selected-frame)
 143           (cons (+ (car edges)
 144                    (/ (car x-y) (frame-char-width)))
 145                 (+ (car (cdr edges))
 146                    (/ (cdr x-y) (frame-char-height)))))))
 147
 148 ;(defun mouse-avoidance-point-position-test ()
 149 ;  (interactive)
 150 ;  (message (format "point=%s mouse=%s"
 151 ;                  (cdr (mouse-avoidance-point-position))
 152 ;                  (cdr (mouse-position)))))
 153
 154 (defun mouse-avoidance-set-mouse-position (pos)
 155   ;; Carefully set mouse position to given position (X . Y)
 156   ;; Ideally, should check if X,Y is in the current frame, and if not,
 157   ;; leave the mouse where it was.  However, this is currently
 158   ;; difficult to do, so we just raise the frame to avoid frame switches.
 159   ;; Returns t if it moved the mouse.
 160   (let ((f (selected-frame)))
 161     (raise-frame f)
 162     (set-mouse-position f (car pos) (cdr pos))
 163     t))
 164
 165 (defun mouse-avoidance-too-close-p (mouse)
 166   "Return t if mouse pointer and point cursor are too close.
 167 MOUSE is the current mouse position as returned by `mouse-position'.
 168 Acceptable distance is defined by `mouse-avoidance-threshold'."
 169   (let* ((frame (car mouse))
 170          (mouse-y (cdr (cdr mouse)))
 171          (tool-bar-lines (frame-parameter nil 'tool-bar-lines)))
 172     (or tool-bar-lines
 173         (setq tool-bar-lines 0))
 174     (if (and mouse-y (< mouse-y tool-bar-lines))
 175         nil
 176       (let ((point (mouse-avoidance-point-position))
 177             (mouse-x (car (cdr mouse))))
 178         (and (eq frame (car point))
 179              (not (null mouse-x))
 180              (< (abs (- mouse-x (car (cdr point))))
 181                 mouse-avoidance-threshold)
 182              (< (abs (- mouse-y (cdr (cdr point))))
 183                 mouse-avoidance-threshold))))))
 184
 185 (defun mouse-avoidance-banish-destination ()
 186   "The position to which Mouse Avoidance mode `banish' moves the mouse.
 187 You can redefine this if you want the mouse banished to a different corner."
 188   (let* ((pos (window-edges)))
 189     (cons (- (nth 2 pos) 2)
 190           (nth 1 pos))))
 191
 192 (defun mouse-avoidance-banish-mouse ()
 193   ;; Put the mouse pointer in the upper-right corner of the current frame.
 194   (mouse-avoidance-set-mouse-position (mouse-avoidance-banish-destination)))
 195
 196 (defsubst mouse-avoidance-delta (cur delta dist var min max)
 197   ;; Decide how far to move in either dimension.
 198   ;; Args are the CURRENT location, the desired DELTA for
 199   ;; warp-conservation, the DISTANCE we like to move, the VARIABILITY
 200   ;; in distance allowed, and the MIN and MAX possible window positions.
 201   ;; Returns something as close to DELTA as possible within the constraints.
 202   (let ((L1 (max (- min cur) (+ (- dist) (- var))))
 203         (R1                  (+ (- dist)    var ))
 204         (L2                  (+    dist  (- var)))
 205         (R2 (min (- max cur) (+    dist     var))))
 206     (if (< R1 (- min cur)) (setq L1 nil R1 nil))
 207     (if (> L2 (- max cur)) (setq L2 nil R2 nil))
 208     (cond ((and L1 (< delta L1)) L1)
 209           ((and R1 (< delta R1)) delta)
 210           ((and R1 (< delta 0)) R1)
 211           ((and L2 (< delta L2)) L2)
 212           ((and R2 (< delta R2)) delta)
 213           (R2)
 214           ((or R1 L2))
 215           (t 0))))
 216
 217 (defun mouse-avoidance-nudge-mouse ()
 218   ;; Push the mouse a little way away, possibly animating the move.
 219   ;; For these modes, state keeps track of the total offset that we've
 220   ;; accumulated, and tries to keep it close to zero.
 221   (let* ((cur (mouse-position))
 222          (cur-frame (car cur))
 223          (cur-pos (cdr cur))
 224          (pos (window-edges))
 225          (wleft (pop pos))
 226          (wtop (pop pos))
 227          (wright (pop pos))
 228          (wbot (pop pos))
 229          (deltax (mouse-avoidance-delta
 230                   (car cur-pos) (- (random mouse-avoidance-nudge-var)
 231                                    (car mouse-avoidance-state))
 232                   mouse-avoidance-nudge-dist mouse-avoidance-nudge-var
 233                   wleft (1- wright)))
 234          (deltay (mouse-avoidance-delta
 235                   (cdr cur-pos) (- (random mouse-avoidance-nudge-var)
 236                                    (cdr mouse-avoidance-state))
 237                   mouse-avoidance-nudge-dist mouse-avoidance-nudge-var
 238                   wtop (1- wbot))))
 239     (setq mouse-avoidance-state
 240           (cons (+ (car mouse-avoidance-state) deltax)
 241                 (+ (cdr mouse-avoidance-state) deltay)))
 242     (if (or (eq mouse-avoidance-mode 'animate)
 243             (eq mouse-avoidance-mode 'proteus))
 244         (let ((i 0.0)
 245               (incr (max .1 (/ 1.0 mouse-avoidance-nudge-dist))))
 246           (setq mouse-avoidance-animating-pointer t)
 247           (while (<= i 1)
 248             (mouse-avoidance-set-mouse-position
 249              (cons (+ (car cur-pos) (round (* i deltax)))
 250                    (+ (cdr cur-pos) (round (* i deltay)))))
 251             (setq i (+ i incr))
 252             (if (eq mouse-avoidance-mode 'proteus)
 253                 (mouse-avoidance-set-pointer-shape
 254                  (mouse-avoidance-random-shape)))
 255             (sit-for mouse-avoidance-animation-delay))
 256           (setq mouse-avoidance-animating-pointer nil))
 257       (mouse-avoidance-set-mouse-position (cons (+ (car (cdr cur)) deltax)
 258                                                 (+ (cdr (cdr cur)) deltay))))))
 259
 260 (defun mouse-avoidance-random-shape ()
 261   "Return a random cursor shape.
 262 This assumes that any variable whose name begins with x-pointer- and
 263 has an integer value is a valid cursor shape.  You might want to
 264 redefine this function to suit your own tastes."
 265   (if (null mouse-avoidance-pointer-shapes)
 266       (progn
 267         (setq mouse-avoidance-pointer-shapes
 268               (mapcar (lambda (x) (symbol-value (intern x)))
 269                       (all-completions "x-pointer-" obarray
 270                                        (lambda (x)
 271                                           (and (boundp x)
 272                                                (integerp (symbol-value x)))))))
 273         (setq mouse-avoidance-n-pointer-shapes
 274               (length mouse-avoidance-pointer-shapes))))
 275   (nth (random mouse-avoidance-n-pointer-shapes)
 276        mouse-avoidance-pointer-shapes))
 277
 278 (defun mouse-avoidance-ignore-p ()
 279   (let ((mp (mouse-position)))
 280     (or executing-kbd-macro            ; don't check inside macro
 281         (null (cadr mp))               ; don't move unless in an Emacs frame
 282         (not (eq (car mp) (selected-frame)))
 283         ;; Don't do anything if last event was a mouse event.
 284         ;; FIXME: this code fails in the case where the mouse was moved
 285         ;; since the last key-press but without generating any event.
 286         (and (consp last-input-event)
 287              (symbolp (car last-input-event))
 288              (let ((modifiers (event-modifiers (car last-input-event))))
 289                (or (memq (car last-input-event)
 290                          '(mouse-movement scroll-bar-movement
 291                            select-window switch-frame))
 292                    (memq 'click modifiers)
 293                    (memq 'double modifiers)
 294                    (memq 'triple modifiers)
 295                    (memq 'drag modifiers)
 296                    (memq 'down modifiers)))))))
 297
 298 (defun mouse-avoidance-banish ()
 299   (if (not (mouse-avoidance-ignore-p))
 300       (mouse-avoidance-banish-mouse)))
 301
 302 (defun mouse-avoidance-exile ()
 303   ;; For exile mode, the state is nil when the mouse is in its normal
 304   ;; position, and set to the old mouse-position when the mouse is in exile.
 305   (if (not (mouse-avoidance-ignore-p))
 306       (let ((mp (mouse-position)))
 307         (cond ((and (not mouse-avoidance-state)
 308                     (mouse-avoidance-too-close-p mp))
 309                (setq mouse-avoidance-state mp)
 310                (mouse-avoidance-banish-mouse))
 311               ((and mouse-avoidance-state
 312                     (not (mouse-avoidance-too-close-p mouse-avoidance-state)))
 313                (if (and (eq (car mp) (selected-frame))
 314                         (equal (cdr mp) (mouse-avoidance-banish-destination)))
 315                    (mouse-avoidance-set-mouse-position
 316                     ;; move back only if user has not moved mouse
 317                     (cdr mouse-avoidance-state)))
 318                ;; but clear state anyway, to be ready for another move
 319                (setq mouse-avoidance-state nil))))))
 320
 321 (defun mouse-avoidance-fancy ()
 322   ;; Used for the "fancy" modes, ie jump et al.
 323   (if (and (not mouse-avoidance-animating-pointer)
 324            (not (mouse-avoidance-ignore-p))
 325            (mouse-avoidance-too-close-p (mouse-position)))
 326       (let ((old-pos (mouse-position)))
 327         (mouse-avoidance-nudge-mouse)
 328         (if (not (eq (selected-frame) (car old-pos)))
 329             ;; This should never happen.
 330             (apply 'set-mouse-position old-pos)))))
 331
 332 ;;;###autoload
 333 (defun mouse-avoidance-mode (&optional mode)
 334   "Set Mouse Avoidance mode to MODE.
 335 MODE should be one of the symbols `banish', `exile', `jump', `animate',
 336 `cat-and-mouse', `proteus', or `none'.
 337
 338 If MODE is nil, toggle mouse avoidance between `none' and `banish'
 339 modes.  Positive numbers and symbols other than the above are treated
 340 as equivalent to `banish'; negative numbers and `-' are equivalent to `none'.
 341
 342 Effects of the different modes:
 343  * banish: Move the mouse to the upper-right corner on any keypress.
 344  * exile: Move the mouse to the corner only if the cursor gets too close,
 345      and allow it to return once the cursor is out of the way.
 346  * jump: If the cursor gets too close to the mouse, displace the mouse
 347      a random distance & direction.
 348  * animate: As `jump', but shows steps along the way for illusion of motion.
 349  * cat-and-mouse: Same as `animate'.
 350  * proteus: As `animate', but changes the shape of the mouse pointer too.
 351
 352 Whenever the mouse is moved, the frame is also raised.
 353
 354 \(See `mouse-avoidance-threshold' for definition of \"too close\",
 355 and `mouse-avoidance-nudge-dist' and `mouse-avoidance-nudge-var' for
 356 definition of \"random distance\".)"
 357   (interactive
 358    (list (intern (completing-read
 359                   "Select cursor avoidance technique (SPACE for list): "
 360                   '(("banish") ("exile") ("jump") ("animate")
 361                     ("cat-and-mouse") ("proteus") ("none"))
 362                   nil t))))
 363   (if (eq mode 'cat-and-mouse)
 364       (setq mode 'animate))
 365   (if mouse-avoidance-timer
 366       (cancel-timer mouse-avoidance-timer))
 367   (setq mouse-avoidance-timer nil)
 368
 369   ;; Restore pointer shape if necessary
 370   (if (eq mouse-avoidance-mode 'proteus)
 371       (mouse-avoidance-set-pointer-shape mouse-avoidance-old-pointer-shape))
 372
 373   ;; Do additional setup depending on version of mode requested
 374   (cond ((eq mode 'none)
 375          (setq mouse-avoidance-mode nil))
 376         ((or (eq mode 'jump)
 377              (eq mode 'animate)
 378              (eq mode 'proteus))
 379          (setq mouse-avoidance-timer
 380                (run-with-idle-timer 0.1 t 'mouse-avoidance-fancy))
 381          (setq mouse-avoidance-mode mode
 382                mouse-avoidance-state (cons 0 0)
 383                mouse-avoidance-old-pointer-shape
 384                (and (boundp 'x-pointer-shape) x-pointer-shape)))
 385         ((eq mode 'exile)
 386          (setq mouse-avoidance-timer
 387                (run-with-idle-timer 0.1 t 'mouse-avoidance-exile))
 388          (setq mouse-avoidance-mode mode
 389                mouse-avoidance-state nil))
 390         ((or (eq mode 'banish)
 391              (eq mode t)
 392              (and (null mode) (null mouse-avoidance-mode))
 393              (and mode (> (prefix-numeric-value mode) 0)))
 394          (setq mouse-avoidance-timer
 395                (run-with-idle-timer 0.1 t 'mouse-avoidance-banish))
 396          (setq mouse-avoidance-mode 'banish))
 397         (t (setq mouse-avoidance-mode nil)))
 398   (force-mode-line-update))
 399
 400 ;; Most people who use avoid mode leave it on all the time, so it's not
 401 ;; very informative to announce it in the mode line.
 402 ;;(or (assq 'mouse-avoidance-mode minor-mode-alist)
 403 ;;    (setq minor-mode-alist (cons '(mouse-avoidance-mode " Avoid")
 404 ;;                               minor-mode-alist)))
 405
 406 ;; Needed for custom.
 407 (if mouse-avoidance-mode
 408     (mouse-avoidance-mode mouse-avoidance-mode))
 409
 410 ;; arch-tag: 64ad4ef8-a870-4183-8d96-3aa93b7a6800
 411 ;;; avoid.el ends here