code.delx.au - gnu-emacs/blob - lisp/cmuscheme.el

   1 ;;; cmuscheme.el --- Scheme process in a buffer. Adapted from tea.el
   2
   3 ;; Copyright (C) 1988, 1994, 1997, 2002, 2003, 2004,
   4 ;;   2005, 2006 Free Software Foundation, Inc.
   5
   6 ;; Author: Olin Shivers <olin.shivers@cs.cmu.edu>
   7 ;; Maintainer: FSF
   8 ;; Keywords: processes, lisp
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  25 ;; Boston, MA 02110-1301, USA.
  26
  27 ;;; Commentary:
  28
  29 ;;    This is a customization of comint-mode (see comint.el)
  30 ;;
  31 ;; Written by Olin Shivers (olin.shivers@cs.cmu.edu). With bits and pieces
  32 ;; lifted from scheme.el, shell.el, clisp.el, newclisp.el, cobol.el, et al..
  33 ;; 8/88
  34 ;;
  35 ;; Please send me bug reports, bug fixes, and extensions, so that I can
  36 ;; merge them into the master source.
  37 ;;
  38 ;; The changelog is at the end of this file.
  39 ;;
  40 ;; NOTE: MIT Cscheme, when invoked with the -emacs flag, has a special user
  41 ;; interface that communicates process state back to the superior emacs by
  42 ;; outputting special control sequences. The gnumacs package, xscheme.el, has
  43 ;; lots and lots of special purpose code to read these control sequences, and
  44 ;; so is very tightly integrated with the cscheme process. The cscheme
  45 ;; interrupt handler and debugger read single character commands in cbreak
  46 ;; mode; when this happens, xscheme.el switches to special keymaps that bind
  47 ;; the single letter command keys to emacs functions that directly send the
  48 ;; character to the scheme process.  Cmuscheme mode does *not* provide this
  49 ;; functionality. If you are a cscheme user, you may prefer to use the
  50 ;; xscheme.el/cscheme -emacs interaction.
  51 ;;
  52 ;; Here's a summary of the pros and cons, as I see them.
  53 ;; xscheme: Tightly integrated with inferior cscheme process!  A few commands
  54 ;;           not in cmuscheme. But. Integration is a bit of a hack.  Input
  55 ;;           history only keeps the immediately prior input. Bizarre
  56 ;;           keybindings.
  57 ;;
  58 ;; cmuscheme: Not tightly integrated with inferior cscheme process.  But.
  59 ;;            Carefully integrated functionality with the entire suite of
  60 ;;            comint-derived CMU process modes. Keybindings reminiscent of
  61 ;;            Zwei and Hemlock. Good input history. A few commands not in
  62 ;;            xscheme.
  63 ;;
  64 ;; It's a tradeoff. Pay your money; take your choice. If you use a Scheme
  65 ;; that isn't Cscheme, of course, there isn't a choice. Xscheme.el is *very*
  66 ;; Cscheme-specific; you must use cmuscheme.el.  Interested parties are
  67 ;; invited to port xscheme functionality on top of comint mode...
  68
  69 ;;; CHANGE LOG
  70 ;;; ===========================================================================
  71 ;;; 8/88 Olin
  72 ;;; Created.
  73 ;;;
  74 ;;; 2/15/89 Olin
  75 ;;; Removed -emacs flag from process invocation. It's only useful for
  76 ;;; cscheme, and makes cscheme assume it's running under xscheme.el,
  77 ;;; which messes things up royally. A bug.
  78 ;;;
  79 ;;; 5/22/90 Olin
  80 ;;; - Upgraded to use comint-send-string and comint-send-region.
  81 ;;; - run-scheme now offers to let you edit the command line if
  82 ;;;   you invoke it with a prefix-arg. M-x scheme is redundant, and
  83 ;;;   has been removed.
  84 ;;; - Explicit references to process "scheme" have been replaced with
  85 ;;;   (scheme-proc). This allows better handling of multiple process bufs.
  86 ;;; - Added scheme-send-last-sexp, bound to C-x C-e. A gnu convention.
  87 ;;; - Have not added process query facility a la cmulisp.el's lisp-show-arglist
  88 ;;;   and friends, but interested hackers might find a useful application
  89 ;;;   of this facility.
  90 ;;;
  91 ;;; 3/12/90 Olin
  92 ;;; - scheme-load-file and scheme-compile-file no longer switch-to-scheme.
  93 ;;;   Tale suggested this.
  94
  95 ;;; Code:
  96
  97 (require 'scheme)
  98 (require 'comint)
  99
 100
 101 (defgroup cmuscheme nil
 102   "Run a scheme process in a buffer."
 103   :group 'scheme)
 104
 105 ;;; INFERIOR SCHEME MODE STUFF
 106 ;;;============================================================================
 107
 108 (defcustom inferior-scheme-mode-hook nil
 109   "*Hook for customizing inferior-scheme mode."
 110   :type 'hook
 111   :group 'cmuscheme)
 112
 113 (defvar inferior-scheme-mode-map
 114   (let ((m (make-sparse-keymap)))
 115     (define-key m "\M-\C-x" 'scheme-send-definition) ;gnu convention
 116     (define-key m "\C-x\C-e" 'scheme-send-last-sexp)
 117     (define-key m "\C-c\C-l" 'scheme-load-file)
 118     (define-key m "\C-c\C-k" 'scheme-compile-file)
 119     (scheme-mode-commands m)
 120     m))
 121
 122 ;; Install the process communication commands in the scheme-mode keymap.
 123 (define-key scheme-mode-map "\M-\C-x" 'scheme-send-definition);gnu convention
 124 (define-key scheme-mode-map "\C-x\C-e" 'scheme-send-last-sexp);gnu convention
 125 (define-key scheme-mode-map "\C-c\C-e" 'scheme-send-definition)
 126 (define-key scheme-mode-map "\C-c\M-e" 'scheme-send-definition-and-go)
 127 (define-key scheme-mode-map "\C-c\C-r" 'scheme-send-region)
 128 (define-key scheme-mode-map "\C-c\M-r" 'scheme-send-region-and-go)
 129 (define-key scheme-mode-map "\C-c\M-c" 'scheme-compile-definition)
 130 (define-key scheme-mode-map "\C-c\C-c" 'scheme-compile-definition-and-go)
 131 (define-key scheme-mode-map "\C-c\C-t" 'scheme-trace-procedure)
 132 (define-key scheme-mode-map "\C-c\C-x" 'scheme-expand-current-form)
 133 (define-key scheme-mode-map "\C-c\C-z" 'switch-to-scheme)
 134 (define-key scheme-mode-map "\C-c\C-l" 'scheme-load-file)
 135 (define-key scheme-mode-map "\C-c\C-k" 'scheme-compile-file) ;k for "kompile"
 136
 137 (let ((map (lookup-key scheme-mode-map [menu-bar scheme])))
 138   (define-key map [separator-eval] '("--"))
 139   (define-key map [compile-file]
 140     '("Compile Scheme File" . scheme-compile-file))
 141   (define-key map [load-file]
 142     '("Load Scheme File" . scheme-load-file))
 143   (define-key map [switch]
 144     '("Switch to Scheme" . switch-to-scheme))
 145   (define-key map [com-def-go]
 146     '("Compile Definition & Go" . scheme-compile-definition-and-go))
 147   (define-key map [com-def]
 148     '("Compile Definition" . scheme-compile-definition))
 149   (define-key map [exp-form]
 150     '("Expand current form" . scheme-expand-current-form))
 151   (define-key map [trace-proc]
 152     '("Trace procedure" . scheme-trace-procedure))
 153   (define-key map [send-def-go]
 154     '("Evaluate Last Definition & Go" . scheme-send-definition-and-go))
 155   (define-key map [send-def]
 156     '("Evaluate Last Definition" . scheme-send-definition))
 157   (define-key map [send-region-go]
 158     '("Evaluate Region & Go" . scheme-send-region-and-go))
 159   (define-key map [send-region]
 160     '("Evaluate Region" . scheme-send-region))
 161   (define-key map [send-sexp]
 162     '("Evaluate Last S-expression" . scheme-send-last-sexp))
 163   )
 164
 165 (defvar scheme-buffer)
 166
 167 (define-derived-mode inferior-scheme-mode comint-mode "Inferior Scheme"
 168   "Major mode for interacting with an inferior Scheme process.
 169
 170 The following commands are available:
 171 \\{inferior-scheme-mode-map}
 172
 173 A Scheme process can be fired up with M-x run-scheme.
 174
 175 Customization: Entry to this mode runs the hooks on comint-mode-hook and
 176 inferior-scheme-mode-hook (in that order).
 177
 178 You can send text to the inferior Scheme process from other buffers containing
 179 Scheme source.
 180     switch-to-scheme switches the current buffer to the Scheme process buffer.
 181     scheme-send-definition sends the current definition to the Scheme process.
 182     scheme-compile-definition compiles the current definition.
 183     scheme-send-region sends the current region to the Scheme process.
 184     scheme-compile-region compiles the current region.
 185
 186     scheme-send-definition-and-go, scheme-compile-definition-and-go,
 187         scheme-send-region-and-go, and scheme-compile-region-and-go
 188         switch to the Scheme process buffer after sending their text.
 189 For information on running multiple processes in multiple buffers, see
 190 documentation for variable scheme-buffer.
 191
 192 Commands:
 193 Return after the end of the process' output sends the text from the
 194     end of process to point.
 195 Return before the end of the process' output copies the sexp ending at point
 196     to the end of the process' output, and sends it.
 197 Delete converts tabs to spaces as it moves back.
 198 Tab indents for Scheme; with argument, shifts rest
 199     of expression rigidly with the current line.
 200 C-M-q does Tab on each line starting within following expression.
 201 Paragraphs are separated only by blank lines.  Semicolons start comments.
 202 If you accidentally suspend your process, use \\[comint-continue-subjob]
 203 to continue it."
 204   ;; Customize in inferior-scheme-mode-hook
 205   (setq comint-prompt-regexp "^[^>\n]*>+ *") ; OK for cscheme, oaklisp, T,...
 206   (scheme-mode-variables)
 207   (setq mode-line-process '(":%s"))
 208   (setq comint-input-filter (function scheme-input-filter))
 209   (setq comint-get-old-input (function scheme-get-old-input)))
 210
 211 (defcustom inferior-scheme-filter-regexp "\\`\\s *\\S ?\\S ?\\s *\\'"
 212   "*Input matching this regexp are not saved on the history list.
 213 Defaults to a regexp ignoring all inputs of 0, 1, or 2 letters."
 214   :type 'regexp
 215   :group 'cmuscheme)
 216
 217 (defun scheme-input-filter (str)
 218   "Don't save anything matching `inferior-scheme-filter-regexp'."
 219   (not (string-match inferior-scheme-filter-regexp str)))
 220
 221 (defun scheme-get-old-input ()
 222   "Snarf the sexp ending at point."
 223   (save-excursion
 224     (let ((end (point)))
 225       (backward-sexp)
 226       (buffer-substring (point) end))))
 227
 228 (defun scheme-args-to-list (string)
 229   (let ((where (string-match "[ \t]" string)))
 230     (cond ((null where) (list string))
 231           ((not (= where 0))
 232            (cons (substring string 0 where)
 233                  (scheme-args-to-list (substring string (+ 1 where)
 234                                                  (length string)))))
 235           (t (let ((pos (string-match "[^ \t]" string)))
 236                (if (null pos)
 237                    nil
 238                  (scheme-args-to-list (substring string pos
 239                                                  (length string)))))))))
 240
 241 ;;;###autoload
 242 (defun run-scheme (cmd)
 243   "Run an inferior Scheme process, input and output via buffer `*scheme*'.
 244 If there is a process already running in `*scheme*', switch to that buffer.
 245 With argument, allows you to edit the command line (default is value
 246 of `scheme-program-name').
 247 If a file `~/.emacs_SCHEMENAME' exists, it is given as initial input.
 248 Note that this may lose due to a timing error if the Scheme processor
 249 discards input when it starts up.
 250 Runs the hook `inferior-scheme-mode-hook' \(after the `comint-mode-hook'
 251 is run).
 252 \(Type \\[describe-mode] in the process buffer for a list of commands.)"
 253
 254   (interactive (list (if current-prefix-arg
 255                          (read-string "Run Scheme: " scheme-program-name)
 256                          scheme-program-name)))
 257   (if (not (comint-check-proc "*scheme*"))
 258       (let ((cmdlist (scheme-args-to-list cmd)))
 259         (set-buffer (apply 'make-comint "scheme" (car cmdlist)
 260                            (scheme-start-file (car cmdlist)) (cdr cmdlist)))
 261         (inferior-scheme-mode)))
 262   (setq scheme-program-name cmd)
 263   (setq scheme-buffer "*scheme*")
 264   (pop-to-buffer "*scheme*"))
 265 ;;;###autoload (add-hook 'same-window-buffer-names "*scheme*")
 266
 267 (defun scheme-start-file (prog)
 268   "Return the name of the start file corresponding to PROG.
 269 Search in the directories \"~\" and \"~/.emacs.d\", in this
 270 order.  Return nil if no start file found."
 271   (let* ((name (concat ".emacs_" (file-name-nondirectory prog)))
 272          (start-file (concat "~/" name)))
 273     (if (file-exists-p start-file)
 274         start-file
 275       (let ((start-file (concat "~/.emacs.d/" name)))
 276         (and (file-exists-p start-file) start-file)))))
 277
 278 (defun scheme-send-region (start end)
 279   "Send the current region to the inferior Scheme process."
 280   (interactive "r")
 281   (comint-send-region (scheme-proc) start end)
 282   (comint-send-string (scheme-proc) "\n"))
 283
 284 (defun scheme-send-definition ()
 285   "Send the current definition to the inferior Scheme process."
 286   (interactive)
 287   (save-excursion
 288    (end-of-defun)
 289    (let ((end (point)))
 290      (beginning-of-defun)
 291      (scheme-send-region (point) end))))
 292
 293 (defun scheme-send-last-sexp ()
 294   "Send the previous sexp to the inferior Scheme process."
 295   (interactive)
 296   (scheme-send-region (save-excursion (backward-sexp) (point)) (point)))
 297
 298 (defcustom scheme-compile-exp-command "(compile '%s)"
 299   "*Template for issuing commands to compile arbitrary Scheme expressions."
 300   :type 'string
 301   :group 'cmuscheme)
 302
 303 (defun scheme-compile-region (start end)
 304   "Compile the current region in the inferior Scheme process.
 305 \(A BEGIN is wrapped around the region: (BEGIN <region>))"
 306   (interactive "r")
 307   (comint-send-string (scheme-proc) (format scheme-compile-exp-command
 308                                             (format "(begin %s)"
 309                                                     (buffer-substring start end))))
 310   (comint-send-string (scheme-proc) "\n"))
 311
 312 (defun scheme-compile-definition ()
 313   "Compile the current definition in the inferior Scheme process."
 314   (interactive)
 315   (save-excursion
 316    (end-of-defun)
 317    (let ((end (point)))
 318      (beginning-of-defun)
 319      (scheme-compile-region (point) end))))
 320
 321 (defcustom scheme-trace-command "(trace %s)"
 322   "*Template for issuing commands to trace a Scheme procedure.
 323 Some Scheme implementations might require more elaborate commands here.
 324 For PLT-Scheme, e.g., one should use
 325
 326    (setq scheme-trace-command \"(begin (require (lib \\\"trace.ss\\\")) (trace %s))\")
 327
 328 For Scheme 48 and Scsh use \",trace %s\"."
 329   :type 'string
 330   :group 'cmuscheme)
 331
 332 (defcustom scheme-untrace-command "(untrace %s)"
 333   "*Template for switching off tracing of a Scheme procedure.
 334 Scheme 48 and Scsh users should set this variable to \",untrace %s\"."
 335
 336   :type 'string
 337   :group 'cmuscheme)
 338
 339 (defun scheme-trace-procedure (proc &optional untrace)
 340   "Trace procedure PROC in the inferior Scheme process.
 341 With a prefix argument switch off tracing of procedure PROC."
 342   (interactive
 343    (list (let ((current (symbol-at-point))
 344                (action (if current-prefix-arg "Untrace" "Trace")))
 345            (if current
 346                (read-string (format "%s procedure [%s]: " action current) nil nil (symbol-name current))
 347              (read-string (format "%s procedure: " action))))
 348          current-prefix-arg))
 349   (when (= (length proc) 0)
 350     (error "Invalid procedure name"))
 351   (comint-send-string (scheme-proc)
 352                       (format
 353                        (if untrace scheme-untrace-command scheme-trace-command)
 354                        proc))
 355   (comint-send-string (scheme-proc) "\n"))
 356
 357 (defcustom scheme-macro-expand-command "(expand %s)"
 358   "*Template for macro-expanding a Scheme form.
 359 For Scheme 48 and Scsh use \",expand %s\"."
 360   :type 'string
 361   :group 'cmuscheme)
 362
 363 (defun scheme-expand-current-form ()
 364   "Macro-expand the form at point in the inferior Scheme process."
 365   (interactive)
 366   (let ((current-form (scheme-form-at-point)))
 367     (if current-form
 368         (progn
 369           (comint-send-string (scheme-proc)
 370                               (format
 371                                scheme-macro-expand-command
 372                                current-form))
 373           (comint-send-string (scheme-proc) "\n"))
 374       (error "Not at a form"))))
 375
 376 (defun scheme-form-at-point ()
 377   (let ((next-sexp (thing-at-point 'sexp)))
 378     (if (and next-sexp (string-equal (substring next-sexp 0 1) "("))
 379         next-sexp
 380       (save-excursion
 381         (backward-up-list)
 382         (scheme-form-at-point)))))
 383
 384 (defun switch-to-scheme (eob-p)
 385   "Switch to the scheme process buffer.
 386 With argument, position cursor at end of buffer."
 387   (interactive "P")
 388   (if (or (and scheme-buffer (get-buffer scheme-buffer))
 389           (scheme-interactively-start-process))
 390       (pop-to-buffer scheme-buffer)
 391     (error "No current process buffer.  See variable `scheme-buffer'"))
 392   (when eob-p
 393     (push-mark)
 394     (goto-char (point-max))))
 395
 396 (defun scheme-send-region-and-go (start end)
 397   "Send the current region to the inferior Scheme process.
 398 Then switch to the process buffer."
 399   (interactive "r")
 400   (scheme-send-region start end)
 401   (switch-to-scheme t))
 402
 403 (defun scheme-send-definition-and-go ()
 404   "Send the current definition to the inferior Scheme.
 405 Then switch to the process buffer."
 406   (interactive)
 407   (scheme-send-definition)
 408   (switch-to-scheme t))
 409
 410 (defun scheme-compile-definition-and-go ()
 411   "Compile the current definition in the inferior Scheme.
 412 Then switch to the process buffer."
 413   (interactive)
 414   (scheme-compile-definition)
 415   (switch-to-scheme t))
 416
 417 (defun scheme-compile-region-and-go (start end)
 418   "Compile the current region in the inferior Scheme.
 419 Then switch to the process buffer."
 420   (interactive "r")
 421   (scheme-compile-region start end)
 422   (switch-to-scheme t))
 423
 424 (defcustom scheme-source-modes '(scheme-mode)
 425   "*Used to determine if a buffer contains Scheme source code.
 426 If it's loaded into a buffer that is in one of these major modes, it's
 427 considered a scheme source file by `scheme-load-file' and `scheme-compile-file'.
 428 Used by these commands to determine defaults."
 429   :type '(repeat function)
 430   :group 'cmuscheme)
 431
 432 (defvar scheme-prev-l/c-dir/file nil
 433   "Caches the last (directory . file) pair.
 434 Caches the last pair used in the last `scheme-load-file' or
 435 `scheme-compile-file' command.  Used for determining the default
 436 in the next one.")
 437
 438 (defun scheme-load-file (file-name)
 439   "Load a Scheme file FILE-NAME into the inferior Scheme process."
 440   (interactive (comint-get-source "Load Scheme file: " scheme-prev-l/c-dir/file
 441                                   scheme-source-modes t)) ; t because `load'
 442                                                           ; needs an exact name
 443   (comint-check-source file-name) ; Check to see if buffer needs saved.
 444   (setq scheme-prev-l/c-dir/file (cons (file-name-directory    file-name)
 445                                        (file-name-nondirectory file-name)))
 446   (comint-send-string (scheme-proc) (concat "(load \""
 447                                             file-name
 448                                             "\"\)\n")))
 449
 450 (defun scheme-compile-file (file-name)
 451   "Compile a Scheme file FILE-NAME in the inferior Scheme process."
 452   (interactive (comint-get-source "Compile Scheme file: "
 453                                   scheme-prev-l/c-dir/file
 454                                   scheme-source-modes
 455                                   nil)) ; nil because COMPILE doesn't
 456                                         ; need an exact name.
 457   (comint-check-source file-name) ; Check to see if buffer needs saved.
 458   (setq scheme-prev-l/c-dir/file (cons (file-name-directory    file-name)
 459                                        (file-name-nondirectory file-name)))
 460   (comint-send-string (scheme-proc) (concat "(compile-file \""
 461                                             file-name
 462                                             "\"\)\n")))
 463
 464 \f
 465 (defvar scheme-buffer nil "*The current scheme process buffer.
 466
 467 MULTIPLE PROCESS SUPPORT
 468 ===========================================================================
 469 Cmuscheme.el supports, in a fairly simple fashion, running multiple Scheme
 470 processes.  To run multiple Scheme processes, you start the first up with
 471 \\[run-scheme].  It will be in a buffer named *scheme*.  Rename this buffer
 472 with \\[rename-buffer].  You may now start up a new process with another
 473 \\[run-scheme].  It will be in a new buffer, named *scheme*.  You can
 474 switch between the different process buffers with \\[switch-to-buffer].
 475
 476 Commands that send text from source buffers to Scheme processes --
 477 like `scheme-send-definition' or `scheme-compile-region' -- have to choose a
 478 process to send to, when you have more than one Scheme process around.  This
 479 is determined by the global variable `scheme-buffer'.  Suppose you
 480 have three inferior Schemes running:
 481     Buffer      Process
 482     foo         scheme
 483     bar         scheme<2>
 484     *scheme*    scheme<3>
 485 If you do a \\[scheme-send-definition-and-go] command on some Scheme source
 486 code, what process do you send it to?
 487
 488 - If you're in a process buffer (foo, bar, or *scheme*),
 489   you send it to that process.
 490 - If you're in some other buffer (e.g., a source file), you
 491   send it to the process attached to buffer `scheme-buffer'.
 492 This process selection is performed by function `scheme-proc'.
 493
 494 Whenever \\[run-scheme] fires up a new process, it resets `scheme-buffer'
 495 to be the new process's buffer.  If you only run one process, this will
 496 do the right thing.  If you run multiple processes, you can change
 497 `scheme-buffer' to another process buffer with \\[set-variable].
 498
 499 More sophisticated approaches are, of course, possible.  If you find yourself
 500 needing to switch back and forth between multiple processes frequently,
 501 you may wish to consider ilisp.el, a larger, more sophisticated package
 502 for running inferior Lisp and Scheme processes.  The approach taken here is
 503 for a minimal, simple implementation.  Feel free to extend it.")
 504
 505 (defun scheme-proc ()
 506   "Return the current Scheme process, starting one if necessary.
 507 See variable `scheme-buffer'."
 508   (unless (and scheme-buffer
 509                (get-buffer scheme-buffer)
 510                (comint-check-proc scheme-buffer))
 511     (scheme-interactively-start-process))
 512   (or (scheme-get-process)
 513       (error "No current process.  See variable `scheme-buffer'")))
 514
 515 (defun scheme-get-process ()
 516   "Return the current Scheme process or nil if none is running."
 517   (get-buffer-process (if (eq major-mode 'inferior-scheme-mode)
 518                           (current-buffer)
 519                         scheme-buffer)))
 520
 521 (defun scheme-interactively-start-process (&optional cmd)
 522   "Start an inferior Scheme process.  Return the process started.
 523 Since this command is run implicitly, always ask the user for the
 524 command to run."
 525   (save-window-excursion
 526     (run-scheme (read-string "Run Scheme: " scheme-program-name))))
 527
 528 ;;; Do the user's customization...
 529
 530 (defcustom cmuscheme-load-hook nil
 531   "This hook is run when cmuscheme is loaded in.
 532 This is a good place to put keybindings."
 533   :type 'hook
 534   :group 'cmuscheme)
 535
 536 (run-hooks 'cmuscheme-load-hook)
 537
 538 (provide 'cmuscheme)
 539
 540 ;; arch-tag: e8795f4a-c496-45a2-97b4-8e0f2a2c57d2
 541 ;;; cmuscheme.el ends here