code.delx.au - gnu-emacs/blob - lisp/saveplace.el

   1 ;;; saveplace.el --- automatically save place in files
   2
   3 ;; Copyright (C) 1993, 1994, 2001, 2002, 2003, 2004,
   4 ;;   2005, 2006 Free Software Foundation, Inc.
   5
   6 ;; Author: Karl Fogel <kfogel@red-bean.com>
   7 ;; Maintainer: FSF
   8 ;; Created: July, 1993
   9 ;; Keywords: bookmarks, placeholders
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software; you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation; either version 2, or (at your option)
  16 ;; any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  25 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  26 ;; Boston, MA 02110-1301, USA.
  27
  28 ;;; Commentary:
  29
  30 ;; Automatically save place in files, so that visiting them later
  31 ;; (even during a different Emacs session) automatically moves point
  32 ;; to the saved position, when the file is first found.  Uses the
  33 ;; value of buffer-local variable save-place to determine whether to
  34 ;; save position or not.
  35 ;;
  36 ;; Thanks to Stefan Schoef, who sent a patch with the
  37 ;; `save-place-version-control' stuff in it.
  38
  39 ;;; Code:
  40
  41 ;; this is what I was using during testing:
  42 ;; (define-key ctl-x-map "p" 'toggle-save-place)
  43
  44 (defgroup save-place nil
  45   "Automatically save place in files."
  46   :group 'data)
  47
  48
  49 (defvar save-place-alist nil
  50   "Alist of saved places to go back to when revisiting files.
  51 Each element looks like (FILENAME . POSITION);
  52 visiting file FILENAME goes automatically to position POSITION
  53 rather than the beginning of the buffer.
  54 This alist is saved between Emacs sessions.")
  55
  56 (defcustom save-place nil
  57   "*Non-nil means automatically save place in each file.
  58 This means when you visit a file, point goes to the last place
  59 where it was when you previously visited the same file.
  60 This variable is automatically buffer-local.
  61
  62 If you wish your place in any file to always be automatically saved,
  63 simply put this in your `~/.emacs' file:
  64
  65 \(setq-default save-place t)
  66 \(require 'saveplace)
  67
  68 or else use the Custom facility to set this option."
  69   :type 'boolean
  70   :require 'saveplace
  71   :group 'save-place)
  72
  73 (make-variable-buffer-local 'save-place)
  74
  75 (defcustom save-place-file (convert-standard-filename "~/.emacs-places")
  76   "*Name of the file that records `save-place-alist' value."
  77   :type 'file
  78   :group 'save-place)
  79
  80 (defcustom save-place-version-control nil
  81   "*Controls whether to make numbered backups of master save-place file.
  82 It can have four values: t, nil, `never', and `nospecial'.  The first
  83 three have the same meaning that they do for the variable
  84 `version-control', and the final value `nospecial' means just use the
  85 value of `version-control'."
  86   :type '(radio (const :tag "Unconditionally" t)
  87                 (const :tag "For VC Files" nil)
  88                 (const never)
  89                 (const :tag "Use value of `version-control'" nospecial))
  90   :group 'save-place)
  91
  92 (defvar save-place-loaded nil
  93   "Non-nil means that the `save-place-file' has been loaded.")
  94
  95 (defcustom save-place-limit nil
  96   "Maximum number of entries to retain in the list; nil means no limit."
  97   :type '(choice (integer :tag "Entries" :value 1)
  98                  (const :tag "No Limit" nil))
  99   :group 'save-place)
 100
 101 (defcustom save-place-forget-unreadable-files t
 102   "Non-nil means forget place in unreadable files.
 103
 104 The filenames in `save-place-alist' that do not match
 105 `save-place-skip-check-regexp' are filtered through
 106 `file-readable-p'. if nil, their alist entries are removed.
 107
 108 You may do this anytime by calling the complementary function,
 109 `save-place-forget-unreadable-files'.  When this option is turned on,
 110 this happens automatically before saving `save-place-alist' to
 111 `save-place-file'."
 112   :type 'boolean :group 'save-place)
 113
 114 (defcustom save-place-save-skipped t
 115   "If non-nil, remember files matching `save-place-skip-check-regexp'.
 116
 117 When filtering `save-place-alist' for unreadable files, some will not
 118 be checked, based on said regexp, and instead saved or forgotten based
 119 on this flag."
 120   :type 'boolean :group 'save-place)
 121
 122 (defcustom save-place-skip-check-regexp
 123   ;; thanks to ange-ftp-name-format
 124   "\\`/\\(?:cdrom\\|floppy\\|mnt\\|\\(?:[^@/:]*@\\)?[^@/:]*[^@/:.]:\\)"
 125   "Regexp whose file names shall not be checked for readability.
 126
 127 When forgetting unreadable files, file names matching this regular
 128 expression shall not be checked for readability, but instead be
 129 subject to `save-place-save-skipped'.
 130
 131 Files for which such a check may be inconvenient include those on
 132 removable and network volumes."
 133   :type 'regexp :group 'save-place)
 134
 135 (defun toggle-save-place (&optional parg)
 136   "Toggle whether to save your place in this file between sessions.
 137 If this mode is enabled, point is recorded when you kill the buffer
 138 or exit Emacs.  Visiting this file again will go to that position,
 139 even in a later Emacs session.
 140
 141 If called with a prefix arg, the mode is enabled if and only if
 142 the argument is positive.
 143
 144 To save places automatically in all files, put this in your `.emacs' file:
 145
 146 \(setq-default save-place t\)"
 147   (interactive "P")
 148   (if (not buffer-file-name)
 149       (message "Buffer `%s' not visiting a file" (buffer-name))
 150     (if (and save-place (or (not parg) (<= parg 0)))
 151         (progn
 152           (message "No place will be saved in this file")
 153           (setq save-place nil))
 154       (message "Place will be saved")
 155       (setq save-place t))))
 156
 157 (defun save-place-to-alist ()
 158   ;; put filename and point in a cons box and then cons that onto the
 159   ;; front of the save-place-alist, if save-place is non-nil.
 160   ;; Otherwise, just delete that file from the alist.
 161   ;; first check to make sure alist has been loaded in from the master
 162   ;; file.  If not, do so, then feel free to modify the alist.  It
 163   ;; will be saved again when Emacs is killed.
 164   (or save-place-loaded (load-save-place-alist-from-file))
 165   (if buffer-file-name
 166       (progn
 167         (let ((cell (assoc buffer-file-name save-place-alist))
 168               (position (if (not (eq major-mode 'hexl-mode))
 169                             (point)
 170                           (with-no-warnings
 171                             (1+ (hexl-current-address))))))
 172           (if cell
 173               (setq save-place-alist (delq cell save-place-alist)))
 174           (if (and save-place
 175                    (not (= position 1)))  ;; Optimize out the degenerate case.
 176               (setq save-place-alist
 177                     (cons (cons buffer-file-name position)
 178                           save-place-alist)))))))
 179
 180 (defun save-place-forget-unreadable-files ()
 181   "Remove unreadable files from `save-place-alist'.
 182 For each entry in the alist, if `file-readable-p' returns nil for the
 183 filename, remove the entry.  Save the new alist \(as the first pair
 184 may have changed\) back to `save-place-alist'."
 185   (interactive)
 186   ;; the following was adapted from an in-place filtering function,
 187   ;; `filter-mod', used in the original.
 188   (unless (null save-place-alist)       ;says it better than `when'
 189     ;; first, check all except first
 190     (let ((fmprev save-place-alist) (fmcur (cdr save-place-alist)))
 191       (while fmcur                      ;not null
 192         ;; a value is only saved when it becomes FMPREV.
 193         (if (if (string-match save-place-skip-check-regexp (caar fmcur))
 194                 save-place-save-skipped
 195               (file-readable-p (caar fmcur)))
 196             (setq fmprev fmcur)
 197           (setcdr fmprev (cdr fmcur)))
 198         (setq fmcur (cdr fmcur))))
 199     ;; test first pair, keep it if OK, otherwise 2nd element, which
 200     ;; may be '()
 201     (unless (if (string-match save-place-skip-check-regexp
 202                               (caar save-place-alist))
 203                 save-place-save-skipped
 204               (file-readable-p (caar save-place-alist)))
 205       (setq save-place-alist (cdr save-place-alist)))))
 206
 207 (defun save-place-alist-to-file ()
 208   (let ((file (expand-file-name save-place-file)))
 209     (save-excursion
 210       (message "Saving places to %s..." file)
 211       (set-buffer (get-buffer-create " *Saved Places*"))
 212       (delete-region (point-min) (point-max))
 213       (when save-place-forget-unreadable-files
 214         (save-place-forget-unreadable-files))
 215       (let ((print-length nil)
 216             (print-level nil))
 217         (print save-place-alist (current-buffer)))
 218       (let ((version-control
 219              (cond
 220               ((null save-place-version-control) nil)
 221               ((eq 'never save-place-version-control) 'never)
 222               ((eq 'nospecial save-place-version-control) version-control)
 223               (t
 224                t))))
 225         (condition-case nil
 226             ;; Don't use write-file; we don't want this buffer to visit it.
 227             (write-region (point-min) (point-max) file)
 228           (file-error (message "Can't write %s" file)))
 229         (kill-buffer (current-buffer))
 230         (message "Saving places to %s...done" file)))))
 231
 232 (defun load-save-place-alist-from-file ()
 233   (if (not save-place-loaded)
 234       (progn
 235         (setq save-place-loaded t)
 236         (let ((file (expand-file-name save-place-file)))
 237           ;; make sure that the alist does not get overwritten, and then
 238           ;; load it if it exists:
 239           (if (file-readable-p file)
 240               (save-excursion
 241                 (message "Loading places from %s..." save-place-file)
 242                 ;; don't want to use find-file because we have been
 243                 ;; adding hooks to it.
 244                 (set-buffer (get-buffer-create " *Saved Places*"))
 245                 (delete-region (point-min) (point-max))
 246                 (insert-file-contents file)
 247                 (goto-char (point-min))
 248                 (setq save-place-alist
 249                       (car (read-from-string
 250                             (buffer-substring (point-min) (point-max)))))
 251
 252                 ;; If there is a limit, and we're over it, then we'll
 253                 ;; have to truncate the end of the list:
 254                 (if save-place-limit
 255                     (if (<= save-place-limit 0)
 256                         ;; Zero gets special cased.  I'm not thrilled
 257                         ;; with this, but the loop for >= 1 is tight.
 258                         (setq save-place-alist nil)
 259                       ;; Else the limit is >= 1, so enforce it by
 260                       ;; counting and then `setcdr'ing.
 261                       (let ((s save-place-alist)
 262                             (count 1))
 263                         (while s
 264                           (if (>= count save-place-limit)
 265                               (setcdr s nil)
 266                             (setq count (1+ count)))
 267                           (setq s (cdr s))))))
 268
 269                 (kill-buffer (current-buffer))
 270                 (message "Loading places from %s...done" file)))
 271           nil))))
 272
 273 (defun save-places-to-alist ()
 274   ;; go through buffer-list, saving places to alist if save-place is
 275   ;; non-nil, deleting them from alist if it is nil.
 276   (let ((buf-list (buffer-list)))
 277     (while buf-list
 278       ;; put this into a save-excursion in case someone is counting on
 279       ;; another function in kill-emacs-hook to act on the last buffer
 280       ;; they were in:
 281       (save-excursion
 282         (set-buffer (car buf-list))
 283         ;; save-place checks buffer-file-name too, but we can avoid
 284         ;; overhead of function call by checking here too.
 285         (and buffer-file-name (save-place-to-alist))
 286         (setq buf-list (cdr buf-list))))))
 287
 288 (defun save-place-find-file-hook ()
 289   (or save-place-loaded (load-save-place-alist-from-file))
 290   (let ((cell (assoc buffer-file-name save-place-alist)))
 291     (if cell
 292         (progn
 293           (or after-find-file-from-revert-buffer
 294               (goto-char (cdr cell)))
 295           ;; and make sure it will be saved again for later
 296           (setq save-place t)))))
 297
 298 (defun save-place-kill-emacs-hook ()
 299   ;; First update the alist.  This loads the old save-place-file if nec.
 300   (save-places-to-alist)
 301   ;; Now save the alist in the file, if we have ever loaded the file
 302   ;; (including just now).
 303   (if save-place-loaded
 304       (save-place-alist-to-file)))
 305
 306 (add-hook 'find-file-hook 'save-place-find-file-hook t)
 307
 308 (add-hook 'kill-emacs-hook 'save-place-kill-emacs-hook)
 309
 310 (add-hook 'kill-buffer-hook 'save-place-to-alist)
 311
 312 (provide 'saveplace) ; why not...
 313
 314 ;;; arch-tag: 3c2ef47b-0a22-4558-b116-118c9ef454a0
 315 ;;; saveplace.el ends here