code.delx.au - gnu-emacs/blob - lisp/image-mode.el

   1 ;;; image-mode.el --- support for visiting image files  -*- lexical-binding: t -*-
   2 ;;
   3 ;; Copyright (C) 2005-2013 Free Software Foundation, Inc.
   4 ;;
   5 ;; Author: Richard Stallman <rms@gnu.org>
   6 ;; Keywords: multimedia
   7 ;; Package: emacs
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; Defines a major mode for visiting image files
  27 ;; that allows conversion between viewing the text of the file
  28 ;; and viewing the file as an image.  Viewing the image
  29 ;; works by putting a `display' text-property on the
  30 ;; image data, with the image-data still present underneath; if the
  31 ;; resulting buffer file is saved to another name it will correctly save
  32 ;; the image data to the new file.
  33
  34 ;; Todo:
  35
  36 ;; Consolidate with doc-view to make them work on directories of images or on
  37 ;; image files containing various "pages".
  38
  39 ;;; Code:
  40
  41 (require 'image)
  42 (eval-when-compile (require 'cl-lib))
  43
  44 ;;; Image mode window-info management.
  45
  46 (defvar-local image-mode-winprops-alist t)
  47
  48 (defvar image-mode-new-window-functions nil
  49   "Special hook run when image data is requested in a new window.
  50 It is called with one argument, the initial WINPROPS.")
  51
  52 (defun image-mode-winprops (&optional window cleanup)
  53   "Return winprops of WINDOW.
  54 A winprops object has the shape (WINDOW . ALIST).
  55 WINDOW defaults to `selected-window' if it displays the current buffer, and
  56 otherwise it defaults to t, used for times when the buffer is not displayed."
  57   (cond ((null window)
  58          (setq window
  59                (if (eq (current-buffer) (window-buffer)) (selected-window) t)))
  60         ((eq window t))
  61         ((not (windowp window))
  62          (error "Not a window: %s" window)))
  63   (when cleanup
  64     (setq image-mode-winprops-alist
  65           (delq nil (mapcar (lambda (winprop)
  66                               (let ((w (car-safe winprop)))
  67                                 (if (or (not (windowp w)) (window-live-p w))
  68                                     winprop)))
  69                             image-mode-winprops-alist))))
  70   (let ((winprops (assq window image-mode-winprops-alist)))
  71     ;; For new windows, set defaults from the latest.
  72     (unless winprops
  73       (setq winprops (cons window
  74                            (copy-alist (cdar image-mode-winprops-alist))))
  75       (run-hook-with-args 'image-mode-new-window-functions winprops))
  76     ;; Move window to front.
  77     (setq image-mode-winprops-alist
  78           (cons winprops (delq winprops image-mode-winprops-alist)))
  79     winprops))
  80
  81 (defun image-mode-window-get (prop &optional winprops)
  82   (declare (gv-setter (lambda (val)
  83                         `(image-mode-window-put ,prop ,val ,winprops))))
  84   (unless (consp winprops) (setq winprops (image-mode-winprops winprops)))
  85   (cdr (assq prop (cdr winprops))))
  86
  87 (defun image-mode-window-put (prop val &optional winprops)
  88   (unless (consp winprops) (setq winprops (image-mode-winprops winprops)))
  89   (setcdr winprops (cons (cons prop val)
  90                          (delq (assq prop (cdr winprops)) (cdr winprops)))))
  91
  92 (defun image-set-window-vscroll (vscroll)
  93   (setf (image-mode-window-get 'vscroll) vscroll)
  94   (set-window-vscroll (selected-window) vscroll))
  95
  96 (defun image-set-window-hscroll (ncol)
  97   (setf (image-mode-window-get 'hscroll) ncol)
  98   (set-window-hscroll (selected-window) ncol))
  99
 100 (defun image-mode-reapply-winprops ()
 101   ;; When set-window-buffer, set hscroll and vscroll to what they were
 102   ;; last time the image was displayed in this window.
 103   (when (and (image-get-display-property)
 104              (listp image-mode-winprops-alist))
 105     (let* ((winprops (image-mode-winprops nil t))
 106            (hscroll (image-mode-window-get 'hscroll winprops))
 107            (vscroll (image-mode-window-get 'vscroll winprops)))
 108       (if hscroll (set-window-hscroll (selected-window) hscroll))
 109       (if vscroll (set-window-vscroll (selected-window) vscroll)))))
 110
 111 (defun image-mode-setup-winprops ()
 112   ;; Record current scroll settings.
 113   (unless (listp image-mode-winprops-alist)
 114     (setq image-mode-winprops-alist nil))
 115   (add-hook 'window-configuration-change-hook
 116             'image-mode-reapply-winprops nil t))
 117
 118 ;;; Image scrolling functions
 119
 120 (defun image-get-display-property ()
 121   (get-char-property (point-min) 'display
 122                      ;; There might be different images for different displays.
 123                      (if (eq (window-buffer) (current-buffer))
 124                          (selected-window))))
 125
 126 (declare-function image-size "image.c" (spec &optional pixels frame))
 127
 128 (defun image-display-size (spec &optional pixels frame)
 129   "Wrapper around `image-size', handling slice display properties.
 130 Like `image-size', the return value is (WIDTH . HEIGHT).
 131 WIDTH and HEIGHT are in canonical character units if PIXELS is
 132 nil, and in pixel units if PIXELS is non-nil.
 133
 134 If SPEC is an image display property, this function is equivalent
 135 to `image-size'.  If SPEC is a list of properties containing
 136 `image' and `slice' properties, return the display size taking
 137 the slice property into account.  If the list contains `image'
 138 but not `slice', return the `image-size' of the specified image."
 139   (if (eq (car spec) 'image)
 140       (image-size spec pixels frame)
 141     (let ((image (assoc 'image spec))
 142           (slice (assoc 'slice spec)))
 143       (cond ((and image slice)
 144              (if pixels
 145                  (cons (nth 3 slice) (nth 4 slice))
 146                (cons (/ (float (nth 3 slice)) (frame-char-width frame))
 147                      (/ (float (nth 4 slice)) (frame-char-height frame)))))
 148             (image
 149              (image-size image pixels frame))
 150             (t
 151              (error "Invalid image specification: %s" spec))))))
 152
 153 (defun image-forward-hscroll (&optional n)
 154   "Scroll image in current window to the left by N character widths.
 155 Stop if the right edge of the image is reached."
 156   (interactive "p")
 157   (cond ((= n 0) nil)
 158         ((< n 0)
 159          (image-set-window-hscroll (max 0 (+ (window-hscroll) n))))
 160         (t
 161          (let* ((image (image-get-display-property))
 162                 (edges (window-inside-edges))
 163                 (win-width (- (nth 2 edges) (nth 0 edges)))
 164                 (img-width (ceiling (car (image-display-size image)))))
 165            (image-set-window-hscroll (min (max 0 (- img-width win-width))
 166                                           (+ n (window-hscroll))))))))
 167
 168 (defun image-backward-hscroll (&optional n)
 169   "Scroll image in current window to the right by N character widths.
 170 Stop if the left edge of the image is reached."
 171   (interactive "p")
 172   (image-forward-hscroll (- n)))
 173
 174 (defun image-next-line (n)
 175   "Scroll image in current window upward by N lines.
 176 Stop if the bottom edge of the image is reached."
 177   (interactive "p")
 178   (cond ((= n 0) nil)
 179         ((< n 0)
 180          (image-set-window-vscroll (max 0 (+ (window-vscroll) n))))
 181         (t
 182          (let* ((image (image-get-display-property))
 183                 (edges (window-inside-edges))
 184                 (win-height (- (nth 3 edges) (nth 1 edges)))
 185                 (img-height (ceiling (cdr (image-display-size image)))))
 186            (image-set-window-vscroll (min (max 0 (- img-height win-height))
 187                                           (+ n (window-vscroll))))))))
 188
 189 (defun image-previous-line (&optional n)
 190   "Scroll image in current window downward by N lines.
 191 Stop if the top edge of the image is reached."
 192   (interactive "p")
 193   (image-next-line (- n)))
 194
 195 (defun image-scroll-up (&optional n)
 196   "Scroll image in current window upward by N lines.
 197 Stop if the bottom edge of the image is reached.
 198 If ARG is omitted or nil, scroll upward by a near full screen.
 199 A near full screen is `next-screen-context-lines' less than a full screen.
 200 Negative ARG means scroll downward.
 201 If ARG is the atom `-', scroll downward by nearly full screen.
 202 When calling from a program, supply as argument a number, nil, or `-'."
 203   (interactive "P")
 204   (cond ((null n)
 205          (let* ((edges (window-inside-edges))
 206                 (win-height (- (nth 3 edges) (nth 1 edges))))
 207            (image-next-line
 208             (max 0 (- win-height next-screen-context-lines)))))
 209         ((eq n '-)
 210          (let* ((edges (window-inside-edges))
 211                 (win-height (- (nth 3 edges) (nth 1 edges))))
 212            (image-next-line
 213             (min 0 (- next-screen-context-lines win-height)))))
 214         (t (image-next-line (prefix-numeric-value n)))))
 215
 216 (defun image-scroll-down (&optional n)
 217   "Scroll image in current window downward by N lines.
 218 Stop if the top edge of the image is reached.
 219 If ARG is omitted or nil, scroll downward by a near full screen.
 220 A near full screen is `next-screen-context-lines' less than a full screen.
 221 Negative ARG means scroll upward.
 222 If ARG is the atom `-', scroll upward by nearly full screen.
 223 When calling from a program, supply as argument a number, nil, or `-'."
 224   (interactive "P")
 225   (cond ((null n)
 226          (let* ((edges (window-inside-edges))
 227                 (win-height (- (nth 3 edges) (nth 1 edges))))
 228            (image-next-line
 229             (min 0 (- next-screen-context-lines win-height)))))
 230         ((eq n '-)
 231          (let* ((edges (window-inside-edges))
 232                 (win-height (- (nth 3 edges) (nth 1 edges))))
 233            (image-next-line
 234             (max 0 (- win-height next-screen-context-lines)))))
 235         (t (image-next-line (- (prefix-numeric-value n))))))
 236
 237 (defun image-bol (arg)
 238   "Scroll horizontally to the left edge of the image in the current window.
 239 With argument ARG not nil or 1, move forward ARG - 1 lines first,
 240 stopping if the top or bottom edge of the image is reached."
 241   (interactive "p")
 242   (and arg
 243        (/= (setq arg (prefix-numeric-value arg)) 1)
 244        (image-next-line (- arg 1)))
 245   (image-set-window-hscroll 0))
 246
 247 (defun image-eol (arg)
 248   "Scroll horizontally to the right edge of the image in the current window.
 249 With argument ARG not nil or 1, move forward ARG - 1 lines first,
 250 stopping if the top or bottom edge of the image is reached."
 251   (interactive "p")
 252   (and arg
 253        (/= (setq arg (prefix-numeric-value arg)) 1)
 254        (image-next-line (- arg 1)))
 255   (let* ((image (image-get-display-property))
 256          (edges (window-inside-edges))
 257          (win-width (- (nth 2 edges) (nth 0 edges)))
 258          (img-width (ceiling (car (image-display-size image)))))
 259     (image-set-window-hscroll (max 0 (- img-width win-width)))))
 260
 261 (defun image-bob ()
 262   "Scroll to the top-left corner of the image in the current window."
 263   (interactive)
 264   (image-set-window-hscroll 0)
 265   (image-set-window-vscroll 0))
 266
 267 (defun image-eob ()
 268   "Scroll to the bottom-right corner of the image in the current window."
 269   (interactive)
 270   (let* ((image (image-get-display-property))
 271          (edges (window-inside-edges))
 272          (win-width (- (nth 2 edges) (nth 0 edges)))
 273          (img-width (ceiling (car (image-display-size image))))
 274          (win-height (- (nth 3 edges) (nth 1 edges)))
 275          (img-height (ceiling (cdr (image-display-size image)))))
 276     (image-set-window-hscroll (max 0 (- img-width win-width)))
 277     (image-set-window-vscroll (max 0 (- img-height win-height)))))
 278
 279 ;; Adjust frame and image size.
 280
 281 (defun image-mode-fit-frame (&optional frame toggle)
 282   "Fit FRAME to the current image.
 283 If FRAME is omitted or nil, it defaults to the selected frame.
 284 All other windows on the frame are deleted.
 285
 286 If called interactively, or if TOGGLE is non-nil, toggle between
 287 fitting FRAME to the current image and restoring the size and
 288 window configuration prior to the last `image-mode-fit-frame'
 289 call."
 290   (interactive (list nil t))
 291   (let* ((buffer (current-buffer))
 292          (display (image-get-display-property))
 293          (size (image-display-size display))
 294          (saved (frame-parameter frame 'image-mode-saved-params))
 295          (window-configuration (current-window-configuration frame))
 296          (width  (frame-width  frame))
 297          (height (frame-height frame)))
 298     (with-selected-frame (or frame (selected-frame))
 299       (if (and toggle saved
 300                (= (caar saved) width)
 301                (= (cdar saved) height))
 302           (progn
 303             (set-frame-width  frame (car (nth 1 saved)))
 304             (set-frame-height frame (cdr (nth 1 saved)))
 305             (set-window-configuration (nth 2 saved))
 306             (set-frame-parameter frame 'image-mode-saved-params nil))
 307         (delete-other-windows)
 308         (switch-to-buffer buffer t t)
 309         (let* ((edges (window-inside-edges))
 310                (inner-width  (- (nth 2 edges) (nth 0 edges)))
 311                (inner-height (- (nth 3 edges) (nth 1 edges))))
 312           (set-frame-width  frame (+ (ceiling (car size))
 313                                      width (- inner-width)))
 314           (set-frame-height frame (+ (ceiling (cdr size))
 315                                      height (- inner-height)))
 316           ;; The frame size after the above `set-frame-*' calls may
 317           ;; differ from what we specified, due to window manager
 318           ;; interference.  We have to call `frame-width' and
 319           ;; `frame-height' to get the actual results.
 320           (set-frame-parameter frame 'image-mode-saved-params
 321                                (list (cons (frame-width)
 322                                            (frame-height))
 323                                      (cons width height)
 324                                      window-configuration)))))))
 325
 326 ;;; Image Mode setup
 327
 328 (defvar image-type nil
 329   "The image type for the current Image mode buffer.")
 330 (make-variable-buffer-local 'image-type)
 331
 332 (defvar-local image-multi-frame nil
 333   "Non-nil if image for the current Image mode buffer has multiple frames.")
 334
 335 (defvar image-mode-previous-major-mode nil
 336   "Internal variable to keep the previous non-image major mode.")
 337
 338 (defvar image-mode-map
 339   (let ((map (make-sparse-keymap)))
 340     (set-keymap-parent map special-mode-map)
 341     (define-key map "\C-c\C-c" 'image-toggle-display)
 342     (define-key map (kbd "SPC")       'image-scroll-up)
 343     (define-key map (kbd "S-SPC")     'image-scroll-down)
 344     (define-key map (kbd "DEL")       'image-scroll-down)
 345     (define-key map (kbd "RET")       'image-toggle-animation)
 346     (define-key map "F" 'image-goto-frame)
 347     (define-key map "f" 'image-next-frame)
 348     (define-key map "b" 'image-previous-frame)
 349     (define-key map "n" 'image-next-file)
 350     (define-key map "p" 'image-previous-file)
 351     (define-key map [remap forward-char] 'image-forward-hscroll)
 352     (define-key map [remap backward-char] 'image-backward-hscroll)
 353     (define-key map [remap right-char] 'image-forward-hscroll)
 354     (define-key map [remap left-char] 'image-backward-hscroll)
 355     (define-key map [remap previous-line] 'image-previous-line)
 356     (define-key map [remap next-line] 'image-next-line)
 357     (define-key map [remap scroll-up] 'image-scroll-up)
 358     (define-key map [remap scroll-down] 'image-scroll-down)
 359     (define-key map [remap scroll-up-command] 'image-scroll-up)
 360     (define-key map [remap scroll-down-command] 'image-scroll-down)
 361     (define-key map [remap move-beginning-of-line] 'image-bol)
 362     (define-key map [remap move-end-of-line] 'image-eol)
 363     (define-key map [remap beginning-of-buffer] 'image-bob)
 364     (define-key map [remap end-of-buffer] 'image-eob)
 365     (easy-menu-define image-mode-menu map "Menu for Image mode."
 366       '("Image"
 367         ["Show as Text" image-toggle-display :active t
 368          :help "Show image as text"]
 369         "--"
 370         ["Fit Frame to Image" image-mode-fit-frame :active t
 371          :help "Resize frame to match image"]
 372         ["Fit to Window Height" image-transform-fit-to-height
 373          :visible (eq image-type 'imagemagick)
 374          :help "Resize image to match the window height"]
 375         ["Fit to Window Width" image-transform-fit-to-width
 376          :visible (eq image-type 'imagemagick)
 377          :help "Resize image to match the window width"]
 378         ["Rotate Image..." image-transform-set-rotation
 379          :visible (eq image-type 'imagemagick)
 380          :help "Rotate the image"]
 381         "--"
 382         ["Show Thumbnails"
 383          (lambda ()
 384            (interactive)
 385            (image-dired default-directory))
 386          :active default-directory
 387          :help "Show thumbnails for all images in this directory"]
 388         ["Next Image" image-next-file :active buffer-file-name
 389          :help "Move to next image in this directory"]
 390         ["Previous Image" image-previous-file :active buffer-file-name
 391          :help "Move to previous image in this directory"]
 392         "--"
 393         ["Animate Image" image-toggle-animation :style toggle
 394          :selected (let ((image (image-get-display-property)))
 395                      (and image (image-animate-timer image)))
 396          :active image-multi-frame
 397          :help "Toggle image animation"]
 398         ["Loop Animation"
 399          (lambda () (interactive)
 400 ;;;        (make-variable-buffer-local 'image-animate-loop)
 401            (setq image-animate-loop (not image-animate-loop))
 402            ;; FIXME this is a hacky way to make it affect a currently
 403            ;; animating image.
 404            (when (let ((image (image-get-display-property)))
 405                    (and image (image-animate-timer image)))
 406              (image-toggle-animation)
 407              (image-toggle-animation)))
 408          :style toggle :selected image-animate-loop
 409          :active image-multi-frame
 410          :help "Animate images once, or forever?"]
 411         ["Next Frame" image-next-frame :active image-multi-frame
 412          :help "Show the next frame of this image"]
 413         ["Previous Frame" image-previous-frame :active image-multi-frame
 414          :help "Show the previous frame of this image"]
 415         ["Goto Frame..." image-goto-frame :active image-multi-frame
 416          :help "Show a specific frame of this image"]
 417         ))
 418     map)
 419   "Mode keymap for `image-mode'.")
 420
 421 (defvar image-minor-mode-map
 422   (let ((map (make-sparse-keymap)))
 423     (define-key map "\C-c\C-c" 'image-toggle-display)
 424     map)
 425   "Mode keymap for `image-minor-mode'.")
 426
 427 (defvar bookmark-make-record-function)
 428
 429 (put 'image-mode 'mode-class 'special)
 430
 431 ;;;###autoload
 432 (defun image-mode ()
 433   "Major mode for image files.
 434 You can use \\<image-mode-map>\\[image-toggle-display]
 435 to toggle between display as an image and display as text."
 436   (interactive)
 437   (condition-case err
 438       (progn
 439         (unless (display-images-p)
 440           (error "Display does not support images"))
 441
 442         (kill-all-local-variables)
 443         (setq major-mode 'image-mode)
 444
 445         (if (not (image-get-display-property))
 446             (progn
 447               (image-toggle-display-image)
 448               ;; If attempt to display the image fails.
 449               (if (not (image-get-display-property))
 450                   (error "Invalid image")))
 451           ;; Set next vars when image is already displayed but local
 452           ;; variables were cleared by kill-all-local-variables
 453           (setq cursor-type nil truncate-lines t
 454                 image-type (plist-get (cdr (image-get-display-property)) :type)))
 455
 456         (setq mode-name (if image-type (format "Image[%s]" image-type) "Image"))
 457         (use-local-map image-mode-map)
 458
 459         ;; Use our own bookmarking function for images.
 460         (set (make-local-variable 'bookmark-make-record-function)
 461              'image-bookmark-make-record)
 462
 463         ;; Keep track of [vh]scroll when switching buffers
 464         (image-mode-setup-winprops)
 465
 466         (add-hook 'change-major-mode-hook 'image-toggle-display-text nil t)
 467         (add-hook 'after-revert-hook 'image-after-revert-hook nil t)
 468         (run-mode-hooks 'image-mode-hook)
 469         (let ((image (image-get-display-property))
 470               (msg1 (substitute-command-keys
 471                      "Type \\[image-toggle-display] to view the image as "))
 472               animated)
 473           (cond
 474            ((null image)
 475             (message "%s" (concat msg1 "an image.")))
 476            ((setq animated (image-multi-frame-p image))
 477             (setq image-multi-frame t
 478                   mode-line-process
 479                   `(:eval
 480                     (concat " "
 481                             (propertize
 482                              (format "[%s/%s]"
 483                                      (1+ (image-current-frame ',image))
 484                                      ,(car animated))
 485                              'help-echo "Frames
 486 mouse-1: Next frame
 487 mouse-3: Previous frame"
 488                              'mouse-face 'mode-line-highlight
 489                              'local-map
 490                              '(keymap
 491                                (mode-line
 492                                 keymap
 493                                 (down-mouse-1 . image-next-frame)
 494                                 (down-mouse-3 . image-previous-frame)))))))
 495             (message "%s"
 496                      (concat msg1 "text.  This image has multiple frames.")))
 497 ;;;                          (substitute-command-keys
 498 ;;;                           "\\[image-toggle-animation] to animate."))))
 499            (t
 500             (message "%s" (concat msg1 "text."))))))
 501
 502     (error
 503      (image-mode-as-text)
 504      (funcall
 505       (if (called-interactively-p 'any) 'error 'message)
 506       "Cannot display image: %s" (cdr err)))))
 507
 508 ;;;###autoload
 509 (define-minor-mode image-minor-mode
 510   "Toggle Image minor mode in this buffer.
 511 With a prefix argument ARG, enable Image minor mode if ARG is
 512 positive, and disable it otherwise.  If called from Lisp, enable
 513 the mode if ARG is omitted or nil.
 514
 515 Image minor mode provides the key \\<image-mode-map>\\[image-toggle-display],
 516 to switch back to `image-mode' and display an image file as the
 517 actual image."
 518   nil (:eval (if image-type (format " Image[%s]" image-type) " Image"))
 519   image-minor-mode-map
 520   :group 'image
 521   :version "22.1"
 522   (if image-minor-mode
 523       (add-hook 'change-major-mode-hook (lambda () (image-minor-mode -1)) nil t)))
 524
 525 ;;;###autoload
 526 (defun image-mode-as-text ()
 527   "Set a non-image mode as major mode in combination with image minor mode.
 528 A non-image major mode found from `auto-mode-alist' or Fundamental mode
 529 displays an image file as text.  `image-minor-mode' provides the key
 530 \\<image-mode-map>\\[image-toggle-display] to switch back to `image-mode'
 531 to display an image file as the actual image.
 532
 533 You can use `image-mode-as-text' in `auto-mode-alist' when you want
 534 to display an image file as text initially.
 535
 536 See commands `image-mode' and `image-minor-mode' for more information
 537 on these modes."
 538   (interactive)
 539   ;; image-mode-as-text = normal-mode + image-minor-mode
 540   (let ((previous-image-type image-type)) ; preserve `image-type'
 541     (if image-mode-previous-major-mode
 542         ;; Restore previous major mode that was already found by this
 543         ;; function and cached in `image-mode-previous-major-mode'
 544         (funcall image-mode-previous-major-mode)
 545       (let ((auto-mode-alist
 546              (delq nil (mapcar
 547                         (lambda (elt)
 548                           (unless (memq (or (car-safe (cdr elt)) (cdr elt))
 549                                         '(image-mode image-mode-maybe image-mode-as-text))
 550                             elt))
 551                         auto-mode-alist)))
 552             (magic-fallback-mode-alist
 553              (delq nil (mapcar
 554                         (lambda (elt)
 555                           (unless (memq (or (car-safe (cdr elt)) (cdr elt))
 556                                         '(image-mode image-mode-maybe image-mode-as-text))
 557                             elt))
 558                         magic-fallback-mode-alist))))
 559         (normal-mode)
 560         (set (make-local-variable 'image-mode-previous-major-mode) major-mode)))
 561     ;; Restore `image-type' after `kill-all-local-variables' in `normal-mode'.
 562     (setq image-type previous-image-type)
 563     ;; Enable image minor mode with `C-c C-c'.
 564     (image-minor-mode 1)
 565     ;; Show the image file as text.
 566     (image-toggle-display-text)
 567     (message "%s" (concat
 568                    (substitute-command-keys
 569                     "Type \\[image-toggle-display] to view the image as ")
 570                    (if (image-get-display-property)
 571                        "text" "an image") "."))))
 572
 573 (define-obsolete-function-alias 'image-mode-maybe 'image-mode "23.2")
 574
 575 (defun image-toggle-display-text ()
 576   "Show the image file as text.
 577 Remove text properties that display the image."
 578   (let ((inhibit-read-only t)
 579         (buffer-undo-list t)
 580         (modified (buffer-modified-p)))
 581     (remove-list-of-text-properties (point-min) (point-max)
 582                                     '(display read-nonsticky ;; intangible
 583                                               read-only front-sticky))
 584     (set-buffer-modified-p modified)
 585     (if (called-interactively-p 'any)
 586         (message "Repeat this command to go back to displaying the image"))))
 587
 588 (defvar archive-superior-buffer)
 589 (defvar tar-superior-buffer)
 590 (declare-function image-flush "image.c" (spec &optional frame))
 591
 592 (defun image-toggle-display-image ()
 593   "Show the image of the image file.
 594 Turn the image data into a real image, but only if the whole file
 595 was inserted."
 596   (unless (derived-mode-p 'image-mode)
 597     (error "The buffer is not in Image mode"))
 598   (let* ((filename (buffer-file-name))
 599          (data-p (not (and filename
 600                            (file-readable-p filename)
 601                            (not (file-remote-p filename))
 602                            (not (buffer-modified-p))
 603                            (not (and (boundp 'archive-superior-buffer)
 604                                      archive-superior-buffer))
 605                            (not (and (boundp 'tar-superior-buffer)
 606                                      tar-superior-buffer)))))
 607          (file-or-data (if data-p
 608                            (string-make-unibyte
 609                             (buffer-substring-no-properties (point-min) (point-max)))
 610                          filename))
 611          (type (image-type file-or-data nil data-p))
 612          (image (create-image file-or-data type data-p))
 613          (inhibit-read-only t)
 614          (buffer-undo-list t)
 615          (modified (buffer-modified-p))
 616          props)
 617
 618     ;; Discard any stale image data before looking it up again.
 619     (image-flush image)
 620     (setq image (append image (image-transform-properties image)))
 621     (setq props
 622           `(display ,image
 623                     ;; intangible ,image
 624                     rear-nonsticky (display) ;; intangible
 625                     read-only t front-sticky (read-only)))
 626
 627     (let ((buffer-file-truename nil)) ; avoid changing dir mtime by lock_file
 628       (add-text-properties (point-min) (point-max) props)
 629       (restore-buffer-modified-p modified))
 630     ;; Inhibit the cursor when the buffer contains only an image,
 631     ;; because cursors look very strange on top of images.
 632     (setq cursor-type nil)
 633     ;; This just makes the arrow displayed in the right fringe
 634     ;; area look correct when the image is wider than the window.
 635     (setq truncate-lines t)
 636     ;; Disable adding a newline at the end of the image file when it
 637     ;; is written with, e.g., C-x C-w.
 638     (if (coding-system-equal (coding-system-base buffer-file-coding-system)
 639                              'no-conversion)
 640         (set (make-local-variable 'find-file-literally) t))
 641     ;; Allow navigation of large images
 642     (set (make-local-variable 'auto-hscroll-mode) nil)
 643     (setq image-type type)
 644     (if (eq major-mode 'image-mode)
 645         (setq mode-name (format "Image[%s]" type)))
 646     (image-transform-check-size)
 647     (if (called-interactively-p 'any)
 648         (message "Repeat this command to go back to displaying the file as text"))))
 649
 650 (defun image-toggle-display ()
 651   "Toggle between image and text display.
 652 If the current buffer is displaying an image file as an image,
 653 call `image-mode-as-text' to switch to text.  Otherwise, display
 654 the image by calling `image-mode'."
 655   (interactive)
 656   (if (image-get-display-property)
 657       (image-mode-as-text)
 658     (image-mode)))
 659
 660 (defun image-after-revert-hook ()
 661   (when (image-get-display-property)
 662     (image-toggle-display-text)
 663     ;; Update image display.
 664     (mapc (lambda (window) (redraw-frame (window-frame window)))
 665           (get-buffer-window-list (current-buffer) 'nomini 'visible))
 666     (image-toggle-display-image)))
 667
 668 \f
 669 ;;; Animated images
 670
 671 (defcustom image-animate-loop nil
 672   "Non-nil means animated images loop forever, rather than playing once."
 673   :type 'boolean
 674   :version "24.1"
 675   :group 'image)
 676
 677 (defun image-toggle-animation ()
 678   "Start or stop animating the current image.
 679 If `image-animate-loop' is non-nil, animation loops forever.
 680 Otherwise it plays once, then stops."
 681   (interactive)
 682   (let ((image (image-get-display-property))
 683         animation)
 684     (cond
 685      ((null image)
 686       (error "No image is present"))
 687      ((null (setq animation (image-multi-frame-p image)))
 688       (message "No image animation."))
 689      (t
 690       (let ((timer (image-animate-timer image)))
 691         (if timer
 692             (cancel-timer timer)
 693           (let ((index (plist-get (cdr image) :index)))
 694             ;; If we're at the end, restart.
 695             (and index
 696                  (>= index (1- (car animation)))
 697                  (setq index nil))
 698             (image-animate image index
 699                            (if image-animate-loop t)))))))))
 700
 701 (defun image-goto-frame (n &optional relative)
 702   "Show frame N of a multi-frame image.
 703 Optional argument OFFSET non-nil means interpret N as relative to the
 704 current frame.  Frames are indexed from 1."
 705   (interactive
 706    (list (or current-prefix-arg
 707              (read-number "Show frame number: "))))
 708   (let ((image (image-get-display-property)))
 709     (cond
 710      ((null image)
 711       (error "No image is present"))
 712      ((null image-multi-frame)
 713       (message "No image animation."))
 714      (t
 715       (image-show-frame image
 716                         (if relative
 717                             (+ n (image-current-frame image))
 718                           (1- n)))))))
 719
 720 (defun image-next-frame (&optional n)
 721   "Switch to the next frame of a multi-frame image.
 722 With optional argument N, switch to the Nth frame after the current one.
 723 If N is negative, switch to the Nth frame before the current one."
 724   (interactive "p")
 725   (image-goto-frame n t))
 726
 727 (defun image-previous-frame (&optional n)
 728   "Switch to the previous frame of a multi-frame image.
 729 With optional argument N, switch to the Nth frame before the current one.
 730 If N is negative, switch to the Nth frame after the current one."
 731   (interactive "p")
 732   (image-next-frame (- n)))
 733
 734 \f
 735 ;;; Switching to the next/previous image
 736
 737 (defun image-next-file (&optional n)
 738   "Visit the next image in the same directory as the current image file.
 739 With optional argument N, visit the Nth image file after the
 740 current one, in cyclic alphabetical order.
 741
 742 This command visits the specified file via `find-alternate-file',
 743 replacing the current Image mode buffer."
 744   (interactive "p")
 745   (unless (derived-mode-p 'image-mode)
 746     (error "The buffer is not in Image mode"))
 747   (unless buffer-file-name
 748     (error "The current image is not associated with a file"))
 749   (let* ((file (file-name-nondirectory buffer-file-name))
 750          (images (image-mode--images-in-directory file))
 751          (idx 0))
 752     (catch 'image-visit-next-file
 753       (dolist (f images)
 754         (if (string= f file)
 755             (throw 'image-visit-next-file (1+ idx)))
 756         (setq idx (1+ idx))))
 757     (setq idx (mod (+ idx (or n 1)) (length images)))
 758     (find-alternate-file (nth idx images))))
 759
 760 (defun image-previous-file (&optional n)
 761   "Visit the preceding image in the same directory as the current file.
 762 With optional argument N, visit the Nth image file preceding the
 763 current one, in cyclic alphabetical order.
 764
 765 This command visits the specified file via `find-alternate-file',
 766 replacing the current Image mode buffer."
 767   (interactive "p")
 768   (image-next-file (- n)))
 769
 770 (defun image-mode--images-in-directory (file)
 771   (let* ((dir (file-name-directory buffer-file-name))
 772          (files (directory-files dir nil
 773                                  (image-file-name-regexp) t)))
 774     ;; Add the current file to the list of images if necessary, in
 775     ;; case it does not match `image-file-name-regexp'.
 776     (unless (member file files)
 777       (push file files))
 778     (sort files 'string-lessp)))
 779
 780 \f
 781 ;;; Support for bookmark.el
 782 (declare-function bookmark-make-record-default
 783                   "bookmark" (&optional no-file no-context posn))
 784 (declare-function bookmark-prop-get "bookmark" (bookmark prop))
 785 (declare-function bookmark-default-handler "bookmark" (bmk))
 786
 787 (defun image-bookmark-make-record ()
 788   `(,@(bookmark-make-record-default nil 'no-context 0)
 789       (image-type . ,image-type)
 790       (handler    . image-bookmark-jump)))
 791
 792 ;;;###autoload
 793 (defun image-bookmark-jump (bmk)
 794   ;; This implements the `handler' function interface for record type
 795   ;; returned by `bookmark-make-record-function', which see.
 796   (prog1 (bookmark-default-handler bmk)
 797     (when (not (string= image-type (bookmark-prop-get bmk 'image-type)))
 798       (image-toggle-display))))
 799 \f
 800
 801 ;; Not yet implemented.
 802 ;; (defvar image-transform-minor-mode-map
 803 ;;   (let ((map (make-sparse-keymap)))
 804 ;;     ;; (define-key map  [(control ?+)] 'image-scale-in)
 805 ;;     ;; (define-key map  [(control ?-)] 'image-scale-out)
 806 ;;     ;; (define-key map  [(control ?=)] 'image-scale-none)
 807 ;;     ;; (define-key map "c f h" 'image-scale-fit-height)
 808 ;;     ;; (define-key map "c ]" 'image-rotate-right)
 809 ;;     map)
 810 ;;   "Minor mode keymap `image-transform-mode'.")
 811 ;;
 812 ;; (define-minor-mode image-transform-mode
 813 ;;   "Minor mode for scaling and rotating images.
 814 ;; With a prefix argument ARG, enable the mode if ARG is positive,
 815 ;; and disable it otherwise.  If called from Lisp, enable the mode
 816 ;; if ARG is omitted or nil.  This minor mode requires Emacs to have
 817 ;; been compiled with ImageMagick support."
 818 ;;   nil "image-transform" image-transform-minor-mode-map)
 819
 820
 821 ;; FIXME this doesn't seem mature yet. Document in manual when it is.
 822 (defvar image-transform-resize nil
 823   "The image resize operation.
 824 Its value should be one of the following:
 825  - nil, meaning no resizing.
 826  - `fit-height', meaning to fit the image to the window height.
 827  - `fit-width', meaning to fit the image to the window width.
 828  - A number, which is a scale factor (the default size is 1).")
 829
 830 (defvar image-transform-scale 1.0
 831   "The scale factor of the image being displayed.")
 832
 833 (defvar image-transform-rotation 0.0
 834   "Rotation angle for the image in the current Image mode buffer.")
 835
 836 (defvar image-transform-right-angle-fudge 0.0001
 837   "Snap distance to a multiple of a right angle.
 838 There's no deep theory behind the default value, it should just
 839 be somewhat larger than ImageMagick's MagickEpsilon.")
 840
 841 (defsubst image-transform-width (width height)
 842   "Return the bounding box width of a rotated WIDTH x HEIGHT rectangle.
 843 The rotation angle is the value of `image-transform-rotation' in degrees."
 844   (let ((angle (degrees-to-radians image-transform-rotation)))
 845     ;; Assume, w.l.o.g., that the vertices of the rectangle have the
 846     ;; coordinates (+-w/2, +-h/2) and that (0, 0) is the center of the
 847     ;; rotation by the angle A.  The projections onto the first axis
 848     ;; of the vertices of the rotated rectangle are +- (w/2) cos A +-
 849     ;; (h/2) sin A, and the difference between the largest and the
 850     ;; smallest of the four values is the expression below.
 851     (+ (* width (abs (cos angle))) (* height (abs (sin angle))))))
 852
 853 ;; The following comment and code snippet are from
 854 ;; ImageMagick-6.7.4-4/magick/distort.c
 855
 856 ;;    /* Set the output image geometry to calculated 'best fit'.
 857 ;;       Yes this tends to 'over do' the file image size, ON PURPOSE!
 858 ;;       Do not do this for DePolar which needs to be exact for virtual tiling.
 859 ;;    */
 860 ;;    if ( fix_bounds ) {
 861 ;;      geometry.x = (ssize_t) floor(min.x-0.5);
 862 ;;      geometry.y = (ssize_t) floor(min.y-0.5);
 863 ;;      geometry.width=(size_t) ceil(max.x-geometry.x+0.5);
 864 ;;      geometry.height=(size_t) ceil(max.y-geometry.y+0.5);
 865 ;;    }
 866
 867 ;; Other parts of the same file show that here the origin is in the
 868 ;; left lower corner of the image rectangle, the center of the
 869 ;; rotation is the center of the rectangle and min.x and max.x
 870 ;; (resp. min.y and max.y) are the smallest and the largest of the
 871 ;; projections of the vertices onto the first (resp. second) axis.
 872
 873 (defun image-transform-fit-width (width height length)
 874   "Return (w . h) so that a rotated w x h image has exactly width LENGTH.
 875 The rotation angle is the value of `image-transform-rotation'.
 876 Write W for WIDTH and H for HEIGHT.  Then the w x h rectangle is
 877 an \"approximately uniformly\" scaled W x H rectangle, which
 878 currently means that w is one of floor(s W) + {0, 1, -1} and h is
 879 floor(s H), where s can be recovered as the value of `image-transform-scale'.
 880 The value of `image-transform-rotation' may be replaced by
 881 a slightly different angle.  Currently this is done for values
 882 close to a multiple of 90, see `image-transform-right-angle-fudge'."
 883   (cond ((< (abs (- (mod (+ image-transform-rotation 90) 180) 90))
 884             image-transform-right-angle-fudge)
 885          (cl-assert (not (zerop width)) t)
 886          (setq image-transform-rotation
 887                (float (round image-transform-rotation))
 888                image-transform-scale (/ (float length) width))
 889          (cons length nil))
 890         ((< (abs (- (mod (+ image-transform-rotation 45) 90) 45))
 891             image-transform-right-angle-fudge)
 892          (cl-assert (not (zerop height)) t)
 893          (setq image-transform-rotation
 894                (float (round image-transform-rotation))
 895                image-transform-scale (/ (float length) height))
 896          (cons nil length))
 897         (t
 898          (cl-assert (not (and (zerop width) (zerop height))) t)
 899          (setq image-transform-scale
 900                (/ (float (1- length)) (image-transform-width width height)))
 901          ;; Assume we have a w x h image and an angle A, and let l =
 902          ;; l(w, h) = w |cos A| + h |sin A|, which is the actual width
 903          ;; of the bounding box of the rotated image, as calculated by
 904          ;; `image-transform-width'.  The code snippet quoted above
 905          ;; means that ImageMagick puts the rotated image in
 906          ;; a bounding box of width L = 2 ceil((w+l+1)/2) - w.
 907          ;; Elementary considerations show that this is equivalent to
 908          ;; L - w being even and L-3 < l(w, h) <= L-1.  In our case, L is
 909          ;; the given `length' parameter and our job is to determine
 910          ;; reasonable values for w and h which satisfy these
 911          ;; conditions.
 912          (let ((w (floor (* image-transform-scale width)))
 913                (h (floor (* image-transform-scale height))))
 914            ;; Let w and h as bound above.  Then l(w, h) <= l(s W, s H)
 915            ;; = L-1 < l(w+1, h+1) = l(w, h) + l(1, 1) <= l(w, h) + 2,
 916            ;; hence l(w, h) > (L-1) - 2 = L-3.
 917            (cons
 918             (cond ((= (mod w 2) (mod length 2))
 919                    w)
 920                   ;; l(w+1, h) >= l(w, h) > L-3, but does l(w+1, h) <=
 921                   ;; L-1 hold?
 922                   ((<= (image-transform-width (1+ w) h) (1- length))
 923                    (1+ w))
 924                   ;; No, it doesn't, but this implies that l(w-1, h) =
 925                   ;; l(w+1, h) - l(2, 0) >= l(w+1, h) - 2 > (L-1) -
 926                   ;; 2 = L-3.  Clearly, l(w-1, h) <= l(w, h) <= L-1.
 927                   (t
 928                    (1- w)))
 929             h)))))
 930
 931 (defun image-transform-check-size ()
 932   "Check that the image exactly fits the width/height of the window.
 933
 934 Do this for an image of type `imagemagick' to make sure that the
 935 elisp code matches the way ImageMagick computes the bounding box
 936 of a rotated image."
 937   (when (and (not (numberp image-transform-resize))
 938              (boundp 'image-type)
 939              (eq image-type 'imagemagick))
 940     (let ((size (image-display-size (image-get-display-property) t)))
 941       (cond ((eq image-transform-resize 'fit-width)
 942              (cl-assert (= (car size)
 943                         (- (nth 2 (window-inside-pixel-edges))
 944                            (nth 0 (window-inside-pixel-edges))))
 945                      t))
 946             ((eq image-transform-resize 'fit-height)
 947              (cl-assert (= (cdr size)
 948                         (- (nth 3 (window-inside-pixel-edges))
 949                            (nth 1 (window-inside-pixel-edges))))
 950                      t))))))
 951
 952 (defun image-transform-properties (spec)
 953   "Return rescaling/rotation properties for image SPEC.
 954 These properties are determined by the Image mode variables
 955 `image-transform-resize' and `image-transform-rotation'.  The
 956 return value is suitable for appending to an image spec.
 957
 958 Rescaling and rotation properties only take effect if Emacs is
 959 compiled with ImageMagick support."
 960   (setq image-transform-scale 1.0)
 961   (when (or image-transform-resize
 962             (/= image-transform-rotation 0.0))
 963     ;; Note: `image-size' looks up and thus caches the untransformed
 964     ;; image.  There's no easy way to prevent that.
 965     (let* ((size (image-size spec t))
 966            (resized
 967             (cond
 968              ((numberp image-transform-resize)
 969               (unless (= image-transform-resize 1)
 970                 (setq image-transform-scale image-transform-resize)
 971                 (cons nil (floor (* image-transform-resize (cdr size))))))
 972              ((eq image-transform-resize 'fit-width)
 973               (image-transform-fit-width
 974                (car size) (cdr size)
 975                (- (nth 2 (window-inside-pixel-edges))
 976                   (nth 0 (window-inside-pixel-edges)))))
 977              ((eq image-transform-resize 'fit-height)
 978               (let ((res (image-transform-fit-width
 979                           (cdr size) (car size)
 980                           (- (nth 3 (window-inside-pixel-edges))
 981                              (nth 1 (window-inside-pixel-edges))))))
 982                 (cons (cdr res) (car res)))))))
 983       `(,@(when (car resized)
 984             (list :width (car resized)))
 985         ,@(when (cdr resized)
 986             (list :height (cdr resized)))
 987         ,@(unless (= 0.0 image-transform-rotation)
 988             (list :rotation image-transform-rotation))))))
 989
 990 (defun image-transform-set-scale (scale)
 991   "Prompt for a number, and resize the current image by that amount.
 992 This command has no effect unless Emacs is compiled with
 993 ImageMagick support."
 994   (interactive "nScale: ")
 995   (setq image-transform-resize scale)
 996   (image-toggle-display-image))
 997
 998 (defun image-transform-fit-to-height ()
 999   "Fit the current image to the height of the current window.
1000 This command has no effect unless Emacs is compiled with
1001 ImageMagick support."
1002   (interactive)
1003   (setq image-transform-resize 'fit-height)
1004   (image-toggle-display-image))
1005
1006 (defun image-transform-fit-to-width ()
1007   "Fit the current image to the width of the current window.
1008 This command has no effect unless Emacs is compiled with
1009 ImageMagick support."
1010   (interactive)
1011   (setq image-transform-resize 'fit-width)
1012   (image-toggle-display-image))
1013
1014 (defun image-transform-set-rotation (rotation)
1015   "Prompt for an angle ROTATION, and rotate the image by that amount.
1016 ROTATION should be in degrees.  This command has no effect unless
1017 Emacs is compiled with ImageMagick support."
1018   (interactive "nRotation angle (in degrees): ")
1019   (setq image-transform-rotation (float (mod rotation 360)))
1020   (image-toggle-display-image))
1021
1022 (provide 'image-mode)
1023
1024 ;;; image-mode.el ends here