code.delx.au - gnu-emacs/blob - lisp/cedet/cedet-cscope.el

   1 ;;; cedet-cscope.el --- CScope support for CEDET
   2
   3 ;;; Copyright (C) 2009, 2010, 2011 Free Software Foundation, Inc.
   4
   5 ;; Author: Eric M. Ludlam <zappo@gnu.org>
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software: you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation, either version 3 of the License, or
  12 ;; (at your option) any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  21
  22 ;;; Commentary:
  23 ;;
  24 ;; Support using CScope for symbol lookups.
  25
  26 ;;; Code:
  27
  28 (declare-function inversion-check-version "inversion")
  29
  30 (defvar cedet-cscope-min-version "16.0"
  31   "Minimum version of CScope required.")
  32
  33 (defcustom cedet-cscope-command "cscope"
  34   "Command name for the CScope executable."
  35   :type 'string
  36   :group 'cedet)
  37
  38 (defun cedet-cscope-search (searchtext texttype type scope)
  39   "Perform a search with CScope, return the created buffer.
  40 SEARCHTEXT is text to find.
  41 TEXTTYPE is the type of text, such as 'regexp, 'string, 'tagname,
  42 'tagregexp, or 'tagcompletions.
  43 TYPE is the type of search, meaning that SEARCHTEXT is compared to
  44 filename, tagname (tags table), references (uses of a tag) , or
  45 symbol (uses of something not in the tag table.)
  46 SCOPE is the scope of the search, such as 'project or 'subdirs."
  47   ;; CScope is an interactive program.  It uses number flags
  48   ;; in order to perform command line searches.  Useful for this
  49   ;; tool are:
  50   ;;
  51   ;; -0 = Find C symbol
  52   ;; -1 = Find global definition
  53   ;; -3 = Find references
  54   ;; -6 = Find egrep pattern
  55   ;; -7 = Find file
  56   (let ((idx (cond ((eq type 'file)
  57                     "-7")
  58                    ;; Non files are symbols and such
  59                    ((eq texttype 'tagname)
  60                     "-1")
  61                    ((eq texttype 'tagregexp)
  62                     "-0")
  63                    ((eq texttype 'tagcompletions)
  64                     (setq searchtext (concat "^" searchtext ".*"))
  65                     "-1")
  66                    ((eq texttype 'regexp)
  67                     "-5")
  68                    (t
  69                     "-3")
  70                    )
  71              )
  72         )
  73     (cedet-cscope-call (list "-d" "-L" idx searchtext))))
  74
  75 (defun cedet-cscope-create (flags)
  76   "Create a CScope database at the current directory.
  77 FLAGS are additional flags to pass to cscope beyond the
  78 options -cR."
  79   (cedet-cscope-call (append (list "-cR") flags)))
  80
  81 (defun cedet-cscope-call (flags)
  82   "Call CScope with the list of FLAGS."
  83   (let ((b (get-buffer-create "*CEDET CScope*"))
  84         (cd default-directory)
  85         )
  86     (with-current-buffer b
  87       (setq default-directory cd)
  88       (erase-buffer))
  89     (apply 'call-process cedet-cscope-command
  90            nil b nil
  91            flags)
  92     b))
  93
  94 (defun cedet-cscope-expand-filename (filename)
  95   "Expand the FILENAME with CScope.
  96 Return a fully qualified filename."
  97   (interactive "sFile: ")
  98   (let* ((ans1 (with-current-buffer
  99                    (cedet-cscope-call (list "-d" "-L" "-7" filename))
 100                  (goto-char (point-min))
 101                  (if (looking-at "[^ \n]*cscope: ")
 102                      (error "CScope not available")
 103                    (split-string (buffer-string) "\n" t))))
 104          (ans2 (mapcar (lambda (hit)
 105                          (expand-file-name (car (split-string hit " "))))
 106                        ans1)))
 107     (when (called-interactively-p 'interactive)
 108       (if ans2
 109           (if (= (length ans2) 1)
 110               (message "%s" (car ans2))
 111             (message "%s + %d others" (car ans2)
 112                      (length (cdr ans2))))
 113         (error "No file found")))
 114     ans2))
 115
 116 (defun cedet-cscope-support-for-directory (&optional dir)
 117   "Return non-nil if CScope has a support file for DIR.
 118 If DIR is not supplied, use the current default directory.
 119 This works by running cscope on a bogus symbol, and looking for
 120 the error code."
 121   (interactive "DDirectory: ")
 122   (save-excursion
 123     (let ((default-directory (or dir default-directory)))
 124       (set-buffer (cedet-cscope-call (list "-d" "-L" "-7" "moose")))
 125       (goto-char (point-min))
 126       (let ((ans (looking-at "[^ \n]*cscope: ")))
 127         (if (called-interactively-p 'interactive)
 128             (if ans
 129                 (message "No support for CScope in %s" default-directory)
 130               (message "CScope is supported in %s" default-directory))
 131           (if ans
 132               nil
 133             t))))))
 134
 135 (defun cedet-cscope-version-check (&optional noerror)
 136   "Check the version of the installed CScope command.
 137 If optional programatic argument NOERROR is non-nil, then
 138 instead of throwing an error if CScope isn't available, then
 139 return nil."
 140   (interactive)
 141   (require 'inversion)
 142   (let ((b (condition-case nil
 143                (cedet-cscope-call (list "-V"))
 144              (error nil)))
 145         (rev nil))
 146     (if (not b)
 147         (progn
 148           (when (called-interactively-p 'interactive)
 149             (message "CScope not found."))
 150           nil)
 151       (with-current-buffer b
 152         (goto-char (point-min))
 153         (re-search-forward "cscope: version \\([0-9.]+\\)" nil t)
 154         (setq rev (match-string 1))
 155         (if (inversion-check-version rev nil cedet-cscope-min-version)
 156             (if noerror
 157                 nil
 158               (error "Version of CScope is %s.  Need at least %s"
 159                      rev cedet-cscope-min-version))
 160           ;; Else, return TRUE, as in good enough.
 161           (when (called-interactively-p 'interactive)
 162             (message "CScope %s  - Good enough for CEDET." rev))
 163           t)))))
 164
 165 (defun cedet-cscope-create/update-database (&optional dir)
 166   "Create a CScope database in DIR.
 167 CScope will automatically choose incremental rebuild if
 168 there is already a database in DIR."
 169   (interactive "DDirectory: ")
 170   (let ((default-directory dir))
 171     (cedet-cscope-create nil)))
 172
 173 (provide 'cedet-cscope)
 174
 175 ;; arch-tag: 9973f1ad-f13b-4399-bc67-7f488478d78d
 176 ;;; cedet-cscope.el ends here