code.delx.au - gnu-emacs/blob - lisp/autoinsert.el

   1 ;;; autoinsert.el --- automatic mode-dependent insertion of text into new files
   2
   3 ;; Copyright (C) 1985-1987, 1994-1995, 1998, 2000-2011 Free Software Foundation, Inc.
   4
   5 ;; Author: Charlie Martin <crm@cs.duke.edu>
   6 ;; Adapted-By: Daniel Pfeiffer <occitan@esperanto.org>
   7 ;; Keywords: convenience
   8 ;; Maintainer: FSF
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;;  The following defines an association list for text to be
  28 ;;  automatically inserted when a new file is created, and a function
  29 ;;  which automatically inserts these files; the idea is to insert
  30 ;;  default text much as the mode is automatically set using
  31 ;;  auto-mode-alist.
  32 ;;
  33 ;;  To use:
  34 ;;     (add-hook 'find-file-hook 'auto-insert)
  35 ;;     setq auto-insert-directory to an appropriate slash-terminated value
  36 ;;
  37 ;;  You can also customize the variable `auto-insert-mode' to load the
  38 ;;  package.  Alternatively, add the following to your .emacs file:
  39 ;;  (auto-insert-mode 1)
  40 ;;
  41 ;;  Author:  Charlie Martin
  42 ;;           Department of Computer Science and
  43 ;;           National Biomedical Simulation Resource
  44 ;;           Box 3709
  45 ;;           Duke University Medical Center
  46 ;;           Durham, NC 27710
  47 ;;            (crm@cs.duke.edu,mcnc!duke!crm)
  48
  49 ;;; Code:
  50
  51 (defgroup auto-insert nil
  52   "Automatic mode-dependent insertion of text into new files."
  53   :prefix "auto-insert-"
  54   :group 'files
  55   :group 'convenience
  56   :link '(custom-manual "(autotype) Autoinserting"))
  57
  58
  59 (defcustom auto-insert 'not-modified
  60   "Controls automatic insertion into newly found empty files.
  61 Possible values:
  62         nil     do nothing
  63         t       insert if possible
  64         other   insert if possible, but mark as unmodified.
  65 Insertion is possible when something appropriate is found in
  66 `auto-insert-alist'.  When the insertion is marked as unmodified, you can
  67 save it with  \\[write-file] RET.
  68 This variable is used when the function `auto-insert' is called, e.g.
  69 when you do (add-hook 'find-file-hook 'auto-insert).
  70 With \\[auto-insert], this is always treated as if it were t."
  71   :type '(choice (const :tag "Insert if possible" t)
  72                  (const :tag "Do nothing" nil)
  73                  (other :tag "insert if possible, mark as unmodified."
  74                         not-modified))
  75   :group 'auto-insert)
  76
  77 (defcustom auto-insert-query 'function
  78   "Non-nil means ask user before auto-inserting.
  79 When this is `function', only ask when called non-interactively."
  80   :type '(choice (const :tag "Don't ask" nil)
  81                  (const :tag "Ask if called non-interactively" function)
  82                  (other :tag "Ask" t))
  83   :group 'auto-insert)
  84
  85 (defcustom auto-insert-prompt "Perform %s auto-insertion? "
  86   "Prompt to use when querying whether to auto-insert.
  87 If this contains a %s, that will be replaced by the matching rule."
  88   :type 'string
  89   :group 'auto-insert)
  90
  91
  92 (defcustom auto-insert-alist
  93   '((("\\.\\([Hh]\\|hh\\|hpp\\)\\'" . "C / C++ header")
  94      (upcase (concat (file-name-nondirectory
  95                       (file-name-sans-extension buffer-file-name))
  96                      "_"
  97                      (file-name-extension buffer-file-name)))
  98      "#ifndef " str \n
  99      "#define " str "\n\n"
 100      _ "\n\n#endif")
 101
 102     (("\\.\\([Cc]\\|cc\\|cpp\\)\\'" . "C / C++ program")
 103      nil
 104      "#include \""
 105      (let ((stem (file-name-sans-extension buffer-file-name)))
 106        (cond ((file-exists-p (concat stem ".h"))
 107               (file-name-nondirectory (concat stem ".h")))
 108              ((file-exists-p (concat stem ".hh"))
 109               (file-name-nondirectory (concat stem ".hh")))))
 110      & ?\" | -10)
 111
 112     (("[Mm]akefile\\'" . "Makefile") . "makefile.inc")
 113
 114     (html-mode . (lambda () (sgml-tag "html")))
 115
 116     (plain-tex-mode . "tex-insert.tex")
 117     (bibtex-mode . "tex-insert.tex")
 118     (latex-mode
 119      ;; should try to offer completing read for these
 120      "options, RET: "
 121      "\\documentclass[" str & ?\] | -1
 122      ?{ (read-string "class: ") "}\n"
 123      ("package, %s: "
 124       "\\usepackage[" (read-string "options, RET: ") & ?\] | -1 ?{ str "}\n")
 125      _ "\n\\begin{document}\n" _
 126      "\n\\end{document}")
 127
 128     (("/bin/.*[^/]\\'" . "Shell-Script mode magic number") .
 129      (lambda ()
 130        (if (eq major-mode (default-value 'major-mode))
 131            (sh-mode))))
 132
 133     (ada-mode . ada-header)
 134
 135     (("\\.[1-9]\\'" . "Man page skeleton")
 136      "Short description: "
 137      ".\\\" Copyright (C), " (substring (current-time-string) -4) "  "
 138      (getenv "ORGANIZATION") | (progn user-full-name)
 139      "
 140 .\\\" You may distribute this file under the terms of the GNU Free
 141 .\\\" Documentation License.
 142 .TH " (file-name-sans-extension (file-name-nondirectory (buffer-file-name)))
 143      " " (file-name-extension (buffer-file-name))
 144      " " (format-time-string "%Y-%m-%d ")
 145      "\n.SH NAME\n"
 146      (file-name-sans-extension (file-name-nondirectory (buffer-file-name)))
 147      " \\- " str
 148      "\n.SH SYNOPSIS
 149 .B " (file-name-sans-extension (file-name-nondirectory (buffer-file-name)))
 150      "\n"
 151      _
 152      "
 153 .SH DESCRIPTION
 154 .SH OPTIONS
 155 .SH FILES
 156 .SH \"SEE ALSO\"
 157 .SH BUGS
 158 .SH AUTHOR
 159 " (user-full-name)
 160      '(if (search-backward "&" (line-beginning-position) t)
 161           (replace-match (capitalize (user-login-name)) t t))
 162      '(end-of-line 1) " <" (progn user-mail-address) ">\n")
 163
 164     (("\\.el\\'" . "Emacs Lisp header")
 165      "Short description: "
 166      ";;; " (file-name-nondirectory (buffer-file-name)) " --- " str "
 167
 168 ;; Copyright (C) " (substring (current-time-string) -4) "  "
 169  (getenv "ORGANIZATION") | (progn user-full-name) "
 170
 171 ;; Author: " (user-full-name)
 172 '(if (search-backward "&" (line-beginning-position) t)
 173      (replace-match (capitalize (user-login-name)) t t))
 174 '(end-of-line 1) " <" (progn user-mail-address) ">
 175 ;; Keywords: "
 176  '(require 'finder)
 177  ;;'(setq v1 (apply 'vector (mapcar 'car finder-known-keywords)))
 178  '(setq v1 (mapcar (lambda (x) (list (symbol-name (car x))))
 179                    finder-known-keywords)
 180         v2 (mapconcat (lambda (x) (format "%12s:  %s" (car x) (cdr x)))
 181            finder-known-keywords
 182            "\n"))
 183  ((let ((minibuffer-help-form v2))
 184     (completing-read "Keyword, C-h: " v1 nil t))
 185     str ", ") & -2 "
 186
 187 \;; This program is free software; you can redistribute it and/or modify
 188 \;; it under the terms of the GNU General Public License as published by
 189 \;; the Free Software Foundation, either version 3 of the License, or
 190 \;; (at your option) any later version.
 191
 192 \;; This program is distributed in the hope that it will be useful,
 193 \;; but WITHOUT ANY WARRANTY; without even the implied warranty of
 194 \;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 195 \;; GNU General Public License for more details.
 196
 197 \;; You should have received a copy of the GNU General Public License
 198 \;; along with this program.  If not, see <http://www.gnu.org/licenses/>.
 199
 200 \;;; Commentary:
 201
 202 \;; " _ "
 203
 204 \;;; Code:
 205
 206
 207
 208 \(provide '"
 209        (file-name-sans-extension (file-name-nondirectory (buffer-file-name)))
 210        ")
 211 \;;; " (file-name-nondirectory (buffer-file-name)) " ends here\n")
 212     (("\\.texi\\(nfo\\)?\\'" . "Texinfo file skeleton")
 213      "Title: "
 214      "\\input texinfo   @c -*-texinfo-*-
 215 @c %**start of header
 216 @setfilename "
 217      (file-name-sans-extension
 218       (file-name-nondirectory (buffer-file-name))) ".info\n"
 219       "@settitle " str "
 220 @c %**end of header
 221 @copying\n"
 222       (setq short-description (read-string "Short description: "))
 223       ".\n\n"
 224       "Copyright @copyright{} " (substring (current-time-string) -4) "  "
 225       (getenv "ORGANIZATION") | (progn user-full-name) "
 226
 227 @quotation
 228 Permission is granted to copy, distribute and/or modify this document
 229 under the terms of the GNU Free Documentation License, Version 1.3
 230 or any later version published by the Free Software Foundation;
 231 with no Invariant Sections, no Front-Cover Texts, and no Back-Cover Texts.
 232 A copy of the license is included in the section entitled ``GNU
 233 Free Documentation License''.
 234
 235 A copy of the license is also available from the Free Software
 236 Foundation Web site at @url{http://www.gnu.org/licenses/fdl.html}.
 237
 238 @end quotation
 239
 240 The document was typeset with
 241 @uref{http://www.texinfo.org/, GNU Texinfo}.
 242
 243 @end copying
 244
 245 @titlepage
 246 @title " str "
 247 @subtitle " short-description "
 248 @author " (getenv "ORGANIZATION") | (progn user-full-name)
 249      " <" (progn user-mail-address) ">
 250 @page
 251 @vskip 0pt plus 1filll
 252 @insertcopying
 253 @end titlepage
 254
 255 @c Output the table of the contents at the beginning.
 256 @contents
 257
 258 @ifnottex
 259 @node Top
 260 @top " str "
 261
 262 @insertcopying
 263 @end ifnottex
 264
 265 @c Generate the nodes for this menu with `C-c C-u C-m'.
 266 @menu
 267 @end menu
 268
 269 @c Update all node entries with `C-c C-u C-n'.
 270 @c Insert new nodes with `C-c C-c n'.
 271 @node Chapter One
 272 @chapter Chapter One
 273
 274 " _ "
 275
 276 @node Copying This Manual
 277 @appendix Copying This Manual
 278
 279 @menu
 280 * GNU Free Documentation License::  License for copying this manual.
 281 @end menu
 282
 283 @c Get fdl.texi from http://www.gnu.org/licenses/fdl.html
 284 @include fdl.texi
 285
 286 @node Index
 287 @unnumbered Index
 288
 289 @printindex cp
 290
 291 @bye
 292
 293 @c " (file-name-nondirectory (buffer-file-name)) " ends here\n"))
 294   "A list specifying text to insert by default into a new file.
 295 Elements look like (CONDITION . ACTION) or ((CONDITION . DESCRIPTION) . ACTION).
 296 CONDITION may be a regexp that must match the new file's name, or it may be
 297 a symbol that must match the major mode for this element to apply.
 298 Only the first matching element is effective.
 299 Optional DESCRIPTION is a string for filling `auto-insert-prompt'.
 300 ACTION may be a skeleton to insert (see `skeleton-insert'), an absolute
 301 file-name or one relative to `auto-insert-directory' or a function to call.
 302 ACTION may also be a vector containing several successive single actions as
 303 described above, e.g. [\"header.insert\" date-and-author-update]."
 304   :type 'sexp
 305   :group 'auto-insert)
 306
 307
 308 ;; Establish a default value for auto-insert-directory
 309 (defcustom auto-insert-directory "~/insert/"
 310   "Directory from which auto-inserted files are taken.
 311 The value must be an absolute directory name;
 312 thus, on a GNU or Unix system, it must end in a slash."
 313   :type 'directory
 314   :group 'auto-insert)
 315
 316
 317 ;;;###autoload
 318 (defun auto-insert ()
 319   "Insert default contents into new files if variable `auto-insert' is non-nil.
 320 Matches the visited file name against the elements of `auto-insert-alist'."
 321   (interactive)
 322   (and (not buffer-read-only)
 323        (or (eq this-command 'auto-insert)
 324            (and auto-insert
 325                 (bobp) (eobp)))
 326        (let ((alist auto-insert-alist)
 327              case-fold-search cond desc action)
 328          (goto-char 1)
 329          ;; find first matching alist entry
 330          (while alist
 331            (if (atom (setq cond (car (car alist))))
 332                (setq desc cond)
 333              (setq desc (cdr cond)
 334                    cond (car cond)))
 335            (if (if (symbolp cond)
 336                    (eq cond major-mode)
 337                  (and buffer-file-name
 338                       (string-match cond buffer-file-name)))
 339                (setq action (cdr (car alist))
 340                      alist nil)
 341              (setq alist (cdr alist))))
 342
 343          ;; Now, if we found something, do it
 344          (and action
 345               (or (not (stringp action))
 346                   (file-readable-p (expand-file-name
 347                                     action auto-insert-directory)))
 348               (or (not auto-insert-query)
 349                   (if (eq auto-insert-query 'function)
 350                       (eq this-command 'auto-insert))
 351                   (y-or-n-p (format auto-insert-prompt desc)))
 352               (mapc
 353                (lambda (action)
 354                  (if (stringp action)
 355                      (if (file-readable-p
 356                           (setq action (expand-file-name
 357                                         action auto-insert-directory)))
 358                          (insert-file-contents action))
 359                    (save-window-excursion
 360                      ;; make buffer visible before skeleton or function
 361                      ;; which might ask the user for something
 362                      (switch-to-buffer (current-buffer))
 363                      (if (and (consp action)
 364                               (not (eq (car action) 'lambda)))
 365                          (skeleton-insert action)
 366                        (funcall action)))))
 367                (if (vectorp action)
 368                    action
 369                  (vector action))))
 370          (and (buffer-modified-p)
 371               (not (eq this-command 'auto-insert))
 372               (set-buffer-modified-p (eq auto-insert t)))))
 373   ;; Return nil so that it could be used in
 374   ;; `find-file-not-found-hooks', though that's probably inadvisable.
 375   nil)
 376
 377
 378 ;;;###autoload
 379 (defun define-auto-insert (condition action &optional after)
 380   "Associate CONDITION with (additional) ACTION in `auto-insert-alist'.
 381 Optional AFTER means to insert action after all existing actions for CONDITION,
 382 or if CONDITION had no actions, after all other CONDITIONs."
 383   (let ((elt (assoc condition auto-insert-alist)))
 384     (if elt
 385         (setcdr elt
 386                 (if (vectorp (cdr elt))
 387                     (vconcat (if after (cdr elt))
 388                              (if (vectorp action) action (vector action))
 389                              (if after () (cdr elt)))
 390                   (if after
 391                       (vector (cdr elt) action)
 392                     (vector action (cdr elt)))))
 393       (if after
 394           (nconc auto-insert-alist (list (cons condition action)))
 395         (push (cons condition action) auto-insert-alist)))))
 396
 397 ;;;###autoload
 398 (define-minor-mode auto-insert-mode
 399   "Toggle Auto-insert mode.
 400 With prefix ARG, turn Auto-insert mode on if and only if ARG is positive.
 401 Returns the new status of Auto-insert mode (non-nil means on).
 402
 403 When Auto-insert mode is enabled, when new files are created you can
 404 insert a template for the file depending on the mode of the buffer."
 405   :global t :group 'auto-insert
 406   (if auto-insert-mode
 407       (add-hook 'find-file-hook 'auto-insert)
 408     (remove-hook 'find-file-hook 'auto-insert)))
 409
 410 (provide 'autoinsert)
 411
 412 ;;; autoinsert.el ends here