code.delx.au - gnu-emacs/blob - lisp/ediff-wind.el

   1 ;;; ediff-wind.el --- window manipulation utilities
   2
   3 ;; Copyright (C) 1994, 1995, 1996, 1997, 2000, 2001, 2002, 2003,
   4 ;;   2004, 2005, 2006 Free Software Foundation, Inc.
   5
   6 ;; Author: Michael Kifer <kifer@cs.stonybrook.edu>
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  23 ;; Boston, MA 02110-1301, USA.
  24
  25 ;;; Commentary:
  26
  27 ;;; Code:
  28
  29
  30 ;; Compiler pacifier
  31 (defvar icon-title-format)
  32 (defvar top-toolbar-height)
  33 (defvar bottom-toolbar-height)
  34 (defvar left-toolbar-height)
  35 (defvar right-toolbar-height)
  36 (defvar left-toolbar-width)
  37 (defvar right-toolbar-width)
  38 (defvar default-menubar)
  39 (defvar top-gutter)
  40 (defvar frame-icon-title-format)
  41 (defvar ediff-diff-status)
  42 (defvar ediff-emacs-p)
  43
  44 (eval-when-compile
  45   (let ((load-path (cons (expand-file-name ".") load-path)))
  46     (or (featurep 'ediff-init)
  47         (load "ediff-init.el" nil nil 'nosuffix))
  48     (or (featurep 'ediff-util)
  49         (load "ediff-util.el" nil nil 'nosuffix))
  50     (or (featurep 'ediff-help)
  51         (load "ediff-help.el" nil nil 'nosuffix))
  52     (or (featurep 'ediff-tbar)
  53         ediff-emacs-p
  54         (load "ediff-tbar.el" 'noerror nil 'nosuffix))
  55     ))
  56 ;; end pacifier
  57
  58 (require 'ediff-init)
  59
  60 ;; be careful with ediff-tbar
  61 (if ediff-xemacs-p
  62     (condition-case nil
  63         (require 'ediff-tbar)
  64       (error
  65        (defun ediff-compute-toolbar-width () 0)))
  66   (defun ediff-compute-toolbar-width () 0))
  67
  68 (defgroup ediff-window nil
  69   "Ediff window manipulation."
  70   :prefix "ediff-"
  71   :group 'ediff
  72   :group 'frames)
  73
  74
  75 (defcustom ediff-window-setup-function (if (ediff-window-display-p)
  76                                         'ediff-setup-windows-multiframe
  77                                       'ediff-setup-windows-plain)
  78   "*Function called to set up windows.
  79 Ediff provides a choice of two functions: `ediff-setup-windows-plain', for
  80 doing everything in one frame, and `ediff-setup-windows-multiframe',
  81 which sets the control panel in a separate frame.  Also, if the latter
  82 function detects that one of the buffers A/B is seen in some other frame,
  83 it will try to keep that buffer in that frame.
  84
  85 If you don't like the two functions provided---write your own one.
  86 The basic guidelines:
  87     1. It should leave the control buffer current and the control window
  88        selected.
  89     2. It should set `ediff-window-A', `ediff-window-B', `ediff-window-C',
  90        and `ediff-control-window' to contain window objects that display
  91        the corresponding buffers.
  92     3. It should accept the following arguments:
  93        buffer-A, buffer-B, buffer-C, control-buffer
  94        Buffer C may not be used in jobs that compare only two buffers.
  95 If you plan to do something fancy, take a close look at how the two
  96 provided functions are written."
  97   :type '(choice (const :tag "Multi Frame" ediff-setup-windows-multiframe)
  98                  (const :tag "Single Frame" ediff-setup-windows-plain)
  99                  (function :tag "Other function"))
 100   :group 'ediff-window)
 101
 102 ;; indicates if we are in a multiframe setup
 103 (ediff-defvar-local ediff-multiframe nil "")
 104
 105 ;; Share of the frame occupied by the merge window (buffer C)
 106 (ediff-defvar-local ediff-merge-window-share 0.45 "")
 107
 108 ;; The control window.
 109 (ediff-defvar-local ediff-control-window nil "")
 110 ;; Official window for buffer A
 111 (ediff-defvar-local ediff-window-A nil "")
 112 ;; Official window for buffer B
 113 (ediff-defvar-local ediff-window-B nil "")
 114 ;; Official window for buffer C
 115 (ediff-defvar-local ediff-window-C nil "")
 116 ;; Ediff's window configuration.
 117 ;; Used to minimize the need to rearrange windows.
 118 (ediff-defvar-local ediff-window-config-saved "" "")
 119
 120 ;; Association between buff-type and ediff-window-*
 121 (defconst ediff-window-alist
 122   '((A . ediff-window-A)
 123     (?A . ediff-window-A)
 124     (B . ediff-window-B)
 125     (?B . ediff-window-B)
 126     (C . ediff-window-C)
 127     (?C . ediff-window-C)))
 128
 129
 130 (defcustom ediff-split-window-function 'split-window-vertically
 131   "*The function used to split the main window between buffer-A and buffer-B.
 132 You can set it to a horizontal split instead of the default vertical split
 133 by setting this variable to `split-window-horizontally'.
 134 You can also have your own function to do fancy splits.
 135 This variable has no effect when buffer-A/B are shown in different frames.
 136 In this case, Ediff will use those frames to display these buffers."
 137   :type 'function
 138   :group 'ediff-window)
 139
 140 (defcustom ediff-merge-split-window-function 'split-window-horizontally
 141   "*The function used to split the main window between buffer-A and buffer-B.
 142 You can set it to a vertical split instead of the default horizontal split
 143 by setting this variable to `split-window-vertically'.
 144 You can also have your own function to do fancy splits.
 145 This variable has no effect when buffer-A/B/C are shown in different frames.
 146 In this case, Ediff will use those frames to display these buffers."
 147   :type 'function
 148   :group 'ediff-window)
 149
 150 (defconst ediff-control-frame-parameters
 151   (list
 152    '(name . "Ediff")
 153    ;;'(unsplittable . t)
 154    '(minibuffer . nil)
 155    '(user-position . t)       ; Emacs only
 156    '(vertical-scroll-bars . nil)  ; Emacs only
 157    '(scrollbar-width . 0)         ; XEmacs only
 158    '(scrollbar-height . 0)        ; XEmacs only
 159    '(menu-bar-lines . 0)          ; Emacs only
 160    '(tool-bar-lines . 0)          ; Emacs 21+ only
 161    ;; don't lower but auto-raise
 162    '(auto-lower . nil)
 163    '(auto-raise . t)
 164    '(visibility . nil)
 165    ;; make initial frame small to avoid distraction
 166    '(width . 1) '(height . 1)
 167    ;; this blocks queries from  window manager as to where to put
 168    ;; ediff's control frame. we put the frame outside the display,
 169    ;; so the initial frame won't jump all over the screen
 170    (cons 'top  (if (fboundp 'ediff-display-pixel-height)
 171                    (1+ (ediff-display-pixel-height))
 172                  3000))
 173    (cons 'left (if (fboundp 'ediff-display-pixel-width)
 174                    (1+ (ediff-display-pixel-width))
 175                  3000))
 176    )
 177   "Frame parameters for displaying Ediff Control Panel.
 178 Used internally---not a user option.")
 179
 180 ;; position of the mouse; used to decide whether to warp the mouse into ctl
 181 ;; frame
 182 (ediff-defvar-local ediff-mouse-pixel-position nil "")
 183
 184 ;; not used for now
 185 (defvar ediff-mouse-pixel-threshold 30
 186   "If the user moves mouse more than this many pixels, Ediff won't warp mouse into control window.")
 187
 188 (defcustom ediff-grab-mouse t
 189   "*If t, Ediff will always grab the mouse and put it in the control frame.
 190 If 'maybe, Ediff will do it sometimes, but not after operations that require
 191 relatively long time.  If nil, the mouse will be entirely user's
 192 responsibility."
 193   :type 'boolean
 194   :group 'ediff-window)
 195
 196 (defcustom ediff-control-frame-position-function 'ediff-make-frame-position
 197   "Function to call to determine the desired location for the control panel.
 198 Expects three parameters: the control buffer, the desired width and height
 199 of the control frame.  It returns an association list
 200 of the form \(\(top . <position>\) \(left . <position>\)\)"
 201   :type 'function
 202   :group 'ediff-window)
 203
 204 (defcustom ediff-control-frame-upward-shift 42
 205   "*The upward shift of control frame from the top of buffer A's frame.
 206 Measured in pixels.
 207 This is used by the default control frame positioning function,
 208 `ediff-make-frame-position'.  This variable is provided for easy
 209 customization of the default control frame positioning."
 210   :type 'integer
 211   :group 'ediff-window)
 212
 213 (defcustom ediff-narrow-control-frame-leftward-shift (if ediff-xemacs-p 7 3)
 214   "*The leftward shift of control frame from the right edge of buf A's frame.
 215 Measured in characters.
 216 This is used by the default control frame positioning function,
 217 `ediff-make-frame-position' to adjust the position of the control frame
 218 when it shows the short menu.  This variable is provided for easy
 219 customization of the default."
 220   :type 'integer
 221   :group 'ediff-window)
 222
 223 (defcustom ediff-wide-control-frame-rightward-shift 7
 224   "*The rightward shift of control frame from the left edge of buf A's frame.
 225 Measured in characters.
 226 This is used by the default control frame positioning function,
 227 `ediff-make-frame-position' to adjust the position of the control frame
 228 when it shows the full menu.  This variable is provided for easy
 229 customization of the default."
 230   :type 'integer
 231   :group 'ediff-window)
 232
 233
 234 ;; Wide frame display
 235
 236 ;; t means Ediff is using wide display
 237 (ediff-defvar-local ediff-wide-display-p nil "")
 238 ;; keeps frame config for toggling wide display
 239 (ediff-defvar-local ediff-wide-display-orig-parameters nil
 240   "Frame parameters to be restored when the user wants to toggle the wide
 241 display off.")
 242 (ediff-defvar-local ediff-wide-display-frame nil
 243   "Frame to be used for wide display.")
 244 (ediff-defvar-local ediff-make-wide-display-function 'ediff-make-wide-display
 245   "The value is a function that is called to create a wide display.
 246 The function is called without arguments.  It should resize the frame in
 247 which buffers A, B, and C are to be displayed, and it should save the old
 248 frame parameters in `ediff-wide-display-orig-parameters'.
 249 The variable `ediff-wide-display-frame' should be set to contain
 250 the frame used for the wide display.")
 251
 252 ;; Frame used for the control panel in a windowing system.
 253 (ediff-defvar-local ediff-control-frame nil "")
 254
 255 (defcustom ediff-prefer-iconified-control-frame nil
 256   "*If t, keep control panel iconified when help message is off.
 257 This has effect only on a windowing system.
 258 If t, hitting `?' to toggle control panel off iconifies it.
 259
 260 This is only useful in Emacs and only for certain kinds of window managers,
 261 such as TWM and its derivatives, since the window manager must permit
 262 keyboard input to go into icons.  XEmacs completely ignores keyboard input
 263 into icons, regardless of the window manager."
 264   :type 'boolean
 265   :group 'ediff-window)
 266
 267 ;;; Functions
 268
 269 (defun ediff-get-window-by-clicking (wind prev-wind wind-number)
 270   (let (event)
 271     (message
 272      "Select windows by clicking.  Please click on Window %d " wind-number)
 273     (while (not (ediff-mouse-event-p (setq event (ediff-read-event))))
 274       (if (sit-for 1) ; if sequence of events, wait till the final word
 275           (beep 1))
 276       (message "Please click on Window %d " wind-number))
 277     (ediff-read-event) ; discard event
 278     (setq wind (ediff-cond-compile-for-xemacs-or-emacs
 279                 (event-window event) ; xemacs
 280                 (posn-window (event-start event)) ; emacs
 281                 )
 282           )
 283     ))
 284
 285
 286 ;; Select the lowest window on the frame.
 287 (defun ediff-select-lowest-window ()
 288   (ediff-cond-compile-for-xemacs-or-emacs
 289    (select-window (frame-lowest-window)) ; xemacs
 290    ;; emacs
 291    (let* ((lowest-window (selected-window))
 292           (bottom-edge (car (cdr (cdr (cdr (window-edges))))))
 293           (last-window (save-excursion
 294                          (other-window -1) (selected-window)))
 295           (window-search t))
 296      (while window-search
 297        (let* ((this-window (next-window))
 298               (next-bottom-edge
 299                (car (cdr (cdr (cdr (window-edges this-window)))))))
 300          (if (< bottom-edge next-bottom-edge)
 301              (progn
 302                (setq bottom-edge next-bottom-edge)
 303                (setq lowest-window this-window)))
 304
 305          (select-window this-window)
 306          (if (eq last-window this-window)
 307              (progn
 308                (select-window lowest-window)
 309                (setq window-search nil))))))
 310    ))
 311
 312
 313 ;;; Common window setup routines
 314
 315 ;; Set up the window configuration.  If POS is given, set the points to
 316 ;; the beginnings of the buffers.
 317 ;; When 3way comparison is added, this will have to choose the appropriate
 318 ;; setup function based on ediff-job-name
 319 (defun ediff-setup-windows (buffer-A buffer-B buffer-C control-buffer)
 320   ;; Make sure we are not in the minibuffer window when we try to delete
 321   ;; all other windows.
 322   (run-hooks 'ediff-before-setup-windows-hook)
 323   (if (eq (selected-window) (minibuffer-window))
 324       (other-window 1))
 325
 326   ;; in case user did a no-no on a tty
 327   (or (ediff-window-display-p)
 328       (setq ediff-window-setup-function 'ediff-setup-windows-plain))
 329
 330   (or (ediff-keep-window-config control-buffer)
 331       (funcall
 332        (ediff-with-current-buffer control-buffer ediff-window-setup-function)
 333        buffer-A buffer-B buffer-C control-buffer))
 334   (run-hooks 'ediff-after-setup-windows-hook))
 335
 336 ;; Just set up 3 windows.
 337 ;; Usually used without windowing systems
 338 ;; With windowing, we want to use dedicated frames.
 339 (defun ediff-setup-windows-plain (buffer-A buffer-B buffer-C control-buffer)
 340   (ediff-with-current-buffer control-buffer
 341     (setq ediff-multiframe nil))
 342   (if ediff-merge-job
 343       (ediff-setup-windows-plain-merge
 344        buffer-A buffer-B buffer-C control-buffer)
 345     (ediff-setup-windows-plain-compare
 346      buffer-A buffer-B buffer-C control-buffer)))
 347
 348 (defun ediff-setup-windows-plain-merge (buf-A buf-B buf-C control-buffer)
 349   ;; skip dedicated and unsplittable frames
 350   (ediff-destroy-control-frame control-buffer)
 351   (let ((window-min-height 1)
 352         split-window-function
 353         merge-window-share merge-window-lines
 354         wind-A wind-B wind-C)
 355     (ediff-with-current-buffer control-buffer
 356       (setq merge-window-share ediff-merge-window-share
 357             ;; this lets us have local versions of ediff-split-window-function
 358             split-window-function ediff-split-window-function))
 359     (delete-other-windows)
 360     (split-window-vertically)
 361     (ediff-select-lowest-window)
 362     (ediff-setup-control-buffer control-buffer)
 363
 364     ;; go to the upper window and split it betw A, B, and possibly C
 365     (other-window 1)
 366     (setq merge-window-lines
 367           (max 2 (round (* (window-height) merge-window-share))))
 368     (switch-to-buffer buf-A)
 369     (setq wind-A (selected-window))
 370
 371     ;; XEmacs used to have a lot of trouble with display
 372     ;; It did't set things right unless we tell it to sit still
 373     ;; 19.12 seems ok.
 374     ;;(if ediff-xemacs-p (sit-for 0))
 375
 376     (split-window-vertically (max 2 (- (window-height) merge-window-lines)))
 377     (if (eq (selected-window) wind-A)
 378         (other-window 1))
 379     (setq wind-C (selected-window))
 380     (switch-to-buffer buf-C)
 381
 382     (select-window wind-A)
 383     (funcall split-window-function)
 384
 385     (if (eq (selected-window) wind-A)
 386         (other-window 1))
 387     (switch-to-buffer buf-B)
 388     (setq wind-B (selected-window))
 389
 390     (ediff-with-current-buffer control-buffer
 391       (setq ediff-window-A wind-A
 392             ediff-window-B wind-B
 393             ediff-window-C wind-C))
 394
 395     (ediff-select-lowest-window)
 396     (ediff-setup-control-buffer control-buffer)
 397     ))
 398
 399
 400 ;; This function handles all comparison jobs, including 3way jobs
 401 (defun ediff-setup-windows-plain-compare (buf-A buf-B buf-C control-buffer)
 402   ;; skip dedicated and unsplittable frames
 403   (ediff-destroy-control-frame control-buffer)
 404   (let ((window-min-height 1)
 405         split-window-function wind-width-or-height
 406         three-way-comparison
 407         wind-A-start wind-B-start wind-A wind-B wind-C)
 408     (ediff-with-current-buffer control-buffer
 409       (setq wind-A-start (ediff-overlay-start
 410                           (ediff-get-value-according-to-buffer-type
 411                            'A ediff-narrow-bounds))
 412             wind-B-start (ediff-overlay-start
 413                           (ediff-get-value-according-to-buffer-type
 414                            'B  ediff-narrow-bounds))
 415             ;; this lets us have local versions of ediff-split-window-function
 416             split-window-function ediff-split-window-function
 417             three-way-comparison ediff-3way-comparison-job))
 418     (delete-other-windows)
 419     (split-window-vertically)
 420     (ediff-select-lowest-window)
 421     (ediff-setup-control-buffer control-buffer)
 422
 423     ;; go to the upper window and split it betw A, B, and possibly C
 424     (other-window 1)
 425     (switch-to-buffer buf-A)
 426     (setq wind-A (selected-window))
 427     (if three-way-comparison
 428         (setq wind-width-or-height
 429               (/ (if (eq split-window-function 'split-window-vertically)
 430                      (window-height wind-A)
 431                    (window-width wind-A))
 432                  3)))
 433
 434     ;; XEmacs used to have a lot of trouble with display
 435     ;; It did't set things right unless we told it to sit still
 436     ;; 19.12 seems ok.
 437     ;;(if ediff-xemacs-p (sit-for 0))
 438
 439     (funcall split-window-function wind-width-or-height)
 440
 441     (if (eq (selected-window) wind-A)
 442         (other-window 1))
 443     (switch-to-buffer buf-B)
 444     (setq wind-B (selected-window))
 445
 446     (if three-way-comparison
 447         (progn
 448           (funcall split-window-function) ; equally
 449           (if (eq (selected-window) wind-B)
 450               (other-window 1))
 451           (switch-to-buffer buf-C)
 452           (setq wind-C (selected-window))))
 453
 454     (ediff-with-current-buffer control-buffer
 455       (setq ediff-window-A wind-A
 456             ediff-window-B wind-B
 457             ediff-window-C wind-C))
 458
 459     ;; It is unlikely that we will want to implement 3way window comparison.
 460     ;; So, only buffers A and B are used here.
 461     (if ediff-windows-job
 462         (progn
 463           (set-window-start wind-A wind-A-start)
 464           (set-window-start wind-B wind-B-start)))
 465
 466     (ediff-select-lowest-window)
 467     (ediff-setup-control-buffer control-buffer)
 468     ))
 469
 470
 471 ;; dispatch an appropriate window setup function
 472 (defun ediff-setup-windows-multiframe (buf-A buf-B buf-C control-buf)
 473   (ediff-with-current-buffer control-buf
 474     (setq ediff-multiframe t))
 475   (if ediff-merge-job
 476       (ediff-setup-windows-multiframe-merge buf-A buf-B buf-C control-buf)
 477     (ediff-setup-windows-multiframe-compare buf-A buf-B buf-C control-buf)))
 478
 479 (defun ediff-setup-windows-multiframe-merge (buf-A buf-B buf-C control-buf)
 480 ;;; Algorithm:
 481 ;;;   1. Never use frames that have dedicated windows in them---it is bad to
 482 ;;;      destroy dedicated windows.
 483 ;;;   2. If A and B are in the same frame but C's frame is different--- use one
 484 ;;;      frame for A and B and use a separate frame for C.
 485 ;;;   3. If C's frame is non-existent, then: if the first suitable
 486 ;;;      non-dedicated frame  is different from A&B's, then use it for C.
 487 ;;;      Otherwise, put A,B, and C in one frame.
 488 ;;;   4. If buffers A, B, C are is separate frames, use them to display these
 489 ;;;      buffers.
 490
 491   ;;   Skip dedicated or iconified frames.
 492   ;;   Unsplittable frames are taken care of later.
 493   (ediff-skip-unsuitable-frames 'ok-unsplittable)
 494
 495   (let* ((window-min-height 1)
 496          (wind-A (ediff-get-visible-buffer-window buf-A))
 497          (wind-B (ediff-get-visible-buffer-window buf-B))
 498          (wind-C (ediff-get-visible-buffer-window buf-C))
 499          (frame-A (if wind-A (window-frame wind-A)))
 500          (frame-B (if wind-B (window-frame wind-B)))
 501          (frame-C (if wind-C (window-frame wind-C)))
 502          ;; on wide display, do things in one frame
 503          (force-one-frame
 504           (ediff-with-current-buffer control-buf ediff-wide-display-p))
 505          ;; this lets us have local versions of ediff-split-window-function
 506          (split-window-function
 507           (ediff-with-current-buffer control-buf ediff-split-window-function))
 508          (orig-wind (selected-window))
 509          (orig-frame (selected-frame))
 510          (use-same-frame (or force-one-frame
 511                              ;; A and C must be in one frame
 512                              (eq frame-A (or frame-C orig-frame))
 513                              ;; B and C must be in one frame
 514                              (eq frame-B (or frame-C orig-frame))
 515                              ;; A or B is not visible
 516                              (not (frame-live-p frame-A))
 517                              (not (frame-live-p frame-B))
 518                              ;; A or B is not suitable for display
 519                              (not (ediff-window-ok-for-display wind-A))
 520                              (not (ediff-window-ok-for-display wind-B))
 521                              ;; A and B in the same frame, and no good frame
 522                              ;; for C
 523                              (and (eq frame-A frame-B)
 524                                   (not (frame-live-p frame-C)))
 525                              ))
 526          ;; use-same-frame-for-AB implies wind A and B are ok for display
 527          (use-same-frame-for-AB (and (not use-same-frame)
 528                                      (eq frame-A frame-B)))
 529          (merge-window-share (ediff-with-current-buffer control-buf
 530                                ediff-merge-window-share))
 531          merge-window-lines
 532          designated-minibuffer-frame
 533          done-A done-B done-C)
 534
 535     ;; buf-A on its own
 536     (if (and (window-live-p wind-A)
 537              (null use-same-frame) ; implies wind-A is suitable
 538              (null use-same-frame-for-AB))
 539         (progn ; bug A on its own
 540           ;; buffer buf-A is seen in live wind-A
 541           (select-window wind-A)
 542           (delete-other-windows)
 543           (setq wind-A (selected-window))
 544           (setq done-A t)))
 545
 546     ;; buf-B on its own
 547     (if (and (window-live-p wind-B)
 548              (null use-same-frame) ; implies wind-B is suitable
 549              (null use-same-frame-for-AB))
 550         (progn ; buf B on its own
 551           ;; buffer buf-B is seen in live wind-B
 552           (select-window wind-B)
 553           (delete-other-windows)
 554           (setq wind-B (selected-window))
 555           (setq done-B t)))
 556
 557     ;; buf-C on its own
 558     (if (and (window-live-p wind-C)
 559              (ediff-window-ok-for-display wind-C)
 560              (null use-same-frame)) ; buf C on its own
 561         (progn
 562           ;; buffer buf-C is seen in live wind-C
 563           (select-window wind-C)
 564           (delete-other-windows)
 565           (setq wind-C (selected-window))
 566           (setq done-C t)))
 567
 568     (if (and use-same-frame-for-AB  ; implies wind A and B are suitable
 569              (window-live-p wind-A))
 570         (progn
 571           ;; wind-A must already be displaying buf-A
 572           (select-window wind-A)
 573           (delete-other-windows)
 574           (setq wind-A (selected-window))
 575
 576           (funcall split-window-function)
 577           (if (eq (selected-window) wind-A)
 578               (other-window 1))
 579           (switch-to-buffer buf-B)
 580           (setq wind-B (selected-window))
 581
 582           (setq done-A t
 583                 done-B t)))
 584
 585     (if use-same-frame
 586         (let ((window-min-height 1))
 587           (if (and (eq frame-A frame-B)
 588                    (eq frame-B frame-C)
 589                    (frame-live-p frame-A))
 590               (select-frame frame-A)
 591             ;; avoid dedicated and non-splittable windows
 592             (ediff-skip-unsuitable-frames))
 593           (delete-other-windows)
 594           (setq merge-window-lines
 595                 (max 2 (round (* (window-height) merge-window-share))))
 596           (switch-to-buffer buf-A)
 597           (setq wind-A (selected-window))
 598
 599           (split-window-vertically
 600            (max 2 (- (window-height) merge-window-lines)))
 601           (if (eq (selected-window) wind-A)
 602               (other-window 1))
 603           (setq wind-C (selected-window))
 604           (switch-to-buffer buf-C)
 605
 606           (select-window wind-A)
 607
 608           (funcall split-window-function)
 609           (if (eq (selected-window) wind-A)
 610               (other-window 1))
 611           (switch-to-buffer buf-B)
 612           (setq wind-B (selected-window))
 613
 614           (setq done-A t
 615                 done-B t
 616                 done-C t)
 617           ))
 618
 619     (or done-A  ; Buf A to be set in its own frame,
 620               ;;; or it was set before because use-same-frame = 1
 621         (progn
 622           ;; Buf-A was not set up yet as it wasn't visible,
 623           ;; and use-same-frame = nil, use-same-frame-for-AB = nil
 624           (select-window orig-wind)
 625           (delete-other-windows)
 626           (switch-to-buffer buf-A)
 627           (setq wind-A (selected-window))
 628           ))
 629     (or done-B  ; Buf B to be set in its own frame,
 630               ;;; or it was set before because use-same-frame = 1
 631         (progn
 632           ;; Buf-B was not set up yet as it wasn't visible
 633           ;; and use-same-frame = nil, use-same-frame-for-AB = nil
 634           (select-window orig-wind)
 635           (delete-other-windows)
 636           (switch-to-buffer buf-B)
 637           (setq wind-B (selected-window))
 638           ))
 639
 640     (or done-C  ; Buf C to be set in its own frame,
 641               ;;; or it was set before because use-same-frame = 1
 642         (progn
 643           ;; Buf-C was not set up yet as it wasn't visible
 644           ;; and use-same-frame = nil
 645           (select-window orig-wind)
 646           (delete-other-windows)
 647           (switch-to-buffer buf-C)
 648           (setq wind-C (selected-window))
 649           ))
 650
 651     (ediff-with-current-buffer control-buf
 652       (setq ediff-window-A wind-A
 653             ediff-window-B wind-B
 654             ediff-window-C wind-C)
 655       (setq frame-A (window-frame ediff-window-A)
 656             designated-minibuffer-frame
 657             (window-frame (minibuffer-window frame-A))))
 658
 659     (ediff-setup-control-frame control-buf designated-minibuffer-frame)
 660     ))
 661
 662
 663 ;; Window setup for all comparison jobs, including 3way comparisons
 664 (defun ediff-setup-windows-multiframe-compare (buf-A buf-B buf-C control-buf)
 665 ;;; Algorithm:
 666 ;;;    If a buffer is seen in a frame, use that frame for that buffer.
 667 ;;;    If it is not seen, use the current frame.
 668 ;;;    If both buffers are not seen, they share the current frame.  If one
 669 ;;;    of the buffers is not seen, it is placed in the current frame (where
 670 ;;;    ediff started).  If that frame is displaying the other buffer, it is
 671 ;;;    shared between the two buffers.
 672 ;;;    However, if we decide to put both buffers in one frame
 673 ;;;    and the selected frame isn't splittable, we create a new frame and
 674 ;;;    put both buffers there, event if one of this buffers is visible in
 675 ;;;    another frame.
 676
 677   ;; Skip dedicated or iconified frames.
 678   ;; Unsplittable frames are taken care of later.
 679   (ediff-skip-unsuitable-frames 'ok-unsplittable)
 680
 681   (let* ((window-min-height 1)
 682          (wind-A (ediff-get-visible-buffer-window buf-A))
 683          (wind-B (ediff-get-visible-buffer-window buf-B))
 684          (wind-C (ediff-get-visible-buffer-window buf-C))
 685          (frame-A (if wind-A (window-frame wind-A)))
 686          (frame-B (if wind-B (window-frame wind-B)))
 687          (frame-C (if wind-C (window-frame wind-C)))
 688          (ctl-frame-exists-p (ediff-with-current-buffer control-buf
 689                                (frame-live-p ediff-control-frame)))
 690          ;; on wide display, do things in one frame
 691          (force-one-frame
 692           (ediff-with-current-buffer control-buf ediff-wide-display-p))
 693          ;; this lets us have local versions of ediff-split-window-function
 694          (split-window-function
 695           (ediff-with-current-buffer control-buf ediff-split-window-function))
 696          (three-way-comparison
 697           (ediff-with-current-buffer control-buf ediff-3way-comparison-job))
 698          (orig-wind (selected-window))
 699          (use-same-frame (or force-one-frame
 700                              (eq frame-A frame-B)
 701                              (not (ediff-window-ok-for-display wind-A))
 702                              (not (ediff-window-ok-for-display wind-B))
 703                              (if three-way-comparison
 704                                  (or (eq frame-A frame-C)
 705                                      (eq frame-B frame-C)
 706                                      (not (ediff-window-ok-for-display wind-C))
 707                                      (not (frame-live-p frame-A))
 708                                      (not (frame-live-p frame-B))
 709                                      (not (frame-live-p frame-C))))
 710                              (and (not (frame-live-p frame-B))
 711                                   (or ctl-frame-exists-p
 712                                       (eq frame-A (selected-frame))))
 713                              (and (not (frame-live-p frame-A))
 714                                   (or ctl-frame-exists-p
 715                                       (eq frame-B (selected-frame))))))
 716          wind-A-start wind-B-start
 717          designated-minibuffer-frame
 718          done-A done-B done-C)
 719
 720     (ediff-with-current-buffer control-buf
 721       (setq wind-A-start (ediff-overlay-start
 722                           (ediff-get-value-according-to-buffer-type
 723                            'A ediff-narrow-bounds))
 724             wind-B-start (ediff-overlay-start
 725                           (ediff-get-value-according-to-buffer-type
 726                            'B ediff-narrow-bounds))))
 727
 728     (if (and (window-live-p wind-A) (null use-same-frame)) ; buf-A on its own
 729         (progn
 730           ;; buffer buf-A is seen in live wind-A
 731           (select-window wind-A) ; must be displaying buf-A
 732           (delete-other-windows)
 733           (setq wind-A (selected-window))
 734           (setq done-A t)))
 735
 736     (if (and (window-live-p wind-B) (null use-same-frame)) ; buf B on its own
 737         (progn
 738           ;; buffer buf-B is seen in live wind-B
 739           (select-window wind-B) ; must be displaying buf-B
 740           (delete-other-windows)
 741           (setq wind-B (selected-window))
 742           (setq done-B t)))
 743
 744     (if (and (window-live-p wind-C) (null use-same-frame)) ; buf C on its own
 745         (progn
 746           ;; buffer buf-C is seen in live wind-C
 747           (select-window wind-C) ; must be displaying buf-C
 748           (delete-other-windows)
 749           (setq wind-C (selected-window))
 750           (setq done-C t)))
 751
 752     (if use-same-frame
 753         (let (wind-width-or-height) ; this affects 3way setups only
 754           (if (and (eq frame-A frame-B) (frame-live-p frame-A))
 755               (select-frame frame-A)
 756             ;; avoid dedicated and non-splittable windows
 757             (ediff-skip-unsuitable-frames))
 758           (delete-other-windows)
 759           (switch-to-buffer buf-A)
 760           (setq wind-A (selected-window))
 761
 762           (if three-way-comparison
 763               (setq wind-width-or-height
 764                     (/
 765                      (if (eq split-window-function 'split-window-vertically)
 766                          (window-height wind-A)
 767                        (window-width wind-A))
 768                      3)))
 769
 770           (funcall split-window-function wind-width-or-height)
 771           (if (eq (selected-window) wind-A)
 772               (other-window 1))
 773           (switch-to-buffer buf-B)
 774           (setq wind-B (selected-window))
 775
 776           (if three-way-comparison
 777               (progn
 778                 (funcall split-window-function) ; equally
 779                 (if (memq (selected-window) (list wind-A wind-B))
 780                     (other-window 1))
 781                 (switch-to-buffer buf-C)
 782                 (setq wind-C (selected-window))))
 783           (setq done-A t
 784                 done-B t
 785                 done-C t)
 786           ))
 787
 788     (or done-A  ; Buf A to be set in its own frame
 789               ;;; or it was set before because use-same-frame = 1
 790         (progn
 791           ;; Buf-A was not set up yet as it wasn't visible,
 792           ;; and use-same-frame = nil
 793           (select-window orig-wind)
 794           (delete-other-windows)
 795           (switch-to-buffer buf-A)
 796           (setq wind-A (selected-window))
 797           ))
 798     (or done-B  ; Buf B to be set in its own frame
 799               ;;; or it was set before because use-same-frame = 1
 800         (progn
 801           ;; Buf-B was not set up yet as it wasn't visible,
 802           ;; and use-same-frame = nil
 803           (select-window orig-wind)
 804           (delete-other-windows)
 805           (switch-to-buffer buf-B)
 806           (setq wind-B (selected-window))
 807           ))
 808
 809     (if three-way-comparison
 810         (or done-C  ; Buf C to be set in its own frame
 811                   ;;; or it was set before because use-same-frame = 1
 812             (progn
 813               ;; Buf-C was not set up yet as it wasn't visible,
 814               ;; and use-same-frame = nil
 815               (select-window orig-wind)
 816               (delete-other-windows)
 817               (switch-to-buffer buf-C)
 818               (setq wind-C (selected-window))
 819               )))
 820
 821     (ediff-with-current-buffer control-buf
 822       (setq ediff-window-A wind-A
 823             ediff-window-B wind-B
 824             ediff-window-C wind-C)
 825
 826       (setq frame-A (window-frame ediff-window-A)
 827             designated-minibuffer-frame
 828             (window-frame (minibuffer-window frame-A))))
 829
 830     ;; It is unlikely that we'll implement a version of ediff-windows that
 831     ;; would compare 3 windows at once.  So, we don't use buffer C here.
 832     (if ediff-windows-job
 833         (progn
 834           (set-window-start wind-A wind-A-start)
 835           (set-window-start wind-B wind-B-start)))
 836
 837     (ediff-setup-control-frame control-buf designated-minibuffer-frame)
 838     ))
 839
 840 ;; skip unsplittable frames and frames that have dedicated windows.
 841 ;; create a new splittable frame if none is found
 842 (defun ediff-skip-unsuitable-frames (&optional ok-unsplittable)
 843   (if (ediff-window-display-p)
 844       (let ((wind-frame (window-frame (selected-window)))
 845              seen-windows)
 846         (while (and (not (memq (selected-window) seen-windows))
 847                     (or
 848                      (ediff-frame-has-dedicated-windows wind-frame)
 849                      (ediff-frame-iconified-p wind-frame)
 850                      ;; skip small windows
 851                      (< (frame-height wind-frame)
 852                         (* 3 window-min-height))
 853                      (if ok-unsplittable
 854                          nil
 855                        (ediff-frame-unsplittable-p wind-frame))))
 856           ;; remember history
 857           (setq seen-windows (cons (selected-window) seen-windows))
 858           ;; try new window
 859           (other-window 1 t)
 860           (setq wind-frame (window-frame (selected-window)))
 861           )
 862         (if (memq (selected-window) seen-windows)
 863             ;; fed up, no appropriate frames
 864             (setq wind-frame (make-frame '((unsplittable)))))
 865
 866         (select-frame wind-frame)
 867         )))
 868
 869 (defun ediff-frame-has-dedicated-windows (frame)
 870   (let (ans)
 871     (walk-windows
 872      (lambda (wind) (if (window-dedicated-p wind)
 873                         (setq ans t)))
 874      'ignore-minibuffer
 875      frame)
 876     ans))
 877
 878 ;; window is ok, if it is only one window on the frame, not counting the
 879 ;; minibuffer, or none of the frame's windows is dedicated.
 880 ;; The idea is that it is bad to destroy dedicated windows while creating an
 881 ;; ediff window setup
 882 (defun ediff-window-ok-for-display (wind)
 883   (and
 884    (window-live-p wind)
 885    (or
 886     ;; only one window
 887     (eq wind (next-window wind 'ignore-minibuffer (window-frame wind)))
 888     ;; none is dedicated
 889     (not (ediff-frame-has-dedicated-windows (window-frame wind)))
 890     )))
 891
 892 ;; Prepare or refresh control frame
 893 (defun ediff-setup-control-frame (ctl-buffer designated-minibuffer-frame)
 894   (let ((window-min-height 1)
 895         ctl-frame-iconified-p dont-iconify-ctl-frame deiconify-ctl-frame
 896         ctl-frame old-ctl-frame lines
 897         ;; user-grabbed-mouse
 898         fheight fwidth adjusted-parameters)
 899
 900     (ediff-with-current-buffer ctl-buffer
 901       (ediff-cond-compile-for-xemacs-or-emacs
 902        (when (featurep 'menubar) (set-buffer-menubar nil)) ; xemacs
 903        nil ; emacs
 904        )
 905       ;;(setq user-grabbed-mouse (ediff-user-grabbed-mouse))
 906       (run-hooks 'ediff-before-setup-control-frame-hook))
 907
 908     (setq old-ctl-frame (ediff-with-current-buffer ctl-buffer ediff-control-frame))
 909     (ediff-with-current-buffer ctl-buffer
 910       (setq ctl-frame (if (frame-live-p old-ctl-frame)
 911                           old-ctl-frame
 912                         (make-frame ediff-control-frame-parameters))
 913             ediff-control-frame ctl-frame)
 914       ;; protect against undefined face-attribute
 915       (condition-case nil
 916           (ediff-cond-compile-for-xemacs-or-emacs
 917            nil ; xemacs
 918            (when (face-attribute 'mode-line :box)
 919              (set-face-attribute 'mode-line ctl-frame :box nil))
 920            )
 921         (error))
 922       )
 923
 924     (setq ctl-frame-iconified-p (ediff-frame-iconified-p ctl-frame))
 925     (select-frame ctl-frame)
 926     (if (window-dedicated-p (selected-window))
 927         ()
 928       (delete-other-windows)
 929       (switch-to-buffer ctl-buffer))
 930
 931     ;; must be before ediff-setup-control-buffer
 932     ;; just a precaution--we should be in ctl-buffer already
 933     (ediff-with-current-buffer ctl-buffer
 934       (make-local-variable 'frame-title-format)
 935       (make-local-variable 'frame-icon-title-format)    ; XEmacs
 936       (make-local-variable 'icon-title-format))         ; Emacs
 937
 938     (ediff-setup-control-buffer ctl-buffer)
 939     (setq dont-iconify-ctl-frame
 940           (not (string= ediff-help-message ediff-brief-help-message)))
 941     (setq deiconify-ctl-frame
 942           (and (eq this-command 'ediff-toggle-help)
 943                dont-iconify-ctl-frame))
 944
 945     ;; 1 more line for the modeline
 946     (setq lines (1+ (count-lines (point-min) (point-max)))
 947           fheight lines
 948           fwidth (max (+ (ediff-help-message-line-length) 2)
 949                       (ediff-compute-toolbar-width))
 950           adjusted-parameters
 951           (list
 952            ;; possibly change surrogate minibuffer
 953            (cons 'minibuffer
 954                  (minibuffer-window
 955                   designated-minibuffer-frame))
 956            (cons 'width fwidth)
 957            (cons 'height fheight)
 958            (cons 'user-position t)
 959            ))
 960
 961     ;; adjust autoraise
 962     (setq adjusted-parameters
 963           (cons (if ediff-use-long-help-message
 964                     '(auto-raise . nil)
 965                   '(auto-raise . t))
 966                 adjusted-parameters))
 967
 968     ;; In XEmacs, buffer menubar needs to be killed before frame parameters
 969     ;; are changed.
 970     (if (ediff-has-toolbar-support-p)
 971         (ediff-cond-compile-for-xemacs-or-emacs
 972          (progn ; xemacs
 973            (if (ediff-has-gutter-support-p)
 974                (set-specifier top-gutter (list ctl-frame nil)))
 975            (sit-for 0)
 976            (set-specifier top-toolbar-height (list ctl-frame 0))
 977            ;;(set-specifier bottom-toolbar-height (list ctl-frame 0))
 978            (set-specifier left-toolbar-width (list ctl-frame 0))
 979            (set-specifier right-toolbar-width (list ctl-frame 0))
 980            )
 981          nil ; emacs
 982          )
 983       )
 984
 985     ;; Under OS/2 (emx) we have to call modify frame parameters twice, in order
 986     ;; to make sure that at least once we do it for non-iconified frame.  If
 987     ;; appears that in the OS/2 port of Emacs, one can't modify frame
 988     ;; parameters of iconified frames.  As a precaution, we do likewise for
 989     ;; windows-nt.
 990     (if (memq system-type '(emx windows-nt windows-95))
 991         (modify-frame-parameters ctl-frame adjusted-parameters))
 992
 993     ;; make or zap toolbar (if not requested)
 994     (ediff-make-bottom-toolbar ctl-frame)
 995
 996     (goto-char (point-min))
 997
 998     (modify-frame-parameters ctl-frame adjusted-parameters)
 999     (make-frame-visible ctl-frame)
1000
1001     ;; This works around a bug in 19.25 and earlier.  There, if frame gets
1002     ;; iconified, the current buffer changes to that of the frame that
1003     ;; becomes exposed as a result of this iconification.
1004     ;; So, we make sure the current buffer doesn't change.
1005     (select-frame ctl-frame)
1006     (ediff-refresh-control-frame)
1007
1008     (cond ((and ediff-prefer-iconified-control-frame
1009                 (not ctl-frame-iconified-p) (not dont-iconify-ctl-frame))
1010            (iconify-frame ctl-frame))
1011           ((or deiconify-ctl-frame (not ctl-frame-iconified-p))
1012            (raise-frame ctl-frame)))
1013
1014     (set-window-dedicated-p (selected-window) t)
1015
1016     ;; Now move the frame.  We must do it separately due to an obscure bug in
1017     ;; XEmacs
1018     (modify-frame-parameters
1019      ctl-frame
1020      (funcall ediff-control-frame-position-function ctl-buffer fwidth fheight))
1021
1022     ;; synchronize so the cursor will move to control frame
1023     ;; per RMS suggestion
1024     (if (ediff-window-display-p)
1025         (let ((count 7))
1026           (sit-for .1)
1027           (while (and (not (frame-visible-p ctl-frame)) (> count 0))
1028             (setq count (1- count))
1029             (sit-for .3))))
1030
1031     (or (ediff-frame-iconified-p ctl-frame)
1032         ;; don't warp the mouse, unless ediff-grab-mouse = t
1033         (ediff-reset-mouse ctl-frame
1034                            (or (eq this-command 'ediff-quit)
1035                                (not (eq ediff-grab-mouse t)))))
1036
1037     (if ediff-xemacs-p
1038         (ediff-with-current-buffer ctl-buffer
1039           (ediff-cond-compile-for-xemacs-or-emacs
1040            (make-local-hook 'select-frame-hook) ; xemacs
1041            nil     ; emacs
1042            )
1043           (add-hook
1044            'select-frame-hook 'ediff-xemacs-select-frame-hook nil 'local)
1045           ))
1046
1047     (ediff-with-current-buffer ctl-buffer
1048       (run-hooks 'ediff-after-setup-control-frame-hook))
1049     ))
1050
1051
1052 (defun ediff-destroy-control-frame (ctl-buffer)
1053   (ediff-with-current-buffer ctl-buffer
1054     (if (and (ediff-window-display-p) (frame-live-p ediff-control-frame))
1055         (let ((ctl-frame ediff-control-frame))
1056           (ediff-cond-compile-for-xemacs-or-emacs
1057            (when (featurep 'menubar)
1058              (set-buffer-menubar default-menubar)) ; xemacs
1059            nil ; emacs
1060            )
1061           (setq ediff-control-frame nil)
1062           (delete-frame ctl-frame)
1063           )))
1064   (ediff-skip-unsuitable-frames)
1065   ;;(ediff-reset-mouse nil)
1066   )
1067
1068
1069 ;; finds a good place to clip control frame
1070 (defun ediff-make-frame-position (ctl-buffer ctl-frame-width ctl-frame-height)
1071   (ediff-with-current-buffer ctl-buffer
1072     (let* ((frame-A (window-frame ediff-window-A))
1073            (frame-A-parameters (frame-parameters frame-A))
1074            (frame-A-top (eval (cdr (assoc 'top frame-A-parameters))))
1075            (frame-A-left (eval (cdr (assoc 'left frame-A-parameters))))
1076            (frame-A-width (frame-width frame-A))
1077            (ctl-frame ediff-control-frame)
1078            horizontal-adjustment upward-adjustment
1079            ctl-frame-top ctl-frame-left)
1080
1081       ;; Multiple control frames are clipped based on the value of
1082       ;; ediff-control-buffer-number.  This is done in order not to obscure
1083       ;; other active control panels.
1084       (setq horizontal-adjustment (* 2 ediff-control-buffer-number)
1085             upward-adjustment (* -14 ediff-control-buffer-number))
1086
1087       (setq ctl-frame-top
1088             (- frame-A-top upward-adjustment ediff-control-frame-upward-shift)
1089             ctl-frame-left
1090             (+ frame-A-left
1091                (if ediff-use-long-help-message
1092                    (* (ediff-frame-char-width ctl-frame)
1093                       (+ ediff-wide-control-frame-rightward-shift
1094                          horizontal-adjustment))
1095                  (- (* frame-A-width (ediff-frame-char-width frame-A))
1096                     (* (ediff-frame-char-width ctl-frame)
1097                        (+ ctl-frame-width
1098                           ediff-narrow-control-frame-leftward-shift
1099                           horizontal-adjustment))))))
1100       (setq ctl-frame-top
1101             (min ctl-frame-top
1102                  (- (ediff-display-pixel-height)
1103                     (* 2 ctl-frame-height
1104                        (ediff-frame-char-height ctl-frame))))
1105             ctl-frame-left
1106             (min ctl-frame-left
1107                  (- (ediff-display-pixel-width)
1108                     (* ctl-frame-width (ediff-frame-char-width ctl-frame)))))
1109       ;; keep ctl frame within the visible bounds
1110       (setq ctl-frame-top (max ctl-frame-top 1)
1111             ctl-frame-left (max ctl-frame-left 1))
1112
1113       (list (cons 'top ctl-frame-top)
1114             (cons 'left ctl-frame-left))
1115       )))
1116
1117 (defun ediff-xemacs-select-frame-hook ()
1118   (if (and (equal (selected-frame) ediff-control-frame)
1119            (not ediff-use-long-help-message))
1120       (raise-frame ediff-control-frame)))
1121
1122 (defun ediff-make-wide-display ()
1123   "Construct an alist of parameters for the wide display.
1124 Saves the old frame parameters in `ediff-wide-display-orig-parameters'.
1125 The frame to be resized is kept in `ediff-wide-display-frame'.
1126 This function modifies only the left margin and the width of the display.
1127 It assumes that it is called from within the control buffer."
1128   (if (not (fboundp 'ediff-display-pixel-width))
1129       (error "Can't determine display width"))
1130   (let* ((frame-A (window-frame ediff-window-A))
1131          (frame-A-params (frame-parameters frame-A))
1132          (cw (ediff-frame-char-width frame-A))
1133          (wd (- (/ (ediff-display-pixel-width) cw) 5)))
1134     (setq ediff-wide-display-orig-parameters
1135           (list (cons 'left (max 0 (eval (cdr (assoc 'left frame-A-params)))))
1136                 (cons 'width (cdr (assoc 'width frame-A-params))))
1137           ediff-wide-display-frame frame-A)
1138     (modify-frame-parameters
1139      frame-A `((left . ,cw) (width . ,wd) (user-position t)))))
1140
1141
1142 ;; Revise the mode line to display which difference we have selected
1143 ;; Also resets modelines of buffers A/B, since they may be clobbered by
1144 ;; anothe invocations of Ediff.
1145 (defun ediff-refresh-mode-lines ()
1146   (let (buf-A-state-diff buf-B-state-diff buf-C-state-diff buf-C-state-merge)
1147
1148     (if (ediff-valid-difference-p)
1149         (setq
1150          buf-C-state-diff (ediff-get-state-of-diff ediff-current-difference 'C)
1151          buf-C-state-merge (ediff-get-state-of-merge ediff-current-difference)
1152          buf-A-state-diff (ediff-get-state-of-diff ediff-current-difference 'A)
1153          buf-B-state-diff (ediff-get-state-of-diff ediff-current-difference 'B)
1154          buf-A-state-diff (if buf-A-state-diff
1155                               (format "[%s] " buf-A-state-diff)
1156                             "")
1157          buf-B-state-diff (if buf-B-state-diff
1158                               (format "[%s] " buf-B-state-diff)
1159                             "")
1160          buf-C-state-diff (if (and (ediff-buffer-live-p ediff-buffer-C)
1161                                    (or buf-C-state-diff buf-C-state-merge))
1162                               (format "[%s%s%s] "
1163                                       (or buf-C-state-diff "")
1164                                       (if buf-C-state-merge
1165                                           (concat " " buf-C-state-merge)
1166                                         "")
1167                                       (if (ediff-get-state-of-ancestor
1168                                            ediff-current-difference)
1169                                           " AncestorEmpty"
1170                                         "")
1171                                       )
1172                             ""))
1173       (setq buf-A-state-diff ""
1174             buf-B-state-diff ""
1175             buf-C-state-diff ""))
1176
1177     ;; control buffer format
1178     (setq mode-line-format
1179           (if (ediff-narrow-control-frame-p)
1180               (list "   " mode-line-buffer-identification)
1181             (list "-- " mode-line-buffer-identification "        Quick Help")))
1182     ;; control buffer id
1183     (setq mode-line-buffer-identification
1184           (if (ediff-narrow-control-frame-p)
1185               (ediff-make-narrow-control-buffer-id 'skip-name)
1186             (ediff-make-wide-control-buffer-id)))
1187     ;; Force mode-line redisplay
1188     (force-mode-line-update)
1189
1190     (if (and (ediff-window-display-p) (frame-live-p ediff-control-frame))
1191         (ediff-refresh-control-frame))
1192
1193     (ediff-with-current-buffer ediff-buffer-A
1194       (setq ediff-diff-status buf-A-state-diff)
1195       (ediff-strip-mode-line-format)
1196       (setq mode-line-format
1197             (list " A: " 'ediff-diff-status mode-line-format))
1198       (force-mode-line-update))
1199     (ediff-with-current-buffer ediff-buffer-B
1200       (setq ediff-diff-status buf-B-state-diff)
1201       (ediff-strip-mode-line-format)
1202       (setq mode-line-format
1203             (list " B: " 'ediff-diff-status mode-line-format))
1204       (force-mode-line-update))
1205     (if ediff-3way-job
1206         (ediff-with-current-buffer ediff-buffer-C
1207           (setq ediff-diff-status buf-C-state-diff)
1208           (ediff-strip-mode-line-format)
1209           (setq mode-line-format
1210                 (list " C: " 'ediff-diff-status mode-line-format))
1211           (force-mode-line-update)))
1212     (if (ediff-buffer-live-p ediff-ancestor-buffer)
1213         (ediff-with-current-buffer ediff-ancestor-buffer
1214           (ediff-strip-mode-line-format)
1215           ;; we keep the second dummy string in the mode line format of the
1216           ;; ancestor, since for other buffers Ediff prepends 2 strings and
1217           ;; ediff-strip-mode-line-format expects that.
1218           (setq mode-line-format
1219                 (list " Ancestor: "
1220                       (cond ((not (stringp buf-C-state-merge))
1221                              "")
1222                             ((string-match "prefer-A" buf-C-state-merge)
1223                              "[=diff(B)] ")
1224                             ((string-match "prefer-B" buf-C-state-merge)
1225                              "[=diff(A)] ")
1226                             (t ""))
1227                       mode-line-format))))
1228     ))
1229
1230
1231 (defun ediff-refresh-control-frame ()
1232   (if ediff-emacs-p
1233       ;; set frame/icon titles for Emacs
1234       (modify-frame-parameters
1235        ediff-control-frame
1236        (list (cons 'title (ediff-make-base-title))
1237              (cons 'icon-name (ediff-make-narrow-control-buffer-id))
1238              ))
1239     ;; set frame/icon titles for XEmacs
1240     (setq frame-title-format (ediff-make-base-title)
1241           frame-icon-title-format (ediff-make-narrow-control-buffer-id))
1242     ;; force an update of the frame title
1243     (modify-frame-parameters ediff-control-frame '(()))))
1244
1245
1246 (defun ediff-make-narrow-control-buffer-id (&optional skip-name)
1247   (concat
1248    (if skip-name
1249        " "
1250      (ediff-make-base-title))
1251    (cond ((< ediff-current-difference 0)
1252           (format " _/%d" ediff-number-of-differences))
1253          ((>= ediff-current-difference ediff-number-of-differences)
1254           (format " $/%d" ediff-number-of-differences))
1255          (t
1256           (format " %d/%d"
1257                   (1+ ediff-current-difference)
1258                   ediff-number-of-differences)))))
1259
1260 (defun ediff-make-base-title ()
1261   (concat
1262    (cdr (assoc 'name ediff-control-frame-parameters))
1263    ediff-control-buffer-suffix))
1264
1265 (defun ediff-make-wide-control-buffer-id ()
1266   (cond ((< ediff-current-difference 0)
1267          (list (format "%%b   At start of %d diffs"
1268                        ediff-number-of-differences)))
1269         ((>= ediff-current-difference ediff-number-of-differences)
1270          (list (format "%%b   At end of %d diffs"
1271                        ediff-number-of-differences)))
1272         (t
1273          (list (format "%%b   diff %d of %d"
1274                        (1+ ediff-current-difference)
1275                        ediff-number-of-differences)))))
1276
1277
1278
1279 ;; If buff is not live, return nil
1280 (defun ediff-get-visible-buffer-window (buff)
1281   (if (ediff-buffer-live-p buff)
1282       (if ediff-xemacs-p
1283           (get-buffer-window buff t)
1284         (get-buffer-window buff 'visible))))
1285
1286
1287 ;;; Functions to decide when to redraw windows
1288
1289 (defun ediff-keep-window-config (control-buf)
1290   (and (eq control-buf (current-buffer))
1291        (/= (buffer-size) 0)
1292        (ediff-with-current-buffer control-buf
1293          (let ((ctl-wind ediff-control-window)
1294                (A-wind ediff-window-A)
1295                (B-wind ediff-window-B)
1296                (C-wind ediff-window-C))
1297
1298            (and
1299             (ediff-window-visible-p A-wind)
1300             (ediff-window-visible-p B-wind)
1301             ;; if buffer C is defined then take it into account
1302             (or (not ediff-3way-job)
1303                 (ediff-window-visible-p C-wind))
1304             (eq (window-buffer A-wind) ediff-buffer-A)
1305             (eq (window-buffer B-wind) ediff-buffer-B)
1306             (or (not ediff-3way-job)
1307                 (eq (window-buffer C-wind) ediff-buffer-C))
1308             (string= ediff-window-config-saved
1309                      (format "%S%S%S%S%S%S%S"
1310                              ctl-wind A-wind B-wind C-wind
1311                              ediff-split-window-function
1312                              (ediff-multiframe-setup-p)
1313                              ediff-wide-display-p)))))))
1314
1315
1316 (provide 'ediff-wind)
1317
1318
1319 ;;; Local Variables:
1320 ;;; eval: (put 'ediff-defvar-local 'lisp-indent-hook 'defun)
1321 ;;; eval: (put 'ediff-with-current-buffer 'lisp-indent-hook 1)
1322 ;;; eval: (put 'ediff-with-current-buffer 'edebug-form-spec '(form body))
1323 ;;; End:
1324
1325 ;;; arch-tag: 73d9a5d7-eed7-4d9c-8b4b-21d5d78eb597
1326 ;;; ediff-wind.el ends here