code.delx.au - gnu-emacs/blob - configure.ac

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the 'configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl If you changed any AC_DEFINES, also run autoheader.
   6 dnl
   7 dnl Copyright (C) 1994-1996, 1999-2016 Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation, either version 3 of the License, or
  14 dnl  (at your option) any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 AC_PREREQ(2.65)
  25 dnl Note this is parsed by (at least) make-dist and lisp/cedet/ede/emacs.el.
  26 AC_INIT(GNU Emacs, 25.1.50, bug-gnu-emacs@gnu.org)
  27
  28 dnl Set emacs_config_options to the options of 'configure', quoted for the shell,
  29 dnl and then quoted again for a C string.  Separate options with spaces.
  30 dnl Add some environment variables, if they were passed via the environment
  31 dnl rather than on the command-line.
  32 emacs_config_options=
  33 optsep=
  34 dnl This is the documented way to record the args passed to configure,
  35 dnl rather than $ac_configure_args.
  36 for opt in ${1+"$@"} CFLAGS CPPFLAGS LDFLAGS; do
  37   case $opt in
  38     -n | --no-create | --no-recursion)
  39       continue ;;
  40     CFLAGS | CPPFLAGS | LDFLAGS)
  41       eval 'test "${'$opt'+set}" = set' || continue
  42       case " $*" in
  43         *" $opt="*) continue ;;
  44       esac
  45       eval opt=$opt=\$$opt ;;
  46   esac
  47
  48   emacs_shell_specials=$IFS\''"#$&()*;<>?@<:@\\`{|~'
  49   case $opt in
  50     *[["$emacs_shell_specials"]]*)
  51       case $opt in
  52         *\'*)
  53           emacs_quote_apostrophes="s/'/'\\\\''/g"
  54           opt=`AS_ECHO(["$opt"]) | sed "$emacs_quote_apostrophes"` ;;
  55       esac
  56       opt="'$opt'"
  57       case $opt in
  58         *[['"\\']]*)
  59           emacs_quote_for_c='s/[["\\]]/\\&/g; $!s/$/\\n\\/'
  60           opt=`AS_ECHO(["$opt"]) | sed "$emacs_quote_for_c"` ;;
  61       esac ;;
  62   esac
  63   AS_VAR_APPEND([emacs_config_options], ["$optsep$opt"])
  64   optsep=' '
  65 done
  66
  67 AC_CONFIG_HEADERS(src/config.h:src/config.in)
  68 AC_CONFIG_SRCDIR(src/lisp.h)
  69 AC_CONFIG_AUX_DIR(build-aux)
  70 dnl automake 1.13 and later understand this, making -I m4 unnecessary.
  71 dnl With older versions this is a no-op.
  72 AC_CONFIG_MACRO_DIR(m4)
  73
  74 xcsdkdir=
  75 AC_CHECK_PROGS(XCRUN, [xcrun])
  76 if test -n "$XCRUN"; then
  77   if test -z "$MAKE"; then
  78     dnl Call the variable MAKE_PROG, not MAKE, to avoid confusion with
  79     dnl the usual MAKE variable that 'make' itself uses.
  80     AC_CHECK_PROG([MAKE_PROG], [make], [yes])
  81     if test -z "$MAKE_PROG"; then
  82       MAKE="$XCRUN MAKE"
  83       export MAKE
  84       xcsdkdir=`$XCRUN --show-sdk-path 2>/dev/null`
  85     fi
  86   fi
  87 fi
  88
  89 dnl GNU Make is required, so don't test for its individual features.
  90 am_cv_make_support_nested_variables=yes
  91 AC_DEFUN([AC_PROG_MAKE_SET],
  92   [SET_MAKE=
  93    AC_SUBST([SET_MAKE])])
  94
  95 dnl Check for GNU Make and possibly set MAKE before running AM_INIT_AUTOMAKE.
  96 [emacs_check_gnu_make ()
  97 {
  98   emacs_makeout=`($1 --version) 2>/dev/null` &&
  99   case $emacs_makeout in
 100     'GNU Make '3.8[1-9]* | 'GNU Make '3.9[0-9]* | \
 101     'GNU Make '3.[1-9][0-9][0-9]* | 'GNU Make '[4-9]* | 'GNU Make '[1-9][0-9]* )
 102        ac_path_MAKE_found=:;;
 103   esac
 104 }]
 105 AC_CACHE_CHECK([for GNU Make], [ac_cv_path_MAKE],
 106   [ac_path_MAKE_found=false
 107    if test -n "$MAKE"; then
 108      emacs_check_gnu_make "$MAKE"
 109      ac_cv_path_MAKE=$MAKE
 110    else
 111      emacs_tried_make=false
 112      emacs_tried_gmake=false
 113      emacs_tried_gnumake=false
 114      AC_PATH_PROGS_FEATURE_CHECK([MAKE], [make gmake gnumake],
 115        [[emacs_check_gnu_make "$ac_path_MAKE"
 116          if $ac_path_MAKE_found; then
 117            # Use the fully-qualified program name only if the basename
 118            # would not resolve to it.
 119            if eval \$emacs_tried_$ac_prog; then
 120              ac_cv_path_MAKE=$ac_path_MAKE
 121            else
 122              ac_cv_path_MAKE=$ac_prog
 123            fi
 124          fi
 125          eval emacs_tried_$ac_prog=:]])
 126    fi])
 127 $ac_path_MAKE_found || {
 128 AC_MSG_ERROR([[Building Emacs requires GNU Make, at least version 3.81.
 129 If you have it installed under another name, configure with 'MAKE=...'.
 130 For example, run '$0 MAKE=gnu-make'.]])
 131 }
 132 MAKE=$ac_cv_path_MAKE
 133 export MAKE
 134
 135 dnl Fairly arbitrary, older versions might work too.
 136 AM_INIT_AUTOMAKE(1.11)
 137
 138 dnl Canonicalize the configuration name.
 139 AC_CANONICAL_HOST
 140
 141 case $host in
 142  *-mingw*)
 143
 144   if test -z "$host_alias"; then
 145
 146       # No --host argument was given to 'configure'; therefore $host
 147       # was set to a default value based on the build platform.  But
 148       # this default value may be wrong if we are building from a
 149       # 64-bit MSYS[2] pre-configured to build 32-bit MinGW programs.
 150       # Therefore, we'll try to get the right host platform from the
 151       # compiler's target.
 152
 153       AC_MSG_CHECKING([the compiler's target])
 154       if test -z "$CC"; then
 155           cc=gcc
 156       else
 157           cc=$CC
 158       fi
 159       cc_target=`$cc -v 2>&1 | sed -n 's/Target: //p'`
 160       case "$cc_target" in
 161           *-*) host=$cc_target
 162               ;;
 163           "") AC_MSG_ERROR([Impossible to obtain $cc compiler target.
 164 Please explicitly provide --host.])
 165               ;;
 166           *) AC_MSG_WARN([Compiler reported non-standard target.
 167 Defaulting to $host.])
 168               ;;
 169       esac
 170       AC_MSG_RESULT([$host])
 171   fi
 172
 173   . $srcdir/nt/mingw-cfg.site
 174
 175   case $srcdir in
 176     /* | ?:*)
 177       # srcdir is an absolute path.  In this case, force the format
 178       # "/c/foo/bar", to simplify later conversions to native Windows
 179       # format ("c:/foo/bar").
 180       srcdir=`cd "${srcdir}" && pwd -W`
 181       # 'eval' pacifies strict POSIX non-MinGW shells (Bug#18612).
 182       eval 'srcdir="/${srcdir:0:1}${srcdir:2}"'
 183       ;;
 184   esac;;
 185 esac
 186
 187 canonical=$host
 188 configuration=${host_alias-${build_alias-$host}}
 189
 190 dnl Support for --program-prefix, --program-suffix and
 191 dnl --program-transform-name options
 192 AC_ARG_PROGRAM
 193
 194 dnl It is important that variables on the RHS not be expanded here,
 195 dnl hence the single quotes.  This is per the GNU coding standards, see
 196 dnl (autoconf) Installation Directory Variables
 197 dnl See also epaths.h below.
 198 lispdir='${datadir}/emacs/${version}/lisp'
 199 standardlisppath='${lispdir}'
 200 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
 201 '${datadir}/emacs/site-lisp'
 202 lisppath='${locallisppath}:${standardlisppath}'
 203 etcdir='${datadir}/emacs/${version}/etc'
 204 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
 205 etcdocdir='${datadir}/emacs/${version}/etc'
 206 gamedir='${localstatedir}/games/emacs'
 207
 208 dnl Special option to disable the most of other options.
 209 AC_ARG_WITH(all,
 210 [AS_HELP_STRING([--without-all],
 211                 [omit almost all features and build
 212                 small executable with minimal dependencies])],
 213   [with_features=$withval],
 214   [with_features=yes])
 215
 216 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
 217 dnl Create a new --with option that defaults to being disabled.
 218 dnl NAME is the base name of the option.  The shell variable with_NAME
 219 dnl   will be set to either the user's value (if the option is
 220 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
 221 dnl   option is not specified).  Note that the shell variable name is
 222 dnl   constructed as autoconf does, by replacing non-alphanumeric
 223 dnl   characters with "_".
 224 dnl HELP-STRING is the help text for the option.
 225 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
 226   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
 227     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
 228 ])dnl
 229
 230 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
 231 dnl Create a new --with option that defaults to $with_features.
 232 dnl NAME is the base name of the option.  The shell variable with_NAME
 233 dnl   will be set either to 'no' (for a plain --without-NAME) or to
 234 dnl   'yes' (if the option is not specified).  Note that the shell
 235 dnl   variable name is constructed as autoconf does, by replacing
 236 dnl   non-alphanumeric characters with "_".
 237 dnl HELP-STRING is the help text for the option.
 238 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
 239   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
 240    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=$with_features])dnl
 241 ])dnl
 242
 243 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
 244 if test "$with_pop" = yes; then
 245    AC_DEFINE(MAIL_USE_POP)
 246 fi
 247 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
 248
 249 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
 250 if test "$with_kerberos" != no; then
 251    AC_DEFINE(KERBEROS)
 252 fi
 253 AH_TEMPLATE(KERBEROS,
 254             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
 255
 256 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
 257 if test "${with_kerberos5}" != no; then
 258   if test "${with_kerberos}" = no; then
 259     with_kerberos=yes
 260     AC_DEFINE(KERBEROS)
 261   fi
 262   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
 263 fi
 264
 265 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
 266 dnl FIXME hesiod support may not be present, so it seems like an error
 267 dnl to define, or at least use, this unconditionally.
 268 if test "$with_hesiod" != no; then
 269   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
 270 fi
 271
 272 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
 273 if test "$with_mail_unlink" != no; then
 274    AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
 275 fi
 276
 277 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
 278     [string giving default POP mail host])],
 279     AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
 280
 281 AC_ARG_WITH([sound],[AS_HELP_STRING([--with-sound=VALUE],
 282   [compile with sound support (VALUE one of: yes, alsa, oss, bsd-ossaudio, no;
 283 default yes).  Only for GNU/Linux, FreeBSD, NetBSD, MinGW, Cygwin.])],
 284   [ case "${withval}" in
 285       yes|no|alsa|oss|bsd-ossaudio) val=$withval ;;
 286       *) AC_MSG_ERROR(['--with-sound=$withval' is invalid;
 287 this option's value should be 'yes', 'no', 'alsa', 'oss', or 'bsd-ossaudio'.])
 288       ;;
 289     esac
 290     with_sound=$val
 291   ],
 292   [with_sound=$with_features])
 293
 294 dnl FIXME currently it is not the last.
 295 dnl This should be the last --with option, because --with-x is
 296 dnl added later on when we find the file name of X, and it's best to
 297 dnl keep them together visually.
 298 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 299  [use an X toolkit (KIT one of: yes or gtk, gtk2, gtk3, lucid or athena, motif, no)])],
 300 [         case "${withval}" in
 301             y | ye | yes )      val=gtk ;;
 302             n | no )            val=no  ;;
 303             l | lu | luc | luci | lucid )       val=lucid ;;
 304             a | at | ath | athe | athen | athena )      val=athena ;;
 305             m | mo | mot | moti | motif )       val=motif ;;
 306             g | gt | gtk  )     val=gtk ;;
 307             gtk2  )     val=gtk2 ;;
 308             gtk3  )     val=gtk3 ;;
 309             * )
 310 AC_MSG_ERROR(['--with-x-toolkit=$withval' is invalid;
 311 this option's value should be 'yes', 'no', 'lucid', 'athena', 'motif', 'gtk',
 312 'gtk2' or 'gtk3'.  'yes' and 'gtk' are synonyms.
 313 'athena' and 'lucid' are synonyms.])
 314             ;;
 315           esac
 316           with_x_toolkit=$val
 317 ])
 318
 319 OPTION_DEFAULT_OFF([wide-int], [prefer wide Emacs integers (typically 62-bit); allows buffer and string size up to 2GB on 32-bit hosts, at the cost of 10% to 30% slowdown of Lisp interpreter and larger memory footprint])
 320 if test "$with_wide_int" = yes; then
 321   AC_DEFINE([WIDE_EMACS_INT], 1, [Use long long for EMACS_INT if available.])
 322 fi
 323
 324 dnl _ON results in a '--without' option in the --help output, so
 325 dnl the help text should refer to "don't compile", etc.
 326 with_xpm_set=${with_xpm+set}
 327 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 328 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 329 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 330 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 331 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 332 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 333 OPTION_DEFAULT_OFF([cairo],[compile with Cairo drawing])
 334 OPTION_DEFAULT_ON([xml2],[don't compile with XML parsing support])
 335 OPTION_DEFAULT_ON([imagemagick],[don't compile with ImageMagick image support])
 336
 337 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 338 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 339 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 340
 341 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 342 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 343 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 344 AC_ARG_WITH([ns],[AS_HELP_STRING([--with-ns],
 345 [use Nextstep (OS X Cocoa or GNUstep) windowing system.
 346 On by default on Mac OS X.])],[],[with_ns=maybe])
 347 OPTION_DEFAULT_OFF([w32], [use native MS Windows GUI in a Cygwin build])
 348
 349 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 350 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 351 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 352 OPTION_DEFAULT_ON([gsettings],[don't compile with GSettings support])
 353 OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support])
 354 OPTION_DEFAULT_ON([gnutls],[don't use -lgnutls for SSL/TLS support])
 355 OPTION_DEFAULT_ON([zlib],[don't compile with zlib decompression support])
 356 OPTION_DEFAULT_OFF([modules],[compile with dynamic modules support])
 357
 358 AC_ARG_WITH([file-notification],[AS_HELP_STRING([--with-file-notification=LIB],
 359  [use a file notification library (LIB one of: yes, inotify, kqueue, gfile, w32, no)])],
 360  [ case "${withval}" in
 361     y | ye | yes )      val=yes ;;
 362     n | no )            val=no  ;;
 363     i | in | ino | inot | inoti | inotif | inotify )    val=inotify ;;
 364     k | kq | kqu | kque | kqueu | kqueue )      val=kqueue ;;
 365     g | gf | gfi | gfil | gfile )       val=gfile ;;
 366     w | w3 | w32 )      val=w32 ;;
 367     * ) AC_MSG_ERROR(['--with-file-notification=$withval' is invalid;
 368 this option's value should be 'yes', 'no', 'inotify', 'kqueue', 'gfile' or 'w32'.
 369 'yes' is a synonym for 'w32' on MS-Windows, for 'no' on Nextstep,
 370 otherwise for the first of 'inotify', 'kqueue' or 'gfile' that is usable.])
 371     ;;
 372    esac
 373    with_file_notification=$val
 374  ],
 375  [with_file_notification=$with_features])
 376
 377 ## For the times when you want to build Emacs but don't have
 378 ## a suitable makeinfo, and can live without the manuals.
 379 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 380 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 381
 382 ## This might be a 'configure' arg.
 383 AC_SUBST([ACLOCAL_PATH])
 384
 385 ## Makefile.in needs the cache file name.
 386 AC_SUBST(cache_file)
 387
 388 ## This is an option because I do not know if all info/man support
 389 ## compressed files, nor how to test if they do so.
 390 OPTION_DEFAULT_ON([compress-install],
 391   [don't compress some files (.el, .info, etc.) when installing.  Equivalent to:
 392 make GZIP_PROG= install])
 393
 394 AC_ARG_WITH(gameuser,dnl
 395 [AS_HELP_STRING([--with-gameuser=USER_OR_GROUP],
 396                 [user for shared game score files.
 397                 An argument prefixed by ':' specifies a group instead.])])
 398 gameuser=
 399 gamegroup=
 400 # We don't test if we can actually chown/chgrp here, because configure
 401 # may run without root privileges.  lib-src/Makefile.in will handle
 402 # any errors due to missing user/group gracefully.
 403 case ${with_gameuser} in
 404   no) ;;
 405   "" | yes) gamegroup=games ;;
 406   :*) gamegroup=${with_gameuser#:} ;;
 407   *) gameuser=${with_gameuser} ;;
 408 esac
 409
 410 AC_ARG_WITH([gnustep-conf],dnl
 411 [AS_HELP_STRING([--with-gnustep-conf=FILENAME],
 412    [name of GNUstep configuration file to use on systems where the command
 413     'gnustep-config' does not work; default $GNUSTEP_CONFIG_FILE, or
 414     /etc/GNUstep/GNUstep.conf])])
 415 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 416   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 417 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 418      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 419
 420 AC_ARG_ENABLE(ns-self-contained,
 421 [AS_HELP_STRING([--disable-ns-self-contained],
 422                 [disable self contained build under NeXTstep])],
 423    EN_NS_SELF_CONTAINED=$enableval,
 424    EN_NS_SELF_CONTAINED=yes)
 425
 426 locallisppathset=no
 427 AC_ARG_ENABLE(locallisppath,
 428 [AS_HELP_STRING([--enable-locallisppath=PATH],
 429                 [directories Emacs should search for lisp files specific
 430                  to this site])],
 431 if test "${enableval}" = "no"; then
 432   locallisppath=
 433 elif test "${enableval}" != "yes"; then
 434   locallisppath=${enableval} locallisppathset=yes
 435 fi)
 436
 437 AC_ARG_ENABLE(checking,
 438 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 439                 [enable expensive run-time checks.  With LIST,
 440                  enable only specific categories of checks.
 441                  Categories are: all,yes,no.
 442                  Flags are: stringbytes, stringoverrun, stringfreelist,
 443                  xmallocoverrun, conslist, glyphs])],
 444 [ac_checking_flags="${enableval}"],[])
 445 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 446 for check in $ac_checking_flags
 447 do
 448         case $check in
 449         # these set all the flags to specific states
 450         yes)            ac_enable_checking=1 ;;
 451         no)             ac_enable_checking= ;
 452                         ac_gc_check_stringbytes= ;
 453                         ac_gc_check_string_overrun= ;
 454                         ac_gc_check_string_free_list= ;
 455                         ac_xmalloc_overrun= ;
 456                         ac_gc_check_cons_list= ;
 457                         ac_glyphs_debug= ;;
 458         all)            ac_enable_checking=1 ;
 459                         ac_gc_check_stringbytes=1 ;
 460                         ac_gc_check_string_overrun=1 ;
 461                         ac_gc_check_string_free_list=1 ;
 462                         ac_xmalloc_overrun=1 ;
 463                         ac_gc_check_cons_list=1 ;
 464                         ac_glyphs_debug=1 ;;
 465         # these enable particular checks
 466         stringbytes)    ac_gc_check_stringbytes=1 ;;
 467         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 468         stringfreelist) ac_gc_check_string_free_list=1 ;;
 469         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 470         conslist)       ac_gc_check_cons_list=1 ;;
 471         glyphs)         ac_glyphs_debug=1 ;;
 472         *)      AC_MSG_ERROR(unknown check category $check) ;;
 473         esac
 474 done
 475 IFS="$ac_save_IFS"
 476
 477 if test x$ac_enable_checking != x ; then
 478   AC_DEFINE(ENABLE_CHECKING, 1,
 479 [Define to 1 if expensive run-time data type and consistency checks are enabled.])
 480 fi
 481 if test x$ac_gc_check_stringbytes != x ; then
 482   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 483 [Define this temporarily to hunt a bug.  If defined, the size of
 484    strings is redundantly recorded in sdata structures so that it can
 485    be compared to the sizes recorded in Lisp strings.])
 486 fi
 487 if test x$ac_gc_check_string_overrun != x ; then
 488   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 489 [Define this to check for short string overrun.])
 490 fi
 491 if test x$ac_gc_check_string_free_list != x ; then
 492   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 493 [Define this to check the string free list.])
 494 fi
 495 if test x$ac_xmalloc_overrun != x ; then
 496   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 497 [Define this to check for malloc buffer overrun.])
 498 fi
 499 if test x$ac_gc_check_cons_list != x ; then
 500   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 501 [Define this to check for errors in cons list.])
 502 fi
 503 if test x$ac_glyphs_debug != x ; then
 504   AC_DEFINE(GLYPH_DEBUG, 1,
 505 [Define this to enable glyphs debugging code.])
 506 fi
 507
 508 AC_ARG_ENABLE(check-lisp-object-type,
 509 [AS_HELP_STRING([--enable-check-lisp-object-type],
 510                 [enable compile time checks for the Lisp_Object data type.
 511                 This is useful for development for catching certain types of bugs.])],
 512 if test "${enableval}" != "no"; then
 513    AC_DEFINE(CHECK_LISP_OBJECT_TYPE, 1,
 514    [Define this to enable compile time checks for the Lisp_Object data type.])
 515 fi)
 516
 517
 518 dnl The name of this option is unfortunate.  It predates, and has no
 519 dnl relation to, the "sampling-based elisp profiler" added in 24.3.
 520 dnl Actually, it stops it working.
 521 dnl http://lists.gnu.org/archive/html/emacs-devel/2012-11/msg00393.html
 522 AC_ARG_ENABLE(profiling,
 523 [AS_HELP_STRING([--enable-profiling],
 524                 [build emacs with low-level, gprof profiling support.
 525                 Mainly useful for debugging Emacs itself.  May not work on
 526                 all platforms.  Stops profiler.el working.])],
 527 [ac_enable_profiling="${enableval}"],[])
 528 if test x$ac_enable_profiling != x ; then
 529    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 530 else
 531    PROFILING_CFLAGS=
 532 fi
 533 AC_SUBST(PROFILING_CFLAGS)
 534
 535 AC_ARG_ENABLE(autodepend,
 536 [AS_HELP_STRING([--enable-autodepend],
 537                 [automatically generate dependencies to .h-files.
 538                  Requires gcc, enabled if found.])],
 539 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 540
 541 AC_ARG_ENABLE(gtk-deprecation-warnings,
 542 [AS_HELP_STRING([--enable-gtk-deprecation-warnings],
 543                 [Show Gtk+/Gdk deprecation warnings for Gtk+ >= 3.0])],
 544 [ac_enable_gtk_deprecation_warnings="${enableval}"],[])
 545
 546 dnl This used to use changequote, but, apart from 'changequote is evil'
 547 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 548 dnl the great gob of text.  Thus it's not processed for possible expansion.
 549 dnl Just make sure the brackets remain balanced.
 550 dnl
 551 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 552 dnl indicated by comments.
 553 dnl quotation begins
 554 [
 555
 556 ### If you add support for a new configuration, add code to this
 557 ### switch statement to recognize your configuration name and select
 558 ### the appropriate opsys.
 559
 560 ### As far as handling version numbers on operating systems is
 561 ### concerned, make sure things will fail in a fixable way.  If
 562 ### /etc/MACHINES doesn't say anything about version numbers, be
 563 ### prepared to handle anything reasonably.  If version numbers
 564 ### matter, be sure /etc/MACHINES says something about it.
 565
 566 opsys='' unported=no
 567 case "${canonical}" in
 568
 569   ## GNU/Linux and similar ports
 570   *-*-linux* )
 571     opsys=gnu-linux
 572   ;;
 573
 574   ## FreeBSD ports
 575   *-*-freebsd* )
 576     opsys=freebsd
 577   ;;
 578
 579   ## DragonFly ports
 580   *-*-dragonfly* )
 581     opsys=dragonfly
 582   ;;
 583
 584   ## FreeBSD kernel + glibc based userland
 585   *-*-kfreebsd*gnu* )
 586     opsys=gnu-kfreebsd
 587   ;;
 588
 589   ## NetBSD ports
 590   *-*-netbsd* )
 591     opsys=netbsd
 592   ;;
 593
 594   ## OpenBSD ports
 595   *-*-openbsd* | *-*-mirbsd* )
 596     opsys=openbsd
 597   ;;
 598
 599   ## Apple Darwin / Mac OS X
 600   *-apple-darwin* )
 601     case "${canonical}" in
 602       *-apple-darwin[0-9].*) unported=yes ;;
 603       i[3456]86-* | x86_64-* )  ;;
 604       * )            unported=yes ;;
 605     esac
 606     opsys=darwin
 607     ## Use fink packages if available.
 608     ## FIXME find a better way to do this: http://debbugs.gnu.org/11507
 609 ##    if test -d /sw/include && test -d /sw/lib; then
 610 ##      GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 611 ##      NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 612 ##    fi
 613   ;;
 614
 615   ## Chromium Native Client
 616   *-nacl )
 617     opsys=nacl
 618   ;;
 619
 620   ## Cygwin ports
 621   *-*-cygwin )
 622     opsys=cygwin
 623   ;;
 624
 625   ## HP 9000 series 700 and 800, running HP/UX
 626   hppa*-hp-hpux10.2* )
 627     opsys=hpux10-20
 628   ;;
 629   hppa*-hp-hpux1[1-9]* )
 630     opsys=hpux11
 631     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 632   ;;
 633
 634   ## IBM machines
 635   rs6000-ibm-aix4.[23]* )
 636     opsys=aix4-2
 637   ;;
 638   powerpc-ibm-aix4.[23]*  )
 639     opsys=aix4-2
 640   ;;
 641   rs6000-ibm-aix[56]* )
 642     opsys=aix4-2
 643   ;;
 644   powerpc-ibm-aix[5-9]* | powerpc-ibm-aix[1-9][0-9]* )
 645     opsys=aix4-2
 646   ;;
 647
 648   ## Silicon Graphics machines
 649   ## Iris 4D
 650   mips-sgi-irix6.5 )
 651     opsys=irix6-5
 652     # Without defining _LANGUAGE_C, things get masked out in the headers
 653     # so that, for instance, grepping for 'free' in stdlib.h fails and
 654     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 655     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 656   ;;
 657
 658   ## Suns
 659   *-sun-solaris* \
 660     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 661     | x86_64-*-solaris2*    | x86_64-*-sunos5*)
 662     case "${canonical}" in
 663       i[3456]86-*-* )   ;;
 664       amd64-*-*|x86_64-*-*) ;;
 665       sparc* )          ;;
 666       * )               unported=yes ;;
 667     esac
 668     case "${canonical}" in
 669       *-sunos5.[1-9][0-9]* | *-solaris2.[1-9][0-9]* )
 670                 opsys=sol2-10
 671                 emacs_check_sunpro_c=yes
 672                 ;;
 673       *-sunos5.[1-5]* | *-solaris2.[1-5]* ) unported=yes ;;
 674       ## Note that Emacs 23.1's NEWS said the following would be dropped.
 675       *-sunos5.6* | *-solaris2.6* )
 676                 opsys=sol2-6
 677                 RANLIB="ar -ts"
 678                 ;;
 679       ## 5.7 EOL Aug 2008, 5.8 EOL Mar 2012.
 680       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 681                 opsys=sol2-6
 682                 emacs_check_sunpro_c=yes
 683                 ;;
 684     esac
 685     ## Watch out for a compiler that we know will not work.
 686     case "${canonical}" in
 687      *-solaris* | *-sunos5* )
 688                 if [ "x$CC" = x/usr/ucb/cc ]; then
 689                   ## /usr/ucb/cc doesn't work;
 690                   ## we should find some other compiler that does work.
 691                   unset CC
 692                 fi
 693                 ;;
 694       *) ;;
 695     esac
 696   ;;
 697
 698   ## Intel 386 machines where we don't care about the manufacturer.
 699   i[3456]86-*-* )
 700     case "${canonical}" in
 701       *-darwin* )               opsys=darwin ;;
 702       *-mingw* )
 703                 opsys=mingw32
 704                 # MinGW overrides and adds some system headers in nt/inc.
 705                 GCC_TEST_OPTIONS="-I $srcdir/nt/inc"
 706                 ;;
 707       *-sysv4.2uw* )            opsys=unixware ;;
 708       *-sysv5uw* )              opsys=unixware ;;
 709       *-sysv5OpenUNIX* )        opsys=unixware ;;
 710       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 711     esac
 712   ;;
 713
 714   # MinGW64
 715   x86_64-*-* )
 716     case "${canonical}" in
 717       *-mingw* )
 718                 opsys=mingw32
 719                 # MinGW overrides and adds some system headers in nt/inc.
 720                 GCC_TEST_OPTIONS="-I $srcdir/nt/inc"
 721                 ;;
 722       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 723     esac
 724   ;;
 725
 726   * )
 727     unported=yes
 728   ;;
 729 esac
 730
 731 ### If the code above didn't choose an operating system, just choose
 732 ### an operating system based on the configuration name.  You really
 733 ### only want to use this when you have no idea what the right
 734 ### operating system is; if you know what operating systems a machine
 735 ### runs, it's cleaner to make it explicit in the case statement
 736 ### above.
 737 if test x"${opsys}" = x; then
 738   case "${canonical}" in
 739     *-gnu* )                            opsys=gnu ;;
 740     * )
 741       unported=yes
 742     ;;
 743   esac
 744 fi
 745
 746 ]
 747 dnl quotation ends
 748
 749 if test $unported = yes; then
 750   AC_MSG_ERROR([Emacs does not support '${canonical}' systems.
 751 If you think it should, please send a report to ${PACKAGE_BUGREPORT}.
 752 Check 'etc/MACHINES' for recognized configuration names.])
 753 fi
 754
 755 #### Choose a compiler.
 756
 757 dnl Don't bother to test for C89.
 758 AC_DEFUN([_AC_PROG_CC_C89], [$2])
 759
 760 dnl Sets GCC=yes if using gcc.
 761 AC_PROG_CC([gcc cc cl clang "$XCRUN gcc" "$XCRUN clang"])
 762 if test -n "$XCRUN"; then
 763   AC_CHECK_PROGS(AR, [ar "$XCRUN ar"])
 764   test -n "$AR" && export AR
 765 fi
 766
 767 dnl Emacs needs C99 or later.
 768 gl_PROG_CC_C99
 769
 770 AM_PROG_CC_C_O
 771
 772 if test x$GCC = xyes; then
 773   test "x$GCC_TEST_OPTIONS" != x && CC="$CC $GCC_TEST_OPTIONS"
 774 else
 775   test "x$NON_GCC_TEST_OPTIONS" != x && CC="$CC $NON_GCC_TEST_OPTIONS"
 776 fi
 777
 778 dnl This is used in lib/Makefile.am to use nt/gnulib.mk, the
 779 dnl alternative to lib/gnulib.mk, so as to avoid generating header files
 780 dnl that clash with MinGW.
 781 AM_CONDITIONAL([BUILDING_FOR_WINDOWSNT], [test "x$opsys" = "xmingw32"])
 782
 783 # Avoid gnulib's tests for -lcrypto, so that there's no static dependency on it.
 784 AC_DEFUN([gl_CRYPTO_CHECK])
 785 # Avoid gnulib's tests for HAVE_WORKING_O_NOATIME and HAVE_WORKING_O_NOFOLLOW,
 786 # as we don't use them.
 787 AC_DEFUN([gl_FCNTL_O_FLAGS])
 788 # Avoid gnulib's test for pthread_sigmask.
 789 funcs=
 790 for func in $ac_func_list; do
 791   test $func = pthread_sigmask || AS_VAR_APPEND([funcs], [" $func"])
 792 done
 793 ac_func_list=$funcs
 794 # Use the system putenv even if it lacks GNU features, as we don't need them,
 795 # and the gnulib replacement runs afoul of a FreeBSD 10.1 bug; see Bug#19874.
 796 AC_CHECK_FUNCS_ONCE([putenv])
 797 AC_DEFUN([gl_FUNC_PUTENV],
 798   [test "$ac_cv_func_putenv" = yes || REPLACE_PUTENV=1])
 799
 800 # Initialize gnulib right after choosing the compiler.
 801 dnl Amongst other things, this sets AR and ARFLAGS.
 802 gl_EARLY
 803
 804 if test "$ac_test_CFLAGS" != set; then
 805   # It's helpful to have C macros available to GDB, so prefer -g3 to -g
 806   # if -g3 works and the user does not specify CFLAGS.
 807   # This test must follow gl_EARLY; otherwise AC_LINK_IFELSE complains.
 808   case $CFLAGS in
 809     '-g')
 810       emacs_g3_CFLAGS='-g3';;
 811     '-g -O2')
 812       emacs_g3_CFLAGS='-g3 -O2';;
 813     *)
 814       emacs_g3_CFLAGS='';;
 815   esac
 816   if test -n "$emacs_g3_CFLAGS"; then
 817     emacs_save_CFLAGS=$CFLAGS
 818     CFLAGS=$emacs_g3_CFLAGS
 819     AC_CACHE_CHECK([whether $CC accepts $emacs_g3_CFLAGS],
 820       [emacs_cv_prog_cc_g3],
 821       [AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 822          [emacs_cv_prog_cc_g3=yes],
 823          [emacs_cv_prog_cc_g3=no])])
 824     if test $emacs_cv_prog_cc_g3 != yes; then
 825       CFLAGS=$emacs_save_CFLAGS
 826     fi
 827     if test $opsys = mingw32; then
 828       CFLAGS="$CFLAGS -gdwarf-2"
 829     fi
 830   fi
 831
 832   case $CFLAGS in
 833     *-O*) ;;
 834     *)
 835       # No optimization flag was inferred for this non-GCC compiler.
 836       # Try -O.  This is needed for xlc on AIX; see Bug#14258.
 837       emacs_save_CFLAGS=$CFLAGS
 838       test -z "$CFLAGS" || CFLAGS="$CFLAGS "
 839       CFLAGS=${CFLAGS}-O
 840       AC_CACHE_CHECK([whether $CC accepts -O],
 841         [emacs_cv_prog_cc_o],
 842         [AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 843            [emacs_cv_prog_cc_o=yes],
 844            [emacs_cv_prog_cc_o=no])])
 845       if test $emacs_cv_prog_cc_o != yes; then
 846         CFLAGS=$emacs_save_CFLAGS
 847       fi ;;
 848   esac
 849 fi
 850
 851 AC_ARG_ENABLE([gcc-warnings],
 852   [AS_HELP_STRING([--enable-gcc-warnings],
 853                   [turn on lots of GCC warnings/errors. This is intended for
 854                    developers, and may generate false alarms when used
 855                    with older or non-GNU development tools.])],
 856   [case $enableval in
 857      yes|no) ;;
 858      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
 859    esac
 860    gl_gcc_warnings=$enableval],
 861   [gl_gcc_warnings=no]
 862 )
 863
 864 # clang is unduly picky about some things.
 865 AC_CACHE_CHECK([whether the compiler is clang], [emacs_cv_clang],
 866   [AC_COMPILE_IFELSE(
 867      [AC_LANG_PROGRAM([[
 868           #ifndef __clang__
 869             error "not clang";
 870           #endif
 871         ]])],
 872      [emacs_cv_clang=yes],
 873      [emacs_cv_clang=no])])
 874
 875 # When compiling with GCC, prefer -isystem to -I when including system
 876 # include files, to avoid generating useless diagnostics for the files.
 877 if test "$gl_gcc_warnings" != yes; then
 878   isystem='-I'
 879   if test "$emacs_cv_clang" = yes
 880   then
 881      # Turn off some warnings if supported.
 882      gl_WARN_ADD([-Wno-switch])
 883      gl_WARN_ADD([-Wno-tautological-constant-out-of-range-compare])
 884      gl_WARN_ADD([-Wno-pointer-sign])
 885      gl_WARN_ADD([-Wno-string-plus-int])
 886      gl_WARN_ADD([-Wno-unknown-attributes])
 887   fi
 888 else
 889   isystem='-isystem '
 890
 891   # This, $nw, is the list of warnings we disable.
 892   nw=
 893
 894   case $with_x_toolkit in
 895     lucid | athena | motif)
 896        # Old toolkits mishandle 'const'.
 897        nw="$nw -Wwrite-strings"
 898        ;;
 899     *)
 900        gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
 901        ;;
 902   esac
 903   AC_SUBST([WERROR_CFLAGS])
 904
 905   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
 906   nw="$nw -Woverlength-strings"     # Not a problem these days
 907   nw="$nw -Wformat-nonliteral"      # we do this a lot
 908   nw="$nw -Wvla"                    # Emacs uses <vla.h>.
 909   nw="$nw -Wswitch-default"         # Too many warnings for now
 910   nw="$nw -Winline"                 # OK to ignore 'inline'
 911   nw="$nw -Wjump-misses-init"       # We sometimes safely jump over init.
 912   nw="$nw -Wstrict-overflow"        # OK to optimize assuming that
 913                                     # signed overflow has undefined behavior
 914   nw="$nw -Wsync-nand"              # irrelevant here, and provokes ObjC warning
 915   nw="$nw -Wunsafe-loop-optimizations" # OK to suppress unsafe optimizations
 916   nw="$nw -Wbad-function-cast"      # These casts are no worse than others.
 917
 918   # Emacs doesn't care about shadowing; see
 919   # <http://lists.gnu.org/archive/html/emacs-diffs/2011-11/msg00265.html>.
 920   nw="$nw -Wshadow"
 921
 922   # Emacs's use of alloca inhibits protecting the stack.
 923   nw="$nw -Wstack-protector"
 924
 925   # Emacs's use of partly-const functions such as Fgnutls_available_p
 926   # make this option problematic.
 927   nw="$nw -Wsuggest-attribute=const"
 928
 929   # Emacs's use of partly-pure functions such as CHECK_TYPE make this
 930   # option problematic.
 931   nw="$nw -Wsuggest-attribute=pure"
 932
 933   # This part is merely for shortening the command line,
 934   # since -Wall implies -Wswitch.
 935   nw="$nw -Wswitch"
 936
 937   # This part is merely for shortening the command line,
 938   # since -Wno-FOO needs to be added below regardless.
 939   nw="$nw -Wmissing-field-initializers"
 940   nw="$nw -Wtype-limits"
 941   nw="$nw -Wunused-parameter"
 942
 943   if test $emacs_cv_clang = yes; then
 944     nw="$nw -Wcast-align"
 945   fi
 946
 947   gl_MANYWARN_ALL_GCC([ws])
 948   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
 949   for w in $ws; do
 950     gl_WARN_ADD([$w])
 951   done
 952   gl_WARN_ADD([-Wredundant-decls])     # Prefer this, as we don't use Bison.
 953   gl_WARN_ADD([-Wno-missing-field-initializers]) # We need this one
 954   gl_WARN_ADD([-Wno-sign-compare])     # Too many warnings for now
 955   gl_WARN_ADD([-Wno-type-limits])      # Too many warnings for now
 956   gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now
 957   gl_WARN_ADD([-Wno-format-nonliteral])
 958
 959   # More things that clang is unduly picky about.
 960   if test $emacs_cv_clang = yes; then
 961     gl_WARN_ADD([-Wno-format-extra-args])
 962     gl_WARN_ADD([-Wno-tautological-constant-out-of-range-compare])
 963     gl_WARN_ADD([-Wno-unused-command-line-argument])
 964     gl_WARN_ADD([-Wno-unused-value])
 965   fi
 966
 967   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 968   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 969   AH_VERBATIM([GNULIB_PORTCHECK_FORTIFY_SOURCE],
 970   [/* Enable compile-time and run-time bounds-checking, and some warnings,
 971       without upsetting glibc 2.15+. */
 972    #if (defined GNULIB_PORTCHECK && !defined _FORTIFY_SOURCE \
 973         && defined __OPTIMIZE__ && __OPTIMIZE__)
 974    # define _FORTIFY_SOURCE 2
 975    #endif
 976   ])
 977
 978   # We use a slightly smaller set of warning options for lib/.
 979   # Remove the following and save the result in GNULIB_WARN_CFLAGS.
 980   nw=
 981   nw="$nw -Wunused-macros"
 982
 983   gl_MANYWARN_COMPLEMENT([GNULIB_WARN_CFLAGS], [$WARN_CFLAGS], [$nw])
 984   AC_SUBST([GNULIB_WARN_CFLAGS])
 985 fi
 986
 987 edit_cflags="
 988   s,///*,/,g
 989   s/^/ /
 990   s/ -I/ $isystem/g
 991   s/^ //
 992 "
 993
 994 AC_ARG_ENABLE(link-time-optimization,
 995 [AS_HELP_STRING([--enable-link-time-optimization],
 996                 [build emacs with link-time optimization.
 997                  This requires GCC 4.5.0 or later, or clang.
 998                  (Note that clang support is experimental - see INSTALL.)
 999                  It also makes Emacs harder to debug, and when we tried it
1000                  with GCC 4.9.0 x86-64 it made Emacs slower, so it's not
1001                  recommended for typical use.])],
1002 if test "${enableval}" != "no"; then
1003    ac_lto_supported=no
1004    if test $emacs_cv_clang = yes; then
1005       AC_MSG_CHECKING([whether link-time optimization is supported by clang])
1006       GOLD_PLUGIN=`$CC -print-file-name=LLVMgold.so 2>/dev/null`
1007       if test -x "$GOLD_PLUGIN"; then
1008          LTO="-flto"
1009       fi
1010    elif test x$GCC = xyes; then
1011       AC_MSG_CHECKING([whether link-time optimization is supported by gcc])
1012       CPUS=`getconf _NPROCESSORS_ONLN 2>/dev/null`
1013       if test x$CPUS != x; then
1014          LTO="-flto=$CPUS"
1015       else
1016          LTO="-flto"
1017       fi
1018    else
1019       AC_MSG_ERROR([Link-time optimization is not supported with your compiler.])
1020    fi
1021    if test -z "$LTO"; then
1022       ac_lto_supported=no
1023    else
1024       old_CFLAGS=$CFLAGS
1025       CFLAGS="$CFLAGS $LTO"
1026       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])],
1027          [ac_lto_supported=yes], [ac_lto_supported=no])
1028          CFLAGS="$old_CFLAGS"
1029    fi
1030    AC_MSG_RESULT([$ac_lto_supported])
1031    if test "$ac_lto_supported" = "yes"; then
1032       CFLAGS="$CFLAGS $LTO"
1033       if test x$emacs_cv_clang = xyes; then
1034          AC_MSG_WARN([Please read INSTALL before using link-time optimization with clang])
1035          # WARNING: 'ar --plugin ...' doesn't work without
1036          # command, so plugin name is appended to ARFLAGS.
1037          ARFLAGS="cru --plugin $GOLD_PLUGIN"
1038          RANLIB="$RANLIB --plugin $GOLD_PLUGIN"
1039       else
1040         dnl The following is needed for GCC 4.9.0.  The GCC 4.9.0 release notes
1041         dnl suggest that instead of -ffat-lto-objects we should use gcc-ar and
1042         dnl gcc-ranlib in place of ar and ranlib, but gcc-ar makes /usr/bin/ar
1043         dnl dump core on Fedora 20, so play it safe for now.
1044         gl_COMPILER_OPTION_IF([-ffat-lto-objects],
1045           [CFLAGS="$CFLAGS -ffat-lto-objects"])
1046       fi
1047    fi
1048 fi)
1049
1050 dnl Prefer silent make output.  For verbose output, use
1051 dnl 'configure --disable-silent-rules' or 'make V=1' .
1052 AM_SILENT_RULES([yes])
1053 dnl Port to Automake 1.11.
1054 dnl This section can be removed once we assume Automake 1.14 or later.
1055 : ${AM_V=$AM_DEFAULT_VERBOSITY}
1056 : ${AM_DEFAULT_V=$AM_DEFAULT_VERBOSITY}
1057 AC_SUBST([AM_V])
1058 AM_SUBST_NOTMAKE([AM_V])
1059 AC_SUBST([AM_DEFAULT_V])
1060 AM_SUBST_NOTMAKE([AM_DEFAULT_V])
1061 AC_SUBST([AM_DEFAULT_VERBOSITY])
1062
1063 dnl Some other nice autoconf tests.
1064 dnl These are commented out, since gl_EARLY and/or Autoconf already does them.
1065 dnl AC_PROG_INSTALL
1066 dnl AC_PROG_MKDIR_P
1067 dnl if test "x$RANLIB" = x; then
1068 dnl   AC_PROG_RANLIB
1069 dnl fi
1070
1071
1072 dnl Sadly, AC_PROG_LN_S is too restrictive.  It also tests whether links
1073 dnl can be made to directories.  This is not relevant for our usage, and
1074 dnl excludes some cases that work fine for us.  Eg MS Windows or files
1075 dnl hosted on AFS, both examples where simple links work, but links to
1076 dnl directories fail.  We use a cut-down version instead.
1077 dnl AC_PROG_LN_S
1078
1079 AC_MSG_CHECKING([whether ln -s works for files in the same directory])
1080 rm -f conf$$ conf$$.file
1081
1082 LN_S_FILEONLY='cp -p'
1083
1084 dnl On MinGW, ensure we will call the MSYS /bin/ln.exe, not some
1085 dnl random program in the current directory.
1086 if (echo >conf$$.file) 2>/dev/null; then
1087   if ln -s conf$$.file conf$$ 2>/dev/null; then
1088     if test "$opsys" = "mingw32"; then
1089       LN_S_FILEONLY='/bin/ln -s'
1090     else
1091       LN_S_FILEONLY='ln -s'
1092     fi
1093   elif ln conf$$.file conf$$ 2>/dev/null; then
1094     if test "$opsys" = "mingw32"; then
1095       LN_S_FILEONLY=/bin/ln
1096     else
1097       LN_S_FILEONLY=ln
1098     fi
1099   fi
1100 fi
1101
1102 rm -f conf$$ conf$$.file
1103
1104 if test "$LN_S_FILEONLY" = "ln -s"; then
1105    AC_MSG_RESULT([yes])
1106 else
1107    AC_MSG_RESULT([no, using $LN_S_FILEONLY])
1108 fi
1109
1110 AC_SUBST(LN_S_FILEONLY)
1111
1112
1113 dnl AC_PROG_LN_S sets LN_S to 'cp -pR' for MinGW, on the premise that 'ln'
1114 dnl doesn't support links to directories, as in "ln file dir".  But that
1115 dnl use is non-portable, and OTOH MinGW wants to use hard links for Emacs
1116 dnl executables at "make install" time.
1117 dnl See http://lists.gnu.org/archive/html/emacs-devel/2013-04/msg00475.html
1118 dnl for more details.
1119 if test "$opsys" = "mingw32"; then
1120   LN_S="/bin/ln"
1121 fi
1122
1123 dnl On some Debian versions, "install-info" prints irritating messages
1124 dnl "This is not dpkg install-info anymore, but GNU install-info"
1125 dnl if called via an absolute file name.
1126 dnl Use the entirely-identical-but-quieter ginstall-info instead if present.
1127 dnl Sadly some people may have an old ginstall-info installed on
1128 dnl non-Debian systems, so we can't use this.
1129 dnl AC_PATH_PROGS(INSTALL_INFO, [ginstall-info install-info], :,
1130 dnl   $PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin)
1131
1132 AC_PATH_PROG(INSTALL_INFO, install-info, :,
1133   $PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin)
1134 dnl Don't use GZIP, which is used by gzip for additional parameters.
1135 AC_PATH_PROG(GZIP_PROG, gzip)
1136
1137 test $with_compress_install != yes && test -n "$GZIP_PROG" && \
1138    GZIP_PROG=" # $GZIP_PROG # (disabled by configure --without-compress-install)"
1139
1140 if test $opsys = gnu-linux; then
1141   AC_PATH_PROG(PAXCTL, paxctl,,
1142     [$PATH$PATH_SEPARATOR/sbin$PATH_SEPARATOR/usr/sbin])
1143   if test "X$PAXCTL" != X; then
1144     AC_MSG_CHECKING([whether binaries have a PT_PAX_FLAGS header])
1145     AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
1146       [if $PAXCTL -v conftest$EXEEXT >/dev/null 2>&1; then AC_MSG_RESULT(yes)
1147       else AC_MSG_RESULT(no); PAXCTL=""; fi])
1148   fi
1149
1150   if test "${SETFATTR+set}" != set; then
1151     AC_CACHE_CHECK([for setfattr],
1152       [emacs_cv_prog_setfattr],
1153       [touch conftest.tmp
1154        if (setfattr -n user.pax.flags conftest.tmp) >/dev/null 2>&1; then
1155          emacs_cv_prog_setfattr=yes
1156        else
1157          emacs_cv_prog_setfattr=no
1158        fi])
1159     if test "$emacs_cv_prog_setfattr" = yes; then
1160       SETFATTR=setfattr
1161     else
1162       SETFATTR=
1163     fi
1164     rm -f conftest.tmp
1165     AC_SUBST([SETFATTR])
1166   fi
1167 fi
1168
1169 ## Need makeinfo >= 4.7 (?) to build the manuals.
1170 if test "$MAKEINFO" != "no"; then
1171   if test "$MAKEINFO" = "${am_missing_run}makeinfo"; then
1172     MAKEINFO=makeinfo
1173   fi
1174   case `($MAKEINFO --version) 2>/dev/null` in
1175     *' (GNU texinfo) '4.[[7-9]]* | \
1176     *' (GNU texinfo) '4.[[1-9][0-9]]* | \
1177     *' (GNU texinfo) '[[5-9]]* | \
1178     *' (GNU texinfo) '[[1-9][0-9]]* ) ;;
1179     *) MAKEINFO=no;;
1180   esac
1181 fi
1182
1183 ## Makeinfo is unusual.  For a released Emacs, the manuals are
1184 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
1185 ## therefore in the category of "special tools" not normally required, which
1186 ## configure does not have to check for (eg autoconf itself).
1187 ## In a repository checkout on the other hand, the manuals are not included.
1188 ## So makeinfo is a requirement to build from the repository, and configure
1189 ## should test for it as it does for any other build requirement.
1190 ## We use the presence of $srcdir/info/emacs to distinguish a release,
1191 ## with pre-built manuals, from a repository checkout.
1192 HAVE_MAKEINFO=yes
1193
1194 if test "$MAKEINFO" = "no"; then
1195   MAKEINFO=makeinfo
1196   if test "x${with_makeinfo}" = "xno"; then
1197     HAVE_MAKEINFO=no
1198   elif test ! -e "$srcdir/info/emacs" && test ! -e "$srcdir/info/emacs.info"; then
1199     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.7, and your
1200 source tree does not seem to have pre-built manuals in the 'info' directory.
1201 Either install a suitable version of makeinfo, or re-run configure
1202 with the '--without-makeinfo' option to build without the manuals.] )
1203   fi
1204 fi
1205 AC_SUBST(HAVE_MAKEINFO)
1206
1207 if test $opsys = mingw32; then
1208    DOCMISC_W32=efaq-w32
1209 else
1210    DOCMISC_W32=
1211 fi
1212 AC_SUBST(DOCMISC_W32)
1213
1214 dnl Add our options to ac_link now, after it is set up.
1215
1216 if test x$GCC = xyes; then
1217   test "x$GCC_LINK_TEST_OPTIONS" != x && \
1218     ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
1219 else
1220   test "x$NON_GCC_LINK_TEST_OPTIONS" != x && \
1221     ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
1222 fi
1223
1224 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
1225 dnl If we can link with the flag, it shouldn't do any harm anyhow.
1226 dnl (Don't use '-z nocombreloc' as -z takes no arg on Irix.)
1227 dnl Treat GCC specially since it just gives a non-fatal 'unrecognized option'
1228 dnl if not built to support GNU ld.
1229
1230 dnl For a long time, -znocombreloc was added to LDFLAGS rather than
1231 dnl LD_SWITCH_SYSTEM_TEMACS.  That is:
1232 dnl * inappropriate, as LDFLAGS is a user option but this is essential.
1233 dnl   Eg "make LDFLAGS=... all" could run into problems,
1234 dnl   http://bugs.debian.org/684788
1235 dnl * unnecessary, since temacs is the only thing that actually needs it.
1236 dnl   Indeed this is where it was originally, prior to:
1237 dnl   http://lists.gnu.org/archive/html/emacs-pretest-bug/2004-03/msg00170.html
1238 late_LDFLAGS="$LDFLAGS"
1239 if test x$GCC = xyes; then
1240   LDFLAGS_NOCOMBRELOC="-Wl,-znocombreloc"
1241 else
1242   LDFLAGS_NOCOMBRELOC="-znocombreloc"
1243 fi
1244
1245 LDFLAGS="$LDFLAGS $LDFLAGS_NOCOMBRELOC"
1246
1247 AC_MSG_CHECKING([for -znocombreloc])
1248 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
1249   [AC_MSG_RESULT(yes)],
1250   LDFLAGS_NOCOMBRELOC=
1251   [AC_MSG_RESULT(no)])
1252
1253 LDFLAGS="$late_LDFLAGS"
1254
1255 AC_CACHE_CHECK([whether addresses are sanitized],
1256   [emacs_cv_sanitize_address],
1257   [AC_COMPILE_IFELSE(
1258      [AC_LANG_PROGRAM(
1259         [[#ifndef __has_feature
1260           #define __has_feature(f) 0
1261           #endif
1262           #if defined __SANITIZE_ADDRESS__ || __has_feature (address_sanitizer)
1263           #else
1264            error "Addresses are not sanitized.";
1265           #endif
1266         ]])],
1267      [emacs_cv_sanitize_address=yes],
1268      [emacs_cv_sanitize_address=no])])
1269
1270 dnl The function dump-emacs will not be defined and temacs will do
1271 dnl (load "loadup") automatically unless told otherwise.
1272 test "x$CANNOT_DUMP" = "x" && CANNOT_DUMP=no
1273 case "$opsys" in
1274   nacl) CANNOT_DUMP=yes ;;
1275 esac
1276
1277 if test "$CANNOT_DUMP" = "yes"; then
1278   AC_DEFINE(CANNOT_DUMP, 1, [Define if Emacs cannot be dumped on your system.])
1279 elif test "$emacs_cv_sanitize_address" = yes; then
1280   AC_MSG_WARN([[Addresses are sanitized; suggest CANNOT_DUMP=yes]])
1281 fi
1282
1283 AC_SUBST(CANNOT_DUMP)
1284
1285
1286 UNEXEC_OBJ=unexelf.o
1287 case "$opsys" in
1288   # MSDOS uses unexcoff.o
1289   aix4-2)
1290    UNEXEC_OBJ=unexaix.o
1291    ;;
1292   cygwin)
1293    UNEXEC_OBJ=unexcw.o
1294    ;;
1295   darwin)
1296    UNEXEC_OBJ=unexmacosx.o
1297    ;;
1298   hpux10-20 | hpux11)
1299    UNEXEC_OBJ=unexhp9k800.o
1300    ;;
1301   mingw32)
1302    UNEXEC_OBJ=unexw32.o
1303    ;;
1304   sol2-10)
1305    # Use the Solaris dldump() function, called from unexsol.c, to dump
1306    # emacs, instead of the generic ELF dump code found in unexelf.c.
1307    # The resulting binary has a complete symbol table, and is better
1308    # for debugging and other observability tools (debuggers, pstack, etc).
1309    #
1310    # If you encounter a problem using dldump(), please consider sending
1311    # a message to the OpenSolaris tools-linking mailing list:
1312    #      http://mail.opensolaris.org/mailman/listinfo/tools-linking
1313    #
1314    # It is likely that dldump() works with older Solaris too, but this has
1315    # not been tested, so for now this change is for Solaris 10 or newer.
1316    UNEXEC_OBJ=unexsol.o
1317    ;;
1318 esac
1319
1320 LD_SWITCH_SYSTEM=
1321 case "$opsys" in
1322   freebsd|dragonfly)
1323    ## Let 'ld' find image libs and similar things in /usr/local/lib.
1324    ## The system compiler, GCC, has apparently been modified to not
1325    ## look there, contrary to what a stock GCC would do.
1326 ### It's not our place to do this.  See bug#10313#17.
1327 ###   LD_SWITCH_SYSTEM=-L/usr/local/lib
1328       :
1329    ;;
1330
1331   gnu-linux)
1332    ## cpp test was "ifdef __mips__", but presumably this is equivalent...
1333    case $host_cpu in mips*) LD_SWITCH_SYSTEM="-G 0";; esac
1334    ;;
1335
1336   netbsd)
1337 ### It's not our place to do this.  See bug#10313#17.
1338 ###   LD_SWITCH_SYSTEM="-Wl,-rpath,/usr/pkg/lib -L/usr/pkg/lib -Wl,-rpath,/usr/local/lib -L/usr/local/lib"
1339       :
1340    ;;
1341
1342   openbsd)
1343    ## Han Boetes <han@boetes.org> says this is necessary,
1344    ## otherwise Emacs dumps core on elf systems.
1345    LD_SWITCH_SYSTEM="-Z"
1346    ;;
1347 esac
1348 AC_SUBST(LD_SWITCH_SYSTEM)
1349
1350 ac_link="$ac_link $LD_SWITCH_SYSTEM"
1351
1352 ## This setting of LD_SWITCH_SYSTEM references LD_SWITCH_X_SITE_RPATH,
1353 ## which has not been defined yet.  When this was handled with cpp,
1354 ## it was expanded to null when configure sourced the s/*.h file.
1355 ## Thus LD_SWITCH_SYSTEM had different values in configure and the Makefiles.
1356 ## FIXME it would be cleaner to put this in LD_SWITCH_SYSTEM_TEMACS
1357 ## (or somesuch), but because it is supposed to go at the _front_
1358 ## of LD_SWITCH_SYSTEM, we cannot do that in exactly the same way.
1359 ## Compare with the gnu-linux case below, which added to the end
1360 ## of LD_SWITCH_SYSTEM, and so can instead go at the front of
1361 ## LD_SWITCH_SYSTEM_TEMACS.
1362 case "$opsys" in
1363   netbsd|openbsd)
1364    LD_SWITCH_SYSTEM="\$(LD_SWITCH_X_SITE_RPATH) $LD_SWITCH_SYSTEM" ;;
1365 esac
1366
1367
1368 C_SWITCH_MACHINE=
1369 case $canonical in
1370  alpha*)
1371   AC_CHECK_DECL([__ELF__])
1372   if test "$ac_cv_have_decl___ELF__" = "yes"; then
1373     ## With ELF, make sure that all common symbols get allocated to in the
1374     ## data section.  Otherwise, the dump of temacs may miss variables in
1375     ## the shared library that have been initialized.  For example, with
1376     ## GNU libc, __malloc_initialized would normally be resolved to the
1377     ## shared library's .bss section, which is fatal.
1378     if test "x$GCC" = "xyes"; then
1379       C_SWITCH_MACHINE="-fno-common"
1380     else
1381       AC_MSG_ERROR([Non-GCC compilers are not supported.])
1382     fi
1383   else
1384       dnl This was the unexalpha.c case.  Removed in 24.1, 2010-07-24,
1385       dnl albeit under the mistaken assumption that said file
1386       dnl was no longer used.
1387       AC_MSG_ERROR([Non-ELF systems are not supported since Emacs 24.1.])
1388   fi
1389   ;;
1390 esac
1391 AC_SUBST(C_SWITCH_MACHINE)
1392
1393 AC_SUBST(UNEXEC_OBJ)
1394
1395 C_SWITCH_SYSTEM=
1396 ## Some programs in src produce warnings saying certain subprograms
1397 ## are too complex and need a MAXMEM value greater than 2000 for
1398 ## additional optimization.  --nils@exp-math.uni-essen.de
1399 test "$opsys" = "aix4.2" && test "x$GCC" != "xyes" && \
1400   C_SWITCH_SYSTEM="-ma -qmaxmem=4000"
1401 if test "$opsys" = "mingw32"; then
1402   case "$canonical" in
1403     x86_64-*-mingw*) C_SWITCH_SYSTEM="-mtune=generic" ;;
1404     *) C_SWITCH_SYSTEM="-mtune=pentium4" ;;
1405   esac
1406 fi
1407 ## gnu-linux might need -D_BSD_SOURCE on old libc5 systems.
1408 ## It is redundant in glibc2, since we define _GNU_SOURCE.
1409 AC_SUBST(C_SWITCH_SYSTEM)
1410
1411
1412 LIBS_SYSTEM=
1413 case "$opsys" in
1414   ## IBM's X11R5 uses -lIM and -liconv in AIX 3.2.2.
1415   aix4-2) LIBS_SYSTEM="-lrts -lIM -liconv" ;;
1416
1417   freebsd|dragonfly) LIBS_SYSTEM="-lutil" ;;
1418
1419   hpux*) LIBS_SYSTEM="-l:libdld.sl" ;;
1420
1421   sol2*) LIBS_SYSTEM="-lsocket -lnsl" ;;
1422
1423   ## Motif needs -lgen.
1424   unixware) LIBS_SYSTEM="-lsocket -lnsl -lelf -lgen" ;;
1425 esac
1426
1427 AC_SUBST(LIBS_SYSTEM)
1428
1429 ### Make sure subsequent tests use flags consistent with the build flags.
1430
1431 if test x"${OVERRIDE_CPPFLAGS}" != x; then
1432   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
1433 else
1434   CPPFLAGS="$C_SWITCH_SYSTEM $C_SWITCH_MACHINE $CPPFLAGS"
1435 fi
1436
1437 # Suppress obsolescent Autoconf test for size_t; Emacs assumes C99 or better.
1438 AC_DEFUN([AC_TYPE_SIZE_T])
1439 # Likewise for obsolescent test for uid_t, gid_t; Emacs assumes them.
1440 AC_DEFUN([AC_TYPE_UID_T])
1441
1442 # sqrt and other floating-point functions such as fmod and frexp
1443 # are found in -lm on many systems.
1444 OLD_LIBS=$LIBS
1445 AC_SEARCH_LIBS([sqrt], [m])
1446 if test "X$LIBS" = "X$OLD_LIBS"; then
1447   LIB_MATH=
1448 else
1449   LIB_MATH=$ac_cv_search_sqrt
1450 fi
1451 LIBS=$OLD_LIBS
1452
1453 dnl Current possibilities handled by sed (aix4-2 -> aix,
1454 dnl gnu-linux -> gnu/linux, etc.):
1455 dnl gnu, gnu/linux, gnu/kfreebsd, aix, cygwin, darwin, hpux, irix.
1456 dnl And special cases: berkeley-unix, usg-unix-v, ms-dos, windows-nt.
1457 SYSTEM_TYPE=`echo $opsys | sed -e 's/[[0-9]].*//' -e 's|-|/|'`
1458
1459 case $opsys in
1460   cygwin )
1461     LIB_MATH=
1462     ;;
1463   darwin )
1464     ## Adding -lm confuses the dynamic linker, so omit it.
1465     LIB_MATH=
1466     ;;
1467   freebsd | dragonfly )
1468     SYSTEM_TYPE=berkeley-unix
1469     ;;
1470   gnu-linux | gnu-kfreebsd )
1471     ;;
1472   hpux10-20 | hpux11 )
1473     ;;
1474   mingw32 )
1475     LIB_MATH=
1476     SYSTEM_TYPE=windows-nt
1477     ;;
1478   dnl NB this may be adjusted below.
1479   netbsd | openbsd )
1480     SYSTEM_TYPE=berkeley-unix
1481     ;;
1482
1483   sol2* | unixware )
1484     SYSTEM_TYPE=usg-unix-v
1485     ;;
1486
1487 esac
1488
1489 AC_SUBST(LIB_MATH)
1490 AC_DEFINE_UNQUOTED(SYSTEM_TYPE, "$SYSTEM_TYPE",
1491   [The type of system you are compiling for; sets 'system-type'.])
1492
1493
1494 pre_PKG_CONFIG_CFLAGS=$CFLAGS
1495 pre_PKG_CONFIG_LIBS=$LIBS
1496
1497 PKG_PROG_PKG_CONFIG(0.9.0)
1498
1499 dnl EMACS_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4)
1500 dnl acts like PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4,
1501 dnl HAVE_GSTUFF=yes, HAVE_GSTUFF=no) -- see pkg-config man page --
1502 dnl except that it postprocesses CFLAGS as needed for --enable-gcc-warnings.
1503 dnl EMACS_CHECK_MODULES accepts optional 3rd and 4th arguments that
1504 dnl can take the place of the default HAVE_GSTUFF=yes and HAVE_GSTUFF=no
1505 dnl actions.
1506 AC_DEFUN([EMACS_CHECK_MODULES],
1507   [PKG_CHECK_MODULES([$1], [$2],
1508      [$1_CFLAGS=`AS_ECHO(["$$1_CFLAGS"]) | sed -e "$edit_cflags"`
1509       m4_default([$3], [HAVE_$1=yes])],
1510      [m4_default([$4], [HAVE_$1=no])])])
1511
1512 HAVE_SOUND=no
1513 if test "${with_sound}" != "no"; then
1514   # Sound support for GNU/Linux, the free BSDs, MinGW, and Cygwin.
1515   AC_CHECK_HEADERS([machine/soundcard.h sys/soundcard.h soundcard.h mmsystem.h],
1516     have_sound_header=yes, [], [
1517     #ifdef __MINGW32__
1518     #define WIN32_LEAN_AND_MEAN
1519     #include <windows.h>
1520     #endif
1521     ])
1522   test "${with_sound}" = "oss" && test "${have_sound_header}" != "yes" && \
1523     AC_MSG_ERROR([OSS sound support requested but not found.])
1524
1525   if test "${with_sound}" = "bsd-ossaudio" || test "${with_sound}" = "yes"; then
1526     # Emulation library used on NetBSD.
1527     AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1528     test "${with_sound}" = "bsd-ossaudio" && test -z "$LIBSOUND" && \
1529       AC_MSG_ERROR([bsd-ossaudio sound support requested but not found.])
1530     dnl FIXME?  If we did find ossaudio, should we set with_sound=bsd-ossaudio?
1531     dnl Traditionally, we go on to check for alsa too.  Does that make sense?
1532   fi
1533   AC_SUBST(LIBSOUND)
1534
1535   if test "${with_sound}" = "alsa" || test "${with_sound}" = "yes"; then
1536     ALSA_REQUIRED=1.0.0
1537     ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1538     EMACS_CHECK_MODULES([ALSA], [$ALSA_MODULES])
1539     if test $HAVE_ALSA = yes; then
1540       SAVE_CFLAGS="$CFLAGS"
1541       SAVE_LIBS="$LIBS"
1542       CFLAGS="$ALSA_CFLAGS $CFLAGS"
1543       LIBS="$ALSA_LIBS $LIBS"
1544       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <asoundlib.h>]], [[snd_lib_error_set_handler (0);]])],
1545                       emacs_alsa_normal=yes,
1546                     emacs_alsa_normal=no)
1547       if test "$emacs_alsa_normal" != yes; then
1548         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <alsa/asoundlib.h>]],
1549                        [[snd_lib_error_set_handler (0);]])],
1550                        emacs_alsa_subdir=yes,
1551                      emacs_alsa_subdir=no)
1552         if test "$emacs_alsa_subdir" != yes; then
1553           AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1554         fi
1555         ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1556       fi
1557
1558       CFLAGS="$SAVE_CFLAGS"
1559       LIBS="$SAVE_LIBS"
1560       LIBSOUND="$LIBSOUND $ALSA_LIBS"
1561       CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1562       AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1563     elif test "${with_sound}" = "alsa"; then
1564       AC_MSG_ERROR([ALSA sound support requested but not found.])
1565     fi
1566   fi                            dnl with_sound = alsa|yes
1567
1568   dnl Define HAVE_SOUND if we have sound support.  We know it works and
1569   dnl compiles only on the specified platforms.  For others, it
1570   dnl probably doesn't make sense to try.
1571   dnl FIXME So surely we should bypass this whole section if not using
1572   dnl one of these platforms?
1573   if test x$have_sound_header = xyes || test $HAVE_ALSA = yes; then
1574      case "$opsys" in
1575        dnl defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
1576        dnl Adjust the --with-sound help text if you change this.
1577        gnu-linux|freebsd|netbsd|mingw32|cygwin)
1578          AC_DEFINE(HAVE_SOUND, 1, [Define to 1 if you have sound support.])
1579          HAVE_SOUND=yes
1580          ;;
1581      esac
1582   fi
1583
1584   AC_SUBST(CFLAGS_SOUND)
1585 fi
1586
1587 dnl checks for header files
1588 AC_CHECK_HEADERS_ONCE(
1589   sys/systeminfo.h
1590   sys/sysinfo.h
1591   coff.h pty.h
1592   sys/resource.h
1593   sys/utsname.h pwd.h utmp.h util.h)
1594
1595 AC_MSG_CHECKING(if personality LINUX32 can be set)
1596 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/personality.h>]], [[personality (PER_LINUX32)]])],
1597                emacs_cv_personality_linux32=yes,
1598                emacs_cv_personality_linux32=no)
1599 AC_MSG_RESULT($emacs_cv_personality_linux32)
1600
1601 if test $emacs_cv_personality_linux32 = yes; then
1602   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1603             [Define to 1 if personality LINUX32 can be set.])
1604 fi
1605
1606 # Note that Solaris has sys/sysinfo.h which defines struct
1607 # sysinfo as well.  To make sure that we're using GNU/Linux
1608 # sysinfo, we explicitly set one of its fields.
1609 if test "$ac_cv_header_sys_sysinfo_h" = yes; then
1610   AC_MSG_CHECKING([if Linux sysinfo may be used])
1611   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/sysinfo.h>]],
1612                                      [[struct sysinfo si;
1613                                        si.totalram = 0;
1614                                        sysinfo (&si)]])],
1615     emacs_cv_linux_sysinfo=yes, emacs_cv_linux_sysinfo=no)
1616   AC_MSG_RESULT($emacs_cv_linux_sysinfo)
1617   if test $emacs_cv_linux_sysinfo = yes; then
1618     AC_DEFINE([HAVE_LINUX_SYSINFO], 1, [Define to 1 if you have Linux sysinfo function.])
1619     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/sysinfo.h>]],
1620                                        [[struct sysinfo si; return si.mem_unit]])],
1621       AC_DEFINE(LINUX_SYSINFO_UNIT, 1,
1622                 [Define to 1 if Linux sysinfo sizes are in multiples of mem_unit bytes.]))
1623   fi
1624 fi
1625
1626 dnl On Solaris 8 there's a compilation warning for term.h because
1627 dnl it doesn't define 'bool'.
1628 AC_CHECK_HEADERS(term.h, , , -)
1629 AC_HEADER_TIME
1630 AC_CHECK_DECLS([sys_siglist], [], [], [[#include <signal.h>
1631                                       ]])
1632 if test $ac_cv_have_decl_sys_siglist != yes; then
1633   # For Tru64, at least:
1634   AC_CHECK_DECLS([__sys_siglist], [], [], [[#include <signal.h>
1635                                           ]])
1636 fi
1637 AC_HEADER_SYS_WAIT
1638
1639 AC_CHECK_HEADERS_ONCE(sys/socket.h)
1640 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1641 #if HAVE_SYS_SOCKET_H
1642 #include <sys/socket.h>
1643 #endif])
1644 AC_CHECK_HEADERS(ifaddrs.h, , , [AC_INCLUDES_DEFAULT
1645 #if HAVE_SYS_SOCKET_H
1646 #include <sys/socket.h>
1647 #endif])
1648 AC_CHECK_HEADERS(net/if_dl.h, , , [AC_INCLUDES_DEFAULT
1649 #if HAVE_SYS_SOCKET_H
1650 #include <sys/socket.h>
1651 #endif])
1652
1653 dnl checks for structure members
1654 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1655                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1656                   struct ifreq.ifr_addr,
1657                   struct ifreq.ifr_addr.sa_len], , ,
1658                  [AC_INCLUDES_DEFAULT
1659 #if HAVE_SYS_SOCKET_H
1660 #include <sys/socket.h>
1661 #endif
1662 #if HAVE_NET_IF_H
1663 #include <net/if.h>
1664 #endif])
1665
1666 dnl Check for endianness.
1667 dnl AC_C_BIGENDIAN is done by gnulib.
1668
1669 dnl check for Make feature
1670
1671 AUTO_DEPEND=no
1672 dnl check if we have GCC and autodepend is on.
1673 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1674    AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1675    SAVE_CFLAGS="$CFLAGS"
1676    CFLAGS="$CFLAGS -MMD -MF deps.d -MP"
1677    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], , ac_enable_autodepend=no)
1678    CFLAGS="$SAVE_CFLAGS"
1679    test -f deps.d || ac_enable_autodepend=no
1680    rm -rf deps.d
1681    AC_MSG_RESULT([$ac_enable_autodepend])
1682    if test $ac_enable_autodepend = yes; then
1683       AUTO_DEPEND=yes
1684    fi
1685 fi
1686 AC_SUBST(AUTO_DEPEND)
1687
1688 dnl checks for operating system services
1689 AC_SYS_LONG_FILE_NAMES
1690
1691 #### Choose a window system.
1692
1693 ## We leave window_system equal to none if
1694 ## we end up building without one.  Any new window system should
1695 ## set window_system to an appropriate value and add objects to
1696 ## window-system-specific substs.
1697
1698 window_system=none
1699 AC_PATH_X
1700 if test "$no_x" != yes; then
1701   window_system=x11
1702 fi
1703
1704 LD_SWITCH_X_SITE_RPATH=
1705 if test "${x_libraries}" != NONE; then
1706   if test -n "${x_libraries}"; then
1707     LD_SWITCH_X_SITE=-L`AS_ECHO(["$x_libraries"]) | sed -e 's/:/ -L/g'`
1708     LD_SWITCH_X_SITE_RPATH=-Wl,-rpath,`
1709       AS_ECHO(["$x_libraries"]) | sed -e 's/:/ -Wl,-rpath,/g'
1710     `
1711   fi
1712   x_default_search_path=""
1713   x_search_path=${x_libraries}
1714   if test -z "${x_search_path}"; then
1715     x_search_path=/usr/lib
1716   fi
1717   for x_library in `AS_ECHO(["$x_search_path:"]) | \
1718                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1719     x_search_path="\
1720 ${x_library}/X11/%L/%T/%N%C%S:\
1721 ${x_library}/X11/%l/%T/%N%C%S:\
1722 ${x_library}/X11/%T/%N%C%S:\
1723 ${x_library}/X11/%L/%T/%N%S:\
1724 ${x_library}/X11/%l/%T/%N%S:\
1725 ${x_library}/X11/%T/%N%S"
1726     if test x"${x_default_search_path}" = x; then
1727       x_default_search_path=${x_search_path}
1728     else
1729       x_default_search_path="${x_search_path}:${x_default_search_path}"
1730     fi
1731   done
1732 fi
1733 AC_SUBST(LD_SWITCH_X_SITE_RPATH)
1734
1735 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1736   C_SWITCH_X_SITE=$isystem`AS_ECHO(["$x_includes"]) | sed -e "s/:/ $isystem/g"`
1737 fi
1738
1739 if test x"${x_includes}" = x; then
1740   bitmapdir=/usr/include/X11/bitmaps
1741 else
1742   # accumulate include directories that have X11 bitmap subdirectories
1743   bmd_acc=
1744   for bmd in `AS_ECHO(["$x_includes"]) | sed -e 's/:/ /g'`; do
1745     if test -d "${bmd}/X11/bitmaps"; then
1746       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1747     fi
1748     if test -d "${bmd}/bitmaps"; then
1749       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1750     fi
1751   done
1752   bitmapdir=${bmd_acc#:}
1753 fi
1754
1755 test "${with_ns}" = maybe && test "${opsys}" != darwin && with_ns=no
1756 HAVE_NS=no
1757 NS_GNUSTEP_CONFIG=no
1758 NS_IMPL_COCOA=no
1759 NS_IMPL_GNUSTEP=no
1760 tmp_CPPFLAGS="$CPPFLAGS"
1761 tmp_CFLAGS="$CFLAGS"
1762 CPPFLAGS="$CPPFLAGS -x objective-c"
1763 CFLAGS="$CFLAGS -x objective-c"
1764 GNU_OBJC_CFLAGS=
1765 LIBS_GNUSTEP=
1766 if test "${with_ns}" != no; then
1767   if test "${opsys}" = darwin; then
1768      NS_IMPL_COCOA=yes
1769      ns_appdir=`pwd`/nextstep/Emacs.app
1770      ns_appbindir=${ns_appdir}/Contents/MacOS
1771      ns_appresdir=${ns_appdir}/Contents/Resources
1772      ns_appsrc=Cocoa/Emacs.base
1773      ns_fontfile=macfont.o
1774   elif flags=$( (gnustep-config --objc-flags) 2>/dev/null); then
1775      NS_IMPL_GNUSTEP=yes
1776      NS_GNUSTEP_CONFIG=yes
1777      GNU_OBJC_CFLAGS=$flags
1778      LIBS_GNUSTEP=$(gnustep-config --gui-libs) || exit
1779   elif test -f $GNUSTEP_CONFIG_FILE; then
1780      NS_IMPL_GNUSTEP=yes
1781      dnl FIXME sourcing this several times in subshells seems inefficient.
1782      GNUSTEP_SYSTEM_HEADERS=$(
1783        . $GNUSTEP_CONFIG_FILE
1784        AS_ECHO(["$GNUSTEP_SYSTEM_HEADERS"])
1785      )
1786      GNUSTEP_SYSTEM_LIBRARIES=$(
1787        . $GNUSTEP_CONFIG_FILE
1788        AS_ECHO(["$GNUSTEP_SYSTEM_LIBRARIES"])
1789      )
1790      dnl I seemed to need these as well with GNUstep-startup 0.25.
1791      GNUSTEP_LOCAL_HEADERS=$(
1792        . $GNUSTEP_CONFIG_FILE
1793        AS_ECHO(["$GNUSTEP_LOCAL_HEADERS"])
1794      )
1795      GNUSTEP_LOCAL_LIBRARIES=$(
1796        . $GNUSTEP_CONFIG_FILE
1797        AS_ECHO(["$GNUSTEP_LOCAL_LIBRARIES"])
1798      )
1799      test "x${GNUSTEP_LOCAL_HEADERS}" != "x" && \
1800        GNUSTEP_LOCAL_HEADERS="-I${GNUSTEP_LOCAL_HEADERS}"
1801      test "x${GNUSTEP_LOCAL_LIBRARIES}" != "x" && \
1802        GNUSTEP_LOCAL_LIBRARIES="-L${GNUSTEP_LOCAL_LIBRARIES}"
1803      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1804      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1805      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES}"
1806      LIBS_GNUSTEP="-lgnustep-gui -lgnustep-base -lobjc -lpthread"
1807      dnl GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS to 0 or 1.
1808      dnl If they had chosen to either define it or not, we could have
1809      dnl just used AC_CHECK_DECL here.
1810      AC_CACHE_CHECK(if GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS,
1811        emacs_cv_objc_exceptions,
1812 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <GNUstepBase/GSConfig.h>]],
1813 [[#if defined BASE_NATIVE_OBJC_EXCEPTIONS && BASE_NATIVE_OBJC_EXCEPTIONS > 0
1814 1;
1815 #else
1816 fail;
1817 #endif]])], emacs_cv_objc_exceptions=yes, emacs_cv_objc_exceptions=no ) )
1818      if test $emacs_cv_objc_exceptions = yes; then
1819        dnl _NATIVE_OBJC_EXCEPTIONS is used by the GNUstep headers.
1820        AC_DEFINE(_NATIVE_OBJC_EXCEPTIONS, 1,
1821          [Define if GNUstep uses ObjC exceptions.])
1822        GNU_OBJC_CFLAGS="-fobjc-exceptions"
1823      fi
1824   fi
1825   if test $NS_IMPL_GNUSTEP = yes; then
1826      ns_appdir=`pwd`/nextstep/Emacs.app
1827      ns_appbindir=${ns_appdir}
1828      ns_appresdir=${ns_appdir}/Resources
1829      ns_appsrc=GNUstep/Emacs.base
1830      ns_fontfile=nsfont.o
1831   fi
1832
1833   dnl This is only used while we test the NS headers, it gets reset below.
1834   CPPFLAGS="$CPPFLAGS $GNU_OBJC_CFLAGS"
1835   CFLAGS="$CFLAGS $GNU_OBJC_CFLAGS"
1836
1837   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1838                   [AC_MSG_ERROR([The include files (AppKit/AppKit.h etc) that
1839 are required for a Nextstep build are missing or cannot be compiled.
1840 Either fix this, or re-configure with the option '--without-ns'.])])
1841
1842   macfont_file=""
1843   if test "${NS_IMPL_COCOA}" = "yes"; then
1844     AC_MSG_CHECKING([for OSX 10.6 or newer])
1845     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <AppKit/AppKit.h>],
1846                                      [
1847 #ifdef MAC_OS_X_VERSION_MAX_ALLOWED
1848 #if MAC_OS_X_VERSION_MAX_ALLOWED >= 1060
1849  ; /* OK */
1850 #else
1851  error "OSX 10.6 or newer required";
1852 #endif
1853 #endif
1854                     ])],
1855                     ns_osx_have_106=yes,
1856                     ns_osx_have_106=no)
1857     AC_MSG_RESULT([$ns_osx_have_106])
1858
1859     if test $ns_osx_have_106 = no; then
1860        AC_MSG_ERROR([OSX 10.6 or newer is required]);
1861     fi
1862   fi
1863 fi
1864
1865 AC_SUBST(LIBS_GNUSTEP)
1866
1867 INSTALL_ARCH_INDEP_EXTRA=install-etc
1868 ns_self_contained=no
1869 NS_OBJ=
1870 NS_OBJC_OBJ=
1871 if test "${HAVE_NS}" = yes; then
1872   if test "$with_toolkit_scroll_bars" = "no"; then
1873     AC_MSG_ERROR([Non-toolkit scroll bars are not implemented for Nextstep.])
1874   fi
1875
1876   window_system=nextstep
1877   # set up packaging dirs
1878   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1879      ns_self_contained=yes
1880      prefix=${ns_appresdir}
1881      exec_prefix=${ns_appbindir}
1882      dnl This one isn't really used, only archlibdir is.
1883      libexecdir="\${ns_appbindir}/libexec"
1884      archlibdir="\${ns_appbindir}/libexec"
1885      etcdocdir="\${ns_appresdir}/etc"
1886      etcdir="\${ns_appresdir}/etc"
1887      dnl FIXME maybe set datarootdir instead.
1888      dnl That would also get applications, icons, man.
1889      infodir="\${ns_appresdir}/info"
1890      mandir="\${ns_appresdir}/man"
1891      lispdir="\${ns_appresdir}/lisp"
1892      test "$locallisppathset" = no && locallisppath=""
1893      INSTALL_ARCH_INDEP_EXTRA=
1894   fi
1895
1896   NS_OBJC_OBJ="nsterm.o nsfns.o nsmenu.o nsselect.o nsimage.o $ns_fontfile"
1897 fi
1898 CFLAGS="$tmp_CFLAGS"
1899 CPPFLAGS="$tmp_CPPFLAGS"
1900 AC_SUBST(INSTALL_ARCH_INDEP_EXTRA)
1901 AC_SUBST(ns_self_contained)
1902 AC_SUBST(NS_OBJ)
1903 AC_SUBST(NS_OBJC_OBJ)
1904
1905 HAVE_W32=no
1906 W32_OBJ=
1907 W32_LIBS=
1908 EMACSRES=
1909 CLIENTRES=
1910 CLIENTW=
1911 W32_RES_LINK=
1912 EMACS_MANIFEST=
1913 UPDATE_MANIFEST=
1914 if test "${with_w32}" != no; then
1915   case "${opsys}" in
1916     cygwin)
1917       AC_CHECK_HEADER([windows.h], [HAVE_W32=yes],
1918              [AC_MSG_ERROR(['--with-w32' was specified, but windows.h
1919                    cannot be found.])])
1920     ;;
1921     mingw32)
1922     ## Using --with-w32 with MinGW is a no-op, but we allow it.
1923     ;;
1924     *)
1925       AC_MSG_ERROR([Using w32 with an autotools build is only supported for Cygwin and MinGW32.])
1926     ;;
1927   esac
1928 fi
1929
1930 if test "${opsys}" = "mingw32"; then
1931   AC_MSG_CHECKING([whether Windows API headers are recent enough])
1932   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1933      #include <windows.h>
1934      #include <usp10.h>]],
1935    [[PIMAGE_NT_HEADERS pHeader;
1936      PIMAGE_SECTION_HEADER pSection = IMAGE_FIRST_SECTION(pHeader)]])],
1937    [emacs_cv_w32api=yes
1938     HAVE_W32=yes],
1939    emacs_cv_w32api=no)
1940   AC_MSG_RESULT($emacs_cv_w32api)
1941   if test "${emacs_cv_w32api}" = "no"; then
1942     AC_MSG_ERROR([the Windows API headers are too old to support this build.])
1943   fi
1944 fi
1945
1946 FIRSTFILE_OBJ=
1947 NTDIR=
1948 LIBS_ECLIENT=
1949 LIB_WSOCK32=
1950 NTLIB=
1951 CM_OBJ="cm.o"
1952 XARGS_LIMIT=
1953 if test "${HAVE_W32}" = "yes"; then
1954   AC_DEFINE(HAVE_NTGUI, 1, [Define to use native MS Windows GUI.])
1955   if test "$with_toolkit_scroll_bars" = "no"; then
1956     AC_MSG_ERROR([Non-toolkit scroll bars are not implemented for w32 build.])
1957   fi
1958   AC_CHECK_TOOL(WINDRES, [windres],
1959                 [AC_MSG_ERROR([No resource compiler found.])])
1960   W32_OBJ="w32fns.o w32menu.o w32reg.o w32font.o w32term.o"
1961   W32_OBJ="$W32_OBJ w32xfns.o w32select.o w32uniscribe.o"
1962   EMACSRES="emacs.res"
1963   case "$canonical" in
1964     x86_64-*-*) EMACS_MANIFEST="emacs-x64.manifest" ;;
1965     *) EMACS_MANIFEST="emacs-x86.manifest" ;;
1966   esac
1967   dnl Construct something of the form "24,4,0,0" with 4 components.
1968   comma_version=`echo "${PACKAGE_VERSION}.0.0" | sed -e 's/\./,/g' -e 's/^\([[^,]]*,[[^,]]*,[[^,]]*,[[^,]]*\).*/\1/'`
1969
1970   comma_space_version=`echo "$comma_version" | sed 's/,/, /g'`
1971   AC_SUBST(comma_version)
1972   AC_SUBST(comma_space_version)
1973   AC_CONFIG_FILES([nt/emacs.rc nt/emacsclient.rc])
1974   if test "${opsys}" = "cygwin"; then
1975     W32_LIBS="$W32_LIBS -lkernel32 -luser32 -lgdi32 -lole32 -lcomdlg32"
1976     W32_LIBS="$W32_LIBS -lusp10 -lcomctl32 -lwinspool"
1977     # Tell the linker that emacs.res is an object (which we compile from
1978     # the rc file), not a linker script.
1979     W32_RES_LINK="-Wl,emacs.res"
1980   else
1981     UPDATE_MANIFEST=update-game-score.exe.manifest
1982     W32_OBJ="$W32_OBJ w32.o w32console.o w32heap.o w32inevt.o w32proc.o"
1983     W32_LIBS="$W32_LIBS -lwinmm -lgdi32 -lcomdlg32"
1984     W32_LIBS="$W32_LIBS -lmpr -lwinspool -lole32 -lcomctl32 -lusp10"
1985     W32_RES_LINK="\$(EMACSRES)"
1986     CLIENTRES="emacsclient.res"
1987     CLIENTW="emacsclientw\$(EXEEXT)"
1988     FIRSTFILE_OBJ=firstfile.o
1989     NTDIR=nt
1990     CM_OBJ=
1991     LIBS_ECLIENT="-lcomctl32"
1992     LIB_WSOCK32="-lwsock32"
1993     NTLIB="ntlib.$ac_objext"
1994     XARGS_LIMIT="-s 10000"
1995   fi
1996 fi
1997 AC_SUBST(W32_OBJ)
1998 AC_SUBST(W32_LIBS)
1999 AC_SUBST(EMACSRES)
2000 AC_SUBST(EMACS_MANIFEST)
2001 AC_SUBST(UPDATE_MANIFEST)
2002 AC_SUBST(CLIENTRES)
2003 AC_SUBST(CLIENTW)
2004 AC_SUBST(W32_RES_LINK)
2005 AC_SUBST(FIRSTFILE_OBJ)
2006 AC_SUBST(NTDIR)
2007 AC_SUBST(CM_OBJ)
2008 AC_SUBST(LIBS_ECLIENT)
2009 AC_SUBST(LIB_WSOCK32)
2010 AC_SUBST(NTLIB)
2011 AC_SUBST(XARGS_LIMIT)
2012
2013 if test "${HAVE_W32}" = "yes"; then
2014   window_system=w32
2015   with_xft=no
2016 fi
2017
2018 ## $window_system is now set to the window system we will
2019 ## ultimately use.
2020
2021 if test "$window_system" = none && test "$gl_gcc_warnings" = yes; then
2022    # Too many warnings for now.
2023    nw=
2024    nw="$nw -Wsuggest-attribute=noreturn"
2025    gl_MANYWARN_COMPLEMENT([WARN_CFLAGS], [$WARN_CFLAGS], [$nw])
2026
2027    gl_WARN_ADD([-Wno-unused-variable])
2028    gl_WARN_ADD([-Wno-unused-but-set-variable])
2029    gl_WARN_ADD([-Wno-unused-but-set-parameter])
2030 fi
2031
2032 term_header=
2033 HAVE_X_WINDOWS=no
2034 HAVE_X11=no
2035 USE_X_TOOLKIT=none
2036
2037 case "${window_system}" in
2038   x11 )
2039     HAVE_X_WINDOWS=yes
2040     HAVE_X11=yes
2041     term_header=xterm.h
2042     case "${with_x_toolkit}" in
2043       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
2044       motif ) USE_X_TOOLKIT=MOTIF ;;
2045       gtk ) with_gtk=yes
2046             term_header=gtkutil.h
2047 dnl Don't set this for GTK.  A lot of tests below assumes Xt when
2048 dnl USE_X_TOOLKIT is set.
2049             USE_X_TOOLKIT=none ;;
2050       gtk2 ) with_gtk2=yes
2051              term_header=gtkutil.h
2052              USE_X_TOOLKIT=none ;;
2053       gtk3 ) with_gtk3=yes
2054              term_header=gtkutil.h
2055              USE_X_TOOLKIT=none ;;
2056       no ) USE_X_TOOLKIT=none ;;
2057 dnl If user did not say whether to use a toolkit, make this decision later:
2058 dnl use the toolkit if we have gtk, or X11R5 or newer.
2059       * ) USE_X_TOOLKIT=maybe ;;
2060     esac
2061   ;;
2062   nextstep )
2063     term_header=nsterm.h
2064   ;;
2065   w32 )
2066     term_header=w32term.h
2067   ;;
2068 esac
2069
2070 if test "$window_system" = none && test "X$with_x" != "Xno"; then
2071    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
2072    if test "$HAVE_XSERVER" = true ||
2073       test -n "$DISPLAY" ||
2074       {
2075         for emacs_libX11 in /usr/lib/libX11.*; do break; done
2076         test "$emacs_libX11" != '/usr/lib/libX11.*'
2077       }
2078    then
2079         AC_MSG_ERROR([You seem to be running X, but no X development libraries
2080 were found.  You should install the relevant development files for X
2081 and for the toolkit you want, such as Gtk+ or Motif.  Also make
2082 sure you have development files for image handling, i.e.
2083 tiff, gif, jpeg, png and xpm.
2084 If you are sure you want Emacs compiled without X window support, pass
2085   --without-x
2086 to configure.])
2087    fi
2088 fi
2089
2090 # Does the opsystem file prohibit the use of the GNU malloc?
2091 # Assume not, until told otherwise.
2092 GNU_MALLOC=yes
2093
2094 AC_CACHE_CHECK(
2095   [whether malloc is Doug Lea style],
2096   [emacs_cv_var_doug_lea_malloc],
2097   [emacs_cv_var_doug_lea_malloc=no
2098    dnl Hooks do not work with address sanitization.
2099    if test "$emacs_cv_sanitize_address" != yes; then
2100      AC_LINK_IFELSE(
2101        [AC_LANG_PROGRAM(
2102           [[#include <malloc.h>
2103             static void hook (void) {}]],
2104           [[malloc_set_state (malloc_get_state ());
2105             __after_morecore_hook = hook;
2106             __malloc_initialize_hook = hook;]])],
2107        [emacs_cv_var_doug_lea_malloc=yes])
2108    fi])
2109 doug_lea_malloc=$emacs_cv_var_doug_lea_malloc
2110
2111 system_malloc=$emacs_cv_sanitize_address
2112
2113 hybrid_malloc=
2114
2115 case "$opsys" in
2116   ## darwin ld insists on the use of malloc routines in the System framework.
2117   darwin | mingw32 | nacl | sol2-10) system_malloc=yes ;;
2118   cygwin) hybrid_malloc=yes;;
2119 esac
2120
2121 GMALLOC_OBJ=
2122 if test "${system_malloc}" = "yes"; then
2123   AC_DEFINE([SYSTEM_MALLOC], 1,
2124     [Define to 1 to use the system memory allocator, even if it is not
2125      Doug Lea style.])
2126   GNU_MALLOC=no
2127   GNU_MALLOC_reason="
2128     (The GNU allocators don't work with this system configuration.)"
2129   VMLIMIT_OBJ=
2130 elif test "$hybrid_malloc" = yes; then
2131   AC_DEFINE(HYBRID_MALLOC, 1,
2132     [Define to use gmalloc before dumping and the system malloc after.])
2133   GNU_MALLOC=
2134   GNU_MALLOC_reason="only before dumping"
2135   GMALLOC_OBJ=gmalloc.o
2136   VMLIMIT_OBJ=
2137 else
2138   test "$doug_lea_malloc" != "yes" && GMALLOC_OBJ=gmalloc.o
2139   VMLIMIT_OBJ=vm-limit.o
2140
2141   AC_CHECK_HEADERS([sys/vlimit.h])
2142   AC_CACHE_CHECK([for data_start], [emacs_cv_data_start],
2143     [AC_LINK_IFELSE(
2144        [AC_LANG_PROGRAM(
2145          [[extern char data_start[]; char ch;]],
2146          [[return data_start < &ch;]])],
2147        [emacs_cv_data_start=yes],
2148        [emacs_cv_data_start=no])])
2149   if test $emacs_cv_data_start = yes; then
2150     AC_DEFINE([HAVE_DATA_START], 1,
2151       [Define to 1 if data_start is the address of the start
2152        of the main data segment.])
2153   fi
2154 fi
2155 AC_SUBST(GMALLOC_OBJ)
2156 AC_SUBST(VMLIMIT_OBJ)
2157
2158 if test "$doug_lea_malloc" = "yes" ; then
2159   if test "$GNU_MALLOC" = yes ; then
2160     GNU_MALLOC_reason="
2161       (Using Doug Lea's new malloc from the GNU C Library.)"
2162   fi
2163   AC_DEFINE(DOUG_LEA_MALLOC, 1,
2164     [Define to 1 if the system memory allocator is Doug Lea style,
2165      with malloc hooks and malloc_set_state.])
2166
2167   ## Use mmap directly for allocating larger buffers.
2168   ## FIXME this comes from src/s/{gnu,gnu-linux}.h:
2169   ## #ifdef DOUG_LEA_MALLOC; #undef REL_ALLOC; #endif
2170   ## Does the AC_FUNC_MMAP test below make this check unnecessary?
2171   case "$opsys" in
2172     mingw32|gnu*) REL_ALLOC=no ;;
2173   esac
2174 fi
2175
2176 if test x"${REL_ALLOC}" = x; then
2177   REL_ALLOC=${GNU_MALLOC}
2178 fi
2179
2180 use_mmap_for_buffers=no
2181 case "$opsys" in
2182   cygwin|mingw32|freebsd|irix6-5) use_mmap_for_buffers=yes ;;
2183 esac
2184
2185 AC_FUNC_MMAP
2186 if test $use_mmap_for_buffers = yes; then
2187   AC_DEFINE(USE_MMAP_FOR_BUFFERS, 1, [Define to use mmap to allocate buffer text.])
2188   REL_ALLOC=no
2189 fi
2190
2191 LIBS="$LIBS_SYSTEM $LIBS"
2192
2193 dnl FIXME replace main with a function we actually want from this library.
2194 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
2195
2196 dnl Check for the POSIX thread library.
2197 LIB_PTHREAD=
2198 AC_CHECK_HEADERS_ONCE(pthread.h)
2199 if test "$ac_cv_header_pthread_h" && test "$opsys" != "mingw32"; then
2200   AC_CACHE_CHECK([for pthread library],
2201     [emacs_cv_pthread_lib],
2202     [emacs_cv_pthread_lib=no
2203      OLD_LIBS=$LIBS
2204      for emacs_pthread_lib in 'none needed' -lpthread; do
2205        case $emacs_pthread_lib in
2206          -*) LIBS="$OLD_LIBS $emacs_pthread_lib";;
2207        esac
2208        AC_LINK_IFELSE(
2209          [AC_LANG_PROGRAM(
2210             [[#include <pthread.h>
2211               #include <signal.h>
2212               sigset_t old_mask, new_mask;
2213               void noop (void) {}]],
2214             [[pthread_t th = pthread_self ();
2215               int status = 0;
2216               status += pthread_create (&th, 0, 0, 0);
2217               status += pthread_sigmask (SIG_BLOCK, &new_mask, &old_mask);
2218               status += pthread_kill (th, 0);
2219               #if ! (defined SYSTEM_MALLOC || defined HYBRID_MALLOC \
2220                      || defined DOUG_LEA_MALLOC)
2221               /* Test for pthread_atfork only if gmalloc uses it,
2222                  as older-style hosts like MirBSD 10 lack it.  */
2223               status += pthread_atfork (noop, noop, noop);
2224               #endif
2225               return status;]])],
2226          [emacs_cv_pthread_lib=$emacs_pthread_lib])
2227        LIBS=$OLD_LIBS
2228        if test "$emacs_cv_pthread_lib" != no; then
2229          break
2230        fi
2231      done])
2232   if test "$emacs_cv_pthread_lib" != no; then
2233     AC_DEFINE([HAVE_PTHREAD], 1, [Define to 1 if you have POSIX threads.])
2234     case $emacs_cv_pthread_lib in
2235       -*) LIB_PTHREAD=$emacs_cv_pthread_lib;;
2236     esac
2237     ac_cv_func_pthread_sigmask=yes
2238     # Some systems optimize for single-threaded programs by default, and
2239     # need special flags to disable these optimizations. For example, the
2240     # definition of 'errno' in <errno.h>.
2241     case $opsys in
2242       hpux* | sol*)
2243         AC_DEFINE([_REENTRANT], 1,
2244           [Define to 1 if your system requires this in multithreaded code.]);;
2245       aix4-2)
2246         AC_DEFINE([_THREAD_SAFE], 1,
2247           [Define to 1 if your system requires this in multithreaded code.]);;
2248     esac
2249   fi
2250 fi
2251 AC_SUBST([LIB_PTHREAD])
2252
2253 dnl Check for need for bigtoc support on IBM AIX
2254
2255 case ${host_os} in
2256 aix*)
2257   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
2258     case $GCC in
2259     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
2260     *) gdb_cv_bigtoc=-bbigtoc ;;
2261     esac
2262
2263     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
2264     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[int i;]])], [], [gdb_cv_bigtoc=])
2265   ])
2266   ;;
2267 esac
2268
2269 # Change CFLAGS, CPPFLAGS, and LIBS temporarily so that C_SWITCH_X_SITE
2270 # is for the tests that follow.  We set them back later on.
2271
2272 REAL_CFLAGS="$CFLAGS"
2273 REAL_CPPFLAGS="$CPPFLAGS"
2274 REAL_LIBS="$LIBS"
2275
2276 if test "${HAVE_X11}" = "yes"; then
2277   DEFS="$C_SWITCH_X_SITE $DEFS"
2278   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
2279   LIBS="-lX11 $LIBS"
2280   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
2281   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
2282
2283   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
2284   # This is handled by LD_SWITCH_X_SITE_RPATH during the real build,
2285   # but it's more convenient here to set LD_RUN_PATH since this
2286   # also works on hosts that don't understand LD_SWITCH_X_SITE_RPATH.
2287   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
2288     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
2289     export LD_RUN_PATH
2290   fi
2291
2292   if test "${opsys}" = "gnu-linux"; then
2293     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
2294     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
2295      [[XOpenDisplay ("foo");]])],
2296      [xgnu_linux_first_failure=no],
2297      [xgnu_linux_first_failure=yes])
2298     if test "${xgnu_linux_first_failure}" = "yes"; then
2299       OLD_CPPFLAGS="$CPPFLAGS"
2300       OLD_LIBS="$LIBS"
2301       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
2302       LIBS="$LIBS -b i486-linuxaout"
2303       AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
2304        [[XOpenDisplay ("foo");]])],
2305        [xgnu_linux_second_failure=no],
2306        [xgnu_linux_second_failure=yes])
2307       if test "${xgnu_linux_second_failure}" = "yes"; then
2308         # If we get the same failure with -b, there is no use adding -b.
2309         # So leave it out.  This plays safe.
2310         AC_MSG_RESULT(no)
2311       else
2312         LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
2313         C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
2314         AC_MSG_RESULT(yes)
2315       fi
2316       CPPFLAGS=$OLD_CPPFLAGS
2317       LIBS=$OLD_LIBS
2318     else
2319       AC_MSG_RESULT(no)
2320     fi
2321   fi
2322
2323   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
2324   # header files included from there.
2325   AC_MSG_CHECKING(for Xkb)
2326   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
2327 #include <X11/XKBlib.h>]],
2328         [[XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);]])],
2329         emacs_xkb=yes, emacs_xkb=no)
2330   AC_MSG_RESULT($emacs_xkb)
2331   if test $emacs_xkb = yes; then
2332     AC_DEFINE(HAVE_XKB, 1, [Define to 1 if you have the Xkb extension.])
2333   fi
2334
2335   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
2336 XScreenNumberOfScreen)
2337 fi
2338
2339 if test "${window_system}" = "x11"; then
2340   AC_MSG_CHECKING(X11 version 6)
2341   AC_CACHE_VAL(emacs_cv_x11_version_6,
2342   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>]],
2343 [[#if XlibSpecificationRelease < 6
2344 fail;
2345 #endif
2346 ]])], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
2347   if test $emacs_cv_x11_version_6 = yes; then
2348     AC_MSG_RESULT(6 or newer)
2349     AC_DEFINE(HAVE_X11R6, 1,
2350               [Define to 1 if you have the X11R6 or newer version of Xlib.])
2351     AC_DEFINE(HAVE_X_I18N, 1, [Define if you have usable i18n support.])
2352     ## inoue@ainet.or.jp says Solaris has a bug related to X11R6-style
2353     ## XIM support.
2354     case "$opsys" in
2355       sol2-*) : ;;
2356       *) AC_DEFINE(HAVE_X11R6_XIM, 1,
2357            [Define if you have usable X11R6-style XIM support.])
2358          ;;
2359     esac
2360   else
2361     AC_MSG_RESULT(before 6)
2362   fi
2363 fi
2364
2365
2366 ### Use -lrsvg-2 if available, unless '--with-rsvg=no' is specified.
2367 HAVE_RSVG=no
2368 if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes" || test "${opsys}" = "mingw32"; then
2369   if test "${with_rsvg}" != "no"; then
2370     RSVG_REQUIRED=2.11.0
2371     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
2372
2373     EMACS_CHECK_MODULES([RSVG], [$RSVG_MODULE])
2374     AC_SUBST(RSVG_CFLAGS)
2375     AC_SUBST(RSVG_LIBS)
2376
2377     if test $HAVE_RSVG = yes; then
2378       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
2379       CFLAGS="$CFLAGS $RSVG_CFLAGS"
2380       # Windows loads librsvg dynamically
2381       if test "${opsys}" = "mingw32"; then
2382         RSVG_LIBS=
2383       fi
2384     fi
2385   fi
2386 fi
2387
2388 HAVE_IMAGEMAGICK=no
2389 if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes" || test "${HAVE_W32}" = "yes"; then
2390   if test "${with_imagemagick}" != "no"; then
2391     ## 6.3.5 is the earliest version known to work; see Bug#17339.
2392     ## 6.8.2 makes Emacs crash; see Bug#13867.
2393     IMAGEMAGICK_MODULE="Wand >= 6.3.5 Wand != 6.8.2"
2394     EMACS_CHECK_MODULES([IMAGEMAGICK], [$IMAGEMAGICK_MODULE])
2395     AC_SUBST(IMAGEMAGICK_CFLAGS)
2396     AC_SUBST(IMAGEMAGICK_LIBS)
2397
2398     if test $HAVE_IMAGEMAGICK = yes; then
2399       AC_DEFINE(HAVE_IMAGEMAGICK, 1, [Define to 1 if using imagemagick.])
2400       OLD_CFLAGS=$CFLAGS
2401       OLD_LIBS=$LIBS
2402       CFLAGS="$CFLAGS $IMAGEMAGICK_CFLAGS"
2403       LIBS="$IMAGEMAGICK_LIBS $LIBS"
2404       AC_CHECK_FUNCS(MagickExportImagePixels MagickMergeImageLayers)
2405       CFLAGS=$OLD_CFLAGS
2406       LIBS=$OLD_LIBS
2407     fi
2408   fi
2409 fi
2410
2411 AC_CHECK_LIB(anl, getaddrinfo_a, HAVE_GETADDRINFO_A=yes)
2412 if test "${HAVE_GETADDRINFO_A}" = "yes"; then
2413   AC_DEFINE(HAVE_GETADDRINFO_A, 1,
2414 [Define to 1 if you have getaddrinfo_a for asynchronous DNS resolution.])
2415   GETADDRINFO_A_LIBS="-lanl"
2416   AC_SUBST(GETADDRINFO_A_LIBS)
2417 fi
2418
2419 HAVE_GTK=no
2420 GTK_OBJ=
2421 gtk_term_header=$term_header
2422 check_gtk2=no
2423 gtk3_pkg_errors=
2424 if test "${opsys}" != "mingw32"; then
2425   if test "${with_gtk3}" = "yes" || test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
2426     GLIB_REQUIRED=2.28
2427     GTK_REQUIRED=3.0
2428     GTK_MODULES="gtk+-3.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
2429
2430     dnl Checks for libraries.
2431     EMACS_CHECK_MODULES([GTK], [$GTK_MODULES],
2432       [pkg_check_gtk=yes], [pkg_check_gtk=no])
2433     if test "$pkg_check_gtk" = "no" && test "$with_gtk3" = "yes"; then
2434        AC_MSG_ERROR($GTK_PKG_ERRORS)
2435     fi
2436     if test "$pkg_check_gtk" = "yes"; then
2437        AC_DEFINE(HAVE_GTK3, 1, [Define to 1 if using GTK 3 or later.])
2438        GTK_OBJ=emacsgtkfixed.o
2439        gtk_term_header=gtkutil.h
2440        USE_GTK_TOOLKIT="GTK3"
2441        if test "x$ac_enable_gtk_deprecation_warnings" = x; then
2442          AC_DEFINE([GDK_DISABLE_DEPRECATION_WARNINGS], [1],
2443            [Define to 1 to disable GTK+/GDK deprecation warnings.])
2444          AC_DEFINE([GLIB_DISABLE_DEPRECATION_WARNINGS], [1],
2445            [Define to 1 to disable Glib deprecation warnings.])
2446        fi
2447     else
2448        check_gtk2=yes
2449        gtk3_pkg_errors="$GTK_PKG_ERRORS "
2450     fi
2451   fi
2452
2453   if test "${with_gtk2}" = "yes" || test "$check_gtk2" = "yes"; then
2454     GLIB_REQUIRED=2.10
2455     GTK_REQUIRED=2.10
2456     GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
2457
2458     dnl Checks for libraries.
2459     EMACS_CHECK_MODULES([GTK], [$GTK_MODULES],
2460       [pkg_check_gtk=yes], [pkg_check_gtk=no])
2461     if test "$pkg_check_gtk" = "no" &&
2462        { test "$with_gtk" = yes || test "$with_gtk2" = "yes"; }
2463     then
2464       AC_MSG_ERROR($gtk3_pkg_errors$GTK_PKG_ERRORS)
2465     fi
2466     test "$pkg_check_gtk" = "yes" && USE_GTK_TOOLKIT="GTK2"
2467   fi
2468 fi
2469
2470 OLD_CFLAGS=$CFLAGS
2471 OLD_LIBS=$LIBS
2472
2473 if test x"$pkg_check_gtk" = xyes; then
2474
2475   AC_SUBST(GTK_LIBS)
2476   CFLAGS="$CFLAGS $GTK_CFLAGS"
2477   LIBS="$GTK_LIBS $LIBS"
2478   dnl Try to compile a simple GTK program.
2479   AC_MSG_CHECKING([whether GTK compiles])
2480   GTK_COMPILES=no
2481   AC_LINK_IFELSE(
2482     [AC_LANG_PROGRAM(
2483        [[/* Check the Gtk and Glib APIs.  */
2484          #include <gtk/gtk.h>
2485          #include <glib-object.h>
2486          static void
2487          callback (GObject *go, GParamSpec *spec, gpointer user_data)
2488          {}
2489        ]],
2490        [[
2491          GtkSettings *gs = 0;
2492          /* Use G_CALLBACK to make sure function pointers can be cast to void *;
2493             strict C prohibits this.  Use gtk_main_iteration to test that the
2494             libraries are there.  */
2495          if (g_signal_handler_find (G_OBJECT (gs), G_SIGNAL_MATCH_FUNC,
2496                                     0, 0, 0, G_CALLBACK (callback), 0))
2497            gtk_main_iteration ();
2498        ]])],
2499     [GTK_COMPILES=yes])
2500   AC_MSG_RESULT([$GTK_COMPILES])
2501   if test "${GTK_COMPILES}" != "yes"; then
2502     GTK_OBJ=
2503     if test "$USE_X_TOOLKIT" != "maybe"; then
2504       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
2505     fi
2506   else
2507     C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
2508     HAVE_GTK=yes
2509     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
2510     GTK_OBJ="gtkutil.o $GTK_OBJ"
2511     term_header=$gtk_term_header
2512     USE_X_TOOLKIT=none
2513     AC_MSG_WARN([[Your version of Gtk+ will have problems with
2514        closing open displays.  This is no problem if you just use
2515        one display, but if you use more than one and close one of them
2516        Emacs may crash.
2517        See http://bugzilla.gnome.org/show_bug.cgi?id=85715]])
2518     sleep 3
2519   fi
2520
2521 fi
2522 AC_SUBST(GTK_OBJ)
2523
2524
2525 if test "${HAVE_GTK}" = "yes"; then
2526
2527   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
2528   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
2529   if test "$with_toolkit_scroll_bars" != no; then
2530     with_toolkit_scroll_bars=yes
2531   fi
2532
2533   dnl  Check if we have the old file selection dialog declared and
2534   dnl  in the link library.  In 2.x it may be in the library,
2535   dnl  but not declared if deprecated featured has been selected out.
2536   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
2537   HAVE_GTK_FILE_SELECTION=no
2538   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
2539                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
2540 #include <gtk/gtk.h>])
2541   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
2542     AC_CHECK_FUNCS(gtk_file_selection_new)
2543   fi
2544
2545   dnl Same as above for gtk_handle_box.
2546   HAVE_GTK_HANDLE_BOX=no
2547   AC_CHECK_DECL(GTK_TYPE_HANDLE_BOX, HAVE_GTK_HANDLE_BOX=yes,
2548                    HAVE_GTK_HANDLE_BOX=no, [AC_INCLUDES_DEFAULT
2549 #include <gtk/gtk.h>])
2550   if test "$HAVE_GTK_HANDLE_BOX" = yes; then
2551     AC_CHECK_FUNCS(gtk_handle_box_new)
2552   fi
2553
2554   dnl Same as above for gtk_tearoff_menu_item.
2555   HAVE_GTK_TEAROFF_MENU_ITEM=no
2556   AC_CHECK_DECL(GTK_TYPE_TEAROFF_MENU_ITEM, HAVE_GTK_TEAROFF_MENU_ITEM=yes,
2557                    HAVE_GTK_TEAROFF_MENU_ITEM=no, [AC_INCLUDES_DEFAULT
2558 #include <gtk/gtk.h>])
2559   if test "$HAVE_GTK_TEAROFF_MENU_ITEM" = yes; then
2560     AC_CHECK_FUNCS(gtk_tearoff_menu_item_new)
2561   fi
2562
2563   dnl Check for functions introduced in 2.14 and later.
2564   AC_CHECK_FUNCS(gtk_widget_get_window gtk_widget_set_has_window \
2565                  gtk_dialog_get_action_area gtk_widget_get_sensitive \
2566                  gtk_widget_get_mapped gtk_adjustment_get_page_size \
2567                  gtk_orientable_set_orientation \
2568                  gtk_window_set_has_resize_grip)
2569
2570  term_header=gtkutil.h
2571 fi
2572
2573 CFLAGS=$OLD_CFLAGS
2574 LIBS=$OLD_LIBS
2575
2576 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
2577 dnl other platforms.
2578 HAVE_DBUS=no
2579 DBUS_OBJ=
2580 if test "${with_dbus}" = "yes"; then
2581    EMACS_CHECK_MODULES([DBUS], [dbus-1 >= 1.0])
2582    if test "$HAVE_DBUS" = yes; then
2583      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
2584      dnl dbus_watch_get_unix_fd has been introduced in D-Bus 1.1.1.
2585      dnl dbus_type_is_valid and dbus_validate_* have been introduced in
2586      dnl D-Bus 1.5.12.
2587      OLD_LIBS=$LIBS
2588      LIBS="$LIBS $DBUS_LIBS"
2589      AC_CHECK_FUNCS(dbus_watch_get_unix_fd \
2590                     dbus_type_is_valid \
2591                     dbus_validate_bus_name \
2592                     dbus_validate_path \
2593                     dbus_validate_interface \
2594                     dbus_validate_member)
2595      LIBS=$OLD_LIBS
2596      DBUS_OBJ=dbusbind.o
2597    fi
2598 fi
2599 AC_SUBST(DBUS_CFLAGS)
2600 AC_SUBST(DBUS_LIBS)
2601 AC_SUBST(DBUS_OBJ)
2602
2603 dnl GSettings has been tested under GNU/Linux only.
2604 HAVE_GSETTINGS=no
2605 if test "${HAVE_X11}" = "yes" && test "${with_gsettings}" = "yes"; then
2606    EMACS_CHECK_MODULES([GSETTINGS], [gio-2.0 >= 2.26])
2607    if test "$HAVE_GSETTINGS" = "yes"; then
2608       old_CFLAGS=$CFLAGS
2609       CFLAGS="$CFLAGS $GSETTINGS_CFLAGS"
2610       old_LIBS=$LIBS
2611       LIBS="$LIBS $GSETTINGS_LIBS"
2612       AC_MSG_CHECKING([whether GSettings is in gio])
2613       AC_LINK_IFELSE(
2614          [AC_LANG_PROGRAM(
2615              [[/* Check that gsettings really is present.  */
2616              #include <glib-object.h>
2617              #include <gio/gio.h>
2618              ]],
2619              [[
2620                GSettings *settings;
2621                GVariant *val = g_settings_get_value (settings, "");
2622              ]])],
2623          [], HAVE_GSETTINGS=no)
2624       AC_MSG_RESULT([$HAVE_GSETTINGS])
2625
2626       if test "$HAVE_GSETTINGS" = "yes"; then
2627         AC_DEFINE(HAVE_GSETTINGS, 1, [Define to 1 if using GSettings.])
2628         SETTINGS_CFLAGS="$GSETTINGS_CFLAGS"
2629         SETTINGS_LIBS="$GSETTINGS_LIBS"
2630       fi
2631       CFLAGS=$old_CFLAGS
2632       LIBS=$old_LIBS
2633    fi
2634 fi
2635
2636 dnl GConf has been tested under GNU/Linux only.
2637 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
2638 HAVE_GCONF=no
2639 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
2640    EMACS_CHECK_MODULES([GCONF], [gconf-2.0 >= 2.13])
2641    if test "$HAVE_GCONF" = yes; then
2642       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
2643       dnl Newer GConf doesn't link with g_objects, so this is not defined.
2644       SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GCONF_CFLAGS"
2645       SETTINGS_LIBS="$SETTINGS_LIBS $GCONF_LIBS"
2646    fi
2647 fi
2648
2649 if test "$HAVE_GSETTINGS" = "yes" || test "$HAVE_GCONF" = "yes"; then
2650     EMACS_CHECK_MODULES([GOBJECT], [gobject-2.0 >= 2.0])
2651     if test "$HAVE_GOBJECT" = "yes"; then
2652        SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GOBJECT_CFLAGS"
2653        SETTINGS_LIBS="$SETTINGS_LIBS $GOBJECT_LIBS"
2654     fi
2655     SAVE_CFLAGS="$CFLAGS"
2656     SAVE_LIBS="$LIBS"
2657     CFLAGS="$SETTINGS_CFLAGS $CFLAGS"
2658     LIBS="$SETTINGS_LIBS $LIBS"
2659     CFLAGS="$SAVE_CFLAGS"
2660     LIBS="$SAVE_LIBS"
2661 fi
2662 AC_SUBST(SETTINGS_CFLAGS)
2663 AC_SUBST(SETTINGS_LIBS)
2664
2665
2666 dnl SELinux is available for GNU/Linux only.
2667 HAVE_LIBSELINUX=no
2668 LIBSELINUX_LIBS=
2669 if test "${with_selinux}" = "yes"; then
2670    AC_CHECK_LIB([selinux], [lgetfilecon], HAVE_LIBSELINUX=yes, HAVE_LIBSELINUX=no)
2671    if test "$HAVE_LIBSELINUX" = yes; then
2672       AC_DEFINE(HAVE_LIBSELINUX, 1, [Define to 1 if using SELinux.])
2673       LIBSELINUX_LIBS=-lselinux
2674    fi
2675 fi
2676 AC_SUBST(LIBSELINUX_LIBS)
2677
2678 HAVE_GNUTLS=no
2679 if test "${with_gnutls}" = "yes" ; then
2680   EMACS_CHECK_MODULES([LIBGNUTLS], [gnutls >= 2.6.6],
2681     [HAVE_GNUTLS=yes], [HAVE_GNUTLS=no])
2682   if test "${HAVE_GNUTLS}" = "yes"; then
2683     AC_DEFINE(HAVE_GNUTLS, 1, [Define if using GnuTLS.])
2684     EMACS_CHECK_MODULES([LIBGNUTLS3], [gnutls >= 3.0.0],
2685       [AC_DEFINE(HAVE_GNUTLS3, 1, [Define if using GnuTLS v3.])], [])
2686   fi
2687
2688   # Windows loads GnuTLS dynamically
2689   if test "${opsys}" = "mingw32"; then
2690     LIBGNUTLS_LIBS=
2691   fi
2692 fi
2693
2694 AC_SUBST(LIBGNUTLS_LIBS)
2695 AC_SUBST(LIBGNUTLS_CFLAGS)
2696
2697 NOTIFY_OBJ=
2698 NOTIFY_SUMMARY=no
2699
2700 dnl MS Windows native file monitor is available for mingw32 only.
2701 case $with_file_notification,$opsys in
2702   w32,cygwin)
2703     AC_MSG_ERROR(['--with-file-notification=w32' was specified, but
2704     this is only supported on MS-Windows native and MinGW32 builds.
2705     Consider using gfile instead.])
2706     ;;
2707   w32,* | yes,mingw32)
2708     AC_CHECK_HEADER(windows.h)
2709     if test "$ac_cv_header_windows_h" = yes ; then
2710        AC_DEFINE(HAVE_W32NOTIFY, 1, [Define to 1 to use w32notify.])
2711        NOTIFY_OBJ=w32notify.o
2712        NOTIFY_SUMMARY="yes (w32)"
2713     fi ;;
2714 esac
2715
2716 dnl inotify is available only on GNU/Linux.
2717 case $with_file_notification,$NOTIFY_OBJ in
2718   inotify, | yes,)
2719     AC_CHECK_HEADER(sys/inotify.h)
2720     if test "$ac_cv_header_sys_inotify_h" = yes ; then
2721         AC_CHECK_FUNC(inotify_init1)
2722         if test "$ac_cv_func_inotify_init1" = yes; then
2723           AC_DEFINE(HAVE_INOTIFY, 1, [Define to 1 to use inotify.])
2724           NOTIFY_OBJ=inotify.o
2725           NOTIFY_SUMMARY="yes -lglibc (inotify)"
2726        fi
2727     fi ;;
2728 esac
2729
2730 dnl kqueue is available on BSD-like systems.
2731 case $with_file_notification,$NOTIFY_OBJ in
2732   kqueue,* | yes,)
2733     EMACS_CHECK_MODULES([KQUEUE], [libkqueue])
2734     if test "$HAVE_KQUEUE" = "yes"; then
2735        AC_DEFINE(HAVE_KQUEUE, 1, [Define to 1 to use kqueue.])
2736        CPPFLAGS="$CPPFLAGS -I/usr/include/kqueue"
2737        NOTIFY_CFLAGS=$KQUEUE_CFLAGS
2738        NOTIFY_LIBS=$KQUEUE_LIBS
2739        NOTIFY_OBJ=kqueue.o
2740        NOTIFY_SUMMARY="yes -lkqueue"
2741     else
2742        AC_SEARCH_LIBS(kqueue, [])
2743        if test "$ac_cv_search_kqueue" != no; then
2744          AC_DEFINE(HAVE_KQUEUE, 1, [Define to 1 to use kqueue.])
2745          NOTIFY_OBJ=kqueue.o
2746          NOTIFY_SUMMARY="yes (kqueue)"
2747        fi
2748     fi ;;
2749 esac
2750
2751 dnl g_file_monitor exists since glib 2.18.  G_FILE_MONITOR_EVENT_MOVED
2752 dnl has been added in glib 2.24.  It has been tested under
2753 dnl GNU/Linux only.
2754 case $with_file_notification,$NOTIFY_OBJ in
2755   gfile,* | yes,)
2756     if test "${HAVE_NS}" = yes; then
2757        AC_MSG_ERROR(['--with-file-notification=gfile' is not supported in NextStep builds.
2758 Consider kqueue instead.])
2759     else
2760        EMACS_CHECK_MODULES([GFILENOTIFY], [gio-2.0 >= 2.24])
2761        if test "$HAVE_GFILENOTIFY" = "yes"; then
2762           AC_DEFINE(HAVE_GFILENOTIFY, 1, [Define to 1 if using GFile.])
2763           NOTIFY_CFLAGS=$GFILENOTIFY_CFLAGS
2764           NOTIFY_LIBS=$GFILENOTIFY_LIBS
2765           NOTIFY_OBJ=gfilenotify.o
2766           NOTIFY_SUMMARY="yes -lgio (gfile)"
2767        fi
2768     fi ;;
2769 esac
2770
2771 case $with_file_notification,$NOTIFY_OBJ in
2772   yes,* | no,* | *,?*) ;;
2773   *) AC_MSG_ERROR([File notification '$with_file_notification' requested but requirements not found.]) ;;
2774 esac
2775
2776 if test -n "$NOTIFY_OBJ"; then
2777    AC_DEFINE(USE_FILE_NOTIFY, 1, [Define to 1 if using file notifications.])
2778 fi
2779 AC_SUBST(NOTIFY_CFLAGS)
2780 AC_SUBST(NOTIFY_LIBS)
2781 AC_SUBST(NOTIFY_OBJ)
2782
2783 dnl Do not put whitespace before the #include statements below.
2784 dnl Older compilers (eg sunos4 cc) choke on it.
2785 HAVE_XAW3D=no
2786 LUCID_LIBW=
2787 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
2788   if test "$with_xaw3d" != no; then
2789     AC_CACHE_VAL(emacs_cv_xaw3d,
2790     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2791 #include <X11/Intrinsic.h>
2792 #include <X11/Xaw3d/Simple.h>]],
2793       [[]])],
2794       [AC_CHECK_LIB(Xaw3d, XawScrollbarSetThumb,
2795                     emacs_cv_xaw3d=yes, emacs_cv_xaw3d=no)],
2796       emacs_cv_xaw3d=no)])
2797   else
2798     emacs_cv_xaw3d=no
2799   fi
2800   if test $emacs_cv_xaw3d = yes; then
2801     AC_MSG_CHECKING(for xaw3d)
2802     AC_MSG_RESULT([yes; using Lucid toolkit])
2803     USE_X_TOOLKIT=LUCID
2804     HAVE_XAW3D=yes
2805     LUCID_LIBW=-lXaw3d
2806     AC_DEFINE(HAVE_XAW3D, 1,
2807               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
2808   else
2809     AC_MSG_CHECKING(for xaw3d)
2810     AC_MSG_RESULT(no)
2811     AC_MSG_CHECKING(for libXaw)
2812     AC_CACHE_VAL(emacs_cv_xaw,
2813     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2814 #include <X11/Intrinsic.h>
2815 #include <X11/Xaw/Simple.h>]],
2816       [[]])],
2817       emacs_cv_xaw=yes,
2818       emacs_cv_xaw=no)])
2819     if test $emacs_cv_xaw = yes; then
2820       AC_MSG_RESULT([yes; using Lucid toolkit])
2821       USE_X_TOOLKIT=LUCID
2822       LUCID_LIBW=-lXaw
2823     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
2824       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
2825     else
2826       AC_MSG_ERROR([No X toolkit could be found.
2827 If you are sure you want Emacs compiled without an X toolkit, pass
2828   --with-x-toolkit=no
2829 to configure.  Otherwise, install the development libraries for the toolkit
2830 that you want to use (e.g. Gtk+) and re-run configure.])
2831     fi
2832   fi
2833 fi
2834
2835 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
2836
2837 LIBXTR6=
2838 LIBXMU=
2839 if test "${USE_X_TOOLKIT}" != "none"; then
2840   AC_MSG_CHECKING(X11 toolkit version)
2841   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
2842   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Intrinsic.h>]],
2843 [[#if XtSpecificationRelease < 6
2844 fail;
2845 #endif
2846 ]])], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
2847   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
2848   if test $emacs_cv_x11_toolkit_version_6 = yes; then
2849     AC_MSG_RESULT(6 or newer)
2850     AC_DEFINE(HAVE_X11XTR6, 1,
2851               [Define to 1 if you have the X11R6 or newer version of Xt.])
2852     LIBXTR6="-lSM -lICE"
2853     case "$opsys" in
2854       ## Use libw.a along with X11R6 Xt.
2855       unixware) LIBXTR6="$LIBXTR6 -lw" ;;
2856     esac
2857   else
2858     AC_MSG_RESULT(before 6)
2859   fi
2860
2861 dnl If using toolkit, check whether libXmu.a exists.
2862 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
2863   OLDLIBS="$LIBS"
2864   if test x$HAVE_X11XTR6 = xyes; then
2865     OTHERLIBS='-lXt -lSM -lICE'
2866   else
2867     OTHERLIBS='-lXt'
2868   fi
2869   AC_SEARCH_LIBS([XmuConvertStandardSelection], [Xmu], [], [], [$OTHERLIBS])
2870   if test "X$LIBS" != "X$OLDLIBS"; then
2871     LIBXMU=$ac_cv_search_XmuConvertStandardSelection
2872   fi
2873   LIBS=$OLDLIBS
2874   dnl ac_cv_search_XmuConvertStandardSelection is also referenced below.
2875 fi
2876 AC_SUBST(LIBXTR6)
2877 AC_SUBST(LIBXMU)
2878
2879 LIBXP=
2880 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2881   # OpenMotif may be installed in such a way on some GNU/Linux systems.
2882   if test -d /usr/include/openmotif; then
2883     CPPFLAGS="-I/usr/include/openmotif $CPPFLAGS"
2884     emacs_cv_openmotif=yes
2885     case "$canonical" in
2886       x86_64-*-linux-gnu* | powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*)
2887       test -d /usr/lib64/openmotif && LDFLAGS="-L/usr/lib64/openmotif $LDFLAGS"
2888       ;;
2889       *)
2890       test -d /usr/lib/openmotif && LDFLAGS="-L/usr/lib/openmotif $LDFLAGS"
2891     esac
2892   else
2893     emacs_cv_openmotif=no
2894   fi
2895   AC_CACHE_CHECK(for (Open)Motif version 2.1, emacs_cv_motif_version_2_1,
2896   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <Xm/Xm.h>]],
2897     [[#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
2898 int x = 5;
2899 #else
2900 Motif version prior to 2.1.
2901 #endif]])],
2902     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
2903   if test $emacs_cv_motif_version_2_1 = yes; then
2904     AC_CHECK_LIB(Xp, XpCreateContext, LIBXP=-lXp)
2905     if test x$emacs_cv_openmotif = xyes; then
2906       REAL_CPPFLAGS="-I/usr/include/openmotif $REAL_CPPFLAGS"
2907     fi
2908   else
2909     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
2910     # We put this in CFLAGS temporarily to precede other -I options
2911     # that might be in CFLAGS temporarily.
2912     # We put this in CPPFLAGS where it precedes the other -I options.
2913     OLD_CPPFLAGS=$CPPFLAGS
2914     OLD_CFLAGS=$CFLAGS
2915     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
2916     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
2917     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>]],
2918       [[int x = 5;]])],
2919       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
2920     if test $emacs_cv_lesstif = yes; then
2921       # Make sure this -I option remains in CPPFLAGS after it is set
2922       # back to REAL_CPPFLAGS.
2923       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
2924       # have those other -I options anyway.  Ultimately, having this
2925       # directory ultimately in CPPFLAGS will be enough.
2926       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
2927       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
2928     else
2929       CFLAGS=$OLD_CFLAGS
2930       CPPFLAGS=$OLD_CPPFLAGS
2931     fi
2932   fi
2933   AC_CHECK_HEADER([Xm/BulletinB.h], [],
2934     [AC_MSG_ERROR([Motif toolkit requested but requirements not found.])])
2935 fi
2936
2937 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
2938 dnl using Motif or Xaw3d is available, and unless
2939 dnl --with-toolkit-scroll-bars=no was specified.
2940
2941 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
2942             [Define to 1 if we should use toolkit scroll bars.])dnl
2943 USE_TOOLKIT_SCROLL_BARS=no
2944 if test "${with_toolkit_scroll_bars}" != "no"; then
2945   if test "${USE_X_TOOLKIT}" != "none"; then
2946     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2947       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2948       HAVE_XAW3D=no
2949       USE_TOOLKIT_SCROLL_BARS=yes
2950     elif test "${HAVE_XAW3D}" = "yes" || test "${USE_X_TOOLKIT}" = "LUCID"; then
2951       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2952       USE_TOOLKIT_SCROLL_BARS=yes
2953     fi
2954   elif test "${HAVE_GTK}" = "yes"; then
2955     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2956     USE_TOOLKIT_SCROLL_BARS=yes
2957   elif test "${HAVE_NS}" = "yes"; then
2958     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2959     USE_TOOLKIT_SCROLL_BARS=yes
2960   elif test "${HAVE_W32}" = "yes"; then
2961     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2962     USE_TOOLKIT_SCROLL_BARS=yes
2963   fi
2964 fi
2965
2966 dnl See if XIM is available.
2967 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2968           #include <X11/Xlib.h>
2969           #include <X11/Xresource.h>]],
2970          [[XIMProc  callback;]])],
2971          [HAVE_XIM=yes
2972          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
2973          HAVE_XIM=no)
2974
2975 dnl '--with-xim' now controls only the initial value of use_xim at run time.
2976
2977 if test "${with_xim}" != "no"; then
2978   AC_DEFINE(USE_XIM, 1,
2979             [Define to 1 if we should use XIM, if it is available.])
2980 fi
2981
2982
2983 if test "${HAVE_XIM}" != "no"; then
2984   late_CFLAGS=$CFLAGS
2985   if test "$GCC" = yes; then
2986     CFLAGS="$CFLAGS --pedantic-errors"
2987   fi
2988   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2989 #include <X11/Xlib.h>
2990 #include <X11/Xresource.h>]],
2991 [[Display *display;
2992 XrmDatabase db;
2993 char *res_name;
2994 char *res_class;
2995 XIMProc  callback;
2996 XPointer *client_data;
2997 #ifndef __GNUC__
2998 /* If we're not using GCC, it's probably not XFree86, and this is
2999    probably right, but we can't use something like --pedantic-errors.  */
3000 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
3001                                            char*, XIMProc, XPointer*);
3002 #endif
3003 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
3004    client_data);]])],
3005     [emacs_cv_arg6_star=yes])
3006   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
3007          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
3008 either XPointer or XPointer*.])dnl
3009   if test "$emacs_cv_arg6_star" = yes; then
3010     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
3011   else
3012     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
3013   fi
3014   CFLAGS=$late_CFLAGS
3015 fi
3016
3017 ### Start of font-backend (under any platform) section.
3018 # (nothing here yet -- this is a placeholder)
3019 ### End of font-backend (under any platform) section.
3020
3021 ### Start of font-backend (under X11) section.
3022 if test "${HAVE_X11}" = "yes"; then
3023     ## Use -lXft if available, unless '--with-xft=no'.
3024     HAVE_XFT=maybe
3025     if test "x${with_x}" = "xno"; then
3026       with_xft="no";
3027     fi
3028
3029     if test "$with_xft" != no; then
3030       EMACS_CHECK_MODULES([FONTCONFIG], [fontconfig >= 2.2.0])
3031       with_xft=$HAVE_FONTCONFIG
3032     fi
3033
3034     if test "x${with_xft}" != "xno"; then
3035
3036       EMACS_CHECK_MODULES([XFT], [xft >= 0.13.0], [], [HAVE_XFT=no])
3037       ## Because xftfont.c uses XRenderQueryExtension, we also
3038       ## need to link to -lXrender.
3039       HAVE_XRENDER=no
3040       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
3041       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
3042         OLD_CPPFLAGS="$CPPFLAGS"
3043         OLD_CFLAGS="$CFLAGS"
3044         OLD_LIBS="$LIBS"
3045         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
3046         CFLAGS="$CFLAGS $XFT_CFLAGS"
3047         XFT_LIBS="-lXrender $XFT_LIBS"
3048         LIBS="$XFT_LIBS $LIBS"
3049         AC_CHECK_HEADER(X11/Xft/Xft.h,
3050           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS) , ,
3051           [[#include <X11/X.h>]])
3052
3053         if test "${HAVE_XFT}" = "yes"; then
3054           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
3055             AC_SUBST(XFT_LIBS)
3056           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
3057         fi                        # "${HAVE_XFT}" = "yes"
3058         CPPFLAGS=$OLD_CPPFLAGS
3059         CFLAGS=$OLD_CFLAGS
3060         LIBS=$OLD_LIBS
3061       fi                          # "$HAVE_XFT" != no
3062     fi                            # "x${with_xft}" != "xno"
3063
3064     ## We used to allow building with FreeType and without Xft.
3065     ## However, the ftx font backend driver is not in good shape.
3066     if test "$HAVE_XFT" != "yes"; then
3067        dnl For the "Does Emacs use" message at the end.
3068        HAVE_XFT=no
3069        HAVE_FREETYPE=no
3070     else
3071        dnl Strict linkers fail with
3072        dnl ftfont.o: undefined reference to symbol 'FT_New_Face'
3073        dnl if -lfreetype is not specified.
3074        dnl The following is needed to set FREETYPE_LIBS.
3075        EMACS_CHECK_MODULES([FREETYPE], [freetype2])
3076
3077        test "$HAVE_FREETYPE" = "no" && AC_MSG_ERROR(libxft requires libfreetype)
3078     fi
3079
3080     HAVE_LIBOTF=no
3081     if test "${HAVE_FREETYPE}" = "yes"; then
3082       AC_DEFINE(HAVE_FREETYPE, 1,
3083                 [Define to 1 if using the freetype and fontconfig libraries.])
3084       if test "${with_libotf}" != "no"; then
3085         EMACS_CHECK_MODULES([LIBOTF], [libotf])
3086         if test "$HAVE_LIBOTF" = "yes"; then
3087           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
3088           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
3089                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
3090                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
3091           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
3092             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
3093                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
3094           fi
3095         fi
3096       fi
3097     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
3098     dnl Does the new font backend require it, or can it work without it?
3099     fi
3100
3101     HAVE_M17N_FLT=no
3102     if test "${HAVE_LIBOTF}" = yes; then
3103       if test "${with_m17n_flt}" != "no"; then
3104         EMACS_CHECK_MODULES([M17N_FLT], [m17n-flt])
3105         if test "$HAVE_M17N_FLT" = "yes"; then
3106           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
3107         fi
3108       fi
3109     fi
3110 else
3111     HAVE_XFT=no
3112     HAVE_FREETYPE=no
3113     HAVE_LIBOTF=no
3114     HAVE_M17N_FLT=no
3115 fi
3116
3117 ### End of font-backend (under X11) section.
3118
3119 AC_SUBST(FREETYPE_CFLAGS)
3120 AC_SUBST(FREETYPE_LIBS)
3121 AC_SUBST(FONTCONFIG_CFLAGS)
3122 AC_SUBST(FONTCONFIG_LIBS)
3123 AC_SUBST(LIBOTF_CFLAGS)
3124 AC_SUBST(LIBOTF_LIBS)
3125 AC_SUBST(M17N_FLT_CFLAGS)
3126 AC_SUBST(M17N_FLT_LIBS)
3127
3128 USE_CAIRO=no
3129 if test "${HAVE_X11}" = "yes"; then
3130   if test "${with_cairo}" != "no"; then
3131     CAIRO_REQUIRED=1.12.0
3132     CAIRO_MODULE="cairo >= $CAIRO_REQUIRED"
3133     PKG_CHECK_MODULES(CAIRO, $CAIRO_MODULE, USE_CAIRO=yes, :)
3134     if test $USE_CAIRO = yes; then
3135       AC_DEFINE(USE_CAIRO, 1, [Define to 1 if using cairo.])
3136     else
3137       AC_MSG_ERROR([cairo requested but not found.])
3138     fi
3139
3140     CFLAGS="$CFLAGS $CAIRO_CFLAGS"
3141     LIBS="$LIBS $CAIRO_LIBS"
3142     AC_SUBST(CAIRO_CFLAGS)
3143     AC_SUBST(CAIRO_LIBS)
3144   fi
3145 fi
3146
3147 if test "${HAVE_X11}" = "yes"; then
3148   AC_CHECK_HEADER(X11/Xlib-xcb.h,
3149     AC_CHECK_LIB(xcb, xcb_translate_coordinates, HAVE_XCB=yes))
3150   if test "${HAVE_XCB}" = "yes"; then
3151     AC_CHECK_LIB(X11-xcb, XGetXCBConnection, HAVE_X11_XCB=yes)
3152     if test "${HAVE_X11_XCB}" = "yes"; then
3153       AC_DEFINE(USE_XCB, 1,
3154 [Define to 1 if you have the XCB library and X11-XCB library for mixed
3155    X11/XCB programming.])
3156       XCB_LIBS="-lX11-xcb -lxcb"
3157       AC_SUBST(XCB_LIBS)
3158     fi
3159   fi
3160 fi
3161
3162 ### Use -lXpm if available, unless '--with-xpm=no'.
3163 ### mingw32 doesn't use -lXpm, since it loads the library dynamically.
3164 ### In the Cygwin-w32 build, we need to use /usr/include/noX/X11/xpm.h
3165 ### rather than /usr/include/X11/xpm.h, so we set CPPFLAGS (and
3166 ### LDFLAGS) accordingly.
3167 HAVE_XPM=no
3168 LIBXPM=
3169 if test "${HAVE_W32}" = "yes" && test "${opsys}" = "cygwin"; then
3170   if test "${with_xpm}" != "no"; then
3171     SAVE_CPPFLAGS="$CPPFLAGS"
3172     SAVE_LDFLAGS="$LDFLAGS"
3173     CPPFLAGS="$CPPFLAGS -I/usr/include/noX"
3174     LDFLAGS="$LDFLAGS -L/usr/lib/noX"
3175     AC_CHECK_HEADER(X11/xpm.h,
3176       [AC_CHECK_LIB(Xpm, XpmReadFileToImage, HAVE_XPM=yes)])
3177     if test "${HAVE_XPM}" = "yes"; then
3178       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
3179       AC_EGREP_CPP(no_return_alloc_pixels,
3180       [#include "X11/xpm.h"
3181 #ifndef XpmReturnAllocPixels
3182 no_return_alloc_pixels
3183 #endif
3184       ], HAVE_XPM=no, HAVE_XPM=yes)
3185
3186       if test "${HAVE_XPM}" = "yes"; then
3187         REAL_CPPFLAGS="$REAL_CPPFLAGS -I/usr/include/noX"
3188         AC_MSG_RESULT(yes)
3189       else
3190         AC_MSG_RESULT(no)
3191         CPPFLAGS="$SAVE_CPPFLAGS"
3192         LDFLAGS="$SAVE_LDFLAGS"
3193       fi
3194     fi
3195   fi
3196
3197   if test "${HAVE_XPM}" = "yes"; then
3198     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
3199     LIBXPM=-lXpm
3200   fi
3201 fi
3202
3203 if test "${HAVE_X11}" = "yes"; then
3204   dnl Avoid Xpm on AIX unless requested, as it crashes; see Bug#17598.
3205   test "$opsys$with_xpm_set" = aix4-2 && with_xpm=no
3206
3207   if test "${with_xpm}" != "no"; then
3208     AC_CHECK_HEADER(X11/xpm.h,
3209       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
3210     if test "${HAVE_XPM}" = "yes"; then
3211       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
3212       AC_EGREP_CPP(no_return_alloc_pixels,
3213       [#include "X11/xpm.h"
3214 #ifndef XpmReturnAllocPixels
3215 no_return_alloc_pixels
3216 #endif
3217       ], HAVE_XPM=no, HAVE_XPM=yes)
3218
3219       if test "${HAVE_XPM}" = "yes"; then
3220         AC_MSG_RESULT(yes)
3221       else
3222         AC_MSG_RESULT(no)
3223       fi
3224     fi
3225   fi
3226
3227   if test "${HAVE_XPM}" = "yes"; then
3228     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
3229     LIBXPM=-lXpm
3230   elif test "$opsys,$LUCID_LIBW" = aix4-2,-lXaw; then
3231     dnl AIX -lXaw needs -lXpm linked too; see Bug#17598 Message#152.
3232     LIBXPM=-lXpm
3233   fi
3234 fi
3235
3236 ### FIXME: Perhaps regroup to minimize code duplication due to MinGW's
3237 ### slightly different requirements wrt image libraries (it doesn't
3238 ### use -lXpm because it loads the xpm shared library dynamically at
3239 ### run time).
3240 if test "${opsys}" = "mingw32"; then
3241   if test "${with_xpm}" != "no"; then
3242     AC_CHECK_HEADER(X11/xpm.h, HAVE_XPM=yes, HAVE_XPM=no, [
3243 #define FOR_MSW 1])
3244   fi
3245
3246   if test "${HAVE_XPM}" = "yes"; then
3247     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
3248   fi
3249 fi
3250
3251 AC_SUBST(LIBXPM)
3252
3253 ### Use -ljpeg if available, unless '--with-jpeg=no'.
3254 HAVE_JPEG=no
3255 LIBJPEG=
3256 if test "${with_jpeg}" != "no"; then
3257   AC_CACHE_CHECK([for jpeglib 6b or later],
3258     [emacs_cv_jpeglib],
3259     [OLD_LIBS=$LIBS
3260      for emacs_cv_jpeglib in yes -ljpeg no; do
3261        case $emacs_cv_jpeglib in
3262          yes) ;;
3263          no) break;;
3264          *) LIBS="$LIBS $emacs_cv_jpeglib";;
3265        esac
3266        AC_LINK_IFELSE(
3267          [AC_LANG_PROGRAM(
3268             [[#undef HAVE_STDLIB_H /* Avoid config.h/jpeglib.h collision.  */
3269               #include <stdio.h> /* jpeglib.h needs FILE and size_t.  */
3270               #include <jpeglib.h>
3271               #include <jerror.h>
3272               char verify[JPEG_LIB_VERSION < 62 ? -1 : 1];
3273               struct jpeg_decompress_struct cinfo;
3274             ]],
3275             [[
3276               jpeg_create_decompress (&cinfo);
3277               WARNMS (&cinfo, JWRN_JPEG_EOF);
3278               jpeg_destroy_decompress (&cinfo);
3279             ]])],
3280          [emacs_link_ok=yes],
3281          [emacs_link_ok=no])
3282        LIBS=$OLD_LIBS
3283        test $emacs_link_ok = yes && break
3284      done])
3285   if test "$emacs_cv_jpeglib" != no; then
3286     HAVE_JPEG=yes
3287     AC_DEFINE([HAVE_JPEG], 1,
3288       [Define to 1 if you have the jpeg library (typically -ljpeg).])
3289     ### mingw32 doesn't use -ljpeg, since it loads the library
3290     ### dynamically when needed, and doesn't want a run-time
3291     ### dependency on the jpeglib DLL.
3292     test "$emacs_cv_jpeglib" != yes && test "${opsys}" != "mingw32" \
3293     && LIBJPEG=$emacs_cv_jpeglib
3294   fi
3295 fi
3296 AC_SUBST(LIBJPEG)
3297
3298 HAVE_ZLIB=no
3299 LIBZ=
3300 if test "${with_zlib}" != "no"; then
3301   OLIBS=$LIBS
3302   AC_SEARCH_LIBS([inflateEnd], [z], [HAVE_ZLIB=yes])
3303   LIBS=$OLIBS
3304   case $ac_cv_search_inflateEnd in
3305     -*) LIBZ=$ac_cv_search_inflateEnd ;;
3306   esac
3307 fi
3308 if test "${HAVE_ZLIB}" = "yes"; then
3309   AC_DEFINE([HAVE_ZLIB], 1, [Define to 1 if you have the zlib library (-lz).])
3310   ### mingw32 doesn't use -lz, since it loads the library dynamically.
3311   if test "${opsys}" = "mingw32"; then
3312      LIBZ=
3313   fi
3314 fi
3315 AC_SUBST(LIBZ)
3316
3317 ### Dynamic modules support
3318 LIBMODULES=
3319 HAVE_MODULES=no
3320 MODULES_OBJ=
3321 MODULES_SUFFIX=
3322 if test "${with_modules}" != "no"; then
3323   if test "$opsys" = "gnu-linux"; then
3324     LIBMODULES="-ldl"
3325     MODULES_SUFFIX=".so"
3326     HAVE_MODULES=yes
3327   elif test "$opsys" = "cygwin"; then
3328     MODULES_SUFFIX=".dll"
3329     HAVE_MODULES=yes
3330   elif test "$opsys" = "darwin"; then
3331     MODULES_SUFFIX=".so"
3332     HAVE_MODULES=yes
3333   elif test "$opsys" = "mingw32"; then
3334     MODULES_SUFFIX=".dll"
3335     HAVE_MODULES=yes
3336   else
3337     # BSD system have dlopen in the libc
3338     AC_CHECK_FUNC(dlopen, [MODULES_SUFFIX=".so"]
3339                           [HAVE_MODULES=yes], [])
3340   fi
3341
3342   if test "${HAVE_MODULES}" = no; then
3343     AC_MSG_ERROR([Dynamic modules are not supported on your system])
3344   else
3345     SAVE_LIBS=$LIBS
3346     LIBS="$LIBS $LIBMODULES"
3347     AC_CHECK_FUNCS([dlfunc])
3348     LIBS=$SAVE_LIBS
3349   fi
3350 fi
3351
3352 if test "${HAVE_MODULES}" = yes; then
3353    MODULES_OBJ="dynlib.o emacs-module.o"
3354    AC_DEFINE(HAVE_MODULES, 1, [Define to 1 if dynamic modules are enabled])
3355    AC_DEFINE_UNQUOTED(MODULES_SUFFIX, "$MODULES_SUFFIX",
3356      [System extension for dynamic libraries])
3357 fi
3358 AC_SUBST(MODULES_OBJ)
3359 AC_SUBST(LIBMODULES)
3360 AC_CHECK_FUNCS(dladdr)
3361
3362 ### Use -lpng if available, unless '--with-png=no'.
3363 HAVE_PNG=no
3364 LIBPNG=
3365 PNG_CFLAGS=
3366 if test "${NS_IMPL_COCOA}" = yes; then
3367   : # Nothing to do
3368 elif test "${with_png}" != no; then
3369   # mingw32 loads the library dynamically.
3370   if test "$opsys" = mingw32; then
3371     AC_CHECK_HEADER([png.h], [HAVE_PNG=yes])
3372   elif test "${HAVE_X11}" = "yes" || test "${HAVE_W32}" = "yes"; then
3373     AC_MSG_CHECKING([for png])
3374     png_cflags=`(libpng-config --cflags) 2>&AS_MESSAGE_LOG_FD` &&
3375     png_libs=`(libpng-config --libs) 2>&AS_MESSAGE_LOG_FD` || {
3376       # libpng-config does not work; configure by hand.
3377       # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
3378       # in /usr/include/libpng.
3379       if test -r /usr/include/libpng/png.h &&
3380          test ! -r /usr/include/png.h; then
3381         png_cflags=-I/usr/include/libpng
3382       else
3383         png_cflags=
3384       fi
3385       png_libs='-lpng'
3386     }
3387     SAVE_CFLAGS=$CFLAGS
3388     SAVE_LIBS=$LIBS
3389     CFLAGS="$CFLAGS $png_cflags"
3390     LIBS="$png_libs -lz -lm $LIBS"
3391     AC_LINK_IFELSE(
3392       [AC_LANG_PROGRAM([[#include <png.h>]],
3393          [[return !png_get_channels (0, 0);]])],
3394       [HAVE_PNG=yes
3395        PNG_CFLAGS=`AS_ECHO(["$png_cflags"]) | sed -e "$edit_cflags"`
3396        LIBPNG=$png_libs
3397        # $LIBPNG requires explicit -lz in some cases.
3398        # We don't know what those cases are, exactly, so play it safe and
3399        # append -lz to any nonempty $LIBPNG, unless we're already using LIBZ.
3400        if test -n "$LIBPNG" && test -z "$LIBZ"; then
3401          LIBPNG="$LIBPNG -lz"
3402        fi])
3403     CFLAGS=$SAVE_CFLAGS
3404     LIBS=$SAVE_LIBS
3405     AC_MSG_RESULT([$HAVE_PNG])
3406   fi
3407 fi
3408 if test $HAVE_PNG = yes; then
3409   AC_DEFINE([HAVE_PNG], [1], [Define to 1 if you have the png library.])
3410
3411   SAVE_CFLAGS=$CFLAGS
3412   CFLAGS="$CFLAGS $PNG_CFLAGS"
3413   AC_CHECK_DECL([png_longjmp],
3414     [],
3415     [AC_DEFINE([PNG_DEPSTRUCT], [],
3416        [Define to empty to suppress deprecation warnings when building
3417         with --enable-gcc-warnings and with libpng versions before 1.5,
3418         which lack png_longjmp.])],
3419     [[#include <png.h>
3420     ]])
3421   CFLAGS=$SAVE_CFLAGS
3422 fi
3423 AC_SUBST(LIBPNG)
3424 AC_SUBST(PNG_CFLAGS)
3425
3426 ### Use -ltiff if available, unless '--with-tiff=no'.
3427 ### mingw32 doesn't use -ltiff, since it loads the library dynamically.
3428 HAVE_TIFF=no
3429 LIBTIFF=
3430 if test "${opsys}" = "mingw32"; then
3431   if test "${with_tiff}" != "no"; then
3432     AC_CHECK_HEADER(tiffio.h, HAVE_TIFF=yes, HAVE_TIFF=no)
3433   fi
3434   if test "${HAVE_TIFF}" = "yes"; then
3435     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
3436   fi
3437 elif test "${HAVE_X11}" = "yes" || test "${HAVE_W32}" = "yes"; then
3438   if test "${with_tiff}" != "no"; then
3439     AC_CHECK_HEADER(tiffio.h,
3440       [tifflibs="-lz -lm"
3441       # At least one tiff package requires the jpeg library.
3442       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
3443       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
3444   fi
3445
3446   if test "${HAVE_TIFF}" = "yes"; then
3447     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
3448     dnl FIXME -lz -lm, as per libpng?
3449     LIBTIFF=-ltiff
3450   fi
3451 fi
3452 AC_SUBST(LIBTIFF)
3453
3454 ### Use -lgif or -lungif if available, unless '--with-gif=no'.
3455 ### mingw32 doesn't use -lgif/-lungif, since it loads the library dynamically.
3456 HAVE_GIF=no
3457 LIBGIF=
3458 if test "${opsys}" = "mingw32"; then
3459   if test "${with_gif}" != "no"; then
3460     AC_CHECK_HEADER(gif_lib.h, HAVE_GIF=yes, HAVE_GIF=no)
3461   fi
3462   if test "${HAVE_GIF}" = "yes"; then
3463     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
3464   fi
3465 elif test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no" \
3466         || test "${HAVE_W32}" = "yes"; then
3467   AC_CHECK_HEADER(gif_lib.h,
3468 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
3469 # Earlier versions can crash Emacs, but version 5.0 removes EGifPutExtensionLast.
3470     [AC_CHECK_LIB(gif, GifMakeMapObject, HAVE_GIF=yes,
3471         [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])])
3472
3473   if test "$HAVE_GIF" = yes; then
3474     LIBGIF=-lgif
3475   elif test "$HAVE_GIF" = maybe; then
3476 # If gif_lib.h but no libgif, try libungif.
3477     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
3478     test "$HAVE_GIF" = yes && LIBGIF=-lungif
3479   fi
3480
3481   if test "${HAVE_GIF}" = "yes"; then
3482     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
3483   fi
3484 fi
3485 AC_SUBST(LIBGIF)
3486
3487 dnl Check for required libraries.
3488 if test "${HAVE_X11}" = "yes"; then
3489   MISSING=""
3490   WITH_NO=""
3491   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
3492     MISSING="libXpm" && WITH_NO="--with-xpm=no"
3493   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
3494     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
3495   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
3496     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
3497   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
3498     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
3499   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
3500     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
3501
3502   if test "X${MISSING}" != X; then
3503     AC_MSG_ERROR([The following required libraries were not found:
3504     $MISSING
3505 Maybe some development libraries/packages are missing?
3506 If you don't want to link with them give
3507     $WITH_NO
3508 as options to configure])
3509   fi
3510 fi
3511
3512 ### Use -lgpm if available, unless '--with-gpm=no'.
3513 HAVE_GPM=no
3514 LIBGPM=
3515 if test "${with_gpm}" != "no"; then
3516   AC_CHECK_HEADER(gpm.h,
3517     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
3518
3519   if test "${HAVE_GPM}" = "yes"; then
3520     AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
3521     LIBGPM=-lgpm
3522   fi
3523 fi
3524 AC_SUBST(LIBGPM)
3525
3526 dnl Check for malloc/malloc.h on darwin
3527 AC_CHECK_HEADERS_ONCE(malloc/malloc.h)
3528
3529 GNUSTEP_CFLAGS=
3530 ### Use NeXTstep API to implement GUI.
3531 if test "${HAVE_NS}" = "yes"; then
3532   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
3533   if test "${NS_IMPL_COCOA}" = "yes"; then
3534     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
3535   fi
3536   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
3537     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
3538     if test $NS_GNUSTEP_CONFIG != yes; then
3539       # See also .m.o rule in src/Makefile.in.  */
3540       # FIXME: are all these flags really needed?  Document here why.  */
3541       GNUSTEP_CFLAGS="-D_REENTRANT -fPIC -fno-strict-aliasing -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
3542       ## Extra CFLAGS applied to src/*.m files.
3543       GNU_OBJC_CFLAGS="$GNU_OBJC_CFLAGS -fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
3544     fi
3545   fi
3546   OTHER_FILES=ns-app
3547 fi
3548
3549 ### Use session management (-lSM -lICE) if available
3550 HAVE_X_SM=no
3551 LIBXSM=
3552 if test "${HAVE_X11}" = "yes"; then
3553   AC_CHECK_HEADER(X11/SM/SMlib.h,
3554     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
3555
3556   if test "${HAVE_X_SM}" = "yes"; then
3557     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
3558     LIBXSM="-lSM -lICE"
3559   fi
3560 fi
3561 AC_SUBST(LIBXSM)
3562
3563 ### Use XRandr (-lXrandr) if available
3564 HAVE_XRANDR=no
3565 if test "${HAVE_X11}" = "yes"; then
3566   XRANDR_REQUIRED=1.2.2
3567   XRANDR_MODULES="xrandr >= $XRANDR_REQUIRED"
3568   EMACS_CHECK_MODULES([XRANDR], [$XRANDR_MODULES])
3569   if test $HAVE_XRANDR = no; then
3570     # Test old way in case pkg-config doesn't have it (older machines).
3571     # Include Xrender.h by hand to work around bug in older Xrandr.h
3572     # (e.g. RHEL5) and silence (harmless) configure warning (bug#18465).
3573     AC_CHECK_HEADER(X11/extensions/Xrandr.h,
3574       [AC_CHECK_LIB(Xrandr, XRRGetScreenResources, HAVE_XRANDR=yes)],
3575       [], [AC_INCLUDES_DEFAULT
3576 #include <X11/extensions/Xrender.h>])
3577     if test $HAVE_XRANDR = yes; then
3578       XRANDR_LIBS=-lXrandr
3579     fi
3580   fi
3581   if test $HAVE_XRANDR = yes; then
3582     SAVE_CFLAGS="$CFLAGS"
3583     SAVE_LIBS="$LIBS"
3584     CFLAGS="$XRANDR_CFLAGS $CFLAGS"
3585     LIBS="$XRANDR_LIBS $LIBS"
3586     AC_CHECK_FUNCS(XRRGetOutputPrimary XRRGetScreenResourcesCurrent)
3587     CFLAGS="$SAVE_CFLAGS"
3588     LIBS="$SAVE_LIBS"
3589
3590     AC_DEFINE(HAVE_XRANDR, 1, [Define to 1 if you have the XRandr extension.])
3591   fi
3592 fi
3593 AC_SUBST(XRANDR_CFLAGS)
3594 AC_SUBST(XRANDR_LIBS)
3595
3596 ### Use Xinerama (-lXinerama) if available
3597 HAVE_XINERAMA=no
3598 if test "${HAVE_X11}" = "yes"; then
3599   XINERAMA_REQUIRED=1.0.2
3600   XINERAMA_MODULES="xinerama >= $XINERAMA_REQUIRED"
3601   EMACS_CHECK_MODULES([XINERAMA], [$XINERAMA_MODULES])
3602   if test $HAVE_XINERAMA = no; then
3603     # Test old way in case pkg-config doesn't have it (older machines).
3604     AC_CHECK_HEADER(X11/extensions/Xinerama.h,
3605       [AC_CHECK_LIB(Xinerama, XineramaQueryExtension, HAVE_XINERAMA=yes)])
3606     if test $HAVE_XINERAMA = yes; then
3607       XINERAMA_LIBS=-lXinerama
3608     fi
3609   fi
3610   if test $HAVE_XINERAMA = yes; then
3611     AC_DEFINE(HAVE_XINERAMA, 1, [Define to 1 if you have the Xinerama extension.])
3612   fi
3613 fi
3614 AC_SUBST(XINERAMA_CFLAGS)
3615 AC_SUBST(XINERAMA_LIBS)
3616
3617 ### Use Xfixes (-lXfixes) if available
3618 HAVE_XFIXES=no
3619 if test "${HAVE_X11}" = "yes"; then
3620   XFIXES_REQUIRED=4.0.0
3621   XFIXES_MODULES="xfixes >= $XFIXES_REQUIRED"
3622   EMACS_CHECK_MODULES([XFIXES], [$XFIXES_MODULES])
3623   if test $HAVE_XFIXES = no; then
3624     # Test old way in case pkg-config doesn't have it (older machines).
3625     AC_CHECK_HEADER(X11/extensions/Xfixes.h,
3626       [AC_CHECK_LIB(Xfixes, XFixesHideCursor, HAVE_XFIXES=yes)])
3627     if test $HAVE_XFIXES = yes; then
3628       XFIXES_LIBS=-lXfixes
3629     fi
3630   fi
3631   if test $HAVE_XFIXES = yes; then
3632     AC_DEFINE(HAVE_XFIXES, 1, [Define to 1 if you have the Xfixes extension.])
3633   fi
3634 fi
3635 AC_SUBST(XFIXES_CFLAGS)
3636 AC_SUBST(XFIXES_LIBS)
3637
3638 ### Use libxml (-lxml2) if available
3639 ### mingw32 doesn't use -lxml2, since it loads the library dynamically.
3640 HAVE_LIBXML2=no
3641 if test "${with_xml2}" != "no"; then
3642   ### I'm not sure what the version number should be, so I just guessed.
3643   EMACS_CHECK_MODULES([LIBXML2], [libxml-2.0 > 2.6.17])
3644   # Built-in libxml2 on OS X 10.8 lacks libxml-2.0.pc.
3645   if test "${HAVE_LIBXML2}" != "yes" && test "$opsys" = "darwin"; then
3646     SAVE_CPPFLAGS="$CPPFLAGS"
3647     if test -z "$xcsdkdir" -a -n "$XCRUN" -a ! -d /usr/include; then
3648       dnl /usr/include is not found.  Try Xcode SDK dir if it is sane.
3649       xcsdkdir=`$XCRUN --show-sdk-path 2>/dev/null`
3650       case $xcsdkdir in
3651         *[[\\\"\#\$\&\'\`$am_lf\ \      ]]*)
3652         xcsdkdir="" ;;
3653       esac
3654     fi
3655     CPPFLAGS="$CPPFLAGS -I$xcsdkdir/usr/include/libxml2"
3656     AC_CHECK_HEADER(libxml/HTMLparser.h,
3657       [AC_CHECK_DECL(HTML_PARSE_RECOVER, HAVE_LIBXML2=yes, ,
3658                      [#include <libxml/HTMLparser.h>])])
3659     CPPFLAGS="$SAVE_CPPFLAGS"
3660     if test "${HAVE_LIBXML2}" = "yes"; then
3661       LIBXML2_CFLAGS="-I'$xcsdkdir/usr/include/libxml2'"
3662       LIBXML2_LIBS="-lxml2"
3663     fi
3664   fi
3665   if test "${HAVE_LIBXML2}" = "yes"; then
3666     if test "${opsys}" != "mingw32"; then
3667       AC_CHECK_LIB(xml2, htmlReadMemory, HAVE_LIBXML2=yes, HAVE_LIBXML2=no,
3668         [$LIBXML2_LIBS])
3669     else
3670       LIBXML2_LIBS=""
3671     fi
3672     if test "${HAVE_LIBXML2}" = "yes"; then
3673       AC_DEFINE(HAVE_LIBXML2, 1, [Define to 1 if you have the libxml library (-lxml2).])
3674     else
3675       LIBXML2_LIBS=""
3676       LIBXML2_CFLAGS=""
3677     fi
3678   fi
3679 fi
3680 AC_SUBST(LIBXML2_LIBS)
3681 AC_SUBST(LIBXML2_CFLAGS)
3682
3683 # If netdb.h doesn't declare h_errno, we must declare it by hand.
3684 # On MinGW, that is provided by nt/inc/sys/socket.h and w32.c.
3685 if test "${opsys}" = "mingw32"; then
3686   emacs_cv_netdb_declares_h_errno=yes
3687 fi
3688 AC_CACHE_CHECK(whether netdb declares h_errno,
3689                emacs_cv_netdb_declares_h_errno,
3690 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
3691   [[return h_errno;]])],
3692   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
3693 if test $emacs_cv_netdb_declares_h_errno = yes; then
3694   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
3695 fi
3696
3697 # Check for mail-locking functions in a "mail" library.  Probably this should
3698 # have the same check as for liblockfile below.
3699 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
3700 if test $have_mail = yes; then
3701   LIBS_MAIL=-lmail
3702   AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the 'mail' library (-lmail).])
3703
3704   OLD_LIBS=$LIBS
3705   LIBS="$LIBS_MAIL $LIBS"
3706   AC_CHECK_FUNCS(touchlock)
3707   LIBS=$OLD_LIBS
3708 else
3709   LIBS_MAIL=
3710 fi
3711 dnl Debian, at least:
3712 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
3713 if test $have_lockfile = yes; then
3714    LIBS_MAIL=-llockfile
3715    AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the 'lockfile' library (-llockfile).])
3716 else
3717 # If we have the shared liblockfile, assume we must use it for mail
3718 # locking (e.g. Debian).  If we couldn't link against liblockfile
3719 # (no liblockfile.a installed), ensure that we don't need to.
3720   dnl This works for files generally, not just executables.
3721   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
3722   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
3723                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
3724   if test $ac_cv_prog_liblockfile = yes; then
3725     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
3726 This probably means that movemail could lose mail.
3727 There may be a 'development' package to install containing liblockfile.])
3728   fi
3729 fi
3730 AC_CHECK_HEADERS_ONCE(maillock.h)
3731 AC_SUBST(LIBS_MAIL)
3732
3733 ## Define MAIL_USE_FLOCK (or LOCKF) if the mailer uses flock (or lockf) to
3734 ## interlock access to the mail spool.  The alternative is a lock file named
3735 ## /usr/spool/mail/$USER.lock.
3736 mail_lock=no
3737 case "$opsys" in
3738   aix4-2) mail_lock="lockf" ;;
3739
3740   gnu|freebsd|dragonfly|netbsd|openbsd|darwin|irix6-5) mail_lock="flock" ;;
3741
3742   ## On GNU/Linux systems, both methods are used by various mail programs.
3743   ## I assume most people are using newer mailers that have heard of flock.
3744   ## Change this if you need to.
3745   ## Debian contains a patch which says: "On Debian/GNU/Linux systems,
3746   ## configure gets the right answers, and that means *NOT* using flock.
3747   ## Using flock is guaranteed to be the wrong thing. See Debian Policy
3748   ## for details." and then uses '#ifdef DEBIAN'.  Unfortunately the
3749   ## Debian maintainer hasn't provided a clean fix for Emacs.
3750   ## movemail.c will use 'maillock' when MAILDIR, HAVE_LIBMAIL and
3751   ## HAVE_MAILLOCK_H are defined, so the following appears to be the
3752   ## correct logic.  -- fx
3753   ## We must check for HAVE_LIBLOCKFILE too, as movemail does.
3754   ## liblockfile is a Free Software replacement for libmail, used on
3755   ## Debian systems and elsewhere. -rfr.
3756   gnu-*)
3757     mail_lock="flock"
3758     if test $have_mail = yes || test $have_lockfile = yes; then
3759       test $ac_cv_header_maillock_h = yes && mail_lock=no
3760     fi
3761     ;;
3762
3763   mingw32)
3764     mail_lock="none-needed" ;;
3765 esac
3766
3767 BLESSMAIL_TARGET=
3768 case "$mail_lock" in
3769   flock) AC_DEFINE(MAIL_USE_FLOCK, 1, [Define if the mailer uses flock to interlock the mail spool.]) ;;
3770
3771   lockf) AC_DEFINE(MAIL_USE_LOCKF, 1, [Define if the mailer uses lockf to interlock the mail spool.]) ;;
3772
3773   none-needed) ;;
3774
3775   *) BLESSMAIL_TARGET="need-blessmail" ;;
3776 esac
3777 AC_SUBST(BLESSMAIL_TARGET)
3778
3779 OLD_LIBS=$LIBS
3780 LIBS="$LIB_PTHREAD $LIB_MATH $LIBS"
3781 AC_CHECK_FUNCS(accept4 fchdir gethostname \
3782 getrusage get_current_dir_name \
3783 lrand48 random rint \
3784 select getpagesize setlocale newlocale \
3785 getrlimit setrlimit shutdown getaddrinfo \
3786 pthread_sigmask strsignal setitimer \
3787 sendto recvfrom getsockname getpeername getifaddrs freeifaddrs \
3788 gai_strerror sync \
3789 getpwent endpwent getgrent endgrent \
3790 cfmakeraw cfsetspeed copysign __executable_start log2)
3791 LIBS=$OLD_LIBS
3792
3793 dnl No need to check for aligned_alloc and posix_memalign if using
3794 dnl gmalloc.o, as it supplies them, unless we're using hybrid_malloc.
3795 dnl Don't use these functions on Darwin as they are incompatible with
3796 dnl unexmacosx.c.
3797 if (test -z "$GMALLOC_OBJ" || test "$hybrid_malloc" = yes) \
3798   && test "$opsys" != darwin; then
3799   AC_CHECK_FUNCS([aligned_alloc posix_memalign], [break])
3800 fi
3801
3802 dnl Cannot use AC_CHECK_FUNCS
3803 AC_CACHE_CHECK([for __builtin_unwind_init],
3804                emacs_cv_func___builtin_unwind_init,
3805 [AC_LINK_IFELSE([AC_LANG_PROGRAM([], [__builtin_unwind_init ();])],
3806                 emacs_cv_func___builtin_unwind_init=yes,
3807                 emacs_cv_func___builtin_unwind_init=no)])
3808 if test $emacs_cv_func___builtin_unwind_init = yes; then
3809   AC_DEFINE(HAVE___BUILTIN_UNWIND_INIT, 1,
3810             [Define to 1 if you have the '__builtin_unwind_init' function.])
3811 fi
3812
3813 AC_CHECK_HEADERS_ONCE(sys/un.h)
3814
3815 AC_FUNC_FSEEKO
3816
3817 # UNIX98 PTYs.
3818 AC_CHECK_FUNCS(grantpt)
3819
3820 # PTY-related GNU extensions.
3821 AC_CHECK_FUNCS(getpt posix_openpt)
3822
3823 # Check this now, so that we will NOT find the above functions in ncurses.
3824 # That is because we have not set up to link ncurses in lib-src.
3825 # It's better to believe a function is not available
3826 # than to expect to find it in ncurses.
3827 # Also we need tputs and friends to be able to build at all.
3828 AC_MSG_CHECKING([for library containing tputs])
3829 # Run a test program that contains a call to tputs, a call that is
3830 # never executed.  This tests whether a pre-'main' dynamic linker
3831 # works with the library.  It's too much trouble to actually call
3832 # tputs in the test program, due to portability hassles.  When
3833 # cross-compiling, assume the test program will run if it links.
3834 AC_DEFUN([tputs_link_source], [
3835   AC_LANG_SOURCE(
3836      [[extern void tputs (const char *, int, int (*)(int));
3837        int main (int argc, char **argv)
3838        {
3839           if (argc == 10000)
3840             tputs (argv[0], 0, 0);
3841           return 0;
3842        }]])
3843 ])
3844 if test "${opsys}" = "mingw32"; then
3845   msg='none required'
3846 else
3847   # Maybe curses should be tried earlier?
3848   # See http://debbugs.gnu.org/cgi/bugreport.cgi?bug=9736#35
3849   for tputs_library in '' tinfo ncurses terminfo termcap curses; do
3850     OLIBS=$LIBS
3851     if test -z "$tputs_library"; then
3852       LIBS_TERMCAP=
3853       msg='none required'
3854     else
3855       LIBS_TERMCAP=-l$tputs_library
3856       msg=$LIBS_TERMCAP
3857       LIBS="$LIBS_TERMCAP $LIBS"
3858     fi
3859     AC_RUN_IFELSE([tputs_link_source], [], [msg=no],
3860       [AC_LINK_IFELSE([tputs_link_source], [], [msg=no])])
3861     LIBS=$OLIBS
3862     if test "X$msg" != Xno; then
3863       break
3864     fi
3865   done
3866 fi
3867 AC_MSG_RESULT([$msg])
3868 if test "X$msg" = Xno; then
3869   AC_MSG_ERROR([The required function 'tputs' was not found in any library.
3870 The following libraries were tried (in order):
3871   libtinfo, libncurses, libterminfo, libtermcap, libcurses
3872 Please try installing whichever of these libraries is most appropriate
3873 for your system, together with its header files.
3874 For example, a libncurses-dev(el) or similar package.])
3875 fi
3876
3877 ## Use termcap instead of terminfo?
3878 ## Only true for: freebsd < 40000, ms-w32, msdos, netbsd < 599002500.
3879 TERMINFO=yes
3880 ## FIXME?  In the cases below where we unconditionally set
3881 ## LIBS_TERMCAP="-lncurses", this overrides LIBS_TERMCAP = -ltinfo,
3882 ## if that was found above to have tputs.
3883 ## Should we use the gnu* logic everywhere?
3884 case "$opsys" in
3885   ## darwin: Prevents crashes when running Emacs in Terminal.app under 10.2.
3886   ##  The ncurses library has been moved out of the System framework in
3887   ##  Mac OS X 10.2.  So if configure detects it, set the command-line
3888   ##  option to use it.
3889   darwin) LIBS_TERMCAP="-lncurses" ;;
3890
3891   gnu*) test -z "$LIBS_TERMCAP" && LIBS_TERMCAP="-lncurses" ;;
3892
3893   freebsd)
3894     AC_MSG_CHECKING([whether FreeBSD is new enough to use terminfo])
3895     AC_CACHE_VAL(emacs_cv_freebsd_terminfo,
3896     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <osreldate.h>]],
3897 [[#if __FreeBSD_version < 400000
3898 fail;
3899 #endif
3900 ]])], emacs_cv_freebsd_terminfo=yes, emacs_cv_freebsd_terminfo=no)])
3901
3902     AC_MSG_RESULT($emacs_cv_freebsd_terminfo)
3903
3904     if test $emacs_cv_freebsd_terminfo = yes; then
3905       LIBS_TERMCAP="-lncurses"
3906     else
3907       TERMINFO=no
3908       LIBS_TERMCAP="-ltermcap"
3909     fi
3910     ;;
3911
3912   mingw32)
3913     TERMINFO=no
3914     LIBS_TERMCAP=
3915     ;;
3916
3917   netbsd)
3918     if test "x$LIBS_TERMCAP" != "x-lterminfo"; then
3919       TERMINFO=no
3920       LIBS_TERMCAP="-ltermcap"
3921     fi
3922     ;;
3923
3924   openbsd | dragonfly) LIBS_TERMCAP="-lncurses" ;;
3925
3926   ## hpux: Make sure we get select from libc rather than from libcurses
3927   ##  because libcurses on HPUX 10.10 has a broken version of select.
3928   ##  We used to use -lc -lcurses, but this may be cleaner.
3929   ## FIXME?  But TERMINFO = yes on hpux (it used to be explicitly
3930   # set that way, now it uses the default).  Isn't this a contradiction?
3931   hpux*) LIBS_TERMCAP="-ltermcap" ;;
3932
3933 esac
3934
3935 TERMCAP_OBJ=tparam.o
3936 if test $TERMINFO = yes; then
3937   AC_DEFINE(TERMINFO, 1, [Define to 1 if you use terminfo instead of termcap.])
3938   TERMCAP_OBJ=terminfo.o
3939 fi
3940 if test "X$LIBS_TERMCAP" = "X-lncurses"; then
3941   AC_DEFINE(USE_NCURSES, 1, [Define to 1 if you use ncurses.])
3942 fi
3943 AC_SUBST(LIBS_TERMCAP)
3944 AC_SUBST(TERMCAP_OBJ)
3945
3946 # GNU/Linux-specific timer functions.
3947 AC_CACHE_CHECK([for timerfd interface], [emacs_cv_have_timerfd],
3948   [AC_COMPILE_IFELSE(
3949      [AC_LANG_PROGRAM([[#include <sys/timerfd.h>
3950                       ]],
3951                       [[timerfd_create (CLOCK_REALTIME,
3952                                         TFD_CLOEXEC | TFD_NONBLOCK);
3953                         timerfd_settime (0, TFD_TIMER_ABSTIME, 0, 0);]])],
3954      [emacs_cv_have_timerfd=yes],
3955      [emacs_cv_have_timerfd=no])])
3956 if test "$emacs_cv_have_timerfd" = yes; then
3957   AC_DEFINE([HAVE_TIMERFD], 1,
3958     [Define to 1 if timerfd functions are supported as in GNU/Linux.])
3959 fi
3960
3961 # Alternate stack for signal handlers.
3962 AC_CACHE_CHECK([whether signals can be handled on alternate stack],
3963                [emacs_cv_alternate_stack],
3964   [AC_COMPILE_IFELSE(
3965      [AC_LANG_PROGRAM([[#include <signal.h>
3966                       ]],
3967                       [[stack_t ss;
3968                         struct sigaction sa;
3969                         ss.ss_sp = malloc (SIGSTKSZ);
3970                         ss.ss_size = SIGSTKSZ;
3971                         sa.sa_flags = SA_SIGINFO | SA_ONSTACK;
3972                         sigaltstack (&ss, 0);
3973                         sigaction (SIGSEGV, &sa, 0);]])],
3974      [emacs_cv_alternate_stack=yes],
3975      [emacs_cv_alternate_stack=no])])
3976
3977 # Do we have res_init, for detecting changes in /etc/resolv.conf?
3978 # On Darwin, res_init appears not to be useful: see bug#562 and
3979 # http://lists.gnu.org/archive/html/emacs-devel/2007-11/msg01467.html
3980 resolv=no
3981
3982 if test $opsys != darwin; then
3983
3984   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
3985 #include <arpa/nameser.h>
3986 #include <resolv.h>]],
3987     [[return res_init();]])],
3988     have_res_init=yes, have_res_init=no)
3989   if test "$have_res_init" = no; then
3990     OLIBS="$LIBS"
3991     LIBS="$LIBS -lresolv"
3992     AC_MSG_CHECKING(for res_init with -lresolv)
3993     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
3994 #include <arpa/nameser.h>
3995 #include <resolv.h>]],
3996       [[return res_init();]])],
3997       have_res_init=yes, have_res_init=no)
3998     AC_MSG_RESULT($have_res_init)
3999     if test "$have_res_init" = yes ; then
4000       resolv=yes
4001     fi
4002     LIBS="$OLIBS"
4003   fi
4004
4005   if test "$have_res_init" = yes; then
4006     AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
4007   fi
4008 fi                              dnl !darwin
4009
4010 # Do we need the Hesiod library to provide the support routines?
4011 dnl FIXME?  Should we be skipping this on Darwin too?
4012 LIBHESIOD=
4013 if test "$with_hesiod" != no ; then
4014   # Don't set $LIBS here -- see comments above.  FIXME which comments?
4015   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
4016      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
4017                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
4018   if test "$resolv" = yes ; then
4019     RESOLVLIB=-lresolv
4020   else
4021     RESOLVLIB=
4022   fi
4023   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
4024         hesiod=yes, :, $RESOLVLIB)])
4025
4026   if test x"$hesiod" = xyes; then
4027     LIBHESIOD=-lhesiod
4028   fi
4029 fi
4030 AC_SUBST(LIBHESIOD)
4031
4032 # Do we need libresolv (due to res_init or Hesiod)?
4033 if test "$resolv" = yes && test $opsys != darwin; then
4034   LIBRESOLV=-lresolv
4035 else
4036   LIBRESOLV=
4037 fi
4038 AC_SUBST(LIBRESOLV)
4039
4040 # These tell us which Kerberos-related libraries to use.
4041 COM_ERRLIB=
4042 CRYPTOLIB=
4043 KRB5LIB=
4044 DESLIB=
4045 KRB4LIB=
4046
4047 if test "${with_kerberos}" != no; then
4048   OLD_LIBS=$LIBS
4049   AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
4050   if test $have_com_err = yes; then
4051     COM_ERRLIB=-lcom_err
4052     LIBS="$COM_ERRLIB $LIBS"
4053   fi
4054   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
4055   if test $have_crypto = yes; then
4056     CRYPTOLIB=-lcrypto
4057     LIBS="$CRYPTOLIB $LIBS"
4058   fi
4059   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
4060   if test $have_k5crypto = yes; then
4061     CRYPTOLIB=-lk5crypto
4062     LIBS="$CRYPTOLIB $LIBS"
4063   fi
4064   AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
4065   if test $have_krb5=yes; then
4066     KRB5LIB=-lkrb5
4067     LIBS="$KRB5LIB $LIBS"
4068   fi
4069   dnl FIXME Simplify.  Does not match 22 logic, thanks to default_off?
4070   if test "${with_kerberos5}" = no; then
4071     AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
4072     if test $have_des425 = yes; then
4073       DESLIB=-ldes425
4074       LIBS="$DESLIB $LIBS"
4075     else
4076       AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
4077       if test $have_des = yes; then
4078         DESLIB=-ldes
4079         LIBS="$DESLIB $LIBS"
4080       fi
4081     fi
4082     AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
4083     if test $have_krb4 = yes; then
4084       KRB4LIB=-lkrb4
4085       LIBS="$KRB4LIB $LIBS"
4086     else
4087       AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
4088       if test $have_krb = yes; then
4089         KRB4LIB=-lkrb
4090         LIBS="$KRB4LIB $LIBS"
4091       fi
4092     fi
4093   fi
4094
4095   if test "${with_kerberos5}" != no; then
4096     AC_CHECK_HEADERS(krb5.h,
4097       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
4098                         [#include <krb5.h>])])
4099   else
4100     AC_CHECK_HEADERS(krb.h,,
4101                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
4102                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
4103   fi
4104   AC_CHECK_HEADERS(com_err.h)
4105   LIBS=$OLD_LIBS
4106 fi
4107
4108 AC_SUBST(COM_ERRLIB)
4109 AC_SUBST(CRYPTOLIB)
4110 AC_SUBST(KRB5LIB)
4111 AC_SUBST(DESLIB)
4112 AC_SUBST(KRB4LIB)
4113
4114 AC_CHECK_HEADERS(valgrind/valgrind.h)
4115
4116 AC_CHECK_MEMBERS([struct unipair.unicode], [], [], [[#include <linux/kd.h>]])
4117
4118 AC_CHECK_FUNCS_ONCE(tzset)
4119
4120 ok_so_far=yes
4121 AC_CHECK_FUNC(socket, , ok_so_far=no)
4122 if test $ok_so_far = yes; then
4123   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
4124 fi
4125 if test $ok_so_far = yes; then
4126   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
4127 fi
4128 if test $ok_so_far = yes; then
4129 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
4130   AC_DEFINE(HAVE_INET_SOCKETS, 1,
4131             [Define to 1 if you have inet sockets.])
4132 fi
4133
4134 AC_FUNC_FORK
4135
4136 AC_CHECK_FUNCS(snprintf)
4137
4138 dnl Check for glib.  This differs from other library checks in that
4139 dnl Emacs need not link to glib unless some other library is already
4140 dnl linking to glib.  Although glib provides no facilities that Emacs
4141 dnl needs for its own purposes, when glib is present Emacs needs to
4142 dnl use primitives like g_main_context_query to avoid clashing with
4143 dnl glib at a low level.
4144 dnl
4145 dnl Check this late, since it depends on $GTK_CFLAGS etc.
4146 XGSELOBJ=
4147 OLDCFLAGS="$CFLAGS"
4148 OLDLIBS="$LIBS"
4149 CFLAGS="$CFLAGS $GTK_CFLAGS $RSVG_CFLAGS $DBUS_CFLAGS $SETTINGS_CFLAGS"
4150 LIBS="$LIBS $GTK_LIBS $RSVG_LIBS $DBUS_LIBS $SETTINGS_LIBS"
4151 CFLAGS="$CFLAGS $NOTIFY_CFLAGS $CAIRO_CFLAGS"
4152 LIBS="$LIBS $NOTIFY_LIBS $CAIRO_LIBS"
4153 AC_MSG_CHECKING([whether GLib is linked in])
4154 AC_LINK_IFELSE([AC_LANG_PROGRAM(
4155         [[#include <glib.h>
4156         ]],
4157         [[g_print ("Hello world");]])],
4158      [links_glib=yes],
4159      [links_glib=no])
4160 AC_MSG_RESULT([$links_glib])
4161 if test "${links_glib}" = "yes"; then
4162   AC_DEFINE(HAVE_GLIB, 1, [Define to 1 if GLib is linked in.])
4163   if test "$HAVE_NS" = no;then
4164     XGSELOBJ=xgselect.o
4165   fi
4166 fi
4167 CFLAGS="$OLDCFLAGS"
4168 LIBS="$OLDLIBS"
4169 AC_SUBST(XGSELOBJ)
4170
4171 dnl Adapted from Haible's version.
4172 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
4173   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
4174     [[char* cs = nl_langinfo(CODESET);]])],
4175     emacs_cv_langinfo_codeset=yes,
4176     emacs_cv_langinfo_codeset=no)
4177   ])
4178 if test $emacs_cv_langinfo_codeset = yes; then
4179   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
4180     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
4181 fi
4182
4183 AC_TYPE_MBSTATE_T
4184
4185 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
4186 dnl how the tty code is related to POSIX and/or other versions of termios.
4187 dnl The following looks like a useful start.
4188 dnl
4189 dnl AC_SYS_POSIX_TERMIOS
4190 dnl if test $ac_cv_sys_posix_termios = yes; then
4191 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
4192 dnl                                and macros for terminal control.])
4193 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
4194 dnl fi
4195
4196 dnl Turned on June 1996 supposing nobody will mind it.
4197 dnl MinGW emulates passwd database, so this feature doesn't make sense there.
4198 if test "${opsys}" != "mingw32"; then
4199    AC_DEFINE(AMPERSAND_FULL_NAME, 1, [Define to use the convention that &
4200      in the full name stands for the login id.])
4201 fi
4202
4203 dnl Everybody supports this, except MS.
4204 dnl Seems like the kind of thing we should be testing for, though.
4205 ## Note: PTYs are broken on darwin <6.  Use at your own risk.
4206 if test "${opsys}" != "mingw32"; then
4207   AC_DEFINE(HAVE_PTYS, 1, [Define if the system supports pty devices.])
4208 fi
4209
4210 dnl Everybody supports this, except MS-DOS.
4211 dnl Seems like the kind of thing we should be testing for, though.
4212 dnl Compare with HAVE_INET_SOCKETS (which is unused...) above.
4213 AC_DEFINE(HAVE_SOCKETS, 1, [Define if the system supports
4214   4.2-compatible sockets.])
4215
4216 AH_TEMPLATE(INTERNAL_TERMINAL, [This is substituted when $TERM is "internal".])
4217
4218 AH_TEMPLATE(NULL_DEVICE, [Name of the file to open to get
4219   a null file, or a data sink.])
4220 if test "${opsys}" = "mingw32"; then
4221   AC_DEFINE(NULL_DEVICE, ["NUL:"])
4222 else
4223   AC_DEFINE(NULL_DEVICE, ["/dev/null"])
4224 fi
4225
4226 if test "${opsys}" = "mingw32"; then
4227   SEPCHAR=';'
4228 else
4229   SEPCHAR=':'
4230 fi
4231 AC_DEFINE_UNQUOTED(SEPCHAR, ['$SEPCHAR'], [Character that separates PATH elements.])
4232 dnl This is for MinGW, and is used in test/Makefile.in.
4233 dnl The MSYS Bash has heuristics for replacing ':' with ';' when it
4234 dnl decides that a command-line argument to be passed to a MinGW program
4235 dnl is a PATH-style list of directories.  But that heuristics plays it
4236 dnl safe, and only does the replacement when it is _absolutely_ sure it
4237 dnl sees a colon-separated list of file names; e.g. ":." is left alone,
4238 dnl which breaks in-tree builds.  So we do this manually instead.
4239 dnl Note that we cannot rely on PATH_SEPARATOR, as that one will always
4240 dnl be computed as ':' in MSYS Bash.
4241 AC_SUBST(SEPCHAR)
4242
4243 dnl Everybody supports this, except MS-DOS.
4244 AC_DEFINE(subprocesses, 1, [Define to enable asynchronous subprocesses.])
4245
4246 AC_DEFINE(USER_FULL_NAME, [pw->pw_gecos], [How to get a user's full name.])
4247
4248
4249 AC_DEFINE(DIRECTORY_SEP, ['/'],
4250   [Character that separates directories in a file name.])
4251
4252 if test "${opsys}" = "mingw32"; then
4253   AC_DEFINE(IS_DEVICE_SEP(_c_), [((_c_) == ':')],
4254     [Returns true if character is a device separator.])
4255
4256   AC_DEFINE(IS_DIRECTORY_SEP(_c_), [((_c_) == '/' || (_c_) == '\\')],
4257     [Returns true if character is a directory separator.])
4258
4259   AC_DEFINE(IS_ANY_SEP(_c_), [(IS_DIRECTORY_SEP (_c_) || IS_DEVICE_SEP(_c_))],
4260     [Returns true if character is any form of separator.])
4261 else
4262   AC_DEFINE(IS_DEVICE_SEP(_c_), 0,
4263     [Returns true if character is a device separator.])
4264
4265   AC_DEFINE(IS_DIRECTORY_SEP(_c_), [((_c_) == DIRECTORY_SEP)],
4266     [Returns true if character is a directory separator.])
4267
4268   AC_DEFINE(IS_ANY_SEP(_c_), [(IS_DIRECTORY_SEP (_c_))],
4269     [Returns true if character is any form of separator.])
4270 fi
4271
4272 AH_TEMPLATE(NO_EDITRES, [Define if XEditRes should not be used.])
4273
4274 case $opsys in
4275   aix4-2)
4276     dnl Unfortunately without libXmu we cannot support EditRes.
4277     if test "x$ac_cv_search_XmuConvertStandardSelection" = xno; then
4278       AC_DEFINE(NO_EDITRES, 1)
4279     fi
4280     ;;
4281
4282   hpux*)
4283     dnl Assar Westerlund <assar@sics.se> says this is necessary for
4284     dnl HP-UX 10.20, and that it works for HP-UX 0 as well.
4285     AC_DEFINE(NO_EDITRES, 1)
4286     ;;
4287 esac
4288
4289
4290 case $opsys in
4291   irix6-5 | sol2* | unixware )
4292     dnl Some SVr4s don't define NSIG in sys/signal.h for ANSI environments;
4293     dnl instead, there's a system variable _sys_nsig.  Unfortunately, we
4294     dnl need the constant to dimension an array.  So wire in the appropriate
4295     dnl value here.
4296     AC_DEFINE(NSIG_MINIMUM, 32, [Minimum value of NSIG.])
4297     ;;
4298 esac
4299
4300 emacs_broken_SIGIO=no
4301
4302 case $opsys in
4303   dnl SIGIO exists, but the feature doesn't work in the way Emacs needs.
4304   dnl See eg <http://article.gmane.org/gmane.os.openbsd.ports/46831>.
4305   hpux* | irix6-5 | nacl | openbsd | sol2* | unixware )
4306     emacs_broken_SIGIO=yes
4307     ;;
4308
4309   aix4-2)
4310     dnl On AIX Emacs uses the gmalloc.c malloc implementation.  But given
4311     dnl the way this system works, libc functions that return malloced
4312     dnl memory use the libc malloc implementation. Calling xfree or
4313     dnl xrealloc on the results of such functions results in a crash.
4314     dnl
4315     dnl One solution for this could be to define SYSTEM_MALLOC in configure,
4316     dnl but that does not currently work on this system.
4317     dnl
4318     dnl It is possible to completely override the malloc implementation on
4319     dnl AIX, but that involves putting the malloc functions in a shared
4320     dnl library and setting the MALLOCTYPE environment variable to point to
4321     dnl that shared library.
4322     dnl
4323     dnl Emacs currently calls xrealloc on the results of get_current_dir name,
4324     dnl to avoid a crash just use the Emacs implementation for that function.
4325     dnl
4326     dnl FIXME We could change the AC_CHECK_FUNCS call near the start
4327     dnl of this file, so that we do not check for get_current_dir_name
4328     dnl on AIX.  But that might be fragile if something else ends
4329     dnl up testing for get_current_dir_name as a dependency.
4330     AC_DEFINE(BROKEN_GET_CURRENT_DIR_NAME, 1, [Define if
4331       get_current_dir_name should not be used.])
4332     ;;
4333
4334   freebsd)
4335     dnl Circumvent a bug in FreeBSD.  In the following sequence of
4336     dnl writes/reads on a PTY, read(2) returns bogus data:
4337     dnl
4338     dnl write(2)  1022 bytes
4339     dnl write(2)   954 bytes, get EAGAIN
4340     dnl read(2)   1024 bytes in process_read_output
4341     dnl read(2)     11 bytes in process_read_output
4342     dnl
4343     dnl That is, read(2) returns more bytes than have ever been written
4344     dnl successfully.  The 1033 bytes read are the 1022 bytes written
4345     dnl successfully after processing (for example with CRs added if the
4346     dnl terminal is set up that way which it is here).  The same bytes will
4347     dnl be seen again in a later read(2), without the CRs.
4348     AC_DEFINE(BROKEN_PTY_READ_AFTER_EAGAIN, 1, [Define on FreeBSD to
4349       work around an issue when reading from a PTY.])
4350     ;;
4351 esac
4352
4353 case $opsys in
4354   gnu-* | sol2-10 )
4355     dnl FIXME Can't we test if this exists (eg /proc/$$)?
4356     AC_DEFINE(HAVE_PROCFS, 1, [Define if you have the /proc filesystem.])
4357   ;;
4358 esac
4359
4360 case $opsys in
4361   darwin | dragonfly | freebsd | netbsd | openbsd )
4362     AC_DEFINE(DONT_REOPEN_PTY, 1, [Define if process.c does not need to
4363       close a pty to make it a controlling terminal (it is already a
4364       controlling terminal of the subprocess, because we did ioctl TIOCSCTTY).])
4365   ;;
4366 esac
4367
4368 dnl FIXME Surely we can test for this rather than hard-code it.
4369 case $opsys in
4370   netbsd | openbsd) sound_device="/dev/audio" ;;
4371   *) sound_device="/dev/dsp" ;;
4372 esac
4373
4374 dnl Used in sound.c
4375 AC_DEFINE_UNQUOTED(DEFAULT_SOUND_DEVICE, "$sound_device",
4376   [Name of the default sound device.])
4377
4378
4379 dnl Emacs can read input using SIGIO and buffering characters itself,
4380 dnl or using CBREAK mode and making C-g cause SIGINT.
4381 dnl The choice is controlled by the variable interrupt_input.
4382 dnl
4383 dnl Define INTERRUPT_INPUT to make interrupt_input = 1 the default (use SIGIO)
4384 dnl
4385 dnl Emacs uses the presence of the USABLE_SIGIO macro
4386 dnl to indicate whether or not signal-driven I/O is possible.  It uses
4387 dnl INTERRUPT_INPUT to decide whether to use it by default.
4388 dnl
4389 dnl SIGIO can be used only on systems that implement it (4.2 and 4.3).
4390 dnl CBREAK mode has two disadvantages
4391 dnl 1) At least in 4.2, it is impossible to handle the Meta key properly.
4392 dnl I hear that in system V this problem does not exist.
4393 dnl 2) Control-G causes output to be discarded.
4394 dnl I do not know whether this can be fixed in system V.
4395 dnl
4396 dnl Another method of doing input is planned but not implemented.
4397 dnl It would have Emacs fork off a separate process
4398 dnl to read the input and send it to the true Emacs process
4399 dnl through a pipe.
4400 case $opsys in
4401   darwin | gnu-linux | gnu-kfreebsd )
4402     AC_DEFINE(INTERRUPT_INPUT, 1, [Define to read input using SIGIO.])
4403   ;;
4404 esac
4405
4406
4407 dnl If the system's imake configuration file defines 'NeedWidePrototypes'
4408 dnl as 'NO', we must define NARROWPROTO manually.  Such a define is
4409 dnl generated in the Makefile generated by 'xmkmf'.  If we don't define
4410 dnl NARROWPROTO, we will see the wrong function prototypes for X functions
4411 dnl taking float or double parameters.
4412 case $opsys in
4413   cygwin|gnu|gnu-linux|gnu-kfreebsd|irix6-5|freebsd|netbsd|openbsd)
4414     AC_DEFINE(NARROWPROTO, 1, [Define if system's imake configuration
4415       file defines 'NeedWidePrototypes' as 'NO'.])
4416   ;;
4417 esac
4418
4419
4420 dnl Used in process.c, this must be a loop, even if it only runs once.
4421 dnl (Except on SGI; see below.  Take that, clarity and consistency!)
4422 AH_TEMPLATE(PTY_ITERATION, [How to iterate over PTYs.])
4423 dnl Only used if !PTY_ITERATION.  Iterate from FIRST_PTY_LETTER to z,
4424 dnl trying suffixes 0-16.
4425 AH_TEMPLATE(FIRST_PTY_LETTER, [Letter to use in finding device name of
4426   first PTY, if PTYs are supported.])
4427 AH_TEMPLATE(PTY_OPEN, [How to open a PTY, if non-standard.])
4428 AH_TEMPLATE(PTY_NAME_SPRINTF, [How to get the device name of the control
4429   end of a PTY, if non-standard.])
4430 AH_TEMPLATE(PTY_TTY_NAME_SPRINTF, [How to get device name of the tty
4431   end of a PTY, if non-standard.])
4432
4433 case $opsys in
4434   aix4-2 )
4435     AC_DEFINE(PTY_ITERATION, [int c; for (c = 0; !c ; c++)])
4436     dnl You allocate a pty by opening /dev/ptc to get the master side.
4437     dnl To get the name of the slave side, you just ttyname() the master side.
4438     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptc");])
4439     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [strcpy (pty_name, ttyname (fd));])
4440     ;;
4441
4442   cygwin )
4443     AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
4444     dnl multi-line AC_DEFINEs are hard. :(
4445     AC_DEFINE(PTY_OPEN, [ do { int dummy; sigset_t blocked, procmask; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, &procmask); if (-1 == openpty (&fd, &dummy, pty_name, 0, 0)) fd = -1; pthread_sigmask (SIG_SETMASK, &procmask, 0); if (fd >= 0) emacs_close (dummy); } while (false)])
4446     AC_DEFINE(PTY_NAME_SPRINTF, [])
4447     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
4448     ;;
4449
4450   gnu | openbsd )
4451     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4452     ;;
4453
4454   gnu-linux | gnu-kfreebsd | dragonfly | freebsd | netbsd | darwin | nacl )
4455     dnl if HAVE_GRANTPT
4456     if test "x$ac_cv_func_grantpt" = xyes; then
4457       AC_DEFINE(UNIX98_PTYS, 1, [Define if the system has Unix98 PTYs.])
4458       AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
4459       dnl Note that grantpt and unlockpt may fork.  We must block SIGCHLD
4460       dnl to prevent sigchld_handler from intercepting the child's death.
4461       AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptyname = 0; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); if (grantpt (fd) != -1 && unlockpt (fd) != -1) ptyname = ptsname(fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (!ptyname) { emacs_close (fd); return -1; } snprintf (pty_name, PTY_NAME_SIZE, "%s", ptyname); }])
4462       dnl if HAVE_POSIX_OPENPT
4463       if test "x$ac_cv_func_posix_openpt" = xyes; then
4464         AC_DEFINE(PTY_OPEN, [do { fd = posix_openpt (O_RDWR | O_CLOEXEC | O_NOCTTY); if (fd < 0 && errno == EINVAL) fd = posix_openpt (O_RDWR | O_NOCTTY); } while (false)])
4465         AC_DEFINE(PTY_NAME_SPRINTF, [])
4466       dnl if HAVE_GETPT
4467       elif test "x$ac_cv_func_getpt" = xyes; then
4468         AC_DEFINE(PTY_OPEN, [fd = getpt ()])
4469         AC_DEFINE(PTY_NAME_SPRINTF, [])
4470       else
4471         AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptmx");])
4472       fi
4473     else
4474       AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4475     fi
4476     ;;
4477
4478   hpux*)
4479     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4480     AC_DEFINE(PTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/ptym/pty%c%x", c, i);])
4481     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/pty/tty%c%x", c, i);])
4482     ;;
4483
4484   irix6-5 )
4485     dnl It looks like this cannot be right, because it is not a loop.
4486     dnl However, process.c actually does this:
4487     dnl # ifndef __sgi
4488     dnl   continue;
4489     dnl # else
4490     dnl   return -1;
4491     dnl # endif
4492     dnl which presumably makes it OK, since irix == sgi (?).
4493     dnl FIXME it seems like this special treatment is unnecessary?
4494     dnl Why can't irix use a single-trip loop like eg cygwin?
4495     AC_DEFINE(PTY_ITERATION, [])
4496     dnl Not used, because PTY_ITERATION is defined.
4497     AC_DEFINE(FIRST_PTY_LETTER, ['q'])
4498     AC_DEFINE(PTY_OPEN, [ { struct sigaction ocstat, cstat; struct stat stb; char * name; sigemptyset(&cstat.sa_mask); cstat.sa_handler = SIG_DFL; cstat.sa_flags = 0; sigaction(SIGCHLD, &cstat, &ocstat); name = _getpty (&fd, O_RDWR | O_NDELAY, 0600, 0); sigaction(SIGCHLD, &ocstat, (struct sigaction *)0); if (name == 0) return -1; if (fd < 0) return -1; if (fstat (fd, &stb) < 0) return -1; strcpy (pty_name, name); }])
4499     dnl No need to get the pty name at all.
4500     AC_DEFINE(PTY_NAME_SPRINTF, [])
4501     dnl No need to use sprintf to get the tty name--we get that from _getpty.
4502     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
4503     ;;
4504
4505   sol2* )
4506     dnl On SysVr4, grantpt(3) forks a subprocess, so do not use
4507     dnl O_CLOEXEC when opening the pty, and keep the SIGCHLD handler
4508     dnl from intercepting that death.  If any child but grantpt's should die
4509     dnl within, it should be caught after sigrelse(2).
4510     AC_DEFINE(PTY_OPEN, [fd = open (pty_name, O_RDWR | O_NONBLOCK)])
4511     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptsname (int), *ptyname; int grantpt_result; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); grantpt_result = grantpt (fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (grantpt_result == -1 || unlockpt (fd) == -1 || !(ptyname = ptsname (fd))) { emacs_close (fd); return -1; } snprintf (pty_name, PTY_NAME_SIZE, "%s", ptyname); }])
4512     ;;
4513
4514   unixware )
4515     dnl Comments are as per sol2*.
4516     AC_DEFINE(PTY_OPEN, [fd = open (pty_name, O_RDWR | O_NONBLOCK)])
4517     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptsname (int), *ptyname; int grantpt_result; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); grantpt_result = grantpt (fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (grantpt_result == -1) fatal("could not grant slave pty"); if (unlockpt(fd) == -1) fatal("could not unlock slave pty"); if (!(ptyname = ptsname(fd))) fatal ("could not enable slave pty"); snprintf (pty_name, PTY_NAME_SIZE, "%s", ptyname); }])
4518     ;;
4519 esac
4520
4521
4522 case $opsys in
4523   sol2* | unixware )
4524     dnl This change means that we don't loop through allocate_pty too
4525     dnl many times in the (rare) event of a failure.
4526     AC_DEFINE(FIRST_PTY_LETTER, ['z'])
4527     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptmx");])
4528     dnl Push various streams modules onto a PTY channel.  Used in process.c.
4529     AC_DEFINE(SETUP_SLAVE_PTY, [if (ioctl (forkin, I_PUSH, "ptem") == -1) fatal ("ioctl I_PUSH ptem"); if (ioctl (forkin, I_PUSH, "ldterm") == -1) fatal ("ioctl I_PUSH ldterm"); if (ioctl (forkin, I_PUSH, "ttcompat") == -1) fatal ("ioctl I_PUSH ttcompat");], [How to set up a slave PTY, if needed.])
4530     ;;
4531 esac
4532
4533
4534 AH_TEMPLATE(SIGNALS_VIA_CHARACTERS, [Make process_send_signal work by
4535 "typing" a signal character on the pty.])
4536
4537 case $opsys in
4538   dnl Perry Smith <pedz@ddivt1.austin.ibm.com> says this is correct for AIX.
4539   dnl thomas@mathematik.uni-bremen.de says this is needed for IRIX.
4540   aix4-2 | cygwin | gnu | irix6-5 | dragonfly | freebsd | netbsd | openbsd | darwin )
4541     AC_DEFINE(SIGNALS_VIA_CHARACTERS, 1)
4542     ;;
4543
4544   dnl 21 Jun 06: Eric Hanchrow <offby1@blarg.net> says this works.
4545   dnl FIXME Does gnu-kfreebsd have linux/version.h?  It seems unlikely...
4546   gnu-linux | gnu-kfreebsd )
4547
4548     AC_MSG_CHECKING([for signals via characters])
4549     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4550 #include <linux/version.h>
4551 #if LINUX_VERSION_CODE < 0x20400
4552 # error "Linux version too old"
4553 #endif
4554       ]], [[]])], emacs_signals_via_chars=yes, emacs_signals_via_chars=no)
4555
4556     AC_MSG_RESULT([$emacs_signals_via_chars])
4557     test $emacs_signals_via_chars = yes && AC_DEFINE(SIGNALS_VIA_CHARACTERS, 1)
4558     ;;
4559 esac
4560
4561
4562 AH_TEMPLATE(TAB3, [Undocumented.])
4563
4564 case $opsys in
4565   darwin) AC_DEFINE(TAB3, OXTABS) ;;
4566
4567   gnu | dragonfly | freebsd | netbsd | openbsd )
4568     AC_DEFINE(TABDLY, OXTABS, [Undocumented.])
4569     AC_DEFINE(TAB3, OXTABS)
4570     ;;
4571
4572   gnu-linux | gnu-kfreebsd )
4573     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4574 #ifndef __ia64__
4575 # error "not ia64"
4576 #endif
4577       ]], [[]])], AC_DEFINE(GC_MARK_SECONDARY_STACK(),
4578         [do { extern void *__libc_ia64_register_backing_store_base; __builtin_ia64_flushrs (); mark_memory (__libc_ia64_register_backing_store_base, __builtin_ia64_bsp ());} while (false)],
4579         [Mark a secondary stack, like the register stack on the ia64.]), [])
4580     ;;
4581
4582   hpux*)
4583     AC_DEFINE(RUN_TIME_REMAP, 1, [Define if emacs.c needs to call
4584       run_time_remap; for HPUX.])
4585     ;;
4586 esac
4587
4588
4589 dnl This won't be used automatically yet.  We also need to know, at least,
4590 dnl that the stack is continuous.
4591 AH_TEMPLATE(GC_SETJMP_WORKS, [Define if setjmp is known to save all
4592   registers relevant for conservative garbage collection in the jmp_buf.])
4593
4594
4595 case $opsys in
4596   dnl Not all the architectures are tested, but there are Debian packages
4597   dnl for SCM and/or Guile on them, so the technique must work.  See also
4598   dnl comments in alloc.c concerning setjmp and gcc.
4599   dnl Fixme: it's probably safe to just use the GCC conditional below.
4600   gnu-linux | gnu-kfreebsd )
4601     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4602 #if defined __i386__ || defined __sparc__ || defined __mc68000__ \
4603   || defined __alpha__ || defined __mips__ || defined __s390__ \
4604   || defined __arm__ || defined __powerpc__ || defined __amd64__ \
4605   || defined __ia64__ || defined __sh__
4606 /* ok */
4607 #else
4608 # error "setjmp not known to work on this arch"
4609 #endif
4610     ]], [[]])], AC_DEFINE(GC_SETJMP_WORKS, 1))
4611     ;;
4612 esac
4613
4614
4615 if test x$GCC = xyes; then
4616    dnl GC_SETJMP_WORKS is nearly always appropriate for GCC.
4617    AC_DEFINE(GC_SETJMP_WORKS, 1)
4618 else
4619   case $opsys in
4620     dnl irix: Tested on Irix 6.5.  SCM worked on earlier versions.
4621     aix* | dragonfly | freebsd | netbsd | openbsd | irix6-5 | sol2* )
4622       AC_DEFINE(GC_SETJMP_WORKS, 1)
4623       ;;
4624   esac
4625 fi                              dnl GCC?
4626
4627 dnl In a weird quirk, MS runtime uses _setjmp and longjmp.
4628 AC_CACHE_CHECK([for _setjmp], [emacs_cv_func__setjmp],
4629   [AC_LINK_IFELSE(
4630      [AC_LANG_PROGRAM(
4631        [[#include <setjmp.h>
4632          #ifdef __MINGW32__
4633          # define _longjmp longjmp
4634          #endif
4635        ]],
4636        [[jmp_buf j;
4637          if (! _setjmp (j))
4638            _longjmp (j, 1);]])],
4639      [emacs_cv_func__setjmp=yes],
4640      [emacs_cv_func__setjmp=no])])
4641 if test $emacs_cv_func__setjmp = yes; then
4642   AC_DEFINE([HAVE__SETJMP], 1, [Define to 1 if _setjmp and _longjmp work.])
4643 fi
4644
4645 # We need to preserve signal mask to handle C stack overflows.
4646 AC_CACHE_CHECK([for sigsetjmp], [emacs_cv_func_sigsetjmp],
4647   [AC_LINK_IFELSE(
4648      [AC_LANG_PROGRAM(
4649        [[#include <setjmp.h>
4650        ]],
4651        [[sigjmp_buf j;
4652          if (! sigsetjmp (j, 1))
4653            siglongjmp (j, 1);]])],
4654      [emacs_cv_func_sigsetjmp=yes],
4655      [emacs_cv_func_sigsetjmp=no])])
4656 if test $emacs_cv_func_sigsetjmp = yes; then
4657   AC_DEFINE([HAVE_SIGSETJMP], 1,
4658     [Define to 1 if sigsetjmp and siglongjmp work.])
4659 fi
4660
4661 case $emacs_cv_func_sigsetjmp,$emacs_cv_alternate_stack,$opsys in
4662   yes,yes,* | *,*,mingw32)
4663     AC_DEFINE([HAVE_STACK_OVERFLOW_HANDLING], 1,
4664       [Define to 1 if C stack overflow can be handled in some cases.]);;
4665 esac
4666
4667 case $opsys in
4668   sol2* | unixware )
4669     dnl TIOCGPGRP is broken in SysVr4, so we can't send signals to PTY
4670     dnl subprocesses the usual way.  But TIOCSIGNAL does work for PTYs,
4671     dnl and this is all we need.
4672     AC_DEFINE(TIOCSIGSEND, TIOCSIGNAL, [Some platforms redefine this.])
4673     ;;
4674 esac
4675
4676
4677 case $opsys in
4678   hpux* | sol2* )
4679     dnl Used in xfaces.c.
4680     AC_DEFINE(XOS_NEEDS_TIME_H, 1, [Compensate for a bug in Xos.h on
4681       some systems, where it requires time.h.])
4682     ;;
4683 esac
4684
4685
4686 dnl Define symbols to identify the version of Unix this is.
4687 dnl Define all the symbols that apply correctly.
4688 AH_TEMPLATE(DOS_NT, [Define if the system is MS DOS or MS Windows.])
4689 AH_TEMPLATE(MSDOS, [Define if the system is MS DOS.])
4690 AH_TEMPLATE(USG, [Define if the system is compatible with System III.])
4691 AH_TEMPLATE(USG5_4, [Define if the system is compatible with System V Release 4.])
4692
4693 case $opsys in
4694   aix4-2)
4695     AC_DEFINE(USG, [])
4696     dnl This symbol should be defined on AIX Version 3  ???????
4697     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4698 #ifndef _AIX
4699 # error "_AIX not defined"
4700 #endif
4701     ]], [[]])], [], AC_DEFINE(_AIX, [], [Define if the system is AIX.]))
4702     ;;
4703
4704   cygwin)
4705     AC_DEFINE(CYGWIN, 1, [Define if the system is Cygwin.])
4706     ;;
4707
4708   darwin)
4709     dnl Not __APPLE__, as this may not be defined on non-OSX Darwin.
4710     dnl Not DARWIN, because Panther and lower CoreFoundation.h use DARWIN to
4711     dnl distinguish OS X from pure Darwin.
4712     AC_DEFINE(DARWIN_OS, [], [Define if the system is Darwin.])
4713     ;;
4714
4715   gnu-linux | gnu-kfreebsd )
4716     AC_DEFINE(USG, [])
4717     AC_DEFINE(GNU_LINUX, [], [Define if ths system is compatible with GNU/Linux.])
4718     ;;
4719
4720   hpux*)
4721     AC_DEFINE(USG, [])
4722     AC_DEFINE(HPUX, [], [Define if the system is HPUX.])
4723     ;;
4724
4725   irix6-5)
4726     AC_DEFINE(USG, [])
4727     AC_DEFINE(USG5_4, [])
4728     AC_DEFINE(IRIX6_5, [], [Define if the system is IRIX.])
4729     ;;
4730
4731   mingw32)
4732     AC_DEFINE(DOS_NT, [])
4733     AC_DEFINE(WINDOWSNT, 1, [Define if compiling for native MS Windows.])
4734     if test "x$ac_enable_checking" != "x" ; then
4735       AC_DEFINE(EMACSDEBUG, 1, [Define to 1 to enable w32 debug facilities.])
4736     fi
4737     ;;
4738
4739   sol2*)
4740     AC_DEFINE(USG, [])
4741     AC_DEFINE(USG5_4, [])
4742     AC_DEFINE(SOLARIS2, [], [Define if the system is Solaris.])
4743     ;;
4744
4745   unixware)
4746     AC_DEFINE(USG, [])
4747     AC_DEFINE(USG5_4, [])
4748     ;;
4749 esac
4750
4751 AC_CACHE_CHECK([for usable FIONREAD], [emacs_cv_usable_FIONREAD],
4752   [case $opsys in
4753      aix4-2 | nacl)
4754        dnl BUILD 9008 - FIONREAD problem still exists in X-Windows.
4755        emacs_cv_usable_FIONREAD=no
4756        ;;
4757
4758      mingw32)
4759        emacs_cv_usable_FIONREAD=yes
4760        ;;
4761
4762      *)
4763        AC_COMPILE_IFELSE(
4764          [AC_LANG_PROGRAM([[#include <sys/types.h>
4765                             #include <sys/ioctl.h>
4766                             #ifdef USG5_4
4767                             # include <sys/filio.h>
4768                             #endif
4769                           ]],
4770                           [[int foo = ioctl (0, FIONREAD, &foo);]])],
4771          [emacs_cv_usable_FIONREAD=yes],
4772          [emacs_cv_usable_FIONREAD=no])
4773        ;;
4774    esac])
4775 if test $emacs_cv_usable_FIONREAD = yes; then
4776   AC_DEFINE([USABLE_FIONREAD], [1], [Define to 1 if FIONREAD is usable.])
4777
4778   if test $emacs_broken_SIGIO = no; then
4779     AC_CACHE_CHECK([for usable SIGIO], [emacs_cv_usable_SIGIO],
4780       [AC_COMPILE_IFELSE(
4781          [AC_LANG_PROGRAM([[#include <fcntl.h>
4782                             #include <signal.h>
4783                           ]],
4784                           [[int foo = SIGIO | F_SETFL | FASYNC;]])],
4785          [emacs_cv_usable_SIGIO=yes],
4786          [emacs_cv_usable_SIGIO=no])],
4787       [emacs_cv_usable_SIGIO=yes],
4788       [emacs_cv_usable_SIGIO=no])
4789     if test $emacs_cv_usable_SIGIO = yes; then
4790       AC_DEFINE([USABLE_SIGIO], [1], [Define to 1 if SIGIO is usable.])
4791     fi
4792   fi
4793 fi
4794
4795 case $opsys in
4796   hpux11)
4797     dnl It works to open the pty's tty in the parent (Emacs), then
4798     dnl close and reopen it in the child.
4799     AC_DEFINE(USG_SUBTTY_WORKS, 1, [Define for USG systems where it
4800       works to open a pty's tty in the parent process, then close and
4801       reopen it in the child.])
4802     ;;
4803
4804   irix6-5)
4805     AC_DEFINE(PREFER_VSUSP, 1, [Define if process_send_signal should
4806       use VSUSP instead of VSWTCH.])
4807     ;;
4808
4809   sol2-10)
4810     AC_DEFINE(_STRUCTURED_PROC, 1, [Needed for system_process_attributes
4811       on Solaris.])
4812     ;;
4813 esac
4814
4815 # Set up the CFLAGS for real compilation, so we can substitute it.
4816 CFLAGS="$REAL_CFLAGS"
4817 CPPFLAGS="$REAL_CPPFLAGS"
4818 LIBS="$REAL_LIBS"
4819
4820 ## Hack to detect a buggy GCC version.
4821 if test "$GCC" = yes && \
4822    $CC --version 2> /dev/null | grep 'gcc.* 4.5.0' >/dev/null; then
4823   case $CFLAGS in
4824     *-fno-optimize-sibling-calls*) ;;
4825     *-O@<:@23@:>@*)
4826       AC_MSG_ERROR([GCC 4.5.0 has problems compiling Emacs; see etc/PROBLEMS.]);;
4827   esac
4828 fi
4829
4830 version=$PACKAGE_VERSION
4831
4832 copyright="Copyright (C) 2016 Free Software Foundation, Inc."
4833 AC_DEFINE_UNQUOTED(COPYRIGHT, ["$copyright"],
4834   [Short copyright string for this version of Emacs.])
4835 AC_SUBST(copyright)
4836
4837 ### Specify what sort of things we'll be editing into Makefile and config.h.
4838 ### Use configuration here uncanonicalized to avoid exceeding size limits.
4839 AC_SUBST(version)
4840 AC_SUBST(configuration)
4841 ## Unused?
4842 AC_SUBST(canonical)
4843 AC_SUBST(srcdir)
4844 AC_SUBST(prefix)
4845 AC_SUBST(exec_prefix)
4846 AC_SUBST(bindir)
4847 AC_SUBST(datadir)
4848 AC_SUBST(sharedstatedir)
4849 AC_SUBST(libexecdir)
4850 AC_SUBST(mandir)
4851 AC_SUBST(infodir)
4852 AC_SUBST(lispdir)
4853 AC_SUBST(standardlisppath)
4854 AC_SUBST(locallisppath)
4855 AC_SUBST(lisppath)
4856 AC_SUBST(x_default_search_path)
4857 AC_SUBST(etcdir)
4858 AC_SUBST(archlibdir)
4859 AC_SUBST(etcdocdir)
4860 AC_SUBST(bitmapdir)
4861 AC_SUBST(gamedir)
4862 AC_SUBST(gameuser)
4863 AC_SUBST(gamegroup)
4864 ## FIXME? Nothing uses @LD_SWITCH_X_SITE@.
4865 ## src/Makefile.in did add LD_SWITCH_X_SITE (as a cpp define) to the
4866 ## end of LIBX_BASE, but nothing ever set it.
4867 AC_SUBST(LD_SWITCH_X_SITE)
4868 AC_SUBST(C_SWITCH_X_SITE)
4869 AC_SUBST(GNUSTEP_CFLAGS)
4870 AC_SUBST(CFLAGS)
4871 ## Used in lwlib/Makefile.in.
4872 AC_SUBST(X_TOOLKIT_TYPE)
4873 AC_SUBST(ns_appdir)
4874 AC_SUBST(ns_appbindir)
4875 AC_SUBST(ns_appresdir)
4876 AC_SUBST(ns_appsrc)
4877 AC_SUBST(GNU_OBJC_CFLAGS)
4878 AC_SUBST(OTHER_FILES)
4879
4880 if test -n "${term_header}"; then
4881     AC_DEFINE_UNQUOTED(TERM_HEADER, "${term_header}",
4882         [Define to the header for the built-in window system.])
4883 fi
4884
4885 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
4886                    [Define to the canonical Emacs configuration name.])
4887 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${emacs_config_options}",
4888                    [Define to the options passed to configure.])
4889 AH_TEMPLATE(config_opsysfile, [Some platforms that do not use configure
4890   define this to include extra configuration information.])
4891
4892 case $opsys in
4893   mingw32)
4894     AC_DEFINE(config_opsysfile, <ms-w32.h>, [])
4895     ;;
4896 esac
4897
4898 XMENU_OBJ=
4899 XOBJ=
4900 FONT_OBJ=
4901 if test "${HAVE_X_WINDOWS}" = "yes" ; then
4902   AC_DEFINE(HAVE_X_WINDOWS, 1,
4903             [Define to 1 if you want to use the X window system.])
4904   XMENU_OBJ=xmenu.o
4905   XOBJ="xterm.o xfns.o xselect.o xrdb.o xsmfns.o xsettings.o"
4906   FONT_OBJ=xfont.o
4907   if test "$USE_CAIRO" = "yes"; then
4908     FONT_OBJ="ftfont.o ftcrfont.o"
4909   elif test "$HAVE_XFT" = "yes"; then
4910     FONT_OBJ="$FONT_OBJ ftfont.o xftfont.o ftxfont.o"
4911   elif test "$HAVE_FREETYPE" = "yes"; then
4912     FONT_OBJ="$FONT_OBJ ftfont.o ftxfont.o"
4913   fi
4914   AC_SUBST(FONT_OBJ)
4915 fi
4916 AC_SUBST(XMENU_OBJ)
4917 AC_SUBST(XOBJ)
4918 AC_SUBST(FONT_OBJ)
4919
4920 WIDGET_OBJ=
4921 MOTIF_LIBW=
4922 if test "${USE_X_TOOLKIT}" != "none" ; then
4923   WIDGET_OBJ=widget.o
4924   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
4925   if test "${USE_X_TOOLKIT}" = "LUCID"; then
4926     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
4927   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
4928     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
4929     MOTIF_LIBW=-lXm
4930     case "$opsys" in
4931       gnu-linux)
4932         ## Paul Abrahams <abrahams at equinox.shaysnet.com> says this is needed.
4933         MOTIF_LIBW="$MOTIF_LIBW -lXpm"
4934         ;;
4935
4936       unixware)
4937         ## Richard Anthony Ryan <ryanr at ellingtn.ftc.nrcs.usda.gov>
4938         ## says -lXimp is needed in UNIX_SV ... 4.2 1.1.2.
4939         MOTIF_LIBW="MOTIF_LIBW -lXimp"
4940         ;;
4941
4942       aix4-2)
4943         ## olson@mcs.anl.gov says -li18n is needed by -lXm.
4944         MOTIF_LIBW="$MOTIF_LIBW -li18n"
4945         ;;
4946     esac
4947     MOTIF_LIBW="$MOTIF_LIBW $LIBXP"
4948   fi
4949 fi
4950 AC_SUBST(WIDGET_OBJ)
4951
4952 TOOLKIT_LIBW=
4953 case "$USE_X_TOOLKIT" in
4954   MOTIF) TOOLKIT_LIBW="$MOTIF_LIBW" ;;
4955   LUCID) TOOLKIT_LIBW="$LUCID_LIBW" ;;
4956   none) test "x$HAVE_GTK" = "xyes" && TOOLKIT_LIBW="$GTK_LIBS" ;;
4957 esac
4958 AC_SUBST(TOOLKIT_LIBW)
4959
4960 if test "${opsys}" != "mingw32"; then
4961   if test "$USE_X_TOOLKIT" = "none"; then
4962     LIBXT_OTHER="\$(LIBXSM)"
4963   else
4964     LIBXT_OTHER="\$(LIBXMU) -lXt \$(LIBXTR6) -lXext"
4965   fi
4966 fi
4967 AC_SUBST(LIBXT_OTHER)
4968
4969 if test "${HAVE_X11}" = "yes" ; then
4970   AC_DEFINE(HAVE_X11, 1,
4971             [Define to 1 if you want to use version 11 of X windows.])
4972   LIBX_OTHER="\$(LIBXT) \$(LIBX_EXTRA)"
4973 else
4974   LIBX_OTHER=
4975 fi
4976 AC_SUBST(LIBX_OTHER)
4977
4978 if test "$HAVE_GTK" = yes || test "$HAVE_X11" != yes; then
4979   LIBXMENU=
4980 elif test "$USE_X_TOOLKIT" = none; then
4981   LIBXMENU='$(oldXMenudir)/libXMenu11.a'
4982 else
4983   LIBXMENU='$(lwlibdir)/liblw.a'
4984 fi
4985 AC_SUBST(LIBXMENU)
4986
4987 AC_CACHE_CHECK([for struct alignment],
4988   [emacs_cv_struct_alignment],
4989   [AC_COMPILE_IFELSE(
4990      [AC_LANG_PROGRAM([[#include <stddef.h>
4991                         struct __attribute__ ((aligned (8))) s { char c; };
4992                         struct t { char c; struct s s; };
4993                         char verify[offsetof (struct t, s) == 8 ? 1 : -1];
4994                       ]])],
4995      [emacs_cv_struct_alignment=yes],
4996      [emacs_cv_struct_alignment=no])])
4997 if test "$emacs_cv_struct_alignment" = yes; then
4998   AC_DEFINE([HAVE_STRUCT_ATTRIBUTE_ALIGNED], 1,
4999     [Define to 1 if 'struct __attribute__ ((aligned (N)))' aligns the
5000      structure to an N-byte boundary.])
5001 fi
5002
5003 if test "${GNU_MALLOC}" = "yes" ; then
5004   AC_DEFINE(GNU_MALLOC, 1,
5005             [Define to 1 if you want to use the GNU memory allocator.])
5006 fi
5007
5008 RALLOC_OBJ=
5009 if test "${REL_ALLOC}" = "yes" ; then
5010   AC_DEFINE(REL_ALLOC, 1,
5011             [Define REL_ALLOC if you want to use the relocating allocator for
5012              buffer space.])
5013
5014   test "$system_malloc" != "yes" && RALLOC_OBJ=ralloc.o
5015 fi
5016 AC_SUBST(RALLOC_OBJ)
5017
5018 if test "$opsys" = "cygwin"; then
5019   CYGWIN_OBJ="sheap.o cygw32.o"
5020   ## Cygwin differs because of its unexec().
5021   PRE_ALLOC_OBJ=
5022   POST_ALLOC_OBJ=lastfile.o
5023 elif test "$opsys" = "mingw32"; then
5024   CYGWIN_OBJ=
5025   PRE_ALLOC_OBJ=
5026   POST_ALLOC_OBJ=lastfile.o
5027 else
5028   CYGWIN_OBJ=
5029   PRE_ALLOC_OBJ=lastfile.o
5030   POST_ALLOC_OBJ=
5031 fi
5032 AC_SUBST(CYGWIN_OBJ)
5033 AC_SUBST(PRE_ALLOC_OBJ)
5034 AC_SUBST(POST_ALLOC_OBJ)
5035
5036 dnl Call this 'FORTIFY_SOUR' so that it sorts before the 'FORTIFY_SOURCE'
5037 dnl verbatim defined above.  The tricky name is apropos, as this hack
5038 dnl makes Fortify go sour!
5039 AH_VERBATIM([FORTIFY_SOUR],
5040 [/* Without the following workaround, Emacs runs slowly on OS X 10.8.
5041    The workaround disables some useful run-time checking, so it
5042    should be conditional to the platforms with the performance bug.
5043    Perhaps Apple will fix this some day; also see m4/extern-inline.m4.  */
5044 #if defined __APPLE__ && defined __GNUC__
5045 # ifndef _DONT_USE_CTYPE_INLINE_
5046 #  define _DONT_USE_CTYPE_INLINE_
5047 # endif
5048 # ifndef _FORTIFY_SOURCE
5049 #  define _FORTIFY_SOURCE 0
5050 # endif
5051 #endif
5052 ])
5053
5054 # If user asks to omit features, disable optional features that gnulib
5055 # might otherwise enable.
5056 if test "$with_features" = no && test "$enable_acl" != yes; then
5057   enable_acl=no
5058 fi
5059
5060 # Configure gnulib.  Although this does not affect CFLAGS or LIBS permanently.
5061 # it temporarily reverts them to their pre-pkg-config values,
5062 # because gnulib needs to work with both src (which uses the
5063 # pkg-config stuff) and lib-src (which does not).  For example, gnulib
5064 # may need to determine whether LIB_CLOCK_GETTIME should contain -lrt,
5065 # and it therefore needs to run in an environment where LIBS does not
5066 # already contain -lrt merely because 'pkg-config --libs' printed '-lrt'
5067 # for some package unrelated to lib-src.
5068 SAVE_CFLAGS=$CFLAGS
5069 SAVE_LIBS=$LIBS
5070 CFLAGS=$pre_PKG_CONFIG_CFLAGS
5071 LIBS="$LIB_PTHREAD $pre_PKG_CONFIG_LIBS"
5072 gl_ASSERT_NO_GNULIB_POSIXCHECK
5073 gl_ASSERT_NO_GNULIB_TESTS
5074 gl_INIT
5075 CFLAGS=$SAVE_CFLAGS
5076 LIBS=$SAVE_LIBS
5077
5078 if test "${opsys}" = "mingw32"; then
5079   CPPFLAGS="$CPPFLAGS -DUSE_CRT_DLL=1 -I \${abs_top_srcdir}/nt/inc"
5080   # Remove unneeded switches from the value of CC that goes to Makefiles
5081   CC=`AS_ECHO(["$CC"]) | sed -e "s,$GCC_TEST_OPTIONS,,"`
5082 fi
5083
5084 case "$opsys" in
5085   aix4-2) LD_SWITCH_SYSTEM_TEMACS="-Wl,-bnodelcsect" ;;
5086
5087   cygwin) LD_SWITCH_SYSTEM_TEMACS="-Wl,-stack,0x00800000" ;;
5088
5089   darwin)
5090    ## The -headerpad option tells ld (see man page) to leave room at the
5091    ## end of the header for adding load commands.  Needed for dumping.
5092    ## 0x1000 is enough for roughly 52 load commands on the x86_64
5093    ## architecture (where they are 78 bytes each). The actual number of
5094    ## load commands added is not consistent but normally ranges from
5095    ## about 14 to about 34. Setting it high gets us plenty of slop and
5096    ## only costs about 1.5K of wasted binary space.
5097    headerpad_extra=1000
5098    if test "$HAVE_NS" = "yes"; then
5099      libs_nsgui="-framework AppKit"
5100      if test "$NS_IMPL_COCOA" = "yes"; then
5101         libs_nsgui="$libs_nsgui -framework IOKit"
5102      fi
5103    else
5104      libs_nsgui=
5105    fi
5106    LD_SWITCH_SYSTEM_TEMACS="-fno-pie -prebind $libs_nsgui -Xlinker -headerpad -Xlinker $headerpad_extra"
5107
5108    ## This is here because src/Makefile.in did some extra fiddling around
5109    ## with LD_SWITCH_SYSTEM.  It seems cleaner to put this in
5110    ## LD_SWITCH_SYSTEM_TEMACS instead,
5111    test "x$LD_SWITCH_SYSTEM" = "x" && test "x$GCC" != "xyes" && \
5112      LD_SWITCH_SYSTEM_TEMACS="-X $LD_SWITCH_SYSTEM_TEMACS"
5113    ;;
5114
5115   ## LD_SWITCH_X_SITE_RPATH is a -rpath option saying where to
5116   ## find X at run-time.
5117   ## When handled by cpp, this was in LD_SWITCH_SYSTEM.  However, at the
5118   ## point where configure sourced the s/*.h file, LD_SWITCH_X_SITE_RPATH
5119   ## had not yet been defined and was expanded to null.  Hence LD_SWITCH_SYSTEM
5120   ## had different values in configure (in ac_link) and src/Makefile.in.
5121   ## It seems clearer therefore to put this piece in LD_SWITCH_SYSTEM_TEMACS.
5122   gnu*) LD_SWITCH_SYSTEM_TEMACS="\$(LD_SWITCH_X_SITE_RPATH)" ;;
5123
5124   mingw32)
5125    ## Is it any better under MinGW64 to relocate emacs into higher addresses?
5126    case "$canonical" in
5127      x86_64-*-*) LD_SWITCH_SYSTEM_TEMACS="-Wl,-stack,0x00800000 -Wl,-heap,0x00100000 -Wl,-image-base,0x400000000 -Wl,-entry,__start -Wl,-Map,./temacs.map" ;;
5128      *) LD_SWITCH_SYSTEM_TEMACS="-Wl,-stack,0x00800000 -Wl,-heap,0x00100000 -Wl,-image-base,0x01000000 -Wl,-entry,__start -Wl,-Map,./temacs.map" ;;
5129    esac
5130    ;;
5131
5132   *) LD_SWITCH_SYSTEM_TEMACS= ;;
5133 esac
5134
5135 # -nopie fixes a temacs segfault on Gentoo, OpenBSD, and other systems
5136 # with "hardened" GCC configurations for some reason (Bug#18784).
5137 # We don't know why -nopie works, but not segfaulting is better than
5138 # segfaulting.  Use ac_c_werror_flag=yes when trying -nopie, otherwise
5139 # clang keeps warning that it does not understand -nopie, and pre-4.6
5140 # GCC has a similar problem (Bug#20338).
5141 AC_CACHE_CHECK([whether $CC accepts -nopie],
5142   [emacs_cv_prog_cc_nopie],
5143   [emacs_save_c_werror_flag=$ac_c_werror_flag
5144    emacs_save_LDFLAGS=$LDFLAGS
5145    ac_c_werror_flag=yes
5146    LDFLAGS="$LDFLAGS -nopie"
5147    AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
5148      [emacs_cv_prog_cc_nopie=yes],
5149      [emacs_cv_prog_cc_nopie=no])
5150    ac_c_werror_flag=$emacs_save_c_werror_flag
5151    LDFLAGS=$emacs_save_LDFLAGS])
5152 if test "$emacs_cv_prog_cc_nopie" = yes; then
5153   LD_SWITCH_SYSTEM_TEMACS="$LD_SWITCH_SYSTEM_TEMACS -nopie"
5154 fi
5155
5156 if test x$ac_enable_profiling != x ; then
5157   case $opsys in
5158     *freebsd | gnu-linux) ;;
5159     *) LD_SWITCH_SYSTEM_TEMACS="$LD_SWITCH_SYSTEM_TEMACS -pg" ;;
5160   esac
5161 fi
5162
5163 LD_SWITCH_SYSTEM_TEMACS="$LDFLAGS_NOCOMBRELOC $LD_SWITCH_SYSTEM_TEMACS"
5164
5165 AC_SUBST(LD_SWITCH_SYSTEM_TEMACS)
5166
5167 ## Common for all window systems
5168 if test "$window_system" != "none"; then
5169   AC_DEFINE(HAVE_WINDOW_SYSTEM, 1, [Define if you have a window system.])
5170   AC_DEFINE(POLL_FOR_INPUT, 1, [Define if you poll periodically to detect C-g.])
5171   WINDOW_SYSTEM_OBJ="fontset.o fringe.o image.o"
5172 fi
5173
5174 AC_SUBST(WINDOW_SYSTEM_OBJ)
5175
5176 AH_TOP([/* GNU Emacs site configuration template file.
5177
5178 Copyright (C) 1988, 1993-1994, 1999-2002, 2004-2016
5179   Free Software Foundation, Inc.
5180
5181 This file is part of GNU Emacs.
5182
5183 GNU Emacs is free software: you can redistribute it and/or modify
5184 it under the terms of the GNU General Public License as published by
5185 the Free Software Foundation, either version 3 of the License, or
5186 (at your option) any later version.
5187
5188 GNU Emacs is distributed in the hope that it will be useful,
5189 but WITHOUT ANY WARRANTY; without even the implied warranty of
5190 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
5191 GNU General Public License for more details.
5192
5193 You should have received a copy of the GNU General Public License
5194 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
5195
5196
5197 /* No code in Emacs #includes config.h twice, but some bits of code
5198    intended to work with other packages as well (like gmalloc.c)
5199    think they can include it as many times as they like.  */
5200 #ifndef EMACS_CONFIG_H
5201 #define EMACS_CONFIG_H
5202 ])dnl
5203
5204 AH_BOTTOM([#include <conf_post.h>
5205
5206 #endif /* EMACS_CONFIG_H */
5207
5208 /*
5209 Local Variables:
5210 mode: c
5211 End:
5212 */
5213 ])dnl
5214
5215 #### Report on what we decided to do.
5216 #### Report GTK as a toolkit, even if it doesn't use Xt.
5217 #### It makes printing result more understandable as using GTK sets
5218 #### toolkit_scroll_bars to yes by default.
5219 if test "${HAVE_GTK}" = "yes"; then
5220   USE_X_TOOLKIT="$USE_GTK_TOOLKIT"
5221 fi
5222
5223 if test $USE_ACL -ne 0; then
5224   ACL_SUMMARY="yes $LIB_ACL"
5225 else
5226   ACL_SUMMARY=no
5227 fi
5228
5229 emacs_standard_dirs='Standard dirs'
5230 AS_ECHO(["
5231 Configured for '${canonical}'.
5232
5233   Where should the build process find the source code?    ${srcdir}
5234   What compiler should emacs be built with?               ${CC} ${CFLAGS}
5235   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
5236   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
5237   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
5238   What window system should Emacs use?                    ${window_system}
5239   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}
5240   Where do we find X Windows header files?                ${x_includes:-$emacs_standard_dirs}
5241   Where do we find X Windows libraries?                   ${x_libraries:-$emacs_standard_dirs}"])
5242
5243 optsep=
5244 emacs_config_features=
5245 for opt in XAW3D XPM JPEG TIFF GIF PNG RSVG CAIRO IMAGEMAGICK SOUND GPM DBUS \
5246   GCONF GSETTINGS NOTIFY ACL LIBSELINUX GNUTLS LIBXML2 FREETYPE M17N_FLT \
5247   LIBOTF XFT ZLIB TOOLKIT_SCROLL_BARS X_TOOLKIT X11 NS MODULES; do
5248
5249     case $opt in
5250       NOTIFY|ACL) eval val=\${${opt}_SUMMARY} ;;
5251       CAIRO|TOOLKIT_SCROLL_BARS|X_TOOLKIT) eval val=\${USE_$opt} ;;
5252       *) eval val=\${HAVE_$opt} ;;
5253     esac
5254     case x$val in
5255       xno|xnone|x) continue ;;
5256     esac
5257     case $opt in
5258       X_TOOLKIT)
5259         case $val in
5260           GTK*|LUCID|MOTIF) opt=$val ;;
5261           *) continue ;;
5262         esac
5263       ;;
5264     esac
5265     AS_VAR_APPEND([emacs_config_features], ["$optsep$opt"])
5266     optsep=' '
5267 done
5268 AC_DEFINE_UNQUOTED(EMACS_CONFIG_FEATURES, "${emacs_config_features}",
5269   [Summary of some of the main features enabled by configure.])
5270
5271 AS_ECHO(["  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}
5272   Does Emacs use -lXpm?                                   ${HAVE_XPM}
5273   Does Emacs use -ljpeg?                                  ${HAVE_JPEG}
5274   Does Emacs use -ltiff?                                  ${HAVE_TIFF}
5275   Does Emacs use a gif library?                           ${HAVE_GIF} $LIBGIF
5276   Does Emacs use a png library?                           ${HAVE_PNG} $LIBPNG
5277   Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}
5278   Does Emacs use cairo?                                   ${USE_CAIRO}
5279   Does Emacs use imagemagick?                             ${HAVE_IMAGEMAGICK}
5280   Does Emacs support sound?                               ${HAVE_SOUND}
5281   Does Emacs use -lgpm?                                   ${HAVE_GPM}
5282   Does Emacs use -ldbus?                                  ${HAVE_DBUS}
5283   Does Emacs use -lgconf?                                 ${HAVE_GCONF}
5284   Does Emacs use GSettings?                               ${HAVE_GSETTINGS}
5285   Does Emacs use a file notification library?             ${NOTIFY_SUMMARY}
5286   Does Emacs use access control lists?                    ${ACL_SUMMARY}
5287   Does Emacs use -lselinux?                               ${HAVE_LIBSELINUX}
5288   Does Emacs use -lgnutls?                                ${HAVE_GNUTLS}
5289   Does Emacs use -lxml2?                                  ${HAVE_LIBXML2}
5290   Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}
5291   Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}
5292   Does Emacs use -lotf?                                   ${HAVE_LIBOTF}
5293   Does Emacs use -lxft?                                   ${HAVE_XFT}
5294   Does Emacs directly use zlib?                           ${HAVE_ZLIB}
5295   Does Emacs have dynamic modules support?                ${HAVE_MODULES}
5296   Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}
5297 "])
5298
5299 if test -n "${EMACSDATA}"; then
5300    AS_ECHO(["  Environment variable EMACSDATA set to:                  $EMACSDATA"])
5301 fi
5302 if test -n "${EMACSDOC}"; then
5303    AS_ECHO(["  Environment variable EMACSDOC set to:                   $EMACSDOC"])
5304 fi
5305
5306 echo
5307
5308 if test "$HAVE_NS" = "yes"; then
5309    echo
5310    AS_ECHO(["You must run \"${MAKE-make} install\" in order to test the built application.
5311 The installed application will go to nextstep/Emacs.app and can be
5312 run or moved from there."])
5313    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
5314       echo "The application will be fully self-contained."
5315     else
5316       AS_ECHO(["The lisp resources for the application will be installed under ${prefix}.
5317 You may need to run \"${MAKE-make} install\" with sudo.  The application will fail
5318 to run if these resources are not installed."])
5319    fi
5320    echo
5321 fi
5322
5323 if test "${opsys}" = "cygwin"; then
5324   case `uname -r` in
5325     1.5.*) AC_MSG_WARN([[building Emacs on Cygwin 1.5 is not supported.]])
5326            echo
5327            ;;
5328   esac
5329 fi
5330
5331 # Remove any trailing slashes in these variables.
5332 case $prefix in
5333   */) prefix=`AS_DIRNAME(["$prefix."])`;;
5334 esac
5335 case $exec_prefix in
5336   */) exec_prefix=`AS_DIRNAME(["$exec_prefix."])`;;
5337 esac
5338
5339 if test "$HAVE_NS" = "yes"; then
5340   if test "$NS_IMPL_GNUSTEP" = yes; then
5341     AC_CONFIG_FILES([nextstep/GNUstep/Emacs.base/Resources/Info-gnustep.plist:nextstep/templates/Info-gnustep.plist.in \
5342       nextstep/GNUstep/Emacs.base/Resources/Emacs.desktop:nextstep/templates/Emacs.desktop.in])
5343     ns_check_file=Resources/Info-gnustep.plist
5344   else
5345     AC_CONFIG_FILES([nextstep/Cocoa/Emacs.base/Contents/Info.plist:nextstep/templates/Info.plist.in \
5346       nextstep/Cocoa/Emacs.base/Contents/Resources/English.lproj/InfoPlist.strings:nextstep/templates/InfoPlist.strings.in])
5347     ns_check_file=Contents/Info.plist
5348   fi
5349   AC_SUBST(ns_check_file)
5350 fi
5351
5352 dnl config.status treats $srcdir specially, so I think this is ok...
5353 AC_CONFIG_FILES([$srcdir/doc/man/emacs.1])
5354
5355 dnl Obviously there is duplication here wrt $SUBDIR_MAKEFILES.
5356 dnl You _can_ use that variable in AC_CONFIG_FILES, so long as any directory
5357 dnl using automake (ie lib/) is explicitly listed and not "hidden" in a variable
5358 dnl (else you get "no 'Makefile.am' found for any configure output").
5359 dnl This will work, but you get a config.status that is not quite right
5360 dnl (see http://lists.gnu.org/archive/html/bug-autoconf/2008-08/msg00028.html).
5361 dnl That doesn't have any obvious consequences for Emacs, but on the whole
5362 dnl it seems better to just live with the duplication.
5363 SUBDIR_MAKEFILES="lib/Makefile lib-src/Makefile oldXMenu/Makefile doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile leim/Makefile nextstep/Makefile nt/Makefile"
5364
5365 AC_CONFIG_FILES([Makefile lib/Makefile lib-src/Makefile oldXMenu/Makefile \
5366        doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
5367        doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile \
5368        leim/Makefile nextstep/Makefile nt/Makefile])
5369
5370 dnl test/ is not present in release tarfiles.
5371 opt_makefile=test/Makefile
5372
5373 if test -f "$srcdir/$opt_makefile.in"; then
5374   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES $opt_makefile"
5375   dnl Again, it's best not to use a variable.  Though you can add
5376   dnl ", [], [opt_makefile='$opt_makefile']" and it should work.
5377   AC_CONFIG_FILES([test/Makefile])
5378 fi
5379
5380
5381 dnl The admin/ directory used to be excluded from tarfiles.
5382 if test -d $srcdir/admin; then
5383   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES admin/charsets/Makefile admin/unidata/Makefile admin/grammars/Makefile"
5384   AC_CONFIG_FILES([admin/charsets/Makefile])
5385   AC_CONFIG_FILES([admin/unidata/Makefile])
5386   AC_CONFIG_FILES([admin/grammars/Makefile])
5387 fi                              dnl -d admin
5388
5389
5390 SUBDIR_MAKEFILES_IN=`echo " ${SUBDIR_MAKEFILES}" | sed -e 's| | $(srcdir)/|g' -e 's|Makefile|Makefile.in|g'`
5391
5392 AC_SUBST(SUBDIR_MAKEFILES_IN)
5393
5394 dnl You might wonder (I did) why epaths.h is generated by running make,
5395 dnl rather than just letting configure generate it from epaths.in.
5396 dnl One reason is that the various paths are not fully expanded (see above);
5397 dnl eg gamedir=${prefix}/var/games/emacs.
5398 dnl Secondly, the GNU Coding standards require that one should be able
5399 dnl to run 'make prefix=/some/where/else' and override the values set
5400 dnl by configure.  This also explains the 'move-if-change' test and
5401 dnl the use of force in the 'epaths-force' rule in Makefile.in.
5402 AC_CONFIG_COMMANDS([src/epaths.h], [
5403 if test "${opsys}" = "mingw32"; then
5404   ${MAKE-make} MAKEFILE_NAME=do-not-make-Makefile epaths-force-w32
5405 else
5406   ${MAKE-make} MAKEFILE_NAME=do-not-make-Makefile epaths-force
5407 fi || AC_MSG_ERROR(['src/epaths.h' could not be made.])
5408 ], [GCC="$GCC" CPPFLAGS="$CPPFLAGS" opsys="$opsys"])
5409
5410 dnl NB we have to cheat and use the ac_... version because abs_top_srcdir
5411 dnl is not yet set, sigh.  Or we could use ../$srcdir/src/.gdbinit,
5412 dnl or a symlink?
5413 AC_CONFIG_COMMANDS([src/.gdbinit], [
5414 if test ! -f src/.gdbinit && test -f "$srcdir/src/.gdbinit"; then
5415   AS_ECHO(["source $ac_abs_top_srcdir/src/.gdbinit"]) > src/.gdbinit
5416 fi
5417 ])
5418
5419 dnl Perhaps this would be better named doc-emacs-emacsver.texi?
5420 dnl See comments for etc-refcards-emacsver.tex.
5421 dnl Since we get a doc/emacs directory generated anyway, for the Makefile,
5422 dnl it is not quite the same.  But we are generating in $srcdir.
5423 AC_CONFIG_COMMANDS([doc/emacs/emacsver.texi], [
5424 ${MAKE-make} -s --no-print-directory -C doc/emacs doc-emacsver || \
5425 AC_MSG_ERROR(['doc/emacs/emacsver.texi' could not be made.])
5426 ])
5427
5428 dnl If we give this the more natural name, etc/refcards/emacsver.texi,
5429 dnl then a directory etc/refcards is created in the build directory,
5430 dnl which is probably harmless, but confusing (in out-of-tree builds).
5431 dnl (If we were to generate etc/refcards/Makefile, this might change.)
5432 dnl It is really $srcdir/etc/refcards/emacsver.tex that we generate.
5433 AC_CONFIG_COMMANDS([etc-refcards-emacsver.tex], [
5434 ${MAKE-make} -s MAKEFILE_NAME=do-not-make-Makefile etc-emacsver || \
5435 AC_MSG_ERROR(['etc/refcards/emacsver.tex' could not be made.])
5436 ])
5437
5438 AC_OUTPUT
5439
5440 test "$MAKE" = make || AC_MSG_NOTICE([Now you can run '$MAKE'.])