code.delx.au - gnu-emacs/blob - test/lisp/abbrev-tests.el

   1 ;;; abbrev-tests.el --- Test suite for abbrevs  -*- lexical-binding: t; -*-
   2
   3 ;; Copyright (C) 2015-2016 Free Software Foundation, Inc.
   4
   5 ;; Author: Eli Zaretskii <eliz@gnu.org>
   6 ;; Keywords: abbrevs
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; `kill-all-abbrevs-test' will remove all user *and* system abbrevs
  26 ;; if called noninteractively with the init file loaded.
  27
  28 ;;; Code:
  29
  30 (require 'ert)
  31 (require 'abbrev)
  32 (require 'seq)
  33
  34 ;; set up test abbrev table and abbrev entry
  35 (defun setup-test-abbrev-table ()
  36   (defvar ert-test-abbrevs nil)
  37   (define-abbrev-table 'ert-test-abbrevs '(("a-e-t" "abbrev-ert-test")))
  38   (abbrev-table-put ert-test-abbrevs :ert-test "ert-test-value")
  39   ert-test-abbrevs)
  40
  41 (ert-deftest abbrev-table-p-test ()
  42   (should-not (abbrev-table-p 42))
  43   (should-not (abbrev-table-p "aoeu"))
  44   (should-not (abbrev-table-p '()))
  45   (should-not (abbrev-table-p []))
  46   ;; Missing :abbrev-table-modiff counter:
  47   (should-not (abbrev-table-p (obarray-make)))
  48   (let* ((table (obarray-make)))
  49     (should (abbrev-table-empty-p (make-abbrev-table)))))
  50
  51 (ert-deftest abbrev-make-abbrev-table-test ()
  52   ;; Table without properties:
  53   (let ((table (make-abbrev-table)))
  54     (should (abbrev-table-p table))
  55     (should (= (length table) obarray-default-size)))
  56   ;; Table with one property 'foo with value 'bar:
  57   (let ((table (make-abbrev-table '(foo bar))))
  58     (should (abbrev-table-p table))
  59     (should (= (length table) obarray-default-size))
  60     (should (eq (abbrev-table-get table 'foo) 'bar))))
  61
  62 (ert-deftest abbrev-table-get-put-test ()
  63   (let ((table (make-abbrev-table)))
  64     (should-not (abbrev-table-get table 'foo))
  65     (should (= (abbrev-table-put table 'foo 42) 42))
  66     (should (= (abbrev-table-get table 'foo) 42))
  67     (should (eq (abbrev-table-put table 'foo 'bar) 'bar))
  68     (should (eq (abbrev-table-get table 'foo) 'bar))))
  69
  70 (ert-deftest copy-abbrev-table-test ()
  71   (defvar foo-abbrev-table nil)         ; Avoid compiler warning
  72   (define-abbrev-table 'foo-abbrev-table
  73     '())
  74   (should (abbrev-table-p foo-abbrev-table))
  75   ;; Bug 21828
  76   (let ((new-foo-abbrev-table
  77          (condition-case nil
  78              (copy-abbrev-table foo-abbrev-table)
  79            (error nil))))
  80     (should (abbrev-table-p new-foo-abbrev-table)))
  81   (should-not (string-equal (buffer-name) "*Backtrace*")))
  82
  83 (ert-deftest abbrev-table-empty-p-test ()
  84   (should-error (abbrev-table-empty-p 42))
  85   (should-error (abbrev-table-empty-p "aoeu"))
  86   (should-error (abbrev-table-empty-p '()))
  87   (should-error (abbrev-table-empty-p []))
  88   ;; Missing :abbrev-table-modiff counter:
  89   (should-error (abbrev-table-empty-p (obarray-make)))
  90   (let* ((table (obarray-make)))
  91     (abbrev-table-put table :abbrev-table-modiff 42)
  92     (should (abbrev-table-empty-p table))))
  93
  94 (ert-deftest kill-all-abbrevs-test ()
  95   "Test undefining all defined abbrevs"
  96   (unless noninteractive
  97     (ert-skip "Cannot test kill-all-abbrevs in interactive mode"))
  98
  99   (let ((num-tables 0))
 100     ;; ensure at least one abbrev exists
 101     (should (abbrev-table-p (setup-test-abbrev-table)))
 102     (setf num-tables (length abbrev-table-name-list))
 103     (kill-all-abbrevs)
 104
 105     ;; no tables should have been removed/added
 106     (should (= num-tables (length abbrev-table-name-list)))
 107     ;; number of empty tables should be the same as number of tables
 108     (should (= num-tables (length (seq-filter
 109                                    (lambda (table)
 110                                        (abbrev-table-empty-p (symbol-value table)))
 111                                    abbrev-table-name-list))))))
 112
 113 (ert-deftest abbrev-table-name-test ()
 114   "Test returning name of abbrev-table"
 115   (let ((ert-test-abbrevs (setup-test-abbrev-table))
 116         (no-such-table nil))
 117     (should (equal 'ert-test-abbrevs (abbrev-table-name ert-test-abbrevs)))
 118     (should (equal nil (abbrev-table-name no-such-table)))))
 119
 120 (ert-deftest clear-abbrev-table-test ()
 121   "Test clearing single abbrev table"
 122   (let ((ert-test-abbrevs (setup-test-abbrev-table)))
 123     (should (equal "abbrev-ert-test" (abbrev-expansion "a-e-t" ert-test-abbrevs)))
 124     (clear-abbrev-table ert-test-abbrevs)
 125     (should (equal nil (abbrev-expansion "a-e-t" ert-test-abbrevs)))
 126     (should (equal t (abbrev-table-empty-p ert-test-abbrevs)))))
 127
 128 (ert-deftest list-abbrevs-test ()
 129   "Test generation of abbrev list buffer"
 130   ;; Somewhat redundant as prepare-abbrev-list-buffer is also tested.
 131   ;; all abbrevs
 132   (let ((abbrev-buffer (prepare-abbrev-list-buffer)))
 133     (should (equal "*Abbrevs*" (buffer-name abbrev-buffer)))
 134     (kill-buffer abbrev-buffer))
 135   ;; mode-specific abbrevs
 136   (let ((abbrev-buffer (prepare-abbrev-list-buffer t)))
 137     (should (equal "*Abbrevs*" (buffer-name abbrev-buffer)))
 138     (kill-buffer abbrev-buffer)))
 139
 140 (ert-deftest prepare-abbrev-list-buffer-test ()
 141   "Test generation of abbrev list buffer"
 142   ;; all abbrevs
 143   (let ((ert-test-abbrevs (setup-test-abbrev-table)))
 144     (with-current-buffer (prepare-abbrev-list-buffer)
 145       ;; Check for a couple of abbrev-table names in buffer.
 146       (should (and (progn
 147                      (goto-char (point-min))
 148                      (search-forward (symbol-name (abbrev-table-name ert-test-abbrevs))))
 149                    (progn
 150                      (goto-char (point-min))
 151                      (search-forward "global-abbrev-table"))))
 152       (should (equal 'edit-abbrevs-mode major-mode))
 153       (kill-buffer "*Abbrevs*")))
 154
 155   ;; mode-specific abbrevs (temp buffer uses fundamental-mode)
 156   (with-temp-buffer
 157     (prepare-abbrev-list-buffer t)
 158     (with-current-buffer "*Abbrevs*"
 159       (should (progn
 160                 (goto-char (point-min))
 161                 (search-forward "fundamental-mode-abbrev-table")))
 162       (should-error (progn
 163                       (goto-char (point-min))
 164                       (search-forward "global-abbrev-table")))
 165       (should-not (equal 'edit-abbrevs-mode major-mode))
 166       (kill-buffer "*Abbrevs*"))))
 167
 168 (ert-deftest insert-abbrevs-test ()
 169   "Test inserting abbrev definitions into buffer"
 170   (with-temp-buffer
 171     (insert-abbrevs)
 172       (should (progn
 173                 (goto-char (point-min))
 174                 (search-forward "global-abbrev-table")))))
 175
 176 (ert-deftest edit-abbrevs-test ()
 177   "Test editing abbrevs from buffer"
 178   (defvar ert-edit-abbrevs-test-table nil)
 179   (let ((ert-test-abbrevs (setup-test-abbrev-table)))
 180     (with-temp-buffer
 181       ;; insert test table and new abbrev, redefine, check definition
 182       (goto-char (point-min))
 183       (insert "(ert-edit-abbrevs-test-table)\n")
 184       (insert "\n" "\"e-a-t\"\t" "0\t" "\"edit-abbrevs-test\"\n")
 185       ;; check test table before redefine
 186       (should (equal "abbrev-ert-test"
 187                      (abbrev-expansion "a-e-t" ert-test-abbrevs)))
 188       (edit-abbrevs-redefine)
 189       (should-not (abbrev-expansion "a-e-t" ert-test-abbrevs))
 190       (should (equal "edit-abbrevs-test"
 191                      (abbrev-expansion "e-a-t" ert-edit-abbrevs-test-table))))))
 192
 193 (ert-deftest define-abbrevs-test ()
 194   "Test defining abbrevs from buffer"
 195   (defvar ert-bad-abbrev-table nil)
 196   (defvar ert-good-abbrev-table nil)
 197   (defvar ert-redefine-abbrev-table nil)
 198   (with-temp-buffer
 199     ;; insert bad abbrev data and attempt define
 200     (goto-char (point-min))
 201     (insert "ert-bad-abbrev-table\n")
 202     (insert "\n" "\"b-a-t\"\t" "0\t" "\n")
 203     (should-not (define-abbrevs))
 204     (should (equal nil (abbrev-expansion "b-a-t" ert-bad-abbrev-table)))
 205     (delete-region (point-min) (point-max))
 206     ;; try with valid abbrev data
 207     (goto-char (point-min))
 208     (insert "(ert-good-abbrev-table)\n")
 209     (insert "\n" "\"g-a-t\"\t" "0\t" "\"good-abbrev-table\"\n")
 210     (define-abbrevs)
 211     (should (equal "good-abbrev-table"
 212                    (abbrev-expansion "g-a-t" ert-good-abbrev-table)))
 213     ;; redefine from buffer
 214     (delete-region (point-min) (point-max))
 215     (insert "(ert-redefine-abbrev-table)\n")
 216     (insert "\n" "\"r-a-t\"\t" "0\t" "\"redefine-abbrev-table\"\n")
 217     ;; arg = kill-all-abbrevs
 218     (define-abbrevs t)
 219     (should (equal "redefine-abbrev-table"
 220                    (abbrev-expansion "r-a-t" ert-redefine-abbrev-table)))
 221     (should (equal nil (abbrev-expansion "g-a-t" ert-good-abbrev-table)))))
 222
 223 (ert-deftest read-write-abbrev-file-test ()
 224   "Test reading and writing abbrevs from file"
 225   (let ((temp-test-file (make-temp-file "ert-abbrev-test"))
 226         (ert-test-abbrevs (setup-test-abbrev-table)))
 227     (write-abbrev-file temp-test-file)
 228     (clear-abbrev-table ert-test-abbrevs)
 229     (should (abbrev-table-empty-p ert-test-abbrevs))
 230     (read-abbrev-file temp-test-file)
 231     (should (equal "abbrev-ert-test" (abbrev-expansion "a-e-t" ert-test-abbrevs)))
 232     (delete-file temp-test-file)))
 233
 234 (ert-deftest abbrev-edit-save-to-file-test ()
 235   "Test saving abbrev definitions in buffer to file"
 236   (defvar ert-save-test-table nil)
 237   (let ((temp-test-file (make-temp-file "ert-abbrev-test"))
 238         (ert-test-abbrevs (setup-test-abbrev-table)))
 239     (with-temp-buffer
 240       (goto-char (point-min))
 241       (insert "(ert-save-test-table)\n")
 242       (insert "\n" "\"s-a-t\"\t" "0\t" "\"save-abbrevs-test\"\n")
 243       (should (equal "abbrev-ert-test"
 244                      (abbrev-expansion "a-e-t" ert-test-abbrevs)))
 245       ;; clears abbrev tables
 246       (abbrev-edit-save-to-file temp-test-file)
 247       (should-not (abbrev-expansion "a-e-t" ert-test-abbrevs))
 248       (read-abbrev-file temp-test-file)
 249       (should (equal "save-abbrevs-test"
 250                      (abbrev-expansion "s-a-t" ert-save-test-table)))
 251       (delete-file temp-test-file))))
 252
 253 (provide 'abbrev-tests)
 254
 255 ;;; abbrev-tests.el ends here