code.delx.au - gnu-emacs/blob - lisp/vc/vc-svn.el

   1 ;;; vc-svn.el --- non-resident support for Subversion version-control  -*- lexical-binding:t -*-
   2
   3 ;; Copyright (C) 2003-2015 Free Software Foundation, Inc.
   4
   5 ;; Author:      FSF (see vc.el for full credits)
   6 ;; Maintainer:  Stefan Monnier <monnier@gnu.org>
   7 ;; Package: vc
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; Sync'd with Subversion's vc-svn.el as of revision 5801. but this version
  27 ;; has been extensively modified since to handle filesets.
  28
  29 ;;; Code:
  30
  31 (eval-when-compile
  32   (require 'vc))
  33
  34 ;; Clear up the cache to force vc-call to check again and discover
  35 ;; new functions when we reload this file.
  36 (put 'SVN 'vc-functions nil)
  37
  38 ;;;
  39 ;;; Customization options
  40 ;;;
  41
  42 (defgroup vc-svn nil
  43   "VC Subversion (svn) backend."
  44   :version "24.1"
  45   :group 'vc)
  46
  47 ;; FIXME there is also svnadmin.
  48 (defcustom vc-svn-program "svn"
  49   "Name of the SVN executable."
  50   :type 'string
  51   :group 'vc-svn)
  52
  53 ;; Might be nice if svn defaulted to non-interactive if stdin not tty.
  54 ;; http://svn.haxx.se/dev/archive-2008-05/0762.shtml
  55 ;; http://svn.haxx.se/dev/archive-2009-04/0094.shtml
  56 ;; Maybe newer ones do?
  57 (defcustom vc-svn-global-switches (unless (eq system-type 'darwin) ; bug#13513
  58                                     '("--non-interactive"))
  59   "Global switches to pass to any SVN command.
  60 The option \"--non-interactive\" is often needed to prevent SVN
  61 hanging while prompting for authorization."
  62   :type '(choice (const :tag "None" nil)
  63                  (string :tag "Argument String")
  64                  (repeat :tag "Argument List"
  65                          :value ("")
  66                          string))
  67   :version "24.4"
  68   :group 'vc-svn)
  69
  70 (defcustom vc-svn-register-switches nil
  71   "Switches for registering a file into SVN.
  72 A string or list of strings passed to the checkin program by
  73 \\[vc-register].  If nil, use the value of `vc-register-switches'.
  74 If t, use no switches."
  75   :type '(choice (const :tag "Unspecified" nil)
  76                  (const :tag "None" t)
  77                  (string :tag "Argument String")
  78                  (repeat :tag "Argument List" :value ("") string))
  79   :version "22.1"
  80   :group 'vc-svn)
  81
  82 (defcustom vc-svn-diff-switches
  83   t                        ;`svn' doesn't support common args like -c or -b.
  84   "String or list of strings specifying extra switches for svn diff under VC.
  85 If nil, use the value of `vc-diff-switches' (or `diff-switches'),
  86 together with \"-x --diff-cmd=\"`diff-command' (since 'svn diff'
  87 does not support the default \"-c\" value of `diff-switches').
  88 If you want to force an empty list of arguments, use t."
  89   :type '(choice (const :tag "Unspecified" nil)
  90                  (const :tag "None" t)
  91                  (string :tag "Argument String")
  92                  (repeat :tag "Argument List"
  93                          :value ("")
  94                          string))
  95   :version "22.1"
  96   :group 'vc-svn)
  97
  98 (defcustom vc-svn-header '("\$Id\$")
  99   "Header keywords to be inserted by `vc-insert-headers'."
 100   :version "24.1"     ; no longer consult the obsolete vc-header-alist
 101   :type '(repeat string)
 102   :group 'vc-svn)
 103
 104 ;; We want to autoload it for use by the autoloaded version of
 105 ;; vc-svn-registered, but we want the value to be compiled at startup, not
 106 ;; at dump time.
 107 ;; ;;;###autoload
 108 (defconst vc-svn-admin-directory
 109   (cond ((and (memq system-type '(cygwin windows-nt ms-dos))
 110               (getenv "SVN_ASP_DOT_NET_HACK"))
 111          "_svn")
 112         (t ".svn"))
 113   "The name of the \".svn\" subdirectory or its equivalent.")
 114
 115 ;;; Properties of the backend
 116
 117 (defun vc-svn-revision-granularity () 'repository)
 118 (defun vc-svn-checkout-model (_files) 'implicit)
 119
 120 ;;;
 121 ;;; State-querying functions
 122 ;;;
 123
 124 ;;; vc-svn-admin-directory is generally not defined when the
 125 ;;; autoloaded function is called.
 126
 127 ;;;###autoload (defun vc-svn-registered (f)
 128 ;;;###autoload   (let ((admin-dir (cond ((and (eq system-type 'windows-nt)
 129 ;;;###autoload                                (getenv "SVN_ASP_DOT_NET_HACK"))
 130 ;;;###autoload                           "_svn")
 131 ;;;###autoload                          (t ".svn"))))
 132 ;;;###autoload     (when (vc-find-root f admin-dir)
 133 ;;;###autoload       (load "vc-svn" nil t)
 134 ;;;###autoload       (vc-svn-registered f))))
 135
 136 (defun vc-svn-registered (file)
 137   "Check if FILE is SVN registered."
 138   (when (vc-svn-root file)
 139     (with-temp-buffer
 140       (cd (file-name-directory file))
 141       (let* (process-file-side-effects
 142              (status
 143              (condition-case nil
 144                  ;; Ignore all errors.
 145                  (vc-svn-command t t file "status" "-v")
 146                ;; Some problem happened.  E.g. We can't find an `svn'
 147                ;; executable.  We used to only catch `file-error' but when
 148                ;; the process is run on a remote host via Tramp, the error
 149                ;; is only reported via the exit status which is turned into
 150                ;; an `error' by vc-do-command.
 151                (error nil))))
 152         (when (eq 0 status)
 153           (let ((parsed (vc-svn-parse-status file)))
 154             (and parsed (not (memq parsed '(ignored unregistered))))))))))
 155
 156 (defun vc-svn-state (file &optional localp)
 157   "SVN-specific version of `vc-state'."
 158   (let (process-file-side-effects)
 159     (setq localp (or localp (vc-stay-local-p file 'SVN)))
 160     (with-temp-buffer
 161       (cd (file-name-directory file))
 162       (vc-svn-command t 0 file "status" (if localp "-v" "-u"))
 163       (vc-svn-parse-status file))))
 164
 165 ;; NB this does not handle svn properties, which can be changed
 166 ;; without changing the file timestamp.
 167 ;; Note that unlike vc-cvs-state-heuristic, this is not called from
 168 ;; vc-svn-state.  AFAICS, it is only called from vc-state-refresh via
 169 ;; vc-after-save (bug#7850).  Therefore the fact that it ignores
 170 ;; properties is irrelevant.  If you want to make vc-svn-state call
 171 ;; this, it should be extended to handle svn properties.
 172 (defun vc-svn-state-heuristic (file)
 173   "SVN-specific state heuristic."
 174   ;; If the file has not changed since checkout, consider it `up-to-date'.
 175   ;; Otherwise consider it `edited'.  Copied from vc-cvs-state-heuristic.
 176   (let ((checkout-time (vc-file-getprop file 'vc-checkout-time))
 177         (lastmod (nth 5 (file-attributes file))))
 178     (cond
 179      ((equal checkout-time lastmod) 'up-to-date)
 180      ((string= (vc-working-revision file) "0") 'added)
 181      ((null checkout-time) 'unregistered)
 182      (t 'edited))))
 183
 184 ;; FIXME it would be better not to have the "remote" argument,
 185 ;; but to distinguish the two output formats based on content.
 186 (defun vc-svn-after-dir-status (callback &optional remote)
 187   (let ((state-map '((?A . added)
 188                      (?C . conflict)
 189                      (?I . ignored)
 190                      (?M . edited)
 191                      (?D . removed)
 192                      (?R . removed)
 193                      (?? . unregistered)
 194                      ;; This is what vc-svn-parse-status does.
 195                      (?~ . edited)))
 196         (re (if remote "^\\(.\\)\\(.\\).....? \\([ *]\\) +\\(?:[-0-9]+\\)?   \\(.*\\)$"
 197               ;; Subexp 3 is a dummy in this case, so the numbers match.
 198               "^\\(.\\)\\(.\\)...\\(.\\).? \\(.*\\)$"))
 199        result)
 200     (goto-char (point-min))
 201     (while (re-search-forward re nil t)
 202       (let ((state (cdr (assq (aref (match-string 1) 0) state-map)))
 203             (propstat (cdr (assq (aref (match-string 2) 0) state-map)))
 204             (filename (if (memq system-type '(windows-nt ms-dos))
 205                           (replace-regexp-in-string "\\\\" "/" (match-string 4))
 206                         (match-string 4))))
 207         (and (memq propstat '(conflict edited))
 208              (not (eq state 'conflict)) ; conflict always wins
 209              (setq state propstat))
 210         (and remote (string-equal (match-string 3) "*")
 211              ;; FIXME are there other possible combinations?
 212              (cond ((eq state 'edited) (setq state 'needs-merge))
 213                    ((not state) (setq state 'needs-update))))
 214         (when (and state (not (string= "." filename)))
 215          (setq result (cons (list filename state) result)))))
 216     (funcall callback result)))
 217
 218 ;; -dir-status called from vc-dir, which loads vc, which loads vc-dispatcher.
 219 (declare-function vc-exec-after "vc-dispatcher" (code))
 220
 221 (defun vc-svn-dir-status (dir callback)
 222   "Run 'svn status' for DIR and update BUFFER via CALLBACK.
 223 CALLBACK is called as (CALLBACK RESULT BUFFER), where
 224 RESULT is a list of conses (FILE . STATE) for directory DIR."
 225   ;; FIXME should this rather be all the files in dir?
 226   ;; FIXME: the vc-stay-local-p logic below is disabled, it ends up
 227   ;; calling synchronously (vc-svn-registered DIR) => calling svn status -v DIR
 228   ;; which is VERY SLOW for big trees and it makes emacs
 229   ;; completely unresponsive during that time.
 230   (let* ((local (and nil (vc-stay-local-p dir 'SVN)))
 231          (remote (or t (not local) (eq local 'only-file))))
 232     (vc-svn-command (current-buffer) 'async nil "status"
 233                     (if remote "-u"))
 234   (vc-run-delayed
 235    (vc-svn-after-dir-status callback remote))))
 236
 237 (defun vc-svn-dir-status-files (_dir files _default-state callback)
 238   (apply 'vc-svn-command (current-buffer) 'async nil "status" files)
 239   (vc-run-delayed
 240    (vc-svn-after-dir-status callback)))
 241
 242 (defun vc-svn-dir-extra-headers (_dir)
 243   "Generate extra status headers for a Subversion working copy."
 244   (let (process-file-side-effects)
 245     (vc-svn-command "*vc*" 0 nil "info"))
 246   (let ((repo
 247          (save-excursion
 248            (and (progn
 249                   (set-buffer "*vc*")
 250                   (goto-char (point-min))
 251                   (re-search-forward "Repository Root: *\\(.*\\)" nil t))
 252                 (match-string 1)))))
 253     (concat
 254      (cond (repo
 255             (concat
 256              (propertize "Repository : " 'face 'font-lock-type-face)
 257              (propertize repo 'face 'font-lock-variable-name-face)))
 258            (t "")))))
 259
 260 (defun vc-svn-working-revision (file)
 261   "SVN-specific version of `vc-working-revision'."
 262   ;; There is no need to consult RCS headers under SVN, because we
 263   ;; get the workfile version for free when we recognize that a file
 264   ;; is registered in SVN.
 265   (vc-svn-registered file)
 266   (vc-file-getprop file 'vc-working-revision))
 267
 268 ;; vc-svn-mode-line-string doesn't exist because the default implementation
 269 ;; works just fine.
 270
 271 (defun vc-svn-previous-revision (_file rev)
 272   (let ((newrev (1- (string-to-number rev))))
 273     (when (< 0 newrev)
 274       (number-to-string newrev))))
 275
 276 (defun vc-svn-next-revision (file rev)
 277   (let ((newrev (1+ (string-to-number rev))))
 278     ;; The "working revision" is an uneasy conceptual fit under Subversion;
 279     ;; we use it as the upper bound until a better idea comes along.  If the
 280     ;; workfile version W coincides with the tree's latest revision R, then
 281     ;; this check prevents a "no such revision: R+1" error.  Otherwise, it
 282     ;; inhibits showing of W+1 through R, which could be considered anywhere
 283     ;; from gracious to impolite.
 284     (unless (< (string-to-number (vc-file-getprop file 'vc-working-revision))
 285                newrev)
 286       (number-to-string newrev))))
 287
 288
 289 ;;;
 290 ;;; State-changing functions
 291 ;;;
 292
 293 (defun vc-svn-create-repo ()
 294   "Create a new SVN repository."
 295   (vc-do-command "*vc*" 0 "svnadmin" '("create" "SVN"))
 296   ;; Expand default-directory because svn gets confused by eg
 297   ;; file://~/path/to/file.  (Bug#15446).
 298   (vc-svn-command "*vc*" 0 "." "checkout"
 299                   (concat "file://" (expand-file-name default-directory) "SVN")))
 300
 301 (autoload 'vc-switches "vc")
 302
 303 (defun vc-svn-register (files &optional _rev _comment)
 304   "Register FILES into the SVN version-control system.
 305 The COMMENT argument is ignored  This does an add but not a commit.
 306 Passes either `vc-svn-register-switches' or `vc-register-switches'
 307 to the SVN command."
 308   (apply 'vc-svn-command nil 0 files "add" (vc-switches 'SVN 'register)))
 309
 310 (defun vc-svn-root (file)
 311   (vc-find-root file vc-svn-admin-directory))
 312
 313 (defalias 'vc-svn-responsible-p 'vc-svn-root)
 314
 315 (defalias 'vc-svn-could-register 'vc-svn-root
 316   "Return non-nil if FILE could be registered in SVN.
 317 This is only possible if SVN is responsible for FILE's directory.")
 318
 319 (defun vc-svn-checkin (files rev comment &optional _extra-args-ignored)
 320   "SVN-specific version of `vc-backend-checkin'."
 321   (if rev (error "Committing to a specific revision is unsupported in SVN"))
 322   (let ((status (apply
 323                  'vc-svn-command nil 1 files "ci"
 324                  (nconc (list "-m" comment) (vc-switches 'SVN 'checkin)))))
 325     (set-buffer "*vc*")
 326     (goto-char (point-min))
 327     (unless (equal status 0)
 328       ;; Check checkin problem.
 329       (cond
 330        ((search-forward "Transaction is out of date" nil t)
 331         (mapc (lambda (file) (vc-file-setprop file 'vc-state 'needs-merge))
 332               files)
 333         (error (substitute-command-keys
 334                 (concat "Up-to-date check failed: "
 335                         "type \\[vc-next-action] to merge in changes"))))
 336        (t
 337         (pop-to-buffer (current-buffer))
 338         (goto-char (point-min))
 339         (shrink-window-if-larger-than-buffer)
 340         (error "Check-in failed"))))
 341     ;; Update file properties
 342     ;; (vc-file-setprop
 343     ;;  file 'vc-working-revision
 344     ;;  (vc-parse-buffer "^\\(new\\|initial\\) revision: \\([0-9.]+\\)" 2))
 345     ))
 346
 347 (defun vc-svn-find-revision (file rev buffer)
 348   "SVN-specific retrieval of a specified version into a buffer."
 349   (let (process-file-side-effects)
 350     (apply 'vc-svn-command
 351            buffer 0 file
 352            "cat"
 353            (and rev (not (string= rev ""))
 354                 (concat "-r" rev))
 355            (vc-switches 'SVN 'checkout))))
 356
 357 (defun vc-svn-ignore (file &optional directory remove)
 358   "Ignore FILE under Subversion.
 359 FILE is a file wildcard, relative to the root directory of DIRECTORY."
 360   (let* ((ignores (vc-svn-ignore-completion-table directory))
 361          (file (file-relative-name file directory))
 362          (ignores (if remove
 363                       (delete file ignores)
 364                     (push file ignores))))
 365     (vc-svn-command nil 0 nil nil "propset" "svn:ignore"
 366                     (mapconcat #'identity ignores "\n")
 367                     (expand-file-name directory))))
 368
 369 (defun vc-svn-ignore-completion-table (directory)
 370   "Return the list of ignored files in DIRECTORY."
 371   (with-temp-buffer
 372     (vc-svn-command t t nil "propget" "svn:ignore" (expand-file-name directory))
 373     (split-string (buffer-string))))
 374
 375 (defun vc-svn-find-admin-dir (file)
 376   "Return the administrative directory of FILE."
 377   (expand-file-name vc-svn-admin-directory (vc-svn-root file)))
 378
 379 (defun vc-svn-checkout (file &optional editable rev)
 380   (message "Checking out %s..." file)
 381   (with-current-buffer (or (get-file-buffer file) (current-buffer))
 382     (vc-svn-update file editable rev (vc-switches 'SVN 'checkout)))
 383   (vc-mode-line file 'SVN)
 384   (message "Checking out %s...done" file))
 385
 386 (defun vc-svn-update (file _editable rev switches)
 387   (if (and (file-exists-p file) (not rev))
 388       ;; If no revision was specified, there's nothing to do.
 389       nil
 390     ;; Check out a particular version (or recreate the file).
 391     (vc-file-setprop file 'vc-working-revision nil)
 392     (apply 'vc-svn-command nil 0 file
 393            "update"
 394            (cond
 395             ((null rev) "-rBASE")
 396             ((or (eq rev t) (equal rev "")) nil)
 397             (t (concat "-r" rev)))
 398            switches)))
 399
 400 (defun vc-svn-delete-file (file)
 401   (vc-svn-command nil 0 file "remove"))
 402
 403 (defun vc-svn-rename-file (old new)
 404   (vc-svn-command nil 0 new "move" (file-relative-name old)))
 405
 406 (defun vc-svn-revert (file &optional contents-done)
 407   "Revert FILE to the version it was based on."
 408   (unless contents-done
 409     (vc-svn-command nil 0 file "revert")))
 410
 411 (defun vc-svn-merge (file first-version &optional second-version)
 412   "Merge changes into current working copy of FILE.
 413 The changes are between FIRST-VERSION and SECOND-VERSION."
 414   (vc-svn-command nil 0 file
 415                  "merge"
 416                  "-r" (if second-version
 417                         (concat first-version ":" second-version)
 418                       first-version))
 419   (vc-file-setprop file 'vc-state 'edited)
 420   (with-current-buffer (get-buffer "*vc*")
 421     (goto-char (point-min))
 422     (if (looking-at "C  ")
 423         1                               ; signal conflict
 424       0)))                              ; signal success
 425
 426 (defun vc-svn-merge-news (file)
 427   "Merge in any new changes made to FILE."
 428   (message "Merging changes into %s..." file)
 429   ;; (vc-file-setprop file 'vc-working-revision nil)
 430   (vc-file-setprop file 'vc-checkout-time 0)
 431   (vc-svn-command nil 0 file "update")
 432   ;; Analyze the merge result reported by SVN, and set
 433   ;; file properties accordingly.
 434   (with-current-buffer (get-buffer "*vc*")
 435     (goto-char (point-min))
 436     ;; get new working revision
 437     (if (re-search-forward
 438          "^\\(Updated to\\|At\\) revision \\([0-9]+\\)" nil t)
 439         (vc-file-setprop file 'vc-working-revision (match-string 2))
 440       (vc-file-setprop file 'vc-working-revision nil))
 441     ;; get file status
 442     (goto-char (point-min))
 443     (prog1
 444         (if (looking-at "At revision")
 445             0 ;; there were no news; indicate success
 446           (if (re-search-forward
 447                ;; Newer SVN clients have 3 columns of chars (one for the
 448                ;; file's contents, then second for its properties, and the
 449                ;; third for lock-grabbing info), before the 2 spaces.
 450                ;; We also used to match the filename in column 0 without any
 451                ;; meta-info before it, but I believe this can never happen.
 452                (concat "^\\(\\([ACGDU]\\)\\(.[B ]\\)?  \\)"
 453                        (regexp-quote (file-relative-name file)))
 454                nil t)
 455               (cond
 456                ;; Merge successful, we are in sync with repository now
 457                ((string= (match-string 2) "U")
 458                 (vc-file-setprop file 'vc-state 'up-to-date)
 459                 (vc-file-setprop file 'vc-checkout-time
 460                                  (nth 5 (file-attributes file)))
 461                 0);; indicate success to the caller
 462                ;; Merge successful, but our own changes are still in the file
 463                ((string= (match-string 2) "G")
 464                 (vc-file-setprop file 'vc-state 'edited)
 465                 0);; indicate success to the caller
 466                ;; Conflicts detected!
 467                (t
 468                 (vc-file-setprop file 'vc-state 'edited)
 469                 1);; signal the error to the caller
 470                )
 471             (pop-to-buffer "*vc*")
 472             (error "Couldn't analyze svn update result")))
 473       (message "Merging changes into %s...done" file))))
 474
 475 (defun vc-svn-modify-change-comment (_files rev comment)
 476   "Modify the change comments for a specified REV.
 477 You must have ssh access to the repository host, and the directory Emacs
 478 uses locally for temp files must also be writable by you on that host.
 479 This is only supported if the repository access method is either file://
 480 or svn+ssh://."
 481   (let (tempfile host remotefile directory fileurl-p)
 482     (with-temp-buffer
 483       (vc-svn-command (current-buffer) 0 nil "info")
 484       (goto-char (point-min))
 485       (unless (re-search-forward "Repository Root: \\(file://\\(/.*\\)\\)\\|\\(svn\\+ssh://\\([^/]+\\)\\(/.*\\)\\)" nil t)
 486         (error "Repository information is unavailable"))
 487       (if (match-string 1)
 488           (progn
 489             (setq fileurl-p t)
 490             (setq directory (match-string 2)))
 491         (setq host (match-string 4))
 492         (setq directory (match-string 5))
 493         (setq remotefile (concat host ":" tempfile))))
 494     (with-temp-file (setq tempfile (make-temp-file user-mail-address))
 495       (insert comment))
 496     (if fileurl-p
 497         ;; Repository Root is a local file.
 498         (progn
 499           (unless (vc-do-command
 500                    "*vc*" 0 "svnadmin" nil
 501                    "setlog" "--bypass-hooks" directory
 502                    "-r" rev (format "%s" tempfile))
 503             (error "Log edit failed"))
 504           (delete-file tempfile))
 505
 506       ;; Remote repository, using svn+ssh.
 507       (unless (vc-do-command "*vc*" 0 "scp" nil "-q" tempfile remotefile)
 508         (error "Copy of comment to %s failed" remotefile))
 509       (unless (vc-do-command
 510                "*vc*" 0 "ssh" nil "-q" host
 511                (format "svnadmin setlog --bypass-hooks %s -r %s %s; rm %s"
 512                        directory rev tempfile tempfile))
 513         (error "Log edit failed")))))
 514
 515 ;;;
 516 ;;; History functions
 517 ;;;
 518
 519 (defvar log-view-per-file-logs)
 520
 521 (define-derived-mode vc-svn-log-view-mode log-view-mode "SVN-Log-View"
 522   (require 'add-log)
 523   (set (make-local-variable 'log-view-per-file-logs) nil))
 524
 525 (autoload 'vc-setup-buffer "vc-dispatcher")
 526
 527 (defun vc-svn-print-log (files buffer &optional _shortlog start-revision limit)
 528   "Print commit log associated with FILES into specified BUFFER.
 529 SHORTLOG is ignored.
 530 If START-REVISION is non-nil, it is the newest revision to show.
 531 If LIMIT is non-nil, show no more than this many entries."
 532   (save-current-buffer
 533     (vc-setup-buffer buffer)
 534     (let ((inhibit-read-only t))
 535       (goto-char (point-min))
 536       (if files
 537           (dolist (file files)
 538                   (insert "Working file: " file "\n")
 539                   (apply
 540                    'vc-svn-command
 541                    buffer
 542                    'async
 543                    ;; (if (and (= (length files) 1) (vc-stay-local-p file 'SVN)) 'async 0)
 544                    (list file)
 545                    "log"
 546                    (append
 547                     (list
 548                      (if start-revision
 549                          (format "-r%s:1" start-revision)
 550                        ;; By default Subversion only shows the log up to the
 551                        ;; working revision, whereas we also want the log of the
 552                        ;; subsequent commits.  At least that's what the
 553                        ;; vc-cvs.el code does.
 554                        "-rHEAD:0"))
 555                     (when limit (list "--limit" (format "%s" limit))))))
 556         ;; Dump log for the entire directory.
 557         (apply 'vc-svn-command buffer 0 nil "log"
 558                (append
 559                 (list
 560                  (if start-revision (format "-r%s" start-revision) "-rHEAD:0"))
 561                 (when limit (list "--limit" (format "%s" limit)))))))))
 562
 563 (defun vc-svn-diff (files &optional oldvers newvers buffer)
 564   "Get a difference report using SVN between two revisions of fileset FILES."
 565   (and oldvers
 566        (not newvers)
 567        files
 568        (catch 'no
 569          (dolist (f files)
 570            (or (equal oldvers (vc-working-revision f))
 571                (throw 'no nil)))
 572          t)
 573        ;; Use nil rather than the current revision because svn handles
 574        ;; it better (i.e. locally).  Note that if _any_ of the files
 575        ;; has a different revision, we fetch the lot, which is
 576        ;; obviously sub-optimal.
 577        (setq oldvers nil))
 578   (let* ((switches
 579             (if vc-svn-diff-switches
 580                 (vc-switches 'SVN 'diff)
 581               (list (concat "--diff-cmd=" diff-command) "-x"
 582                     (mapconcat 'identity (vc-switches nil 'diff) " "))))
 583            (async (and (not vc-disable-async-diff)
 584                        (vc-stay-local-p files 'SVN)
 585                        (or oldvers newvers)))) ; Svn diffs those locally.
 586       (apply 'vc-svn-command buffer
 587              (if async 'async 0)
 588              files "diff"
 589              (append
 590               switches
 591               (when oldvers
 592                 (list "-r" (if newvers (concat oldvers ":" newvers)
 593                              oldvers)))))
 594       (if async 1                     ; async diff => pessimistic assumption
 595         ;; For some reason `svn diff' does not return a useful
 596         ;; status w.r.t whether the diff was empty or not.
 597         (buffer-size (get-buffer buffer)))))
 598
 599 ;;;
 600 ;;; Tag system
 601 ;;;
 602
 603 (defun vc-svn-create-tag (dir name branchp)
 604   "Assign to DIR's current revision a given NAME.
 605 If BRANCHP is non-nil, the name is created as a branch (and the current
 606 workspace is immediately moved to that new branch).
 607 NAME is assumed to be a URL."
 608   (vc-svn-command nil 0 dir "copy" name)
 609   (when branchp (vc-svn-retrieve-tag dir name nil)))
 610
 611 (defun vc-svn-retrieve-tag (dir name _update)
 612   "Retrieve a tag at and below DIR.
 613 NAME is the name of the tag; if it is empty, do a `svn update'.
 614 If UPDATE is non-nil, then update (resynch) any affected buffers.
 615 NAME is assumed to be a URL."
 616   (vc-svn-command nil 0 dir "switch" name)
 617   ;; FIXME: parse the output and obey `update'.
 618   )
 619
 620 ;;;
 621 ;;; Miscellaneous
 622 ;;;
 623
 624 ;; Subversion makes backups for us, so don't bother.
 625 ;; (defun vc-svn-make-version-backups-p (file)
 626 ;;   "Return non-nil if version backups should be made for FILE."
 627 ;;  (vc-stay-local-p file 'SVN))
 628
 629 (defun vc-svn-check-headers ()
 630   "Check if the current file has any headers in it."
 631   (save-excursion
 632     (goto-char (point-min))
 633     (re-search-forward "\\$[A-Za-z\300-\326\330-\366\370-\377]+\
 634 \\(: [\t -#%-\176\240-\377]*\\)?\\$" nil t)))
 635
 636
 637 ;;;
 638 ;;; Internal functions
 639 ;;;
 640
 641 (defun vc-svn-command (buffer okstatus file-or-list &rest flags)
 642   "A wrapper around `vc-do-command' for use in vc-svn.el.
 643 The difference to vc-do-command is that this function always invokes `svn',
 644 and that it passes `vc-svn-global-switches' to it before FLAGS."
 645   (apply 'vc-do-command (or buffer "*vc*") okstatus vc-svn-program file-or-list
 646          (if (stringp vc-svn-global-switches)
 647              (cons vc-svn-global-switches flags)
 648            (append vc-svn-global-switches flags))))
 649
 650 (defun vc-svn-repository-hostname (dirname)
 651   (with-temp-buffer
 652     (let (process-file-side-effects)
 653       (vc-svn-command t t dirname "info" "--xml"))
 654     (goto-char (point-min))
 655     (when (re-search-forward "<url>\\(.*\\)</url>" nil t)
 656       ;; This is not a hostname but a URL.  This may actually be considered
 657       ;; as a feature since it allows vc-svn-stay-local to specify different
 658       ;; behavior for different modules on the same server.
 659       (match-string 1))))
 660
 661 (defun vc-svn-resolve-when-done ()
 662   "Call \"svn resolved\" if the conflict markers have been removed."
 663   (save-excursion
 664     (goto-char (point-min))
 665     (unless (re-search-forward "^<<<<<<< " nil t)
 666       (vc-svn-command nil 0 buffer-file-name "resolved")
 667       ;; Remove the hook so that it is not called multiple times.
 668       (remove-hook 'after-save-hook 'vc-svn-resolve-when-done t))))
 669
 670 ;; Inspired by vc-arch-find-file-hook.
 671 (defun vc-svn-find-file-hook ()
 672   (when (eq ?C (vc-file-getprop buffer-file-name 'vc-svn-status))
 673     ;; If the file is marked as "conflicted", then we should try and call
 674     ;; "svn resolved" when applicable.
 675     (if (save-excursion
 676           (goto-char (point-min))
 677           (re-search-forward "^<<<<<<< " nil t))
 678         ;; There are conflict markers.
 679         (progn
 680           (smerge-start-session)
 681           (add-hook 'after-save-hook 'vc-svn-resolve-when-done nil t))
 682       ;; There are no conflict markers.  This is problematic: maybe it means
 683       ;; the conflict has been resolved and we should immediately call "svn
 684       ;; resolved", or it means that the file's type does not allow Svn to
 685       ;; use conflict markers in which case we don't really know what to do.
 686       ;; So let's just punt for now.
 687       nil)
 688     (message "There are unresolved conflicts in this file")))
 689
 690 (defun vc-svn-parse-status (&optional filename)
 691   "Parse output of \"svn status\" command in the current buffer.
 692 Set file properties accordingly.  If FILENAME is non-nil, return its status."
 693   (let (multifile file status propstat)
 694     (goto-char (point-min))
 695     (while (re-search-forward
 696             ;; Ignore the files with status X.
 697             "^\\(?:\\?\\|[ ACDGIMR!~][ MC][ L][ +][ S]..\\([ *]\\) +\\([-0-9]+\\) +\\([0-9?]+\\) +\\([^ ]+\\)\\) +" nil t)
 698       ;; If the username contains spaces, the output format is ambiguous,
 699       ;; so don't trust the output's filename unless we have to.
 700       (setq file (or (unless multifile filename)
 701                      (expand-file-name
 702                       (buffer-substring (point) (line-end-position))))
 703             ;; If we are parsing the result of running status on a directory,
 704             ;; there could be multiple files in the output.
 705             ;; We assume that filename, if supplied, applies to the first
 706             ;; listed file (ie, the directory).  Bug#15322.
 707             multifile t
 708             status (char-after (line-beginning-position))
 709             ;; Status of the item's properties ([ MC]).
 710             propstat (char-after (1+ (line-beginning-position))))
 711       (if (eq status ??)
 712           (vc-file-setprop file 'vc-state 'unregistered)
 713         ;; Use the last-modified revision, so that searching in vc-print-log
 714         ;; output works.
 715         (vc-file-setprop file 'vc-working-revision (match-string 3))
 716         ;; Remember Svn's own status.
 717         (vc-file-setprop file 'vc-svn-status status)
 718         (vc-file-setprop
 719          file 'vc-state
 720          (cond
 721           ((and (eq status ?\ ) (eq propstat ?\ ))
 722            (if (eq (char-after (match-beginning 1)) ?*)
 723                'needs-update
 724              (vc-file-setprop file 'vc-checkout-time
 725                               (nth 5 (file-attributes file)))
 726              'up-to-date))
 727           ((eq status ?A)
 728            ;; If the file was actually copied, (match-string 2) is "-".
 729            (vc-file-setprop file 'vc-working-revision "0")
 730            (vc-file-setprop file 'vc-checkout-time 0)
 731            'added)
 732           ;; Conflict in contents or properties.
 733           ((or (eq status ?C) (eq propstat ?C))
 734            (vc-file-setprop file 'vc-state 'conflict))
 735           ;; Modified contents or properties.
 736           ((or (eq status ?M) (eq propstat ?M))
 737            (if (eq (char-after (match-beginning 1)) ?*)
 738                'needs-merge
 739              'edited))
 740           ((eq status ?I)
 741            (vc-file-setprop file 'vc-state 'ignored))
 742           ((memq status '(?D ?R))
 743            (vc-file-setprop file 'vc-state 'removed))
 744           (t 'edited)))))
 745     (when filename (vc-file-getprop filename 'vc-state))))
 746
 747 (defun vc-svn-valid-symbolic-tag-name-p (tag)
 748   "Return non-nil if TAG is a valid symbolic tag name."
 749   ;; According to the SVN manual, a valid symbolic tag must start with
 750   ;; an uppercase or lowercase letter and can contain uppercase and
 751   ;; lowercase letters, digits, `-', and `_'.
 752   (and (string-match "^[a-zA-Z]" tag)
 753        (not (string-match "[^a-z0-9A-Z-_]" tag))))
 754
 755 (defun vc-svn-valid-revision-number-p (tag)
 756   "Return non-nil if TAG is a valid revision number."
 757   (and (string-match "^[0-9]" tag)
 758        (not (string-match "[^0-9]" tag))))
 759
 760 ;; Support for `svn annotate'
 761
 762 (defun vc-svn-annotate-command (file buf &optional rev)
 763   (vc-svn-command buf 'async file "annotate" (if rev (concat "-r" rev))))
 764
 765 (defun vc-svn-annotate-time-of-rev (rev)
 766   ;; Arbitrarily assume 10 commits per day.
 767   (/ (string-to-number rev) 10.0))
 768
 769 (defvar vc-annotate-parent-rev)
 770
 771 (defun vc-svn-annotate-current-time ()
 772   (vc-svn-annotate-time-of-rev vc-annotate-parent-rev))
 773
 774 (defconst vc-svn-annotate-re "[ \t]*\\([0-9]+\\)[ \t]+[^\t ]+ ")
 775
 776 (defun vc-svn-annotate-time ()
 777   (when (looking-at vc-svn-annotate-re)
 778     (goto-char (match-end 0))
 779     (vc-svn-annotate-time-of-rev (match-string 1))))
 780
 781 (defun vc-svn-annotate-extract-revision-at-line ()
 782   (save-excursion
 783     (beginning-of-line)
 784     (if (looking-at vc-svn-annotate-re) (match-string 1))))
 785
 786 (defun vc-svn-revision-table (files)
 787   (let ((vc-svn-revisions '()))
 788     (with-current-buffer "*vc*"
 789       (vc-svn-command nil 0 files "log" "-q")
 790       (goto-char (point-min))
 791       (forward-line)
 792       (let ((start (point-min))
 793             (loglines (buffer-substring-no-properties (point-min)
 794                                                       (point-max))))
 795         (while (string-match "^r\\([0-9]+\\) " loglines)
 796           (push (match-string 1 loglines) vc-svn-revisions)
 797           (setq start (+ start (match-end 0)))
 798           (setq loglines (buffer-substring-no-properties start (point-max)))))
 799     vc-svn-revisions)))
 800
 801 (provide 'vc-svn)
 802
 803 ;;; vc-svn.el ends here