code.delx.au - gnu-emacs/blob - lisp/emacs-lisp/elint.el

   1 ;;; elint.el --- Lint Emacs Lisp
   2
   3 ;; Copyright (C) 1997, 2001-2011  Free Software Foundation, Inc.
   4
   5 ;; Author: Peter Liljenberg <petli@lysator.liu.se>
   6 ;; Created: May 1997
   7 ;; Keywords: lisp
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; This is a linter for Emacs Lisp.  Currently, it mainly catches
  27 ;; misspellings and undefined variables, although it can also catch
  28 ;; function calls with the wrong number of arguments.
  29
  30 ;; To use, call elint-current-buffer or elint-defun to lint a buffer
  31 ;; or defun.  The first call runs `elint-initialize' to set up some
  32 ;; argument data, which may take a while.
  33
  34 ;; The linter will try to "include" any require'd libraries to find
  35 ;; the variables defined in those.  There is a fair amount of voodoo
  36 ;; involved in this, but it seems to work in normal situations.
  37
  38 ;;; To do:
  39
  40 ;; * Adding type checking. (Stop that sniggering!)
  41 ;; * Make eval-when-compile be sensitive to the difference between
  42 ;;   funcs and macros.
  43 ;; * Requires within function bodies.
  44 ;; * Handle defstruct.
  45 ;; * Prevent recursive requires.
  46
  47 ;;; Code:
  48
  49 (defgroup elint nil
  50   "Linting for Emacs Lisp."
  51   :prefix "elint-"
  52   :group 'maint)
  53
  54 (defcustom elint-log-buffer "*Elint*"
  55   "The buffer in which to log lint messages."
  56   :type 'string
  57   :safe 'stringp
  58   :group 'elint)
  59
  60 (defcustom elint-scan-preloaded t
  61   "Non-nil means to scan `preloaded-file-list' when initializing.
  62 Otherwise, just scan the DOC file for functions and variables.
  63 This is faster, but less accurate, since it misses undocumented features.
  64 This may result in spurious warnings about unknown functions, etc."
  65   :type 'boolean
  66   :safe 'booleanp
  67   :group 'elint
  68   :version "23.2")
  69
  70 (defcustom elint-ignored-warnings nil
  71   "If non-nil, a list of issue types that Elint should ignore.
  72 This is useful if Elint has trouble understanding your code and
  73 you need to suppress lots of spurious warnings.  The valid list elements
  74 are as follows, and suppress messages about the indicated features:
  75   undefined-functions - calls to unknown functions
  76   unbound-reference   - reference to unknown variables
  77   unbound-assignment  - assignment to unknown variables
  78   macro-expansions    - failure to expand macros
  79   empty-let           - let-bindings with empty variable lists"
  80   :type '(choice (const :tag "Don't suppress any warnings" nil)
  81                  (repeat :tag "List of issues to ignore"
  82                          (choice (const undefined-functions
  83                                         :tag "Calls to unknown functions")
  84                                  (const unbound-reference
  85                                         :tag "Reference to unknown variables")
  86                                  (const unbound-assignment
  87                                         :tag "Assignment to unknown variables")
  88                                  (const macro-expansion
  89                                         :tag "Failure to expand macros")
  90                                  (const empty-let
  91                                         :tag "Let-binding with empty varlist"))))
  92   :safe (lambda (value) (or (null value)
  93                             (and (listp value)
  94                                  (equal value
  95                                         (mapcar
  96                                          (lambda (e)
  97                                            (if (memq e
  98                                                      '(undefined-functions
  99                                                        unbound-reference
 100                                                        unbound-assignment
 101                                                        macro-expansion
 102                                                        empty-let))
 103                                                e))
 104                                          value)))))
 105   :version "23.2"
 106   :group 'elint)
 107
 108 (defcustom elint-directory-skip-re "\\(ldefs-boot\\|loaddefs\\)\\.el\\'"
 109   "If nil, a regexp matching files to skip when linting a directory."
 110   :type '(choice (const :tag "Lint all files" nil)
 111                  (regexp :tag "Regexp to skip"))
 112   :safe 'string-or-null-p
 113   :group 'elint
 114   :version "23.2")
 115
 116 ;;;
 117 ;;; Data
 118 ;;;
 119
 120 (defconst elint-standard-variables
 121   ;; Most of these are defined in C with no documentation.
 122   ;; FIXME I don't see why they shouldn't just get doc-strings.
 123   '(vc-mode local-write-file-hooks activate-menubar-hook buffer-name-history
 124             coding-system-history extended-command-history
 125             kbd-macro-termination-hook read-expression-history
 126             yes-or-no-p-history)
 127   "Standard variables, excluding `elint-builtin-variables'.
 128 These are variables that we cannot detect automatically for some reason.")
 129
 130 (defvar elint-builtin-variables nil
 131   "List of built-in variables.  Set by `elint-initialize'.
 132 This is actually all those documented in the DOC file, which includes
 133 built-in variables and those from dumped Lisp files.")
 134
 135 (defvar elint-autoloaded-variables nil
 136   "List of `loaddefs.el' variables.  Set by `elint-initialize'.")
 137
 138 (defvar elint-preloaded-env nil
 139   "Environment defined by the preloaded (dumped) Lisp files.
 140 Set by `elint-initialize', if `elint-scan-preloaded' is non-nil.")
 141
 142 (defconst elint-unknown-builtin-args
 143   ;; encode-time allows extra arguments for use with decode-time.
 144   ;; For some reason, some people seem to like to use them in other cases.
 145   '((encode-time second minute hour day month year &rest zone))
 146   "Those built-ins for which we can't find arguments, if any.")
 147
 148 (defvar elint-extra-errors '(file-locked file-supersession ftp-error)
 149   "Errors without `error-message' or `error-conditions' properties.")
 150
 151 (defconst elint-preloaded-skip-re
 152   (regexp-opt '("loaddefs.el" "loadup.el" "cus-start" "language/"
 153                 "eucjp-ms" "mule-conf" "/characters" "/charprop"
 154                 "cp51932"))
 155   "Regexp matching elements of `preloaded-file-list' to ignore.
 156 We ignore them because they contain no definitions of use to Elint.")
 157
 158 ;;;
 159 ;;; ADT: top-form
 160 ;;;
 161
 162 (defsubst elint-make-top-form (form pos)
 163   "Create a top form.
 164 FORM is the form, and POS is the point where it starts in the buffer."
 165   (cons form pos))
 166
 167 (defsubst elint-top-form-form (top-form)
 168   "Extract the form from a TOP-FORM."
 169   (car top-form))
 170
 171 (defsubst elint-top-form-pos (top-form)
 172   "Extract the position from a TOP-FORM."
 173   (cdr top-form))
 174
 175 ;;;
 176 ;;; ADT: env
 177 ;;;
 178
 179 (defsubst elint-make-env ()
 180   "Create an empty environment."
 181   (list (list nil) nil nil))
 182
 183 (defsubst elint-env-add-env (env newenv)
 184   "Augment ENV with NEWENV.
 185 None of them is modified, and the new env is returned."
 186   (list (append (car env) (car newenv))
 187         (append (cadr env) (cadr newenv))
 188         (append (car (cdr (cdr env))) (car (cdr (cdr newenv))))))
 189
 190 (defsubst elint-env-add-var (env var)
 191   "Augment ENV with the variable VAR.
 192 The new environment is returned, the old is unmodified."
 193   (cons (cons (list var) (car env)) (cdr env)))
 194
 195 (defsubst elint-env-add-global-var (env var)
 196   "Augment ENV with the variable VAR.
 197 ENV is modified so VAR is seen everywhere.
 198 ENV is returned."
 199   (nconc (car env) (list (list var)))
 200   env)
 201
 202 (defsubst elint-env-find-var (env var)
 203   "Non-nil if ENV contains the variable VAR.
 204 Actually, a list with VAR as a single element is returned."
 205   (assq var (car env)))
 206
 207 (defsubst elint-env-add-func (env func args)
 208   "Augment ENV with the function FUNC, which has the arguments ARGS.
 209 The new environment is returned, the old is unmodified."
 210   (list (car env)
 211         (cons (list func args) (cadr env))
 212         (car (cdr (cdr env)))))
 213
 214 (defsubst elint-env-find-func (env func)
 215   "Non-nil if ENV contains the function FUNC.
 216 Actually, a list of (FUNC ARGS) is returned."
 217   (assq func (cadr env)))
 218
 219 (defsubst elint-env-add-macro (env macro def)
 220   "Augment ENV with the macro named MACRO.
 221 DEF is the macro definition (a lambda expression or similar).
 222 The new environment is returned, the old is unmodified."
 223   (list (car env)
 224         (cadr env)
 225         (cons (cons macro def) (car (cdr (cdr env))))))
 226
 227 (defsubst elint-env-macro-env (env)
 228   "Return the macro environment of ENV.
 229 This environment can be passed to `macroexpand'."
 230   (car (cdr (cdr env))))
 231
 232 (defsubst elint-env-macrop (env macro)
 233   "Non-nil if ENV contains MACRO."
 234   (assq macro (elint-env-macro-env env)))
 235
 236 ;;;
 237 ;;; User interface
 238 ;;;
 239
 240 ;;;###autoload
 241 (defun elint-file (file)
 242   "Lint the file FILE."
 243   (interactive "fElint file: ")
 244   (setq file (expand-file-name file))
 245   (or elint-builtin-variables
 246       (elint-initialize))
 247   (let ((dir (file-name-directory file)))
 248     (let ((default-directory dir))
 249       (elint-display-log))
 250     (elint-set-mode-line t)
 251     (with-current-buffer elint-log-buffer
 252       (unless (string-equal default-directory dir)
 253         (elint-log-message (format "\f\nLeaving directory `%s'"
 254                                    default-directory) t)
 255         (elint-log-message (format "Entering directory `%s'" dir) t)
 256         (setq default-directory dir))))
 257   (let ((str (format "Linting file %s" file)))
 258     (message "%s..." str)
 259     (or noninteractive
 260         (elint-log-message (format "\f\n%s at %s" str (current-time-string)) t))
 261     ;; elint-current-buffer clears log.
 262     (with-temp-buffer
 263       (insert-file-contents file)
 264       (let ((buffer-file-name file)
 265             (max-lisp-eval-depth (max 1000 max-lisp-eval-depth)))
 266         (with-syntax-table emacs-lisp-mode-syntax-table
 267           (mapc 'elint-top-form (elint-update-env)))))
 268     (elint-set-mode-line)
 269     (message "%s...done" str)))
 270
 271 ;; cf byte-recompile-directory.
 272 ;;;###autoload
 273 (defun elint-directory (directory)
 274   "Lint all the .el files in DIRECTORY.
 275 A complicated directory may require a lot of memory."
 276   (interactive "DElint directory: ")
 277   (let ((elint-running t))
 278     (dolist (file (directory-files directory t))
 279       ;; Bytecomp has emacs-lisp-file-regexp.
 280       (when (and (string-match "\\.el\\'" file)
 281                  (file-readable-p file)
 282                  (not (auto-save-file-name-p file)))
 283         (if (string-match elint-directory-skip-re file)
 284             (message "Skipping file %s" file)
 285           (elint-file file)))))
 286   (elint-set-mode-line))
 287
 288 ;;;###autoload
 289 (defun elint-current-buffer ()
 290   "Lint the current buffer.
 291 If necessary, this first calls `elint-initialize'."
 292   (interactive)
 293   (or elint-builtin-variables
 294       (elint-initialize))
 295   (elint-clear-log (format "Linting %s" (or (buffer-file-name)
 296                                             (buffer-name))))
 297   (elint-display-log)
 298   (elint-set-mode-line t)
 299   (mapc 'elint-top-form (elint-update-env))
 300   ;; Tell the user we're finished.  This is terribly klugy: we set
 301     ;; elint-top-form-logged so elint-log-message doesn't print the
 302     ;; ** top form ** header...
 303   (elint-set-mode-line)
 304   (elint-log-message "\nLinting finished.\n" t))
 305
 306
 307 ;;;###autoload
 308 (defun elint-defun ()
 309   "Lint the function at point.
 310 If necessary, this first calls `elint-initialize'."
 311   (interactive)
 312   (or elint-builtin-variables
 313       (elint-initialize))
 314   (save-excursion
 315     (or (beginning-of-defun) (error "Lint what?"))
 316     (let ((pos (point))
 317           (def (read (current-buffer))))
 318       (elint-display-log)
 319       (elint-update-env)
 320       (elint-top-form (elint-make-top-form def pos)))))
 321
 322 ;;;
 323 ;;; Top form functions
 324 ;;;
 325
 326 (defvar elint-buffer-env nil
 327   "The environment of an elisp buffer.
 328 Will be local in linted buffers.")
 329
 330 (defvar elint-buffer-forms nil
 331   "The top forms in a buffer.
 332 Will be local in linted buffers.")
 333
 334 (defvar elint-last-env-time nil
 335   "The last time the buffers env was updated.
 336 Is measured in buffer-modified-ticks and is local in linted buffers.")
 337
 338 ;; This is a minor optimization.  It is local to every buffer, and so
 339 ;; does not prevent recursive requirs.  It does not list the requires
 340 ;; of requires.
 341 (defvar elint-features nil
 342   "List of all libraries this buffer has required, or that have been provided.")
 343
 344 (defun elint-update-env ()
 345   "Update the elint environment in the current buffer.
 346 Don't do anything if the buffer hasn't been changed since this
 347 function was called the last time.
 348 Returns the forms."
 349   (if (and (local-variable-p 'elint-buffer-env (current-buffer))
 350            (local-variable-p 'elint-buffer-forms (current-buffer))
 351            (local-variable-p 'elint-last-env-time (current-buffer))
 352            (= (buffer-modified-tick) elint-last-env-time))
 353       ;; Env is up to date
 354       elint-buffer-forms
 355     ;; Remake env
 356     (set (make-local-variable 'elint-buffer-forms) (elint-get-top-forms))
 357     (set (make-local-variable 'elint-features) nil)
 358     (set (make-local-variable 'elint-buffer-env)
 359          (elint-init-env elint-buffer-forms))
 360     (if elint-preloaded-env
 361         (elint-env-add-env elint-preloaded-env elint-buffer-env))
 362     (set (make-local-variable 'elint-last-env-time) (buffer-modified-tick))
 363     elint-buffer-forms))
 364
 365 (defun elint-get-top-forms ()
 366   "Collect all the top forms in the current buffer."
 367   (save-excursion
 368     (let (tops)
 369       (goto-char (point-min))
 370       (while (elint-find-next-top-form)
 371         (let ((elint-current-pos (point)))
 372           ;; non-list check could be here too. errors may be out of seq.
 373           ;; quoted check cannot be elsewhere, since quotes skipped.
 374           (if (looking-back "'")
 375               ;; Eg cust-print.el uses ' as a comment syntax.
 376               (elint-warning "Skipping quoted form `'%.20s...'"
 377                            (read (current-buffer)))
 378             (condition-case nil
 379                 (setq tops (cons
 380                             (elint-make-top-form (read (current-buffer))
 381                                                  elint-current-pos)
 382                             tops))
 383               (end-of-file
 384                (goto-char elint-current-pos)
 385                (error "Missing ')' in top form: %s"
 386                       (buffer-substring elint-current-pos
 387                                         (line-end-position))))))))
 388       (nreverse tops))))
 389
 390 (defun elint-find-next-top-form ()
 391   "Find the next top form from point.
 392 Return nil if there are no more forms, t otherwise."
 393   (parse-partial-sexp (point) (point-max) nil t)
 394   (not (eobp)))
 395
 396 (defvar elint-env)                      ; from elint-init-env
 397
 398 (defun elint-init-form (form)
 399   "Process FORM, adding to ELINT-ENV if recognized."
 400   (cond
 401    ;; Eg nnmaildir seems to use [] as a form of comment syntax.
 402    ((not (listp form))
 403     (elint-warning "Skipping non-list form `%s'" form))
 404    ;; Add defined variable
 405    ((memq (car form) '(defvar defconst defcustom))
 406     (setq elint-env (elint-env-add-var elint-env (cadr form))))
 407    ;; Add function
 408    ((memq (car form) '(defun defsubst))
 409     (setq elint-env (elint-env-add-func elint-env (cadr form) (nth 2 form))))
 410    ;; FIXME needs a handler to say second arg is not a variable when we come
 411    ;; to scan the form.
 412    ((eq (car form) 'define-derived-mode)
 413     (setq elint-env (elint-env-add-func elint-env (cadr form) ())
 414           elint-env (elint-env-add-var elint-env (cadr form))
 415           elint-env (elint-env-add-var elint-env
 416                                        (intern (format "%s-map" (cadr form))))))
 417    ((eq (car form) 'define-minor-mode)
 418     (setq elint-env (elint-env-add-func elint-env (cadr form) '(&optional arg))
 419           ;; FIXME mode map?
 420           elint-env (elint-env-add-var elint-env (cadr form))))
 421    ((and (eq (car form) 'easy-menu-define)
 422          (cadr form))
 423     (setq elint-env (elint-env-add-func elint-env (cadr form) '(event))
 424           elint-env (elint-env-add-var elint-env (cadr form))))
 425    ;; FIXME it would be nice to check the autoloads are correct.
 426    ((eq (car form) 'autoload)
 427     (setq elint-env (elint-env-add-func elint-env (cadr (cadr form)) 'unknown)))
 428    ((eq (car form) 'declare-function)
 429     (setq elint-env (elint-env-add-func
 430                elint-env (cadr form)
 431                (if (or (< (length form) 4)
 432                        (eq (nth 3 form) t)
 433                        (unless (stringp (nth 2 form))
 434                          (elint-error "Malformed declaration for `%s'"
 435                                       (cadr form))
 436                          t))
 437                    'unknown
 438                  (nth 3 form)))))
 439    ((and (eq (car form) 'defalias) (listp (nth 2 form)))
 440     ;; If the alias points to something already in the environment,
 441     ;; add the alias to the environment with the same arguments.
 442     ;; FIXME symbol-function, eg backquote.el?
 443     (let ((def (elint-env-find-func elint-env (cadr (nth 2 form)))))
 444       (setq elint-env (elint-env-add-func elint-env (cadr (cadr form))
 445                                     (if def (cadr def) 'unknown)))))
 446    ;; Add macro, both as a macro and as a function
 447    ((eq (car form) 'defmacro)
 448     (setq elint-env (elint-env-add-macro elint-env (cadr form)
 449                                    (cons 'lambda (cddr form)))
 450           elint-env (elint-env-add-func elint-env (cadr form) (nth 2 form))))
 451    ((and (eq (car form) 'put)
 452          (= 4 (length form))
 453          (eq (car-safe (cadr form)) 'quote)
 454          (equal (nth 2 form) '(quote error-conditions)))
 455     (set (make-local-variable 'elint-extra-errors)
 456          (cons (cadr (cadr form)) elint-extra-errors)))
 457    ((eq (car form) 'provide)
 458     (add-to-list 'elint-features (eval (cadr form))))
 459    ;; Import variable definitions
 460    ((memq (car form) '(require cc-require cc-require-when-compile))
 461     (let ((name (eval (cadr form)))
 462           (file (eval (nth 2 form)))
 463           (elint-doing-cl (bound-and-true-p elint-doing-cl)))
 464       (unless (memq name elint-features)
 465         (add-to-list 'elint-features name)
 466         ;; cl loads cl-macs in an opaque manner.
 467         ;; Since cl-macs requires cl, we can just process cl-macs.
 468         (and (eq name 'cl) (not elint-doing-cl)
 469              ;; We need cl if elint-form is to be able to expand cl macros.
 470              (require 'cl)
 471              (setq name 'cl-macs
 472                    file nil
 473                    elint-doing-cl t)) ; blech
 474         (setq elint-env (elint-add-required-env elint-env name file))))))
 475   elint-env)
 476
 477 (defun elint-init-env (forms)
 478   "Initialize the environment from FORMS."
 479   (let ((elint-env (elint-make-env))
 480         form)
 481     (while forms
 482       (setq form (elint-top-form-form (car forms))
 483             forms (cdr forms))
 484       ;; FIXME eval-when-compile should be treated differently (macros).
 485       ;; Could bind something that makes elint-init-form only check
 486       ;; defmacros.
 487       (if (memq (car-safe form)
 488                 '(eval-and-compile eval-when-compile progn prog1 prog2
 489                                    with-no-warnings))
 490           (mapc 'elint-init-form (cdr form))
 491         (elint-init-form form)))
 492     elint-env))
 493
 494 (defun elint-add-required-env (env name file)
 495   "Augment ENV with the variables defined by feature NAME in FILE."
 496   (condition-case err
 497       (let* ((libname (if (stringp file)
 498                           file
 499                         (symbol-name name)))
 500
 501              ;; First try to find .el files, then the raw name
 502              (lib1 (locate-library (concat libname ".el") t))
 503              (lib (or lib1 (locate-library libname t))))
 504         ;; Clear the messages :-/
 505         ;; (Messes up the "Initializing elint..." message.)
 506 ;;;     (message nil)
 507         (if lib
 508             (with-current-buffer (find-file-noselect lib)
 509               ;; FIXME this doesn't use a temp buffer, because it
 510               ;; stores the result in buffer-local variables so that
 511               ;; it can be reused.
 512               (elint-update-env)
 513               (setq env (elint-env-add-env env elint-buffer-env)))
 514               ;;; (with-temp-buffer
 515               ;;;       (insert-file-contents lib)
 516               ;;;       (with-syntax-table emacs-lisp-mode-syntax-table
 517               ;;;         (elint-update-env))
 518               ;;;       (setq env (elint-env-add-env env elint-buffer-env))))
 519               ;;(message "Elint processed (require '%s)" name))
 520           (error "%s.el not found in load-path" libname)))
 521     (error
 522      (message "Can't get variables from require'd library %s: %s"
 523               name (error-message-string err))))
 524   env)
 525
 526 (defvar elint-top-form nil
 527   "The currently linted top form, or nil.")
 528
 529 (defvar elint-top-form-logged nil
 530   "The value t if the currently linted top form has been mentioned in the log buffer.")
 531
 532 (defun elint-top-form (form)
 533   "Lint a top FORM."
 534   (let ((elint-top-form form)
 535         (elint-top-form-logged nil)
 536         (elint-current-pos (elint-top-form-pos form)))
 537     (elint-form (elint-top-form-form form) elint-buffer-env)))
 538
 539 ;;;
 540 ;;; General form linting functions
 541 ;;;
 542
 543 (defconst elint-special-forms
 544   '((let . elint-check-let-form)
 545     (let* . elint-check-let-form)
 546     (setq . elint-check-setq-form)
 547     (quote . elint-check-quote-form)
 548     (function . elint-check-quote-form)
 549     (cond . elint-check-cond-form)
 550     (lambda . elint-check-defun-form)
 551     (function . elint-check-function-form)
 552     (setq-default . elint-check-setq-form)
 553     (defalias . elint-check-defalias-form)
 554     (defun . elint-check-defun-form)
 555     (defsubst . elint-check-defun-form)
 556     (defmacro . elint-check-defun-form)
 557     (defvar . elint-check-defvar-form)
 558     (defconst . elint-check-defvar-form)
 559     (defcustom . elint-check-defcustom-form)
 560     (macro . elint-check-macro-form)
 561     (condition-case . elint-check-condition-case-form)
 562     (if . elint-check-conditional-form)
 563     (when . elint-check-conditional-form)
 564     (unless . elint-check-conditional-form)
 565     (and . elint-check-conditional-form)
 566     (or . elint-check-conditional-form))
 567   "Functions to call when some special form should be linted.")
 568
 569 (defun elint-form (form env &optional nohandler)
 570   "Lint FORM in the environment ENV.
 571 Optional argument NOHANDLER non-nil means ignore `elint-special-forms'.
 572 Returns the environment created by the form."
 573   (cond
 574    ((consp form)
 575     (let ((func (cdr (assq (car form) elint-special-forms))))
 576       (if (and func (not nohandler))
 577           ;; Special form
 578           (funcall func form env)
 579
 580         (let* ((func (car form))
 581                (args (elint-get-args func env))
 582                (argsok t))
 583           (cond
 584            ((eq args 'undefined)
 585             (setq argsok nil)
 586             (or (memq 'undefined-functions elint-ignored-warnings)
 587                 (elint-error "Call to undefined function: %s" func)))
 588
 589            ((eq args 'unknown) nil)
 590
 591            (t (setq argsok (elint-match-args form args))))
 592
 593           ;; Is this a macro?
 594           (if (elint-env-macrop env func)
 595               ;; Macro defined in buffer, expand it
 596               (if argsok
 597                   ;; FIXME error if macro uses macro, eg bytecomp.el.
 598                   (condition-case nil
 599                       (elint-form
 600                        (macroexpand form (elint-env-macro-env env)) env)
 601                     (error
 602                      (or (memq 'macro-expansion elint-ignored-warnings)
 603                          (elint-error "Elint failed to expand macro: %s" func))
 604                      env))
 605                 env)
 606
 607             (let ((fcode (if (symbolp func)
 608                              (if (fboundp func)
 609                                  (indirect-function func))
 610                            func)))
 611               (if (and (listp fcode) (eq (car fcode) 'macro))
 612                   ;; Macro defined outside buffer
 613                   (if argsok
 614                       (elint-form (macroexpand form) env)
 615                     env)
 616                 ;; Function, lint its parameters
 617                 (elint-forms (cdr form) env))))))))
 618    ((symbolp form)
 619     ;; :foo variables are quoted
 620     (and (/= (aref (symbol-name form) 0) ?:)
 621          (not (memq 'unbound-reference elint-ignored-warnings))
 622          (elint-unbound-variable form env)
 623          (elint-warning "Reference to unbound symbol: %s" form))
 624     env)
 625
 626    (t env)))
 627
 628 (defun elint-forms (forms env)
 629   "Lint the FORMS, accumulating an environment, starting with ENV."
 630   ;; grumblegrumbletailrecursiongrumblegrumble
 631   (if (listp forms)
 632       (dolist (f forms env)
 633         (setq env (elint-form f env)))
 634     ;; Loop macro?
 635     (elint-error "Elint failed to parse form: %s" forms)
 636     env))
 637
 638 (defvar elint-bound-variable nil
 639   "Name of a temporarily bound symbol.")
 640
 641 (defun elint-unbound-variable (var env)
 642   "Return t if VAR is unbound in ENV."
 643   ;; #1063 suggests adding (symbol-file var) here, but I don't think
 644   ;; this is right, because it depends on what files you happen to have
 645   ;; loaded at the time, which might not be the same when the code runs.
 646   ;; It also suggests adding:
 647   ;; (numberp (get var 'variable-documentation))
 648   ;; (numberp (cdr-safe (get var 'variable-documentation)))
 649   ;; but this is not needed now elint-scan-doc-file exists.
 650   (not (or (memq var '(nil t))
 651            (eq var elint-bound-variable)
 652            (elint-env-find-var env var)
 653            (memq var elint-builtin-variables)
 654            (memq var elint-autoloaded-variables)
 655            (memq var elint-standard-variables))))
 656
 657 ;;;
 658 ;;; Function argument checking
 659 ;;;
 660
 661 (defun elint-match-args (arglist argpattern)
 662   "Match ARGLIST against ARGPATTERN."
 663   (let ((state 'all)
 664         (al (cdr arglist))
 665         (ap argpattern)
 666         (ok t))
 667     (while
 668         (cond
 669          ((and (null al) (null ap)) nil)
 670          ((eq (car ap) '&optional)
 671           (setq state 'optional)
 672           (setq ap (cdr ap))
 673           t)
 674          ((eq (car ap) '&rest)
 675           nil)
 676          ((or (and (eq state 'all) (or (null al) (null ap)))
 677               (and (eq state 'optional) (and al (null ap))))
 678           (elint-error "Wrong number of args: %s, %s" arglist argpattern)
 679           (setq ok nil)
 680           nil)
 681          ((and (eq state 'optional) (null al))
 682           nil)
 683          (t (setq al (cdr al)
 684                   ap (cdr ap))
 685             t)))
 686     ok))
 687
 688 (defvar elint-bound-function nil
 689   "Name of a temporarily bound function symbol.")
 690
 691 (defun elint-get-args (func env)
 692   "Find the args of FUNC in ENV.
 693 Returns `unknown' if we couldn't find arguments."
 694   (let ((f (elint-env-find-func env func)))
 695     (if f
 696         (cadr f)
 697       (if (symbolp func)
 698           (if (eq func elint-bound-function)
 699               'unknown
 700             (if (fboundp func)
 701                 (let ((fcode (indirect-function func)))
 702                   (if (subrp fcode)
 703                       ;; FIXME builtins with no args have args = nil.
 704                       (or (get func 'elint-args) 'unknown)
 705                     (elint-find-args-in-code fcode)))
 706               'undefined))
 707         (elint-find-args-in-code func)))))
 708
 709 (defun elint-find-args-in-code (code)
 710   "Extract the arguments from CODE.
 711 CODE can be a lambda expression, a macro, or byte-compiled code."
 712   (cond
 713    ((byte-code-function-p code)
 714     (aref code 0))
 715    ((and (listp code) (eq (car code) 'lambda))
 716     (car (cdr code)))
 717    ((and (listp code) (eq (car code) 'macro))
 718     (elint-find-args-in-code (cdr code)))
 719    (t 'unknown)))
 720
 721 ;;;
 722 ;;; Functions to check some special forms
 723 ;;;
 724
 725 (defun elint-check-cond-form (form env)
 726   "Lint a cond FORM in ENV."
 727   (dolist (f (cdr form))
 728     (if (consp f)
 729         (let ((test (car f)))
 730           (cond ((equal test '(featurep (quote xemacs))))
 731                 ((equal test '(not (featurep (quote emacs)))))
 732                 ;; FIXME (and (boundp 'foo)
 733                 ((and (eq (car-safe test) 'fboundp)
 734                       (= 2 (length test))
 735                       (eq (car-safe (cadr test)) 'quote))
 736                  (let ((elint-bound-function (cadr (cadr test))))
 737                    (elint-forms f env)))
 738                 ((and (eq (car-safe test) 'boundp)
 739                       (= 2 (length test))
 740                       (eq (car-safe (cadr test)) 'quote))
 741                  (let ((elint-bound-variable (cadr (cadr test))))
 742                    (elint-forms f env)))
 743                 (t (elint-forms f env))))
 744       (elint-error "cond clause should be a list: %s" f)))
 745   env)
 746
 747 (defun elint-check-defun-form (form env)
 748   "Lint a defun/defmacro/lambda FORM in ENV."
 749   (setq form (if (eq (car form) 'lambda) (cdr form) (cddr form)))
 750   (mapc (lambda (p)
 751           (or (memq p '(&optional &rest))
 752               (setq env (elint-env-add-var env p))))
 753         (car form))
 754   (elint-forms (cdr form) env))
 755
 756 (defun elint-check-defalias-form (form env)
 757   "Lint a defalias FORM in ENV."
 758   (let ((alias (cadr form))
 759         (target (nth 2 form)))
 760     (and (eq (car-safe alias) 'quote)
 761          (eq (car-safe target) 'quote)
 762          (eq (elint-get-args (cadr target) env) 'undefined)
 763          (elint-warning "Alias `%s' has unknown target `%s'"
 764                         (cadr alias) (cadr target))))
 765   (elint-form form env t))
 766
 767 (defun elint-check-let-form (form env)
 768   "Lint the let/let* FORM in ENV."
 769   (let ((varlist (cadr form)))
 770     (if (not varlist)
 771         (if (> (length form) 2)
 772             ;; An empty varlist is not really an error.  Eg some cl macros
 773             ;; can expand to such a form.
 774             (progn
 775               (or (memq 'empty-let elint-ignored-warnings)
 776                   (elint-warning "Empty varlist in let: %s" form))
 777               ;; Lint the body forms
 778               (elint-forms (cddr form) env))
 779           (elint-error "Malformed let: %s" form)
 780           env)
 781       ;; Check for (let (a (car b)) ...) type of error
 782       (if (and (= (length varlist) 2)
 783                (symbolp (car varlist))
 784                (listp (car (cdr varlist)))
 785                (fboundp (car (car (cdr varlist)))))
 786           (elint-warning "Suspect varlist: %s" form))
 787       ;; Add variables to environment, and check the init values
 788       (let ((newenv env))
 789         (mapc (lambda (s)
 790                 (cond
 791                  ((symbolp s)
 792                   (setq newenv (elint-env-add-var newenv s)))
 793                  ((and (consp s) (<= (length s) 2))
 794                   (elint-form (cadr s)
 795                               (if (eq (car form) 'let)
 796                                   env
 797                                 newenv))
 798                   (setq newenv
 799                         (elint-env-add-var newenv (car s))))
 800                  (t (elint-error
 801                      "Malformed `let' declaration: %s" s))))
 802               varlist)
 803
 804         ;; Lint the body forms
 805         (elint-forms (cddr form) newenv)))))
 806
 807 (defun elint-check-setq-form (form env)
 808   "Lint the setq FORM in ENV."
 809   (or (= (mod (length form) 2) 1)
 810       ;; (setq foo) is valid and equivalent to (setq foo nil).
 811       (elint-warning "Missing value in setq: %s" form))
 812   (let ((newenv env)
 813         sym val)
 814     (setq form (cdr form))
 815     (while form
 816       (setq sym (car form)
 817             val (car (cdr form))
 818             form (cdr (cdr form)))
 819       (if (symbolp sym)
 820           (and (not (memq 'unbound-assignment elint-ignored-warnings))
 821                (elint-unbound-variable sym newenv)
 822                (elint-warning "Setting previously unbound symbol: %s" sym))
 823         (elint-error "Setting non-symbol in setq: %s" sym))
 824       (elint-form val newenv)
 825       (if (symbolp sym)
 826           (setq newenv (elint-env-add-var newenv sym))))
 827     newenv))
 828
 829 (defun elint-check-defvar-form (form env)
 830   "Lint the defvar/defconst FORM in ENV."
 831   (if (or (= (length form) 2)
 832           (= (length form) 3)
 833           ;; Eg the defcalcmodevar macro can expand with a nil doc-string.
 834           (and (= (length form) 4) (string-or-null-p (nth 3 form))))
 835           (elint-env-add-global-var (elint-form (nth 2 form) env)
 836                              (car (cdr form)))
 837     (elint-error "Malformed variable declaration: %s" form)
 838     env))
 839
 840 (defun elint-check-defcustom-form (form env)
 841   "Lint the defcustom FORM in ENV."
 842   (if (and (> (length form) 3)
 843            ;; even no. of keyword/value args ?
 844            (zerop (logand (length form) 1)))
 845       (elint-env-add-global-var (elint-form (nth 2 form) env)
 846                                 (car (cdr form)))
 847     (elint-error "Malformed variable declaration: %s" form)
 848     env))
 849
 850 (defun elint-check-function-form (form env)
 851   "Lint the function FORM in ENV."
 852   (let ((func (car (cdr-safe form))))
 853     (cond
 854      ((symbolp func)
 855       (or (elint-env-find-func env func)
 856           ;; FIXME potentially bogus, since it uses the current
 857           ;; environment rather than a clean one.
 858           (fboundp func)
 859           (elint-warning "Reference to undefined function: %s" form))
 860       env)
 861      ((and (consp func) (memq (car func) '(lambda macro)))
 862       (elint-form func env))
 863      ((stringp func) env)
 864      (t (elint-error "Not a function object: %s" form)
 865         env))))
 866
 867 (defun elint-check-quote-form (form env)
 868   "Lint the quote FORM in ENV."
 869   env)
 870
 871 (defun elint-check-macro-form (form env)
 872   "Check the macro FORM in ENV."
 873   (elint-check-function-form (list (car form) (cdr form)) env))
 874
 875 (defun elint-check-condition-case-form (form env)
 876   "Check the `condition-case' FORM in ENV."
 877   (let ((resenv env))
 878     (if (< (length form) 3)
 879         (elint-error "Malformed condition-case: %s" form)
 880       (or (symbolp (cadr form))
 881           (elint-warning "First parameter should be a symbol: %s" form))
 882       (setq resenv (elint-form (nth 2 form) env))
 883       (let ((newenv (elint-env-add-var env (cadr form)))
 884             errlist)
 885         (dolist (err (nthcdr 3 form))
 886           (setq errlist (car err))
 887           (mapc (lambda (s)
 888                   (or (get s 'error-conditions)
 889                       (get s 'error-message)
 890                       (memq s elint-extra-errors)
 891                       (elint-warning
 892                        "Not an error symbol in error handler: %s" s)))
 893                 (cond
 894                  ((symbolp errlist) (list errlist))
 895                  ((listp errlist) errlist)
 896                  (t (elint-error "Bad error list in error handler: %s"
 897                                  errlist)
 898                     nil)))
 899           (elint-forms (cdr err) newenv))))
 900     resenv))
 901
 902 ;; For the featurep parts, an alternative is to have
 903 ;; elint-get-top-forms skip the irrelevant branches.
 904 (defun elint-check-conditional-form (form env)
 905   "Check the when/unless/and/or FORM in ENV.
 906 Does basic handling of `featurep' tests."
 907   (let ((func (car form))
 908         (test (cadr form))
 909         sym)
 910     ;; Misses things like (and t (featurep 'xemacs))
 911     ;; Check byte-compile-maybe-guarded.
 912     (cond ((and (memq func '(when and))
 913                 (eq (car-safe test) 'boundp)
 914                 (= 2 (length test))
 915                 (eq (car-safe (cadr test)) 'quote))
 916            ;; Cf elint-check-let-form, which modifies the whole ENV.
 917            (let ((elint-bound-variable (cadr (cadr test))))
 918              (elint-form form env t)))
 919           ((and (memq func '(when and))
 920                 (eq (car-safe test) 'fboundp)
 921                 (= 2 (length test))
 922                 (eq (car-safe (cadr test)) 'quote))
 923            (let ((elint-bound-function (cadr (cadr test))))
 924              (elint-form form env t)))
 925           ;; Let's not worry about (if (not (boundp...
 926           ((and (eq func 'if)
 927                 (eq (car-safe test) 'boundp)
 928                 (= 2 (length test))
 929                 (eq (car-safe (cadr test)) 'quote))
 930            (let ((elint-bound-variable (cadr (cadr test))))
 931              (elint-form (nth 2 form) env))
 932            (dolist (f (nthcdr 3 form))
 933              (elint-form f env)))
 934           ((and (eq func 'if)
 935                 (eq (car-safe test) 'fboundp)
 936                 (= 2 (length test))
 937                 (eq (car-safe (cadr test)) 'quote))
 938            (let ((elint-bound-function (cadr (cadr test))))
 939              (elint-form (nth 2 form) env))
 940            (dolist (f (nthcdr 3 form))
 941              (elint-form f env)))
 942           ((and (memq func '(when and)) ; skip all
 943                 (or (null test)
 944                     (member test '((featurep (quote xemacs))
 945                                    (not (featurep (quote emacs)))))
 946                     (and (eq (car-safe test) 'and)
 947                          (equal (car-safe (cdr test))
 948                                 '(featurep (quote xemacs)))))))
 949           ((and (memq func '(unless or))
 950                 (equal test '(featurep (quote emacs)))))
 951           ((and (eq func 'if)
 952                 (or (null test)       ; eg custom-browse-insert-prefix
 953                     (member test '((featurep (quote xemacs))
 954                                    (not (featurep (quote emacs)))))
 955                     (and (eq (car-safe test) 'and)
 956                          (equal (car-safe (cdr test))
 957                                 '(featurep (quote xemacs))))))
 958            (dolist (f (nthcdr 3 form))
 959              (elint-form f env)))       ; lint the else branch
 960           ((and (eq func 'if)
 961                 (equal test '(featurep (quote emacs))))
 962            (elint-form (nth 2 form) env)) ; lint the if branch
 963           ;; Process conditional as normal, without handler.
 964           (t
 965            (elint-form form env t))))
 966   env)
 967
 968 ;;;
 969 ;;; Message functions
 970 ;;;
 971
 972 (defvar elint-current-pos)       ; dynamically bound in elint-top-form
 973
 974 (defun elint-log (type string args)
 975   (elint-log-message (format "%s:%d:%s: %s"
 976                              (let ((f (buffer-file-name)))
 977                                (if f
 978                                    (file-name-nondirectory f)
 979                                  (buffer-name)))
 980                              (if (boundp 'elint-current-pos)
 981                                  (save-excursion
 982                                    (goto-char elint-current-pos)
 983                                    (1+ (count-lines (point-min)
 984                                                     (line-beginning-position))))
 985                                0)       ; unknown position
 986                              type
 987                              (apply 'format string args))))
 988
 989 (defun elint-error (string &rest args)
 990   "Report a linting error.
 991 STRING and ARGS are thrown on `format' to get the message."
 992   (elint-log "Error" string args))
 993
 994 (defun elint-warning (string &rest args)
 995   "Report a linting warning.
 996 See `elint-error'."
 997   (elint-log "Warning" string args))
 998
 999 (defun elint-output (string)
1000   "Print or insert STRING, depending on value of `noninteractive'."
1001   (if noninteractive
1002       (message "%s" string)
1003     (insert string "\n")))
1004
1005 (defun elint-log-message (errstr &optional top)
1006   "Insert ERRSTR last in the lint log buffer.
1007 Optional argument TOP non-nil means pretend `elint-top-form-logged' is non-nil."
1008   (with-current-buffer (elint-get-log-buffer)
1009     (goto-char (point-max))
1010     (let ((inhibit-read-only t))
1011       (or (bolp) (newline))
1012       ;; Do we have to say where we are?
1013       (unless (or elint-top-form-logged top)
1014         (let* ((form (elint-top-form-form elint-top-form))
1015                (top (car form)))
1016           (elint-output (cond
1017                          ((memq top '(defun defsubst))
1018                           (format "\nIn function %s:" (cadr form)))
1019                          ((eq top 'defmacro)
1020                           (format "\nIn macro %s:" (cadr form)))
1021                          ((memq top '(defvar defconst))
1022                           (format "\nIn variable %s:" (cadr form)))
1023                          (t "\nIn top level expression:"))))
1024         (setq elint-top-form-logged t))
1025       (elint-output errstr))))
1026
1027 (defun elint-clear-log (&optional header)
1028   "Clear the lint log buffer.
1029 Insert HEADER followed by a blank line if non-nil."
1030   (let ((dir default-directory))
1031     (with-current-buffer (elint-get-log-buffer)
1032       (setq default-directory dir)
1033       (let ((inhibit-read-only t))
1034         (erase-buffer)
1035         (if header (insert header "\n"))))))
1036
1037 (defun elint-display-log ()
1038   "Display the lint log buffer."
1039   (let ((pop-up-windows t))
1040     (display-buffer (elint-get-log-buffer))
1041     (sit-for 0)))
1042
1043 (defvar elint-running)
1044
1045 (defun elint-set-mode-line (&optional on)
1046   "Set the mode-line-process of the Elint log buffer."
1047   (with-current-buffer (elint-get-log-buffer)
1048     (and (eq major-mode 'compilation-mode)
1049          (setq mode-line-process
1050                (list (if (or on (bound-and-true-p elint-running))
1051                          (propertize ":run" 'face 'compilation-warning)
1052                        (propertize ":finished" 'face 'compilation-info)))))))
1053
1054 (defun elint-get-log-buffer ()
1055   "Return a log buffer for elint."
1056   (or (get-buffer elint-log-buffer)
1057       (with-current-buffer (get-buffer-create elint-log-buffer)
1058         (or (eq major-mode 'compilation-mode)
1059             (compilation-mode))
1060         (setq buffer-undo-list t)
1061         (current-buffer))))
1062
1063 ;;;
1064 ;;; Initializing code
1065 ;;;
1066
1067 (defun elint-put-function-args (func args)
1068   "Mark function FUNC as having argument list ARGS."
1069   (and (symbolp func)
1070        args
1071        (not (eq args 'unknown))
1072        (put func 'elint-args args)))
1073
1074 ;;;###autoload
1075 (defun elint-initialize (&optional reinit)
1076   "Initialize elint.
1077 If elint is already initialized, this does nothing, unless
1078 optional prefix argument REINIT is non-nil."
1079   (interactive "P")
1080   (if (and elint-builtin-variables (not reinit))
1081       (message "Elint is already initialized")
1082     (message "Initializing elint...")
1083     (setq elint-builtin-variables (elint-scan-doc-file)
1084           elint-autoloaded-variables (elint-find-autoloaded-variables))
1085     (mapc (lambda (x) (elint-put-function-args (car x) (cdr x)))
1086           (elint-find-builtin-args))
1087     (if elint-unknown-builtin-args
1088         (mapc (lambda (x) (elint-put-function-args (car x) (cdr x)))
1089               elint-unknown-builtin-args))
1090     (when elint-scan-preloaded
1091       (dolist (lib preloaded-file-list)
1092         ;; Skip files that contain nothing of use to us.
1093         (unless (string-match elint-preloaded-skip-re lib)
1094           (setq elint-preloaded-env
1095                 (elint-add-required-env elint-preloaded-env nil lib)))))
1096     (message "Initializing elint...done")))
1097
1098
1099 ;; This includes all the built-in and dumped things with documentation.
1100 (defun elint-scan-doc-file ()
1101   "Scan the DOC file for function and variables.
1102 Marks the function wih their arguments, and returns a list of variables."
1103   ;; Cribbed from help-fns.el.
1104   (let ((docbuf " *DOC*")
1105         vars sym args)
1106     (save-excursion
1107       (if (get-buffer docbuf)
1108           (progn
1109             (set-buffer docbuf)
1110             (goto-char (point-min)))
1111         (set-buffer (get-buffer-create docbuf))
1112         (insert-file-contents-literally
1113          (expand-file-name internal-doc-file-name doc-directory)))
1114       (while (re-search-forward "\1f\\([VF]\\)" nil t)
1115         (when (setq sym (intern-soft (buffer-substring (point)
1116                                                        (line-end-position))))
1117           (if (string-equal (match-string 1) "V")
1118               ;; Excludes platform-specific stuff not relevant to the
1119               ;; running platform.
1120               (if (boundp sym) (setq vars (cons sym vars)))
1121             ;; Function.
1122             (when (fboundp sym)
1123               (when (re-search-forward "\\(^(fn.*)\\)?\1f" nil t)
1124                 (backward-char 1)
1125                 ;; FIXME distinguish no args from not found.
1126                 (and (setq args (match-string 1))
1127                      (setq args
1128                            (ignore-errors
1129                              (read
1130                               (replace-regexp-in-string "^(fn ?" "(" args))))
1131                      (elint-put-function-args sym args))))))))
1132     vars))
1133
1134 (defun elint-find-autoloaded-variables ()
1135   "Return a list of all autoloaded variables."
1136   (let (var vars)
1137     (with-temp-buffer
1138       (insert-file-contents (locate-library "loaddefs.el"))
1139       (while (re-search-forward "^(defvar \\([[:alnum:]_-]+\\)" nil t)
1140         (and (setq var (intern-soft (match-string 1)))
1141              (boundp var)
1142              (setq vars (cons var vars)))))
1143     vars))
1144
1145 (defun elint-find-builtins ()
1146   "Return a list of all built-in functions."
1147   (let (subrs)
1148     (mapatoms (lambda (s) (and (fboundp s) (subrp (symbol-function s))
1149                                (setq subrs (cons s subrs)))))
1150     subrs))
1151
1152 (defun elint-find-builtin-args (&optional list)
1153   "Return a list of the built-in functions and their arguments.
1154 If LIST is nil, call `elint-find-builtins' to get a list of all built-in
1155 functions, otherwise use LIST.
1156
1157 Each function is represented by a cons cell:
1158 \(function-symbol . args)
1159 If no documentation could be found args will be `unknown'."
1160   (mapcar (lambda (f)
1161             (let ((doc (documentation f t)))
1162               (or (and doc
1163                        (string-match "\n\n(fn\\(.*)\\)\\'" doc)
1164                        (ignore-errors
1165                         ;; "BODY...)" -> "&rest BODY)".
1166                         (read (replace-regexp-in-string
1167                                "\\([^ ]+\\)\\.\\.\\.)\\'" "&rest \\1)"
1168                                (format "(%s %s" f (match-string 1 doc)) t))))
1169                   (cons f 'unknown))))
1170           (or list (elint-find-builtins))))
1171
1172 (provide 'elint)
1173
1174 ;;; elint.el ends here