code.delx.au - gnu-emacs/blob - configure.in

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl
   6 dnl  Copyright (C) 1994, 1995, 1996, 1999, 2000, 2001, 2002, 2003,
   7 dnl    2004, 2005, 2006, 2007, 2008  Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation, either version 3 of the License, or
  14 dnl  (at your option) any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 AC_PREREQ(2.61)
  25 AC_INIT(emacs, 23.0.60)
  26 AC_CONFIG_HEADER(src/config.h:src/config.in)
  27 AC_CONFIG_SRCDIR(src/lisp.h)
  28
  29 dnl Support for --program-prefix, --program-suffix and
  30 dnl --program-transform-name options
  31 AC_ARG_PROGRAM
  32
  33 lispdir='${datadir}/emacs/${version}/lisp'
  34 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  35 '${datadir}/emacs/site-lisp'
  36 lisppath='${locallisppath}:${lispdir}:${datadir}/emacs/${version}/leim'
  37 etcdir='${datadir}/emacs/${version}/etc'
  38 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  39 docdir='${datadir}/emacs/${version}/etc'
  40 gamedir='${localstatedir}/games/emacs'
  41
  42 gameuser=games
  43
  44 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
  45 dnl Create a new --with option that defaults to being disabled.
  46 dnl NAME is the base name of the option.  The shell variable with_NAME
  47 dnl   will be set to either the user's value (if the option is
  48 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
  49 dnl   option is not specified).  Note that the shell variable name is
  50 dnl   constructed as autoconf does, by replacing non-alphanumeric
  51 dnl   characters with "_".
  52 dnl HELP-STRING is the help text for the option.
  53 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
  54   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
  55     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
  56 ])dnl
  57
  58 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
  59 dnl Create a new --with option that defaults to being enabled.  NAME
  60 dnl   is the base name of the option.  The shell variable with_NAME
  61 dnl   will be set either to 'no' (for a plain --without-NAME) or to
  62 dnl   'yes' (if the option is not specified).  Note that the shell
  63 dnl   variable name is constructed as autoconf does, by replacing
  64 dnl   non-alphanumeric characters with "_".
  65 dnl HELP-STRING is the help text for the option.
  66 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
  67   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
  68    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=yes])dnl
  69 ])dnl
  70
  71 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
  72 if test "$with_pop" = yes; then
  73    AC_DEFINE(MAIL_USE_POP)
  74 fi
  75 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
  76
  77 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
  78 if test "$with_kerberos" != no; then
  79    AC_DEFINE(KERBEROS)
  80 fi
  81 AH_TEMPLATE(KERBEROS,
  82             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
  83
  84 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
  85 if test "${with_kerberos5}" != no; then
  86   if test "${with_kerberos}" = no; then
  87     with_kerberos=yes
  88     AC_DEFINE(KERBEROS)
  89   fi
  90   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
  91 fi
  92
  93 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
  94 if test "$with_hesiod" != no; then
  95   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
  96 fi
  97
  98 OPTION_DEFAULT_ON([sound],[don't compile with sound support])
  99
 100 OPTION_DEFAULT_ON([sync-input],[Process async input synchronously])
 101 if test "$with_sync_input" = yes; then
 102    AC_DEFINE(SYNC_INPUT, 1, [Process async input synchronously.])
 103 fi
 104
 105 dnl FIXME currently it is not the last.
 106 dnl This should be the last --with option, because --with-x is
 107 dnl added later on when we find the path of X, and it's best to
 108 dnl keep them together visually.
 109 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 110  [use an X toolkit (KIT one of: yes, lucid, athena, motif, gtk, no)])],
 111 [         case "${withval}" in
 112             y | ye | yes )      val=gtk ;;
 113             n | no )            val=no  ;;
 114             l | lu | luc | luci | lucid )       val=lucid ;;
 115             a | at | ath | athe | athen | athena )      val=athena ;;
 116             m | mo | mot | moti | motif )       val=motif ;;
 117             g | gt | gtk  )     val=gtk ;;
 118             * )
 119 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 120 this option's value should be `yes', `no', `lucid', `athena', `motif' or `gtk'.
 121 `yes' and `gtk' are synonyms. `athena' and `lucid' are synonyms.])
 122             ;;
 123           esac
 124           with_x_toolkit=$val
 125 ])
 126
 127 dnl _ON results in a '--without' option in the --help output, so
 128 dnl the help text should refer to "don't compile", etc.
 129 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 130 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 131 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 132 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 133 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 134 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 135
 136 OPTION_DEFAULT_ON([freetype],[don't use Freetype for local font support])
 137 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 138 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 139 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 140
 141 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 142 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 143 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 144 OPTION_DEFAULT_OFF([ns],[use nextstep (Cocoa or GNUstep) windowing system])
 145
 146 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 147 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 148
 149 ## For the times when you want to build Emacs but don't have
 150 ## a suitable makeinfo, and can live without the manuals.
 151 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 152 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 153
 154 dnl Can remove these in Emacs 24.
 155 AC_ARG_WITH([gtk],,
 156   [AC_MSG_ERROR([--with-gtk has been removed.  Use --with-x-toolkit to
 157 specify a toolkit.])],,)
 158
 159 AC_ARG_WITH([gcc],,
 160   [AC_MSG_ERROR([--with-gcc has been removed.  Set the `CC' environment
 161 variable to specify a compiler.])],,)
 162
 163 AC_ARG_WITH([pkg-config-prog],dnl
 164 [AS_HELP_STRING([--with-pkg-config-prog=PATH],
 165                   [Path to pkg-config for finding GTK and librsvg])])
 166 if test "X${with_pkg_config_prog}" != X; then
 167    if test "${with_pkg_config_prog}" != yes; then
 168       PKG_CONFIG="${with_pkg_config_prog}"
 169    fi
 170 fi
 171
 172 AC_ARG_ENABLE(cocoa-experimental-ctrl-g,
 173 [AS_HELP_STRING([--enable-cocoa-experimental-ctrl-g],
 174                 [enable experimental improved ctrl-g recognition])],
 175    EN_COCOA_EXPERIMENTAL_CTRL_G=$enableval,
 176    EN_COCOA_EXPERIMENTAL_CTRL_G=no)
 177
 178 AC_ARG_ENABLE(ns-self-contained,
 179 [AS_HELP_STRING([--disable-ns-self-contained],
 180                 [disable self contained build under NeXTstep])],
 181    EN_NS_SELF_CONTAINED=$enableval,
 182    EN_NS_SELF_CONTAINED=yes)
 183
 184 AC_ARG_ENABLE(asserts,
 185 [AS_HELP_STRING([--enable-asserts], [compile code with asserts enabled])],
 186       USE_XASSERTS=$enableval,
 187       USE_XASSERTS=no)
 188
 189 AC_ARG_ENABLE(maintainer-mode,
 190 [AS_HELP_STRING([--enable-maintainer-mode],
 191                 [enable make rules and dependencies not useful (and sometimes
 192                  confusing) to the casual installer])],
 193       USE_MAINTAINER_MODE=$enableval,
 194       USE_MAINTAINER_MODE=no)
 195 if test $USE_MAINTAINER_MODE = yes; then
 196   MAINT=
 197 else
 198   MAINT=#
 199 fi
 200 AC_SUBST(MAINT)
 201
 202 AC_ARG_ENABLE(locallisppath,
 203 [AS_HELP_STRING([--enable-locallisppath=PATH],
 204                 [directories Emacs should search for lisp files specific
 205                  to this site])],
 206 if test "${enableval}" = "no"; then
 207   locallisppath=
 208 elif test "${enableval}" != "yes"; then
 209   locallisppath=${enableval}
 210 fi)
 211
 212 #### Make srcdir absolute, if it isn't already.  It's important to
 213 #### avoid running the path through pwd unnecessarily, since pwd can
 214 #### give you automounter prefixes, which can go away.  We do all this
 215 #### so Emacs can find its files when run uninstalled.
 216 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 217 unset CDPATH
 218 case "${srcdir}" in
 219   /* ) ;;
 220   . )
 221     ## We may be able to use the $PWD environment variable to make this
 222     ## absolute.  But sometimes PWD is inaccurate.
 223     ## Note: we used to use ${PWD} at the end instead of `pwd`,
 224     ## but that tested only for a well-formed and valid PWD,
 225     ## it did not object when PWD was well-formed and valid but just wrong.
 226     if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`"  ;
 227     then
 228       srcdir="$PWD"
 229     else
 230       srcdir="`(cd ${srcdir}; pwd)`"
 231     fi
 232   ;;
 233   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
 234 esac
 235
 236 #### Check if the source directory already has a configured system in it.
 237 if test `pwd` != `(cd ${srcdir} && pwd)` \
 238    && test -f "${srcdir}/src/config.h" ; then
 239   AC_MSG_WARN([[The directory tree `${srcdir}' is being used
 240    as a build directory right now; it has been configured in its own
 241    right.  To configure in another directory as well, you MUST
 242    use GNU make.  If you do not have GNU make, then you must
 243    now do `make distclean' in ${srcdir},
 244    and then run $0 again.]])
 245 fi
 246
 247 #### Given the configuration name, set machfile and opsysfile to the
 248 #### names of the m/*.h and s/*.h files we should use.
 249
 250 ### Canonicalize the configuration name.
 251
 252 AC_CANONICAL_HOST
 253 canonical=$host
 254 configuration=${host_alias-${build_alias-$host}}
 255
 256 dnl This used to use changequote, but, apart from `changequote is evil'
 257 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 258 dnl the great gob of text.  Thus it's not processed for possible expansion.
 259 dnl Just make sure the brackets remain balanced.
 260 dnl
 261 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 262 dnl indicated by comments.
 263 dnl quotation begins
 264 [
 265
 266 ### If you add support for a new configuration, add code to this
 267 ### switch statement to recognize your configuration name and select
 268 ### the appropriate operating system and machine description files.
 269
 270 ### You would hope that you could choose an m/*.h file pretty much
 271 ### based on the machine portion of the configuration name, and an s-
 272 ### file based on the operating system portion.  However, it turns out
 273 ### that each m/*.h file is pretty manufacturer-specific - for
 274 ### example mips.h is MIPS
 275 ### So we basically have to have a special case for each
 276 ### configuration name.
 277 ###
 278 ### As far as handling version numbers on operating systems is
 279 ### concerned, make sure things will fail in a fixable way.  If
 280 ### /etc/MACHINES doesn't say anything about version numbers, be
 281 ### prepared to handle anything reasonably.  If version numbers
 282 ### matter, be sure /etc/MACHINES says something about it.
 283 ###
 284 ### Eric Raymond says we should accept strings like "sysvr4" to mean
 285 ### "System V Release 4"; he writes, "The old convention encouraged
 286 ### confusion between `system' and `release' levels'."
 287
 288 machine='' opsys='' unported=no
 289 case "${canonical}" in
 290
 291   ## FreeBSD ports
 292   *-*-freebsd* )
 293     opsys=freebsd
 294     case "${canonical}" in
 295       alpha*-*-freebsd*)        machine=alpha ;;
 296       arm*-*-freebsd*)          machine=arm ;;
 297       ia64-*-freebsd*)          machine=ia64 ;;
 298       sparc-*-freebsd*)         machine=sparc ;;
 299       sparc64-*-freebsd*)       machine=sparc ;;
 300       powerpc-*-freebsd*)       machine=macppc ;;
 301       i[3456]86-*-freebsd*)     machine=intel386 ;;
 302       amd64-*-freebsd*|x86_64-*-freebsd*) machine=amdx86-64 ;;
 303     esac
 304   ;;
 305
 306   ## FreeBSD kernel + glibc based userland
 307   *-*-kfreebsd*gnu* )
 308     opsys=gnu-kfreebsd
 309     case "${canonical}" in
 310       alpha*-*-kfreebsd*)       machine=alpha ;;
 311       ia64-*-kfreebsd*)         machine=ia64 ;;
 312       sparc-*-kfreebsd*)        machine=sparc ;;
 313       sparc64-*-kfreebsd*)      machine=sparc ;;
 314       powerpc-*-kfreebsd*)      machine=macppc ;;
 315       i[3456]86-*-kfreebsd*)    machine=intel386 ;;
 316       amd64-*-kfreebsd*|x86_64-*-kfreebsd*) machine=amdx86-64 ;;
 317     esac
 318   ;;
 319
 320   ## NetBSD ports
 321   *-*-netbsd* )
 322     opsys=netbsd
 323     if test -f /usr/lib/crti.o; then]
 324 dnl The close and open brackets here are because this section is quoted --
 325 dnl see the `changequote' comment above.
 326       AC_DEFINE(HAVE_CRTIN, [], [Define to 1 if you have /usr/lib/crti.o.])
 327 [   fi
 328
 329     case "${canonical}" in
 330       alpha*-*-netbsd*) machine=alpha ;;
 331       i[3456]86-*-netbsd*) machine=intel386 ;;
 332       powerpc-*-netbsd*) machine=macppc ;;
 333       sparc*-*-netbsd*) machine=sparc ;;
 334       vax-*-netbsd*)    machine=vax ;;
 335       arm-*-netbsd*)    machine=arm ;;
 336       x86_64-*-netbsd*) machine=amdx86-64 ;;
 337       hppa-*-netbsd*)   machine=hp800 ;;
 338     esac
 339   ;;
 340
 341   ## OpenBSD ports
 342   *-*-openbsd* )
 343     opsys=openbsd
 344     case "${canonical}" in
 345       alpha*-*-openbsd*)        machine=alpha ;;
 346       arm-*-openbsd*)          machine=arm ;;
 347       i386-*-openbsd*)         machine=intel386 ;;
 348       powerpc-*-openbsd*)      machine=macppc ;;
 349       sparc*-*-openbsd*)       machine=sparc ;;
 350       vax-*-openbsd*)          machine=vax ;;
 351       x86_64-*-openbsd*)       machine=amdx86-64 ;;
 352     esac
 353   ;;
 354
 355   ## LynxOS ports
 356   *-*-lynxos* )
 357     opsys=lynxos
 358     case "${canonical}" in
 359       i[3456]86-*-lynxos*) machine=intel386 ;;
 360       powerpc-*-lynxos*) machine=powerpc ;;
 361     esac
 362   ;;
 363
 364   alpha*-*-linux-gnu* )
 365     machine=alpha opsys=gnu-linux
 366   ;;
 367
 368   arm*-*-linux-gnu* )
 369     machine=arm opsys=gnu-linux
 370   ;;
 371
 372   ## Apple Darwin / Mac OS X
 373   *-apple-darwin* )
 374     case "${canonical}" in
 375       i[3456]86-* )  machine=intel386 ;;
 376       powerpc-* )    machine=macppc ;;
 377       * )            unported=yes ;;
 378     esac
 379     opsys=darwin
 380     # Define CPP as follows to make autoconf work correctly.
 381     CPP="${CC-cc} -E -no-cpp-precomp"
 382     # Use fink packages if available.
 383     if test -d /sw/include && test -d /sw/lib; then
 384       GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 385       CPP="${CPP} ${GCC_TEST_OPTIONS}"
 386       NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 387     fi
 388   ;;
 389
 390   ## HP 9000 series 700 and 800, running HP/UX
 391   hppa*-hp-hpux10.2* )
 392     machine=hp800 opsys=hpux10-20
 393   ;;
 394   hppa*-hp-hpux1[1-9]* )
 395     machine=hp800 opsys=hpux11
 396     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 397   ;;
 398
 399   hppa*-*-linux-gnu* )
 400     machine=hp800 opsys=gnu-linux
 401   ;;
 402
 403   ## IBM machines
 404   s390-*-linux-gnu* )
 405     machine=ibms390 opsys=gnu-linux
 406   ;;
 407   s390x-*-linux-gnu* )
 408     machine=ibms390x opsys=gnu-linux
 409   ;;
 410   rs6000-ibm-aix4.2* | powerpc-ibm-aix4.2*  )
 411     machine=ibmrs6000 opsys=aix4-2
 412   ;;
 413   rs6000-ibm-aix4.3* | powerpc-ibm-aix4.3*  )
 414     machine=ibmrs6000 opsys=aix4-2
 415   ;;
 416   rs6000-ibm-aix5* | powerpc-ibm-aix5*  )
 417     machine=ibmrs6000 opsys=aix4-2
 418   ;;
 419   rs6000-ibm-aix5* | powerpc-ibm-aix6*  )
 420     machine=ibmrs6000 opsys=aix4-2
 421   ;;
 422
 423   ## Macintosh PowerPC
 424   powerpc*-*-linux-gnu* )
 425     machine=macppc opsys=gnu-linux
 426   ;;
 427
 428   ## Silicon Graphics machines
 429   ## Iris 4D
 430   mips-sgi-irix6.5 )
 431     machine=iris4d opsys=irix6-5
 432     # Without defining _LANGUAGE_C, things get masked out in the headers
 433     # so that, for instance, grepping for `free' in stdlib.h fails and
 434     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 435     NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
 436     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 437   ;;
 438
 439   ## Suns
 440   sparc-*-linux-gnu* | sparc64-*-linux-gnu* )
 441     machine=sparc opsys=gnu-linux
 442   ;;
 443
 444   *-sun-solaris* \
 445     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* | powerpc*-*-solaris2* \
 446     | rs6000-*-solaris2*)
 447     case "${canonical}" in
 448       i[3456]86-*-* )     machine=intel386 ;;
 449       amd64-*-*|x86_64-*-*)     machine=amdx86-64 ;;
 450       powerpc* | rs6000* )  machine=ibmrs6000 ;;
 451       sparc* )          machine=sparc ;;
 452       * )               unported=yes ;;
 453     esac
 454     case "${canonical}" in
 455       *-sunos5.3* | *-solaris2.3* )
 456                 opsys=sol2-3
 457                 NON_GNU_CPP=/usr/ccs/lib/cpp
 458                 ;;
 459       *-sunos5.4* | *-solaris2.4* )
 460                 opsys=sol2-4
 461                 NON_GNU_CPP=/usr/ccs/lib/cpp
 462                 RANLIB="ar -ts"
 463                 ;;
 464       *-sunos5.5* | *-solaris2.5* )
 465                 opsys=sol2-5
 466                 NON_GNU_CPP=/usr/ccs/lib/cpp
 467                 RANLIB="ar -ts"
 468                 ;;
 469       *-sunos5.6* | *-solaris2.6* )
 470                 opsys=sol2-6
 471                 NON_GNU_CPP=/usr/ccs/lib/cpp
 472                 RANLIB="ar -ts"
 473                 ;;
 474       *-sunos5.[7-9]* | *-solaris[7-9]* )
 475                 opsys=sol2-6
 476                 emacs_check_sunpro_c=yes
 477                 NON_GNU_CPP=/usr/ccs/lib/cpp
 478                 ;;
 479       *-sunos5* | *-solaris* )
 480                 opsys=sol2-10
 481                 emacs_check_sunpro_c=yes
 482                 NON_GNU_CPP=/usr/ccs/lib/cpp
 483                 ;;
 484     esac
 485     ## Watch out for a compiler that we know will not work.
 486     case "${canonical}" in
 487      *-solaris* | *-sunos5* )
 488                 if [ "x$CC" = x/usr/ucb/cc ]; then
 489                   ## /usr/ucb/cc doesn't work;
 490                   ## we should find some other compiler that does work.
 491                   unset CC
 492                 fi
 493                 ;;
 494       *) ;;
 495     esac
 496   ;;
 497
 498   ## Vaxen.
 499   vax-dec-* )
 500     machine=vax
 501     case "${canonical}" in
 502       *-vms* )                                          opsys=vms ;;
 503       * )                                               unported=yes
 504     esac
 505   ;;
 506
 507   ## IA-64
 508   ia64*-*-linux* )
 509     machine=ia64 opsys=gnu-linux
 510   ;;
 511
 512   ## Intel 386 machines where we don't care about the manufacturer
 513   i[3456]86-*-* )
 514     machine=intel386
 515     case "${canonical}" in
 516       *-cygwin )                opsys=cygwin ;;
 517       *-darwin* )               opsys=darwin
 518                                 CPP="${CC-cc} -E -no-cpp-precomp"
 519                                 ;;
 520       *-linux-gnu* )            opsys=gnu-linux ;;
 521       *-sysv4.2uw* )            opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 522       *-sysv5uw* )              opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 523       *-sysv5OpenUNIX* )        opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 524       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 525     esac
 526   ;;
 527
 528   ## m68k Linux-based GNU system
 529   m68k-*-linux-gnu* )
 530     machine=m68k opsys=gnu-linux
 531   ;;
 532
 533   ## Mips Linux-based GNU system
 534   mips-*-linux-gnu* | mipsel-*-linux-gnu* )
 535     machine=mips opsys=gnu-linux
 536   ;;
 537
 538   ## AMD x86-64 Linux-based GNU system
 539   x86_64-*-linux-gnu* )
 540     machine=amdx86-64 opsys=gnu-linux
 541   ;;
 542
 543   ## Tensilica Xtensa Linux-based GNU system
 544   xtensa*-*-linux-gnu* )
 545     machine=xtensa opsys=gnu-linux
 546     ;;
 547
 548   ## SuperH Linux-based GNU system
 549   sh[34]*-*-linux-gnu* )
 550     machine=sh3 opsys=gnu-linux
 551   ;;
 552
 553   * )
 554     unported=yes
 555   ;;
 556 esac
 557
 558 ### If the code above didn't choose an operating system, just choose
 559 ### an operating system based on the configuration name.  You really
 560 ### only want to use this when you have no idea what the right
 561 ### operating system is; if you know what operating systems a machine
 562 ### runs, it's cleaner to make it explicit in the case statement
 563 ### above.
 564 if test x"${opsys}" = x; then
 565   case "${canonical}" in
 566     *-gnu* )                            opsys=gnu ;;
 567     *-sysv4.2uw* )                      opsys=unixware ;;
 568     *-sysv5uw* )                        opsys=unixware ;;
 569     *-sysv5OpenUNIX* )                  opsys=unixware ;;
 570     *-sysv4.1* | *-sysvr4.1* )
 571         NON_GNU_CPP=/usr/lib/cpp
 572         opsys=usg5-4 ;;
 573     *-sysv4.[2-9]* | *-sysvr4.[2-9]* )
 574         if [ x$NON_GNU_CPP = x ]; then
 575           if [ -f /usr/ccs/lib/cpp ]; then
 576             NON_GNU_CPP=/usr/ccs/lib/cpp
 577           else
 578             NON_GNU_CPP=/lib/cpp
 579           fi
 580         fi
 581         opsys=usg5-4-2 ;;
 582     *-sysv4* | *-sysvr4* )              opsys=usg5-4 ;;
 583     * )
 584       unported=yes
 585     ;;
 586   esac
 587 fi
 588
 589 ]
 590 dnl quotation ends
 591
 592 if test $unported = yes; then
 593   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
 594 Check `etc/MACHINES' for recognized configuration names.])
 595 fi
 596
 597 machfile="m/${machine}.h"
 598 opsysfile="s/${opsys}.h"
 599
 600
 601 #### Choose a compiler.
 602 test -n "$CC" && cc_specified=yes
 603
 604 # Save the value of CFLAGS that the user specified.
 605 SPECIFIED_CFLAGS="$CFLAGS"
 606
 607 dnl Sets GCC=yes if using gcc.
 608 AC_PROG_CC
 609
 610 # On Suns, sometimes $CPP names a directory.
 611 if test -n "$CPP" && test -d "$CPP"; then
 612   CPP=
 613 fi
 614
 615 ## If not using gcc, and on Solaris, and no CPP specified, see if
 616 ## using a Sun compiler, which needs -Xs to prevent whitespace.
 617 if test x"$GCC" != xyes && test x"$emacs_check_sunpro_c" = xyes && \
 618  test x"$CPP" = x; then
 619   AC_MSG_CHECKING([whether we are using a Sun C compiler])
 620   AC_CACHE_VAL(emacs_cv_sunpro_c,
 621   [AC_TRY_LINK([],
 622 [#ifndef __SUNPRO_C
 623 fail;
 624 #endif
 625 ], emacs_cv_sunpro_c=yes, emacs_cv_sunpro_c=no)])
 626   AC_MSG_RESULT($emacs_cv_sunpro_c)
 627
 628   if test x"$emacs_cv_sunpro_c" = xyes; then
 629     NON_GNU_CPP="$CC -E -Xs"
 630   fi
 631 fi
 632
 633 #### Some systems specify a CPP to use unless we are using GCC.
 634 #### Now that we know whether we are using GCC, we can decide whether
 635 #### to use that one.
 636 if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x
 637 then
 638   CPP="$NON_GNU_CPP"
 639 fi
 640
 641 #### Some systems specify a CC to use unless we are using GCC.
 642 #### Now that we know whether we are using GCC, we can decide whether
 643 #### to use that one.
 644 if test "x$NON_GNU_CC" != x && test x$GCC != xyes &&
 645   test x$cc_specified != xyes
 646 then
 647   CC="$NON_GNU_CC"
 648 fi
 649
 650 if test x$GCC = xyes && test "x$GCC_TEST_OPTIONS" != x
 651 then
 652   CC="$CC $GCC_TEST_OPTIONS"
 653 fi
 654
 655 if test x$GCC = x && test "x$NON_GCC_TEST_OPTIONS" != x
 656 then
 657   CC="$CC $NON_GCC_TEST_OPTIONS"
 658 fi
 659
 660 dnl checks for Unix variants
 661 AC_USE_SYSTEM_EXTENSIONS
 662
 663 ### Use -Wno-pointer-sign if the compiler supports it
 664 AC_MSG_CHECKING([whether gcc understands -Wno-pointer-sign])
 665 SAVE_CFLAGS="$CFLAGS"
 666 CFLAGS="$CFLAGS -Wno-pointer-sign"
 667 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 668 if test $has_option = yes; then
 669    C_WARNINGS_SWITCH="-Wno-pointer-sign $C_WARNINGS_SWITCH"
 670 fi
 671 AC_MSG_RESULT($has_option)
 672 CFLAGS="$SAVE_CFLAGS"
 673 unset has_option
 674 unset SAVE_CFLAGS
 675
 676 #### Some other nice autoconf tests.
 677
 678 dnl checks for programs
 679 AC_PROG_LN_S
 680 AC_PROG_CPP
 681 AC_PROG_INSTALL
 682 if test "x$RANLIB" = x; then
 683   AC_PROG_RANLIB
 684 fi
 685 AC_PATH_PROG(INSTALL_INFO, install-info)
 686 AC_PATH_PROG(INSTALL_INFO, install-info,, /usr/sbin)
 687 AC_PATH_PROG(INSTALL_INFO, install-info,:, /sbin)
 688 dnl Don't use GZIP, which is used by gzip for additional parameters.
 689 AC_PATH_PROG(GZIP_PROG, gzip)
 690
 691
 692 ## Need makeinfo >= 4.6 (?) to build the manuals.
 693 AC_PATH_PROG(MAKEINFO, makeinfo, no)
 694 dnl By this stage, configure has already checked for egrep and set EGREP,
 695 dnl or exited with an error if no egrep was found.
 696 if test "$MAKEINFO" != "no" && \
 697   test x"`$MAKEINFO --version 2> /dev/null | $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[6-9]]|4\.[[1-5]][[0-9]]+)'`" = x; then
 698    MAKEINFO=no
 699 fi
 700
 701 ## Makeinfo is unusual.  For a released Emacs, the manuals are
 702 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
 703 ## therefore in the category of "special tools" not normally required, which
 704 ## configure does not have to check for (eg autoconf itself).
 705 ## In a CVS checkout on the other hand, the manuals are not included.
 706 ## So makeinfo is a requirement to build from CVS, and configure
 707 ## should test for it as it does for any other build requirement.
 708 ## We use the presence of $srcdir/info/emacs to distinguish a release,
 709 ## with pre-built manuals, from a CVS checkout.
 710 if test "$MAKEINFO" = "no"; then
 711   if test "x${with_makeinfo}" = "xno"; then
 712     MAKEINFO=off
 713   elif ! test -e $srcdir/info/emacs; then
 714     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.6, and your
 715 source tree does not seem to have pre-built manuals in the `info' directory.
 716 Either install a suitable version of makeinfo, or re-run configure
 717 with the `--without-makeinfo' option to build without the manuals.] )
 718   fi
 719 fi
 720
 721 dnl Add our options to ac_link now, after it is set up.
 722
 723 if test x$GCC = xyes && test "x$GCC_LINK_TEST_OPTIONS" != x
 724 then
 725   ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
 726 fi
 727
 728 if test x$GCC = x && test "x$NON_GCC_LINK_TEST_OPTIONS" != x
 729 then
 730   ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
 731 fi
 732
 733 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
 734 dnl If we can link with the flag, it shouldn't do any harm anyhow.
 735 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
 736 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
 737 dnl if not built to support GNU ld.
 738
 739 late_LDFLAGS=$LDFLAGS
 740 if test "$GCC" = yes; then
 741   LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
 742 else
 743   LDFLAGS="$LDFLAGS -znocombreloc"
 744 fi
 745
 746 AC_MSG_CHECKING([for -znocombreloc])
 747 AC_LINK_IFELSE([main(){return 0;}],
 748   [AC_MSG_RESULT(yes)],
 749   LDFLAGS=$late_LDFLAGS
 750   [AC_MSG_RESULT(no)])
 751
 752 #### Extract some information from the operating system and machine files.
 753
 754 AC_CHECKING([the machine- and system-dependent files to find out
 755  - which libraries the lib-src programs will want, and
 756  - whether the GNU malloc routines are usable])
 757
 758 ### First figure out CFLAGS (which we use for running the compiler here)
 759 ### and REAL_CFLAGS (which we use for real compilation).
 760 ### The two are the same except on a few systems, where they are made
 761 ### different to work around various lossages.  For example,
 762 ### GCC 2.5 on GNU/Linux needs them to be different because it treats -g
 763 ### as implying static linking.
 764
 765 ### If the CFLAGS env var is specified, we use that value
 766 ### instead of the default.
 767
 768 ### It's not important that this name contain the PID; you can't run
 769 ### two configures in the same directory and have anything work
 770 ### anyway.
 771 tempcname="conftest.c"
 772
 773 echo '
 774 #include "'${srcdir}'/src/'${opsysfile}'"
 775 #include "'${srcdir}'/src/'${machfile}'"
 776 #ifndef LIBS_MACHINE
 777 #define LIBS_MACHINE
 778 #endif
 779 #ifndef LIBS_SYSTEM
 780 #define LIBS_SYSTEM
 781 #endif
 782 #ifndef C_SWITCH_SYSTEM
 783 #define C_SWITCH_SYSTEM
 784 #endif
 785 #ifndef C_SWITCH_MACHINE
 786 #define C_SWITCH_MACHINE
 787 #endif
 788 configure___ libsrc_libs=LIBS_MACHINE LIBS_SYSTEM
 789 configure___ c_switch_system=C_SWITCH_SYSTEM
 790 configure___ c_switch_machine=C_SWITCH_MACHINE
 791
 792 #ifndef LIB_X11_LIB
 793 #define LIB_X11_LIB -lX11
 794 #endif
 795
 796 #ifndef LIBX11_SYSTEM
 797 #define LIBX11_SYSTEM
 798 #endif
 799 configure___ LIBX=LIB_X11_LIB LIBX11_SYSTEM
 800
 801 #ifdef UNEXEC
 802 configure___ unexec=UNEXEC
 803 #else
 804 configure___ unexec=unexec.o
 805 #endif
 806
 807 #ifdef SYSTEM_MALLOC
 808 configure___ system_malloc=yes
 809 #else
 810 configure___ system_malloc=no
 811 #endif
 812
 813 #ifdef USE_MMAP_FOR_BUFFERS
 814 configure___ use_mmap_for_buffers=yes
 815 #else
 816 configure___ use_mmap_for_buffers=no
 817 #endif
 818
 819 #ifndef C_DEBUG_SWITCH
 820 #define C_DEBUG_SWITCH -g
 821 #endif
 822
 823 #ifndef C_OPTIMIZE_SWITCH
 824 #ifdef __GNUC__
 825 #define C_OPTIMIZE_SWITCH -O2
 826 #else
 827 #define C_OPTIMIZE_SWITCH -O
 828 #endif
 829 #endif
 830
 831 #ifndef C_WARNINGS_SWITCH
 832 #define C_WARNINGS_SWITCH ${C_WARNINGS_SWITCH}
 833 #endif
 834
 835 #ifndef LD_SWITCH_MACHINE
 836 #define LD_SWITCH_MACHINE
 837 #endif
 838
 839 #ifndef LD_SWITCH_SYSTEM
 840 #define LD_SWITCH_SYSTEM
 841 #endif
 842
 843 #ifndef LD_SWITCH_X_SITE_AUX
 844 #define LD_SWITCH_X_SITE_AUX
 845 #endif
 846
 847 configure___ ld_switch_system=LD_SWITCH_SYSTEM
 848 configure___ ld_switch_machine=LD_SWITCH_MACHINE
 849
 850 #ifdef THIS_IS_CONFIGURE
 851
 852 /* Get the CFLAGS for tests in configure.  */
 853 #ifdef __GNUC__
 854 configure___ CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH '${SPECIFIED_CFLAGS}'
 855 #else
 856 configure___ CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
 857 #endif
 858
 859 #else /* not THIS_IS_CONFIGURE */
 860
 861 /* Get the CFLAGS for real compilation.  */
 862 #ifdef __GNUC__
 863 configure___ REAL_CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH C_WARNINGS_SWITCH '${SPECIFIED_CFLAGS}'
 864 #else
 865 configure___ REAL_CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
 866 #endif
 867
 868 #endif /* not THIS_IS_CONFIGURE */
 869 ' > ${tempcname}
 870
 871 # The value of CPP is a quoted variable reference, so we need to do this
 872 # to get its actual value...
 873 CPP=`eval "echo $CPP"`
 874 [eval `${CPP} -Isrc ${tempcname} \
 875        | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
 876 if test "x$SPECIFIED_CFLAGS" = x; then
 877   eval `${CPP} -Isrc -DTHIS_IS_CONFIGURE ${tempcname} \
 878          | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
 879 else
 880   REAL_CFLAGS="$CFLAGS"
 881 fi]
 882 rm ${tempcname}
 883
 884 ac_link="$ac_link $ld_switch_machine $ld_switch_system"
 885
 886 ### Make sure subsequent tests use flags consistent with the build flags.
 887
 888 if test x"${OVERRIDE_CPPFLAGS}" != x; then
 889   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
 890 else
 891   CPPFLAGS="$c_switch_system $c_switch_machine $CPPFLAGS"
 892 fi
 893
 894 dnl For AC_FUNC_GETLOADAVG, at least:
 895 AC_CONFIG_LIBOBJ_DIR(src)
 896
 897 dnl Do this early because it can frob feature test macros for Unix-98 &c.
 898 AC_SYS_LARGEFILE
 899
 900
 901 ### The standard library on x86-64 and s390x GNU/Linux distributions can
 902 ### be located in either /usr/lib64 or /usr/lib.
 903 case "${canonical}" in
 904   x86_64-*-linux-gnu* | s390x-*-linux-gnu* )
 905     if test -d /usr/lib64; then
 906       AC_DEFINE(HAVE_LIB64_DIR, 1,
 907         [Define to 1 if the directory /usr/lib64 exists.])
 908 fi
 909 esac
 910
 911 dnl This function defintion taken from Gnome 2.0
 912 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
 913 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
 914 dnl also defines GSTUFF_PKG_ERRORS on error
 915 AC_DEFUN([PKG_CHECK_MODULES], [
 916   succeeded=no
 917
 918   AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
 919
 920   if test "$PKG_CONFIG" = "no" ; then
 921      ifelse([$4], , [AC_MSG_ERROR([
 922       *** The pkg-config script could not be found. Make sure it is in your path, or give the full path to pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
 923   else
 924      PKG_CONFIG_MIN_VERSION=0.9.0
 925      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
 926         AC_MSG_CHECKING(for $2)
 927
 928         if $PKG_CONFIG --exists "$2" 2>&AS_MESSAGE_LOG_FD; then
 929             AC_MSG_RESULT(yes)
 930             succeeded=yes
 931
 932             AC_MSG_CHECKING($1_CFLAGS)
 933             $1_CFLAGS=`$PKG_CONFIG --cflags "$2"|sed -e 's,///*,/,g'`
 934             AC_MSG_RESULT($$1_CFLAGS)
 935
 936             AC_MSG_CHECKING($1_LIBS)
 937             $1_LIBS=`$PKG_CONFIG --libs "$2"|sed -e 's,///*,/,g'`
 938             AC_MSG_RESULT($$1_LIBS)
 939         else
 940             AC_MSG_RESULT(no)
 941             $1_CFLAGS=""
 942             $1_LIBS=""
 943             ## If we have a custom action on failure, don't print errors, but
 944             ## do set a variable so people can do so.
 945             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
 946             ifelse([$4], ,echo $$1_PKG_ERRORS,)
 947         fi
 948
 949         AC_SUBST($1_CFLAGS)
 950         AC_SUBST($1_LIBS)
 951      else
 952         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
 953         echo "*** See http://www.freedesktop.org/software/pkgconfig"
 954      fi
 955   fi
 956
 957   if test $succeeded = yes; then
 958      ifelse([$3], , :, [$3])
 959   else
 960      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
 961   fi
 962 ])
 963
 964
 965 if test "${with_sound}" != "no"; then
 966   # Sound support for GNU/Linux and the free BSDs.
 967   AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h)
 968   # Emulation library used on NetBSD.
 969   AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
 970   AC_SUBST(LIBSOUND)
 971
 972   ALSA_REQUIRED=1.0.0
 973   ALSA_MODULES="alsa >= $ALSA_REQUIRED"
 974   PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
 975   if test $HAVE_ALSA = yes; then
 976     SAVE_CFLAGS="$CFLAGS"
 977     SAVE_LDFLAGS="$LDFLAGS"
 978     CFLAGS="$ALSA_CFLAGS $CFLAGS"
 979     LDFLAGS="$ALSA_LIBS $LDFLAGS"
 980     AC_TRY_COMPILE([#include <asoundlib.h>], [snd_lib_error_set_handler (0);],
 981                     emacs_alsa_normal=yes,
 982                     emacs_alsa_normal=no)
 983     if test "$emacs_alsa_normal" != yes; then
 984       AC_TRY_COMPILE([#include <alsa/asoundlib.h>],
 985                      [snd_lib_error_set_handler (0);],
 986                      emacs_alsa_subdir=yes,
 987                      emacs_alsa_subdir=no)
 988       if test "$emacs_alsa_subdir" != yes; then
 989         AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
 990       fi
 991       ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
 992     fi
 993
 994     CFLAGS="$SAVE_CFLAGS"
 995     LDFLAGS="$SAVE_LDFLAGS"
 996     LIBSOUND="$LIBSOUND $ALSA_LIBS"
 997     CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
 998     AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
 999   fi
1000   AC_SUBST(CFLAGS_SOUND)
1001 fi
1002
1003 dnl checks for header files
1004 AC_CHECK_HEADERS(sys/select.h sys/timeb.h sys/time.h unistd.h utime.h \
1005   linux/version.h sys/systeminfo.h termios.h limits.h string.h stdlib.h \
1006   termcap.h stdio_ext.h fcntl.h strings.h coff.h pty.h sys/mman.h \
1007   sys/param.h sys/vlimit.h sys/resource.h locale.h sys/_mbstate_t.h \
1008   sys/utsname.h pwd.h)
1009
1010 AC_MSG_CHECKING(if personality LINUX32 can be set)
1011 AC_TRY_COMPILE([#include <sys/personality.h>], [personality (PER_LINUX32)],
1012                emacs_cv_personality_linux32=yes,
1013                emacs_cv_personality_linux32=no)
1014 AC_MSG_RESULT($emacs_cv_personality_linux32)
1015
1016 if test $emacs_cv_personality_linux32 = yes; then
1017   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1018             [Define to 1 if personality LINUX32 can be set.])
1019 fi
1020
1021 dnl On Solaris 8 there's a compilation warning for term.h because
1022 dnl it doesn't define `bool'.
1023 AC_CHECK_HEADERS(term.h, , , -)
1024 AC_HEADER_STDC
1025 AC_HEADER_TIME
1026 AC_CHECK_DECLS([sys_siglist])
1027 if test $ac_cv_have_decl_sys_siglist != yes; then
1028   # For Tru64, at least:
1029   AC_CHECK_DECLS([__sys_siglist])
1030   if test $ac_cv_have_decl___sys_siglist = yes; then
1031     AC_DEFINE(sys_siglist, __sys_siglist,
1032               [Define to any substitute for sys_siglist.])
1033   fi
1034 fi
1035 AC_HEADER_SYS_WAIT
1036
1037 dnl Some systems have utime.h but don't declare the struct anyplace.
1038 AC_CACHE_CHECK(for struct utimbuf, emacs_cv_struct_utimbuf,
1039 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1040 #include <sys/time.h>
1041 #include <time.h>
1042 #else
1043 #ifdef HAVE_SYS_TIME_H
1044 #include <sys/time.h>
1045 #else
1046 #include <time.h>
1047 #endif
1048 #endif
1049 #ifdef HAVE_UTIME_H
1050 #include <utime.h>
1051 #endif], [static struct utimbuf x; x.actime = x.modtime;],
1052   emacs_cv_struct_utimbuf=yes, emacs_cv_struct_utimbuf=no))
1053 if test $emacs_cv_struct_utimbuf = yes; then
1054   AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if `struct utimbuf' is declared by <utime.h>.])
1055 fi
1056
1057 dnl checks for typedefs
1058 AC_TYPE_SIGNAL
1059
1060 dnl Check for speed_t typedef.
1061 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1062   [AC_TRY_COMPILE([#include <termios.h>], [speed_t x = 1;],
1063     emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1064 if test $emacs_cv_speed_t = yes; then
1065   AC_DEFINE(HAVE_SPEED_T, 1,
1066            [Define to 1 if `speed_t' is declared by <termios.h>.])
1067 fi
1068
1069 AC_CACHE_CHECK(for struct timeval, emacs_cv_struct_timeval,
1070 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1071 #include <sys/time.h>
1072 #include <time.h>
1073 #else
1074 #ifdef HAVE_SYS_TIME_H
1075 #include <sys/time.h>
1076 #else
1077 #include <time.h>
1078 #endif
1079 #endif], [static struct timeval x; x.tv_sec = x.tv_usec;],
1080   emacs_cv_struct_timeval=yes, emacs_cv_struct_timeval=no))
1081 HAVE_TIMEVAL=$emacs_cv_struct_timeval
1082 if test $emacs_cv_struct_timeval = yes; then
1083   AC_DEFINE(HAVE_TIMEVAL, 1, [Define to 1 if `struct timeval' is declared by <sys/time.h>.])
1084 fi
1085
1086 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1087 AC_TRY_COMPILE([#include <math.h>],
1088 [static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;],
1089   emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1090 HAVE_EXCEPTION=$emacs_cv_struct_exception
1091 if test $emacs_cv_struct_exception != yes; then
1092   AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1093 fi
1094
1095 AC_CHECK_HEADERS(sys/socket.h)
1096 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1097 #if HAVE_SYS_SOCKET_H
1098 #include <sys/socket.h>
1099 #endif])
1100
1101 dnl checks for structure members
1102 AC_STRUCT_TM
1103 AC_STRUCT_TIMEZONE
1104 AC_CHECK_MEMBER(struct tm.tm_gmtoff,
1105                 [AC_DEFINE(HAVE_TM_GMTOFF, 1,
1106                            [Define to 1 if `tm_gmtoff' is member of `struct tm'.])],,
1107                 [#include <time.h>])
1108 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1109                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1110                   struct ifreq.ifr_addr], , ,
1111                  [AC_INCLUDES_DEFAULT
1112 #if HAVE_SYS_SOCKET_H
1113 #include <sys/socket.h>
1114 #endif
1115 #if HAVE_NET_IF_H
1116 #include <net/if.h>
1117 #endif])
1118
1119 dnl checks for compiler characteristics
1120
1121 dnl Testing __STDC__ to determine prototype support isn't good enough.
1122 dnl DEC C, for instance, doesn't define it with default options, and
1123 dnl is used on 64-bit systems (OSF Alphas).  Similarly for volatile
1124 dnl and void *.
1125 AC_C_PROTOTYPES
1126 AC_C_VOLATILE
1127 AC_C_CONST
1128 dnl This isn't useful because we can't turn on use of `inline' unless
1129 dnl the compiler groks `extern inline'.
1130 dnl AC_C_INLINE
1131 AC_CACHE_CHECK([for void * support], emacs_cv_void_star,
1132   [AC_TRY_COMPILE(, [void * foo;],
1133                    emacs_cv_void_star=yes, emacs_cv_void_star=no)])
1134 if test $emacs_cv_void_star = yes; then
1135   AC_DEFINE(POINTER_TYPE, void)
1136 else
1137   AC_DEFINE(POINTER_TYPE, char)
1138 fi
1139 AH_TEMPLATE(POINTER_TYPE,
1140             [Define as `void' if your compiler accepts `void *'; otherwise
1141              define as `char'.])dnl
1142
1143
1144
1145 dnl This could be used for targets which can have both byte sexes.
1146 dnl We could presumably replace the hardwired WORDS_BIG_ENDIAN generally.
1147 dnl AC_C_BIGENDIAN
1148
1149 dnl check for Make feature
1150 AC_PROG_MAKE_SET
1151
1152 dnl checks for operating system services
1153 AC_SYS_LONG_FILE_NAMES
1154
1155 #### Choose a window system.
1156
1157 AC_PATH_X
1158 if test "$no_x" = yes; then
1159   window_system=none
1160 else
1161   window_system=x11
1162 fi
1163
1164 ## Workaround for bug in autoconf <= 2.62.
1165 ## http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01551.html
1166 ## No need to do anything special for these standard directories.
1167 ## This is an experiment, take it out if it causes problems.
1168 if test -n "${x_libraries}" && test x"${x_libraries}" != xNONE; then
1169
1170    x_libraries=`echo :${x_libraries}: | sed -e 's|:/usr/lib64:|:|g' -e 's|:/lib64:|:|g' -e 's|^:||' -e 's|:$||'`
1171
1172 fi
1173
1174 if test "${x_libraries}" != NONE; then
1175   if test -n "${x_libraries}"; then
1176     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1177     LD_SWITCH_X_SITE_AUX=-R`echo ${x_libraries} | sed -e "s/:/ -R/g"`
1178   fi
1179   x_default_search_path=""
1180   x_search_path=${x_libraries}
1181   if test -z "${x_search_path}"; then
1182     x_search_path=/usr/lib
1183   fi
1184   for x_library in `echo ${x_search_path}: | \
1185                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1186     x_search_path="\
1187 ${x_library}/X11/%L/%T/%N%C%S:\
1188 ${x_library}/X11/%l/%T/%N%C%S:\
1189 ${x_library}/X11/%T/%N%C%S:\
1190 ${x_library}/X11/%L/%T/%N%S:\
1191 ${x_library}/X11/%l/%T/%N%S:\
1192 ${x_library}/X11/%T/%N%S"
1193     if test x"${x_default_search_path}" = x; then
1194       x_default_search_path=${x_search_path}
1195     else
1196       x_default_search_path="${x_search_path}:${x_default_search_path}"
1197     fi
1198   done
1199 fi
1200 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1201   C_SWITCH_X_SITE=-I`echo ${x_includes} | sed -e "s/:/ -I/g"`
1202 fi
1203
1204 if test x"${x_includes}" = x; then
1205   bitmapdir=/usr/include/X11/bitmaps
1206 else
1207   # accumulate include directories that have X11 bitmap subdirectories
1208   bmd_acc="dummyval"
1209   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1210     if test -d "${bmd}/X11/bitmaps"; then
1211       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1212     fi
1213     if test -d "${bmd}/bitmaps"; then
1214       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1215     fi
1216   done
1217   if test ${bmd_acc} != "dummyval"; then
1218     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1219   fi
1220 fi
1221
1222 HAVE_NS=no
1223 NS_IMPL_COCOA=no
1224 NS_IMPL_GNUSTEP=no
1225 tmp_CPPFLAGS="$CPPFLAGS"
1226 tmp_CFLAGS="$CFLAGS"
1227 CPPFLAGS="$CPPFLAGS -x objective-c"
1228 CFLAGS="$CFLAGS -x objective-c"
1229 if test "${with_ns}" != no; then
1230   if test "${opsys}" = darwin; then
1231      NS_IMPL_COCOA=yes
1232      ns_appdir=`pwd`/nextstep/Emacs.app
1233      ns_appbindir=`pwd`/nextstep/Emacs.app/Contents/MacOS
1234      ns_appresdir=`pwd`/nextstep/Emacs.app/Contents/Resources
1235      ns_appsrc=${srcdir}/nextstep/Cocoa/Emacs.base
1236   elif test -f /etc/GNUstep/GNUstep.conf; then
1237      NS_IMPL_GNUSTEP=yes
1238      ns_appdir=`pwd`/nextstep/Emacs.app
1239      ns_appbindir=`pwd`/nextstep/Emacs.app
1240      ns_appresdir=`pwd`/nextstep/Emacs.app/Resources
1241      ns_appsrc=${srcdir}/nextstep/GNUstep/Emacs.base
1242      GNUSTEP_MAKEFILES="$(source /etc/GNUstep/GNUstep.conf; echo $GNUSTEP_MAKEFILES)"
1243      GNUSTEP_SYSTEM_HEADERS="$(source /etc/GNUstep/GNUstep.conf; echo $GNUSTEP_SYSTEM_HEADERS)"
1244      GNUSTEP_SYSTEM_LIBRARIES="$(source /etc/GNUstep/GNUstep.conf; echo $GNUSTEP_SYSTEM_LIBRARIES)"
1245      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS}"
1246      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS}"
1247      REAL_CFLAGS="$REAL_CFLAGS -I${GNUSTEP_SYSTEM_HEADERS}"
1248      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES}"
1249   fi
1250   AC_CHECK_HEADER(AppKit/AppKit.h, HAVE_NS=yes)
1251   NS_HAVE_NSINTEGER=yes
1252   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <Foundation/NSObjCRuntime.h>],
1253                                      [NSInteger i;])],
1254                     ns_have_nsinteger=yes,
1255                     ns_have_nsinteger=no)
1256   if test $ns_have_nsinteger = no; then
1257     NS_HAVE_NSINTEGER=no
1258   fi
1259 fi
1260 if test "${HAVE_NS}" = yes; then
1261   window_system=nextstep
1262   with_xft=no
1263   with_freetype=no
1264   # set up packaging dirs
1265   exec_prefix=${ns_appbindir}
1266   libexecdir=${ns_appbindir}/libexec
1267   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1268      prefix=${ns_appresdir}
1269   fi
1270 fi
1271 CFLAGS="$tmp_CFLAGS"
1272 CPPFLAGS="$tmp_CPPFLAGS"
1273
1274 case "${window_system}" in
1275   x11 )
1276     HAVE_X_WINDOWS=yes
1277     HAVE_X11=yes
1278     case "${with_x_toolkit}" in
1279       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1280       motif ) USE_X_TOOLKIT=MOTIF ;;
1281       gtk ) with_gtk=yes
1282 dnl Dont set this for GTK.  A lot of tests below assumes Xt when
1283 dnl USE_X_TOOLKIT is set.
1284             USE_X_TOOLKIT=none ;;
1285       no ) USE_X_TOOLKIT=none ;;
1286 dnl If user did not say whether to use a toolkit, make this decision later:
1287 dnl use the toolkit if we have gtk, or X11R5 or newer.
1288       * ) USE_X_TOOLKIT=maybe ;;
1289     esac
1290   ;;
1291   nextstep | none )
1292     HAVE_X_WINDOWS=no
1293     HAVE_X11=no
1294     USE_X_TOOLKIT=none
1295   ;;
1296 esac
1297
1298 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1299    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1300    if test "$HAVE_XSERVER" = true ||
1301       test -n "$DISPLAY" ||
1302       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1303         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1304 were found.  You should install the relevant development files for X
1305 and for the toolkit you want, such as Gtk+, Lesstif or Motif.  Also make
1306 sure you have development files for image handling, i.e.
1307 tiff, gif, jpeg, png and xpm.
1308 If you are sure you want Emacs compiled without X window support, pass
1309   --without-x
1310 to configure.])
1311    fi
1312 fi
1313
1314 ### If we're using X11, we should use the X menu package.
1315 HAVE_MENUS=no
1316 case ${HAVE_X11} in
1317   yes ) HAVE_MENUS=yes ;;
1318 esac
1319
1320 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1321 # Assume not, until told otherwise.
1322 GNU_MALLOC=yes
1323 doug_lea_malloc=yes
1324 AC_CHECK_FUNC(malloc_get_state, ,doug_lea_malloc=no)
1325 AC_CHECK_FUNC(malloc_set_state, ,doug_lea_malloc=no)
1326 AC_CACHE_CHECK(whether __after_morecore_hook exists,
1327                emacs_cv_var___after_morecore_hook,
1328 [AC_TRY_LINK([extern void (* __after_morecore_hook)();],[__after_morecore_hook = 0],
1329   emacs_cv_var___after_morecore_hook=yes,
1330   emacs_cv_var___after_morecore_hook=no)])
1331 if test $emacs_cv_var___after_morecore_hook = no; then
1332   doug_lea_malloc=no
1333 fi
1334 if test "${system_malloc}" = "yes"; then
1335   GNU_MALLOC=no
1336   GNU_MALLOC_reason="
1337     (The GNU allocators don't work with this system configuration.)"
1338 fi
1339 if test "$doug_lea_malloc" = "yes" ; then
1340   if test "$GNU_MALLOC" = yes ; then
1341     GNU_MALLOC_reason="
1342       (Using Doug Lea's new malloc from the GNU C Library.)"
1343   fi
1344   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1345             [Define to 1 if you are using the GNU C Library.])
1346 fi
1347
1348 if test x"${REL_ALLOC}" = x; then
1349   REL_ALLOC=${GNU_MALLOC}
1350 fi
1351
1352 dnl For now, need to use an explicit `#define USE_MMAP_FOR_BUFFERS 1'
1353 dnl the system configuration file (s/*.h) to turn the use of mmap
1354 dnl in the relocating allocator on.
1355
1356 AC_FUNC_MMAP
1357 if test $use_mmap_for_buffers = yes; then
1358   REL_ALLOC=no
1359 fi
1360
1361 LIBS="$libsrc_libs $LIBS"
1362
1363 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1364 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1365 AC_CHECK_LIB(dnet, dnet_ntoa)
1366 dnl This causes -lresolv to get used in subsequent tests,
1367 dnl which causes failures on some systems such as HPUX 9.
1368 dnl AC_CHECK_LIB(resolv, gethostbyname)
1369
1370 dnl FIXME replace main with a function we actually want from this library.
1371 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1372
1373 AC_CHECK_LIB(pthreads, cma_open)
1374
1375 dnl Check for need for bigtoc support on IBM AIX
1376
1377 case ${host_os} in
1378 aix*)
1379   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1380     case $GCC in
1381     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1382     *) gdb_cv_bigtoc=-bbigtoc ;;
1383     esac
1384
1385     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1386     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1387   ])
1388   ;;
1389 esac
1390
1391 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1392 # used for the tests that follow.  We set them back to REAL_CFLAGS and
1393 # REAL_CPPFLAGS later on.
1394
1395 REAL_CPPFLAGS="$CPPFLAGS"
1396
1397 if test "${HAVE_X11}" = "yes"; then
1398   DEFS="$C_SWITCH_X_SITE $DEFS"
1399   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1400   LIBS="$LIBX $LIBS"
1401   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1402   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1403
1404   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1405   # This is handled by LD_SWITCH_X_SITE_AUX during the real build,
1406   # but it's more convenient here to set LD_RUN_PATH
1407   # since this also works on hosts that don't understand LD_SWITCH_X_SITE_AUX.
1408   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1409     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1410     export LD_RUN_PATH
1411   fi
1412
1413   if test "${opsys}" = "gnu-linux"; then
1414     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1415     AC_TRY_LINK([],
1416      [XOpenDisplay ("foo");],
1417      [xlinux_first_failure=no],
1418      [xlinux_first_failure=yes])
1419     if test "${xlinux_first_failure}" = "yes"; then
1420       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1421       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1422       OLD_CPPFLAGS="$CPPFLAGS"
1423       OLD_LIBS="$LIBS"
1424       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1425       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1426       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1427       LIBS="$LIBS -b i486-linuxaout"
1428       AC_TRY_LINK([],
1429        [XOpenDisplay ("foo");],
1430        [xlinux_second_failure=no],
1431        [xlinux_second_failure=yes])
1432       if test "${xlinux_second_failure}" = "yes"; then
1433         # If we get the same failure with -b, there is no use adding -b.
1434         # So take it out.  This plays safe.
1435         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1436         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1437         CPPFLAGS="$OLD_CPPFLAGS"
1438         LIBS="$OLD_LIBS"
1439         AC_MSG_RESULT(no)
1440       else
1441         AC_MSG_RESULT(yes)
1442       fi
1443     else
1444       AC_MSG_RESULT(no)
1445     fi
1446   fi
1447
1448   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1449   # header files included from there.
1450   AC_MSG_CHECKING(for Xkb)
1451   AC_TRY_LINK([#include <X11/Xlib.h>
1452 #include <X11/XKBlib.h>],
1453         [XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);],
1454         emacs_xkb=yes, emacs_xkb=no)
1455   AC_MSG_RESULT($emacs_xkb)
1456   if test $emacs_xkb = yes; then
1457     AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1458   fi
1459
1460   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1461 XScreenNumberOfScreen XSetWMProtocols)
1462 fi
1463
1464 if test "${window_system}" = "x11"; then
1465   AC_MSG_CHECKING(X11 version 6)
1466   AC_CACHE_VAL(emacs_cv_x11_version_6,
1467   [AC_TRY_LINK([#include <X11/Xlib.h>],
1468 [#if XlibSpecificationRelease < 6
1469 fail;
1470 #endif
1471 ], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1472   if test $emacs_cv_x11_version_6 = yes; then
1473     AC_MSG_RESULT(6 or newer)
1474     AC_DEFINE(HAVE_X11R6, 1,
1475               [Define to 1 if you have the X11R6 or newer version of Xlib.])
1476   else
1477     AC_MSG_RESULT(before 6)
1478   fi
1479 fi
1480
1481
1482 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
1483 HAVE_RSVG=no
1484 if test "${HAVE_X11}" = "yes"; then
1485   if test "${with_rsvg}" != "no"; then
1486     RSVG_REQUIRED=2.0.0
1487     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
1488
1489     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, :, :)
1490     AC_SUBST(RSVG_CFLAGS)
1491     AC_SUBST(RSVG_LIBS)
1492
1493     if test ".${RSVG_CFLAGS}" != "."; then
1494       HAVE_RSVG=yes
1495       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
1496       CFLAGS="$CFLAGS $RSVG_CFLAGS"
1497       LIBS="$RSVG_LIBS $LIBS"
1498     fi
1499   fi
1500 fi
1501
1502
1503 HAVE_GTK=no
1504 if test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
1505   GLIB_REQUIRED=2.6
1506   GTK_REQUIRED=2.6
1507   GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1508
1509   dnl Checks for libraries.
1510   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1511   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1512      AC_MSG_ERROR($GTK_PKG_ERRORS)
1513   fi
1514 fi
1515
1516
1517 if test x"$pkg_check_gtk" = xyes; then
1518
1519   AC_SUBST(GTK_CFLAGS)
1520   AC_SUBST(GTK_LIBS)
1521   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
1522   CFLAGS="$CFLAGS $GTK_CFLAGS"
1523   LIBS="$GTK_LIBS $LIBS"
1524   dnl Try to compile a simple GTK program.
1525   GTK_COMPILES=no
1526   AC_CHECK_FUNCS(gtk_main, GTK_COMPILES=yes)
1527   if test "${GTK_COMPILES}" != "yes"; then
1528     if test "$USE_X_TOOLKIT" != "maybe"; then
1529       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
1530     fi
1531   else
1532     HAVE_GTK=yes
1533     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
1534     USE_X_TOOLKIT=none
1535     if $PKG_CONFIG --atleast-version=2.10 gtk+-2.0; then
1536       :
1537     else
1538       AC_MSG_WARN([[Your version of Gtk+ will have problems with
1539        closing open displays.  This is no problem if you just use
1540        one display, but if you use more than one and close one of them
1541        Emacs may crash.]])
1542       sleep 3
1543     fi
1544   fi
1545
1546 fi
1547
1548
1549 if test "${HAVE_GTK}" = "yes"; then
1550
1551   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
1552   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
1553   if test "$with_toolkit_scroll_bars" != no; then
1554     with_toolkit_scroll_bars=yes
1555   fi
1556
1557   dnl  Check if we can use multiple displays with this GTK version.
1558   dnl  If gdk_display_open exists, assume all others are there also.
1559   HAVE_GTK_MULTIDISPLAY=no
1560   AC_CHECK_FUNCS(gdk_display_open, HAVE_GTK_MULTIDISPLAY=yes)
1561   if test "${HAVE_GTK_MULTIDISPLAY}" = "yes"; then
1562     AC_DEFINE(HAVE_GTK_MULTIDISPLAY, 1,
1563               [Define to 1 if GTK can handle more than one display.])
1564   fi
1565
1566   dnl  Check if we have the old file selection dialog.
1567   dnl  If gdk_display_open exists, assume all others are there also.
1568   HAVE_GTK_FILE_SELECTION=no
1569   AC_CHECK_FUNCS(gtk_file_selection_new, HAVE_GTK_FILE_SELECTION=yes)
1570
1571   dnl  Check if we have the new file chooser dialog
1572   dnl  If gdk_display_open exists, assume all others are there also.
1573   HAVE_GTK_FILE_CHOOSER=no
1574   AC_CHECK_FUNCS(gtk_file_chooser_dialog_new, HAVE_GTK_FILE_CHOOSER=yes)
1575
1576   if test "$HAVE_GTK_FILE_SELECTION" = yes \
1577      && test "$HAVE_GTK_FILE_CHOOSER" = yes;  then
1578     AC_DEFINE(HAVE_GTK_FILE_BOTH, 1,
1579               [Define to 1 if GTK has both file selection and chooser dialog.])
1580   fi
1581
1582   dnl Check if pthreads are available.  Emacs only needs this when using
1583   dnl gtk_file_chooser under Gnome.
1584   if test "$HAVE_GTK_FILE_CHOOSER" = yes; then
1585     HAVE_GTK_AND_PTHREAD=no
1586     AC_CHECK_HEADERS(pthread.h)
1587     if test "$ac_cv_header_pthread_h"; then
1588       AC_CHECK_LIB(pthread, pthread_self, HAVE_GTK_AND_PTHREAD=yes)
1589     fi
1590     if test "$HAVE_GTK_AND_PTHREAD" = yes; then
1591       case "${canonical}" in
1592         *-hpux*) ;;
1593         *) GTK_LIBS="$GTK_LIBS -lpthread" ;;
1594       esac
1595       AC_DEFINE(HAVE_GTK_AND_PTHREAD, 1,
1596                [Define to 1 if you have GTK and pthread (-lpthread).])
1597     fi
1598   fi
1599 fi
1600
1601 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
1602 dnl other platforms.  Support for higher D-Bus versions than 1.0 is
1603 dnl also not configured.
1604 HAVE_DBUS=no
1605 if test "${with_dbus}" = "yes"; then
1606    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
1607    if test "$HAVE_DBUS" = yes; then
1608       AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
1609    fi
1610 fi
1611
1612 dnl Do not put whitespace before the #include statements below.
1613 dnl Older compilers (eg sunos4 cc) choke on it.
1614 HAVE_XAW3D=no
1615 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
1616   if test "$with_xaw3d" != no; then
1617     AC_MSG_CHECKING(for xaw3d)
1618     AC_CACHE_VAL(emacs_cv_xaw3d,
1619     [AC_TRY_LINK([
1620 #include <X11/Intrinsic.h>
1621 #include <X11/Xaw3d/Simple.h>],
1622       [],
1623       emacs_cv_xaw3d=yes,
1624       emacs_cv_xaw3d=no)])
1625   else
1626     emacs_cv_xaw3d=no
1627   fi
1628   if test $emacs_cv_xaw3d = yes; then
1629     AC_MSG_RESULT([yes; using Lucid toolkit])
1630     USE_X_TOOLKIT=LUCID
1631     HAVE_XAW3D=yes
1632     AC_DEFINE(HAVE_XAW3D, 1,
1633               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
1634   else
1635     AC_MSG_RESULT(no)
1636     AC_MSG_CHECKING(for libXaw)
1637     AC_CACHE_VAL(emacs_cv_xaw,
1638     [AC_TRY_LINK([
1639 #include <X11/Intrinsic.h>
1640 #include <X11/Xaw/Simple.h>],
1641       [],
1642       emacs_cv_xaw=yes,
1643       emacs_cv_xaw=no)])
1644     if test $emacs_cv_xaw = yes; then
1645       AC_MSG_RESULT([yes; using Lucid toolkit])
1646       USE_X_TOOLKIT=LUCID
1647     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
1648       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
1649     else
1650       AC_MSG_RESULT([no; do not use toolkit by default])
1651       USE_X_TOOLKIT=none
1652     fi
1653   fi
1654 fi
1655
1656 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
1657
1658 if test "${USE_X_TOOLKIT}" != "none"; then
1659   AC_MSG_CHECKING(X11 toolkit version)
1660   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
1661   [AC_TRY_LINK([#include <X11/Intrinsic.h>],
1662 [#if XtSpecificationRelease < 6
1663 fail;
1664 #endif
1665 ], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
1666   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
1667   if test $emacs_cv_x11_toolkit_version_6 = yes; then
1668     AC_MSG_RESULT(6 or newer)
1669     AC_DEFINE(HAVE_X11XTR6, 1,
1670               [Define to 1 if you have the X11R6 or newer version of Xt.])
1671   else
1672     AC_MSG_RESULT(before 6)
1673   fi
1674
1675 dnl If using toolkit, check whether libXmu.a exists.
1676 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
1677   OLDLIBS="$LIBS"
1678   if test x$HAVE_X11XTR6 = xyes; then
1679     LIBS="-lXt -lSM -lICE $LIBS"
1680   else
1681     LIBS="-lXt $LIBS"
1682   fi
1683   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
1684   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
1685 fi
1686
1687 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
1688 if test "${HAVE_X11}" = "yes"; then
1689   if test "${USE_X_TOOLKIT}" != "none"; then
1690     AC_CHECK_LIB(Xext, XShapeQueryExtension)
1691   fi
1692 fi
1693
1694 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
1695   AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
1696   [AC_TRY_COMPILE([#include <Xm/Xm.h>],
1697     [#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
1698 int x = 5;
1699 #else
1700 Motif version prior to 2.1.
1701 #endif],
1702     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
1703   HAVE_MOTIF_2_1=$emacs_cv_motif_version_2_1
1704   if test $emacs_cv_motif_version_2_1 = yes; then
1705     HAVE_LIBXP=no
1706     AC_DEFINE(HAVE_MOTIF_2_1, 1,
1707               [Define to 1 if you have Motif 2.1 or newer.])
1708     AC_CHECK_LIB(Xp, XpCreateContext, HAVE_LIBXP=yes)
1709     if test ${HAVE_LIBXP} = yes; then
1710       AC_DEFINE(HAVE_LIBXP, 1,
1711                 [Define to 1 if you have the Xp library (-lXp).])
1712     fi
1713   else
1714     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
1715     # We put this in CFLAGS temporarily to precede other -I options
1716     # that might be in CFLAGS temporarily.
1717     # We put this in CPPFLAGS where it precedes the other -I options.
1718     OLD_CPPFLAGS=$CPPFLAGS
1719     OLD_CFLAGS=$CFLAGS
1720     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
1721     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
1722     [AC_TRY_COMPILE([#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>],
1723       [int x = 5;],
1724       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
1725     if test $emacs_cv_lesstif = yes; then
1726       # Make sure this -I option remains in CPPFLAGS after it is set
1727       # back to REAL_CPPFLAGS.
1728       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
1729       # have those other -I options anyway.  Ultimately, having this
1730       # directory ultimately in CPPFLAGS will be enough.
1731       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
1732       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
1733     else
1734       CFLAGS=$OLD_CFLAGS
1735       CPPFLAGS=$OLD_CPPFLAGS
1736     fi
1737   fi
1738 fi
1739
1740 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
1741 dnl using Motif or Xaw3d is available, and unless
1742 dnl --with-toolkit-scroll-bars=no was specified.
1743
1744 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
1745             [Define to 1 if we should use toolkit scroll bars.])dnl
1746 USE_TOOLKIT_SCROLL_BARS=no
1747 if test "${with_toolkit_scroll_bars}" != "no"; then
1748   if test "${USE_X_TOOLKIT}" != "none"; then
1749     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
1750       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1751       HAVE_XAW3D=no
1752       USE_TOOLKIT_SCROLL_BARS=yes
1753     elif test "${HAVE_XAW3D}" = "yes"; then
1754       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1755       USE_TOOLKIT_SCROLL_BARS=yes
1756     fi
1757   elif test "${HAVE_GTK}" = "yes"; then
1758     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1759     USE_TOOLKIT_SCROLL_BARS=yes
1760   elif test "${HAVE_NS}" = "yes"; then
1761     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1762     USE_TOOLKIT_SCROLL_BARS=yes
1763   fi
1764 fi
1765
1766 dnl See if XIM is available.
1767 AC_TRY_COMPILE([
1768           #include <X11/Xlib.h>
1769           #include <X11/Xresource.h>],
1770          [XIMProc  callback;],
1771          [HAVE_XIM=yes
1772          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
1773          HAVE_XIM=no)
1774
1775 dnl `--with-xim' now controls only the initial value of use_xim at run time.
1776
1777 if test "${with_xim}" != "no"; then
1778   AC_DEFINE(USE_XIM, 1,
1779             [Define to 1 if we should use XIM, if it is available.])
1780 fi
1781
1782
1783 if test "${HAVE_XIM}" != "no"; then
1784   late_CFLAGS=$CFLAGS
1785   if test "$GCC" = yes; then
1786     CFLAGS="$CFLAGS --pedantic-errors"
1787   fi
1788   AC_TRY_COMPILE([
1789 #include <X11/Xlib.h>
1790 #include <X11/Xresource.h>],
1791 [Display *display;
1792 XrmDatabase db;
1793 char *res_name;
1794 char *res_class;
1795 XIMProc  callback;
1796 XPointer *client_data;
1797 #ifndef __GNUC__
1798 /* If we're not using GCC, it's probably not XFree86, and this is
1799    probably right, but we can't use something like --pedantic-errors.  */
1800 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
1801                                            char*, XIMProc, XPointer*);
1802 #endif
1803 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
1804    client_data);],
1805     [emacs_cv_arg6_star=yes])
1806   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
1807          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
1808 either XPointer or XPointer*.])dnl
1809   if test "$emacs_cv_arg6_star" = yes; then
1810     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
1811   else
1812     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
1813   fi
1814   CFLAGS=$late_CFLAGS
1815 fi
1816
1817 ### Start of font-backend section.
1818
1819 ## Use -lXft if available, unless `--with-freetype=no' nor `--with-xft=no'.
1820 HAVE_XFT=maybe
1821 if test "x${with_freetype}" = "xno" || test "x${with_x}" = "xno"; then
1822   with_xft="no";
1823 fi
1824 if test "x${with_xft}" != "xno"; then
1825
1826   PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
1827   if test "$HAVE_XFT" != no; then
1828     OLD_CPPFLAGS="$CPPFLAGS"
1829     OLD_CFLAGS="$CFLAGS"
1830     OLD_LIBS="$LIBS"
1831     CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
1832     CFLAGS="$CFLAGS $XFT_CFLAGS"
1833     LIBS="$XFT_LIBS $LIBS"
1834     AC_CHECK_HEADER(X11/Xft/Xft.h,
1835       AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS))
1836
1837     if test "${HAVE_XFT}" = "yes"; then
1838       AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
1839         AC_SUBST(XFT_LIBS)
1840       C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
1841     else
1842       CPPFLAGS="$OLD_CPPFLAGS"
1843       CFLAGS="$OLD_CFLAGS"
1844       LIBS="$OLD_LIBS"
1845     fi                        # "${HAVE_XFT}" = "yes"
1846   fi                          # "$HAVE_XFT" != no
1847 fi                            # "x${with_xft}" != "xno"
1848
1849 dnl For the "Does Emacs use" message at the end.
1850 if test "$HAVE_XFT" != "yes"; then
1851    HAVE_XFT=no
1852 fi
1853
1854
1855 HAVE_FREETYPE=no
1856 ### Use -lfreetype if available, unless `--with-freetype=no'.
1857 if test "${HAVE_XFT}" = "yes"; then
1858   dnl As we use Xft, we anyway use freetype.
1859   dnl In this case, there's no need of additional CFLAGS and LIBS.
1860   HAVE_FREETYPE=yes
1861 elif test "x${with_freetype}" != "xno" && test "x${with_x}" != "xno"; then
1862
1863   PKG_CHECK_MODULES(FREETYPE, freetype2, HAVE_FREETYPE=yes, HAVE_FREETYPE=no)
1864   if test "${HAVE_FREETYPE}" = "yes"; then
1865     PKG_CHECK_MODULES(FONTCONFIG, fontconfig, HAVE_FC=yes, HAVE_FC=no)
1866     if test "${HAVE_FC}" = "no"; then
1867       dnl Without fontconfig, we can't use freetype at the moment.
1868       HAVE_FREETYPE=no
1869     fi
1870   fi
1871 fi
1872
1873 HAVE_LIBOTF=no
1874 if test "${HAVE_FREETYPE}" = "yes"; then
1875   AC_DEFINE(HAVE_FREETYPE, 1,
1876             [Define to 1 if using the freetype and fontconfig libraries.])
1877   if test "${with_libotf}" != "no"; then
1878     PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
1879                       HAVE_LIBOTF=no)
1880     if test "$HAVE_LIBOTF" = "yes"; then
1881       AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
1882     fi
1883   fi
1884 dnl FIXME should there be an error if HAVE_FREETYPE != yes?
1885 dnl Does the new font backend require it, or can it work without it?
1886 fi
1887
1888 HAVE_M17N_FLT=no
1889 if test "${HAVE_LIBOTF}" = yes; then
1890   if test "${with_m17n_flt}" != "no"; then
1891     PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no)
1892     if test "$HAVE_M17N_FLT" = "yes"; then
1893       AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
1894     fi
1895   fi
1896 fi
1897
1898 AC_SUBST(FREETYPE_CFLAGS)
1899 AC_SUBST(FREETYPE_LIBS)
1900 AC_SUBST(FONTCONFIG_CFLAGS)
1901 AC_SUBST(FONTCONFIG_LIBS)
1902 AC_SUBST(LIBOTF_CFLAGS)
1903 AC_SUBST(LIBOTF_LIBS)
1904 AC_SUBST(M17N_FLT_CFLAGS)
1905 AC_SUBST(M17N_FLT_LIBS)
1906
1907 ### End of font-backend section.
1908
1909 ### Use -lXpm if available, unless `--with-xpm=no'.
1910 HAVE_XPM=no
1911 if test "${HAVE_X11}" = "yes"; then
1912   if test "${with_xpm}" != "no"; then
1913     AC_CHECK_HEADER(X11/xpm.h,
1914       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
1915     if test "${HAVE_XPM}" = "yes"; then
1916       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
1917       AC_EGREP_CPP(no_return_alloc_pixels,
1918       [#include "X11/xpm.h"
1919 #ifndef XpmReturnAllocPixels
1920 no_return_alloc_pixels
1921 #endif
1922       ], HAVE_XPM=no, HAVE_XPM=yes)
1923
1924       if test "${HAVE_XPM}" = "yes"; then
1925         AC_MSG_RESULT(yes)
1926       else
1927         AC_MSG_RESULT(no)
1928       fi
1929     fi
1930   fi
1931
1932   if test "${HAVE_XPM}" = "yes"; then
1933     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm libary (-lXpm).])
1934   fi
1935 fi
1936
1937 ### Use -ljpeg if available, unless `--with-jpeg=no'.
1938 HAVE_JPEG=no
1939 if test "${HAVE_X11}" = "yes"; then
1940   if test "${with_jpeg}" != "no"; then
1941     dnl Checking for jpeglib.h can lose because of a redefinition of
1942     dnl  HAVE_STDLIB_H.
1943     AC_CHECK_HEADER(jerror.h,
1944       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
1945   fi
1946
1947   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
1948   if test "${HAVE_JPEG}" = "yes"; then
1949     AC_DEFINE(HAVE_JPEG)
1950     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
1951         [#include <jpeglib.h>
1952          version=JPEG_LIB_VERSION
1953 ],
1954         [AC_DEFINE(HAVE_JPEG)],
1955         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
1956         HAVE_JPEG=no])
1957   fi
1958 fi
1959
1960 ### Use -lpng if available, unless `--with-png=no'.
1961 HAVE_PNG=no
1962 if test "${HAVE_X11}" = "yes"; then
1963   if test "${with_png}" != "no"; then
1964     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
1965     # in /usr/include/libpng.
1966     AC_CHECK_HEADERS(png.h libpng/png.h)
1967     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
1968       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
1969     fi
1970   fi
1971
1972   if test "${HAVE_PNG}" = "yes"; then
1973     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
1974   fi
1975 fi
1976
1977 ### Use -ltiff if available, unless `--with-tiff=no'.
1978 HAVE_TIFF=no
1979 if test "${HAVE_X11}" = "yes"; then
1980   if test "${with_tiff}" != "no"; then
1981     AC_CHECK_HEADER(tiffio.h,
1982       [tifflibs="-lz -lm"
1983       # At least one tiff package requires the jpeg library.
1984       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
1985       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
1986   fi
1987
1988   if test "${HAVE_TIFF}" = "yes"; then
1989     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
1990   fi
1991 fi
1992
1993 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
1994 HAVE_GIF=no
1995 if test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no"; then
1996   AC_CHECK_HEADER(gif_lib.h,
1997 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
1998 # Earlier versions can crash Emacs.
1999     [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, try_libungif=yes)])
2000
2001   if test "$HAVE_GIF" = yes; then
2002       ac_gif_lib_name="-lgif"
2003   fi
2004
2005 # If gif_lib.h but no libgif, try libungif.
2006   if test x"$try_libungif" = xyes; then
2007     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes)
2008
2009     if test "$HAVE_GIF" = yes; then
2010       AC_DEFINE(LIBGIF, -lungif, [Compiler option to link with the gif library (if not -lgif).])
2011       ac_gif_lib_name="-lungif"
2012     fi
2013   fi
2014
2015   if test "${HAVE_GIF}" = "yes"; then
2016     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif library (default -lgif; otherwise specify with LIBGIF).])
2017   fi
2018 fi
2019
2020 dnl Check for required libraries.
2021 if test "${HAVE_X11}" = "yes"; then
2022   MISSING=""
2023   WITH_NO=""
2024   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
2025     MISSING="libXpm" && WITH_NO="--with-xpm=no"
2026   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
2027     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
2028   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
2029     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
2030   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
2031     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
2032   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
2033     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
2034
2035   if test "X${MISSING}" != X; then
2036     AC_MSG_ERROR([The following required libraries were not found:
2037     $MISSING
2038 Maybe some development libraries/packages are missing?
2039 If you don't want to link with them give
2040     $WITH_NO
2041 as options to configure])
2042   fi
2043 fi
2044
2045 ### Use -lgpm if available, unless `--with-gpm=no'.
2046 HAVE_GPM=no
2047 if test "${with_gpm}" != "no"; then
2048   AC_CHECK_HEADER(gpm.h,
2049     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
2050 fi
2051
2052 if test "${HAVE_GPM}" = "yes"; then
2053   AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
2054 fi
2055
2056 dnl Check for malloc/malloc.h on darwin
2057 AC_CHECK_HEADER(malloc/malloc.h, [AC_DEFINE(HAVE_MALLOC_MALLOC_H, 1, [Define to 1 if you have the <malloc/malloc.h> header file.])])
2058
2059 ### Use NeXTstep API to implement GUI.
2060 if test "${HAVE_NS}" = "yes"; then
2061   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
2062   if test "${NS_IMPL_COCOA}" = "yes"; then
2063     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
2064     GNU_OBJC_CFLAGS=
2065     LIB_SRC_EXTRA_INSTALLABLES=mac-fix-env
2066   fi
2067   if test "${EN_COCOA_EXPERIMENTAL_CTRL_G}" = "yes"; then
2068     AC_DEFINE(COCOA_EXPERIMENTAL_CTRL_G, 1, [Define to 1 if you are trying experimental enhanced Ctrl-g support using NS windowing under MacOS X.])
2069   fi
2070   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
2071     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
2072     GNU_OBJC_CFLAGS="-fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
2073   fi
2074   if test "${NS_HAVE_NSINTEGER}" = "yes"; then
2075     AC_DEFINE(NS_HAVE_NSINTEGER, 1, [Define to 1 if `NSInteger' is defined.])
2076   fi
2077   # We also have mouse menus.
2078   HAVE_MENUS=yes
2079 fi
2080
2081
2082 ### Use session management (-lSM -lICE) if available
2083 HAVE_X_SM=no
2084 if test "${HAVE_X11}" = "yes"; then
2085   AC_CHECK_HEADER(X11/SM/SMlib.h,
2086     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
2087
2088   if test "${HAVE_X_SM}" = "yes"; then
2089     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2090     case "$LIBS" in
2091       *-lSM*) ;;
2092       *)      LIBS="-lSM -lICE $LIBS" ;;
2093     esac
2094   fi
2095 fi
2096
2097 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2098 AC_CACHE_CHECK(whether netdb declares h_errno,
2099                emacs_cv_netdb_declares_h_errno,
2100 [AC_TRY_LINK([#include <netdb.h>],
2101   [return h_errno;],
2102   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2103 if test $emacs_cv_netdb_declares_h_errno = yes; then
2104   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2105 fi
2106
2107 AC_FUNC_ALLOCA
2108
2109 dnl src/alloca.c has been removed.  Could also check if $ALLOCA is set?
2110 dnl FIXME is there an autoconf test that does the right thing, without
2111 dnl needing to call A_M_E afterwards?
2112 if test x"$ac_cv_func_alloca_works" != xyes; then
2113    AC_MSG_ERROR( [a system implementation of alloca is required] )
2114 fi
2115
2116 # fmod, logb, and frexp are found in -lm on most systems.
2117 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2118 AC_CHECK_LIB(m, sqrt)
2119
2120 # Check for mail-locking functions in a "mail" library.  Probably this should
2121 # have the same check as for liblockfile below.
2122 AC_CHECK_LIB(mail, maillock)
2123 dnl Debian, at least:
2124 AC_CHECK_LIB(lockfile, maillock)
2125 # If we have the shared liblockfile, assume we must use it for mail
2126 # locking (e.g. Debian).  If we couldn't link against liblockfile
2127 # (no liblockfile.a installed), ensure that we don't need to.
2128 if test "$ac_cv_lib_lockfile_maillock" = no; then
2129   dnl This works for files generally, not just executables.
2130   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
2131   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2132                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2133   if test $ac_cv_prog_liblockfile = yes; then
2134     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2135 This probably means that movemail could lose mail.
2136 There may be a `development' package to install containing liblockfile.])
2137   else :
2138   fi
2139 fi
2140 AC_CHECK_FUNCS(touchlock)
2141 AC_CHECK_HEADERS(maillock.h)
2142
2143 AC_CHECK_FUNCS(gethostname getdomainname dup2 \
2144 rename closedir mkdir rmdir sysinfo getrusage get_current_dir_name \
2145 random lrand48 bcopy bcmp logb frexp fmod rint cbrt ftime setsid \
2146 strerror fpathconf select mktime euidaccess getpagesize tzset setlocale \
2147 utimes getrlimit setrlimit setpgid getcwd getwd shutdown getaddrinfo \
2148 __fpending mblen mbrlen mbsinit strsignal setitimer ualarm index rindex \
2149 sendto recvfrom getsockopt setsockopt getsockname getpeername \
2150 gai_strerror mkstemp getline getdelim mremap memmove fsync sync bzero \
2151 memset memcmp difftime memcpy mempcpy mblen mbrlen posix_memalign \
2152 cfmakeraw cfsetspeed)
2153
2154 AC_CHECK_HEADERS(sys/un.h)
2155
2156 AC_FUNC_MKTIME
2157 if test "$ac_cv_func_working_mktime" = no; then
2158   AC_DEFINE(BROKEN_MKTIME, 1, [Define to 1 if the mktime function is broken.])
2159 fi
2160
2161 AC_FUNC_GETLOADAVG
2162
2163 AC_FUNC_FSEEKO
2164
2165 # Configure getopt.
2166 m4_include([m4/getopt.m4])
2167 gl_GETOPT_IFELSE([
2168   gl_GETOPT_SUBSTITUTE_HEADER
2169   gl_PREREQ_GETOPT
2170   GETOPTOBJS='getopt.o getopt1.o'
2171 ])
2172 AC_SUBST(GETOPTOBJS)
2173
2174 AC_FUNC_GETPGRP
2175
2176 AC_FUNC_STRFTIME
2177
2178 # UNIX98 PTYs.
2179 AC_CHECK_FUNCS(grantpt)
2180
2181 # PTY-related GNU extensions.
2182 AC_CHECK_FUNCS(getpt)
2183
2184 # Check this now, so that we will NOT find the above functions in ncurses.
2185 # That is because we have not set up to link ncurses in lib-src.
2186 # It's better to believe a function is not available
2187 # than to expect to find it in ncurses.
2188 AC_CHECK_LIB(ncurses, tparm)
2189
2190 # Do we have res_init, for detecting changes in /etc/resolv.conf?
2191
2192 resolv=no
2193 AC_TRY_LINK([#include <netinet/in.h>
2194 #include <arpa/nameser.h>
2195 #include <resolv.h>],
2196     [return res_init();],
2197     have_res_init=yes, have_res_init=no)
2198 if test "$have_res_init" = no; then
2199   OLIBS="$LIBS"
2200   LIBS="$LIBS -lresolv"
2201   AC_MSG_CHECKING(for res_init with -lresolv)
2202   AC_TRY_LINK([#include <netinet/in.h>
2203 #include <arpa/nameser.h>
2204 #include <resolv.h>],
2205     [return res_init();],
2206     have_res_init=yes, have_res_init=no)
2207   AC_MSG_RESULT($have_res_init)
2208   if test "$have_res_init" = yes ; then
2209     resolv=yes
2210   fi
2211   LIBS="$OLIBS"
2212 fi
2213
2214 if test "$have_res_init" = yes; then
2215   AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
2216 fi
2217
2218 # Do we need the Hesiod library to provide the support routines?
2219 if test "$with_hesiod" != no ; then
2220   # Don't set $LIBS here -- see comments above.
2221   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
2222      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
2223                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
2224   if test "$resolv" = yes ; then
2225     RESOLVLIB=-lresolv
2226   else
2227     RESOLVLIB=
2228   fi
2229   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2230         [AC_DEFINE(HAVE_LIBHESIOD, 1,
2231                   [Define to 1 if you have the hesiod library (-lhesiod).])],
2232         :, $RESOLVLIB)])
2233 fi
2234
2235 # Do we need libresolv (due to res_init or Hesiod)?
2236 if test "$resolv" = yes ; then
2237   AC_DEFINE(HAVE_LIBRESOLV, 1,
2238             [Define to 1 if you have the resolv library (-lresolv).])
2239 fi
2240
2241 # These tell us which Kerberos-related libraries to use.
2242 if test "${with_kerberos}" != no; then
2243   AC_CHECK_LIB(com_err, com_err)
2244   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt)
2245   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt)
2246   AC_CHECK_LIB(krb5, krb5_init_context)
2247   if test "${with_kerberos5}" = no; then
2248     AC_CHECK_LIB(des425, des_cbc_encrypt,,
2249                  [AC_CHECK_LIB(des, des_cbc_encrypt)])
2250     AC_CHECK_LIB(krb4, krb_get_cred,,
2251                  [AC_CHECK_LIB(krb, krb_get_cred)])
2252   fi
2253
2254   if test "${with_kerberos5}" != no; then
2255     AC_CHECK_HEADERS(krb5.h,
2256       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
2257                         [#include <krb5.h>])])
2258   else
2259     AC_CHECK_HEADERS(des.h,,
2260                      [AC_CHECK_HEADERS(kerberosIV/des.h,,
2261                                        [AC_CHECK_HEADERS(kerberos/des.h)])])
2262     AC_CHECK_HEADERS(krb.h,,
2263                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
2264                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
2265   fi
2266   AC_CHECK_HEADERS(com_err.h)
2267 fi
2268
2269 # Solaris requires -lintl if you want strerror (which calls dgettext)
2270 # to return localized messages.
2271 AC_CHECK_LIB(intl, dgettext)
2272
2273 AC_MSG_CHECKING(whether localtime caches TZ)
2274 AC_CACHE_VAL(emacs_cv_localtime_cache,
2275 [if test x$ac_cv_func_tzset = xyes; then
2276 AC_TRY_RUN([#include <time.h>
2277 extern char **environ;
2278 unset_TZ ()
2279 {
2280   char **from, **to;
2281   for (to = from = environ; (*to = *from); from++)
2282     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
2283       to++;
2284 }
2285 char TZ_GMT0[] = "TZ=GMT0";
2286 char TZ_PST8[] = "TZ=PST8";
2287 main()
2288 {
2289   time_t now = time ((time_t *) 0);
2290   int hour_GMT0, hour_unset;
2291   if (putenv (TZ_GMT0) != 0)
2292     exit (1);
2293   hour_GMT0 = localtime (&now)->tm_hour;
2294   unset_TZ ();
2295   hour_unset = localtime (&now)->tm_hour;
2296   if (putenv (TZ_PST8) != 0)
2297     exit (1);
2298   if (localtime (&now)->tm_hour == hour_GMT0)
2299     exit (1);
2300   unset_TZ ();
2301   if (localtime (&now)->tm_hour != hour_unset)
2302     exit (1);
2303   exit (0);
2304 }], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
2305 [# If we have tzset, assume the worst when cross-compiling.
2306 emacs_cv_localtime_cache=yes])
2307 else
2308         # If we lack tzset, report that localtime does not cache TZ,
2309         # since we can't invalidate the cache if we don't have tzset.
2310         emacs_cv_localtime_cache=no
2311 fi])dnl
2312 AC_MSG_RESULT($emacs_cv_localtime_cache)
2313 if test $emacs_cv_localtime_cache = yes; then
2314   AC_DEFINE(LOCALTIME_CACHE, 1,
2315             [Define to 1 if localtime caches TZ.])
2316 fi
2317
2318 if test "x$HAVE_TIMEVAL" = xyes; then
2319   AC_CHECK_FUNCS(gettimeofday)
2320   if test $ac_cv_func_gettimeofday = yes; then
2321     AC_CACHE_CHECK(whether gettimeofday can accept two arguments,
2322                    emacs_cv_gettimeofday_two_arguments,
2323     [AC_TRY_COMPILE([
2324 #ifdef TIME_WITH_SYS_TIME
2325 #include <sys/time.h>
2326 #include <time.h>
2327 #else
2328 #ifdef HAVE_SYS_TIME_H
2329 #include <sys/time.h>
2330 #else
2331 #include <time.h>
2332 #endif
2333 #endif],
2334       [struct timeval time;
2335        gettimeofday (&time, 0);],
2336       emacs_cv_gettimeofday_two_arguments=yes,
2337       emacs_cv_gettimeofday_two_arguments=no)])
2338     if test $emacs_cv_gettimeofday_two_arguments = no; then
2339       AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT, 1,
2340                 [Define to 1 if gettimeofday accepts only one argument.])
2341     fi
2342   fi
2343 fi
2344
2345 ok_so_far=yes
2346 AC_CHECK_FUNC(socket, , ok_so_far=no)
2347 if test $ok_so_far = yes; then
2348   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
2349 fi
2350 if test $ok_so_far = yes; then
2351   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
2352 fi
2353 if test $ok_so_far = yes; then
2354 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
2355   AC_DEFINE(HAVE_INET_SOCKETS, 1,
2356             [Define to 1 if you have inet sockets.])
2357 fi
2358
2359 AC_CHECK_HEADERS(sys/ioctl.h)
2360
2361 if test -f /usr/lpp/X11/bin/smt.exp; then
2362   AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
2363             [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
2364 fi
2365
2366 AC_MSG_CHECKING(whether system supports dynamic ptys)
2367 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
2368   AC_MSG_RESULT(yes)
2369   AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
2370 else
2371   AC_MSG_RESULT(no)
2372 fi
2373
2374 AC_FUNC_FORK
2375
2376 dnl Adapted from Haible's version.
2377 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
2378   [AC_TRY_LINK([#include <langinfo.h>],
2379     [char* cs = nl_langinfo(CODESET);],
2380     emacs_cv_langinfo_codeset=yes,
2381     emacs_cv_langinfo_codeset=no)
2382   ])
2383 if test $emacs_cv_langinfo_codeset = yes; then
2384   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
2385     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
2386 fi
2387
2388 AC_CHECK_TYPES(size_t)
2389
2390 AC_TYPE_MBSTATE_T
2391
2392 dnl Restrict could probably be used effectively other than in regex.c.
2393 AC_CACHE_CHECK([for C restrict keyword], emacs_cv_c_restrict,
2394   [AC_TRY_COMPILE([void fred (int *restrict x);], [],
2395                   emacs_cv_c_restrict=yes,
2396                   [AC_TRY_COMPILE([void fred (int *__restrict x);], [],
2397                                   emacs_cv_c_restrict=__restrict,
2398                                   emacs_cv_c_restrict=no)])])
2399 case "$emacs_cv_c_restrict" in
2400   yes) emacs_restrict=restrict;;
2401   no) emacs_restrict="";;
2402   *) emacs_restrict="$emacs_cv_c_restrict";;
2403 esac
2404 if test "$emacs_restrict" != __restrict; then
2405   AC_DEFINE_UNQUOTED(__restrict, $emacs_restrict,
2406     [Define to compiler's equivalent of C99 restrict keyword.
2407      Don't define if equivalent is `__restrict'.])
2408 fi
2409
2410 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
2411   [AC_TRY_COMPILE([void fred (int x[__restrict]);], [],
2412                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
2413 if test "$emacs_cv_c_restrict_arr" = yes; then
2414   AC_DEFINE(__restrict_arr, __restrict,
2415     [Define to compiler's equivalent of C99 restrict keyword in array
2416      declarations.  Define as empty for no equivalent.])
2417 fi
2418
2419 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
2420 dnl how the tty code is related to POSIX and/or other versions of termios.
2421 dnl The following looks like a useful start.
2422 dnl
2423 dnl AC_SYS_POSIX_TERMIOS
2424 dnl if test $ac_cv_sys_posix_termios = yes; then
2425 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
2426 dnl                                and macros for terminal control.])
2427 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
2428 dnl fi
2429
2430 dnl Fixme: Use AC_FUNC_MEMCMP since memcmp is used.  (Needs libobj replacement.)
2431
2432 # Set up the CFLAGS for real compilation, so we can substitute it.
2433 CFLAGS="$REAL_CFLAGS"
2434 CPPFLAGS="$REAL_CPPFLAGS"
2435
2436 #### Find out which version of Emacs this is.
2437 [version=`grep 'defconst[        ]*emacs-version' ${srcdir}/lisp/version.el \
2438          | sed -e 's/^[^"]*"\([^"]*\)".*$/\1/'`]
2439 if test x"${version}" = x; then
2440   AC_MSG_ERROR([can't find current emacs version in `${srcdir}/lisp/version.el'.])
2441 fi
2442
2443 ### Specify what sort of things we'll be editing into Makefile and config.h.
2444 ### Use configuration here uncanonicalized to avoid exceeding size limits.
2445 AC_SUBST(version)
2446 AC_SUBST(configuration)
2447 AC_SUBST(canonical)
2448 AC_SUBST(srcdir)
2449 AC_SUBST(prefix)
2450 AC_SUBST(exec_prefix)
2451 AC_SUBST(bindir)
2452 AC_SUBST(datadir)
2453 AC_SUBST(sharedstatedir)
2454 AC_SUBST(libexecdir)
2455 AC_SUBST(mandir)
2456 AC_SUBST(infodir)
2457 AC_SUBST(lispdir)
2458 AC_SUBST(locallisppath)
2459 AC_SUBST(lisppath)
2460 AC_SUBST(x_default_search_path)
2461 AC_SUBST(etcdir)
2462 AC_SUBST(archlibdir)
2463 AC_SUBST(docdir)
2464 AC_SUBST(bitmapdir)
2465 AC_SUBST(gamedir)
2466 AC_SUBST(gameuser)
2467 AC_SUBST(c_switch_system)
2468 AC_SUBST(c_switch_machine)
2469 AC_SUBST(LD_SWITCH_X_SITE)
2470 AC_SUBST(LD_SWITCH_X_SITE_AUX)
2471 AC_SUBST(C_SWITCH_X_SITE)
2472 AC_SUBST(CFLAGS)
2473 AC_SUBST(X_TOOLKIT_TYPE)
2474 AC_SUBST(machfile)
2475 AC_SUBST(opsysfile)
2476 AC_SUBST(GETLOADAVG_LIBS)
2477 AC_SUBST(ns_appdir)
2478 AC_SUBST(ns_appbindir)
2479 AC_SUBST(ns_appresdir)
2480 AC_SUBST(ns_appsrc)
2481 AC_SUBST(GNUSTEP_MAKEFILES)
2482 AC_SUBST(GNUSTEP_SYSTEM_HEADERS)
2483 AC_SUBST(GNUSTEP_SYSTEM_LIBRARIES)
2484 AC_SUBST(GNU_OBJC_CFLAGS)
2485 AC_SUBST(LIB_SRC_EXTRA_INSTALLABLES)
2486
2487 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
2488                    [Define to the canonical Emacs configuration name.])
2489 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
2490                    [Define to the options passed to configure.])
2491 AC_DEFINE_UNQUOTED(config_machfile,  "${machfile}",
2492                    [Define to the used machine dependent file.])
2493 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}",
2494                    [Define to the used os dependent file.])
2495 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE, ${LD_SWITCH_X_SITE},
2496 [Define LD_SWITCH_X_SITE to contain any special flags your loader
2497  may need to deal with X Windows.  For instance, if you've defined
2498  HAVE_X_WINDOWS above and your X libraries aren't in a place that
2499  your loader can find on its own, you might want to add "-L/..." or
2500  something similar.])
2501 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE_AUX, ${LD_SWITCH_X_SITE_AUX},
2502                    [Define LD_SWITCH_X_SITE_AUX with an -R option
2503                     in case it's needed (for Solaris, for example).])
2504 AC_DEFINE_UNQUOTED(C_SWITCH_X_SITE,  ${C_SWITCH_X_SITE},
2505 [Define C_SWITCH_X_SITE to contain any special flags your compiler
2506  may need to deal with X Windows.  For instance, if you've defined
2507  HAVE_X_WINDOWS above and your X include files aren't in a place
2508  that your compiler can find on its own, you might want to add
2509  "-I/..." or something similar.])
2510 AC_DEFINE_UNQUOTED(UNEXEC_SRC,       ${UNEXEC_SRC},
2511                    [Define to the unexec source file name.])
2512
2513 if test "${HAVE_X_WINDOWS}" = "yes" ; then
2514   AC_DEFINE(HAVE_X_WINDOWS, 1,
2515             [Define to 1 if you want to use the X window system.])
2516 fi
2517 if test "${USE_X_TOOLKIT}" != "none" ; then
2518   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
2519   if test "${USE_X_TOOLKIT}" = "LUCID"; then
2520     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
2521   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
2522     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
2523   fi
2524 fi
2525 if test "${HAVE_X11}" = "yes" ; then
2526   AC_DEFINE(HAVE_X11, 1,
2527             [Define to 1 if you want to use version 11 of X windows.
2528              Otherwise, Emacs expects to use version 10.])
2529 fi
2530 if test "${HAVE_MENUS}" = "yes" ; then
2531   AC_DEFINE(HAVE_MENUS, 1,
2532             [Define to 1 if you have mouse menus.
2533              (This is automatic if you use X, but the option to specify it remains.)
2534              It is also defined with other window systems that support xmenu.c.])
2535 fi
2536 if test "${GNU_MALLOC}" = "yes" ; then
2537   AC_DEFINE(GNU_MALLOC, 1,
2538             [Define to 1 if you want to use the GNU memory allocator.])
2539 fi
2540 if test "${REL_ALLOC}" = "yes" ; then
2541   AC_DEFINE(REL_ALLOC, 1,
2542             [Define REL_ALLOC if you want to use the relocating allocator for
2543              buffer space.])
2544 fi
2545
2546
2547 AH_TOP([/* GNU Emacs site configuration template file.
2548    Copyright (C) 1988, 1993, 1994, 1999, 2000, 2001, 2002, 2004, 2005,
2549      2006, 2007, 2008  Free Software Foundation, Inc.
2550
2551 This file is part of GNU Emacs.
2552
2553 GNU Emacs is free software: you can redistribute it and/or modify
2554 it under the terms of the GNU General Public License as published by
2555 the Free Software Foundation, either version 3 of the License, or
2556 (at your option) any later version.
2557
2558 GNU Emacs is distributed in the hope that it will be useful,
2559 but WITHOUT ANY WARRANTY; without even the implied warranty of
2560 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
2561 GNU General Public License for more details.
2562
2563 You should have received a copy of the GNU General Public License
2564 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
2565
2566
2567 /* No code in Emacs #includes config.h twice, but some bits of code
2568    intended to work with other packages as well (like gmalloc.c)
2569    think they can include it as many times as they like.  */
2570 #ifndef EMACS_CONFIG_H
2571 #define EMACS_CONFIG_H
2572 ])dnl
2573
2574 AH_BOTTOM([
2575 /* If we're using X11/Carbon/GNUstep, define some consequences.  */
2576 #if defined(HAVE_X_WINDOWS) || defined(HAVE_NS)
2577 #define HAVE_WINDOW_SYSTEM
2578 #define HAVE_MOUSE
2579 #endif
2580
2581 /* Sadly for now, GNUstep dump does not work.  */
2582 #ifdef NS_IMPL_GNUSTEP
2583 #define CANNOT_DUMP
2584 #endif
2585
2586 /* Define AMPERSAND_FULL_NAME if you use the convention
2587    that & in the full name stands for the login id.  */
2588 /* Turned on June 1996 supposing nobody will mind it.  */
2589 #define AMPERSAND_FULL_NAME
2590
2591 /* Define HAVE_SOUND if we have sound support.  We know it works
2592    and compiles only on the specified platforms.   For others,
2593    it probably doesn't make sense to try.  */
2594
2595 #if defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
2596 #ifdef HAVE_MACHINE_SOUNDCARD_H
2597 #define HAVE_SOUND 1
2598 #endif
2599 #ifdef HAVE_SYS_SOUNDCARD_H
2600 #define HAVE_SOUND 1
2601 #endif
2602 #ifdef HAVE_SOUNDCARD_H
2603 #define HAVE_SOUND 1
2604 #endif
2605 #ifdef HAVE_ALSA
2606 #define HAVE_SOUND 1
2607 #endif
2608 #endif /* __FreeBSD__ || __NetBSD__ || __linux__  */
2609
2610 /* If using GNU, then support inline function declarations. */
2611 /* Don't try to switch on inline handling as detected by AC_C_INLINE
2612    generally, because even if non-gcc compilers accept `inline', they
2613    may reject `extern inline'.  */
2614 #if defined (__GNUC__) && defined (OPTIMIZE)
2615 #define INLINE __inline__
2616 #else
2617 #define INLINE
2618 #endif
2619
2620 /* `subprocesses' should be defined if you want to
2621    have code for asynchronous subprocesses
2622    (as used in M-x compile and M-x shell).
2623    Only MSDOS does not support this (it overrides
2624    this in its config_opsysfile below).  */
2625
2626 #define subprocesses
2627
2628 /* Include the os and machine dependent files.  */
2629 #include config_opsysfile
2630 #include config_machfile
2631
2632 /* Set up some defines, C and LD flags for NeXTstep interface on GNUstep.
2633   (There is probably a better place to do this, but right now the Cocoa
2634    side does this in s/darwin.h and we cannot
2635    parallel this exactly since GNUstep is multi-OS. */
2636 #ifdef HAVE_NS
2637 #define OTHER_FILES ns-app
2638 # ifdef NS_IMPL_GNUSTEP
2639 /* See also .m.o rule in Makefile.in */
2640 /* FIXME: are all these flags really needed?  Document here why.  */
2641 #  define C_SWITCH_X_SYSTEM -D_REENTRANT -fPIC -fno-strict-aliasing
2642 /* GNUstep needs a bit more pure memory.  Of the existing knobs,
2643 SYSTEM_PURESIZE_EXTRA seems like the least likely to cause problems.  */
2644 #  define SYSTEM_PURESIZE_EXTRA 30000
2645 # endif /* NS_IMPL_GNUSTEP */
2646 #endif /* HAVE_NS */
2647
2648 /* SIGTYPE is the macro we actually use.  */
2649 #ifndef SIGTYPE
2650 #define SIGTYPE RETSIGTYPE
2651 #endif
2652
2653 #ifdef emacs /* Don't do this for lib-src.  */
2654 /* Tell regex.c to use a type compatible with Emacs.  */
2655 #define RE_TRANSLATE_TYPE Lisp_Object
2656 #define RE_TRANSLATE(TBL, C) CHAR_TABLE_TRANSLATE (TBL, C)
2657 #ifdef make_number
2658 /* If make_number is a macro, use it.  */
2659 #define RE_TRANSLATE_P(TBL) (!EQ (TBL, make_number (0)))
2660 #else
2661 /* If make_number is a function, avoid it.  */
2662 #define RE_TRANSLATE_P(TBL) (!(INTEGERP (TBL) && XINT (TBL) == 0))
2663 #endif
2664 #endif
2665
2666 /* Avoid link-time collision with system mktime if we will use our own.  */
2667 #if ! HAVE_MKTIME || BROKEN_MKTIME
2668 #define mktime emacs_mktime
2669 #endif
2670
2671 #define my_strftime nstrftime   /* for strftime.c */
2672
2673 /* The rest of the code currently tests the CPP symbol BSTRING.
2674    Override any claims made by the system-description files.
2675    Note that on some SCO version it is possible to have bcopy and not bcmp.  */
2676 #undef BSTRING
2677 #if defined (HAVE_BCOPY) && defined (HAVE_BCMP)
2678 #define BSTRING
2679 #endif
2680
2681 /* Some of the files of Emacs which are intended for use with other
2682    programs assume that if you have a config.h file, you must declare
2683    the type of getenv.
2684
2685    This declaration shouldn't appear when alloca.s or Makefile.in
2686    includes config.h.  */
2687 #ifndef NOT_C_CODE
2688 extern char *getenv ();
2689 #endif
2690
2691 /* These default definitions are good for almost all machines.
2692    The exceptions override them in m/MACHINE.h.  */
2693
2694 #ifndef BITS_PER_CHAR
2695 #define BITS_PER_CHAR 8
2696 #endif
2697
2698 #ifndef BITS_PER_SHORT
2699 #define BITS_PER_SHORT 16
2700 #endif
2701
2702 /* Note that lisp.h uses this in a preprocessor conditional, so it
2703    would not work to use sizeof.  That being so, we do all of them
2704    without sizeof, for uniformity's sake.  */
2705 #ifndef BITS_PER_INT
2706 #define BITS_PER_INT 32
2707 #endif
2708
2709 #ifndef BITS_PER_LONG
2710 #ifdef _LP64
2711 #define BITS_PER_LONG 64
2712 #else
2713 #define BITS_PER_LONG 32
2714 #endif
2715 #endif
2716
2717 /* Define if the compiler supports function prototypes.  It may do so
2718    but not define __STDC__ (e.g. DEC C by default) or may define it as
2719    zero.  */
2720 #undef PROTOTYPES
2721 /* For mktime.c:  */
2722 #ifndef __P
2723 # if defined PROTOTYPES
2724 #  define __P(args) args
2725 # else
2726 #  define __P(args) ()
2727 # endif  /* GCC.  */
2728 #endif /* __P */
2729
2730 /* Don't include "string.h" or <stdlib.h> in non-C code.  */
2731 #ifndef NOT_C_CODE
2732 #ifdef HAVE_STRING_H
2733 #include "string.h"
2734 #endif
2735 #ifdef HAVE_STRINGS_H
2736 #include "strings.h"  /* May be needed for bcopy & al. */
2737 #endif
2738 #ifdef HAVE_STDLIB_H
2739 #include <stdlib.h>
2740 #endif
2741 #ifndef __GNUC__
2742 # ifdef HAVE_ALLOCA_H
2743 #  include <alloca.h>
2744 # else /* AIX files deal with #pragma.  */
2745 #  ifndef alloca /* predefined by HP cc +Olibcalls */
2746 char *alloca ();
2747 #  endif
2748 # endif /* HAVE_ALLOCA_H */
2749 #endif /* __GNUC__ */
2750 #ifndef HAVE_SIZE_T
2751 typedef unsigned size_t;
2752 #endif
2753 #endif /* NOT_C_CODE */
2754
2755 /* Define HAVE_X_I18N if we have usable i18n support.  */
2756
2757 #ifdef HAVE_X11R6
2758 #define HAVE_X_I18N
2759 #elif !defined X11R5_INHIBIT_I18N
2760 #define HAVE_X_I18N
2761 #endif
2762
2763 /* Define HAVE_X11R6_XIM if we have usable X11R6-style XIM support.  */
2764
2765 #if defined HAVE_X11R6 && !defined INHIBIT_X11R6_XIM
2766 #define HAVE_X11R6_XIM
2767 #endif
2768
2769 /* Should we enable expensive run-time checking of data types?  */
2770 #undef ENABLE_CHECKING
2771
2772 #if defined __GNUC__ && (__GNUC__ > 2 \
2773                          || (__GNUC__ == 2 && __GNUC_MINOR__ >= 5))
2774 #define NO_RETURN       __attribute__ ((__noreturn__))
2775 #else
2776 #define NO_RETURN       /* nothing */
2777 #endif
2778
2779 /* These won't be used automatically yet.  We also need to know, at least,
2780    that the stack is continuous.  */
2781 #ifdef __GNUC__
2782 #  ifndef GC_SETJMP_WORKS
2783   /* GC_SETJMP_WORKS is nearly always appropriate for GCC --
2784      see NON_SAVING_SETJMP in the target descriptions.  */
2785   /* Exceptions (see NON_SAVING_SETJMP in target description) are
2786      SCO5 non-ELF (but Emacs specifies ELF) and SVR3 on x86.
2787      Fixme: Deal with SVR3.  */
2788 #    define GC_SETJMP_WORKS 1
2789 #  endif
2790 #  ifndef GC_LISP_OBJECT_ALIGNMENT
2791 #    define GC_LISP_OBJECT_ALIGNMENT (__alignof__ (Lisp_Object))
2792 #  endif
2793 #endif
2794
2795 #ifndef HAVE_BCOPY
2796 #define bcopy(a,b,s) memcpy (b,a,s)
2797 #endif
2798 #ifndef HAVE_BZERO
2799 #define bzero(a,s) memset (a,0,s)
2800 #endif
2801 #ifndef HAVE_BCMP
2802 #define BCMP memcmp
2803 #endif
2804
2805 #endif /* EMACS_CONFIG_H */
2806
2807 /*
2808 Local Variables:
2809 mode: c
2810 End:
2811 */
2812 ])dnl
2813
2814 #### Report on what we decided to do.
2815 #### Report GTK as a toolkit, even if it doesn't use Xt.
2816 #### It makes printing result more understandable as using GTK sets
2817 #### toolkit_scroll_bars to yes by default.
2818 if test "${HAVE_GTK}" = "yes"; then
2819   USE_X_TOOLKIT=GTK
2820 fi
2821
2822 echo "
2823 Configured for \`${canonical}'.
2824
2825   Where should the build process find the source code?    ${srcdir}
2826   What operating system and machine description files should Emacs use?
2827         \`${opsysfile}' and \`${machfile}'
2828   What compiler should emacs be built with?               ${CC} ${CFLAGS}
2829   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
2830   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
2831   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
2832   What window system should Emacs use?                    ${window_system}
2833   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
2834
2835 if test -n "${x_includes}"; then
2836 echo "  Where do we find X Windows header files?                ${x_includes}"
2837 else
2838 echo "  Where do we find X Windows header files?                Standard dirs"
2839 fi
2840 if test -n "${x_libraries}"; then
2841 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
2842 else
2843 echo "  Where do we find X Windows libraries?                   Standard dirs"
2844 fi
2845
2846 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
2847 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
2848 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
2849 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
2850 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $ac_gif_lib_name"
2851 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
2852 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
2853 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
2854 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
2855
2856 echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
2857 echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
2858 echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
2859 echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
2860
2861 echo "  Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}"
2862 echo
2863
2864 if test $USE_XASSERTS = yes; then
2865    echo "  Compiling with asserts turned on."
2866    CPPFLAGS="$CPPFLAGS -DXASSERTS=1"
2867 fi
2868
2869 echo
2870
2871 if test "$USE_X_TOOLKIT" = GTK; then
2872   case "$canonical" in
2873   *cygwin*)
2874     echo "There are known problems with Emacs and Gtk+ on cygwin, so you
2875   will probably get a crash on startup.  If this happens, please use another
2876   toolkit for Emacs.  See etc/PROBLEMS for more information."
2877   ;;
2878   esac
2879 fi
2880
2881 if test "$HAVE_NS" = "yes"; then
2882    echo
2883    echo "You must run \"make install\" in order to test the built application.
2884 The installed application will go to nextstep/Emacs.app and can be
2885 run or moved from there."
2886    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
2887       echo "The application will be fully self-contained."
2888     else
2889       echo "The lisp resources for the application will be installed under ${prefix}.
2890 You may need to run \"make install\" with sudo.  The application will fail
2891 to run if these resources are not installed."
2892    fi
2893    echo
2894 fi
2895
2896 if test "$HAVE_DBUS" = yes && test "${opsys}" != "gnu-linux"; then
2897   echo "D-Bus integration has been tested for GNU/Linux only."
2898   echo
2899 fi
2900
2901
2902 # Remove any trailing slashes in these variables.
2903 [test "${prefix}" != NONE &&
2904   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
2905 test "${exec_prefix}" != NONE &&
2906   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
2907
2908 # Now get this: Some word that is part of the ${srcdir} directory name
2909 # or the ${configuration} value might, just might, happen to be an
2910 # identifier like `sun4' or `i386' or something, and be predefined by
2911 # the C preprocessor to some helpful value like 1, or maybe the empty
2912 # string.  Needless to say consequent macro substitutions are less
2913 # than conducive to the makefile finding the correct directory.
2914 [cpp_undefs="`echo $srcdir $configuration $canonical |
2915   sed -e 's/[^a-zA-Z0-9_]/ /g' -e 's/^/ /' -e 's/  *$//' \
2916   -e 's/  */ -U/g' -e 's/-U[0-9][^ ]*//g'`"]
2917
2918 ## Check if the C preprocessor will convert `..' to `. .'.  If so, set
2919 ## CPP_NEED_TRADITIONAL to `yes' so that the code to generate Makefile
2920 ## from Makefile.c can correctly provide the arg `-traditional' to the
2921 ## C preprocessor.
2922
2923 AC_EGREP_CPP(yes..yes,
2924         [yes..yes],
2925         CPP_NEED_TRADITIONAL=no,
2926         CPP_NEED_TRADITIONAL=yes)
2927
2928 AC_OUTPUT(Makefile lib-src/Makefile.c:lib-src/Makefile.in oldXMenu/Makefile \
2929         doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
2930         doc/lispref/Makefile src/Makefile.c:src/Makefile.in \
2931         lwlib/Makefile lisp/Makefile leim/Makefile, [
2932
2933 ### Make the necessary directories, if they don't exist.
2934 for dir in etc lisp ; do
2935   test -d ${dir} || mkdir ${dir}
2936 done
2937
2938 # Build src/Makefile from ${srcdir}/src/Makefile.c
2939 # and lib-src/Makefile from ${srcdir}/lib-src/Makefile.c
2940 # This must be done after src/config.h is built, since we rely on that file.
2941
2942 echo creating src/epaths.h
2943 ${MAKE-make} epaths-force
2944
2945 # As of 2000-11-19, newest development versions of GNU cpp preprocess
2946 # `..' to `. .'  unless invoked with -traditional
2947
2948 if test "x$GCC" = xyes && test "x$CPP_NEED_TRADITIONAL" = xyes; then
2949   CPPFLAGS="$CPPFLAGS -traditional"
2950 fi
2951
2952 echo creating lib-src/Makefile
2953 ( cd lib-src
2954   rm -f junk.c junk1.c junk2.c
2955   sed -e '/start of cpp stuff/q' \
2956       < Makefile.c > junk1.c
2957   sed -e '1,/start of cpp stuff/d'\
2958       -e 's,/\*\*/#\(.*\)$,/* \1 */,' \
2959       < Makefile.c > junk.c
2960   $CPP $cpp_undefs -I. -I$srcdir/src $CPPFLAGS junk.c | \
2961       sed -e 's/^ /     /' -e '/^#/d' -e '/^[   \f]*$/d' > junk2.c
2962   cat junk1.c junk2.c > Makefile.new
2963   rm -f junk.c junk1.c junk2.c
2964   chmod 444 Makefile.new
2965   mv -f Makefile.new Makefile
2966 )
2967
2968 echo creating src/Makefile
2969 ( cd src
2970   rm -f junk.c junk1.c junk2.c
2971   sed -e '/start of cpp stuff/q' \
2972       < Makefile.c > junk1.c
2973   sed -e '1,/start of cpp stuff/d'\
2974       -e 's,/\*\*/#\(.*\)$,/* \1 */,' \
2975       < Makefile.c > junk.c
2976   $CPP $cpp_undefs -I. -I$srcdir/src $CPPFLAGS junk.c | \
2977       sed -e 's/^ /     /' -e '/^#/d' -e '/^[   \f]*$/d' > junk2.c
2978   cat junk1.c junk2.c > Makefile.new
2979   rm -f junk.c junk1.c junk2.c
2980   chmod 444 Makefile.new
2981   mv -f Makefile.new Makefile
2982 )
2983
2984 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
2985   echo creating src/.gdbinit
2986   echo source $srcdir/src/.gdbinit > src/.gdbinit
2987 fi
2988
2989 ], [GCC="$GCC" NON_GNU_CPP="$NON_GNU_CPP" CPP="$CPP" CPP_NEED_TRADITIONAL="$CPP_NEED_TRADITIONAL" CPPFLAGS="$CPPFLAGS" cpp_undefs="$cpp_undefs"])
2990
2991 m4_if(dnl       Do not change this comment
2992    arch-tag: 156a4dd5-bddc-4d18-96ac-f37742cf6a5e
2993 )dnl