code.delx.au - gnu-emacs/blob - lisp/progmodes/xref.el

   1 ;; xref.el --- Cross-referencing commands              -*-lexical-binding:t-*-
   2
   3 ;; Copyright (C) 2014-2015 Free Software Foundation, Inc.
   4
   5 ;; This file is part of GNU Emacs.
   6
   7 ;; GNU Emacs is free software: you can redistribute it and/or modify
   8 ;; it under the terms of the GNU General Public License as published by
   9 ;; the Free Software Foundation, either version 3 of the License, or
  10 ;; (at your option) any later version.
  11
  12 ;; GNU Emacs is distributed in the hope that it will be useful,
  13 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ;; GNU General Public License for more details.
  16
  17 ;; You should have received a copy of the GNU General Public License
  18 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 ;;; Commentary:
  21
  22 ;; This file provides a somewhat generic infrastructure for cross
  23 ;; referencing commands, in particular "find-definition".
  24 ;;
  25 ;; Some part of the functionality must be implemented in a language
  26 ;; dependent way and that's done by defining `xref-find-function',
  27 ;; `xref-identifier-at-point-function' and
  28 ;; `xref-identifier-completion-table-function', which see.
  29 ;;
  30 ;; A major mode should make these variables buffer-local first.
  31 ;;
  32 ;; `xref-find-function' can be called in several ways, see its
  33 ;; description.  It has to operate with "xref" and "location" values.
  34 ;;
  35 ;; One would usually call `make-xref' and `xref-make-file-location',
  36 ;; `xref-make-buffer-location' or `xref-make-bogus-location' to create
  37 ;; them.  More generally, a location must be an instance of an EIEIO
  38 ;; class inheriting from `xref-location' and implementing
  39 ;; `xref-location-group' and `xref-location-marker'.
  40 ;;
  41 ;; Each identifier must be represented as a string.  Implementers can
  42 ;; use string properties to store additional information about the
  43 ;; identifier, but they should keep in mind that values returned from
  44 ;; `xref-identifier-completion-table-function' should still be
  45 ;; distinct, because the user can't see the properties when making the
  46 ;; choice.
  47 ;;
  48 ;; See the functions `etags-xref-find' and `elisp-xref-find' for full
  49 ;; examples.
  50
  51 ;;; Code:
  52
  53 (require 'cl-lib)
  54 (require 'eieio)
  55 (require 'ring)
  56 (require 'pcase)
  57 (require 'project)
  58
  59 (defgroup xref nil "Cross-referencing commands"
  60   :group 'tools)
  61
  62 \f
  63 ;;; Locations
  64
  65 (defclass xref-location () ()
  66   :documentation "A location represents a position in a file or buffer.")
  67
  68 ;; If a backend decides to subclass xref-location it can provide
  69 ;; methods for some of the following functions:
  70 (cl-defgeneric xref-location-marker (location)
  71   "Return the marker for LOCATION.")
  72
  73 (cl-defgeneric xref-location-group (location)
  74   "Return a string used to group a set of locations.
  75 This is typically the filename.")
  76
  77 (cl-defgeneric xref-location-line (_location)
  78   "Return the line number corresponding to the location."
  79   nil)
  80
  81 ;;;; Commonly needed location classes are defined here:
  82
  83 ;; FIXME: might be useful to have an optional "hint" i.e. a string to
  84 ;; search for in case the line number is sightly out of date.
  85 (defclass xref-file-location (xref-location)
  86   ((file :type string :initarg :file)
  87    (line :type fixnum :initarg :line :reader xref-location-line)
  88    (column :type fixnum :initarg :column))
  89   :documentation "A file location is a file/line/column triple.
  90 Line numbers start from 1 and columns from 0.")
  91
  92 (defun xref-make-file-location (file line column)
  93   "Create and return a new xref-file-location."
  94   (make-instance 'xref-file-location :file file :line line :column column))
  95
  96 (cl-defmethod xref-location-marker ((l xref-file-location))
  97   (with-slots (file line column) l
  98     (with-current-buffer
  99         (or (get-file-buffer file)
 100             (let ((find-file-suppress-same-file-warnings t))
 101               (find-file-noselect file)))
 102       (save-restriction
 103         (widen)
 104         (save-excursion
 105           (goto-char (point-min))
 106           (beginning-of-line line)
 107           (move-to-column column)
 108           (point-marker))))))
 109
 110 (cl-defmethod xref-location-group ((l xref-file-location))
 111   (oref l file))
 112
 113 (defclass xref-buffer-location (xref-location)
 114   ((buffer :type buffer :initarg :buffer)
 115    (position :type fixnum :initarg :position)))
 116
 117 (defun xref-make-buffer-location (buffer position)
 118   "Create and return a new xref-buffer-location."
 119   (make-instance 'xref-buffer-location :buffer buffer :position position))
 120
 121 (cl-defmethod xref-location-marker ((l xref-buffer-location))
 122   (with-slots (buffer position) l
 123     (let ((m (make-marker)))
 124       (move-marker m position buffer))))
 125
 126 (cl-defmethod xref-location-group ((l xref-buffer-location))
 127   (with-slots (buffer) l
 128     (or (buffer-file-name buffer)
 129         (format "(buffer %s)" (buffer-name buffer)))))
 130
 131 (defclass xref-bogus-location (xref-location)
 132   ((message :type string :initarg :message
 133             :reader xref-bogus-location-message))
 134   :documentation "Bogus locations are sometimes useful to
 135 indicate errors, e.g. when we know that a function exists but the
 136 actual location is not known.")
 137
 138 (defun xref-make-bogus-location (message)
 139   "Create and return a new xref-bogus-location."
 140   (make-instance 'xref-bogus-location :message message))
 141
 142 (cl-defmethod xref-location-marker ((l xref-bogus-location))
 143   (user-error "%s" (oref l message)))
 144
 145 (cl-defmethod xref-location-group ((_ xref-bogus-location)) "(No location)")
 146
 147 \f
 148 ;;; Cross-reference
 149
 150 (defclass xref--xref ()
 151   ((description :type string :initarg :description
 152                 :reader xref--xref-description)
 153    (location :initarg :location
 154              :reader xref--xref-location))
 155   :comment "An xref is used to display and locate constructs like
 156 variables or functions.")
 157
 158 (defun xref-make (description location)
 159   "Create and return a new xref.
 160 DESCRIPTION is a short string to describe the xref.
 161 LOCATION is an `xref-location'."
 162   (make-instance 'xref--xref :description description :location location))
 163
 164 \f
 165 ;;; API
 166
 167 (declare-function etags-xref-find "etags" (action id))
 168 (declare-function tags-lazy-completion-table "etags" ())
 169
 170 ;; For now, make the etags backend the default.
 171 (defvar xref-find-function #'etags-xref-find
 172   "Function to look for cross-references.
 173 It can be called in several ways:
 174
 175  (definitions IDENTIFIER): Find definitions of IDENTIFIER.  The
 176 result must be a list of xref objects.  If no definitions can be
 177 found, return nil.
 178
 179  (references IDENTIFIER): Find references of IDENTIFIER.  The
 180 result must be a list of xref objects.  If no references can be
 181 found, return nil.
 182
 183  (apropos PATTERN): Find all symbols that match PATTERN.  PATTERN
 184 is a regexp.
 185
 186 IDENTIFIER can be any string returned by
 187 `xref-identifier-at-point-function', or from the table returned
 188 by `xref-identifier-completion-table-function'.
 189
 190 To create an xref object, call `xref-make'.")
 191
 192 (defvar xref-identifier-at-point-function #'xref-default-identifier-at-point
 193   "Function to get the relevant identifier at point.
 194
 195 The return value must be a string or nil.  nil means no
 196 identifier at point found.
 197
 198 If it's hard to determine the identifier precisely (e.g., because
 199 it's a method call on unknown type), the implementation can
 200 return a simple string (such as symbol at point) marked with a
 201 special text property which `xref-find-function' would recognize
 202 and then delegate the work to an external process.")
 203
 204 (defvar xref-identifier-completion-table-function #'tags-lazy-completion-table
 205   "Function that returns the completion table for identifiers.")
 206
 207 (defun xref-default-identifier-at-point ()
 208   (let ((thing (thing-at-point 'symbol)))
 209     (and thing (substring-no-properties thing))))
 210
 211 \f
 212 ;;; misc utilities
 213 (defun xref--alistify (list key test)
 214   "Partition the elements of LIST into an alist.
 215 KEY extracts the key from an element and TEST is used to compare
 216 keys."
 217   (let ((alist '()))
 218     (dolist (e list)
 219       (let* ((k (funcall key e))
 220              (probe (cl-assoc k alist :test test)))
 221         (if probe
 222             (setcdr probe (cons e (cdr probe)))
 223           (push (cons k (list e)) alist))))
 224     ;; Put them back in order.
 225     (cl-loop for (key . value) in (reverse alist)
 226              collect (cons key (reverse value)))))
 227
 228 (defun xref--insert-propertized (props &rest strings)
 229   "Insert STRINGS with text properties PROPS."
 230   (let ((start (point)))
 231     (apply #'insert strings)
 232     (add-text-properties start (point) props)))
 233
 234 (defun xref--search-property (property &optional backward)
 235     "Search the next text range where text property PROPERTY is non-nil.
 236 Return the value of PROPERTY.  If BACKWARD is non-nil, search
 237 backward."
 238   (let ((next (if backward
 239                   #'previous-single-char-property-change
 240                 #'next-single-char-property-change))
 241         (start (point))
 242         (value nil))
 243     (while (progn
 244              (goto-char (funcall next (point) property))
 245              (not (or (setq value (get-text-property (point) property))
 246                       (eobp)
 247                       (bobp)))))
 248     (cond (value)
 249           (t (goto-char start) nil))))
 250
 251 \f
 252 ;;; Marker stack  (M-. pushes, M-, pops)
 253
 254 (defcustom xref-marker-ring-length 16
 255   "Length of the xref marker ring."
 256   :type 'integer
 257   :version "25.1")
 258
 259 (defcustom xref-prompt-for-identifier '(not xref-find-definitions
 260                                             xref-find-definitions-other-window
 261                                             xref-find-definitions-other-frame)
 262   "When t, always prompt for the identifier name.
 263
 264 When nil, prompt only when there's no value at point we can use,
 265 or when the command has been called with the prefix argument.
 266
 267 Otherwise, it's a list of xref commands which will prompt
 268 anyway (the value at point, if any, will be used as the default).
 269
 270 If the list starts with `not', the meaning of the rest of the
 271 elements is negated."
 272   :type '(choice (const :tag "always" t)
 273                  (const :tag "auto" nil)
 274                  (set :menu-tag "command specific" :tag "commands"
 275                       :value (not)
 276                       (const :tag "Except" not)
 277                       (repeat :inline t (symbol :tag "command"))))
 278   :version "25.1")
 279
 280 (defcustom xref-pulse-on-jump t
 281   "When non-nil, momentarily highlight jump locations."
 282   :type 'boolean
 283   :version "25.1")
 284
 285 (defvar xref--marker-ring (make-ring xref-marker-ring-length)
 286   "Ring of markers to implement the marker stack.")
 287
 288 (defun xref-push-marker-stack (&optional m)
 289   "Add point M (defaults to `point-marker') to the marker stack."
 290   (ring-insert xref--marker-ring (or m (point-marker))))
 291
 292 ;;;###autoload
 293 (defun xref-pop-marker-stack ()
 294   "Pop back to where \\[xref-find-definitions] was last invoked."
 295   (interactive)
 296   (let ((ring xref--marker-ring))
 297     (when (ring-empty-p ring)
 298       (error "Marker stack is empty"))
 299     (let ((marker (ring-remove ring 0)))
 300       (switch-to-buffer (or (marker-buffer marker)
 301                             (error "The marked buffer has been deleted")))
 302       (goto-char (marker-position marker))
 303       (set-marker marker nil nil)
 304       (xref--maybe-pulse))))
 305
 306 (defun xref--maybe-pulse ()
 307   (when xref-pulse-on-jump
 308     (let (beg end)
 309       (save-excursion
 310         (back-to-indentation)
 311         (if (eolp)
 312             (setq beg (line-beginning-position)
 313                   end (1+ (point)))
 314           (setq beg (point)
 315                 end (line-end-position))))
 316       (pulse-momentary-highlight-region beg end 'next-error))))
 317
 318 ;; etags.el needs this
 319 (defun xref-clear-marker-stack ()
 320   "Discard all markers from the marker stack."
 321   (let ((ring xref--marker-ring))
 322     (while (not (ring-empty-p ring))
 323       (let ((marker (ring-remove ring)))
 324         (set-marker marker nil nil)))))
 325
 326 ;;;###autoload
 327 (defun xref-marker-stack-empty-p ()
 328   "Return t if the marker stack is empty; nil otherwise."
 329   (ring-empty-p xref--marker-ring))
 330
 331 \f
 332 (defun xref--goto-location (location)
 333   "Set buffer and point according to xref-location LOCATION."
 334   (let ((marker (xref-location-marker location)))
 335     (set-buffer (marker-buffer marker))
 336     (cond ((and (<= (point-min) marker) (<= marker (point-max))))
 337           (widen-automatically (widen))
 338           (t (error "Location is outside accessible part of buffer")))
 339     (goto-char marker)))
 340
 341 (defun xref--pop-to-location (location &optional window)
 342   "Goto xref-location LOCATION and display the buffer.
 343 WINDOW controls how the buffer is displayed:
 344   nil      -- switch-to-buffer
 345   'window  -- pop-to-buffer (other window)
 346   'frame   -- pop-to-buffer (other frame)"
 347   (xref--goto-location location)
 348   (cl-ecase window
 349     ((nil)  (switch-to-buffer (current-buffer)))
 350     (window (pop-to-buffer (current-buffer) t))
 351     (frame  (let ((pop-up-frames t)) (pop-to-buffer (current-buffer) t))))
 352   (xref--maybe-pulse))
 353
 354 \f
 355 ;;; XREF buffer (part of the UI)
 356
 357 ;; The xref buffer is used to display a set of xrefs.
 358
 359 (defvar-local xref--display-history nil
 360   "List of pairs (BUFFER . WINDOW), for temporarily displayed buffers.")
 361
 362 (defvar-local xref--temporary-buffers nil
 363   "List of buffers created by xref code.")
 364
 365 (defvar-local xref--current nil
 366   "Non-nil if this buffer was once current, except while displaying xrefs.
 367 Used for temporary buffers.")
 368
 369 (defvar xref--inhibit-mark-current nil)
 370
 371 (defun xref--mark-selected ()
 372   (unless xref--inhibit-mark-current
 373     (setq xref--current t))
 374   (remove-hook 'buffer-list-update-hook #'xref--mark-selected t))
 375
 376 (defun xref--save-to-history (buf win)
 377   (let ((restore (window-parameter win 'quit-restore)))
 378     ;; Save the new entry if the window displayed another buffer
 379     ;; previously.
 380     (when (and restore (not (eq (car restore) 'same)))
 381       (push (cons buf win) xref--display-history))))
 382
 383 (defun xref--display-position (pos other-window recenter-arg xref-buf)
 384   ;; Show the location, but don't hijack focus.
 385   (with-selected-window (display-buffer (current-buffer) other-window)
 386     (goto-char pos)
 387     (recenter recenter-arg)
 388     (xref--maybe-pulse)
 389     (let ((buf (current-buffer))
 390           (win (selected-window)))
 391       (with-current-buffer xref-buf
 392         (setq-local other-window-scroll-buffer buf)
 393         (xref--save-to-history buf win)))))
 394
 395 (defun xref--show-location (location)
 396   (condition-case err
 397       (let ((xref-buf (current-buffer))
 398             (bl (buffer-list))
 399             (xref--inhibit-mark-current t))
 400         (xref--goto-location location)
 401         (let ((buf (current-buffer)))
 402           (unless (memq buf bl)
 403             ;; Newly created.
 404             (add-hook 'buffer-list-update-hook #'xref--mark-selected nil t)
 405             (with-current-buffer xref-buf
 406               (push buf xref--temporary-buffers))))
 407         (xref--display-position (point) t 1 xref-buf))
 408     (user-error (message (error-message-string err)))))
 409
 410 (defun xref-show-location-at-point ()
 411   "Display the source of xref at point in the other window, if any."
 412   (interactive)
 413   (let ((loc (xref--location-at-point)))
 414     (when loc
 415       (xref--show-location loc))))
 416
 417 (defun xref-next-line ()
 418   "Move to the next xref and display its source in the other window."
 419   (interactive)
 420   (xref--search-property 'xref-location)
 421   (xref-show-location-at-point))
 422
 423 (defun xref-prev-line ()
 424   "Move to the previous xref and display its source in the other window."
 425   (interactive)
 426   (xref--search-property 'xref-location t)
 427   (xref-show-location-at-point))
 428
 429 (defun xref--location-at-point ()
 430   (save-excursion
 431     (back-to-indentation)
 432     (get-text-property (point) 'xref-location)))
 433
 434 (defvar-local xref--window nil
 435   "ACTION argument to call `display-buffer' with.")
 436
 437 (defun xref-goto-xref ()
 438   "Jump to the xref on the current line and bury the xref buffer."
 439   (interactive)
 440   (let ((loc (or (xref--location-at-point)
 441                  (user-error "No reference at point")))
 442         (window xref--window))
 443     (xref-quit)
 444     (xref--pop-to-location loc window)))
 445
 446 (defvar xref--xref-buffer-mode-map
 447   (let ((map (make-sparse-keymap)))
 448     (define-key map [remap quit-window] #'xref-quit)
 449     (define-key map (kbd "n") #'xref-next-line)
 450     (define-key map (kbd "p") #'xref-prev-line)
 451     (define-key map (kbd "RET") #'xref-goto-xref)
 452     (define-key map (kbd "C-o") #'xref-show-location-at-point)
 453     ;; suggested by Johan Claesson "to further reduce finger movement":
 454     (define-key map (kbd ".") #'xref-next-line)
 455     (define-key map (kbd ",") #'xref-prev-line)
 456     map))
 457
 458 (define-derived-mode xref--xref-buffer-mode special-mode "XREF"
 459   "Mode for displaying cross-references."
 460   (setq buffer-read-only t)
 461   (setq next-error-function #'xref--next-error-function)
 462   (setq next-error-last-buffer (current-buffer)))
 463
 464 (defun xref--next-error-function (n reset?)
 465   (when reset?
 466     (goto-char (point-min)))
 467   (let ((backward (< n 0))
 468         (n (abs n))
 469         (loc nil))
 470     (dotimes (_ n)
 471       (setq loc (xref--search-property 'xref-location backward)))
 472     (cond (loc
 473            (xref--pop-to-location loc))
 474           (t
 475            (error "No %s xref" (if backward "previous" "next"))))))
 476
 477 (defun xref-quit (&optional kill)
 478   "Bury temporarily displayed buffers, then quit the current window.
 479
 480 If KILL is non-nil, kill all buffers that were created in the
 481 process of showing xrefs, and also kill the current buffer.
 482
 483 The buffers that the user has otherwise interacted with in the
 484 meantime are preserved."
 485   (interactive "P")
 486   (let ((window (selected-window))
 487         (history xref--display-history))
 488     (setq xref--display-history nil)
 489     (pcase-dolist (`(,buf . ,win) history)
 490       (when (and (window-live-p win)
 491                  (eq buf (window-buffer win)))
 492         (quit-window nil win)))
 493     (when kill
 494       (let ((xref--inhibit-mark-current t)
 495             kill-buffer-query-functions)
 496         (dolist (buf xref--temporary-buffers)
 497           (unless (buffer-local-value 'xref--current buf)
 498             (kill-buffer buf)))
 499         (setq xref--temporary-buffers nil)))
 500     (quit-window kill window)))
 501
 502 (defconst xref-buffer-name "*xref*"
 503   "The name of the buffer to show xrefs.")
 504
 505 (defvar xref--button-map
 506   (let ((map (make-sparse-keymap)))
 507     (define-key map [(control ?m)] #'xref-goto-xref)
 508     (define-key map [mouse-1] #'xref-goto-xref)
 509     (define-key map [mouse-2] #'xref--mouse-2)
 510     map))
 511
 512 (defun xref--mouse-2 (event)
 513   "Move point to the button and show the xref definition."
 514   (interactive "e")
 515   (mouse-set-point event)
 516   (forward-line 0)
 517   (xref--search-property 'xref-location)
 518   (xref-show-location-at-point))
 519
 520 (defun xref--insert-xrefs (xref-alist)
 521   "Insert XREF-ALIST in the current-buffer.
 522 XREF-ALIST is of the form ((GROUP . (XREF ...)) ...).  Where
 523 GROUP is a string for decoration purposes and XREF is an
 524 `xref--xref' object."
 525   (require 'compile) ; For the compilation faces.
 526   (cl-loop for ((group . xrefs) . more1) on xref-alist
 527            for max-line-width =
 528            (cl-loop for xref in xrefs
 529                     maximize (let ((line (xref-location-line
 530                                           (oref xref location))))
 531                                (length (and line (format "%d" line)))))
 532            for line-format = (and max-line-width
 533                                   (format "%%%dd: " max-line-width))
 534            do
 535            (xref--insert-propertized '(face compilation-info) group "\n")
 536            (cl-loop for (xref . more2) on xrefs do
 537                     (with-slots (description location) xref
 538                       (let* ((line (xref-location-line location))
 539                              (prefix
 540                               (if line
 541                                   (propertize (format line-format line)
 542                                               'face 'compilation-line-number)
 543                                 "  ")))
 544                         (xref--insert-propertized
 545                          (list 'xref-location location
 546                                ;; 'face 'font-lock-keyword-face
 547                                'mouse-face 'highlight
 548                                'keymap xref--button-map
 549                                'help-echo
 550                                (concat "mouse-2: display in another window, "
 551                                        "RET or mouse-1: follow reference"))
 552                          prefix description)))
 553                     (insert "\n"))))
 554
 555 (defun xref--analyze (xrefs)
 556   "Find common filenames in XREFS.
 557 Return an alist of the form ((FILENAME . (XREF ...)) ...)."
 558   (xref--alistify xrefs
 559                   (lambda (x)
 560                     (xref-location-group (xref--xref-location x)))
 561                   #'equal))
 562
 563 (defun xref--show-xref-buffer (xrefs alist)
 564   (let ((xref-alist (xref--analyze xrefs)))
 565     (with-current-buffer (get-buffer-create xref-buffer-name)
 566       (let ((inhibit-read-only t))
 567         (erase-buffer)
 568         (xref--insert-xrefs xref-alist)
 569         (xref--xref-buffer-mode)
 570         (pop-to-buffer (current-buffer))
 571         (goto-char (point-min))
 572         (setq xref--window (assoc-default 'window alist))
 573         (setq xref--temporary-buffers (assoc-default 'temporary-buffers alist))
 574         (dolist (buf xref--temporary-buffers)
 575           (with-current-buffer buf
 576             (add-hook 'buffer-list-update-hook #'xref--mark-selected nil t)))
 577         (current-buffer)))))
 578
 579 \f
 580 ;; This part of the UI seems fairly uncontroversial: it reads the
 581 ;; identifier and deals with the single definition case.
 582 ;;
 583 ;; The controversial multiple definitions case is handed off to
 584 ;; xref-show-xrefs-function.
 585
 586 (defvar xref-show-xrefs-function 'xref--show-xref-buffer
 587   "Function to display a list of xrefs.")
 588
 589 (defvar xref--read-identifier-history nil)
 590
 591 (defvar xref--read-pattern-history nil)
 592
 593 (defun xref--show-xrefs (input kind arg window)
 594   (let* ((bl (buffer-list))
 595          (xrefs (funcall xref-find-function kind arg))
 596          (tb (cl-set-difference (buffer-list) bl)))
 597     (cond
 598      ((null xrefs)
 599       (user-error "No %s found for: %s" (symbol-name kind) input))
 600      ((not (cdr xrefs))
 601       (xref-push-marker-stack)
 602       (xref--pop-to-location (xref--xref-location (car xrefs)) window))
 603      (t
 604       (xref-push-marker-stack)
 605       (funcall xref-show-xrefs-function xrefs
 606                `((window . ,window)
 607                  (temporary-buffers . ,tb)))))))
 608
 609 (defun xref--prompt-p (command)
 610   (or (eq xref-prompt-for-identifier t)
 611       (if (eq (car xref-prompt-for-identifier) 'not)
 612           (not (memq command (cdr xref-prompt-for-identifier)))
 613         (memq command xref-prompt-for-identifier))))
 614
 615 (defun xref--read-identifier (prompt)
 616   "Return the identifier at point or read it from the minibuffer."
 617   (let ((id (funcall xref-identifier-at-point-function)))
 618     (cond ((or current-prefix-arg
 619                (not id)
 620                (xref--prompt-p this-command))
 621            (completing-read prompt
 622                             (funcall xref-identifier-completion-table-function)
 623                             nil nil nil
 624                             'xref--read-identifier-history id))
 625           (t id))))
 626
 627 \f
 628 ;;; Commands
 629
 630 (defun xref--find-definitions (id window)
 631   (xref--show-xrefs id 'definitions id window))
 632
 633 ;;;###autoload
 634 (defun xref-find-definitions (identifier)
 635   "Find the definition of the identifier at point.
 636 With prefix argument or when there's no identifier at point,
 637 prompt for it."
 638   (interactive (list (xref--read-identifier "Find definitions of: ")))
 639   (xref--find-definitions identifier nil))
 640
 641 ;;;###autoload
 642 (defun xref-find-definitions-other-window (identifier)
 643   "Like `xref-find-definitions' but switch to the other window."
 644   (interactive (list (xref--read-identifier "Find definitions of: ")))
 645   (xref--find-definitions identifier 'window))
 646
 647 ;;;###autoload
 648 (defun xref-find-definitions-other-frame (identifier)
 649   "Like `xref-find-definitions' but switch to the other frame."
 650   (interactive (list (xref--read-identifier "Find definitions of: ")))
 651   (xref--find-definitions identifier 'frame))
 652
 653 ;;;###autoload
 654 (defun xref-find-references (identifier)
 655   "Find references to the identifier at point.
 656 With prefix argument, prompt for the identifier."
 657   (interactive (list (xref--read-identifier "Find references of: ")))
 658   (xref--show-xrefs identifier 'references identifier nil))
 659
 660 ;;;###autoload
 661 (defun xref-find-regexp (regexp)
 662   "Find all matches for REGEXP.
 663 With \\[universal-argument] prefix, you can specify the directory
 664 to search in."
 665   (interactive (list (xref--read-identifier "Find regexp: ")))
 666   (let* ((proj (project-current))
 667          (dirs (if current-prefix-arg
 668                    (list (read-directory-name "In directory: "))
 669                  (project--prune-directories
 670                   (nconc
 671                    (project-directories proj)
 672                    (project-search-path proj)))))
 673          (xref-find-function
 674           (lambda (_kind regexp)
 675             (cl-mapcan
 676              (lambda (dir)
 677                (xref-collect-matches regexp dir (project-ignores proj)))
 678              dirs))))
 679     (xref--show-xrefs regexp 'matches regexp nil)))
 680
 681 (declare-function apropos-parse-pattern "apropos" (pattern))
 682
 683 ;;;###autoload
 684 (defun xref-find-apropos (pattern)
 685   "Find all meaningful symbols that match PATTERN.
 686 The argument has the same meaning as in `apropos'."
 687   (interactive (list (read-string
 688                       "Search for pattern (word list or regexp): "
 689                       nil 'xref--read-pattern-history)))
 690   (require 'apropos)
 691   (xref--show-xrefs pattern 'apropos
 692                     (apropos-parse-pattern
 693                      (if (string-equal (regexp-quote pattern) pattern)
 694                          ;; Split into words
 695                          (or (split-string pattern "[ \t]+" t)
 696                              (user-error "No word list given"))
 697                        pattern))
 698                     nil))
 699
 700 \f
 701 ;;; Key bindings
 702
 703 ;;;###autoload (define-key esc-map "." #'xref-find-definitions)
 704 ;;;###autoload (define-key esc-map "," #'xref-pop-marker-stack)
 705 ;;;###autoload (define-key esc-map [?\C-.] #'xref-find-apropos)
 706 ;;;###autoload (define-key ctl-x-4-map "." #'xref-find-definitions-other-window)
 707 ;;;###autoload (define-key ctl-x-5-map "." #'xref-find-definitions-other-frame)
 708
 709 \f
 710 ;;; Helper functions
 711
 712 (defvar xref-etags-mode--saved nil)
 713
 714 (define-minor-mode xref-etags-mode
 715   "Minor mode to make xref use etags again.
 716
 717 Certain major modes install their own mechanisms for listing
 718 identifiers and navigation.  Turn this on to undo those settings
 719 and just use etags."
 720   :lighter ""
 721   (if xref-etags-mode
 722       (progn
 723         (setq xref-etags-mode--saved
 724               (cons xref-find-function
 725                     xref-identifier-completion-table-function))
 726         (kill-local-variable 'xref-find-function)
 727         (kill-local-variable 'xref-identifier-completion-table-function))
 728     (setq-local xref-find-function (car xref-etags-mode--saved))
 729     (setq-local xref-identifier-completion-table-function
 730                 (cdr xref-etags-mode--saved))))
 731
 732 (declare-function semantic-symref-find-references-by-name "semantic/symref")
 733 (declare-function semantic-symref-find-text "semantic/symref")
 734 (declare-function semantic-find-file-noselect "semantic/fw")
 735 (declare-function rgrep-default-command "grep")
 736
 737 (defun xref-collect-references (symbol dir)
 738   "Collect references to SYMBOL inside DIR.
 739 This function uses the Semantic Symbol Reference API, see
 740 `semantic-symref-find-references-by-name' for details on which
 741 tools are used, and when."
 742   (cl-assert (directory-name-p dir))
 743   (require 'semantic/symref)
 744   (defvar semantic-symref-tool)
 745   (let* ((default-directory dir)
 746          (semantic-symref-tool 'detect)
 747          (res (semantic-symref-find-references-by-name symbol 'subdirs))
 748          (hits (and res (oref res hit-lines)))
 749          (orig-buffers (buffer-list)))
 750     (unwind-protect
 751         (delq nil
 752               (mapcar (lambda (hit) (xref--collect-match
 753                                 hit (format "\\_<%s\\_>" (regexp-quote symbol))))
 754                       hits))
 755       (mapc #'kill-buffer
 756             (cl-set-difference (buffer-list) orig-buffers)))))
 757
 758 (defun xref-collect-matches (regexp dir ignores)
 759   "Collect matches for REGEXP inside DIR using rgrep."
 760   (cl-assert (directory-name-p dir))
 761   (require 'semantic/fw)
 762   (grep-compute-defaults)
 763   (defvar grep-find-template)
 764   (defvar grep-highlight-matches)
 765   (let* ((grep-find-template (replace-regexp-in-string "-e " "-E "
 766                                                        grep-find-template t t))
 767          (grep-highlight-matches nil)
 768          (command (xref--rgrep-command (xref--regexp-to-extended regexp)
 769                                        "*.*" dir ignores))
 770          (orig-buffers (buffer-list))
 771          (buf (get-buffer-create " *xref-grep*"))
 772          (grep-re (caar grep-regexp-alist))
 773          hits)
 774     (with-current-buffer buf
 775       (erase-buffer)
 776       (call-process-shell-command command nil t)
 777       (goto-char (point-min))
 778       (while (re-search-forward grep-re nil t)
 779         (push (cons (string-to-number (match-string 2))
 780                     (match-string 1))
 781               hits)))
 782     (unwind-protect
 783         (delq nil
 784               (mapcar (lambda (hit) (xref--collect-match hit regexp))
 785                       (nreverse hits)))
 786       (mapc #'kill-buffer
 787             (cl-set-difference (buffer-list) orig-buffers)))))
 788
 789 (defun xref--rgrep-command (regexp files dir ignores)
 790   (require 'find-dired)      ; for `find-name-arg'
 791   (defvar grep-find-template)
 792   (defvar find-name-arg)
 793   (grep-expand-template
 794    grep-find-template
 795    regexp
 796    (concat (shell-quote-argument "(")
 797            " " find-name-arg " "
 798            (mapconcat
 799             #'shell-quote-argument
 800             (split-string files)
 801             (concat " -o " find-name-arg " "))
 802            " "
 803            (shell-quote-argument ")"))
 804    dir
 805    (concat
 806     (shell-quote-argument "(")
 807     " -path "
 808     (mapconcat
 809      (lambda (ignore)
 810        (when (string-match "\\(\\.\\)/" ignore)
 811          (setq ignore (replace-match dir t t ignore 1)))
 812        (when (string-match-p "/\\'" ignore)
 813          (setq ignore (concat ignore "*")))
 814        (unless (string-prefix-p "*" ignore)
 815          (setq ignore (concat "*/" ignore)))
 816        (shell-quote-argument ignore))
 817      ignores
 818      " -o -path ")
 819     " "
 820     (shell-quote-argument ")")
 821     " -prune -o ")))
 822
 823 (defun xref--regexp-to-extended (str)
 824   (replace-regexp-in-string
 825    ;; FIXME: Add tests.  Move to subr.el, make a public function.
 826    ;; Maybe error on Emacs-only constructs.
 827    "\\(?:\\\\\\\\\\)*\\(?:\\\\[][]\\)?\\(?:\\[.+?\\]\\|\\(\\\\?[(){}|]\\)\\)"
 828    (lambda (str)
 829      (cond
 830       ((not (match-beginning 1))
 831        str)
 832       ((eq (length (match-string 1 str)) 2)
 833        (concat (substring str 0 (match-beginning 1))
 834                (substring (match-string 1 str) 1 2)))
 835       (t
 836        (concat (substring str 0 (match-beginning 1))
 837                "\\"
 838                (match-string 1 str)))))
 839    str t t))
 840
 841 (defun xref--collect-match (hit regexp)
 842   (pcase-let* ((`(,line . ,file) hit)
 843                (buf (or (find-buffer-visiting file)
 844                         (semantic-find-file-noselect file))))
 845     (with-current-buffer buf
 846       (save-excursion
 847         (goto-char (point-min))
 848         (forward-line (1- line))
 849         (syntax-propertize (line-end-position))
 850         (when (re-search-forward regexp (line-end-position) t)
 851           (goto-char (match-beginning 0))
 852           (xref-make (buffer-substring
 853                       (line-beginning-position)
 854                       (line-end-position))
 855                      (xref-make-file-location file line
 856                                               (current-column))))))))
 857
 858 (provide 'xref)
 859
 860 ;;; xref.el ends here