code.delx.au - gnu-emacs/blob - lisp/erc/erc-list.el

   1 ;;; erc-list.el --- /list support for ERC
   2
   3 ;; Copyright (C) 2008-2011 Free Software Foundation, Inc.
   4
   5 ;; Author: Tom Tromey <tromey@redhat.com>
   6 ;; Version: 0.1
   7 ;; Keywords: comm
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; This file provides nice support for /list in ERC.
  27
  28 ;;; Code:
  29
  30 (require 'erc)
  31
  32 ;; This is implicitly the width of the channel name column.  Pick
  33 ;; something small enough that the topic has a chance of being
  34 ;; readable, but long enough that most channel names won't make for
  35 ;; strange formatting.
  36 (defconst erc-list-nusers-column 25)
  37
  38 ;; Width of the number-of-users column.
  39 (defconst erc-list-topic-column (+ erc-list-nusers-column 10))
  40
  41 ;; The list buffer.  This is buffer local in the server buffer.
  42 (defvar erc-list-buffer nil)
  43
  44 ;; The argument to the last "/list".  This is buffer local in the
  45 ;; server buffer.
  46 (defvar erc-list-last-argument nil)
  47
  48 ;; The server buffer corresponding to the list buffer.  This is buffer
  49 ;; local in the list buffer.
  50 (defvar erc-list-server-buffer nil)
  51
  52 ;; Define module:
  53 ;;;###autoload (autoload 'erc-list-mode "erc-list")
  54 (define-erc-module list nil
  55   "List channels nicely in a separate buffer."
  56   ((remove-hook 'erc-server-321-functions 'erc-server-321-message)
  57    (remove-hook 'erc-server-322-functions 'erc-server-322-message))
  58   ((erc-with-all-buffers-of-server nil
  59      #'erc-open-server-buffer-p
  60      (remove-hook 'erc-server-322-functions 'erc-list-handle-322 t))
  61    (add-hook 'erc-server-321-functions 'erc-server-321-message t)
  62    (add-hook 'erc-server-322-functions 'erc-server-322-message t)))
  63
  64 ;; Format a record for display.
  65 (defun erc-list-make-string (channel users topic)
  66   (concat
  67    channel
  68    (erc-propertize " "
  69                    'display (list 'space :align-to erc-list-nusers-column)
  70                    'face 'fixed-pitch)
  71    users
  72    (erc-propertize " "
  73                    'display (list 'space :align-to erc-list-topic-column)
  74                    'face 'fixed-pitch)
  75    topic))
  76
  77 ;; Insert a record into the list buffer.
  78 (defun erc-list-insert-item (channel users topic)
  79   (save-excursion
  80     (let ((buffer-read-only nil))
  81       (goto-char (point-max))
  82       (insert (erc-list-make-string channel users topic) "\n"))))
  83
  84 (defun erc-list-join ()
  85   "Join the irc channel named on this line."
  86   (interactive)
  87   (unless (eobp)
  88     (beginning-of-line)
  89     (unless (looking-at "\\([&#+!][^ \n]+\\)")
  90       (error "Not looking at channel name?"))
  91     (let ((chan (match-string 1)))
  92       (with-current-buffer erc-list-server-buffer
  93         (erc-join-channel chan)))))
  94
  95 (defun erc-list-kill ()
  96   "Kill the current ERC list buffer."
  97   (interactive)
  98   (kill-buffer (current-buffer)))
  99
 100 (defun erc-list-revert ()
 101   "Refresh the list of channels."
 102   (interactive)
 103   (with-current-buffer erc-list-server-buffer
 104     (erc-cmd-LIST erc-list-last-argument)))
 105
 106 (defun erc-list-menu-sort-by-column (&optional e)
 107   "Sort the channel list by the column clicked on."
 108   (interactive (list last-input-event))
 109   (if e (mouse-select-window e))
 110   (let* ((pos (event-start e))
 111          (obj (posn-object pos))
 112          (col (if obj
 113                   (get-text-property (cdr obj) 'column-number (car obj))
 114                 (get-text-property (posn-point pos) 'column-number))))
 115     (let ((buffer-read-only nil))
 116       (if (= col 1)
 117           (sort-fields col (point-min) (point-max))
 118         (sort-numeric-fields col (point-min) (point-max))))))
 119
 120 (defvar erc-list-menu-mode-map
 121   (let ((map (make-keymap)))
 122     (suppress-keymap map)
 123     (define-key map "k" 'erc-list-kill)
 124     (define-key map "j" 'erc-list-join)
 125     (define-key map "g" 'erc-list-revert)
 126     (define-key map "n" 'next-line)
 127     (define-key map "p" 'previous-line)
 128     (define-key map "q" 'quit-window)
 129     map)
 130   "Local keymap for `erc-list-mode' buffers.")
 131
 132 (defvar erc-list-menu-sort-button-map nil
 133   "Local keymap for ERC list menu mode sorting buttons.")
 134
 135 (unless erc-list-menu-sort-button-map
 136   (let ((map (make-sparse-keymap)))
 137     (define-key map [header-line mouse-1] 'erc-list-menu-sort-by-column)
 138     (define-key map [follow-link] 'mouse-face)
 139     (setq erc-list-menu-sort-button-map map)))
 140
 141 ;; Helper function that makes a buttonized column header.
 142 (defun erc-list-button (title column)
 143   (erc-propertize title
 144                   'column-number column
 145                   'help-echo "mouse-1: sort by column"
 146                   'mouse-face 'highlight
 147                   'keymap erc-list-menu-sort-button-map))
 148
 149 (define-derived-mode erc-list-menu-mode nil "ERC-List"
 150   "Major mode for editing a list of irc channels."
 151   (setq header-line-format
 152         (concat
 153          (erc-propertize " "
 154                          'display '(space :align-to 0)
 155                          'face 'fixed-pitch)
 156          (erc-list-make-string (erc-list-button "Channel" 1)
 157                                (erc-list-button "# Users" 2)
 158                                "Topic")))
 159   (setq truncate-lines t))
 160
 161 (put 'erc-list-menu-mode 'mode-class 'special)
 162
 163 ;; Handle a "322" response.  This response tells us about a single
 164 ;; channel.
 165 (defun erc-list-handle-322 (proc parsed)
 166   (let* ((args (cdr (erc-response.command-args parsed)))
 167          (channel (car args))
 168          (nusers (car (cdr args)))
 169          (topic (erc-response.contents parsed)))
 170     (when (buffer-live-p erc-list-buffer)
 171       (with-current-buffer erc-list-buffer
 172         (erc-list-insert-item channel nusers topic))))
 173   ;; Don't let another hook run.
 174   t)
 175
 176 ;; Helper function to install our 322 handler and make our buffer.
 177 (defun erc-list-install-322-handler (server-buffer)
 178   (with-current-buffer server-buffer
 179     ;; Arrange for 322 responses to insert into our buffer.
 180     (add-hook 'erc-server-322-functions 'erc-list-handle-322 t t)
 181     ;; Arrange for 323 (end of list) to end this.
 182     (erc-once-with-server-event
 183      323
 184      '(progn
 185         (remove-hook 'erc-server-322-functions 'erc-list-handle-322 t)))
 186     ;; Find the list buffer, empty it, and display it.
 187     (set (make-local-variable 'erc-list-buffer)
 188          (get-buffer-create (concat "*Channels of "
 189                                     erc-server-announced-name
 190                                     "*")))
 191     (with-current-buffer erc-list-buffer
 192       (erc-list-menu-mode)
 193       (setq buffer-read-only nil)
 194       (erase-buffer)
 195       (set (make-local-variable 'erc-list-server-buffer) server-buffer)
 196       (setq buffer-read-only t))
 197     (pop-to-buffer erc-list-buffer))
 198   t)
 199
 200 ;; The main entry point.
 201 (defun erc-cmd-LIST (&optional line)
 202   "Show a listing of channels on the current server in a separate window.
 203
 204 If LINE is specified, include it with the /LIST command.  It
 205 should usually be one or more channels, separated by commas.
 206
 207 Please note that this function only works with IRC servers which conform
 208 to RFC and send the LIST header (#321) at start of list transmission."
 209   (erc-with-server-buffer
 210     (set (make-local-variable 'erc-list-last-argument) line)
 211     (erc-once-with-server-event
 212      321
 213      (list 'progn
 214            (list 'erc-list-install-322-handler (current-buffer)))))
 215   (erc-server-send (concat "LIST :" (or (and line (substring line 1))
 216                                         ""))))
 217 (put 'erc-cmd-LIST 'do-not-parse-args t)
 218
 219 ;;; erc-list.el ends here
 220 ;;
 221 ;; Local Variables:
 222 ;; indent-tabs-mode: t
 223 ;; tab-width: 8
 224 ;; End:
 225