code.delx.au - gnu-emacs/blob - test/lisp/emacs-lisp/map-tests.el

   1 ;;; map-tests.el --- Tests for map.el  -*- lexical-binding:t -*-
   2
   3 ;; Copyright (C) 2015-2016 Free Software Foundation, Inc.
   4
   5 ;; Author: Nicolas Petton <nicolas@petton.fr>
   6 ;; Maintainer: emacs-devel@gnu.org
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; Tests for map.el
  26
  27 ;;; Code:
  28
  29 (require 'ert)
  30 (require 'map)
  31
  32 (defmacro with-maps-do (var &rest body)
  33   "Successively bind VAR to an alist, vector and hash-table.
  34 Each map is built from the following alist data:
  35 '((0 . 3) (1 . 4) (2 . 5)).
  36 Evaluate BODY for each created map.
  37
  38 \(fn (var map) body)"
  39   (declare (indent 1) (debug t))
  40   (let ((alist (make-symbol "alist"))
  41         (vec (make-symbol "vec"))
  42         (ht (make-symbol "ht")))
  43    `(let ((,alist (list (cons 0 3)
  44                         (cons 1 4)
  45                         (cons 2 5)))
  46           (,vec (vector 3 4 5))
  47           (,ht (make-hash-table)))
  48       (puthash 0 3 ,ht)
  49       (puthash 1 4 ,ht)
  50       (puthash 2 5 ,ht)
  51       (dolist (,var (list ,alist ,vec ,ht))
  52         ,@body))))
  53
  54 (ert-deftest test-map-elt ()
  55   (with-maps-do map
  56     (should (= 3 (map-elt map 0)))
  57     (should (= 4 (map-elt map 1)))
  58     (should (= 5 (map-elt map 2)))
  59     (should (null (map-elt map -1)))
  60     (should (null (map-elt map 4)))))
  61
  62 (ert-deftest test-map-elt-default ()
  63   (with-maps-do map
  64     (should (= 5 (map-elt map 7 5)))))
  65
  66 (ert-deftest test-map-elt-with-nil-value ()
  67   (should (null (map-elt '((a . 1)
  68                            (b))
  69                          'b
  70                          '2))))
  71
  72 (ert-deftest test-map-put ()
  73   (with-maps-do map
  74     (setf (map-elt map 2) 'hello)
  75     (should (eq (map-elt map 2) 'hello)))
  76   (with-maps-do map
  77     (map-put map 2 'hello)
  78     (should (eq (map-elt map 2) 'hello)))
  79   (let ((ht (make-hash-table)))
  80     (setf (map-elt ht 2) 'a)
  81     (should (eq (map-elt ht 2)
  82                 'a)))
  83   (let ((alist '((0 . a) (1 . b) (2 . c))))
  84     (setf (map-elt alist 2) 'a)
  85     (should (eq (map-elt alist 2)
  86                 'a)))
  87   (let ((vec [3 4 5]))
  88    (should-error (setf (map-elt vec 3) 6))))
  89
  90 (ert-deftest test-map-put-alist-new-key ()
  91   "Regression test for Bug#23105."
  92   (let ((alist '((0 . a))))
  93     (map-put alist 2 'b)
  94     (should (eq (map-elt alist 2)
  95                 'b))))
  96
  97 (ert-deftest test-map-put-return-value ()
  98   (let ((ht (make-hash-table)))
  99     (should (eq (map-put ht 'a 'hello) 'hello))))
 100
 101 (ert-deftest test-map-delete ()
 102   (with-maps-do map
 103     (map-delete map 1)
 104     (should (null (map-elt map 1))))
 105   (with-maps-do map
 106     (map-delete map -2)
 107     (should (null (map-elt map -2)))))
 108
 109 (ert-deftest test-map-delete-return-value ()
 110   (let ((ht (make-hash-table)))
 111     (should (eq (map-delete ht 'a) ht))))
 112
 113 (ert-deftest test-map-nested-elt ()
 114   (let ((vec [a b [c d [e f]]]))
 115     (should (eq (map-nested-elt vec '(2 2 0)) 'e)))
 116   (let ((alist '((a . 1)
 117                  (b . ((c . 2)
 118                        (d . 3)
 119                        (e . ((f . 4)
 120                              (g . 5))))))))
 121     (should (eq (map-nested-elt alist '(b e f))
 122                 4)))
 123   (let ((ht (make-hash-table)))
 124     (setf (map-elt ht 'a) 1)
 125     (setf (map-elt ht 'b) (make-hash-table))
 126     (setf (map-elt (map-elt ht 'b) 'c) 2)
 127     (should (eq (map-nested-elt ht '(b c))
 128                 2))))
 129
 130 (ert-deftest test-map-nested-elt-default ()
 131   (let ((vec [a b [c d]]))
 132     (should (null (map-nested-elt vec '(2 3))))
 133     (should (null (map-nested-elt vec '(2 1 1))))
 134     (should (= 4 (map-nested-elt vec '(2 1 1) 4)))))
 135
 136 (ert-deftest test-mapp ()
 137   (should (mapp nil))
 138   (should (mapp '((a . b) (c . d))))
 139   (should (mapp '(a b c d)))
 140   (should (mapp []))
 141   (should (mapp [1 2 3]))
 142   (should (mapp (make-hash-table)))
 143   (should (mapp "hello"))
 144   (should (not (mapp 1)))
 145   (should (not (mapp 'hello))))
 146
 147 (ert-deftest test-map-keys ()
 148   (with-maps-do map
 149     (should (equal (map-keys map) '(0 1 2))))
 150   (should (null (map-keys nil)))
 151   (should (null (map-keys []))))
 152
 153 (ert-deftest test-map-values ()
 154   (with-maps-do map
 155     (should (equal (map-values map) '(3 4 5)))))
 156
 157 (ert-deftest test-map-pairs ()
 158   (with-maps-do map
 159     (should (equal (map-pairs map) '((0 . 3)
 160                                      (1 . 4)
 161                                      (2 . 5))))))
 162
 163 (ert-deftest test-map-length ()
 164   (let ((ht (make-hash-table)))
 165     (puthash 'a 1 ht)
 166     (puthash 'b 2 ht)
 167     (puthash 'c 3 ht)
 168     (puthash 'd 4 ht)
 169     (should (= 0 (map-length nil)))
 170     (should (= 0 (map-length [])))
 171     (should (= 0 (map-length (make-hash-table))))
 172     (should (= 5 (map-length [0 1 2 3 4])))
 173     (should (= 2 (map-length '((a . 1) (b . 2)))))
 174     (should (= 4 (map-length ht)))))
 175
 176 (ert-deftest test-map-copy ()
 177   (with-maps-do map
 178     (let ((copy (map-copy map)))
 179       (should (equal (map-keys map) (map-keys copy)))
 180       (should (equal (map-values map) (map-values copy)))
 181       (should (not (eq map copy))))))
 182
 183 (ert-deftest test-map-apply ()
 184   (with-maps-do map
 185     (should (equal (map-apply (lambda (k v) (cons (int-to-string k) v))
 186                               map)
 187                    '(("0" . 3) ("1" . 4) ("2" . 5)))))
 188   (let ((vec [a b c]))
 189     (should (equal (map-apply (lambda (k v) (cons (1+ k) v))
 190                               vec)
 191                    '((1 . a)
 192                      (2 . b)
 193                      (3 . c))))))
 194
 195 (ert-deftest test-map-keys-apply ()
 196   (with-maps-do map
 197     (should (equal (map-keys-apply (lambda (k) (int-to-string k))
 198                                    map)
 199                    '("0" "1" "2"))))
 200   (let ((vec [a b c]))
 201     (should (equal (map-keys-apply (lambda (k) (1+ k))
 202                                    vec)
 203                    '(1 2 3)))))
 204
 205 (ert-deftest test-map-values-apply ()
 206   (with-maps-do map
 207     (should (equal (map-values-apply (lambda (v) (1+ v))
 208                                      map)
 209                    '(4 5 6))))
 210   (let ((vec [a b c]))
 211     (should (equal (map-values-apply (lambda (v) (symbol-name v))
 212                                      vec)
 213                    '("a" "b" "c")))))
 214
 215 (ert-deftest test-map-filter ()
 216   (with-maps-do map
 217     (should (equal (map-keys (map-filter (lambda (_k v)
 218                                            (<= 4 v))
 219                                          map))
 220                    '(1 2)))
 221     (should (null (map-filter (lambda (k _v)
 222                                 (eq 'd k))
 223                               map))))
 224   (should (null (map-filter (lambda (_k v)
 225                               (eq 3 v))
 226                             [1 2 4 5])))
 227   (should (equal (map-filter (lambda (k _v)
 228                                (eq 3 k))
 229                              [1 2 4 5])
 230                  '((3 . 5)))))
 231
 232 (ert-deftest test-map-remove ()
 233   (with-maps-do map
 234     (should (equal (map-keys (map-remove (lambda (_k v)
 235                                            (>= v 4))
 236                                          map))
 237                    '(0)))
 238     (should (equal (map-keys (map-remove (lambda (k _v)
 239                                            (eq 'd k))
 240                                          map))
 241                    (map-keys map))))
 242   (should (equal (map-remove (lambda (_k v)
 243                                (eq 3 v))
 244                              [1 2 4 5])
 245                  '((0 . 1)
 246                    (1 . 2)
 247                    (2 . 4)
 248                    (3 . 5))))
 249   (should (null (map-remove (lambda (k _v)
 250                               (>= k 0))
 251                             [1 2 4 5]))))
 252
 253 (ert-deftest test-map-empty-p ()
 254   (should (map-empty-p nil))
 255   (should (not (map-empty-p '((a . b) (c . d)))))
 256   (should (map-empty-p []))
 257   (should (not (map-empty-p [1 2 3])))
 258   (should (map-empty-p (make-hash-table)))
 259   (should (not (map-empty-p "hello")))
 260   (should (map-empty-p "")))
 261
 262 (ert-deftest test-map-contains-key ()
 263   (should (map-contains-key '((a . 1) (b . 2)) 'a))
 264   (should (not (map-contains-key '((a . 1) (b . 2)) 'c)))
 265   (should (map-contains-key '(("a" . 1)) "a"))
 266   (should (not (map-contains-key '(("a" . 1)) "a" #'eq)))
 267   (should (map-contains-key [a b c] 2))
 268   (should (not (map-contains-key [a b c] 3))))
 269
 270 (ert-deftest test-map-some ()
 271   (with-maps-do map
 272     (should (map-some (lambda (k _v)
 273                         (eq 1 k))
 274                       map))
 275     (should-not (map-some (lambda (k _v)
 276                             (eq 'd k))
 277                           map)))
 278   (let ((vec [a b c]))
 279     (should (map-some (lambda (k _v)
 280                         (> k 1))
 281                       vec))
 282     (should-not (map-some (lambda (k _v)
 283                             (> k 3))
 284                           vec))))
 285
 286 (ert-deftest test-map-every-p ()
 287   (with-maps-do map
 288     (should (map-every-p (lambda (k _v)
 289                            k)
 290                          map))
 291     (should (not (map-every-p (lambda (_k _v)
 292                                 nil)
 293                               map))))
 294   (let ((vec [a b c]))
 295     (should (map-every-p (lambda (k _v)
 296                            (>= k 0))
 297                          vec))
 298     (should (not (map-every-p (lambda (k _v)
 299                                 (> k 3))
 300                               vec)))))
 301
 302 (ert-deftest test-map-into ()
 303   (let* ((alist '((a . 1) (b . 2)))
 304          (ht (map-into alist 'hash-table)))
 305     (should (hash-table-p ht))
 306     (should (equal (map-into (map-into alist 'hash-table) 'list)
 307                    alist))
 308     (should (listp (map-into ht 'list)))
 309     (should (equal (map-keys (map-into (map-into ht 'list) 'hash-table))
 310                    (map-keys ht)))
 311     (should (equal (map-values (map-into (map-into ht 'list) 'hash-table))
 312                    (map-values ht)))
 313     (should (null (map-into nil 'list)))
 314     (should (map-empty-p (map-into nil 'hash-table)))
 315     (should-error (map-into [1 2 3] 'string))))
 316
 317 (ert-deftest test-map-let ()
 318   (map-let (foo bar baz) '((foo . 1) (bar . 2))
 319     (should (= foo 1))
 320     (should (= bar 2))
 321     (should (null baz)))
 322   (map-let (('foo a)
 323             ('bar b)
 324             ('baz c))
 325       '((foo . 1) (bar . 2))
 326     (should (= a 1))
 327     (should (= b 2))
 328     (should (null c))))
 329
 330 (ert-deftest test-map-merge-with ()
 331   (should (equal (map-merge-with 'list #'+
 332                                  '((1 . 2))
 333                                  '((1 . 3) (2 . 4))
 334                                  '((1 . 1) (2 . 5) (3 . 0)))
 335                  '((3 . 0) (2 . 9) (1 . 6)))))
 336
 337 (provide 'map-tests)
 338 ;;; map-tests.el ends here