code.delx.au - gnu-emacs/blob - lisp/progmodes/ld-script.el

   1 ;;; ld-script.el --- GNU linker script editing mode for Emacs
   2
   3 ;; Copyright (C) 2001-2011  Free Software Foundation, Inc.
   4
   5 ;; Author: Masatake YAMATO<jet@gyve.org>
   6 ;; Keywords: languages, faces
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; Major mode for editing GNU linker (ld) scripts.
  26
  27 ;;; Code:
  28
  29 ;; Custom
  30 (defgroup ld-script nil
  31   "GNU linker script code editing commands for Emacs."
  32   :prefix "ld-script-"
  33   :group 'languages)
  34
  35 (defvar ld-script-location-counter-face 'ld-script-location-counter)
  36 (defface ld-script-location-counter
  37   '((t :weight bold :inherit font-lock-builtin-face))
  38   "Face for location counter in GNU ld script."
  39   :group 'ld-script)
  40
  41 ;; Syntax rules
  42 (defvar ld-script-mode-syntax-table
  43   (let ((st (make-syntax-table)))
  44     (modify-syntax-entry ?\  "-"   st)
  45     (modify-syntax-entry ?{ "(}" st)
  46     (modify-syntax-entry ?} "){" st)
  47     (modify-syntax-entry ?\( "()" st)
  48     (modify-syntax-entry ?\) ")(" st)
  49     (modify-syntax-entry ?\[ "(]" st)
  50     (modify-syntax-entry ?\] ")[" st)
  51     (modify-syntax-entry ?_ "w"   st)
  52     (modify-syntax-entry ?. "_"   st)
  53     (modify-syntax-entry ?\\  "\\" st)
  54     (modify-syntax-entry ?: "." st)
  55     (modify-syntax-entry ?, "." st)
  56     (modify-syntax-entry ?? "." st)
  57     (modify-syntax-entry ?= "." st)
  58     (modify-syntax-entry ?* ". 23" st)
  59     (modify-syntax-entry ?/ ". 14" st)
  60     (modify-syntax-entry ?+ "." st)
  61     (modify-syntax-entry ?- "." st)
  62     (modify-syntax-entry ?! "." st)
  63     (modify-syntax-entry ?~ "." st)
  64     (modify-syntax-entry ?% "." st)
  65     (modify-syntax-entry ?< "." st)
  66     (modify-syntax-entry ?> "." st)
  67     (modify-syntax-entry ?& "." st)
  68     (modify-syntax-entry ?| "." st)
  69     (modify-syntax-entry ?\" "\"" st)
  70     st)
  71   "Syntax table used while in `ld-script-mode'.")
  72
  73 ;; Font lock keywords
  74 ;; (The section number comes from ld's info.)
  75 (defvar ld-script-keywords
  76   '(
  77     ;; 3.4.1 Setting the Entry Point
  78     "ENTRY"
  79     ;; 3.4.2 Commands Dealing with Files
  80     "INCLUDE" "INPUT" "GROUP" "AS_NEEDED" "OUTPUT" "SEARCH_DIR" "STARTUP"
  81     ;; 3.4.3 Commands Dealing with Object File Formats
  82     "OUTPUT_FORMAT" "TARGET"
  83     ;; 3.4.3 Other Linker Script Commands
  84     "ASSERT" "EXTERN" "FORCE_COMMON_ALLOCATION"
  85     "INHIBIT_COMMON_ALLOCATION" "NOCROSSREFS" "OUTPUT_ARCH"
  86     ;; 3.5.2 PROVIDE
  87     "PROVIDE"
  88     ;; 3.5.3 PROVIDE_HIDDEN
  89     "PROVIDE_HIDDEN"
  90     ;; 3.6 SECTIONS Command
  91     "SECTIONS"
  92     ;; 3.6.4.2 Input Section Wildcard Patterns
  93     "SORT" "SORT_BY_NAME" "SORT_BY_ALIGNMENT"
  94     ;; 3.6.4.3 Input Section for Common Symbols
  95     "COMMON"
  96     ;; 3.6.4.4 Input Section and Garbage Collection
  97     "KEEP"
  98     ;; 3.6.5 Output Section Data
  99     "BYTE" "SHORT" "LONG" "QUAD" "SQUAD" "FILL"
 100     ;; 3.6.6 Output Section Keywords
 101     "CREATE_OBJECT_SYMBOLS" "CONSTRUCTORS"
 102     "__CTOR_LIST__" "__CTOR_END__" "__DTOR_LIST__" "__DTOR_END__"
 103     ;; 3.6.7 Output Section Discarding
 104     ;; See `ld-script-font-lock-keywords'
 105     ;; 3.6.8.1 Output Section Type
 106     "NOLOAD" "DSECT" "COPY" "INFO" "OVERLAY"
 107     ;; 3.6.8.2 Output Section LMA
 108     "AT"
 109     ;; 3.6.8.4 Forced Input Alignment
 110     "SUBALIGN"
 111     ;; 3.6.8.6 Output Section Phdr
 112     ":PHDR"
 113     ;; 3.7 MEMORY Command
 114     "MEMORY"
 115     ;; 3.8 PHDRS Command
 116     "PHDRS" "FILEHDR" "FLAGS"
 117     "PT_NULL" "PT_LOAD" "PT_DYNAMIC" "PT_INTERP" "PT_NONE" "PT_SHLIB" "PT_PHDR"
 118     ;; 3.9 VERSION Command
 119     "VERSION")
 120   "Keywords used of GNU ld script.")
 121
 122 ;; 3.10.8 Builtin Functions
 123 (defvar ld-script-builtins
 124   '("ABSOLUTE"
 125     "ADDR"
 126     "ALIGN"
 127     "BLOCK"
 128     "DATA_SEGMENT_ALIGN"
 129     "DATA_SEGMENT_END"
 130     "DATA_SEGMENT_RELRO_END"
 131     "DEFINED"
 132     "LENGTH" "len" "l"
 133     "LOADADDR"
 134     "MAX"
 135     "MIN"
 136     "NEXT"
 137     "ORIGIN" "org" "o"
 138     "SEGMENT_START"
 139     "SIZEOF"
 140     "SIZEOF_HEADERS"
 141     "sizeof_headers")
 142   "Builtin functions of GNU ld script.")
 143
 144 (defvar ld-script-font-lock-keywords
 145   (append
 146    `((,(regexp-opt ld-script-keywords 'words)
 147       1 font-lock-keyword-face)
 148      (,(regexp-opt ld-script-builtins 'words)
 149       1 font-lock-builtin-face)
 150      ;; 3.6.7 Output Section Discarding
 151      ;; 3.6.4.1 Input Section Basics
 152      ;; 3.6.8.6 Output Section Phdr
 153      ("/DISCARD/\\|EXCLUDE_FILE\\|:NONE" . font-lock-warning-face)
 154      ("\\W\\(\\.\\)\\W" 1 ld-script-location-counter-face)
 155      )
 156    cpp-font-lock-keywords)
 157   "Default font-lock-keywords for `ld-script-mode'.")
 158
 159 ;;;###autoload
 160 (define-derived-mode ld-script-mode nil "LD-Script"
 161    "A major mode to edit GNU ld script files"
 162   (set (make-local-variable 'comment-start) "/* ")
 163   (set (make-local-variable 'comment-end)   " */")
 164   (set (make-local-variable 'font-lock-defaults)
 165        '(ld-script-font-lock-keywords nil)))
 166
 167 (provide 'ld-script)
 168
 169 ;;; ld-script.el ends here