code.delx.au - gnu-emacs/blob - lisp/tooltip.el

   1 ;;; tooltip.el --- show tooltip windows
   2
   3 ;; Copyright (C) 1997, 1999, 2000, 2001, 2002, 2003, 2004,
   4 ;;   2005, 2006 Free Software Foundation, Inc.
   5
   6 ;; Author: Gerd Moellmann <gerd@acm.org>
   7 ;; Keywords: help c mouse tools
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 ;; Boston, MA 02110-1301, USA.
  25
  26 ;;; Commentary:
  27
  28 ;;; Code:
  29
  30 (defvar comint-prompt-regexp)
  31
  32 (defgroup tooltip nil
  33   "Customization group for the `tooltip' package."
  34   :group 'help
  35   :group 'gud
  36   :group 'mouse
  37   :group 'tools
  38   :version "21.1"
  39   :tag "Tool Tips")
  40 \f
  41 ;;; Switching tooltips on/off
  42
  43 ;; We don't set track-mouse globally because this is a big redisplay
  44 ;; problem in buffers having a pre-command-hook or such installed,
  45 ;; which does a set-buffer, like the summary buffer of Gnus.  Calling
  46 ;; set-buffer prevents redisplay optimizations, so every mouse motion
  47 ;; would be accompanied by a full redisplay.
  48
  49 (define-minor-mode tooltip-mode
  50   "Toggle Tooltip mode.
  51 With ARG, turn Tooltip mode on if and only if ARG is positive.
  52 When this minor mode is enabled, Emacs displays help text
  53 in a pop-up window for buttons and menu items that you put the mouse on.
  54 \(However, if `tooltip-use-echo-area' is non-nil, this and
  55 all pop-up help appears in the echo area.)
  56
  57 When Tooltip mode is disabled, Emacs displays one line of
  58 the help text in the echo area, and does not make a pop-up window."
  59   :global t
  60   :init-value (not (or noninteractive
  61                        emacs-basic-display
  62                        (not (display-graphic-p))
  63                        (not (fboundp 'x-show-tip))))
  64   :initialize 'custom-initialize-safe-default
  65   :group 'tooltip
  66   (unless (or (null tooltip-mode) (fboundp 'x-show-tip))
  67     (error "Sorry, tooltips are not yet available on this system"))
  68   (if tooltip-mode
  69       (progn
  70         (add-hook 'pre-command-hook 'tooltip-hide)
  71         (add-hook 'tooltip-hook 'tooltip-help-tips))
  72     (unless (and (boundp 'gud-tooltip-mode) gud-tooltip-mode)
  73       (remove-hook 'pre-command-hook 'tooltip-hide))
  74     (remove-hook 'tooltip-hook 'tooltip-help-tips))
  75   (setq show-help-function
  76         (if tooltip-mode 'tooltip-show-help nil)))
  77
  78 \f
  79 ;;; Customizable settings
  80
  81 (defcustom tooltip-delay 0.7
  82   "Seconds to wait before displaying a tooltip the first time."
  83   :type 'number
  84   :group 'tooltip)
  85
  86 (defcustom tooltip-short-delay 0.1
  87   "Seconds to wait between subsequent tooltips on different items."
  88   :type 'number
  89   :group 'tooltip)
  90
  91 (defcustom tooltip-recent-seconds 1
  92   "Display tooltips if changing tip items within this many seconds.
  93 Do so after `tooltip-short-delay'."
  94   :type 'number
  95   :group 'tooltip)
  96
  97 (defcustom tooltip-hide-delay 10
  98   "Hide tooltips automatically after this many seconds."
  99   :type 'number
 100   :group 'tooltip)
 101
 102 (defcustom tooltip-x-offset 5
 103   "X offset, in pixels, for the display of tooltips.
 104 The offset is the distance between the X position of the mouse and
 105 the left border of the tooltip window.  It must be chosen so that the
 106 tooltip window doesn't contain the mouse when it pops up, or it may
 107 interfere with clicking where you wish.
 108
 109 If `tooltip-frame-parameters' includes the `left' parameter,
 110 the value of `tooltip-x-offset' is ignored."
 111   :type 'integer
 112   :group 'tooltip)
 113
 114 (defcustom tooltip-y-offset +20
 115   "Y offset, in pixels, for the display of tooltips.
 116 The offset is the distance between the Y position of the mouse and
 117 the top border of the tooltip window.  It must be chosen so that the
 118 tooltip window doesn't contain the mouse when it pops up, or it may
 119 interfere with clicking where you wish.
 120
 121 If `tooltip-frame-parameters' includes the `top' parameter,
 122 the value of `tooltip-y-offset' is ignored."
 123   :type 'integer
 124   :group 'tooltip)
 125
 126 (defcustom tooltip-frame-parameters
 127   '((name . "tooltip")
 128     (internal-border-width . 2)
 129     (border-width . 1))
 130   "Frame parameters used for tooltips.
 131
 132 If `left' or `top' parameters are included, they specify the absolute
 133 position to pop up the tooltip."
 134   :type 'sexp
 135   :group 'tooltip)
 136
 137 (defface tooltip
 138   '((((class color))
 139      :background "lightyellow"
 140      :foreground "black"
 141      :inherit variable-pitch)
 142     (t
 143      :inherit variable-pitch))
 144   "Face for tooltips."
 145   :group 'tooltip
 146   :group 'basic-faces)
 147
 148 (defcustom tooltip-use-echo-area nil
 149   "Use the echo area instead of tooltip frames for help and GUD tooltips.
 150 To display multi-line help text in the echo area, set this to t
 151 and enable `tooltip-mode'."
 152   :type 'boolean
 153   :group 'tooltip)
 154
 155 \f
 156 ;;; Variables that are not customizable.
 157
 158 (defvar tooltip-hook nil
 159   "Functions to call to display tooltips.
 160 Each function is called with one argument EVENT which is a copy of
 161 the last mouse movement event that occurred.")
 162
 163 (defvar tooltip-timeout-id nil
 164   "The id of the timeout started when Emacs becomes idle.")
 165
 166 (defvar tooltip-last-mouse-motion-event nil
 167   "A copy of the last mouse motion event seen.")
 168
 169 (defvar tooltip-hide-time nil
 170   "Time when the last tooltip was hidden.")
 171
 172 (defvar gud-tooltip-mode) ;; Prevent warning.
 173
 174 ;;; Event accessors
 175
 176 (defun tooltip-event-buffer (event)
 177   "Return the buffer over which event EVENT occurred.
 178 This might return nil if the event did not occur over a buffer."
 179   (let ((window (posn-window (event-end event))))
 180     (and window (window-buffer window))))
 181
 182 \f
 183 ;;; Timeout for tooltip display
 184
 185 (defun tooltip-delay ()
 186   "Return the delay in seconds for the next tooltip."
 187   (let ((delay tooltip-delay)
 188         (now (float-time)))
 189     (when (and tooltip-hide-time
 190                (< (- now tooltip-hide-time) tooltip-recent-seconds))
 191       (setq delay tooltip-short-delay))
 192     delay))
 193
 194 (defun tooltip-cancel-delayed-tip ()
 195   "Disable the tooltip timeout."
 196   (when tooltip-timeout-id
 197     (disable-timeout tooltip-timeout-id)
 198     (setq tooltip-timeout-id nil)))
 199
 200 (defun tooltip-start-delayed-tip ()
 201   "Add a one-shot timeout to call function `tooltip-timeout'."
 202   (setq tooltip-timeout-id
 203         (add-timeout (tooltip-delay) 'tooltip-timeout nil)))
 204
 205 (defun tooltip-timeout (object)
 206   "Function called when timer with id `tooltip-timeout-id' fires."
 207   (run-hook-with-args-until-success 'tooltip-hook
 208                                     tooltip-last-mouse-motion-event))
 209
 210 \f
 211 ;;; Displaying tips
 212
 213 (defun tooltip-set-param (alist key value)
 214   "Change the value of KEY in alist ALIST to VALUE.
 215 If there's no association for KEY in ALIST, add one, otherwise
 216 change the existing association.  Value is the resulting alist."
 217   (let ((param (assq key alist)))
 218     (if (consp param)
 219         (setcdr param value)
 220       (push (cons key value) alist))
 221     alist))
 222
 223 (defun tooltip-show (text &optional use-echo-area)
 224   "Show a tooltip window displaying TEXT.
 225
 226 Text larger than `x-max-tooltip-size' is clipped.
 227
 228 If the alist in `tooltip-frame-parameters' includes `left' and `top'
 229 parameters, they determine the x and y position where the tooltip
 230 is displayed.  Otherwise, the tooltip pops at offsets specified by
 231 `tooltip-x-offset' and `tooltip-y-offset' from the current mouse
 232 position.
 233
 234 Optional second arg USE-ECHO-AREA non-nil means to show tooltip
 235 in echo area."
 236   (if use-echo-area
 237       (message "%s" text)
 238     (condition-case error
 239         (let ((params (copy-sequence tooltip-frame-parameters))
 240               (fg (face-attribute 'tooltip :foreground))
 241               (bg (face-attribute 'tooltip :background)))
 242           (when (stringp fg)
 243             (setq params (tooltip-set-param params 'foreground-color fg))
 244             (setq params (tooltip-set-param params 'border-color fg)))
 245           (when (stringp bg)
 246             (setq params (tooltip-set-param params 'background-color bg)))
 247           (x-show-tip (propertize text 'face 'tooltip)
 248                       (selected-frame)
 249                       params
 250                       tooltip-hide-delay
 251                       tooltip-x-offset
 252                       tooltip-y-offset))
 253       (error
 254        (message "Error while displaying tooltip: %s" error)
 255        (sit-for 1)
 256        (message "%s" text)))))
 257
 258 (defun tooltip-hide (&optional ignored-arg)
 259   "Hide a tooltip, if one is displayed.
 260 Value is non-nil if tooltip was open."
 261   (tooltip-cancel-delayed-tip)
 262   (when (x-hide-tip)
 263     (setq tooltip-hide-time (float-time))))
 264
 265 \f
 266 ;;; Debugger-related functions
 267
 268 (defun tooltip-identifier-from-point (point)
 269   "Extract the identifier at POINT, if any.
 270 Value is nil if no identifier exists at point.  Identifier extraction
 271 is based on the current syntax table."
 272   (save-excursion
 273     (goto-char point)
 274     (let ((start (progn (skip-syntax-backward "w_") (point))))
 275       (unless (looking-at "[0-9]")
 276         (skip-syntax-forward "w_")
 277         (when (> (point) start)
 278           (buffer-substring start (point)))))))
 279
 280 (defmacro tooltip-region-active-p ()
 281   "Value is non-nil if the region is currently active."
 282   (if (string-match "^GNU" (emacs-version))
 283       `(and transient-mark-mode mark-active)
 284     `(region-active-p)))
 285
 286 (defun tooltip-expr-to-print (event)
 287   "Return an expression that should be printed for EVENT.
 288 If a region is active and the mouse is inside the region, print
 289 the region.  Otherwise, figure out the identifier around the point
 290 where the mouse is."
 291   (save-excursion
 292     (set-buffer (tooltip-event-buffer event))
 293     (let ((point (posn-point (event-end event))))
 294       (if (tooltip-region-active-p)
 295           (when (and (<= (region-beginning) point) (<= point (region-end)))
 296             (buffer-substring (region-beginning) (region-end)))
 297         (tooltip-identifier-from-point point)))))
 298
 299 (defun tooltip-process-prompt-regexp (process)
 300   "Return regexp matching the prompt of PROCESS at the end of a string.
 301 The prompt is taken from the value of `comint-prompt-regexp' in
 302 the buffer of PROCESS."
 303   (let ((prompt-regexp (save-excursion
 304                          (set-buffer (process-buffer process))
 305                          comint-prompt-regexp)))
 306     ;; Most start with `^' but the one for `sdb' cannot be easily
 307     ;; stripped.  Code the prompt for `sdb' fixed here.
 308     (if (= (aref prompt-regexp 0) ?^)
 309         (setq prompt-regexp (substring prompt-regexp 1))
 310       (setq prompt-regexp "\\*"))
 311     (concat "\n*" prompt-regexp "$")))
 312
 313 (defun tooltip-strip-prompt (process output)
 314   "Return OUTPUT with any prompt of PROCESS stripped from its end."
 315   (let ((prompt-regexp (tooltip-process-prompt-regexp process)))
 316     (save-match-data
 317       (when (string-match prompt-regexp output)
 318         (setq output (substring output 0 (match-beginning 0)))))
 319     output))
 320
 321 \f
 322 ;;; Tooltip help.
 323
 324 (defvar tooltip-help-message nil
 325   "The last help message received via `tooltip-show-help'.")
 326
 327 (defun tooltip-show-help (msg)
 328   "Function installed as `show-help-function'.
 329 MSG is either a help string to display, or nil to cancel the display."
 330   (let ((previous-help tooltip-help-message))
 331     (setq tooltip-help-message msg)
 332     (cond ((null msg)
 333            ;; Cancel display.  This also cancels a delayed tip, if
 334            ;; there is one.
 335            (tooltip-hide))
 336           ((equal previous-help msg)
 337            ;; Same help as before (but possibly the mouse has moved).
 338            ;; Keep what we have.
 339            )
 340           (t
 341            ;; A different help.  Remove a previous tooltip, and
 342            ;; display a new one, with some delay.
 343            (tooltip-hide)
 344            (tooltip-start-delayed-tip)))))
 345
 346 (defun tooltip-help-tips (event)
 347   "Hook function to display a help tooltip.
 348 This is installed on the hook `tooltip-hook', which is run when
 349 the timer with id `tooltip-timeout-id' fires.
 350 Value is non-nil if this function handled the tip."
 351   (when (stringp tooltip-help-message)
 352     (tooltip-show tooltip-help-message tooltip-use-echo-area)
 353     t))
 354
 355 (provide 'tooltip)
 356
 357 ;; arch-tag: 3d61135e-4618-4a78-af28-183f6df5636f
 358 ;;; tooltip.el ends here