code.delx.au - gnu-emacs/blob - configure.ac

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the 'configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl If you changed any AC_DEFINES, also run autoheader.
   6 dnl
   7 dnl Copyright (C) 1994-1996, 1999-2016 Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation, either version 3 of the License, or
  14 dnl  (at your option) any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 AC_PREREQ(2.65)
  25 dnl Note this is parsed by (at least) make-dist and lisp/cedet/ede/emacs.el.
  26 AC_INIT(GNU Emacs, 25.1.50, bug-gnu-emacs@gnu.org)
  27
  28 dnl Set emacs_config_options to the options of 'configure', quoted for the shell,
  29 dnl and then quoted again for a C string.  Separate options with spaces.
  30 dnl Add some environment variables, if they were passed via the environment
  31 dnl rather than on the command-line.
  32 emacs_config_options=
  33 optsep=
  34 dnl This is the documented way to record the args passed to configure,
  35 dnl rather than $ac_configure_args.
  36 for opt in "$@" CFLAGS CPPFLAGS LDFLAGS; do
  37   case $opt in
  38     -n | --no-create | --no-recursion)
  39       continue ;;
  40     CFLAGS | CPPFLAGS | LDFLAGS)
  41       eval 'test "${'$opt'+set}" = set' || continue
  42       case " $*" in
  43         *" $opt="*) continue ;;
  44       esac
  45       eval opt=$opt=\$$opt ;;
  46   esac
  47
  48   emacs_shell_specials=$IFS\''"#$&()*;<>?@<:@\\`{|~'
  49   case $opt in
  50     *[["$emacs_shell_specials"]]*)
  51       case $opt in
  52         *\'*)
  53           emacs_quote_apostrophes="s/'/'\\\\''/g"
  54           opt=`AS_ECHO(["$opt"]) | sed "$emacs_quote_apostrophes"` ;;
  55       esac
  56       opt="'$opt'"
  57       case $opt in
  58         *[['"\\']]*)
  59           emacs_quote_for_c='s/[["\\]]/\\&/g; $!s/$/\\n\\/'
  60           opt=`AS_ECHO(["$opt"]) | sed "$emacs_quote_for_c"` ;;
  61       esac ;;
  62   esac
  63   AS_VAR_APPEND([emacs_config_options], ["$optsep$opt"])
  64   optsep=' '
  65 done
  66
  67 AC_CONFIG_HEADERS(src/config.h:src/config.in)
  68 AC_CONFIG_SRCDIR(src/lisp.h)
  69 AC_CONFIG_AUX_DIR(build-aux)
  70 dnl automake 1.13 and later understand this, making -I m4 unnecessary.
  71 dnl With older versions this is a no-op.
  72 AC_CONFIG_MACRO_DIR(m4)
  73
  74 xcsdkdir=
  75 AC_CHECK_PROGS(XCRUN, [xcrun])
  76 if test -n "$XCRUN"; then
  77   if test -z "$MAKE"; then
  78     dnl Call the variable MAKE_PROG, not MAKE, to avoid confusion with
  79     dnl the usual MAKE variable that 'make' itself uses.
  80     AC_CHECK_PROG([MAKE_PROG], [make], [yes])
  81     if test -z "$MAKE_PROG"; then
  82       MAKE="$XCRUN MAKE"
  83       export MAKE
  84       xcsdkdir=`$XCRUN --show-sdk-path 2>/dev/null`
  85     fi
  86   fi
  87 fi
  88
  89 dnl GNU Make is required, so don't test for its individual features.
  90 am_cv_make_support_nested_variables=yes
  91 AC_DEFUN([AC_PROG_MAKE_SET],
  92   [SET_MAKE=
  93    AC_SUBST([SET_MAKE])])
  94
  95 dnl Check for GNU Make and possibly set MAKE before running AM_INIT_AUTOMAKE.
  96 [emacs_check_gnu_make ()
  97 {
  98   emacs_makeout=`($1 --version) 2>/dev/null` &&
  99   case $emacs_makeout in
 100     'GNU Make '3.8[1-9]* | 'GNU Make '3.9[0-9]* | \
 101     'GNU Make '3.[1-9][0-9][0-9]* | 'GNU Make '[4-9]* | 'GNU Make '[1-9][0-9]* )
 102        ac_path_MAKE_found=:;;
 103   esac
 104 }]
 105 AC_CACHE_CHECK([for GNU Make], [ac_cv_path_MAKE],
 106   [ac_path_MAKE_found=false
 107    if test -n "$MAKE"; then
 108      emacs_check_gnu_make "$MAKE"
 109      ac_cv_path_MAKE=$MAKE
 110    else
 111      emacs_tried_make=false
 112      emacs_tried_gmake=false
 113      emacs_tried_gnumake=false
 114      AC_PATH_PROGS_FEATURE_CHECK([MAKE], [make gmake gnumake],
 115        [[emacs_check_gnu_make "$ac_path_MAKE"
 116          if $ac_path_MAKE_found; then
 117            # Use the fully-qualified program name only if the basename
 118            # would not resolve to it.
 119            if eval \$emacs_tried_$ac_prog; then
 120              ac_cv_path_MAKE=$ac_path_MAKE
 121            else
 122              ac_cv_path_MAKE=$ac_prog
 123            fi
 124          fi
 125          eval emacs_tried_$ac_prog=:]])
 126    fi])
 127 $ac_path_MAKE_found || {
 128 AC_MSG_ERROR([[Building Emacs requires GNU Make, at least version 3.81.
 129 If you have it installed under another name, configure with 'MAKE=...'.
 130 For example, run '$0 MAKE=gnu-make'.]])
 131 }
 132 MAKE=$ac_cv_path_MAKE
 133 export MAKE
 134
 135 dnl Fairly arbitrary, older versions might work too.
 136 AM_INIT_AUTOMAKE(1.11)
 137
 138 dnl Canonicalize the configuration name.
 139 AC_CANONICAL_HOST
 140
 141 case $host in
 142  *-mingw*)
 143
 144   if test -z "$host_alias"; then
 145
 146       # No --host argument was given to 'configure'; therefore $host
 147       # was set to a default value based on the build platform.  But
 148       # this default value may be wrong if we are building from a
 149       # 64-bit MSYS[2] pre-configured to build 32-bit MinGW programs.
 150       # Therefore, we'll try to get the right host platform from the
 151       # compiler's target.
 152
 153       AC_MSG_CHECKING([the compiler's target])
 154       if test -z "$CC"; then
 155           cc=gcc
 156       else
 157           cc=$CC
 158       fi
 159       cc_target=`$cc -v 2>&1 | sed -n 's/Target: //p'`
 160       case "$cc_target" in
 161           *-*) host=$cc_target
 162               ;;
 163           "") AC_MSG_ERROR([Impossible to obtain $cc compiler target.
 164 Please explicitly provide --host.])
 165               ;;
 166           *) AC_MSG_WARN([Compiler reported non-standard target.
 167 Defaulting to $host.])
 168               ;;
 169       esac
 170       AC_MSG_RESULT([$host])
 171   fi
 172
 173   . $srcdir/nt/mingw-cfg.site
 174
 175   case $srcdir in
 176     /* | ?:*)
 177       # srcdir is an absolute path.  In this case, force the format
 178       # "/c/foo/bar", to simplify later conversions to native Windows
 179       # format ("c:/foo/bar").
 180       srcdir=`cd "${srcdir}" && pwd -W`
 181       # 'eval' pacifies strict POSIX non-MinGW shells (Bug#18612).
 182       eval 'srcdir="/${srcdir:0:1}${srcdir:2}"'
 183       ;;
 184   esac;;
 185 esac
 186
 187 canonical=$host
 188 configuration=${host_alias-${build_alias-$host}}
 189
 190 dnl Support for --program-prefix, --program-suffix and
 191 dnl --program-transform-name options
 192 AC_ARG_PROGRAM
 193
 194 dnl It is important that variables on the RHS not be expanded here,
 195 dnl hence the single quotes.  This is per the GNU coding standards, see
 196 dnl (autoconf) Installation Directory Variables
 197 dnl See also epaths.h below.
 198 lispdir='${datadir}/emacs/${version}/lisp'
 199 standardlisppath='${lispdir}'
 200 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
 201 '${datadir}/emacs/site-lisp'
 202 lisppath='${locallisppath}:${standardlisppath}'
 203 etcdir='${datadir}/emacs/${version}/etc'
 204 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
 205 etcdocdir='${datadir}/emacs/${version}/etc'
 206 gamedir='${localstatedir}/games/emacs'
 207
 208 dnl Special option to disable the most of other options.
 209 AC_ARG_WITH(all,
 210 [AS_HELP_STRING([--without-all],
 211                 [omit almost all features and build
 212                 small executable with minimal dependencies])],
 213   [with_features=$withval],
 214   [with_features=yes])
 215
 216 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
 217 dnl Create a new --with option that defaults to being disabled.
 218 dnl NAME is the base name of the option.  The shell variable with_NAME
 219 dnl   will be set to either the user's value (if the option is
 220 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
 221 dnl   option is not specified).  Note that the shell variable name is
 222 dnl   constructed as autoconf does, by replacing non-alphanumeric
 223 dnl   characters with "_".
 224 dnl HELP-STRING is the help text for the option.
 225 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
 226   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
 227     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
 228 ])dnl
 229
 230 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
 231 dnl Create a new --with option that defaults to $with_features.
 232 dnl NAME is the base name of the option.  The shell variable with_NAME
 233 dnl   will be set either to 'no' (for a plain --without-NAME) or to
 234 dnl   'yes' (if the option is not specified).  Note that the shell
 235 dnl   variable name is constructed as autoconf does, by replacing
 236 dnl   non-alphanumeric characters with "_".
 237 dnl HELP-STRING is the help text for the option.
 238 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
 239   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
 240    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=$with_features])dnl
 241 ])dnl
 242
 243 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
 244 if test "$with_pop" = yes; then
 245    AC_DEFINE(MAIL_USE_POP)
 246 fi
 247 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
 248
 249 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
 250 if test "$with_kerberos" != no; then
 251    AC_DEFINE(KERBEROS)
 252 fi
 253 AH_TEMPLATE(KERBEROS,
 254             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
 255
 256 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
 257 if test "${with_kerberos5}" != no; then
 258   if test "${with_kerberos}" = no; then
 259     with_kerberos=yes
 260     AC_DEFINE(KERBEROS)
 261   fi
 262   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
 263 fi
 264
 265 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
 266 dnl FIXME hesiod support may not be present, so it seems like an error
 267 dnl to define, or at least use, this unconditionally.
 268 if test "$with_hesiod" != no; then
 269   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
 270 fi
 271
 272 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
 273 if test "$with_mail_unlink" != no; then
 274    AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
 275 fi
 276
 277 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
 278     [string giving default POP mail host])],
 279     AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
 280
 281 AC_ARG_WITH([sound],[AS_HELP_STRING([--with-sound=VALUE],
 282   [compile with sound support (VALUE one of: yes, alsa, oss, bsd-ossaudio, no;
 283 default yes).  Only for GNU/Linux, FreeBSD, NetBSD, MinGW, Cygwin.])],
 284   [ case "${withval}" in
 285       yes|no|alsa|oss|bsd-ossaudio) val=$withval ;;
 286       *) AC_MSG_ERROR(['--with-sound=$withval' is invalid;
 287 this option's value should be 'yes', 'no', 'alsa', 'oss', or 'bsd-ossaudio'.])
 288       ;;
 289     esac
 290     with_sound=$val
 291   ],
 292   [with_sound=$with_features])
 293
 294 dnl FIXME currently it is not the last.
 295 dnl This should be the last --with option, because --with-x is
 296 dnl added later on when we find the file name of X, and it's best to
 297 dnl keep them together visually.
 298 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 299  [use an X toolkit (KIT one of: yes or gtk, gtk2, gtk3, lucid or athena, motif, no)])],
 300 [         case "${withval}" in
 301             y | ye | yes )      val=gtk ;;
 302             n | no )            val=no  ;;
 303             l | lu | luc | luci | lucid )       val=lucid ;;
 304             a | at | ath | athe | athen | athena )      val=athena ;;
 305             m | mo | mot | moti | motif )       val=motif ;;
 306             g | gt | gtk  )     val=gtk ;;
 307             gtk2  )     val=gtk2 ;;
 308             gtk3  )     val=gtk3 ;;
 309             * )
 310 AC_MSG_ERROR(['--with-x-toolkit=$withval' is invalid;
 311 this option's value should be 'yes', 'no', 'lucid', 'athena', 'motif', 'gtk',
 312 'gtk2' or 'gtk3'.  'yes' and 'gtk' are synonyms.
 313 'athena' and 'lucid' are synonyms.])
 314             ;;
 315           esac
 316           with_x_toolkit=$val
 317 ])
 318
 319 OPTION_DEFAULT_OFF([wide-int], [prefer wide Emacs integers (typically 62-bit); allows buffer and string size up to 2GB on 32-bit hosts, at the cost of 10% to 30% slowdown of Lisp interpreter and larger memory footprint])
 320 if test "$with_wide_int" = yes; then
 321   AC_DEFINE([WIDE_EMACS_INT], 1, [Use long long for EMACS_INT if available.])
 322 fi
 323
 324 dnl _ON results in a '--without' option in the --help output, so
 325 dnl the help text should refer to "don't compile", etc.
 326 with_xpm_set=${with_xpm+set}
 327 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 328 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 329 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 330 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 331 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 332 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 333 OPTION_DEFAULT_OFF([cairo],[compile with Cairo drawing (experimental)])
 334 OPTION_DEFAULT_ON([xml2],[don't compile with XML parsing support])
 335 OPTION_DEFAULT_ON([imagemagick],[don't compile with ImageMagick image support])
 336
 337 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 338 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 339 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 340
 341 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 342 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 343 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 344 AC_ARG_WITH([ns],[AS_HELP_STRING([--with-ns],
 345 [use Nextstep (OS X Cocoa or GNUstep) windowing system.
 346 On by default on Mac OS X.])],[],[with_ns=maybe])
 347 OPTION_DEFAULT_OFF([w32], [use native MS Windows GUI in a Cygwin build])
 348
 349 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 350 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 351 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 352 OPTION_DEFAULT_ON([gsettings],[don't compile with GSettings support])
 353 OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support])
 354 OPTION_DEFAULT_ON([gnutls],[don't use -lgnutls for SSL/TLS support])
 355 OPTION_DEFAULT_ON([zlib],[don't compile with zlib decompression support])
 356 OPTION_DEFAULT_OFF([modules],[compile with dynamic modules support])
 357
 358 AC_ARG_WITH([file-notification],[AS_HELP_STRING([--with-file-notification=LIB],
 359  [use a file notification library (LIB one of: yes, inotify, kqueue, gfile, w32, no)])],
 360  [ case "${withval}" in
 361     y | ye | yes )      val=yes ;;
 362     n | no )            val=no  ;;
 363     i | in | ino | inot | inoti | inotif | inotify )    val=inotify ;;
 364     k | kq | kqu | kque | kqueu | kqueue )      val=kqueue ;;
 365     g | gf | gfi | gfil | gfile )       val=gfile ;;
 366     w | w3 | w32 )      val=w32 ;;
 367     * ) AC_MSG_ERROR(['--with-file-notification=$withval' is invalid;
 368 this option's value should be 'yes', 'no', 'inotify', 'kqueue', 'gfile' or 'w32'.
 369 'yes' is a synonym for 'w32' on MS-Windows, for 'no' on Nextstep,
 370 otherwise for the first of 'inotify', 'kqueue' or 'gfile' that is usable.])
 371     ;;
 372    esac
 373    with_file_notification=$val
 374  ],
 375  [with_file_notification=$with_features])
 376
 377 OPTION_DEFAULT_OFF([xwidgets],
 378   [enable use of some gtk widgets in Emacs buffers (requires gtk3)])
 379
 380 ## For the times when you want to build Emacs but don't have
 381 ## a suitable makeinfo, and can live without the manuals.
 382 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 383 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 384
 385 ## This might be a 'configure' arg.
 386 AC_SUBST([ACLOCAL_PATH])
 387
 388 ## Makefile.in needs the cache file name.
 389 AC_SUBST(cache_file)
 390
 391 ## This is an option because I do not know if all info/man support
 392 ## compressed files, nor how to test if they do so.
 393 OPTION_DEFAULT_ON([compress-install],
 394   [don't compress some files (.el, .info, etc.) when installing.  Equivalent to:
 395 make GZIP_PROG= install])
 396
 397 AC_ARG_WITH(gameuser,dnl
 398 [AS_HELP_STRING([--with-gameuser=USER_OR_GROUP],
 399                 [user for shared game score files.
 400                 An argument prefixed by ':' specifies a group instead.])])
 401 gameuser=
 402 gamegroup=
 403 # We don't test if we can actually chown/chgrp here, because configure
 404 # may run without root privileges.  lib-src/Makefile.in will handle
 405 # any errors due to missing user/group gracefully.
 406 case ${with_gameuser} in
 407   no) ;;
 408   "" | yes) gamegroup=games ;;
 409   :*) gamegroup=${with_gameuser#:} ;;
 410   *) gameuser=${with_gameuser} ;;
 411 esac
 412
 413 AC_ARG_WITH([gnustep-conf],dnl
 414 [AS_HELP_STRING([--with-gnustep-conf=FILENAME],
 415    [name of GNUstep configuration file to use on systems where the command
 416     'gnustep-config' does not work; default $GNUSTEP_CONFIG_FILE, or
 417     /etc/GNUstep/GNUstep.conf])])
 418 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 419   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 420 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 421      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 422
 423 AC_ARG_ENABLE(ns-self-contained,
 424 [AS_HELP_STRING([--disable-ns-self-contained],
 425                 [disable self contained build under NeXTstep])],
 426    EN_NS_SELF_CONTAINED=$enableval,
 427    EN_NS_SELF_CONTAINED=yes)
 428
 429 locallisppathset=no
 430 AC_ARG_ENABLE(locallisppath,
 431 [AS_HELP_STRING([--enable-locallisppath=PATH],
 432                 [directories Emacs should search for lisp files specific
 433                  to this site])],
 434 if test "${enableval}" = "no"; then
 435   locallisppath=
 436 elif test "${enableval}" != "yes"; then
 437   locallisppath=${enableval} locallisppathset=yes
 438 fi)
 439
 440 AC_ARG_ENABLE(checking,
 441 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 442                 [enable expensive run-time checks.  With LIST,
 443                  enable only specific categories of checks.
 444                  Categories are: all,yes,no.
 445                  Flags are: stringbytes, stringoverrun, stringfreelist,
 446                  xmallocoverrun, conslist, glyphs])],
 447 [ac_checking_flags="${enableval}"],[])
 448 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 449 for check in $ac_checking_flags
 450 do
 451         case $check in
 452         # these set all the flags to specific states
 453         yes)            ac_enable_checking=1 ;;
 454         no)             ac_enable_checking= ;
 455                         ac_gc_check_stringbytes= ;
 456                         ac_gc_check_string_overrun= ;
 457                         ac_gc_check_string_free_list= ;
 458                         ac_xmalloc_overrun= ;
 459                         ac_gc_check_cons_list= ;
 460                         ac_glyphs_debug= ;;
 461         all)            ac_enable_checking=1 ;
 462                         ac_gc_check_stringbytes=1 ;
 463                         ac_gc_check_string_overrun=1 ;
 464                         ac_gc_check_string_free_list=1 ;
 465                         ac_xmalloc_overrun=1 ;
 466                         ac_gc_check_cons_list=1 ;
 467                         ac_glyphs_debug=1 ;;
 468         # these enable particular checks
 469         stringbytes)    ac_gc_check_stringbytes=1 ;;
 470         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 471         stringfreelist) ac_gc_check_string_free_list=1 ;;
 472         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 473         conslist)       ac_gc_check_cons_list=1 ;;
 474         glyphs)         ac_glyphs_debug=1 ;;
 475         *)      AC_MSG_ERROR(unknown check category $check) ;;
 476         esac
 477 done
 478 IFS="$ac_save_IFS"
 479
 480 if test x$ac_enable_checking != x ; then
 481   AC_DEFINE(ENABLE_CHECKING, 1,
 482 [Define to 1 if expensive run-time data type and consistency checks are enabled.])
 483 fi
 484 if test x$ac_gc_check_stringbytes != x ; then
 485   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 486 [Define this temporarily to hunt a bug.  If defined, the size of
 487    strings is redundantly recorded in sdata structures so that it can
 488    be compared to the sizes recorded in Lisp strings.])
 489 fi
 490 if test x$ac_gc_check_string_overrun != x ; then
 491   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 492 [Define this to check for short string overrun.])
 493 fi
 494 if test x$ac_gc_check_string_free_list != x ; then
 495   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 496 [Define this to check the string free list.])
 497 fi
 498 if test x$ac_xmalloc_overrun != x ; then
 499   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 500 [Define this to check for malloc buffer overrun.])
 501 fi
 502 if test x$ac_gc_check_cons_list != x ; then
 503   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 504 [Define this to check for errors in cons list.])
 505 fi
 506 if test x$ac_glyphs_debug != x ; then
 507   AC_DEFINE(GLYPH_DEBUG, 1,
 508 [Define this to enable glyphs debugging code.])
 509 fi
 510
 511 AC_ARG_ENABLE(check-lisp-object-type,
 512 [AS_HELP_STRING([--enable-check-lisp-object-type],
 513                 [enable compile time checks for the Lisp_Object data type.
 514                 This is useful for development for catching certain types of bugs.])],
 515 if test "${enableval}" != "no"; then
 516    AC_DEFINE(CHECK_LISP_OBJECT_TYPE, 1,
 517    [Define this to enable compile time checks for the Lisp_Object data type.])
 518 fi)
 519
 520
 521 dnl The name of this option is unfortunate.  It predates, and has no
 522 dnl relation to, the "sampling-based elisp profiler" added in 24.3.
 523 dnl Actually, it stops it working.
 524 dnl http://lists.gnu.org/archive/html/emacs-devel/2012-11/msg00393.html
 525 AC_ARG_ENABLE(profiling,
 526 [AS_HELP_STRING([--enable-profiling],
 527                 [build emacs with low-level, gprof profiling support.
 528                 Mainly useful for debugging Emacs itself.  May not work on
 529                 all platforms.  Stops profiler.el working.])],
 530 [ac_enable_profiling="${enableval}"],[])
 531 if test x$ac_enable_profiling != x ; then
 532    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 533 else
 534    PROFILING_CFLAGS=
 535 fi
 536 AC_SUBST(PROFILING_CFLAGS)
 537
 538 AC_ARG_ENABLE(autodepend,
 539 [AS_HELP_STRING([--enable-autodepend],
 540                 [automatically generate dependencies to .h-files.
 541                  Requires gcc, enabled if found.])],
 542 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 543
 544 AC_ARG_ENABLE(gtk-deprecation-warnings,
 545 [AS_HELP_STRING([--enable-gtk-deprecation-warnings],
 546                 [Show Gtk+/Gdk deprecation warnings for Gtk+ >= 3.0])],
 547 [ac_enable_gtk_deprecation_warnings="${enableval}"],[])
 548
 549 BUILD_DETAILS=
 550 AC_ARG_ENABLE([build-details],
 551   [AS_HELP_STRING([--disable-build-details],
 552                   [Make the build more deterministic by omitting host
 553                    names, time stamps, etc. from the output.])],
 554   [test "$enableval" = no && BUILD_DETAILS=--no-build-details])
 555 AC_SUBST([BUILD_DETAILS])
 556
 557 dnl This used to use changequote, but, apart from 'changequote is evil'
 558 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 559 dnl the great gob of text.  Thus it's not processed for possible expansion.
 560 dnl Just make sure the brackets remain balanced.
 561 dnl
 562 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 563 dnl indicated by comments.
 564 dnl quotation begins
 565 [
 566
 567 ### If you add support for a new configuration, add code to this
 568 ### switch statement to recognize your configuration name and select
 569 ### the appropriate opsys.
 570
 571 ### As far as handling version numbers on operating systems is
 572 ### concerned, make sure things will fail in a fixable way.  If
 573 ### /etc/MACHINES doesn't say anything about version numbers, be
 574 ### prepared to handle anything reasonably.  If version numbers
 575 ### matter, be sure /etc/MACHINES says something about it.
 576
 577 opsys='' unported=no
 578 case "${canonical}" in
 579
 580   ## GNU/Linux and similar ports
 581   *-*-linux* )
 582     opsys=gnu-linux
 583   ;;
 584
 585   ## FreeBSD ports
 586   *-*-freebsd* )
 587     opsys=freebsd
 588   ;;
 589
 590   ## DragonFly ports
 591   *-*-dragonfly* )
 592     opsys=dragonfly
 593   ;;
 594
 595   ## FreeBSD kernel + glibc based userland
 596   *-*-kfreebsd*gnu* )
 597     opsys=gnu-kfreebsd
 598   ;;
 599
 600   ## NetBSD ports
 601   *-*-netbsd* )
 602     opsys=netbsd
 603   ;;
 604
 605   ## OpenBSD ports
 606   *-*-openbsd* | *-*-mirbsd* )
 607     opsys=openbsd
 608   ;;
 609
 610   ## Apple Darwin / Mac OS X
 611   *-apple-darwin* )
 612     case "${canonical}" in
 613       *-apple-darwin[0-9].*) unported=yes ;;
 614       i[3456]86-* | x86_64-* )  ;;
 615       * )            unported=yes ;;
 616     esac
 617     opsys=darwin
 618     ## Use fink packages if available.
 619     ## FIXME find a better way to do this: http://debbugs.gnu.org/11507
 620 ##    if test -d /sw/include && test -d /sw/lib; then
 621 ##      GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 622 ##      NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 623 ##    fi
 624   ;;
 625
 626   ## Chromium Native Client
 627   *-nacl )
 628     opsys=nacl
 629   ;;
 630
 631   ## Cygwin ports
 632   *-*-cygwin )
 633     opsys=cygwin
 634   ;;
 635
 636   ## HP 9000 series 700 and 800, running HP/UX
 637   hppa*-hp-hpux10.2* )
 638     opsys=hpux10-20
 639   ;;
 640   hppa*-hp-hpux1[1-9]* )
 641     opsys=hpux11
 642     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 643   ;;
 644
 645   ## IBM machines
 646   rs6000-ibm-aix4.[23]* )
 647     opsys=aix4-2
 648   ;;
 649   powerpc-ibm-aix4.[23]*  )
 650     opsys=aix4-2
 651   ;;
 652   rs6000-ibm-aix[56]* )
 653     opsys=aix4-2
 654   ;;
 655   powerpc-ibm-aix[5-9]* | powerpc-ibm-aix[1-9][0-9]* )
 656     opsys=aix4-2
 657   ;;
 658
 659   ## Silicon Graphics machines
 660   ## Iris 4D
 661   mips-sgi-irix6.5 )
 662     opsys=irix6-5
 663     # Without defining _LANGUAGE_C, things get masked out in the headers
 664     # so that, for instance, grepping for 'free' in stdlib.h fails and
 665     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 666     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 667   ;;
 668
 669   ## Suns
 670   *-sun-solaris* \
 671     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 672     | x86_64-*-solaris2*    | x86_64-*-sunos5*)
 673     case "${canonical}" in
 674       i[3456]86-*-* )   ;;
 675       amd64-*-*|x86_64-*-*) ;;
 676       sparc* )          ;;
 677       * )               unported=yes ;;
 678     esac
 679     case "${canonical}" in
 680       *-sunos5.[1-9][0-9]* | *-solaris2.[1-9][0-9]* )
 681                 opsys=sol2-10
 682                 emacs_check_sunpro_c=yes
 683                 ;;
 684       *-sunos5.[1-5]* | *-solaris2.[1-5]* ) unported=yes ;;
 685       ## Note that Emacs 23.1's NEWS said the following would be dropped.
 686       *-sunos5.6* | *-solaris2.6* )
 687                 opsys=sol2-6
 688                 RANLIB="ar -ts"
 689                 ;;
 690       ## 5.7 EOL Aug 2008, 5.8 EOL Mar 2012.
 691       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 692                 opsys=sol2-6
 693                 emacs_check_sunpro_c=yes
 694                 ;;
 695     esac
 696     ## Watch out for a compiler that we know will not work.
 697     case "${canonical}" in
 698      *-solaris* | *-sunos5* )
 699                 if [ "x$CC" = x/usr/ucb/cc ]; then
 700                   ## /usr/ucb/cc doesn't work;
 701                   ## we should find some other compiler that does work.
 702                   unset CC
 703                 fi
 704                 ;;
 705       *) ;;
 706     esac
 707   ;;
 708
 709   ## Intel 386 machines where we don't care about the manufacturer.
 710   i[3456]86-*-* )
 711     case "${canonical}" in
 712       *-darwin* )               opsys=darwin ;;
 713       *-mingw* )
 714                 opsys=mingw32
 715                 # MinGW overrides and adds some system headers in nt/inc.
 716                 GCC_TEST_OPTIONS="-I $srcdir/nt/inc"
 717                 ;;
 718       *-sysv4.2uw* )            opsys=unixware ;;
 719       *-sysv5uw* )              opsys=unixware ;;
 720       *-sysv5OpenUNIX* )        opsys=unixware ;;
 721       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 722     esac
 723   ;;
 724
 725   # MinGW64
 726   x86_64-*-* )
 727     case "${canonical}" in
 728       *-mingw* )
 729                 opsys=mingw32
 730                 # MinGW overrides and adds some system headers in nt/inc.
 731                 GCC_TEST_OPTIONS="-I $srcdir/nt/inc"
 732                 ;;
 733       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 734     esac
 735   ;;
 736
 737   * )
 738     unported=yes
 739   ;;
 740 esac
 741
 742 ### If the code above didn't choose an operating system, just choose
 743 ### an operating system based on the configuration name.  You really
 744 ### only want to use this when you have no idea what the right
 745 ### operating system is; if you know what operating systems a machine
 746 ### runs, it's cleaner to make it explicit in the case statement
 747 ### above.
 748 if test x"${opsys}" = x; then
 749   case "${canonical}" in
 750     *-gnu* )                            opsys=gnu ;;
 751     * )
 752       unported=yes
 753     ;;
 754   esac
 755 fi
 756
 757 ]
 758 dnl quotation ends
 759
 760 if test $unported = yes; then
 761   AC_MSG_ERROR([Emacs does not support '${canonical}' systems.
 762 If you think it should, please send a report to ${PACKAGE_BUGREPORT}.
 763 Check 'etc/MACHINES' for recognized configuration names.])
 764 fi
 765
 766 #### Choose a compiler.
 767
 768 dnl Don't bother to test for C89.
 769 AC_DEFUN([_AC_PROG_CC_C89], [$2])
 770
 771 dnl Sets GCC=yes if using gcc.
 772 AC_PROG_CC([gcc cc cl clang "$XCRUN gcc" "$XCRUN clang"])
 773 if test -n "$XCRUN"; then
 774   AC_CHECK_PROGS(AR, [ar "$XCRUN ar"])
 775   test -n "$AR" && export AR
 776 fi
 777
 778 dnl Emacs needs C99 or later.
 779 gl_PROG_CC_C99
 780
 781 AM_PROG_CC_C_O
 782
 783 if test x$GCC = xyes; then
 784   test "x$GCC_TEST_OPTIONS" != x && CC="$CC $GCC_TEST_OPTIONS"
 785 else
 786   test "x$NON_GCC_TEST_OPTIONS" != x && CC="$CC $NON_GCC_TEST_OPTIONS"
 787 fi
 788
 789 dnl This is used in lib/Makefile.am to use nt/gnulib.mk, the
 790 dnl alternative to lib/gnulib.mk, so as to avoid generating header files
 791 dnl that clash with MinGW.
 792 AM_CONDITIONAL([BUILDING_FOR_WINDOWSNT], [test "x$opsys" = "xmingw32"])
 793
 794 # Avoid gnulib's tests for -lcrypto, so that there's no static dependency on it.
 795 AC_DEFUN([gl_CRYPTO_CHECK])
 796 # Avoid gnulib's tests for HAVE_WORKING_O_NOATIME and HAVE_WORKING_O_NOFOLLOW,
 797 # as we don't use them.
 798 AC_DEFUN([gl_FCNTL_O_FLAGS])
 799 # Avoid gnulib's test for pthread_sigmask.
 800 funcs=
 801 for func in $ac_func_list; do
 802   test $func = pthread_sigmask || AS_VAR_APPEND([funcs], [" $func"])
 803 done
 804 ac_func_list=$funcs
 805 # Use the system putenv even if it lacks GNU features, as we don't need them,
 806 # and the gnulib replacement runs afoul of a FreeBSD 10.1 bug; see Bug#19874.
 807 AC_CHECK_FUNCS_ONCE([putenv])
 808 AC_DEFUN([gl_FUNC_PUTENV],
 809   [test "$ac_cv_func_putenv" = yes || REPLACE_PUTENV=1])
 810
 811 # Initialize gnulib right after choosing the compiler.
 812 dnl Amongst other things, this sets AR and ARFLAGS.
 813 gl_EARLY
 814
 815 if test "$ac_test_CFLAGS" != set; then
 816   # It's helpful to have C macros available to GDB, so prefer -g3 to -g
 817   # if -g3 works and the user does not specify CFLAGS.
 818   # This test must follow gl_EARLY; otherwise AC_LINK_IFELSE complains.
 819   case $CFLAGS in
 820     '-g')
 821       emacs_g3_CFLAGS='-g3';;
 822     '-g -O2')
 823       emacs_g3_CFLAGS='-g3 -O2';;
 824     *)
 825       emacs_g3_CFLAGS='';;
 826   esac
 827   if test -n "$emacs_g3_CFLAGS"; then
 828     emacs_save_CFLAGS=$CFLAGS
 829     CFLAGS=$emacs_g3_CFLAGS
 830     AC_CACHE_CHECK([whether $CC accepts $emacs_g3_CFLAGS],
 831       [emacs_cv_prog_cc_g3],
 832       [AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 833          [emacs_cv_prog_cc_g3=yes],
 834          [emacs_cv_prog_cc_g3=no])])
 835     if test $emacs_cv_prog_cc_g3 != yes; then
 836       CFLAGS=$emacs_save_CFLAGS
 837     fi
 838     if test $opsys = mingw32; then
 839       CFLAGS="$CFLAGS -gdwarf-2"
 840     fi
 841   fi
 842
 843   case $CFLAGS in
 844     *-O*) ;;
 845     *)
 846       # No optimization flag was inferred for this non-GCC compiler.
 847       # Try -O.  This is needed for xlc on AIX; see Bug#14258.
 848       emacs_save_CFLAGS=$CFLAGS
 849       test -z "$CFLAGS" || CFLAGS="$CFLAGS "
 850       CFLAGS=${CFLAGS}-O
 851       AC_CACHE_CHECK([whether $CC accepts -O],
 852         [emacs_cv_prog_cc_o],
 853         [AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 854            [emacs_cv_prog_cc_o=yes],
 855            [emacs_cv_prog_cc_o=no])])
 856       if test $emacs_cv_prog_cc_o != yes; then
 857         CFLAGS=$emacs_save_CFLAGS
 858       fi ;;
 859   esac
 860 fi
 861
 862 AC_ARG_ENABLE([gcc-warnings],
 863   [AS_HELP_STRING([--enable-gcc-warnings],
 864                   [turn on lots of GCC warnings/errors. This is intended for
 865                    developers, and may generate false alarms when used
 866                    with older or non-GNU development tools.])],
 867   [case $enableval in
 868      yes|no) ;;
 869      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
 870    esac
 871    gl_gcc_warnings=$enableval],
 872   [gl_gcc_warnings=no]
 873 )
 874
 875 # clang is unduly picky about some things.
 876 AC_CACHE_CHECK([whether the compiler is clang], [emacs_cv_clang],
 877   [AC_COMPILE_IFELSE(
 878      [AC_LANG_PROGRAM([[
 879           #ifndef __clang__
 880             error "not clang";
 881           #endif
 882         ]])],
 883      [emacs_cv_clang=yes],
 884      [emacs_cv_clang=no])])
 885
 886 # When compiling with GCC, prefer -isystem to -I when including system
 887 # include files, to avoid generating useless diagnostics for the files.
 888 if test "$gl_gcc_warnings" != yes; then
 889   isystem='-I'
 890   if test "$emacs_cv_clang" = yes
 891   then
 892      # Turn off some warnings if supported.
 893      gl_WARN_ADD([-Wno-switch])
 894      gl_WARN_ADD([-Wno-tautological-constant-out-of-range-compare])
 895      gl_WARN_ADD([-Wno-pointer-sign])
 896      gl_WARN_ADD([-Wno-string-plus-int])
 897      gl_WARN_ADD([-Wno-unknown-attributes])
 898   fi
 899 else
 900   isystem='-isystem '
 901
 902   # This, $nw, is the list of warnings we disable.
 903   nw=
 904
 905   case $with_x_toolkit in
 906     lucid | athena | motif)
 907        # Old toolkits mishandle 'const'.
 908        nw="$nw -Wwrite-strings"
 909        ;;
 910     *)
 911        gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
 912        ;;
 913   esac
 914   AC_SUBST([WERROR_CFLAGS])
 915
 916   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
 917   nw="$nw -Woverlength-strings"     # Not a problem these days
 918   nw="$nw -Wformat-nonliteral"      # we do this a lot
 919   nw="$nw -Wvla"                    # Emacs uses <vla.h>.
 920   nw="$nw -Wswitch-default"         # Too many warnings for now
 921   nw="$nw -Winline"                 # OK to ignore 'inline'
 922   nw="$nw -Wstrict-overflow"        # OK to optimize assuming that
 923                                     # signed overflow has undefined behavior
 924   nw="$nw -Wsync-nand"              # irrelevant here, and provokes ObjC warning
 925   nw="$nw -Wunsafe-loop-optimizations" # OK to suppress unsafe optimizations
 926   nw="$nw -Wbad-function-cast"      # These casts are no worse than others.
 927
 928   # Emacs doesn't care about shadowing; see
 929   # <http://lists.gnu.org/archive/html/emacs-diffs/2011-11/msg00265.html>.
 930   nw="$nw -Wshadow"
 931
 932   # Emacs's use of alloca inhibits protecting the stack.
 933   nw="$nw -Wstack-protector"
 934
 935   # Emacs's use of partly-const functions such as Fgnutls_available_p
 936   # make this option problematic.
 937   nw="$nw -Wsuggest-attribute=const"
 938
 939   # Emacs's use of partly-pure functions such as CHECK_TYPE make this
 940   # option problematic.
 941   nw="$nw -Wsuggest-attribute=pure"
 942
 943   # This part is merely for shortening the command line,
 944   # since -Wall implies -Wswitch.
 945   nw="$nw -Wswitch"
 946
 947   # This part is merely for shortening the command line,
 948   # since -Wno-FOO needs to be added below regardless.
 949   nw="$nw -Wmissing-field-initializers"
 950   nw="$nw -Wtype-limits"
 951   nw="$nw -Wunused-parameter"
 952
 953   if test $emacs_cv_clang = yes; then
 954     nw="$nw -Wcast-align"
 955   fi
 956
 957   gl_MANYWARN_ALL_GCC([ws])
 958   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
 959   for w in $ws; do
 960     gl_WARN_ADD([$w])
 961   done
 962   gl_WARN_ADD([-Wredundant-decls])     # Prefer this, as we don't use Bison.
 963   gl_WARN_ADD([-Wno-missing-field-initializers]) # We need this one
 964   gl_WARN_ADD([-Wno-sign-compare])     # Too many warnings for now
 965   gl_WARN_ADD([-Wno-type-limits])      # Too many warnings for now
 966   gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now
 967   gl_WARN_ADD([-Wno-format-nonliteral])
 968
 969   # More things that clang is unduly picky about.
 970   if test $emacs_cv_clang = yes; then
 971     gl_WARN_ADD([-Wno-format-extra-args])
 972     gl_WARN_ADD([-Wno-tautological-constant-out-of-range-compare])
 973     gl_WARN_ADD([-Wno-unused-command-line-argument])
 974     gl_WARN_ADD([-Wno-unused-value])
 975   fi
 976
 977   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 978   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 979   AH_VERBATIM([GNULIB_PORTCHECK_FORTIFY_SOURCE],
 980   [/* Enable compile-time and run-time bounds-checking, and some warnings,
 981       without upsetting glibc 2.15+. */
 982    #if (defined GNULIB_PORTCHECK && !defined _FORTIFY_SOURCE \
 983         && defined __OPTIMIZE__ && __OPTIMIZE__)
 984    # define _FORTIFY_SOURCE 2
 985    #endif
 986   ])
 987
 988   # We use a slightly smaller set of warning options for lib/.
 989   # Remove the following and save the result in GNULIB_WARN_CFLAGS.
 990   nw=
 991   nw="$nw -Wunused-macros"
 992
 993   gl_MANYWARN_COMPLEMENT([GNULIB_WARN_CFLAGS], [$WARN_CFLAGS], [$nw])
 994   AC_SUBST([GNULIB_WARN_CFLAGS])
 995 fi
 996
 997 edit_cflags="
 998   s,///*,/,g
 999   s/^/ /
1000   s/ -I/ $isystem/g
1001   s/^ //
1002 "
1003
1004 AC_ARG_ENABLE(link-time-optimization,
1005 [AS_HELP_STRING([--enable-link-time-optimization],
1006                 [build emacs with link-time optimization.
1007                  This requires GCC 4.5.0 or later, or clang.
1008                  (Note that clang support is experimental - see INSTALL.)
1009                  It also makes Emacs harder to debug, and when we tried it
1010                  with GCC 4.9.0 x86-64 it made Emacs slower, so it's not
1011                  recommended for typical use.])],
1012 if test "${enableval}" != "no"; then
1013    ac_lto_supported=no
1014    if test $emacs_cv_clang = yes; then
1015       AC_MSG_CHECKING([whether link-time optimization is supported by clang])
1016       GOLD_PLUGIN=`$CC -print-file-name=LLVMgold.so 2>/dev/null`
1017       if test -x "$GOLD_PLUGIN"; then
1018          LTO="-flto"
1019       fi
1020    elif test x$GCC = xyes; then
1021       AC_MSG_CHECKING([whether link-time optimization is supported by gcc])
1022       CPUS=`getconf _NPROCESSORS_ONLN 2>/dev/null`
1023       if test x$CPUS != x; then
1024          LTO="-flto=$CPUS"
1025       else
1026          LTO="-flto"
1027       fi
1028    else
1029       AC_MSG_ERROR([Link-time optimization is not supported with your compiler.])
1030    fi
1031    if test -z "$LTO"; then
1032       ac_lto_supported=no
1033    else
1034       old_CFLAGS=$CFLAGS
1035       CFLAGS="$CFLAGS $LTO"
1036       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])],
1037          [ac_lto_supported=yes], [ac_lto_supported=no])
1038          CFLAGS="$old_CFLAGS"
1039    fi
1040    AC_MSG_RESULT([$ac_lto_supported])
1041    if test "$ac_lto_supported" = "yes"; then
1042       CFLAGS="$CFLAGS $LTO"
1043       if test x$emacs_cv_clang = xyes; then
1044          AC_MSG_WARN([Please read INSTALL before using link-time optimization with clang])
1045          # WARNING: 'ar --plugin ...' doesn't work without
1046          # command, so plugin name is appended to ARFLAGS.
1047          ARFLAGS="cru --plugin $GOLD_PLUGIN"
1048          RANLIB="$RANLIB --plugin $GOLD_PLUGIN"
1049       else
1050         dnl The following is needed for GCC 4.9.0.  The GCC 4.9.0 release notes
1051         dnl suggest that instead of -ffat-lto-objects we should use gcc-ar and
1052         dnl gcc-ranlib in place of ar and ranlib, but gcc-ar makes /usr/bin/ar
1053         dnl dump core on Fedora 20, so play it safe for now.
1054         gl_COMPILER_OPTION_IF([-ffat-lto-objects],
1055           [CFLAGS="$CFLAGS -ffat-lto-objects"])
1056       fi
1057    fi
1058 fi)
1059
1060 dnl Prefer silent make output.  For verbose output, use
1061 dnl 'configure --disable-silent-rules' or 'make V=1' .
1062 AM_SILENT_RULES([yes])
1063 dnl Port to Automake 1.11.
1064 dnl This section can be removed once we assume Automake 1.14 or later.
1065 : ${AM_V=$AM_DEFAULT_VERBOSITY}
1066 : ${AM_DEFAULT_V=$AM_DEFAULT_VERBOSITY}
1067 AC_SUBST([AM_V])
1068 AM_SUBST_NOTMAKE([AM_V])
1069 AC_SUBST([AM_DEFAULT_V])
1070 AM_SUBST_NOTMAKE([AM_DEFAULT_V])
1071 AC_SUBST([AM_DEFAULT_VERBOSITY])
1072
1073 dnl Some other nice autoconf tests.
1074 dnl These are commented out, since gl_EARLY and/or Autoconf already does them.
1075 dnl AC_PROG_INSTALL
1076 dnl AC_PROG_MKDIR_P
1077 dnl if test "x$RANLIB" = x; then
1078 dnl   AC_PROG_RANLIB
1079 dnl fi
1080
1081
1082 dnl Sadly, AC_PROG_LN_S is too restrictive.  It also tests whether links
1083 dnl can be made to directories.  This is not relevant for our usage, and
1084 dnl excludes some cases that work fine for us.  Eg MS Windows or files
1085 dnl hosted on AFS, both examples where simple links work, but links to
1086 dnl directories fail.  We use a cut-down version instead.
1087 dnl AC_PROG_LN_S
1088
1089 AC_MSG_CHECKING([whether ln -s works for files in the same directory])
1090 rm -f conf$$ conf$$.file
1091
1092 LN_S_FILEONLY='cp -p'
1093
1094 dnl On MinGW, ensure we will call the MSYS /bin/ln.exe, not some
1095 dnl random program in the current directory.
1096 if (echo >conf$$.file) 2>/dev/null; then
1097   if ln -s conf$$.file conf$$ 2>/dev/null; then
1098     if test "$opsys" = "mingw32"; then
1099       LN_S_FILEONLY='/bin/ln -s'
1100     else
1101       LN_S_FILEONLY='ln -s'
1102     fi
1103   elif ln conf$$.file conf$$ 2>/dev/null; then
1104     if test "$opsys" = "mingw32"; then
1105       LN_S_FILEONLY=/bin/ln
1106     else
1107       LN_S_FILEONLY=ln
1108     fi
1109   fi
1110 fi
1111
1112 rm -f conf$$ conf$$.file
1113
1114 if test "$LN_S_FILEONLY" = "ln -s"; then
1115    AC_MSG_RESULT([yes])
1116 else
1117    AC_MSG_RESULT([no, using $LN_S_FILEONLY])
1118 fi
1119
1120 AC_SUBST(LN_S_FILEONLY)
1121
1122
1123 dnl AC_PROG_LN_S sets LN_S to 'cp -pR' for MinGW, on the premise that 'ln'
1124 dnl doesn't support links to directories, as in "ln file dir".  But that
1125 dnl use is non-portable, and OTOH MinGW wants to use hard links for Emacs
1126 dnl executables at "make install" time.
1127 dnl See http://lists.gnu.org/archive/html/emacs-devel/2013-04/msg00475.html
1128 dnl for more details.
1129 if test "$opsys" = "mingw32"; then
1130   LN_S="/bin/ln"
1131 fi
1132
1133 dnl On some Debian versions, "install-info" prints irritating messages
1134 dnl "This is not dpkg install-info anymore, but GNU install-info"
1135 dnl if called via an absolute file name.
1136 dnl Use the entirely-identical-but-quieter ginstall-info instead if present.
1137 dnl Sadly some people may have an old ginstall-info installed on
1138 dnl non-Debian systems, so we can't use this.
1139 dnl AC_PATH_PROGS(INSTALL_INFO, [ginstall-info install-info], :,
1140 dnl   $PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin)
1141
1142 AC_PATH_PROG(INSTALL_INFO, install-info, :,
1143   $PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin)
1144 dnl Don't use GZIP, which is used by gzip for additional parameters.
1145 AC_PATH_PROG(GZIP_PROG, gzip)
1146
1147 test $with_compress_install != yes && test -n "$GZIP_PROG" && \
1148    GZIP_PROG=" # $GZIP_PROG # (disabled by configure --without-compress-install)"
1149
1150 if test $opsys = gnu-linux; then
1151   AC_PATH_PROG(PAXCTL, paxctl,,
1152     [$PATH$PATH_SEPARATOR/sbin$PATH_SEPARATOR/usr/sbin])
1153   if test "X$PAXCTL" != X; then
1154     AC_MSG_CHECKING([whether binaries have a PT_PAX_FLAGS header])
1155     AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
1156       [if $PAXCTL -v conftest$EXEEXT >/dev/null 2>&1; then AC_MSG_RESULT(yes)
1157       else AC_MSG_RESULT(no); PAXCTL=""; fi])
1158   fi
1159
1160   if test "${SETFATTR+set}" != set; then
1161     AC_CACHE_CHECK([for setfattr],
1162       [emacs_cv_prog_setfattr],
1163       [touch conftest.tmp
1164        if (setfattr -n user.pax.flags conftest.tmp) >/dev/null 2>&1; then
1165          emacs_cv_prog_setfattr=yes
1166        else
1167          emacs_cv_prog_setfattr=no
1168        fi])
1169     if test "$emacs_cv_prog_setfattr" = yes; then
1170       SETFATTR=setfattr
1171     else
1172       SETFATTR=
1173     fi
1174     rm -f conftest.tmp
1175     AC_SUBST([SETFATTR])
1176   fi
1177 fi
1178
1179 ## Need makeinfo >= 4.7 (?) to build the manuals.
1180 if test "$MAKEINFO" != "no"; then
1181   if test "$MAKEINFO" = "${am_missing_run}makeinfo"; then
1182     MAKEINFO=makeinfo
1183   fi
1184   case `($MAKEINFO --version) 2>/dev/null` in
1185     *' (GNU texinfo) '4.[[7-9]]* | \
1186     *' (GNU texinfo) '4.[[1-9][0-9]]* | \
1187     *' (GNU texinfo) '[[5-9]]* | \
1188     *' (GNU texinfo) '[[1-9][0-9]]* ) ;;
1189     *) MAKEINFO=no;;
1190   esac
1191 fi
1192
1193 ## Makeinfo is unusual.  For a released Emacs, the manuals are
1194 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
1195 ## therefore in the category of "special tools" not normally required, which
1196 ## configure does not have to check for (eg autoconf itself).
1197 ## In a repository checkout on the other hand, the manuals are not included.
1198 ## So makeinfo is a requirement to build from the repository, and configure
1199 ## should test for it as it does for any other build requirement.
1200 ## We use the presence of $srcdir/info/emacs to distinguish a release,
1201 ## with pre-built manuals, from a repository checkout.
1202 HAVE_MAKEINFO=yes
1203
1204 if test "$MAKEINFO" = "no"; then
1205   MAKEINFO=makeinfo
1206   if test "x${with_makeinfo}" = "xno"; then
1207     HAVE_MAKEINFO=no
1208   elif test ! -e "$srcdir/info/emacs" && test ! -e "$srcdir/info/emacs.info"; then
1209     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.7, and your
1210 source tree does not seem to have pre-built manuals in the 'info' directory.
1211 Either install a suitable version of makeinfo, or re-run configure
1212 with the '--without-makeinfo' option to build without the manuals.] )
1213   fi
1214 fi
1215 AC_SUBST(HAVE_MAKEINFO)
1216
1217 if test $opsys = mingw32; then
1218    DOCMISC_W32=efaq-w32
1219 else
1220    DOCMISC_W32=
1221 fi
1222 AC_SUBST(DOCMISC_W32)
1223
1224 dnl Add our options to ac_link now, after it is set up.
1225
1226 if test x$GCC = xyes; then
1227   test "x$GCC_LINK_TEST_OPTIONS" != x && \
1228     ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
1229 else
1230   test "x$NON_GCC_LINK_TEST_OPTIONS" != x && \
1231     ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
1232 fi
1233
1234 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
1235 dnl If we can link with the flag, it shouldn't do any harm anyhow.
1236 dnl (Don't use '-z nocombreloc' as -z takes no arg on Irix.)
1237 dnl Treat GCC specially since it just gives a non-fatal 'unrecognized option'
1238 dnl if not built to support GNU ld.
1239
1240 dnl For a long time, -znocombreloc was added to LDFLAGS rather than
1241 dnl LD_SWITCH_SYSTEM_TEMACS.  That is:
1242 dnl * inappropriate, as LDFLAGS is a user option but this is essential.
1243 dnl   Eg "make LDFLAGS=... all" could run into problems,
1244 dnl   http://bugs.debian.org/684788
1245 dnl * unnecessary, since temacs is the only thing that actually needs it.
1246 dnl   Indeed this is where it was originally, prior to:
1247 dnl   http://lists.gnu.org/archive/html/emacs-pretest-bug/2004-03/msg00170.html
1248 late_LDFLAGS="$LDFLAGS"
1249 if test x$GCC = xyes; then
1250   LDFLAGS_NOCOMBRELOC="-Wl,-znocombreloc"
1251 else
1252   LDFLAGS_NOCOMBRELOC="-znocombreloc"
1253 fi
1254
1255 LDFLAGS="$LDFLAGS $LDFLAGS_NOCOMBRELOC"
1256
1257 AC_MSG_CHECKING([for -znocombreloc])
1258 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
1259   [AC_MSG_RESULT(yes)],
1260   LDFLAGS_NOCOMBRELOC=
1261   [AC_MSG_RESULT(no)])
1262
1263 LDFLAGS="$late_LDFLAGS"
1264
1265 AC_CACHE_CHECK([whether addresses are sanitized],
1266   [emacs_cv_sanitize_address],
1267   [AC_COMPILE_IFELSE(
1268      [AC_LANG_PROGRAM(
1269         [[#ifndef __has_feature
1270           #define __has_feature(f) 0
1271           #endif
1272           #if defined __SANITIZE_ADDRESS__ || __has_feature (address_sanitizer)
1273           #else
1274            error "Addresses are not sanitized.";
1275           #endif
1276         ]])],
1277      [emacs_cv_sanitize_address=yes],
1278      [emacs_cv_sanitize_address=no])])
1279
1280 dnl The function dump-emacs will not be defined and temacs will do
1281 dnl (load "loadup") automatically unless told otherwise.
1282 test "x$CANNOT_DUMP" = "x" && CANNOT_DUMP=no
1283 case "$opsys" in
1284   nacl) CANNOT_DUMP=yes ;;
1285 esac
1286
1287 if test "$CANNOT_DUMP" = "yes"; then
1288   AC_DEFINE(CANNOT_DUMP, 1, [Define if Emacs cannot be dumped on your system.])
1289 elif test "$emacs_cv_sanitize_address" = yes; then
1290   AC_MSG_WARN([[Addresses are sanitized; suggest CANNOT_DUMP=yes]])
1291 fi
1292
1293 AC_SUBST(CANNOT_DUMP)
1294
1295
1296 UNEXEC_OBJ=unexelf.o
1297 case "$opsys" in
1298   # MSDOS uses unexcoff.o
1299   aix4-2)
1300    UNEXEC_OBJ=unexaix.o
1301    ;;
1302   cygwin)
1303    UNEXEC_OBJ=unexcw.o
1304    ;;
1305   darwin)
1306    UNEXEC_OBJ=unexmacosx.o
1307    ;;
1308   hpux10-20 | hpux11)
1309    UNEXEC_OBJ=unexhp9k800.o
1310    ;;
1311   mingw32)
1312    UNEXEC_OBJ=unexw32.o
1313    ;;
1314   sol2-10)
1315    # Use the Solaris dldump() function, called from unexsol.c, to dump
1316    # emacs, instead of the generic ELF dump code found in unexelf.c.
1317    # The resulting binary has a complete symbol table, and is better
1318    # for debugging and other observability tools (debuggers, pstack, etc).
1319    #
1320    # If you encounter a problem using dldump(), please consider sending
1321    # a message to the OpenSolaris tools-linking mailing list:
1322    #      http://mail.opensolaris.org/mailman/listinfo/tools-linking
1323    #
1324    # It is likely that dldump() works with older Solaris too, but this has
1325    # not been tested, so for now this change is for Solaris 10 or newer.
1326    UNEXEC_OBJ=unexsol.o
1327    ;;
1328 esac
1329
1330 LD_SWITCH_SYSTEM=
1331 case "$opsys" in
1332   freebsd|dragonfly)
1333    ## Let 'ld' find image libs and similar things in /usr/local/lib.
1334    ## The system compiler, GCC, has apparently been modified to not
1335    ## look there, contrary to what a stock GCC would do.
1336 ### It's not our place to do this.  See bug#10313#17.
1337 ###   LD_SWITCH_SYSTEM=-L/usr/local/lib
1338       :
1339    ;;
1340
1341   gnu-linux)
1342    ## cpp test was "ifdef __mips__", but presumably this is equivalent...
1343    case $host_cpu in mips*) LD_SWITCH_SYSTEM="-G 0";; esac
1344    ;;
1345
1346   netbsd)
1347 ### It's not our place to do this.  See bug#10313#17.
1348 ###   LD_SWITCH_SYSTEM="-Wl,-rpath,/usr/pkg/lib -L/usr/pkg/lib -Wl,-rpath,/usr/local/lib -L/usr/local/lib"
1349       :
1350    ;;
1351
1352   openbsd)
1353    ## Han Boetes <han@boetes.org> says this is necessary,
1354    ## otherwise Emacs dumps core on elf systems.
1355    LD_SWITCH_SYSTEM="-Z"
1356    ;;
1357 esac
1358 AC_SUBST(LD_SWITCH_SYSTEM)
1359
1360 ac_link="$ac_link $LD_SWITCH_SYSTEM"
1361
1362 ## This setting of LD_SWITCH_SYSTEM references LD_SWITCH_X_SITE_RPATH,
1363 ## which has not been defined yet.  When this was handled with cpp,
1364 ## it was expanded to null when configure sourced the s/*.h file.
1365 ## Thus LD_SWITCH_SYSTEM had different values in configure and the Makefiles.
1366 ## FIXME it would be cleaner to put this in LD_SWITCH_SYSTEM_TEMACS
1367 ## (or somesuch), but because it is supposed to go at the _front_
1368 ## of LD_SWITCH_SYSTEM, we cannot do that in exactly the same way.
1369 ## Compare with the gnu-linux case below, which added to the end
1370 ## of LD_SWITCH_SYSTEM, and so can instead go at the front of
1371 ## LD_SWITCH_SYSTEM_TEMACS.
1372 case "$opsys" in
1373   netbsd|openbsd)
1374    LD_SWITCH_SYSTEM="\$(LD_SWITCH_X_SITE_RPATH) $LD_SWITCH_SYSTEM" ;;
1375 esac
1376
1377
1378 C_SWITCH_MACHINE=
1379 case $canonical in
1380  alpha*)
1381   AC_CHECK_DECL([__ELF__])
1382   if test "$ac_cv_have_decl___ELF__" = "yes"; then
1383     ## With ELF, make sure that all common symbols get allocated to in the
1384     ## data section.  Otherwise, the dump of temacs may miss variables in
1385     ## the shared library that have been initialized.  For example, with
1386     ## GNU libc, __malloc_initialized would normally be resolved to the
1387     ## shared library's .bss section, which is fatal.
1388     if test "x$GCC" = "xyes"; then
1389       C_SWITCH_MACHINE="-fno-common"
1390     else
1391       AC_MSG_ERROR([Non-GCC compilers are not supported.])
1392     fi
1393   else
1394       dnl This was the unexalpha.c case.  Removed in 24.1, 2010-07-24,
1395       dnl albeit under the mistaken assumption that said file
1396       dnl was no longer used.
1397       AC_MSG_ERROR([Non-ELF systems are not supported since Emacs 24.1.])
1398   fi
1399   ;;
1400 esac
1401 AC_SUBST(C_SWITCH_MACHINE)
1402
1403 AC_SUBST(UNEXEC_OBJ)
1404
1405 C_SWITCH_SYSTEM=
1406 ## Some programs in src produce warnings saying certain subprograms
1407 ## are too complex and need a MAXMEM value greater than 2000 for
1408 ## additional optimization.  --nils@exp-math.uni-essen.de
1409 test "$opsys" = "aix4.2" && test "x$GCC" != "xyes" && \
1410   C_SWITCH_SYSTEM="-ma -qmaxmem=4000"
1411 if test "$opsys" = "mingw32"; then
1412   case "$canonical" in
1413     x86_64-*-mingw*) C_SWITCH_SYSTEM="-mtune=generic" ;;
1414     *) C_SWITCH_SYSTEM="-mtune=pentium4" ;;
1415   esac
1416 fi
1417 ## gnu-linux might need -D_BSD_SOURCE on old libc5 systems.
1418 ## It is redundant in glibc2, since we define _GNU_SOURCE.
1419 AC_SUBST(C_SWITCH_SYSTEM)
1420
1421
1422 LIBS_SYSTEM=
1423 case "$opsys" in
1424   ## IBM's X11R5 uses -lIM and -liconv in AIX 3.2.2.
1425   aix4-2) LIBS_SYSTEM="-lrts -lIM -liconv" ;;
1426
1427   freebsd|dragonfly) LIBS_SYSTEM="-lutil" ;;
1428
1429   hpux*) LIBS_SYSTEM="-l:libdld.sl" ;;
1430
1431   sol2*) LIBS_SYSTEM="-lsocket -lnsl" ;;
1432
1433   ## Motif needs -lgen.
1434   unixware) LIBS_SYSTEM="-lsocket -lnsl -lelf -lgen" ;;
1435 esac
1436
1437 AC_SUBST(LIBS_SYSTEM)
1438
1439 ### Make sure subsequent tests use flags consistent with the build flags.
1440
1441 if test x"${OVERRIDE_CPPFLAGS}" != x; then
1442   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
1443 else
1444   CPPFLAGS="$C_SWITCH_SYSTEM $C_SWITCH_MACHINE $CPPFLAGS"
1445 fi
1446
1447 # Suppress obsolescent Autoconf test for size_t; Emacs assumes C99 or better.
1448 AC_DEFUN([AC_TYPE_SIZE_T])
1449 # Likewise for obsolescent test for uid_t, gid_t; Emacs assumes them.
1450 AC_DEFUN([AC_TYPE_UID_T])
1451
1452 # sqrt and other floating-point functions such as fmod and frexp
1453 # are found in -lm on many systems.
1454 OLD_LIBS=$LIBS
1455 AC_SEARCH_LIBS([sqrt], [m])
1456 if test "X$LIBS" = "X$OLD_LIBS"; then
1457   LIB_MATH=
1458 else
1459   LIB_MATH=$ac_cv_search_sqrt
1460 fi
1461 LIBS=$OLD_LIBS
1462
1463 dnl Current possibilities handled by sed (aix4-2 -> aix,
1464 dnl gnu-linux -> gnu/linux, etc.):
1465 dnl gnu, gnu/linux, gnu/kfreebsd, aix, cygwin, darwin, hpux, irix.
1466 dnl And special cases: berkeley-unix, usg-unix-v, ms-dos, windows-nt.
1467 SYSTEM_TYPE=`echo $opsys | sed -e 's/[[0-9]].*//' -e 's|-|/|'`
1468
1469 case $opsys in
1470   cygwin )
1471     LIB_MATH=
1472     ;;
1473   darwin )
1474     ## Adding -lm confuses the dynamic linker, so omit it.
1475     LIB_MATH=
1476     ;;
1477   freebsd | dragonfly )
1478     SYSTEM_TYPE=berkeley-unix
1479     ;;
1480   gnu-linux | gnu-kfreebsd )
1481     ;;
1482   hpux10-20 | hpux11 )
1483     ;;
1484   mingw32 )
1485     LIB_MATH=
1486     SYSTEM_TYPE=windows-nt
1487     ;;
1488   dnl NB this may be adjusted below.
1489   netbsd | openbsd )
1490     SYSTEM_TYPE=berkeley-unix
1491     ;;
1492
1493   sol2* | unixware )
1494     SYSTEM_TYPE=usg-unix-v
1495     ;;
1496
1497 esac
1498
1499 AC_SUBST(LIB_MATH)
1500 AC_DEFINE_UNQUOTED(SYSTEM_TYPE, "$SYSTEM_TYPE",
1501   [The type of system you are compiling for; sets 'system-type'.])
1502
1503
1504 pre_PKG_CONFIG_CFLAGS=$CFLAGS
1505 pre_PKG_CONFIG_LIBS=$LIBS
1506
1507 PKG_PROG_PKG_CONFIG(0.9.0)
1508
1509 dnl EMACS_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4)
1510 dnl acts like PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4,
1511 dnl HAVE_GSTUFF=yes, HAVE_GSTUFF=no) -- see pkg-config man page --
1512 dnl except that it postprocesses CFLAGS as needed for --enable-gcc-warnings.
1513 dnl EMACS_CHECK_MODULES accepts optional 3rd and 4th arguments that
1514 dnl can take the place of the default HAVE_GSTUFF=yes and HAVE_GSTUFF=no
1515 dnl actions.
1516 AC_DEFUN([EMACS_CHECK_MODULES],
1517   [PKG_CHECK_MODULES([$1], [$2],
1518      [$1_CFLAGS=`AS_ECHO(["$$1_CFLAGS"]) | sed -e "$edit_cflags"`
1519       m4_default([$3], [HAVE_$1=yes])],
1520      [m4_default([$4], [HAVE_$1=no])])])
1521
1522 HAVE_SOUND=no
1523 if test "${with_sound}" != "no"; then
1524   # Sound support for GNU/Linux, the free BSDs, MinGW, and Cygwin.
1525   AC_CHECK_HEADERS([machine/soundcard.h sys/soundcard.h soundcard.h mmsystem.h],
1526     have_sound_header=yes, [], [
1527     #ifdef __MINGW32__
1528     #define WIN32_LEAN_AND_MEAN
1529     #include <windows.h>
1530     #endif
1531     ])
1532   test "${with_sound}" = "oss" && test "${have_sound_header}" != "yes" && \
1533     AC_MSG_ERROR([OSS sound support requested but not found.])
1534
1535   if test "${with_sound}" = "bsd-ossaudio" || test "${with_sound}" = "yes"; then
1536     # Emulation library used on NetBSD.
1537     AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1538     test "${with_sound}" = "bsd-ossaudio" && test -z "$LIBSOUND" && \
1539       AC_MSG_ERROR([bsd-ossaudio sound support requested but not found.])
1540     dnl FIXME?  If we did find ossaudio, should we set with_sound=bsd-ossaudio?
1541     dnl Traditionally, we go on to check for alsa too.  Does that make sense?
1542   fi
1543   AC_SUBST(LIBSOUND)
1544
1545   if test "${with_sound}" = "alsa" || test "${with_sound}" = "yes"; then
1546     ALSA_REQUIRED=1.0.0
1547     ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1548     EMACS_CHECK_MODULES([ALSA], [$ALSA_MODULES])
1549     if test $HAVE_ALSA = yes; then
1550       SAVE_CFLAGS="$CFLAGS"
1551       SAVE_LIBS="$LIBS"
1552       CFLAGS="$ALSA_CFLAGS $CFLAGS"
1553       LIBS="$ALSA_LIBS $LIBS"
1554       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <asoundlib.h>]], [[snd_lib_error_set_handler (0);]])],
1555                       emacs_alsa_normal=yes,
1556                     emacs_alsa_normal=no)
1557       if test "$emacs_alsa_normal" != yes; then
1558         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <alsa/asoundlib.h>]],
1559                        [[snd_lib_error_set_handler (0);]])],
1560                        emacs_alsa_subdir=yes,
1561                      emacs_alsa_subdir=no)
1562         if test "$emacs_alsa_subdir" != yes; then
1563           AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1564         fi
1565         ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1566       fi
1567
1568       CFLAGS="$SAVE_CFLAGS"
1569       LIBS="$SAVE_LIBS"
1570       LIBSOUND="$LIBSOUND $ALSA_LIBS"
1571       CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1572       AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1573     elif test "${with_sound}" = "alsa"; then
1574       AC_MSG_ERROR([ALSA sound support requested but not found.])
1575     fi
1576   fi                            dnl with_sound = alsa|yes
1577
1578   dnl Define HAVE_SOUND if we have sound support.  We know it works and
1579   dnl compiles only on the specified platforms.  For others, it
1580   dnl probably doesn't make sense to try.
1581   dnl FIXME So surely we should bypass this whole section if not using
1582   dnl one of these platforms?
1583   if test x$have_sound_header = xyes || test $HAVE_ALSA = yes; then
1584      case "$opsys" in
1585        dnl defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
1586        dnl Adjust the --with-sound help text if you change this.
1587        gnu-linux|freebsd|netbsd|mingw32|cygwin)
1588          AC_DEFINE(HAVE_SOUND, 1, [Define to 1 if you have sound support.])
1589          HAVE_SOUND=yes
1590          ;;
1591      esac
1592   fi
1593
1594   AC_SUBST(CFLAGS_SOUND)
1595 fi
1596
1597 dnl checks for header files
1598 AC_CHECK_HEADERS_ONCE(
1599   malloc.h
1600   sys/systeminfo.h
1601   sys/sysinfo.h
1602   coff.h pty.h
1603   sys/resource.h
1604   sys/utsname.h pwd.h utmp.h util.h)
1605
1606 AC_MSG_CHECKING(if personality LINUX32 can be set)
1607 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/personality.h>]], [[personality (PER_LINUX32)]])],
1608                emacs_cv_personality_linux32=yes,
1609                emacs_cv_personality_linux32=no)
1610 AC_MSG_RESULT($emacs_cv_personality_linux32)
1611
1612 if test $emacs_cv_personality_linux32 = yes; then
1613   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1614             [Define to 1 if personality LINUX32 can be set.])
1615 fi
1616
1617 # Note that Solaris has sys/sysinfo.h which defines struct
1618 # sysinfo as well.  To make sure that we're using GNU/Linux
1619 # sysinfo, we explicitly set one of its fields.
1620 if test "$ac_cv_header_sys_sysinfo_h" = yes; then
1621   AC_MSG_CHECKING([if Linux sysinfo may be used])
1622   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/sysinfo.h>]],
1623                                      [[struct sysinfo si;
1624                                        si.totalram = 0;
1625                                        sysinfo (&si)]])],
1626     emacs_cv_linux_sysinfo=yes, emacs_cv_linux_sysinfo=no)
1627   AC_MSG_RESULT($emacs_cv_linux_sysinfo)
1628   if test $emacs_cv_linux_sysinfo = yes; then
1629     AC_DEFINE([HAVE_LINUX_SYSINFO], 1, [Define to 1 if you have Linux sysinfo function.])
1630     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/sysinfo.h>]],
1631                                        [[struct sysinfo si; return si.mem_unit]])],
1632       AC_DEFINE(LINUX_SYSINFO_UNIT, 1,
1633                 [Define to 1 if Linux sysinfo sizes are in multiples of mem_unit bytes.]))
1634   fi
1635 fi
1636
1637 dnl On Solaris 8 there's a compilation warning for term.h because
1638 dnl it doesn't define 'bool'.
1639 AC_CHECK_HEADERS(term.h, , , -)
1640 AC_HEADER_TIME
1641 AC_CHECK_DECLS([sys_siglist], [], [], [[#include <signal.h>
1642                                       ]])
1643 if test $ac_cv_have_decl_sys_siglist != yes; then
1644   # For Tru64, at least:
1645   AC_CHECK_DECLS([__sys_siglist], [], [], [[#include <signal.h>
1646                                           ]])
1647 fi
1648 AC_HEADER_SYS_WAIT
1649
1650 AC_CHECK_HEADERS_ONCE(sys/socket.h)
1651 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1652 #if HAVE_SYS_SOCKET_H
1653 #include <sys/socket.h>
1654 #endif])
1655 AC_CHECK_HEADERS(ifaddrs.h, , , [AC_INCLUDES_DEFAULT
1656 #if HAVE_SYS_SOCKET_H
1657 #include <sys/socket.h>
1658 #endif])
1659 AC_CHECK_HEADERS(net/if_dl.h, , , [AC_INCLUDES_DEFAULT
1660 #if HAVE_SYS_SOCKET_H
1661 #include <sys/socket.h>
1662 #endif])
1663
1664 dnl checks for structure members
1665 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1666                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1667                   struct ifreq.ifr_addr,
1668                   struct ifreq.ifr_addr.sa_len], , ,
1669                  [AC_INCLUDES_DEFAULT
1670 #if HAVE_SYS_SOCKET_H
1671 #include <sys/socket.h>
1672 #endif
1673 #if HAVE_NET_IF_H
1674 #include <net/if.h>
1675 #endif])
1676
1677 dnl Check for endianness.
1678 dnl AC_C_BIGENDIAN is done by gnulib.
1679
1680 dnl check for Make feature
1681
1682 AUTO_DEPEND=no
1683 dnl check if we have GCC and autodepend is on.
1684 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1685    AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1686    SAVE_CFLAGS="$CFLAGS"
1687    CFLAGS="$CFLAGS -MMD -MF deps.d -MP"
1688    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], , ac_enable_autodepend=no)
1689    CFLAGS="$SAVE_CFLAGS"
1690    test -f deps.d || ac_enable_autodepend=no
1691    rm -rf deps.d
1692    AC_MSG_RESULT([$ac_enable_autodepend])
1693    if test $ac_enable_autodepend = yes; then
1694       AUTO_DEPEND=yes
1695    fi
1696 fi
1697 AC_SUBST(AUTO_DEPEND)
1698
1699 dnl checks for operating system services
1700 AC_SYS_LONG_FILE_NAMES
1701
1702 #### Choose a window system.
1703
1704 ## We leave window_system equal to none if
1705 ## we end up building without one.  Any new window system should
1706 ## set window_system to an appropriate value and add objects to
1707 ## window-system-specific substs.
1708
1709 window_system=none
1710 AC_PATH_X
1711 if test "$no_x" != yes; then
1712   window_system=x11
1713 fi
1714
1715 LD_SWITCH_X_SITE_RPATH=
1716 if test "${x_libraries}" != NONE; then
1717   if test -n "${x_libraries}"; then
1718     LD_SWITCH_X_SITE=-L`AS_ECHO(["$x_libraries"]) | sed -e 's/:/ -L/g'`
1719     LD_SWITCH_X_SITE_RPATH=-Wl,-rpath,`
1720       AS_ECHO(["$x_libraries"]) | sed -e 's/:/ -Wl,-rpath,/g'
1721     `
1722   fi
1723   x_default_search_path=""
1724   x_search_path=${x_libraries}
1725   if test -z "${x_search_path}"; then
1726     x_search_path=/usr/lib
1727   fi
1728   for x_library in `AS_ECHO(["$x_search_path:"]) | \
1729                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1730     x_search_path="\
1731 ${x_library}/X11/%L/%T/%N%C%S:\
1732 ${x_library}/X11/%l/%T/%N%C%S:\
1733 ${x_library}/X11/%T/%N%C%S:\
1734 ${x_library}/X11/%L/%T/%N%S:\
1735 ${x_library}/X11/%l/%T/%N%S:\
1736 ${x_library}/X11/%T/%N%S"
1737     if test x"${x_default_search_path}" = x; then
1738       x_default_search_path=${x_search_path}
1739     else
1740       x_default_search_path="${x_search_path}:${x_default_search_path}"
1741     fi
1742   done
1743 fi
1744 AC_SUBST(LD_SWITCH_X_SITE_RPATH)
1745
1746 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1747   C_SWITCH_X_SITE=$isystem`AS_ECHO(["$x_includes"]) | sed -e "s/:/ $isystem/g"`
1748 fi
1749
1750 if test x"${x_includes}" = x; then
1751   bitmapdir=/usr/include/X11/bitmaps
1752 else
1753   # accumulate include directories that have X11 bitmap subdirectories
1754   bmd_acc=
1755   for bmd in `AS_ECHO(["$x_includes"]) | sed -e 's/:/ /g'`; do
1756     if test -d "${bmd}/X11/bitmaps"; then
1757       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1758     fi
1759     if test -d "${bmd}/bitmaps"; then
1760       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1761     fi
1762   done
1763   bitmapdir=${bmd_acc#:}
1764 fi
1765
1766 test "${with_ns}" = maybe && test "${opsys}" != darwin && with_ns=no
1767 HAVE_NS=no
1768 NS_GNUSTEP_CONFIG=no
1769 NS_IMPL_COCOA=no
1770 NS_IMPL_GNUSTEP=no
1771 tmp_CPPFLAGS="$CPPFLAGS"
1772 tmp_CFLAGS="$CFLAGS"
1773 CPPFLAGS="$CPPFLAGS -x objective-c"
1774 CFLAGS="$CFLAGS -x objective-c"
1775 GNU_OBJC_CFLAGS=
1776 LIBS_GNUSTEP=
1777 if test "${with_ns}" != no; then
1778   if test "${opsys}" = darwin; then
1779      NS_IMPL_COCOA=yes
1780      ns_appdir=`pwd`/nextstep/Emacs.app
1781      ns_appbindir=${ns_appdir}/Contents/MacOS
1782      ns_appresdir=${ns_appdir}/Contents/Resources
1783      ns_appsrc=Cocoa/Emacs.base
1784      ns_fontfile=macfont.o
1785   elif flags=$( (gnustep-config --objc-flags) 2>/dev/null); then
1786      NS_IMPL_GNUSTEP=yes
1787      NS_GNUSTEP_CONFIG=yes
1788      GNU_OBJC_CFLAGS=$flags
1789      LIBS_GNUSTEP=$(gnustep-config --gui-libs) || exit
1790   elif test -f $GNUSTEP_CONFIG_FILE; then
1791      NS_IMPL_GNUSTEP=yes
1792      dnl FIXME sourcing this several times in subshells seems inefficient.
1793      GNUSTEP_SYSTEM_HEADERS=$(
1794        . $GNUSTEP_CONFIG_FILE
1795        AS_ECHO(["$GNUSTEP_SYSTEM_HEADERS"])
1796      )
1797      GNUSTEP_SYSTEM_LIBRARIES=$(
1798        . $GNUSTEP_CONFIG_FILE
1799        AS_ECHO(["$GNUSTEP_SYSTEM_LIBRARIES"])
1800      )
1801      dnl I seemed to need these as well with GNUstep-startup 0.25.
1802      GNUSTEP_LOCAL_HEADERS=$(
1803        . $GNUSTEP_CONFIG_FILE
1804        AS_ECHO(["$GNUSTEP_LOCAL_HEADERS"])
1805      )
1806      GNUSTEP_LOCAL_LIBRARIES=$(
1807        . $GNUSTEP_CONFIG_FILE
1808        AS_ECHO(["$GNUSTEP_LOCAL_LIBRARIES"])
1809      )
1810      test "x${GNUSTEP_LOCAL_HEADERS}" != "x" && \
1811        GNUSTEP_LOCAL_HEADERS="-I${GNUSTEP_LOCAL_HEADERS}"
1812      test "x${GNUSTEP_LOCAL_LIBRARIES}" != "x" && \
1813        GNUSTEP_LOCAL_LIBRARIES="-L${GNUSTEP_LOCAL_LIBRARIES}"
1814      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1815      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1816      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES}"
1817      LIBS_GNUSTEP="-lgnustep-gui -lgnustep-base -lobjc -lpthread"
1818      dnl GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS to 0 or 1.
1819      dnl If they had chosen to either define it or not, we could have
1820      dnl just used AC_CHECK_DECL here.
1821      AC_CACHE_CHECK(if GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS,
1822        emacs_cv_objc_exceptions,
1823 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <GNUstepBase/GSConfig.h>]],
1824 [[#if defined BASE_NATIVE_OBJC_EXCEPTIONS && BASE_NATIVE_OBJC_EXCEPTIONS > 0
1825 1;
1826 #else
1827 fail;
1828 #endif]])], emacs_cv_objc_exceptions=yes, emacs_cv_objc_exceptions=no ) )
1829      if test $emacs_cv_objc_exceptions = yes; then
1830        dnl _NATIVE_OBJC_EXCEPTIONS is used by the GNUstep headers.
1831        AC_DEFINE(_NATIVE_OBJC_EXCEPTIONS, 1,
1832          [Define if GNUstep uses ObjC exceptions.])
1833        GNU_OBJC_CFLAGS="-fobjc-exceptions"
1834      fi
1835   fi
1836   if test $NS_IMPL_GNUSTEP = yes; then
1837      ns_appdir=`pwd`/nextstep/Emacs.app
1838      ns_appbindir=${ns_appdir}
1839      ns_appresdir=${ns_appdir}/Resources
1840      ns_appsrc=GNUstep/Emacs.base
1841      ns_fontfile=nsfont.o
1842   fi
1843
1844   dnl This is only used while we test the NS headers, it gets reset below.
1845   CPPFLAGS="$CPPFLAGS $GNU_OBJC_CFLAGS"
1846   CFLAGS="$CFLAGS $GNU_OBJC_CFLAGS"
1847
1848   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1849                   [AC_MSG_ERROR([The include files (AppKit/AppKit.h etc) that
1850 are required for a Nextstep build are missing or cannot be compiled.
1851 Either fix this, or re-configure with the option '--without-ns'.])])
1852
1853   macfont_file=""
1854   if test "${NS_IMPL_COCOA}" = "yes"; then
1855     AC_MSG_CHECKING([for OSX 10.6 or newer])
1856     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <AppKit/AppKit.h>],
1857                                      [
1858 #ifdef MAC_OS_X_VERSION_MAX_ALLOWED
1859 #if MAC_OS_X_VERSION_MAX_ALLOWED >= 1060
1860  ; /* OK */
1861 #else
1862  error "OSX 10.6 or newer required";
1863 #endif
1864 #endif
1865                     ])],
1866                     ns_osx_have_106=yes,
1867                     ns_osx_have_106=no)
1868     AC_MSG_RESULT([$ns_osx_have_106])
1869
1870     if test $ns_osx_have_106 = no; then
1871        AC_MSG_ERROR([OSX 10.6 or newer is required]);
1872     fi
1873   fi
1874 fi
1875
1876 AC_SUBST(LIBS_GNUSTEP)
1877
1878 INSTALL_ARCH_INDEP_EXTRA=install-etc
1879 ns_self_contained=no
1880 NS_OBJ=
1881 NS_OBJC_OBJ=
1882 if test "${HAVE_NS}" = yes; then
1883   if test "$with_toolkit_scroll_bars" = "no"; then
1884     AC_MSG_ERROR([Non-toolkit scroll bars are not implemented for Nextstep.])
1885   fi
1886
1887   window_system=nextstep
1888   # set up packaging dirs
1889   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1890      ns_self_contained=yes
1891      prefix=${ns_appresdir}
1892      exec_prefix=${ns_appbindir}
1893      dnl This one isn't really used, only archlibdir is.
1894      libexecdir="\${ns_appbindir}/libexec"
1895      archlibdir="\${ns_appbindir}/libexec"
1896      etcdocdir="\${ns_appresdir}/etc"
1897      etcdir="\${ns_appresdir}/etc"
1898      dnl FIXME maybe set datarootdir instead.
1899      dnl That would also get applications, icons, man.
1900      infodir="\${ns_appresdir}/info"
1901      mandir="\${ns_appresdir}/man"
1902      lispdir="\${ns_appresdir}/lisp"
1903      test "$locallisppathset" = no && locallisppath=""
1904      INSTALL_ARCH_INDEP_EXTRA=
1905   fi
1906
1907   NS_OBJC_OBJ="nsterm.o nsfns.o nsmenu.o nsselect.o nsimage.o $ns_fontfile"
1908 fi
1909 CFLAGS="$tmp_CFLAGS"
1910 CPPFLAGS="$tmp_CPPFLAGS"
1911 AC_SUBST(INSTALL_ARCH_INDEP_EXTRA)
1912 AC_SUBST(ns_self_contained)
1913 AC_SUBST(NS_OBJ)
1914 AC_SUBST(NS_OBJC_OBJ)
1915
1916 HAVE_W32=no
1917 W32_OBJ=
1918 W32_LIBS=
1919 EMACSRES=
1920 CLIENTRES=
1921 CLIENTW=
1922 W32_RES_LINK=
1923 EMACS_MANIFEST=
1924 UPDATE_MANIFEST=
1925 if test "${with_w32}" != no; then
1926   case "${opsys}" in
1927     cygwin)
1928       AC_CHECK_HEADER([windows.h], [HAVE_W32=yes],
1929              [AC_MSG_ERROR(['--with-w32' was specified, but windows.h
1930                    cannot be found.])])
1931     ;;
1932     mingw32)
1933     ## Using --with-w32 with MinGW is a no-op, but we allow it.
1934     ;;
1935     *)
1936       AC_MSG_ERROR([Using w32 with an autotools build is only supported for Cygwin and MinGW32.])
1937     ;;
1938   esac
1939 fi
1940
1941 if test "${opsys}" = "mingw32"; then
1942   AC_MSG_CHECKING([whether Windows API headers are recent enough])
1943   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1944      #include <windows.h>
1945      #include <usp10.h>]],
1946    [[PIMAGE_NT_HEADERS pHeader;
1947      PIMAGE_SECTION_HEADER pSection = IMAGE_FIRST_SECTION(pHeader)]])],
1948    [emacs_cv_w32api=yes
1949     HAVE_W32=yes],
1950    emacs_cv_w32api=no)
1951   AC_MSG_RESULT($emacs_cv_w32api)
1952   if test "${emacs_cv_w32api}" = "no"; then
1953     AC_MSG_ERROR([the Windows API headers are too old to support this build.])
1954   fi
1955 fi
1956
1957 FIRSTFILE_OBJ=
1958 NTDIR=
1959 LIBS_ECLIENT=
1960 LIB_WSOCK32=
1961 NTLIB=
1962 CM_OBJ="cm.o"
1963 XARGS_LIMIT=
1964 if test "${HAVE_W32}" = "yes"; then
1965   AC_DEFINE(HAVE_NTGUI, 1, [Define to use native MS Windows GUI.])
1966   if test "$with_toolkit_scroll_bars" = "no"; then
1967     AC_MSG_ERROR([Non-toolkit scroll bars are not implemented for w32 build.])
1968   fi
1969   AC_CHECK_TOOL(WINDRES, [windres],
1970                 [AC_MSG_ERROR([No resource compiler found.])])
1971   W32_OBJ="w32fns.o w32menu.o w32reg.o w32font.o w32term.o"
1972   W32_OBJ="$W32_OBJ w32xfns.o w32select.o w32uniscribe.o"
1973   EMACSRES="emacs.res"
1974   case "$canonical" in
1975     x86_64-*-*) EMACS_MANIFEST="emacs-x64.manifest" ;;
1976     *) EMACS_MANIFEST="emacs-x86.manifest" ;;
1977   esac
1978   dnl Construct something of the form "24,4,0,0" with 4 components.
1979   comma_version=`echo "${PACKAGE_VERSION}.0.0" | sed -e 's/\./,/g' -e 's/^\([[^,]]*,[[^,]]*,[[^,]]*,[[^,]]*\).*/\1/'`
1980
1981   comma_space_version=`echo "$comma_version" | sed 's/,/, /g'`
1982   AC_SUBST(comma_version)
1983   AC_SUBST(comma_space_version)
1984   AC_CONFIG_FILES([nt/emacs.rc nt/emacsclient.rc])
1985   if test "${opsys}" = "cygwin"; then
1986     W32_LIBS="$W32_LIBS -lkernel32 -luser32 -lgdi32 -lole32 -lcomdlg32"
1987     W32_LIBS="$W32_LIBS -lusp10 -lcomctl32 -lwinspool"
1988     # Tell the linker that emacs.res is an object (which we compile from
1989     # the rc file), not a linker script.
1990     W32_RES_LINK="-Wl,emacs.res"
1991   else
1992     UPDATE_MANIFEST=update-game-score.exe.manifest
1993     W32_OBJ="$W32_OBJ w32.o w32console.o w32heap.o w32inevt.o w32proc.o"
1994     W32_LIBS="$W32_LIBS -lwinmm -lgdi32 -lcomdlg32"
1995     W32_LIBS="$W32_LIBS -lmpr -lwinspool -lole32 -lcomctl32 -lusp10"
1996     W32_RES_LINK="\$(EMACSRES)"
1997     CLIENTRES="emacsclient.res"
1998     CLIENTW="emacsclientw\$(EXEEXT)"
1999     FIRSTFILE_OBJ=firstfile.o
2000     NTDIR=nt
2001     CM_OBJ=
2002     LIBS_ECLIENT="-lcomctl32"
2003     LIB_WSOCK32="-lwsock32"
2004     NTLIB="ntlib.$ac_objext"
2005     XARGS_LIMIT="-s 10000"
2006   fi
2007 fi
2008 AC_SUBST(W32_OBJ)
2009 AC_SUBST(W32_LIBS)
2010 AC_SUBST(EMACSRES)
2011 AC_SUBST(EMACS_MANIFEST)
2012 AC_SUBST(UPDATE_MANIFEST)
2013 AC_SUBST(CLIENTRES)
2014 AC_SUBST(CLIENTW)
2015 AC_SUBST(W32_RES_LINK)
2016 AC_SUBST(FIRSTFILE_OBJ)
2017 AC_SUBST(NTDIR)
2018 AC_SUBST(CM_OBJ)
2019 AC_SUBST(LIBS_ECLIENT)
2020 AC_SUBST(LIB_WSOCK32)
2021 AC_SUBST(NTLIB)
2022 AC_SUBST(XARGS_LIMIT)
2023
2024 if test "${HAVE_W32}" = "yes"; then
2025   window_system=w32
2026   with_xft=no
2027 fi
2028
2029 ## $window_system is now set to the window system we will
2030 ## ultimately use.
2031
2032 if test "$window_system" = none && test "$gl_gcc_warnings" = yes; then
2033    # Too many warnings for now.
2034    nw=
2035    nw="$nw -Wsuggest-attribute=noreturn"
2036    gl_MANYWARN_COMPLEMENT([WARN_CFLAGS], [$WARN_CFLAGS], [$nw])
2037
2038    gl_WARN_ADD([-Wno-unused-variable])
2039    gl_WARN_ADD([-Wno-unused-but-set-variable])
2040    gl_WARN_ADD([-Wno-unused-but-set-parameter])
2041 fi
2042
2043 term_header=
2044 HAVE_X_WINDOWS=no
2045 HAVE_X11=no
2046 USE_X_TOOLKIT=none
2047
2048 case "${window_system}" in
2049   x11 )
2050     HAVE_X_WINDOWS=yes
2051     HAVE_X11=yes
2052     term_header=xterm.h
2053     case "${with_x_toolkit}" in
2054       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
2055       motif ) USE_X_TOOLKIT=MOTIF ;;
2056       gtk ) with_gtk=yes
2057             term_header=gtkutil.h
2058 dnl Don't set this for GTK.  A lot of tests below assumes Xt when
2059 dnl USE_X_TOOLKIT is set.
2060             USE_X_TOOLKIT=none ;;
2061       gtk2 ) with_gtk2=yes
2062              term_header=gtkutil.h
2063              USE_X_TOOLKIT=none ;;
2064       gtk3 ) with_gtk3=yes
2065              term_header=gtkutil.h
2066              USE_X_TOOLKIT=none ;;
2067       no ) USE_X_TOOLKIT=none ;;
2068 dnl If user did not say whether to use a toolkit, make this decision later:
2069 dnl use the toolkit if we have gtk, or X11R5 or newer.
2070       * ) USE_X_TOOLKIT=maybe ;;
2071     esac
2072   ;;
2073   nextstep )
2074     term_header=nsterm.h
2075   ;;
2076   w32 )
2077     term_header=w32term.h
2078   ;;
2079 esac
2080
2081 if test "$window_system" = none && test "X$with_x" != "Xno"; then
2082    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
2083    if test "$HAVE_XSERVER" = true ||
2084       test -n "$DISPLAY" ||
2085       {
2086         for emacs_libX11 in /usr/lib/libX11.*; do break; done
2087         test "$emacs_libX11" != '/usr/lib/libX11.*'
2088       }
2089    then
2090         AC_MSG_ERROR([You seem to be running X, but no X development libraries
2091 were found.  You should install the relevant development files for X
2092 and for the toolkit you want, such as Gtk+ or Motif.  Also make
2093 sure you have development files for image handling, i.e.
2094 tiff, gif, jpeg, png and xpm.
2095 If you are sure you want Emacs compiled without X window support, pass
2096   --without-x
2097 to configure.])
2098    fi
2099 fi
2100
2101 # Does the opsystem file prohibit the use of the GNU malloc?
2102 # Assume not, until told otherwise.
2103 GNU_MALLOC=yes
2104
2105 AC_CACHE_CHECK(
2106   [whether malloc is Doug Lea style],
2107   [emacs_cv_var_doug_lea_malloc],
2108   [emacs_cv_var_doug_lea_malloc=no
2109    dnl Hooks do not work with address sanitization.
2110    if test "$emacs_cv_sanitize_address" != yes; then
2111      AC_LINK_IFELSE(
2112        [AC_LANG_PROGRAM(
2113           [[#include <malloc.h>
2114             static void hook (void) {}]],
2115           [[malloc_set_state (malloc_get_state ());
2116             __after_morecore_hook = hook;
2117             __malloc_initialize_hook = hook;]])],
2118        [emacs_cv_var_doug_lea_malloc=yes])
2119    fi])
2120 doug_lea_malloc=$emacs_cv_var_doug_lea_malloc
2121
2122 system_malloc=$emacs_cv_sanitize_address
2123
2124 hybrid_malloc=
2125
2126 case "$opsys" in
2127   ## darwin ld insists on the use of malloc routines in the System framework.
2128   darwin | mingw32 | nacl | sol2-10) system_malloc=yes ;;
2129   cygwin) hybrid_malloc=yes;;
2130 esac
2131
2132 if test "${system_malloc}" != yes && test "${doug_lea_malloc}" != yes \
2133    && test "${UNEXEC_OBJ}" = unexelf.o; then
2134   hybrid_malloc=yes
2135 fi
2136
2137 GMALLOC_OBJ=
2138 HYBRID_MALLOC=
2139 if test "${system_malloc}" = "yes"; then
2140   AC_DEFINE([SYSTEM_MALLOC], 1,
2141     [Define to 1 to use the system memory allocator, even if it is not
2142      Doug Lea style.])
2143   GNU_MALLOC=no
2144   GNU_MALLOC_reason="
2145     (The GNU allocators don't work with this system configuration.)"
2146   VMLIMIT_OBJ=
2147 elif test "$hybrid_malloc" = yes; then
2148   AC_DEFINE(HYBRID_MALLOC, 1,
2149     [Define to use gmalloc before dumping and the system malloc after.])
2150   HYBRID_MALLOC=1
2151   GNU_MALLOC=
2152   GNU_MALLOC_reason="only before dumping"
2153   GMALLOC_OBJ=gmalloc.o
2154   VMLIMIT_OBJ=
2155 else
2156   test "$doug_lea_malloc" != "yes" && GMALLOC_OBJ=gmalloc.o
2157   VMLIMIT_OBJ=vm-limit.o
2158
2159   AC_CHECK_HEADERS([sys/vlimit.h])
2160   AC_CACHE_CHECK([for data_start], [emacs_cv_data_start],
2161     [AC_LINK_IFELSE(
2162        [AC_LANG_PROGRAM(
2163          [[extern char data_start[]; char ch;]],
2164          [[return data_start < &ch;]])],
2165        [emacs_cv_data_start=yes],
2166        [emacs_cv_data_start=no])])
2167   if test $emacs_cv_data_start = yes; then
2168     AC_DEFINE([HAVE_DATA_START], 1,
2169       [Define to 1 if data_start is the address of the start
2170        of the main data segment.])
2171   fi
2172 fi
2173 AC_SUBST([HYBRID_MALLOC])
2174 AM_CONDITIONAL([HYBRID_MALLOC_LIB], [test -n "$HYBRID_MALLOC"])
2175 AC_SUBST(GMALLOC_OBJ)
2176 AC_SUBST(VMLIMIT_OBJ)
2177
2178 if test "$doug_lea_malloc" = "yes" && test "$hybrid_malloc" != yes; then
2179   if test "$GNU_MALLOC" = yes ; then
2180     GNU_MALLOC_reason="
2181       (Using Doug Lea's new malloc from the GNU C Library.)"
2182   fi
2183   AC_DEFINE(DOUG_LEA_MALLOC, 1,
2184     [Define to 1 if the system memory allocator is Doug Lea style,
2185      with malloc hooks and malloc_set_state.])
2186
2187   ## Use mmap directly for allocating larger buffers.
2188   ## FIXME this comes from src/s/{gnu,gnu-linux}.h:
2189   ## #ifdef DOUG_LEA_MALLOC; #undef REL_ALLOC; #endif
2190   ## Does the AC_FUNC_MMAP test below make this check unnecessary?
2191   case "$opsys" in
2192     mingw32|gnu*) REL_ALLOC=no ;;
2193   esac
2194 fi
2195
2196 if test x"${REL_ALLOC}" = x; then
2197   REL_ALLOC=${GNU_MALLOC}
2198 fi
2199
2200 use_mmap_for_buffers=no
2201 case "$opsys" in
2202   cygwin|mingw32|irix6-5) use_mmap_for_buffers=yes ;;
2203 esac
2204
2205 AC_FUNC_MMAP
2206 if test $use_mmap_for_buffers = yes; then
2207   AC_DEFINE(USE_MMAP_FOR_BUFFERS, 1, [Define to use mmap to allocate buffer text.])
2208   REL_ALLOC=no
2209 fi
2210
2211 LIBS="$LIBS_SYSTEM $LIBS"
2212
2213 dnl FIXME replace main with a function we actually want from this library.
2214 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
2215
2216 dnl Check for the POSIX thread library.
2217 LIB_PTHREAD=
2218 AC_CHECK_HEADERS_ONCE(pthread.h)
2219 if test "$ac_cv_header_pthread_h" && test "$opsys" != "mingw32"; then
2220   AC_CACHE_CHECK([for pthread library],
2221     [emacs_cv_pthread_lib],
2222     [emacs_cv_pthread_lib=no
2223      OLD_LIBS=$LIBS
2224      for emacs_pthread_lib in 'none needed' -lpthread; do
2225        case $emacs_pthread_lib in
2226          -*) LIBS="$OLD_LIBS $emacs_pthread_lib";;
2227        esac
2228        AC_LINK_IFELSE(
2229          [AC_LANG_PROGRAM(
2230             [[#include <pthread.h>
2231               #include <signal.h>
2232               sigset_t old_mask, new_mask;
2233               void noop (void) {}]],
2234             [[pthread_t th = pthread_self ();
2235               int status = 0;
2236               status += pthread_create (&th, 0, 0, 0);
2237               status += pthread_sigmask (SIG_BLOCK, &new_mask, &old_mask);
2238               status += pthread_kill (th, 0);
2239               #if ! (defined SYSTEM_MALLOC || defined HYBRID_MALLOC \
2240                      || defined DOUG_LEA_MALLOC)
2241               /* Test for pthread_atfork only if gmalloc uses it,
2242                  as older-style hosts like MirBSD 10 lack it.  */
2243               status += pthread_atfork (noop, noop, noop);
2244               #endif
2245               return status;]])],
2246          [emacs_cv_pthread_lib=$emacs_pthread_lib])
2247        LIBS=$OLD_LIBS
2248        if test "$emacs_cv_pthread_lib" != no; then
2249          break
2250        fi
2251      done])
2252   if test "$emacs_cv_pthread_lib" != no; then
2253     AC_DEFINE([HAVE_PTHREAD], 1, [Define to 1 if you have POSIX threads.])
2254     case $emacs_cv_pthread_lib in
2255       -*) LIB_PTHREAD=$emacs_cv_pthread_lib;;
2256     esac
2257     ac_cv_func_pthread_sigmask=yes
2258     # Some systems optimize for single-threaded programs by default, and
2259     # need special flags to disable these optimizations. For example, the
2260     # definition of 'errno' in <errno.h>.
2261     case $opsys in
2262       hpux* | sol*)
2263         AC_DEFINE([_REENTRANT], 1,
2264           [Define to 1 if your system requires this in multithreaded code.]);;
2265       aix4-2)
2266         AC_DEFINE([_THREAD_SAFE], 1,
2267           [Define to 1 if your system requires this in multithreaded code.]);;
2268     esac
2269   fi
2270 fi
2271 AC_SUBST([LIB_PTHREAD])
2272
2273 dnl Check for need for bigtoc support on IBM AIX
2274
2275 case ${host_os} in
2276 aix*)
2277   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
2278     case $GCC in
2279     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
2280     *) gdb_cv_bigtoc=-bbigtoc ;;
2281     esac
2282
2283     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
2284     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[int i;]])], [], [gdb_cv_bigtoc=])
2285   ])
2286   ;;
2287 esac
2288
2289 # Change CFLAGS, CPPFLAGS, and LIBS temporarily so that C_SWITCH_X_SITE
2290 # is for the tests that follow.  We set them back later on.
2291
2292 REAL_CFLAGS="$CFLAGS"
2293 REAL_CPPFLAGS="$CPPFLAGS"
2294 REAL_LIBS="$LIBS"
2295
2296 if test "${HAVE_X11}" = "yes"; then
2297   DEFS="$C_SWITCH_X_SITE $DEFS"
2298   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
2299   LIBS="-lX11 $LIBS"
2300   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
2301   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
2302
2303   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
2304   # This is handled by LD_SWITCH_X_SITE_RPATH during the real build,
2305   # but it's more convenient here to set LD_RUN_PATH since this
2306   # also works on hosts that don't understand LD_SWITCH_X_SITE_RPATH.
2307   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
2308     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
2309     export LD_RUN_PATH
2310   fi
2311
2312   if test "${opsys}" = "gnu-linux"; then
2313     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
2314     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
2315      [[XOpenDisplay ("foo");]])],
2316      [xgnu_linux_first_failure=no],
2317      [xgnu_linux_first_failure=yes])
2318     if test "${xgnu_linux_first_failure}" = "yes"; then
2319       OLD_CPPFLAGS="$CPPFLAGS"
2320       OLD_LIBS="$LIBS"
2321       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
2322       LIBS="$LIBS -b i486-linuxaout"
2323       AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
2324        [[XOpenDisplay ("foo");]])],
2325        [xgnu_linux_second_failure=no],
2326        [xgnu_linux_second_failure=yes])
2327       if test "${xgnu_linux_second_failure}" = "yes"; then
2328         # If we get the same failure with -b, there is no use adding -b.
2329         # So leave it out.  This plays safe.
2330         AC_MSG_RESULT(no)
2331       else
2332         LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
2333         C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
2334         AC_MSG_RESULT(yes)
2335       fi
2336       CPPFLAGS=$OLD_CPPFLAGS
2337       LIBS=$OLD_LIBS
2338     else
2339       AC_MSG_RESULT(no)
2340     fi
2341   fi
2342
2343   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
2344   # header files included from there.
2345   AC_MSG_CHECKING(for Xkb)
2346   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
2347 #include <X11/XKBlib.h>]],
2348         [[XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);]])],
2349         emacs_xkb=yes, emacs_xkb=no)
2350   AC_MSG_RESULT($emacs_xkb)
2351   if test $emacs_xkb = yes; then
2352     AC_DEFINE(HAVE_XKB, 1, [Define to 1 if you have the Xkb extension.])
2353   fi
2354
2355   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
2356 XScreenNumberOfScreen)
2357 fi
2358
2359 if test "${window_system}" = "x11"; then
2360   AC_MSG_CHECKING(X11 version 6)
2361   AC_CACHE_VAL(emacs_cv_x11_version_6,
2362   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>]],
2363 [[#if XlibSpecificationRelease < 6
2364 fail;
2365 #endif
2366 ]])], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
2367   if test $emacs_cv_x11_version_6 = yes; then
2368     AC_MSG_RESULT(6 or newer)
2369     AC_DEFINE(HAVE_X11R6, 1,
2370               [Define to 1 if you have the X11R6 or newer version of Xlib.])
2371     AC_DEFINE(HAVE_X_I18N, 1, [Define if you have usable i18n support.])
2372     ## inoue@ainet.or.jp says Solaris has a bug related to X11R6-style
2373     ## XIM support.
2374     case "$opsys" in
2375       sol2-*) : ;;
2376       *) AC_DEFINE(HAVE_X11R6_XIM, 1,
2377            [Define if you have usable X11R6-style XIM support.])
2378          ;;
2379     esac
2380   else
2381     AC_MSG_RESULT(before 6)
2382   fi
2383 fi
2384
2385
2386 ### Use -lrsvg-2 if available, unless '--with-rsvg=no' is specified.
2387 HAVE_RSVG=no
2388 if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes" || test "${opsys}" = "mingw32"; then
2389   if test "${with_rsvg}" != "no"; then
2390     RSVG_REQUIRED=2.11.0
2391     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
2392
2393     EMACS_CHECK_MODULES([RSVG], [$RSVG_MODULE])
2394     AC_SUBST(RSVG_CFLAGS)
2395     AC_SUBST(RSVG_LIBS)
2396
2397     if test $HAVE_RSVG = yes; then
2398       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
2399       CFLAGS="$CFLAGS $RSVG_CFLAGS"
2400       # Windows loads librsvg dynamically
2401       if test "${opsys}" = "mingw32"; then
2402         RSVG_LIBS=
2403       fi
2404     fi
2405   fi
2406 fi
2407
2408 HAVE_IMAGEMAGICK=no
2409 if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes" || test "${HAVE_W32}" = "yes"; then
2410   if test "${with_imagemagick}" != "no"; then
2411     ## 6.3.5 is the earliest version known to work; see Bug#17339.
2412     ## 6.8.2 makes Emacs crash; see Bug#13867.
2413     IMAGEMAGICK_MODULE="Wand >= 6.3.5 Wand != 6.8.2"
2414     EMACS_CHECK_MODULES([IMAGEMAGICK], [$IMAGEMAGICK_MODULE])
2415     AC_SUBST(IMAGEMAGICK_CFLAGS)
2416     AC_SUBST(IMAGEMAGICK_LIBS)
2417
2418     if test $HAVE_IMAGEMAGICK = yes; then
2419       AC_DEFINE(HAVE_IMAGEMAGICK, 1, [Define to 1 if using imagemagick.])
2420       OLD_CFLAGS=$CFLAGS
2421       OLD_LIBS=$LIBS
2422       CFLAGS="$CFLAGS $IMAGEMAGICK_CFLAGS"
2423       LIBS="$IMAGEMAGICK_LIBS $LIBS"
2424       AC_CHECK_FUNCS(MagickExportImagePixels MagickMergeImageLayers MagickAutoOrientImage)
2425       CFLAGS=$OLD_CFLAGS
2426       LIBS=$OLD_LIBS
2427     fi
2428   fi
2429 fi
2430
2431 AC_CHECK_LIB(anl, getaddrinfo_a, HAVE_GETADDRINFO_A=yes)
2432 if test "${HAVE_GETADDRINFO_A}" = "yes"; then
2433   AC_DEFINE(HAVE_GETADDRINFO_A, 1,
2434 [Define to 1 if you have getaddrinfo_a for asynchronous DNS resolution.])
2435   GETADDRINFO_A_LIBS="-lanl"
2436   AC_SUBST(GETADDRINFO_A_LIBS)
2437 fi
2438
2439 HAVE_GTK=no
2440 GTK_OBJ=
2441 gtk_term_header=$term_header
2442 check_gtk2=no
2443 gtk3_pkg_errors=
2444 if test "${opsys}" != "mingw32"; then
2445   if test "${with_gtk3}" = "yes" || test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
2446     GLIB_REQUIRED=2.28
2447     GTK_REQUIRED=3.0
2448     GTK_MODULES="gtk+-3.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
2449
2450     dnl Checks for libraries.
2451     EMACS_CHECK_MODULES([GTK], [$GTK_MODULES],
2452       [pkg_check_gtk=yes], [pkg_check_gtk=no])
2453     if test "$pkg_check_gtk" = "no" && test "$with_gtk3" = "yes"; then
2454        AC_MSG_ERROR($GTK_PKG_ERRORS)
2455     fi
2456     if test "$pkg_check_gtk" = "yes"; then
2457        AC_DEFINE(HAVE_GTK3, 1, [Define to 1 if using GTK 3 or later.])
2458        GTK_OBJ=emacsgtkfixed.o
2459        gtk_term_header=gtkutil.h
2460        USE_GTK_TOOLKIT="GTK3"
2461        if test "x$ac_enable_gtk_deprecation_warnings" = x; then
2462          AC_DEFINE([GDK_DISABLE_DEPRECATION_WARNINGS], [1],
2463            [Define to 1 to disable GTK+/GDK deprecation warnings.])
2464          AC_DEFINE([GLIB_DISABLE_DEPRECATION_WARNINGS], [1],
2465            [Define to 1 to disable Glib deprecation warnings.])
2466        fi
2467     else
2468        check_gtk2=yes
2469        gtk3_pkg_errors="$GTK_PKG_ERRORS "
2470     fi
2471   fi
2472
2473   if test "${with_gtk2}" = "yes" || test "$check_gtk2" = "yes"; then
2474     GLIB_REQUIRED=2.10
2475     GTK_REQUIRED=2.10
2476     GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
2477
2478     dnl Checks for libraries.
2479     EMACS_CHECK_MODULES([GTK], [$GTK_MODULES],
2480       [pkg_check_gtk=yes], [pkg_check_gtk=no])
2481     if test "$pkg_check_gtk" = "no" &&
2482        { test "$with_gtk" = yes || test "$with_gtk2" = "yes"; }
2483     then
2484       AC_MSG_ERROR($gtk3_pkg_errors$GTK_PKG_ERRORS)
2485     fi
2486     test "$pkg_check_gtk" = "yes" && USE_GTK_TOOLKIT="GTK2"
2487   fi
2488 fi
2489
2490 OLD_CFLAGS=$CFLAGS
2491 OLD_LIBS=$LIBS
2492
2493 if test x"$pkg_check_gtk" = xyes; then
2494
2495   AC_SUBST(GTK_LIBS)
2496   CFLAGS="$CFLAGS $GTK_CFLAGS"
2497   LIBS="$GTK_LIBS $LIBS"
2498   dnl Try to compile a simple GTK program.
2499   AC_MSG_CHECKING([whether GTK compiles])
2500   GTK_COMPILES=no
2501   AC_LINK_IFELSE(
2502     [AC_LANG_PROGRAM(
2503        [[/* Check the Gtk and Glib APIs.  */
2504          #include <gtk/gtk.h>
2505          #include <glib-object.h>
2506          static void
2507          callback (GObject *go, GParamSpec *spec, gpointer user_data)
2508          {}
2509        ]],
2510        [[
2511          GtkSettings *gs = 0;
2512          /* Use G_CALLBACK to make sure function pointers can be cast to void *;
2513             strict C prohibits this.  Use gtk_main_iteration to test that the
2514             libraries are there.  */
2515          if (g_signal_handler_find (G_OBJECT (gs), G_SIGNAL_MATCH_FUNC,
2516                                     0, 0, 0, G_CALLBACK (callback), 0))
2517            gtk_main_iteration ();
2518        ]])],
2519     [GTK_COMPILES=yes])
2520   AC_MSG_RESULT([$GTK_COMPILES])
2521   if test "${GTK_COMPILES}" != "yes"; then
2522     GTK_OBJ=
2523     if test "$USE_X_TOOLKIT" != "maybe"; then
2524       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
2525     fi
2526   else
2527     C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
2528     HAVE_GTK=yes
2529     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
2530     GTK_OBJ="gtkutil.o $GTK_OBJ"
2531     term_header=$gtk_term_header
2532     USE_X_TOOLKIT=none
2533     AC_MSG_WARN([[Your version of Gtk+ will have problems with
2534        closing open displays.  This is no problem if you just use
2535        one display, but if you use more than one and close one of them
2536        Emacs may crash.
2537        See http://bugzilla.gnome.org/show_bug.cgi?id=85715]])
2538     sleep 3
2539   fi
2540
2541 fi
2542 AC_SUBST(GTK_OBJ)
2543
2544
2545 if test "${HAVE_GTK}" = "yes"; then
2546
2547   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
2548   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
2549   if test "$with_toolkit_scroll_bars" != no; then
2550     with_toolkit_scroll_bars=yes
2551   fi
2552
2553   dnl  Check if we have the old file selection dialog declared and
2554   dnl  in the link library.  In 2.x it may be in the library,
2555   dnl  but not declared if deprecated featured has been selected out.
2556   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
2557   HAVE_GTK_FILE_SELECTION=no
2558   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
2559                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
2560 #include <gtk/gtk.h>])
2561   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
2562     AC_CHECK_FUNCS(gtk_file_selection_new)
2563   fi
2564
2565   dnl Same as above for gtk_handle_box.
2566   HAVE_GTK_HANDLE_BOX=no
2567   AC_CHECK_DECL(GTK_TYPE_HANDLE_BOX, HAVE_GTK_HANDLE_BOX=yes,
2568                    HAVE_GTK_HANDLE_BOX=no, [AC_INCLUDES_DEFAULT
2569 #include <gtk/gtk.h>])
2570   if test "$HAVE_GTK_HANDLE_BOX" = yes; then
2571     AC_CHECK_FUNCS(gtk_handle_box_new)
2572   fi
2573
2574   dnl Same as above for gtk_tearoff_menu_item.
2575   HAVE_GTK_TEAROFF_MENU_ITEM=no
2576   AC_CHECK_DECL(GTK_TYPE_TEAROFF_MENU_ITEM, HAVE_GTK_TEAROFF_MENU_ITEM=yes,
2577                    HAVE_GTK_TEAROFF_MENU_ITEM=no, [AC_INCLUDES_DEFAULT
2578 #include <gtk/gtk.h>])
2579   if test "$HAVE_GTK_TEAROFF_MENU_ITEM" = yes; then
2580     AC_CHECK_FUNCS(gtk_tearoff_menu_item_new)
2581   fi
2582
2583   dnl Check for functions introduced in 2.14 and later.
2584   AC_CHECK_FUNCS(gtk_widget_get_window gtk_widget_set_has_window \
2585                  gtk_dialog_get_action_area gtk_widget_get_sensitive \
2586                  gtk_widget_get_mapped gtk_adjustment_get_page_size \
2587                  gtk_orientable_set_orientation \
2588                  gtk_window_set_has_resize_grip)
2589
2590  term_header=gtkutil.h
2591 fi
2592
2593
2594 dnl Enable xwidgets if GTK3 and WebKitGTK+ are available.
2595 HAVE_XWIDGETS=no
2596 XWIDGETS_OBJ=
2597 if test "$with_xwidgets" != "no"; then
2598   test "$USE_GTK_TOOLKIT" = "GTK3" && test "$window_system" != "none" ||
2599     AC_MSG_ERROR([xwidgets requested but gtk3 not used.])
2600
2601   WEBKIT_REQUIRED=1.4.0
2602   WEBKIT_MODULES="webkitgtk-3.0 >= $WEBKIT_REQUIRED"
2603   EMACS_CHECK_MODULES([WEBKIT], [$WEBKIT_MODULES])
2604   HAVE_XWIDGETS=$HAVE_WEBKIT
2605   test $HAVE_XWIDGETS = yes ||
2606     AC_MSG_ERROR([xwidgets requested but WebKitGTK+ not found.])
2607
2608   XWIDGETS_OBJ=xwidget.o
2609   AC_DEFINE([HAVE_XWIDGETS], 1, [Define to 1 if you have xwidgets support.])
2610 fi
2611 AC_SUBST(XWIDGETS_OBJ)
2612
2613 CFLAGS=$OLD_CFLAGS
2614 LIBS=$OLD_LIBS
2615
2616 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
2617 dnl other platforms.
2618 HAVE_DBUS=no
2619 DBUS_OBJ=
2620 if test "${with_dbus}" = "yes"; then
2621    EMACS_CHECK_MODULES([DBUS], [dbus-1 >= 1.0])
2622    if test "$HAVE_DBUS" = yes; then
2623      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
2624      dnl dbus_watch_get_unix_fd has been introduced in D-Bus 1.1.1.
2625      dnl dbus_type_is_valid and dbus_validate_* have been introduced in
2626      dnl D-Bus 1.5.12.
2627      OLD_LIBS=$LIBS
2628      LIBS="$LIBS $DBUS_LIBS"
2629      AC_CHECK_FUNCS(dbus_watch_get_unix_fd \
2630                     dbus_type_is_valid \
2631                     dbus_validate_bus_name \
2632                     dbus_validate_path \
2633                     dbus_validate_interface \
2634                     dbus_validate_member)
2635      LIBS=$OLD_LIBS
2636      DBUS_OBJ=dbusbind.o
2637    fi
2638 fi
2639 AC_SUBST(DBUS_CFLAGS)
2640 AC_SUBST(DBUS_LIBS)
2641 AC_SUBST(DBUS_OBJ)
2642
2643 dnl GSettings has been tested under GNU/Linux only.
2644 HAVE_GSETTINGS=no
2645 if test "${HAVE_X11}" = "yes" && test "${with_gsettings}" = "yes"; then
2646    EMACS_CHECK_MODULES([GSETTINGS], [gio-2.0 >= 2.26])
2647    if test "$HAVE_GSETTINGS" = "yes"; then
2648       old_CFLAGS=$CFLAGS
2649       CFLAGS="$CFLAGS $GSETTINGS_CFLAGS"
2650       old_LIBS=$LIBS
2651       LIBS="$LIBS $GSETTINGS_LIBS"
2652       AC_MSG_CHECKING([whether GSettings is in gio])
2653       AC_LINK_IFELSE(
2654          [AC_LANG_PROGRAM(
2655              [[/* Check that gsettings really is present.  */
2656              #include <glib-object.h>
2657              #include <gio/gio.h>
2658              ]],
2659              [[
2660                GSettings *settings;
2661                GVariant *val = g_settings_get_value (settings, "");
2662              ]])],
2663          [], HAVE_GSETTINGS=no)
2664       AC_MSG_RESULT([$HAVE_GSETTINGS])
2665
2666       if test "$HAVE_GSETTINGS" = "yes"; then
2667         AC_DEFINE(HAVE_GSETTINGS, 1, [Define to 1 if using GSettings.])
2668         SETTINGS_CFLAGS="$GSETTINGS_CFLAGS"
2669         SETTINGS_LIBS="$GSETTINGS_LIBS"
2670       fi
2671       CFLAGS=$old_CFLAGS
2672       LIBS=$old_LIBS
2673    fi
2674 fi
2675
2676 dnl GConf has been tested under GNU/Linux only.
2677 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
2678 HAVE_GCONF=no
2679 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
2680    EMACS_CHECK_MODULES([GCONF], [gconf-2.0 >= 2.13])
2681    if test "$HAVE_GCONF" = yes; then
2682       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
2683       dnl Newer GConf doesn't link with g_objects, so this is not defined.
2684       SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GCONF_CFLAGS"
2685       SETTINGS_LIBS="$SETTINGS_LIBS $GCONF_LIBS"
2686    fi
2687 fi
2688
2689 if test "$HAVE_GSETTINGS" = "yes" || test "$HAVE_GCONF" = "yes"; then
2690     EMACS_CHECK_MODULES([GOBJECT], [gobject-2.0 >= 2.0])
2691     if test "$HAVE_GOBJECT" = "yes"; then
2692        SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GOBJECT_CFLAGS"
2693        SETTINGS_LIBS="$SETTINGS_LIBS $GOBJECT_LIBS"
2694     fi
2695     SAVE_CFLAGS="$CFLAGS"
2696     SAVE_LIBS="$LIBS"
2697     CFLAGS="$SETTINGS_CFLAGS $CFLAGS"
2698     LIBS="$SETTINGS_LIBS $LIBS"
2699     CFLAGS="$SAVE_CFLAGS"
2700     LIBS="$SAVE_LIBS"
2701 fi
2702 AC_SUBST(SETTINGS_CFLAGS)
2703 AC_SUBST(SETTINGS_LIBS)
2704
2705
2706 dnl SELinux is available for GNU/Linux only.
2707 HAVE_LIBSELINUX=no
2708 LIBSELINUX_LIBS=
2709 if test "${with_selinux}" = "yes"; then
2710    AC_CHECK_LIB([selinux], [lgetfilecon], HAVE_LIBSELINUX=yes, HAVE_LIBSELINUX=no)
2711    if test "$HAVE_LIBSELINUX" = yes; then
2712       AC_DEFINE(HAVE_LIBSELINUX, 1, [Define to 1 if using SELinux.])
2713       LIBSELINUX_LIBS=-lselinux
2714    fi
2715 fi
2716 AC_SUBST(LIBSELINUX_LIBS)
2717
2718 HAVE_GNUTLS=no
2719 if test "${with_gnutls}" = "yes" ; then
2720   EMACS_CHECK_MODULES([LIBGNUTLS], [gnutls >= 2.6.6],
2721     [HAVE_GNUTLS=yes], [HAVE_GNUTLS=no])
2722   if test "${HAVE_GNUTLS}" = "yes"; then
2723     AC_DEFINE(HAVE_GNUTLS, 1, [Define if using GnuTLS.])
2724     EMACS_CHECK_MODULES([LIBGNUTLS3], [gnutls >= 3.0.0],
2725       [AC_DEFINE(HAVE_GNUTLS3, 1, [Define if using GnuTLS v3.])], [])
2726   fi
2727
2728   # Windows loads GnuTLS dynamically
2729   if test "${opsys}" = "mingw32"; then
2730     LIBGNUTLS_LIBS=
2731   fi
2732 fi
2733
2734 AC_SUBST(LIBGNUTLS_LIBS)
2735 AC_SUBST(LIBGNUTLS_CFLAGS)
2736
2737 NOTIFY_OBJ=
2738 NOTIFY_SUMMARY=no
2739
2740 dnl MS Windows native file monitor is available for mingw32 only.
2741 case $with_file_notification,$opsys in
2742   w32,cygwin)
2743     AC_MSG_ERROR(['--with-file-notification=w32' was specified, but
2744     this is only supported on MS-Windows native and MinGW32 builds.
2745     Consider using gfile instead.])
2746     ;;
2747   w32,* | yes,mingw32)
2748     AC_CHECK_HEADER(windows.h)
2749     if test "$ac_cv_header_windows_h" = yes ; then
2750        AC_DEFINE(HAVE_W32NOTIFY, 1, [Define to 1 to use w32notify.])
2751        NOTIFY_OBJ=w32notify.o
2752        NOTIFY_SUMMARY="yes (w32)"
2753     fi ;;
2754 esac
2755
2756 dnl inotify is available only on GNU/Linux.
2757 case $with_file_notification,$NOTIFY_OBJ in
2758   inotify, | yes,)
2759     AC_CHECK_HEADER(sys/inotify.h)
2760     if test "$ac_cv_header_sys_inotify_h" = yes ; then
2761         AC_CHECK_FUNC(inotify_init1)
2762         if test "$ac_cv_func_inotify_init1" = yes; then
2763           AC_DEFINE(HAVE_INOTIFY, 1, [Define to 1 to use inotify.])
2764           NOTIFY_OBJ=inotify.o
2765           NOTIFY_SUMMARY="yes -lglibc (inotify)"
2766        fi
2767     fi ;;
2768 esac
2769
2770 dnl kqueue is available on BSD-like systems.
2771 case $with_file_notification,$NOTIFY_OBJ in
2772   kqueue,* | yes,)
2773     EMACS_CHECK_MODULES([KQUEUE], [libkqueue])
2774     if test "$HAVE_KQUEUE" = "yes"; then
2775        AC_DEFINE(HAVE_KQUEUE, 1, [Define to 1 to use kqueue.])
2776        CPPFLAGS="$CPPFLAGS -I/usr/include/kqueue"
2777        NOTIFY_CFLAGS=$KQUEUE_CFLAGS
2778        NOTIFY_LIBS=$KQUEUE_LIBS
2779        NOTIFY_OBJ=kqueue.o
2780        NOTIFY_SUMMARY="yes -lkqueue"
2781     else
2782        AC_SEARCH_LIBS(kqueue, [])
2783        if test "$ac_cv_search_kqueue" != no; then
2784          AC_DEFINE(HAVE_KQUEUE, 1, [Define to 1 to use kqueue.])
2785          NOTIFY_OBJ=kqueue.o
2786          NOTIFY_SUMMARY="yes (kqueue)"
2787        fi
2788     fi ;;
2789 esac
2790
2791 dnl g_file_monitor exists since glib 2.18.  G_FILE_MONITOR_EVENT_MOVED
2792 dnl has been added in glib 2.24.  It has been tested under
2793 dnl GNU/Linux only.
2794 case $with_file_notification,$NOTIFY_OBJ in
2795   gfile,* | yes,)
2796     if test "${HAVE_NS}" = yes; then
2797        AC_MSG_ERROR(['--with-file-notification=gfile' is not supported in NextStep builds.
2798 Consider kqueue instead.])
2799     else
2800        EMACS_CHECK_MODULES([GFILENOTIFY], [gio-2.0 >= 2.24])
2801        if test "$HAVE_GFILENOTIFY" = "yes"; then
2802           AC_DEFINE(HAVE_GFILENOTIFY, 1, [Define to 1 if using GFile.])
2803           NOTIFY_CFLAGS=$GFILENOTIFY_CFLAGS
2804           NOTIFY_LIBS=$GFILENOTIFY_LIBS
2805           NOTIFY_OBJ=gfilenotify.o
2806           NOTIFY_SUMMARY="yes -lgio (gfile)"
2807        fi
2808     fi ;;
2809 esac
2810
2811 case $with_file_notification,$NOTIFY_OBJ in
2812   yes,* | no,* | *,?*) ;;
2813   *) AC_MSG_ERROR([File notification '$with_file_notification' requested but requirements not found.]) ;;
2814 esac
2815
2816 if test -n "$NOTIFY_OBJ"; then
2817    AC_DEFINE(USE_FILE_NOTIFY, 1, [Define to 1 if using file notifications.])
2818 fi
2819 AC_SUBST(NOTIFY_CFLAGS)
2820 AC_SUBST(NOTIFY_LIBS)
2821 AC_SUBST(NOTIFY_OBJ)
2822
2823 dnl Do not put whitespace before the #include statements below.
2824 dnl Older compilers (eg sunos4 cc) choke on it.
2825 HAVE_XAW3D=no
2826 LUCID_LIBW=
2827 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
2828   if test "$with_xaw3d" != no; then
2829     AC_CACHE_VAL(emacs_cv_xaw3d,
2830     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2831 #include <X11/Intrinsic.h>
2832 #include <X11/Xaw3d/Simple.h>]],
2833       [[]])],
2834       [AC_CHECK_LIB(Xaw3d, XawScrollbarSetThumb,
2835                     emacs_cv_xaw3d=yes, emacs_cv_xaw3d=no)],
2836       emacs_cv_xaw3d=no)])
2837   else
2838     emacs_cv_xaw3d=no
2839   fi
2840   if test $emacs_cv_xaw3d = yes; then
2841     AC_MSG_CHECKING(for xaw3d)
2842     AC_MSG_RESULT([yes; using Lucid toolkit])
2843     USE_X_TOOLKIT=LUCID
2844     HAVE_XAW3D=yes
2845     LUCID_LIBW=-lXaw3d
2846     AC_DEFINE(HAVE_XAW3D, 1,
2847               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
2848   else
2849     AC_MSG_CHECKING(for xaw3d)
2850     AC_MSG_RESULT(no)
2851     AC_MSG_CHECKING(for libXaw)
2852     AC_CACHE_VAL(emacs_cv_xaw,
2853     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2854 #include <X11/Intrinsic.h>
2855 #include <X11/Xaw/Simple.h>]],
2856       [[]])],
2857       emacs_cv_xaw=yes,
2858       emacs_cv_xaw=no)])
2859     if test $emacs_cv_xaw = yes; then
2860       AC_MSG_RESULT([yes; using Lucid toolkit])
2861       USE_X_TOOLKIT=LUCID
2862       LUCID_LIBW=-lXaw
2863     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
2864       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
2865     else
2866       AC_MSG_ERROR([No X toolkit could be found.
2867 If you are sure you want Emacs compiled without an X toolkit, pass
2868   --with-x-toolkit=no
2869 to configure.  Otherwise, install the development libraries for the toolkit
2870 that you want to use (e.g. Gtk+) and re-run configure.])
2871     fi
2872   fi
2873 fi
2874
2875 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
2876
2877 LIBXTR6=
2878 LIBXMU=
2879 if test "${USE_X_TOOLKIT}" != "none"; then
2880   AC_MSG_CHECKING(X11 toolkit version)
2881   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
2882   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Intrinsic.h>]],
2883 [[#if XtSpecificationRelease < 6
2884 fail;
2885 #endif
2886 ]])], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
2887   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
2888   if test $emacs_cv_x11_toolkit_version_6 = yes; then
2889     AC_MSG_RESULT(6 or newer)
2890     AC_DEFINE(HAVE_X11XTR6, 1,
2891               [Define to 1 if you have the X11R6 or newer version of Xt.])
2892     LIBXTR6="-lSM -lICE"
2893     case "$opsys" in
2894       ## Use libw.a along with X11R6 Xt.
2895       unixware) LIBXTR6="$LIBXTR6 -lw" ;;
2896     esac
2897   else
2898     AC_MSG_RESULT(before 6)
2899   fi
2900
2901 dnl If using toolkit, check whether libXmu.a exists.
2902 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
2903   OLDLIBS="$LIBS"
2904   if test x$HAVE_X11XTR6 = xyes; then
2905     OTHERLIBS='-lXt -lSM -lICE'
2906   else
2907     OTHERLIBS='-lXt'
2908   fi
2909   AC_SEARCH_LIBS([XmuConvertStandardSelection], [Xmu], [], [], [$OTHERLIBS])
2910   if test "X$LIBS" != "X$OLDLIBS"; then
2911     LIBXMU=$ac_cv_search_XmuConvertStandardSelection
2912   fi
2913   LIBS=$OLDLIBS
2914   dnl ac_cv_search_XmuConvertStandardSelection is also referenced below.
2915 fi
2916 AC_SUBST(LIBXTR6)
2917 AC_SUBST(LIBXMU)
2918
2919 LIBXP=
2920 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2921   # OpenMotif may be installed in such a way on some GNU/Linux systems.
2922   if test -d /usr/include/openmotif; then
2923     CPPFLAGS="-I/usr/include/openmotif $CPPFLAGS"
2924     emacs_cv_openmotif=yes
2925     case "$canonical" in
2926       x86_64-*-linux-gnu* | powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*)
2927       test -d /usr/lib64/openmotif && LDFLAGS="-L/usr/lib64/openmotif $LDFLAGS"
2928       ;;
2929       *)
2930       test -d /usr/lib/openmotif && LDFLAGS="-L/usr/lib/openmotif $LDFLAGS"
2931     esac
2932   else
2933     emacs_cv_openmotif=no
2934   fi
2935   AC_CACHE_CHECK(for (Open)Motif version 2.1, emacs_cv_motif_version_2_1,
2936   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <Xm/Xm.h>]],
2937     [[#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
2938 int x = 5;
2939 #else
2940 Motif version prior to 2.1.
2941 #endif]])],
2942     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
2943   if test $emacs_cv_motif_version_2_1 = yes; then
2944     AC_CHECK_LIB(Xp, XpCreateContext, LIBXP=-lXp)
2945     if test x$emacs_cv_openmotif = xyes; then
2946       REAL_CPPFLAGS="-I/usr/include/openmotif $REAL_CPPFLAGS"
2947     fi
2948   else
2949     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
2950     # We put this in CFLAGS temporarily to precede other -I options
2951     # that might be in CFLAGS temporarily.
2952     # We put this in CPPFLAGS where it precedes the other -I options.
2953     OLD_CPPFLAGS=$CPPFLAGS
2954     OLD_CFLAGS=$CFLAGS
2955     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
2956     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
2957     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>]],
2958       [[int x = 5;]])],
2959       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
2960     if test $emacs_cv_lesstif = yes; then
2961       # Make sure this -I option remains in CPPFLAGS after it is set
2962       # back to REAL_CPPFLAGS.
2963       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
2964       # have those other -I options anyway.  Ultimately, having this
2965       # directory ultimately in CPPFLAGS will be enough.
2966       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
2967       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
2968     else
2969       CFLAGS=$OLD_CFLAGS
2970       CPPFLAGS=$OLD_CPPFLAGS
2971     fi
2972   fi
2973   AC_CHECK_HEADER([Xm/BulletinB.h], [],
2974     [AC_MSG_ERROR([Motif toolkit requested but requirements not found.])])
2975 fi
2976
2977 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
2978 dnl using Motif or Xaw3d is available, and unless
2979 dnl --with-toolkit-scroll-bars=no was specified.
2980
2981 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
2982             [Define to 1 if we should use toolkit scroll bars.])dnl
2983 USE_TOOLKIT_SCROLL_BARS=no
2984 if test "${with_toolkit_scroll_bars}" != "no"; then
2985   if test "${USE_X_TOOLKIT}" != "none"; then
2986     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2987       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2988       HAVE_XAW3D=no
2989       USE_TOOLKIT_SCROLL_BARS=yes
2990     elif test "${HAVE_XAW3D}" = "yes" || test "${USE_X_TOOLKIT}" = "LUCID"; then
2991       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2992       USE_TOOLKIT_SCROLL_BARS=yes
2993     fi
2994   elif test "${HAVE_GTK}" = "yes"; then
2995     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2996     USE_TOOLKIT_SCROLL_BARS=yes
2997   elif test "${HAVE_NS}" = "yes"; then
2998     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2999     USE_TOOLKIT_SCROLL_BARS=yes
3000   elif test "${HAVE_W32}" = "yes"; then
3001     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
3002     USE_TOOLKIT_SCROLL_BARS=yes
3003   fi
3004 fi
3005
3006 dnl See if XIM is available.
3007 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
3008           #include <X11/Xlib.h>
3009           #include <X11/Xresource.h>]],
3010          [[XIMProc  callback;]])],
3011          [HAVE_XIM=yes
3012          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
3013          HAVE_XIM=no)
3014
3015 dnl '--with-xim' now controls only the initial value of use_xim at run time.
3016
3017 if test "${with_xim}" != "no"; then
3018   AC_DEFINE(USE_XIM, 1,
3019             [Define to 1 if we should use XIM, if it is available.])
3020 fi
3021
3022
3023 if test "${HAVE_XIM}" != "no"; then
3024   late_CFLAGS=$CFLAGS
3025   if test "$GCC" = yes; then
3026     CFLAGS="$CFLAGS --pedantic-errors"
3027   fi
3028   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
3029 #include <X11/Xlib.h>
3030 #include <X11/Xresource.h>]],
3031 [[Display *display;
3032 XrmDatabase db;
3033 char *res_name;
3034 char *res_class;
3035 XIMProc  callback;
3036 XPointer *client_data;
3037 #ifndef __GNUC__
3038 /* If we're not using GCC, it's probably not XFree86, and this is
3039    probably right, but we can't use something like --pedantic-errors.  */
3040 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
3041                                            char*, XIMProc, XPointer*);
3042 #endif
3043 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
3044    client_data);]])],
3045     [emacs_cv_arg6_star=yes])
3046   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
3047          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
3048 either XPointer or XPointer*.])dnl
3049   if test "$emacs_cv_arg6_star" = yes; then
3050     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
3051   else
3052     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
3053   fi
3054   CFLAGS=$late_CFLAGS
3055 fi
3056
3057 ### Start of font-backend (under any platform) section.
3058 # (nothing here yet -- this is a placeholder)
3059 ### End of font-backend (under any platform) section.
3060
3061 ### Start of font-backend (under X11) section.
3062 if test "${HAVE_X11}" = "yes"; then
3063     ## Use -lXft if available, unless '--with-xft=no'.
3064     HAVE_XFT=maybe
3065     if test "x${with_x}" = "xno"; then
3066       with_xft="no";
3067     fi
3068
3069     if test "$with_xft" != no; then
3070       EMACS_CHECK_MODULES([FONTCONFIG], [fontconfig >= 2.2.0])
3071       with_xft=$HAVE_FONTCONFIG
3072     fi
3073
3074     if test "x${with_xft}" != "xno"; then
3075
3076       EMACS_CHECK_MODULES([XFT], [xft >= 0.13.0], [], [HAVE_XFT=no])
3077       ## Because xftfont.c uses XRenderQueryExtension, we also
3078       ## need to link to -lXrender.
3079       HAVE_XRENDER=no
3080       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
3081       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
3082         OLD_CPPFLAGS="$CPPFLAGS"
3083         OLD_CFLAGS="$CFLAGS"
3084         OLD_LIBS="$LIBS"
3085         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
3086         CFLAGS="$CFLAGS $XFT_CFLAGS"
3087         XFT_LIBS="-lXrender $XFT_LIBS"
3088         LIBS="$XFT_LIBS $LIBS"
3089         AC_CHECK_HEADER(X11/Xft/Xft.h,
3090           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS) , ,
3091           [[#include <X11/X.h>]])
3092
3093         if test "${HAVE_XFT}" = "yes"; then
3094           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
3095             AC_SUBST(XFT_LIBS)
3096           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
3097         fi                        # "${HAVE_XFT}" = "yes"
3098         CPPFLAGS=$OLD_CPPFLAGS
3099         CFLAGS=$OLD_CFLAGS
3100         LIBS=$OLD_LIBS
3101       fi                          # "$HAVE_XFT" != no
3102     fi                            # "x${with_xft}" != "xno"
3103
3104     ## We used to allow building with FreeType and without Xft.
3105     ## However, the ftx font backend driver is not in good shape.
3106     if test "$HAVE_XFT" != "yes"; then
3107        dnl For the "Does Emacs use" message at the end.
3108        HAVE_XFT=no
3109        HAVE_FREETYPE=no
3110     else
3111        dnl Strict linkers fail with
3112        dnl ftfont.o: undefined reference to symbol 'FT_New_Face'
3113        dnl if -lfreetype is not specified.
3114        dnl The following is needed to set FREETYPE_LIBS.
3115        EMACS_CHECK_MODULES([FREETYPE], [freetype2])
3116
3117        test "$HAVE_FREETYPE" = "no" && AC_MSG_ERROR(libxft requires libfreetype)
3118     fi
3119
3120     HAVE_LIBOTF=no
3121     if test "${HAVE_FREETYPE}" = "yes"; then
3122       AC_DEFINE(HAVE_FREETYPE, 1,
3123                 [Define to 1 if using the freetype and fontconfig libraries.])
3124       if test "${with_libotf}" != "no"; then
3125         EMACS_CHECK_MODULES([LIBOTF], [libotf])
3126         if test "$HAVE_LIBOTF" = "yes"; then
3127           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
3128           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
3129                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
3130                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
3131           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
3132             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
3133                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
3134           fi
3135         fi
3136       fi
3137     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
3138     dnl Does the new font backend require it, or can it work without it?
3139     fi
3140
3141     HAVE_M17N_FLT=no
3142     if test "${HAVE_LIBOTF}" = yes; then
3143       if test "${with_m17n_flt}" != "no"; then
3144         EMACS_CHECK_MODULES([M17N_FLT], [m17n-flt])
3145         if test "$HAVE_M17N_FLT" = "yes"; then
3146           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
3147         fi
3148       fi
3149     fi
3150 else
3151     HAVE_XFT=no
3152     HAVE_FREETYPE=no
3153     HAVE_LIBOTF=no
3154     HAVE_M17N_FLT=no
3155 fi
3156
3157 ### End of font-backend (under X11) section.
3158
3159 AC_SUBST(FREETYPE_CFLAGS)
3160 AC_SUBST(FREETYPE_LIBS)
3161 AC_SUBST(FONTCONFIG_CFLAGS)
3162 AC_SUBST(FONTCONFIG_LIBS)
3163 AC_SUBST(LIBOTF_CFLAGS)
3164 AC_SUBST(LIBOTF_LIBS)
3165 AC_SUBST(M17N_FLT_CFLAGS)
3166 AC_SUBST(M17N_FLT_LIBS)
3167
3168 HAVE_CAIRO=no
3169 if test "${HAVE_X11}" = "yes"; then
3170   if test "${with_cairo}" != "no"; then
3171     CAIRO_REQUIRED=1.12.0
3172     CAIRO_MODULE="cairo >= $CAIRO_REQUIRED"
3173     EMACS_CHECK_MODULES(CAIRO, $CAIRO_MODULE)
3174     if test $HAVE_CAIRO = yes; then
3175       AC_DEFINE(USE_CAIRO, 1, [Define to 1 if using cairo.])
3176     else
3177       AC_MSG_ERROR([cairo requested but not found.])
3178     fi
3179
3180     CFLAGS="$CFLAGS $CAIRO_CFLAGS"
3181     LIBS="$LIBS $CAIRO_LIBS"
3182     AC_SUBST(CAIRO_CFLAGS)
3183     AC_SUBST(CAIRO_LIBS)
3184   fi
3185 fi
3186
3187 if test "${HAVE_X11}" = "yes"; then
3188   AC_CHECK_HEADER(X11/Xlib-xcb.h,
3189     AC_CHECK_LIB(xcb, xcb_translate_coordinates, HAVE_XCB=yes))
3190   if test "${HAVE_XCB}" = "yes"; then
3191     AC_CHECK_LIB(X11-xcb, XGetXCBConnection, HAVE_X11_XCB=yes)
3192     if test "${HAVE_X11_XCB}" = "yes"; then
3193       AC_DEFINE(USE_XCB, 1,
3194 [Define to 1 if you have the XCB library and X11-XCB library for mixed
3195    X11/XCB programming.])
3196       XCB_LIBS="-lX11-xcb -lxcb"
3197       AC_SUBST(XCB_LIBS)
3198     fi
3199   fi
3200 fi
3201
3202 ### Use -lXpm if available, unless '--with-xpm=no'.
3203 ### mingw32 doesn't use -lXpm, since it loads the library dynamically.
3204 ### In the Cygwin-w32 build, we need to use /usr/include/noX/X11/xpm.h
3205 ### rather than /usr/include/X11/xpm.h, so we set CPPFLAGS (and
3206 ### LDFLAGS) accordingly.
3207 HAVE_XPM=no
3208 LIBXPM=
3209 if test "${HAVE_W32}" = "yes" && test "${opsys}" = "cygwin"; then
3210   if test "${with_xpm}" != "no"; then
3211     SAVE_CPPFLAGS="$CPPFLAGS"
3212     SAVE_LDFLAGS="$LDFLAGS"
3213     CPPFLAGS="$CPPFLAGS -I/usr/include/noX"
3214     LDFLAGS="$LDFLAGS -L/usr/lib/noX"
3215     AC_CHECK_HEADER(X11/xpm.h,
3216       [AC_CHECK_LIB(Xpm, XpmReadFileToImage, HAVE_XPM=yes)])
3217     if test "${HAVE_XPM}" = "yes"; then
3218       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
3219       AC_EGREP_CPP(no_return_alloc_pixels,
3220       [#include "X11/xpm.h"
3221 #ifndef XpmReturnAllocPixels
3222 no_return_alloc_pixels
3223 #endif
3224       ], HAVE_XPM=no, HAVE_XPM=yes)
3225
3226       if test "${HAVE_XPM}" = "yes"; then
3227         REAL_CPPFLAGS="$REAL_CPPFLAGS -I/usr/include/noX"
3228         AC_MSG_RESULT(yes)
3229       else
3230         AC_MSG_RESULT(no)
3231         CPPFLAGS="$SAVE_CPPFLAGS"
3232         LDFLAGS="$SAVE_LDFLAGS"
3233       fi
3234     fi
3235   fi
3236
3237   if test "${HAVE_XPM}" = "yes"; then
3238     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
3239     LIBXPM=-lXpm
3240   fi
3241 fi
3242
3243 if test "${HAVE_X11}" = "yes"; then
3244   dnl Avoid Xpm on AIX unless requested, as it crashes; see Bug#17598.
3245   test "$opsys$with_xpm_set" = aix4-2 && with_xpm=no
3246
3247   if test "${with_xpm}" != "no"; then
3248     AC_CHECK_HEADER(X11/xpm.h,
3249       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
3250     if test "${HAVE_XPM}" = "yes"; then
3251       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
3252       AC_EGREP_CPP(no_return_alloc_pixels,
3253       [#include "X11/xpm.h"
3254 #ifndef XpmReturnAllocPixels
3255 no_return_alloc_pixels
3256 #endif
3257       ], HAVE_XPM=no, HAVE_XPM=yes)
3258
3259       if test "${HAVE_XPM}" = "yes"; then
3260         AC_MSG_RESULT(yes)
3261       else
3262         AC_MSG_RESULT(no)
3263       fi
3264     fi
3265   fi
3266
3267   if test "${HAVE_XPM}" = "yes"; then
3268     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
3269     LIBXPM=-lXpm
3270   elif test "$opsys,$LUCID_LIBW" = aix4-2,-lXaw; then
3271     dnl AIX -lXaw needs -lXpm linked too; see Bug#17598 Message#152.
3272     LIBXPM=-lXpm
3273   fi
3274 fi
3275
3276 ### FIXME: Perhaps regroup to minimize code duplication due to MinGW's
3277 ### slightly different requirements wrt image libraries (it doesn't
3278 ### use -lXpm because it loads the xpm shared library dynamically at
3279 ### run time).
3280 if test "${opsys}" = "mingw32"; then
3281   if test "${with_xpm}" != "no"; then
3282     AC_CHECK_HEADER(X11/xpm.h, HAVE_XPM=yes, HAVE_XPM=no, [
3283 #define FOR_MSW 1])
3284   fi
3285
3286   if test "${HAVE_XPM}" = "yes"; then
3287     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
3288   fi
3289 fi
3290
3291 AC_SUBST(LIBXPM)
3292
3293 ### Use -ljpeg if available, unless '--with-jpeg=no'.
3294 HAVE_JPEG=no
3295 LIBJPEG=
3296 if test "${with_jpeg}" != "no"; then
3297   AC_CACHE_CHECK([for jpeglib 6b or later],
3298     [emacs_cv_jpeglib],
3299     [OLD_LIBS=$LIBS
3300      for emacs_cv_jpeglib in yes -ljpeg no; do
3301        case $emacs_cv_jpeglib in
3302          yes) ;;
3303          no) break;;
3304          *) LIBS="$LIBS $emacs_cv_jpeglib";;
3305        esac
3306        AC_LINK_IFELSE(
3307          [AC_LANG_PROGRAM(
3308             [[#undef HAVE_STDLIB_H /* Avoid config.h/jpeglib.h collision.  */
3309               #include <stdio.h> /* jpeglib.h needs FILE and size_t.  */
3310               #include <jpeglib.h>
3311               #include <jerror.h>
3312               char verify[JPEG_LIB_VERSION < 62 ? -1 : 1];
3313               struct jpeg_decompress_struct cinfo;
3314             ]],
3315             [[
3316               jpeg_create_decompress (&cinfo);
3317               WARNMS (&cinfo, JWRN_JPEG_EOF);
3318               jpeg_destroy_decompress (&cinfo);
3319             ]])],
3320          [emacs_link_ok=yes],
3321          [emacs_link_ok=no])
3322        LIBS=$OLD_LIBS
3323        test $emacs_link_ok = yes && break
3324      done])
3325   if test "$emacs_cv_jpeglib" != no; then
3326     HAVE_JPEG=yes
3327     AC_DEFINE([HAVE_JPEG], 1,
3328       [Define to 1 if you have the jpeg library (typically -ljpeg).])
3329     ### mingw32 doesn't use -ljpeg, since it loads the library
3330     ### dynamically when needed, and doesn't want a run-time
3331     ### dependency on the jpeglib DLL.
3332     test "$emacs_cv_jpeglib" != yes && test "${opsys}" != "mingw32" \
3333     && LIBJPEG=$emacs_cv_jpeglib
3334   fi
3335 fi
3336 AC_SUBST(LIBJPEG)
3337
3338 HAVE_ZLIB=no
3339 LIBZ=
3340 if test "${with_zlib}" != "no"; then
3341   OLIBS=$LIBS
3342   AC_SEARCH_LIBS([inflateEnd], [z], [HAVE_ZLIB=yes])
3343   LIBS=$OLIBS
3344   case $ac_cv_search_inflateEnd in
3345     -*) LIBZ=$ac_cv_search_inflateEnd ;;
3346   esac
3347 fi
3348 if test "${HAVE_ZLIB}" = "yes"; then
3349   AC_DEFINE([HAVE_ZLIB], 1, [Define to 1 if you have the zlib library (-lz).])
3350   ### mingw32 doesn't use -lz, since it loads the library dynamically.
3351   if test "${opsys}" = "mingw32"; then
3352      LIBZ=
3353   fi
3354 fi
3355 AC_SUBST(LIBZ)
3356
3357 ### Dynamic modules support
3358 LIBMODULES=
3359 HAVE_MODULES=no
3360 MODULES_OBJ=
3361 MODULES_SUFFIX=
3362 if test "${with_modules}" != "no"; then
3363   if test "$opsys" = "gnu-linux"; then
3364     LIBMODULES="-ldl"
3365     MODULES_SUFFIX=".so"
3366     HAVE_MODULES=yes
3367   elif test "$opsys" = "cygwin"; then
3368     MODULES_SUFFIX=".dll"
3369     HAVE_MODULES=yes
3370   elif test "$opsys" = "darwin"; then
3371     MODULES_SUFFIX=".so"
3372     HAVE_MODULES=yes
3373   elif test "$opsys" = "mingw32"; then
3374     MODULES_SUFFIX=".dll"
3375     HAVE_MODULES=yes
3376   else
3377     # BSD system have dlopen in the libc
3378     AC_CHECK_FUNC(dlopen, [MODULES_SUFFIX=".so"]
3379                           [HAVE_MODULES=yes], [])
3380   fi
3381
3382   if test "${HAVE_MODULES}" = no; then
3383     AC_MSG_ERROR([Dynamic modules are not supported on your system])
3384   else
3385     SAVE_LIBS=$LIBS
3386     LIBS="$LIBS $LIBMODULES"
3387     AC_CHECK_FUNCS([dladdr dlfunc])
3388     LIBS=$SAVE_LIBS
3389   fi
3390 fi
3391
3392 if test "${HAVE_MODULES}" = yes; then
3393    MODULES_OBJ="dynlib.o emacs-module.o"
3394    AC_DEFINE(HAVE_MODULES, 1, [Define to 1 if dynamic modules are enabled])
3395    AC_DEFINE_UNQUOTED(MODULES_SUFFIX, "$MODULES_SUFFIX",
3396      [System extension for dynamic libraries])
3397 fi
3398 AC_SUBST(MODULES_OBJ)
3399 AC_SUBST(LIBMODULES)
3400
3401 ### Use -lpng if available, unless '--with-png=no'.
3402 HAVE_PNG=no
3403 LIBPNG=
3404 PNG_CFLAGS=
3405 if test "${NS_IMPL_COCOA}" = yes; then
3406   : # Nothing to do
3407 elif test "${with_png}" != no; then
3408   # mingw32 loads the library dynamically.
3409   if test "$opsys" = mingw32; then
3410     AC_CHECK_HEADER([png.h], [HAVE_PNG=yes])
3411   elif test "${HAVE_X11}" = "yes" || test "${HAVE_W32}" = "yes"; then
3412     AC_MSG_CHECKING([for png])
3413     png_cflags=`(libpng-config --cflags) 2>&AS_MESSAGE_LOG_FD` &&
3414     png_libs=`(libpng-config --libs) 2>&AS_MESSAGE_LOG_FD` || {
3415       # libpng-config does not work; configure by hand.
3416       # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
3417       # in /usr/include/libpng.
3418       if test -r /usr/include/libpng/png.h &&
3419          test ! -r /usr/include/png.h; then
3420         png_cflags=-I/usr/include/libpng
3421       else
3422         png_cflags=
3423       fi
3424       png_libs='-lpng'
3425     }
3426     SAVE_CFLAGS=$CFLAGS
3427     SAVE_LIBS=$LIBS
3428     CFLAGS="$CFLAGS $png_cflags"
3429     LIBS="$png_libs -lz -lm $LIBS"
3430     AC_LINK_IFELSE(
3431       [AC_LANG_PROGRAM([[#include <png.h>]],
3432          [[return !png_get_channels (0, 0);]])],
3433       [HAVE_PNG=yes
3434        PNG_CFLAGS=`AS_ECHO(["$png_cflags"]) | sed -e "$edit_cflags"`
3435        LIBPNG=$png_libs
3436        # $LIBPNG requires explicit -lz in some cases.
3437        # We don't know what those cases are, exactly, so play it safe and
3438        # append -lz to any nonempty $LIBPNG, unless we're already using LIBZ.
3439        if test -n "$LIBPNG" && test -z "$LIBZ"; then
3440          LIBPNG="$LIBPNG -lz"
3441        fi])
3442     CFLAGS=$SAVE_CFLAGS
3443     LIBS=$SAVE_LIBS
3444     AC_MSG_RESULT([$HAVE_PNG])
3445   fi
3446 fi
3447 if test $HAVE_PNG = yes; then
3448   AC_DEFINE([HAVE_PNG], [1], [Define to 1 if you have the png library.])
3449
3450   SAVE_CFLAGS=$CFLAGS
3451   CFLAGS="$CFLAGS $PNG_CFLAGS"
3452   AC_CHECK_DECL([png_longjmp],
3453     [],
3454     [AC_DEFINE([PNG_DEPSTRUCT], [],
3455        [Define to empty to suppress deprecation warnings when building
3456         with --enable-gcc-warnings and with libpng versions before 1.5,
3457         which lack png_longjmp.])],
3458     [[#include <png.h>
3459     ]])
3460   CFLAGS=$SAVE_CFLAGS
3461 fi
3462 AC_SUBST(LIBPNG)
3463 AC_SUBST(PNG_CFLAGS)
3464
3465 ### Use -ltiff if available, unless '--with-tiff=no'.
3466 ### mingw32 doesn't use -ltiff, since it loads the library dynamically.
3467 HAVE_TIFF=no
3468 LIBTIFF=
3469 if test "${opsys}" = "mingw32"; then
3470   if test "${with_tiff}" != "no"; then
3471     AC_CHECK_HEADER(tiffio.h, HAVE_TIFF=yes, HAVE_TIFF=no)
3472   fi
3473   if test "${HAVE_TIFF}" = "yes"; then
3474     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
3475   fi
3476 elif test "${HAVE_X11}" = "yes" || test "${HAVE_W32}" = "yes"; then
3477   if test "${with_tiff}" != "no"; then
3478     AC_CHECK_HEADER(tiffio.h,
3479       [tifflibs="-lz -lm"
3480       # At least one tiff package requires the jpeg library.
3481       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
3482       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
3483   fi
3484
3485   if test "${HAVE_TIFF}" = "yes"; then
3486     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
3487     dnl FIXME -lz -lm, as per libpng?
3488     LIBTIFF=-ltiff
3489   fi
3490 fi
3491 AC_SUBST(LIBTIFF)
3492
3493 ### Use -lgif or -lungif if available, unless '--with-gif=no'.
3494 ### mingw32 doesn't use -lgif/-lungif, since it loads the library dynamically.
3495 HAVE_GIF=no
3496 LIBGIF=
3497 if test "${opsys}" = "mingw32"; then
3498   if test "${with_gif}" != "no"; then
3499     AC_CHECK_HEADER(gif_lib.h, HAVE_GIF=yes, HAVE_GIF=no)
3500   fi
3501   if test "${HAVE_GIF}" = "yes"; then
3502     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
3503   fi
3504 elif test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no" \
3505         || test "${HAVE_W32}" = "yes"; then
3506   AC_CHECK_HEADER(gif_lib.h,
3507 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
3508 # Earlier versions can crash Emacs, but version 5.0 removes EGifPutExtensionLast.
3509     [AC_CHECK_LIB(gif, GifMakeMapObject, HAVE_GIF=yes,
3510         [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])])
3511
3512   if test "$HAVE_GIF" = yes; then
3513     LIBGIF=-lgif
3514   elif test "$HAVE_GIF" = maybe; then
3515 # If gif_lib.h but no libgif, try libungif.
3516     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
3517     test "$HAVE_GIF" = yes && LIBGIF=-lungif
3518   fi
3519
3520   if test "${HAVE_GIF}" = "yes"; then
3521     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
3522   fi
3523 fi
3524 AC_SUBST(LIBGIF)
3525
3526 dnl Check for required libraries.
3527 if test "${HAVE_X11}" = "yes"; then
3528   MISSING=""
3529   WITH_NO=""
3530   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
3531     MISSING="libXpm" && WITH_NO="--with-xpm=no"
3532   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
3533     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
3534   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
3535     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
3536   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
3537     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
3538   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
3539     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
3540
3541   if test "X${MISSING}" != X; then
3542     AC_MSG_ERROR([The following required libraries were not found:
3543     $MISSING
3544 Maybe some development libraries/packages are missing?
3545 If you don't want to link with them give
3546     $WITH_NO
3547 as options to configure])
3548   fi
3549 fi
3550
3551 ### Use -lgpm if available, unless '--with-gpm=no'.
3552 HAVE_GPM=no
3553 LIBGPM=
3554 if test "${with_gpm}" != "no"; then
3555   AC_CHECK_HEADER(gpm.h,
3556     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
3557
3558   if test "${HAVE_GPM}" = "yes"; then
3559     AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
3560     LIBGPM=-lgpm
3561   fi
3562 fi
3563 AC_SUBST(LIBGPM)
3564
3565 dnl Check for malloc/malloc.h on darwin
3566 AC_CHECK_HEADERS_ONCE(malloc/malloc.h)
3567
3568 GNUSTEP_CFLAGS=
3569 ### Use NeXTstep API to implement GUI.
3570 if test "${HAVE_NS}" = "yes"; then
3571   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
3572   if test "${NS_IMPL_COCOA}" = "yes"; then
3573     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
3574   fi
3575   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
3576     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
3577     if test $NS_GNUSTEP_CONFIG != yes; then
3578       # See also .m.o rule in src/Makefile.in.  */
3579       # FIXME: are all these flags really needed?  Document here why.  */
3580       GNUSTEP_CFLAGS="-D_REENTRANT -fPIC -fno-strict-aliasing -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
3581       ## Extra CFLAGS applied to src/*.m files.
3582       GNU_OBJC_CFLAGS="$GNU_OBJC_CFLAGS -fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
3583     fi
3584   fi
3585   OTHER_FILES=ns-app
3586 fi
3587
3588 ### Use session management (-lSM -lICE) if available
3589 HAVE_X_SM=no
3590 LIBXSM=
3591 if test "${HAVE_X11}" = "yes"; then
3592   AC_CHECK_HEADER(X11/SM/SMlib.h,
3593     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
3594
3595   if test "${HAVE_X_SM}" = "yes"; then
3596     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
3597     LIBXSM="-lSM -lICE"
3598   fi
3599 fi
3600 AC_SUBST(LIBXSM)
3601
3602 ### Use XRandr (-lXrandr) if available
3603 HAVE_XRANDR=no
3604 if test "${HAVE_X11}" = "yes"; then
3605   XRANDR_REQUIRED=1.2.2
3606   XRANDR_MODULES="xrandr >= $XRANDR_REQUIRED"
3607   EMACS_CHECK_MODULES([XRANDR], [$XRANDR_MODULES])
3608   if test $HAVE_XRANDR = no; then
3609     # Test old way in case pkg-config doesn't have it (older machines).
3610     # Include Xrender.h by hand to work around bug in older Xrandr.h
3611     # (e.g. RHEL5) and silence (harmless) configure warning (bug#18465).
3612     AC_CHECK_HEADER(X11/extensions/Xrandr.h,
3613       [AC_CHECK_LIB(Xrandr, XRRGetScreenResources, HAVE_XRANDR=yes)],
3614       [], [AC_INCLUDES_DEFAULT
3615 #include <X11/extensions/Xrender.h>])
3616     if test $HAVE_XRANDR = yes; then
3617       XRANDR_LIBS=-lXrandr
3618     fi
3619   fi
3620   if test $HAVE_XRANDR = yes; then
3621     SAVE_CFLAGS="$CFLAGS"
3622     SAVE_LIBS="$LIBS"
3623     CFLAGS="$XRANDR_CFLAGS $CFLAGS"
3624     LIBS="$XRANDR_LIBS $LIBS"
3625     AC_CHECK_FUNCS(XRRGetOutputPrimary XRRGetScreenResourcesCurrent)
3626     CFLAGS="$SAVE_CFLAGS"
3627     LIBS="$SAVE_LIBS"
3628
3629     AC_DEFINE(HAVE_XRANDR, 1, [Define to 1 if you have the XRandr extension.])
3630   fi
3631 fi
3632 AC_SUBST(XRANDR_CFLAGS)
3633 AC_SUBST(XRANDR_LIBS)
3634
3635 ### Use Xinerama (-lXinerama) if available
3636 HAVE_XINERAMA=no
3637 if test "${HAVE_X11}" = "yes"; then
3638   XINERAMA_REQUIRED=1.0.2
3639   XINERAMA_MODULES="xinerama >= $XINERAMA_REQUIRED"
3640   EMACS_CHECK_MODULES([XINERAMA], [$XINERAMA_MODULES])
3641   if test $HAVE_XINERAMA = no; then
3642     # Test old way in case pkg-config doesn't have it (older machines).
3643     AC_CHECK_HEADER(X11/extensions/Xinerama.h,
3644       [AC_CHECK_LIB(Xinerama, XineramaQueryExtension, HAVE_XINERAMA=yes)])
3645     if test $HAVE_XINERAMA = yes; then
3646       XINERAMA_LIBS=-lXinerama
3647     fi
3648   fi
3649   if test $HAVE_XINERAMA = yes; then
3650     AC_DEFINE(HAVE_XINERAMA, 1, [Define to 1 if you have the Xinerama extension.])
3651   fi
3652 fi
3653 AC_SUBST(XINERAMA_CFLAGS)
3654 AC_SUBST(XINERAMA_LIBS)
3655
3656 ### Use Xfixes (-lXfixes) if available
3657 HAVE_XFIXES=no
3658 if test "${HAVE_X11}" = "yes"; then
3659   XFIXES_REQUIRED=4.0.0
3660   XFIXES_MODULES="xfixes >= $XFIXES_REQUIRED"
3661   EMACS_CHECK_MODULES([XFIXES], [$XFIXES_MODULES])
3662   if test $HAVE_XFIXES = no; then
3663     # Test old way in case pkg-config doesn't have it (older machines).
3664     AC_CHECK_HEADER(X11/extensions/Xfixes.h,
3665       [AC_CHECK_LIB(Xfixes, XFixesHideCursor, HAVE_XFIXES=yes)])
3666     if test $HAVE_XFIXES = yes; then
3667       XFIXES_LIBS=-lXfixes
3668     fi
3669   fi
3670   if test $HAVE_XFIXES = yes; then
3671     AC_DEFINE(HAVE_XFIXES, 1, [Define to 1 if you have the Xfixes extension.])
3672   fi
3673 fi
3674 AC_SUBST(XFIXES_CFLAGS)
3675 AC_SUBST(XFIXES_LIBS)
3676
3677 ### Use libxml (-lxml2) if available
3678 ### mingw32 doesn't use -lxml2, since it loads the library dynamically.
3679 HAVE_LIBXML2=no
3680 if test "${with_xml2}" != "no"; then
3681   ### I'm not sure what the version number should be, so I just guessed.
3682   EMACS_CHECK_MODULES([LIBXML2], [libxml-2.0 > 2.6.17])
3683   # Built-in libxml2 on OS X 10.8 lacks libxml-2.0.pc.
3684   if test "${HAVE_LIBXML2}" != "yes" && test "$opsys" = "darwin"; then
3685     SAVE_CPPFLAGS="$CPPFLAGS"
3686     if test -z "$xcsdkdir" -a -n "$XCRUN" -a ! -d /usr/include; then
3687       dnl /usr/include is not found.  Try Xcode SDK dir if it is sane.
3688       xcsdkdir=`$XCRUN --show-sdk-path 2>/dev/null`
3689       case $xcsdkdir in
3690         *[[\\\"\#\$\&\'\`$am_lf\ \      ]]*)
3691         xcsdkdir="" ;;
3692       esac
3693     fi
3694     CPPFLAGS="$CPPFLAGS -I$xcsdkdir/usr/include/libxml2"
3695     AC_CHECK_HEADER(libxml/HTMLparser.h,
3696       [AC_CHECK_DECL(HTML_PARSE_RECOVER, HAVE_LIBXML2=yes, ,
3697                      [#include <libxml/HTMLparser.h>])])
3698     CPPFLAGS="$SAVE_CPPFLAGS"
3699     if test "${HAVE_LIBXML2}" = "yes"; then
3700       LIBXML2_CFLAGS="-I'$xcsdkdir/usr/include/libxml2'"
3701       LIBXML2_LIBS="-lxml2"
3702     fi
3703   fi
3704   if test "${HAVE_LIBXML2}" = "yes"; then
3705     if test "${opsys}" != "mingw32"; then
3706       AC_CHECK_LIB(xml2, htmlReadMemory, HAVE_LIBXML2=yes, HAVE_LIBXML2=no,
3707         [$LIBXML2_LIBS])
3708     else
3709       LIBXML2_LIBS=""
3710     fi
3711     if test "${HAVE_LIBXML2}" = "yes"; then
3712       AC_DEFINE(HAVE_LIBXML2, 1, [Define to 1 if you have the libxml library (-lxml2).])
3713     else
3714       LIBXML2_LIBS=""
3715       LIBXML2_CFLAGS=""
3716     fi
3717   fi
3718 fi
3719 AC_SUBST(LIBXML2_LIBS)
3720 AC_SUBST(LIBXML2_CFLAGS)
3721
3722 # If netdb.h doesn't declare h_errno, we must declare it by hand.
3723 # On MinGW, that is provided by nt/inc/sys/socket.h and w32.c.
3724 if test "${opsys}" = "mingw32"; then
3725   emacs_cv_netdb_declares_h_errno=yes
3726 fi
3727 AC_CACHE_CHECK(whether netdb declares h_errno,
3728                emacs_cv_netdb_declares_h_errno,
3729 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
3730   [[return h_errno;]])],
3731   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
3732 if test $emacs_cv_netdb_declares_h_errno = yes; then
3733   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
3734 fi
3735
3736 # Check for mail-locking functions in a "mail" library.  Probably this should
3737 # have the same check as for liblockfile below.
3738 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
3739 if test $have_mail = yes; then
3740   LIBS_MAIL=-lmail
3741   AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the 'mail' library (-lmail).])
3742
3743   OLD_LIBS=$LIBS
3744   LIBS="$LIBS_MAIL $LIBS"
3745   AC_CHECK_FUNCS(touchlock)
3746   LIBS=$OLD_LIBS
3747 else
3748   LIBS_MAIL=
3749 fi
3750 dnl Debian, at least:
3751 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
3752 if test $have_lockfile = yes; then
3753    LIBS_MAIL=-llockfile
3754    AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the 'lockfile' library (-llockfile).])
3755 else
3756 # If we have the shared liblockfile, assume we must use it for mail
3757 # locking (e.g. Debian).  If we couldn't link against liblockfile
3758 # (no liblockfile.a installed), ensure that we don't need to.
3759   dnl This works for files generally, not just executables.
3760   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
3761   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
3762                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
3763   if test $ac_cv_prog_liblockfile = yes; then
3764     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
3765 This probably means that movemail could lose mail.
3766 There may be a 'development' package to install containing liblockfile.])
3767   fi
3768 fi
3769 AC_CHECK_HEADERS_ONCE(maillock.h)
3770 AC_SUBST(LIBS_MAIL)
3771
3772 ## Define MAIL_USE_FLOCK (or LOCKF) if the mailer uses flock (or lockf) to
3773 ## interlock access to the mail spool.  The alternative is a lock file named
3774 ## /usr/spool/mail/$USER.lock.
3775 mail_lock=no
3776 case "$opsys" in
3777   aix4-2) mail_lock="lockf" ;;
3778
3779   gnu|freebsd|dragonfly|netbsd|openbsd|darwin|irix6-5) mail_lock="flock" ;;
3780
3781   ## On GNU/Linux systems, both methods are used by various mail programs.
3782   ## I assume most people are using newer mailers that have heard of flock.
3783   ## Change this if you need to.
3784   ## Debian contains a patch which says: "On Debian/GNU/Linux systems,
3785   ## configure gets the right answers, and that means *NOT* using flock.
3786   ## Using flock is guaranteed to be the wrong thing. See Debian Policy
3787   ## for details." and then uses '#ifdef DEBIAN'.  Unfortunately the
3788   ## Debian maintainer hasn't provided a clean fix for Emacs.
3789   ## movemail.c will use 'maillock' when MAILDIR, HAVE_LIBMAIL and
3790   ## HAVE_MAILLOCK_H are defined, so the following appears to be the
3791   ## correct logic.  -- fx
3792   ## We must check for HAVE_LIBLOCKFILE too, as movemail does.
3793   ## liblockfile is a Free Software replacement for libmail, used on
3794   ## Debian systems and elsewhere. -rfr.
3795   gnu-*)
3796     mail_lock="flock"
3797     if test $have_mail = yes || test $have_lockfile = yes; then
3798       test $ac_cv_header_maillock_h = yes && mail_lock=no
3799     fi
3800     ;;
3801
3802   mingw32)
3803     mail_lock="none-needed" ;;
3804 esac
3805
3806 BLESSMAIL_TARGET=
3807 case "$mail_lock" in
3808   flock) AC_DEFINE(MAIL_USE_FLOCK, 1, [Define if the mailer uses flock to interlock the mail spool.]) ;;
3809
3810   lockf) AC_DEFINE(MAIL_USE_LOCKF, 1, [Define if the mailer uses lockf to interlock the mail spool.]) ;;
3811
3812   none-needed) ;;
3813
3814   *) BLESSMAIL_TARGET="need-blessmail" ;;
3815 esac
3816 AC_SUBST(BLESSMAIL_TARGET)
3817
3818 OLD_LIBS=$LIBS
3819 LIBS="$LIB_PTHREAD $LIB_MATH $LIBS"
3820 AC_CHECK_FUNCS(accept4 fchdir gethostname \
3821 getrusage get_current_dir_name \
3822 lrand48 random rint \
3823 select getpagesize setlocale newlocale \
3824 getrlimit setrlimit shutdown getaddrinfo \
3825 pthread_sigmask strsignal setitimer \
3826 sendto recvfrom getsockname getpeername getifaddrs freeifaddrs \
3827 gai_strerror sync \
3828 getpwent endpwent getgrent endgrent \
3829 cfmakeraw cfsetspeed copysign __executable_start log2)
3830 LIBS=$OLD_LIBS
3831
3832 dnl No need to check for posix_memalign if aligned_alloc works.
3833 AC_CHECK_FUNCS([aligned_alloc posix_memalign], [break])
3834 AC_CHECK_DECLS([aligned_alloc], [], [], [[#include <stdlib.h>]])
3835
3836 dnl Cannot use AC_CHECK_FUNCS
3837 AC_CACHE_CHECK([for __builtin_unwind_init],
3838                emacs_cv_func___builtin_unwind_init,
3839 [AC_LINK_IFELSE([AC_LANG_PROGRAM([], [__builtin_unwind_init ();])],
3840                 emacs_cv_func___builtin_unwind_init=yes,
3841                 emacs_cv_func___builtin_unwind_init=no)])
3842 if test $emacs_cv_func___builtin_unwind_init = yes; then
3843   AC_DEFINE(HAVE___BUILTIN_UNWIND_INIT, 1,
3844             [Define to 1 if you have the '__builtin_unwind_init' function.])
3845 fi
3846
3847 AC_CHECK_HEADERS_ONCE(sys/un.h)
3848
3849 AC_FUNC_FSEEKO
3850
3851 # UNIX98 PTYs.
3852 AC_CHECK_FUNCS(grantpt)
3853
3854 # PTY-related GNU extensions.
3855 AC_CHECK_FUNCS(getpt posix_openpt)
3856
3857 # Check this now, so that we will NOT find the above functions in ncurses.
3858 # That is because we have not set up to link ncurses in lib-src.
3859 # It's better to believe a function is not available
3860 # than to expect to find it in ncurses.
3861 # Also we need tputs and friends to be able to build at all.
3862 AC_MSG_CHECKING([for library containing tputs])
3863 # Run a test program that contains a call to tputs, a call that is
3864 # never executed.  This tests whether a pre-'main' dynamic linker
3865 # works with the library.  It's too much trouble to actually call
3866 # tputs in the test program, due to portability hassles.  When
3867 # cross-compiling, assume the test program will run if it links.
3868 AC_DEFUN([tputs_link_source], [
3869   AC_LANG_SOURCE(
3870      [[extern void tputs (const char *, int, int (*)(int));
3871        int main (int argc, char **argv)
3872        {
3873           if (argc == 10000)
3874             tputs (argv[0], 0, 0);
3875           return 0;
3876        }]])
3877 ])
3878 if test "${opsys}" = "mingw32"; then
3879   msg='none required'
3880 else
3881   # Maybe curses should be tried earlier?
3882   # See http://debbugs.gnu.org/cgi/bugreport.cgi?bug=9736#35
3883   for tputs_library in '' tinfo ncurses terminfo termcap curses; do
3884     OLIBS=$LIBS
3885     if test -z "$tputs_library"; then
3886       LIBS_TERMCAP=
3887       msg='none required'
3888     else
3889       LIBS_TERMCAP=-l$tputs_library
3890       msg=$LIBS_TERMCAP
3891       LIBS="$LIBS_TERMCAP $LIBS"
3892     fi
3893     AC_RUN_IFELSE([tputs_link_source], [], [msg=no],
3894       [AC_LINK_IFELSE([tputs_link_source], [], [msg=no])])
3895     LIBS=$OLIBS
3896     if test "X$msg" != Xno; then
3897       break
3898     fi
3899   done
3900 fi
3901 AC_MSG_RESULT([$msg])
3902 if test "X$msg" = Xno; then
3903   AC_MSG_ERROR([The required function 'tputs' was not found in any library.
3904 The following libraries were tried (in order):
3905   libtinfo, libncurses, libterminfo, libtermcap, libcurses
3906 Please try installing whichever of these libraries is most appropriate
3907 for your system, together with its header files.
3908 For example, a libncurses-dev(el) or similar package.])
3909 fi
3910
3911 ## Use termcap instead of terminfo?
3912 ## Only true for: freebsd < 40000, ms-w32, msdos, netbsd < 599002500.
3913 TERMINFO=yes
3914 ## FIXME?  In the cases below where we unconditionally set
3915 ## LIBS_TERMCAP="-lncurses", this overrides LIBS_TERMCAP = -ltinfo,
3916 ## if that was found above to have tputs.
3917 ## Should we use the gnu* logic everywhere?
3918 case "$opsys" in
3919   ## darwin: Prevents crashes when running Emacs in Terminal.app under 10.2.
3920   ##  The ncurses library has been moved out of the System framework in
3921   ##  Mac OS X 10.2.  So if configure detects it, set the command-line
3922   ##  option to use it.
3923   darwin) LIBS_TERMCAP="-lncurses" ;;
3924
3925   gnu*) test -z "$LIBS_TERMCAP" && LIBS_TERMCAP="-lncurses" ;;
3926
3927   freebsd)
3928     AC_MSG_CHECKING([whether FreeBSD is new enough to use terminfo])
3929     AC_CACHE_VAL(emacs_cv_freebsd_terminfo,
3930     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <osreldate.h>]],
3931 [[#if __FreeBSD_version < 400000
3932 fail;
3933 #endif
3934 ]])], emacs_cv_freebsd_terminfo=yes, emacs_cv_freebsd_terminfo=no)])
3935
3936     AC_MSG_RESULT($emacs_cv_freebsd_terminfo)
3937
3938     if test $emacs_cv_freebsd_terminfo = yes; then
3939       LIBS_TERMCAP="-lncurses"
3940     else
3941       TERMINFO=no
3942       LIBS_TERMCAP="-ltermcap"
3943     fi
3944     ;;
3945
3946   mingw32)
3947     TERMINFO=no
3948     LIBS_TERMCAP=
3949     ;;
3950
3951   netbsd)
3952     if test "x$LIBS_TERMCAP" != "x-lterminfo"; then
3953       TERMINFO=no
3954       LIBS_TERMCAP="-ltermcap"
3955     fi
3956     ;;
3957
3958   openbsd | dragonfly) LIBS_TERMCAP="-lncurses" ;;
3959
3960   ## hpux: Make sure we get select from libc rather than from libcurses
3961   ##  because libcurses on HPUX 10.10 has a broken version of select.
3962   ##  We used to use -lc -lcurses, but this may be cleaner.
3963   ## FIXME?  But TERMINFO = yes on hpux (it used to be explicitly
3964   # set that way, now it uses the default).  Isn't this a contradiction?
3965   hpux*) LIBS_TERMCAP="-ltermcap" ;;
3966
3967 esac
3968
3969 TERMCAP_OBJ=tparam.o
3970 if test $TERMINFO = yes; then
3971   AC_DEFINE(TERMINFO, 1, [Define to 1 if you use terminfo instead of termcap.])
3972   TERMCAP_OBJ=terminfo.o
3973 fi
3974 if test "X$LIBS_TERMCAP" = "X-lncurses"; then
3975   AC_DEFINE(USE_NCURSES, 1, [Define to 1 if you use ncurses.])
3976 fi
3977 AC_SUBST(LIBS_TERMCAP)
3978 AC_SUBST(TERMCAP_OBJ)
3979
3980 # GNU/Linux-specific timer functions.
3981 AC_CACHE_CHECK([for timerfd interface], [emacs_cv_have_timerfd],
3982   [AC_COMPILE_IFELSE(
3983      [AC_LANG_PROGRAM([[#include <sys/timerfd.h>
3984                       ]],
3985                       [[timerfd_create (CLOCK_REALTIME,
3986                                         TFD_CLOEXEC | TFD_NONBLOCK);
3987                         timerfd_settime (0, TFD_TIMER_ABSTIME, 0, 0);]])],
3988      [emacs_cv_have_timerfd=yes],
3989      [emacs_cv_have_timerfd=no])])
3990 if test "$emacs_cv_have_timerfd" = yes; then
3991   AC_DEFINE([HAVE_TIMERFD], 1,
3992     [Define to 1 if timerfd functions are supported as in GNU/Linux.])
3993 fi
3994
3995 # Alternate stack for signal handlers.
3996 AC_CACHE_CHECK([whether signals can be handled on alternate stack],
3997                [emacs_cv_alternate_stack],
3998   [AC_COMPILE_IFELSE(
3999      [AC_LANG_PROGRAM([[#include <signal.h>
4000                       ]],
4001                       [[stack_t ss;
4002                         struct sigaction sa;
4003                         ss.ss_sp = malloc (SIGSTKSZ);
4004                         ss.ss_size = SIGSTKSZ;
4005                         sa.sa_flags = SA_SIGINFO | SA_ONSTACK;
4006                         sigaltstack (&ss, 0);
4007                         sigaction (SIGSEGV, &sa, 0);]])],
4008      [emacs_cv_alternate_stack=yes],
4009      [emacs_cv_alternate_stack=no])])
4010
4011 # Do we need the Hesiod library to provide the support routines?
4012 dnl FIXME?  Should we be skipping this on Darwin too?
4013 LIBHESIOD=
4014 LIBRESOLV=
4015 if test "$with_hesiod" != no ; then
4016   # Don't set $LIBS here -- see comments above.  FIXME which comments?
4017   resolv=no
4018   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
4019      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
4020                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
4021   if test "$resolv" = yes ; then
4022     RESOLVLIB=-lresolv
4023   else
4024     RESOLVLIB=
4025   fi
4026   hesiod=no
4027   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
4028         hesiod=yes, :, $RESOLVLIB)])
4029
4030   if test x"$hesiod" = xyes; then
4031     LIBHESIOD=-lhesiod
4032     LIBRESOLV=$RESOLVLIB
4033   fi
4034 fi
4035 AC_SUBST(LIBHESIOD)
4036 AC_SUBST(LIBRESOLV)
4037
4038 # These tell us which Kerberos-related libraries to use.
4039 COM_ERRLIB=
4040 CRYPTOLIB=
4041 KRB5LIB=
4042 DESLIB=
4043 KRB4LIB=
4044
4045 if test "${with_kerberos}" != no; then
4046   OLD_LIBS=$LIBS
4047   AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
4048   if test $have_com_err = yes; then
4049     COM_ERRLIB=-lcom_err
4050     LIBS="$COM_ERRLIB $LIBS"
4051   fi
4052   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
4053   if test $have_crypto = yes; then
4054     CRYPTOLIB=-lcrypto
4055     LIBS="$CRYPTOLIB $LIBS"
4056   fi
4057   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
4058   if test $have_k5crypto = yes; then
4059     CRYPTOLIB=-lk5crypto
4060     LIBS="$CRYPTOLIB $LIBS"
4061   fi
4062   AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
4063   if test $have_krb5=yes; then
4064     KRB5LIB=-lkrb5
4065     LIBS="$KRB5LIB $LIBS"
4066   fi
4067   dnl FIXME Simplify.  Does not match 22 logic, thanks to default_off?
4068   if test "${with_kerberos5}" = no; then
4069     AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
4070     if test $have_des425 = yes; then
4071       DESLIB=-ldes425
4072       LIBS="$DESLIB $LIBS"
4073     else
4074       AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
4075       if test $have_des = yes; then
4076         DESLIB=-ldes
4077         LIBS="$DESLIB $LIBS"
4078       fi
4079     fi
4080     AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
4081     if test $have_krb4 = yes; then
4082       KRB4LIB=-lkrb4
4083       LIBS="$KRB4LIB $LIBS"
4084     else
4085       AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
4086       if test $have_krb = yes; then
4087         KRB4LIB=-lkrb
4088         LIBS="$KRB4LIB $LIBS"
4089       fi
4090     fi
4091   fi
4092
4093   if test "${with_kerberos5}" != no; then
4094     AC_CHECK_HEADERS(krb5.h,
4095       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
4096                         [#include <krb5.h>])])
4097   else
4098     AC_CHECK_HEADERS(krb.h,,
4099                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
4100                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
4101   fi
4102   AC_CHECK_HEADERS(com_err.h)
4103   LIBS=$OLD_LIBS
4104 fi
4105
4106 AC_SUBST(COM_ERRLIB)
4107 AC_SUBST(CRYPTOLIB)
4108 AC_SUBST(KRB5LIB)
4109 AC_SUBST(DESLIB)
4110 AC_SUBST(KRB4LIB)
4111
4112 AC_CHECK_HEADERS(valgrind/valgrind.h)
4113
4114 AC_CHECK_MEMBERS([struct unipair.unicode], [], [], [[#include <linux/kd.h>]])
4115
4116 AC_CHECK_FUNCS_ONCE(tzset)
4117
4118 ok_so_far=yes
4119 AC_CHECK_FUNC(socket, , ok_so_far=no)
4120 if test $ok_so_far = yes; then
4121   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
4122 fi
4123 if test $ok_so_far = yes; then
4124   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
4125 fi
4126 if test $ok_so_far = yes; then
4127 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
4128   AC_DEFINE(HAVE_INET_SOCKETS, 1,
4129             [Define to 1 if you have inet sockets.])
4130 fi
4131
4132 AC_FUNC_FORK
4133
4134 AC_CHECK_FUNCS(snprintf)
4135
4136 dnl Check for glib.  This differs from other library checks in that
4137 dnl Emacs need not link to glib unless some other library is already
4138 dnl linking to glib.  Although glib provides no facilities that Emacs
4139 dnl needs for its own purposes, when glib is present Emacs needs to
4140 dnl use primitives like g_main_context_query to avoid clashing with
4141 dnl glib at a low level.
4142 dnl
4143 dnl Check this late, since it depends on $GTK_CFLAGS etc.
4144 XGSELOBJ=
4145 OLDCFLAGS="$CFLAGS"
4146 OLDLIBS="$LIBS"
4147 CFLAGS="$CFLAGS $GTK_CFLAGS $RSVG_CFLAGS $DBUS_CFLAGS $SETTINGS_CFLAGS"
4148 LIBS="$LIBS $GTK_LIBS $RSVG_LIBS $DBUS_LIBS $SETTINGS_LIBS"
4149 CFLAGS="$CFLAGS $NOTIFY_CFLAGS $CAIRO_CFLAGS"
4150 LIBS="$LIBS $NOTIFY_LIBS $CAIRO_LIBS"
4151 AC_MSG_CHECKING([whether GLib is linked in])
4152 AC_LINK_IFELSE([AC_LANG_PROGRAM(
4153         [[#include <glib.h>
4154         ]],
4155         [[g_print ("Hello world");]])],
4156      [links_glib=yes],
4157      [links_glib=no])
4158 AC_MSG_RESULT([$links_glib])
4159 if test "${links_glib}" = "yes"; then
4160   AC_DEFINE(HAVE_GLIB, 1, [Define to 1 if GLib is linked in.])
4161   if test "$HAVE_NS" = no;then
4162     XGSELOBJ=xgselect.o
4163   fi
4164 fi
4165 CFLAGS="$OLDCFLAGS"
4166 LIBS="$OLDLIBS"
4167 AC_SUBST(XGSELOBJ)
4168
4169 dnl Adapted from Haible's version.
4170 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
4171   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
4172     [[char* cs = nl_langinfo(CODESET);]])],
4173     emacs_cv_langinfo_codeset=yes,
4174     emacs_cv_langinfo_codeset=no)
4175   ])
4176 if test $emacs_cv_langinfo_codeset = yes; then
4177   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
4178     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
4179 fi
4180
4181 AC_TYPE_MBSTATE_T
4182
4183 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
4184 dnl how the tty code is related to POSIX and/or other versions of termios.
4185 dnl The following looks like a useful start.
4186 dnl
4187 dnl AC_SYS_POSIX_TERMIOS
4188 dnl if test $ac_cv_sys_posix_termios = yes; then
4189 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
4190 dnl                                and macros for terminal control.])
4191 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
4192 dnl fi
4193
4194 dnl Turned on June 1996 supposing nobody will mind it.
4195 dnl MinGW emulates passwd database, so this feature doesn't make sense there.
4196 if test "${opsys}" != "mingw32"; then
4197    AC_DEFINE(AMPERSAND_FULL_NAME, 1, [Define to use the convention that &
4198      in the full name stands for the login id.])
4199 fi
4200
4201 dnl Everybody supports this, except MS.
4202 dnl Seems like the kind of thing we should be testing for, though.
4203 ## Note: PTYs are broken on darwin <6.  Use at your own risk.
4204 if test "${opsys}" != "mingw32"; then
4205   AC_DEFINE(HAVE_PTYS, 1, [Define if the system supports pty devices.])
4206 fi
4207
4208 dnl Everybody supports this, except MS-DOS.
4209 dnl Seems like the kind of thing we should be testing for, though.
4210 dnl Compare with HAVE_INET_SOCKETS (which is unused...) above.
4211 AC_DEFINE(HAVE_SOCKETS, 1, [Define if the system supports
4212   4.2-compatible sockets.])
4213
4214 AH_TEMPLATE(INTERNAL_TERMINAL, [This is substituted when $TERM is "internal".])
4215
4216 AH_TEMPLATE(NULL_DEVICE, [Name of the file to open to get
4217   a null file, or a data sink.])
4218 if test "${opsys}" = "mingw32"; then
4219   AC_DEFINE(NULL_DEVICE, ["NUL:"])
4220 else
4221   AC_DEFINE(NULL_DEVICE, ["/dev/null"])
4222 fi
4223
4224 if test "${opsys}" = "mingw32"; then
4225   SEPCHAR=';'
4226 else
4227   SEPCHAR=':'
4228 fi
4229 AC_DEFINE_UNQUOTED(SEPCHAR, ['$SEPCHAR'], [Character that separates PATH elements.])
4230 dnl This is for MinGW, and is used in test/Makefile.in.
4231 dnl The MSYS Bash has heuristics for replacing ':' with ';' when it
4232 dnl decides that a command-line argument to be passed to a MinGW program
4233 dnl is a PATH-style list of directories.  But that heuristics plays it
4234 dnl safe, and only does the replacement when it is _absolutely_ sure it
4235 dnl sees a colon-separated list of file names; e.g. ":." is left alone,
4236 dnl which breaks in-tree builds.  So we do this manually instead.
4237 dnl Note that we cannot rely on PATH_SEPARATOR, as that one will always
4238 dnl be computed as ':' in MSYS Bash.
4239 AC_SUBST(SEPCHAR)
4240
4241 dnl Everybody supports this, except MS-DOS.
4242 AC_DEFINE(subprocesses, 1, [Define to enable asynchronous subprocesses.])
4243
4244 AC_DEFINE(USER_FULL_NAME, [pw->pw_gecos], [How to get a user's full name.])
4245
4246
4247 AC_DEFINE(DIRECTORY_SEP, ['/'],
4248   [Character that separates directories in a file name.])
4249
4250 if test "${opsys}" = "mingw32"; then
4251   AC_DEFINE(IS_DEVICE_SEP(_c_), [((_c_) == ':')],
4252     [Returns true if character is a device separator.])
4253
4254   AC_DEFINE(IS_DIRECTORY_SEP(_c_), [((_c_) == '/' || (_c_) == '\\')],
4255     [Returns true if character is a directory separator.])
4256
4257   AC_DEFINE(IS_ANY_SEP(_c_), [(IS_DIRECTORY_SEP (_c_) || IS_DEVICE_SEP(_c_))],
4258     [Returns true if character is any form of separator.])
4259 else
4260   AC_DEFINE(IS_DEVICE_SEP(_c_), 0,
4261     [Returns true if character is a device separator.])
4262
4263   AC_DEFINE(IS_DIRECTORY_SEP(_c_), [((_c_) == DIRECTORY_SEP)],
4264     [Returns true if character is a directory separator.])
4265
4266   AC_DEFINE(IS_ANY_SEP(_c_), [(IS_DIRECTORY_SEP (_c_))],
4267     [Returns true if character is any form of separator.])
4268 fi
4269
4270 AH_TEMPLATE(NO_EDITRES, [Define if XEditRes should not be used.])
4271
4272 case $opsys in
4273   aix4-2)
4274     dnl Unfortunately without libXmu we cannot support EditRes.
4275     if test "x$ac_cv_search_XmuConvertStandardSelection" = xno; then
4276       AC_DEFINE(NO_EDITRES, 1)
4277     fi
4278     ;;
4279
4280   hpux*)
4281     dnl Assar Westerlund <assar@sics.se> says this is necessary for
4282     dnl HP-UX 10.20, and that it works for HP-UX 0 as well.
4283     AC_DEFINE(NO_EDITRES, 1)
4284     ;;
4285 esac
4286
4287
4288 case $opsys in
4289   irix6-5 | sol2* | unixware )
4290     dnl Some SVr4s don't define NSIG in sys/signal.h for ANSI environments;
4291     dnl instead, there's a system variable _sys_nsig.  Unfortunately, we
4292     dnl need the constant to dimension an array.  So wire in the appropriate
4293     dnl value here.
4294     AC_DEFINE(NSIG_MINIMUM, 32, [Minimum value of NSIG.])
4295     ;;
4296 esac
4297
4298 emacs_broken_SIGIO=no
4299
4300 case $opsys in
4301   dnl SIGIO exists, but the feature doesn't work in the way Emacs needs.
4302   dnl See eg <http://article.gmane.org/gmane.os.openbsd.ports/46831>.
4303   hpux* | irix6-5 | nacl | openbsd | sol2* | unixware )
4304     emacs_broken_SIGIO=yes
4305     ;;
4306
4307   aix4-2)
4308     dnl On AIX Emacs uses the gmalloc.c malloc implementation.  But given
4309     dnl the way this system works, libc functions that return malloced
4310     dnl memory use the libc malloc implementation. Calling xfree or
4311     dnl xrealloc on the results of such functions results in a crash.
4312     dnl
4313     dnl One solution for this could be to define SYSTEM_MALLOC in configure,
4314     dnl but that does not currently work on this system.
4315     dnl
4316     dnl It is possible to completely override the malloc implementation on
4317     dnl AIX, but that involves putting the malloc functions in a shared
4318     dnl library and setting the MALLOCTYPE environment variable to point to
4319     dnl that shared library.
4320     dnl
4321     dnl Emacs currently calls xrealloc on the results of get_current_dir name,
4322     dnl to avoid a crash just use the Emacs implementation for that function.
4323     dnl
4324     dnl FIXME We could change the AC_CHECK_FUNCS call near the start
4325     dnl of this file, so that we do not check for get_current_dir_name
4326     dnl on AIX.  But that might be fragile if something else ends
4327     dnl up testing for get_current_dir_name as a dependency.
4328     AC_DEFINE(BROKEN_GET_CURRENT_DIR_NAME, 1, [Define if
4329       get_current_dir_name should not be used.])
4330     ;;
4331
4332   freebsd)
4333     dnl Circumvent a bug in FreeBSD.  In the following sequence of
4334     dnl writes/reads on a PTY, read(2) returns bogus data:
4335     dnl
4336     dnl write(2)  1022 bytes
4337     dnl write(2)   954 bytes, get EAGAIN
4338     dnl read(2)   1024 bytes in process_read_output
4339     dnl read(2)     11 bytes in process_read_output
4340     dnl
4341     dnl That is, read(2) returns more bytes than have ever been written
4342     dnl successfully.  The 1033 bytes read are the 1022 bytes written
4343     dnl successfully after processing (for example with CRs added if the
4344     dnl terminal is set up that way which it is here).  The same bytes will
4345     dnl be seen again in a later read(2), without the CRs.
4346     AC_DEFINE(BROKEN_PTY_READ_AFTER_EAGAIN, 1, [Define on FreeBSD to
4347       work around an issue when reading from a PTY.])
4348     ;;
4349 esac
4350
4351 case $opsys in
4352   gnu-* | sol2-10 )
4353     dnl FIXME Can't we test if this exists (eg /proc/$$)?
4354     AC_DEFINE(HAVE_PROCFS, 1, [Define if you have the /proc filesystem.])
4355   ;;
4356 esac
4357
4358 case $opsys in
4359   darwin | dragonfly | freebsd | netbsd | openbsd )
4360     AC_DEFINE(DONT_REOPEN_PTY, 1, [Define if process.c does not need to
4361       close a pty to make it a controlling terminal (it is already a
4362       controlling terminal of the subprocess, because we did ioctl TIOCSCTTY).])
4363   ;;
4364 esac
4365
4366 dnl FIXME Surely we can test for this rather than hard-code it.
4367 case $opsys in
4368   netbsd | openbsd) sound_device="/dev/audio" ;;
4369   *) sound_device="/dev/dsp" ;;
4370 esac
4371
4372 dnl Used in sound.c
4373 AC_DEFINE_UNQUOTED(DEFAULT_SOUND_DEVICE, "$sound_device",
4374   [Name of the default sound device.])
4375
4376
4377 dnl Emacs can read input using SIGIO and buffering characters itself,
4378 dnl or using CBREAK mode and making C-g cause SIGINT.
4379 dnl The choice is controlled by the variable interrupt_input.
4380 dnl
4381 dnl Define INTERRUPT_INPUT to make interrupt_input = 1 the default (use SIGIO)
4382 dnl
4383 dnl Emacs uses the presence of the USABLE_SIGIO macro
4384 dnl to indicate whether or not signal-driven I/O is possible.  It uses
4385 dnl INTERRUPT_INPUT to decide whether to use it by default.
4386 dnl
4387 dnl SIGIO can be used only on systems that implement it (4.2 and 4.3).
4388 dnl CBREAK mode has two disadvantages
4389 dnl 1) At least in 4.2, it is impossible to handle the Meta key properly.
4390 dnl I hear that in system V this problem does not exist.
4391 dnl 2) Control-G causes output to be discarded.
4392 dnl I do not know whether this can be fixed in system V.
4393 dnl
4394 dnl Another method of doing input is planned but not implemented.
4395 dnl It would have Emacs fork off a separate process
4396 dnl to read the input and send it to the true Emacs process
4397 dnl through a pipe.
4398 case $opsys in
4399   darwin | gnu-linux | gnu-kfreebsd )
4400     AC_DEFINE(INTERRUPT_INPUT, 1, [Define to read input using SIGIO.])
4401   ;;
4402 esac
4403
4404
4405 dnl If the system's imake configuration file defines 'NeedWidePrototypes'
4406 dnl as 'NO', we must define NARROWPROTO manually.  Such a define is
4407 dnl generated in the Makefile generated by 'xmkmf'.  If we don't define
4408 dnl NARROWPROTO, we will see the wrong function prototypes for X functions
4409 dnl taking float or double parameters.
4410 case $opsys in
4411   cygwin|gnu|gnu-linux|gnu-kfreebsd|irix6-5|freebsd|netbsd|openbsd)
4412     AC_DEFINE(NARROWPROTO, 1, [Define if system's imake configuration
4413       file defines 'NeedWidePrototypes' as 'NO'.])
4414   ;;
4415 esac
4416
4417
4418 dnl Used in process.c, this must be a loop, even if it only runs once.
4419 dnl (Except on SGI; see below.  Take that, clarity and consistency!)
4420 AH_TEMPLATE(PTY_ITERATION, [How to iterate over PTYs.])
4421 dnl Only used if !PTY_ITERATION.  Iterate from FIRST_PTY_LETTER to z,
4422 dnl trying suffixes 0-16.
4423 AH_TEMPLATE(FIRST_PTY_LETTER, [Letter to use in finding device name of
4424   first PTY, if PTYs are supported.])
4425 AH_TEMPLATE(PTY_OPEN, [How to open a PTY, if non-standard.])
4426 AH_TEMPLATE(PTY_NAME_SPRINTF, [How to get the device name of the control
4427   end of a PTY, if non-standard.])
4428 AH_TEMPLATE(PTY_TTY_NAME_SPRINTF, [How to get device name of the tty
4429   end of a PTY, if non-standard.])
4430
4431 case $opsys in
4432   aix4-2 )
4433     AC_DEFINE(PTY_ITERATION, [int c; for (c = 0; !c ; c++)])
4434     dnl You allocate a pty by opening /dev/ptc to get the master side.
4435     dnl To get the name of the slave side, you just ttyname() the master side.
4436     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptc");])
4437     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [strcpy (pty_name, ttyname (fd));])
4438     ;;
4439
4440   cygwin )
4441     AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
4442     dnl multi-line AC_DEFINEs are hard. :(
4443     AC_DEFINE(PTY_OPEN, [ do { int dummy; sigset_t blocked, procmask; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, &procmask); if (-1 == openpty (&fd, &dummy, pty_name, 0, 0)) fd = -1; pthread_sigmask (SIG_SETMASK, &procmask, 0); if (fd >= 0) emacs_close (dummy); } while (false)])
4444     AC_DEFINE(PTY_NAME_SPRINTF, [])
4445     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
4446     ;;
4447
4448   gnu | openbsd )
4449     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4450     ;;
4451
4452   gnu-linux | gnu-kfreebsd | dragonfly | freebsd | netbsd | darwin | nacl )
4453     dnl if HAVE_GRANTPT
4454     if test "x$ac_cv_func_grantpt" = xyes; then
4455       AC_DEFINE(UNIX98_PTYS, 1, [Define if the system has Unix98 PTYs.])
4456       AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
4457       dnl Note that grantpt and unlockpt may fork.  We must block SIGCHLD
4458       dnl to prevent sigchld_handler from intercepting the child's death.
4459       AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptyname = 0; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); if (grantpt (fd) != -1 && unlockpt (fd) != -1) ptyname = ptsname(fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (!ptyname) { emacs_close (fd); return -1; } snprintf (pty_name, PTY_NAME_SIZE, "%s", ptyname); }])
4460       dnl if HAVE_POSIX_OPENPT
4461       if test "x$ac_cv_func_posix_openpt" = xyes; then
4462         AC_DEFINE(PTY_OPEN, [do { fd = posix_openpt (O_RDWR | O_CLOEXEC | O_NOCTTY); if (fd < 0 && errno == EINVAL) fd = posix_openpt (O_RDWR | O_NOCTTY); } while (false)])
4463         AC_DEFINE(PTY_NAME_SPRINTF, [])
4464       dnl if HAVE_GETPT
4465       elif test "x$ac_cv_func_getpt" = xyes; then
4466         AC_DEFINE(PTY_OPEN, [fd = getpt ()])
4467         AC_DEFINE(PTY_NAME_SPRINTF, [])
4468       else
4469         AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptmx");])
4470       fi
4471     else
4472       AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4473     fi
4474     ;;
4475
4476   hpux*)
4477     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4478     AC_DEFINE(PTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/ptym/pty%c%x", c, i);])
4479     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/pty/tty%c%x", c, i);])
4480     ;;
4481
4482   irix6-5 )
4483     dnl It looks like this cannot be right, because it is not a loop.
4484     dnl However, process.c actually does this:
4485     dnl # ifndef __sgi
4486     dnl   continue;
4487     dnl # else
4488     dnl   return -1;
4489     dnl # endif
4490     dnl which presumably makes it OK, since irix == sgi (?).
4491     dnl FIXME it seems like this special treatment is unnecessary?
4492     dnl Why can't irix use a single-trip loop like eg cygwin?
4493     AC_DEFINE(PTY_ITERATION, [])
4494     dnl Not used, because PTY_ITERATION is defined.
4495     AC_DEFINE(FIRST_PTY_LETTER, ['q'])
4496     AC_DEFINE(PTY_OPEN, [ { struct sigaction ocstat, cstat; struct stat stb; char * name; sigemptyset(&cstat.sa_mask); cstat.sa_handler = SIG_DFL; cstat.sa_flags = 0; sigaction(SIGCHLD, &cstat, &ocstat); name = _getpty (&fd, O_RDWR | O_NDELAY, 0600, 0); sigaction(SIGCHLD, &ocstat, (struct sigaction *)0); if (name == 0) return -1; if (fd < 0) return -1; if (fstat (fd, &stb) < 0) return -1; strcpy (pty_name, name); }])
4497     dnl No need to get the pty name at all.
4498     AC_DEFINE(PTY_NAME_SPRINTF, [])
4499     dnl No need to use sprintf to get the tty name--we get that from _getpty.
4500     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
4501     ;;
4502
4503   sol2* )
4504     dnl On SysVr4, grantpt(3) forks a subprocess, so do not use
4505     dnl O_CLOEXEC when opening the pty, and keep the SIGCHLD handler
4506     dnl from intercepting that death.  If any child but grantpt's should die
4507     dnl within, it should be caught after sigrelse(2).
4508     AC_DEFINE(PTY_OPEN, [fd = open (pty_name, O_RDWR | O_NONBLOCK)])
4509     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptsname (int), *ptyname; int grantpt_result; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); grantpt_result = grantpt (fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (grantpt_result == -1 || unlockpt (fd) == -1 || !(ptyname = ptsname (fd))) { emacs_close (fd); return -1; } snprintf (pty_name, PTY_NAME_SIZE, "%s", ptyname); }])
4510     ;;
4511
4512   unixware )
4513     dnl Comments are as per sol2*.
4514     AC_DEFINE(PTY_OPEN, [fd = open (pty_name, O_RDWR | O_NONBLOCK)])
4515     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptsname (int), *ptyname; int grantpt_result; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); grantpt_result = grantpt (fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (grantpt_result == -1) fatal("could not grant slave pty"); if (unlockpt(fd) == -1) fatal("could not unlock slave pty"); if (!(ptyname = ptsname(fd))) fatal ("could not enable slave pty"); snprintf (pty_name, PTY_NAME_SIZE, "%s", ptyname); }])
4516     ;;
4517 esac
4518
4519
4520 case $opsys in
4521   sol2* | unixware )
4522     dnl This change means that we don't loop through allocate_pty too
4523     dnl many times in the (rare) event of a failure.
4524     AC_DEFINE(FIRST_PTY_LETTER, ['z'])
4525     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptmx");])
4526     dnl Push various streams modules onto a PTY channel.  Used in process.c.
4527     AC_DEFINE(SETUP_SLAVE_PTY, [if (ioctl (forkin, I_PUSH, "ptem") == -1) fatal ("ioctl I_PUSH ptem"); if (ioctl (forkin, I_PUSH, "ldterm") == -1) fatal ("ioctl I_PUSH ldterm"); if (ioctl (forkin, I_PUSH, "ttcompat") == -1) fatal ("ioctl I_PUSH ttcompat");], [How to set up a slave PTY, if needed.])
4528     ;;
4529 esac
4530
4531
4532 AH_TEMPLATE(SIGNALS_VIA_CHARACTERS, [Make process_send_signal work by
4533 "typing" a signal character on the pty.])
4534
4535 case $opsys in
4536   dnl Perry Smith <pedz@ddivt1.austin.ibm.com> says this is correct for AIX.
4537   dnl thomas@mathematik.uni-bremen.de says this is needed for IRIX.
4538   aix4-2 | cygwin | gnu | irix6-5 | dragonfly | freebsd | netbsd | openbsd | darwin )
4539     AC_DEFINE(SIGNALS_VIA_CHARACTERS, 1)
4540     ;;
4541
4542   dnl 21 Jun 06: Eric Hanchrow <offby1@blarg.net> says this works.
4543   dnl FIXME Does gnu-kfreebsd have linux/version.h?  It seems unlikely...
4544   gnu-linux | gnu-kfreebsd )
4545
4546     AC_MSG_CHECKING([for signals via characters])
4547     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4548 #include <linux/version.h>
4549 #if LINUX_VERSION_CODE < 0x20400
4550 # error "Linux version too old"
4551 #endif
4552       ]], [[]])], emacs_signals_via_chars=yes, emacs_signals_via_chars=no)
4553
4554     AC_MSG_RESULT([$emacs_signals_via_chars])
4555     test $emacs_signals_via_chars = yes && AC_DEFINE(SIGNALS_VIA_CHARACTERS, 1)
4556     ;;
4557 esac
4558
4559
4560 AH_TEMPLATE(TAB3, [Undocumented.])
4561
4562 case $opsys in
4563   darwin) AC_DEFINE(TAB3, OXTABS) ;;
4564
4565   gnu | dragonfly | freebsd | netbsd | openbsd )
4566     AC_DEFINE(TABDLY, OXTABS, [Undocumented.])
4567     AC_DEFINE(TAB3, OXTABS)
4568     ;;
4569
4570   gnu-linux | gnu-kfreebsd )
4571     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4572 #ifndef __ia64__
4573 # error "not ia64"
4574 #endif
4575       ]], [[]])], AC_DEFINE(GC_MARK_SECONDARY_STACK(),
4576         [do { extern void *__libc_ia64_register_backing_store_base; __builtin_ia64_flushrs (); mark_memory (__libc_ia64_register_backing_store_base, __builtin_ia64_bsp ());} while (false)],
4577         [Mark a secondary stack, like the register stack on the ia64.]), [])
4578     ;;
4579
4580   hpux*)
4581     AC_DEFINE(RUN_TIME_REMAP, 1, [Define if emacs.c needs to call
4582       run_time_remap; for HPUX.])
4583     ;;
4584 esac
4585
4586
4587 dnl This won't be used automatically yet.  We also need to know, at least,
4588 dnl that the stack is continuous.
4589 AH_TEMPLATE(GC_SETJMP_WORKS, [Define if setjmp is known to save all
4590   registers relevant for conservative garbage collection in the jmp_buf.])
4591
4592
4593 case $opsys in
4594   dnl Not all the architectures are tested, but there are Debian packages
4595   dnl for SCM and/or Guile on them, so the technique must work.  See also
4596   dnl comments in alloc.c concerning setjmp and gcc.
4597   dnl Fixme: it's probably safe to just use the GCC conditional below.
4598   gnu-linux | gnu-kfreebsd )
4599     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4600 #if defined __i386__ || defined __sparc__ || defined __mc68000__ \
4601   || defined __alpha__ || defined __mips__ || defined __s390__ \
4602   || defined __arm__ || defined __powerpc__ || defined __amd64__ \
4603   || defined __ia64__ || defined __sh__
4604 /* ok */
4605 #else
4606 # error "setjmp not known to work on this arch"
4607 #endif
4608     ]], [[]])], AC_DEFINE(GC_SETJMP_WORKS, 1))
4609     ;;
4610 esac
4611
4612
4613 if test x$GCC = xyes; then
4614    dnl GC_SETJMP_WORKS is nearly always appropriate for GCC.
4615    AC_DEFINE(GC_SETJMP_WORKS, 1)
4616 else
4617   case $opsys in
4618     dnl irix: Tested on Irix 6.5.  SCM worked on earlier versions.
4619     aix* | dragonfly | freebsd | netbsd | openbsd | irix6-5 | sol2* )
4620       AC_DEFINE(GC_SETJMP_WORKS, 1)
4621       ;;
4622   esac
4623 fi                              dnl GCC?
4624
4625 dnl In a weird quirk, MS runtime uses _setjmp and longjmp.
4626 AC_CACHE_CHECK([for _setjmp], [emacs_cv_func__setjmp],
4627   [AC_LINK_IFELSE(
4628      [AC_LANG_PROGRAM(
4629        [[#include <setjmp.h>
4630          #ifdef __MINGW32__
4631          # define _longjmp longjmp
4632          #endif
4633        ]],
4634        [[jmp_buf j;
4635          if (! _setjmp (j))
4636            _longjmp (j, 1);]])],
4637      [emacs_cv_func__setjmp=yes],
4638      [emacs_cv_func__setjmp=no])])
4639 if test $emacs_cv_func__setjmp = yes; then
4640   AC_DEFINE([HAVE__SETJMP], 1, [Define to 1 if _setjmp and _longjmp work.])
4641 fi
4642
4643 # We need to preserve signal mask to handle C stack overflows.
4644 AC_CACHE_CHECK([for sigsetjmp], [emacs_cv_func_sigsetjmp],
4645   [AC_LINK_IFELSE(
4646      [AC_LANG_PROGRAM(
4647        [[#include <setjmp.h>
4648        ]],
4649        [[sigjmp_buf j;
4650          if (! sigsetjmp (j, 1))
4651            siglongjmp (j, 1);]])],
4652      [emacs_cv_func_sigsetjmp=yes],
4653      [emacs_cv_func_sigsetjmp=no])])
4654 if test $emacs_cv_func_sigsetjmp = yes; then
4655   AC_DEFINE([HAVE_SIGSETJMP], 1,
4656     [Define to 1 if sigsetjmp and siglongjmp work.])
4657 fi
4658
4659 case $emacs_cv_func_sigsetjmp,$emacs_cv_alternate_stack,$opsys in
4660   yes,yes,* | *,*,mingw32)
4661     AC_DEFINE([HAVE_STACK_OVERFLOW_HANDLING], 1,
4662       [Define to 1 if C stack overflow can be handled in some cases.]);;
4663 esac
4664
4665 case $opsys in
4666   sol2* | unixware )
4667     dnl TIOCGPGRP is broken in SysVr4, so we can't send signals to PTY
4668     dnl subprocesses the usual way.  But TIOCSIGNAL does work for PTYs,
4669     dnl and this is all we need.
4670     AC_DEFINE(TIOCSIGSEND, TIOCSIGNAL, [Some platforms redefine this.])
4671     ;;
4672 esac
4673
4674
4675 case $opsys in
4676   hpux* | sol2* )
4677     dnl Used in xfaces.c.
4678     AC_DEFINE(XOS_NEEDS_TIME_H, 1, [Compensate for a bug in Xos.h on
4679       some systems, where it requires time.h.])
4680     ;;
4681 esac
4682
4683
4684 dnl Define symbols to identify the version of Unix this is.
4685 dnl Define all the symbols that apply correctly.
4686 AH_TEMPLATE(DOS_NT, [Define if the system is MS DOS or MS Windows.])
4687 AH_TEMPLATE(MSDOS, [Define if the system is MS DOS.])
4688 AH_TEMPLATE(USG, [Define if the system is compatible with System III.])
4689 AH_TEMPLATE(USG5_4, [Define if the system is compatible with System V Release 4.])
4690
4691 case $opsys in
4692   aix4-2)
4693     AC_DEFINE(USG, [])
4694     dnl This symbol should be defined on AIX Version 3  ???????
4695     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4696 #ifndef _AIX
4697 # error "_AIX not defined"
4698 #endif
4699     ]], [[]])], [], AC_DEFINE(_AIX, [], [Define if the system is AIX.]))
4700     ;;
4701
4702   cygwin)
4703     AC_DEFINE(CYGWIN, 1, [Define if the system is Cygwin.])
4704     ;;
4705
4706   darwin)
4707     dnl Not __APPLE__, as this may not be defined on non-OSX Darwin.
4708     dnl Not DARWIN, because Panther and lower CoreFoundation.h use DARWIN to
4709     dnl distinguish OS X from pure Darwin.
4710     AC_DEFINE(DARWIN_OS, [], [Define if the system is Darwin.])
4711     ;;
4712
4713   gnu-linux | gnu-kfreebsd )
4714     AC_DEFINE(USG, [])
4715     AC_DEFINE(GNU_LINUX, [], [Define if ths system is compatible with GNU/Linux.])
4716     ;;
4717
4718   hpux*)
4719     AC_DEFINE(USG, [])
4720     AC_DEFINE(HPUX, [], [Define if the system is HPUX.])
4721     ;;
4722
4723   irix6-5)
4724     AC_DEFINE(USG, [])
4725     AC_DEFINE(USG5_4, [])
4726     AC_DEFINE(IRIX6_5, [], [Define if the system is IRIX.])
4727     ;;
4728
4729   mingw32)
4730     AC_DEFINE(DOS_NT, [])
4731     AC_DEFINE(WINDOWSNT, 1, [Define if compiling for native MS Windows.])
4732     if test "x$ac_enable_checking" != "x" ; then
4733       AC_DEFINE(EMACSDEBUG, 1, [Define to 1 to enable w32 debug facilities.])
4734     fi
4735     ;;
4736
4737   sol2*)
4738     AC_DEFINE(USG, [])
4739     AC_DEFINE(USG5_4, [])
4740     AC_DEFINE(SOLARIS2, [], [Define if the system is Solaris.])
4741     ;;
4742
4743   unixware)
4744     AC_DEFINE(USG, [])
4745     AC_DEFINE(USG5_4, [])
4746     ;;
4747 esac
4748
4749 AC_CACHE_CHECK([for usable FIONREAD], [emacs_cv_usable_FIONREAD],
4750   [case $opsys in
4751      aix4-2 | nacl)
4752        dnl BUILD 9008 - FIONREAD problem still exists in X-Windows.
4753        emacs_cv_usable_FIONREAD=no
4754        ;;
4755
4756      mingw32)
4757        emacs_cv_usable_FIONREAD=yes
4758        ;;
4759
4760      *)
4761        AC_COMPILE_IFELSE(
4762          [AC_LANG_PROGRAM([[#include <sys/types.h>
4763                             #include <sys/ioctl.h>
4764                             #ifdef USG5_4
4765                             # include <sys/filio.h>
4766                             #endif
4767                           ]],
4768                           [[int foo = ioctl (0, FIONREAD, &foo);]])],
4769          [emacs_cv_usable_FIONREAD=yes],
4770          [emacs_cv_usable_FIONREAD=no])
4771        ;;
4772    esac])
4773 if test $emacs_cv_usable_FIONREAD = yes; then
4774   AC_DEFINE([USABLE_FIONREAD], [1], [Define to 1 if FIONREAD is usable.])
4775
4776   if test $emacs_broken_SIGIO = no; then
4777     AC_CACHE_CHECK([for usable SIGIO], [emacs_cv_usable_SIGIO],
4778       [AC_COMPILE_IFELSE(
4779          [AC_LANG_PROGRAM([[#include <fcntl.h>
4780                             #include <signal.h>
4781                           ]],
4782                           [[int foo = SIGIO | F_SETFL | FASYNC;]])],
4783          [emacs_cv_usable_SIGIO=yes],
4784          [emacs_cv_usable_SIGIO=no])],
4785       [emacs_cv_usable_SIGIO=yes],
4786       [emacs_cv_usable_SIGIO=no])
4787     if test $emacs_cv_usable_SIGIO = yes; then
4788       AC_DEFINE([USABLE_SIGIO], [1], [Define to 1 if SIGIO is usable.])
4789     fi
4790   fi
4791 fi
4792
4793 case $opsys in
4794   hpux11)
4795     dnl It works to open the pty's tty in the parent (Emacs), then
4796     dnl close and reopen it in the child.
4797     AC_DEFINE(USG_SUBTTY_WORKS, 1, [Define for USG systems where it
4798       works to open a pty's tty in the parent process, then close and
4799       reopen it in the child.])
4800     ;;
4801
4802   irix6-5)
4803     AC_DEFINE(PREFER_VSUSP, 1, [Define if process_send_signal should
4804       use VSUSP instead of VSWTCH.])
4805     ;;
4806
4807   sol2-10)
4808     AC_DEFINE(_STRUCTURED_PROC, 1, [Needed for system_process_attributes
4809       on Solaris.])
4810     ;;
4811 esac
4812
4813 # Set up the CFLAGS for real compilation, so we can substitute it.
4814 CFLAGS="$REAL_CFLAGS"
4815 CPPFLAGS="$REAL_CPPFLAGS"
4816 LIBS="$REAL_LIBS"
4817
4818 ## Hack to detect a buggy GCC version.
4819 if test "$GCC" = yes && \
4820    $CC --version 2> /dev/null | grep 'gcc.* 4.5.0' >/dev/null; then
4821   case $CFLAGS in
4822     *-fno-optimize-sibling-calls*) ;;
4823     *-O@<:@23@:>@*)
4824       AC_MSG_ERROR([GCC 4.5.0 has problems compiling Emacs; see etc/PROBLEMS.]);;
4825   esac
4826 fi
4827
4828 version=$PACKAGE_VERSION
4829
4830 copyright="Copyright (C) 2016 Free Software Foundation, Inc."
4831 AC_DEFINE_UNQUOTED(COPYRIGHT, ["$copyright"],
4832   [Short copyright string for this version of Emacs.])
4833 AC_SUBST(copyright)
4834
4835 ### Specify what sort of things we'll be editing into Makefile and config.h.
4836 ### Use configuration here uncanonicalized to avoid exceeding size limits.
4837 AC_SUBST(version)
4838 AC_SUBST(configuration)
4839 ## Unused?
4840 AC_SUBST(canonical)
4841 AC_SUBST(srcdir)
4842 AC_SUBST(prefix)
4843 AC_SUBST(exec_prefix)
4844 AC_SUBST(bindir)
4845 AC_SUBST(datadir)
4846 AC_SUBST(sharedstatedir)
4847 AC_SUBST(libexecdir)
4848 AC_SUBST(mandir)
4849 AC_SUBST(infodir)
4850 AC_SUBST(lispdir)
4851 AC_SUBST(standardlisppath)
4852 AC_SUBST(locallisppath)
4853 AC_SUBST(lisppath)
4854 AC_SUBST(x_default_search_path)
4855 AC_SUBST(etcdir)
4856 AC_SUBST(archlibdir)
4857 AC_SUBST(etcdocdir)
4858 AC_SUBST(bitmapdir)
4859 AC_SUBST(gamedir)
4860 AC_SUBST(gameuser)
4861 AC_SUBST(gamegroup)
4862 ## FIXME? Nothing uses @LD_SWITCH_X_SITE@.
4863 ## src/Makefile.in did add LD_SWITCH_X_SITE (as a cpp define) to the
4864 ## end of LIBX_BASE, but nothing ever set it.
4865 AC_SUBST(LD_SWITCH_X_SITE)
4866 AC_SUBST(C_SWITCH_X_SITE)
4867 AC_SUBST(GNUSTEP_CFLAGS)
4868 AC_SUBST(CFLAGS)
4869 ## Used in lwlib/Makefile.in.
4870 AC_SUBST(X_TOOLKIT_TYPE)
4871 AC_SUBST(ns_appdir)
4872 AC_SUBST(ns_appbindir)
4873 AC_SUBST(ns_appresdir)
4874 AC_SUBST(ns_appsrc)
4875 AC_SUBST(GNU_OBJC_CFLAGS)
4876 AC_SUBST(OTHER_FILES)
4877
4878 if test -n "${term_header}"; then
4879     AC_DEFINE_UNQUOTED(TERM_HEADER, "${term_header}",
4880         [Define to the header for the built-in window system.])
4881 fi
4882
4883 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
4884                    [Define to the canonical Emacs configuration name.])
4885 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${emacs_config_options}",
4886                    [Define to the options passed to configure.])
4887 AH_TEMPLATE(config_opsysfile, [Some platforms that do not use configure
4888   define this to include extra configuration information.])
4889
4890 case $opsys in
4891   mingw32)
4892     AC_DEFINE(config_opsysfile, <ms-w32.h>, [])
4893     ;;
4894 esac
4895
4896 XMENU_OBJ=
4897 XOBJ=
4898 FONT_OBJ=
4899 if test "${HAVE_X_WINDOWS}" = "yes" ; then
4900   AC_DEFINE(HAVE_X_WINDOWS, 1,
4901             [Define to 1 if you want to use the X window system.])
4902   XMENU_OBJ=xmenu.o
4903   XOBJ="xterm.o xfns.o xselect.o xrdb.o xsmfns.o xsettings.o"
4904   FONT_OBJ=xfont.o
4905   if test "$HAVE_CAIRO" = "yes"; then
4906     FONT_OBJ="ftfont.o ftcrfont.o"
4907   elif test "$HAVE_XFT" = "yes"; then
4908     FONT_OBJ="$FONT_OBJ ftfont.o xftfont.o ftxfont.o"
4909   elif test "$HAVE_FREETYPE" = "yes"; then
4910     FONT_OBJ="$FONT_OBJ ftfont.o ftxfont.o"
4911   fi
4912   AC_SUBST(FONT_OBJ)
4913 fi
4914 AC_SUBST(XMENU_OBJ)
4915 AC_SUBST(XOBJ)
4916 AC_SUBST(FONT_OBJ)
4917
4918 WIDGET_OBJ=
4919 MOTIF_LIBW=
4920 if test "${USE_X_TOOLKIT}" != "none" ; then
4921   WIDGET_OBJ=widget.o
4922   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
4923   if test "${USE_X_TOOLKIT}" = "LUCID"; then
4924     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
4925   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
4926     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
4927     MOTIF_LIBW=-lXm
4928     case "$opsys" in
4929       gnu-linux)
4930         ## Paul Abrahams <abrahams at equinox.shaysnet.com> says this is needed.
4931         MOTIF_LIBW="$MOTIF_LIBW -lXpm"
4932         ;;
4933
4934       unixware)
4935         ## Richard Anthony Ryan <ryanr at ellingtn.ftc.nrcs.usda.gov>
4936         ## says -lXimp is needed in UNIX_SV ... 4.2 1.1.2.
4937         MOTIF_LIBW="MOTIF_LIBW -lXimp"
4938         ;;
4939
4940       aix4-2)
4941         ## olson@mcs.anl.gov says -li18n is needed by -lXm.
4942         MOTIF_LIBW="$MOTIF_LIBW -li18n"
4943         ;;
4944     esac
4945     MOTIF_LIBW="$MOTIF_LIBW $LIBXP"
4946   fi
4947 fi
4948 AC_SUBST(WIDGET_OBJ)
4949
4950 TOOLKIT_LIBW=
4951 case "$USE_X_TOOLKIT" in
4952   MOTIF) TOOLKIT_LIBW="$MOTIF_LIBW" ;;
4953   LUCID) TOOLKIT_LIBW="$LUCID_LIBW" ;;
4954   none) test "x$HAVE_GTK" = "xyes" && TOOLKIT_LIBW="$GTK_LIBS" ;;
4955 esac
4956 if test "$HAVE_XWIDGETS" = "yes"; then
4957   TOOLKIT_LIBW="$TOOLKIT_LIBW -lXcomposite"
4958 fi
4959 AC_SUBST(TOOLKIT_LIBW)
4960
4961 if test "${opsys}" != "mingw32"; then
4962   if test "$USE_X_TOOLKIT" = "none"; then
4963     LIBXT_OTHER="\$(LIBXSM)"
4964   else
4965     LIBXT_OTHER="\$(LIBXMU) -lXt \$(LIBXTR6) -lXext"
4966   fi
4967 fi
4968 AC_SUBST(LIBXT_OTHER)
4969
4970 if test "${HAVE_X11}" = "yes" ; then
4971   AC_DEFINE(HAVE_X11, 1,
4972             [Define to 1 if you want to use version 11 of X windows.])
4973   LIBX_OTHER="\$(LIBXT) \$(LIBX_EXTRA)"
4974 else
4975   LIBX_OTHER=
4976 fi
4977 AC_SUBST(LIBX_OTHER)
4978
4979 if test "$HAVE_GTK" = yes || test "$HAVE_X11" != yes; then
4980   LIBXMENU=
4981 elif test "$USE_X_TOOLKIT" = none; then
4982   LIBXMENU='$(oldXMenudir)/libXMenu11.a'
4983 else
4984   LIBXMENU='$(lwlibdir)/liblw.a'
4985 fi
4986 AC_SUBST(LIBXMENU)
4987
4988 AC_CACHE_CHECK([for struct alignment],
4989   [emacs_cv_struct_alignment],
4990   [AC_COMPILE_IFELSE(
4991      [AC_LANG_PROGRAM([[#include <stddef.h>
4992                         struct __attribute__ ((aligned (8))) s { char c; };
4993                         struct t { char c; struct s s; };
4994                         char verify[offsetof (struct t, s) == 8 ? 1 : -1];
4995                       ]])],
4996      [emacs_cv_struct_alignment=yes],
4997      [emacs_cv_struct_alignment=no])])
4998 if test "$emacs_cv_struct_alignment" = yes; then
4999   AC_DEFINE([HAVE_STRUCT_ATTRIBUTE_ALIGNED], 1,
5000     [Define to 1 if 'struct __attribute__ ((aligned (N)))' aligns the
5001      structure to an N-byte boundary.])
5002 fi
5003
5004 if test "${GNU_MALLOC}" = "yes" ; then
5005   AC_DEFINE(GNU_MALLOC, 1,
5006             [Define to 1 if you want to use the GNU memory allocator.])
5007 fi
5008
5009 RALLOC_OBJ=
5010 if test "${REL_ALLOC}" = "yes" ; then
5011   AC_DEFINE(REL_ALLOC, 1,
5012             [Define REL_ALLOC if you want to use the relocating allocator for
5013              buffer space.])
5014
5015   test "$system_malloc" != "yes" && RALLOC_OBJ=ralloc.o
5016 fi
5017 AC_SUBST(RALLOC_OBJ)
5018
5019 if test "$opsys" = "cygwin"; then
5020   CYGWIN_OBJ="cygw32.o"
5021   ## Cygwin differs because of its unexec().
5022   PRE_ALLOC_OBJ=
5023   POST_ALLOC_OBJ=lastfile.o
5024 elif test "$opsys" = "mingw32"; then
5025   CYGWIN_OBJ=
5026   PRE_ALLOC_OBJ=
5027   POST_ALLOC_OBJ=lastfile.o
5028 else
5029   CYGWIN_OBJ=
5030   PRE_ALLOC_OBJ=lastfile.o
5031   POST_ALLOC_OBJ=
5032 fi
5033 AC_SUBST(CYGWIN_OBJ)
5034 AC_SUBST(PRE_ALLOC_OBJ)
5035 AC_SUBST(POST_ALLOC_OBJ)
5036
5037 dnl Call this 'FORTIFY_SOUR' so that it sorts before the 'FORTIFY_SOURCE'
5038 dnl verbatim defined above.  The tricky name is apropos, as this hack
5039 dnl makes Fortify go sour!
5040 AH_VERBATIM([FORTIFY_SOUR],
5041 [/* Without the following workaround, Emacs runs slowly on OS X 10.8.
5042    The workaround disables some useful run-time checking, so it
5043    should be conditional to the platforms with the performance bug.
5044    Perhaps Apple will fix this some day; also see m4/extern-inline.m4.  */
5045 #if defined __APPLE__ && defined __GNUC__
5046 # ifndef _DONT_USE_CTYPE_INLINE_
5047 #  define _DONT_USE_CTYPE_INLINE_
5048 # endif
5049 # ifndef _FORTIFY_SOURCE
5050 #  define _FORTIFY_SOURCE 0
5051 # endif
5052 #endif
5053 ])
5054
5055 # If user asks to omit features, disable optional features that gnulib
5056 # might otherwise enable.
5057 if test "$with_features" = no && test "$enable_acl" != yes; then
5058   enable_acl=no
5059 fi
5060
5061 # Configure gnulib.  Although this does not affect CFLAGS or LIBS permanently.
5062 # it temporarily reverts them to their pre-pkg-config values,
5063 # because gnulib needs to work with both src (which uses the
5064 # pkg-config stuff) and lib-src (which does not).  For example, gnulib
5065 # may need to determine whether LIB_CLOCK_GETTIME should contain -lrt,
5066 # and it therefore needs to run in an environment where LIBS does not
5067 # already contain -lrt merely because 'pkg-config --libs' printed '-lrt'
5068 # for some package unrelated to lib-src.
5069 SAVE_CFLAGS=$CFLAGS
5070 SAVE_LIBS=$LIBS
5071 CFLAGS=$pre_PKG_CONFIG_CFLAGS
5072 LIBS="$LIB_PTHREAD $pre_PKG_CONFIG_LIBS"
5073 gl_ASSERT_NO_GNULIB_POSIXCHECK
5074 gl_ASSERT_NO_GNULIB_TESTS
5075 gl_INIT
5076 CFLAGS=$SAVE_CFLAGS
5077 LIBS=$SAVE_LIBS
5078
5079 if test "${opsys}" = "mingw32"; then
5080   CPPFLAGS="$CPPFLAGS -DUSE_CRT_DLL=1 -I \${abs_top_srcdir}/nt/inc"
5081   # Remove unneeded switches from the value of CC that goes to Makefiles
5082   CC=`AS_ECHO(["$CC"]) | sed -e "s,$GCC_TEST_OPTIONS,,"`
5083 fi
5084
5085 case "$opsys" in
5086   aix4-2) LD_SWITCH_SYSTEM_TEMACS="-Wl,-bnodelcsect" ;;
5087
5088   cygwin) LD_SWITCH_SYSTEM_TEMACS="-Wl,-stack,0x00800000" ;;
5089
5090   darwin)
5091    ## The -headerpad option tells ld (see man page) to leave room at the
5092    ## end of the header for adding load commands.  Needed for dumping.
5093    ## 0x1000 is enough for roughly 52 load commands on the x86_64
5094    ## architecture (where they are 78 bytes each). The actual number of
5095    ## load commands added is not consistent but normally ranges from
5096    ## about 14 to about 34. Setting it high gets us plenty of slop and
5097    ## only costs about 1.5K of wasted binary space.
5098    headerpad_extra=1000
5099    if test "$HAVE_NS" = "yes"; then
5100      libs_nsgui="-framework AppKit"
5101      if test "$NS_IMPL_COCOA" = "yes"; then
5102         libs_nsgui="$libs_nsgui -framework IOKit"
5103      fi
5104    else
5105      libs_nsgui=
5106    fi
5107    LD_SWITCH_SYSTEM_TEMACS="-fno-pie -prebind $libs_nsgui -Xlinker -headerpad -Xlinker $headerpad_extra"
5108
5109    ## This is here because src/Makefile.in did some extra fiddling around
5110    ## with LD_SWITCH_SYSTEM.  It seems cleaner to put this in
5111    ## LD_SWITCH_SYSTEM_TEMACS instead,
5112    test "x$LD_SWITCH_SYSTEM" = "x" && test "x$GCC" != "xyes" && \
5113      LD_SWITCH_SYSTEM_TEMACS="-X $LD_SWITCH_SYSTEM_TEMACS"
5114    ;;
5115
5116   ## LD_SWITCH_X_SITE_RPATH is a -rpath option saying where to
5117   ## find X at run-time.
5118   ## When handled by cpp, this was in LD_SWITCH_SYSTEM.  However, at the
5119   ## point where configure sourced the s/*.h file, LD_SWITCH_X_SITE_RPATH
5120   ## had not yet been defined and was expanded to null.  Hence LD_SWITCH_SYSTEM
5121   ## had different values in configure (in ac_link) and src/Makefile.in.
5122   ## It seems clearer therefore to put this piece in LD_SWITCH_SYSTEM_TEMACS.
5123   gnu*) LD_SWITCH_SYSTEM_TEMACS="\$(LD_SWITCH_X_SITE_RPATH)" ;;
5124
5125   mingw32)
5126    ## Is it any better under MinGW64 to relocate emacs into higher addresses?
5127    case "$canonical" in
5128      x86_64-*-*) LD_SWITCH_SYSTEM_TEMACS="-Wl,-stack,0x00800000 -Wl,-heap,0x00100000 -Wl,-image-base,0x400000000 -Wl,-entry,__start -Wl,-Map,./temacs.map" ;;
5129      *) LD_SWITCH_SYSTEM_TEMACS="-Wl,-stack,0x00800000 -Wl,-heap,0x00100000 -Wl,-image-base,0x01000000 -Wl,-entry,__start -Wl,-Map,./temacs.map" ;;
5130    esac
5131    ;;
5132
5133   *) LD_SWITCH_SYSTEM_TEMACS= ;;
5134 esac
5135
5136 # -nopie fixes a temacs segfault on Gentoo, OpenBSD, and other systems
5137 # with "hardened" GCC configurations for some reason (Bug#18784).
5138 # We don't know why -nopie works, but not segfaulting is better than
5139 # segfaulting.  Use ac_c_werror_flag=yes when trying -nopie, otherwise
5140 # clang keeps warning that it does not understand -nopie, and pre-4.6
5141 # GCC has a similar problem (Bug#20338).
5142 AC_CACHE_CHECK([whether $CC accepts -nopie],
5143   [emacs_cv_prog_cc_nopie],
5144   [emacs_save_c_werror_flag=$ac_c_werror_flag
5145    emacs_save_LDFLAGS=$LDFLAGS
5146    ac_c_werror_flag=yes
5147    LDFLAGS="$LDFLAGS -nopie"
5148    AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
5149      [emacs_cv_prog_cc_nopie=yes],
5150      [emacs_cv_prog_cc_nopie=no])
5151    ac_c_werror_flag=$emacs_save_c_werror_flag
5152    LDFLAGS=$emacs_save_LDFLAGS])
5153 if test "$emacs_cv_prog_cc_nopie" = yes; then
5154   LD_SWITCH_SYSTEM_TEMACS="$LD_SWITCH_SYSTEM_TEMACS -nopie"
5155 fi
5156
5157 if test x$ac_enable_profiling != x ; then
5158   case $opsys in
5159     *freebsd | gnu-linux) ;;
5160     *) LD_SWITCH_SYSTEM_TEMACS="$LD_SWITCH_SYSTEM_TEMACS -pg" ;;
5161   esac
5162 fi
5163
5164 LD_SWITCH_SYSTEM_TEMACS="$LDFLAGS_NOCOMBRELOC $LD_SWITCH_SYSTEM_TEMACS"
5165
5166 AC_SUBST(LD_SWITCH_SYSTEM_TEMACS)
5167
5168 ## Common for all window systems
5169 if test "$window_system" != "none"; then
5170   AC_DEFINE(HAVE_WINDOW_SYSTEM, 1, [Define if you have a window system.])
5171   AC_DEFINE(POLL_FOR_INPUT, 1, [Define if you poll periodically to detect C-g.])
5172   WINDOW_SYSTEM_OBJ="fontset.o fringe.o image.o"
5173 fi
5174
5175 AC_SUBST(WINDOW_SYSTEM_OBJ)
5176
5177 AH_TOP([/* GNU Emacs site configuration template file.
5178
5179 Copyright (C) 1988, 1993-1994, 1999-2002, 2004-2016
5180   Free Software Foundation, Inc.
5181
5182 This file is part of GNU Emacs.
5183
5184 GNU Emacs is free software: you can redistribute it and/or modify
5185 it under the terms of the GNU General Public License as published by
5186 the Free Software Foundation, either version 3 of the License, or
5187 (at your option) any later version.
5188
5189 GNU Emacs is distributed in the hope that it will be useful,
5190 but WITHOUT ANY WARRANTY; without even the implied warranty of
5191 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
5192 GNU General Public License for more details.
5193
5194 You should have received a copy of the GNU General Public License
5195 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
5196
5197
5198 /* No code in Emacs #includes config.h twice, but some bits of code
5199    intended to work with other packages as well (like gmalloc.c)
5200    think they can include it as many times as they like.  */
5201 #ifndef EMACS_CONFIG_H
5202 #define EMACS_CONFIG_H
5203 ])dnl
5204
5205 AH_BOTTOM([#include <conf_post.h>
5206
5207 #endif /* EMACS_CONFIG_H */
5208
5209 /*
5210 Local Variables:
5211 mode: c
5212 End:
5213 */
5214 ])dnl
5215
5216 #### Report on what we decided to do.
5217 #### Report GTK as a toolkit, even if it doesn't use Xt.
5218 #### It makes printing result more understandable as using GTK sets
5219 #### toolkit_scroll_bars to yes by default.
5220 if test "${HAVE_GTK}" = "yes"; then
5221   USE_X_TOOLKIT="$USE_GTK_TOOLKIT"
5222 fi
5223
5224 if test $USE_ACL -ne 0; then
5225   ACL_SUMMARY="yes $LIB_ACL"
5226 else
5227   ACL_SUMMARY=no
5228 fi
5229
5230 emacs_standard_dirs='Standard dirs'
5231 AS_ECHO(["
5232 Configured for '${canonical}'.
5233
5234   Where should the build process find the source code?    ${srcdir}
5235   What compiler should emacs be built with?               ${CC} ${CFLAGS}
5236   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
5237   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
5238   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
5239   What window system should Emacs use?                    ${window_system}
5240   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}
5241   Where do we find X Windows header files?                ${x_includes:-$emacs_standard_dirs}
5242   Where do we find X Windows libraries?                   ${x_libraries:-$emacs_standard_dirs}"])
5243
5244 optsep=
5245 emacs_config_features=
5246 for opt in XAW3D XPM JPEG TIFF GIF PNG RSVG CAIRO IMAGEMAGICK SOUND GPM DBUS \
5247   GCONF GSETTINGS NOTIFY ACL LIBSELINUX GNUTLS LIBXML2 FREETYPE M17N_FLT \
5248   LIBOTF XFT ZLIB TOOLKIT_SCROLL_BARS X_TOOLKIT X11 NS MODULES \
5249   XWIDGETS; do
5250
5251     case $opt in
5252       NOTIFY|ACL) eval val=\${${opt}_SUMMARY} ;;
5253       TOOLKIT_SCROLL_BARS|X_TOOLKIT) eval val=\${USE_$opt} ;;
5254       *) eval val=\${HAVE_$opt} ;;
5255     esac
5256     case x$val in
5257       xno|xnone|x) continue ;;
5258     esac
5259     case $opt in
5260       X_TOOLKIT)
5261         case $val in
5262           GTK*|LUCID|MOTIF) opt=$val ;;
5263           *) continue ;;
5264         esac
5265       ;;
5266     esac
5267     AS_VAR_APPEND([emacs_config_features], ["$optsep$opt"])
5268     optsep=' '
5269 done
5270 AC_DEFINE_UNQUOTED(EMACS_CONFIG_FEATURES, "${emacs_config_features}",
5271   [Summary of some of the main features enabled by configure.])
5272
5273 AS_ECHO(["  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}
5274   Does Emacs use -lXpm?                                   ${HAVE_XPM}
5275   Does Emacs use -ljpeg?                                  ${HAVE_JPEG}
5276   Does Emacs use -ltiff?                                  ${HAVE_TIFF}
5277   Does Emacs use a gif library?                           ${HAVE_GIF} $LIBGIF
5278   Does Emacs use a png library?                           ${HAVE_PNG} $LIBPNG
5279   Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}
5280   Does Emacs use cairo?                                   ${HAVE_CAIRO}
5281   Does Emacs use imagemagick?                             ${HAVE_IMAGEMAGICK}
5282   Does Emacs support sound?                               ${HAVE_SOUND}
5283   Does Emacs use -lgpm?                                   ${HAVE_GPM}
5284   Does Emacs use -ldbus?                                  ${HAVE_DBUS}
5285   Does Emacs use -lgconf?                                 ${HAVE_GCONF}
5286   Does Emacs use GSettings?                               ${HAVE_GSETTINGS}
5287   Does Emacs use a file notification library?             ${NOTIFY_SUMMARY}
5288   Does Emacs use access control lists?                    ${ACL_SUMMARY}
5289   Does Emacs use -lselinux?                               ${HAVE_LIBSELINUX}
5290   Does Emacs use -lgnutls?                                ${HAVE_GNUTLS}
5291   Does Emacs use -lxml2?                                  ${HAVE_LIBXML2}
5292   Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}
5293   Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}
5294   Does Emacs use -lotf?                                   ${HAVE_LIBOTF}
5295   Does Emacs use -lxft?                                   ${HAVE_XFT}
5296   Does Emacs directly use zlib?                           ${HAVE_ZLIB}
5297   Does Emacs have dynamic modules support?                ${HAVE_MODULES}
5298   Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}
5299   Does Emacs support Xwidgets (requires gtk3)?            ${HAVE_XWIDGETS}
5300 "])
5301
5302 if test -n "${EMACSDATA}"; then
5303    AS_ECHO(["  Environment variable EMACSDATA set to:                  $EMACSDATA"])
5304 fi
5305 if test -n "${EMACSDOC}"; then
5306    AS_ECHO(["  Environment variable EMACSDOC set to:                   $EMACSDOC"])
5307 fi
5308
5309 echo
5310
5311 if test "$HAVE_NS" = "yes"; then
5312    echo
5313    AS_ECHO(["You must run \"${MAKE-make} install\" in order to test the built application.
5314 The installed application will go to nextstep/Emacs.app and can be
5315 run or moved from there."])
5316    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
5317       echo "The application will be fully self-contained."
5318     else
5319       AS_ECHO(["The lisp resources for the application will be installed under ${prefix}.
5320 You may need to run \"${MAKE-make} install\" with sudo.  The application will fail
5321 to run if these resources are not installed."])
5322    fi
5323    echo
5324 fi
5325
5326 if test "${opsys}" = "cygwin"; then
5327   case `uname -r` in
5328     1.5.*) AC_MSG_WARN([[building Emacs on Cygwin 1.5 is not supported.]])
5329            echo
5330            ;;
5331   esac
5332 fi
5333
5334 # Remove any trailing slashes in these variables.
5335 case $prefix in
5336   */) prefix=`AS_DIRNAME(["$prefix."])`;;
5337 esac
5338 case $exec_prefix in
5339   */) exec_prefix=`AS_DIRNAME(["$exec_prefix."])`;;
5340 esac
5341
5342 if test "$HAVE_NS" = "yes"; then
5343   if test "$NS_IMPL_GNUSTEP" = yes; then
5344     AC_CONFIG_FILES([nextstep/GNUstep/Emacs.base/Resources/Info-gnustep.plist:nextstep/templates/Info-gnustep.plist.in \
5345       nextstep/GNUstep/Emacs.base/Resources/Emacs.desktop:nextstep/templates/Emacs.desktop.in])
5346     ns_check_file=Resources/Info-gnustep.plist
5347   else
5348     AC_CONFIG_FILES([nextstep/Cocoa/Emacs.base/Contents/Info.plist:nextstep/templates/Info.plist.in \
5349       nextstep/Cocoa/Emacs.base/Contents/Resources/English.lproj/InfoPlist.strings:nextstep/templates/InfoPlist.strings.in])
5350     ns_check_file=Contents/Info.plist
5351   fi
5352   AC_SUBST(ns_check_file)
5353 fi
5354
5355 dnl config.status treats $srcdir specially, so I think this is ok...
5356 AC_CONFIG_FILES([$srcdir/doc/man/emacs.1])
5357
5358 dnl Obviously there is duplication here wrt $SUBDIR_MAKEFILES.
5359 dnl You _can_ use that variable in AC_CONFIG_FILES, so long as any directory
5360 dnl using automake (ie lib/) is explicitly listed and not "hidden" in a variable
5361 dnl (else you get "no 'Makefile.am' found for any configure output").
5362 dnl This will work, but you get a config.status that is not quite right
5363 dnl (see http://lists.gnu.org/archive/html/bug-autoconf/2008-08/msg00028.html).
5364 dnl That doesn't have any obvious consequences for Emacs, but on the whole
5365 dnl it seems better to just live with the duplication.
5366 SUBDIR_MAKEFILES="lib/Makefile lib-src/Makefile oldXMenu/Makefile doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile leim/Makefile nextstep/Makefile nt/Makefile"
5367
5368 AC_CONFIG_FILES([Makefile lib/Makefile lib-src/Makefile oldXMenu/Makefile \
5369        doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
5370        doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile \
5371        leim/Makefile nextstep/Makefile nt/Makefile])
5372
5373 dnl test/ is not present in release tarfiles.
5374 opt_makefile=test/Makefile
5375
5376 if test -f "$srcdir/$opt_makefile.in"; then
5377   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES $opt_makefile"
5378   dnl Again, it's best not to use a variable.  Though you can add
5379   dnl ", [], [opt_makefile='$opt_makefile']" and it should work.
5380   AC_CONFIG_FILES([test/Makefile])
5381 fi
5382
5383
5384 dnl The admin/ directory used to be excluded from tarfiles.
5385 if test -d $srcdir/admin; then
5386   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES admin/charsets/Makefile admin/unidata/Makefile admin/grammars/Makefile"
5387   AC_CONFIG_FILES([admin/charsets/Makefile])
5388   AC_CONFIG_FILES([admin/unidata/Makefile])
5389   AC_CONFIG_FILES([admin/grammars/Makefile])
5390 fi                              dnl -d admin
5391
5392
5393 SUBDIR_MAKEFILES_IN=`echo " ${SUBDIR_MAKEFILES}" | sed -e 's| | $(srcdir)/|g' -e 's|Makefile|Makefile.in|g'`
5394
5395 AC_SUBST(SUBDIR_MAKEFILES_IN)
5396
5397 dnl You might wonder (I did) why epaths.h is generated by running make,
5398 dnl rather than just letting configure generate it from epaths.in.
5399 dnl One reason is that the various paths are not fully expanded (see above);
5400 dnl eg gamedir=${prefix}/var/games/emacs.
5401 dnl Secondly, the GNU Coding standards require that one should be able
5402 dnl to run 'make prefix=/some/where/else' and override the values set
5403 dnl by configure.  This also explains the 'move-if-change' test and
5404 dnl the use of force in the 'epaths-force' rule in Makefile.in.
5405 AC_CONFIG_COMMANDS([src/epaths.h], [
5406 if test "${opsys}" = "mingw32"; then
5407   ${MAKE-make} MAKEFILE_NAME=do-not-make-Makefile epaths-force-w32
5408 else
5409   ${MAKE-make} MAKEFILE_NAME=do-not-make-Makefile epaths-force
5410 fi || AC_MSG_ERROR(['src/epaths.h' could not be made.])
5411 ], [GCC="$GCC" CPPFLAGS="$CPPFLAGS" opsys="$opsys"])
5412
5413 dnl NB we have to cheat and use the ac_... version because abs_top_srcdir
5414 dnl is not yet set, sigh.  Or we could use ../$srcdir/src/.gdbinit,
5415 dnl or a symlink?
5416 AC_CONFIG_COMMANDS([src/.gdbinit], [
5417 if test ! -f src/.gdbinit && test -f "$srcdir/src/.gdbinit"; then
5418   AS_ECHO(["source $ac_abs_top_srcdir/src/.gdbinit"]) > src/.gdbinit
5419 fi
5420 ])
5421
5422 dnl Perhaps this would be better named doc-emacs-emacsver.texi?
5423 dnl See comments for etc-refcards-emacsver.tex.
5424 dnl Since we get a doc/emacs directory generated anyway, for the Makefile,
5425 dnl it is not quite the same.  But we are generating in $srcdir.
5426 AC_CONFIG_COMMANDS([doc/emacs/emacsver.texi], [
5427 ${MAKE-make} -s --no-print-directory -C doc/emacs doc-emacsver || \
5428 AC_MSG_ERROR(['doc/emacs/emacsver.texi' could not be made.])
5429 ])
5430
5431 dnl If we give this the more natural name, etc/refcards/emacsver.texi,
5432 dnl then a directory etc/refcards is created in the build directory,
5433 dnl which is probably harmless, but confusing (in out-of-tree builds).
5434 dnl (If we were to generate etc/refcards/Makefile, this might change.)
5435 dnl It is really $srcdir/etc/refcards/emacsver.tex that we generate.
5436 AC_CONFIG_COMMANDS([etc-refcards-emacsver.tex], [
5437 ${MAKE-make} -s MAKEFILE_NAME=do-not-make-Makefile etc-emacsver || \
5438 AC_MSG_ERROR(['etc/refcards/emacsver.tex' could not be made.])
5439 ])
5440
5441 AC_OUTPUT
5442
5443 test "$MAKE" = make || AC_MSG_NOTICE([Now you can run '$MAKE'.])