code.delx.au - gnu-emacs/blob - lisp/vc/vc-hg.el

   1 ;;; vc-hg.el --- VC backend for the mercurial version control system  -*- lexical-binding: t -*-
   2
   3 ;; Copyright (C) 2006-2015 Free Software Foundation, Inc.
   4
   5 ;; Author: Ivan Kanis
   6 ;; Maintainer: emacs-devel@gnu.org
   7 ;; Keywords: vc tools
   8 ;; Package: vc
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; This is a mercurial version control backend
  28
  29 ;;; Thanks:
  30
  31 ;;; Bugs:
  32
  33 ;;; Installation:
  34
  35 ;;; Todo:
  36
  37 ;; 1) Implement the rest of the vc interface. See the comment at the
  38 ;; beginning of vc.el. The current status is:
  39
  40 ;; FUNCTION NAME                               STATUS
  41 ;; BACKEND PROPERTIES
  42 ;; * revision-granularity                      OK
  43 ;; STATE-QUERYING FUNCTIONS
  44 ;; * registered (file)                         OK
  45 ;; * state (file)                              OK
  46 ;; - state-heuristic (file)                    NOT NEEDED
  47 ;; - dir-status (dir update-function)          OK
  48 ;; - dir-status-files (dir files ds uf)        OK
  49 ;; - dir-extra-headers (dir)                   OK
  50 ;; - dir-printer (fileinfo)                    OK
  51 ;; * working-revision (file)                   OK
  52 ;; - latest-on-branch-p (file)                 ??
  53 ;; * checkout-model (files)                    OK
  54 ;; - workfile-unchanged-p (file)               OK
  55 ;; - mode-line-string (file)                   NOT NEEDED
  56 ;; STATE-CHANGING FUNCTIONS
  57 ;; * register (files &optional rev comment)    OK
  58 ;; * create-repo ()                            OK
  59 ;; - init-revision ()                          NOT NEEDED
  60 ;; - responsible-p (file)                      OK
  61 ;; - could-register (file)                     OK
  62 ;; - receive-file (file rev)                   ?? PROBABLY NOT NEEDED
  63 ;; - unregister (file)                         OK
  64 ;; * checkin (files rev comment)               OK
  65 ;; * find-revision (file rev buffer)           OK
  66 ;; * checkout (file &optional editable rev)    OK
  67 ;; * revert (file &optional contents-done)     OK
  68 ;; - rollback (files)                          ?? PROBABLY NOT NEEDED
  69 ;; - merge (file rev1 rev2)                    NEEDED
  70 ;; - merge-news (file)                         NEEDED
  71 ;; - steal-lock (file &optional revision)      NOT NEEDED
  72 ;; HISTORY FUNCTIONS
  73 ;; * print-log (files buffer &optional shortlog start-revision limit) OK
  74 ;; - log-view-mode ()                          OK
  75 ;; - show-log-entry (revision)                 NOT NEEDED, DEFAULT IS GOOD
  76 ;; - comment-history (file)                    NOT NEEDED
  77 ;; - update-changelog (files)                  NOT NEEDED
  78 ;; * diff (files &optional rev1 rev2 buffer)   OK
  79 ;; - revision-completion-table (files)         OK?
  80 ;; - annotate-command (file buf &optional rev) OK
  81 ;; - annotate-time ()                          OK
  82 ;; - annotate-current-time ()                  NOT NEEDED
  83 ;; - annotate-extract-revision-at-line ()      OK
  84 ;; TAG SYSTEM
  85 ;; - create-tag (dir name branchp)             NEEDED
  86 ;; - retrieve-tag (dir name update)            NEEDED
  87 ;; MISCELLANEOUS
  88 ;; - make-version-backups-p (file)             ??
  89 ;; - repository-hostname (dirname)             ??
  90 ;; - previous-revision (file rev)              OK
  91 ;; - next-revision (file rev)                  OK
  92 ;; - check-headers ()                          ??
  93 ;; - clear-headers ()                          ??
  94 ;; - delete-file (file)                        TEST IT
  95 ;; - rename-file (old new)                     OK
  96 ;; - find-file-hook ()                         added for bug#10709
  97
  98 ;; 2) Implement Stefan Monnier's advice:
  99 ;; vc-hg-registered and vc-hg-state
 100 ;; Both of those functions should be super extra careful to fail gracefully in
 101 ;; unexpected circumstances. The reason this is important is that any error
 102 ;; there will prevent the user from even looking at the file :-(
 103 ;; Ideally, just like in vc-arch and vc-cvs, checking that the file is under
 104 ;; mercurial's control and extracting the current revision should be done
 105 ;; without even using `hg' (this way even if you don't have `hg' installed,
 106 ;; Emacs is able to tell you this file is under mercurial's control).
 107
 108 ;;; History:
 109 ;;
 110
 111 ;;; Code:
 112
 113 (eval-when-compile
 114   (require 'cl-lib)
 115   (require 'vc)
 116   (require 'vc-dir))
 117
 118 ;;; Customization options
 119
 120 (defgroup vc-hg nil
 121   "VC Mercurial (hg) backend."
 122   :version "24.1"
 123   :group 'vc)
 124
 125 (defcustom vc-hg-global-switches nil
 126   "Global switches to pass to any Hg command."
 127   :type '(choice (const :tag "None" nil)
 128          (string :tag "Argument String")
 129          (repeat :tag "Argument List" :value ("") string))
 130   :version "22.2"
 131   :group 'vc-hg)
 132
 133 (defcustom vc-hg-diff-switches t ; Hg doesn't support common args like -u
 134   "String or list of strings specifying switches for Hg diff under VC.
 135 If nil, use the value of `vc-diff-switches'.  If t, use no switches."
 136   :type '(choice (const :tag "Unspecified" nil)
 137                  (const :tag "None" t)
 138                  (string :tag "Argument String")
 139                  (repeat :tag "Argument List" :value ("") string))
 140   :version "23.1"
 141   :group 'vc-hg)
 142
 143 (defcustom vc-hg-program "hg"
 144   "Name of the Mercurial executable (excluding any arguments)."
 145   :type 'string
 146   :group 'vc-hg)
 147
 148 (defcustom vc-hg-root-log-format
 149   `(,(concat "{rev}:{ifeq(branch, 'default','', '{branch}')}"
 150              ":{bookmarks}:{tags}:{author|person}"
 151              " {date|shortdate} {desc|firstline}\\n")
 152     ,(concat "^\\(?:[+@o x|-]*\\)"      ;Graph data.
 153              "\\([0-9]+\\):\\([^:]*\\)"
 154              ":\\([^:]*\\):\\([^:]*\\):\\(.*?\\)"
 155              "[ \t]+\\([0-9]\\{4\\}-[0-9]\\{2\\}-[0-9]\\{2\\}\\)")
 156     ((1 'log-view-message-face)
 157      (2 'change-log-file)
 158      (3 'change-log-list)
 159      (4 'change-log-conditionals)
 160      (5 'change-log-name)
 161      (6 'change-log-date)))
 162   "Mercurial log template for `vc-hg-print-log' short format.
 163 This should be a list (TEMPLATE REGEXP KEYWORDS), where TEMPLATE
 164 is the \"--template\" argument string to pass to Mercurial,
 165 REGEXP is a regular expression matching the resulting Mercurial
 166 output, and KEYWORDS is a list of `font-lock-keywords' for
 167 highlighting the Log View buffer."
 168   :type '(list string string (repeat sexp))
 169   :group 'vc-hg
 170   :version "24.5")
 171
 172 \f
 173 ;;; Properties of the backend
 174
 175 (defvar vc-hg-history nil)
 176
 177 (defun vc-hg-revision-granularity () 'repository)
 178 (defun vc-hg-checkout-model (_files) 'implicit)
 179
 180 ;;; State querying functions
 181
 182 ;;;###autoload (defun vc-hg-registered (file)
 183 ;;;###autoload   "Return non-nil if FILE is registered with hg."
 184 ;;;###autoload   (if (vc-find-root file ".hg")       ; short cut
 185 ;;;###autoload       (progn
 186 ;;;###autoload         (load "vc-hg" nil t)
 187 ;;;###autoload         (vc-hg-registered file))))
 188
 189 ;; Modeled after the similar function in vc-bzr.el
 190 (defun vc-hg-registered (file)
 191   "Return non-nil if FILE is registered with hg."
 192   (when (vc-hg-root file)           ; short cut
 193     (let ((state (vc-hg-state file)))  ; expensive
 194       (and state (not (memq state '(ignored unregistered)))))))
 195
 196 (defun vc-hg-state (file)
 197   "Hg-specific version of `vc-state'."
 198   (let*
 199       ((status nil)
 200        (default-directory (file-name-directory file))
 201        (out
 202         (with-output-to-string
 203           (with-current-buffer
 204               standard-output
 205             (setq status
 206                   (condition-case nil
 207                       ;; Ignore all errors.
 208                       (let ((process-environment
 209                              ;; Avoid localization of messages so we
 210                              ;; can parse the output.  Disable pager.
 211                              (append
 212                               (list "TERM=dumb" "LANGUAGE=C" "HGPLAIN=1")
 213                               process-environment)))
 214                         (if (file-remote-p file)
 215                             (process-file
 216                              "env" nil t nil
 217                              "HGPLAIN=1" vc-hg-program
 218                              "--config" "alias.status=status"
 219                              "--config" "defaults.status="
 220                              "status" "-A" (file-relative-name file))
 221                           (process-file
 222                            vc-hg-program nil t nil
 223                            "--config" "alias.status=status"
 224                            "--config" "defaults.status="
 225                            "status" "-A" (file-relative-name file))))
 226                     ;; Some problem happened.  E.g. We can't find an `hg'
 227                     ;; executable.
 228                     (error nil)))))))
 229     (when (eq 0 status)
 230         (when (null (string-match ".*: No such file or directory$" out))
 231           (let ((state (aref out 0)))
 232             (cond
 233              ((eq state ?=) 'up-to-date)
 234              ((eq state ?A) 'added)
 235              ((eq state ?M) 'edited)
 236              ((eq state ?I) 'ignored)
 237              ((eq state ?R) 'removed)
 238              ((eq state ?!) 'missing)
 239              ((eq state ??) 'unregistered)
 240              ((eq state ?C) 'up-to-date) ;; Older mercurial versions use this.
 241              (t 'up-to-date)))))))
 242
 243 (defun vc-hg-working-revision (file)
 244   "Hg-specific version of `vc-working-revision'."
 245   (or (ignore-errors
 246         (with-output-to-string
 247           (vc-hg-command standard-output 0 file
 248                          "parent" "--template" "{rev}")))
 249       "0"))
 250
 251 ;;; History functions
 252
 253 (defcustom vc-hg-log-switches nil
 254   "String or list of strings specifying switches for hg log under VC."
 255   :type '(choice (const :tag "None" nil)
 256                  (string :tag "Argument String")
 257                  (repeat :tag "Argument List" :value ("") string))
 258   :group 'vc-hg)
 259
 260 (autoload 'vc-setup-buffer "vc-dispatcher")
 261
 262 (defvar vc-hg-log-graph nil
 263   "If non-nil, use `--graph' in the short log output.")
 264
 265 (defun vc-hg-print-log (files buffer &optional shortlog start-revision limit)
 266   "Print commit log associated with FILES into specified BUFFER.
 267 If SHORTLOG is non-nil, use a short format based on `vc-hg-root-log-format'.
 268 If START-REVISION is non-nil, it is the newest revision to show.
 269 If LIMIT is non-nil, show no more than this many entries."
 270   ;; `vc-do-command' creates the buffer, but we need it before running
 271   ;; the command.
 272   (vc-setup-buffer buffer)
 273   ;; If the buffer exists from a previous invocation it might be
 274   ;; read-only.
 275   (let ((inhibit-read-only t))
 276     (with-current-buffer
 277         buffer
 278       (apply 'vc-hg-command buffer 0 files "log"
 279              (nconc
 280               (when start-revision (list (format "-r%s:0" start-revision)))
 281               (when limit (list "-l" (format "%s" limit)))
 282               (when shortlog `(,@(if vc-hg-log-graph '("--graph"))
 283                                "--template"
 284                                ,(car vc-hg-root-log-format)))
 285               vc-hg-log-switches)))))
 286
 287 (defvar log-view-message-re)
 288 (defvar log-view-file-re)
 289 (defvar log-view-font-lock-keywords)
 290 (defvar log-view-per-file-logs)
 291 (defvar log-view-expanded-log-entry-function)
 292
 293 (define-derived-mode vc-hg-log-view-mode log-view-mode "Hg-Log-View"
 294   (require 'add-log) ;; we need the add-log faces
 295   (set (make-local-variable 'log-view-file-re) "\\`a\\`")
 296   (set (make-local-variable 'log-view-per-file-logs) nil)
 297   (set (make-local-variable 'log-view-message-re)
 298        (if (eq vc-log-view-type 'short)
 299            (cadr vc-hg-root-log-format)
 300          "^changeset:[ \t]*\\([0-9]+\\):\\(.+\\)"))
 301   ;; Allow expanding short log entries
 302   (when (eq vc-log-view-type 'short)
 303     (setq truncate-lines t)
 304     (set (make-local-variable 'log-view-expanded-log-entry-function)
 305          'vc-hg-expanded-log-entry))
 306   (set (make-local-variable 'log-view-font-lock-keywords)
 307        (if (eq vc-log-view-type 'short)
 308            (list (cons (nth 1 vc-hg-root-log-format)
 309                        (nth 2 vc-hg-root-log-format)))
 310          (append
 311           log-view-font-lock-keywords
 312           '(
 313             ;; Handle the case:
 314             ;; user: FirstName LastName <foo@bar>
 315             ("^user:[ \t]+\\([^<(]+?\\)[ \t]*[(<]\\([A-Za-z0-9_.+-]+@[A-Za-z0-9_.-]+\\)[>)]"
 316              (1 'change-log-name)
 317              (2 'change-log-email))
 318             ;; Handle the cases:
 319             ;; user: foo@bar
 320             ;; and
 321             ;; user: foo
 322             ("^user:[ \t]+\\([A-Za-z0-9_.+-]+\\(?:@[A-Za-z0-9_.-]+\\)?\\)"
 323              (1 'change-log-email))
 324             ("^date: \\(.+\\)" (1 'change-log-date))
 325             ("^tag: +\\([^ ]+\\)$" (1 'highlight))
 326             ("^summary:[ \t]+\\(.+\\)" (1 'log-view-message)))))))
 327
 328 (autoload 'vc-switches "vc")
 329
 330 (defun vc-hg-diff (files &optional oldvers newvers buffer)
 331   "Get a difference report using hg between two revisions of FILES."
 332   (let* ((firstfile (car files))
 333          (working (and firstfile (vc-working-revision firstfile))))
 334     (when (and (equal oldvers working) (not newvers))
 335       (setq oldvers nil))
 336     (when (and (not oldvers) newvers)
 337       (setq oldvers working))
 338     (apply #'vc-hg-command (or buffer "*vc-diff*") nil files "diff"
 339            (append
 340             (vc-switches 'hg 'diff)
 341             (when oldvers
 342               (if newvers
 343                   (list "-r" oldvers "-r" newvers)
 344                 (list "-r" oldvers)))))))
 345
 346 (defun vc-hg-expanded-log-entry (revision)
 347   (with-temp-buffer
 348     (vc-hg-command t nil nil "log" "-r" revision)
 349     (goto-char (point-min))
 350     (unless (eobp)
 351       ;; Indent the expanded log entry.
 352       (indent-region (point-min) (point-max) 2)
 353       (goto-char (point-max))
 354       (buffer-string))))
 355
 356 (defun vc-hg-revision-table (files)
 357   (let ((default-directory (file-name-directory (car files))))
 358     (with-temp-buffer
 359       (vc-hg-command t nil files "log" "--template" "{rev} ")
 360       (split-string
 361        (buffer-substring-no-properties (point-min) (point-max))))))
 362
 363 ;; Modeled after the similar function in vc-cvs.el
 364 (defun vc-hg-revision-completion-table (files)
 365   (letrec ((table (lazy-completion-table
 366                    table (lambda () (vc-hg-revision-table files)))))
 367     table))
 368
 369 (defun vc-hg-annotate-command (file buffer &optional revision)
 370   "Execute \"hg annotate\" on FILE, inserting the contents in BUFFER.
 371 Optional arg REVISION is a revision to annotate from."
 372   (vc-hg-command buffer 0 file "annotate" "-d" "-n" "--follow"
 373                  (when revision (concat "-r" revision))))
 374
 375 (declare-function vc-annotate-convert-time "vc-annotate" (time))
 376
 377 ;; The format for one line output by "hg annotate -d -n" looks like this:
 378 ;;215 Wed Jun 20 21:22:58 2007 -0700: CONTENTS
 379 ;; i.e: VERSION_NUMBER DATE: CONTENTS
 380 ;; If the user has set the "--follow" option, the output looks like:
 381 ;;215 Wed Jun 20 21:22:58 2007 -0700 foo.c: CONTENTS
 382 ;; i.e. VERSION_NUMBER DATE FILENAME: CONTENTS
 383 (defconst vc-hg-annotate-re
 384   "^[ \t]*\\([0-9]+\\) \\(.\\{30\\}\\)\\(?:\\(: \\)\\|\\(?: +\\([^:\n]+\\(?::\\(?:[^: \n][^:\n]*\\)?\\)*\\): \\)\\)")
 385
 386 (defun vc-hg-annotate-time ()
 387   (when (looking-at vc-hg-annotate-re)
 388     (goto-char (match-end 0))
 389     (vc-annotate-convert-time
 390      (date-to-time (match-string-no-properties 2)))))
 391
 392 (defun vc-hg-annotate-extract-revision-at-line ()
 393   (save-excursion
 394     (beginning-of-line)
 395     (when (looking-at vc-hg-annotate-re)
 396       (if (match-beginning 3)
 397           (match-string-no-properties 1)
 398         (cons (match-string-no-properties 1)
 399               (expand-file-name (match-string-no-properties 4)
 400                                 (vc-hg-root default-directory)))))))
 401
 402 (defun vc-hg-previous-revision (_file rev)
 403   (let ((newrev (1- (string-to-number rev))))
 404     (when (>= newrev 0)
 405       (number-to-string newrev))))
 406
 407 (defun vc-hg-next-revision (_file rev)
 408   (let ((newrev (1+ (string-to-number rev)))
 409         (tip-revision
 410          (with-temp-buffer
 411            (vc-hg-command t 0 nil "tip" "--style=default")
 412            (goto-char (point-min))
 413            (re-search-forward "^changeset:[ \t]*\\([0-9]+\\):")
 414            (string-to-number (match-string-no-properties 1)))))
 415     ;; We don't want to exceed the maximum possible revision number, ie
 416     ;; the tip revision.
 417     (when (<= newrev tip-revision)
 418       (number-to-string newrev))))
 419
 420 ;; Modeled after the similar function in vc-bzr.el
 421 (defun vc-hg-delete-file (file)
 422   "Delete FILE and delete it in the hg repository."
 423   (condition-case ()
 424       (delete-file file)
 425     (file-error nil))
 426   (vc-hg-command nil 0 file "remove" "--after" "--force"))
 427
 428 ;; Modeled after the similar function in vc-bzr.el
 429 (defun vc-hg-rename-file (old new)
 430   "Rename file from OLD to NEW using `hg mv'."
 431   (vc-hg-command nil 0 new "mv" old))
 432
 433 (defun vc-hg-register (files &optional _rev _comment)
 434   "Register FILES under hg.
 435 REV is ignored.
 436 COMMENT is ignored."
 437   (vc-hg-command nil 0 files "add"))
 438
 439 (defun vc-hg-create-repo ()
 440   "Create a new Mercurial repository."
 441   (vc-hg-command nil 0 nil "init"))
 442
 443 (defalias 'vc-hg-responsible-p 'vc-hg-root)
 444
 445 ;; Modeled after the similar function in vc-bzr.el
 446 (defun vc-hg-could-register (file)
 447   "Return non-nil if FILE could be registered under hg."
 448   (and (vc-hg-responsible-p file)      ; shortcut
 449        (condition-case ()
 450            (with-temp-buffer
 451              (vc-hg-command t nil file "add" "--dry-run"))
 452              ;; The command succeeds with no output if file is
 453              ;; registered.
 454          (error))))
 455
 456 (defun vc-hg-unregister (file)
 457   "Unregister FILE from hg."
 458   (vc-hg-command nil 0 file "forget"))
 459
 460 (declare-function log-edit-extract-headers "log-edit" (headers string))
 461
 462 (defun vc-hg-checkin (files _rev comment)
 463   "Hg-specific version of `vc-backend-checkin'.
 464 REV is ignored."
 465   (apply 'vc-hg-command nil 0 files
 466          (nconc (list "commit" "-m")
 467                 (log-edit-extract-headers '(("Author" . "--user")
 468                                             ("Date" . "--date"))
 469                                           comment))))
 470
 471 (defun vc-hg-find-revision (file rev buffer)
 472   (let ((coding-system-for-read 'binary)
 473         (coding-system-for-write 'binary))
 474     (if rev
 475         (vc-hg-command buffer 0 file "cat" "-r" rev)
 476       (vc-hg-command buffer 0 file "cat"))))
 477
 478 (defun vc-hg-find-ignore-file (file)
 479   "Return the root directory of the repository of FILE."
 480   (expand-file-name ".hgignore"
 481                     (vc-hg-root file)))
 482
 483 ;; Modeled after the similar function in vc-bzr.el
 484 (defun vc-hg-checkout (file &optional _editable rev)
 485   "Retrieve a revision of FILE.
 486 EDITABLE is ignored.
 487 REV is the revision to check out into WORKFILE."
 488   (let ((coding-system-for-read 'binary)
 489         (coding-system-for-write 'binary))
 490   (with-current-buffer (or (get-file-buffer file) (current-buffer))
 491     (if rev
 492         (vc-hg-command t 0 file "cat" "-r" rev)
 493       (vc-hg-command t 0 file "cat")))))
 494
 495 (defun vc-hg-resolve-when-done ()
 496   "Call \"hg resolve -m\" if the conflict markers have been removed."
 497   (save-excursion
 498     (goto-char (point-min))
 499     (unless (re-search-forward "^<<<<<<< " nil t)
 500       (vc-hg-command nil 0 buffer-file-name "resolve" "-m")
 501       ;; Remove the hook so that it is not called multiple times.
 502       (remove-hook 'after-save-hook 'vc-hg-resolve-when-done t))))
 503
 504 (defun vc-hg-find-file-hook ()
 505   (when (and buffer-file-name
 506              (file-exists-p (concat buffer-file-name ".orig"))
 507              ;; Hg does not seem to have a "conflict" status, eg
 508              ;; hg http://bz.selenic.com/show_bug.cgi?id=2724
 509              (memq (vc-file-getprop buffer-file-name 'vc-state)
 510                    '(edited conflict))
 511              ;; Maybe go on to check that "hg resolve -l" says "U"?
 512              ;; If "hg resolve -l" says there's a conflict but there are no
 513              ;; conflict markers, it's not clear what we should do.
 514              (save-excursion
 515                (goto-char (point-min))
 516                (re-search-forward "^<<<<<<< " nil t)))
 517     ;; Hg may not recognize "conflict" as a state, but we can do better.
 518     (vc-file-setprop buffer-file-name 'vc-state 'conflict)
 519     (smerge-start-session)
 520     (add-hook 'after-save-hook 'vc-hg-resolve-when-done nil t)
 521     (message "There are unresolved conflicts in this file")))
 522
 523
 524 ;; Modeled after the similar function in vc-bzr.el
 525 (defun vc-hg-workfile-unchanged-p (file)
 526   (eq 'up-to-date (vc-hg-state file)))
 527
 528 ;; Modeled after the similar function in vc-bzr.el
 529 (defun vc-hg-revert (file &optional contents-done)
 530   (unless contents-done
 531     (with-temp-buffer (vc-hg-command t 0 file "revert"))))
 532
 533 ;;; Hg specific functionality.
 534
 535 (defvar vc-hg-extra-menu-map
 536   (let ((map (make-sparse-keymap)))
 537     map))
 538
 539 (defun vc-hg-extra-menu () vc-hg-extra-menu-map)
 540
 541 (defun vc-hg-extra-status-menu () vc-hg-extra-menu-map)
 542
 543 (defvar log-view-vc-backend)
 544
 545 (cl-defstruct (vc-hg-extra-fileinfo
 546             (:copier nil)
 547             (:constructor vc-hg-create-extra-fileinfo (rename-state extra-name))
 548             (:conc-name vc-hg-extra-fileinfo->))
 549   rename-state        ;; rename or copy state
 550   extra-name)         ;; original name for copies and rename targets, new name for
 551
 552 (declare-function vc-default-dir-printer "vc-dir" (backend fileentry))
 553
 554 (defun vc-hg-dir-printer (info)
 555   "Pretty-printer for the vc-dir-fileinfo structure."
 556   (let ((extra (vc-dir-fileinfo->extra info)))
 557     (vc-default-dir-printer 'Hg info)
 558     (when extra
 559       (insert (propertize
 560                (format "   (%s %s)"
 561                        (pcase (vc-hg-extra-fileinfo->rename-state extra)
 562                          (`copied "copied from")
 563                          (`renamed-from "renamed from")
 564                          (`renamed-to "renamed to"))
 565                        (vc-hg-extra-fileinfo->extra-name extra))
 566                'face 'font-lock-comment-face)))))
 567
 568 (defun vc-hg-after-dir-status (update-function)
 569   (let ((file nil)
 570         (translation '((?= . up-to-date)
 571                        (?C . up-to-date)
 572                        (?A . added)
 573                        (?R . removed)
 574                        (?M . edited)
 575                        (?I . ignored)
 576                        (?! . missing)
 577                        (?  . copy-rename-line)
 578                        (?? . unregistered)))
 579         (translated nil)
 580         (result nil)
 581         (last-added nil)
 582         (last-line-copy nil))
 583       (goto-char (point-min))
 584       (while (not (eobp))
 585         (setq translated (cdr (assoc (char-after) translation)))
 586         (setq file
 587               (buffer-substring-no-properties (+ (point) 2)
 588                                               (line-end-position)))
 589         (cond ((not translated)
 590                (setq last-line-copy nil))
 591               ((eq translated 'up-to-date)
 592                (setq last-line-copy nil))
 593               ((eq translated 'copy-rename-line)
 594                ;; For copied files the output looks like this:
 595                ;; A COPIED_FILE_NAME
 596                ;;   ORIGINAL_FILE_NAME
 597                (setf (nth 2 last-added)
 598                      (vc-hg-create-extra-fileinfo 'copied file))
 599                (setq last-line-copy t))
 600               ((and last-line-copy (eq translated 'removed))
 601                ;; For renamed files the output looks like this:
 602                ;; A NEW_FILE_NAME
 603                ;;   ORIGINAL_FILE_NAME
 604                ;; R ORIGINAL_FILE_NAME
 605                ;; We need to adjust the previous entry to not think it is a copy.
 606                (setf (vc-hg-extra-fileinfo->rename-state (nth 2 last-added))
 607                      'renamed-from)
 608                (push (list file translated
 609                            (vc-hg-create-extra-fileinfo
 610                             'renamed-to (nth 0 last-added))) result)
 611                (setq last-line-copy nil))
 612               (t
 613                (setq last-added (list file translated nil))
 614                (push last-added result)
 615                (setq last-line-copy nil)))
 616         (forward-line))
 617       (funcall update-function result)))
 618
 619 ;; Follows vc-hg-command (or vc-do-async-command), which uses vc-do-command
 620 ;; from vc-dispatcher.
 621 (declare-function vc-exec-after "vc-dispatcher" (code))
 622 ;; Follows vc-exec-after.
 623 (declare-function vc-set-async-update "vc-dispatcher" (process-buffer))
 624
 625 (defun vc-hg-dir-status (dir update-function)
 626   (vc-hg-command (current-buffer) 'async dir "status" "-C")
 627   (vc-run-delayed
 628    (vc-hg-after-dir-status update-function)))
 629
 630 (defun vc-hg-dir-status-files (dir files _default-state update-function)
 631   (apply 'vc-hg-command (current-buffer) 'async dir "status" "-mardui" "-C" files)
 632   (vc-run-delayed
 633    (vc-hg-after-dir-status update-function)))
 634
 635 (defun vc-hg-dir-extra-header (name &rest commands)
 636   (concat (propertize name 'face 'font-lock-type-face)
 637           (propertize
 638            (with-temp-buffer
 639              (apply 'vc-hg-command (current-buffer) 0 nil commands)
 640              (buffer-substring-no-properties (point-min) (1- (point-max))))
 641            'face 'font-lock-variable-name-face)))
 642
 643 (defun vc-hg-dir-extra-headers (dir)
 644   "Generate extra status headers for a Mercurial tree."
 645   (let ((default-directory dir))
 646     (concat
 647      (vc-hg-dir-extra-header "Root       : " "root") "\n"
 648      (vc-hg-dir-extra-header "Branch     : " "id" "-b") "\n"
 649      (vc-hg-dir-extra-header "Tags       : " "id" "-t") ; "\n"
 650      ;; these change after each commit
 651      ;; (vc-hg-dir-extra-header "Local num  : " "id" "-n") "\n"
 652      ;; (vc-hg-dir-extra-header "Global id  : " "id" "-i")
 653      )))
 654
 655 (defun vc-hg-log-incoming (buffer remote-location)
 656   (vc-hg-command buffer 1 nil "incoming" "-n" (unless (string= remote-location "")
 657                                                 remote-location)))
 658
 659 (defun vc-hg-log-outgoing (buffer remote-location)
 660   (vc-hg-command buffer 1 nil "outgoing" "-n" (unless (string= remote-location "")
 661                                                 remote-location)))
 662
 663 (declare-function log-view-get-marked "log-view" ())
 664
 665 ;; XXX maybe also add key bindings for these functions.
 666 (defun vc-hg-push ()
 667   (interactive)
 668   (let ((marked-list (log-view-get-marked)))
 669     (if marked-list
 670         (apply #'vc-hg-command
 671                nil 0 nil
 672                "push"
 673                (apply 'nconc
 674                       (mapcar (lambda (arg) (list "-r" arg)) marked-list)))
 675       (error "No log entries selected for push"))))
 676
 677 (defvar vc-hg-error-regexp-alist nil
 678   ;; 'hg pull' does not list modified files, so, for now, the only
 679   ;; benefit of `vc-compilation-mode' is that one can get rid of
 680   ;; *vc-hg* buffer with 'q' or 'z'.
 681   ;; TODO: call 'hg incoming' before pull/merge to get the list of
 682   ;;       modified files
 683   "Value of `compilation-error-regexp-alist' in *vc-hg* buffers.")
 684
 685 (autoload 'vc-do-async-command "vc-dispatcher")
 686
 687 (defun vc-hg-pull (prompt)
 688   "Issue a Mercurial pull command.
 689 If called interactively with a set of marked Log View buffers,
 690 call \"hg pull -r REVS\" to pull in the specified revisions REVS.
 691
 692 With a prefix argument or if PROMPT is non-nil, prompt for a
 693 specific Mercurial pull command.  The default is \"hg pull -u\",
 694 which fetches changesets from the default remote repository and
 695 then attempts to update the working directory."
 696   (interactive "P")
 697   (let (marked-list)
 698     ;; The `vc-hg-pull' command existed before the `pull' VC action
 699     ;; was implemented.  Keep it for backward compatibility.
 700     (if (and (called-interactively-p 'interactive)
 701              (setq marked-list (log-view-get-marked)))
 702         (apply #'vc-hg-command
 703                nil 0 nil
 704                "pull"
 705                (apply 'nconc
 706                       (mapcar (lambda (arg) (list "-r" arg))
 707                               marked-list)))
 708       (let* ((root (vc-hg-root default-directory))
 709              (buffer (format "*vc-hg : %s*" (expand-file-name root)))
 710              (command "pull")
 711              (hg-program vc-hg-program)
 712              ;; Fixme: before updating the working copy to the latest
 713              ;; state, should check if it's visiting an old revision.
 714              (args '("-u")))
 715         ;; If necessary, prompt for the exact command.
 716         (when prompt
 717           (setq args (split-string
 718                       (read-shell-command "Run Hg (like this): "
 719                                           (format "%s pull -u" hg-program)
 720                                           'vc-hg-history)
 721                       " " t))
 722           (setq hg-program (car  args)
 723                 command    (cadr args)
 724                 args       (cddr args)))
 725         (apply 'vc-do-async-command buffer root hg-program
 726                command args)
 727         (with-current-buffer buffer
 728           (vc-run-delayed (vc-compilation-mode 'hg)))
 729         (vc-set-async-update buffer)))))
 730
 731 (defun vc-hg-merge-branch ()
 732   "Merge incoming changes into the current working directory.
 733 This runs the command \"hg merge\"."
 734   (let* ((root (vc-hg-root default-directory))
 735          (buffer (format "*vc-hg : %s*" (expand-file-name root))))
 736     (apply 'vc-do-async-command buffer root vc-hg-program '("merge"))
 737     (with-current-buffer buffer (vc-run-delayed (vc-compilation-mode 'hg)))
 738     (vc-set-async-update buffer)))
 739
 740 ;;; Internal functions
 741
 742 (defun vc-hg-command (buffer okstatus file-or-list &rest flags)
 743   "A wrapper around `vc-do-command' for use in vc-hg.el.
 744 This function differs from vc-do-command in that it invokes
 745 `vc-hg-program', and passes `vc-hg-global-switches' to it before FLAGS."
 746   (apply 'vc-do-command (or buffer "*vc*") okstatus vc-hg-program file-or-list
 747          (if (stringp vc-hg-global-switches)
 748              (cons vc-hg-global-switches flags)
 749            (append vc-hg-global-switches
 750                    flags))))
 751
 752 (defun vc-hg-root (file)
 753   (vc-find-root file ".hg"))
 754
 755 (provide 'vc-hg)
 756
 757 ;;; vc-hg.el ends here