code.delx.au - gnu-emacs/blob - lisp/help-fns.el

   1 ;;; help-fns.el --- Complex help functions
   2
   3 ;; Copyright (C) 1985-1986, 1993-1994, 1998-2011
   4 ;;   Free Software Foundation, Inc.
   5
   6 ;; Maintainer: FSF
   7 ;; Keywords: help, internal
   8 ;; Package: emacs
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; This file contains those help commands which are complicated, and
  28 ;; which may not be used in every session.  For example
  29 ;; `describe-function' will probably be heavily used when doing elisp
  30 ;; programming, but not if just editing C files.  Simpler help commands
  31 ;; are in help.el
  32
  33 ;;; Code:
  34
  35 ;; Functions
  36
  37 ;;;###autoload
  38 (defun describe-function (function)
  39   "Display the full documentation of FUNCTION (a symbol)."
  40   (interactive
  41    (let ((fn (function-called-at-point))
  42          (enable-recursive-minibuffers t)
  43          val)
  44      (setq val (completing-read (if fn
  45                                     (format "Describe function (default %s): " fn)
  46                                   "Describe function: ")
  47                                 obarray 'fboundp t nil nil
  48                                 (and fn (symbol-name fn))))
  49      (list (if (equal val "")
  50                fn (intern val)))))
  51   (if (null function)
  52       (message "You didn't specify a function")
  53     (help-setup-xref (list #'describe-function function)
  54                      (called-interactively-p 'interactive))
  55     (save-excursion
  56       (with-help-window (help-buffer)
  57         (prin1 function)
  58         ;; Use " is " instead of a colon so that
  59         ;; it is easier to get out the function name using forward-sexp.
  60         (princ " is ")
  61         (describe-function-1 function)
  62         (with-current-buffer standard-output
  63           ;; Return the text we displayed.
  64           (buffer-string))))))
  65
  66 (defun help-split-fundoc (docstring def)
  67   "Split a function DOCSTRING into the actual doc and the usage info.
  68 Return (USAGE . DOC) or nil if there's no usage info.
  69 DEF is the function whose usage we're looking for in DOCSTRING."
  70   ;; Functions can get the calling sequence at the end of the doc string.
  71   ;; In cases where `function' has been fset to a subr we can't search for
  72   ;; function's name in the doc string so we use `fn' as the anonymous
  73   ;; function name instead.
  74   (when (and docstring (string-match "\n\n(fn\\(\\( .*\\)?)\\)\\'" docstring))
  75     (cons (format "(%s%s"
  76                   ;; Replace `fn' with the actual function name.
  77                   (if (consp def) "anonymous" def)
  78                   (match-string 1 docstring))
  79           (substring docstring 0 (match-beginning 0)))))
  80
  81 (defun help-add-fundoc-usage (docstring arglist)
  82   "Add the usage info to DOCSTRING.
  83 If DOCSTRING already has a usage info, then just return it unchanged.
  84 The usage info is built from ARGLIST.  DOCSTRING can be nil.
  85 ARGLIST can also be t or a string of the form \"(FUN ARG1 ARG2 ...)\"."
  86   (unless (stringp docstring) (setq docstring "Not documented"))
  87   (if (or (string-match "\n\n(fn\\(\\( .*\\)?)\\)\\'" docstring) (eq arglist t))
  88       docstring
  89     (concat docstring
  90             (if (string-match "\n?\n\\'" docstring)
  91                 (if (< (- (match-end 0) (match-beginning 0)) 2) "\n" "")
  92               "\n\n")
  93             (if (and (stringp arglist)
  94                      (string-match "\\`([^ ]+\\(.*\\))\\'" arglist))
  95                 (concat "(fn" (match-string 1 arglist) ")")
  96               (format "%S" (help-make-usage 'fn arglist))))))
  97
  98 (defun help-function-arglist (def)
  99   ;; Handle symbols aliased to other symbols.
 100   (if (and (symbolp def) (fboundp def)) (setq def (indirect-function def)))
 101   ;; If definition is a macro, find the function inside it.
 102   (if (eq (car-safe def) 'macro) (setq def (cdr def)))
 103   (cond
 104    ((byte-code-function-p def) (aref def 0))
 105    ((eq (car-safe def) 'lambda) (nth 1 def))
 106    ((and (eq (car-safe def) 'autoload) (not (eq (nth 4 def) 'keymap)))
 107     "[Arg list not available until function definition is loaded.]")
 108    (t t)))
 109
 110 (defun help-make-usage (function arglist)
 111   (cons (if (symbolp function) function 'anonymous)
 112         (mapcar (lambda (arg)
 113                   (if (not (symbolp arg))
 114                       (if (and (consp arg) (symbolp (car arg)))
 115                           ;; CL style default values for optional args.
 116                           (cons (intern (upcase (symbol-name (car arg))))
 117                                 (cdr arg))
 118                         arg)
 119                     (let ((name (symbol-name arg)))
 120                       (if (string-match "\\`&" name) arg
 121                         (intern (upcase name))))))
 122                 arglist)))
 123
 124 ;; Could be this, if we make symbol-file do the work below.
 125 ;; (defun help-C-file-name (subr-or-var kind)
 126 ;;   "Return the name of the C file where SUBR-OR-VAR is defined.
 127 ;; KIND should be `var' for a variable or `subr' for a subroutine."
 128 ;;   (symbol-file (if (symbolp subr-or-var) subr-or-var
 129 ;;               (subr-name subr-or-var))
 130 ;;             (if (eq kind 'var) 'defvar 'defun)))
 131 ;;;###autoload
 132 (defun help-C-file-name (subr-or-var kind)
 133   "Return the name of the C file where SUBR-OR-VAR is defined.
 134 KIND should be `var' for a variable or `subr' for a subroutine."
 135   (let ((docbuf (get-buffer-create " *DOC*"))
 136         (name (if (eq 'var kind)
 137                   (concat "V" (symbol-name subr-or-var))
 138                 (concat "F" (subr-name subr-or-var)))))
 139     (with-current-buffer docbuf
 140       (goto-char (point-min))
 141       (if (eobp)
 142           (insert-file-contents-literally
 143            (expand-file-name internal-doc-file-name doc-directory)))
 144       (let ((file (catch 'loop
 145                     (while t
 146                       (let ((pnt (search-forward (concat "\1f" name "\n"))))
 147                         (re-search-backward "\1fS\\(.*\\)")
 148                         (let ((file (match-string 1)))
 149                           (if (member file build-files)
 150                               (throw 'loop file)
 151                             (goto-char pnt))))))))
 152         (if (string-match "^ns.*\\(\\.o\\|obj\\)\\'" file)
 153             (setq file (replace-match ".m" t t file 1))
 154           (if (string-match "\\.\\(o\\|obj\\)\\'" file)
 155               (setq file (replace-match ".c" t t file))))
 156         (if (string-match "\\.\\(c\\|m\\)\\'" file)
 157             (concat "src/" file)
 158           file)))))
 159
 160 (defcustom help-downcase-arguments nil
 161   "If non-nil, argument names in *Help* buffers are downcased."
 162   :type 'boolean
 163   :group 'help
 164   :version "23.2")
 165
 166 (defun help-highlight-arg (arg)
 167   "Highlight ARG as an argument name for a *Help* buffer.
 168 Return ARG in face `help-argument-name'; ARG is also downcased
 169 if the variable `help-downcase-arguments' is non-nil."
 170   (propertize (if help-downcase-arguments (downcase arg) arg)
 171               'face 'help-argument-name))
 172
 173 (defun help-do-arg-highlight (doc args)
 174   (with-syntax-table (make-syntax-table emacs-lisp-mode-syntax-table)
 175     (modify-syntax-entry ?\- "w")
 176     (dolist (arg args doc)
 177       (setq doc (replace-regexp-in-string
 178                  ;; This is heuristic, but covers all common cases
 179                  ;; except ARG1-ARG2
 180                  (concat "\\<"                   ; beginning of word
 181                          "\\(?:[a-z-]*-\\)?"     ; for xxx-ARG
 182                          "\\("
 183                          (regexp-quote arg)
 184                          "\\)"
 185                          "\\(?:es\\|s\\|th\\)?"  ; for ARGth, ARGs
 186                          "\\(?:-[a-z0-9-]+\\)?"  ; for ARG-xxx, ARG-n
 187                          "\\(?:-[{([<`\"].*?\\)?"; for ARG-{x}, (x), <x>, [x], `x'
 188                          "\\>")                  ; end of word
 189                  (help-highlight-arg arg)
 190                  doc t t 1)))))
 191
 192 (defun help-highlight-arguments (usage doc &rest args)
 193   (when usage
 194     (with-temp-buffer
 195       (insert usage)
 196       (goto-char (point-min))
 197       (let ((case-fold-search nil)
 198             (next (not (or args (looking-at "\\["))))
 199             (opt nil))
 200         ;; Make a list of all arguments
 201         (skip-chars-forward "^ ")
 202         (while next
 203           (or opt (not (looking-at " &")) (setq opt t))
 204           (if (not (re-search-forward " \\([\\[(]*\\)\\([^] &)\.]+\\)" nil t))
 205               (setq next nil)
 206             (setq args (cons (match-string 2) args))
 207             (when (and opt (string= (match-string 1) "("))
 208               ;; A pesky CL-style optional argument with default value,
 209               ;; so let's skip over it
 210               (search-backward "(")
 211               (goto-char (scan-sexps (point) 1)))))
 212         ;; Highlight aguments in the USAGE string
 213         (setq usage (help-do-arg-highlight (buffer-string) args))
 214         ;; Highlight arguments in the DOC string
 215         (setq doc (and doc (help-do-arg-highlight doc args))))))
 216   ;; Return value is like the one from help-split-fundoc, but highlighted
 217   (cons usage doc))
 218
 219 ;; The following function was compiled from the former functions
 220 ;; `describe-simplify-lib-file-name' and `find-source-lisp-file' with
 221 ;; some excerpts from `describe-function-1' and `describe-variable'.
 222 ;; The only additional twists provided are (1) locate the defining file
 223 ;; for autoloaded functions, and (2) give preference to files in the
 224 ;; "install directory" (directories found via `load-path') rather than
 225 ;; to files in the "compile directory" (directories found by searching
 226 ;; the loaddefs.el file).  We autoload it because it's also used by
 227 ;; `describe-face' (instead of `describe-simplify-lib-file-name').
 228
 229 ;;;###autoload
 230 (defun find-lisp-object-file-name (object type)
 231   "Guess the file that defined the Lisp object OBJECT, of type TYPE.
 232 OBJECT should be a symbol associated with a function, variable, or face;
 233   alternatively, it can be a function definition.
 234 If TYPE is `defvar', search for a variable definition.
 235 If TYPE is `defface', search for a face definition.
 236 If TYPE is the value returned by `symbol-function' for a function symbol,
 237  search for a function definition.
 238
 239 The return value is the absolute name of a readable file where OBJECT is
 240 defined.  If several such files exist, preference is given to a file
 241 found via `load-path'.  The return value can also be `C-source', which
 242 means that OBJECT is a function or variable defined in C.  If no
 243 suitable file is found, return nil."
 244   (let* ((autoloaded (eq (car-safe type) 'autoload))
 245          (file-name (or (and autoloaded (nth 1 type))
 246                         (symbol-file
 247                          object (if (memq type (list 'defvar 'defface))
 248                                     type
 249                                   'defun)))))
 250     (cond
 251      (autoloaded
 252       ;; An autoloaded function: Locate the file since `symbol-function'
 253       ;; has only returned a bare string here.
 254       (setq file-name
 255             (locate-file file-name load-path '(".el" ".elc") 'readable)))
 256      ((and (stringp file-name)
 257            (string-match "[.]*loaddefs.el\\'" file-name))
 258       ;; An autoloaded variable or face.  Visit loaddefs.el in a buffer
 259       ;; and try to extract the defining file.  The following form is
 260       ;; from `describe-function-1' and `describe-variable'.
 261       (let ((location
 262              (condition-case nil
 263                  (find-function-search-for-symbol object nil file-name)
 264                (error nil))))
 265         (when (cdr location)
 266           (with-current-buffer (car location)
 267             (goto-char (cdr location))
 268             (when (re-search-backward
 269                    "^;;; Generated autoloads from \\(.*\\)" nil t)
 270               (setq file-name
 271                     (locate-file
 272                      (file-name-sans-extension
 273                       (match-string-no-properties 1))
 274                      load-path '(".el" ".elc") 'readable))))))))
 275
 276     (cond
 277      ((and (not file-name) (subrp type))
 278       ;; A built-in function.  The form is from `describe-function-1'.
 279       (if (get-buffer " *DOC*")
 280           (help-C-file-name type 'subr)
 281         'C-source))
 282      ((and (not file-name) (symbolp object)
 283            (integerp (get object 'variable-documentation)))
 284       ;; A variable defined in C.  The form is from `describe-variable'.
 285       (if (get-buffer " *DOC*")
 286           (help-C-file-name object 'var)
 287         'C-source))
 288      ((not (stringp file-name))
 289       ;; If we don't have a file-name string by now, we lost.
 290       nil)
 291      ;; Now, `file-name' should have become an absolute file name.
 292      ;; For files loaded from ~/.emacs.elc, try ~/.emacs.
 293      ((let (fn)
 294         (and (string-equal file-name
 295                            (expand-file-name ".emacs.elc" "~"))
 296              (file-readable-p (setq fn (expand-file-name ".emacs" "~")))
 297              fn)))
 298      ;; When the Elisp source file can be found in the install
 299      ;; directory, return the name of that file.
 300      ((let ((lib-name
 301              (if (string-match "[.]elc\\'" file-name)
 302                  (substring-no-properties file-name 0 -1)
 303                file-name)))
 304         (or (and (file-readable-p lib-name) lib-name)
 305             ;; The library might be compressed.
 306             (and (file-readable-p (concat lib-name ".gz")) lib-name))))
 307      ((let* ((lib-name (file-name-nondirectory file-name))
 308              ;; The next form is from `describe-simplify-lib-file-name'.
 309              (file-name
 310               ;; Try converting the absolute file name to a library
 311               ;; name, convert that back to a file name and see if we
 312               ;; get the original one.  If so, they are equivalent.
 313               (if (equal file-name (locate-file lib-name load-path '("")))
 314                   (if (string-match "[.]elc\\'" lib-name)
 315                       (substring-no-properties lib-name 0 -1)
 316                     lib-name)
 317                 file-name))
 318              ;; The next three forms are from `find-source-lisp-file'.
 319              (elc-file (locate-file
 320                         (concat file-name
 321                                 (if (string-match "\\.el\\'" file-name)
 322                                     "c"
 323                                   ".elc"))
 324                         load-path nil 'readable))
 325              (str (when elc-file
 326                     (with-temp-buffer
 327                       (insert-file-contents-literally elc-file nil 0 256)
 328                       (buffer-string))))
 329              (src-file (and str
 330                             (string-match ";;; from file \\(.*\\.el\\)" str)
 331                             (match-string 1 str))))
 332         (and src-file (file-readable-p src-file) src-file))))))
 333
 334 (declare-function ad-get-advice-info "advice" (function))
 335
 336 ;;;###autoload
 337 (defun describe-function-1 (function)
 338   (let* ((advised (and (symbolp function) (featurep 'advice)
 339                        (ad-get-advice-info function)))
 340          ;; If the function is advised, use the symbol that has the
 341          ;; real definition, if that symbol is already set up.
 342          (real-function
 343           (or (and advised
 344                    (let ((origname (cdr (assq 'origname advised))))
 345                      (and (fboundp origname) origname)))
 346               function))
 347          ;; Get the real definition.
 348          (def (if (symbolp real-function)
 349                   (symbol-function real-function)
 350                 function))
 351          file-name string
 352          (beg (if (commandp def) "an interactive " "a "))
 353          (pt1 (with-current-buffer (help-buffer) (point)))
 354          errtype)
 355     (setq string
 356           (cond ((or (stringp def)
 357                      (vectorp def))
 358                  "a keyboard macro")
 359                 ((subrp def)
 360                  (if (eq 'unevalled (cdr (subr-arity def)))
 361                      (concat beg "special form")
 362                    (concat beg "built-in function")))
 363                 ((byte-code-function-p def)
 364                  (concat beg "compiled Lisp function"))
 365                 ((symbolp def)
 366                  (while (and (fboundp def)
 367                              (symbolp (symbol-function def)))
 368                    (setq def (symbol-function def)))
 369                  ;; Handle (defalias 'foo 'bar), where bar is undefined.
 370                  (or (fboundp def) (setq errtype 'alias))
 371                  (format "an alias for `%s'" def))
 372                 ((eq (car-safe def) 'lambda)
 373                  (concat beg "Lisp function"))
 374                 ((eq (car-safe def) 'macro)
 375                  "a Lisp macro")
 376                 ((eq (car-safe def) 'autoload)
 377                  (format "%s autoloaded %s"
 378                          (if (commandp def) "an interactive" "an")
 379                          (if (eq (nth 4 def) 'keymap) "keymap"
 380                            (if (nth 4 def) "Lisp macro" "Lisp function"))))
 381                 ((keymapp def)
 382                  (let ((is-full nil)
 383                        (elts (cdr-safe def)))
 384                    (while elts
 385                      (if (char-table-p (car-safe elts))
 386                          (setq is-full t
 387                                elts nil))
 388                      (setq elts (cdr-safe elts)))
 389                    (if is-full
 390                        "a full keymap"
 391                      "a sparse keymap")))
 392                 (t "")))
 393     (princ string)
 394     (if (eq errtype 'alias)
 395         (princ ",\nwhich is not defined.  Please make a bug report.")
 396       (with-current-buffer standard-output
 397         (save-excursion
 398           (save-match-data
 399             (when (re-search-backward "alias for `\\([^`']+\\)'" nil t)
 400               (help-xref-button 1 'help-function def)))))
 401
 402       (setq file-name (find-lisp-object-file-name function def))
 403       (when file-name
 404         (princ " in `")
 405         ;; We used to add .el to the file name,
 406         ;; but that's completely wrong when the user used load-file.
 407         (princ (if (eq file-name 'C-source)
 408                    "C source code"
 409                  (file-name-nondirectory file-name)))
 410         (princ "'")
 411         ;; Make a hyperlink to the library.
 412         (with-current-buffer standard-output
 413           (save-excursion
 414             (re-search-backward "`\\([^`']+\\)'" nil t)
 415             (help-xref-button 1 'help-function-def function file-name))))
 416       (princ ".")
 417       (with-current-buffer (help-buffer)
 418         (fill-region-as-paragraph (save-excursion (goto-char pt1) (forward-line 0) (point))
 419                                   (point)))
 420       (terpri)(terpri)
 421       (when (commandp function)
 422         (let ((pt2 (with-current-buffer (help-buffer) (point)))
 423               (remapped (command-remapping function)))
 424           (unless (memq remapped '(ignore undefined))
 425             (let ((keys (where-is-internal
 426                          (or remapped function) overriding-local-map nil nil))
 427                   non-modified-keys)
 428               (if (and (eq function 'self-insert-command)
 429                        (vectorp (car-safe keys))
 430                        (consp (aref (car keys) 0)))
 431                   (princ "It is bound to many ordinary text characters.\n")
 432                 ;; Which non-control non-meta keys run this command?
 433                 (dolist (key keys)
 434                   (if (member (event-modifiers (aref key 0)) '(nil (shift)))
 435                       (push key non-modified-keys)))
 436                 (when remapped
 437                   (princ "It is remapped to `")
 438                   (princ (symbol-name remapped))
 439                   (princ "'"))
 440
 441                 (when keys
 442                   (princ (if remapped ", which is bound to " "It is bound to "))
 443                   ;; If lots of ordinary text characters run this command,
 444                   ;; don't mention them one by one.
 445                   (if (< (length non-modified-keys) 10)
 446                       (princ (mapconcat 'key-description keys ", "))
 447                     (dolist (key non-modified-keys)
 448                       (setq keys (delq key keys)))
 449                     (if keys
 450                         (progn
 451                           (princ (mapconcat 'key-description keys ", "))
 452                           (princ ", and many ordinary text characters"))
 453                       (princ "many ordinary text characters"))))
 454                 (when (or remapped keys non-modified-keys)
 455                   (princ ".")
 456                   (terpri)))))
 457
 458           (with-current-buffer (help-buffer)
 459             (fill-region-as-paragraph pt2 (point))
 460             (unless (looking-back "\n\n")
 461               (terpri)))))
 462       ;; Note that list* etc do not get this property until
 463       ;; cl-hack-byte-compiler runs, after bytecomp is loaded.
 464       (when (and (symbolp function)
 465                  (eq (get function 'byte-compile)
 466                      'cl-byte-compile-compiler-macro))
 467         (princ "This function has a compiler macro")
 468         (let ((lib (get function 'compiler-macro-file)))
 469           (when (stringp lib)
 470             (princ (format " in `%s'" lib))
 471             (with-current-buffer standard-output
 472               (save-excursion
 473                 (re-search-backward "`\\([^`']+\\)'" nil t)
 474                 (help-xref-button 1 'help-function-cmacro function lib)))))
 475         (princ ".\n\n"))
 476       (let* ((advertised (gethash def advertised-signature-table t))
 477              (arglist (if (listp advertised)
 478                           advertised (help-function-arglist def)))
 479              (doc (documentation function))
 480              (usage (help-split-fundoc doc function)))
 481         (with-current-buffer standard-output
 482           ;; If definition is a keymap, skip arglist note.
 483           (unless (keymapp function)
 484             (if usage (setq doc (cdr usage)))
 485             (let* ((use (cond
 486                          ((and usage (not (listp advertised))) (car usage))
 487                          ((listp arglist)
 488                           (format "%S" (help-make-usage function arglist)))
 489                          ((stringp arglist) arglist)
 490                          ;; Maybe the arglist is in the docstring of a symbol
 491                          ;; this one is aliased to.
 492                          ((let ((fun real-function))
 493                             (while (and (symbolp fun)
 494                                         (setq fun (symbol-function fun))
 495                                         (not (setq usage (help-split-fundoc
 496                                                           (documentation fun)
 497                                                           function)))))
 498                             usage)
 499                           (car usage))
 500                          ((or (stringp def)
 501                               (vectorp def))
 502                           (format "\nMacro: %s" (format-kbd-macro def)))
 503                          (t "[Missing arglist.  Please make a bug report.]")))
 504                    (high (help-highlight-arguments use doc)))
 505               (let ((fill-begin (point)))
 506                 (insert (car high) "\n")
 507                 (fill-region fill-begin (point)))
 508               (setq doc (cdr high))))
 509           (let* ((obsolete (and
 510                             ;; function might be a lambda construct.
 511                             (symbolp function)
 512                             (get function 'byte-obsolete-info)))
 513                  (use (car obsolete)))
 514             (when obsolete
 515               (princ "\nThis function is obsolete")
 516               (when (nth 2 obsolete)
 517                 (insert (format " since %s" (nth 2 obsolete))))
 518               (insert (cond ((stringp use) (concat ";\n" use))
 519                             (use (format ";\nuse `%s' instead." use))
 520                             (t "."))
 521                       "\n"))
 522             (insert "\n"
 523                     (or doc "Not documented."))))))))
 524
 525 \f
 526 ;; Variables
 527
 528 ;;;###autoload
 529 (defun variable-at-point (&optional any-symbol)
 530   "Return the bound variable symbol found at or before point.
 531 Return 0 if there is no such symbol.
 532 If ANY-SYMBOL is non-nil, don't insist the symbol be bound."
 533   (with-syntax-table emacs-lisp-mode-syntax-table
 534     (or (condition-case ()
 535             (save-excursion
 536               (or (not (zerop (skip-syntax-backward "_w")))
 537                   (eq (char-syntax (following-char)) ?w)
 538                   (eq (char-syntax (following-char)) ?_)
 539                   (forward-sexp -1))
 540               (skip-chars-forward "'")
 541               (let ((obj (read (current-buffer))))
 542                 (and (symbolp obj) (boundp obj) obj)))
 543           (error nil))
 544         (let* ((str (find-tag-default))
 545                (sym (if str (intern-soft str))))
 546           (if (and sym (or any-symbol (boundp sym)))
 547               sym
 548             (save-match-data
 549               (when (and str (string-match "\\`\\W*\\(.*?\\)\\W*\\'" str))
 550                 (setq sym (intern-soft (match-string 1 str)))
 551                 (and (or any-symbol (boundp sym)) sym)))))
 552         0)))
 553
 554 (defun describe-variable-custom-version-info (variable)
 555   (let ((custom-version (get variable 'custom-version))
 556         (cpv (get variable 'custom-package-version))
 557         (output nil))
 558     (if custom-version
 559         (setq output
 560               (format "This variable was introduced, or its default value was changed, in\nversion %s of Emacs.\n"
 561                       custom-version))
 562       (when cpv
 563         (let* ((package (car-safe cpv))
 564                (version (if (listp (cdr-safe cpv))
 565                             (car (cdr-safe cpv))
 566                           (cdr-safe cpv)))
 567                (pkg-versions (assq package customize-package-emacs-version-alist))
 568                (emacsv (cdr (assoc version pkg-versions))))
 569           (if (and package version)
 570               (setq output
 571                     (format (concat "This variable was introduced, or its default value was changed, in\nversion %s of the %s package"
 572                                     (if emacsv
 573                                         (format " that is part of Emacs %s" emacsv))
 574                                     ".\n")
 575                             version package))))))
 576     output))
 577
 578 ;;;###autoload
 579 (defun describe-variable (variable &optional buffer frame)
 580   "Display the full documentation of VARIABLE (a symbol).
 581 Returns the documentation as a string, also.
 582 If VARIABLE has a buffer-local value in BUFFER or FRAME
 583 \(default to the current buffer and current frame),
 584 it is displayed along with the global value."
 585   (interactive
 586    (let ((v (variable-at-point))
 587          (enable-recursive-minibuffers t)
 588          val)
 589      (setq val (completing-read (if (symbolp v)
 590                                     (format
 591                                      "Describe variable (default %s): " v)
 592                                   "Describe variable: ")
 593                                 obarray
 594                                 '(lambda (vv)
 595                                    (or (boundp vv)
 596                                        (get vv 'variable-documentation)))
 597                                 t nil nil
 598                                 (if (symbolp v) (symbol-name v))))
 599      (list (if (equal val "")
 600                v (intern val)))))
 601   (let (file-name)
 602     (unless (buffer-live-p buffer) (setq buffer (current-buffer)))
 603     (unless (frame-live-p frame) (setq frame (selected-frame)))
 604     (if (not (symbolp variable))
 605         (message "You did not specify a variable")
 606       (save-excursion
 607         (let ((valvoid (not (with-current-buffer buffer (boundp variable))))
 608               val val-start-pos locus)
 609           ;; Extract the value before setting up the output buffer,
 610           ;; in case `buffer' *is* the output buffer.
 611           (unless valvoid
 612             (with-selected-frame frame
 613               (with-current-buffer buffer
 614                 (setq val (symbol-value variable)
 615                       locus (variable-binding-locus variable)))))
 616           (help-setup-xref (list #'describe-variable variable buffer)
 617                            (called-interactively-p 'interactive))
 618           (with-help-window (help-buffer)
 619             (with-current-buffer buffer
 620               (prin1 variable)
 621               (setq file-name (find-lisp-object-file-name variable 'defvar))
 622
 623               (if file-name
 624                   (progn
 625                     (princ " is a variable defined in `")
 626                     (princ (if (eq file-name 'C-source)
 627                                "C source code"
 628                              (file-name-nondirectory file-name)))
 629                     (princ "'.\n")
 630                     (with-current-buffer standard-output
 631                       (save-excursion
 632                         (re-search-backward "`\\([^`']+\\)'" nil t)
 633                         (help-xref-button 1 'help-variable-def
 634                                           variable file-name)))
 635                     (if valvoid
 636                         (princ "It is void as a variable.")
 637                       (princ "Its ")))
 638                 (if valvoid
 639                     (princ " is void as a variable.")
 640                   (princ "'s "))))
 641             (unless valvoid
 642               (with-current-buffer standard-output
 643                 (setq val-start-pos (point))
 644                 (princ "value is ")
 645                 (let ((from (point)))
 646                   (terpri)
 647                   (pp val)
 648                   (if (< (point) (+ 68 (line-beginning-position 0)))
 649                       (delete-region from (1+ from))
 650                     (delete-region (1- from) from))
 651                   (let* ((sv (get variable 'standard-value))
 652                          (origval (and (consp sv)
 653                                        (condition-case nil
 654                                            (eval (car sv))
 655                                          (error :help-eval-error)))))
 656                     (when (and (consp sv)
 657                                (not (equal origval val))
 658                                (not (equal origval :help-eval-error)))
 659                       (princ "\nOriginal value was \n")
 660                       (setq from (point))
 661                       (pp origval)
 662                       (if (< (point) (+ from 20))
 663                           (delete-region (1- from) from)))))))
 664             (terpri)
 665             (when locus
 666               (if (bufferp locus)
 667                   (princ (format "%socal in buffer %s; "
 668                                  (if (get variable 'permanent-local)
 669                                      "Permanently l" "L")
 670                                  (buffer-name)))
 671                 (princ (format "It is a frame-local variable; ")))
 672               (if (not (default-boundp variable))
 673                   (princ "globally void")
 674                 (let ((val (default-value variable)))
 675                   (with-current-buffer standard-output
 676                     (princ "global value is ")
 677                     (terpri)
 678                     ;; Fixme: pp can take an age if you happen to
 679                     ;; ask for a very large expression.  We should
 680                     ;; probably print it raw once and check it's a
 681                     ;; sensible size before prettyprinting.  -- fx
 682                     (let ((from (point)))
 683                       (pp val)
 684                       ;; See previous comment for this function.
 685                       ;; (help-xref-on-pp from (point))
 686                       (if (< (point) (+ from 20))
 687                           (delete-region (1- from) from))))))
 688               (terpri))
 689
 690             ;; If the value is large, move it to the end.
 691             (with-current-buffer standard-output
 692               (when (> (count-lines (point-min) (point-max)) 10)
 693                 ;; Note that setting the syntax table like below
 694                 ;; makes forward-sexp move over a `'s' at the end
 695                 ;; of a symbol.
 696                 (set-syntax-table emacs-lisp-mode-syntax-table)
 697                 (goto-char val-start-pos)
 698                 ;; The line below previously read as
 699                 ;; (delete-region (point) (progn (end-of-line) (point)))
 700                 ;; which suppressed display of the buffer local value for
 701                 ;; large values.
 702                 (when (looking-at "value is") (replace-match ""))
 703                 (save-excursion
 704                   (insert "\n\nValue:")
 705                   (set (make-local-variable 'help-button-cache)
 706                        (point-marker)))
 707                 (insert "value is shown ")
 708                 (insert-button "below"
 709                                'action help-button-cache
 710                                'follow-link t
 711                                'help-echo "mouse-2, RET: show value")
 712                 (insert ".\n")))
 713             (terpri)
 714
 715             (let* ((alias (condition-case nil
 716                               (indirect-variable variable)
 717                             (error variable)))
 718                    (obsolete (get variable 'byte-obsolete-variable))
 719                    (use (car obsolete))
 720                    (safe-var (get variable 'safe-local-variable))
 721                    (doc (or (documentation-property variable 'variable-documentation)
 722                             (documentation-property alias 'variable-documentation)))
 723                    (extra-line nil))
 724               ;; Add a note for variables that have been make-var-buffer-local.
 725               (when (and (local-variable-if-set-p variable)
 726                          (or (not (local-variable-p variable))
 727                              (with-temp-buffer
 728                                (local-variable-if-set-p variable))))
 729                 (setq extra-line t)
 730                 (princ "  Automatically becomes buffer-local when set in any fashion.\n"))
 731
 732               ;; Mention if it's an alias
 733               (unless (eq alias variable)
 734                 (setq extra-line t)
 735                 (princ (format "  This variable is an alias for `%s'.\n" alias)))
 736
 737               (when obsolete
 738                 (setq extra-line t)
 739                 (princ "  This variable is obsolete")
 740                 (if (cdr obsolete) (princ (format " since %s" (cdr obsolete))))
 741                 (princ (cond ((stringp use) (concat ";\n  " use))
 742                              (use (format ";\n  use `%s' instead." (car obsolete)))
 743                              (t ".")))
 744                 (terpri))
 745
 746               (when (member (cons variable val) file-local-variables-alist)
 747                 (setq extra-line t)
 748                 (if (member (cons variable val) dir-local-variables-alist)
 749                     (let ((file (and (buffer-file-name)
 750                                      (not (file-remote-p (buffer-file-name)))
 751                                      (dir-locals-find-file (buffer-file-name)))))
 752                       (princ "  This variable is a directory local variable")
 753                       (when file
 754                         (princ (concat "\n  from the file \""
 755                                        (if (consp file)
 756                                            (car file)
 757                                          file)
 758                                        "\"")))
 759                       (princ ".\n"))
 760                   (princ "  This variable is a file local variable.\n")))
 761
 762               (when (memq variable ignored-local-variables)
 763                 (setq extra-line t)
 764                 (princ "  This variable is ignored when used as a file local \
 765 variable.\n"))
 766
 767               ;; Can be both risky and safe, eg auto-fill-function.
 768               (when (risky-local-variable-p variable)
 769                 (setq extra-line t)
 770                 (princ "  This variable is potentially risky when used as a \
 771 file local variable.\n")
 772                 (when (assq variable safe-local-variable-values)
 773                   (princ "  However, you have added it to \
 774 `safe-local-variable-values'.\n")))
 775
 776               (when safe-var
 777                 (setq extra-line t)
 778                 (princ "  This variable is safe as a file local variable ")
 779                 (princ "if its value\n  satisfies the predicate ")
 780                 (princ (if (byte-code-function-p safe-var)
 781                            "which is byte-compiled expression.\n"
 782                          (format "`%s'.\n" safe-var))))
 783
 784               (if extra-line (terpri))
 785               (princ "Documentation:\n")
 786               (with-current-buffer standard-output
 787                 (insert (or doc "Not documented as a variable."))))
 788
 789             ;; Make a link to customize if this variable can be customized.
 790             (when (custom-variable-p variable)
 791               (let ((customize-label "customize"))
 792                 (terpri)
 793                 (terpri)
 794                 (princ (concat "You can " customize-label " this variable."))
 795                 (with-current-buffer standard-output
 796                   (save-excursion
 797                     (re-search-backward
 798                      (concat "\\(" customize-label "\\)") nil t)
 799                     (help-xref-button 1 'help-customize-variable variable))))
 800               ;; Note variable's version or package version
 801               (let ((output (describe-variable-custom-version-info variable)))
 802                 (when output
 803                   (terpri)
 804                   (terpri)
 805                   (princ output))))
 806
 807             (with-current-buffer standard-output
 808               ;; Return the text we displayed.
 809               (buffer-string))))))))
 810
 811
 812 ;;;###autoload
 813 (defun describe-syntax (&optional buffer)
 814   "Describe the syntax specifications in the syntax table of BUFFER.
 815 The descriptions are inserted in a help buffer, which is then displayed.
 816 BUFFER defaults to the current buffer."
 817   (interactive)
 818   (setq buffer (or buffer (current-buffer)))
 819   (help-setup-xref (list #'describe-syntax buffer)
 820                    (called-interactively-p 'interactive))
 821   (with-help-window (help-buffer)
 822     (let ((table (with-current-buffer buffer (syntax-table))))
 823       (with-current-buffer standard-output
 824         (describe-vector table 'internal-describe-syntax-value)
 825         (while (setq table (char-table-parent table))
 826           (insert "\nThe parent syntax table is:")
 827           (describe-vector table 'internal-describe-syntax-value))))))
 828
 829 (defun help-describe-category-set (value)
 830   (insert (cond
 831            ((null value) "default")
 832            ((char-table-p value) "deeper char-table ...")
 833            (t (condition-case err
 834                   (category-set-mnemonics value)
 835                 (error "invalid"))))))
 836
 837 ;;;###autoload
 838 (defun describe-categories (&optional buffer)
 839   "Describe the category specifications in the current category table.
 840 The descriptions are inserted in a buffer, which is then displayed.
 841 If BUFFER is non-nil, then describe BUFFER's category table instead.
 842 BUFFER should be a buffer or a buffer name."
 843   (interactive)
 844   (setq buffer (or buffer (current-buffer)))
 845   (help-setup-xref (list #'describe-categories buffer)
 846                    (called-interactively-p 'interactive))
 847   (with-help-window (help-buffer)
 848     (let* ((table (with-current-buffer buffer (category-table)))
 849            (docs (char-table-extra-slot table 0)))
 850       (if (or (not (vectorp docs)) (/= (length docs) 95))
 851           (error "Invalid first extra slot in this category table\n"))
 852       (with-current-buffer standard-output
 853         (insert "Legend of category mnemonics (see the tail for the longer description)\n")
 854         (let ((pos (point)) (items 0) lines n)
 855           (dotimes (i 95)
 856             (if (aref docs i) (setq items (1+ items))))
 857           (setq lines (1+ (/ (1- items) 4)))
 858           (setq n 0)
 859           (dotimes (i 95)
 860             (let ((elt (aref docs i)))
 861               (when elt
 862                 (string-match ".*" elt)
 863                 (setq elt (match-string 0 elt))
 864                 (if (>= (length elt) 17)
 865                     (setq elt (concat (substring elt 0 14) "...")))
 866                 (if (< (point) (point-max))
 867                     (move-to-column (* 20 (/ n lines)) t))
 868                 (insert (+ i ?\s) ?: elt)
 869                 (if (< (point) (point-max))
 870                     (forward-line 1)
 871                   (insert "\n"))
 872                 (setq n (1+ n))
 873                 (if (= (% n lines) 0)
 874                     (goto-char pos))))))
 875         (goto-char (point-max))
 876         (insert "\n"
 877                 "character(s)\tcategory mnemonics\n"
 878                 "------------\t------------------")
 879         (describe-vector table 'help-describe-category-set)
 880         (insert "Legend of category mnemonics:\n")
 881         (dotimes (i 95)
 882           (let ((elt (aref docs i)))
 883             (when elt
 884               (if (string-match "\n" elt)
 885                   (setq elt (substring elt (match-end 0))))
 886               (insert (+ i ?\s) ": " elt "\n"))))
 887         (while (setq table (char-table-parent table))
 888           (insert "\nThe parent category table is:")
 889           (describe-vector table 'help-describe-category-set))))))
 890
 891 \f
 892 ;;; Replacements for old lib-src/ programs.  Don't seem especially useful.
 893
 894 ;; Replaces lib-src/digest-doc.c.
 895 ;;;###autoload
 896 (defun doc-file-to-man (file)
 897   "Produce an nroff buffer containing the doc-strings from the DOC file."
 898   (interactive (list (read-file-name "Name of DOC file: " doc-directory
 899                                      internal-doc-file-name t)))
 900   (or (file-readable-p file)
 901       (error "Cannot read file `%s'" file))
 902   (pop-to-buffer (generate-new-buffer "*man-doc*"))
 903   (setq buffer-undo-list t)
 904   (insert ".TH \"Command Summary for GNU Emacs\"\n"
 905           ".AU Richard M. Stallman\n")
 906   (insert-file-contents file)
 907   (let (notfirst)
 908     (while (search-forward "\1f" nil 'move)
 909       (if (looking-at "S")
 910           (delete-region (1- (point)) (line-end-position))
 911         (delete-char -1)
 912         (if notfirst
 913             (insert "\n.DE\n")
 914           (setq notfirst t))
 915         (insert "\n.SH ")
 916         (insert (if (looking-at "F") "Function " "Variable "))
 917         (delete-char 1)
 918         (forward-line 1)
 919         (insert ".DS L\n"))))
 920   (insert "\n.DE\n")
 921   (setq buffer-undo-list nil)
 922   (nroff-mode))
 923
 924 ;; Replaces lib-src/sorted-doc.c.
 925 ;;;###autoload
 926 (defun doc-file-to-info (file)
 927   "Produce a texinfo buffer with sorted doc-strings from the DOC file."
 928   (interactive (list (read-file-name "Name of DOC file: " doc-directory
 929                                      internal-doc-file-name t)))
 930   (or (file-readable-p file)
 931       (error "Cannot read file `%s'" file))
 932   (let ((i 0) type name doc alist)
 933     (with-temp-buffer
 934       (insert-file-contents file)
 935       ;; The characters "@{}" need special treatment.
 936       (while (re-search-forward "[@{}]" nil t)
 937         (backward-char)
 938         (insert "@")
 939         (forward-char 1))
 940       (goto-char (point-min))
 941       (while (search-forward "\1f" nil t)
 942         (unless (looking-at "S")
 943           (setq type (char-after)
 944                 name (buffer-substring (1+ (point)) (line-end-position))
 945                 doc (buffer-substring (line-beginning-position 2)
 946                                       (if (search-forward  "\1f" nil 'move)
 947                                           (1- (point))
 948                                         (point)))
 949                 alist (cons (list name type doc) alist))
 950           (backward-char 1))))
 951     (pop-to-buffer (generate-new-buffer "*info-doc*"))
 952     (setq buffer-undo-list t)
 953     ;; Write the output header.
 954     (insert "\\input texinfo  @c -*-texinfo-*-\n"
 955             "@setfilename emacsdoc.info\n"
 956             "@settitle Command Summary for GNU Emacs\n"
 957             "@finalout\n"
 958             "\n@node Top\n"
 959             "@unnumbered Command Summary for GNU Emacs\n\n"
 960             "@table @asis\n\n"
 961             "@iftex\n"
 962             "@global@let@ITEM@item\n"
 963             "@def@item{@filbreak@vskip5pt@ITEM}\n"
 964             "@font@tensy cmsy10 scaled @magstephalf\n"
 965             "@font@teni cmmi10 scaled @magstephalf\n"
 966             "@def\\{{@tensy@char110}}\n" ; this backslash goes with cmr10
 967             "@def|{{@tensy@char106}}\n"
 968             "@def@{{{@tensy@char102}}\n"
 969             "@def@}{{@tensy@char103}}\n"
 970             "@def<{{@teni@char62}}\n"
 971             "@def>{{@teni@char60}}\n"
 972             "@chardef@@64\n"
 973             "@catcode43=12\n"
 974             "@tableindent-0.2in\n"
 975             "@end iftex\n")
 976     ;; Sort the array by name; within each name, by type (functions first).
 977     (setq alist (sort alist (lambda (e1 e2)
 978                               (if (string-equal (car e1) (car e2))
 979                                   (<= (cadr e1) (cadr e2))
 980                                 (string-lessp (car e1) (car e2))))))
 981     ;; Print each function.
 982     (dolist (e alist)
 983       (insert "\n@item "
 984               (if (char-equal (cadr e) ?\F) "Function" "Variable")
 985               " @code{" (car e) "}\n@display\n"
 986               (nth 2 e)
 987               "\n@end display\n")
 988       ;; Try to avoid a save size overflow in the TeX output routine.
 989       (if (zerop (setq i (% (1+ i) 100)))
 990           (insert "\n@end table\n@table @asis\n")))
 991     (insert "@end table\n"
 992             "@bye\n")
 993     (setq buffer-undo-list nil)
 994     (texinfo-mode)))
 995
 996 (provide 'help-fns)
 997
 998 ;;; help-fns.el ends here